PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12 use IO::File;
  13 use File::stat;
  14 use JSON;
  15
  16 use PVE::OTP;
  17 use PVE::Ticket;
  18 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  19 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  20 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  21
  22 use PVE::Auth::Plugin;
  23 use PVE::Auth::AD;
  24 use PVE::Auth::LDAP;
  25 use PVE::Auth::PVE;
  26 use PVE::Auth::PAM;
  27
  28 # load and initialize all plugins
  29
  30 PVE::Auth::AD->register();
  31 PVE::Auth::LDAP->register();
  32 PVE::Auth::PVE->register();
  33 PVE::Auth::PAM->register();
  34 PVE::Auth::Plugin->init();
  35
  36 # $authdir must be writable by root only!
  37 my $confdir = "/etc/pve";
  38 my $authdir = "$confdir/priv";
  39
  40 my $pve_www_key_fn = "$confdir/pve-www.key";
  41
  42 my $pve_auth_key_files = {
  43     priv => "$authdir/authkey.key",
  44     pub =>  "$confdir/authkey.pub",
  45     pubold => "$confdir/authkey.pub.old",
  46 };
  47
  48 my $pve_auth_key_cache = {};
  49
  50 my $ticket_lifetime = 3600 * 2; # 2 hours
  51 my $authkey_lifetime = 3600 * 24; # rotate every 24 hours
  52
  53 Crypt::OpenSSL::RSA->import_random_seed();
  54
  55 cfs_register_file('user.cfg',
  56                   \&parse_user_config,
  57                   \&write_user_config);
  58 cfs_register_file('priv/tfa.cfg',
  59                   \&parse_priv_tfa_config,
  60                   \&write_priv_tfa_config);
  61
  62 sub verify_username {
  63     PVE::Auth::Plugin::verify_username(@_);
  64 }
  65
  66 sub pve_verify_realm {
  67     PVE::Auth::Plugin::pve_verify_realm(@_);
  68 }
  69
  70 sub lock_user_config {
  71     my ($code, $errmsg) = @_;
  72
  73     cfs_lock_file("user.cfg", undef, $code);
  74     if (my $err = $@) {
  75         $errmsg ? die "$errmsg: $err" : die $err;
  76     }
  77 }
  78
  79 my $cache_read_key = sub {
  80     my ($type) = @_;
  81
  82     my $path = $pve_auth_key_files->{$type};
  83
  84     my $read_key_and_mtime = sub {
  85         my $fh = IO::File->new($path, "r");
  86
  87         return undef if !defined($fh);
  88
  89         my $st = stat($fh);
  90         my $pem = PVE::Tools::safe_read_from($fh, 0, 0, $path);
  91
  92         close $fh;
  93
  94         my $key;
  95         if ($type eq 'pub' || $type eq 'pubold') {
  96             $key = eval { Crypt::OpenSSL::RSA->new_public_key($pem); };
  97         } elsif ($type eq 'priv') {
  98             $key = eval { Crypt::OpenSSL::RSA->new_private_key($pem); };
  99         } else {
 100             die "Invalid authkey type '$type'\n";
 101         }
 102
 103         return { key => $key, mtime => $st->mtime };
 104     };
 105
 106     if (!defined($pve_auth_key_cache->{$type})) {
 107         $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 108     } else {
 109         my $st = stat($path);
 110         if (!$st || $st->mtime != $pve_auth_key_cache->{$type}->{mtime}) {
 111             $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 112         }
 113     }
 114
 115     return $pve_auth_key_cache->{$type};
 116 };
 117
 118 sub get_pubkey {
 119     my ($old) = @_;
 120
 121     my $type = $old ? 'pubold' : 'pub';
 122
 123     my $res = $cache_read_key->($type);
 124     return undef if !defined($res);
 125
 126     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 127 }
 128
 129 sub get_privkey {
 130     my $res = $cache_read_key->('priv');
 131
 132     if (!defined($res) || !check_authkey(1)) {
 133         rotate_authkey();
 134         $res = $cache_read_key->('priv');
 135     }
 136
 137     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 138 }
 139
 140 sub check_authkey {
 141     my ($quiet) = @_;
 142
 143     # skip check if non-quorate, as rotation is not possible anyway
 144     return 1 if !PVE::Cluster::check_cfs_quorum(1);
 145
 146     my ($pub_key, $mtime) = get_pubkey();
 147     if (!$pub_key) {
 148         warn "auth key pair missing, generating new one..\n"  if !$quiet;
 149         return 0;
 150     } else {
 151         if (time() - $mtime >= $authkey_lifetime) {
 152             warn "auth key pair too old, rotating..\n" if !$quiet;;
 153             return 0;
 154         } else {
 155             warn "auth key new enough, skipping rotation\n" if !$quiet;;
 156             return 1;
 157         }
 158     }
 159 }
 160
 161 sub rotate_authkey {
 162     return if $authkey_lifetime == 0;
 163
 164     PVE::Cluster::cfs_lock_authkey(undef, sub {
 165         # re-check with lock to avoid double rotation in clusters
 166         return if check_authkey();
 167
 168         my $old = get_pubkey();
 169         my $new = Crypt::OpenSSL::RSA->generate_key(2048);
 170
 171         if ($old) {
 172             eval {
 173                 my $pem = $old->get_public_key_x509_string();
 174                 # mtime is used for caching and ticket age range calculation
 175                 PVE::Tools::file_set_contents($pve_auth_key_files->{pubold}, $pem);
 176             };
 177             die "Failed to store old auth key: $@\n" if $@;
 178         }
 179
 180         eval {
 181             my $pem = $new->get_public_key_x509_string();
 182             # mtime is used for caching and ticket age range calculation,
 183             # should be close to that of pubold above
 184             PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 185         };
 186         if ($@) {
 187             if ($old) {
 188                 warn "Failed to store new auth key - $@\n";
 189                 warn "Reverting to previous auth key\n";
 190                 eval {
 191                     my $pem = $old->get_public_key_x509_string();
 192                     PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 193                 };
 194                 die "Failed to restore old auth key: $@\n" if $@;
 195             } else {
 196                 die "Failed to store new auth key - $@\n";
 197             }
 198         }
 199
 200         eval {
 201             my $pem = $new->get_private_key_string();
 202             PVE::Tools::file_set_contents($pve_auth_key_files->{priv}, $pem);
 203         };
 204         if ($@) {
 205             warn "Failed to store new auth key - $@\n";
 206             warn "Deleting auth key to force regeneration\n";
 207             unlink $pve_auth_key_files->{pub};
 208             unlink $pve_auth_key_files->{priv};
 209         }
 210     });
 211     die $@ if $@;
 212 }
 213
 214 PVE::JSONSchema::register_standard_option('tokenid', {
 215     description => "API token identifier.",
 216     type => "string",
 217     format => "pve-tokenid",
 218 });
 219
 220 our $token_subid_regex = $PVE::Auth::Plugin::realm_regex;
 221
 222 # username@realm username realm tokenid
 223 our $token_full_regex = qr/((${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex}))!(${token_subid_regex})/;
 224
 225 our $userid_or_token_regex = qr/^$PVE::Auth::Plugin::user_regex\@$PVE::Auth::Plugin::realm_regex(?:!$token_subid_regex)?$/;
 226
 227 sub split_tokenid {
 228     my ($tokenid, $noerr) = @_;
 229
 230     if ($tokenid =~ /^${token_full_regex}$/) {
 231         return ($1, $4);
 232     }
 233
 234     die "'$tokenid' is not a valid token ID - not able to split into user and token parts\n" if !$noerr;
 235
 236     return undef;
 237 }
 238
 239 sub join_tokenid {
 240     my ($username, $tokensubid) = @_;
 241
 242     my $joined = "${username}!${tokensubid}";
 243
 244     return pve_verify_tokenid($joined);
 245 }
 246
 247 PVE::JSONSchema::register_format('pve-tokenid', \&pve_verify_tokenid);
 248 sub pve_verify_tokenid {
 249     my ($tokenid, $noerr) = @_;
 250
 251     if ($tokenid =~ /^${token_full_regex}$/) {
 252         return wantarray ? ($tokenid, $2, $3, $4) : $tokenid;
 253     }
 254
 255     die "value '$tokenid' does not look like a valid token ID\n" if !$noerr;
 256
 257     return undef;
 258 }
 259
 260
 261 my $csrf_prevention_secret;
 262 my $csrf_prevention_secret_legacy;
 263 my $get_csrfr_secret = sub {
 264     if (!$csrf_prevention_secret) {
 265         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
 266         $csrf_prevention_secret = Digest::SHA::hmac_sha256_base64($input);
 267         $csrf_prevention_secret_legacy = Digest::SHA::sha1_base64($input);
 268     }
 269     return $csrf_prevention_secret;
 270 };
 271
 272 sub assemble_csrf_prevention_token {
 273     my ($username) = @_;
 274
 275     my $secret =  &$get_csrfr_secret();
 276
 277     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
 278 }
 279
 280 sub verify_csrf_prevention_token {
 281     my ($username, $token, $noerr) = @_;
 282
 283     my $secret = $get_csrfr_secret->();
 284
 285     # FIXME: remove with PVE 7 and/or refactor all into PVE::Ticket ?
 286     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 287         my $sig = $2;
 288         if (length($sig) == 27) {
 289             # the legacy secret got populated by above get_csrfr_secret call
 290             $secret = $csrf_prevention_secret_legacy;
 291         }
 292     }
 293
 294     return PVE::Ticket::verify_csrf_prevention_token(
 295         $secret, $username, $token, -300, $ticket_lifetime, $noerr);
 296 }
 297
 298 my $get_ticket_age_range = sub {
 299     my ($now, $mtime, $rotated) = @_;
 300
 301     my $key_age = $now - $mtime;
 302     $key_age = 0 if $key_age < 0;
 303
 304     my $min = -300;
 305     my $max = $ticket_lifetime;
 306
 307     if ($rotated) {
 308         # ticket creation after rotation is not allowed
 309         $min = $key_age - 300;
 310     } else {
 311         if ($key_age > $authkey_lifetime && $authkey_lifetime > 0) {
 312             if (PVE::Cluster::check_cfs_quorum(1)) {
 313                 # key should have been rotated, clamp range accordingly
 314                 $min = $key_age - $authkey_lifetime;
 315             } else {
 316                 warn "Cluster not quorate - extending auth key lifetime!\n";
 317             }
 318         }
 319
 320         $max = $key_age + 300 if $key_age < $ticket_lifetime;
 321     }
 322
 323     return undef if $min > $ticket_lifetime;
 324     return ($min, $max);
 325 };
 326
 327 sub assemble_ticket {
 328     my ($data) = @_;
 329
 330     my $rsa_priv = get_privkey();
 331
 332     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $data);
 333 }
 334
 335 sub verify_ticket {
 336     my ($ticket, $noerr) = @_;
 337
 338     my $now = time();
 339
 340     my $check = sub {
 341         my ($old) = @_;
 342
 343         my ($rsa_pub, $rsa_mtime) = get_pubkey($old);
 344         return undef if !$rsa_pub;
 345
 346         my ($min, $max) = $get_ticket_age_range->($now, $rsa_mtime, $old);
 347         return undef if !defined($min);
 348
 349         return PVE::Ticket::verify_rsa_ticket(
 350             $rsa_pub, 'PVE', $ticket, undef, $min, $max, 1);
 351     };
 352
 353     my ($data, $age) = $check->();
 354
 355     # check with old, rotated key if current key failed
 356     ($data, $age) = $check->(1) if !defined($data);
 357
 358     my $auth_failure = sub {
 359         if ($noerr) {
 360             return undef;
 361         } else {
 362             # raise error via undef ticket
 363             PVE::Ticket::verify_rsa_ticket(undef, 'PVE');
 364         }
 365     };
 366
 367     if (!defined($data)) {
 368         return $auth_failure->();
 369     }
 370
 371     my ($username, $tfa_info);
 372     if ($data =~ m{^u2f!([^!]+)!([0-9a-zA-Z/.=_\-+]+)$}) {
 373         # Ticket for u2f-users:
 374         ($username, my $challenge) = ($1, $2);
 375         if ($challenge eq 'verified') {
 376             # u2f challenge was completed
 377             $challenge = undef;
 378         } elsif (!wantarray) {
 379             # The caller is not aware there could be an ongoing challenge,
 380             # so we treat this ticket as invalid:
 381             return $auth_failure->();
 382         }
 383         $tfa_info = {
 384             type => 'u2f',
 385             challenge => $challenge,
 386         };
 387     } elsif ($data =~ /^tfa!(.*)$/) {
 388         # TOTP and Yubico don't require a challenge so this is the generic
 389         # 'missing 2nd factor ticket'
 390         $username = $1;
 391         $tfa_info = { type => 'tfa' };
 392     } else {
 393         # Regular ticket (full access)
 394         $username = $data;
 395     }
 396
 397     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 398
 399     return wantarray ? ($username, $age, $tfa_info) : $username;
 400 }
 401
 402 # VNC tickets
 403 # - they do not contain the username in plain text
 404 # - they are restricted to a specific resource path (example: '/vms/100')
 405 sub assemble_vnc_ticket {
 406     my ($username, $path) = @_;
 407
 408     my $rsa_priv = get_privkey();
 409
 410     $path = normalize_path($path);
 411
 412     my $secret_data = "$username:$path";
 413
 414     return PVE::Ticket::assemble_rsa_ticket(
 415         $rsa_priv, 'PVEVNC', undef, $secret_data);
 416 }
 417
 418 sub verify_vnc_ticket {
 419     my ($ticket, $username, $path, $noerr) = @_;
 420
 421     my $secret_data = "$username:$path";
 422
 423     my ($rsa_pub, $rsa_mtime) = get_pubkey();
 424     if (!$rsa_pub || (time() - $rsa_mtime > $authkey_lifetime && $authkey_lifetime > 0)) {
 425         if ($noerr) {
 426             return undef;
 427         } else {
 428             # raise error via undef ticket
 429             PVE::Ticket::verify_rsa_ticket($rsa_pub, 'PVEVNC');
 430         }
 431     }
 432
 433     return PVE::Ticket::verify_rsa_ticket(
 434         $rsa_pub, 'PVEVNC', $ticket, $secret_data, -20, 40, $noerr);
 435 }
 436
 437 sub assemble_spice_ticket {
 438     my ($username, $vmid, $node) = @_;
 439
 440     my $secret = &$get_csrfr_secret();
 441
 442     return PVE::Ticket::assemble_spice_ticket(
 443         $secret, $username, $vmid, $node);
 444 }
 445
 446 sub verify_spice_connect_url {
 447     my ($connect_str) = @_;
 448
 449     my $secret = &$get_csrfr_secret();
 450
 451     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 452 }
 453
 454 sub read_x509_subject_spice {
 455     my ($filename) = @_;
 456
 457     # read x509 subject
 458     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 459     die "Could not open $filename using OpenSSL\n"
 460         if !$bio;
 461
 462     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 463     Net::SSLeay::BIO_free($bio);
 464
 465     die "Could not parse X509 certificate in $filename\n"
 466         if !$x509;
 467
 468     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 469     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 470     Net::SSLeay::X509_free($x509);
 471
 472     # remote-viewer wants comma as seperator (not '/')
 473     $subject =~ s!^/!!;
 474     $subject =~ s!/(\w+=)!,$1!g;
 475
 476     return $subject;
 477 }
 478
 479 # helper to generate SPICE remote-viewer configuration
 480 sub remote_viewer_config {
 481     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 482
 483     if (!$proxy) {
 484         my $host = `hostname -f` || PVE::INotify::nodename();
 485         chomp $host;
 486         $proxy = $host;
 487     }
 488
 489     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 490
 491     my $filename = "/etc/pve/local/pve-ssl.pem";
 492     my $subject = read_x509_subject_spice($filename);
 493
 494     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 495     $cacert =~ s/\n/\\n/g;
 496
 497     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 498     my $config = {
 499         'secure-attention' => "Ctrl+Alt+Ins",
 500         'toggle-fullscreen' => "Shift+F11",
 501         'release-cursor' => "Ctrl+Alt+R",
 502         type => 'spice',
 503         title => $title,
 504         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 505         proxy => "http://$proxy:3128",
 506         'tls-port' => $port,
 507         'host-subject' => $subject,
 508         ca => $cacert,
 509         password => $ticket,
 510         'delete-this-file' => 1,
 511     };
 512
 513     return ($ticket, $proxyticket, $config);
 514 }
 515
 516 sub check_user_exist {
 517     my ($usercfg, $username, $noerr) = @_;
 518
 519     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 520     return undef if !$username;
 521
 522     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 523
 524     die "no such user ('$username')\n" if !$noerr;
 525
 526     return undef;
 527 }
 528
 529 sub check_user_enabled {
 530     my ($usercfg, $username, $noerr) = @_;
 531
 532     my $data = check_user_exist($usercfg, $username, $noerr);
 533     return undef if !$data;
 534
 535     return 1 if $data->{enable};
 536
 537     die "user '$username' is disabled\n" if !$noerr;
 538
 539     return undef;
 540 }
 541
 542 sub check_token_exist {
 543     my ($usercfg, $username, $tokenid, $noerr) = @_;
 544
 545     my $user = check_user_exist($usercfg, $username, $noerr);
 546     return undef if !$user;
 547
 548     return $user->{tokens}->{$tokenid}
 549         if defined($user->{tokens}) && $user->{tokens}->{$tokenid};
 550
 551     die "no such token '$tokenid' for user '$username'\n" if !$noerr;
 552
 553     return undef;
 554 }
 555
 556 sub verify_one_time_pw {
 557     my ($type, $username, $keys, $tfa_cfg, $otp) = @_;
 558
 559     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 560
 561     # fixme: proxy support?
 562     my $proxy;
 563
 564     if ($type eq 'yubico') {
 565         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 566                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 567     } elsif ($type eq 'oath') {
 568         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 569     } else {
 570         die "unknown tfa type '$type'\n";
 571     }
 572 }
 573
 574 # password should be utf8 encoded
 575 # Note: some plugins delay/sleep if auth fails
 576 sub authenticate_user {
 577     my ($username, $password, $otp) = @_;
 578
 579     die "no username specified\n" if !$username;
 580
 581     my ($ruid, $realm);
 582
 583     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 584
 585     my $usercfg = cfs_read_file('user.cfg');
 586
 587     check_user_enabled($usercfg, $username);
 588
 589     my $ctime = time();
 590     my $expire = $usercfg->{users}->{$username}->{expire};
 591
 592     die "account expired\n" if $expire && ($expire < $ctime);
 593
 594     my $domain_cfg = cfs_read_file('domains.cfg');
 595
 596     my $cfg = $domain_cfg->{ids}->{$realm};
 597     die "auth domain '$realm' does not exist\n" if !$cfg;
 598     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 599     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 600
 601     my ($type, $tfa_data) = user_get_tfa($username, $realm);
 602     if ($type) {
 603         if ($type eq 'u2f') {
 604             # Note that if the user did not manage to complete the initial u2f registration
 605             # challenge we have a hash containing a 'challenge' entry in the user's tfa.cfg entry:
 606             $tfa_data = undef if exists $tfa_data->{challenge};
 607         } elsif (!defined($otp)) {
 608             # The user requires a 2nd factor but has not provided one. Return success but
 609             # don't clear $tfa_data.
 610         } else {
 611             my $keys = $tfa_data->{keys};
 612             my $tfa_cfg = $tfa_data->{config};
 613             verify_one_time_pw($type, $username, $keys, $tfa_cfg, $otp);
 614             $tfa_data = undef;
 615         }
 616
 617         # Return the type along with the rest:
 618         if ($tfa_data) {
 619             $tfa_data = {
 620                 type => $type,
 621                 data => $tfa_data,
 622             };
 623         }
 624     }
 625
 626     return wantarray ? ($username, $tfa_data) : $username;
 627 }
 628
 629 sub domain_set_password {
 630     my ($realm, $username, $password) = @_;
 631
 632     die "no auth domain specified" if !$realm;
 633
 634     my $domain_cfg = cfs_read_file('domains.cfg');
 635
 636     my $cfg = $domain_cfg->{ids}->{$realm};
 637     die "auth domain '$realm' does not exist\n" if !$cfg;
 638     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 639     $plugin->store_password($cfg, $realm, $username, $password);
 640 }
 641
 642 sub add_user_group {
 643     my ($username, $usercfg, $group) = @_;
 644
 645     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 646     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 647 }
 648
 649 sub delete_user_group {
 650     my ($username, $usercfg) = @_;
 651
 652     foreach my $group (keys %{$usercfg->{groups}}) {
 653
 654         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 655             if $usercfg->{groups}->{$group}->{users}->{$username};
 656     }
 657 }
 658
 659 sub delete_user_acl {
 660     my ($username, $usercfg) = @_;
 661
 662     foreach my $acl (keys %{$usercfg->{acl}}) {
 663
 664         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 665             if $usercfg->{acl}->{$acl}->{users}->{$username};
 666     }
 667 }
 668
 669 sub delete_group_acl {
 670     my ($group, $usercfg) = @_;
 671
 672     foreach my $acl (keys %{$usercfg->{acl}}) {
 673
 674         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 675             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 676     }
 677 }
 678
 679 sub delete_pool_acl {
 680     my ($pool, $usercfg) = @_;
 681
 682     my $path = "/pool/$pool";
 683
 684     delete ($usercfg->{acl}->{$path})
 685 }
 686
 687 # we automatically create some predefined roles by splitting privs
 688 # into 3 groups (per category)
 689 # root: only root is allowed to do that
 690 # admin: an administrator can to that
 691 # user: a normal user/customer can to that
 692 my $privgroups = {
 693     VM => {
 694         root => [],
 695         admin => [
 696             'VM.Config.Disk',
 697             'VM.Config.CPU',
 698             'VM.Config.Memory',
 699             'VM.Config.Network',
 700             'VM.Config.HWType',
 701             'VM.Config.Options', # covers all other things
 702             'VM.Allocate',
 703             'VM.Clone',
 704             'VM.Migrate',
 705             'VM.Monitor',
 706             'VM.Snapshot',
 707             'VM.Snapshot.Rollback',
 708         ],
 709         user => [
 710             'VM.Config.CDROM', # change CDROM media
 711             'VM.Console',
 712             'VM.Backup',
 713             'VM.PowerMgmt',
 714         ],
 715         audit => [
 716             'VM.Audit',
 717         ],
 718     },
 719     Sys => {
 720         root => [
 721             'Sys.PowerMgmt',
 722             'Sys.Modify', # edit/change node settings
 723         ],
 724         admin => [
 725             'Permissions.Modify',
 726             'Sys.Console',
 727             'Sys.Syslog',
 728         ],
 729         user => [],
 730         audit => [
 731             'Sys.Audit',
 732         ],
 733     },
 734     Datastore => {
 735         root => [],
 736         admin => [
 737             'Datastore.Allocate',
 738             'Datastore.AllocateTemplate',
 739         ],
 740         user => [
 741             'Datastore.AllocateSpace',
 742         ],
 743         audit => [
 744             'Datastore.Audit',
 745         ],
 746     },
 747     SDN => {
 748         root => [],
 749         admin => [
 750             'SDN.Allocate',
 751             'SDN.Audit',
 752         ],
 753         audit => [
 754             'SDN.Audit',
 755         ],
 756     },
 757     User => {
 758         root => [
 759             'Realm.Allocate',
 760         ],
 761         admin => [
 762             'User.Modify',
 763             'Group.Allocate', # edit/change group settings
 764             'Realm.AllocateUser',
 765         ],
 766         user => [],
 767         audit => [],
 768     },
 769     Pool => {
 770         root => [],
 771         admin => [
 772             'Pool.Allocate', # create/delete pools
 773         ],
 774         user => [],
 775         audit => [],
 776     },
 777 };
 778
 779 my $valid_privs = {};
 780
 781 my $special_roles = {
 782     'NoAccess' => {}, # no privileges
 783     'Administrator' => $valid_privs, # all privileges
 784 };
 785
 786 sub create_roles {
 787
 788     foreach my $cat (keys %$privgroups) {
 789         my $cd = $privgroups->{$cat};
 790         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 791                        @{$cd->{user}}, @{$cd->{audit}}) {
 792             $valid_privs->{$p} = 1;
 793         }
 794         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 795
 796             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 797             $special_roles->{"PVEAdmin"}->{$p} = 1;
 798         }
 799         if (scalar(@{$cd->{user}})) {
 800             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 801                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 802             }
 803         }
 804         foreach my $p (@{$cd->{audit}}) {
 805             $special_roles->{"PVEAuditor"}->{$p} = 1;
 806         }
 807     }
 808
 809     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
 810 };
 811
 812 create_roles();
 813
 814 sub create_priv_properties {
 815     my $properties = {};
 816     foreach my $priv (keys %$valid_privs) {
 817         $properties->{$priv} = {
 818             type => 'boolean',
 819             optional => 1,
 820         };
 821     }
 822     return $properties;
 823 }
 824
 825 sub role_is_special {
 826     my ($role) = @_;
 827     return (exists $special_roles->{$role}) ? 1 : 0;
 828 }
 829
 830 sub add_role_privs {
 831     my ($role, $usercfg, $privs) = @_;
 832
 833     return if !$privs;
 834
 835     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 836
 837     foreach my $priv (split_list($privs)) {
 838         if (defined ($valid_privs->{$priv})) {
 839             $usercfg->{roles}->{$role}->{$priv} = 1;
 840         } else {
 841             die "invalid privilege '$priv'\n";
 842         }
 843     }
 844 }
 845
 846 sub normalize_path {
 847     my $path = shift;
 848
 849     $path =~ s|/+|/|g;
 850
 851     $path =~ s|/$||;
 852
 853     $path = '/' if !$path;
 854
 855     $path = "/$path" if $path !~ m|^/|;
 856
 857     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
 858
 859     return $path;
 860 }
 861
 862 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 863 sub verify_groupname {
 864     my ($groupname, $noerr) = @_;
 865
 866     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 867
 868         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 869
 870         return undef;
 871     }
 872
 873     return $groupname;
 874 }
 875
 876 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 877 sub verify_rolename {
 878     my ($rolename, $noerr) = @_;
 879
 880     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 881
 882         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 883
 884         return undef;
 885     }
 886
 887     return $rolename;
 888 }
 889
 890 PVE::JSONSchema::register_format('pve-poolid', \&verify_poolname);
 891 sub verify_poolname {
 892     my ($poolname, $noerr) = @_;
 893
 894     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 895
 896         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 897
 898         return undef;
 899     }
 900
 901     return $poolname;
 902 }
 903
 904 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 905 sub verify_privname {
 906     my ($priv, $noerr) = @_;
 907
 908     if (!$valid_privs->{$priv}) {
 909         die "invalid privilege '$priv'\n" if !$noerr;
 910
 911         return undef;
 912     }
 913
 914     return $priv;
 915 }
 916
 917 sub userconfig_force_defaults {
 918     my ($cfg) = @_;
 919
 920     foreach my $r (keys %$special_roles) {
 921         $cfg->{roles}->{$r} = $special_roles->{$r};
 922     }
 923
 924     # add root user if not exists
 925     if (!$cfg->{users}->{'root@pam'}) {
 926         $cfg->{users}->{'root@pam'}->{enable} = 1;
 927     }
 928 }
 929
 930 sub parse_user_config {
 931     my ($filename, $raw) = @_;
 932
 933     my $cfg = {};
 934
 935     userconfig_force_defaults($cfg);
 936
 937     $raw = '' if !defined($raw);
 938     while ($raw =~ /^\s*(.+?)\s*$/gm) {
 939         my $line = $1;
 940         my @data;
 941
 942         foreach my $d (split (/:/, $line)) {
 943             $d =~ s/^\s+//;
 944             $d =~ s/\s+$//;
 945             push @data, $d
 946         }
 947
 948         my $et = shift @data;
 949
 950         if ($et eq 'user') {
 951             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
 952
 953             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
 954             if (!$realm) {
 955                 warn "user config - ignore user '$user' - invalid user name\n";
 956                 next;
 957             }
 958
 959             $enable = $enable ? 1 : 0;
 960
 961             $expire = 0 if !$expire;
 962
 963             if ($expire !~ m/^\d+$/) {
 964                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 965                 next;
 966             }
 967             $expire = int($expire);
 968
 969             #if (!verify_groupname ($group, 1)) {
 970             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
 971             #    next;
 972             #}
 973
 974             $cfg->{users}->{$user} = {
 975                 enable => $enable,
 976                 # group => $group,
 977             };
 978             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
 979             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
 980             $cfg->{users}->{$user}->{email} = $email;
 981             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 982             $cfg->{users}->{$user}->{expire} = $expire;
 983             # keys: allowed yubico key ids or oath secrets (base32 encoded)
 984             $cfg->{users}->{$user}->{keys} = $keys if $keys;
 985
 986             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
 987             #$cfg->{groups}->{$group}->{$user} = 1;
 988
 989         } elsif ($et eq 'group') {
 990             my ($group, $userlist, $comment) = @data;
 991
 992             if (!verify_groupname($group, 1)) {
 993                 warn "user config - ignore group '$group' - invalid characters in group name\n";
 994                 next;
 995             }
 996
 997             # make sure to add the group (even if there are no members)
 998             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
 999
1000             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1001
1002             foreach my $user (split_list($userlist)) {
1003
1004                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
1005                     warn "user config - ignore invalid group member '$user'\n";
1006                     next;
1007                 }
1008
1009                 if ($cfg->{users}->{$user}) { # user exists
1010                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
1011                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
1012                 } else {
1013                     warn "user config - ignore invalid group member '$user'\n";
1014                 }
1015             }
1016
1017         } elsif ($et eq 'role') {
1018             my ($role, $privlist) = @data;
1019
1020             if (!verify_rolename($role, 1)) {
1021                 warn "user config - ignore role '$role' - invalid characters in role name\n";
1022                 next;
1023             }
1024
1025             # make sure to add the role (even if there are no privileges)
1026             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
1027
1028             foreach my $priv (split_list($privlist)) {
1029                 if (defined ($valid_privs->{$priv})) {
1030                     $cfg->{roles}->{$role}->{$priv} = 1;
1031                 } else {
1032                     warn "user config - ignore invalid privilege '$priv'\n";
1033                 }
1034             }
1035
1036         } elsif ($et eq 'acl') {
1037             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
1038
1039             $propagate = $propagate ? 1 : 0;
1040
1041             if (my $path = normalize_path($pathtxt)) {
1042                 foreach my $role (split_list($rolelist)) {
1043
1044                     if (!verify_rolename($role, 1)) {
1045                         warn "user config - ignore invalid role name '$role' in acl\n";
1046                         next;
1047                     }
1048
1049                     foreach my $ug (split_list($uglist)) {
1050                         my ($group) = $ug =~ m/^@(\S+)$/;
1051
1052                         if ($group && verify_groupname($group, 1)) {
1053                             if ($cfg->{groups}->{$group}) { # group exists
1054                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
1055                             } else {
1056                                 warn "user config - ignore invalid acl group '$group'\n";
1057                             }
1058                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
1059                             if ($cfg->{users}->{$ug}) { # user exists
1060                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
1061                             } else {
1062                                 warn "user config - ignore invalid acl member '$ug'\n";
1063                             }
1064                         } elsif (my ($user, $token) = split_tokenid($ug, 1)) {
1065                             if (check_token_exist($cfg, $user, $token, 1)) {
1066                                 $cfg->{acl}->{$path}->{tokens}->{$ug}->{$role} = $propagate;
1067                             } else {
1068                                 warn "user config - ignore invalid acl token '$ug'\n";
1069                             }
1070                         } else {
1071                             warn "user config - invalid user/group '$ug' in acl\n";
1072                         }
1073                     }
1074                 }
1075             } else {
1076                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
1077             }
1078         } elsif ($et eq 'pool') {
1079             my ($pool, $comment, $vmlist, $storelist) = @data;
1080
1081             if (!verify_poolname($pool, 1)) {
1082                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
1083                 next;
1084             }
1085
1086             # make sure to add the pool (even if there are no members)
1087             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
1088
1089             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1090
1091             foreach my $vmid (split_list($vmlist)) {
1092                 if ($vmid !~ m/^\d+$/) {
1093                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
1094                     next;
1095                 }
1096                 $vmid = int($vmid);
1097
1098                 if ($cfg->{vms}->{$vmid}) {
1099                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
1100                     next;
1101                 }
1102
1103                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
1104
1105                 # record vmid ==> pool relation
1106                 $cfg->{vms}->{$vmid} = $pool;
1107             }
1108
1109             foreach my $storeid (split_list($storelist)) {
1110                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
1111                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
1112                     next;
1113                 }
1114                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1115             }
1116         } elsif ($et eq 'token') {
1117             my ($tokenid, $expire, $privsep, $comment) = @data;
1118
1119             my ($user, $token) = split_tokenid($tokenid, 1);
1120             if (!($user && $token)) {
1121                 warn "user config - ignore invalid tokenid '$tokenid'\n";
1122                 next;
1123             }
1124
1125             $privsep = $privsep ? 1 : 0;
1126
1127             $expire = 0 if !$expire;
1128
1129             if ($expire !~ m/^\d+$/) {
1130                 warn "user config - ignore token '$tokenid' - (illegal characters in expire '$expire')\n";
1131                 next;
1132             }
1133             $expire = int($expire);
1134
1135             if (my $user_cfg = $cfg->{users}->{$user}) { # user exists
1136                 $user_cfg->{tokens}->{$token} = {} if !$user_cfg->{tokens}->{$token};
1137                 my $token_cfg = $user_cfg->{tokens}->{$token};
1138                 $token_cfg->{privsep} = $privsep;
1139                 $token_cfg->{expire} = $expire;
1140                 $token_cfg->{comment} = PVE::Tools::decode_text($comment) if $comment;
1141             } else {
1142                 warn "user config - ignore token '$tokenid' - user does not exist\n";
1143             }
1144         } else {
1145             warn "user config - ignore config line: $line\n";
1146         }
1147     }
1148
1149     userconfig_force_defaults($cfg);
1150
1151     return $cfg;
1152 }
1153
1154 sub write_user_config {
1155     my ($filename, $cfg) = @_;
1156
1157     my $data = '';
1158
1159     foreach my $user (sort keys %{$cfg->{users}}) {
1160         my $d = $cfg->{users}->{$user};
1161         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1162         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1163         my $email = $d->{email} || '';
1164         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1165         my $expire = int($d->{expire} || 0);
1166         my $enable = $d->{enable} ? 1 : 0;
1167         my $keys = $d->{keys} ? $d->{keys} : '';
1168         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
1169
1170         my $user_tokens = $d->{tokens};
1171         foreach my $token (sort keys %$user_tokens) {
1172             my $td = $user_tokens->{$token};
1173             my $full_tokenid = join_tokenid($user, $token);
1174             my $comment = $td->{comment} ? PVE::Tools::encode_text($td->{comment}) : '';
1175             my $expire = int($td->{expire} || 0);
1176             my $privsep = $td->{privsep} ? 1 : 0;
1177             $data .= "token:$full_tokenid:$expire:$privsep:$comment:\n";
1178         }
1179     }
1180
1181     $data .= "\n";
1182
1183     foreach my $group (sort keys %{$cfg->{groups}}) {
1184         my $d = $cfg->{groups}->{$group};
1185         my $list = join (',', sort keys %{$d->{users}});
1186         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1187         $data .= "group:$group:$list:$comment:\n";
1188     }
1189
1190     $data .= "\n";
1191
1192     foreach my $pool (sort keys %{$cfg->{pools}}) {
1193         my $d = $cfg->{pools}->{$pool};
1194         my $vmlist = join (',', sort keys %{$d->{vms}});
1195         my $storelist = join (',', sort keys %{$d->{storage}});
1196         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1197         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1198     }
1199
1200     $data .= "\n";
1201
1202     foreach my $role (sort keys %{$cfg->{roles}}) {
1203         next if $special_roles->{$role};
1204
1205         my $d = $cfg->{roles}->{$role};
1206         my $list = join (',', sort keys %$d);
1207         $data .= "role:$role:$list:\n";
1208     }
1209
1210     $data .= "\n";
1211
1212     my $collect_rolelist_members = sub {
1213         my ($acl_members, $result, $prefix, $exclude) = @_;
1214
1215         foreach my $member (keys %$acl_members) {
1216             next if $exclude && $member eq $exclude;
1217
1218             my $l0 = '';
1219             my $l1 = '';
1220             foreach my $role (sort keys %{$acl_members->{$member}}) {
1221                 my $propagate = $acl_members->{$member}->{$role};
1222                 if ($propagate) {
1223                     $l1 .= ',' if $l1;
1224                     $l1 .= $role;
1225                 } else {
1226                     $l0 .= ',' if $l0;
1227                     $l0 .= $role;
1228                 }
1229             }
1230             $result->{0}->{$l0}->{"${prefix}${member}"} = 1 if $l0;
1231             $result->{1}->{$l1}->{"${prefix}${member}"} = 1 if $l1;
1232         }
1233     };
1234
1235     foreach my $path (sort keys %{$cfg->{acl}}) {
1236         my $d = $cfg->{acl}->{$path};
1237
1238         my $rolelist_members = {};
1239
1240         $collect_rolelist_members->($d->{'groups'}, $rolelist_members, '@');
1241
1242         # no need to save 'root@pam', it is always 'Administrator'
1243         $collect_rolelist_members->($d->{'users'}, $rolelist_members, '', 'root@pam');
1244
1245         $collect_rolelist_members->($d->{'tokens'}, $rolelist_members, '');
1246
1247         foreach my $propagate (0,1) {
1248             my $filtered = $rolelist_members->{$propagate};
1249             foreach my $rolelist (sort keys %$filtered) {
1250                 my $uglist = join (',', sort keys %{$filtered->{$rolelist}});
1251                 $data .= "acl:$propagate:$path:$uglist:$rolelist:\n";
1252             }
1253
1254         }
1255     }
1256
1257     return $data;
1258 }
1259
1260 # The TFA configuration in priv/tfa.cfg format contains one line per user of
1261 # the form:
1262 #     USER:TYPE:DATA
1263 # DATA is a base64 encoded json string and its format depends on the type.
1264 sub parse_priv_tfa_config {
1265     my ($filename, $raw) = @_;
1266
1267     my $users = {};
1268     my $cfg = { users => $users };
1269
1270     $raw = '' if !defined($raw);
1271     while ($raw =~ /^\s*(.+?)\s*$/gm) {
1272         my $line = $1;
1273         my ($user, $type, $data) = split(/:/, $line, 3);
1274
1275         my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1276         if (!$realm) {
1277             warn "user tfa config - ignore user '$user' - invalid user name\n";
1278             next;
1279         }
1280
1281         $data = decode_json(decode_base64($data));
1282
1283         $users->{$user} = {
1284             type => $type,
1285             data => $data,
1286         };
1287     }
1288
1289     return $cfg;
1290 }
1291
1292 sub write_priv_tfa_config {
1293     my ($filename, $cfg) = @_;
1294
1295     my $output = '';
1296
1297     my $users = $cfg->{users};
1298     foreach my $user (sort keys %$users) {
1299         my $info = $users->{$user};
1300         next if !%$info; # skip empty entries
1301
1302         $info = {%$info}; # copy to verify contents:
1303
1304         my $type = delete $info->{type};
1305         my $data = delete $info->{data};
1306
1307         if (my @keys = keys %$info) {
1308             die "invalid keys in TFA config for user $user: " . join(', ', @keys) . "\n";
1309         }
1310
1311         $data = encode_base64(encode_json($data), '');
1312         $output .= "${user}:${type}:${data}\n";
1313     }
1314
1315     return $output;
1316 }
1317
1318 sub roles {
1319     my ($cfg, $user, $path) = @_;
1320
1321     # NOTE: we do not consider pools here.
1322     # Use $rpcenv->permission() for any actual permission checks!
1323
1324     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1325
1326     my $perm = {};
1327
1328     foreach my $p (sort keys %{$cfg->{acl}}) {
1329         my $final = ($path eq $p);
1330
1331         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1332
1333         my $acl = $cfg->{acl}->{$p};
1334
1335         #print "CHECKACL $path $p\n";
1336         #print "ACL $path = " . Dumper ($acl);
1337
1338         if (my $ri = $acl->{users}->{$user}) {
1339             my $new;
1340             foreach my $role (keys %$ri) {
1341                 my $propagate = $ri->{$role};
1342                 if ($final || $propagate) {
1343                     #print "APPLY ROLE $p $user $role\n";
1344                     $new = {} if !$new;
1345                     $new->{$role} = 1;
1346                 }
1347             }
1348             if ($new) {
1349                 $perm = $new; # overwrite previous settings
1350                 next; # user privs always override group privs
1351             }
1352         }
1353
1354         my $new;
1355         foreach my $g (keys %{$acl->{groups}}) {
1356             next if !$cfg->{groups}->{$g}->{users}->{$user};
1357             if (my $ri = $acl->{groups}->{$g}) {
1358                 foreach my $role (keys %$ri) {
1359                     my $propagate = $ri->{$role};
1360                     if ($final || $propagate) {
1361                         #print "APPLY ROLE $p \@$g $role\n";
1362                         $new = {} if !$new;
1363                         $new->{$role} = 1;
1364                     }
1365                 }
1366             }
1367         }
1368         if ($new) {
1369             $perm = $new; # overwrite previous settings
1370             next;
1371         }
1372     }
1373
1374     return ('NoAccess') if defined ($perm->{NoAccess});
1375     #return () if defined ($perm->{NoAccess});
1376
1377     #print "permission $user $path = " . Dumper ($perm);
1378
1379     my @ra = keys %$perm;
1380
1381     #print "roles $user $path = " . join (',', @ra) . "\n";
1382
1383     return @ra;
1384 }
1385
1386 sub remove_vm_access {
1387     my ($vmid) = @_;
1388     my $delVMaccessFn = sub {
1389         my $usercfg = cfs_read_file("user.cfg");
1390         my $modified;
1391
1392         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1393             delete $usercfg->{acl}->{"/vms/$vmid"};
1394             $modified = 1;
1395         }
1396         if (my $pool = $usercfg->{vms}->{$vmid}) {
1397             if (my $data = $usercfg->{pools}->{$pool}) {
1398                 delete $data->{vms}->{$vmid};
1399                 delete $usercfg->{vms}->{$vmid};
1400                 $modified = 1;
1401             }
1402         }
1403         cfs_write_file("user.cfg", $usercfg) if $modified;
1404     };
1405
1406     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1407 }
1408
1409 sub remove_storage_access {
1410     my ($storeid) = @_;
1411
1412     my $deleteStorageAccessFn = sub {
1413         my $usercfg = cfs_read_file("user.cfg");
1414         my $modified;
1415
1416         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1417             delete $usercfg->{acl}->{"/storage/$storeid"};
1418             $modified = 1;
1419         }
1420         foreach my $pool (keys %{$usercfg->{pools}}) {
1421             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1422             $modified = 1;
1423         }
1424         cfs_write_file("user.cfg", $usercfg) if $modified;
1425     };
1426
1427     lock_user_config($deleteStorageAccessFn,
1428                      "access permissions cleanup for storage $storeid failed");
1429 }
1430
1431 sub add_vm_to_pool {
1432     my ($vmid, $pool) = @_;
1433
1434     my $addVMtoPoolFn = sub {
1435         my $usercfg = cfs_read_file("user.cfg");
1436         if (my $data = $usercfg->{pools}->{$pool}) {
1437             $data->{vms}->{$vmid} = 1;
1438             $usercfg->{vms}->{$vmid} = $pool;
1439             cfs_write_file("user.cfg", $usercfg);
1440         }
1441     };
1442
1443     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1444 }
1445
1446 sub remove_vm_from_pool {
1447     my ($vmid) = @_;
1448
1449     my $delVMfromPoolFn = sub {
1450         my $usercfg = cfs_read_file("user.cfg");
1451         if (my $pool = $usercfg->{vms}->{$vmid}) {
1452             if (my $data = $usercfg->{pools}->{$pool}) {
1453                 delete $data->{vms}->{$vmid};
1454                 delete $usercfg->{vms}->{$vmid};
1455                 cfs_write_file("user.cfg", $usercfg);
1456             }
1457         }
1458     };
1459
1460     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1461 }
1462
1463 my $USER_CONTROLLED_TFA_TYPES = {
1464     u2f => 1,
1465     oath => 1,
1466 };
1467
1468 # Delete an entry by setting $data=undef in which case $type is ignored.
1469 # Otherwise both must be valid.
1470 sub user_set_tfa {
1471     my ($userid, $realm, $type, $data, $cached_usercfg, $cached_domaincfg) = @_;
1472
1473     if (defined($data) && !defined($type)) {
1474         # This is an internal usage error and should not happen
1475         die "cannot set tfa data without a type\n";
1476     }
1477
1478     my $user_cfg = $cached_usercfg || cfs_read_file('user.cfg');
1479     my $user = $user_cfg->{users}->{$userid}
1480         or die "user '$userid' not found\n";
1481
1482     my $domain_cfg = $cached_domaincfg || cfs_read_file('domains.cfg');
1483     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1484     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1485
1486     my $realm_tfa = $realm_cfg->{tfa};
1487     if (defined($realm_tfa)) {
1488         $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa);
1489         # If the realm has a TFA setting, we're only allowed to use that.
1490         if (defined($data)) {
1491             my $required_type = $realm_tfa->{type};
1492             if ($required_type ne $type) {
1493                 die "realm '$realm' only allows TFA of type '$required_type\n";
1494             }
1495
1496             if (defined($data->{config})) {
1497                 # XXX: Is it enough if the type matches? Or should the configuration also match?
1498             }
1499
1500             # realm-configured tfa always uses a simple key list, so use the user.cfg
1501             $user->{keys} = $data->{keys};
1502         } else {
1503             die "realm '$realm' does not allow removing the 2nd factor\n";
1504         }
1505     } else {
1506         # Without a realm-enforced TFA setting the user can add a u2f or totp entry by themselves.
1507         # The 'yubico' type requires yubico server settings, which have to be configured on the
1508         # realm, so this is not supported here:
1509         die "domain '$realm' does not support TFA type '$type'\n"
1510             if defined($data) && !$USER_CONTROLLED_TFA_TYPES->{$type};
1511     }
1512
1513     # Custom TFA entries are stored in priv/tfa.cfg as they can be more complet: u2f uses a
1514     # public key and a key handle, TOTP requires the usual totp settings...
1515
1516     my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1517     my $tfa = ($tfa_cfg->{users}->{$userid} //= {});
1518
1519     if (defined($data)) {
1520         $tfa->{type} = $type;
1521         $tfa->{data} = $data;
1522         cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1523
1524         $user->{keys} = "x!$type";
1525     } else {
1526         delete $tfa_cfg->{users}->{$userid};
1527         cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1528
1529         delete $user->{keys};
1530     }
1531
1532     cfs_write_file('user.cfg', $user_cfg);
1533 }
1534
1535 sub user_get_tfa {
1536     my ($username, $realm) = @_;
1537
1538     my $user_cfg = cfs_read_file('user.cfg');
1539     my $user = $user_cfg->{users}->{$username}
1540         or die "user '$username' not found\n";
1541
1542     my $keys = $user->{keys};
1543
1544     my $domain_cfg = cfs_read_file('domains.cfg');
1545     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1546     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1547
1548     my $realm_tfa = $realm_cfg->{tfa};
1549     $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa)
1550         if $realm_tfa;
1551
1552     if (!$keys) {
1553         return if !$realm_tfa;
1554         die "missing required 2nd keys\n";
1555     }
1556
1557     # new style config starts with an 'x' and optionally contains a !<type> suffix
1558     if ($keys !~ /^x(?:!.*)?$/) {
1559         # old style config, find the type via the realm
1560         return if !$realm_tfa;
1561         return ($realm_tfa->{type}, {
1562             keys => $keys,
1563             config => $realm_tfa,
1564         });
1565     } else {
1566         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1567         my $tfa = $tfa_cfg->{users}->{$username};
1568         return if !$tfa; # should not happen (user.cfg wasn't cleaned up?)
1569
1570         if ($realm_tfa) {
1571             # if the realm has a tfa setting we need to verify the type:
1572             die "auth domain '$realm' and user have mismatching TFA settings\n"
1573                 if $realm_tfa && $realm_tfa->{type} ne $tfa->{type};
1574         }
1575
1576         return ($tfa->{type}, $tfa->{data});
1577     }
1578 }
1579
1580 # bash completion helpers
1581
1582 register_standard_option('userid-completed',
1583     get_standard_option('userid', { completion => \&complete_username}),
1584 );
1585
1586 sub complete_username {
1587
1588     my $user_cfg = cfs_read_file('user.cfg');
1589
1590     return [ keys %{$user_cfg->{users}} ];
1591 }
1592
1593 sub complete_group {
1594
1595     my $user_cfg = cfs_read_file('user.cfg');
1596
1597     return [ keys %{$user_cfg->{groups}} ];
1598 }
1599
1600 sub complete_realm {
1601
1602     my $domain_cfg = cfs_read_file('domains.cfg');
1603
1604     return [ keys %{$domain_cfg->{ids}} ];
1605 }
1606
1607 1;