src/PVE/RPCEnvironment.pm

   1 package PVE::RPCEnvironment;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::AccessControl;
   7 use PVE::Cluster;
   8 use PVE::Exception qw(raise raise_perm_exc);
   9 use PVE::INotify;
  10 use PVE::ProcFSTools;
  11 use PVE::RESTEnvironment;
  12 use PVE::SafeSyslog;
  13 use PVE::Tools;
  14
  15 use base qw(PVE::RESTEnvironment);
  16
  17 # ACL cache
  18
  19 my $compile_acl_path = sub {
  20     my ($self, $user, $path) = @_;
  21
  22     my $cfg = $self->{user_cfg};
  23
  24     return undef if !$cfg->{roles};
  25
  26     # permissions() has an early return for this case
  27     die "internal error" if $user eq 'root@pam';
  28
  29     my $cache = $self->{aclcache};
  30     $cache->{$user} = {} if !$cache->{$user};
  31     my $data = $cache->{$user};
  32
  33     # permissions() will always prime the cache for the owning user
  34     my ($username, undef) = PVE::AccessControl::split_tokenid($user, 1);
  35     die "internal error" if $username && $username ne 'root@pam' && !defined($cache->{$username});
  36
  37     # resolve and cache roles of the current user/token for all pool ACL paths
  38     if (!$data->{poolroles}) {
  39         $data->{poolroles} = {};
  40
  41         foreach my $pool (keys %{$cfg->{pools}}) {
  42             my $d = $cfg->{pools}->{$pool};
  43             my $pool_roles = PVE::AccessControl::roles($cfg, $user, "/pool/$pool"); # pool roles
  44             next if !scalar(keys %$pool_roles);
  45             foreach my $vmid (keys %{$d->{vms}}) {
  46                 for my $role (keys %$pool_roles) {
  47                     $data->{poolroles}->{"/vms/$vmid"}->{$role} = 1;
  48                 }
  49             }
  50             foreach my $storeid (keys %{$d->{storage}}) {
  51                 for my $role (keys %$pool_roles) {
  52                     $data->{poolroles}->{"/storage/$storeid"}->{$role} = 1;
  53                 }
  54             }
  55         }
  56     }
  57
  58     # get roles of current user/token on checked path - this already handles
  59     # propagation and NoAccess along the path
  60     #
  61     # hash mapping role name to propagation flag value, a key being defined
  62     # means the role is set
  63     my $roles = PVE::AccessControl::roles($cfg, $user, $path);
  64
  65     # apply roles inherited from pools
  66     if ($data->{poolroles}->{$path}) {
  67         # NoAccess must not be trumped by pool ACLs
  68         if (!defined($roles->{NoAccess})) {
  69             if ($data->{poolroles}->{$path}->{NoAccess}) {
  70                 # but pool ACL NoAccess trumps regular ACL
  71                 $roles = { 'NoAccess' => 0 };
  72             } else {
  73                 foreach my $role (keys %{$data->{poolroles}->{$path}}) {
  74                     # only use role from pool ACL if regular ACL didn't already
  75                     # set it, and never set propagation for pool-derived ACLs
  76                     $roles->{$role} = 0 if !defined($roles->{$role});
  77                 }
  78             }
  79         }
  80     }
  81
  82     # cache roles
  83     $data->{roles}->{$path} = $roles;
  84
  85     # derive privs from set roles - hash mapping privilege name to propagation
  86     # flag value, a key being defined means the priv is set
  87     my $privs = {};
  88     foreach my $role (keys %$roles) {
  89         if (my $privset = $cfg->{roles}->{$role}) {
  90             foreach my $p (keys %$privset) {
  91                 # set priv '$p' to propagated iff any of the set roles
  92                 # containing it have the propagated flag set
  93                 $privs->{$p} ||= $roles->{$role};
  94             }
  95         }
  96     }
  97
  98     # intersect user and token permissions
  99     if ($username && $username ne 'root@pam') {
 100         # map of set privs to their propagation flag value, for the owning user
 101         my $user_privs = $cache->{$username}->{privs}->{$path};
 102         # list of privs set both for token and owning user
 103         my $filtered_privs = [ grep { defined($user_privs->{$_}) } keys %$privs ];
 104         # intersection of privs using filtered list, combining both propagation
 105         # flags
 106         $privs = { map { $_ => $user_privs->{$_} && $privs->{$_} } @$filtered_privs };
 107     }
 108
 109     foreach my $priv (keys %$privs) {
 110         # safeguard, this should never happen anyway
 111         delete $privs->{$priv} if !defined($privs->{$priv});
 112     }
 113
 114     # cache privs
 115     $data->{privs}->{$path} = $privs;
 116
 117     return $privs;
 118 };
 119
 120 # this is the method used by permission check helpers below
 121 #
 122 # returned value is a hash mapping all set privileges on $path to their
 123 # respective propagation flag. the propagation flag is informational only -
 124 # actual propagation is handled in PVE::AccessControl::roles(). to determine
 125 # whether a privilege is set, check for definedness in the returned hash.
 126 #
 127 # compiled ACLs are cached, so repeated checks for the same path and user are
 128 # almost free.
 129 #
 130 # if $user is a tokenid, permissions are calculated depending on the
 131 # privilege-separation flag value:
 132 # - non-priv-separated: permissions for owning user are returned
 133 # - priv-separated: permissions for owning user are calculated and intersected
 134 #   with those of token
 135 sub permissions {
 136     my ($self, $user, $path) = @_;
 137
 138     if ($user eq 'root@pam') { # root can do anything
 139         my $cfg = $self->{user_cfg};
 140         return { map { $_ => 1 } keys %{$cfg->{roles}->{'Administrator'}} };
 141     }
 142
 143     if (!defined($path)) {
 144         # this shouldn't happen!
 145         warn "internal error: ACL check called for undefined ACL path!\n";
 146         return {};
 147     }
 148
 149     if (PVE::AccessControl::pve_verify_tokenid($user, 1)) {
 150         my ($username, $token) = PVE::AccessControl::split_tokenid($user);
 151         my $cfg = $self->{user_cfg};
 152         my $token_info = $cfg->{users}->{$username}->{tokens}->{$token};
 153
 154         return {} if !$token_info;
 155
 156         # ensure cache for user is populated
 157         my $user_perms = $self->permissions($username, $path);
 158
 159         # return user privs for non-privsep tokens
 160         return $user_perms if !$token_info->{privsep};
 161     } else {
 162         $user = PVE::AccessControl::verify_username($user, 1);
 163         return {} if !$user;
 164     }
 165
 166     my $cache = $self->{aclcache};
 167     $cache->{$user} = {} if !$cache->{$user};
 168
 169     my $acl = $cache->{$user};
 170
 171     my $perm = $acl->{privs}->{$path};
 172     return $perm if $perm;
 173
 174     return &$compile_acl_path($self, $user, $path);
 175 }
 176
 177 sub compute_api_permission {
 178     my ($self, $authuser) = @_;
 179
 180     my $usercfg = $self->{user_cfg};
 181
 182     my $res = {};
 183     my $priv_re_map = {
 184         vms => qr/VM\.|Permissions\.Modify/,
 185         access => qr/(User|Group)\.|Permissions\.Modify/,
 186         storage => qr/Datastore\.|Permissions\.Modify/,
 187         nodes => qr/Sys\.|Permissions\.Modify/,
 188         sdn => qr/SDN\.|Permissions\.Modify/,
 189         dc => qr/Sys\.Audit|Sys\.Modify|SDN\./,
 190     };
 191     map { $res->{$_} = {} } keys %$priv_re_map;
 192
 193     my $required_paths = ['/', '/nodes', '/access/groups', '/vms', '/storage', '/sdn'];
 194     my $defined_paths = [];
 195     PVE::AccessControl::iterate_acl_tree("/", $usercfg->{acl_root}, sub {
 196         my ($path, $node) = @_;
 197         push @$defined_paths, $path;
 198     });
 199
 200     my $checked_paths = {};
 201     foreach my $path (@$required_paths, @$defined_paths) {
 202         next if $checked_paths->{$path};
 203         $checked_paths->{$path} = 1;
 204
 205         my $path_perm = $self->permissions($authuser, $path);
 206
 207         my $toplevel = ($path =~ /^\/(\w+)/) ? $1 : 'dc';
 208         if ($toplevel eq 'pool') {
 209             foreach my $priv (keys %$path_perm) {
 210                 next if !defined($path_perm->{$priv});
 211
 212                 if ($priv =~ m/^VM\./) {
 213                     $res->{vms}->{$priv} = 1;
 214                 } elsif ($priv =~ m/^Datastore\./) {
 215                     $res->{storage}->{$priv} = 1;
 216                 } elsif ($priv eq 'Permissions.Modify') {
 217                     $res->{storage}->{$priv} = 1;
 218                     $res->{vms}->{$priv} = 1;
 219                 }
 220             }
 221         } else {
 222             my $priv_regex = $priv_re_map->{$toplevel} // next;
 223             foreach my $priv (keys %$path_perm) {
 224                 next if !defined($path_perm->{$priv});
 225
 226                 next if $priv !~ m/^($priv_regex)/;
 227                 $res->{$toplevel}->{$priv} = 1;
 228             }
 229         }
 230     }
 231
 232     return $res;
 233 }
 234
 235 sub get_effective_permissions {
 236     my ($self, $user) = @_;
 237
 238     # default / top level paths
 239     my $paths = {
 240         '/' => 1,
 241         '/access' => 1,
 242         '/access/groups' => 1,
 243         '/nodes' => 1,
 244         '/pools' => 1,
 245         '/sdn' => 1,
 246         '/storage' => 1,
 247         '/vms' => 1,
 248     };
 249
 250     my $cfg = $self->{user_cfg};
 251
 252     # paths explicitly listed in ACLs
 253     PVE::AccessControl::iterate_acl_tree("/", $cfg->{acl_root}, sub {
 254         my ($path, $node) = @_;
 255         $paths->{$path} = 1;
 256     });
 257
 258     # paths referenced by pool definitions
 259     foreach my $pool (keys %{$cfg->{pools}}) {
 260         my $d = $cfg->{pools}->{$pool};
 261         foreach my $vmid (keys %{$d->{vms}}) {
 262             $paths->{"/vms/$vmid"} = 1;
 263         }
 264         foreach my $storeid (keys %{$d->{storage}}) {
 265             $paths->{"/storage/$storeid"} = 1;
 266         }
 267     }
 268
 269     my $perms = {};
 270     foreach my $path (keys %$paths) {
 271         my $path_perms = $self->permissions($user, $path);
 272         foreach my $priv (keys %$path_perms) {
 273             delete $path_perms->{$priv} if !defined($path_perms->{$priv});
 274         }
 275         # filter paths where user has NO permissions
 276         $perms->{$path} = $path_perms if %$path_perms;
 277     }
 278     return $perms;
 279 }
 280
 281 sub check {
 282     my ($self, $user, $path, $privs, $noerr) = @_;
 283
 284     my $perm = $self->permissions($user, $path);
 285
 286     foreach my $priv (@$privs) {
 287         PVE::AccessControl::verify_privname($priv);
 288         if (!defined($perm->{$priv})) {
 289             return undef if $noerr;
 290             raise_perm_exc("$path, $priv");
 291         }
 292     };
 293
 294     return 1;
 295 };
 296
 297 sub check_any {
 298     my ($self, $user, $path, $privs, $noerr) = @_;
 299
 300     my $perm = $self->permissions($user, $path);
 301
 302     my $found = 0;
 303     foreach my $priv (@$privs) {
 304         PVE::AccessControl::verify_privname($priv);
 305         if (defined($perm->{$priv})) {
 306             $found = 1;
 307             last;
 308         }
 309     };
 310
 311     return 1 if $found;
 312
 313     return undef if $noerr;
 314
 315     raise_perm_exc("$path, " . join("|", @$privs));
 316 };
 317
 318 sub check_full {
 319     my ($self, $username, $path, $privs, $any, $noerr) = @_;
 320     if ($any) {
 321         return $self->check_any($username, $path, $privs, $noerr);
 322     } else {
 323         return $self->check($username, $path, $privs, $noerr);
 324     }
 325 }
 326
 327 sub check_sdn_bridge {
 328     my ($self, $username, $zone, $bridge, $privs, $noerr) = @_;
 329
 330     my $path = "/sdn/zones/$zone/$bridge";
 331     my $cfg = $self->{user_cfg};
 332     my $bridge_acl = PVE::AccessControl::find_acl_tree_node($cfg->{acl_root}, $path);
 333     if ($bridge_acl) {
 334         my $vlans = $bridge_acl->{children};
 335         for my $vlan (keys %$vlans) {
 336             my $vlanpath = "$path/$vlan";
 337             return 1 if $self->check_any($username, $vlanpath, $privs, $noerr);
 338         }
 339         # check access to bridge itself
 340         return 1 if $self->check_any($username, $path, $privs, $noerr);
 341     }
 342     return;
 343 }
 344
 345 sub check_user_enabled {
 346     my ($self, $user, $noerr) = @_;
 347
 348     my $cfg = $self->{user_cfg};
 349     return PVE::AccessControl::check_user_enabled($cfg, $user, $noerr);
 350 }
 351
 352 sub check_user_exist {
 353     my ($self, $user, $noerr) = @_;
 354
 355     my $cfg = $self->{user_cfg};
 356     return PVE::AccessControl::check_user_exist($cfg, $user, $noerr);
 357 }
 358
 359 sub check_pool_exist {
 360     my ($self, $pool, $noerr) = @_;
 361
 362     my $cfg = $self->{user_cfg};
 363
 364     return 1 if $cfg->{pools}->{$pool};
 365
 366     return undef if $noerr;
 367
 368     raise_perm_exc("pool '$pool' does not exist");
 369 }
 370
 371 sub check_vm_perm {
 372     my ($self, $user, $vmid, $pool, $privs, $any, $noerr) = @_;
 373
 374     my $cfg = $self->{user_cfg};
 375
 376     if ($pool) {
 377         return if $self->check_full($user, "/pool/$pool", $privs, $any, 1);
 378     }
 379     return $self->check_full($user, "/vms/$vmid", $privs, $any, $noerr);
 380 };
 381
 382 sub is_group_member {
 383     my ($self, $group, $user) = @_;
 384
 385     my $cfg = $self->{user_cfg};
 386
 387     return 0 if !$cfg->{groups}->{$group};
 388
 389     return defined($cfg->{groups}->{$group}->{users}->{$user});
 390 }
 391
 392 sub filter_groups {
 393     my ($self, $user, $privs, $any) = @_;
 394
 395     my $cfg = $self->{user_cfg};
 396
 397     my $groups = {};
 398     foreach my $group (keys %{$cfg->{groups}}) {
 399         my $path = "/access/groups/$group";
 400         if ($self->check_full($user, $path, $privs, $any, 1)) {
 401             $groups->{$group} = $cfg->{groups}->{$group};
 402         }
 403     }
 404
 405     return $groups;
 406 }
 407
 408 sub group_member_join {
 409     my ($self, $grouplist) = @_;
 410
 411     my $users = {};
 412
 413     my $cfg = $self->{user_cfg};
 414     foreach my $group (@$grouplist) {
 415         my $data = $cfg->{groups}->{$group};
 416         next if !$data;
 417         foreach my $user (keys %{$data->{users}}) {
 418             $users->{$user} = 1;
 419         }
 420     }
 421
 422     return $users;
 423 }
 424
 425 sub check_perm_modify {
 426     my ($self, $username, $path, $noerr) = @_;
 427
 428     return $self->check($username, '/access', [ 'Permissions.Modify' ], $noerr) if !$path;
 429
 430     my $testperms = [ 'Permissions.Modify' ];
 431     if ($path =~ m|^/storage/.+$|) {
 432         push @$testperms, 'Datastore.Allocate';
 433     } elsif ($path =~ m|^/vms/.+$|) {
 434         push @$testperms, 'VM.Allocate';
 435     } elsif ($path =~ m|^/pool/.+$|) {
 436         push @$testperms, 'Pool.Allocate';
 437     }
 438
 439     return $self->check_any($username, $path, $testperms, $noerr);
 440 }
 441
 442 sub exec_api2_perm_check {
 443     my ($self, $check, $username, $param, $noerr) = @_;
 444
 445     # syslog("info", "CHECK " . join(', ', @$check));
 446
 447     my $ind = 0;
 448     my $test = $check->[$ind++];
 449     die "no permission test specified" if !$test;
 450
 451     if ($test eq 'and') {
 452         while (my $subcheck = $check->[$ind++]) {
 453             $self->exec_api2_perm_check($subcheck, $username, $param);
 454         }
 455         return 1;
 456     } elsif ($test eq 'or') {
 457         while (my $subcheck = $check->[$ind++]) {
 458             return 1 if $self->exec_api2_perm_check($subcheck, $username, $param, 1);
 459         }
 460         return 0 if $noerr;
 461         raise_perm_exc();
 462     } elsif ($test eq 'perm') {
 463         my ($t, $tmplpath, $privs, %options) = @$check;
 464         my $any = $options{any};
 465         die "missing parameters" if !($tmplpath && $privs);
 466         my $require_param = $options{require_param};
 467         if ($require_param && !defined($param->{$require_param})) {
 468             return 0 if $noerr;
 469             raise_perm_exc();
 470         }
 471         my $path = PVE::Tools::template_replace($tmplpath, $param);
 472         my $normpath = PVE::AccessControl::normalize_path($path);
 473         warn "Failed to normalize '$path'\n" if !defined($normpath) && defined($path);
 474
 475         return $self->check_full($username, $normpath, $privs, $any, $noerr);
 476     } elsif ($test eq 'userid-group') {
 477         my $userid = $param->{userid};
 478         my ($t, $privs, %options) = @$check;
 479
 480         my $check_existing_user = !$options{groups_param} || $options{groups_param} ne 'create';
 481         return 0 if $check_existing_user && !$self->check_user_exist($userid, $noerr);
 482
 483         # check permission for ALL groups (and thus ALL users)
 484         if (!$self->check_any($username, "/access/groups", $privs, 1)) {
 485             # list of groups $username has any of $privs on
 486             my $groups = $self->filter_groups($username, $privs, 1);
 487             if ($options{groups_param}) {
 488                 # does $username have any of $privs on all new/updated/.. groups?
 489                 my @group_param = PVE::Tools::split_list($param->{groups});
 490                 raise_perm_exc("/access/groups, " . join("|", @$privs)) if !scalar(@group_param);
 491                 foreach my $pg (@group_param) {
 492                     raise_perm_exc("/access/groups/$pg, " . join("|", @$privs))
 493                         if !$groups->{$pg};
 494                 }
 495             }
 496             if ($check_existing_user) {
 497                 # does $username have any of $privs on any existing group of $userid
 498                 my $allowed_users = $self->group_member_join([keys %$groups]);
 499                 if (!$allowed_users->{$userid}) {
 500                     return 0 if $noerr;
 501                     raise_perm_exc();
 502                 }
 503             }
 504         }
 505         return 1;
 506     } elsif ($test eq 'userid-param') {
 507         my ($userid, undef, $realm) = PVE::AccessControl::verify_username($param->{userid});
 508         my ($t, $subtest) = @$check;
 509         die "missing parameters" if !$subtest;
 510         if ($subtest eq 'self') {
 511             return 0 if !$self->check_user_exist($userid, $noerr);
 512             return 1 if $username eq $userid;
 513             return 0 if $noerr;
 514             raise_perm_exc();
 515         } elsif ($subtest eq 'Realm.AllocateUser') {
 516             my $path =  "/access/realm/$realm";
 517             return $self->check($username, $path, ['Realm.AllocateUser'], $noerr);
 518         } else {
 519             die "unknown userid-param test";
 520         }
 521     } elsif ($test eq 'perm-modify') {
 522         my ($t, $tmplpath) = @$check;
 523         my $path = PVE::Tools::template_replace($tmplpath, $param);
 524         $path = PVE::AccessControl::normalize_path($path);
 525         return 0 if !defined($path); # should already die in API2::ACL
 526         return $self->check_perm_modify($username, $path, $noerr);
 527     } else {
 528         die "unknown permission test";
 529     }
 530 };
 531
 532 sub check_api2_permissions {
 533     my ($self, $perm, $username, $param) = @_;
 534
 535     return 1 if !$username && $perm->{user} && $perm->{user} eq 'world';
 536
 537     raise_perm_exc("user != null") if !$username;
 538
 539     return 1 if $username eq 'root@pam';
 540
 541     raise_perm_exc('user != root@pam') if !$perm;
 542
 543     return 1 if $perm->{user} && $perm->{user} eq 'all';
 544
 545     return $self->exec_api2_perm_check($perm->{check}, $username, $param)
 546         if $perm->{check};
 547
 548     raise_perm_exc();
 549 }
 550
 551 sub log_cluster_msg {
 552     my ($self, $pri, $user, $msg) = @_;
 553
 554     PVE::Cluster::log_msg($pri, $user, $msg);
 555 }
 556
 557 sub broadcast_tasklist {
 558     my ($self, $tlist) = @_;
 559
 560     PVE::Cluster::broadcast_tasklist($tlist);
 561 }
 562
 563 # initialize environment - must be called once at program startup
 564 sub init {
 565     my ($class, $type, %params) = @_;
 566
 567     $class = ref($class) || $class;
 568
 569     my $self = $class->SUPER::init($type, %params);
 570
 571     $self->{user_cfg} = {};
 572     $self->{aclcache} = {};
 573     $self->{aclversion} = undef;
 574
 575     return $self;
 576 };
 577
 578
 579 # init_request - must be called before each RPC request
 580 sub init_request {
 581     my ($self, %params) = @_;
 582
 583     PVE::Cluster::cfs_update();
 584
 585     $self->{result_attributes} = {};
 586
 587     my $userconfig; # we use this for regression tests
 588     foreach my $p (keys %params) {
 589         if ($p eq 'userconfig') {
 590             $userconfig = $params{$p};
 591         } else {
 592             die "unknown parameter '$p'";
 593         }
 594     }
 595
 596     eval {
 597         $self->{aclcache} = {};
 598         if ($userconfig) {
 599             my $ucdata = PVE::Tools::file_get_contents($userconfig);
 600             my $cfg = PVE::AccessControl::parse_user_config($userconfig, $ucdata);
 601             $self->{user_cfg} = $cfg;
 602         } else {
 603             my $ucvers = PVE::Cluster::cfs_file_version('user.cfg');
 604             if (!$self->{aclcache} || !defined($self->{aclversion}) ||
 605                 !defined($ucvers) ||  ($ucvers ne $self->{aclversion})) {
 606                 $self->{aclversion} = $ucvers;
 607                 my $cfg = PVE::Cluster::cfs_read_file('user.cfg');
 608                 $self->{user_cfg} = $cfg;
 609             }
 610         }
 611     };
 612     if (my $err = $@) {
 613         $self->{user_cfg} = {};
 614         die "Unable to load access control list: $err";
 615     }
 616 }
 617
 618 # hacks: to provide better backwards compatibility
 619
 620 # old code uses PVE::RPCEnvironment::get();
 621 # new code should use PVE::RPCEnvironment->get();
 622 sub get {
 623     return PVE::RESTEnvironment->get();
 624 }
 625
 626 # old code uses PVE::RPCEnvironment::is_worker();
 627 # new code should use PVE::RPCEnvironment->is_worker();
 628 sub is_worker {
 629     return PVE::RESTEnvironment->is_worker();
 630 }
 631
 632 1;