data/PVE/Cluster.pm

   1 package PVE::Cluster;
   2
   3 use strict;
   4 use POSIX;
   5 use File::stat qw();
   6 use Socket;
   7 use Storable qw(dclone);
   8 use IO::File;
   9 use MIME::Base64;
  10 use XML::Parser;
  11 use Digest::SHA;
  12 use Digest::HMAC_SHA1;
  13 use PVE::Tools;
  14 use PVE::INotify;
  15 use PVE::IPCC;
  16 use PVE::SafeSyslog;
  17 use PVE::JSONSchema;
  18 use JSON;
  19 use RRDs;
  20 use Encode;
  21 use base 'Exporter';
  22
  23 our @EXPORT_OK = qw(
  24 cfs_read_file
  25 cfs_write_file
  26 cfs_register_file
  27 cfs_lock_file);
  28
  29 use Data::Dumper; # fixme: remove
  30
  31 # x509 certificate utils
  32
  33 my $basedir = "/etc/pve";
  34 my $authdir = "$basedir/priv";
  35 my $lockdir = "/etc/pve/priv/lock";
  36
  37 my $authprivkeyfn = "$authdir/authkey.key";
  38 my $authpubkeyfn = "$basedir/authkey.pub";
  39 my $pveca_key_fn = "$authdir/pve-root-ca.key";
  40 my $pveca_srl_fn = "$authdir/pve-root-ca.srl";
  41 my $pveca_cert_fn = "$basedir/pve-root-ca.pem";
  42 # this is just a secret accessable by the web browser
  43 # and is used for CSRF prevention
  44 my $pvewww_key_fn = "$basedir/pve-www.key";
  45
  46 # ssh related files
  47 my $ssh_rsa_id_priv = "/root/.ssh/id_rsa";
  48 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
  49 my $ssh_host_rsa_id = "/etc/ssh/ssh_host_rsa_key.pub";
  50 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts";
  51 my $sshknownhosts = "/etc/pve/priv/known_hosts";
  52 my $sshauthkeys = "/etc/pve/priv/authorized_keys";
  53 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
  54
  55 my $observed = {
  56     'vzdump.cron' => 1,
  57     'storage.cfg' => 1,
  58     'datacenter.cfg' => 1,
  59     'cluster.conf' => 1,
  60     'cluster.conf.new' => 1,
  61     'user.cfg' => 1,
  62     'domains.cfg' => 1,
  63     'priv/shadow.cfg' => 1,
  64     '/qemu-server/' => 1,
  65     '/openvz/' => 1,
  66 };
  67
  68 # only write output if something fails
  69 sub run_silent_cmd {
  70     my ($cmd) = @_;
  71
  72     my $outbuf = '';
  73
  74     my $record_output = sub {
  75         $outbuf .= shift;
  76         $outbuf .= "\n";
  77     };
  78
  79     eval {
  80         PVE::Tools::run_command($cmd, outfunc => $record_output,
  81                                 errfunc => $record_output);
  82     };
  83
  84     my $err = $@;
  85
  86     if ($err) {
  87         print STDERR $outbuf;
  88         die $err;
  89     }
  90 }
  91
  92 sub check_cfs_quorum {
  93     my ($noerr) = @_;
  94
  95     # note: -w filename always return 1 for root, so wee need
  96     # to use File::lstat here
  97     my $st = File::stat::lstat("$basedir/local");
  98     my $quorate = ($st && (($st->mode & 0200) != 0));
  99
 100     die "cluster not ready - no quorum?\n" if !$quorate && !$noerr;
 101
 102     return $quorate;
 103 }
 104
 105 sub check_cfs_is_mounted {
 106     my ($noerr) = @_;
 107
 108     my $res = -l "$basedir/local";
 109
 110     die "pve configuration filesystem not mounted\n"
 111         if !$res && !$noerr;
 112
 113     return $res;
 114 }
 115
 116 sub gen_local_dirs {
 117     my ($nodename) = @_;
 118
 119     check_cfs_is_mounted();
 120
 121     my @required_dirs = (
 122         "$basedir/priv",
 123         "$basedir/nodes",
 124         "$basedir/nodes/$nodename",
 125         "$basedir/nodes/$nodename/qemu-server",
 126         "$basedir/nodes/$nodename/openvz",
 127         "$basedir/nodes/$nodename/priv");
 128
 129     foreach my $dir (@required_dirs) {
 130         if (! -d $dir) {
 131             mkdir($dir) || die "unable to create directory '$dir' - $!\n";
 132         }
 133     }
 134 }
 135
 136 sub gen_auth_key {
 137
 138     return if -f "$authprivkeyfn";
 139
 140     check_cfs_is_mounted();
 141
 142     mkdir $authdir || die "unable to create dir '$authdir' - $!\n";
 143
 144     my $cmd = "openssl genrsa -out '$authprivkeyfn' 2048";
 145     run_silent_cmd($cmd);
 146
 147     $cmd = "openssl rsa -in '$authprivkeyfn' -pubout -out '$authpubkeyfn'";
 148     run_silent_cmd($cmd)
 149 }
 150
 151 sub gen_pveca_key {
 152
 153     return if -f $pveca_key_fn;
 154
 155     eval {
 156         run_silent_cmd(['openssl', 'genrsa', '-out', $pveca_key_fn, '2048']);
 157     };
 158
 159     die "unable to generate pve ca key:\n$@" if $@;
 160 }
 161
 162 sub gen_pveca_cert {
 163
 164     if (-f $pveca_key_fn && -f $pveca_cert_fn) {
 165         return 0;
 166     }
 167
 168     gen_pveca_key();
 169
 170     # we try to generate an unique 'subject' to avoid browser problems
 171     # (reused serial numbers, ..)
 172     my $nid = (split (/\s/, `md5sum '$pveca_key_fn'`))[0] || time();
 173
 174     eval {
 175         run_silent_cmd(['openssl', 'req', '-batch', '-days', '3650', '-new',
 176                         '-x509', '-nodes', '-key',
 177                         $pveca_key_fn, '-out', $pveca_cert_fn, '-subj',
 178                         "/CN=Proxmox Virtual Environment/OU=$nid/O=PVE Cluster Manager CA/"]);
 179     };
 180
 181     die "generating pve root certificate failed:\n$@" if $@;
 182
 183     return 1;
 184 }
 185
 186 sub gen_pve_ssl_key {
 187     my ($nodename) = @_;
 188
 189     die "no node name specified" if !$nodename;
 190
 191     my $pvessl_key_fn = "$basedir/nodes/$nodename/pve-ssl.key";
 192
 193     return if -f $pvessl_key_fn;
 194
 195     eval {
 196         run_silent_cmd(['openssl', 'genrsa', '-out', $pvessl_key_fn, '2048']);
 197     };
 198
 199     die "unable to generate pve ssl key for node '$nodename':\n$@" if $@;
 200 }
 201
 202 sub gen_pve_www_key {
 203
 204     return if -f $pvewww_key_fn;
 205
 206     eval {
 207         run_silent_cmd(['openssl', 'genrsa', '-out', $pvewww_key_fn, '2048']);
 208     };
 209
 210     die "unable to generate pve www key:\n$@" if $@;
 211 }
 212
 213 sub update_serial {
 214     my ($serial) = @_;
 215
 216     PVE::Tools::file_set_contents($pveca_srl_fn, $serial);
 217 }
 218
 219 sub gen_pve_ssl_cert {
 220     my ($force, $nodename, $ip) = @_;
 221
 222     die "no node name specified" if !$nodename;
 223     die "no IP specified" if !$ip;
 224
 225     my $pvessl_cert_fn = "$basedir/nodes/$nodename/pve-ssl.pem";
 226
 227     return if !$force && -f $pvessl_cert_fn;
 228
 229     my $names = "IP:127.0.0.1,DNS:localhost";
 230
 231     my $rc = PVE::INotify::read_file('resolvconf');
 232
 233     $names .= ",IP:$ip";
 234
 235     my $fqdn = $nodename;
 236
 237     $names .= ",DNS:$nodename";
 238
 239     if ($rc && $rc->{search}) {
 240         $fqdn = $nodename . "." . $rc->{search};
 241         $names .= ",DNS:$fqdn";
 242     }
 243
 244     my $sslconf = <<__EOD;
 245 RANDFILE = /root/.rnd
 246 extensions = v3_req
 247
 248 [ req ]
 249 default_bits = 2048
 250 distinguished_name = req_distinguished_name
 251 req_extensions = v3_req
 252 prompt = no
 253 string_mask = nombstr
 254
 255 [ req_distinguished_name ]
 256 organizationalUnitName = PVE Cluster Node
 257 organizationName = Proxmox Virtual Environment
 258 commonName = $fqdn
 259
 260 [ v3_req ]
 261 basicConstraints = CA:FALSE
 262 nsCertType = server
 263 keyUsage = nonRepudiation, digitalSignature, keyEncipherment
 264 subjectAltName = $names
 265 __EOD
 266
 267     my $cfgfn = "/tmp/pvesslconf-$$.tmp";
 268     my $fh = IO::File->new ($cfgfn, "w");
 269     print $fh $sslconf;
 270     close ($fh);
 271
 272     my $reqfn = "/tmp/pvecertreq-$$.tmp";
 273     unlink $reqfn;
 274
 275     my $pvessl_key_fn = "$basedir/nodes/$nodename/pve-ssl.key";
 276     eval {
 277         run_silent_cmd(['openssl', 'req', '-batch', '-new', '-config', $cfgfn,
 278                         '-key', $pvessl_key_fn, '-out', $reqfn]);
 279     };
 280
 281     if (my $err = $@) {
 282         unlink $reqfn;
 283         unlink $cfgfn;
 284         die "unable to generate pve certificate request:\n$err";
 285     }
 286
 287     update_serial("0000000000000000") if ! -f $pveca_srl_fn;
 288
 289     eval {
 290         run_silent_cmd(['openssl', 'x509', '-req', '-in', $reqfn, '-days', '3650',
 291                         '-out', $pvessl_cert_fn, '-CAkey', $pveca_key_fn,
 292                         '-CA', $pveca_cert_fn, '-CAserial', $pveca_srl_fn,
 293                         '-extfile', $cfgfn]);
 294     };
 295
 296     if (my $err = $@) {
 297         unlink $reqfn;
 298         unlink $cfgfn;
 299         die "unable to generate pve ssl certificate:\n$err";
 300     }
 301
 302     unlink $cfgfn;
 303     unlink $reqfn;
 304 }
 305
 306 sub gen_pve_node_files {
 307     my ($nodename, $ip, $opt_force) = @_;
 308
 309     gen_local_dirs($nodename);
 310
 311     gen_auth_key();
 312
 313     # make sure we have a (cluster wide) secret
 314     # for CSRFR prevention
 315     gen_pve_www_key();
 316
 317     # make sure we have a (per node) private key
 318     gen_pve_ssl_key($nodename);
 319
 320     # make sure we have a CA
 321     my $force = gen_pveca_cert();
 322
 323     $force = 1 if $opt_force;
 324
 325     gen_pve_ssl_cert($force, $nodename, $ip);
 326 }
 327
 328 my $vzdump_cron_dummy = <<__EOD;
 329 # cluster wide vzdump cron schedule
 330 # Atomatically generated file - do not edit
 331
 332 PATH="/usr/sbin:/usr/bin:/sbin:/bin"
 333
 334 __EOD
 335
 336 sub gen_pve_vzdump_symlink {
 337
 338     my $filename = "/etc/pve/vzdump.cron";
 339
 340     my $link_fn = "/etc/cron.d/vzdump";
 341
 342     if ((-f $filename) && (! -l $link_fn)) {
 343         rename($link_fn, "/root/etc_cron_vzdump.org"); # make backup if file exists
 344         symlink($filename, $link_fn);
 345     }
 346 }
 347
 348 sub gen_pve_vzdump_files {
 349
 350     my $filename = "/etc/pve/vzdump.cron";
 351
 352     PVE::Tools::file_set_contents($filename, $vzdump_cron_dummy)
 353         if ! -f $filename;
 354
 355     gen_pve_vzdump_symlink();
 356 };
 357
 358 my $versions = {};
 359 my $vmlist = {};
 360 my $clinfo = {};
 361
 362 my $ipcc_send_rec = sub {
 363     my ($msgid, $data) = @_;
 364
 365     my $res = PVE::IPCC::ipcc_send_rec($msgid, $data);
 366
 367     die "ipcc_send_rec failed: $!\n" if !defined($res) && ($! != 0);
 368
 369     return $res;
 370 };
 371
 372 my $ipcc_send_rec_json = sub {
 373     my ($msgid, $data) = @_;
 374
 375     my $res = PVE::IPCC::ipcc_send_rec($msgid, $data);
 376
 377     die "ipcc_send_rec failed: $!\n" if !defined($res) && ($! != 0);
 378
 379     return decode_json($res);
 380 };
 381
 382 my $ipcc_get_config = sub {
 383     my ($path) = @_;
 384
 385     my $bindata = pack "Z*", $path;
 386     my $res = PVE::IPCC::ipcc_send_rec(6, $bindata);
 387     if (!defined($res)) {
 388         return undef if ($! != 0);
 389         return '';
 390     }
 391
 392     return $res;
 393 };
 394
 395 my $ipcc_get_status = sub {
 396     my ($name, $nodename) = @_;
 397
 398     my $bindata = pack "Z[256]Z[256]", $name, ($nodename || "");
 399     return PVE::IPCC::ipcc_send_rec(5, $bindata);
 400 };
 401
 402 my $ipcc_update_status = sub {
 403     my ($name, $data) = @_;
 404
 405     my $raw = ref($data) ? encode_json($data) : $data;
 406     # update status
 407     my $bindata = pack "Z[256]Z*", $name, $raw;
 408
 409     return &$ipcc_send_rec(4, $bindata);
 410 };
 411
 412 my $ipcc_log = sub {
 413     my ($priority, $ident, $tag, $msg) = @_;
 414
 415     my $bindata = pack "CCCZ*Z*Z*", $priority, bytes::length($ident) + 1,
 416     bytes::length($tag) + 1, $ident, $tag, $msg;
 417
 418     return &$ipcc_send_rec(7, $bindata);
 419 };
 420
 421 my $ipcc_get_cluster_log = sub {
 422     my ($user, $max) = @_;
 423
 424     $max = 0 if !defined($max);
 425
 426     my $bindata = pack "VVVVZ*", $max, 0, 0, 0, ($user || "");
 427     return &$ipcc_send_rec(8, $bindata);
 428 };
 429
 430 my $ccache = {};
 431
 432 sub cfs_update {
 433     eval {
 434         my $res = &$ipcc_send_rec_json(1);
 435         #warn "GOT1: " . Dumper($res);
 436         die "no starttime\n" if !$res->{starttime};
 437
 438         if (!$res->{starttime} || !$versions->{starttime} ||
 439             $res->{starttime} != $versions->{starttime}) {
 440             #print "detected changed starttime\n";
 441             $vmlist = {};
 442             $clinfo = {};
 443             $ccache = {};
 444         }
 445
 446         $versions = $res;
 447     };
 448     my $err = $@;
 449     if ($err) {
 450         $versions = {};
 451         $vmlist = {};
 452         $clinfo = {};
 453         $ccache = {};
 454         warn $err;
 455     }
 456
 457     eval {
 458         if (!$clinfo->{version} || $clinfo->{version} != $versions->{clinfo}) {
 459             #warn "detected new clinfo\n";
 460             $clinfo = &$ipcc_send_rec_json(2);
 461         }
 462     };
 463     $err = $@;
 464     if ($err) {
 465         $clinfo = {};
 466         warn $err;
 467     }
 468
 469     eval {
 470         if (!$vmlist->{version} || $vmlist->{version} != $versions->{vmlist}) {
 471             #warn "detected new vmlist1\n";
 472             $vmlist = &$ipcc_send_rec_json(3);
 473         }
 474     };
 475     $err = $@;
 476     if ($err) {
 477         $vmlist = {};
 478         warn $err;
 479     }
 480 }
 481
 482 sub get_vmlist {
 483     return $vmlist;
 484 }
 485
 486 sub get_clinfo {
 487     return $clinfo;
 488 }
 489
 490 sub get_members {
 491     return $clinfo->{nodelist};
 492 }
 493
 494 sub get_nodelist {
 495
 496     my $nodelist = $clinfo->{nodelist};
 497
 498     my $result = [];
 499
 500     my $nodename = PVE::INotify::nodename();
 501
 502     if (!$nodelist || !$nodelist->{$nodename}) {
 503         return [ $nodename ];
 504     }
 505
 506     return [ keys %$nodelist ];
 507 }
 508
 509 sub broadcast_tasklist {
 510     my ($data) = @_;
 511
 512     eval {
 513         &$ipcc_update_status("tasklist", $data);
 514     };
 515
 516     warn $@ if $@;
 517 }
 518
 519 my $tasklistcache = {};
 520
 521 sub get_tasklist {
 522     my ($nodename) = @_;
 523
 524     my $kvstore = $versions->{kvstore} || {};
 525
 526     my $nodelist = get_nodelist();
 527
 528     my $res = [];
 529     foreach my $node (@$nodelist) {
 530         next if $nodename && ($nodename ne $node);
 531         eval {
 532             my $ver = $kvstore->{$node}->{tasklist} if $kvstore->{$node};
 533             my $cd = $tasklistcache->{$node};
 534             if (!$cd || !$ver || ($cd->{version} != $ver)) {
 535                 my $raw = &$ipcc_get_status("tasklist", $node) || '[]';
 536                 my $data = decode_json($raw);
 537                 push @$res, @$data;
 538                 $cd = $tasklistcache->{$node} = {
 539                     data => $data,
 540                     version => $ver,
 541                 };
 542             } elsif ($cd && $cd->{data}) {
 543                 push @$res, @{$cd->{data}};
 544             }
 545         };
 546         my $err = $@;
 547         syslog('err', $err) if $err;
 548     }
 549
 550     return $res;
 551 }
 552
 553 sub broadcast_rrd {
 554     my ($rrdid, $data) = @_;
 555
 556     eval {
 557         &$ipcc_update_status("rrd/$rrdid", $data);
 558     };
 559     my $err = $@;
 560
 561     warn $err if $err;
 562 }
 563
 564 my $last_rrd_dump = 0;
 565 my $last_rrd_data = "";
 566
 567 sub rrd_dump {
 568
 569     my $ctime = time();
 570
 571     my $diff = $ctime - $last_rrd_dump;
 572     if ($diff < 2) {
 573         return $last_rrd_data;
 574     }
 575
 576     my $raw;
 577     eval {
 578         $raw = &$ipcc_send_rec(10);
 579     };
 580     my $err = $@;
 581
 582     if ($err) {
 583         warn $err;
 584         return {};
 585     }
 586
 587     my $res = {};
 588
 589     while ($raw =~ s/^(.*)\n//) {
 590         my ($key, @ela) = split(/:/, $1);
 591         next if !$key;
 592         next if !(scalar(@ela) > 1);
 593         $res->{$key} = \@ela;
 594     }
 595
 596     $last_rrd_dump = $ctime;
 597     $last_rrd_data = $res;
 598
 599     return $res;
 600 }
 601
 602 sub create_rrd_data {
 603     my ($rrdname, $timeframe, $cf) = @_;
 604
 605     my $rrddir = "/var/lib/rrdcached/db";
 606
 607     my $rrd = "$rrddir/$rrdname";
 608
 609     my $setup = {
 610         hour =>  [ 60, 70 ],
 611         day  =>  [ 60*30, 70 ],
 612         week =>  [ 60*180, 70 ],
 613         month => [ 60*720, 70 ],
 614         year =>  [ 60*10080, 70 ],
 615     };
 616
 617     my ($reso, $count) = @{$setup->{$timeframe}};
 618     my $ctime  = $reso*int(time()/$reso);
 619     my $req_start = $ctime - $reso*$count;
 620
 621     $cf = "AVERAGE" if !$cf;
 622
 623     my @args = (
 624         "-s" => $req_start,
 625         "-e" => $ctime - 1,
 626         "-r" => $reso,
 627         );
 628
 629     my $socket = "/var/run/rrdcached.sock";
 630     push @args, "--daemon" => "unix:$socket" if -S $socket;
 631
 632     my ($start, $step, $names, $data) = RRDs::fetch($rrd, $cf, @args);
 633
 634     my $err = RRDs::error;
 635     die "RRD error: $err\n" if $err;
 636
 637     die "got wrong time resolution ($step != $reso)\n"
 638         if $step != $reso;
 639
 640     my $res = [];
 641     my $fields = scalar(@$names);
 642     for my $line (@$data) {
 643         my $entry = { 'time' => $start };
 644         $start += $step;
 645         my $found_undefs;
 646         for (my $i = 0; $i < $fields; $i++) {
 647             my $name = $names->[$i];
 648             if (defined(my $val = $line->[$i])) {
 649                 $entry->{$name} = $val;
 650             } else {
 651                 # we only add entryies with all data defined
 652                 # extjs chart has problems with undefined values
 653                 $found_undefs = 1;
 654             }
 655         }
 656         push @$res, $entry if !$found_undefs;
 657     }
 658
 659     return $res;
 660 }
 661
 662 sub create_rrd_graph {
 663     my ($rrdname, $timeframe, $ds, $cf) = @_;
 664
 665     # Using RRD graph is clumsy - maybe it
 666     # is better to simply fetch the data, and do all display
 667     # related things with javascript (new extjs html5 graph library).
 668
 669     my $rrddir = "/var/lib/rrdcached/db";
 670
 671     my $rrd = "$rrddir/$rrdname";
 672
 673     my $filename = "$rrd.png";
 674
 675     my $setup = {
 676         hour =>  [ 60, 60 ],
 677         day  =>  [ 60*30, 70 ],
 678         week =>  [ 60*180, 70 ],
 679         month => [ 60*720, 70 ],
 680         year =>  [ 60*10080, 70 ],
 681     };
 682
 683     my ($reso, $count) = @{$setup->{$timeframe}};
 684
 685     my @args = (
 686         "--imgformat" => "PNG",
 687         "--border" => 0,
 688         "--height" => 200,
 689         "--width" => 800,
 690         "--start" => - $reso*$count,
 691         "--end" => 'now' ,
 692         );
 693
 694     my $socket = "/var/run/rrdcached.sock";
 695     push @args, "--daemon" => "unix:$socket" if -S $socket;
 696
 697     my @ids = PVE::Tools::split_list($ds);
 698
 699     my @coldef = ('#00ddff', '#ff0000');
 700
 701     $cf = "AVERAGE" if !$cf;
 702
 703     my $i = 0;
 704     foreach my $id (@ids) {
 705         my $col = $coldef[$i++] || die "fixme: no color definition";
 706         push @args, "DEF:${id}=$rrd:${id}:$cf";
 707         my $dataid = $id;
 708         if ($id eq 'cpu' || $id eq 'iowait') {
 709             push @args, "CDEF:${id}_per=${id},100,*";
 710             $dataid = "${id}_per";
 711         }
 712         push @args, "LINE2:${dataid}${col}:${id}";
 713     }
 714
 715     push @args, '--full-size-mode';
 716
 717     RRDs::graph($filename, @args);
 718
 719     my $err = RRDs::error;
 720     die "RRD error: $err\n" if $err;
 721
 722     return { filename => $filename };
 723 }
 724
 725 # a fast way to read files (avoid fuse overhead)
 726 sub get_config {
 727     my ($path) = @_;
 728
 729     return &$ipcc_get_config($path);
 730 }
 731
 732 sub get_cluster_log {
 733     my ($user, $max) = @_;
 734
 735     return &$ipcc_get_cluster_log($user, $max);
 736 }
 737
 738 my $file_info = {};
 739
 740 sub cfs_register_file {
 741     my ($filename, $parser, $writer) = @_;
 742
 743     $observed->{$filename} || die "unknown file '$filename'";
 744
 745     die "file '$filename' already registered" if $file_info->{$filename};
 746
 747     $file_info->{$filename} = {
 748         parser => $parser,
 749         writer => $writer,
 750     };
 751 }
 752
 753 my $ccache_read = sub {
 754     my ($filename, $parser, $version) = @_;
 755
 756     $ccache->{$filename} = {} if !$ccache->{$filename};
 757
 758     my $ci = $ccache->{$filename};
 759
 760     if (!$ci->{version} || !$version || $ci->{version} != $version) {
 761         # we always call the parser, even when the file does not exists
 762         # (in that case $data is undef)
 763         my $data = get_config($filename);
 764         $ci->{data} = &$parser("/etc/pve/$filename", $data);
 765         $ci->{version} = $version;
 766     }
 767
 768     my $res = ref($ci->{data}) ? dclone($ci->{data}) : $ci->{data};
 769
 770     return $res;
 771 };
 772
 773 sub cfs_file_version {
 774     my ($filename) = @_;
 775
 776     my $version;
 777     my $infotag;
 778     if ($filename =~ m!^nodes/[^/]+/(openvz|qemu-server)/(\d+)\.conf$!) {
 779         my ($type, $vmid) = ($1, $2);
 780         if ($vmlist && $vmlist->{ids} && $vmlist->{ids}->{$vmid}) {
 781             $version = $vmlist->{ids}->{$vmid}->{version};
 782         }
 783         $infotag = "/$type/";
 784     } else {
 785         $infotag = $filename;
 786         $version = $versions->{$filename};
 787     }
 788
 789     my $info = $file_info->{$infotag} ||
 790         die "unknown file type '$filename'\n";
 791
 792     return wantarray ? ($version, $info) : $version;
 793 }
 794
 795 sub cfs_read_file {
 796     my ($filename) = @_;
 797
 798     my ($version, $info) = cfs_file_version($filename);
 799     my $parser = $info->{parser};
 800
 801     return &$ccache_read($filename, $parser, $version);
 802 }
 803
 804 sub cfs_write_file {
 805     my ($filename, $data) = @_;
 806
 807     my ($version, $info) = cfs_file_version($filename);
 808
 809     my $writer = $info->{writer} || die "no writer defined";
 810
 811     my $fsname = "/etc/pve/$filename";
 812
 813     my $raw = &$writer($fsname, $data);
 814
 815     if (my $ci = $ccache->{$filename}) {
 816         $ci->{version} = undef;
 817     }
 818
 819     PVE::Tools::file_set_contents($fsname, $raw);
 820 }
 821
 822 my $cfs_lock = sub {
 823     my ($lockid, $timeout, $code, @param) = @_;
 824
 825     my $res;
 826
 827     # this timeout is for aquire the lock
 828     $timeout = 10 if !$timeout;
 829
 830     my $filename = "$lockdir/$lockid";
 831
 832     my $msg = "can't aquire cfs lock '$lockid'";
 833
 834     eval {
 835
 836         mkdir $lockdir;
 837
 838         if (! -d $lockdir) {
 839             die "$msg: pve cluster filesystem not online.\n";
 840         }
 841
 842         local $SIG{ALRM} = sub { die "got lock request timeout\n"; };
 843
 844         alarm ($timeout);
 845
 846         if (!(mkdir $filename)) {
 847             print STDERR "trying to aquire cfs lock '$lockid' ...";
 848             while (1) {
 849                 if (!(mkdir $filename)) {
 850                     (utime 0, 0, $filename); # cfs unlock request
 851                 } else {
 852                     print STDERR " OK\n";
 853                     last;
 854                 }
 855                 sleep(1);
 856             }
 857         }
 858
 859         # fixed command timeout: cfs locks have a timeout of 120
 860         # using 60 gives us another 60 seconds to abort the task
 861         alarm(60);
 862         local $SIG{ALRM} = sub { die "got lock timeout - aborting command\n"; };
 863
 864         $res = &$code(@param);
 865
 866         alarm(0);
 867     };
 868
 869     my $err = $@;
 870
 871     alarm(0);
 872
 873     if ($err && ($err eq "got lock request timeout\n") &&
 874         !check_cfs_quorum()){
 875         $err = "$msg: no quorum!\n";
 876     }
 877
 878     if (!$err || $err !~ /^got lock timeout -/) {
 879         rmdir $filename; # cfs unlock
 880     }
 881
 882     if ($err) {
 883         $@ = $err;
 884         return undef;
 885     }
 886
 887     $@ = undef;
 888
 889     return $res;
 890 };
 891
 892 sub cfs_lock_file {
 893     my ($filename, $timeout, $code, @param) = @_;
 894
 895     my $info = $observed->{$filename} || die "unknown file '$filename'";
 896
 897     my $lockid = "file-$filename";
 898     $lockid =~ s/[.\/]/_/g;
 899
 900     &$cfs_lock($lockid, $timeout, $code, @param);
 901 }
 902
 903 sub cfs_lock_storage {
 904     my ($storeid, $timeout, $code, @param) = @_;
 905
 906     my $lockid = "storage-$storeid";
 907
 908     &$cfs_lock($lockid, $timeout, $code, @param);
 909 }
 910
 911 my $log_levels = {
 912     "emerg" => 0,
 913     "alert" => 1,
 914     "crit" => 2,
 915     "critical" => 2,
 916     "err" => 3,
 917     "error" => 3,
 918     "warn" => 4,
 919     "warning" => 4,
 920     "notice" => 5,
 921     "info" => 6,
 922     "debug" => 7,
 923 };
 924
 925 sub log_msg {
 926    my ($priority, $ident, $msg) = @_;
 927
 928    if (my $tmp = $log_levels->{$priority}) {
 929        $priority = $tmp;
 930    }
 931
 932    die "need numeric log priority" if $priority !~ /^\d+$/;
 933
 934    my $tag = PVE::SafeSyslog::tag();
 935
 936    $msg = "empty message" if !$msg;
 937
 938    $ident = "" if !$ident;
 939    $ident = encode("ascii", decode_utf8($ident),
 940                    sub { sprintf "\\u%04x", shift });
 941
 942    my $utf8 = decode_utf8($msg);
 943
 944    my $ascii = encode("ascii", $utf8, sub { sprintf "\\u%04x", shift });
 945
 946    if ($ident) {
 947        syslog($priority, "<%s> %s", $ident, $ascii);
 948    } else {
 949        syslog($priority, "%s", $ascii);
 950    }
 951
 952    eval { &$ipcc_log($priority, $ident, $tag, $ascii); };
 953
 954    syslog("err", "writing cluster log failed: $@") if $@;
 955 }
 956
 957 sub check_node_exists {
 958     my ($nodename, $noerr) = @_;
 959
 960     my $nodelist = $clinfo->{nodelist};
 961     return 1 if $nodelist && $nodelist->{$nodename};
 962
 963     return undef if $noerr;
 964
 965     die "no such cluster node '$nodename'\n";
 966 }
 967
 968 # this is also used to get the IP of the local node
 969 sub remote_node_ip {
 970     my ($nodename, $noerr) = @_;
 971
 972     my $nodelist = $clinfo->{nodelist};
 973     if ($nodelist && $nodelist->{$nodename}) {
 974         if (my $ip = $nodelist->{$nodename}->{ip}) {
 975             return $ip;
 976         }
 977     }
 978
 979     # fallback: try to get IP by other means
 980     my $packed_ip = gethostbyname($nodename);
 981     if (defined $packed_ip) {
 982         my $ip = inet_ntoa($packed_ip);
 983
 984         if ($ip =~ m/^127\./) {
 985             die "hostname lookup failed - got local IP address ($nodename = $ip)\n" if !$noerr;
 986             return undef;
 987         }
 988
 989         return $ip;
 990     }
 991
 992     die "unable to get IP for node '$nodename' - node offline?\n" if !$noerr;
 993
 994     return undef;
 995 }
 996
 997 # ssh related utility functions
 998
 999 sub ssh_merge_keys {
1000     # remove duplicate keys in $sshauthkeys
1001     # ssh-copy-id simply add keys, so the file can grow to large
1002
1003     my $data = '';
1004     if (-f $sshauthkeys) {
1005         $data = PVE::Tools::file_get_contents($sshauthkeys, 128*1024);
1006         chomp($data);
1007     }
1008
1009     # always add ourself
1010     if (-f $ssh_rsa_id) {
1011         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
1012         chomp($pub);
1013         $data .= "\n$pub\n";
1014     }
1015
1016     my $newdata = "";
1017     my $vhash = {};
1018     my @lines = split(/\n/, $data);
1019     foreach my $line (@lines) {
1020         if ($line =~ m/^ssh-rsa\s+(\S+)\s+\S+$/) {
1021             next if $vhash->{$1};
1022             $vhash->{$1} = 1;
1023         }
1024         $newdata .= "$line\n";
1025     }
1026
1027     PVE::Tools::file_set_contents($sshauthkeys, $newdata, 0600);
1028 }
1029
1030 sub setup_ssh_keys {
1031
1032     # create ssh key if it does not exist
1033     if (! -f $ssh_rsa_id) {
1034         mkdir '/root/.ssh/';
1035         system ("echo|ssh-keygen -t rsa -N '' -b 2048 -f ${ssh_rsa_id_priv}");
1036     }
1037
1038     mkdir $authdir;
1039
1040     if (! -f $sshauthkeys) {
1041         if (my $fh = IO::File->new ($sshauthkeys, O_CREAT|O_WRONLY|O_EXCL, 0400)) {
1042             close($fh);
1043         }
1044     }
1045
1046     warn "can't create shared ssh key database '$sshauthkeys'\n"
1047         if ! -f $sshauthkeys;
1048
1049     if (-f $rootsshauthkeys) {
1050         system("mv '$rootsshauthkeys' '$rootsshauthkeys.org'");
1051     }
1052
1053     if (! -l $rootsshauthkeys) {
1054         symlink $sshauthkeys, $rootsshauthkeys;
1055     }
1056     warn "can't create symlink for ssh keys '$rootsshauthkeys' -> '$sshauthkeys'\n"
1057         if ! -l $rootsshauthkeys;
1058
1059 }
1060
1061 sub ssh_unmerge_known_hosts {
1062     return if ! -l $sshglobalknownhosts;
1063
1064     my $old = '';
1065     $old = PVE::Tools::file_get_contents($sshknownhosts, 128*1024)
1066         if -f $sshknownhosts;
1067
1068     PVE::Tools::file_set_contents($sshglobalknownhosts, $old);
1069 }
1070
1071 sub ssh_merge_known_hosts {
1072     my ($nodename, $ip_address, $createLink) = @_;
1073
1074     die "no node name specified" if !$nodename;
1075     die "no ip address specified" if !$ip_address;
1076
1077     mkdir $authdir;
1078
1079     if (! -f $sshknownhosts) {
1080         if (my $fh = IO::File->new($sshknownhosts, O_CREAT|O_WRONLY|O_EXCL, 0600)) {
1081             close($fh);
1082         }
1083     }
1084
1085     my $old = PVE::Tools::file_get_contents($sshknownhosts, 128*1024);
1086
1087     my $new = '';
1088
1089     if ((! -l $sshglobalknownhosts) && (-f $sshglobalknownhosts)) {
1090         $new = PVE::Tools::file_get_contents($sshglobalknownhosts, 128*1024);
1091     }
1092
1093     my $hostkey = PVE::Tools::file_get_contents($ssh_host_rsa_id);
1094     die "can't parse $ssh_rsa_id" if $hostkey !~ m/^(ssh-rsa\s\S+)(\s.*)?$/;
1095     $hostkey = $1;
1096
1097     my $data = '';
1098     my $vhash = {};
1099
1100     my $found_nodename;
1101     my $found_local_ip;
1102
1103     my $merge_line = sub {
1104         my ($line, $all) = @_;
1105
1106         if ($line =~ m/^(\S+)\s(ssh-rsa\s\S+)(\s.*)?$/) {
1107             my $key = $1;
1108             my $rsakey = $2;
1109             if (!$vhash->{$key}) {
1110                 $vhash->{$key} = 1;
1111                 if ($key =~ m/\|1\|([^\|\s]+)\|([^\|\s]+)$/) {
1112                     my $salt = decode_base64($1);
1113                     my $digest = $2;
1114                     my $hmac = Digest::HMAC_SHA1->new($salt);
1115                     $hmac->add($nodename);
1116                     my $hd = $hmac->b64digest . '=';
1117                     if ($digest eq $hd) {
1118                         if ($rsakey eq $hostkey) {
1119                             $found_nodename = 1;
1120                             $data .= $line;
1121                         }
1122                         return;
1123                     }
1124                     $hmac = Digest::HMAC_SHA1->new($salt);
1125                     $hmac->add($ip_address);
1126                     $hd = $hmac->b64digest . '=';
1127                     if ($digest eq $hd) {
1128                         if ($rsakey eq $hostkey) {
1129                             $found_local_ip = 1;
1130                             $data .= $line;
1131                         }
1132                         return;
1133                     }
1134                 }
1135                 $data .= $line;
1136             }
1137         } elsif ($all) {
1138             $data .= $line;
1139         }
1140     };
1141
1142     while ($old && $old =~ s/^((.*?)(\n|$))//) {
1143         my $line = "$2\n";
1144         next if $line =~ m/^\s*$/; # skip empty lines
1145         next if $line =~ m/^#/; # skip comments
1146         &$merge_line($line, 1);
1147     }
1148
1149     while ($new && $new =~ s/^((.*?)(\n|$))//) {
1150         my $line = "$2\n";
1151         next if $line =~ m/^\s*$/; # skip empty lines
1152         next if $line =~ m/^#/; # skip comments
1153         &$merge_line($line);
1154     }
1155
1156     my $addIndex = $$;
1157     my $add_known_hosts_entry  = sub {
1158         my ($name, $hostkey) = @_;
1159         $addIndex++;
1160         my $hmac = Digest::HMAC_SHA1->new("$addIndex" . time());
1161         my $b64salt = $hmac->b64digest . '=';
1162         $hmac = Digest::HMAC_SHA1->new(decode_base64($b64salt));
1163         $hmac->add($name);
1164         my $digest = $hmac->b64digest . '=';
1165         $data .= "|1|$b64salt|$digest $hostkey\n";
1166     };
1167
1168     if (!$found_nodename || !$found_local_ip) {
1169         &$add_known_hosts_entry($nodename, $hostkey) if !$found_nodename;
1170         &$add_known_hosts_entry($ip_address, $hostkey) if !$found_local_ip;
1171     }
1172
1173     PVE::Tools::file_set_contents($sshknownhosts, $data);
1174
1175     return if !$createLink;
1176
1177     unlink $sshglobalknownhosts;
1178     symlink $sshknownhosts, $sshglobalknownhosts;
1179
1180     warn "can't create symlink for ssh known hosts '$sshglobalknownhosts' -> '$sshknownhosts'\n"
1181         if ! -l $sshglobalknownhosts;
1182
1183 }
1184
1185 my $datacenter_schema = {
1186     type => "object",
1187     additionalProperties => 0,
1188     properties => {
1189         keyboard => {
1190             optional => 1,
1191             type => 'string',
1192             description => "Default keybord layout for vnc server.",
1193             enum => PVE::Tools::kvmkeymaplist(),
1194         },
1195         language => {
1196             optional => 1,
1197             type => 'string',
1198             description => "Default GUI language.",
1199             enum => [ 'en', 'de' ],
1200         },
1201         http_proxy => {
1202             optional => 1,
1203             type => 'string',
1204             description => "Specify external http proxy which is used for downloads (example: 'http://username:password\@host:port/')",
1205             pattern => "http://.*",
1206         },
1207     },
1208 };
1209
1210 # make schema accessible from outside (for documentation)
1211 sub get_datacenter_schema { return $datacenter_schema };
1212
1213 sub parse_datacenter_config {
1214     my ($filename, $raw) = @_;
1215
1216     return PVE::JSONSchema::parse_config($datacenter_schema, $filename, $raw);
1217 }
1218
1219 sub write_datacenter_config {
1220     my ($filename, $cfg) = @_;
1221
1222     return PVE::JSONSchema::dump_config($datacenter_schema, $filename, $cfg);
1223 }
1224
1225 cfs_register_file('datacenter.cfg',
1226                   \&parse_datacenter_config,
1227                   \&write_datacenter_config);
1228
1229 sub parse_cluster_conf {
1230     my ($filename, $raw) = @_;
1231
1232     my $conf = {};
1233
1234     my $digest = Digest::SHA::sha1_hex(defined($raw) ? $raw : '');
1235
1236     my $createNode = sub {
1237         my ($expat, $tag, %attrib) = @_;
1238         $expat->{NodeCount}++;
1239         return { text => $tag, id => $expat->{NodeCount}, %attrib };
1240     };
1241
1242     my $handlers = {
1243         Init => sub {
1244             my $expat = shift;
1245             $expat->{NodeCount} = 0;
1246             $expat->{NodeStack} = [];
1247             $expat->{CurNode} = $expat->{Tree} = &$createNode($expat, 'root');
1248         },
1249         Final => sub {
1250             my $expat = shift;
1251             delete $expat->{CurNode};
1252             delete $expat->{NodeStack};
1253             $expat->{Tree};
1254         },
1255         Start => sub {
1256             my $expat = shift;
1257             my $tag = shift;
1258             my $parent = $expat->{CurNode};
1259             push @{ $expat->{NodeStack} }, $parent;
1260             my $node = &$createNode($expat, $tag, @_);
1261             push @{$expat->{CurNode}->{children}}, $node;
1262             $expat->{CurNode} = $node;
1263         },
1264         End => sub {
1265             my $expat = shift;
1266             my $tag = shift;
1267             my $node = pop @{ $expat->{NodeStack} };
1268             $expat->{CurNode} = $node;
1269         },
1270     };
1271
1272     if ($raw) {
1273         my $parser = new XML::Parser(Handlers => $handlers);
1274         $conf = $parser->parse($raw);
1275     }
1276
1277     $conf->{digest} = $digest;
1278
1279     return $conf;
1280 }
1281
1282 sub cluster_conf_version {
1283     my ($conf, $noerr) = @_;
1284
1285     if ($conf && $conf->{children} && $conf->{children}->[0]) {
1286         my $cluster = $conf->{children}->[0];
1287         if ($cluster && ($cluster->{text} eq 'cluster') &&
1288             $cluster->{config_version}) {
1289             if (my $version = int($cluster->{config_version})) {
1290                 return wantarray ? ($version, $cluster) : $version;
1291             }
1292         }
1293     }
1294
1295     return undef if $noerr;
1296
1297     die "no cluster config - unable to read version\n";
1298 }
1299
1300 sub cluster_conf_lookup_cluster_section {
1301     my ($conf, $noerr) = @_;
1302
1303     my ($version, $cluster) = cluster_conf_version($conf, $noerr);
1304
1305     return $cluster;
1306 }
1307
1308 sub cluster_conf_lookup_rm_section {
1309     my ($conf, $create, $noerr) = @_;
1310
1311     my $cluster = cluster_conf_lookup_cluster_section($conf, $noerr);
1312     return undef if !$cluster;
1313
1314     my $rmsec;
1315     foreach my $child (@{$cluster->{children}}) {
1316         if ($child->{text} eq 'rm') {
1317             $rmsec = $child;
1318         }
1319     }
1320     if (!$rmsec) {
1321         if (!$create) {
1322             return undef if $noerr;
1323             die "no resource manager section\n";
1324         }
1325         $rmsec = { text => 'rm' };
1326         push @{$cluster->{children}}, $rmsec;
1327     }
1328
1329     return $rmsec;
1330 }
1331
1332 sub cluster_conf_lookup_pvevm {
1333     my ($conf, $create, $vmid, $noerr) = @_;
1334
1335     my $rmsec = cluster_conf_lookup_rm_section($conf, $create, $noerr);
1336     return undef if !$rmsec;
1337
1338     my $vmref;
1339     foreach my $child (@{$rmsec->{children}}) {
1340         if ($child->{text} eq 'pvevm' && $child->{vmid} eq $vmid) {
1341             $vmref = $child;
1342         }
1343     }
1344
1345     if (!$vmref) {
1346         if (!$create) {
1347             return undef if $noerr;
1348             die "unable to find service 'pvevm:$vmid'\n";
1349         }
1350         $vmref = { text => 'pvevm', vmid => $vmid };
1351         push @{$rmsec->{children}}, $vmref;
1352     } elsif ($create) {
1353         return undef if $noerr;
1354         die "unable to create service 'pvevm:$vmid' - already exists\n";
1355     }
1356
1357     return $vmref;
1358 }
1359
1360 sub xml_escape_attrib {
1361     my ($data) = @_;
1362
1363     return '' if !defined($data);
1364
1365     $data =~ s/&/&amp;/sg;
1366     $data =~ s/</&lt;/sg;
1367     $data =~ s/>/&gt;/sg;
1368     $data =~ s/"/&quot;/sg;
1369
1370     return $data;
1371 }
1372
1373 sub __cluster_conf_dump_node {
1374     my ($node, $indend) = @_;
1375
1376     my $xml = '';
1377
1378     $indend = '' if !defined($indend);
1379
1380     my $attribs = '';
1381
1382     foreach my $key (sort keys %$node) {
1383         my $value = $node->{$key};
1384         next if $key eq 'id' || $key eq 'text' || $key eq 'children';
1385         $attribs .= " $key=\"" .  xml_escape_attrib($value) . "\"";
1386     }
1387
1388     my $children = $node->{children};
1389
1390     if ($children && scalar(@$children)) {
1391         $xml .= "$indend<$node->{text}$attribs>\n";
1392         my $childindend = "$indend  ";
1393         foreach my $child (@$children) {
1394             $xml .= __cluster_conf_dump_node($child, $childindend);
1395         }
1396         $xml .= "$indend</$node->{text}>\n";
1397     } else {
1398         $xml .= "$indend<$node->{text}$attribs/>\n";
1399     }
1400
1401     return $xml;
1402 }
1403
1404 sub write_cluster_conf {
1405     my ($filename, $cfg) = @_;
1406
1407     my $version = cluster_conf_version($cfg);
1408
1409     my $res = "<?xml version=\"1.0\"?>\n";
1410
1411     $res .= __cluster_conf_dump_node($cfg->{children}->[0]);
1412
1413     return $res;
1414 }
1415
1416 # read only - use "rename cluster.conf.new cluster.conf" to write
1417 PVE::Cluster::cfs_register_file('cluster.conf', \&parse_cluster_conf);
1418 # this is read/write
1419 PVE::Cluster::cfs_register_file('cluster.conf.new', \&parse_cluster_conf,
1420                                 \&write_cluster_conf);