PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12
  13 use PVE::OTP;
  14 use PVE::Ticket;
  15 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  16 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  17 use PVE::JSONSchema;
  18
  19 use PVE::Auth::Plugin;
  20 use PVE::Auth::AD;
  21 use PVE::Auth::LDAP;
  22 use PVE::Auth::PVE;
  23 use PVE::Auth::PAM;
  24
  25 # load and initialize all plugins
  26
  27 PVE::Auth::AD->register();
  28 PVE::Auth::LDAP->register();
  29 PVE::Auth::PVE->register();
  30 PVE::Auth::PAM->register();
  31 PVE::Auth::Plugin->init();
  32
  33 # $authdir must be writable by root only!
  34 my $confdir = "/etc/pve";
  35 my $authdir = "$confdir/priv";
  36 my $authprivkeyfn = "$authdir/authkey.key";
  37 my $authpubkeyfn = "$confdir/authkey.pub";
  38 my $pve_www_key_fn = "$confdir/pve-www.key";
  39
  40 my $ticket_lifetime = 3600*2; # 2 hours
  41
  42 Crypt::OpenSSL::RSA->import_random_seed();
  43
  44 cfs_register_file('user.cfg',
  45                   \&parse_user_config,
  46                   \&write_user_config);
  47
  48
  49 sub verify_username {
  50     PVE::Auth::Plugin::verify_username(@_);
  51 }
  52
  53 sub pve_verify_realm {
  54     PVE::Auth::Plugin::pve_verify_realm(@_);
  55 }
  56
  57 sub lock_user_config {
  58     my ($code, $errmsg) = @_;
  59
  60     cfs_lock_file("user.cfg", undef, $code);
  61     if (my $err = $@) {
  62         $errmsg ? die "$errmsg: $err" : die $err;
  63     }
  64 }
  65
  66 my $pve_auth_pub_key;
  67 sub get_pubkey {
  68
  69     return $pve_auth_pub_key if $pve_auth_pub_key;
  70
  71     my $input = PVE::Tools::file_get_contents($authpubkeyfn);
  72
  73     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
  74
  75     return $pve_auth_pub_key;
  76 }
  77
  78 my $csrf_prevention_secret;
  79 my $get_csrfr_secret = sub {
  80     if (!$csrf_prevention_secret) {
  81         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
  82         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
  83     }
  84     return $csrf_prevention_secret;
  85 };
  86
  87 sub assemble_csrf_prevention_token {
  88     my ($username) = @_;
  89
  90     my $secret =  &$get_csrfr_secret();
  91
  92     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
  93 }
  94
  95 sub verify_csrf_prevention_token {
  96     my ($username, $token, $noerr) = @_;
  97
  98     my $secret =  &$get_csrfr_secret();
  99
 100     return PVE::Ticket::verify_csrf_prevention_token(
 101         $secret, $username, $token, -300, $ticket_lifetime, $noerr);
 102 }
 103
 104 my $pve_auth_priv_key;
 105 sub get_privkey {
 106
 107     return $pve_auth_priv_key if $pve_auth_priv_key;
 108
 109     my $input = PVE::Tools::file_get_contents($authprivkeyfn);
 110
 111     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
 112
 113     return $pve_auth_priv_key;
 114 }
 115
 116 sub assemble_ticket {
 117     my ($username) = @_;
 118
 119     my $rsa_priv = get_privkey();
 120
 121     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $username);
 122 }
 123
 124 sub verify_ticket {
 125     my ($ticket, $noerr) = @_;
 126
 127     my $rsa_pub = get_pubkey();
 128
 129     my ($username, $age) = PVE::Ticket::verify_rsa_ticket(
 130         $rsa_pub, 'PVE', $ticket, undef, -300, $ticket_lifetime, $noerr);
 131
 132     return undef if $noerr && !defined($username);
 133
 134     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 135
 136     return wantarray ? ($username, $age) : $username;
 137 }
 138
 139 # VNC tickets
 140 # - they do not contain the username in plain text
 141 # - they are restricted to a specific resource path (example: '/vms/100')
 142 sub assemble_vnc_ticket {
 143     my ($username, $path) = @_;
 144
 145     my $rsa_priv = get_privkey();
 146
 147     $path = normalize_path($path);
 148
 149     my $secret_data = "$username:$path";
 150
 151     return PVE::Ticket::assemble_rsa_ticket(
 152         $rsa_priv, 'PVEVNC', undef, $secret_data);
 153 }
 154
 155 sub verify_vnc_ticket {
 156     my ($ticket, $username, $path, $noerr) = @_;
 157
 158     my $rsa_pub = get_pubkey();
 159
 160     my $secret_data = "$username:$path";
 161
 162     return PVE::Ticket::verify_rsa_ticket(
 163         $rsa_pub, 'PVEVNC', $ticket, $secret_data, -20, 40, $noerr);
 164 }
 165
 166 sub assemble_spice_ticket {
 167     my ($username, $vmid, $node) = @_;
 168
 169     my $secret = &$get_csrfr_secret();
 170
 171     return PVE::Ticket::assemble_spice_ticket(
 172         $secret, $username, $vmid, $node);
 173 }
 174
 175
 176 sub verify_spice_connect_url {
 177     my ($connect_str) = @_;
 178
 179     my $secret = &$get_csrfr_secret();
 180
 181     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 182 }
 183
 184 sub read_x509_subject_spice {
 185     my ($filename) = @_;
 186
 187     # read x509 subject
 188     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 189     die "Could not open $filename using OpenSSL\n"
 190         if !$bio;
 191
 192     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 193     Net::SSLeay::BIO_free($bio);
 194
 195     die "Could not parse X509 certificate in $filename\n"
 196         if !$x509;
 197
 198     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 199     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 200     Net::SSLeay::X509_free($x509);
 201
 202     # remote-viewer wants comma as seperator (not '/')
 203     $subject =~ s!^/!!;
 204     $subject =~ s!/(\w+=)!,$1!g;
 205
 206     return $subject;
 207 }
 208
 209 # helper to generate SPICE remote-viewer configuration
 210 sub remote_viewer_config {
 211     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 212
 213     if (!$proxy) {
 214         my $host = `hostname -f` || PVE::INotify::nodename();
 215         chomp $host;
 216         $proxy = $host;
 217     }
 218
 219     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 220
 221     my $filename = "/etc/pve/local/pve-ssl.pem";
 222     my $subject = read_x509_subject_spice($filename);
 223
 224     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 225     $cacert =~ s/\n/\\n/g;
 226
 227     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 228     my $config = {
 229         'secure-attention' => "Ctrl+Alt+Ins",
 230         'toggle-fullscreen' => "Shift+F11",
 231         'release-cursor' => "Ctrl+Alt+R",
 232         type => 'spice',
 233         title => $title,
 234         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 235         proxy => "http://$proxy:3128",
 236         'tls-port' => $port,
 237         'host-subject' => $subject,
 238         ca => $cacert,
 239         password => $ticket,
 240         'delete-this-file' => 1,
 241     };
 242
 243     return ($ticket, $proxyticket, $config);
 244 }
 245
 246 sub check_user_exist {
 247     my ($usercfg, $username, $noerr) = @_;
 248
 249     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 250     return undef if !$username;
 251
 252     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 253
 254     die "no such user ('$username')\n" if !$noerr;
 255
 256     return undef;
 257 }
 258
 259 sub check_user_enabled {
 260     my ($usercfg, $username, $noerr) = @_;
 261
 262     my $data = check_user_exist($usercfg, $username, $noerr);
 263     return undef if !$data;
 264
 265     return 1 if $data->{enable};
 266
 267     die "user '$username' is disabled\n" if !$noerr;
 268
 269     return undef;
 270 }
 271
 272 sub verify_one_time_pw {
 273     my ($usercfg, $username, $tfa_cfg, $otp) = @_;
 274
 275     my $type = $tfa_cfg->{type};
 276
 277     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 278
 279     # fixme: proxy support?
 280     my $proxy;
 281
 282     if ($type eq 'yubico') {
 283         my $keys = $usercfg->{users}->{$username}->{keys};
 284         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 285                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 286     } elsif ($type eq 'oath') {
 287         my $keys = $usercfg->{users}->{$username}->{keys};
 288         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 289     } else {
 290         die "unknown tfa type '$type'\n";
 291     }
 292 }
 293
 294 # password should be utf8 encoded
 295 # Note: some plugins delay/sleep if auth fails
 296 sub authenticate_user {
 297     my ($username, $password, $otp) = @_;
 298
 299     die "no username specified\n" if !$username;
 300
 301     my ($ruid, $realm);
 302
 303     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 304
 305     my $usercfg = cfs_read_file('user.cfg');
 306
 307     check_user_enabled($usercfg, $username);
 308
 309     my $ctime = time();
 310     my $expire = $usercfg->{users}->{$username}->{expire};
 311
 312     die "account expired\n" if $expire && ($expire < $ctime);
 313
 314     my $domain_cfg = cfs_read_file('domains.cfg');
 315
 316     my $cfg = $domain_cfg->{ids}->{$realm};
 317     die "auth domain '$realm' does not exists\n" if !$cfg;
 318     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 319     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 320
 321     if ($cfg->{tfa}) {
 322         my $tfa_cfg = PVE::Auth::Plugin::parse_tfa_config($cfg->{tfa});
 323         verify_one_time_pw($usercfg, $username, $tfa_cfg, $otp);
 324     }
 325
 326     return $username;
 327 }
 328
 329 sub domain_set_password {
 330     my ($realm, $username, $password) = @_;
 331
 332     die "no auth domain specified" if !$realm;
 333
 334     my $domain_cfg = cfs_read_file('domains.cfg');
 335
 336     my $cfg = $domain_cfg->{ids}->{$realm};
 337     die "auth domain '$realm' does not exist\n" if !$cfg;
 338     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 339     $plugin->store_password($cfg, $realm, $username, $password);
 340 }
 341
 342 sub add_user_group {
 343     my ($username, $usercfg, $group) = @_;
 344
 345     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 346     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 347 }
 348
 349 sub delete_user_group {
 350     my ($username, $usercfg) = @_;
 351
 352     foreach my $group (keys %{$usercfg->{groups}}) {
 353
 354         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 355             if $usercfg->{groups}->{$group}->{users}->{$username};
 356     }
 357 }
 358
 359 sub delete_user_acl {
 360     my ($username, $usercfg) = @_;
 361
 362     foreach my $acl (keys %{$usercfg->{acl}}) {
 363
 364         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 365             if $usercfg->{acl}->{$acl}->{users}->{$username};
 366     }
 367 }
 368
 369 sub delete_group_acl {
 370     my ($group, $usercfg) = @_;
 371
 372     foreach my $acl (keys %{$usercfg->{acl}}) {
 373
 374         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 375             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 376     }
 377 }
 378
 379 sub delete_pool_acl {
 380     my ($pool, $usercfg) = @_;
 381
 382     my $path = "/pool/$pool";
 383
 384     delete ($usercfg->{acl}->{$path})
 385 }
 386
 387 # we automatically create some predefined roles by splitting privs
 388 # into 3 groups (per category)
 389 # root: only root is allowed to do that
 390 # admin: an administrator can to that
 391 # user: a normal user/customer can to that
 392 my $privgroups = {
 393     VM => {
 394         root => [],
 395         admin => [
 396             'VM.Config.Disk',
 397             'VM.Config.CPU',
 398             'VM.Config.Memory',
 399             'VM.Config.Network',
 400             'VM.Config.HWType',
 401             'VM.Config.Options', # covers all other things
 402             'VM.Allocate',
 403             'VM.Clone',
 404             'VM.Migrate',
 405             'VM.Monitor',
 406             'VM.Snapshot',
 407         ],
 408         user => [
 409             'VM.Config.CDROM', # change CDROM media
 410             'VM.Console',
 411             'VM.Backup',
 412             'VM.PowerMgmt',
 413         ],
 414         audit => [
 415             'VM.Audit',
 416         ],
 417     },
 418     Sys => {
 419         root => [
 420             'Sys.PowerMgmt',
 421             'Sys.Modify', # edit/change node settings
 422         ],
 423         admin => [
 424             'Permissions.Modify',
 425             'Sys.Console',
 426             'Sys.Syslog',
 427         ],
 428         user => [],
 429         audit => [
 430             'Sys.Audit',
 431         ],
 432     },
 433     Datastore => {
 434         root => [],
 435         admin => [
 436             'Datastore.Allocate',
 437             'Datastore.AllocateTemplate',
 438         ],
 439         user => [
 440             'Datastore.AllocateSpace',
 441         ],
 442         audit => [
 443             'Datastore.Audit',
 444         ],
 445     },
 446     User => {
 447         root => [
 448             'Realm.Allocate',
 449         ],
 450         admin => [
 451             'User.Modify',
 452             'Group.Allocate', # edit/change group settings
 453             'Realm.AllocateUser',
 454         ],
 455         user => [],
 456         audit => [],
 457     },
 458     Pool => {
 459         root => [],
 460         admin => [
 461             'Pool.Allocate', # create/delete pools
 462         ],
 463         user => [],
 464         audit => [],
 465     },
 466 };
 467
 468 my $valid_privs = {};
 469
 470 my $special_roles = {
 471     'NoAccess' => {}, # no privileges
 472     'Administrator' => $valid_privs, # all privileges
 473 };
 474
 475 sub create_roles {
 476
 477     foreach my $cat (keys %$privgroups) {
 478         my $cd = $privgroups->{$cat};
 479         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 480                        @{$cd->{user}}, @{$cd->{audit}}) {
 481             $valid_privs->{$p} = 1;
 482         }
 483         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 484
 485             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 486             $special_roles->{"PVEAdmin"}->{$p} = 1;
 487         }
 488         if (scalar(@{$cd->{user}})) {
 489             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 490                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 491             }
 492         }
 493         foreach my $p (@{$cd->{audit}}) {
 494             $special_roles->{"PVEAuditor"}->{$p} = 1;
 495         }
 496     }
 497
 498     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
 499 };
 500
 501 create_roles();
 502
 503 sub role_is_special {
 504     my ($role) = @_;
 505     return exists $special_roles->{$role};
 506 }
 507
 508 sub add_role_privs {
 509     my ($role, $usercfg, $privs) = @_;
 510
 511     return if !$privs;
 512
 513     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 514
 515     foreach my $priv (split_list($privs)) {
 516         if (defined ($valid_privs->{$priv})) {
 517             $usercfg->{roles}->{$role}->{$priv} = 1;
 518         } else {
 519             die "invalid privilege '$priv'\n";
 520         }
 521     }
 522 }
 523
 524 sub normalize_path {
 525     my $path = shift;
 526
 527     $path =~ s|/+|/|g;
 528
 529     $path =~ s|/$||;
 530
 531     $path = '/' if !$path;
 532
 533     $path = "/$path" if $path !~ m|^/|;
 534
 535     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
 536
 537     return $path;
 538 }
 539
 540
 541 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 542 sub verify_groupname {
 543     my ($groupname, $noerr) = @_;
 544
 545     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 546
 547         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 548
 549         return undef;
 550     }
 551
 552     return $groupname;
 553 }
 554
 555 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 556 sub verify_rolename {
 557     my ($rolename, $noerr) = @_;
 558
 559     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 560
 561         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 562
 563         return undef;
 564     }
 565
 566     return $rolename;
 567 }
 568
 569 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
 570 sub verify_poolname {
 571     my ($poolname, $noerr) = @_;
 572
 573     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 574
 575         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 576
 577         return undef;
 578     }
 579
 580     return $poolname;
 581 }
 582
 583 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 584 sub verify_privname {
 585     my ($priv, $noerr) = @_;
 586
 587     if (!$valid_privs->{$priv}) {
 588         die "invalid privilege '$priv'\n" if !$noerr;
 589
 590         return undef;
 591     }
 592
 593     return $priv;
 594 }
 595
 596 sub userconfig_force_defaults {
 597     my ($cfg) = @_;
 598
 599     foreach my $r (keys %$special_roles) {
 600         $cfg->{roles}->{$r} = $special_roles->{$r};
 601     }
 602
 603     # add root user if not exists
 604     if (!$cfg->{users}->{'root@pam'}) {
 605         $cfg->{users}->{'root@pam'}->{enable} = 1;
 606     }
 607 }
 608
 609 sub parse_user_config {
 610     my ($filename, $raw) = @_;
 611
 612     my $cfg = {};
 613
 614     userconfig_force_defaults($cfg);
 615
 616     $raw = '' if !defined($raw);
 617     while ($raw =~ /^\s*(.+?)\s*$/gm) {
 618         my $line = $1;
 619         my @data;
 620
 621         foreach my $d (split (/:/, $line)) {
 622             $d =~ s/^\s+//;
 623             $d =~ s/\s+$//;
 624             push @data, $d
 625         }
 626
 627         my $et = shift @data;
 628
 629         if ($et eq 'user') {
 630             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
 631
 632             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
 633             if (!$realm) {
 634                 warn "user config - ignore user '$user' - invalid user name\n";
 635                 next;
 636             }
 637
 638             $enable = $enable ? 1 : 0;
 639
 640             $expire = 0 if !$expire;
 641
 642             if ($expire !~ m/^\d+$/) {
 643                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 644                 next;
 645             }
 646             $expire = int($expire);
 647
 648             #if (!verify_groupname ($group, 1)) {
 649             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
 650             #    next;
 651             #}
 652
 653             $cfg->{users}->{$user} = {
 654                 enable => $enable,
 655                 # group => $group,
 656             };
 657             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
 658             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
 659             $cfg->{users}->{$user}->{email} = $email;
 660             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 661             $cfg->{users}->{$user}->{expire} = $expire;
 662             # keys: allowed yubico key ids or oath secrets (base32 encoded)
 663             $cfg->{users}->{$user}->{keys} = $keys if $keys;
 664
 665             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
 666             #$cfg->{groups}->{$group}->{$user} = 1;
 667
 668         } elsif ($et eq 'group') {
 669             my ($group, $userlist, $comment) = @data;
 670
 671             if (!verify_groupname($group, 1)) {
 672                 warn "user config - ignore group '$group' - invalid characters in group name\n";
 673                 next;
 674             }
 675
 676             # make sure to add the group (even if there are no members)
 677             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
 678
 679             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 680
 681             foreach my $user (split_list($userlist)) {
 682
 683                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
 684                     warn "user config - ignore invalid group member '$user'\n";
 685                     next;
 686                 }
 687
 688                 if ($cfg->{users}->{$user}) { # user exists
 689                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
 690                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
 691                 } else {
 692                     warn "user config - ignore invalid group member '$user'\n";
 693                 }
 694             }
 695
 696         } elsif ($et eq 'role') {
 697             my ($role, $privlist) = @data;
 698
 699             if (!verify_rolename($role, 1)) {
 700                 warn "user config - ignore role '$role' - invalid characters in role name\n";
 701                 next;
 702             }
 703
 704             # make sure to add the role (even if there are no privileges)
 705             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
 706
 707             foreach my $priv (split_list($privlist)) {
 708                 if (defined ($valid_privs->{$priv})) {
 709                     $cfg->{roles}->{$role}->{$priv} = 1;
 710                 } else {
 711                     warn "user config - ignore invalid priviledge '$priv'\n";
 712                 }
 713             }
 714
 715         } elsif ($et eq 'acl') {
 716             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
 717
 718             if (my $path = normalize_path($pathtxt)) {
 719                 foreach my $role (split_list($rolelist)) {
 720
 721                     if (!verify_rolename($role, 1)) {
 722                         warn "user config - ignore invalid role name '$role' in acl\n";
 723                         next;
 724                     }
 725
 726                     foreach my $ug (split_list($uglist)) {
 727                         if ($ug =~ m/^@(\S+)$/) {
 728                             my $group = $1;
 729                             if ($cfg->{groups}->{$group}) { # group exists
 730                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
 731                             } else {
 732                                 warn "user config - ignore invalid acl group '$group'\n";
 733                             }
 734                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
 735                             if ($cfg->{users}->{$ug}) { # user exists
 736                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
 737                             } else {
 738                                 warn "user config - ignore invalid acl member '$ug'\n";
 739                             }
 740                         } else {
 741                             warn "user config - invalid user/group '$ug' in acl\n";
 742                         }
 743                     }
 744                 }
 745             } else {
 746                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
 747             }
 748         } elsif ($et eq 'pool') {
 749             my ($pool, $comment, $vmlist, $storelist) = @data;
 750
 751             if (!verify_poolname($pool, 1)) {
 752                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
 753                 next;
 754             }
 755
 756             # make sure to add the pool (even if there are no members)
 757             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
 758
 759             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 760
 761             foreach my $vmid (split_list($vmlist)) {
 762                 if ($vmid !~ m/^\d+$/) {
 763                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
 764                     next;
 765                 }
 766                 $vmid = int($vmid);
 767
 768                 if ($cfg->{vms}->{$vmid}) {
 769                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
 770                     next;
 771                 }
 772
 773                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
 774
 775                 # record vmid ==> pool relation
 776                 $cfg->{vms}->{$vmid} = $pool;
 777             }
 778
 779             foreach my $storeid (split_list($storelist)) {
 780                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
 781                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
 782                     next;
 783                 }
 784                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
 785             }
 786         } else {
 787             warn "user config - ignore config line: $line\n";
 788         }
 789     }
 790
 791     userconfig_force_defaults($cfg);
 792
 793     return $cfg;
 794 }
 795
 796 sub write_user_config {
 797     my ($filename, $cfg) = @_;
 798
 799     my $data = '';
 800
 801     foreach my $user (keys %{$cfg->{users}}) {
 802         my $d = $cfg->{users}->{$user};
 803         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
 804         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
 805         my $email = $d->{email} || '';
 806         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 807         my $expire = int($d->{expire} || 0);
 808         my $enable = $d->{enable} ? 1 : 0;
 809         my $keys = $d->{keys} ? $d->{keys} : '';
 810         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
 811     }
 812
 813     $data .= "\n";
 814
 815     foreach my $group (keys %{$cfg->{groups}}) {
 816         my $d = $cfg->{groups}->{$group};
 817         my $list = join (',', keys %{$d->{users}});
 818         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 819         $data .= "group:$group:$list:$comment:\n";
 820     }
 821
 822     $data .= "\n";
 823
 824     foreach my $pool (keys %{$cfg->{pools}}) {
 825         my $d = $cfg->{pools}->{$pool};
 826         my $vmlist = join (',', keys %{$d->{vms}});
 827         my $storelist = join (',', keys %{$d->{storage}});
 828         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 829         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
 830     }
 831
 832     $data .= "\n";
 833
 834     foreach my $role (keys %{$cfg->{roles}}) {
 835         next if $special_roles->{$role};
 836
 837         my $d = $cfg->{roles}->{$role};
 838         my $list = join (',', keys %$d);
 839         $data .= "role:$role:$list:\n";
 840     }
 841
 842     $data .= "\n";
 843
 844     foreach my $path (sort keys %{$cfg->{acl}}) {
 845         my $d = $cfg->{acl}->{$path};
 846
 847         my $ra = {};
 848
 849         foreach my $group (keys %{$d->{groups}}) {
 850             my $l0 = '';
 851             my $l1 = '';
 852             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
 853                 my $propagate = $d->{groups}->{$group}->{$role};
 854                 if ($propagate) {
 855                     $l1 .= ',' if $l1;
 856                     $l1 .= $role;
 857                 } else {
 858                     $l0 .= ',' if $l0;
 859                     $l0 .= $role;
 860                 }
 861             }
 862             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
 863             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
 864         }
 865
 866         foreach my $user (keys %{$d->{users}}) {
 867             # no need to save, because root is always 'Administrator'
 868             next if $user eq 'root@pam';
 869
 870             my $l0 = '';
 871             my $l1 = '';
 872             foreach my $role (sort keys %{$d->{users}->{$user}}) {
 873                 my $propagate = $d->{users}->{$user}->{$role};
 874                 if ($propagate) {
 875                     $l1 .= ',' if $l1;
 876                     $l1 .= $role;
 877                 } else {
 878                     $l0 .= ',' if $l0;
 879                     $l0 .= $role;
 880                 }
 881             }
 882             $ra->{0}->{$l0}->{$user} = 1 if $l0;
 883             $ra->{1}->{$l1}->{$user} = 1 if $l1;
 884         }
 885
 886         foreach my $rolelist (sort keys %{$ra->{0}}) {
 887             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
 888             $data .= "acl:0:$path:$uglist:$rolelist:\n";
 889         }
 890         foreach my $rolelist (sort keys %{$ra->{1}}) {
 891             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
 892             $data .= "acl:1:$path:$uglist:$rolelist:\n";
 893         }
 894     }
 895
 896     return $data;
 897 }
 898
 899 sub roles {
 900     my ($cfg, $user, $path) = @_;
 901
 902     # NOTE: we do not consider pools here.
 903     # You need to use $rpcenv->roles() instead if you want that.
 904
 905     return 'Administrator' if $user eq 'root@pam'; # root can do anything
 906
 907     my $perm = {};
 908
 909     foreach my $p (sort keys %{$cfg->{acl}}) {
 910         my $final = ($path eq $p);
 911
 912         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
 913
 914         my $acl = $cfg->{acl}->{$p};
 915
 916         #print "CHECKACL $path $p\n";
 917         #print "ACL $path = " . Dumper ($acl);
 918
 919         if (my $ri = $acl->{users}->{$user}) {
 920             my $new;
 921             foreach my $role (keys %$ri) {
 922                 my $propagate = $ri->{$role};
 923                 if ($final || $propagate) {
 924                     #print "APPLY ROLE $p $user $role\n";
 925                     $new = {} if !$new;
 926                     $new->{$role} = 1;
 927                 }
 928             }
 929             if ($new) {
 930                 $perm = $new; # overwrite previous settings
 931                 next; # user privs always override group privs
 932             }
 933         }
 934
 935         my $new;
 936         foreach my $g (keys %{$acl->{groups}}) {
 937             next if !$cfg->{groups}->{$g}->{users}->{$user};
 938             if (my $ri = $acl->{groups}->{$g}) {
 939                 foreach my $role (keys %$ri) {
 940                     my $propagate = $ri->{$role};
 941                     if ($final || $propagate) {
 942                         #print "APPLY ROLE $p \@$g $role\n";
 943                         $new = {} if !$new;
 944                         $new->{$role} = 1;
 945                     }
 946                 }
 947             }
 948         }
 949         if ($new) {
 950             $perm = $new; # overwrite previous settings
 951             next;
 952         }
 953     }
 954
 955     return ('NoAccess') if defined ($perm->{NoAccess});
 956     #return () if defined ($perm->{NoAccess});
 957
 958     #print "permission $user $path = " . Dumper ($perm);
 959
 960     my @ra = keys %$perm;
 961
 962     #print "roles $user $path = " . join (',', @ra) . "\n";
 963
 964     return @ra;
 965 }
 966
 967 sub permission {
 968     my ($cfg, $user, $path) = @_;
 969
 970     $user = PVE::Auth::Plugin::verify_username($user, 1);
 971     return {} if !$user;
 972
 973     my @ra = roles($cfg, $user, $path);
 974
 975     my $privs = {};
 976
 977     foreach my $role (@ra) {
 978         if (my $privset = $cfg->{roles}->{$role}) {
 979             foreach my $p (keys %$privset) {
 980                 $privs->{$p} = 1;
 981             }
 982         }
 983     }
 984
 985     #print "priviledges $user $path = " . Dumper ($privs);
 986
 987     return $privs;
 988 }
 989
 990 sub check_permissions {
 991     my ($username, $path, $privlist) = @_;
 992
 993     $path = normalize_path($path);
 994     my $usercfg = cfs_read_file('user.cfg');
 995     my $perm = permission($usercfg, $username, $path);
 996
 997     foreach my $priv (split_list($privlist)) {
 998         return undef if !$perm->{$priv};
 999     };
1000
1001     return 1;
1002 }
1003
1004 sub remove_vm_access {
1005     my ($vmid) = @_;
1006     my $delVMaccessFn = sub {
1007         my $usercfg = cfs_read_file("user.cfg");
1008         my $modified;
1009
1010         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1011             delete $usercfg->{acl}->{"/vms/$vmid"};
1012             $modified = 1;
1013         }
1014         if (my $pool = $usercfg->{vms}->{$vmid}) {
1015             if (my $data = $usercfg->{pools}->{$pool}) {
1016                 delete $data->{vms}->{$vmid};
1017                 delete $usercfg->{vms}->{$vmid};
1018                 $modified = 1;
1019             }
1020         }
1021         cfs_write_file("user.cfg", $usercfg) if $modified;
1022     };
1023
1024     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1025 }
1026
1027 sub remove_storage_access {
1028     my ($storeid) = @_;
1029
1030     my $deleteStorageAccessFn = sub {
1031         my $usercfg = cfs_read_file("user.cfg");
1032         my $modified;
1033
1034         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1035             delete $usercfg->{acl}->{"/storage/$storeid"};
1036             $modified = 1;
1037         }
1038         foreach my $pool (keys %{$usercfg->{pools}}) {
1039             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1040             $modified = 1;
1041         }
1042         cfs_write_file("user.cfg", $usercfg) if $modified;
1043     };
1044
1045     lock_user_config($deleteStorageAccessFn,
1046                      "access permissions cleanup for storage $storeid failed");
1047 }
1048
1049 sub add_vm_to_pool {
1050     my ($vmid, $pool) = @_;
1051
1052     my $addVMtoPoolFn = sub {
1053         my $usercfg = cfs_read_file("user.cfg");
1054         if (my $data = $usercfg->{pools}->{$pool}) {
1055             $data->{vms}->{$vmid} = 1;
1056             $usercfg->{vms}->{$vmid} = $pool;
1057             cfs_write_file("user.cfg", $usercfg);
1058         }
1059     };
1060
1061     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1062 }
1063
1064 sub remove_vm_from_pool {
1065     my ($vmid) = @_;
1066
1067     my $delVMfromPoolFn = sub {
1068         my $usercfg = cfs_read_file("user.cfg");
1069         if (my $pool = $usercfg->{vms}->{$vmid}) {
1070             if (my $data = $usercfg->{pools}->{$pool}) {
1071                 delete $data->{vms}->{$vmid};
1072                 delete $usercfg->{vms}->{$vmid};
1073                 cfs_write_file("user.cfg", $usercfg);
1074             }
1075         }
1076     };
1077
1078     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1079 }
1080
1081 # bash completion helpers
1082
1083 sub complete_username {
1084
1085     my $user_cfg = cfs_read_file('user.cfg');
1086
1087     return [ keys %{$user_cfg->{users}} ];
1088 }
1089
1090 sub complete_group {
1091
1092     my $user_cfg = cfs_read_file('user.cfg');
1093
1094     return [ keys %{$user_cfg->{groups}} ];
1095 }
1096
1097 sub complete_realm {
1098
1099     my $domain_cfg = cfs_read_file('domains.cfg');
1100
1101     return [ keys %{$domain_cfg->{ids}} ];
1102 }
1103
1104 1;