data/PVE/Cluster.pm

   1 package PVE::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EEXIST);
   6 use File::stat qw();
   7 use Socket;
   8 use Storable qw(dclone);
   9 use IO::File;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12 use Digest::HMAC_SHA1;
  13 use Net::SSLeay;
  14 use PVE::Tools;
  15 use PVE::INotify;
  16 use PVE::IPCC;
  17 use PVE::SafeSyslog;
  18 use PVE::JSONSchema;
  19 use PVE::Network;
  20 use JSON;
  21 use RRDs;
  22 use Encode;
  23 use UUID;
  24 use base 'Exporter';
  25
  26 our @EXPORT_OK = qw(
  27 cfs_read_file
  28 cfs_write_file
  29 cfs_register_file
  30 cfs_lock_file);
  31
  32 use Data::Dumper; # fixme: remove
  33
  34 # x509 certificate utils
  35
  36 my $basedir = "/etc/pve";
  37 my $authdir = "$basedir/priv";
  38 my $lockdir = "/etc/pve/priv/lock";
  39
  40 my $authprivkeyfn = "$authdir/authkey.key";
  41 my $authpubkeyfn = "$basedir/authkey.pub";
  42 my $pveca_key_fn = "$authdir/pve-root-ca.key";
  43 my $pveca_srl_fn = "$authdir/pve-root-ca.srl";
  44 my $pveca_cert_fn = "$basedir/pve-root-ca.pem";
  45 # this is just a secret accessable by the web browser
  46 # and is used for CSRF prevention
  47 my $pvewww_key_fn = "$basedir/pve-www.key";
  48
  49 # ssh related files
  50 my $ssh_rsa_id_priv = "/root/.ssh/id_rsa";
  51 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
  52 my $ssh_host_rsa_id = "/etc/ssh/ssh_host_rsa_key.pub";
  53 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts";
  54 my $sshknownhosts = "/etc/pve/priv/known_hosts";
  55 my $sshauthkeys = "/etc/pve/priv/authorized_keys";
  56 my $sshd_config_fn = "/etc/ssh/sshd_config";
  57 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
  58 my $rootsshauthkeysbackup = "${rootsshauthkeys}.org";
  59 my $rootsshconfig = "/root/.ssh/config";
  60
  61 my $observed = {
  62     'vzdump.cron' => 1,
  63     'storage.cfg' => 1,
  64     'datacenter.cfg' => 1,
  65     'replication.cfg' => 1,
  66     'corosync.conf' => 1,
  67     'corosync.conf.new' => 1,
  68     'user.cfg' => 1,
  69     'domains.cfg' => 1,
  70     'priv/shadow.cfg' => 1,
  71     '/qemu-server/' => 1,
  72     '/openvz/' => 1,
  73     '/lxc/' => 1,
  74     'ha/crm_commands' => 1,
  75     'ha/manager_status' => 1,
  76     'ha/resources.cfg' => 1,
  77     'ha/groups.cfg' => 1,
  78     'ha/fence.cfg' => 1,
  79     'status.cfg' => 1,
  80 };
  81
  82 # only write output if something fails
  83 sub run_silent_cmd {
  84     my ($cmd) = @_;
  85
  86     my $outbuf = '';
  87
  88     my $record_output = sub {
  89         $outbuf .= shift;
  90         $outbuf .= "\n";
  91     };
  92
  93     eval {
  94         PVE::Tools::run_command($cmd, outfunc => $record_output,
  95                                 errfunc => $record_output);
  96     };
  97
  98     my $err = $@;
  99
 100     if ($err) {
 101         print STDERR $outbuf;
 102         die $err;
 103     }
 104 }
 105
 106 sub check_cfs_quorum {
 107     my ($noerr) = @_;
 108
 109     # note: -w filename always return 1 for root, so wee need
 110     # to use File::lstat here
 111     my $st = File::stat::lstat("$basedir/local");
 112     my $quorate = ($st && (($st->mode & 0200) != 0));
 113
 114     die "cluster not ready - no quorum?\n" if !$quorate && !$noerr;
 115
 116     return $quorate;
 117 }
 118
 119 sub check_cfs_is_mounted {
 120     my ($noerr) = @_;
 121
 122     my $res = -l "$basedir/local";
 123
 124     die "pve configuration filesystem not mounted\n"
 125         if !$res && !$noerr;
 126
 127     return $res;
 128 }
 129
 130 sub gen_local_dirs {
 131     my ($nodename) = @_;
 132
 133     check_cfs_is_mounted();
 134
 135     my @required_dirs = (
 136         "$basedir/priv",
 137         "$basedir/nodes",
 138         "$basedir/nodes/$nodename",
 139         "$basedir/nodes/$nodename/lxc",
 140         "$basedir/nodes/$nodename/qemu-server",
 141         "$basedir/nodes/$nodename/openvz",
 142         "$basedir/nodes/$nodename/priv");
 143
 144     foreach my $dir (@required_dirs) {
 145         if (! -d $dir) {
 146             mkdir($dir) || $! == EEXIST || die "unable to create directory '$dir' - $!\n";
 147         }
 148     }
 149 }
 150
 151 sub gen_auth_key {
 152
 153     return if -f "$authprivkeyfn";
 154
 155     check_cfs_is_mounted();
 156
 157     mkdir $authdir || $! == EEXIST || die "unable to create dir '$authdir' - $!\n";
 158
 159     run_silent_cmd(['openssl', 'genrsa', '-out', $authprivkeyfn, '2048']);
 160
 161     run_silent_cmd(['openssl', 'rsa', '-in', $authprivkeyfn, '-pubout', '-out', $authpubkeyfn]);
 162 }
 163
 164 sub gen_pveca_key {
 165
 166     return if -f $pveca_key_fn;
 167
 168     eval {
 169         run_silent_cmd(['openssl', 'genrsa', '-out', $pveca_key_fn, '4096']);
 170     };
 171
 172     die "unable to generate pve ca key:\n$@" if $@;
 173 }
 174
 175 sub gen_pveca_cert {
 176
 177     if (-f $pveca_key_fn && -f $pveca_cert_fn) {
 178         return 0;
 179     }
 180
 181     gen_pveca_key();
 182
 183     # we try to generate an unique 'subject' to avoid browser problems
 184     # (reused serial numbers, ..)
 185     my $uuid;
 186     UUID::generate($uuid);
 187     my $uuid_str;
 188     UUID::unparse($uuid, $uuid_str);
 189
 190     eval {
 191         # wrap openssl with faketime to prevent bug #904
 192         run_silent_cmd(['faketime', 'yesterday', 'openssl', 'req', '-batch',
 193                         '-days', '3650', '-new', '-x509', '-nodes', '-key',
 194                         $pveca_key_fn, '-out', $pveca_cert_fn, '-subj',
 195                         "/CN=Proxmox Virtual Environment/OU=$uuid_str/O=PVE Cluster Manager CA/"]);
 196     };
 197
 198     die "generating pve root certificate failed:\n$@" if $@;
 199
 200     return 1;
 201 }
 202
 203 sub gen_pve_ssl_key {
 204     my ($nodename) = @_;
 205
 206     die "no node name specified" if !$nodename;
 207
 208     my $pvessl_key_fn = "$basedir/nodes/$nodename/pve-ssl.key";
 209
 210     return if -f $pvessl_key_fn;
 211
 212     eval {
 213         run_silent_cmd(['openssl', 'genrsa', '-out', $pvessl_key_fn, '2048']);
 214     };
 215
 216     die "unable to generate pve ssl key for node '$nodename':\n$@" if $@;
 217 }
 218
 219 sub gen_pve_www_key {
 220
 221     return if -f $pvewww_key_fn;
 222
 223     eval {
 224         run_silent_cmd(['openssl', 'genrsa', '-out', $pvewww_key_fn, '2048']);
 225     };
 226
 227     die "unable to generate pve www key:\n$@" if $@;
 228 }
 229
 230 sub update_serial {
 231     my ($serial) = @_;
 232
 233     PVE::Tools::file_set_contents($pveca_srl_fn, $serial);
 234 }
 235
 236 sub gen_pve_ssl_cert {
 237     my ($force, $nodename, $ip) = @_;
 238
 239     die "no node name specified" if !$nodename;
 240     die "no IP specified" if !$ip;
 241
 242     my $pvessl_cert_fn = "$basedir/nodes/$nodename/pve-ssl.pem";
 243
 244     return if !$force && -f $pvessl_cert_fn;
 245
 246     my $names = "IP:127.0.0.1,IP:::1,DNS:localhost";
 247
 248     my $rc = PVE::INotify::read_file('resolvconf');
 249
 250     $names .= ",IP:$ip";
 251
 252     my $fqdn = $nodename;
 253
 254     $names .= ",DNS:$nodename";
 255
 256     if ($rc && $rc->{search}) {
 257         $fqdn = $nodename . "." . $rc->{search};
 258         $names .= ",DNS:$fqdn";
 259     }
 260
 261     my $sslconf = <<__EOD;
 262 RANDFILE = /root/.rnd
 263 extensions = v3_req
 264
 265 [ req ]
 266 default_bits = 2048
 267 distinguished_name = req_distinguished_name
 268 req_extensions = v3_req
 269 prompt = no
 270 string_mask = nombstr
 271
 272 [ req_distinguished_name ]
 273 organizationalUnitName = PVE Cluster Node
 274 organizationName = Proxmox Virtual Environment
 275 commonName = $fqdn
 276
 277 [ v3_req ]
 278 basicConstraints = CA:FALSE
 279 extendedKeyUsage = serverAuth
 280 subjectAltName = $names
 281 __EOD
 282
 283     my $cfgfn = "/tmp/pvesslconf-$$.tmp";
 284     my $fh = IO::File->new ($cfgfn, "w");
 285     print $fh $sslconf;
 286     close ($fh);
 287
 288     my $reqfn = "/tmp/pvecertreq-$$.tmp";
 289     unlink $reqfn;
 290
 291     my $pvessl_key_fn = "$basedir/nodes/$nodename/pve-ssl.key";
 292     eval {
 293         run_silent_cmd(['openssl', 'req', '-batch', '-new', '-config', $cfgfn,
 294                         '-key', $pvessl_key_fn, '-out', $reqfn]);
 295     };
 296
 297     if (my $err = $@) {
 298         unlink $reqfn;
 299         unlink $cfgfn;
 300         die "unable to generate pve certificate request:\n$err";
 301     }
 302
 303     update_serial("0000000000000000") if ! -f $pveca_srl_fn;
 304
 305     eval {
 306         # wrap openssl with faketime to prevent bug #904
 307         run_silent_cmd(['faketime', 'yesterday', 'openssl', 'x509', '-req',
 308                         '-in', $reqfn, '-days', '3650', '-out', $pvessl_cert_fn,
 309                         '-CAkey', $pveca_key_fn, '-CA', $pveca_cert_fn,
 310                         '-CAserial', $pveca_srl_fn, '-extfile', $cfgfn]);
 311     };
 312
 313     if (my $err = $@) {
 314         unlink $reqfn;
 315         unlink $cfgfn;
 316         die "unable to generate pve ssl certificate:\n$err";
 317     }
 318
 319     unlink $cfgfn;
 320     unlink $reqfn;
 321 }
 322
 323 sub gen_pve_node_files {
 324     my ($nodename, $ip, $opt_force) = @_;
 325
 326     gen_local_dirs($nodename);
 327
 328     gen_auth_key();
 329
 330     # make sure we have a (cluster wide) secret
 331     # for CSRFR prevention
 332     gen_pve_www_key();
 333
 334     # make sure we have a (per node) private key
 335     gen_pve_ssl_key($nodename);
 336
 337     # make sure we have a CA
 338     my $force = gen_pveca_cert();
 339
 340     $force = 1 if $opt_force;
 341
 342     gen_pve_ssl_cert($force, $nodename, $ip);
 343 }
 344
 345 my $vzdump_cron_dummy = <<__EOD;
 346 # cluster wide vzdump cron schedule
 347 # Atomatically generated file - do not edit
 348
 349 PATH="/usr/sbin:/usr/bin:/sbin:/bin"
 350
 351 __EOD
 352
 353 sub gen_pve_vzdump_symlink {
 354
 355     my $filename = "/etc/pve/vzdump.cron";
 356
 357     my $link_fn = "/etc/cron.d/vzdump";
 358
 359     if ((-f $filename) && (! -l $link_fn)) {
 360         rename($link_fn, "/root/etc_cron_vzdump.org"); # make backup if file exists
 361         symlink($filename, $link_fn);
 362     }
 363 }
 364
 365 sub gen_pve_vzdump_files {
 366
 367     my $filename = "/etc/pve/vzdump.cron";
 368
 369     PVE::Tools::file_set_contents($filename, $vzdump_cron_dummy)
 370         if ! -f $filename;
 371
 372     gen_pve_vzdump_symlink();
 373 };
 374
 375 my $versions = {};
 376 my $vmlist = {};
 377 my $clinfo = {};
 378
 379 my $ipcc_send_rec = sub {
 380     my ($msgid, $data) = @_;
 381
 382     my $res = PVE::IPCC::ipcc_send_rec($msgid, $data);
 383
 384     die "ipcc_send_rec[$msgid] failed: $!\n" if !defined($res) && ($! != 0);
 385
 386     return $res;
 387 };
 388
 389 my $ipcc_send_rec_json = sub {
 390     my ($msgid, $data) = @_;
 391
 392     my $res = PVE::IPCC::ipcc_send_rec($msgid, $data);
 393
 394     die "ipcc_send_rec[$msgid] failed: $!\n" if !defined($res) && ($! != 0);
 395
 396     return decode_json($res);
 397 };
 398
 399 my $ipcc_get_config = sub {
 400     my ($path) = @_;
 401
 402     my $bindata = pack "Z*", $path;
 403     my $res = PVE::IPCC::ipcc_send_rec(6, $bindata);
 404     if (!defined($res)) {
 405         return undef if ($! != 0);
 406         return '';
 407     }
 408
 409     return $res;
 410 };
 411
 412 my $ipcc_get_status = sub {
 413     my ($name, $nodename) = @_;
 414
 415     my $bindata = pack "Z[256]Z[256]", $name, ($nodename || "");
 416     return PVE::IPCC::ipcc_send_rec(5, $bindata);
 417 };
 418
 419 my $ipcc_update_status = sub {
 420     my ($name, $data) = @_;
 421
 422     my $raw = ref($data) ? encode_json($data) : $data;
 423     # update status
 424     my $bindata = pack "Z[256]Z*", $name, $raw;
 425
 426     return &$ipcc_send_rec(4, $bindata);
 427 };
 428
 429 my $ipcc_log = sub {
 430     my ($priority, $ident, $tag, $msg) = @_;
 431
 432     my $bindata = pack "CCCZ*Z*Z*", $priority, bytes::length($ident) + 1,
 433     bytes::length($tag) + 1, $ident, $tag, $msg;
 434
 435     return &$ipcc_send_rec(7, $bindata);
 436 };
 437
 438 my $ipcc_get_cluster_log = sub {
 439     my ($user, $max) = @_;
 440
 441     $max = 0 if !defined($max);
 442
 443     my $bindata = pack "VVVVZ*", $max, 0, 0, 0, ($user || "");
 444     return &$ipcc_send_rec(8, $bindata);
 445 };
 446
 447 my $ccache = {};
 448
 449 sub cfs_update {
 450     eval {
 451         my $res = &$ipcc_send_rec_json(1);
 452         #warn "GOT1: " . Dumper($res);
 453         die "no starttime\n" if !$res->{starttime};
 454
 455         if (!$res->{starttime} || !$versions->{starttime} ||
 456             $res->{starttime} != $versions->{starttime}) {
 457             #print "detected changed starttime\n";
 458             $vmlist = {};
 459             $clinfo = {};
 460             $ccache = {};
 461         }
 462
 463         $versions = $res;
 464     };
 465     my $err = $@;
 466     if ($err) {
 467         $versions = {};
 468         $vmlist = {};
 469         $clinfo = {};
 470         $ccache = {};
 471         warn $err;
 472     }
 473
 474     eval {
 475         if (!$clinfo->{version} || $clinfo->{version} != $versions->{clinfo}) {
 476             #warn "detected new clinfo\n";
 477             $clinfo = &$ipcc_send_rec_json(2);
 478         }
 479     };
 480     $err = $@;
 481     if ($err) {
 482         $clinfo = {};
 483         warn $err;
 484     }
 485
 486     eval {
 487         if (!$vmlist->{version} || $vmlist->{version} != $versions->{vmlist}) {
 488             #warn "detected new vmlist1\n";
 489             $vmlist = &$ipcc_send_rec_json(3);
 490         }
 491     };
 492     $err = $@;
 493     if ($err) {
 494         $vmlist = {};
 495         warn $err;
 496     }
 497 }
 498
 499 sub get_vmlist {
 500     return $vmlist;
 501 }
 502
 503 sub get_clinfo {
 504     return $clinfo;
 505 }
 506
 507 sub get_members {
 508     return $clinfo->{nodelist};
 509 }
 510
 511 sub get_nodelist {
 512
 513     my $nodelist = $clinfo->{nodelist};
 514
 515     my $result = [];
 516
 517     my $nodename = PVE::INotify::nodename();
 518
 519     if (!$nodelist || !$nodelist->{$nodename}) {
 520         return [ $nodename ];
 521     }
 522
 523     return [ keys %$nodelist ];
 524 }
 525
 526 sub broadcast_tasklist {
 527     my ($data) = @_;
 528
 529     eval {
 530         &$ipcc_update_status("tasklist", $data);
 531     };
 532
 533     warn $@ if $@;
 534 }
 535
 536 my $tasklistcache = {};
 537
 538 sub get_tasklist {
 539     my ($nodename) = @_;
 540
 541     my $kvstore = $versions->{kvstore} || {};
 542
 543     my $nodelist = get_nodelist();
 544
 545     my $res = [];
 546     foreach my $node (@$nodelist) {
 547         next if $nodename && ($nodename ne $node);
 548         eval {
 549             my $ver = $kvstore->{$node}->{tasklist} if $kvstore->{$node};
 550             my $cd = $tasklistcache->{$node};
 551             if (!$cd || !$ver || !$cd->{version} ||
 552                 ($cd->{version} != $ver)) {
 553                 my $raw = &$ipcc_get_status("tasklist", $node) || '[]';
 554                 my $data = decode_json($raw);
 555                 push @$res, @$data;
 556                 $cd = $tasklistcache->{$node} = {
 557                     data => $data,
 558                     version => $ver,
 559                 };
 560             } elsif ($cd && $cd->{data}) {
 561                 push @$res, @{$cd->{data}};
 562             }
 563         };
 564         my $err = $@;
 565         syslog('err', $err) if $err;
 566     }
 567
 568     return $res;
 569 }
 570
 571 sub broadcast_rrd {
 572     my ($rrdid, $data) = @_;
 573
 574     eval {
 575         &$ipcc_update_status("rrd/$rrdid", $data);
 576     };
 577     my $err = $@;
 578
 579     warn $err if $err;
 580 }
 581
 582 my $last_rrd_dump = 0;
 583 my $last_rrd_data = "";
 584
 585 sub rrd_dump {
 586
 587     my $ctime = time();
 588
 589     my $diff = $ctime - $last_rrd_dump;
 590     if ($diff < 2) {
 591         return $last_rrd_data;
 592     }
 593
 594     my $raw;
 595     eval {
 596         $raw = &$ipcc_send_rec(10);
 597     };
 598     my $err = $@;
 599
 600     if ($err) {
 601         warn $err;
 602         return {};
 603     }
 604
 605     my $res = {};
 606
 607     if ($raw) {
 608         while ($raw =~ s/^(.*)\n//) {
 609             my ($key, @ela) = split(/:/, $1);
 610             next if !$key;
 611             next if !(scalar(@ela) > 1);
 612             $res->{$key} = [ map { $_ eq 'U' ? undef : $_ } @ela ];
 613         }
 614     }
 615
 616     $last_rrd_dump = $ctime;
 617     $last_rrd_data = $res;
 618
 619     return $res;
 620 }
 621
 622 sub create_rrd_data {
 623     my ($rrdname, $timeframe, $cf) = @_;
 624
 625     my $rrddir = "/var/lib/rrdcached/db";
 626
 627     my $rrd = "$rrddir/$rrdname";
 628
 629     my $setup = {
 630         hour =>  [ 60, 70 ],
 631         day  =>  [ 60*30, 70 ],
 632         week =>  [ 60*180, 70 ],
 633         month => [ 60*720, 70 ],
 634         year =>  [ 60*10080, 70 ],
 635     };
 636
 637     my ($reso, $count) = @{$setup->{$timeframe}};
 638     my $ctime  = $reso*int(time()/$reso);
 639     my $req_start = $ctime - $reso*$count;
 640
 641     $cf = "AVERAGE" if !$cf;
 642
 643     my @args = (
 644         "-s" => $req_start,
 645         "-e" => $ctime - 1,
 646         "-r" => $reso,
 647         );
 648
 649     my $socket = "/var/run/rrdcached.sock";
 650     push @args, "--daemon" => "unix:$socket" if -S $socket;
 651
 652     my ($start, $step, $names, $data) = RRDs::fetch($rrd, $cf, @args);
 653
 654     my $err = RRDs::error;
 655     die "RRD error: $err\n" if $err;
 656
 657     die "got wrong time resolution ($step != $reso)\n"
 658         if $step != $reso;
 659
 660     my $res = [];
 661     my $fields = scalar(@$names);
 662     for my $line (@$data) {
 663         my $entry = { 'time' => $start };
 664         $start += $step;
 665         for (my $i = 0; $i < $fields; $i++) {
 666             my $name = $names->[$i];
 667             if (defined(my $val = $line->[$i])) {
 668                 $entry->{$name} = $val;
 669             } else {
 670                 # leave empty fields undefined
 671                 # maybe make this configurable?
 672             }
 673         }
 674         push @$res, $entry;
 675     }
 676
 677     return $res;
 678 }
 679
 680 sub create_rrd_graph {
 681     my ($rrdname, $timeframe, $ds, $cf) = @_;
 682
 683     # Using RRD graph is clumsy - maybe it
 684     # is better to simply fetch the data, and do all display
 685     # related things with javascript (new extjs html5 graph library).
 686
 687     my $rrddir = "/var/lib/rrdcached/db";
 688
 689     my $rrd = "$rrddir/$rrdname";
 690
 691     my @ids = PVE::Tools::split_list($ds);
 692
 693     my $ds_txt = join('_', @ids);
 694
 695     my $filename = "${rrd}_${ds_txt}.png";
 696
 697     my $setup = {
 698         hour =>  [ 60, 60 ],
 699         day  =>  [ 60*30, 70 ],
 700         week =>  [ 60*180, 70 ],
 701         month => [ 60*720, 70 ],
 702         year =>  [ 60*10080, 70 ],
 703     };
 704
 705     my ($reso, $count) = @{$setup->{$timeframe}};
 706
 707     my @args = (
 708         "--imgformat" => "PNG",
 709         "--border" => 0,
 710         "--height" => 200,
 711         "--width" => 800,
 712         "--start" => - $reso*$count,
 713         "--end" => 'now' ,
 714         "--lower-limit" => 0,
 715         );
 716
 717     my $socket = "/var/run/rrdcached.sock";
 718     push @args, "--daemon" => "unix:$socket" if -S $socket;
 719
 720     my @coldef = ('#00ddff', '#ff0000');
 721
 722     $cf = "AVERAGE" if !$cf;
 723
 724     my $i = 0;
 725     foreach my $id (@ids) {
 726         my $col = $coldef[$i++] || die "fixme: no color definition";
 727         push @args, "DEF:${id}=$rrd:${id}:$cf";
 728         my $dataid = $id;
 729         if ($id eq 'cpu' || $id eq 'iowait') {
 730             push @args, "CDEF:${id}_per=${id},100,*";
 731             $dataid = "${id}_per";
 732         }
 733         push @args, "LINE2:${dataid}${col}:${id}";
 734     }
 735
 736     push @args, '--full-size-mode';
 737
 738     # we do not really store data into the file
 739     my $res = RRDs::graphv('', @args);
 740
 741     my $err = RRDs::error;
 742     die "RRD error: $err\n" if $err;
 743
 744     return { filename => $filename, image => $res->{image} };
 745 }
 746
 747 # a fast way to read files (avoid fuse overhead)
 748 sub get_config {
 749     my ($path) = @_;
 750
 751     return &$ipcc_get_config($path);
 752 }
 753
 754 sub get_cluster_log {
 755     my ($user, $max) = @_;
 756
 757     return &$ipcc_get_cluster_log($user, $max);
 758 }
 759
 760 my $file_info = {};
 761
 762 sub cfs_register_file {
 763     my ($filename, $parser, $writer) = @_;
 764
 765     $observed->{$filename} || die "unknown file '$filename'";
 766
 767     die "file '$filename' already registered" if $file_info->{$filename};
 768
 769     $file_info->{$filename} = {
 770         parser => $parser,
 771         writer => $writer,
 772     };
 773 }
 774
 775 my $ccache_read = sub {
 776     my ($filename, $parser, $version) = @_;
 777
 778     $ccache->{$filename} = {} if !$ccache->{$filename};
 779
 780     my $ci = $ccache->{$filename};
 781
 782     if (!$ci->{version} || !$version || $ci->{version} != $version) {
 783         # we always call the parser, even when the file does not exists
 784         # (in that case $data is undef)
 785         my $data = get_config($filename);
 786         $ci->{data} = &$parser("/etc/pve/$filename", $data);
 787         $ci->{version} = $version;
 788     }
 789
 790     my $res = ref($ci->{data}) ? dclone($ci->{data}) : $ci->{data};
 791
 792     return $res;
 793 };
 794
 795 sub cfs_file_version {
 796     my ($filename) = @_;
 797
 798     my $version;
 799     my $infotag;
 800     if ($filename =~ m!^nodes/[^/]+/(openvz|lxc|qemu-server)/(\d+)\.conf$!) {
 801         my ($type, $vmid) = ($1, $2);
 802         if ($vmlist && $vmlist->{ids} && $vmlist->{ids}->{$vmid}) {
 803             $version = $vmlist->{ids}->{$vmid}->{version};
 804         }
 805         $infotag = "/$type/";
 806     } else {
 807         $infotag = $filename;
 808         $version = $versions->{$filename};
 809     }
 810
 811     my $info = $file_info->{$infotag} ||
 812         die "unknown file type '$filename'\n";
 813
 814     return wantarray ? ($version, $info) : $version;
 815 }
 816
 817 sub cfs_read_file {
 818     my ($filename) = @_;
 819
 820     my ($version, $info) = cfs_file_version($filename);
 821     my $parser = $info->{parser};
 822
 823     return &$ccache_read($filename, $parser, $version);
 824 }
 825
 826 sub cfs_write_file {
 827     my ($filename, $data) = @_;
 828
 829     my ($version, $info) = cfs_file_version($filename);
 830
 831     my $writer = $info->{writer} || die "no writer defined";
 832
 833     my $fsname = "/etc/pve/$filename";
 834
 835     my $raw = &$writer($fsname, $data);
 836
 837     if (my $ci = $ccache->{$filename}) {
 838         $ci->{version} = undef;
 839     }
 840
 841     PVE::Tools::file_set_contents($fsname, $raw);
 842 }
 843
 844 my $cfs_lock = sub {
 845     my ($lockid, $timeout, $code, @param) = @_;
 846
 847     my $res;
 848
 849     # this timeout is for aquire the lock
 850     $timeout = 10 if !$timeout;
 851
 852     my $filename = "$lockdir/$lockid";
 853
 854     my $msg = "can't aquire cfs lock '$lockid'";
 855
 856     eval {
 857
 858         mkdir $lockdir;
 859
 860         if (! -d $lockdir) {
 861             die "$msg: pve cluster filesystem not online.\n";
 862         }
 863
 864         local $SIG{ALRM} = sub { die "got lock request timeout\n"; };
 865
 866         alarm ($timeout);
 867
 868         if (!(mkdir $filename)) {
 869             print STDERR "trying to aquire cfs lock '$lockid' ...";
 870             while (1) {
 871                 if (!(mkdir $filename)) {
 872                     (utime 0, 0, $filename); # cfs unlock request
 873                 } else {
 874                     print STDERR " OK\n";
 875                     last;
 876                 }
 877                 sleep(1);
 878             }
 879         }
 880
 881         # fixed command timeout: cfs locks have a timeout of 120
 882         # using 60 gives us another 60 seconds to abort the task
 883         alarm(60);
 884         local $SIG{ALRM} = sub { die "got lock timeout - aborting command\n"; };
 885
 886         cfs_update(); # make sure we read latest versions inside code()
 887
 888         $res = &$code(@param);
 889
 890         alarm(0);
 891     };
 892
 893     my $err = $@;
 894
 895     alarm(0);
 896
 897     if ($err && ($err eq "got lock request timeout\n") &&
 898         !check_cfs_quorum()){
 899         $err = "$msg: no quorum!\n";
 900     }
 901
 902     if (!$err || $err !~ /^got lock timeout -/) {
 903         rmdir $filename; # cfs unlock
 904     }
 905
 906     if ($err) {
 907         $@ = $err;
 908         return undef;
 909     }
 910
 911     $@ = undef;
 912
 913     return $res;
 914 };
 915
 916 sub cfs_lock_file {
 917     my ($filename, $timeout, $code, @param) = @_;
 918
 919     my $info = $observed->{$filename} || die "unknown file '$filename'";
 920
 921     my $lockid = "file-$filename";
 922     $lockid =~ s/[.\/]/_/g;
 923
 924     &$cfs_lock($lockid, $timeout, $code, @param);
 925 }
 926
 927 sub cfs_lock_storage {
 928     my ($storeid, $timeout, $code, @param) = @_;
 929
 930     my $lockid = "storage-$storeid";
 931
 932     &$cfs_lock($lockid, $timeout, $code, @param);
 933 }
 934
 935 sub cfs_lock_domain {
 936     my ($domainname, $timeout, $code, @param) = @_;
 937
 938     my $lockid = "domain-$domainname";
 939
 940     &$cfs_lock($lockid, $timeout, $code, @param);
 941 }
 942
 943 my $log_levels = {
 944     "emerg" => 0,
 945     "alert" => 1,
 946     "crit" => 2,
 947     "critical" => 2,
 948     "err" => 3,
 949     "error" => 3,
 950     "warn" => 4,
 951     "warning" => 4,
 952     "notice" => 5,
 953     "info" => 6,
 954     "debug" => 7,
 955 };
 956
 957 sub log_msg {
 958    my ($priority, $ident, $msg) = @_;
 959
 960    if (my $tmp = $log_levels->{$priority}) {
 961        $priority = $tmp;
 962    }
 963
 964    die "need numeric log priority" if $priority !~ /^\d+$/;
 965
 966    my $tag = PVE::SafeSyslog::tag();
 967
 968    $msg = "empty message" if !$msg;
 969
 970    $ident = "" if !$ident;
 971    $ident = encode("ascii", $ident,
 972                    sub { sprintf "\\u%04x", shift });
 973
 974    my $ascii = encode("ascii", $msg, sub { sprintf "\\u%04x", shift });
 975
 976    if ($ident) {
 977        syslog($priority, "<%s> %s", $ident, $ascii);
 978    } else {
 979        syslog($priority, "%s", $ascii);
 980    }
 981
 982    eval { &$ipcc_log($priority, $ident, $tag, $ascii); };
 983
 984    syslog("err", "writing cluster log failed: $@") if $@;
 985 }
 986
 987 sub check_vmid_unused {
 988     my ($vmid, $noerr) = @_;
 989
 990     my $vmlist = get_vmlist();
 991
 992     my $d = $vmlist->{ids}->{$vmid};
 993     return 1 if !defined($d);
 994
 995     return undef if $noerr;
 996
 997     my $vmtypestr =  $d->{type} eq 'qemu' ? 'VM' : 'CT';
 998     die "$vmtypestr $vmid already exists on node '$d->{node}'\n";
 999 }
1000
1001 sub check_node_exists {
1002     my ($nodename, $noerr) = @_;
1003
1004     my $nodelist = $clinfo->{nodelist};
1005     return 1 if $nodelist && $nodelist->{$nodename};
1006
1007     return undef if $noerr;
1008
1009     die "no such cluster node '$nodename'\n";
1010 }
1011
1012 # this is also used to get the IP of the local node
1013 sub remote_node_ip {
1014     my ($nodename, $noerr) = @_;
1015
1016     my $nodelist = $clinfo->{nodelist};
1017     if ($nodelist && $nodelist->{$nodename}) {
1018         if (my $ip = $nodelist->{$nodename}->{ip}) {
1019             return $ip if !wantarray;
1020             my $family = $nodelist->{$nodename}->{address_family};
1021             if (!$family) {
1022                 $nodelist->{$nodename}->{address_family} =
1023                     $family =
1024                     PVE::Tools::get_host_address_family($ip);
1025             }
1026             return wantarray ? ($ip, $family) : $ip;
1027         }
1028     }
1029
1030     # fallback: try to get IP by other means
1031     return PVE::Network::get_ip_from_hostname($nodename, $noerr);
1032 }
1033
1034 sub get_local_migration_ip {
1035     my ($migration_network, $noerr) = @_;
1036
1037     my $cidr = $migration_network;
1038
1039     if (!defined($cidr)) {
1040         my $dc_conf = cfs_read_file('datacenter.cfg');
1041         $cidr = $dc_conf->{migration}->{network}
1042           if defined($dc_conf->{migration}->{network});
1043     }
1044
1045     if (defined($cidr)) {
1046         my $ips = PVE::Network::get_local_ip_from_cidr($cidr);
1047
1048         die "could not get migration ip: no IP address configured on local " .
1049             "node for network '$cidr'\n" if !$noerr && (scalar(@$ips) == 0);
1050
1051         die "could not get migration ip: multiple IP address configured for " .
1052             "network '$cidr'\n" if !$noerr && (scalar(@$ips) > 1);
1053
1054         return @$ips[0];
1055     }
1056
1057     return undef;
1058 };
1059
1060 # ssh related utility functions
1061
1062 sub ssh_merge_keys {
1063     # remove duplicate keys in $sshauthkeys
1064     # ssh-copy-id simply add keys, so the file can grow to large
1065
1066     my $data = '';
1067     if (-f $sshauthkeys) {
1068         $data = PVE::Tools::file_get_contents($sshauthkeys, 128*1024);
1069         chomp($data);
1070     }
1071
1072     my $found_backup;
1073     if (-f $rootsshauthkeysbackup) {
1074         $data .= "\n";
1075         $data .= PVE::Tools::file_get_contents($rootsshauthkeysbackup, 128*1024);
1076         chomp($data);
1077         $found_backup = 1;
1078     }
1079
1080     # always add ourself
1081     if (-f $ssh_rsa_id) {
1082         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
1083         chomp($pub);
1084         $data .= "\n$pub\n";
1085     }
1086
1087     my $newdata = "";
1088     my $vhash = {};
1089     my @lines = split(/\n/, $data);
1090     foreach my $line (@lines) {
1091         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
1092             next if $vhash->{$3}++;
1093         }
1094         $newdata .= "$line\n";
1095     }
1096
1097     PVE::Tools::file_set_contents($sshauthkeys, $newdata, 0600);
1098
1099     if ($found_backup && -l $rootsshauthkeys) {
1100         # everything went well, so we can remove the backup
1101         unlink $rootsshauthkeysbackup;
1102     }
1103 }
1104
1105 sub setup_sshd_config {
1106     my ($start_sshd) = @_;
1107
1108     my $conf = PVE::Tools::file_get_contents($sshd_config_fn);
1109
1110     return if $conf =~ m/^PermitRootLogin\s+yes\s*$/m;
1111
1112     if ($conf !~ s/^#?PermitRootLogin.*$/PermitRootLogin yes/m) {
1113         chomp $conf;
1114         $conf .= "\nPermitRootLogin yes\n";
1115     }
1116
1117     PVE::Tools::file_set_contents($sshd_config_fn, $conf);
1118
1119     my $cmd = $start_sshd ? 'reload-or-restart' : 'reload-or-try-restart';
1120     PVE::Tools::run_command(['systemctl', $cmd, 'sshd']);
1121 }
1122
1123 sub setup_rootsshconfig {
1124
1125     # create ssh key if it does not exist
1126     if (! -f $ssh_rsa_id) {
1127         mkdir '/root/.ssh/';
1128         system ("echo|ssh-keygen -t rsa -N '' -b 2048 -f ${ssh_rsa_id_priv}");
1129     }
1130
1131     # create ssh config if it does not exist
1132     if (! -f $rootsshconfig) {
1133         mkdir '/root/.ssh';
1134         if (my $fh = IO::File->new($rootsshconfig, O_CREAT|O_WRONLY|O_EXCL, 0640)) {
1135             # this is the default ciphers list from debian openssl0.9.8 except blowfish is added as prefered
1136             print $fh "Ciphers blowfish-cbc,aes128-ctr,aes192-ctr,aes256-ctr,arcfour256,arcfour128,aes128-cbc,3des-cbc\n";
1137             close($fh);
1138         }
1139     }
1140 }
1141
1142 sub setup_ssh_keys {
1143
1144     mkdir $authdir;
1145
1146     my $import_ok;
1147
1148     if (! -f $sshauthkeys) {
1149         my $old;
1150         if (-f $rootsshauthkeys) {
1151             $old = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
1152         }
1153         if (my $fh = IO::File->new ($sshauthkeys, O_CREAT|O_WRONLY|O_EXCL, 0400)) {
1154             PVE::Tools::safe_print($sshauthkeys, $fh, $old) if $old;
1155             close($fh);
1156             $import_ok = 1;
1157         }
1158     }
1159
1160     warn "can't create shared ssh key database '$sshauthkeys'\n"
1161         if ! -f $sshauthkeys;
1162
1163     if (-f $rootsshauthkeys && ! -l $rootsshauthkeys) {
1164         if (!rename($rootsshauthkeys , $rootsshauthkeysbackup)) {
1165             warn "rename $rootsshauthkeys failed - $!\n";
1166         }
1167     }
1168
1169     if (! -l $rootsshauthkeys) {
1170         symlink $sshauthkeys, $rootsshauthkeys;
1171     }
1172
1173     if (! -l $rootsshauthkeys) {
1174         warn "can't create symlink for ssh keys '$rootsshauthkeys' -> '$sshauthkeys'\n";
1175     } else {
1176         unlink $rootsshauthkeysbackup if $import_ok;
1177     }
1178 }
1179
1180 sub ssh_unmerge_known_hosts {
1181     return if ! -l $sshglobalknownhosts;
1182
1183     my $old = '';
1184     $old = PVE::Tools::file_get_contents($sshknownhosts, 128*1024)
1185         if -f $sshknownhosts;
1186
1187     PVE::Tools::file_set_contents($sshglobalknownhosts, $old);
1188 }
1189
1190 sub ssh_merge_known_hosts {
1191     my ($nodename, $ip_address, $createLink) = @_;
1192
1193     die "no node name specified" if !$nodename;
1194     die "no ip address specified" if !$ip_address;
1195
1196     # ssh lowercases hostnames (aliases) before comparision, so we need too
1197     $nodename = lc($nodename);
1198     $ip_address = lc($ip_address);
1199
1200     mkdir $authdir;
1201
1202     if (! -f $sshknownhosts) {
1203         if (my $fh = IO::File->new($sshknownhosts, O_CREAT|O_WRONLY|O_EXCL, 0600)) {
1204             close($fh);
1205         }
1206     }
1207
1208     my $old = PVE::Tools::file_get_contents($sshknownhosts, 128*1024);
1209
1210     my $new = '';
1211
1212     if ((! -l $sshglobalknownhosts) && (-f $sshglobalknownhosts)) {
1213         $new = PVE::Tools::file_get_contents($sshglobalknownhosts, 128*1024);
1214     }
1215
1216     my $hostkey = PVE::Tools::file_get_contents($ssh_host_rsa_id);
1217     # Note: file sometimes containe emty lines at start, so we use multiline match
1218     die "can't parse $ssh_host_rsa_id" if $hostkey !~ m/^(ssh-rsa\s\S+)(\s.*)?$/m;
1219     $hostkey = $1;
1220
1221     my $data = '';
1222     my $vhash = {};
1223
1224     my $found_nodename;
1225     my $found_local_ip;
1226
1227     my $merge_line = sub {
1228         my ($line, $all) = @_;
1229
1230         return if $line =~ m/^\s*$/; # skip empty lines
1231         return if $line =~ m/^#/; # skip comments
1232
1233         if ($line =~ m/^(\S+)\s(ssh-rsa\s\S+)(\s.*)?$/) {
1234             my $key = $1;
1235             my $rsakey = $2;
1236             if (!$vhash->{$key}) {
1237                 $vhash->{$key} = 1;
1238                 if ($key =~ m/\|1\|([^\|\s]+)\|([^\|\s]+)$/) {
1239                     my $salt = decode_base64($1);
1240                     my $digest = $2;
1241                     my $hmac = Digest::HMAC_SHA1->new($salt);
1242                     $hmac->add($nodename);
1243                     my $hd = $hmac->b64digest . '=';
1244                     if ($digest eq $hd) {
1245                         if ($rsakey eq $hostkey) {
1246                             $found_nodename = 1;
1247                             $data .= $line;
1248                         }
1249                         return;
1250                     }
1251                     $hmac = Digest::HMAC_SHA1->new($salt);
1252                     $hmac->add($ip_address);
1253                     $hd = $hmac->b64digest . '=';
1254                     if ($digest eq $hd) {
1255                         if ($rsakey eq $hostkey) {
1256                             $found_local_ip = 1;
1257                             $data .= $line;
1258                         }
1259                         return;
1260                     }
1261                 } else {
1262                     $key = lc($key); # avoid duplicate entries, ssh compares lowercased
1263                     if ($key eq $ip_address) {
1264                         $found_local_ip = 1 if $rsakey eq $hostkey;
1265                     } elsif ($key eq $nodename) {
1266                         $found_nodename = 1 if $rsakey eq $hostkey;
1267                     }
1268                 }
1269                 $data .= $line;
1270             }
1271         } elsif ($all) {
1272             $data .= $line;
1273         }
1274     };
1275
1276     while ($old && $old =~ s/^((.*?)(\n|$))//) {
1277         my $line = "$2\n";
1278         &$merge_line($line, 1);
1279     }
1280
1281     while ($new && $new =~ s/^((.*?)(\n|$))//) {
1282         my $line = "$2\n";
1283         &$merge_line($line);
1284     }
1285
1286     # add our own key if not already there
1287     $data .= "$nodename $hostkey\n" if !$found_nodename;
1288     $data .= "$ip_address $hostkey\n" if !$found_local_ip;
1289
1290     PVE::Tools::file_set_contents($sshknownhosts, $data);
1291
1292     return if !$createLink;
1293
1294     unlink $sshglobalknownhosts;
1295     symlink $sshknownhosts, $sshglobalknownhosts;
1296
1297     warn "can't create symlink for ssh known hosts '$sshglobalknownhosts' -> '$sshknownhosts'\n"
1298         if ! -l $sshglobalknownhosts;
1299
1300 }
1301
1302 my $migration_format = {
1303     type => {
1304         default_key => 1,
1305         type => 'string',
1306         enum => ['secure', 'insecure'],
1307         description => "Migration traffic is encrypted using an SSH tunnel by " .
1308           "default. On secure, completely private networks this can be " .
1309           "disabled to increase performance.",
1310         default => 'secure',
1311     },
1312     network => {
1313         optional => 1,
1314         type => 'string', format => 'CIDR',
1315         format_description => 'CIDR',
1316         description => "CIDR of the (sub) network that is used for migration."
1317     },
1318 };
1319
1320 my $datacenter_schema = {
1321     type => "object",
1322     additionalProperties => 0,
1323     properties => {
1324         keyboard => {
1325             optional => 1,
1326             type => 'string',
1327             description => "Default keybord layout for vnc server.",
1328             enum => PVE::Tools::kvmkeymaplist(),
1329         },
1330         language => {
1331             optional => 1,
1332             type => 'string',
1333             description => "Default GUI language.",
1334             enum => [ 'en', 'de' ],
1335         },
1336         http_proxy => {
1337             optional => 1,
1338             type => 'string',
1339             description => "Specify external http proxy which is used for downloads (example: 'http://username:password\@host:port/')",
1340             pattern => "http://.*",
1341         },
1342         migration_unsecure => {
1343             optional => 1,
1344             type => 'boolean',
1345             description => "Migration is secure using SSH tunnel by default. " .
1346               "For secure private networks you can disable it to speed up " .
1347               "migration. Deprecated, use the 'migration' property instead!",
1348         },
1349         migration => {
1350             optional => 1,
1351             type => 'string', format => $migration_format,
1352             description => "For cluster wide migration settings.",
1353         },
1354         console => {
1355             optional => 1,
1356             type => 'string',
1357             description => "Select the default Console viewer. You can either use the builtin java applet (VNC), an external virt-viewer comtatible application (SPICE), or an HTML5 based viewer (noVNC).",
1358             enum => ['applet', 'vv', 'html5'],
1359         },
1360         email_from => {
1361             optional => 1,
1362             type => 'string',
1363             format => 'email-opt',
1364             description => "Specify email address to send notification from (default is root@\$hostname)",
1365         },
1366         max_workers => {
1367             optional => 1,
1368             type => 'integer',
1369             minimum => 1,
1370             description => "Defines how many workers (per node) are maximal started ".
1371               " on actions like 'stopall VMs' or task from the ha-manager.",
1372         },
1373         fencing => {
1374             optional => 1,
1375             type => 'string',
1376             default => 'watchdog',
1377             enum => [ 'watchdog', 'hardware', 'both' ],
1378             description => "Set the fencing mode of the HA cluster. Hardware mode " .
1379               "needs a valid configuration of fence devices in /etc/pve/ha/fence.cfg." .
1380               " With both all two modes are used." .
1381               "\n\nWARNING: 'hardware' and 'both' are EXPERIMENTAL & WIP",
1382         },
1383         mac_prefix => {
1384             optional => 1,
1385             type => 'string',
1386             pattern => qr/[a-f0-9]{2}(?::[a-f0-9]{2}){0,2}:?/i,
1387             description => 'Prefix for autogenerated MAC addresses.',
1388         },
1389     },
1390 };
1391
1392 # make schema accessible from outside (for documentation)
1393 sub get_datacenter_schema { return $datacenter_schema };
1394
1395 sub parse_datacenter_config {
1396     my ($filename, $raw) = @_;
1397
1398     my $res = PVE::JSONSchema::parse_config($datacenter_schema, $filename, $raw // '');
1399
1400     if (my $migration = $res->{migration}) {
1401         $res->{migration} = PVE::JSONSchema::parse_property_string($migration_format, $migration);
1402     }
1403
1404     # for backwards compatibility only, new migration property has precedence
1405     if (defined($res->{migration_unsecure})) {
1406         if (defined($res->{migration}->{type})) {
1407             warn "deprecated setting 'migration_unsecure' and new 'migration: type' " .
1408               "set at same time! Ignore 'migration_unsecure'\n";
1409         } else {
1410             $res->{migration}->{type} = ($res->{migration_unsecure}) ? 'insecure' : 'secure';
1411         }
1412     }
1413
1414     return $res;
1415 }
1416
1417 sub write_datacenter_config {
1418     my ($filename, $cfg) = @_;
1419
1420     # map deprecated setting to new one
1421     if (defined($cfg->{migration_unsecure}) && !defined($cfg->{migration})) {
1422         my $migration_unsecure = delete $cfg->{migration_unsecure};
1423         $cfg->{migration}->{type} = ($migration_unsecure) ? 'insecure' : 'secure';
1424     }
1425
1426     return PVE::JSONSchema::dump_config($datacenter_schema, $filename, $cfg);
1427 }
1428
1429 cfs_register_file('datacenter.cfg',
1430                   \&parse_datacenter_config,
1431                   \&write_datacenter_config);
1432
1433 # X509 Certificate cache helper
1434
1435 my $cert_cache_nodes = {};
1436 my $cert_cache_timestamp = time();
1437 my $cert_cache_fingerprints = {};
1438
1439 sub update_cert_cache {
1440     my ($update_node, $clear) = @_;
1441
1442     syslog('info', "Clearing outdated entries from certificate cache")
1443         if $clear;
1444
1445     $cert_cache_timestamp = time() if !defined($update_node);
1446
1447     my $node_list = defined($update_node) ?
1448         [ $update_node ] : [ keys %$cert_cache_nodes ];
1449
1450     foreach my $node (@$node_list) {
1451         my $clear_old = sub {
1452             if (my $old_fp = $cert_cache_nodes->{$node}) {
1453                 # distrust old fingerprint
1454                 delete $cert_cache_fingerprints->{$old_fp};
1455                 # ensure reload on next proxied request
1456                 delete $cert_cache_nodes->{$node};
1457             }
1458         };
1459
1460         my $cert_path = "/etc/pve/nodes/$node/pve-ssl.pem";
1461         my $custom_cert_path = "/etc/pve/nodes/$node/pveproxy-ssl.pem";
1462
1463         $cert_path = $custom_cert_path if -f $custom_cert_path;
1464
1465         my $cert;
1466         eval {
1467             my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
1468             $cert = Net::SSLeay::PEM_read_bio_X509($bio);
1469             Net::SSLeay::BIO_free($bio);
1470         };
1471         my $err = $@;
1472         if ($err || !defined($cert)) {
1473             &$clear_old() if $clear;
1474             next;
1475         }
1476
1477         my $fp;
1478         eval {
1479             $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
1480         };
1481         $err = $@;
1482         if ($err || !defined($fp) || $fp eq '') {
1483             &$clear_old() if $clear;
1484             next;
1485         }
1486
1487         my $old_fp = $cert_cache_nodes->{$node};
1488         $cert_cache_fingerprints->{$fp} = 1;
1489         $cert_cache_nodes->{$node} = $fp;
1490
1491         if (defined($old_fp) && $fp ne $old_fp) {
1492             delete $cert_cache_fingerprints->{$old_fp};
1493         }
1494     }
1495 }
1496
1497 # load and cache cert fingerprint once
1498 sub initialize_cert_cache {
1499     my ($node) = @_;
1500
1501     update_cert_cache($node)
1502         if defined($node) && !defined($cert_cache_nodes->{$node});
1503 }
1504
1505 sub check_cert_fingerprint {
1506     my ($cert) = @_;
1507
1508     # clear cache every 30 minutes at least
1509     update_cert_cache(undef, 1) if time() - $cert_cache_timestamp >= 60*30;
1510
1511     # get fingerprint of server certificate
1512     my $fp;
1513     eval {
1514         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
1515     };
1516     return 0 if $@ || !defined($fp) || $fp eq ''; # error
1517
1518     my $check = sub {
1519         for my $expected (keys %$cert_cache_fingerprints) {
1520             return 1 if $fp eq $expected;
1521         }
1522         return 0;
1523     };
1524
1525     return 1 if &$check();
1526
1527     # clear cache and retry at most once every minute
1528     if (time() - $cert_cache_timestamp >= 60) {
1529         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
1530         update_cert_cache();
1531         return &$check();
1532     }
1533
1534     return 0;
1535 }
1536
1537 # bash completion helpers
1538
1539 sub complete_next_vmid {
1540
1541     my $vmlist = get_vmlist() || {};
1542     my $idlist = $vmlist->{ids} || {};
1543
1544     for (my $i = 100; $i < 10000; $i++) {
1545         return [$i] if !defined($idlist->{$i});
1546     }
1547
1548     return [];
1549 }
1550
1551 sub complete_vmid {
1552
1553     my $vmlist = get_vmlist();
1554     my $ids = $vmlist->{ids} || {};
1555
1556     return [ keys %$ids ];
1557 }
1558
1559 sub complete_local_vmid {
1560
1561     my $vmlist = get_vmlist();
1562     my $ids = $vmlist->{ids} || {};
1563
1564     my $nodename = PVE::INotify::nodename();
1565
1566     my $res = [];
1567     foreach my $vmid (keys %$ids) {
1568         my $d = $ids->{$vmid};
1569         next if !$d->{node} || $d->{node} ne $nodename;
1570         push @$res, $vmid;
1571     }
1572
1573     return $res;
1574 }
1575
1576 sub complete_migration_target {
1577
1578     my $res = [];
1579
1580     my $nodename = PVE::INotify::nodename();
1581
1582     my $nodelist = get_nodelist();
1583     foreach my $node (@$nodelist) {
1584         next if $node eq $nodename;
1585         push @$res, $node;
1586     }
1587
1588     return $res;
1589 }
1590
1591 sub get_ssh_info {
1592     my ($node, $network_cidr) = @_;
1593
1594     my $ip;
1595     if (defined($network_cidr)) {
1596         # Use mtunnel via to get the remote node's ip inside $network_cidr.
1597         # This goes over the regular network (iow. uses get_ssh_info() with
1598         # $network_cidr undefined.
1599         # FIXME: Use the REST API client for this after creating an API entry
1600         # for get_migration_ip.
1601         my $default_remote = get_ssh_info($node, undef);
1602         my $default_ssh = ssh_info_to_command($default_remote);
1603         my $cmd =[@$default_ssh, 'pvecm', 'mtunnel',
1604             '-migration_network', $network_cidr,
1605             '-get_migration_ip'
1606         ];
1607         PVE::Tools::run_command($cmd, outfunc => sub {
1608             my ($line) = @_;
1609             chomp $line;
1610             die "internal error: unexpected output from mtunnel\n"
1611                 if defined($ip);
1612             if ($line =~ /^ip: '(.*)'$/) {
1613                 $ip = $1;
1614             } else {
1615                 die "internal error: bad output from mtunnel\n"
1616                     if defined($ip);
1617             }
1618         });
1619         die "failed to get ip for node '$node' in network '$network_cidr'\n"
1620             if !defined($ip);
1621     } else {
1622         $ip = remote_node_ip($node);
1623     }
1624
1625     return {
1626         ip => $ip,
1627         name => $node,
1628         network => $network_cidr,
1629     };
1630 }
1631
1632 sub ssh_info_to_command_base {
1633     my ($info, @extra_options) = @_;
1634     return [
1635         '/usr/bin/ssh',
1636         '-o', 'BatchMode=yes',
1637         '-o', 'HostKeyAlias='.$info->{name},
1638         @extra_options
1639     ];
1640 }
1641
1642 sub ssh_info_to_command {
1643     my ($info, @extra_options) = @_;
1644     my $cmd = ssh_info_to_command_base($info, @extra_options);
1645     push @$cmd, "root\@$info->{ip}";
1646     return $cmd;
1647 }
1648
1649 1;