src/PVE/CpuSet.pm

   1 package PVE::CpuSet;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::Tools;
   6 use PVE::ProcFSTools;
   7
   8 sub new {
   9     my ($class, $members) = @_;
  10
  11     $members //= {};
  12     my $self = bless { members => $members }, $class;
  13
  14     return $self;
  15 }
  16
  17 # Create a new set with the contents of a cgroup-v1 subdirectory
  18 sub new_from_cgroup {
  19     my ($class, $cgroup, $effective) = @_;
  20
  21     my $kind = $effective ? 'effective_cpus' : 'cpus';
  22
  23     my $filename = "/sys/fs/cgroup/cpuset/$cgroup/cpuset.$kind";
  24     my $set_text = PVE::Tools::file_read_firstline($filename) // '';
  25
  26     my ($count, $members) = parse_cpuset($set_text);
  27
  28     die "got empty cpuset for cgroup '$cgroup'\n"
  29         if !$count;
  30
  31     return $class->new($members);
  32 }
  33
  34 sub parse_cpuset {
  35     my ($set_text) = @_;
  36
  37     my $members = {};
  38     my $count = 0;
  39
  40     foreach my $part (split(/,/, $set_text)) {
  41         if ($part =~ /^\s*(\d+)(?:-(\d+))?\s*$/) {
  42             my ($from, $to) = ($1, $2);
  43             $to //= $1;
  44             die "invalid range: $part ($to < $from)\n" if $to < $from;
  45             for (my $i = $from; $i <= $to; $i++) {
  46                 $members->{$i} = 1;
  47                 $count++;
  48             };
  49         } else {
  50             die "invalid range: $part\n";
  51         }
  52     }
  53
  54     return ($count, $members);
  55 }
  56
  57 sub write_to_cgroup {
  58     my ($self, $cgroup) = @_;
  59
  60     my $filename = "/sys/fs/cgroup/cpuset/$cgroup/cpuset.cpus";
  61
  62     my $value = '';
  63     my @members = $self->members();
  64     foreach my $cpuid (@members) {
  65         $value .= ',' if length($value);
  66         $value .= $cpuid;
  67     }
  68
  69     die "unable to write empty cpu set\n" if !length($value);
  70
  71     open(my $fh, '>', $filename) || die "failed to open '$filename' - $!\n";
  72     PVE::Tools::safe_print($filename, $fh, "$value\n");
  73     close($fh) || die "failed to close '$filename' - $!\n";
  74 }
  75
  76 sub insert {
  77     my ($self, @members) = @_;
  78
  79     my $count = 0;
  80
  81     foreach my $cpu (@members) {
  82         next if $self->{members}->{$cpu};
  83         $self->{members}->{$cpu} = 1;
  84         $count++;
  85     }
  86
  87     return $count;
  88 }
  89
  90 sub delete {
  91     my ($self, @members) = @_;
  92
  93     my $count = 0;
  94
  95     foreach my $cpu (@members) {
  96         next if !$self->{members}->{$cpu};
  97         delete $self->{members}->{$cpu};
  98         $count++;
  99     }
 100
 101     return $count;
 102 }
 103
 104 sub has {
 105    my ($self, $cpuid) = @_;
 106
 107    return $self->{members}->{$cpuid};
 108 }
 109
 110 # members: this list is always sorted!
 111 sub members {
 112     my ($self) = @_;
 113
 114     return sort { $a <=> $b } keys %{$self->{members}};
 115 }
 116
 117 sub size {
 118     my ($self) = @_;
 119
 120     return scalar(keys %{$self->{members}});
 121 }
 122
 123 sub is_equal {
 124     my ($self, $set2) = @_;
 125
 126     my $members1 = $self->{members};
 127     my $members2 = $set2->{members};
 128
 129     foreach my $id (keys %$members1) {
 130         return 0 if !$members2->{$id};
 131     }
 132     foreach my $id (keys %$members2) {
 133         return 0 if !$members1->{$id};
 134     }
 135
 136     return 1;
 137 }
 138
 139 sub short_string {
 140     my ($self) = @_;
 141
 142     my @members = $self->members();
 143
 144     my $res = '';
 145     my ($last, $next);
 146     foreach my $cpu (@members) {
 147         if (!defined($last)) {
 148             $last = $next = $cpu;
 149         } elsif (($next + 1) == $cpu) {
 150             $next = $cpu;
 151         } else {
 152             $res .= ',' if length($res);
 153             if ($last != $next) {
 154                 $res .= "$last-$next";
 155             } else {
 156                 $res .= "$last";
 157             }
 158             $last = $next = $cpu;
 159         }
 160     }
 161
 162     if (defined($last)) {
 163         $res .= ',' if length($res);
 164         if ($last != $next) {
 165             $res .= "$last-$next";
 166         } else {
 167             $res .= "$last";
 168         }
 169     }
 170
 171     return $res;
 172 }
 173
 174 1;