data/PVE/CLI/pvecm.pm

   1 package PVE::CLI::pvecm;
   2
   3 use strict;
   4 use warnings;
   5
   6 use File::Path;
   7 use File::Basename;
   8 use PVE::Tools qw(run_command);
   9 use PVE::Cluster;
  10 use PVE::INotify;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use PVE::RPCEnvironment;
  13 use PVE::CLIHandler;
  14 use PVE::PTY;
  15 use PVE::API2::ClusterConfig;
  16 use PVE::Corosync;
  17
  18 use base qw(PVE::CLIHandler);
  19
  20 $ENV{HOME} = '/root'; # for ssh-copy-id
  21
  22 my $basedir = "/etc/pve";
  23 my $clusterconf = "$basedir/corosync.conf";
  24 my $libdir = "/var/lib/pve-cluster";
  25 my $authfile = "/etc/corosync/authkey";
  26
  27
  28 sub setup_environment {
  29     PVE::RPCEnvironment->setup_default_cli_env();
  30 }
  31
  32 __PACKAGE__->register_method ({
  33     name => 'keygen',
  34     path => 'keygen',
  35     method => 'PUT',
  36     description => "Generate new cryptographic key for corosync.",
  37     parameters => {
  38         additionalProperties => 0,
  39         properties => {
  40             filename => {
  41                 type => 'string',
  42                 description => "Output file name"
  43             }
  44         },
  45     },
  46     returns => { type => 'null' },
  47
  48     code => sub {
  49         my ($param) = @_;
  50
  51         my $filename = $param->{filename};
  52
  53         # test EUID
  54         $> == 0 || die "Error: Authorization key must be generated as root user.\n";
  55         my $dirname = dirname($filename);
  56
  57         die "key file '$filename' already exists\n" if -e $filename;
  58
  59         File::Path::make_path($dirname) if $dirname;
  60
  61         run_command(['corosync-keygen', '-l', '-k', $filename]);
  62
  63         return undef;
  64     }});
  65
  66 __PACKAGE__->register_method ({
  67     name => 'add',
  68     path => 'add',
  69     method => 'PUT',
  70     description => "Adds the current node to an existing cluster.",
  71     parameters => {
  72         additionalProperties => 0,
  73         properties => {
  74             hostname => {
  75                 type => 'string',
  76                 description => "Hostname (or IP) of an existing cluster member."
  77             },
  78             nodeid => get_standard_option('corosync-nodeid'),
  79             votes => {
  80                 type => 'integer',
  81                 description => "Number of votes for this node",
  82                 minimum => 0,
  83                 optional => 1,
  84             },
  85             force => {
  86                 type => 'boolean',
  87                 description => "Do not throw error if node already exists.",
  88                 optional => 1,
  89             },
  90             ring0_addr => get_standard_option('corosync-ring0-addr'),
  91             ring1_addr => get_standard_option('corosync-ring1-addr'),
  92             fingerprint => get_standard_option('fingerprint-sha256', {
  93                 optional => 1,
  94             }),
  95             'use_ssh' => {
  96                 type => 'boolean',
  97                 description => "Always use SSH to join, even if peer may do it over API.",
  98                 optional => 1,
  99             },
 100         },
 101     },
 102     returns => { type => 'null' },
 103
 104     code => sub {
 105         my ($param) = @_;
 106
 107         my $nodename = PVE::INotify::nodename();
 108
 109         my $host = $param->{hostname};
 110         my $local_ip_address = remote_node_ip($nodename);
 111
 112         PVE::Cluster::assert_joinable($param->{ring0_addr}, $param->{ring1_addr}, $param->{force});
 113
 114         my $worker = sub {
 115
 116             if (!$param->{use_ssh}) {
 117                 print "Please enter superuser (root) password for '$host':\n";
 118                 my $password = PVE::PTY::read_password("Password for root\@$host: ");
 119
 120                 delete $param->{use_ssh};
 121                 $param->{password} = $password;
 122
 123                 my $local_cluster_lock = "/var/lock/pvecm.lock";
 124                 PVE::Tools::lock_file($local_cluster_lock, 10, \&PVE::Cluster::join, $param);
 125
 126                 if (my $err = $@) {
 127                     if (ref($err) eq 'PVE::APIClient::Exception' && defined($err->{code}) && $err->{code} == 501) {
 128                         $err = "Remote side is not able to use API for Cluster join!\n" .
 129                                "Pass the 'use_ssh' switch or update the remote side.\n";
 130                     }
 131                     die $err;
 132                 }
 133                 return; # all OK, the API join endpoint successfully set us up
 134             }
 135
 136             # allow fallback to old ssh only join if wished or needed
 137
 138             PVE::Cluster::setup_sshd_config();
 139             PVE::Cluster::setup_rootsshconfig();
 140             PVE::Cluster::setup_ssh_keys();
 141
 142             # make sure known_hosts is on local filesystem
 143             PVE::Cluster::ssh_unmerge_known_hosts();
 144
 145             my $cmd = ['ssh-copy-id', '-i', '/root/.ssh/id_rsa', "root\@$host"];
 146             run_command($cmd, 'outfunc' => sub {}, 'errfunc' => sub {},
 147                                     'errmsg' => "unable to copy ssh ID");
 148
 149             $cmd = ['ssh', $host, '-o', 'BatchMode=yes',
 150                     'pvecm', 'addnode', $nodename, '--force', 1];
 151
 152             push @$cmd, '--nodeid', $param->{nodeid} if $param->{nodeid};
 153             push @$cmd, '--votes', $param->{votes} if defined($param->{votes});
 154             push @$cmd, '--ring0_addr', $param->{ring0_addr} // $local_ip_address;
 155             push @$cmd, '--ring1_addr', $param->{ring1_addr} if defined($param->{ring1_addr});
 156
 157             if (system (@$cmd) != 0) {
 158                 my $cmdtxt = join (' ', @$cmd);
 159                 die "unable to add node: command failed ($cmdtxt)\n";
 160             }
 161
 162             my $tmpdir = "$libdir/.pvecm_add.tmp.$$";
 163             mkdir $tmpdir;
 164
 165             eval {
 166                 print "copy corosync auth key\n";
 167                 $cmd = ['rsync', '--rsh=ssh -l root -o BatchMode=yes', '-lpgoq',
 168                         "[$host]:$authfile $clusterconf", $tmpdir];
 169
 170                 system(@$cmd) == 0 || die "can't rsync data from host '$host'\n";
 171
 172                 my $corosync_conf = PVE::Tools::file_get_contents("$tmpdir/corosync.conf");
 173                 my $corosync_authkey = PVE::Tools::file_get_contents("$tmpdir/authkey");
 174
 175                 PVE::Cluster::finish_join($host, $corosync_conf, $corosync_authkey);
 176             };
 177             my $err = $@;
 178
 179             rmtree $tmpdir;
 180
 181             die $err if $err;
 182         };
 183
 184         # use a synced worker so we get a nice task log when joining through CLI
 185         my $rpcenv = PVE::RPCEnvironment::get();
 186         my $authuser = $rpcenv->get_user();
 187
 188         $rpcenv->fork_worker('clusterjoin', '',  $authuser, $worker);
 189
 190         return undef;
 191     }});
 192
 193 __PACKAGE__->register_method ({
 194     name => 'status',
 195     path => 'status',
 196     method => 'GET',
 197     description => "Displays the local view of the cluster status.",
 198     parameters => {
 199         additionalProperties => 0,
 200         properties => {},
 201     },
 202     returns => { type => 'null' },
 203
 204     code => sub {
 205         my ($param) = @_;
 206
 207         PVE::Corosync::check_conf_exists();
 208
 209         my $cmd = ['corosync-quorumtool', '-siH'];
 210
 211         exec (@$cmd);
 212
 213         exit (-1); # should not be reached
 214     }});
 215
 216 __PACKAGE__->register_method ({
 217     name => 'nodes',
 218     path => 'nodes',
 219     method => 'GET',
 220     description => "Displays the local view of the cluster nodes.",
 221     parameters => {
 222         additionalProperties => 0,
 223         properties => {},
 224     },
 225     returns => { type => 'null' },
 226
 227     code => sub {
 228         my ($param) = @_;
 229
 230         PVE::Corosync::check_conf_exists();
 231
 232         my $cmd = ['corosync-quorumtool', '-l'];
 233
 234         exec (@$cmd);
 235
 236         exit (-1); # should not be reached
 237     }});
 238
 239 __PACKAGE__->register_method ({
 240     name => 'expected',
 241     path => 'expected',
 242     method => 'PUT',
 243     description => "Tells corosync a new value of expected votes.",
 244     parameters => {
 245         additionalProperties => 0,
 246         properties => {
 247             expected => {
 248                 type => 'integer',
 249                 description => "Expected votes",
 250                 minimum => 1,
 251             },
 252         },
 253     },
 254     returns => { type => 'null' },
 255
 256     code => sub {
 257         my ($param) = @_;
 258
 259         PVE::Corosync::check_conf_exists();
 260
 261         my $cmd = ['corosync-quorumtool', '-e', $param->{expected}];
 262
 263         exec (@$cmd);
 264
 265         exit (-1); # should not be reached
 266
 267     }});
 268
 269 __PACKAGE__->register_method ({
 270     name => 'updatecerts',
 271     path => 'updatecerts',
 272     method => 'PUT',
 273     description => "Update node certificates (and generate all needed files/directories).",
 274     parameters => {
 275         additionalProperties => 0,
 276         properties => {
 277             force => {
 278                 description => "Force generation of new SSL certifate.",
 279                 type => 'boolean',
 280                 optional => 1,
 281             },
 282             silent => {
 283                 description => "Ignore errors (i.e. when cluster has no quorum).",
 284                 type => 'boolean',
 285                 optional => 1,
 286             },
 287         },
 288     },
 289     returns => { type => 'null' },
 290     code => sub {
 291         my ($param) = @_;
 292
 293         PVE::Cluster::updatecerts_and_ssh($param->@{qw(force silent)});
 294
 295         return undef;
 296     }});
 297
 298 __PACKAGE__->register_method ({
 299     name => 'mtunnel',
 300     path => 'mtunnel',
 301     method => 'POST',
 302     description => "Used by VM/CT migration - do not use manually.",
 303     parameters => {
 304         additionalProperties => 0,
 305         properties => {
 306             get_migration_ip => {
 307                 type => 'boolean',
 308                 default => 0,
 309                 description => 'return the migration IP, if configured',
 310                 optional => 1,
 311             },
 312             migration_network => {
 313                 type => 'string',
 314                 format => 'CIDR',
 315                 description => 'the migration network used to detect the local migration IP',
 316                 optional => 1,
 317             },
 318             'run-command' => {
 319                 type => 'boolean',
 320                 description => 'Run a command with a tcp socket as standard input.'
 321                               .' The IP address and port are printed via this'
 322                               ." command's stdandard output first, each on a separate line.",
 323                 optional => 1,
 324             },
 325             'extra-args' => PVE::JSONSchema::get_standard_option('extra-args'),
 326         },
 327     },
 328     returns => { type => 'null'},
 329     code => sub {
 330         my ($param) = @_;
 331
 332         if (!PVE::Cluster::check_cfs_quorum(1)) {
 333             print "no quorum\n";
 334             return undef;
 335         }
 336
 337         my $network = $param->{migration_network};
 338         if ($param->{get_migration_ip}) {
 339             die "cannot use --run-command with --get_migration_ip\n"
 340                 if $param->{'run-command'};
 341             if (my $ip = PVE::Cluster::get_local_migration_ip($network)) {
 342                 print "ip: '$ip'\n";
 343             } else {
 344                 print "no ip\n";
 345             }
 346             # do not keep tunnel open when asked for migration ip
 347             return undef;
 348         }
 349
 350         if ($param->{'run-command'}) {
 351             my $cmd = $param->{'extra-args'};
 352             die "missing command\n"
 353                 if !$cmd || !scalar(@$cmd);
 354
 355             # Get an ip address to listen on, and find a free migration port
 356             my ($ip, $family);
 357             if (defined($network)) {
 358                 $ip = PVE::Cluster::get_local_migration_ip($network)
 359                     or die "failed to get migration IP address to listen on\n";
 360                 $family = PVE::Tools::get_host_address_family($ip);
 361             } else {
 362                 my $nodename = PVE::INotify::nodename();
 363                 ($ip, $family) = PVE::Network::get_ip_from_hostname($nodename, 0);
 364             }
 365             my $port = PVE::Tools::next_migrate_port($family, $ip);
 366
 367             PVE::Tools::pipe_socket_to_command($cmd, $ip, $port);
 368             return undef;
 369         }
 370
 371         print "tunnel online\n";
 372         *STDOUT->flush();
 373
 374         while (my $line = <STDIN>) {
 375             chomp $line;
 376             last if $line =~ m/^quit$/;
 377         }
 378
 379         return undef;
 380     }});
 381
 382
 383 our $cmddef = {
 384     keygen => [ __PACKAGE__, 'keygen', ['filename']],
 385     create => [ 'PVE::API2::ClusterConfig', 'create', ['clustername']],
 386     add => [ __PACKAGE__, 'add', ['hostname']],
 387     addnode => [ 'PVE::API2::ClusterConfig', 'addnode', ['node']],
 388     delnode => [ 'PVE::API2::ClusterConfig', 'delnode', ['node']],
 389     status => [ __PACKAGE__, 'status' ],
 390     nodes => [ __PACKAGE__, 'nodes' ],
 391     expected => [ __PACKAGE__, 'expected', ['expected']],
 392     updatecerts => [ __PACKAGE__, 'updatecerts', []],
 393     mtunnel => [ __PACKAGE__, 'mtunnel', ['extra-args']],
 394 };
 395
 396 1;