src/PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base32;
  11 use MIME::Base64;
  12 use Digest::SHA;
  13 use IO::File;
  14 use File::stat;
  15 use JSON;
  16 use Scalar::Util 'weaken';
  17 use URI::Escape;
  18
  19 use PVE::OTP;
  20 use PVE::Ticket;
  21 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  22 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  23 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  24
  25 use PVE::RS::TFA;
  26
  27 use PVE::Auth::Plugin;
  28 use PVE::Auth::AD;
  29 use PVE::Auth::LDAP;
  30 use PVE::Auth::PVE;
  31 use PVE::Auth::PAM;
  32 use PVE::Auth::OpenId;
  33
  34 # load and initialize all plugins
  35
  36 PVE::Auth::AD->register();
  37 PVE::Auth::LDAP->register();
  38 PVE::Auth::PVE->register();
  39 PVE::Auth::PAM->register();
  40 PVE::Auth::OpenId->register();
  41 PVE::Auth::Plugin->init();
  42
  43 # $authdir must be writable by root only!
  44 my $confdir = "/etc/pve";
  45 my $authdir = "$confdir/priv";
  46
  47 my $pve_www_key_fn = "$confdir/pve-www.key";
  48
  49 my $pve_auth_key_files = {
  50     priv => "$authdir/authkey.key",
  51     pub =>  "$confdir/authkey.pub",
  52     pubold => "$confdir/authkey.pub.old",
  53 };
  54
  55 my $pve_auth_key_cache = {};
  56
  57 my $ticket_lifetime = 3600 * 2; # 2 hours
  58 my $auth_graceperiod = 60 * 5; # 5 minutes
  59 my $authkey_lifetime = 3600 * 24; # rotate every 24 hours
  60
  61 Crypt::OpenSSL::RSA->import_random_seed();
  62
  63 cfs_register_file('user.cfg', \&parse_user_config, \&write_user_config);
  64 cfs_register_file('priv/tfa.cfg', \&parse_priv_tfa_config, \&write_priv_tfa_config);
  65
  66 sub verify_username {
  67     PVE::Auth::Plugin::verify_username(@_);
  68 }
  69
  70 sub pve_verify_realm {
  71     PVE::Auth::Plugin::pve_verify_realm(@_);
  72 }
  73
  74 # Locking both config files together is only ever allowed in one order:
  75 #  1) tfa config
  76 #  2) user config
  77 # If we permit the other way round, too, we might end up deadlocking!
  78 my $user_config_locked;
  79 sub lock_user_config {
  80     my ($code, $errmsg) = @_;
  81
  82     my $locked = 1;
  83     $user_config_locked = \$locked;
  84     weaken $user_config_locked; # make this scope guard signal safe...
  85
  86     cfs_lock_file("user.cfg", undef, $code);
  87     $user_config_locked = undef;
  88     if (my $err = $@) {
  89         $errmsg ? die "$errmsg: $err" : die $err;
  90     }
  91 }
  92
  93 sub lock_tfa_config {
  94     my ($code, $errmsg) = @_;
  95
  96     die "tfa config lock cannot be acquired while holding user config lock\n"
  97         if ($user_config_locked && $$user_config_locked);
  98
  99     my $res = cfs_lock_file("priv/tfa.cfg", undef, $code);
 100     if (my $err = $@) {
 101         $errmsg ? die "$errmsg: $err" : die $err;
 102     }
 103
 104     return $res;
 105 }
 106
 107 my $cache_read_key = sub {
 108     my ($type) = @_;
 109
 110     my $path = $pve_auth_key_files->{$type};
 111
 112     my $read_key_and_mtime = sub {
 113         my $fh = IO::File->new($path, "r");
 114
 115         return undef if !defined($fh);
 116
 117         my $st = stat($fh);
 118         my $pem = PVE::Tools::safe_read_from($fh, 0, 0, $path);
 119
 120         close $fh;
 121
 122         my $key;
 123         if ($type eq 'pub' || $type eq 'pubold') {
 124             $key = eval { Crypt::OpenSSL::RSA->new_public_key($pem); };
 125         } elsif ($type eq 'priv') {
 126             $key = eval { Crypt::OpenSSL::RSA->new_private_key($pem); };
 127         } else {
 128             die "Invalid authkey type '$type'\n";
 129         }
 130
 131         return { key => $key, mtime => $st->mtime };
 132     };
 133
 134     if (!defined($pve_auth_key_cache->{$type})) {
 135         $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 136     } else {
 137         my $st = stat($path);
 138         if (!$st || $st->mtime != $pve_auth_key_cache->{$type}->{mtime}) {
 139             $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 140         }
 141     }
 142
 143     return $pve_auth_key_cache->{$type};
 144 };
 145
 146 sub get_pubkey {
 147     my ($old) = @_;
 148
 149     my $type = $old ? 'pubold' : 'pub';
 150
 151     my $res = $cache_read_key->($type);
 152     return undef if !defined($res);
 153
 154     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 155 }
 156
 157 sub get_privkey {
 158     my $res = $cache_read_key->('priv');
 159
 160     if (!defined($res) || !check_authkey(1)) {
 161         rotate_authkey();
 162         $res = $cache_read_key->('priv');
 163     }
 164
 165     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 166 }
 167
 168 sub check_authkey {
 169     my ($quiet) = @_;
 170
 171     # skip check if non-quorate, as rotation is not possible anyway
 172     return 1 if !PVE::Cluster::check_cfs_quorum(1);
 173
 174     my ($pub_key, $mtime) = get_pubkey();
 175     if (!$pub_key) {
 176         warn "auth key pair missing, generating new one..\n"  if !$quiet;
 177         return 0;
 178     } else {
 179         my $now = time();
 180         if ($now - $mtime >= $authkey_lifetime) {
 181             warn "auth key pair too old, rotating..\n" if !$quiet;;
 182             return 0;
 183         } elsif ($mtime > $now + $auth_graceperiod) {
 184             # a nodes RTC had a time set in the future during key generation -> ticket
 185             # validity is clamped to 0+5 min grace period until now >= mtime again
 186             my (undef, $old_mtime) = get_pubkey(1);
 187             if ($old_mtime && $mtime >= $old_mtime && $mtime - $old_mtime < $ticket_lifetime) {
 188                 warn "auth key pair generated in the future (key $mtime > host $now),"
 189                     ." but old key still exists and in valid grace period so avoid automatic"
 190                     ." fixup. Cluster time not in sync?\n" if !$quiet;
 191                 return 1;
 192             }
 193             warn "auth key pair generated in the future (key $mtime > host $now), rotating..\n" if !$quiet;
 194             return 0;
 195         } else {
 196             warn "auth key new enough, skipping rotation\n" if !$quiet;;
 197             return 1;
 198         }
 199     }
 200 }
 201
 202 sub rotate_authkey {
 203     return if $authkey_lifetime == 0;
 204
 205     PVE::Cluster::cfs_lock_authkey(undef, sub {
 206         # stat() calls might be answered from the kernel page cache for up to
 207         # 1s, so this special dance is needed to avoid a double rotation in
 208         # clusters *despite* the cfs_lock context..
 209
 210         # drop in-process cache hash
 211         $pve_auth_key_cache = {};
 212         # force open/close of file to invalidate page cache entry
 213         get_pubkey();
 214         # now re-check with lock held and page cache invalidated so that stat()
 215         # does the right thing, and any key updates by other nodes are visible.
 216         return if check_authkey();
 217
 218         my $old = get_pubkey();
 219         my $new = Crypt::OpenSSL::RSA->generate_key(2048);
 220
 221         if ($old) {
 222             eval {
 223                 my $pem = $old->get_public_key_x509_string();
 224                 # mtime is used for caching and ticket age range calculation
 225                 PVE::Tools::file_set_contents($pve_auth_key_files->{pubold}, $pem);
 226             };
 227             die "Failed to store old auth key: $@\n" if $@;
 228         }
 229
 230         eval {
 231             my $pem = $new->get_public_key_x509_string();
 232             # mtime is used for caching and ticket age range calculation,
 233             # should be close to that of pubold above
 234             PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 235         };
 236         if ($@) {
 237             if ($old) {
 238                 warn "Failed to store new auth key - $@\n";
 239                 warn "Reverting to previous auth key\n";
 240                 eval {
 241                     my $pem = $old->get_public_key_x509_string();
 242                     PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 243                 };
 244                 die "Failed to restore old auth key: $@\n" if $@;
 245             } else {
 246                 die "Failed to store new auth key - $@\n";
 247             }
 248         }
 249
 250         eval {
 251             my $pem = $new->get_private_key_string();
 252             PVE::Tools::file_set_contents($pve_auth_key_files->{priv}, $pem);
 253         };
 254         if ($@) {
 255             warn "Failed to store new auth key - $@\n";
 256             warn "Deleting auth key to force regeneration\n";
 257             unlink $pve_auth_key_files->{pub};
 258             unlink $pve_auth_key_files->{priv};
 259         }
 260     });
 261     die $@ if $@;
 262 }
 263
 264 PVE::JSONSchema::register_standard_option('tokenid', {
 265     description => "API token identifier.",
 266     type => "string",
 267     format => "pve-tokenid",
 268 });
 269
 270 our $token_subid_regex = $PVE::Auth::Plugin::realm_regex;
 271
 272 # username@realm username realm tokenid
 273 our $token_full_regex = qr/((${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex}))!(${token_subid_regex})/;
 274
 275 our $userid_or_token_regex = qr/^$PVE::Auth::Plugin::user_regex\@$PVE::Auth::Plugin::realm_regex(?:!$token_subid_regex)?$/;
 276
 277 sub split_tokenid {
 278     my ($tokenid, $noerr) = @_;
 279
 280     if ($tokenid =~ /^${token_full_regex}$/) {
 281         return ($1, $4);
 282     }
 283
 284     die "'$tokenid' is not a valid token ID - not able to split into user and token parts\n" if !$noerr;
 285
 286     return undef;
 287 }
 288
 289 sub join_tokenid {
 290     my ($username, $tokensubid) = @_;
 291
 292     my $joined = "${username}!${tokensubid}";
 293
 294     return pve_verify_tokenid($joined);
 295 }
 296
 297 PVE::JSONSchema::register_format('pve-tokenid', \&pve_verify_tokenid);
 298 sub pve_verify_tokenid {
 299     my ($tokenid, $noerr) = @_;
 300
 301     if ($tokenid =~ /^${token_full_regex}$/) {
 302         return wantarray ? ($tokenid, $2, $3, $4) : $tokenid;
 303     }
 304
 305     die "value '$tokenid' does not look like a valid token ID\n" if !$noerr;
 306
 307     return undef;
 308 }
 309
 310
 311 my $csrf_prevention_secret;
 312 my $csrf_prevention_secret_legacy;
 313 my $get_csrfr_secret = sub {
 314     if (!$csrf_prevention_secret) {
 315         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
 316         $csrf_prevention_secret = Digest::SHA::hmac_sha256_base64($input);
 317         $csrf_prevention_secret_legacy = Digest::SHA::sha1_base64($input);
 318     }
 319     return $csrf_prevention_secret;
 320 };
 321
 322 sub assemble_csrf_prevention_token {
 323     my ($username) = @_;
 324
 325     my $secret =  &$get_csrfr_secret();
 326
 327     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
 328 }
 329
 330 sub verify_csrf_prevention_token {
 331     my ($username, $token, $noerr) = @_;
 332
 333     my $secret = $get_csrfr_secret->();
 334
 335     # FIXME: remove with PVE 7 and/or refactor all into PVE::Ticket ?
 336     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 337         my $sig = $2;
 338         if (length($sig) == 27) {
 339             # the legacy secret got populated by above get_csrfr_secret call
 340             $secret = $csrf_prevention_secret_legacy;
 341         }
 342     }
 343
 344     return PVE::Ticket::verify_csrf_prevention_token(
 345         $secret, $username, $token, -$auth_graceperiod, $ticket_lifetime, $noerr);
 346 }
 347
 348 my $get_ticket_age_range = sub {
 349     my ($now, $mtime, $rotated) = @_;
 350
 351     my $key_age = $now - $mtime;
 352     $key_age = 0 if $key_age < 0;
 353
 354     my $min = -$auth_graceperiod;
 355     my $max = $ticket_lifetime;
 356
 357     if ($rotated) {
 358         # ticket creation after rotation is not allowed
 359         $min = $key_age - $auth_graceperiod;
 360     } else {
 361         if ($key_age > $authkey_lifetime && $authkey_lifetime > 0) {
 362             if (PVE::Cluster::check_cfs_quorum(1)) {
 363                 # key should have been rotated, clamp range accordingly
 364                 $min = $key_age - $authkey_lifetime;
 365             } else {
 366                 warn "Cluster not quorate - extending auth key lifetime!\n";
 367             }
 368         }
 369
 370         $max = $key_age + $auth_graceperiod if $key_age < $ticket_lifetime;
 371     }
 372
 373     return undef if $min > $ticket_lifetime;
 374     return ($min, $max);
 375 };
 376
 377 sub assemble_ticket : prototype($;$) {
 378     my ($data, $aad) = @_;
 379
 380     my $rsa_priv = get_privkey();
 381
 382     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $data, $aad);
 383 }
 384
 385 # Returns the username, "age" and tfa info.
 386 #
 387 # Note that for the new-style outh, tfa info is never set, as it only uses the `/ticket` api call
 388 # via the new 'tfa-challenge' parameter, so this part can go with PVE-8.
 389 #
 390 # New-style auth still uses this function, but sets `$tfa_ticket` to true when validating the tfa
 391 # ticket.
 392 sub verify_ticket : prototype($;$$) {
 393     my ($ticket, $noerr, $tfa_ticket_aad) = @_;
 394
 395     my $now = time();
 396
 397     my $check = sub {
 398         my ($old) = @_;
 399
 400         my ($rsa_pub, $rsa_mtime) = get_pubkey($old);
 401         return undef if !$rsa_pub;
 402
 403         my ($min, $max) = $get_ticket_age_range->($now, $rsa_mtime, $old);
 404         return undef if !defined($min);
 405
 406         return PVE::Ticket::verify_rsa_ticket(
 407             $rsa_pub, 'PVE', $ticket, $tfa_ticket_aad, $min, $max, 1);
 408     };
 409
 410     my ($data, $age) = $check->();
 411
 412     # check with old, rotated key if current key failed
 413     ($data, $age) = $check->(1) if !defined($data);
 414
 415     my $auth_failure = sub {
 416         if ($noerr) {
 417             return undef;
 418         } else {
 419             # raise error via undef ticket
 420             PVE::Ticket::verify_rsa_ticket(undef, 'PVE');
 421         }
 422     };
 423
 424     if (!defined($data)) {
 425         return $auth_failure->();
 426     }
 427
 428     if ($tfa_ticket_aad) {
 429         # We're validating a ticket-call's 'tfa-challenge' parameter, so just return its data.
 430         if ($data =~ /^!tfa!(.*)$/) {
 431             return $1;
 432         }
 433         die "bad ticket\n";
 434     }
 435
 436     my ($username, $tfa_info);
 437     if ($data =~ /^!tfa!(.*)$/) {
 438         # PBS style half-authenticated ticket, contains a json string form of a `TfaChallenge`
 439         # object.
 440         # This type of ticket does not contain the user name.
 441         return { type => 'new', data => $1 };
 442     }
 443     if ($data =~ m{^u2f!([^!]+)!([0-9a-zA-Z/.=_\-+]+)$}) {
 444         # Ticket for u2f-users:
 445         ($username, my $challenge) = ($1, $2);
 446         if ($challenge eq 'verified') {
 447             # u2f challenge was completed
 448             $challenge = undef;
 449         } elsif (!wantarray) {
 450             # The caller is not aware there could be an ongoing challenge,
 451             # so we treat this ticket as invalid:
 452             return $auth_failure->();
 453         }
 454         $tfa_info = {
 455             type => 'u2f',
 456             challenge => $challenge,
 457         };
 458     } elsif ($data =~ /^tfa!(.*)$/) {
 459         # TOTP and Yubico don't require a challenge so this is the generic
 460         # 'missing 2nd factor ticket'
 461         $username = $1;
 462         $tfa_info = { type => 'tfa' };
 463     } else {
 464         # Regular ticket (full access)
 465         $username = $data;
 466     }
 467
 468     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 469
 470     return wantarray ? ($username, $age, $tfa_info) : $username;
 471 }
 472
 473 sub verify_token {
 474     my ($api_token) = @_;
 475
 476     die "no API token specified\n" if !$api_token;
 477
 478     my ($tokenid, $value);
 479     if ($api_token =~ /^(.*)=(.*)$/) {
 480         $tokenid = $1;
 481         $value = $2;
 482     } else {
 483         die "no tokenid specified\n";
 484     }
 485
 486     my ($username, $token) = split_tokenid($tokenid);
 487
 488     my $usercfg = cfs_read_file('user.cfg');
 489     check_user_enabled($usercfg, $username);
 490     check_token_exist($usercfg, $username, $token);
 491
 492     my $user = $usercfg->{users}->{$username};
 493     my $token_info = $user->{tokens}->{$token};
 494
 495     my $ctime = time();
 496     die "token '$token' access expired\n" if $token_info->{expire} && ($token_info->{expire} < $ctime);
 497
 498     die "invalid token value!\n" if !PVE::Cluster::verify_token($tokenid, $value);
 499
 500     return wantarray ? ($tokenid) : $tokenid;
 501 }
 502
 503 my $assemble_short_lived_ticket = sub {
 504     my ($prefix, $username, $path) = @_;
 505
 506     my $rsa_priv = get_privkey();
 507
 508     $path = normalize_path($path);
 509
 510     die "invalid ticket path\n" if !defined($path);
 511
 512     my $secret_data = "$username:$path";
 513
 514     return PVE::Ticket::assemble_rsa_ticket(
 515         $rsa_priv, $prefix, undef, $secret_data);
 516 };
 517
 518 my $verify_short_lived_ticket = sub {
 519     my ($ticket, $prefix, $username, $path, $noerr) = @_;
 520
 521     $path = normalize_path($path);
 522
 523     die "invalid ticket path\n" if !defined($path);
 524
 525     my $secret_data = "$username:$path";
 526
 527     my ($rsa_pub, $rsa_mtime) = get_pubkey();
 528     if (!$rsa_pub || (time() - $rsa_mtime > $authkey_lifetime && $authkey_lifetime > 0)) {
 529         if ($noerr) {
 530             return undef;
 531         } else {
 532             # raise error via undef ticket
 533             PVE::Ticket::verify_rsa_ticket($rsa_pub, $prefix);
 534         }
 535     }
 536
 537     return PVE::Ticket::verify_rsa_ticket(
 538         $rsa_pub, $prefix, $ticket, $secret_data, -20, 40, $noerr);
 539 };
 540
 541 # VNC tickets
 542 # - they do not contain the username in plain text
 543 # - they are restricted to a specific resource path (example: '/vms/100')
 544 sub assemble_vnc_ticket {
 545     my ($username, $path) = @_;
 546
 547     return $assemble_short_lived_ticket->('PVEVNC', $username, $path);
 548 }
 549
 550 sub verify_vnc_ticket {
 551     my ($ticket, $username, $path, $noerr) = @_;
 552
 553     return $verify_short_lived_ticket->($ticket, 'PVEVNC', $username, $path, $noerr);
 554 }
 555
 556 # Tunnel tickets
 557 # - they do not contain the username in plain text
 558 # - they are restricted to a specific resource path (example: '/vms/100', '/socket/run/qemu-server/123.storage')
 559 sub assemble_tunnel_ticket {
 560     my ($username, $path) = @_;
 561
 562     return $assemble_short_lived_ticket->('PVETUNNEL', $username, $path);
 563 }
 564
 565 sub verify_tunnel_ticket {
 566     my ($ticket, $username, $path, $noerr) = @_;
 567
 568     return $verify_short_lived_ticket->($ticket, 'PVETUNNEL', $username, $path, $noerr);
 569 }
 570
 571 sub assemble_spice_ticket {
 572     my ($username, $vmid, $node) = @_;
 573
 574     my $secret = &$get_csrfr_secret();
 575
 576     return PVE::Ticket::assemble_spice_ticket(
 577         $secret, $username, $vmid, $node);
 578 }
 579
 580 sub verify_spice_connect_url {
 581     my ($connect_str) = @_;
 582
 583     my $secret = &$get_csrfr_secret();
 584
 585     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 586 }
 587
 588 sub read_x509_subject_spice {
 589     my ($filename) = @_;
 590
 591     # read x509 subject
 592     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 593     die "Could not open $filename using OpenSSL\n"
 594         if !$bio;
 595
 596     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 597     Net::SSLeay::BIO_free($bio);
 598
 599     die "Could not parse X509 certificate in $filename\n"
 600         if !$x509;
 601
 602     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 603     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 604     Net::SSLeay::X509_free($x509);
 605
 606     # remote-viewer wants comma as separator (not '/')
 607     $subject =~ s!^/!!;
 608     $subject =~ s!/(\w+=)!,$1!g;
 609
 610     return $subject;
 611 }
 612
 613 # helper to generate SPICE remote-viewer configuration
 614 sub remote_viewer_config {
 615     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 616
 617     if (!$proxy) {
 618         my $host = `hostname -f` || PVE::INotify::nodename();
 619         chomp $host;
 620         $proxy = $host;
 621     }
 622
 623     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 624
 625     my $filename = "/etc/pve/local/pve-ssl.pem";
 626     my $subject = read_x509_subject_spice($filename);
 627
 628     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 629     $cacert =~ s/\n/\\n/g;
 630
 631     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 632     my $config = {
 633         'secure-attention' => "Ctrl+Alt+Ins",
 634         'toggle-fullscreen' => "Shift+F11",
 635         'release-cursor' => "Ctrl+Alt+R",
 636         type => 'spice',
 637         title => $title,
 638         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 639         proxy => "http://$proxy:3128",
 640         'tls-port' => $port,
 641         'host-subject' => $subject,
 642         ca => $cacert,
 643         password => $ticket,
 644         'delete-this-file' => 1,
 645     };
 646
 647     return ($ticket, $proxyticket, $config);
 648 }
 649
 650 sub check_user_exist {
 651     my ($usercfg, $username, $noerr) = @_;
 652
 653     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 654     return undef if !$username;
 655
 656     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 657
 658     die "no such user ('$username')\n" if !$noerr;
 659
 660     return undef;
 661 }
 662
 663 sub check_user_enabled {
 664     my ($usercfg, $username, $noerr) = @_;
 665
 666     my $data = check_user_exist($usercfg, $username, $noerr);
 667     return undef if !$data;
 668
 669     if (!$data->{enable}) {
 670         die "user '$username' is disabled\n" if !$noerr;
 671         return undef;
 672     }
 673
 674     my $ctime = time();
 675     my $expire = $usercfg->{users}->{$username}->{expire};
 676
 677     if ($expire && $expire < $ctime) {
 678         die "user '$username' access expired\n" if !$noerr;
 679         return undef;
 680     }
 681
 682     return 1; # enabled and not expired
 683 }
 684
 685 sub check_token_exist {
 686     my ($usercfg, $username, $tokenid, $noerr) = @_;
 687
 688     my $user = check_user_exist($usercfg, $username, $noerr);
 689     return undef if !$user;
 690
 691     return $user->{tokens}->{$tokenid}
 692         if defined($user->{tokens}) && $user->{tokens}->{$tokenid};
 693
 694     die "no such token '$tokenid' for user '$username'\n" if !$noerr;
 695
 696     return undef;
 697 }
 698
 699 # deprecated
 700 sub verify_one_time_pw {
 701     my ($type, $username, $keys, $tfa_cfg, $otp) = @_;
 702
 703     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 704
 705     # fixme: proxy support?
 706     my $proxy;
 707
 708     if ($type eq 'yubico') {
 709         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 710                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 711     } elsif ($type eq 'oath') {
 712         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 713     } else {
 714         die "unknown tfa type '$type'\n";
 715     }
 716 }
 717
 718 # password should be utf8 encoded
 719 # Note: some plugins delay/sleep if auth fails
 720 sub authenticate_user : prototype($$$$;$) {
 721     my ($username, $password, $otp, $new_format, $tfa_challenge) = @_;
 722
 723     die "no username specified\n" if !$username;
 724
 725     my ($ruid, $realm);
 726
 727     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 728
 729     my $usercfg = cfs_read_file('user.cfg');
 730
 731     check_user_enabled($usercfg, $username);
 732
 733     my $domain_cfg = cfs_read_file('domains.cfg');
 734
 735     my $cfg = $domain_cfg->{ids}->{$realm};
 736     die "auth domain '$realm' does not exist\n" if !$cfg;
 737     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 738
 739     if ($tfa_challenge) {
 740         # This is the 2nd factor, use the password for the OTP response.
 741         my $tfa_challenge = authenticate_2nd_new($username, $realm, $password, $tfa_challenge);
 742         return wantarray ? ($username, $tfa_challenge) : $username;
 743     }
 744
 745     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 746
 747     if ($new_format) {
 748         # This is the first factor with an optional immediate 2nd factor for TOTP:
 749         my $tfa_challenge = authenticate_2nd_new($username, $realm, $otp, $tfa_challenge);
 750         return wantarray ? ($username, $tfa_challenge) : $username;
 751     } else {
 752         return authenticate_2nd_old($username, $realm, $otp);
 753     }
 754 }
 755
 756 sub authenticate_2nd_old : prototype($$$) {
 757     my ($username, $realm, $otp) = @_;
 758
 759     my ($type, $tfa_data) = user_get_tfa($username, $realm, 0);
 760     if ($type) {
 761         if ($type eq 'incompatible') {
 762             die "old login api disabled, user has incompatible TFA entries\n";
 763         } elsif ($type eq 'u2f') {
 764             # Note that if the user did not manage to complete the initial u2f registration
 765             # challenge we have a hash containing a 'challenge' entry in the user's tfa.cfg entry:
 766             $tfa_data = undef if exists $tfa_data->{challenge};
 767         } elsif (!defined($otp)) {
 768             # The user requires a 2nd factor but has not provided one. Return success but
 769             # don't clear $tfa_data.
 770         } else {
 771             my $keys = $tfa_data->{keys};
 772             my $tfa_cfg = $tfa_data->{config};
 773             verify_one_time_pw($type, $username, $keys, $tfa_cfg, $otp);
 774             $tfa_data = undef;
 775         }
 776
 777         # Return the type along with the rest:
 778         if ($tfa_data) {
 779             $tfa_data = {
 780                 type => $type,
 781                 data => $tfa_data,
 782             };
 783         }
 784     }
 785
 786     return wantarray ? ($username, $tfa_data) : $username;
 787 }
 788
 789 # Returns a tfa challenge or undef.
 790 sub authenticate_2nd_new : prototype($$$$) {
 791     my ($username, $realm, $otp, $tfa_challenge) = @_;
 792
 793     my $result = lock_tfa_config(sub {
 794         my ($tfa_cfg, $realm_tfa) = user_get_tfa($username, $realm, 1);
 795
 796         if (!defined($tfa_cfg)) {
 797             return undef;
 798         }
 799
 800         my $realm_type = $realm_tfa && $realm_tfa->{type};
 801         # verify realm type unless using recovery keys:
 802         if (defined($realm_type)) {
 803             $realm_type = 'totp' if $realm_type eq 'oath'; # we used to call it that
 804             if ($realm_type eq 'yubico') {
 805                 # Yubico auth will not be supported in rust for now...
 806                 if (!defined($tfa_challenge)) {
 807                     my $challenge = { yubico => JSON::true };
 808                     # Even with yubico auth we do allow recovery keys to be used:
 809                     if (my $recovery = $tfa_cfg->recovery_state($username)) {
 810                         $challenge->{recovery} = $recovery;
 811                     }
 812                     return to_json($challenge);
 813                 }
 814
 815                 if ($otp =~ /^yubico:(.*)$/) {
 816                     $otp = $1;
 817                     # Defer to after unlocking the TFA config:
 818                     return sub {
 819                         authenticate_yubico_new(
 820                             $tfa_cfg, $username, $realm_tfa, $tfa_challenge, $otp,
 821                         );
 822                     };
 823                 }
 824             }
 825
 826             my $response_type;
 827             if (defined($otp)) {
 828                 if ($otp !~ /^([^:]+):/) {
 829                     die "bad otp response\n";
 830                 }
 831                 $response_type = $1;
 832             }
 833
 834             die "realm requires $realm_type authentication\n"
 835                 if $response_type && $response_type ne 'recovery' && $response_type ne $realm_type;
 836         }
 837
 838         configure_u2f_and_wa($tfa_cfg);
 839
 840         my $must_save = 0;
 841         if (defined($tfa_challenge)) {
 842             $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 843             $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $otp);
 844             $tfa_challenge = undef;
 845         } else {
 846             $tfa_challenge = $tfa_cfg->authentication_challenge($username);
 847             if (defined($otp)) {
 848                 if (defined($tfa_challenge)) {
 849                     $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $otp);
 850                 } else {
 851                     die "no such challenge\n";
 852                 }
 853             }
 854         }
 855
 856         if ($must_save) {
 857             cfs_write_file('priv/tfa.cfg', $tfa_cfg);
 858         }
 859
 860         return $tfa_challenge;
 861     });
 862
 863     # Yubico auth returns the authentication sub:
 864     if (ref($result) eq 'CODE') {
 865         $result = $result->();
 866     }
 867
 868     return $result;
 869 }
 870
 871 sub authenticate_yubico_new : prototype($$$) {
 872     my ($tfa_cfg, $username, $realm, $tfa_challenge, $otp) = @_;
 873
 874     $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 875     $tfa_challenge = from_json($tfa_challenge);
 876
 877     if (!$tfa_challenge->{yubico}) {
 878         die "no such challenge\n";
 879     }
 880
 881     my $keys = $tfa_cfg->get_yubico_keys($username);
 882     die "no keys configured\n" if !defined($keys) || !length($keys);
 883
 884     authenticate_yubico_do($otp, $keys, $realm);
 885
 886     # return `undef` to clear the tfa challenge.
 887     return undef;
 888 }
 889
 890 sub authenticate_yubico_do : prototype($$$) {
 891     my ($value, $keys, $realm) = @_;
 892
 893     # fixme: proxy support?
 894     my $proxy = undef;
 895
 896     PVE::OTP::yubico_verify_otp($value, $keys, $realm->{url}, $realm->{id}, $realm->{key}, $proxy);
 897 }
 898
 899 sub configure_u2f_and_wa : prototype($) {
 900     my ($tfa_cfg) = @_;
 901
 902     my $rpc_origin;
 903     my $get_origin = sub {
 904         return $rpc_origin if defined($rpc_origin);
 905         my $rpcenv = PVE::RPCEnvironment::get();
 906         if (my $origin = $rpcenv->get_request_host(1)) {
 907             $rpc_origin = "https://$origin";
 908             return $rpc_origin;
 909         }
 910         die "failed to figure out origin\n";
 911     };
 912
 913     my $dc = cfs_read_file('datacenter.cfg');
 914     if (my $u2f = $dc->{u2f}) {
 915         eval {
 916             $tfa_cfg->set_u2f_config({
 917                 origin => $u2f->{origin} // $get_origin->(),
 918                 appid => $u2f->{appid},
 919             });
 920         };
 921         warn "u2f unavailable, configuration error: $@\n" if $@;
 922     }
 923     if (my $wa = $dc->{webauthn}) {
 924         $wa->{origin} //= $get_origin->();
 925         eval { $tfa_cfg->set_webauthn_config({%$wa}) };
 926         warn "webauthn unavailable, configuration error: $@\n" if $@;
 927     }
 928 }
 929
 930 sub domain_set_password {
 931     my ($realm, $username, $password) = @_;
 932
 933     die "no auth domain specified" if !$realm;
 934
 935     my $domain_cfg = cfs_read_file('domains.cfg');
 936
 937     my $cfg = $domain_cfg->{ids}->{$realm};
 938     die "auth domain '$realm' does not exist\n" if !$cfg;
 939     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 940     $plugin->store_password($cfg, $realm, $username, $password);
 941 }
 942
 943 sub add_user_group {
 944     my ($username, $usercfg, $group) = @_;
 945
 946     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 947     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 948 }
 949
 950 sub delete_user_group {
 951     my ($username, $usercfg) = @_;
 952
 953     foreach my $group (keys %{$usercfg->{groups}}) {
 954
 955         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 956             if $usercfg->{groups}->{$group}->{users}->{$username};
 957     }
 958 }
 959
 960 sub delete_user_acl {
 961     my ($username, $usercfg) = @_;
 962
 963     foreach my $acl (keys %{$usercfg->{acl}}) {
 964
 965         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 966             if $usercfg->{acl}->{$acl}->{users}->{$username};
 967     }
 968 }
 969
 970 sub delete_group_acl {
 971     my ($group, $usercfg) = @_;
 972
 973     foreach my $acl (keys %{$usercfg->{acl}}) {
 974
 975         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 976             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 977     }
 978 }
 979
 980 sub delete_pool_acl {
 981     my ($pool, $usercfg) = @_;
 982
 983     my $path = "/pool/$pool";
 984
 985     delete ($usercfg->{acl}->{$path})
 986 }
 987
 988 # we automatically create some predefined roles by splitting privs
 989 # into 3 groups (per category)
 990 # root: only root is allowed to do that
 991 # admin: an administrator can to that
 992 # user: a normal user/customer can to that
 993 my $privgroups = {
 994     VM => {
 995         root => [],
 996         admin => [
 997             'VM.Config.Disk',
 998             'VM.Config.CPU',
 999             'VM.Config.Memory',
1000             'VM.Config.Network',
1001             'VM.Config.HWType',
1002             'VM.Config.Options', # covers all other things
1003             'VM.Allocate',
1004             'VM.Clone',
1005             'VM.Migrate',
1006             'VM.Monitor',
1007             'VM.Snapshot',
1008             'VM.Snapshot.Rollback',
1009         ],
1010         user => [
1011             'VM.Config.CDROM', # change CDROM media
1012             'VM.Config.Cloudinit',
1013             'VM.Console',
1014             'VM.Backup',
1015             'VM.PowerMgmt',
1016         ],
1017         audit => [
1018             'VM.Audit',
1019         ],
1020     },
1021     Sys => {
1022         root => [
1023             'Sys.PowerMgmt',
1024             'Sys.Modify', # edit/change node settings
1025         ],
1026         admin => [
1027             'Permissions.Modify',
1028             'Sys.Console',
1029             'Sys.Syslog',
1030         ],
1031         user => [],
1032         audit => [
1033             'Sys.Audit',
1034         ],
1035     },
1036     Datastore => {
1037         root => [],
1038         admin => [
1039             'Datastore.Allocate',
1040             'Datastore.AllocateTemplate',
1041         ],
1042         user => [
1043             'Datastore.AllocateSpace',
1044         ],
1045         audit => [
1046             'Datastore.Audit',
1047         ],
1048     },
1049     SDN => {
1050         root => [],
1051         admin => [
1052             'SDN.Allocate',
1053             'SDN.Audit',
1054         ],
1055         audit => [
1056             'SDN.Audit',
1057         ],
1058     },
1059     User => {
1060         root => [
1061             'Realm.Allocate',
1062         ],
1063         admin => [
1064             'User.Modify',
1065             'Group.Allocate', # edit/change group settings
1066             'Realm.AllocateUser',
1067         ],
1068         user => [],
1069         audit => [],
1070     },
1071     Pool => {
1072         root => [],
1073         admin => [
1074             'Pool.Allocate', # create/delete pools
1075         ],
1076         user => [
1077             'Pool.Audit',
1078         ],
1079         audit => [
1080             'Pool.Audit',
1081         ],
1082     },
1083 };
1084
1085 my $valid_privs = {};
1086
1087 my $special_roles = {
1088     'NoAccess' => {}, # no privileges
1089     'Administrator' => $valid_privs, # all privileges
1090 };
1091
1092 sub create_roles {
1093
1094     foreach my $cat (keys %$privgroups) {
1095         my $cd = $privgroups->{$cat};
1096         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
1097                        @{$cd->{user}}, @{$cd->{audit}}) {
1098             $valid_privs->{$p} = 1;
1099         }
1100         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
1101
1102             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
1103             $special_roles->{"PVEAdmin"}->{$p} = 1;
1104         }
1105         if (scalar(@{$cd->{user}})) {
1106             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
1107                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
1108             }
1109         }
1110         foreach my $p (@{$cd->{audit}}) {
1111             $special_roles->{"PVEAuditor"}->{$p} = 1;
1112         }
1113     }
1114
1115     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
1116 };
1117
1118 create_roles();
1119
1120 sub create_priv_properties {
1121     my $properties = {};
1122     foreach my $priv (keys %$valid_privs) {
1123         $properties->{$priv} = {
1124             type => 'boolean',
1125             optional => 1,
1126         };
1127     }
1128     return $properties;
1129 }
1130
1131 sub role_is_special {
1132     my ($role) = @_;
1133     return (exists $special_roles->{$role}) ? 1 : 0;
1134 }
1135
1136 sub add_role_privs {
1137     my ($role, $usercfg, $privs) = @_;
1138
1139     return if !$privs;
1140
1141     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
1142
1143     foreach my $priv (split_list($privs)) {
1144         if (defined ($valid_privs->{$priv})) {
1145             $usercfg->{roles}->{$role}->{$priv} = 1;
1146         } else {
1147             die "invalid privilege '$priv'\n";
1148         }
1149     }
1150 }
1151
1152 sub lookup_username {
1153     my ($username, $noerr) = @_;
1154
1155     $username =~ m!^(${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex})$!;
1156
1157     my $realm = $2;
1158     my $domain_cfg = cfs_read_file("domains.cfg");
1159     my $casesensitive = $domain_cfg->{ids}->{$realm}->{'case-sensitive'} // 1;
1160     my $usercfg = cfs_read_file('user.cfg');
1161
1162     if (!$casesensitive) {
1163         my @matches = grep { lc $username eq lc $_ } (keys %{$usercfg->{users}});
1164
1165         die "ambiguous case insensitive match of username '$username', cannot safely grant access!\n"
1166             if scalar @matches > 1 && !$noerr;
1167
1168         return $matches[0]
1169     }
1170
1171     return $username;
1172 }
1173
1174 sub normalize_path {
1175     my $path = shift;
1176
1177     return undef if !$path;
1178
1179     $path =~ s|/+|/|g;
1180
1181     $path =~ s|/$||;
1182
1183     $path = '/' if !$path;
1184
1185     $path = "/$path" if $path !~ m|^/|;
1186
1187     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
1188
1189     return $path;
1190 }
1191
1192 sub check_path {
1193     my ($path) = @_;
1194     return $path =~ m!^(
1195         /
1196         |/access
1197         |/access/groups
1198         |/access/groups/[[:alnum:]\.\-\_]+
1199         |/access/realm
1200         |/access/realm/[[:alnum:]\.\-\_]+
1201         |/nodes
1202         |/nodes/[[:alnum:]\.\-\_]+
1203         |/pool
1204         |/pool/[[:alnum:]\.\-\_]+
1205         |/sdn
1206         |/sdn/zones/[[:alnum:]\.\-\_]+
1207         |/sdn/vnets/[[:alnum:]\.\-\_]+
1208         |/storage
1209         |/storage/[[:alnum:]\.\-\_]+
1210         |/vms
1211         |/vms/[1-9][0-9]{2,}
1212     )$!xs;
1213 }
1214
1215 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
1216 sub verify_groupname {
1217     my ($groupname, $noerr) = @_;
1218
1219     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1220
1221         die "group name '$groupname' contains invalid characters\n" if !$noerr;
1222
1223         return undef;
1224     }
1225
1226     return $groupname;
1227 }
1228
1229 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
1230 sub verify_rolename {
1231     my ($rolename, $noerr) = @_;
1232
1233     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
1234
1235         die "role name '$rolename' contains invalid characters\n" if !$noerr;
1236
1237         return undef;
1238     }
1239
1240     return $rolename;
1241 }
1242
1243 PVE::JSONSchema::register_format('pve-poolid', \&verify_poolname);
1244 sub verify_poolname {
1245     my ($poolname, $noerr) = @_;
1246
1247     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1248
1249         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
1250
1251         return undef;
1252     }
1253
1254     return $poolname;
1255 }
1256
1257 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
1258 sub verify_privname {
1259     my ($priv, $noerr) = @_;
1260
1261     if (!$valid_privs->{$priv}) {
1262         die "invalid privilege '$priv'\n" if !$noerr;
1263
1264         return undef;
1265     }
1266
1267     return $priv;
1268 }
1269
1270 sub userconfig_force_defaults {
1271     my ($cfg) = @_;
1272
1273     foreach my $r (keys %$special_roles) {
1274         $cfg->{roles}->{$r} = $special_roles->{$r};
1275     }
1276
1277     # add root user if not exists
1278     if (!$cfg->{users}->{'root@pam'}) {
1279         $cfg->{users}->{'root@pam'}->{enable} = 1;
1280     }
1281 }
1282
1283 sub parse_user_config {
1284     my ($filename, $raw) = @_;
1285
1286     my $cfg = {};
1287
1288     userconfig_force_defaults($cfg);
1289
1290     $raw = '' if !defined($raw);
1291     while ($raw =~ /^\s*(.+?)\s*$/gm) {
1292         my $line = $1;
1293         my @data;
1294
1295         foreach my $d (split (/:/, $line)) {
1296             $d =~ s/^\s+//;
1297             $d =~ s/\s+$//;
1298             push @data, $d
1299         }
1300
1301         my $et = shift @data;
1302
1303         if ($et eq 'user') {
1304             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
1305
1306             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1307             if (!$realm) {
1308                 warn "user config - ignore user '$user' - invalid user name\n";
1309                 next;
1310             }
1311
1312             $enable = $enable ? 1 : 0;
1313
1314             $expire = 0 if !$expire;
1315
1316             if ($expire !~ m/^\d+$/) {
1317                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
1318                 next;
1319             }
1320             $expire = int($expire);
1321
1322             #if (!verify_groupname ($group, 1)) {
1323             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
1324             #    next;
1325             #}
1326
1327             $cfg->{users}->{$user} = {
1328                 enable => $enable,
1329                 # group => $group,
1330             };
1331             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
1332             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
1333             $cfg->{users}->{$user}->{email} = $email;
1334             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1335             $cfg->{users}->{$user}->{expire} = $expire;
1336             # keys: allowed yubico key ids or oath secrets (base32 encoded)
1337             $cfg->{users}->{$user}->{keys} = $keys if $keys;
1338
1339             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
1340             #$cfg->{groups}->{$group}->{$user} = 1;
1341
1342         } elsif ($et eq 'group') {
1343             my ($group, $userlist, $comment) = @data;
1344
1345             if (!verify_groupname($group, 1)) {
1346                 warn "user config - ignore group '$group' - invalid characters in group name\n";
1347                 next;
1348             }
1349
1350             # make sure to add the group (even if there are no members)
1351             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
1352
1353             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1354
1355             foreach my $user (split_list($userlist)) {
1356
1357                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
1358                     warn "user config - ignore invalid group member '$user'\n";
1359                     next;
1360                 }
1361
1362                 if ($cfg->{users}->{$user}) { # user exists
1363                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
1364                 } else {
1365                     warn "user config - ignore invalid group member '$user'\n";
1366                 }
1367                 $cfg->{groups}->{$group}->{users}->{$user} = 1;
1368             }
1369
1370         } elsif ($et eq 'role') {
1371             my ($role, $privlist) = @data;
1372
1373             if (!verify_rolename($role, 1)) {
1374                 warn "user config - ignore role '$role' - invalid characters in role name\n";
1375                 next;
1376             }
1377
1378             # make sure to add the role (even if there are no privileges)
1379             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
1380
1381             foreach my $priv (split_list($privlist)) {
1382                 if (defined ($valid_privs->{$priv})) {
1383                     $cfg->{roles}->{$role}->{$priv} = 1;
1384                 } else {
1385                     warn "user config - ignore invalid privilege '$priv'\n";
1386                 }
1387             }
1388
1389         } elsif ($et eq 'acl') {
1390             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
1391
1392             $propagate = $propagate ? 1 : 0;
1393
1394             if (my $path = normalize_path($pathtxt)) {
1395                 foreach my $role (split_list($rolelist)) {
1396
1397                     if (!verify_rolename($role, 1)) {
1398                         warn "user config - ignore invalid role name '$role' in acl\n";
1399                         next;
1400                     }
1401
1402                     if (!$cfg->{roles}->{$role}) {
1403                         warn "user config - ignore invalid acl role '$role'\n";
1404                         next;
1405                     }
1406
1407                     foreach my $ug (split_list($uglist)) {
1408                         my ($group) = $ug =~ m/^@(\S+)$/;
1409
1410                         if ($group && verify_groupname($group, 1)) {
1411                             if (!$cfg->{groups}->{$group}) { # group does not exist
1412                                 warn "user config - ignore invalid acl group '$group'\n";
1413                             }
1414                             $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
1415                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
1416                             if (!$cfg->{users}->{$ug}) { # user does not exist
1417                                 warn "user config - ignore invalid acl member '$ug'\n";
1418                             }
1419                             $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
1420                         } elsif (my ($user, $token) = split_tokenid($ug, 1)) {
1421                             if (check_token_exist($cfg, $user, $token, 1)) {
1422                                 $cfg->{acl}->{$path}->{tokens}->{$ug}->{$role} = $propagate;
1423                             } else {
1424                                 warn "user config - ignore invalid acl token '$ug'\n";
1425                             }
1426                         } else {
1427                             warn "user config - invalid user/group '$ug' in acl\n";
1428                         }
1429                     }
1430                 }
1431             } else {
1432                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
1433             }
1434         } elsif ($et eq 'pool') {
1435             my ($pool, $comment, $vmlist, $storelist) = @data;
1436
1437             if (!verify_poolname($pool, 1)) {
1438                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
1439                 next;
1440             }
1441
1442             # make sure to add the pool (even if there are no members)
1443             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
1444
1445             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1446
1447             foreach my $vmid (split_list($vmlist)) {
1448                 if ($vmid !~ m/^\d+$/) {
1449                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
1450                     next;
1451                 }
1452                 $vmid = int($vmid);
1453
1454                 if ($cfg->{vms}->{$vmid}) {
1455                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
1456                     next;
1457                 }
1458
1459                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
1460
1461                 # record vmid ==> pool relation
1462                 $cfg->{vms}->{$vmid} = $pool;
1463             }
1464
1465             foreach my $storeid (split_list($storelist)) {
1466                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
1467                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
1468                     next;
1469                 }
1470                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1471             }
1472         } elsif ($et eq 'token') {
1473             my ($tokenid, $expire, $privsep, $comment) = @data;
1474
1475             my ($user, $token) = split_tokenid($tokenid, 1);
1476             if (!($user && $token)) {
1477                 warn "user config - ignore invalid tokenid '$tokenid'\n";
1478                 next;
1479             }
1480
1481             $privsep = $privsep ? 1 : 0;
1482
1483             $expire = 0 if !$expire;
1484
1485             if ($expire !~ m/^\d+$/) {
1486                 warn "user config - ignore token '$tokenid' - (illegal characters in expire '$expire')\n";
1487                 next;
1488             }
1489             $expire = int($expire);
1490
1491             if (my $user_cfg = $cfg->{users}->{$user}) { # user exists
1492                 $user_cfg->{tokens}->{$token} = {} if !$user_cfg->{tokens}->{$token};
1493                 my $token_cfg = $user_cfg->{tokens}->{$token};
1494                 $token_cfg->{privsep} = $privsep;
1495                 $token_cfg->{expire} = $expire;
1496                 $token_cfg->{comment} = PVE::Tools::decode_text($comment) if $comment;
1497             } else {
1498                 warn "user config - ignore token '$tokenid' - user does not exist\n";
1499             }
1500         } else {
1501             warn "user config - ignore config line: $line\n";
1502         }
1503     }
1504
1505     userconfig_force_defaults($cfg);
1506
1507     return $cfg;
1508 }
1509
1510 sub write_user_config {
1511     my ($filename, $cfg) = @_;
1512
1513     my $data = '';
1514
1515     foreach my $user (sort keys %{$cfg->{users}}) {
1516         my $d = $cfg->{users}->{$user};
1517         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1518         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1519         my $email = $d->{email} || '';
1520         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1521         my $expire = int($d->{expire} || 0);
1522         my $enable = $d->{enable} ? 1 : 0;
1523         my $keys = $d->{keys} ? $d->{keys} : '';
1524         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
1525
1526         my $user_tokens = $d->{tokens};
1527         foreach my $token (sort keys %$user_tokens) {
1528             my $td = $user_tokens->{$token};
1529             my $full_tokenid = join_tokenid($user, $token);
1530             my $comment = $td->{comment} ? PVE::Tools::encode_text($td->{comment}) : '';
1531             my $expire = int($td->{expire} || 0);
1532             my $privsep = $td->{privsep} ? 1 : 0;
1533             $data .= "token:$full_tokenid:$expire:$privsep:$comment:\n";
1534         }
1535     }
1536
1537     $data .= "\n";
1538
1539     foreach my $group (sort keys %{$cfg->{groups}}) {
1540         my $d = $cfg->{groups}->{$group};
1541         my $list = join (',', sort keys %{$d->{users}});
1542         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1543         $data .= "group:$group:$list:$comment:\n";
1544     }
1545
1546     $data .= "\n";
1547
1548     foreach my $pool (sort keys %{$cfg->{pools}}) {
1549         my $d = $cfg->{pools}->{$pool};
1550         my $vmlist = join (',', sort keys %{$d->{vms}});
1551         my $storelist = join (',', sort keys %{$d->{storage}});
1552         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1553         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1554     }
1555
1556     $data .= "\n";
1557
1558     foreach my $role (sort keys %{$cfg->{roles}}) {
1559         next if $special_roles->{$role};
1560
1561         my $d = $cfg->{roles}->{$role};
1562         my $list = join (',', sort keys %$d);
1563         $data .= "role:$role:$list:\n";
1564     }
1565
1566     $data .= "\n";
1567
1568     my $collect_rolelist_members = sub {
1569         my ($acl_members, $result, $prefix, $exclude) = @_;
1570
1571         foreach my $member (keys %$acl_members) {
1572             next if $exclude && $member eq $exclude;
1573
1574             my $l0 = '';
1575             my $l1 = '';
1576             foreach my $role (sort keys %{$acl_members->{$member}}) {
1577                 my $propagate = $acl_members->{$member}->{$role};
1578                 if ($propagate) {
1579                     $l1 .= ',' if $l1;
1580                     $l1 .= $role;
1581                 } else {
1582                     $l0 .= ',' if $l0;
1583                     $l0 .= $role;
1584                 }
1585             }
1586             $result->{0}->{$l0}->{"${prefix}${member}"} = 1 if $l0;
1587             $result->{1}->{$l1}->{"${prefix}${member}"} = 1 if $l1;
1588         }
1589     };
1590
1591     foreach my $path (sort keys %{$cfg->{acl}}) {
1592         my $d = $cfg->{acl}->{$path};
1593
1594         my $rolelist_members = {};
1595
1596         $collect_rolelist_members->($d->{'groups'}, $rolelist_members, '@');
1597
1598         # no need to save 'root@pam', it is always 'Administrator'
1599         $collect_rolelist_members->($d->{'users'}, $rolelist_members, '', 'root@pam');
1600
1601         $collect_rolelist_members->($d->{'tokens'}, $rolelist_members, '');
1602
1603         foreach my $propagate (0,1) {
1604             my $filtered = $rolelist_members->{$propagate};
1605             foreach my $rolelist (sort keys %$filtered) {
1606                 my $uglist = join (',', sort keys %{$filtered->{$rolelist}});
1607                 $data .= "acl:$propagate:$path:$uglist:$rolelist:\n";
1608             }
1609
1610         }
1611     }
1612
1613     return $data;
1614 }
1615
1616 # Creates a `PVE::RS::TFA` instance from the raw config data.
1617 # Its contained hash will also support the legacy functionality.
1618 sub parse_priv_tfa_config {
1619     my ($filename, $raw) = @_;
1620
1621     $raw = '' if !defined($raw);
1622     my $cfg = PVE::RS::TFA->new($raw);
1623
1624     # Purge invalid users:
1625     foreach my $user ($cfg->users()->@*) {
1626         my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1627         if (!$realm) {
1628             warn "user tfa config - ignore user '$user' - invalid user name\n";
1629             $cfg->remove_user($user);
1630         }
1631     }
1632
1633     return $cfg;
1634 }
1635
1636 sub write_priv_tfa_config {
1637     my ($filename, $cfg) = @_;
1638
1639     assert_new_tfa_config_available();
1640
1641     return $cfg->write();
1642 }
1643
1644 sub roles {
1645     my ($cfg, $user, $path) = @_;
1646
1647     # NOTE: we do not consider pools here.
1648     # NOTE: for privsep tokens, this does not filter roles by those that the
1649     # corresponding user has.
1650     # Use $rpcenv->permission() for any actual permission checks!
1651
1652     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1653
1654     if (!defined($path)) {
1655         # this shouldn't happen!
1656         warn "internal error: ACL check called for undefined ACL path!\n";
1657         return {};
1658     }
1659
1660     if (pve_verify_tokenid($user, 1)) {
1661         my $tokenid = $user;
1662         my ($username, $token) = split_tokenid($tokenid);
1663
1664         my $token_info = $cfg->{users}->{$username}->{tokens}->{$token};
1665         return () if !$token_info;
1666
1667         my $user_roles = roles($cfg, $username, $path);
1668
1669         # return full user privileges
1670         return $user_roles if !$token_info->{privsep};
1671     }
1672
1673     my $roles = {};
1674
1675     foreach my $p (sort keys %{$cfg->{acl}}) {
1676         my $final = ($path eq $p);
1677
1678         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1679
1680         my $acl = $cfg->{acl}->{$p};
1681
1682         #print "CHECKACL $path $p\n";
1683         #print "ACL $path = " . Dumper ($acl);
1684         if (my $ri = $acl->{tokens}->{$user}) {
1685             my $new;
1686             foreach my $role (keys %$ri) {
1687                 my $propagate = $ri->{$role};
1688                 if ($final || $propagate) {
1689                     #print "APPLY ROLE $p $user $role\n";
1690                     $new = {} if !$new;
1691                     $new->{$role} = $propagate;
1692                 }
1693             }
1694             if ($new) {
1695                 $roles = $new; # overwrite previous settings
1696                 next;
1697             }
1698         }
1699
1700         if (my $ri = $acl->{users}->{$user}) {
1701             my $new;
1702             foreach my $role (keys %$ri) {
1703                 my $propagate = $ri->{$role};
1704                 if ($final || $propagate) {
1705                     #print "APPLY ROLE $p $user $role\n";
1706                     $new = {} if !$new;
1707                     $new->{$role} = $propagate;
1708                 }
1709             }
1710             if ($new) {
1711                 $roles = $new; # overwrite previous settings
1712                 next; # user privs always override group privs
1713             }
1714         }
1715
1716         my $new;
1717         foreach my $g (keys %{$acl->{groups}}) {
1718             next if !$cfg->{groups}->{$g}->{users}->{$user};
1719             if (my $ri = $acl->{groups}->{$g}) {
1720                 foreach my $role (keys %$ri) {
1721                     my $propagate = $ri->{$role};
1722                     if ($final || $propagate) {
1723                         #print "APPLY ROLE $p \@$g $role\n";
1724                         $new = {} if !$new;
1725                         $new->{$role} = $propagate;
1726                     }
1727                 }
1728             }
1729         }
1730         if ($new) {
1731             $roles = $new; # overwrite previous settings
1732             next;
1733         }
1734     }
1735
1736     return { 'NoAccess' => $roles->{NoAccess} } if defined ($roles->{NoAccess});
1737     #return () if defined ($roles->{NoAccess});
1738
1739     #print "permission $user $path = " . Dumper ($roles);
1740
1741     #print "roles $user $path = " . join (',', @ra) . "\n";
1742
1743     return $roles;
1744 }
1745
1746 sub remove_vm_access {
1747     my ($vmid) = @_;
1748     my $delVMaccessFn = sub {
1749         my $usercfg = cfs_read_file("user.cfg");
1750         my $modified;
1751
1752         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1753             delete $usercfg->{acl}->{"/vms/$vmid"};
1754             $modified = 1;
1755         }
1756         if (my $pool = $usercfg->{vms}->{$vmid}) {
1757             if (my $data = $usercfg->{pools}->{$pool}) {
1758                 delete $data->{vms}->{$vmid};
1759                 delete $usercfg->{vms}->{$vmid};
1760                 $modified = 1;
1761             }
1762         }
1763         cfs_write_file("user.cfg", $usercfg) if $modified;
1764     };
1765
1766     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1767 }
1768
1769 sub remove_storage_access {
1770     my ($storeid) = @_;
1771
1772     my $deleteStorageAccessFn = sub {
1773         my $usercfg = cfs_read_file("user.cfg");
1774         my $modified;
1775
1776         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1777             delete $usercfg->{acl}->{"/storage/$storeid"};
1778             $modified = 1;
1779         }
1780         foreach my $pool (keys %{$usercfg->{pools}}) {
1781             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1782             $modified = 1;
1783         }
1784         cfs_write_file("user.cfg", $usercfg) if $modified;
1785     };
1786
1787     lock_user_config($deleteStorageAccessFn,
1788                      "access permissions cleanup for storage $storeid failed");
1789 }
1790
1791 sub add_vm_to_pool {
1792     my ($vmid, $pool) = @_;
1793
1794     my $addVMtoPoolFn = sub {
1795         my $usercfg = cfs_read_file("user.cfg");
1796         if (my $data = $usercfg->{pools}->{$pool}) {
1797             $data->{vms}->{$vmid} = 1;
1798             $usercfg->{vms}->{$vmid} = $pool;
1799             cfs_write_file("user.cfg", $usercfg);
1800         }
1801     };
1802
1803     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1804 }
1805
1806 sub remove_vm_from_pool {
1807     my ($vmid) = @_;
1808
1809     my $delVMfromPoolFn = sub {
1810         my $usercfg = cfs_read_file("user.cfg");
1811         if (my $pool = $usercfg->{vms}->{$vmid}) {
1812             if (my $data = $usercfg->{pools}->{$pool}) {
1813                 delete $data->{vms}->{$vmid};
1814                 delete $usercfg->{vms}->{$vmid};
1815                 cfs_write_file("user.cfg", $usercfg);
1816             }
1817         }
1818     };
1819
1820     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1821 }
1822
1823 my $USER_CONTROLLED_TFA_TYPES = {
1824     u2f => 1,
1825     oath => 1,
1826 };
1827
1828 sub assert_new_tfa_config_available() {
1829     PVE::Cluster::cfs_update();
1830     my $version_info = PVE::Cluster::get_node_kv('version-info');
1831     die "cannot update tfa config, please make sure all cluster nodes are up to date\n"
1832         if !$version_info;
1833     my $members = PVE::Cluster::get_members() or return; # get_members returns undef on no cluster
1834     my $old = '';
1835     foreach my $node (keys $members->%*) {
1836         my $info = $version_info->{$node};
1837         if (!$info) {
1838             $old .= "  cluster node '$node' is too old, did not broadcast its version info\n";
1839             next;
1840         }
1841         $info = from_json($info);
1842         my $ver = $info->{version};
1843         if ($ver !~ /^(\d+\.\d+)-(\d+)/) {
1844             $old .= "  cluster node '$node' provided an invalid version string: '$ver'\n";
1845             next;
1846         }
1847         my ($maj, $rel) = ($1, $2);
1848         if (!($maj > 7.0 || ($maj == 7.0 && $rel >= 15))) {
1849             $old .= "  cluster node '$node' is too old ($ver < 7.0-15)\n";
1850             next;
1851         }
1852     }
1853     die "cannot update tfa config, following nodes are not up to date:\n$old" if length($old);
1854 }
1855
1856 sub user_remove_tfa : prototype($) {
1857     my ($userid) = @_;
1858
1859     assert_new_tfa_config_available();
1860
1861     my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1862     $tfa_cfg->remove_user($userid);
1863     cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1864 }
1865
1866 my sub add_old_yubico_keys : prototype($$$) {
1867     my ($userid, $tfa_cfg, $keys) = @_;
1868
1869     my $count = 0;
1870     foreach my $key (split_list($keys)) {
1871         my $description = "<old userconfig key $count>";
1872         ++$count;
1873         $tfa_cfg->add_yubico_entry($userid, $description, $key);
1874     }
1875 }
1876
1877 my sub normalize_totp_secret : prototype($) {
1878     my ($key) = @_;
1879
1880     my $binkey;
1881     # See PVE::OTP::oath_verify_otp:
1882     if ($key =~ /^v2-0x([0-9a-fA-F]+)$/) {
1883         # v2, hex
1884         $binkey = pack('H*', $1);
1885     } elsif ($key =~ /^v2-([A-Z2-7=]+)$/) {
1886         # v2, base32
1887         $binkey = MIME::Base32::decode_rfc3548($1);
1888     } elsif ($key =~ /^[A-Z2-7=]{16}$/) {
1889         $binkey = MIME::Base32::decode_rfc3548($key);
1890     } elsif ($key =~ /^[A-Fa-f0-9]{40}$/) {
1891         $binkey = pack('H*', $key);
1892     } else {
1893         return undef;
1894     }
1895
1896     return MIME::Base32::encode_rfc3548($binkey);
1897 }
1898
1899 my sub add_old_totp_keys : prototype($$$$) {
1900     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1901
1902     my $issuer = 'Proxmox%20VE';
1903     my $account = uri_escape("Old key for $userid");
1904     my $digits = $realm_tfa->{digits} || 6;
1905     my $step = $realm_tfa->{step} || 30;
1906     my $uri = "otpauth://totp/$issuer:$account?digits=$digits&period=$step&algorithm=SHA1&secret=";
1907
1908     my $count = 0;
1909     foreach my $key (split_list($keys)) {
1910         $key = normalize_totp_secret($key);
1911         # and just skip invalid keys:
1912         next if !defined($key);
1913
1914         my $description = "<old userconfig key $count>";
1915         ++$count;
1916         eval { $tfa_cfg->add_totp_entry($userid, $description, $uri . $key) };
1917         warn $@ if $@;
1918     }
1919 }
1920
1921 sub add_old_keys_to_realm_tfa : prototype($$$$) {
1922     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1923
1924     # if there's no realm tfa configured, we don't know what the keys mean, so we just ignore
1925     # them...
1926     return if !$realm_tfa;
1927
1928     my $type = $realm_tfa->{type};
1929     if ($type eq 'oath') {
1930         add_old_totp_keys($userid, $tfa_cfg, $realm_tfa, $keys);
1931     } elsif ($type eq 'yubico') {
1932         add_old_yubico_keys($userid, $tfa_cfg, $keys);
1933     } else {
1934         # invalid keys, we'll just drop them now...
1935     }
1936 }
1937
1938 sub user_get_tfa : prototype($$$) {
1939     my ($username, $realm, $new_format) = @_;
1940
1941     my $user_cfg = cfs_read_file('user.cfg');
1942     my $user = $user_cfg->{users}->{$username}
1943         or die "user '$username' not found\n";
1944
1945     my $keys = $user->{keys};
1946
1947     my $domain_cfg = cfs_read_file('domains.cfg');
1948     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1949     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1950
1951     my $realm_tfa = $realm_cfg->{tfa};
1952     $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa)
1953         if $realm_tfa;
1954
1955     if (!$keys) {
1956         return if !$realm_tfa;
1957         die "missing required 2nd keys\n";
1958     }
1959
1960     if ($new_format) {
1961         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1962         if (defined($keys) && $keys !~ /^x(?:!.*)$/) {
1963             add_old_keys_to_realm_tfa($username, $tfa_cfg, $realm_tfa, $keys);
1964         }
1965         return ($tfa_cfg, $realm_tfa);
1966     }
1967
1968     # new style config starts with an 'x' and optionally contains a !<type> suffix
1969     if ($keys !~ /^x(?:!.*)?$/) {
1970         # old style config, find the type via the realm
1971         return if !$realm_tfa;
1972         return ($realm_tfa->{type}, {
1973             keys => $keys,
1974             config => $realm_tfa,
1975         });
1976     } else {
1977         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1978         my $tfa = $tfa_cfg->{users}->{$username};
1979         return if !$tfa; # should not happen (user.cfg wasn't cleaned up?)
1980
1981         if ($realm_tfa) {
1982             # if the realm has a tfa setting we need to verify the type:
1983             die "auth domain '$realm' and user have mismatching TFA settings\n"
1984                 if $realm_tfa && $realm_tfa->{type} ne $tfa->{type};
1985         }
1986
1987         return ($tfa->{type}, $tfa->{data});
1988     }
1989 }
1990
1991 # bash completion helpers
1992
1993 register_standard_option('userid-completed',
1994     get_standard_option('userid', { completion => \&complete_username}),
1995 );
1996
1997 sub complete_username {
1998
1999     my $user_cfg = cfs_read_file('user.cfg');
2000
2001     return [ keys %{$user_cfg->{users}} ];
2002 }
2003
2004 sub complete_group {
2005
2006     my $user_cfg = cfs_read_file('user.cfg');
2007
2008     return [ keys %{$user_cfg->{groups}} ];
2009 }
2010
2011 sub complete_realm {
2012
2013     my $domain_cfg = cfs_read_file('domains.cfg');
2014
2015     return [ keys %{$domain_cfg->{ids}} ];
2016 }
2017
2018 1;