]>
Commit | Line | Data |
---|---|---|
1 | package PVE::Tools; | |
2 | ||
3 | use strict; | |
4 | use warnings; | |
5 | use POSIX qw(EINTR EEXIST EOPNOTSUPP); | |
6 | use IO::Socket::IP; | |
7 | use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM | |
8 | IPPROTO_TCP); | |
9 | use IO::Select; | |
10 | use File::Basename; | |
11 | use File::Path qw(make_path); | |
12 | use Filesys::Df (); # don't overwrite our df() | |
13 | use IO::Pipe; | |
14 | use IO::File; | |
15 | use IO::Dir; | |
16 | use IO::Handle; | |
17 | use IPC::Open3; | |
18 | use Fcntl qw(:DEFAULT :flock); | |
19 | use base 'Exporter'; | |
20 | use URI::Escape; | |
21 | use Encode; | |
22 | use Digest::SHA; | |
23 | use JSON; | |
24 | use Text::ParseWords; | |
25 | use String::ShellQuote; | |
26 | use Time::HiRes qw(usleep gettimeofday tv_interval alarm); | |
27 | use Scalar::Util 'weaken'; | |
28 | use PVE::Syscall; | |
29 | ||
30 | # avoid warning when parsing long hex values with hex() | |
31 | no warnings 'portable'; # Support for 64-bit ints required | |
32 | ||
33 | our @EXPORT_OK = qw( | |
34 | $IPV6RE | |
35 | $IPV4RE | |
36 | lock_file | |
37 | lock_file_full | |
38 | run_command | |
39 | file_set_contents | |
40 | file_get_contents | |
41 | file_read_firstline | |
42 | dir_glob_regex | |
43 | dir_glob_foreach | |
44 | split_list | |
45 | template_replace | |
46 | safe_print | |
47 | trim | |
48 | extract_param | |
49 | file_copy | |
50 | get_host_arch | |
51 | O_PATH | |
52 | O_TMPFILE | |
53 | AT_EMPTY_PATH | |
54 | AT_FDCWD | |
55 | CLONE_NEWNS | |
56 | CLONE_NEWUTS | |
57 | CLONE_NEWIPC | |
58 | CLONE_NEWUSER | |
59 | CLONE_NEWPID | |
60 | CLONE_NEWNET | |
61 | ); | |
62 | ||
63 | my $pvelogdir = "/var/log/pve"; | |
64 | my $pvetaskdir = "$pvelogdir/tasks"; | |
65 | ||
66 | mkdir $pvelogdir; | |
67 | mkdir $pvetaskdir; | |
68 | ||
69 | my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])"; | |
70 | our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)"; | |
71 | my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})"; | |
72 | my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))"; | |
73 | ||
74 | our $IPV6RE = "(?:" . | |
75 | "(?:(?:" . "(?:$IPV6H16:){6})$IPV6LS32)|" . | |
76 | "(?:(?:" . "::(?:$IPV6H16:){5})$IPV6LS32)|" . | |
77 | "(?:(?:(?:" . "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" . | |
78 | "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" . | |
79 | "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" . | |
80 | "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" . | |
81 | "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" . ")$IPV6LS32)|" . | |
82 | "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" . ")$IPV6H16)|" . | |
83 | "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" . ")))"; | |
84 | ||
85 | our $IPRE = "(?:$IPV4RE|$IPV6RE)"; | |
86 | ||
87 | use constant {CLONE_NEWNS => 0x00020000, | |
88 | CLONE_NEWUTS => 0x04000000, | |
89 | CLONE_NEWIPC => 0x08000000, | |
90 | CLONE_NEWUSER => 0x10000000, | |
91 | CLONE_NEWPID => 0x20000000, | |
92 | CLONE_NEWNET => 0x40000000}; | |
93 | ||
94 | use constant {O_PATH => 0x00200000, | |
95 | O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY | |
96 | ||
97 | use constant {AT_EMPTY_PATH => 0x1000, | |
98 | AT_FDCWD => -100}; | |
99 | ||
100 | sub run_with_timeout { | |
101 | my ($timeout, $code, @param) = @_; | |
102 | ||
103 | die "got timeout\n" if $timeout <= 0; | |
104 | ||
105 | my $prev_alarm = alarm 0; # suspend outer alarm early | |
106 | ||
107 | my $sigcount = 0; | |
108 | ||
109 | my $res; | |
110 | ||
111 | eval { | |
112 | local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; }; | |
113 | local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" }; | |
114 | local $SIG{__DIE__}; # see SA bug 4631 | |
115 | ||
116 | alarm($timeout); | |
117 | ||
118 | eval { $res = &$code(@param); }; | |
119 | ||
120 | alarm(0); # avoid race conditions | |
121 | ||
122 | die $@ if $@; | |
123 | }; | |
124 | ||
125 | my $err = $@; | |
126 | ||
127 | alarm $prev_alarm; | |
128 | ||
129 | # this shouldn't happen anymore? | |
130 | die "unknown error" if $sigcount && !$err; # seems to happen sometimes | |
131 | ||
132 | die $err if $err; | |
133 | ||
134 | return $res; | |
135 | } | |
136 | ||
137 | # flock: we use one file handle per process, so lock file | |
138 | # can be nested multiple times and succeeds for the same process. | |
139 | # | |
140 | # Since this is the only way we lock now and we don't have the old | |
141 | # 'lock(); code(); unlock();' pattern anymore we do not actually need to | |
142 | # count how deep we're nesting. Therefore this hash now stores a weak reference | |
143 | # to a boolean telling us whether we already have a lock. | |
144 | ||
145 | my $lock_handles = {}; | |
146 | ||
147 | sub lock_file_full { | |
148 | my ($filename, $timeout, $shared, $code, @param) = @_; | |
149 | ||
150 | $timeout = 10 if !$timeout; | |
151 | ||
152 | my $mode = $shared ? LOCK_SH : LOCK_EX; | |
153 | ||
154 | my $lockhash = ($lock_handles->{$$} //= {}); | |
155 | ||
156 | # Returns a locked file handle. | |
157 | my $get_locked_file = sub { | |
158 | my $fh = IO::File->new(">>$filename") | |
159 | or die "can't open file - $!\n"; | |
160 | ||
161 | if (!flock($fh, $mode|LOCK_NB)) { | |
162 | print STDERR "trying to acquire lock...\n"; | |
163 | my $success; | |
164 | while(1) { | |
165 | $success = flock($fh, $mode); | |
166 | # try again on EINTR (see bug #273) | |
167 | if ($success || ($! != EINTR)) { | |
168 | last; | |
169 | } | |
170 | } | |
171 | if (!$success) { | |
172 | print STDERR " failed\n"; | |
173 | die "can't acquire lock '$filename' - $!\n"; | |
174 | } | |
175 | print STDERR " OK\n"; | |
176 | } | |
177 | ||
178 | return $fh; | |
179 | }; | |
180 | ||
181 | my $res; | |
182 | my $checkptr = $lockhash->{$filename}; | |
183 | my $check = 0; # This must not go out of scope before running the code. | |
184 | my $local_fh; # This must stay local | |
185 | if (!$checkptr || !$$checkptr) { | |
186 | # We cannot create a weak reference in a single atomic step, so we first | |
187 | # create a false-value, then create a reference to it, then weaken it, | |
188 | # and after successfully locking the file we change the boolean value. | |
189 | # | |
190 | # The reason for this is that if an outer SIGALRM throws an exception | |
191 | # between creating the reference and weakening it, a subsequent call to | |
192 | # lock_file_full() will see a leftover full reference to a valid | |
193 | # variable. This variable must be 0 in order for said call to attempt to | |
194 | # lock the file anew. | |
195 | # | |
196 | # An externally triggered exception elsewhere in the code will cause the | |
197 | # weak reference to become 'undef', and since the file handle is only | |
198 | # stored in the local scope in $local_fh, the file will be closed by | |
199 | # perl's cleanup routines as well. | |
200 | # | |
201 | # This still assumes that an IO::File handle can properly deal with such | |
202 | # exceptions thrown during its own destruction, but that's up to perls | |
203 | # guts now. | |
204 | $lockhash->{$filename} = \$check; | |
205 | weaken $lockhash->{$filename}; | |
206 | $local_fh = eval { run_with_timeout($timeout, $get_locked_file) }; | |
207 | if ($@) { | |
208 | $@ = "can't lock file '$filename' - $@"; | |
209 | return undef; | |
210 | } | |
211 | $check = 1; | |
212 | } | |
213 | $res = eval { &$code(@param); }; | |
214 | return undef if $@; | |
215 | return $res; | |
216 | } | |
217 | ||
218 | ||
219 | sub lock_file { | |
220 | my ($filename, $timeout, $code, @param) = @_; | |
221 | ||
222 | return lock_file_full($filename, $timeout, 0, $code, @param); | |
223 | } | |
224 | ||
225 | sub file_set_contents { | |
226 | my ($filename, $data, $perm) = @_; | |
227 | ||
228 | $perm = 0644 if !defined($perm); | |
229 | ||
230 | my $tmpname = "$filename.tmp.$$"; | |
231 | ||
232 | eval { | |
233 | my ($fh, $tries) = (undef, 0); | |
234 | while (!$fh && $tries++ < 3) { | |
235 | $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm); | |
236 | if (!$fh && $! == EEXIST) { | |
237 | unlink($tmpname) or die "unable to delete old temp file: $!\n"; | |
238 | } | |
239 | } | |
240 | die "unable to open file '$tmpname' - $!\n" if !$fh; | |
241 | die "unable to write '$tmpname' - $!\n" unless print $fh $data; | |
242 | die "closing file '$tmpname' failed - $!\n" unless close $fh; | |
243 | }; | |
244 | my $err = $@; | |
245 | ||
246 | if ($err) { | |
247 | unlink $tmpname; | |
248 | die $err; | |
249 | } | |
250 | ||
251 | if (!rename($tmpname, $filename)) { | |
252 | my $msg = "close (rename) atomic file '$filename' failed: $!\n"; | |
253 | unlink $tmpname; | |
254 | die $msg; | |
255 | } | |
256 | } | |
257 | ||
258 | sub file_get_contents { | |
259 | my ($filename, $max) = @_; | |
260 | ||
261 | my $fh = IO::File->new($filename, "r") || | |
262 | die "can't open '$filename' - $!\n"; | |
263 | ||
264 | my $content = safe_read_from($fh, $max, 0, $filename); | |
265 | ||
266 | close $fh; | |
267 | ||
268 | return $content; | |
269 | } | |
270 | ||
271 | sub file_copy { | |
272 | my ($filename, $dst, $max, $perm) = @_; | |
273 | ||
274 | file_set_contents ($dst, file_get_contents($filename, $max), $perm); | |
275 | } | |
276 | ||
277 | sub file_read_firstline { | |
278 | my ($filename) = @_; | |
279 | ||
280 | my $fh = IO::File->new ($filename, "r"); | |
281 | return undef if !$fh; | |
282 | my $res = <$fh>; | |
283 | chomp $res if $res; | |
284 | $fh->close; | |
285 | return $res; | |
286 | } | |
287 | ||
288 | sub safe_read_from { | |
289 | my ($fh, $max, $oneline, $filename) = @_; | |
290 | ||
291 | $max = 32768 if !$max; | |
292 | ||
293 | my $subject = defined($filename) ? "file '$filename'" : 'input'; | |
294 | ||
295 | my $br = 0; | |
296 | my $input = ''; | |
297 | my $count; | |
298 | while ($count = sysread($fh, $input, 8192, $br)) { | |
299 | $br += $count; | |
300 | die "$subject too long - aborting\n" if $br > $max; | |
301 | if ($oneline && $input =~ m/^(.*)\n/) { | |
302 | $input = $1; | |
303 | last; | |
304 | } | |
305 | } | |
306 | die "unable to read $subject - $!\n" if !defined($count); | |
307 | ||
308 | return $input; | |
309 | } | |
310 | ||
311 | # The $cmd parameter can be: | |
312 | # -) a string | |
313 | # This is generally executed by passing it to the shell with the -c option. | |
314 | # However, it can be executed in one of two ways, depending on whether | |
315 | # there's a pipe involved: | |
316 | # *) with pipe: passed explicitly to bash -c, prefixed with: | |
317 | # set -o pipefail && | |
318 | # *) without a pipe: passed to perl's open3 which uses 'sh -c' | |
319 | # (Note that this may result in two different syntax requirements!) | |
320 | # FIXME? | |
321 | # -) an array of arguments (strings) | |
322 | # Will be executed without interference from a shell. (Parameters are passed | |
323 | # as is, no escape sequences of strings will be touched.) | |
324 | # -) an array of arrays | |
325 | # Each array represents a command, and each command's output is piped into | |
326 | # the following command's standard input. | |
327 | # For this a shell command string is created with pipe symbols between each | |
328 | # command. | |
329 | # Each command is a list of strings meant to end up in the final command | |
330 | # unchanged. In order to achieve this, every argument is shell-quoted. | |
331 | # Quoting can be disabled for a particular argument by turning it into a | |
332 | # reference, this allows inserting arbitrary shell options. | |
333 | # For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not | |
334 | # produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ] | |
335 | # will literally print: hello >/dev/null | |
336 | sub run_command { | |
337 | my ($cmd, %param) = @_; | |
338 | ||
339 | my $old_umask; | |
340 | my $cmdstr; | |
341 | ||
342 | if (my $ref = ref($cmd)) { | |
343 | if (ref($cmd->[0])) { | |
344 | $cmdstr = 'set -o pipefail && '; | |
345 | my $pipe = ''; | |
346 | foreach my $command (@$cmd) { | |
347 | # concatenate quoted parameters | |
348 | # strings which are passed by reference are NOT shell quoted | |
349 | $cmdstr .= $pipe . join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command); | |
350 | $pipe = ' | '; | |
351 | } | |
352 | $cmd = [ '/bin/bash', '-c', "$cmdstr" ]; | |
353 | } else { | |
354 | $cmdstr = cmd2string($cmd); | |
355 | } | |
356 | } else { | |
357 | $cmdstr = $cmd; | |
358 | if ($cmd =~ m/\|/) { | |
359 | # see 'man bash' for option pipefail | |
360 | $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ]; | |
361 | } else { | |
362 | $cmd = [ $cmd ]; | |
363 | } | |
364 | } | |
365 | ||
366 | my $errmsg; | |
367 | my $laststderr; | |
368 | my $timeout; | |
369 | my $oldtimeout; | |
370 | my $pid; | |
371 | my $exitcode = -1; | |
372 | ||
373 | my $outfunc; | |
374 | my $errfunc; | |
375 | my $logfunc; | |
376 | my $input; | |
377 | my $output; | |
378 | my $afterfork; | |
379 | my $noerr; | |
380 | my $keeplocale; | |
381 | my $quiet; | |
382 | ||
383 | eval { | |
384 | ||
385 | foreach my $p (keys %param) { | |
386 | if ($p eq 'timeout') { | |
387 | $timeout = $param{$p}; | |
388 | } elsif ($p eq 'umask') { | |
389 | $old_umask = umask($param{$p}); | |
390 | } elsif ($p eq 'errmsg') { | |
391 | $errmsg = $param{$p}; | |
392 | } elsif ($p eq 'input') { | |
393 | $input = $param{$p}; | |
394 | } elsif ($p eq 'output') { | |
395 | $output = $param{$p}; | |
396 | } elsif ($p eq 'outfunc') { | |
397 | $outfunc = $param{$p}; | |
398 | } elsif ($p eq 'errfunc') { | |
399 | $errfunc = $param{$p}; | |
400 | } elsif ($p eq 'logfunc') { | |
401 | $logfunc = $param{$p}; | |
402 | } elsif ($p eq 'afterfork') { | |
403 | $afterfork = $param{$p}; | |
404 | } elsif ($p eq 'noerr') { | |
405 | $noerr = $param{$p}; | |
406 | } elsif ($p eq 'keeplocale') { | |
407 | $keeplocale = $param{$p}; | |
408 | } elsif ($p eq 'quiet') { | |
409 | $quiet = $param{$p}; | |
410 | } else { | |
411 | die "got unknown parameter '$p' for run_command\n"; | |
412 | } | |
413 | } | |
414 | ||
415 | if ($errmsg) { | |
416 | my $origerrfunc = $errfunc; | |
417 | $errfunc = sub { | |
418 | if ($laststderr) { | |
419 | if ($origerrfunc) { | |
420 | &$origerrfunc("$laststderr\n"); | |
421 | } else { | |
422 | print STDERR "$laststderr\n" if $laststderr; | |
423 | } | |
424 | } | |
425 | $laststderr = shift; | |
426 | }; | |
427 | } | |
428 | ||
429 | my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new(); | |
430 | my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new(); | |
431 | my $error = IO::File->new(); | |
432 | ||
433 | my $orig_pid = $$; | |
434 | ||
435 | eval { | |
436 | local $ENV{LC_ALL} = 'C' if !$keeplocale; | |
437 | ||
438 | # suppress LVM warnings like: "File descriptor 3 left open"; | |
439 | local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1"; | |
440 | ||
441 | $pid = open3($writer, $reader, $error, @$cmd) || die $!; | |
442 | ||
443 | # if we pipe fron STDIN, open3 closes STDIN, so we we | |
444 | # a perl warning "Filehandle STDIN reopened as GENXYZ .. " | |
445 | # as soon as we open a new file. | |
446 | # to avoid that we open /dev/null | |
447 | if (!ref($writer) && !defined(fileno(STDIN))) { | |
448 | POSIX::close(0); | |
449 | open(STDIN, "</dev/null"); | |
450 | } | |
451 | }; | |
452 | ||
453 | my $err = $@; | |
454 | ||
455 | # catch exec errors | |
456 | if ($orig_pid != $$) { | |
457 | warn "ERROR: $err"; | |
458 | POSIX::_exit (1); | |
459 | kill ('KILL', $$); | |
460 | } | |
461 | ||
462 | die $err if $err; | |
463 | ||
464 | local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout; | |
465 | $oldtimeout = alarm($timeout) if $timeout; | |
466 | ||
467 | &$afterfork() if $afterfork; | |
468 | ||
469 | if (ref($writer)) { | |
470 | print $writer $input if defined $input; | |
471 | close $writer; | |
472 | } | |
473 | ||
474 | my $select = new IO::Select; | |
475 | $select->add($reader) if ref($reader); | |
476 | $select->add($error); | |
477 | ||
478 | my $outlog = ''; | |
479 | my $errlog = ''; | |
480 | ||
481 | my $starttime = time(); | |
482 | ||
483 | while ($select->count) { | |
484 | my @handles = $select->can_read(1); | |
485 | ||
486 | foreach my $h (@handles) { | |
487 | my $buf = ''; | |
488 | my $count = sysread ($h, $buf, 4096); | |
489 | if (!defined ($count)) { | |
490 | my $err = $!; | |
491 | kill (9, $pid); | |
492 | waitpid ($pid, 0); | |
493 | die $err; | |
494 | } | |
495 | $select->remove ($h) if !$count; | |
496 | if ($h eq $reader) { | |
497 | if ($outfunc || $logfunc) { | |
498 | eval { | |
499 | $outlog .= $buf; | |
500 | while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) { | |
501 | my $line = $1; | |
502 | &$outfunc($line) if $outfunc; | |
503 | &$logfunc($line) if $logfunc; | |
504 | } | |
505 | }; | |
506 | my $err = $@; | |
507 | if ($err) { | |
508 | kill (9, $pid); | |
509 | waitpid ($pid, 0); | |
510 | die $err; | |
511 | } | |
512 | } elsif (!$quiet) { | |
513 | print $buf; | |
514 | *STDOUT->flush(); | |
515 | } | |
516 | } elsif ($h eq $error) { | |
517 | if ($errfunc || $logfunc) { | |
518 | eval { | |
519 | $errlog .= $buf; | |
520 | while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) { | |
521 | my $line = $1; | |
522 | &$errfunc($line) if $errfunc; | |
523 | &$logfunc($line) if $logfunc; | |
524 | } | |
525 | }; | |
526 | my $err = $@; | |
527 | if ($err) { | |
528 | kill (9, $pid); | |
529 | waitpid ($pid, 0); | |
530 | die $err; | |
531 | } | |
532 | } elsif (!$quiet) { | |
533 | print STDERR $buf; | |
534 | *STDERR->flush(); | |
535 | } | |
536 | } | |
537 | } | |
538 | } | |
539 | ||
540 | &$outfunc($outlog) if $outfunc && $outlog; | |
541 | &$logfunc($outlog) if $logfunc && $outlog; | |
542 | ||
543 | &$errfunc($errlog) if $errfunc && $errlog; | |
544 | &$logfunc($errlog) if $logfunc && $errlog; | |
545 | ||
546 | waitpid ($pid, 0); | |
547 | ||
548 | if ($? == -1) { | |
549 | die "failed to execute\n"; | |
550 | } elsif (my $sig = ($? & 127)) { | |
551 | die "got signal $sig\n"; | |
552 | } elsif ($exitcode = ($? >> 8)) { | |
553 | if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) { | |
554 | if ($errmsg && $laststderr) { | |
555 | my $lerr = $laststderr; | |
556 | $laststderr = undef; | |
557 | die "$lerr\n"; | |
558 | } | |
559 | die "exit code $exitcode\n"; | |
560 | } | |
561 | } | |
562 | ||
563 | alarm(0); | |
564 | }; | |
565 | ||
566 | my $err = $@; | |
567 | ||
568 | alarm(0); | |
569 | ||
570 | if ($errmsg && $laststderr) { | |
571 | &$errfunc(undef); # flush laststderr | |
572 | } | |
573 | ||
574 | umask ($old_umask) if defined($old_umask); | |
575 | ||
576 | alarm($oldtimeout) if $oldtimeout; | |
577 | ||
578 | if ($err) { | |
579 | if ($pid && ($err eq "got timeout\n")) { | |
580 | kill (9, $pid); | |
581 | waitpid ($pid, 0); | |
582 | die "command '$cmdstr' failed: $err"; | |
583 | } | |
584 | ||
585 | if ($errmsg) { | |
586 | $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|; | |
587 | die "$errmsg: $err"; | |
588 | } elsif(!$noerr) { | |
589 | die "command '$cmdstr' failed: $err"; | |
590 | } | |
591 | } | |
592 | ||
593 | return $exitcode; | |
594 | } | |
595 | ||
596 | # Run a command with a tcp socket as standard input. | |
597 | sub pipe_socket_to_command { | |
598 | my ($cmd, $ip, $port) = @_; | |
599 | ||
600 | my $params = { | |
601 | Listen => 1, | |
602 | ReuseAddr => 1, | |
603 | Proto => &Socket::IPPROTO_TCP, | |
604 | GetAddrInfoFlags => 0, | |
605 | LocalAddr => $ip, | |
606 | LocalPort => $port, | |
607 | }; | |
608 | my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n"; | |
609 | ||
610 | print "$ip\n$port\n"; # tell remote where to connect | |
611 | *STDOUT->flush(); | |
612 | ||
613 | alarm 0; | |
614 | local $SIG{ALRM} = sub { die "timed out waiting for client\n" }; | |
615 | alarm 30; | |
616 | my $client = $socket->accept; # Wait for a client | |
617 | alarm 0; | |
618 | close($socket); | |
619 | ||
620 | # We want that the command talks over the TCP socket and takes | |
621 | # ownership of it, so that when it closes it the connection is | |
622 | # terminated, so we need to be able to close the socket. So we | |
623 | # can't really use PVE::Tools::run_command(). | |
624 | my $pid = fork() // die "fork failed: $!\n"; | |
625 | if (!$pid) { | |
626 | POSIX::dup2(fileno($client), 0); | |
627 | POSIX::dup2(fileno($client), 1); | |
628 | close($client); | |
629 | exec {$cmd->[0]} @$cmd or do { | |
630 | warn "exec failed: $!\n"; | |
631 | POSIX::_exit(1); | |
632 | }; | |
633 | } | |
634 | ||
635 | close($client); | |
636 | if (waitpid($pid, 0) != $pid) { | |
637 | kill(15 => $pid); # if we got interrupted terminate the child | |
638 | my $count = 0; | |
639 | while (waitpid($pid, POSIX::WNOHANG) != $pid) { | |
640 | usleep(100000); | |
641 | $count++; | |
642 | kill(9 => $pid), last if $count > 300; # 30 second timeout | |
643 | } | |
644 | } | |
645 | if (my $sig = ($? & 127)) { | |
646 | die "got signal $sig\n"; | |
647 | } elsif (my $exitcode = ($? >> 8)) { | |
648 | die "exit code $exitcode\n"; | |
649 | } | |
650 | ||
651 | return undef; | |
652 | } | |
653 | ||
654 | sub split_list { | |
655 | my $listtxt = shift // ''; | |
656 | ||
657 | return split (/\0/, $listtxt) if $listtxt =~ m/\0/; | |
658 | ||
659 | $listtxt =~ s/[,;]/ /g; | |
660 | $listtxt =~ s/^\s+//; | |
661 | ||
662 | my @data = split (/\s+/, $listtxt); | |
663 | ||
664 | return @data; | |
665 | } | |
666 | ||
667 | sub trim { | |
668 | my $txt = shift; | |
669 | ||
670 | return $txt if !defined($txt); | |
671 | ||
672 | $txt =~ s/^\s+//; | |
673 | $txt =~ s/\s+$//; | |
674 | ||
675 | return $txt; | |
676 | } | |
677 | ||
678 | # simple uri templates like "/vms/{vmid}" | |
679 | sub template_replace { | |
680 | my ($tmpl, $data) = @_; | |
681 | ||
682 | return $tmpl if !$tmpl; | |
683 | ||
684 | my $res = ''; | |
685 | while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) { | |
686 | $res .= $1 if $1; | |
687 | $res .= ($data->{$3} || '-') if $2; | |
688 | } | |
689 | return $res; | |
690 | } | |
691 | ||
692 | sub safe_print { | |
693 | my ($filename, $fh, $data) = @_; | |
694 | ||
695 | return if !$data; | |
696 | ||
697 | my $res = print $fh $data; | |
698 | ||
699 | die "write to '$filename' failed\n" if !$res; | |
700 | } | |
701 | ||
702 | sub debmirrors { | |
703 | ||
704 | return { | |
705 | 'at' => 'ftp.at.debian.org', | |
706 | 'au' => 'ftp.au.debian.org', | |
707 | 'be' => 'ftp.be.debian.org', | |
708 | 'bg' => 'ftp.bg.debian.org', | |
709 | 'br' => 'ftp.br.debian.org', | |
710 | 'ca' => 'ftp.ca.debian.org', | |
711 | 'ch' => 'ftp.ch.debian.org', | |
712 | 'cl' => 'ftp.cl.debian.org', | |
713 | 'cz' => 'ftp.cz.debian.org', | |
714 | 'de' => 'ftp.de.debian.org', | |
715 | 'dk' => 'ftp.dk.debian.org', | |
716 | 'ee' => 'ftp.ee.debian.org', | |
717 | 'es' => 'ftp.es.debian.org', | |
718 | 'fi' => 'ftp.fi.debian.org', | |
719 | 'fr' => 'ftp.fr.debian.org', | |
720 | 'gr' => 'ftp.gr.debian.org', | |
721 | 'hk' => 'ftp.hk.debian.org', | |
722 | 'hr' => 'ftp.hr.debian.org', | |
723 | 'hu' => 'ftp.hu.debian.org', | |
724 | 'ie' => 'ftp.ie.debian.org', | |
725 | 'is' => 'ftp.is.debian.org', | |
726 | 'it' => 'ftp.it.debian.org', | |
727 | 'jp' => 'ftp.jp.debian.org', | |
728 | 'kr' => 'ftp.kr.debian.org', | |
729 | 'mx' => 'ftp.mx.debian.org', | |
730 | 'nl' => 'ftp.nl.debian.org', | |
731 | 'no' => 'ftp.no.debian.org', | |
732 | 'nz' => 'ftp.nz.debian.org', | |
733 | 'pl' => 'ftp.pl.debian.org', | |
734 | 'pt' => 'ftp.pt.debian.org', | |
735 | 'ro' => 'ftp.ro.debian.org', | |
736 | 'ru' => 'ftp.ru.debian.org', | |
737 | 'se' => 'ftp.se.debian.org', | |
738 | 'si' => 'ftp.si.debian.org', | |
739 | 'sk' => 'ftp.sk.debian.org', | |
740 | 'tr' => 'ftp.tr.debian.org', | |
741 | 'tw' => 'ftp.tw.debian.org', | |
742 | 'gb' => 'ftp.uk.debian.org', | |
743 | 'us' => 'ftp.us.debian.org', | |
744 | }; | |
745 | } | |
746 | ||
747 | my $keymaphash = { | |
748 | 'dk' => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'], | |
749 | 'de' => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ], | |
750 | 'de-ch' => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz', 'ch', 'de_nodeadkeys' ], | |
751 | 'en-gb' => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef], | |
752 | 'en-us' => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz', 'us', undef ], | |
753 | 'es' => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'], | |
754 | #'et' => [], # Ethopia or Estonia ?? | |
755 | 'fi' => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'], | |
756 | #'fo' => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'], | |
757 | 'fr' => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'], | |
758 | 'fr-be' => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'], | |
759 | 'fr-ca' => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'], | |
760 | 'fr-ch' => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'], | |
761 | #'hr' => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2? | |
762 | 'hu' => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef], | |
763 | 'is' => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'], | |
764 | 'it' => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'], | |
765 | 'jp' => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef], | |
766 | 'lt' => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'], | |
767 | #'lv' => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7? | |
768 | 'mk' => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'], | |
769 | 'nl' => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef], | |
770 | #'nl-be' => ['Belgium-Dutch', 'nl-be', ?, ?, ?], | |
771 | 'no' => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'], | |
772 | 'pl' => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef], | |
773 | 'pt' => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'], | |
774 | 'pt-br' => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'], | |
775 | #'ru' => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know? | |
776 | 'si' => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef], | |
777 | 'se' => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'], | |
778 | #'th' => [], | |
779 | 'tr' => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef], | |
780 | }; | |
781 | ||
782 | my $kvmkeymaparray = []; | |
783 | foreach my $lc (sort keys %$keymaphash) { | |
784 | push @$kvmkeymaparray, $keymaphash->{$lc}->[1]; | |
785 | } | |
786 | ||
787 | sub kvmkeymaps { | |
788 | return $keymaphash; | |
789 | } | |
790 | ||
791 | sub kvmkeymaplist { | |
792 | return $kvmkeymaparray; | |
793 | } | |
794 | ||
795 | sub extract_param { | |
796 | my ($param, $key) = @_; | |
797 | ||
798 | my $res = $param->{$key}; | |
799 | delete $param->{$key}; | |
800 | ||
801 | return $res; | |
802 | } | |
803 | ||
804 | # Note: we use this to wait until vncterm/spiceterm is ready | |
805 | sub wait_for_vnc_port { | |
806 | my ($port, $family, $timeout) = @_; | |
807 | ||
808 | $timeout = 5 if !$timeout; | |
809 | my $sleeptime = 0; | |
810 | my $starttime = [gettimeofday]; | |
811 | my $elapsed; | |
812 | ||
813 | my $cmd = ['/bin/ss', '-Htln', "sport = :$port"]; | |
814 | push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family); | |
815 | ||
816 | my $found; | |
817 | while (($elapsed = tv_interval($starttime)) < $timeout) { | |
818 | # -Htln = don't print header, tcp, listening sockets only, numeric ports | |
819 | run_command($cmd, outfunc => sub { | |
820 | my $line = shift; | |
821 | if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) { | |
822 | $found = 1 if ($port == $1); | |
823 | } | |
824 | }); | |
825 | return 1 if $found; | |
826 | $sleeptime += 100000 if $sleeptime < 1000000; | |
827 | usleep($sleeptime); | |
828 | } | |
829 | ||
830 | die "Timeout while waiting for port '$port' to get ready!\n"; | |
831 | } | |
832 | ||
833 | sub next_unused_port { | |
834 | my ($range_start, $range_end, $family, $address) = @_; | |
835 | ||
836 | # We use a file to register allocated ports. | |
837 | # Those registrations expires after $expiretime. | |
838 | # We use this to avoid race conditions between | |
839 | # allocation and use of ports. | |
840 | ||
841 | my $filename = "/var/tmp/pve-reserved-ports"; | |
842 | ||
843 | my $code = sub { | |
844 | ||
845 | my $expiretime = 5; | |
846 | my $ctime = time(); | |
847 | ||
848 | my $ports = {}; | |
849 | ||
850 | if (my $fh = IO::File->new ($filename, "r")) { | |
851 | while (my $line = <$fh>) { | |
852 | if ($line =~ m/^(\d+)\s(\d+)$/) { | |
853 | my ($port, $timestamp) = ($1, $2); | |
854 | if (($timestamp + $expiretime) > $ctime) { | |
855 | $ports->{$port} = $timestamp; # not expired | |
856 | } | |
857 | } | |
858 | } | |
859 | } | |
860 | ||
861 | my $newport; | |
862 | my %sockargs = (Listen => 5, | |
863 | ReuseAddr => 1, | |
864 | Family => $family, | |
865 | Proto => IPPROTO_TCP, | |
866 | GetAddrInfoFlags => 0); | |
867 | $sockargs{LocalAddr} = $address if defined($address); | |
868 | ||
869 | for (my $p = $range_start; $p < $range_end; $p++) { | |
870 | next if $ports->{$p}; # reserved | |
871 | ||
872 | $sockargs{LocalPort} = $p; | |
873 | my $sock = IO::Socket::IP->new(%sockargs); | |
874 | ||
875 | if ($sock) { | |
876 | close($sock); | |
877 | $newport = $p; | |
878 | $ports->{$p} = $ctime; | |
879 | last; | |
880 | } | |
881 | } | |
882 | ||
883 | my $data = ""; | |
884 | foreach my $p (keys %$ports) { | |
885 | $data .= "$p $ports->{$p}\n"; | |
886 | } | |
887 | ||
888 | file_set_contents($filename, $data); | |
889 | ||
890 | return $newport; | |
891 | }; | |
892 | ||
893 | my $p = lock_file('/var/lock/pve-ports.lck', 10, $code); | |
894 | die $@ if $@; | |
895 | ||
896 | die "unable to find free port (${range_start}-${range_end})\n" if !$p; | |
897 | ||
898 | return $p; | |
899 | } | |
900 | ||
901 | sub next_migrate_port { | |
902 | my ($family, $address) = @_; | |
903 | return next_unused_port(60000, 60050, $family, $address); | |
904 | } | |
905 | ||
906 | sub next_vnc_port { | |
907 | my ($family, $address) = @_; | |
908 | return next_unused_port(5900, 6000, $family, $address); | |
909 | } | |
910 | ||
911 | sub spice_port_range { | |
912 | return (61000, 61999); | |
913 | } | |
914 | ||
915 | sub next_spice_port { | |
916 | my ($family, $address) = @_; | |
917 | return next_unused_port(spice_port_range(), $family, $address); | |
918 | } | |
919 | ||
920 | sub must_stringify { | |
921 | my ($value) = @_; | |
922 | eval { $value = "$value" }; | |
923 | return "error turning value into a string: $@" if $@; | |
924 | return $value; | |
925 | } | |
926 | ||
927 | # sigkill after $timeout a $sub running in a fork if it can't write a pipe | |
928 | # the $sub has to return a single scalar | |
929 | sub run_fork_with_timeout { | |
930 | my ($timeout, $sub) = @_; | |
931 | ||
932 | my $res; | |
933 | my $error; | |
934 | my $pipe_out = IO::Pipe->new(); | |
935 | ||
936 | # disable pending alarms, save their remaining time | |
937 | my $prev_alarm = alarm 0; | |
938 | ||
939 | # avoid leaving a zombie if the parent gets interrupted | |
940 | my $sig_received; | |
941 | ||
942 | my $child = fork(); | |
943 | if (!defined($child)) { | |
944 | die "fork failed: $!\n"; | |
945 | return $res; | |
946 | } | |
947 | ||
948 | if (!$child) { | |
949 | $pipe_out->writer(); | |
950 | ||
951 | eval { | |
952 | $res = $sub->(); | |
953 | print {$pipe_out} encode_json({ result => $res }); | |
954 | $pipe_out->flush(); | |
955 | }; | |
956 | if (my $err = $@) { | |
957 | print {$pipe_out} encode_json({ error => must_stringify($err) }); | |
958 | $pipe_out->flush(); | |
959 | POSIX::_exit(1); | |
960 | } | |
961 | POSIX::_exit(0); | |
962 | } | |
963 | ||
964 | local $SIG{INT} = sub { $sig_received++; }; | |
965 | local $SIG{TERM} = sub { | |
966 | $error //= "interrupted by unexpected signal\n"; | |
967 | kill('TERM', $child); | |
968 | }; | |
969 | ||
970 | $pipe_out->reader(); | |
971 | ||
972 | my $readvalues = sub { | |
973 | local $/ = undef; | |
974 | my $child_res = decode_json(readline_nointr($pipe_out)); | |
975 | $res = $child_res->{result}; | |
976 | $error = $child_res->{error}; | |
977 | }; | |
978 | eval { | |
979 | if (defined($timeout)) { | |
980 | run_with_timeout($timeout, $readvalues); | |
981 | } else { | |
982 | $readvalues->(); | |
983 | } | |
984 | }; | |
985 | warn $@ if $@; | |
986 | $pipe_out->close(); | |
987 | kill('KILL', $child); | |
988 | waitpid($child, 0); | |
989 | ||
990 | alarm $prev_alarm; | |
991 | die "interrupted by unexpected signal\n" if $sig_received; | |
992 | ||
993 | die $error if $error; | |
994 | return $res; | |
995 | } | |
996 | ||
997 | sub run_fork { | |
998 | my ($code) = @_; | |
999 | return run_fork_with_timeout(undef, $code); | |
1000 | } | |
1001 | ||
1002 | # NOTE: NFS syscall can't be interrupted, so alarm does | |
1003 | # not work to provide timeouts. | |
1004 | # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation" | |
1005 | # So fork() before using Filesys::Df | |
1006 | sub df { | |
1007 | my ($path, $timeout) = @_; | |
1008 | ||
1009 | my $df = sub { return Filesys::Df::df($path, 1) }; | |
1010 | ||
1011 | my $res = eval { run_fork_with_timeout($timeout, $df) } // {}; | |
1012 | warn $@ if $@; | |
1013 | ||
1014 | # untaint, but be flexible: PB usage can result in scientific notation | |
1015 | my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 } | |
1016 | $res->@{qw(blocks used bavail)}; | |
1017 | ||
1018 | return { | |
1019 | total => $blocks, | |
1020 | used => $used, | |
1021 | avail => $bavail, | |
1022 | }; | |
1023 | } | |
1024 | ||
1025 | sub du { | |
1026 | my ($path, $timeout) = @_; | |
1027 | ||
1028 | my $size; | |
1029 | ||
1030 | $timeout //= 10; | |
1031 | ||
1032 | my $parser = sub { | |
1033 | my $line = shift; | |
1034 | ||
1035 | if ($line =~ m/^(\d+)\s+total$/) { | |
1036 | $size = $1; | |
1037 | } | |
1038 | }; | |
1039 | ||
1040 | run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout); | |
1041 | ||
1042 | return $size; | |
1043 | } | |
1044 | ||
1045 | # UPID helper | |
1046 | # We use this to uniquely identify a process. | |
1047 | # An 'Unique Process ID' has the following format: | |
1048 | # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user" | |
1049 | ||
1050 | sub upid_encode { | |
1051 | my $d = shift; | |
1052 | ||
1053 | # Note: pstart can be > 32bit if uptime > 497 days, so this can result in | |
1054 | # more that 8 characters for pstart | |
1055 | return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid}, | |
1056 | $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id}, | |
1057 | $d->{user}); | |
1058 | } | |
1059 | ||
1060 | sub upid_decode { | |
1061 | my ($upid, $noerr) = @_; | |
1062 | ||
1063 | my $res; | |
1064 | my $filename; | |
1065 | ||
1066 | # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user" | |
1067 | # Note: allow up to 9 characters for pstart (work until 20 years uptime) | |
1068 | if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) { | |
1069 | $res->{node} = $1; | |
1070 | $res->{pid} = hex($3); | |
1071 | $res->{pstart} = hex($4); | |
1072 | $res->{starttime} = hex($5); | |
1073 | $res->{type} = $6; | |
1074 | $res->{id} = $7; | |
1075 | $res->{user} = $8; | |
1076 | ||
1077 | my $subdir = substr($5, 7, 8); | |
1078 | $filename = "$pvetaskdir/$subdir/$upid"; | |
1079 | ||
1080 | } else { | |
1081 | return undef if $noerr; | |
1082 | die "unable to parse worker upid '$upid'\n"; | |
1083 | } | |
1084 | ||
1085 | return wantarray ? ($res, $filename) : $res; | |
1086 | } | |
1087 | ||
1088 | sub upid_open { | |
1089 | my ($upid) = @_; | |
1090 | ||
1091 | my ($task, $filename) = upid_decode($upid); | |
1092 | ||
1093 | my $dirname = dirname($filename); | |
1094 | make_path($dirname); | |
1095 | ||
1096 | my $wwwid = getpwnam('www-data') || | |
1097 | die "getpwnam failed"; | |
1098 | ||
1099 | my $perm = 0640; | |
1100 | ||
1101 | my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) || | |
1102 | die "unable to create output file '$filename' - $!\n"; | |
1103 | chown $wwwid, -1, $outfh; | |
1104 | ||
1105 | return $outfh; | |
1106 | }; | |
1107 | ||
1108 | sub upid_read_status { | |
1109 | my ($upid) = @_; | |
1110 | ||
1111 | my ($task, $filename) = upid_decode($upid); | |
1112 | my $fh = IO::File->new($filename, "r"); | |
1113 | return "unable to open file - $!" if !$fh; | |
1114 | my $maxlen = 4096; | |
1115 | sysseek($fh, -$maxlen, 2); | |
1116 | my $readbuf = ''; | |
1117 | my $br = sysread($fh, $readbuf, $maxlen); | |
1118 | close($fh); | |
1119 | if ($br) { | |
1120 | return "unable to extract last line" | |
1121 | if $readbuf !~ m/\n?(.+)$/; | |
1122 | my $line = $1; | |
1123 | if ($line =~ m/^TASK OK$/) { | |
1124 | return 'OK'; | |
1125 | } elsif ($line =~ m/^TASK ERROR: (.+)$/) { | |
1126 | return $1; | |
1127 | } else { | |
1128 | return "unexpected status"; | |
1129 | } | |
1130 | } | |
1131 | return "unable to read tail (got $br bytes)"; | |
1132 | } | |
1133 | ||
1134 | # useful functions to store comments in config files | |
1135 | sub encode_text { | |
1136 | my ($text) = @_; | |
1137 | ||
1138 | # all control and hi-bit characters, and ':' | |
1139 | my $unsafe = "^\x20-\x39\x3b-\x7e"; | |
1140 | return uri_escape(Encode::encode("utf8", $text), $unsafe); | |
1141 | } | |
1142 | ||
1143 | sub decode_text { | |
1144 | my ($data) = @_; | |
1145 | ||
1146 | return Encode::decode("utf8", uri_unescape($data)); | |
1147 | } | |
1148 | ||
1149 | # depreciated - do not use! | |
1150 | # we now decode all parameters by default | |
1151 | sub decode_utf8_parameters { | |
1152 | my ($param) = @_; | |
1153 | ||
1154 | foreach my $p (qw(comment description firstname lastname)) { | |
1155 | $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p}; | |
1156 | } | |
1157 | ||
1158 | return $param; | |
1159 | } | |
1160 | ||
1161 | sub random_ether_addr { | |
1162 | my ($prefix) = @_; | |
1163 | ||
1164 | my ($seconds, $microseconds) = gettimeofday; | |
1165 | ||
1166 | my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds); | |
1167 | ||
1168 | # clear multicast, set local id | |
1169 | vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2; | |
1170 | ||
1171 | my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand)); | |
1172 | if (defined($prefix)) { | |
1173 | $addr = uc($prefix) . substr($addr, length($prefix)); | |
1174 | } | |
1175 | return $addr; | |
1176 | } | |
1177 | ||
1178 | sub shellquote { | |
1179 | my $str = shift; | |
1180 | ||
1181 | return String::ShellQuote::shell_quote($str); | |
1182 | } | |
1183 | ||
1184 | sub cmd2string { | |
1185 | my ($cmd) = @_; | |
1186 | ||
1187 | die "no arguments" if !$cmd; | |
1188 | ||
1189 | return $cmd if !ref($cmd); | |
1190 | ||
1191 | my @qa = (); | |
1192 | foreach my $arg (@$cmd) { push @qa, shellquote($arg); } | |
1193 | ||
1194 | return join (' ', @qa); | |
1195 | } | |
1196 | ||
1197 | # split an shell argument string into an array, | |
1198 | sub split_args { | |
1199 | my ($str) = @_; | |
1200 | ||
1201 | return $str ? [ Text::ParseWords::shellwords($str) ] : []; | |
1202 | } | |
1203 | ||
1204 | sub dump_logfile { | |
1205 | my ($filename, $start, $limit, $filter) = @_; | |
1206 | ||
1207 | my $lines = []; | |
1208 | my $count = 0; | |
1209 | ||
1210 | my $fh = IO::File->new($filename, "r"); | |
1211 | if (!$fh) { | |
1212 | $count++; | |
1213 | push @$lines, { n => $count, t => "unable to open file - $!"}; | |
1214 | return ($count, $lines); | |
1215 | } | |
1216 | ||
1217 | $start = 0 if !$start; | |
1218 | $limit = 50 if !$limit; | |
1219 | ||
1220 | my $line; | |
1221 | ||
1222 | if ($filter) { | |
1223 | # duplicate code, so that we do not slow down normal path | |
1224 | while (defined($line = <$fh>)) { | |
1225 | next if $line !~ m/$filter/; | |
1226 | next if $count++ < $start; | |
1227 | next if $limit <= 0; | |
1228 | chomp $line; | |
1229 | push @$lines, { n => $count, t => $line}; | |
1230 | $limit--; | |
1231 | } | |
1232 | } else { | |
1233 | while (defined($line = <$fh>)) { | |
1234 | next if $count++ < $start; | |
1235 | next if $limit <= 0; | |
1236 | chomp $line; | |
1237 | push @$lines, { n => $count, t => $line}; | |
1238 | $limit--; | |
1239 | } | |
1240 | } | |
1241 | ||
1242 | close($fh); | |
1243 | ||
1244 | # HACK: ExtJS store.guaranteeRange() does not like empty array | |
1245 | # so we add a line | |
1246 | if (!$count) { | |
1247 | $count++; | |
1248 | push @$lines, { n => $count, t => "no content"}; | |
1249 | } | |
1250 | ||
1251 | return ($count, $lines); | |
1252 | } | |
1253 | ||
1254 | sub dump_journal { | |
1255 | my ($start, $limit, $since, $until, $service) = @_; | |
1256 | ||
1257 | my $lines = []; | |
1258 | my $count = 0; | |
1259 | ||
1260 | $start = 0 if !$start; | |
1261 | $limit = 50 if !$limit; | |
1262 | ||
1263 | my $parser = sub { | |
1264 | my $line = shift; | |
1265 | ||
1266 | return if $count++ < $start; | |
1267 | return if $limit <= 0; | |
1268 | push @$lines, { n => int($count), t => $line}; | |
1269 | $limit--; | |
1270 | }; | |
1271 | ||
1272 | my $cmd = ['journalctl', '-o', 'short', '--no-pager']; | |
1273 | ||
1274 | push @$cmd, '--unit', $service if $service; | |
1275 | push @$cmd, '--since', $since if $since; | |
1276 | push @$cmd, '--until', $until if $until; | |
1277 | run_command($cmd, outfunc => $parser); | |
1278 | ||
1279 | # HACK: ExtJS store.guaranteeRange() does not like empty array | |
1280 | # so we add a line | |
1281 | if (!$count) { | |
1282 | $count++; | |
1283 | push @$lines, { n => $count, t => "no content"}; | |
1284 | } | |
1285 | ||
1286 | return ($count, $lines); | |
1287 | } | |
1288 | ||
1289 | sub dir_glob_regex { | |
1290 | my ($dir, $regex) = @_; | |
1291 | ||
1292 | my $dh = IO::Dir->new ($dir); | |
1293 | return wantarray ? () : undef if !$dh; | |
1294 | ||
1295 | while (defined(my $tmp = $dh->read)) { | |
1296 | if (my @res = $tmp =~ m/^($regex)$/) { | |
1297 | $dh->close; | |
1298 | return wantarray ? @res : $tmp; | |
1299 | } | |
1300 | } | |
1301 | $dh->close; | |
1302 | ||
1303 | return wantarray ? () : undef; | |
1304 | } | |
1305 | ||
1306 | sub dir_glob_foreach { | |
1307 | my ($dir, $regex, $func) = @_; | |
1308 | ||
1309 | my $dh = IO::Dir->new ($dir); | |
1310 | if (defined $dh) { | |
1311 | while (defined(my $tmp = $dh->read)) { | |
1312 | if (my @res = $tmp =~ m/^($regex)$/) { | |
1313 | &$func (@res); | |
1314 | } | |
1315 | } | |
1316 | } | |
1317 | } | |
1318 | ||
1319 | sub assert_if_modified { | |
1320 | my ($digest1, $digest2) = @_; | |
1321 | ||
1322 | if ($digest1 && $digest2 && ($digest1 ne $digest2)) { | |
1323 | die "detected modified configuration - file changed by other user? Try again.\n"; | |
1324 | } | |
1325 | } | |
1326 | ||
1327 | # Digest for short strings | |
1328 | # like FNV32a, but we only return 31 bits (positive numbers) | |
1329 | sub fnv31a { | |
1330 | my ($string) = @_; | |
1331 | ||
1332 | my $hval = 0x811c9dc5; | |
1333 | ||
1334 | foreach my $c (unpack('C*', $string)) { | |
1335 | $hval ^= $c; | |
1336 | $hval += ( | |
1337 | (($hval << 1) ) + | |
1338 | (($hval << 4) ) + | |
1339 | (($hval << 7) ) + | |
1340 | (($hval << 8) ) + | |
1341 | (($hval << 24) ) ); | |
1342 | $hval = $hval & 0xffffffff; | |
1343 | } | |
1344 | return $hval & 0x7fffffff; | |
1345 | } | |
1346 | ||
1347 | sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); } | |
1348 | ||
1349 | sub unpack_sockaddr_in46 { | |
1350 | my ($sin) = @_; | |
1351 | my $family = Socket::sockaddr_family($sin); | |
1352 | my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin) | |
1353 | : Socket::unpack_sockaddr_in($sin)); | |
1354 | return ($family, $port, $host); | |
1355 | } | |
1356 | ||
1357 | sub getaddrinfo_all { | |
1358 | my ($hostname, @opts) = @_; | |
1359 | my %hints = ( flags => AI_V4MAPPED | AI_ALL, | |
1360 | @opts ); | |
1361 | my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints); | |
1362 | die "failed to get address info for: $hostname: $err\n" if $err; | |
1363 | return @res; | |
1364 | } | |
1365 | ||
1366 | sub get_host_address_family { | |
1367 | my ($hostname, $socktype) = @_; | |
1368 | my @res = getaddrinfo_all($hostname, socktype => $socktype); | |
1369 | return $res[0]->{family}; | |
1370 | } | |
1371 | ||
1372 | # get the fully qualified domain name of a host | |
1373 | # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns, | |
1374 | # given a nodename as a parameter | |
1375 | sub get_fqdn { | |
1376 | my ($nodename) = @_; | |
1377 | ||
1378 | my $hints = { | |
1379 | flags => AI_CANONNAME, | |
1380 | socktype => SOCK_DGRAM | |
1381 | }; | |
1382 | ||
1383 | my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints); | |
1384 | ||
1385 | die "getaddrinfo: $err" if $err; | |
1386 | ||
1387 | return $addrs[0]->{canonname}; | |
1388 | } | |
1389 | ||
1390 | # Parses any sane kind of host, or host+port pair: | |
1391 | # The port is always optional and thus may be undef. | |
1392 | sub parse_host_and_port { | |
1393 | my ($address) = @_; | |
1394 | if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ || # ipv4 or host with optional ':port' | |
1395 | $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port' | |
1396 | $address =~ /^($IPV6RE)(?:\.(\d+))?$/) # ipv6 with optional port separated by dot | |
1397 | { | |
1398 | return ($1, $2, 1); # end with 1 to support simple if(parse...) tests | |
1399 | } | |
1400 | return; # nothing | |
1401 | } | |
1402 | ||
1403 | sub setresuid($$$) { | |
1404 | my ($ruid, $euid, $suid) = @_; | |
1405 | return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid); | |
1406 | } | |
1407 | ||
1408 | sub unshare($) { | |
1409 | my ($flags) = @_; | |
1410 | return 0 == syscall(PVE::Syscall::unshare, $flags); | |
1411 | } | |
1412 | ||
1413 | sub setns($$) { | |
1414 | my ($fileno, $nstype) = @_; | |
1415 | return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype); | |
1416 | } | |
1417 | ||
1418 | sub syncfs($) { | |
1419 | my ($fileno) = @_; | |
1420 | return 0 == syscall(PVE::Syscall::syncfs, $fileno); | |
1421 | } | |
1422 | ||
1423 | sub fsync($) { | |
1424 | my ($fileno) = @_; | |
1425 | return 0 == syscall(PVE::Syscall::fsync, $fileno); | |
1426 | } | |
1427 | ||
1428 | sub sync_mountpoint { | |
1429 | my ($path) = @_; | |
1430 | sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n"; | |
1431 | my $result = syncfs(fileno($fd)); | |
1432 | close($fd); | |
1433 | return $result; | |
1434 | } | |
1435 | ||
1436 | # support sending multi-part mail messages with a text and or a HTML part | |
1437 | # mailto may be a single email string or an array of receivers | |
1438 | sub sendmail { | |
1439 | my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_; | |
1440 | my $mail_re = qr/[^-a-zA-Z0-9+._@]/; | |
1441 | ||
1442 | $mailto = [ $mailto ] if !ref($mailto); | |
1443 | ||
1444 | foreach (@$mailto) { | |
1445 | die "illegal character in mailto address\n" | |
1446 | if ($_ =~ $mail_re); | |
1447 | } | |
1448 | ||
1449 | my $rcvrtxt = join (', ', @$mailto); | |
1450 | ||
1451 | $mailfrom = $mailfrom || "root"; | |
1452 | die "illegal character in mailfrom address\n" | |
1453 | if $mailfrom =~ $mail_re; | |
1454 | ||
1455 | $author = $author || 'Proxmox VE'; | |
1456 | ||
1457 | open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) || | |
1458 | die "unable to open 'sendmail' - $!"; | |
1459 | ||
1460 | # multipart spec see https://www.ietf.org/rfc/rfc1521.txt | |
1461 | my $boundary = "----_=_NextPart_001_".int(time).$$; | |
1462 | ||
1463 | print MAIL "Content-Type: multipart/alternative;\n"; | |
1464 | print MAIL "\tboundary=\"$boundary\"\n"; | |
1465 | print MAIL "MIME-Version: 1.0\n"; | |
1466 | ||
1467 | print MAIL "FROM: $author <$mailfrom>\n"; | |
1468 | print MAIL "TO: $rcvrtxt\n"; | |
1469 | print MAIL "SUBJECT: $subject\n"; | |
1470 | print MAIL "\n"; | |
1471 | print MAIL "This is a multi-part message in MIME format.\n\n"; | |
1472 | print MAIL "--$boundary\n"; | |
1473 | ||
1474 | if (defined($text)) { | |
1475 | print MAIL "Content-Type: text/plain;\n"; | |
1476 | print MAIL "\tcharset=\"UTF8\"\n"; | |
1477 | print MAIL "Content-Transfer-Encoding: 8bit\n"; | |
1478 | print MAIL "\n"; | |
1479 | ||
1480 | # avoid 'remove extra line breaks' issue (MS Outlook) | |
1481 | my $fill = ' '; | |
1482 | $text =~ s/^/$fill/gm; | |
1483 | ||
1484 | print MAIL $text; | |
1485 | ||
1486 | print MAIL "\n--$boundary\n"; | |
1487 | } | |
1488 | ||
1489 | if (defined($html)) { | |
1490 | print MAIL "Content-Type: text/html;\n"; | |
1491 | print MAIL "\tcharset=\"UTF8\"\n"; | |
1492 | print MAIL "Content-Transfer-Encoding: 8bit\n"; | |
1493 | print MAIL "\n"; | |
1494 | ||
1495 | print MAIL $html; | |
1496 | ||
1497 | print MAIL "\n--$boundary--\n"; | |
1498 | } | |
1499 | ||
1500 | close(MAIL); | |
1501 | } | |
1502 | ||
1503 | sub tempfile { | |
1504 | my ($perm, %opts) = @_; | |
1505 | ||
1506 | # default permissions are stricter than with file_set_contents | |
1507 | $perm = 0600 if !defined($perm); | |
1508 | ||
1509 | my $dir = $opts{dir} // '/run'; | |
1510 | my $mode = $opts{mode} // O_RDWR; | |
1511 | $mode |= O_EXCL if !$opts{allow_links}; | |
1512 | ||
1513 | my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm); | |
1514 | if (!$fh && $! == EOPNOTSUPP) { | |
1515 | $dir = '/tmp' if !defined($opts{dir}); | |
1516 | $dir .= "/.tmpfile.$$"; | |
1517 | $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm); | |
1518 | unlink($dir) if $fh; | |
1519 | } | |
1520 | die "failed to create tempfile: $!\n" if !$fh; | |
1521 | return $fh; | |
1522 | } | |
1523 | ||
1524 | sub tempfile_contents { | |
1525 | my ($data, $perm, %opts) = @_; | |
1526 | ||
1527 | my $fh = tempfile($perm, %opts); | |
1528 | eval { | |
1529 | die "unable to write to tempfile: $!\n" if !print {$fh} $data; | |
1530 | die "unable to flush to tempfile: $!\n" if !defined($fh->flush()); | |
1531 | }; | |
1532 | if (my $err = $@) { | |
1533 | close $fh; | |
1534 | die $err; | |
1535 | } | |
1536 | ||
1537 | return ("/proc/$$/fd/".$fh->fileno, $fh); | |
1538 | } | |
1539 | ||
1540 | sub validate_ssh_public_keys { | |
1541 | my ($raw) = @_; | |
1542 | my @lines = split(/\n/, $raw); | |
1543 | ||
1544 | foreach my $line (@lines) { | |
1545 | next if $line =~ m/^\s*$/; | |
1546 | eval { | |
1547 | my ($filename, $handle) = tempfile_contents($line); | |
1548 | run_command(["ssh-keygen", "-l", "-f", $filename], | |
1549 | outfunc => sub {}, errfunc => sub {}); | |
1550 | }; | |
1551 | die "SSH public key validation error\n" if $@; | |
1552 | } | |
1553 | } | |
1554 | ||
1555 | sub openat($$$;$) { | |
1556 | my ($dirfd, $pathname, $flags, $mode) = @_; | |
1557 | my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0); | |
1558 | return undef if $fd < 0; | |
1559 | # sysopen() doesn't deal with numeric file descriptors apparently | |
1560 | # so we need to convert to a mode string for IO::Handle->new_from_fd | |
1561 | my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r'; | |
1562 | my $handle = IO::Handle->new_from_fd($fd, $flagstr); | |
1563 | return $handle if $handle; | |
1564 | my $err = $!; # save error before closing the raw fd | |
1565 | syscall(PVE::Syscall::close, $fd); # close | |
1566 | $! = $err; | |
1567 | return undef; | |
1568 | } | |
1569 | ||
1570 | sub mkdirat($$$) { | |
1571 | my ($dirfd, $name, $mode) = @_; | |
1572 | return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0; | |
1573 | } | |
1574 | ||
1575 | sub fchownat($$$$$) { | |
1576 | my ($dirfd, $pathname, $owner, $group, $flags) = @_; | |
1577 | return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0; | |
1578 | } | |
1579 | ||
1580 | my $salt_starter = time(); | |
1581 | ||
1582 | sub encrypt_pw { | |
1583 | my ($pw) = @_; | |
1584 | ||
1585 | $salt_starter++; | |
1586 | my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8); | |
1587 | ||
1588 | # crypt does not want '+' in salt (see 'man crypt') | |
1589 | $salt =~ s/\+/X/g; | |
1590 | ||
1591 | return crypt(encode("utf8", $pw), "\$5\$$salt\$"); | |
1592 | } | |
1593 | ||
1594 | # intended usage: convert_size($val, "kb" => "gb") | |
1595 | # we round up to the next integer by default | |
1596 | # E.g. `convert_size(1023, "b" => "kb")` returns 1 | |
1597 | # use $no_round_up to switch this off, above example would then return 0 | |
1598 | # this is also true for converting down e.g. 0.0005 gb to mb returns 1 | |
1599 | # (0 if $no_round_up is true) | |
1600 | # allowed formats for value: | |
1601 | # 1234 | |
1602 | # 1234. | |
1603 | # 1234.1234 | |
1604 | # .1234 | |
1605 | sub convert_size { | |
1606 | my ($value, $from, $to, $no_round_up) = @_; | |
1607 | ||
1608 | my $units = { | |
1609 | b => 0, | |
1610 | kb => 1, | |
1611 | mb => 2, | |
1612 | gb => 3, | |
1613 | tb => 4, | |
1614 | pb => 5, | |
1615 | }; | |
1616 | ||
1617 | die "no value given" | |
1618 | if !defined($value) || $value eq ""; | |
1619 | ||
1620 | $from = lc($from // ''); $to = lc($to // ''); | |
1621 | die "unknown 'from' and/or 'to' units ($from => $to)" | |
1622 | if !defined($units->{$from}) || !defined($units->{$to}); | |
1623 | ||
1624 | die "value '$value' is not a valid, positive number" | |
1625 | if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/; | |
1626 | ||
1627 | my $shift_amount = ($units->{$from} - $units->{$to}) * 10; | |
1628 | ||
1629 | $value *= 2**$shift_amount; | |
1630 | $value++ if !$no_round_up && ($value - int($value)) > 0.0; | |
1631 | ||
1632 | return int($value); | |
1633 | } | |
1634 | ||
1635 | # uninterruptible readline | |
1636 | # retries on EINTR | |
1637 | sub readline_nointr { | |
1638 | my ($fh) = @_; | |
1639 | my $line; | |
1640 | while (1) { | |
1641 | $line = <$fh>; | |
1642 | last if defined($line) || ($! != EINTR); | |
1643 | } | |
1644 | return $line; | |
1645 | } | |
1646 | ||
1647 | my $host_arch; | |
1648 | sub get_host_arch { | |
1649 | $host_arch = (POSIX::uname())[4] if !$host_arch; | |
1650 | return $host_arch; | |
1651 | } | |
1652 | ||
1653 | # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ] | |
1654 | sub dev_t_major($) { | |
1655 | my ($dev_t) = @_; | |
1656 | return (int($dev_t) & 0xfff00) >> 8; | |
1657 | } | |
1658 | ||
1659 | sub dev_t_minor($) { | |
1660 | my ($dev_t) = @_; | |
1661 | $dev_t = int($dev_t); | |
1662 | return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff); | |
1663 | } | |
1664 | ||
1665 | # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ] | |
1666 | # Returns the intersection of elements as a single array [a b] | |
1667 | sub array_intersect { | |
1668 | my ($arrays) = @_; | |
1669 | ||
1670 | if (!ref($arrays->[0])) { | |
1671 | $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ]; | |
1672 | } | |
1673 | ||
1674 | return [] if scalar(@$arrays) == 0; | |
1675 | return $arrays->[0] if scalar(@$arrays) == 1; | |
1676 | ||
1677 | my $array_unique = sub { | |
1678 | my %seen = (); | |
1679 | return grep { ! $seen{ $_ }++ } @_; | |
1680 | }; | |
1681 | ||
1682 | # base idea is to get all unique members from the first array, then | |
1683 | # check the common elements with the next (uniquely made) one, only keep | |
1684 | # those. Repeat for every array and at the end we only have those left | |
1685 | # which exist in all arrays | |
1686 | my $return_arr = [ $array_unique->(@{$arrays->[0]}) ]; | |
1687 | for my $i (1 .. $#$arrays) { | |
1688 | my %count = (); | |
1689 | # $return_arr is already unique, explicit at before the loop, implicit below. | |
1690 | foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) { | |
1691 | $count{$element}++; | |
1692 | } | |
1693 | $return_arr = []; | |
1694 | foreach my $element (keys %count) { | |
1695 | push @$return_arr, $element if $count{$element} > 1; | |
1696 | } | |
1697 | last if scalar(@$return_arr) == 0; # empty intersection, early exit | |
1698 | } | |
1699 | ||
1700 | return $return_arr; | |
1701 | } | |
1702 | ||
1703 | sub open_tree($$$) { | |
1704 | my ($dfd, $pathname, $flags) = @_; | |
1705 | return PVE::Syscall::file_handle_result(syscall( | |
1706 | &PVE::Syscall::open_tree, | |
1707 | $dfd, | |
1708 | $pathname, | |
1709 | $flags, | |
1710 | )); | |
1711 | } | |
1712 | ||
1713 | sub move_mount($$$$$) { | |
1714 | my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_; | |
1715 | return 0 == syscall( | |
1716 | &PVE::Syscall::move_mount, | |
1717 | $from_dirfd, | |
1718 | $from_pathname, | |
1719 | $to_dirfd, | |
1720 | $to_pathname, | |
1721 | $flags, | |
1722 | ); | |
1723 | } | |
1724 | ||
1725 | sub fsopen($$) { | |
1726 | my ($fsname, $flags) = @_; | |
1727 | return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags)); | |
1728 | } | |
1729 | ||
1730 | sub fsmount($$$) { | |
1731 | my ($fd, $flags, $mount_attrs) = @_; | |
1732 | return PVE::Syscall::file_handle_result(syscall( | |
1733 | &PVE::Syscall::fsmount, | |
1734 | $fd, | |
1735 | $flags, | |
1736 | $mount_attrs, | |
1737 | )); | |
1738 | } | |
1739 | ||
1740 | sub fspick($$$) { | |
1741 | my ($dirfd, $pathname, $flags) = @_; | |
1742 | return PVE::Syscall::file_handle_result(syscall( | |
1743 | &PVE::Syscall::fspick, | |
1744 | $dirfd, | |
1745 | $pathname, | |
1746 | $flags, | |
1747 | )); | |
1748 | } | |
1749 | ||
1750 | sub fsconfig($$$$$) { | |
1751 | my ($fd, $command, $key, $value, $aux) = @_; | |
1752 | return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux); | |
1753 | } | |
1754 | ||
1755 | # "raw" mount, old api, not for generic use (as it does not invoke any helpers). | |
1756 | # use for lower level stuff such as bind/remount/... or simple tmpfs mounts | |
1757 | sub mount($$$$$) { | |
1758 | my ($source, $target, $filesystemtype, $mountflags, $data) = @_; | |
1759 | return 0 == syscall( | |
1760 | &PVE::Syscall::mount, | |
1761 | $source, | |
1762 | $target, | |
1763 | $filesystemtype, | |
1764 | $mountflags, | |
1765 | $data, | |
1766 | ); | |
1767 | } | |
1768 | ||
1769 | 1; |