src/PVE/CLIHandler.pm

   1 package PVE::CLIHandler;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Exception qw(raise raise_param_exc);
   8 use PVE::RESTHandler;
   9 use PVE::INotify;
  10
  11 use base qw(PVE::RESTHandler);
  12
  13 # $cmddef defines which (sub)commands are available in a specific CLI class.
  14 # A real command is always an array consisting of its class, name, array of
  15 # position fixed (required) parameters and hash of predefined parameters when
  16 # mapping a CLI command t o an API call. Optionally an output method can be
  17 # passed at the end, e.g., for formatting or transformation purpose.
  18 #
  19 # [class, name, fixed_params, API_pre-set params, output_sub ]
  20 #
  21 # In case of so called 'simple commands', the $cmddef can be also just an
  22 # array.
  23 #
  24 # Examples:
  25 # $cmddef = {
  26 #     command => [ 'PVE::API2::Class', 'command', [ 'arg1', 'arg2' ], { node => $nodename } ],
  27 #     do => {
  28 #         this => [ 'PVE::API2::OtherClass', 'method', [ 'arg1' ], undef, sub {
  29 #             my ($res) = @_;
  30 #             print "$res\n";
  31 #         }],
  32 #         that => [ 'PVE::API2::OtherClass', 'subroutine' [] ],
  33 #     },
  34 #     dothat => { alias => 'do that' },
  35 # }
  36 my $cmddef;
  37 my $exename;
  38 my $cli_handler_class;
  39
  40 my $assert_initialized = sub {
  41     my @caller = caller;
  42     die "$caller[0]:$caller[2] - not initialized\n"
  43         if !($cmddef && $exename && $cli_handler_class);
  44 };
  45
  46 my $abort = sub {
  47     my ($reason, $cmd) = @_;
  48     print_usage_short (\*STDERR, $reason, $cmd);
  49     exit (-1);
  50 };
  51
  52 my $expand_command_name = sub {
  53     my ($def, $cmd) = @_;
  54
  55     return $cmd if exists $def->{$cmd}; # command is already complete
  56
  57     my $is_alias = sub { ref($_[0]) eq 'HASH' && exists($_[0]->{alias}) };
  58     my @expanded = grep { /^\Q$cmd\E/ && !$is_alias->($def->{$_}) } keys %$def;
  59
  60     return $expanded[0] if scalar(@expanded) == 1; # enforce exact match
  61
  62     return undef;
  63 };
  64
  65 my $get_commands = sub {
  66     my $def = shift // die "no command definition passed!";
  67     return [ grep { !(ref($def->{$_}) eq 'HASH' && defined($def->{$_}->{alias})) } sort keys %$def ];
  68 };
  69
  70 my $complete_command_names = sub { $get_commands->($cmddef) };
  71
  72 # traverses the command definition using the $argv array, resolving one level
  73 # of aliases.
  74 # Returns the matching (sub) command and its definition, and argument array for
  75 # this (sub) command and a hash where we marked which (sub) commands got
  76 # expanded (e.g. st => status) while traversing
  77 sub resolve_cmd {
  78     my ($argv, $is_alias) = @_;
  79
  80     my ($def, $cmd) = ($cmddef, $argv);
  81     my $cmdstr = $exename;
  82
  83     if (ref($argv) eq 'ARRAY') {
  84         my $expanded_last_arg;
  85         my $last_arg_id = scalar(@$argv) - 1;
  86
  87         for my $i (0..$last_arg_id) {
  88             $cmd = $expand_command_name->($def, $argv->[$i]);
  89             if (defined($cmd)) {
  90                 # If the argument was expanded (or was already complete) and it
  91                 # is the final argument, tell our caller about it:
  92                 $expanded_last_arg = $cmd if $i == $last_arg_id;
  93             } else {
  94                 # Otherwise continue with the unexpanded version of it.
  95                 $cmd = $argv->[$i];
  96             }
  97             $cmdstr .= " $cmd";
  98             $def = $def->{$cmd};
  99             last if !defined($def);
 100
 101             if (ref($def) eq 'ARRAY') {
 102                 # could expand to a real command, rest of $argv are its arguments
 103                 my $cmd_args = [ @$argv[$i+1..$last_arg_id] ];
 104                 return ($cmd, $def, $cmd_args, $expanded_last_arg, $cmdstr);
 105             }
 106
 107             if (defined($def->{alias})) {
 108                 die "alias loop detected for '$cmd'" if $is_alias; # avoids cycles
 109                 # replace aliased (sub)command with the expanded aliased command
 110                 splice @$argv, $i, 1, split(/ +/, $def->{alias});
 111                 return resolve_cmd($argv, 1);
 112             }
 113         }
 114         # got either a special command (bashcomplete, verifyapi) or an unknown
 115         # cmd, just return first entry as cmd and the rest of $argv as cmd_arg
 116         my $cmd_args = [ @$argv[1..$last_arg_id] ];
 117         return ($argv->[0], $def, $cmd_args, $expanded_last_arg, $cmdstr);
 118     }
 119     return ($cmd, $def, undef, undef, $cmdstr);
 120 }
 121
 122 sub generate_usage_str {
 123     my ($format, $cmd, $indent, $separator, $sortfunc) = @_;
 124
 125     $assert_initialized->();
 126     die 'format required' if !$format;
 127
 128     $sortfunc //= sub { sort keys %{$_[0]} };
 129     $separator //= '';
 130     $indent //= '';
 131
 132     my $read_password_func = $cli_handler_class->can('read_password');
 133     my $param_mapping_func = $cli_handler_class->can('param_mapping') ||
 134         $cli_handler_class->can('string_param_file_mapping');
 135
 136     my ($subcmd, $def, undef, undef, $cmdstr) = resolve_cmd($cmd);
 137     $abort->("unknown command '$cmdstr'") if !defined($def) && ref($cmd) eq 'ARRAY';
 138
 139     my $generate;
 140     $generate = sub {
 141         my ($indent, $separator, $def, $prefix) = @_;
 142
 143         my $str = '';
 144         if (ref($def) eq 'HASH') {
 145             my $oldclass = undef;
 146             foreach my $cmd (&$sortfunc($def)) {
 147
 148                 if (ref($def->{$cmd}) eq 'ARRAY') {
 149                     my ($class, $name, $arg_param, $fixed_param) = @{$def->{$cmd}};
 150
 151                     $str .= $separator if $oldclass && $oldclass ne $class;
 152                     $str .= $indent;
 153                     $str .= $class->usage_str($name, "$prefix $cmd", $arg_param,
 154                                               $fixed_param, $format,
 155                                               $read_password_func, $param_mapping_func);
 156                     $oldclass = $class;
 157
 158                 } elsif (defined($def->{$cmd}->{alias}) && ($format eq 'asciidoc')) {
 159
 160                     $str .= "*$prefix $cmd*\n\nAn alias for '$exename $def->{$cmd}->{alias}'.\n\n";
 161
 162                 } else {
 163                     next if $def->{$cmd}->{alias};
 164
 165                     my $substr = $generate->($indent, $separator, $def->{$cmd}, "$prefix $cmd");
 166                     if ($substr) {
 167                         $substr .= $separator if $substr !~ /\Q$separator\E{2}/;
 168                         $str .= $substr;
 169                     }
 170                 }
 171
 172             }
 173         } else {
 174             my ($class, $name, $arg_param, $fixed_param) = @$def;
 175             $abort->("unknown command '$cmd'") if !$class;
 176
 177             $str .= $indent;
 178             $str .= $class->usage_str($name, $prefix, $arg_param, $fixed_param, $format,
 179                                       $read_password_func, $param_mapping_func);
 180         }
 181         return $str;
 182     };
 183
 184     return $generate->($indent, $separator, $def, $cmdstr);
 185 }
 186
 187 __PACKAGE__->register_method ({
 188     name => 'help',
 189     path => 'help',
 190     method => 'GET',
 191     description => "Get help about specified command.",
 192     parameters => {
 193         additionalProperties => 0,
 194         properties => {
 195             'extra-args' => PVE::JSONSchema::get_standard_option('extra-args', {
 196                 description => 'Shows help for a specific command',
 197                 completion => $complete_command_names,
 198             }),
 199             verbose => {
 200                 description => "Verbose output format.",
 201                 type => 'boolean',
 202                 optional => 1,
 203             },
 204         },
 205     },
 206     returns => { type => 'null' },
 207
 208     code => sub {
 209         my ($param) = @_;
 210
 211         $assert_initialized->();
 212
 213         my $cmd = $param->{'extra-args'};
 214
 215         my $verbose = defined($cmd) && $cmd;
 216         $verbose = $param->{verbose} if defined($param->{verbose});
 217
 218         if (!$cmd) {
 219             if ($verbose) {
 220                 print_usage_verbose();
 221             } else {
 222                 print_usage_short(\*STDOUT);
 223             }
 224             return undef;
 225         }
 226
 227         my $str;
 228         if ($verbose) {
 229             $str = generate_usage_str('full', $cmd, '');
 230         } else {
 231             $str = generate_usage_str('short', $cmd, ' ' x 7);
 232         }
 233         $str =~ s/^\s+//;
 234
 235         if ($verbose) {
 236             print "$str\n";
 237         } else {
 238             print "USAGE: $str\n";
 239         }
 240
 241         return undef;
 242
 243     }});
 244
 245 sub print_simple_asciidoc_synopsis {
 246     $assert_initialized->();
 247
 248     my $synopsis = "*${exename}* `help`\n\n";
 249     $synopsis .= generate_usage_str('asciidoc');
 250
 251     return $synopsis;
 252 }
 253
 254 sub print_asciidoc_synopsis {
 255     $assert_initialized->();
 256
 257     my $synopsis = "";
 258
 259     $synopsis .= "*${exename}* `<COMMAND> [ARGS] [OPTIONS]`\n\n";
 260
 261     $synopsis .= generate_usage_str('asciidoc');
 262
 263     $synopsis .= "\n";
 264
 265     return $synopsis;
 266 }
 267
 268 sub print_usage_verbose {
 269     $assert_initialized->();
 270
 271     print "USAGE: $exename <COMMAND> [ARGS] [OPTIONS]\n\n";
 272
 273     my $str = generate_usage_str('full');
 274
 275     print "$str\n";
 276 }
 277
 278 sub print_usage_short {
 279     my ($fd, $msg, $cmd) = @_;
 280
 281     $assert_initialized->();
 282
 283     print $fd "ERROR: $msg\n" if $msg;
 284     print $fd "USAGE: $exename <COMMAND> [ARGS] [OPTIONS]\n";
 285
 286     print {$fd} generate_usage_str('short', $cmd, ' ' x 7, "\n", sub {
 287         my ($h) = @_;
 288         return sort {
 289             if (ref($h->{$a}) eq 'ARRAY' && ref($h->{$b}) eq 'ARRAY') {
 290                 # $a and $b are both real commands order them by their class
 291                 return $h->{$a}->[0] cmp $h->{$b}->[0] || $a cmp $b;
 292             } elsif (ref($h->{$a}) eq 'ARRAY' xor ref($h->{$b}) eq 'ARRAY') {
 293                 # real command and subcommand mixed, put sub commands first
 294                 return ref($h->{$b}) eq 'ARRAY' ? -1 : 1;
 295             } else {
 296                 # both are either from the same class or subcommands
 297                 return $a cmp $b;
 298             }
 299         } keys %$h;
 300     });
 301 }
 302
 303 my $print_bash_completion = sub {
 304     my ($simple_cmd, $bash_command, $cur, $prev) = @_;
 305
 306     my $debug = 0;
 307
 308     return if !(defined($cur) && defined($prev) && defined($bash_command));
 309     return if !defined($ENV{COMP_LINE});
 310     return if !defined($ENV{COMP_POINT});
 311
 312     my $cmdline = substr($ENV{COMP_LINE}, 0, $ENV{COMP_POINT});
 313     print STDERR "\nCMDLINE: $ENV{COMP_LINE}\n" if $debug;
 314
 315     my $args = PVE::Tools::split_args($cmdline);
 316     shift @$args; # no need for program name
 317     my $print_result = sub {
 318         foreach my $p (@_) {
 319             print "$p\n" if $p =~ m/^\Q$cur\E/;
 320         }
 321     };
 322
 323     my ($cmd, $def) = ($simple_cmd, $cmddef);
 324     if (!$simple_cmd) {
 325         ($cmd, $def, $args, my $expanded) = resolve_cmd($args);
 326
 327         if (defined($expanded) && $prev ne $expanded) {
 328             print "$expanded\n";
 329             return;
 330         }
 331
 332         if (ref($def) eq 'HASH') {
 333             &$print_result(@{$get_commands->($def)});
 334             return;
 335         }
 336     }
 337     return if !$def;
 338
 339     my $pos = scalar(@$args) - 1;
 340     $pos += 1 if $cmdline =~ m/\s+$/;
 341     print STDERR "pos: $pos\n" if $debug;
 342     return if $pos < 0;
 343
 344     my $skip_param = {};
 345
 346     my ($class, $name, $arg_param, $uri_param) = @$def;
 347     $arg_param //= [];
 348     $uri_param //= {};
 349
 350     $arg_param = [ $arg_param ] if !ref($arg_param);
 351
 352     map { $skip_param->{$_} = 1; } @$arg_param;
 353     map { $skip_param->{$_} = 1; } keys %$uri_param;
 354
 355     my $info = $class->map_method_by_name($name);
 356
 357     my $prop = $info->{parameters}->{properties};
 358
 359     my $print_parameter_completion = sub {
 360         my ($pname) = @_;
 361         my $d = $prop->{$pname};
 362         if ($d->{completion}) {
 363             my $vt = ref($d->{completion});
 364             if ($vt eq 'CODE') {
 365                 my $res = $d->{completion}->($cmd, $pname, $cur, $args);
 366                 &$print_result(@$res);
 367             }
 368         } elsif ($d->{type} eq 'boolean') {
 369             &$print_result('0', '1');
 370         } elsif ($d->{enum}) {
 371             &$print_result(@{$d->{enum}});
 372         }
 373     };
 374
 375     # positional arguments
 376     if ($pos < scalar(@$arg_param)) {
 377         my $pname = $arg_param->[$pos];
 378         &$print_parameter_completion($pname);
 379         return;
 380     }
 381
 382     my @option_list = ();
 383     foreach my $key (keys %$prop) {
 384         next if $skip_param->{$key};
 385         push @option_list, "--$key";
 386     }
 387
 388     if ($cur =~ m/^-/) {
 389         &$print_result(@option_list);
 390         return;
 391     }
 392
 393     if ($prev =~ m/^--?(.+)$/ && $prop->{$1}) {
 394         my $pname = $1;
 395         &$print_parameter_completion($pname);
 396         return;
 397     }
 398
 399     &$print_result(@option_list);
 400 };
 401
 402 # prints a formatted table with a title row.
 403 # $formatopts is an array of hashes, with the following keys:
 404 # 'key' - key of $data element to print
 405 # 'title' - column title, defaults to 'key' - won't get cutoff
 406 # 'cutoff' - maximal (print) length of this column values, if set
 407 #            the last column will never be cutoff
 408 # 'default' - optional default value for the column
 409 # formatopts element order defines column order (left to right)
 410 sub print_text_table {
 411     my ($formatopts, $data) = @_;
 412     my ($formatstring, @keys, @titles, %cutoffs, %defaults, $last_col);
 413
 414     $last_col = $formatopts->[$#{$formatopts}];
 415     foreach my $col ( @$formatopts ) {
 416         my ($key, $title, $cutoff, $default) = @$col{ qw(key title cutoff default)};
 417         $title //= $key;
 418
 419         push @keys, $key;
 420         push @titles, $title;
 421         $defaults{$key} = $default;
 422
 423         #calculate maximal print width and cutoff
 424         my $titlelen = length($title);
 425
 426         my $longest = $titlelen;
 427         foreach my $entry (@$data) {
 428             my $len = length($entry->{$key}) // 0;
 429             $longest = $len if $len > $longest;
 430         }
 431
 432         $cutoff = (defined($cutoff) && $cutoff < $longest) ? $cutoff : $longest;
 433         $cutoffs{$key} = $cutoff;
 434
 435         my $printalign = $cutoff > $titlelen ? '-' : '';
 436         if ($col == $last_col) {
 437             $formatstring .= "%${printalign}${titlelen}s\n";
 438         } else {
 439             $formatstring .= "%${printalign}${cutoff}s ";
 440         }
 441     }
 442
 443     printf $formatstring, @titles;
 444
 445     foreach my $entry (sort { $a->{$keys[0]} cmp $b->{$keys[0]} } @$data){
 446         printf $formatstring, map { substr(($entry->{$_} // $defaults{$_}), 0 , $cutoffs{$_}) } @keys;
 447     }
 448 }
 449
 450 sub print_entry {
 451     my $entry = shift;
 452     #TODO: handle objects/hashes as well
 453     foreach my $item (sort keys %$entry) {
 454         if (ref($entry->{$item}) eq 'ARRAY'){
 455             printf "%s: [ %s ]\n", $item, join(", ", @{$entry->{$item}});
 456         } else {
 457             printf "%s: %s\n", $item, $entry->{$item};
 458         }
 459     }
 460 }
 461
 462 # prints the result of an API GET call returning an array
 463 # and to have the results key of the API call defined.
 464 sub print_api_list {
 465     my ($props_to_print, $data, $returninfo) = @_;
 466     my $formatopts;
 467     my $returnprops = $returninfo->{items}->{properties};
 468     foreach my $prop ( @$props_to_print ) {
 469         my $propinfo = $returnprops->{$prop};
 470         my $colopts = {
 471             key => $prop,
 472             title => $propinfo->{title},
 473             default => $propinfo->{default},
 474             cutoff => $propinfo->{print_width} // $propinfo->{maxLength},
 475         };
 476         push @$formatopts, $colopts;
 477     }
 478
 479     print_text_table($formatopts, $data);
 480 }
 481
 482 sub verify_api {
 483     my ($class) = @_;
 484
 485     # simply verify all registered methods
 486     PVE::RESTHandler::validate_method_schemas();
 487 }
 488
 489 my $get_exe_name = sub {
 490     my ($class) = @_;
 491
 492     my $name = $class;
 493     $name =~ s/^.*:://;
 494     $name =~ s/_/-/g;
 495
 496     return $name;
 497 };
 498
 499 sub generate_bash_completions {
 500     my ($class) = @_;
 501
 502     # generate bash completion config
 503
 504     $exename = &$get_exe_name($class);
 505
 506     print <<__EOD__;
 507 # $exename bash completion
 508
 509 # see http://tiswww.case.edu/php/chet/bash/FAQ
 510 # and __ltrim_colon_completions() in /usr/share/bash-completion/bash_completion
 511 # this modifies global var, but I found no better way
 512 COMP_WORDBREAKS=\${COMP_WORDBREAKS//:}
 513
 514 complete -o default -C '$exename bashcomplete' $exename
 515 __EOD__
 516 }
 517
 518 sub generate_asciidoc_synopsys {
 519     my ($class) = @_;
 520     $class->generate_asciidoc_synopsis();
 521 };
 522
 523 sub generate_asciidoc_synopsis {
 524     my ($class) = @_;
 525
 526     $cli_handler_class = $class;
 527
 528     $exename = &$get_exe_name($class);
 529
 530     no strict 'refs';
 531     my $def = ${"${class}::cmddef"};
 532     $cmddef = $def;
 533
 534     if (ref($def) eq 'ARRAY') {
 535         print_simple_asciidoc_synopsis();
 536     } else {
 537         $cmddef->{help} = [ __PACKAGE__, 'help', ['cmd'] ];
 538
 539         print_asciidoc_synopsis();
 540     }
 541 }
 542
 543 # overwrite this if you want to run/setup things early
 544 sub setup_environment {
 545     my ($class) = @_;
 546
 547     # do nothing by default
 548 }
 549
 550 my $handle_cmd  = sub {
 551     my ($args, $read_password_func, $preparefunc, $param_mapping_func) = @_;
 552
 553     $cmddef->{help} = [ __PACKAGE__, 'help', ['extra-args'] ];
 554
 555     my ($cmd, $def, $cmd_args, undef, $cmd_str) = resolve_cmd($args);
 556
 557     $abort->("no command specified") if !$cmd;
 558
 559     # call verifyapi before setup_environment(), don't execute any real code in
 560     # this case
 561     if ($cmd eq 'verifyapi') {
 562         PVE::RESTHandler::validate_method_schemas();
 563         return;
 564     }
 565
 566     $cli_handler_class->setup_environment();
 567
 568     if ($cmd eq 'bashcomplete') {
 569         &$print_bash_completion(undef, @$cmd_args);
 570         return;
 571     }
 572
 573     # checked special commands, if def is still a hash we got an incomplete sub command
 574     $abort->("incomplete command '$cmd_str'", $args) if ref($def) eq 'HASH';
 575
 576     &$preparefunc() if $preparefunc;
 577
 578     my ($class, $name, $arg_param, $uri_param, $outsub) = @{$def || []};
 579     $abort->("unknown command '$cmd_str'") if !$class;
 580
 581     my $res = $class->cli_handler($cmd_str, $name, $cmd_args, $arg_param, $uri_param, $read_password_func, $param_mapping_func);
 582
 583     if (defined $outsub) {
 584         my $returninfo = $class->map_method_by_name($name)->{returns};
 585         $outsub->($res, $returninfo);
 586     }
 587 };
 588
 589 my $handle_simple_cmd = sub {
 590     my ($args, $read_password_func, $preparefunc, $param_mapping_func) = @_;
 591
 592     my ($class, $name, $arg_param, $uri_param, $outsub) = @{$cmddef};
 593     die "no class specified" if !$class;
 594
 595     if (scalar(@$args) >= 1) {
 596         if ($args->[0] eq 'help') {
 597             my $str = "USAGE: $name help\n";
 598             $str .= generate_usage_str('long');
 599             print STDERR "$str\n\n";
 600             return;
 601         } elsif ($args->[0] eq 'verifyapi') {
 602             PVE::RESTHandler::validate_method_schemas();
 603             return;
 604         }
 605     }
 606
 607     $cli_handler_class->setup_environment();
 608
 609     if (scalar(@$args) >= 1) {
 610         if ($args->[0] eq 'bashcomplete') {
 611             shift @$args;
 612             &$print_bash_completion($name, @$args);
 613             return;
 614         }
 615     }
 616
 617     &$preparefunc() if $preparefunc;
 618
 619     my $res = $class->cli_handler($name, $name, \@ARGV, $arg_param, $uri_param, $read_password_func, $param_mapping_func);
 620
 621     if (defined $outsub) {
 622         my $returninfo = $class->map_method_by_name($name)->{returns};
 623         $outsub->($res, $returninfo);
 624     }
 625 };
 626
 627 sub run_cli_handler {
 628     my ($class, %params) = @_;
 629
 630     $cli_handler_class = $class;
 631
 632     $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
 633
 634     foreach my $key (keys %params) {
 635         next if $key eq 'prepare';
 636         next if $key eq 'no_init'; # not used anymore
 637         next if $key eq 'no_rpcenv'; # not used anymore
 638         die "unknown parameter '$key'";
 639     }
 640
 641     my $preparefunc = $params{prepare};
 642
 643     my $read_password_func = $class->can('read_password');
 644     my $param_mapping_func = $cli_handler_class->can('param_mapping') ||
 645         $class->can('string_param_file_mapping');
 646
 647     $exename = &$get_exe_name($class);
 648
 649     initlog($exename);
 650
 651     no strict 'refs';
 652     $cmddef = ${"${class}::cmddef"};
 653
 654     if (ref($cmddef) eq 'ARRAY') {
 655         &$handle_simple_cmd(\@ARGV, $read_password_func, $preparefunc, $param_mapping_func);
 656     } else {
 657         &$handle_cmd(\@ARGV, $read_password_func, $preparefunc, $param_mapping_func);
 658     }
 659
 660     exit 0;
 661 }
 662
 663 1;