data/PVE/Cluster.pm

   1 package PVE::Cluster;
   2
   3 use strict;
   4 use POSIX;
   5 use File::stat qw();
   6 use Socket;
   7 use Storable qw(dclone);
   8 use IO::File;
   9 use MIME::Base64;
  10 use XML::Parser;
  11 use Digest::SHA;
  12 use Digest::HMAC_SHA1;
  13 use PVE::Tools;
  14 use PVE::INotify;
  15 use PVE::IPCC;
  16 use PVE::SafeSyslog;
  17 use PVE::JSONSchema;
  18 use JSON;
  19 use RRDs;
  20 use Encode;
  21 use base 'Exporter';
  22
  23 our @EXPORT_OK = qw(
  24 cfs_read_file
  25 cfs_write_file
  26 cfs_register_file
  27 cfs_lock_file);
  28
  29 use Data::Dumper; # fixme: remove
  30
  31 # x509 certificate utils
  32
  33 my $basedir = "/etc/pve";
  34 my $authdir = "$basedir/priv";
  35 my $lockdir = "/etc/pve/priv/lock";
  36
  37 my $authprivkeyfn = "$authdir/authkey.key";
  38 my $authpubkeyfn = "$basedir/authkey.pub";
  39 my $pveca_key_fn = "$authdir/pve-root-ca.key";
  40 my $pveca_srl_fn = "$authdir/pve-root-ca.srl";
  41 my $pveca_cert_fn = "$basedir/pve-root-ca.pem";
  42 # this is just a secret accessable by the web browser
  43 # and is used for CSRF prevention
  44 my $pvewww_key_fn = "$basedir/pve-www.key";
  45
  46 # ssh related files
  47 my $ssh_rsa_id_priv = "/root/.ssh/id_rsa";
  48 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
  49 my $ssh_host_rsa_id = "/etc/ssh/ssh_host_rsa_key.pub";
  50 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts";
  51 my $sshknownhosts = "/etc/pve/priv/known_hosts";
  52 my $sshauthkeys = "/etc/pve/priv/authorized_keys";
  53 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
  54
  55 my $observed = {
  56     'vzdump.cron' => 1,
  57     'storage.cfg' => 1,
  58     'datacenter.cfg' => 1,
  59     'cluster.conf' => 1,
  60     'cluster.conf.new' => 1,
  61     'user.cfg' => 1,
  62     'domains.cfg' => 1,
  63     'priv/shadow.cfg' => 1,
  64     '/qemu-server/' => 1,
  65     '/openvz/' => 1,
  66 };
  67
  68 # only write output if something fails
  69 sub run_silent_cmd {
  70     my ($cmd) = @_;
  71
  72     my $outbuf = '';
  73
  74     my $record_output = sub {
  75         $outbuf .= shift;
  76         $outbuf .= "\n";
  77     };
  78
  79     eval {
  80         PVE::Tools::run_command($cmd, outfunc => $record_output,
  81                                 errfunc => $record_output);
  82     };
  83
  84     my $err = $@;
  85
  86     if ($err) {
  87         print STDERR $outbuf;
  88         die $err;
  89     }
  90 }
  91
  92 sub check_cfs_quorum {
  93     my ($noerr) = @_;
  94
  95     # note: -w filename always return 1 for root, so wee need
  96     # to use File::lstat here
  97     my $st = File::stat::lstat("$basedir/local");
  98     my $quorate = ($st && (($st->mode & 0200) != 0));
  99
 100     die "cluster not ready - no quorum?\n" if !$quorate && !$noerr;
 101
 102     return $quorate;
 103 }
 104
 105 sub check_cfs_is_mounted {
 106     my ($noerr) = @_;
 107
 108     my $res = -l "$basedir/local";
 109
 110     die "pve configuration filesystem not mounted\n"
 111         if !$res && !$noerr;
 112
 113     return $res;
 114 }
 115
 116 sub gen_local_dirs {
 117     my ($nodename) = @_;
 118
 119     check_cfs_is_mounted();
 120
 121     my @required_dirs = (
 122         "$basedir/priv",
 123         "$basedir/nodes",
 124         "$basedir/nodes/$nodename",
 125         "$basedir/nodes/$nodename/qemu-server",
 126         "$basedir/nodes/$nodename/openvz",
 127         "$basedir/nodes/$nodename/priv");
 128
 129     foreach my $dir (@required_dirs) {
 130         if (! -d $dir) {
 131             mkdir($dir) || die "unable to create directory '$dir' - $!\n";
 132         }
 133     }
 134 }
 135
 136 sub gen_auth_key {
 137
 138     return if -f "$authprivkeyfn";
 139
 140     check_cfs_is_mounted();
 141
 142     mkdir $authdir || die "unable to create dir '$authdir' - $!\n";
 143
 144     my $cmd = "openssl genrsa -out '$authprivkeyfn' 2048";
 145     run_silent_cmd($cmd);
 146
 147     $cmd = "openssl rsa -in '$authprivkeyfn' -pubout -out '$authpubkeyfn'";
 148     run_silent_cmd($cmd)
 149 }
 150
 151 sub gen_pveca_key {
 152
 153     return if -f $pveca_key_fn;
 154
 155     eval {
 156         run_silent_cmd(['openssl', 'genrsa', '-out', $pveca_key_fn, '2048']);
 157     };
 158
 159     die "unable to generate pve ca key:\n$@" if $@;
 160 }
 161
 162 sub gen_pveca_cert {
 163
 164     if (-f $pveca_key_fn && -f $pveca_cert_fn) {
 165         return 0;
 166     }
 167
 168     gen_pveca_key();
 169
 170     # we try to generate an unique 'subject' to avoid browser problems
 171     # (reused serial numbers, ..)
 172     my $nid = (split (/\s/, `md5sum '$pveca_key_fn'`))[0] || time();
 173
 174     eval {
 175         run_silent_cmd(['openssl', 'req', '-batch', '-days', '3650', '-new',
 176                         '-x509', '-nodes', '-key',
 177                         $pveca_key_fn, '-out', $pveca_cert_fn, '-subj',
 178                         "/CN=Proxmox Virtual Environment/OU=$nid/O=PVE Cluster Manager CA/"]);
 179     };
 180
 181     die "generating pve root certificate failed:\n$@" if $@;
 182
 183     return 1;
 184 }
 185
 186 sub gen_pve_ssl_key {
 187     my ($nodename) = @_;
 188
 189     die "no node name specified" if !$nodename;
 190
 191     my $pvessl_key_fn = "$basedir/nodes/$nodename/pve-ssl.key";
 192
 193     return if -f $pvessl_key_fn;
 194
 195     eval {
 196         run_silent_cmd(['openssl', 'genrsa', '-out', $pvessl_key_fn, '2048']);
 197     };
 198
 199     die "unable to generate pve ssl key for node '$nodename':\n$@" if $@;
 200 }
 201
 202 sub gen_pve_www_key {
 203
 204     return if -f $pvewww_key_fn;
 205
 206     eval {
 207         run_silent_cmd(['openssl', 'genrsa', '-out', $pvewww_key_fn, '2048']);
 208     };
 209
 210     die "unable to generate pve www key:\n$@" if $@;
 211 }
 212
 213 sub update_serial {
 214     my ($serial) = @_;
 215
 216     PVE::Tools::file_set_contents($pveca_srl_fn, $serial);
 217 }
 218
 219 sub gen_pve_ssl_cert {
 220     my ($force, $nodename, $ip) = @_;
 221
 222     die "no node name specified" if !$nodename;
 223     die "no IP specified" if !$ip;
 224
 225     my $pvessl_cert_fn = "$basedir/nodes/$nodename/pve-ssl.pem";
 226
 227     return if !$force && -f $pvessl_cert_fn;
 228
 229     my $names = "IP:127.0.0.1,DNS:localhost";
 230
 231     my $rc = PVE::INotify::read_file('resolvconf');
 232
 233     $names .= ",IP:$ip";
 234
 235     my $fqdn = $nodename;
 236
 237     $names .= ",DNS:$nodename";
 238
 239     if ($rc && $rc->{search}) {
 240         $fqdn = $nodename . "." . $rc->{search};
 241         $names .= ",DNS:$fqdn";
 242     }
 243
 244     my $sslconf = <<__EOD;
 245 RANDFILE = /root/.rnd
 246 extensions = v3_req
 247
 248 [ req ]
 249 default_bits = 2048
 250 distinguished_name = req_distinguished_name
 251 req_extensions = v3_req
 252 prompt = no
 253 string_mask = nombstr
 254
 255 [ req_distinguished_name ]
 256 organizationalUnitName = PVE Cluster Node
 257 organizationName = Proxmox Virtual Environment
 258 commonName = $fqdn
 259
 260 [ v3_req ]
 261 basicConstraints = CA:FALSE
 262 nsCertType = server
 263 keyUsage = nonRepudiation, digitalSignature, keyEncipherment
 264 subjectAltName = $names
 265 __EOD
 266
 267     my $cfgfn = "/tmp/pvesslconf-$$.tmp";
 268     my $fh = IO::File->new ($cfgfn, "w");
 269     print $fh $sslconf;
 270     close ($fh);
 271
 272     my $reqfn = "/tmp/pvecertreq-$$.tmp";
 273     unlink $reqfn;
 274
 275     my $pvessl_key_fn = "$basedir/nodes/$nodename/pve-ssl.key";
 276     eval {
 277         run_silent_cmd(['openssl', 'req', '-batch', '-new', '-config', $cfgfn,
 278                         '-key', $pvessl_key_fn, '-out', $reqfn]);
 279     };
 280
 281     if (my $err = $@) {
 282         unlink $reqfn;
 283         unlink $cfgfn;
 284         die "unable to generate pve certificate request:\n$err";
 285     }
 286
 287     update_serial("0000000000000000") if ! -f $pveca_srl_fn;
 288
 289     eval {
 290         run_silent_cmd(['openssl', 'x509', '-req', '-in', $reqfn, '-days', '3650',
 291                         '-out', $pvessl_cert_fn, '-CAkey', $pveca_key_fn,
 292                         '-CA', $pveca_cert_fn, '-CAserial', $pveca_srl_fn,
 293                         '-extfile', $cfgfn]);
 294     };
 295
 296     if (my $err = $@) {
 297         unlink $reqfn;
 298         unlink $cfgfn;
 299         die "unable to generate pve ssl certificate:\n$err";
 300     }
 301
 302     unlink $cfgfn;
 303     unlink $reqfn;
 304 }
 305
 306 sub gen_pve_node_files {
 307     my ($nodename, $ip, $opt_force) = @_;
 308
 309     gen_local_dirs($nodename);
 310
 311     gen_auth_key();
 312
 313     # make sure we have a (cluster wide) secret
 314     # for CSRFR prevention
 315     gen_pve_www_key();
 316
 317     # make sure we have a (per node) private key
 318     gen_pve_ssl_key($nodename);
 319
 320     # make sure we have a CA
 321     my $force = gen_pveca_cert();
 322
 323     $force = 1 if $opt_force;
 324
 325     gen_pve_ssl_cert($force, $nodename, $ip);
 326 }
 327
 328 my $vzdump_cron_dummy = <<__EOD;
 329 # cluster wide vzdump cron schedule
 330 # Atomatically generated file - do not edit
 331
 332 PATH="/usr/sbin:/usr/bin:/sbin:/bin"
 333
 334 __EOD
 335
 336 sub gen_pve_vzdump_symlink {
 337
 338     my $filename = "/etc/pve/vzdump.cron";
 339
 340     my $link_fn = "/etc/cron.d/vzdump";
 341
 342     if ((-f $filename) && (! -l $link_fn)) {
 343         rename($link_fn, "/root/etc_cron_vzdump.org"); # make backup if file exists
 344         symlink($filename, $link_fn);
 345     }
 346 }
 347
 348 sub gen_pve_vzdump_files {
 349
 350     my $filename = "/etc/pve/vzdump.cron";
 351
 352     PVE::Tools::file_set_contents($filename, $vzdump_cron_dummy)
 353         if ! -f $filename;
 354
 355     gen_pve_vzdump_symlink();
 356 };
 357
 358 my $versions = {};
 359 my $vmlist = {};
 360 my $clinfo = {};
 361
 362 my $ipcc_send_rec = sub {
 363     my ($msgid, $data) = @_;
 364
 365     my $res = PVE::IPCC::ipcc_send_rec($msgid, $data);
 366
 367     die "ipcc_send_rec failed: $!\n" if !defined($res) && ($! != 0);
 368
 369     return $res;
 370 };
 371
 372 my $ipcc_send_rec_json = sub {
 373     my ($msgid, $data) = @_;
 374
 375     my $res = PVE::IPCC::ipcc_send_rec($msgid, $data);
 376
 377     die "ipcc_send_rec failed: $!\n" if !defined($res) && ($! != 0);
 378
 379     return decode_json($res);
 380 };
 381
 382 my $ipcc_get_config = sub {
 383     my ($path) = @_;
 384
 385     my $bindata = pack "Z*", $path;
 386     my $res = PVE::IPCC::ipcc_send_rec(6, $bindata);
 387     if (!defined($res)) {
 388         return undef if ($! != 0);
 389         return '';
 390     }
 391
 392     return $res;
 393 };
 394
 395 my $ipcc_get_status = sub {
 396     my ($name, $nodename) = @_;
 397
 398     my $bindata = pack "Z[256]Z[256]", $name, ($nodename || "");
 399     return PVE::IPCC::ipcc_send_rec(5, $bindata);
 400 };
 401
 402 my $ipcc_update_status = sub {
 403     my ($name, $data) = @_;
 404
 405     my $raw = ref($data) ? encode_json($data) : $data;
 406     # update status
 407     my $bindata = pack "Z[256]Z*", $name, $raw;
 408
 409     return &$ipcc_send_rec(4, $bindata);
 410 };
 411
 412 my $ipcc_log = sub {
 413     my ($priority, $ident, $tag, $msg) = @_;
 414
 415     my $bindata = pack "CCCZ*Z*Z*", $priority, bytes::length($ident) + 1,
 416     bytes::length($tag) + 1, $ident, $tag, $msg;
 417
 418     return &$ipcc_send_rec(7, $bindata);
 419 };
 420
 421 my $ipcc_get_cluster_log = sub {
 422     my ($user, $max) = @_;
 423
 424     $max = 0 if !defined($max);
 425
 426     my $bindata = pack "VVVVZ*", $max, 0, 0, 0, ($user || "");
 427     return &$ipcc_send_rec(8, $bindata);
 428 };
 429
 430 my $ccache = {};
 431
 432 sub cfs_update {
 433     eval {
 434         my $res = &$ipcc_send_rec_json(1);
 435         #warn "GOT1: " . Dumper($res);
 436         die "no starttime\n" if !$res->{starttime};
 437
 438         if (!$res->{starttime} || !$versions->{starttime} ||
 439             $res->{starttime} != $versions->{starttime}) {
 440             #print "detected changed starttime\n";
 441             $vmlist = {};
 442             $clinfo = {};
 443             $ccache = {};
 444         }
 445
 446         $versions = $res;
 447     };
 448     my $err = $@;
 449     if ($err) {
 450         $versions = {};
 451         $vmlist = {};
 452         $clinfo = {};
 453         $ccache = {};
 454         warn $err;
 455     }
 456
 457     eval {
 458         if (!$clinfo->{version} || $clinfo->{version} != $versions->{clinfo}) {
 459             #warn "detected new clinfo\n";
 460             $clinfo = &$ipcc_send_rec_json(2);
 461         }
 462     };
 463     $err = $@;
 464     if ($err) {
 465         $clinfo = {};
 466         warn $err;
 467     }
 468
 469     eval {
 470         if (!$vmlist->{version} || $vmlist->{version} != $versions->{vmlist}) {
 471             #warn "detected new vmlist1\n";
 472             $vmlist = &$ipcc_send_rec_json(3);
 473         }
 474     };
 475     $err = $@;
 476     if ($err) {
 477         $vmlist = {};
 478         warn $err;
 479     }
 480 }
 481
 482 sub get_vmlist {
 483     return $vmlist;
 484 }
 485
 486 sub get_clinfo {
 487     return $clinfo;
 488 }
 489
 490 sub get_members {
 491     return $clinfo->{nodelist};
 492 }
 493
 494 sub get_nodelist {
 495
 496     my $nodelist = $clinfo->{nodelist};
 497
 498     my $result = [];
 499
 500     my $nodename = PVE::INotify::nodename();
 501
 502     if (!$nodelist || !$nodelist->{$nodename}) {
 503         return [ $nodename ];
 504     }
 505
 506     return [ keys %$nodelist ];
 507 }
 508
 509 sub broadcast_tasklist {
 510     my ($data) = @_;
 511
 512     eval {
 513         &$ipcc_update_status("tasklist", $data);
 514     };
 515
 516     warn $@ if $@;
 517 }
 518
 519 my $tasklistcache = {};
 520
 521 sub get_tasklist {
 522     my ($nodename) = @_;
 523
 524     my $kvstore = $versions->{kvstore} || {};
 525
 526     my $nodelist = get_nodelist();
 527
 528     my $res = [];
 529     foreach my $node (@$nodelist) {
 530         next if $nodename && ($nodename ne $node);
 531         eval {
 532             my $ver = $kvstore->{$node}->{tasklist} if $kvstore->{$node};
 533             my $cd = $tasklistcache->{$node};
 534             if (!$cd || !$ver || ($cd->{version} != $ver)) {
 535                 my $raw = &$ipcc_get_status("tasklist", $node) || '[]';
 536                 my $data = decode_json($raw);
 537                 push @$res, @$data;
 538                 $cd = $tasklistcache->{$node} = {
 539                     data => $data,
 540                     version => $ver,
 541                 };
 542             } elsif ($cd && $cd->{data}) {
 543                 push @$res, @{$cd->{data}};
 544             }
 545         };
 546         my $err = $@;
 547         syslog('err', $err) if $err;
 548     }
 549
 550     return $res;
 551 }
 552
 553 sub broadcast_rrd {
 554     my ($rrdid, $data) = @_;
 555
 556     eval {
 557         &$ipcc_update_status("rrd/$rrdid", $data);
 558     };
 559     my $err = $@;
 560
 561     warn $err if $err;
 562 }
 563
 564 my $last_rrd_dump = 0;
 565 my $last_rrd_data = "";
 566
 567 sub rrd_dump {
 568
 569     my $ctime = time();
 570
 571     my $diff = $ctime - $last_rrd_dump;
 572     if ($diff < 2) {
 573         return $last_rrd_data;
 574     }
 575
 576     my $raw;
 577     eval {
 578         $raw = &$ipcc_send_rec(10);
 579     };
 580     my $err = $@;
 581
 582     if ($err) {
 583         warn $err;
 584         return {};
 585     }
 586
 587     my $res = {};
 588
 589     while ($raw =~ s/^(.*)\n//) {
 590         my ($key, @ela) = split(/:/, $1);
 591         next if !$key;
 592         next if !(scalar(@ela) > 1);
 593         $res->{$key} = \@ela;
 594     }
 595
 596     $last_rrd_dump = $ctime;
 597     $last_rrd_data = $res;
 598
 599     return $res;
 600 }
 601
 602 sub create_rrd_data {
 603     my ($rrdname, $timeframe, $cf) = @_;
 604
 605     my $rrddir = "/var/lib/rrdcached/db";
 606
 607     my $rrd = "$rrddir/$rrdname";
 608
 609     my $setup = {
 610         hour =>  [ 60, 70 ],
 611         day  =>  [ 60*30, 70 ],
 612         week =>  [ 60*180, 70 ],
 613         month => [ 60*720, 70 ],
 614         year =>  [ 60*10080, 70 ],
 615     };
 616
 617     my ($reso, $count) = @{$setup->{$timeframe}};
 618     my $ctime  = $reso*int(time()/$reso);
 619     my $req_start = $ctime - $reso*$count;
 620
 621     $cf = "AVERAGE" if !$cf;
 622
 623     my @args = (
 624         "-s" => $req_start,
 625         "-e" => $ctime - 1,
 626         "-r" => $reso,
 627         );
 628
 629     my $socket = "/var/run/rrdcached.sock";
 630     push @args, "--daemon" => "unix:$socket" if -S $socket;
 631
 632     my ($start, $step, $names, $data) = RRDs::fetch($rrd, $cf, @args);
 633
 634     my $err = RRDs::error;
 635     die "RRD error: $err\n" if $err;
 636
 637     die "got wrong time resolution ($step != $reso)\n"
 638         if $step != $reso;
 639
 640     my $res = [];
 641     my $fields = scalar(@$names);
 642     for my $line (@$data) {
 643         my $entry = { 'time' => $start };
 644         $start += $step;
 645         my $found_undefs;
 646         for (my $i = 0; $i < $fields; $i++) {
 647             my $name = $names->[$i];
 648             if (defined(my $val = $line->[$i])) {
 649                 $entry->{$name} = $val;
 650             } else {
 651                 # we only add entryies with all data defined
 652                 # extjs chart has problems with undefined values
 653                 $found_undefs = 1;
 654             }
 655         }
 656         push @$res, $entry if !$found_undefs;
 657     }
 658
 659     return $res;
 660 }
 661
 662 sub create_rrd_graph {
 663     my ($rrdname, $timeframe, $ds, $cf) = @_;
 664
 665     # Using RRD graph is clumsy - maybe it
 666     # is better to simply fetch the data, and do all display
 667     # related things with javascript (new extjs html5 graph library).
 668
 669     my $rrddir = "/var/lib/rrdcached/db";
 670
 671     my $rrd = "$rrddir/$rrdname";
 672
 673     my @ids = PVE::Tools::split_list($ds);
 674
 675     my $ds_txt = join('_', @ids);
 676
 677     my $filename = "${rrd}_${ds_txt}.png";
 678
 679     my $setup = {
 680         hour =>  [ 60, 60 ],
 681         day  =>  [ 60*30, 70 ],
 682         week =>  [ 60*180, 70 ],
 683         month => [ 60*720, 70 ],
 684         year =>  [ 60*10080, 70 ],
 685     };
 686
 687     my ($reso, $count) = @{$setup->{$timeframe}};
 688
 689     my @args = (
 690         "--imgformat" => "PNG",
 691         "--border" => 0,
 692         "--height" => 200,
 693         "--width" => 800,
 694         "--start" => - $reso*$count,
 695         "--end" => 'now' ,
 696         );
 697
 698     my $socket = "/var/run/rrdcached.sock";
 699     push @args, "--daemon" => "unix:$socket" if -S $socket;
 700
 701     my @coldef = ('#00ddff', '#ff0000');
 702
 703     $cf = "AVERAGE" if !$cf;
 704
 705     my $i = 0;
 706     foreach my $id (@ids) {
 707         my $col = $coldef[$i++] || die "fixme: no color definition";
 708         push @args, "DEF:${id}=$rrd:${id}:$cf";
 709         my $dataid = $id;
 710         if ($id eq 'cpu' || $id eq 'iowait') {
 711             push @args, "CDEF:${id}_per=${id},100,*";
 712             $dataid = "${id}_per";
 713         }
 714         push @args, "LINE2:${dataid}${col}:${id}";
 715     }
 716
 717     push @args, '--full-size-mode';
 718
 719     # we do not really store data into the file
 720     my $res = RRDs::graphv(undef, @args);
 721
 722     my $err = RRDs::error;
 723     die "RRD error: $err\n" if $err;
 724
 725     return { filename => $filename, image => $res->{image} };
 726 }
 727
 728 # a fast way to read files (avoid fuse overhead)
 729 sub get_config {
 730     my ($path) = @_;
 731
 732     return &$ipcc_get_config($path);
 733 }
 734
 735 sub get_cluster_log {
 736     my ($user, $max) = @_;
 737
 738     return &$ipcc_get_cluster_log($user, $max);
 739 }
 740
 741 my $file_info = {};
 742
 743 sub cfs_register_file {
 744     my ($filename, $parser, $writer) = @_;
 745
 746     $observed->{$filename} || die "unknown file '$filename'";
 747
 748     die "file '$filename' already registered" if $file_info->{$filename};
 749
 750     $file_info->{$filename} = {
 751         parser => $parser,
 752         writer => $writer,
 753     };
 754 }
 755
 756 my $ccache_read = sub {
 757     my ($filename, $parser, $version) = @_;
 758
 759     $ccache->{$filename} = {} if !$ccache->{$filename};
 760
 761     my $ci = $ccache->{$filename};
 762
 763     if (!$ci->{version} || !$version || $ci->{version} != $version) {
 764         # we always call the parser, even when the file does not exists
 765         # (in that case $data is undef)
 766         my $data = get_config($filename);
 767         $ci->{data} = &$parser("/etc/pve/$filename", $data);
 768         $ci->{version} = $version;
 769     }
 770
 771     my $res = ref($ci->{data}) ? dclone($ci->{data}) : $ci->{data};
 772
 773     return $res;
 774 };
 775
 776 sub cfs_file_version {
 777     my ($filename) = @_;
 778
 779     my $version;
 780     my $infotag;
 781     if ($filename =~ m!^nodes/[^/]+/(openvz|qemu-server)/(\d+)\.conf$!) {
 782         my ($type, $vmid) = ($1, $2);
 783         if ($vmlist && $vmlist->{ids} && $vmlist->{ids}->{$vmid}) {
 784             $version = $vmlist->{ids}->{$vmid}->{version};
 785         }
 786         $infotag = "/$type/";
 787     } else {
 788         $infotag = $filename;
 789         $version = $versions->{$filename};
 790     }
 791
 792     my $info = $file_info->{$infotag} ||
 793         die "unknown file type '$filename'\n";
 794
 795     return wantarray ? ($version, $info) : $version;
 796 }
 797
 798 sub cfs_read_file {
 799     my ($filename) = @_;
 800
 801     my ($version, $info) = cfs_file_version($filename);
 802     my $parser = $info->{parser};
 803
 804     return &$ccache_read($filename, $parser, $version);
 805 }
 806
 807 sub cfs_write_file {
 808     my ($filename, $data) = @_;
 809
 810     my ($version, $info) = cfs_file_version($filename);
 811
 812     my $writer = $info->{writer} || die "no writer defined";
 813
 814     my $fsname = "/etc/pve/$filename";
 815
 816     my $raw = &$writer($fsname, $data);
 817
 818     if (my $ci = $ccache->{$filename}) {
 819         $ci->{version} = undef;
 820     }
 821
 822     PVE::Tools::file_set_contents($fsname, $raw);
 823 }
 824
 825 my $cfs_lock = sub {
 826     my ($lockid, $timeout, $code, @param) = @_;
 827
 828     my $res;
 829
 830     # this timeout is for aquire the lock
 831     $timeout = 10 if !$timeout;
 832
 833     my $filename = "$lockdir/$lockid";
 834
 835     my $msg = "can't aquire cfs lock '$lockid'";
 836
 837     eval {
 838
 839         mkdir $lockdir;
 840
 841         if (! -d $lockdir) {
 842             die "$msg: pve cluster filesystem not online.\n";
 843         }
 844
 845         local $SIG{ALRM} = sub { die "got lock request timeout\n"; };
 846
 847         alarm ($timeout);
 848
 849         if (!(mkdir $filename)) {
 850             print STDERR "trying to aquire cfs lock '$lockid' ...";
 851             while (1) {
 852                 if (!(mkdir $filename)) {
 853                     (utime 0, 0, $filename); # cfs unlock request
 854                 } else {
 855                     print STDERR " OK\n";
 856                     last;
 857                 }
 858                 sleep(1);
 859             }
 860         }
 861
 862         # fixed command timeout: cfs locks have a timeout of 120
 863         # using 60 gives us another 60 seconds to abort the task
 864         alarm(60);
 865         local $SIG{ALRM} = sub { die "got lock timeout - aborting command\n"; };
 866
 867         $res = &$code(@param);
 868
 869         alarm(0);
 870     };
 871
 872     my $err = $@;
 873
 874     alarm(0);
 875
 876     if ($err && ($err eq "got lock request timeout\n") &&
 877         !check_cfs_quorum()){
 878         $err = "$msg: no quorum!\n";
 879     }
 880
 881     if (!$err || $err !~ /^got lock timeout -/) {
 882         rmdir $filename; # cfs unlock
 883     }
 884
 885     if ($err) {
 886         $@ = $err;
 887         return undef;
 888     }
 889
 890     $@ = undef;
 891
 892     return $res;
 893 };
 894
 895 sub cfs_lock_file {
 896     my ($filename, $timeout, $code, @param) = @_;
 897
 898     my $info = $observed->{$filename} || die "unknown file '$filename'";
 899
 900     my $lockid = "file-$filename";
 901     $lockid =~ s/[.\/]/_/g;
 902
 903     &$cfs_lock($lockid, $timeout, $code, @param);
 904 }
 905
 906 sub cfs_lock_storage {
 907     my ($storeid, $timeout, $code, @param) = @_;
 908
 909     my $lockid = "storage-$storeid";
 910
 911     &$cfs_lock($lockid, $timeout, $code, @param);
 912 }
 913
 914 my $log_levels = {
 915     "emerg" => 0,
 916     "alert" => 1,
 917     "crit" => 2,
 918     "critical" => 2,
 919     "err" => 3,
 920     "error" => 3,
 921     "warn" => 4,
 922     "warning" => 4,
 923     "notice" => 5,
 924     "info" => 6,
 925     "debug" => 7,
 926 };
 927
 928 sub log_msg {
 929    my ($priority, $ident, $msg) = @_;
 930
 931    if (my $tmp = $log_levels->{$priority}) {
 932        $priority = $tmp;
 933    }
 934
 935    die "need numeric log priority" if $priority !~ /^\d+$/;
 936
 937    my $tag = PVE::SafeSyslog::tag();
 938
 939    $msg = "empty message" if !$msg;
 940
 941    $ident = "" if !$ident;
 942    $ident = encode("ascii", decode_utf8($ident),
 943                    sub { sprintf "\\u%04x", shift });
 944
 945    my $utf8 = decode_utf8($msg);
 946
 947    my $ascii = encode("ascii", $utf8, sub { sprintf "\\u%04x", shift });
 948
 949    if ($ident) {
 950        syslog($priority, "<%s> %s", $ident, $ascii);
 951    } else {
 952        syslog($priority, "%s", $ascii);
 953    }
 954
 955    eval { &$ipcc_log($priority, $ident, $tag, $ascii); };
 956
 957    syslog("err", "writing cluster log failed: $@") if $@;
 958 }
 959
 960 sub check_node_exists {
 961     my ($nodename, $noerr) = @_;
 962
 963     my $nodelist = $clinfo->{nodelist};
 964     return 1 if $nodelist && $nodelist->{$nodename};
 965
 966     return undef if $noerr;
 967
 968     die "no such cluster node '$nodename'\n";
 969 }
 970
 971 # this is also used to get the IP of the local node
 972 sub remote_node_ip {
 973     my ($nodename, $noerr) = @_;
 974
 975     my $nodelist = $clinfo->{nodelist};
 976     if ($nodelist && $nodelist->{$nodename}) {
 977         if (my $ip = $nodelist->{$nodename}->{ip}) {
 978             return $ip;
 979         }
 980     }
 981
 982     # fallback: try to get IP by other means
 983     my $packed_ip = gethostbyname($nodename);
 984     if (defined $packed_ip) {
 985         my $ip = inet_ntoa($packed_ip);
 986
 987         if ($ip =~ m/^127\./) {
 988             die "hostname lookup failed - got local IP address ($nodename = $ip)\n" if !$noerr;
 989             return undef;
 990         }
 991
 992         return $ip;
 993     }
 994
 995     die "unable to get IP for node '$nodename' - node offline?\n" if !$noerr;
 996
 997     return undef;
 998 }
 999
1000 # ssh related utility functions
1001
1002 sub ssh_merge_keys {
1003     # remove duplicate keys in $sshauthkeys
1004     # ssh-copy-id simply add keys, so the file can grow to large
1005
1006     my $data = '';
1007     if (-f $sshauthkeys) {
1008         $data = PVE::Tools::file_get_contents($sshauthkeys, 128*1024);
1009         chomp($data);
1010     }
1011
1012     # always add ourself
1013     if (-f $ssh_rsa_id) {
1014         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
1015         chomp($pub);
1016         $data .= "\n$pub\n";
1017     }
1018
1019     my $newdata = "";
1020     my $vhash = {};
1021     my @lines = split(/\n/, $data);
1022     foreach my $line (@lines) {
1023         if ($line =~ m/^ssh-rsa\s+(\S+)\s+\S+$/) {
1024             next if $vhash->{$1};
1025             $vhash->{$1} = 1;
1026         }
1027         $newdata .= "$line\n";
1028     }
1029
1030     PVE::Tools::file_set_contents($sshauthkeys, $newdata, 0600);
1031 }
1032
1033 sub setup_ssh_keys {
1034
1035     # create ssh key if it does not exist
1036     if (! -f $ssh_rsa_id) {
1037         mkdir '/root/.ssh/';
1038         system ("echo|ssh-keygen -t rsa -N '' -b 2048 -f ${ssh_rsa_id_priv}");
1039     }
1040
1041     mkdir $authdir;
1042
1043     if (! -f $sshauthkeys) {
1044         if (my $fh = IO::File->new ($sshauthkeys, O_CREAT|O_WRONLY|O_EXCL, 0400)) {
1045             close($fh);
1046         }
1047     }
1048
1049     warn "can't create shared ssh key database '$sshauthkeys'\n"
1050         if ! -f $sshauthkeys;
1051
1052     if (-f $rootsshauthkeys) {
1053         system("mv '$rootsshauthkeys' '$rootsshauthkeys.org'");
1054     }
1055
1056     if (! -l $rootsshauthkeys) {
1057         symlink $sshauthkeys, $rootsshauthkeys;
1058     }
1059     warn "can't create symlink for ssh keys '$rootsshauthkeys' -> '$sshauthkeys'\n"
1060         if ! -l $rootsshauthkeys;
1061
1062 }
1063
1064 sub ssh_unmerge_known_hosts {
1065     return if ! -l $sshglobalknownhosts;
1066
1067     my $old = '';
1068     $old = PVE::Tools::file_get_contents($sshknownhosts, 128*1024)
1069         if -f $sshknownhosts;
1070
1071     PVE::Tools::file_set_contents($sshglobalknownhosts, $old);
1072 }
1073
1074 sub ssh_merge_known_hosts {
1075     my ($nodename, $ip_address, $createLink) = @_;
1076
1077     die "no node name specified" if !$nodename;
1078     die "no ip address specified" if !$ip_address;
1079
1080     mkdir $authdir;
1081
1082     if (! -f $sshknownhosts) {
1083         if (my $fh = IO::File->new($sshknownhosts, O_CREAT|O_WRONLY|O_EXCL, 0600)) {
1084             close($fh);
1085         }
1086     }
1087
1088     my $old = PVE::Tools::file_get_contents($sshknownhosts, 128*1024);
1089
1090     my $new = '';
1091
1092     if ((! -l $sshglobalknownhosts) && (-f $sshglobalknownhosts)) {
1093         $new = PVE::Tools::file_get_contents($sshglobalknownhosts, 128*1024);
1094     }
1095
1096     my $hostkey = PVE::Tools::file_get_contents($ssh_host_rsa_id);
1097     die "can't parse $ssh_rsa_id" if $hostkey !~ m/^(ssh-rsa\s\S+)(\s.*)?$/;
1098     $hostkey = $1;
1099
1100     my $data = '';
1101     my $vhash = {};
1102
1103     my $found_nodename;
1104     my $found_local_ip;
1105
1106     my $merge_line = sub {
1107         my ($line, $all) = @_;
1108
1109         if ($line =~ m/^(\S+)\s(ssh-rsa\s\S+)(\s.*)?$/) {
1110             my $key = $1;
1111             my $rsakey = $2;
1112             if (!$vhash->{$key}) {
1113                 $vhash->{$key} = 1;
1114                 if ($key =~ m/\|1\|([^\|\s]+)\|([^\|\s]+)$/) {
1115                     my $salt = decode_base64($1);
1116                     my $digest = $2;
1117                     my $hmac = Digest::HMAC_SHA1->new($salt);
1118                     $hmac->add($nodename);
1119                     my $hd = $hmac->b64digest . '=';
1120                     if ($digest eq $hd) {
1121                         if ($rsakey eq $hostkey) {
1122                             $found_nodename = 1;
1123                             $data .= $line;
1124                         }
1125                         return;
1126                     }
1127                     $hmac = Digest::HMAC_SHA1->new($salt);
1128                     $hmac->add($ip_address);
1129                     $hd = $hmac->b64digest . '=';
1130                     if ($digest eq $hd) {
1131                         if ($rsakey eq $hostkey) {
1132                             $found_local_ip = 1;
1133                             $data .= $line;
1134                         }
1135                         return;
1136                     }
1137                 }
1138                 $data .= $line;
1139             }
1140         } elsif ($all) {
1141             $data .= $line;
1142         }
1143     };
1144
1145     while ($old && $old =~ s/^((.*?)(\n|$))//) {
1146         my $line = "$2\n";
1147         next if $line =~ m/^\s*$/; # skip empty lines
1148         next if $line =~ m/^#/; # skip comments
1149         &$merge_line($line, 1);
1150     }
1151
1152     while ($new && $new =~ s/^((.*?)(\n|$))//) {
1153         my $line = "$2\n";
1154         next if $line =~ m/^\s*$/; # skip empty lines
1155         next if $line =~ m/^#/; # skip comments
1156         &$merge_line($line);
1157     }
1158
1159     my $addIndex = $$;
1160     my $add_known_hosts_entry  = sub {
1161         my ($name, $hostkey) = @_;
1162         $addIndex++;
1163         my $hmac = Digest::HMAC_SHA1->new("$addIndex" . time());
1164         my $b64salt = $hmac->b64digest . '=';
1165         $hmac = Digest::HMAC_SHA1->new(decode_base64($b64salt));
1166         $hmac->add($name);
1167         my $digest = $hmac->b64digest . '=';
1168         $data .= "|1|$b64salt|$digest $hostkey\n";
1169     };
1170
1171     if (!$found_nodename || !$found_local_ip) {
1172         &$add_known_hosts_entry($nodename, $hostkey) if !$found_nodename;
1173         &$add_known_hosts_entry($ip_address, $hostkey) if !$found_local_ip;
1174     }
1175
1176     PVE::Tools::file_set_contents($sshknownhosts, $data);
1177
1178     return if !$createLink;
1179
1180     unlink $sshglobalknownhosts;
1181     symlink $sshknownhosts, $sshglobalknownhosts;
1182
1183     warn "can't create symlink for ssh known hosts '$sshglobalknownhosts' -> '$sshknownhosts'\n"
1184         if ! -l $sshglobalknownhosts;
1185
1186 }
1187
1188 my $datacenter_schema = {
1189     type => "object",
1190     additionalProperties => 0,
1191     properties => {
1192         keyboard => {
1193             optional => 1,
1194             type => 'string',
1195             description => "Default keybord layout for vnc server.",
1196             enum => PVE::Tools::kvmkeymaplist(),
1197         },
1198         language => {
1199             optional => 1,
1200             type => 'string',
1201             description => "Default GUI language.",
1202             enum => [ 'en', 'de' ],
1203         },
1204         http_proxy => {
1205             optional => 1,
1206             type => 'string',
1207             description => "Specify external http proxy which is used for downloads (example: 'http://username:password\@host:port/')",
1208             pattern => "http://.*",
1209         },
1210     },
1211 };
1212
1213 # make schema accessible from outside (for documentation)
1214 sub get_datacenter_schema { return $datacenter_schema };
1215
1216 sub parse_datacenter_config {
1217     my ($filename, $raw) = @_;
1218
1219     return PVE::JSONSchema::parse_config($datacenter_schema, $filename, $raw);
1220 }
1221
1222 sub write_datacenter_config {
1223     my ($filename, $cfg) = @_;
1224
1225     return PVE::JSONSchema::dump_config($datacenter_schema, $filename, $cfg);
1226 }
1227
1228 cfs_register_file('datacenter.cfg',
1229                   \&parse_datacenter_config,
1230                   \&write_datacenter_config);
1231
1232 sub parse_cluster_conf {
1233     my ($filename, $raw) = @_;
1234
1235     my $conf = {};
1236
1237     my $digest = Digest::SHA::sha1_hex(defined($raw) ? $raw : '');
1238
1239     my $createNode = sub {
1240         my ($expat, $tag, %attrib) = @_;
1241         $expat->{NodeCount}++;
1242         return { text => $tag, id => $expat->{NodeCount}, %attrib };
1243     };
1244
1245     my $handlers = {
1246         Init => sub {
1247             my $expat = shift;
1248             $expat->{NodeCount} = 0;
1249             $expat->{NodeStack} = [];
1250             $expat->{CurNode} = $expat->{Tree} = &$createNode($expat, 'root');
1251         },
1252         Final => sub {
1253             my $expat = shift;
1254             delete $expat->{CurNode};
1255             delete $expat->{NodeStack};
1256             $expat->{Tree};
1257         },
1258         Start => sub {
1259             my $expat = shift;
1260             my $tag = shift;
1261             my $parent = $expat->{CurNode};
1262             push @{ $expat->{NodeStack} }, $parent;
1263             my $node = &$createNode($expat, $tag, @_);
1264             push @{$expat->{CurNode}->{children}}, $node;
1265             $expat->{CurNode} = $node;
1266         },
1267         End => sub {
1268             my $expat = shift;
1269             my $tag = shift;
1270             my $node = pop @{ $expat->{NodeStack} };
1271             $expat->{CurNode} = $node;
1272         },
1273     };
1274
1275     if ($raw) {
1276         my $parser = new XML::Parser(Handlers => $handlers);
1277         $conf = $parser->parse($raw);
1278     }
1279
1280     $conf->{digest} = $digest;
1281
1282     return $conf;
1283 }
1284
1285 sub cluster_conf_version {
1286     my ($conf, $noerr) = @_;
1287
1288     if ($conf && $conf->{children} && $conf->{children}->[0]) {
1289         my $cluster = $conf->{children}->[0];
1290         if ($cluster && ($cluster->{text} eq 'cluster') &&
1291             $cluster->{config_version}) {
1292             if (my $version = int($cluster->{config_version})) {
1293                 return wantarray ? ($version, $cluster) : $version;
1294             }
1295         }
1296     }
1297
1298     return undef if $noerr;
1299
1300     die "no cluster config - unable to read version\n";
1301 }
1302
1303 sub cluster_conf_lookup_cluster_section {
1304     my ($conf, $noerr) = @_;
1305
1306     my ($version, $cluster) = cluster_conf_version($conf, $noerr);
1307
1308     return $cluster;
1309 }
1310
1311 sub cluster_conf_lookup_rm_section {
1312     my ($conf, $create, $noerr) = @_;
1313
1314     my $cluster = cluster_conf_lookup_cluster_section($conf, $noerr);
1315     return undef if !$cluster;
1316
1317     my $rmsec;
1318     foreach my $child (@{$cluster->{children}}) {
1319         if ($child->{text} eq 'rm') {
1320             $rmsec = $child;
1321         }
1322     }
1323     if (!$rmsec) {
1324         if (!$create) {
1325             return undef if $noerr;
1326             die "no resource manager section\n";
1327         }
1328         $rmsec = { text => 'rm' };
1329         push @{$cluster->{children}}, $rmsec;
1330     }
1331
1332     return $rmsec;
1333 }
1334
1335 sub cluster_conf_lookup_pvevm {
1336     my ($conf, $create, $vmid, $noerr) = @_;
1337
1338     my $rmsec = cluster_conf_lookup_rm_section($conf, $create, $noerr);
1339     return undef if !$rmsec;
1340
1341     my $vmref;
1342     foreach my $child (@{$rmsec->{children}}) {
1343         if ($child->{text} eq 'pvevm' && $child->{vmid} eq $vmid) {
1344             $vmref = $child;
1345         }
1346     }
1347
1348     if (!$vmref) {
1349         if (!$create) {
1350             return undef if $noerr;
1351             die "unable to find service 'pvevm:$vmid'\n";
1352         }
1353         $vmref = { text => 'pvevm', vmid => $vmid };
1354         push @{$rmsec->{children}}, $vmref;
1355     } elsif ($create) {
1356         return undef if $noerr;
1357         die "unable to create service 'pvevm:$vmid' - already exists\n";
1358     }
1359
1360     return $vmref;
1361 }
1362
1363 sub xml_escape_attrib {
1364     my ($data) = @_;
1365
1366     return '' if !defined($data);
1367
1368     $data =~ s/&/&amp;/sg;
1369     $data =~ s/</&lt;/sg;
1370     $data =~ s/>/&gt;/sg;
1371     $data =~ s/"/&quot;/sg;
1372
1373     return $data;
1374 }
1375
1376 sub __cluster_conf_dump_node {
1377     my ($node, $indend) = @_;
1378
1379     my $xml = '';
1380
1381     $indend = '' if !defined($indend);
1382
1383     my $attribs = '';
1384
1385     foreach my $key (sort keys %$node) {
1386         my $value = $node->{$key};
1387         next if $key eq 'id' || $key eq 'text' || $key eq 'children';
1388         $attribs .= " $key=\"" .  xml_escape_attrib($value) . "\"";
1389     }
1390
1391     my $children = $node->{children};
1392
1393     if ($children && scalar(@$children)) {
1394         $xml .= "$indend<$node->{text}$attribs>\n";
1395         my $childindend = "$indend  ";
1396         foreach my $child (@$children) {
1397             $xml .= __cluster_conf_dump_node($child, $childindend);
1398         }
1399         $xml .= "$indend</$node->{text}>\n";
1400     } else {
1401         $xml .= "$indend<$node->{text}$attribs/>\n";
1402     }
1403
1404     return $xml;
1405 }
1406
1407 sub write_cluster_conf {
1408     my ($filename, $cfg) = @_;
1409
1410     my $version = cluster_conf_version($cfg);
1411
1412     my $res = "<?xml version=\"1.0\"?>\n";
1413
1414     $res .= __cluster_conf_dump_node($cfg->{children}->[0]);
1415
1416     return $res;
1417 }
1418
1419 # read only - use "rename cluster.conf.new cluster.conf" to write
1420 PVE::Cluster::cfs_register_file('cluster.conf', \&parse_cluster_conf);
1421 # this is read/write
1422 PVE::Cluster::cfs_register_file('cluster.conf.new', \&parse_cluster_conf,
1423                                 \&write_cluster_conf);