src/PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base32;
  11 use MIME::Base64;
  12 use Digest::SHA;
  13 use IO::File;
  14 use File::stat;
  15 use JSON;
  16 use Scalar::Util 'weaken';
  17 use URI::Escape;
  18
  19 use PVE::OTP;
  20 use PVE::Ticket;
  21 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  22 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  23 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  24
  25 use PVE::RS::TFA;
  26
  27 use PVE::Auth::Plugin;
  28 use PVE::Auth::AD;
  29 use PVE::Auth::LDAP;
  30 use PVE::Auth::PVE;
  31 use PVE::Auth::PAM;
  32 use PVE::Auth::OpenId;
  33
  34 # load and initialize all plugins
  35
  36 PVE::Auth::AD->register();
  37 PVE::Auth::LDAP->register();
  38 PVE::Auth::PVE->register();
  39 PVE::Auth::PAM->register();
  40 PVE::Auth::OpenId->register();
  41 PVE::Auth::Plugin->init();
  42
  43 # $authdir must be writable by root only!
  44 my $confdir = "/etc/pve";
  45 my $authdir = "$confdir/priv";
  46
  47 my $pve_www_key_fn = "$confdir/pve-www.key";
  48
  49 my $pve_auth_key_files = {
  50     priv => "$authdir/authkey.key",
  51     pub =>  "$confdir/authkey.pub",
  52     pubold => "$confdir/authkey.pub.old",
  53 };
  54
  55 my $pve_auth_key_cache = {};
  56
  57 my $ticket_lifetime = 3600 * 2; # 2 hours
  58 my $auth_graceperiod = 60 * 5; # 5 minutes
  59 my $authkey_lifetime = 3600 * 24; # rotate every 24 hours
  60
  61 Crypt::OpenSSL::RSA->import_random_seed();
  62
  63 cfs_register_file('user.cfg', \&parse_user_config, \&write_user_config);
  64 cfs_register_file('priv/tfa.cfg', \&parse_priv_tfa_config, \&write_priv_tfa_config);
  65
  66 sub verify_username {
  67     PVE::Auth::Plugin::verify_username(@_);
  68 }
  69
  70 sub pve_verify_realm {
  71     PVE::Auth::Plugin::pve_verify_realm(@_);
  72 }
  73
  74 # Locking both config files together is only ever allowed in one order:
  75 #  1) tfa config
  76 #  2) user config
  77 # If we permit the other way round, too, we might end up deadlocking!
  78 my $user_config_locked;
  79 sub lock_user_config {
  80     my ($code, $errmsg) = @_;
  81
  82     my $locked = 1;
  83     $user_config_locked = \$locked;
  84     weaken $user_config_locked; # make this scope guard signal safe...
  85
  86     cfs_lock_file("user.cfg", undef, $code);
  87     $user_config_locked = undef;
  88     if (my $err = $@) {
  89         $errmsg ? die "$errmsg: $err" : die $err;
  90     }
  91 }
  92
  93 sub lock_tfa_config {
  94     my ($code, $errmsg) = @_;
  95
  96     die "tfa config lock cannot be acquired while holding user config lock\n"
  97         if ($user_config_locked && $$user_config_locked);
  98
  99     my $res = cfs_lock_file("priv/tfa.cfg", undef, $code);
 100     if (my $err = $@) {
 101         $errmsg ? die "$errmsg: $err" : die $err;
 102     }
 103
 104     return $res;
 105 }
 106
 107 my $cache_read_key = sub {
 108     my ($type) = @_;
 109
 110     my $path = $pve_auth_key_files->{$type};
 111
 112     my $read_key_and_mtime = sub {
 113         my $fh = IO::File->new($path, "r");
 114
 115         return undef if !defined($fh);
 116
 117         my $st = stat($fh);
 118         my $pem = PVE::Tools::safe_read_from($fh, 0, 0, $path);
 119
 120         close $fh;
 121
 122         my $key;
 123         if ($type eq 'pub' || $type eq 'pubold') {
 124             $key = eval { Crypt::OpenSSL::RSA->new_public_key($pem); };
 125         } elsif ($type eq 'priv') {
 126             $key = eval { Crypt::OpenSSL::RSA->new_private_key($pem); };
 127         } else {
 128             die "Invalid authkey type '$type'\n";
 129         }
 130
 131         return { key => $key, mtime => $st->mtime };
 132     };
 133
 134     if (!defined($pve_auth_key_cache->{$type})) {
 135         $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 136     } else {
 137         my $st = stat($path);
 138         if (!$st || $st->mtime != $pve_auth_key_cache->{$type}->{mtime}) {
 139             $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 140         }
 141     }
 142
 143     return $pve_auth_key_cache->{$type};
 144 };
 145
 146 sub get_pubkey {
 147     my ($old) = @_;
 148
 149     my $type = $old ? 'pubold' : 'pub';
 150
 151     my $res = $cache_read_key->($type);
 152     return undef if !defined($res);
 153
 154     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 155 }
 156
 157 sub get_privkey {
 158     my $res = $cache_read_key->('priv');
 159
 160     if (!defined($res) || !check_authkey(1)) {
 161         rotate_authkey();
 162         $res = $cache_read_key->('priv');
 163     }
 164
 165     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 166 }
 167
 168 sub check_authkey {
 169     my ($quiet) = @_;
 170
 171     # skip check if non-quorate, as rotation is not possible anyway
 172     return 1 if !PVE::Cluster::check_cfs_quorum(1);
 173
 174     my ($pub_key, $mtime) = get_pubkey();
 175     if (!$pub_key) {
 176         warn "auth key pair missing, generating new one..\n"  if !$quiet;
 177         return 0;
 178     } else {
 179         my $now = time();
 180         if ($now - $mtime >= $authkey_lifetime) {
 181             warn "auth key pair too old, rotating..\n" if !$quiet;;
 182             return 0;
 183         } elsif ($mtime > $now + $auth_graceperiod) {
 184             # a nodes RTC had a time set in the future during key generation -> ticket
 185             # validity is clamped to 0+5 min grace period until now >= mtime again
 186             my (undef, $old_mtime) = get_pubkey(1);
 187             if ($old_mtime && $mtime >= $old_mtime && $mtime - $old_mtime < $ticket_lifetime) {
 188                 warn "auth key pair generated in the future (key $mtime > host $now),"
 189                     ." but old key still exists and in valid grace period so avoid automatic"
 190                     ." fixup. Cluster time not in sync?\n" if !$quiet;
 191                 return 1;
 192             }
 193             warn "auth key pair generated in the future (key $mtime > host $now), rotating..\n" if !$quiet;
 194             return 0;
 195         } else {
 196             warn "auth key new enough, skipping rotation\n" if !$quiet;;
 197             return 1;
 198         }
 199     }
 200 }
 201
 202 sub rotate_authkey {
 203     return if $authkey_lifetime == 0;
 204
 205     PVE::Cluster::cfs_lock_authkey(undef, sub {
 206         # stat() calls might be answered from the kernel page cache for up to
 207         # 1s, so this special dance is needed to avoid a double rotation in
 208         # clusters *despite* the cfs_lock context..
 209
 210         # drop in-process cache hash
 211         $pve_auth_key_cache = {};
 212         # force open/close of file to invalidate page cache entry
 213         get_pubkey();
 214         # now re-check with lock held and page cache invalidated so that stat()
 215         # does the right thing, and any key updates by other nodes are visible.
 216         return if check_authkey();
 217
 218         my $old = get_pubkey();
 219         my $new = Crypt::OpenSSL::RSA->generate_key(2048);
 220
 221         if ($old) {
 222             eval {
 223                 my $pem = $old->get_public_key_x509_string();
 224                 # mtime is used for caching and ticket age range calculation
 225                 PVE::Tools::file_set_contents($pve_auth_key_files->{pubold}, $pem);
 226             };
 227             die "Failed to store old auth key: $@\n" if $@;
 228         }
 229
 230         eval {
 231             my $pem = $new->get_public_key_x509_string();
 232             # mtime is used for caching and ticket age range calculation,
 233             # should be close to that of pubold above
 234             PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 235         };
 236         if ($@) {
 237             if ($old) {
 238                 warn "Failed to store new auth key - $@\n";
 239                 warn "Reverting to previous auth key\n";
 240                 eval {
 241                     my $pem = $old->get_public_key_x509_string();
 242                     PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 243                 };
 244                 die "Failed to restore old auth key: $@\n" if $@;
 245             } else {
 246                 die "Failed to store new auth key - $@\n";
 247             }
 248         }
 249
 250         eval {
 251             my $pem = $new->get_private_key_string();
 252             PVE::Tools::file_set_contents($pve_auth_key_files->{priv}, $pem);
 253         };
 254         if ($@) {
 255             warn "Failed to store new auth key - $@\n";
 256             warn "Deleting auth key to force regeneration\n";
 257             unlink $pve_auth_key_files->{pub};
 258             unlink $pve_auth_key_files->{priv};
 259         }
 260     });
 261     die $@ if $@;
 262 }
 263
 264 PVE::JSONSchema::register_standard_option('tokenid', {
 265     description => "API token identifier.",
 266     type => "string",
 267     format => "pve-tokenid",
 268 });
 269
 270 our $token_subid_regex = $PVE::Auth::Plugin::realm_regex;
 271
 272 # username@realm username realm tokenid
 273 our $token_full_regex = qr/((${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex}))!(${token_subid_regex})/;
 274
 275 our $userid_or_token_regex = qr/^$PVE::Auth::Plugin::user_regex\@$PVE::Auth::Plugin::realm_regex(?:!$token_subid_regex)?$/;
 276
 277 sub split_tokenid {
 278     my ($tokenid, $noerr) = @_;
 279
 280     if ($tokenid =~ /^${token_full_regex}$/) {
 281         return ($1, $4);
 282     }
 283
 284     die "'$tokenid' is not a valid token ID - not able to split into user and token parts\n" if !$noerr;
 285
 286     return undef;
 287 }
 288
 289 sub join_tokenid {
 290     my ($username, $tokensubid) = @_;
 291
 292     my $joined = "${username}!${tokensubid}";
 293
 294     return pve_verify_tokenid($joined);
 295 }
 296
 297 PVE::JSONSchema::register_format('pve-tokenid', \&pve_verify_tokenid);
 298 sub pve_verify_tokenid {
 299     my ($tokenid, $noerr) = @_;
 300
 301     if ($tokenid =~ /^${token_full_regex}$/) {
 302         return wantarray ? ($tokenid, $2, $3, $4) : $tokenid;
 303     }
 304
 305     die "value '$tokenid' does not look like a valid token ID\n" if !$noerr;
 306
 307     return undef;
 308 }
 309
 310
 311 my $csrf_prevention_secret;
 312 my $csrf_prevention_secret_legacy;
 313 my $get_csrfr_secret = sub {
 314     if (!$csrf_prevention_secret) {
 315         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
 316         $csrf_prevention_secret = Digest::SHA::hmac_sha256_base64($input);
 317         $csrf_prevention_secret_legacy = Digest::SHA::sha1_base64($input);
 318     }
 319     return $csrf_prevention_secret;
 320 };
 321
 322 sub assemble_csrf_prevention_token {
 323     my ($username) = @_;
 324
 325     my $secret =  &$get_csrfr_secret();
 326
 327     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
 328 }
 329
 330 sub verify_csrf_prevention_token {
 331     my ($username, $token, $noerr) = @_;
 332
 333     my $secret = $get_csrfr_secret->();
 334
 335     # FIXME: remove with PVE 7 and/or refactor all into PVE::Ticket ?
 336     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 337         my $sig = $2;
 338         if (length($sig) == 27) {
 339             # the legacy secret got populated by above get_csrfr_secret call
 340             $secret = $csrf_prevention_secret_legacy;
 341         }
 342     }
 343
 344     return PVE::Ticket::verify_csrf_prevention_token(
 345         $secret, $username, $token, -$auth_graceperiod, $ticket_lifetime, $noerr);
 346 }
 347
 348 my $get_ticket_age_range = sub {
 349     my ($now, $mtime, $rotated) = @_;
 350
 351     my $key_age = $now - $mtime;
 352     $key_age = 0 if $key_age < 0;
 353
 354     my $min = -$auth_graceperiod;
 355     my $max = $ticket_lifetime;
 356
 357     if ($rotated) {
 358         # ticket creation after rotation is not allowed
 359         $min = $key_age - $auth_graceperiod;
 360     } else {
 361         if ($key_age > $authkey_lifetime && $authkey_lifetime > 0) {
 362             if (PVE::Cluster::check_cfs_quorum(1)) {
 363                 # key should have been rotated, clamp range accordingly
 364                 $min = $key_age - $authkey_lifetime;
 365             } else {
 366                 warn "Cluster not quorate - extending auth key lifetime!\n";
 367             }
 368         }
 369
 370         $max = $key_age + $auth_graceperiod if $key_age < $ticket_lifetime;
 371     }
 372
 373     return undef if $min > $ticket_lifetime;
 374     return ($min, $max);
 375 };
 376
 377 sub assemble_ticket : prototype($;$) {
 378     my ($data, $aad) = @_;
 379
 380     my $rsa_priv = get_privkey();
 381
 382     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $data, $aad);
 383 }
 384
 385 # Returns the username, "age" and tfa info.
 386 #
 387 # Note that for the new-style outh, tfa info is never set, as it only uses the `/ticket` api call
 388 # via the new 'tfa-challenge' parameter, so this part can go with PVE-8.
 389 #
 390 # New-style auth still uses this function, but sets `$tfa_ticket` to true when validating the tfa
 391 # ticket.
 392 sub verify_ticket : prototype($;$$) {
 393     my ($ticket, $noerr, $tfa_ticket_aad) = @_;
 394
 395     my $now = time();
 396
 397     my $check = sub {
 398         my ($old) = @_;
 399
 400         my ($rsa_pub, $rsa_mtime) = get_pubkey($old);
 401         return undef if !$rsa_pub;
 402
 403         my ($min, $max) = $get_ticket_age_range->($now, $rsa_mtime, $old);
 404         return undef if !defined($min);
 405
 406         return PVE::Ticket::verify_rsa_ticket(
 407             $rsa_pub, 'PVE', $ticket, $tfa_ticket_aad, $min, $max, 1);
 408     };
 409
 410     my ($data, $age) = $check->();
 411
 412     # check with old, rotated key if current key failed
 413     ($data, $age) = $check->(1) if !defined($data);
 414
 415     my $auth_failure = sub {
 416         if ($noerr) {
 417             return undef;
 418         } else {
 419             # raise error via undef ticket
 420             PVE::Ticket::verify_rsa_ticket(undef, 'PVE');
 421         }
 422     };
 423
 424     if (!defined($data)) {
 425         return $auth_failure->();
 426     }
 427
 428     if ($tfa_ticket_aad) {
 429         # We're validating a ticket-call's 'tfa-challenge' parameter, so just return its data.
 430         if ($data =~ /^!tfa!(.*)$/) {
 431             return $1;
 432         }
 433         die "bad ticket\n";
 434     }
 435
 436     my ($username, $tfa_info);
 437     if ($data =~ /^!tfa!(.*)$/) {
 438         # PBS style half-authenticated ticket, contains a json string form of a `TfaChallenge`
 439         # object.
 440         # This type of ticket does not contain the user name.
 441         return { type => 'new', data => $1 };
 442     }
 443     if ($data =~ m{^u2f!([^!]+)!([0-9a-zA-Z/.=_\-+]+)$}) {
 444         # Ticket for u2f-users:
 445         ($username, my $challenge) = ($1, $2);
 446         if ($challenge eq 'verified') {
 447             # u2f challenge was completed
 448             $challenge = undef;
 449         } elsif (!wantarray) {
 450             # The caller is not aware there could be an ongoing challenge,
 451             # so we treat this ticket as invalid:
 452             return $auth_failure->();
 453         }
 454         $tfa_info = {
 455             type => 'u2f',
 456             challenge => $challenge,
 457         };
 458     } elsif ($data =~ /^tfa!(.*)$/) {
 459         # TOTP and Yubico don't require a challenge so this is the generic
 460         # 'missing 2nd factor ticket'
 461         $username = $1;
 462         $tfa_info = { type => 'tfa' };
 463     } else {
 464         # Regular ticket (full access)
 465         $username = $data;
 466     }
 467
 468     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 469
 470     return wantarray ? ($username, $age, $tfa_info) : $username;
 471 }
 472
 473 sub verify_token {
 474     my ($api_token) = @_;
 475
 476     die "no API token specified\n" if !$api_token;
 477
 478     my ($tokenid, $value);
 479     if ($api_token =~ /^(.*)=(.*)$/) {
 480         $tokenid = $1;
 481         $value = $2;
 482     } else {
 483         die "no tokenid specified\n";
 484     }
 485
 486     my ($username, $token) = split_tokenid($tokenid);
 487
 488     my $usercfg = cfs_read_file('user.cfg');
 489     check_user_enabled($usercfg, $username);
 490     check_token_exist($usercfg, $username, $token);
 491
 492     my $user = $usercfg->{users}->{$username};
 493     my $token_info = $user->{tokens}->{$token};
 494
 495     my $ctime = time();
 496     die "token '$token' access expired\n" if $token_info->{expire} && ($token_info->{expire} < $ctime);
 497
 498     die "invalid token value!\n" if !PVE::Cluster::verify_token($tokenid, $value);
 499
 500     return wantarray ? ($tokenid) : $tokenid;
 501 }
 502
 503 my $assemble_short_lived_ticket = sub {
 504     my ($prefix, $username, $path) = @_;
 505
 506     my $rsa_priv = get_privkey();
 507
 508     $path = normalize_path($path);
 509
 510     die "invalid ticket path\n" if !defined($path);
 511
 512     my $secret_data = "$username:$path";
 513
 514     return PVE::Ticket::assemble_rsa_ticket(
 515         $rsa_priv, $prefix, undef, $secret_data);
 516 };
 517
 518 my $verify_short_lived_ticket = sub {
 519     my ($ticket, $prefix, $username, $path, $noerr) = @_;
 520
 521     $path = normalize_path($path);
 522
 523     die "invalid ticket path\n" if !defined($path);
 524
 525     my $secret_data = "$username:$path";
 526
 527     my ($rsa_pub, $rsa_mtime) = get_pubkey();
 528     if (!$rsa_pub || (time() - $rsa_mtime > $authkey_lifetime && $authkey_lifetime > 0)) {
 529         if ($noerr) {
 530             return undef;
 531         } else {
 532             # raise error via undef ticket
 533             PVE::Ticket::verify_rsa_ticket($rsa_pub, $prefix);
 534         }
 535     }
 536
 537     return PVE::Ticket::verify_rsa_ticket(
 538         $rsa_pub, $prefix, $ticket, $secret_data, -20, 40, $noerr);
 539 };
 540
 541 # VNC tickets
 542 # - they do not contain the username in plain text
 543 # - they are restricted to a specific resource path (example: '/vms/100')
 544 sub assemble_vnc_ticket {
 545     my ($username, $path) = @_;
 546
 547     return $assemble_short_lived_ticket->('PVEVNC', $username, $path);
 548 }
 549
 550 sub verify_vnc_ticket {
 551     my ($ticket, $username, $path, $noerr) = @_;
 552
 553     return $verify_short_lived_ticket->($ticket, 'PVEVNC', $username, $path, $noerr);
 554 }
 555
 556 # Tunnel tickets
 557 # - they do not contain the username in plain text
 558 # - they are restricted to a specific resource path (example: '/vms/100', '/socket/run/qemu-server/123.storage')
 559 sub assemble_tunnel_ticket {
 560     my ($username, $path) = @_;
 561
 562     return $assemble_short_lived_ticket->('PVETUNNEL', $username, $path);
 563 }
 564
 565 sub verify_tunnel_ticket {
 566     my ($ticket, $username, $path, $noerr) = @_;
 567
 568     return $verify_short_lived_ticket->($ticket, 'PVETUNNEL', $username, $path, $noerr);
 569 }
 570
 571 sub assemble_spice_ticket {
 572     my ($username, $vmid, $node) = @_;
 573
 574     my $secret = &$get_csrfr_secret();
 575
 576     return PVE::Ticket::assemble_spice_ticket(
 577         $secret, $username, $vmid, $node);
 578 }
 579
 580 sub verify_spice_connect_url {
 581     my ($connect_str) = @_;
 582
 583     my $secret = &$get_csrfr_secret();
 584
 585     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 586 }
 587
 588 sub read_x509_subject_spice {
 589     my ($filename) = @_;
 590
 591     # read x509 subject
 592     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 593     die "Could not open $filename using OpenSSL\n"
 594         if !$bio;
 595
 596     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 597     Net::SSLeay::BIO_free($bio);
 598
 599     die "Could not parse X509 certificate in $filename\n"
 600         if !$x509;
 601
 602     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 603     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 604     Net::SSLeay::X509_free($x509);
 605
 606     # remote-viewer wants comma as separator (not '/')
 607     $subject =~ s!^/!!;
 608     $subject =~ s!/(\w+=)!,$1!g;
 609
 610     return $subject;
 611 }
 612
 613 # helper to generate SPICE remote-viewer configuration
 614 sub remote_viewer_config {
 615     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 616
 617     if (!$proxy) {
 618         my $host = `hostname -f` || PVE::INotify::nodename();
 619         chomp $host;
 620         $proxy = $host;
 621     }
 622
 623     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 624
 625     my $filename = "/etc/pve/local/pve-ssl.pem";
 626     my $subject = read_x509_subject_spice($filename);
 627
 628     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 629     $cacert =~ s/\n/\\n/g;
 630
 631     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 632     my $config = {
 633         'secure-attention' => "Ctrl+Alt+Ins",
 634         'toggle-fullscreen' => "Shift+F11",
 635         'release-cursor' => "Ctrl+Alt+R",
 636         type => 'spice',
 637         title => $title,
 638         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 639         proxy => "http://$proxy:3128",
 640         'tls-port' => $port,
 641         'host-subject' => $subject,
 642         ca => $cacert,
 643         password => $ticket,
 644         'delete-this-file' => 1,
 645     };
 646
 647     return ($ticket, $proxyticket, $config);
 648 }
 649
 650 sub check_user_exist {
 651     my ($usercfg, $username, $noerr) = @_;
 652
 653     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 654     return undef if !$username;
 655
 656     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 657
 658     die "no such user ('$username')\n" if !$noerr;
 659
 660     return undef;
 661 }
 662
 663 sub check_user_enabled {
 664     my ($usercfg, $username, $noerr) = @_;
 665
 666     my $data = check_user_exist($usercfg, $username, $noerr);
 667     return undef if !$data;
 668
 669     if (!$data->{enable}) {
 670         die "user '$username' is disabled\n" if !$noerr;
 671         return undef;
 672     }
 673
 674     my $ctime = time();
 675     my $expire = $usercfg->{users}->{$username}->{expire};
 676
 677     if ($expire && $expire < $ctime) {
 678         die "user '$username' access expired\n" if !$noerr;
 679         return undef;
 680     }
 681
 682     return 1; # enabled and not expired
 683 }
 684
 685 sub check_token_exist {
 686     my ($usercfg, $username, $tokenid, $noerr) = @_;
 687
 688     my $user = check_user_exist($usercfg, $username, $noerr);
 689     return undef if !$user;
 690
 691     return $user->{tokens}->{$tokenid}
 692         if defined($user->{tokens}) && $user->{tokens}->{$tokenid};
 693
 694     die "no such token '$tokenid' for user '$username'\n" if !$noerr;
 695
 696     return undef;
 697 }
 698
 699 # deprecated
 700 sub verify_one_time_pw {
 701     my ($type, $username, $keys, $tfa_cfg, $otp) = @_;
 702
 703     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 704
 705     # fixme: proxy support?
 706     my $proxy;
 707
 708     if ($type eq 'yubico') {
 709         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 710                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 711     } elsif ($type eq 'oath') {
 712         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 713     } else {
 714         die "unknown tfa type '$type'\n";
 715     }
 716 }
 717
 718 # password should be utf8 encoded
 719 # Note: some plugins delay/sleep if auth fails
 720 sub authenticate_user : prototype($$$$;$) {
 721     my ($username, $password, $otp, $new_format, $tfa_challenge) = @_;
 722
 723     die "no username specified\n" if !$username;
 724
 725     my ($ruid, $realm);
 726
 727     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 728
 729     my $usercfg = cfs_read_file('user.cfg');
 730
 731     check_user_enabled($usercfg, $username);
 732
 733     my $domain_cfg = cfs_read_file('domains.cfg');
 734
 735     my $cfg = $domain_cfg->{ids}->{$realm};
 736     die "auth domain '$realm' does not exist\n" if !$cfg;
 737     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 738
 739     if ($tfa_challenge) {
 740         # This is the 2nd factor, use the password for the OTP response.
 741         my $tfa_challenge = authenticate_2nd_new($username, $realm, $password, $tfa_challenge);
 742         return wantarray ? ($username, $tfa_challenge) : $username;
 743     }
 744
 745     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 746
 747     if ($new_format) {
 748         # This is the first factor with an optional immediate 2nd factor for TOTP:
 749         my $tfa_challenge = authenticate_2nd_new($username, $realm, $otp, $tfa_challenge);
 750         return wantarray ? ($username, $tfa_challenge) : $username;
 751     } else {
 752         return authenticate_2nd_old($username, $realm, $otp);
 753     }
 754 }
 755
 756 sub authenticate_2nd_old : prototype($$$) {
 757     my ($username, $realm, $otp) = @_;
 758
 759     my ($type, $tfa_data) = user_get_tfa($username, $realm, 0);
 760     if ($type) {
 761         if ($type eq 'incompatible') {
 762             die "old login api disabled, user has incompatible TFA entries\n";
 763         } elsif ($type eq 'u2f') {
 764             # Note that if the user did not manage to complete the initial u2f registration
 765             # challenge we have a hash containing a 'challenge' entry in the user's tfa.cfg entry:
 766             $tfa_data = undef if exists $tfa_data->{challenge};
 767         } elsif (!defined($otp)) {
 768             # The user requires a 2nd factor but has not provided one. Return success but
 769             # don't clear $tfa_data.
 770         } else {
 771             my $keys = $tfa_data->{keys};
 772             my $tfa_cfg = $tfa_data->{config};
 773             verify_one_time_pw($type, $username, $keys, $tfa_cfg, $otp);
 774             $tfa_data = undef;
 775         }
 776
 777         # Return the type along with the rest:
 778         if ($tfa_data) {
 779             $tfa_data = {
 780                 type => $type,
 781                 data => $tfa_data,
 782             };
 783         }
 784     }
 785
 786     return wantarray ? ($username, $tfa_data) : $username;
 787 }
 788
 789 sub authenticate_2nd_new_do : prototype($$$$) {
 790     my ($username, $realm, $tfa_response, $tfa_challenge) = @_;
 791     my ($tfa_cfg, $realm_tfa) = user_get_tfa($username, $realm, 1);
 792
 793     if (!defined($tfa_cfg)) {
 794         return undef;
 795     }
 796
 797     my $realm_type = $realm_tfa && $realm_tfa->{type};
 798     # verify realm type unless using recovery keys:
 799     if (defined($realm_type)) {
 800         $realm_type = 'totp' if $realm_type eq 'oath'; # we used to call it that
 801         if ($realm_type eq 'yubico') {
 802             # Yubico auth will not be supported in rust for now...
 803             if (!defined($tfa_challenge)) {
 804                 my $challenge = { yubico => JSON::true };
 805                 # Even with yubico auth we do allow recovery keys to be used:
 806                 if (my $recovery = $tfa_cfg->recovery_state($username)) {
 807                     $challenge->{recovery} = $recovery;
 808                 }
 809                 return to_json($challenge);
 810             }
 811
 812             if ($tfa_response =~ /^yubico:(.*)$/) {
 813                 $tfa_response = $1;
 814                 # Defer to after unlocking the TFA config:
 815                 return sub {
 816                     authenticate_yubico_new(
 817                         $tfa_cfg, $username, $realm_tfa, $tfa_challenge, $tfa_response,
 818                     );
 819                 };
 820             }
 821         }
 822
 823         my $response_type;
 824         if (defined($tfa_response)) {
 825             if ($tfa_response !~ /^([^:]+):/) {
 826                 die "bad otp response\n";
 827             }
 828             $response_type = $1;
 829         }
 830
 831         die "realm requires $realm_type authentication\n"
 832             if $response_type && $response_type ne 'recovery' && $response_type ne $realm_type;
 833     }
 834
 835     configure_u2f_and_wa($tfa_cfg);
 836
 837     my $must_save = 0;
 838     if (defined($tfa_challenge)) {
 839         $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 840         $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $tfa_response);
 841         $tfa_challenge = undef;
 842     } else {
 843         $tfa_challenge = $tfa_cfg->authentication_challenge($username);
 844         if (defined($tfa_response)) {
 845             if (defined($tfa_challenge)) {
 846                 $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $tfa_response);
 847             } else {
 848                 die "no such challenge\n";
 849             }
 850         }
 851     }
 852
 853     if ($must_save) {
 854         cfs_write_file('priv/tfa.cfg', $tfa_cfg);
 855     }
 856
 857     return $tfa_challenge;
 858 }
 859
 860 # Returns a tfa challenge or undef.
 861 sub authenticate_2nd_new : prototype($$$$) {
 862     my ($username, $realm, $tfa_response, $tfa_challenge) = @_;
 863
 864     my $result;
 865
 866     if (defined($tfa_response) && $tfa_response =~ m/^recovery:/) {
 867         $result = lock_tfa_config(sub {
 868             authenticate_2nd_new_do($username, $realm, $tfa_response, $tfa_challenge);
 869         });
 870     } else {
 871         $result = authenticate_2nd_new_do($username, $realm, $tfa_response, $tfa_challenge);
 872     }
 873
 874     # Yubico auth returns the authentication sub:
 875     if (ref($result) eq 'CODE') {
 876         $result = $result->();
 877     }
 878
 879     return $result;
 880 }
 881
 882 sub authenticate_yubico_new : prototype($$$) {
 883     my ($tfa_cfg, $username, $realm, $tfa_challenge, $otp) = @_;
 884
 885     $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 886     $tfa_challenge = from_json($tfa_challenge);
 887
 888     if (!$tfa_challenge->{yubico}) {
 889         die "no such challenge\n";
 890     }
 891
 892     my $keys = $tfa_cfg->get_yubico_keys($username);
 893     die "no keys configured\n" if !defined($keys) || !length($keys);
 894
 895     authenticate_yubico_do($otp, $keys, $realm);
 896
 897     # return `undef` to clear the tfa challenge.
 898     return undef;
 899 }
 900
 901 sub authenticate_yubico_do : prototype($$$) {
 902     my ($value, $keys, $realm) = @_;
 903
 904     # fixme: proxy support?
 905     my $proxy = undef;
 906
 907     PVE::OTP::yubico_verify_otp($value, $keys, $realm->{url}, $realm->{id}, $realm->{key}, $proxy);
 908 }
 909
 910 sub configure_u2f_and_wa : prototype($) {
 911     my ($tfa_cfg) = @_;
 912
 913     my $rpc_origin;
 914     my $get_origin = sub {
 915         return $rpc_origin if defined($rpc_origin);
 916         my $rpcenv = PVE::RPCEnvironment::get();
 917         if (my $origin = $rpcenv->get_request_host(1)) {
 918             $rpc_origin = "https://$origin";
 919             return $rpc_origin;
 920         }
 921         die "failed to figure out origin\n";
 922     };
 923
 924     my $dc = cfs_read_file('datacenter.cfg');
 925     if (my $u2f = $dc->{u2f}) {
 926         eval {
 927             $tfa_cfg->set_u2f_config({
 928                 origin => $u2f->{origin} // $get_origin->(),
 929                 appid => $u2f->{appid},
 930             });
 931         };
 932         warn "u2f unavailable, configuration error: $@\n" if $@;
 933     }
 934     if (my $wa = $dc->{webauthn}) {
 935         $wa->{origin} //= $get_origin->();
 936         eval { $tfa_cfg->set_webauthn_config({%$wa}) };
 937         warn "webauthn unavailable, configuration error: $@\n" if $@;
 938     }
 939 }
 940
 941 sub domain_set_password {
 942     my ($realm, $username, $password) = @_;
 943
 944     die "no auth domain specified" if !$realm;
 945
 946     my $domain_cfg = cfs_read_file('domains.cfg');
 947
 948     my $cfg = $domain_cfg->{ids}->{$realm};
 949     die "auth domain '$realm' does not exist\n" if !$cfg;
 950     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 951     $plugin->store_password($cfg, $realm, $username, $password);
 952 }
 953
 954 sub add_user_group {
 955     my ($username, $usercfg, $group) = @_;
 956
 957     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 958     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 959 }
 960
 961 sub delete_user_group {
 962     my ($username, $usercfg) = @_;
 963
 964     foreach my $group (keys %{$usercfg->{groups}}) {
 965
 966         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 967             if $usercfg->{groups}->{$group}->{users}->{$username};
 968     }
 969 }
 970
 971 sub delete_user_acl {
 972     my ($username, $usercfg) = @_;
 973
 974     foreach my $acl (keys %{$usercfg->{acl}}) {
 975
 976         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 977             if $usercfg->{acl}->{$acl}->{users}->{$username};
 978     }
 979 }
 980
 981 sub delete_group_acl {
 982     my ($group, $usercfg) = @_;
 983
 984     foreach my $acl (keys %{$usercfg->{acl}}) {
 985
 986         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 987             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 988     }
 989 }
 990
 991 sub delete_pool_acl {
 992     my ($pool, $usercfg) = @_;
 993
 994     my $path = "/pool/$pool";
 995
 996     delete ($usercfg->{acl}->{$path})
 997 }
 998
 999 # we automatically create some predefined roles by splitting privs
1000 # into 3 groups (per category)
1001 # root: only root is allowed to do that
1002 # admin: an administrator can to that
1003 # user: a normal user/customer can to that
1004 my $privgroups = {
1005     VM => {
1006         root => [],
1007         admin => [
1008             'VM.Config.Disk',
1009             'VM.Config.CPU',
1010             'VM.Config.Memory',
1011             'VM.Config.Network',
1012             'VM.Config.HWType',
1013             'VM.Config.Options', # covers all other things
1014             'VM.Allocate',
1015             'VM.Clone',
1016             'VM.Migrate',
1017             'VM.Monitor',
1018             'VM.Snapshot',
1019             'VM.Snapshot.Rollback',
1020         ],
1021         user => [
1022             'VM.Config.CDROM', # change CDROM media
1023             'VM.Config.Cloudinit',
1024             'VM.Console',
1025             'VM.Backup',
1026             'VM.PowerMgmt',
1027         ],
1028         audit => [
1029             'VM.Audit',
1030         ],
1031     },
1032     Sys => {
1033         root => [
1034             'Sys.PowerMgmt',
1035             'Sys.Modify', # edit/change node settings
1036         ],
1037         admin => [
1038             'Permissions.Modify',
1039             'Sys.Console',
1040             'Sys.Syslog',
1041         ],
1042         user => [],
1043         audit => [
1044             'Sys.Audit',
1045         ],
1046     },
1047     Datastore => {
1048         root => [],
1049         admin => [
1050             'Datastore.Allocate',
1051             'Datastore.AllocateTemplate',
1052         ],
1053         user => [
1054             'Datastore.AllocateSpace',
1055         ],
1056         audit => [
1057             'Datastore.Audit',
1058         ],
1059     },
1060     SDN => {
1061         root => [],
1062         admin => [
1063             'SDN.Allocate',
1064             'SDN.Audit',
1065         ],
1066         audit => [
1067             'SDN.Audit',
1068         ],
1069     },
1070     User => {
1071         root => [
1072             'Realm.Allocate',
1073         ],
1074         admin => [
1075             'User.Modify',
1076             'Group.Allocate', # edit/change group settings
1077             'Realm.AllocateUser',
1078         ],
1079         user => [],
1080         audit => [],
1081     },
1082     Pool => {
1083         root => [],
1084         admin => [
1085             'Pool.Allocate', # create/delete pools
1086         ],
1087         user => [
1088             'Pool.Audit',
1089         ],
1090         audit => [
1091             'Pool.Audit',
1092         ],
1093     },
1094 };
1095
1096 my $valid_privs = {};
1097
1098 my $special_roles = {
1099     'NoAccess' => {}, # no privileges
1100     'Administrator' => $valid_privs, # all privileges
1101 };
1102
1103 sub create_roles {
1104
1105     foreach my $cat (keys %$privgroups) {
1106         my $cd = $privgroups->{$cat};
1107         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
1108                        @{$cd->{user}}, @{$cd->{audit}}) {
1109             $valid_privs->{$p} = 1;
1110         }
1111         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
1112
1113             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
1114             $special_roles->{"PVEAdmin"}->{$p} = 1;
1115         }
1116         if (scalar(@{$cd->{user}})) {
1117             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
1118                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
1119             }
1120         }
1121         foreach my $p (@{$cd->{audit}}) {
1122             $special_roles->{"PVEAuditor"}->{$p} = 1;
1123         }
1124     }
1125
1126     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
1127 };
1128
1129 create_roles();
1130
1131 sub create_priv_properties {
1132     my $properties = {};
1133     foreach my $priv (keys %$valid_privs) {
1134         $properties->{$priv} = {
1135             type => 'boolean',
1136             optional => 1,
1137         };
1138     }
1139     return $properties;
1140 }
1141
1142 sub role_is_special {
1143     my ($role) = @_;
1144     return (exists $special_roles->{$role}) ? 1 : 0;
1145 }
1146
1147 sub add_role_privs {
1148     my ($role, $usercfg, $privs) = @_;
1149
1150     return if !$privs;
1151
1152     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
1153
1154     foreach my $priv (split_list($privs)) {
1155         if (defined ($valid_privs->{$priv})) {
1156             $usercfg->{roles}->{$role}->{$priv} = 1;
1157         } else {
1158             die "invalid privilege '$priv'\n";
1159         }
1160     }
1161 }
1162
1163 sub lookup_username {
1164     my ($username, $noerr) = @_;
1165
1166     $username =~ m!^(${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex})$!;
1167
1168     my $realm = $2;
1169     my $domain_cfg = cfs_read_file("domains.cfg");
1170     my $casesensitive = $domain_cfg->{ids}->{$realm}->{'case-sensitive'} // 1;
1171     my $usercfg = cfs_read_file('user.cfg');
1172
1173     if (!$casesensitive) {
1174         my @matches = grep { lc $username eq lc $_ } (keys %{$usercfg->{users}});
1175
1176         die "ambiguous case insensitive match of username '$username', cannot safely grant access!\n"
1177             if scalar @matches > 1 && !$noerr;
1178
1179         return $matches[0]
1180     }
1181
1182     return $username;
1183 }
1184
1185 sub normalize_path {
1186     my $path = shift;
1187
1188     return undef if !$path;
1189
1190     $path =~ s|/+|/|g;
1191
1192     $path =~ s|/$||;
1193
1194     $path = '/' if !$path;
1195
1196     $path = "/$path" if $path !~ m|^/|;
1197
1198     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
1199
1200     return $path;
1201 }
1202
1203 sub check_path {
1204     my ($path) = @_;
1205     return $path =~ m!^(
1206         /
1207         |/access
1208         |/access/groups
1209         |/access/groups/[[:alnum:]\.\-\_]+
1210         |/access/realm
1211         |/access/realm/[[:alnum:]\.\-\_]+
1212         |/nodes
1213         |/nodes/[[:alnum:]\.\-\_]+
1214         |/pool
1215         |/pool/[[:alnum:]\.\-\_]+
1216         |/sdn
1217         |/sdn/zones/[[:alnum:]\.\-\_]+
1218         |/sdn/vnets/[[:alnum:]\.\-\_]+
1219         |/storage
1220         |/storage/[[:alnum:]\.\-\_]+
1221         |/vms
1222         |/vms/[1-9][0-9]{2,}
1223     )$!xs;
1224 }
1225
1226 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
1227 sub verify_groupname {
1228     my ($groupname, $noerr) = @_;
1229
1230     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1231
1232         die "group name '$groupname' contains invalid characters\n" if !$noerr;
1233
1234         return undef;
1235     }
1236
1237     return $groupname;
1238 }
1239
1240 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
1241 sub verify_rolename {
1242     my ($rolename, $noerr) = @_;
1243
1244     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
1245
1246         die "role name '$rolename' contains invalid characters\n" if !$noerr;
1247
1248         return undef;
1249     }
1250
1251     return $rolename;
1252 }
1253
1254 PVE::JSONSchema::register_format('pve-poolid', \&verify_poolname);
1255 sub verify_poolname {
1256     my ($poolname, $noerr) = @_;
1257
1258     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1259
1260         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
1261
1262         return undef;
1263     }
1264
1265     return $poolname;
1266 }
1267
1268 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
1269 sub verify_privname {
1270     my ($priv, $noerr) = @_;
1271
1272     if (!$valid_privs->{$priv}) {
1273         die "invalid privilege '$priv'\n" if !$noerr;
1274
1275         return undef;
1276     }
1277
1278     return $priv;
1279 }
1280
1281 sub userconfig_force_defaults {
1282     my ($cfg) = @_;
1283
1284     foreach my $r (keys %$special_roles) {
1285         $cfg->{roles}->{$r} = $special_roles->{$r};
1286     }
1287
1288     # add root user if not exists
1289     if (!$cfg->{users}->{'root@pam'}) {
1290         $cfg->{users}->{'root@pam'}->{enable} = 1;
1291     }
1292 }
1293
1294 sub parse_user_config {
1295     my ($filename, $raw) = @_;
1296
1297     my $cfg = {};
1298
1299     userconfig_force_defaults($cfg);
1300
1301     $raw = '' if !defined($raw);
1302     while ($raw =~ /^\s*(.+?)\s*$/gm) {
1303         my $line = $1;
1304         my @data;
1305
1306         foreach my $d (split (/:/, $line)) {
1307             $d =~ s/^\s+//;
1308             $d =~ s/\s+$//;
1309             push @data, $d
1310         }
1311
1312         my $et = shift @data;
1313
1314         if ($et eq 'user') {
1315             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
1316
1317             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1318             if (!$realm) {
1319                 warn "user config - ignore user '$user' - invalid user name\n";
1320                 next;
1321             }
1322
1323             $enable = $enable ? 1 : 0;
1324
1325             $expire = 0 if !$expire;
1326
1327             if ($expire !~ m/^\d+$/) {
1328                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
1329                 next;
1330             }
1331             $expire = int($expire);
1332
1333             #if (!verify_groupname ($group, 1)) {
1334             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
1335             #    next;
1336             #}
1337
1338             $cfg->{users}->{$user} = {
1339                 enable => $enable,
1340                 # group => $group,
1341             };
1342             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
1343             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
1344             $cfg->{users}->{$user}->{email} = $email;
1345             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1346             $cfg->{users}->{$user}->{expire} = $expire;
1347             # keys: allowed yubico key ids or oath secrets (base32 encoded)
1348             $cfg->{users}->{$user}->{keys} = $keys if $keys;
1349
1350             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
1351             #$cfg->{groups}->{$group}->{$user} = 1;
1352
1353         } elsif ($et eq 'group') {
1354             my ($group, $userlist, $comment) = @data;
1355
1356             if (!verify_groupname($group, 1)) {
1357                 warn "user config - ignore group '$group' - invalid characters in group name\n";
1358                 next;
1359             }
1360
1361             # make sure to add the group (even if there are no members)
1362             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
1363
1364             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1365
1366             foreach my $user (split_list($userlist)) {
1367
1368                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
1369                     warn "user config - ignore invalid group member '$user'\n";
1370                     next;
1371                 }
1372
1373                 if ($cfg->{users}->{$user}) { # user exists
1374                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
1375                 } else {
1376                     warn "user config - ignore invalid group member '$user'\n";
1377                 }
1378                 $cfg->{groups}->{$group}->{users}->{$user} = 1;
1379             }
1380
1381         } elsif ($et eq 'role') {
1382             my ($role, $privlist) = @data;
1383
1384             if (!verify_rolename($role, 1)) {
1385                 warn "user config - ignore role '$role' - invalid characters in role name\n";
1386                 next;
1387             }
1388
1389             # make sure to add the role (even if there are no privileges)
1390             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
1391
1392             foreach my $priv (split_list($privlist)) {
1393                 if (defined ($valid_privs->{$priv})) {
1394                     $cfg->{roles}->{$role}->{$priv} = 1;
1395                 } else {
1396                     warn "user config - ignore invalid privilege '$priv'\n";
1397                 }
1398             }
1399
1400         } elsif ($et eq 'acl') {
1401             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
1402
1403             $propagate = $propagate ? 1 : 0;
1404
1405             if (my $path = normalize_path($pathtxt)) {
1406                 foreach my $role (split_list($rolelist)) {
1407
1408                     if (!verify_rolename($role, 1)) {
1409                         warn "user config - ignore invalid role name '$role' in acl\n";
1410                         next;
1411                     }
1412
1413                     if (!$cfg->{roles}->{$role}) {
1414                         warn "user config - ignore invalid acl role '$role'\n";
1415                         next;
1416                     }
1417
1418                     foreach my $ug (split_list($uglist)) {
1419                         my ($group) = $ug =~ m/^@(\S+)$/;
1420
1421                         if ($group && verify_groupname($group, 1)) {
1422                             if (!$cfg->{groups}->{$group}) { # group does not exist
1423                                 warn "user config - ignore invalid acl group '$group'\n";
1424                             }
1425                             $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
1426                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
1427                             if (!$cfg->{users}->{$ug}) { # user does not exist
1428                                 warn "user config - ignore invalid acl member '$ug'\n";
1429                             }
1430                             $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
1431                         } elsif (my ($user, $token) = split_tokenid($ug, 1)) {
1432                             if (check_token_exist($cfg, $user, $token, 1)) {
1433                                 $cfg->{acl}->{$path}->{tokens}->{$ug}->{$role} = $propagate;
1434                             } else {
1435                                 warn "user config - ignore invalid acl token '$ug'\n";
1436                             }
1437                         } else {
1438                             warn "user config - invalid user/group '$ug' in acl\n";
1439                         }
1440                     }
1441                 }
1442             } else {
1443                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
1444             }
1445         } elsif ($et eq 'pool') {
1446             my ($pool, $comment, $vmlist, $storelist) = @data;
1447
1448             if (!verify_poolname($pool, 1)) {
1449                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
1450                 next;
1451             }
1452
1453             # make sure to add the pool (even if there are no members)
1454             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
1455
1456             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1457
1458             foreach my $vmid (split_list($vmlist)) {
1459                 if ($vmid !~ m/^\d+$/) {
1460                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
1461                     next;
1462                 }
1463                 $vmid = int($vmid);
1464
1465                 if ($cfg->{vms}->{$vmid}) {
1466                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
1467                     next;
1468                 }
1469
1470                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
1471
1472                 # record vmid ==> pool relation
1473                 $cfg->{vms}->{$vmid} = $pool;
1474             }
1475
1476             foreach my $storeid (split_list($storelist)) {
1477                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
1478                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
1479                     next;
1480                 }
1481                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1482             }
1483         } elsif ($et eq 'token') {
1484             my ($tokenid, $expire, $privsep, $comment) = @data;
1485
1486             my ($user, $token) = split_tokenid($tokenid, 1);
1487             if (!($user && $token)) {
1488                 warn "user config - ignore invalid tokenid '$tokenid'\n";
1489                 next;
1490             }
1491
1492             $privsep = $privsep ? 1 : 0;
1493
1494             $expire = 0 if !$expire;
1495
1496             if ($expire !~ m/^\d+$/) {
1497                 warn "user config - ignore token '$tokenid' - (illegal characters in expire '$expire')\n";
1498                 next;
1499             }
1500             $expire = int($expire);
1501
1502             if (my $user_cfg = $cfg->{users}->{$user}) { # user exists
1503                 $user_cfg->{tokens}->{$token} = {} if !$user_cfg->{tokens}->{$token};
1504                 my $token_cfg = $user_cfg->{tokens}->{$token};
1505                 $token_cfg->{privsep} = $privsep;
1506                 $token_cfg->{expire} = $expire;
1507                 $token_cfg->{comment} = PVE::Tools::decode_text($comment) if $comment;
1508             } else {
1509                 warn "user config - ignore token '$tokenid' - user does not exist\n";
1510             }
1511         } else {
1512             warn "user config - ignore config line: $line\n";
1513         }
1514     }
1515
1516     userconfig_force_defaults($cfg);
1517
1518     return $cfg;
1519 }
1520
1521 sub write_user_config {
1522     my ($filename, $cfg) = @_;
1523
1524     my $data = '';
1525
1526     foreach my $user (sort keys %{$cfg->{users}}) {
1527         my $d = $cfg->{users}->{$user};
1528         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1529         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1530         my $email = $d->{email} || '';
1531         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1532         my $expire = int($d->{expire} || 0);
1533         my $enable = $d->{enable} ? 1 : 0;
1534         my $keys = $d->{keys} ? $d->{keys} : '';
1535         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
1536
1537         my $user_tokens = $d->{tokens};
1538         foreach my $token (sort keys %$user_tokens) {
1539             my $td = $user_tokens->{$token};
1540             my $full_tokenid = join_tokenid($user, $token);
1541             my $comment = $td->{comment} ? PVE::Tools::encode_text($td->{comment}) : '';
1542             my $expire = int($td->{expire} || 0);
1543             my $privsep = $td->{privsep} ? 1 : 0;
1544             $data .= "token:$full_tokenid:$expire:$privsep:$comment:\n";
1545         }
1546     }
1547
1548     $data .= "\n";
1549
1550     foreach my $group (sort keys %{$cfg->{groups}}) {
1551         my $d = $cfg->{groups}->{$group};
1552         my $list = join (',', sort keys %{$d->{users}});
1553         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1554         $data .= "group:$group:$list:$comment:\n";
1555     }
1556
1557     $data .= "\n";
1558
1559     foreach my $pool (sort keys %{$cfg->{pools}}) {
1560         my $d = $cfg->{pools}->{$pool};
1561         my $vmlist = join (',', sort keys %{$d->{vms}});
1562         my $storelist = join (',', sort keys %{$d->{storage}});
1563         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1564         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1565     }
1566
1567     $data .= "\n";
1568
1569     foreach my $role (sort keys %{$cfg->{roles}}) {
1570         next if $special_roles->{$role};
1571
1572         my $d = $cfg->{roles}->{$role};
1573         my $list = join (',', sort keys %$d);
1574         $data .= "role:$role:$list:\n";
1575     }
1576
1577     $data .= "\n";
1578
1579     my $collect_rolelist_members = sub {
1580         my ($acl_members, $result, $prefix, $exclude) = @_;
1581
1582         foreach my $member (keys %$acl_members) {
1583             next if $exclude && $member eq $exclude;
1584
1585             my $l0 = '';
1586             my $l1 = '';
1587             foreach my $role (sort keys %{$acl_members->{$member}}) {
1588                 my $propagate = $acl_members->{$member}->{$role};
1589                 if ($propagate) {
1590                     $l1 .= ',' if $l1;
1591                     $l1 .= $role;
1592                 } else {
1593                     $l0 .= ',' if $l0;
1594                     $l0 .= $role;
1595                 }
1596             }
1597             $result->{0}->{$l0}->{"${prefix}${member}"} = 1 if $l0;
1598             $result->{1}->{$l1}->{"${prefix}${member}"} = 1 if $l1;
1599         }
1600     };
1601
1602     foreach my $path (sort keys %{$cfg->{acl}}) {
1603         my $d = $cfg->{acl}->{$path};
1604
1605         my $rolelist_members = {};
1606
1607         $collect_rolelist_members->($d->{'groups'}, $rolelist_members, '@');
1608
1609         # no need to save 'root@pam', it is always 'Administrator'
1610         $collect_rolelist_members->($d->{'users'}, $rolelist_members, '', 'root@pam');
1611
1612         $collect_rolelist_members->($d->{'tokens'}, $rolelist_members, '');
1613
1614         foreach my $propagate (0,1) {
1615             my $filtered = $rolelist_members->{$propagate};
1616             foreach my $rolelist (sort keys %$filtered) {
1617                 my $uglist = join (',', sort keys %{$filtered->{$rolelist}});
1618                 $data .= "acl:$propagate:$path:$uglist:$rolelist:\n";
1619             }
1620
1621         }
1622     }
1623
1624     return $data;
1625 }
1626
1627 # Creates a `PVE::RS::TFA` instance from the raw config data.
1628 # Its contained hash will also support the legacy functionality.
1629 sub parse_priv_tfa_config {
1630     my ($filename, $raw) = @_;
1631
1632     $raw = '' if !defined($raw);
1633     my $cfg = PVE::RS::TFA->new($raw);
1634
1635     # Purge invalid users:
1636     foreach my $user ($cfg->users()->@*) {
1637         my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1638         if (!$realm) {
1639             warn "user tfa config - ignore user '$user' - invalid user name\n";
1640             $cfg->remove_user($user);
1641         }
1642     }
1643
1644     return $cfg;
1645 }
1646
1647 sub write_priv_tfa_config {
1648     my ($filename, $cfg) = @_;
1649
1650     assert_new_tfa_config_available();
1651
1652     return $cfg->write();
1653 }
1654
1655 sub roles {
1656     my ($cfg, $user, $path) = @_;
1657
1658     # NOTE: we do not consider pools here.
1659     # NOTE: for privsep tokens, this does not filter roles by those that the
1660     # corresponding user has.
1661     # Use $rpcenv->permission() for any actual permission checks!
1662
1663     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1664
1665     if (!defined($path)) {
1666         # this shouldn't happen!
1667         warn "internal error: ACL check called for undefined ACL path!\n";
1668         return {};
1669     }
1670
1671     if (pve_verify_tokenid($user, 1)) {
1672         my $tokenid = $user;
1673         my ($username, $token) = split_tokenid($tokenid);
1674
1675         my $token_info = $cfg->{users}->{$username}->{tokens}->{$token};
1676         return () if !$token_info;
1677
1678         my $user_roles = roles($cfg, $username, $path);
1679
1680         # return full user privileges
1681         return $user_roles if !$token_info->{privsep};
1682     }
1683
1684     my $roles = {};
1685
1686     foreach my $p (sort keys %{$cfg->{acl}}) {
1687         my $final = ($path eq $p);
1688
1689         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1690
1691         my $acl = $cfg->{acl}->{$p};
1692
1693         #print "CHECKACL $path $p\n";
1694         #print "ACL $path = " . Dumper ($acl);
1695         if (my $ri = $acl->{tokens}->{$user}) {
1696             my $new;
1697             foreach my $role (keys %$ri) {
1698                 my $propagate = $ri->{$role};
1699                 if ($final || $propagate) {
1700                     #print "APPLY ROLE $p $user $role\n";
1701                     $new = {} if !$new;
1702                     $new->{$role} = $propagate;
1703                 }
1704             }
1705             if ($new) {
1706                 $roles = $new; # overwrite previous settings
1707                 next;
1708             }
1709         }
1710
1711         if (my $ri = $acl->{users}->{$user}) {
1712             my $new;
1713             foreach my $role (keys %$ri) {
1714                 my $propagate = $ri->{$role};
1715                 if ($final || $propagate) {
1716                     #print "APPLY ROLE $p $user $role\n";
1717                     $new = {} if !$new;
1718                     $new->{$role} = $propagate;
1719                 }
1720             }
1721             if ($new) {
1722                 $roles = $new; # overwrite previous settings
1723                 next; # user privs always override group privs
1724             }
1725         }
1726
1727         my $new;
1728         foreach my $g (keys %{$acl->{groups}}) {
1729             next if !$cfg->{groups}->{$g}->{users}->{$user};
1730             if (my $ri = $acl->{groups}->{$g}) {
1731                 foreach my $role (keys %$ri) {
1732                     my $propagate = $ri->{$role};
1733                     if ($final || $propagate) {
1734                         #print "APPLY ROLE $p \@$g $role\n";
1735                         $new = {} if !$new;
1736                         $new->{$role} = $propagate;
1737                     }
1738                 }
1739             }
1740         }
1741         if ($new) {
1742             $roles = $new; # overwrite previous settings
1743             next;
1744         }
1745     }
1746
1747     return { 'NoAccess' => $roles->{NoAccess} } if defined ($roles->{NoAccess});
1748     #return () if defined ($roles->{NoAccess});
1749
1750     #print "permission $user $path = " . Dumper ($roles);
1751
1752     #print "roles $user $path = " . join (',', @ra) . "\n";
1753
1754     return $roles;
1755 }
1756
1757 sub remove_vm_access {
1758     my ($vmid) = @_;
1759     my $delVMaccessFn = sub {
1760         my $usercfg = cfs_read_file("user.cfg");
1761         my $modified;
1762
1763         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1764             delete $usercfg->{acl}->{"/vms/$vmid"};
1765             $modified = 1;
1766         }
1767         if (my $pool = $usercfg->{vms}->{$vmid}) {
1768             if (my $data = $usercfg->{pools}->{$pool}) {
1769                 delete $data->{vms}->{$vmid};
1770                 delete $usercfg->{vms}->{$vmid};
1771                 $modified = 1;
1772             }
1773         }
1774         cfs_write_file("user.cfg", $usercfg) if $modified;
1775     };
1776
1777     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1778 }
1779
1780 sub remove_storage_access {
1781     my ($storeid) = @_;
1782
1783     my $deleteStorageAccessFn = sub {
1784         my $usercfg = cfs_read_file("user.cfg");
1785         my $modified;
1786
1787         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1788             delete $usercfg->{acl}->{"/storage/$storeid"};
1789             $modified = 1;
1790         }
1791         foreach my $pool (keys %{$usercfg->{pools}}) {
1792             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1793             $modified = 1;
1794         }
1795         cfs_write_file("user.cfg", $usercfg) if $modified;
1796     };
1797
1798     lock_user_config($deleteStorageAccessFn,
1799                      "access permissions cleanup for storage $storeid failed");
1800 }
1801
1802 sub add_vm_to_pool {
1803     my ($vmid, $pool) = @_;
1804
1805     my $addVMtoPoolFn = sub {
1806         my $usercfg = cfs_read_file("user.cfg");
1807         if (my $data = $usercfg->{pools}->{$pool}) {
1808             $data->{vms}->{$vmid} = 1;
1809             $usercfg->{vms}->{$vmid} = $pool;
1810             cfs_write_file("user.cfg", $usercfg);
1811         }
1812     };
1813
1814     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1815 }
1816
1817 sub remove_vm_from_pool {
1818     my ($vmid) = @_;
1819
1820     my $delVMfromPoolFn = sub {
1821         my $usercfg = cfs_read_file("user.cfg");
1822         if (my $pool = $usercfg->{vms}->{$vmid}) {
1823             if (my $data = $usercfg->{pools}->{$pool}) {
1824                 delete $data->{vms}->{$vmid};
1825                 delete $usercfg->{vms}->{$vmid};
1826                 cfs_write_file("user.cfg", $usercfg);
1827             }
1828         }
1829     };
1830
1831     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1832 }
1833
1834 my $USER_CONTROLLED_TFA_TYPES = {
1835     u2f => 1,
1836     oath => 1,
1837 };
1838
1839 sub assert_new_tfa_config_available() {
1840     PVE::Cluster::cfs_update();
1841     my $version_info = PVE::Cluster::get_node_kv('version-info');
1842     die "cannot update tfa config, please make sure all cluster nodes are up to date\n"
1843         if !$version_info;
1844     my $members = PVE::Cluster::get_members() or return; # get_members returns undef on no cluster
1845     my $old = '';
1846     foreach my $node (keys $members->%*) {
1847         my $info = $version_info->{$node};
1848         if (!$info) {
1849             $old .= "  cluster node '$node' is too old, did not broadcast its version info\n";
1850             next;
1851         }
1852         $info = from_json($info);
1853         my $ver = $info->{version};
1854         if ($ver !~ /^(\d+\.\d+)-(\d+)/) {
1855             $old .= "  cluster node '$node' provided an invalid version string: '$ver'\n";
1856             next;
1857         }
1858         my ($maj, $rel) = ($1, $2);
1859         if (!($maj > 7.0 || ($maj == 7.0 && $rel >= 15))) {
1860             $old .= "  cluster node '$node' is too old ($ver < 7.0-15)\n";
1861             next;
1862         }
1863     }
1864     die "cannot update tfa config, following nodes are not up to date:\n$old" if length($old);
1865 }
1866
1867 sub user_remove_tfa : prototype($) {
1868     my ($userid) = @_;
1869
1870     assert_new_tfa_config_available();
1871
1872     my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1873     $tfa_cfg->remove_user($userid);
1874     cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1875 }
1876
1877 my sub add_old_yubico_keys : prototype($$$) {
1878     my ($userid, $tfa_cfg, $keys) = @_;
1879
1880     my $count = 0;
1881     foreach my $key (split_list($keys)) {
1882         my $description = "<old userconfig key $count>";
1883         ++$count;
1884         $tfa_cfg->add_yubico_entry($userid, $description, $key);
1885     }
1886 }
1887
1888 my sub normalize_totp_secret : prototype($) {
1889     my ($key) = @_;
1890
1891     my $binkey;
1892     # See PVE::OTP::oath_verify_otp:
1893     if ($key =~ /^v2-0x([0-9a-fA-F]+)$/) {
1894         # v2, hex
1895         $binkey = pack('H*', $1);
1896     } elsif ($key =~ /^v2-([A-Z2-7=]+)$/) {
1897         # v2, base32
1898         $binkey = MIME::Base32::decode_rfc3548($1);
1899     } elsif ($key =~ /^[A-Z2-7=]{16}$/) {
1900         $binkey = MIME::Base32::decode_rfc3548($key);
1901     } elsif ($key =~ /^[A-Fa-f0-9]{40}$/) {
1902         $binkey = pack('H*', $key);
1903     } else {
1904         return undef;
1905     }
1906
1907     return MIME::Base32::encode_rfc3548($binkey);
1908 }
1909
1910 my sub add_old_totp_keys : prototype($$$$) {
1911     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1912
1913     my $issuer = 'Proxmox%20VE';
1914     my $account = uri_escape("Old key for $userid");
1915     my $digits = $realm_tfa->{digits} || 6;
1916     my $step = $realm_tfa->{step} || 30;
1917     my $uri = "otpauth://totp/$issuer:$account?digits=$digits&period=$step&algorithm=SHA1&secret=";
1918
1919     my $count = 0;
1920     foreach my $key (split_list($keys)) {
1921         $key = normalize_totp_secret($key);
1922         # and just skip invalid keys:
1923         next if !defined($key);
1924
1925         my $description = "<old userconfig key $count>";
1926         ++$count;
1927         eval { $tfa_cfg->add_totp_entry($userid, $description, $uri . $key) };
1928         warn $@ if $@;
1929     }
1930 }
1931
1932 sub add_old_keys_to_realm_tfa : prototype($$$$) {
1933     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1934
1935     # if there's no realm tfa configured, we don't know what the keys mean, so we just ignore
1936     # them...
1937     return if !$realm_tfa;
1938
1939     my $type = $realm_tfa->{type};
1940     if ($type eq 'oath') {
1941         add_old_totp_keys($userid, $tfa_cfg, $realm_tfa, $keys);
1942     } elsif ($type eq 'yubico') {
1943         add_old_yubico_keys($userid, $tfa_cfg, $keys);
1944     } else {
1945         # invalid keys, we'll just drop them now...
1946     }
1947 }
1948
1949 sub user_get_tfa : prototype($$$) {
1950     my ($username, $realm, $new_format) = @_;
1951
1952     my $user_cfg = cfs_read_file('user.cfg');
1953     my $user = $user_cfg->{users}->{$username}
1954         or die "user '$username' not found\n";
1955
1956     my $keys = $user->{keys};
1957
1958     my $domain_cfg = cfs_read_file('domains.cfg');
1959     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1960     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1961
1962     my $realm_tfa = $realm_cfg->{tfa};
1963     $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa)
1964         if $realm_tfa;
1965
1966     if (!$keys) {
1967         return if !$realm_tfa;
1968         die "missing required 2nd keys\n";
1969     }
1970
1971     if ($new_format) {
1972         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1973         if (defined($keys) && $keys !~ /^x(?:!.*)$/) {
1974             add_old_keys_to_realm_tfa($username, $tfa_cfg, $realm_tfa, $keys);
1975         }
1976         return ($tfa_cfg, $realm_tfa);
1977     }
1978
1979     # new style config starts with an 'x' and optionally contains a !<type> suffix
1980     if ($keys !~ /^x(?:!.*)?$/) {
1981         # old style config, find the type via the realm
1982         return if !$realm_tfa;
1983         return ($realm_tfa->{type}, {
1984             keys => $keys,
1985             config => $realm_tfa,
1986         });
1987     } else {
1988         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1989         my $tfa = $tfa_cfg->{users}->{$username};
1990         return if !$tfa; # should not happen (user.cfg wasn't cleaned up?)
1991
1992         if ($realm_tfa) {
1993             # if the realm has a tfa setting we need to verify the type:
1994             die "auth domain '$realm' and user have mismatching TFA settings\n"
1995                 if $realm_tfa && $realm_tfa->{type} ne $tfa->{type};
1996         }
1997
1998         return ($tfa->{type}, $tfa->{data});
1999     }
2000 }
2001
2002 # bash completion helpers
2003
2004 register_standard_option('userid-completed',
2005     get_standard_option('userid', { completion => \&complete_username}),
2006 );
2007
2008 sub complete_username {
2009
2010     my $user_cfg = cfs_read_file('user.cfg');
2011
2012     return [ keys %{$user_cfg->{users}} ];
2013 }
2014
2015 sub complete_group {
2016
2017     my $user_cfg = cfs_read_file('user.cfg');
2018
2019     return [ keys %{$user_cfg->{groups}} ];
2020 }
2021
2022 sub complete_realm {
2023
2024     my $domain_cfg = cfs_read_file('domains.cfg');
2025
2026     return [ keys %{$domain_cfg->{ids}} ];
2027 }
2028
2029 1;