src/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4 use strict;
   5 use warnings;
   6
   7 use Clone qw(clone);
   8 use Digest::SHA;
   9 use Encode qw(encode decode);
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::stat;
  13 use IO::Dir;
  14 use IO::File;
  15 use JSON;
  16 use Linux::Inotify2;
  17 use POSIX;
  18
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::JSONSchema;
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools;
  25
  26 use base 'Exporter';
  27
  28 our @EXPORT_OK = qw(read_file write_file register_file);
  29
  30 my $ccache;
  31 my $ccachemap;
  32 my $ccacheregex;
  33 my $inotify;
  34 my $inotify_pid = 0;
  35 my $versions;
  36 my $shadowfiles = {
  37     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  38 };
  39
  40 # to enable cached operation, you need to call 'inotify_init'
  41 # inotify handles are a limited resource, so use with care (only
  42 # enable the cache if you really need it)
  43
  44 # Note: please close the inotify handle after you fork
  45
  46 sub ccache_default_writer {
  47     my ($filename, $data) = @_;
  48
  49     die "undefined config writer for '$filename' :ERROR";
  50 }
  51
  52 sub ccache_default_parser {
  53     my ($filename, $srcfd) = @_;
  54
  55     die "undefined config reader for '$filename' :ERROR";
  56 }
  57
  58 sub ccache_compute_diff {
  59     my ($filename, $shadow) = @_;
  60
  61     my $diff = '';
  62
  63     my $cmd = ['/usr/bin/diff', '-b', '-N', '-u', $filename, $shadow];
  64     PVE::Tools::run_command($cmd, noerr => 1, outfunc => sub {
  65         my ($line) = @_;
  66         $diff .= decode('UTF-8', $line) . "\n";
  67     });
  68
  69     $diff = undef if !$diff;
  70
  71     return $diff;
  72 }
  73
  74 sub ccache_info {
  75     my ($filename) = @_;
  76
  77     foreach my $uid (keys %$ccacheregex) {
  78         my $ccinfo = $ccacheregex->{$uid};
  79         my $dir = $ccinfo->{dir};
  80         my $regex = $ccinfo->{regex};
  81         if ($filename =~ m|^$dir/+$regex$|) {
  82             if (!$ccache->{$filename}) {
  83                 my $cp = {};
  84                 while (my ($k, $v) = each %$ccinfo) {
  85                     $cp->{$k} = $v;
  86                 }
  87                 $ccache->{$filename} = $cp;
  88             }
  89             return ($ccache->{$filename}, $filename);
  90         }
  91     }
  92
  93     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  94
  95     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  96
  97     return ($ccache->{$filename}, $filename);
  98 }
  99
 100 sub write_file {
 101     my ($fileid, $data, $full) = @_;
 102
 103     my ($ccinfo, $filename) = ccache_info($fileid);
 104
 105     my $writer = $ccinfo->{writer};
 106
 107     my $realname = $filename;
 108
 109     my $shadow;
 110     if ($shadow = $shadowfiles->{$filename}) {
 111         $realname = $shadow;
 112     }
 113
 114     my $perm = $ccinfo->{perm} || 0644;
 115
 116     my $tmpname = "$realname.tmp.$$";
 117
 118     my $res;
 119     eval {
 120         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 121         die "unable to open file '$tmpname' - $!\n" if !$fh;
 122
 123         $res = &$writer($filename, $fh, $data);
 124
 125         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 126     };
 127     my $err = $@;
 128
 129     $ccinfo->{version} = undef;
 130
 131     if ($err) {
 132         unlink $tmpname;
 133         die $err;
 134     }
 135
 136     if (!rename($tmpname, $realname)) {
 137         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 138         unlink $tmpname;
 139         die $msg;
 140     }
 141
 142     my $diff;
 143     if ($shadow && $full) {
 144         $diff = ccache_compute_diff ($filename, $shadow);
 145     }
 146
 147     if ($full) {
 148         return { data => $res, changes => $diff };
 149     }
 150
 151     return $res;
 152 }
 153
 154 sub update_file {
 155     my ($fileid, $data, @args) = @_;
 156
 157     my ($ccinfo, $filename) = ccache_info($fileid);
 158
 159     my $update = $ccinfo->{update};
 160
 161     die "unable to update/merge data" if !$update;
 162
 163     my $lkfn = "$filename.lock";
 164
 165     my $timeout = 10;
 166
 167     my $fd;
 168
 169     my $code = sub {
 170
 171         $fd = IO::File->new ($filename, "r");
 172
 173         my $new = &$update($filename, $fd, $data, @args);
 174
 175         if (defined($new)) {
 176             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 177         } else {
 178             unlink $filename;
 179         }
 180     };
 181
 182     PVE::Tools::lock_file($lkfn, $timeout, $code);
 183     my $err = $@;
 184
 185     close($fd) if defined($fd);
 186
 187     die $err if $err;
 188
 189     return undef;
 190 }
 191
 192 sub discard_changes {
 193     my ($fileid, $full) = @_;
 194
 195     my ($ccinfo, $filename) = ccache_info($fileid);
 196
 197     if (my $copy = $shadowfiles->{$filename}) {
 198         unlink $copy;
 199     }
 200
 201     return read_file ($filename, $full);
 202 }
 203
 204 sub poll_changes {
 205     my ($filename) = @_;
 206
 207     poll() if $inotify; # read new inotify events
 208
 209     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 210
 211     return $versions->{$filename};
 212 }
 213
 214 sub read_file {
 215     my ($fileid, $full) = @_;
 216
 217     my $parser;
 218
 219     my ($ccinfo, $filename) = ccache_info($fileid);
 220
 221     $parser = $ccinfo->{parser};
 222
 223     my $fd;
 224     my $shadow;
 225
 226     my $cver = poll_changes($filename);
 227
 228     if (my $copy = $shadowfiles->{$filename}) {
 229         if ($fd = IO::File->new ($copy, "r")) {
 230             $shadow = $copy;
 231         } else {
 232             $fd = IO::File->new ($filename, "r");
 233         }
 234     } else {
 235         $fd = IO::File->new ($filename, "r");
 236     }
 237
 238     my $acp = $ccinfo->{always_call_parser};
 239
 240     if (!$fd) {
 241         $ccinfo->{version} = undef;
 242         $ccinfo->{data} = undef;
 243         $ccinfo->{diff} = undef;
 244         return undef if !$acp;
 245     }
 246
 247     my $noclone = $ccinfo->{noclone};
 248
 249     # file unchanged?
 250     if (!$ccinfo->{nocache} &&
 251         $inotify && $cver &&
 252         defined ($ccinfo->{data}) &&
 253         defined ($ccinfo->{version}) &&
 254         ($ccinfo->{readonce} ||
 255          ($ccinfo->{version} == $cver))) {
 256
 257         my $ret;
 258         if (!$noclone && ref ($ccinfo->{data})) {
 259             $ret->{data} = clone ($ccinfo->{data});
 260         } else {
 261             $ret->{data} = $ccinfo->{data};
 262         }
 263         $ret->{changes} = $ccinfo->{diff};
 264
 265         return $full ? $ret : $ret->{data};
 266     }
 267
 268     my $diff;
 269
 270     if ($shadow) {
 271         $diff = ccache_compute_diff ($filename, $shadow);
 272     }
 273
 274     my $res = &$parser($filename, $fd);
 275
 276     if (!$ccinfo->{nocache}) {
 277         $ccinfo->{version} = $cver;
 278     }
 279
 280     # we cache data with references, so we always need to
 281     # clone this data. Else the original data may get
 282     # modified.
 283     $ccinfo->{data} = $res;
 284
 285     # also store diff
 286     $ccinfo->{diff} = $diff;
 287
 288     my $ret;
 289     if (!$noclone && ref ($ccinfo->{data})) {
 290         $ret->{data} = clone ($ccinfo->{data});
 291     } else {
 292         $ret->{data} = $ccinfo->{data};
 293     }
 294     $ret->{changes} = $ccinfo->{diff};
 295
 296     return $full ? $ret : $ret->{data};
 297 }
 298
 299 sub parse_ccache_options {
 300     my ($ccinfo, %options) = @_;
 301
 302     foreach my $opt (keys %options) {
 303         my $v = $options{$opt};
 304         if ($opt eq 'readonce') {
 305             $ccinfo->{$opt} = $v;
 306         } elsif ($opt eq 'nocache') {
 307             $ccinfo->{$opt} = $v;
 308         } elsif ($opt eq 'shadow') {
 309             $ccinfo->{$opt} = $v;
 310         } elsif ($opt eq 'perm') {
 311             $ccinfo->{$opt} = $v;
 312         } elsif ($opt eq 'noclone') {
 313             # noclone flag for large read-only data chunks like aplinfo
 314             $ccinfo->{$opt} = $v;
 315         } elsif ($opt eq 'always_call_parser') {
 316             # when set, we call parser even when the file does not exist.
 317             # this allows the parser to return some default
 318             $ccinfo->{$opt} = $v;
 319         } else {
 320             die "internal error - unsupported option '$opt'";
 321         }
 322     }
 323 }
 324
 325 sub register_file {
 326     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 327
 328     die "can't register file '$filename' after inotify_init" if $inotify;
 329
 330     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 331     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 332
 333     my $ccinfo = {};
 334
 335     $ccinfo->{id} = $id;
 336     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 337     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 338     $ccinfo->{update} = $update;
 339
 340     parse_ccache_options($ccinfo, %options);
 341
 342     if ($options{shadow}) {
 343         $shadowfiles->{$filename} = $options{shadow};
 344     }
 345
 346     $ccachemap->{$id} = $filename;
 347     $ccache->{$filename} = $ccinfo;
 348 }
 349
 350 sub register_regex {
 351     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 352
 353     die "can't register regex after inotify_init" if $inotify;
 354
 355     my $uid = "$dir/$regex";
 356     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 357
 358     my $ccinfo = {};
 359
 360     $ccinfo->{dir} = $dir;
 361     $ccinfo->{regex} = $regex;
 362     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 363     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 364     $ccinfo->{update} = $update;
 365
 366     parse_ccache_options($ccinfo, %options);
 367
 368     $ccacheregex->{$uid} = $ccinfo;
 369 }
 370
 371 sub poll {
 372     return if !$inotify;
 373
 374     if ($inotify_pid != $$) {
 375         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 376         $inotify = undef;
 377     } else {
 378         1 while $inotify && $inotify->poll;
 379     }
 380 }
 381
 382 sub flushcache {
 383     foreach my $filename (keys %$ccache) {
 384         $ccache->{$filename}->{version} = undef;
 385         $ccache->{$filename}->{data} = undef;
 386         $ccache->{$filename}->{diff} = undef;
 387     }
 388 }
 389
 390 sub inotify_close {
 391     $inotify = undef;
 392 }
 393
 394 sub inotify_init {
 395
 396     die "only one inotify instance allowed" if $inotify;
 397
 398     $inotify =  Linux::Inotify2->new()
 399         || die "Unable to create new inotify object: $!";
 400
 401     $inotify->blocking (0);
 402
 403     $versions = {};
 404
 405     my $dirhash = {};
 406     foreach my $fn (keys %$ccache) {
 407         my $dir = dirname ($fn);
 408         my $base = basename ($fn);
 409
 410         $dirhash->{$dir}->{$base} = $fn;
 411
 412         if (my $sf = $shadowfiles->{$fn}) {
 413             $base = basename ($sf);
 414             $dir = dirname ($sf);
 415             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 416         }
 417     }
 418
 419     foreach my $uid (keys %$ccacheregex) {
 420         my $ccinfo = $ccacheregex->{$uid};
 421         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 422     }
 423
 424     $inotify_pid = $$;
 425
 426     foreach my $dir (keys %$dirhash) {
 427
 428         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 429         $inotify->watch ($dir, $evlist, sub {
 430             my $e = shift;
 431             my $name = $e->name;
 432
 433             if ($inotify_pid != $$) {
 434                 syslog ('err', "got inotify event in wrong process");
 435             }
 436
 437             if ($e->IN_ISDIR || !$name) {
 438                 return;
 439             }
 440
 441             if ($e->IN_Q_OVERFLOW) {
 442                 syslog ('info', "got inotify overflow - flushing cache");
 443                 flushcache();
 444                 return;
 445             }
 446
 447             if ($e->IN_UNMOUNT) {
 448                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 449                 $inotify = undef;
 450             }
 451             if ($e->IN_IGNORED) {
 452                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 453                 $inotify = undef;
 454             }
 455
 456             if ($dirhash->{$dir}->{_regex}) {
 457                 foreach my $uid (keys %$ccacheregex) {
 458                     my $ccinfo = $ccacheregex->{$uid};
 459                     next if $dir ne $ccinfo->{dir};
 460                     my $regex = $ccinfo->{regex};
 461                     if ($regex && ($name =~ m|^$regex$|)) {
 462
 463                         my $fn = "$dir/$name";
 464                         $versions->{$fn}++;
 465                         #print "VERSION:$fn:$versions->{$fn}\n";
 466                     }
 467                 }
 468             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 469
 470                 $versions->{$fn}++;
 471                 #print "VERSION:$fn:$versions->{$fn}\n";
 472             }
 473         });
 474     }
 475
 476     foreach my $dir (keys %$dirhash) {
 477         foreach my $name (keys %{$dirhash->{$dir}}) {
 478             if ($name eq '_regex') {
 479                 foreach my $uid (keys %$ccacheregex) {
 480                     my $ccinfo = $ccacheregex->{$uid};
 481                     next if $dir ne $ccinfo->{dir};
 482                     my $re = $ccinfo->{regex};
 483                     if (my $fd = IO::Dir->new ($dir)) {
 484                         while (defined(my $de = $fd->read)) {
 485                             if ($de =~ m/^$re$/) {
 486                                 my $fn = "$dir/$de";
 487                                 $versions->{$fn}++; # init with version
 488                                 #print "init:$fn:$versions->{$fn}\n";
 489                             }
 490                         }
 491                     }
 492                 }
 493             } else {
 494                 my $fn = $dirhash->{$dir}->{$name};
 495                 $versions->{$fn}++; # init with version
 496                 #print "init:$fn:$versions->{$fn}\n";
 497             }
 498         }
 499     }
 500 }
 501
 502 my $cached_nodename;
 503
 504 sub nodename {
 505
 506     return $cached_nodename if $cached_nodename;
 507
 508     my ($sysname, $nodename) = POSIX::uname();
 509
 510     $nodename =~ s/\..*$//; # strip domain part, if any
 511
 512     die "unable to read node name\n" if !$nodename;
 513
 514     $cached_nodename = $nodename;
 515
 516     return $cached_nodename;
 517 }
 518
 519 sub read_etc_hostname {
 520     my ($filename, $fd) = @_;
 521
 522     my $hostname = <$fd>;
 523
 524     chomp $hostname;
 525
 526     $hostname =~ s/\..*$//; # strip domain part, if any
 527
 528     return $hostname;
 529 }
 530
 531 sub write_etc_hostname {
 532     my ($filename, $fh, $hostname) = @_;
 533
 534     die "write failed: $!" unless print $fh "$hostname\n";
 535
 536     return $hostname;
 537 }
 538
 539 register_file('hostname', "/etc/hostname",
 540               \&read_etc_hostname,
 541               \&write_etc_hostname);
 542
 543 sub read_etc_hosts {
 544     my ($filename, $fh) = @_;
 545
 546     my $raw = '';
 547     my $data = '';
 548
 549     while (my $line = <$fh>) {
 550         $raw .= $line;
 551         if ($line =~ m/^\s*#/) {
 552             $line = decode('UTF-8', $line);
 553         }
 554         $data .= $line;
 555     }
 556
 557     return {
 558         digest => Digest::SHA::sha1_hex($raw),
 559         data => $data,
 560     }
 561 }
 562
 563 sub write_etc_hosts {
 564     my ($filename, $fh, $hosts, @args) = @_;
 565
 566     # check validity of ips/names
 567     for my $line (split("\n", $hosts)) {
 568         next if $line =~ m/^\s*#/; # comments
 569         next if $line =~ m/^\s*$/; # whitespace/empty lines
 570
 571         my ($ip, @names) = split(/\s+/, $line);
 572
 573         raise_param_exc({ 'data' => "Invalid IP '$ip'" })
 574             if $ip !~ m/^$PVE::Tools::IPRE$/;
 575
 576         for my $name (@names) {
 577             raise_param_exc({ 'data' => "Invalid Hostname '$name'" })
 578                 if $name !~ m/^[.\-a-zA-Z0-9]+$/;
 579         }
 580     }
 581
 582     die "write failed: $!" if !print $fh encode('UTF-8', $hosts);
 583
 584     return $hosts;
 585 }
 586
 587 register_file('etchosts', "/etc/hosts",
 588               \&read_etc_hosts,
 589               \&write_etc_hosts);
 590
 591 sub read_etc_resolv_conf {
 592     my ($filename, $fh) = @_;
 593
 594     my $res = {};
 595
 596     my $nscount = 0;
 597     while (my $line = <$fh>) {
 598         chomp $line;
 599         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 600             $res->{search} = $2;
 601         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
 602             $nscount++;
 603             if ($nscount <= 3) {
 604                 $res->{"dns$nscount"} = $1;
 605             }
 606         }
 607     }
 608
 609     return $res;
 610 }
 611
 612 sub update_etc_resolv_conf {
 613     my ($filename, $fh, $resolv, @args) = @_;
 614
 615     my $data = "";
 616
 617     $data = "search $resolv->{search}\n"
 618         if $resolv->{search};
 619
 620     my $written = {};
 621     foreach my $k ("dns1", "dns2", "dns3") {
 622         my $ns = $resolv->{$k};
 623         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 624             $written->{$ns} = 1;
 625             $data .= "nameserver $ns\n";
 626         }
 627     }
 628
 629     while (my $line = <$fh>) {
 630         next if $line =~ m/^(search|domain|nameserver)\s+/;
 631         $data .= $line
 632     }
 633
 634     return $data;
 635 }
 636
 637 register_file('resolvconf', "/etc/resolv.conf",
 638               \&read_etc_resolv_conf, undef,
 639               \&update_etc_resolv_conf);
 640
 641 sub read_etc_timezone {
 642     my ($filename, $fd) = @_;
 643
 644     my $timezone = <$fd>;
 645
 646     chomp $timezone;
 647
 648     return $timezone;
 649 }
 650
 651 sub write_etc_timezone {
 652     my ($filename, $fh, $timezone) = @_;
 653
 654     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 655
 656     raise_param_exc({ 'timezone' => "No such timezone" })
 657         if (! -f $tzinfo);
 658
 659     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 660
 661     print $fh "$timezone\n";
 662
 663     unlink ("/etc/localtime");
 664     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 665
 666 }
 667
 668 register_file('timezone', "/etc/timezone",
 669               \&read_etc_timezone,
 670               \&write_etc_timezone);
 671
 672 sub read_active_workers {
 673     my ($filename, $fh) = @_;
 674
 675     return [] if !$fh;
 676
 677     my $res = [];
 678     while (defined (my $line = <$fh>)) {
 679         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 680             my $upid = $1;
 681             my $saved = $2;
 682             my $endtime = $4;
 683             my $status = $6;
 684             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 685                 $task->{upid} = $upid;
 686                 $task->{saved} = $saved;
 687                 $task->{endtime} = hex($endtime) if $endtime;
 688                 $task->{status} = $status if $status;
 689                 push @$res, $task;
 690             }
 691         } else {
 692             warn "unable to parse line: $line";
 693         }
 694     }
 695
 696     return $res;
 697
 698 }
 699
 700 sub write_active_workers {
 701     my ($filename, $fh, $tasklist) = @_;
 702
 703     my $raw = '';
 704     foreach my $task (@$tasklist) {
 705         my $upid = $task->{upid};
 706         my $saved = $task->{saved} ? 1 : 0;
 707         if ($task->{endtime}) {
 708             if ($task->{status}) {
 709                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
 710             } else {
 711                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
 712             }
 713         } else {
 714             $raw .= "$upid $saved\n";
 715         }
 716     }
 717
 718     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 719 }
 720
 721 register_file('active', "/var/log/pve/tasks/active",
 722               \&read_active_workers,
 723               \&write_active_workers);
 724
 725
 726 our $bond_modes = {
 727     'balance-rr' => 0,
 728     'active-backup' => 1,
 729     'balance-xor' => 2,
 730     'broadcast' => 3,
 731     '802.3ad' => 4,
 732     'balance-tlb' => 5,
 733     'balance-alb' => 6,
 734 };
 735
 736 my $ovs_bond_modes = {
 737     'active-backup' => 1,
 738     'balance-slb' => 1,
 739     'lacp-balance-slb' => 1,
 740     'lacp-balance-tcp' => 1,
 741 };
 742
 743 #sub get_bond_modes {
 744 #    return $bond_modes;
 745 #}
 746
 747 my $parse_ovs_option = sub {
 748     my ($data) = @_;
 749
 750     my $opts = {};
 751     foreach my $kv (split (/\s+/, $data || '')) {
 752         my ($k, $v) = split('=', $kv, 2);
 753         $opts->{$k} = $v if $k && $v;
 754     }
 755     return $opts;
 756 };
 757
 758 my $set_ovs_option = sub {
 759     my ($d, %params) = @_;
 760
 761     my $opts = &$parse_ovs_option($d->{ovs_options});
 762
 763     foreach my $k (keys %params) {
 764         my $v = $params{$k};
 765         if ($v) {
 766             $opts->{$k} = $v;
 767         } else {
 768             delete $opts->{$k};
 769         }
 770     }
 771
 772     my $res = [];
 773     foreach my $k (keys %$opts) {
 774         push @$res, "$k=$opts->{$k}";
 775     }
 776
 777     if (my $new = join(' ', @$res)) {
 778         $d->{ovs_options} = $new;
 779         return $d->{ovs_options};
 780     } else {
 781         delete $d->{ovs_options};
 782         return undef;
 783     }
 784 };
 785
 786 my $extract_ovs_option = sub {
 787     my ($d, $name) = @_;
 788
 789     my $opts = &$parse_ovs_option($d->{ovs_options});
 790
 791     my $v = delete $opts->{$name};
 792
 793     my $res = [];
 794     foreach my $k (keys %$opts) {
 795         push @$res, "$k=$opts->{$k}";
 796     }
 797
 798     if (my $new = join(' ', @$res)) {
 799         $d->{ovs_options} = $new;
 800     } else {
 801         delete $d->{ovs_options};
 802     }
 803
 804     return $v;
 805 };
 806
 807 my $check_mtu = sub {
 808     my ($ifaces, $parent, $child) = @_;
 809
 810     die "check mtu - missing parent interface\n" if !$parent;
 811     die "check mtu - missing child interface\n" if !$child;
 812
 813     my $cmtu = $ifaces->{$child}->{mtu};
 814     return if !$cmtu;
 815
 816     my $parentdata = $ifaces->{$parent};
 817     my $pmtu = $parentdata->{mtu};
 818     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
 819     $pmtu = 1500 if !$pmtu;
 820
 821     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
 822         if $pmtu < $cmtu;
 823 };
 824
 825 # config => {
 826 #   ifaces => {
 827 #     $ifname => {
 828 #       <optional> exists => BOOL,
 829 #       <optional> active => BOOL,
 830 #       <optional> autostart => BOOL,
 831 #       <auto> priority => INT,
 832 #
 833 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
 834 #
 835 #       families => ["inet", "inet6", ...],
 836 #
 837 #       method => "manual" | "static" | "dhcp" | ... ,
 838 #       address => IP,
 839 #       netmask => SUBNET,
 840 #       broadcast => IP,
 841 #       gateway => IP,
 842 #       comments => [ "..." ],
 843 #
 844 #       method6 => "manual" | "static" | "dhcp" | ... ,
 845 #       address6 => IP,
 846 #       netmask6 => SUBNET,
 847 #       gateway6 => IP,
 848 #       comments6 => [ "..." ],
 849 #
 850 #       <known options>, # like bridge_ports, ovs_*
 851 #
 852 #       # extra/unknown options stored by-family:
 853 #       options => { <inet options>... }
 854 #       options6 => { <inet6 options>... }
 855 #     }
 856 #   },
 857 #   options => [
 858 #     # mappings end up here as well, as we don't need to understand them
 859 #     [priority,line]
 860 #   ]
 861 # }
 862 sub read_etc_network_interfaces {
 863     my ($filename, $fh) = @_;
 864     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
 865     my $active = PVE::ProcFSTools::get_active_network_interfaces();
 866     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
 867 }
 868
 869 sub __read_etc_network_interfaces {
 870     my ($fh, $proc_net_dev, $active_ifaces) = @_;
 871
 872     my $config = {};
 873     my $ifaces = $config->{ifaces} = {};
 874     my $options = $config->{options} = [];
 875
 876     my $options_alternatives = {
 877         'ovs_mtu'     => 'mtu',
 878         'bond-slaves' => 'slaves',
 879         'bond_slaves' => 'slaves',
 880         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
 881         'bond-mode' => 'bond_mode',
 882         'bond-miimon' =>'bond_miimon',
 883         'bridge-vlan-aware' => 'bridge_vlan_aware',
 884         'bridge-fd' => 'bridge_fd',
 885         'bridge-stp' => 'bridge_stp',
 886         'bridge-ports' => 'bridge_ports',
 887         'bridge-vids' => 'bridge_vids'
 888     };
 889
 890     my $line;
 891
 892     if ($proc_net_dev) {
 893         while (defined ($line = <$proc_net_dev>)) {
 894             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
 895                 $ifaces->{$1}->{exists} = 1;
 896             }
 897         }
 898         close($proc_net_dev);
 899     }
 900
 901     # we try to keep order inside the file
 902     my $priority = 2; # 1 is reserved for lo
 903
 904     SECTION: while (defined ($line = <$fh>)) {
 905         chomp ($line);
 906         next if $line =~ m/^\s*#/;
 907
 908         if ($line =~ m/^\s*(allow-auto|auto|allow-ovs)\s+(.*)$/) {
 909
 910             $ifaces->{$_}->{autostart} = 1 for split (/\s+/, $2);
 911
 912         } elsif ($line =~ m/^\s*(allow-hotplug)\s+(.*)$/) {
 913
 914             # FIXME: handle those differently? auto makes it required on-boot, vs. best-effort
 915             $ifaces->{$_}->{autostart} = 1 for split (/\s+/, $2);
 916
 917         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
 918             my $i = $1;
 919             my $family = $2;
 920             my $f = { method => $3 }; # by family, merged to $d with a $suffix
 921             (my $suffix = $family) =~ s/^inet//;
 922
 923             my $d = $ifaces->{$i} ||= {};
 924             $d->{priority} = $priority++ if !$d->{priority};
 925             push @{$d->{families}}, $family;
 926
 927             while (defined ($line = <$fh>)) {
 928                 $line =~ s/\s+$//; # drop trailing whitespaces
 929
 930                 if ($line =~ m/^\s*#(.*?)\s*$/) {
 931                     $f->{comments} = '' if !$f->{comments};
 932                     my $comment = decode('UTF-8', $1);
 933                     $f->{comments} .= "$comment\n";
 934                 } elsif ($line =~ m/^\s*(?:(?:iface|mapping|auto|source|source-directory)\s|allow-)/) {
 935                     last;
 936                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
 937                     my $option = $1;
 938                     my ($id, $value) = ($2, $3);
 939
 940                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
 941
 942                     my $simple_options = {
 943                         'mtu' => 1,
 944                         'ovs_type' => 1,
 945                         'ovs_options' => 1,
 946                         'ovs_bridge' => 1,
 947                         'ovs_bonds' => 1,
 948                         'ovs_ports' => 1,
 949                         'bridge_fd' => 1,
 950                         'bridge_vids' => 1,
 951                         'bridge-access' => 1,
 952                         'bridge-learning' => 1,
 953                         'bridge-arp-nd-suppress' => 1,
 954                         'bridge-unicast-flood' => 1,
 955                         'bridge-multicast-flood' => 1,
 956                         'bond_miimon' => 1,
 957                         'bond_xmit_hash_policy' => 1,
 958                         'bond-primary' => 1,
 959                         'link-type'   => 1,
 960                         'uplink-id' => 1,
 961                         'vlan-protocol' => 1,
 962                         'vlan-raw-device' => 1,
 963                         'vlan-id' => 1,
 964                         'vxlan-id' => 1,
 965                         'vxlan-svcnodeip' => 1,
 966                         'vxlan-physdev' => 1,
 967                         'vxlan-local-tunnelip' => 1,
 968                     };
 969
 970                     if ($id eq 'address' || $id eq 'netmask' || $id eq 'broadcast' || $id eq 'gateway') {
 971                         $f->{$id} = $value;
 972                     } elsif ($simple_options->{$id}) {
 973                         $d->{$id} = $value;
 974                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 975                         my $devs = {};
 976                         foreach my $p (split (/\s+/, $value)) {
 977                             next if $p eq 'none';
 978                             $devs->{$p} = 1;
 979                         }
 980                         my $str = join (' ', sort keys %{$devs});
 981                         if ($d->{$id}) {
 982                             $d->{$id} .= ' ' . $str if $str;
 983                         } else {
 984                             $d->{$id} = $str || '';
 985                         }
 986                     } elsif ($id eq 'bridge_stp') {
 987                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 988                             $d->{$id} = 'on';
 989                         } else {
 990                             $d->{$id} = 'off';
 991                         }
 992                     } elsif ($id eq 'bridge_vlan_aware') {
 993                         $d->{$id} = 1;
 994                     } elsif ($id eq 'bond_mode') {
 995                         # always use names
 996                         foreach my $bm (keys %$bond_modes) {
 997                             if ($bond_modes->{$bm} eq $value) {
 998                                 $value = $bm;
 999                                 last;
1000                             }
1001                         }
1002                         $d->{$id} = $value;
1003                     } elsif ($id eq 'vxlan-remoteip') {
1004                         push @{$d->{$id}}, $value;
1005                     } else {
1006                         push @{$f->{options}}, $option;
1007                     }
1008                 } else {
1009                     last;
1010                 }
1011             }
1012             $d->{"$_$suffix"} = $f->{$_} for keys $f->%*;
1013             last SECTION if !defined($line);
1014             redo SECTION;
1015         } elsif ($line =~ /\w/) {
1016             push @$options, [$priority++, $line];
1017         }
1018     }
1019
1020     foreach my $ifname (@$active_ifaces) {
1021         if (my $iface = $ifaces->{$ifname}) {
1022             $iface->{active} = 1;
1023         }
1024     }
1025
1026     if (!$ifaces->{lo}) {
1027         $ifaces->{lo} = {
1028             priority => 1,
1029             method => 'loopback',
1030             type => 'loopback',
1031             autostart => 1,
1032         };
1033     }
1034
1035     foreach my $iface (keys %$ifaces) {
1036         my $d = $ifaces->{$iface};
1037         $d->{type} = 'unknown';
1038         if ($iface =~ m/^bond\d+$/) {
1039             if (!$d->{ovs_type}) {
1040                 $d->{type} = 'bond';
1041             } elsif ($d->{ovs_type} eq 'OVSBond') {
1042                 $d->{type} = $d->{ovs_type};
1043                 # translate: ovs_options => bond_mode
1044                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
1045                 my $lacp = &$extract_ovs_option($d, 'lacp');
1046                 if ($lacp && $lacp eq 'active') {
1047                     if ($d->{'bond_mode'} eq 'balance-slb') {
1048                         $d->{'bond_mode'} = 'lacp-balance-slb';
1049                     }
1050                 }
1051                 # Note: balance-tcp needs lacp
1052                 if ($d->{'bond_mode'} eq 'balance-tcp') {
1053                     $d->{'bond_mode'} = 'lacp-balance-tcp';
1054                 }
1055                 my $tag = &$extract_ovs_option($d, 'tag');
1056                 $d->{ovs_tag} = $tag if defined($tag);
1057             }
1058         } elsif ($iface =~ m/^vmbr\d+$/) {
1059             if (!$d->{ovs_type}) {
1060                 $d->{type} = 'bridge';
1061                 if (!defined ($d->{bridge_stp})) {
1062                     $d->{bridge_stp} = 'off';
1063                 }
1064                 if (!defined($d->{bridge_fd}) && $d->{bridge_stp} eq 'off') {
1065                     $d->{bridge_fd} = 0;
1066                 }
1067             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1068                 $d->{type} = $d->{ovs_type};
1069             }
1070         } elsif ($iface =~ m/^(\S+):\d+$/) {
1071             $d->{type} = 'alias';
1072             if (defined ($ifaces->{$1})) {
1073                 $d->{exists} = $ifaces->{$1}->{exists};
1074             } else {
1075                 $ifaces->{$1}->{exists} = 0;
1076                 $d->{exists} = 0;
1077             }
1078         } elsif ($iface =~ m/^(\S+)\.(\d+)$/ || $d->{'vlan-raw-device'}) {
1079             $d->{type} = 'vlan';
1080
1081             my ($dev, $id) = ($1, $2);
1082             $d->{'vlan-raw-device'} = $dev if defined($dev) && !$d->{'vlan-raw-device'};
1083
1084             if (!$id && $iface =~ m/^vlan(\d+)$/) { # VLAN id 0 is not valid, so truthy check it is
1085                 $id = $1;
1086             }
1087             $d->{'vlan-id'} = $id if $id;
1088
1089             my $raw_iface = $d->{'vlan-raw-device'};
1090
1091             if (defined ($ifaces->{$raw_iface})) {
1092                 $d->{exists} = $ifaces->{$raw_iface}->{exists};
1093             } else {
1094                 $ifaces->{$raw_iface}->{exists} = 0;
1095                 $d->{exists} = 0;
1096             }
1097         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1098             if (!$d->{ovs_type}) {
1099                 $d->{type} = 'eth';
1100             } elsif ($d->{ovs_type} eq 'OVSPort') {
1101                 $d->{type} = $d->{ovs_type};
1102                 my $tag = &$extract_ovs_option($d, 'tag');
1103                 $d->{ovs_tag} = $tag if defined($tag);
1104             }
1105         } elsif ($iface =~ m/^lo$/) {
1106             $d->{type} = 'loopback';
1107         } else {
1108             if ($d->{'vxlan-id'}) {
1109                 $d->{type} = 'vxlan';
1110             } elsif (defined($d->{ovs_type})) {
1111                 if ($d->{ovs_type} eq 'OVSIntPort') {
1112                     $d->{type} = $d->{ovs_type};
1113                     my $tag = &$extract_ovs_option($d, 'tag');
1114                     $d->{ovs_tag} = $tag if defined($tag);
1115                 }
1116             } elsif (defined($d->{'link-type'})) {
1117                 $d->{type} = $d->{'link-type'} if $d->{'link-type'} eq 'dummy';
1118             }
1119         }
1120
1121         # map address and netmask to cidr
1122         if (my $addr = $d->{address}) {
1123             if (_address_is_cidr($addr)) {
1124                 $d->{cidr} = $addr;
1125                 my ($baseaddr, $mask) = _cidr_split($addr);
1126                 $d->{address} = $baseaddr;
1127                 $d->{netmask} = $mask;
1128             } elsif (my $cidr = _get_cidr($d->{address}, $d->{netmask})) {
1129                 $d->{cidr} = $cidr;
1130                 (undef, $d->{netmask}) = _cidr_split($cidr);
1131             } else {
1132                 # no mask, else we'd got a cidr above
1133                 $d->{cidr} = $addr ."/32";
1134             }
1135         }
1136
1137         # map address6 and netmask6 to cidr6
1138         if (my $addr6 = $d->{address6}) {
1139             if (_address_is_cidr($addr6)) {
1140                 $d->{cidr6} = $addr6;
1141                 my ($baseaddr, $mask) = _cidr_split($addr6);
1142                 $d->{address6} = $baseaddr;
1143                 $d->{netmask6} = $mask;
1144             } elsif (my $cidr6 = _get_cidr($d->{address6}, $d->{netmask6})) {
1145                 $d->{cidr6} = $cidr6;
1146             } else {
1147                 # no mask, else we'd got a cidr above
1148                 $d->{cidr6} = $addr6 ."/128";
1149             }
1150         }
1151
1152         $d->{method} = 'manual' if !$d->{method};
1153         $d->{method6} = 'manual' if !$d->{method6};
1154
1155         if (my $comments6 = delete $d->{comments6}) {
1156             $d->{comments} = ($d->{comments} // '') . $comments6;
1157         }
1158
1159         $d->{families} ||= ['inet'];
1160     }
1161
1162     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1163     # from the {options} hash for them to be removed correctly.
1164     @$options = grep {defined($_)} map {
1165         my ($pri, $line) = @$_;
1166         if ($line =~ /^allow-ovs\s+(.*)$/) {
1167             undef;
1168         } elsif ($line =~ /^allow-(\S+)\s+(.*)$/) {
1169             my $bridge = $1;
1170             my @ports = split(/\s+/, $2);
1171             if (defined(my $br = $ifaces->{$bridge})) {
1172                 # if this port is part of a bridge, remove it
1173                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1174                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1175             }
1176             # create the allow line for the remaining ports, or delete if empty
1177             if (@ports) {
1178                 [$pri, "allow-$bridge " . join(' ', @ports)];
1179             } else {
1180                 undef;
1181             }
1182         } else {
1183             # don't modify other lines
1184             $_;
1185         }
1186     } @$options;
1187
1188     return $config;
1189 }
1190
1191 sub _address_is_cidr {
1192     my ($addr) = @_;
1193     return $addr =~ /\/\d+$/ ? 1 : 0;
1194 }
1195
1196 sub _cidr_split {
1197     my ($cidr) = @_;
1198     $cidr =~ /^(.+)\/(\d+)$/;
1199     return ($1, $2); # (address, mask)
1200 }
1201
1202 sub _get_cidr {
1203     my ($addr, $mask) = @_;
1204
1205     return $addr if _address_is_cidr($addr);
1206     return undef if !$mask;
1207
1208     if ($mask =~ m/^\d+$/) { # cidr notation
1209         return $addr . "/" . $mask;
1210     } elsif (my $cidrmask = PVE::JSONSchema::get_netmask_bits($mask)) {
1211         return $addr . "/" . $cidrmask;
1212     }
1213     return undef;
1214 }
1215
1216 sub __interface_to_string {
1217     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1218
1219     (my $suffix = $family) =~ s/^inet//;
1220
1221     return '' if !($d && $d->{"method$suffix"});
1222
1223     my $raw = "iface $iface $family " . $d->{"method$suffix"} . "\n";
1224
1225     if (my $addr = $d->{"address$suffix"}) {
1226         if ($addr !~ /\/\d+$/ && $d->{"netmask$suffix"}) {
1227             if ($d->{"netmask$suffix"} =~ m/^\d+$/) {
1228                 $addr .= "/" . $d->{"netmask$suffix"};
1229             } elsif (my $mask = PVE::JSONSchema::get_netmask_bits($d->{"netmask$suffix"})) {
1230                 $addr .= "/" . $mask;
1231             }
1232         }
1233         $raw .= "\taddress ${addr}\n";
1234     }
1235
1236     $raw .= "\tgateway " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1237
1238     my $done = {
1239         type => 1, priority => 1, method => 1, active => 1, exists => 1, comments => 1,
1240         autostart => 1, options => 1, address => 1, netmask => 1, gateway => 1, broadcast => 1,
1241         method6 => 1, families => 1, options6 => 1, comments6 => 1, address6 => 1,
1242         netmask6 => 1, gateway6 => 1, broadcast6 => 1, 'uplink-id' => 1,
1243      };
1244
1245     if (!$first_block) {
1246         # not printing out options
1247     } elsif ($d->{type} eq 'bridge') {
1248
1249         my $ports = $d->{bridge_ports} || 'none';
1250         $ports =~ s/[;,\s]+/ /g;
1251         $raw .= "\tbridge-ports $ports\n";
1252         $done->{bridge_ports} = 1;
1253
1254         my $br_stp = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1255         my $no_stp = $br_stp eq 'off';
1256
1257         $raw .= "\tbridge-stp $br_stp\n";
1258         $done->{bridge_stp} = 1;
1259
1260         # NOTE: forwarding delay must be 2 <= FD <= 30 if STP is enabled
1261         if (defined(my $br_fd = $d->{bridge_fd})) {
1262             if ($no_stp || ($br_fd >= 2 && $br_fd <= 30)) {
1263                 $raw .= "\tbridge-fd $br_fd\n";
1264             } else {
1265                 # only complain if the user actually set a value, but not for default fallback below
1266                 warn "'$iface': ignoring 'bridge_fd' value '$br_fd', outside of allowed range 2-30\n";
1267             }
1268         } elsif ($no_stp) {
1269             $raw .= "\tbridge-fd 0\n";
1270         }
1271         $done->{bridge_fd} = 1;
1272
1273         if( defined($d->{bridge_vlan_aware})) {
1274             $raw .= "\tbridge-vlan-aware yes\n";
1275             my $vlans = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1276             $raw .= "\tbridge-vids $vlans\n";
1277         }
1278         $done->{bridge_vlan_aware} = 1;
1279         $done->{bridge_vids} = 1;
1280
1281         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1282         $done->{mtu} = 1;
1283
1284     } elsif ($d->{type} eq 'bond') {
1285
1286         $d->{slaves} =~ s/[;,\s]+/ /g;
1287         my $slaves = $d->{slaves} || 'none';
1288         $raw .= "\tbond-slaves $slaves\n";
1289         $done->{slaves} = 1;
1290
1291         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1292         $raw .= "\tbond-miimon $v\n";
1293         $done->{'bond_miimon'} = 1;
1294
1295         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1296         $raw .= "\tbond-mode $v\n";
1297         $done->{'bond_mode'} = 1;
1298
1299         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1300             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1301             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1302         }
1303         $done->{'bond_xmit_hash_policy'} = 1;
1304
1305         if ($d->{'bond_mode'} && $d->{'bond_mode'} eq 'active-backup' && $d->{'bond-primary'}) {
1306             $raw .= "\tbond-primary $d->{'bond-primary'}\n";
1307         }
1308         $done->{'bond-primary'} = 1;
1309
1310         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1311         $done->{mtu} = 1;
1312
1313     } elsif ($d->{type} eq 'vlan') {
1314         die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n"
1315             if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
1316
1317     } elsif ($d->{type} eq 'vxlan') {
1318
1319         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1320             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1321             $done->{$k} = 1;
1322         }
1323
1324         if ($d->{'vxlan-remoteip'}) {
1325             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1326                 $raw .= "\tvxlan-remoteip $remoteip\n";
1327             }
1328             $done->{'vxlan-remoteip'} = 1;
1329         }
1330
1331         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1332         $done->{mtu} = 1;
1333
1334     } elsif ($d->{type} eq 'OVSBridge') {
1335
1336         $raw .= "\tovs_type $d->{type}\n";
1337         $done->{ovs_type} = 1;
1338
1339         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1340         $done->{ovs_ports} = 1;
1341
1342         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1343         $done->{mtu} = 1;
1344
1345     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' || $d->{type} eq 'OVSBond') {
1346
1347         $d->{autostart} = 0; # started by the bridge
1348
1349         if (defined($d->{ovs_tag})) {
1350             &$set_ovs_option($d, tag => $d->{ovs_tag});
1351         }
1352         $done->{ovs_tag} = 1;
1353
1354         if ($d->{type} eq 'OVSBond') {
1355
1356             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1357
1358             $ovs_bond_modes->{$d->{bond_mode}} ||
1359                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1360
1361             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1362                 &$set_ovs_option($d, lacp => 'active');
1363                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1364             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1365                 &$set_ovs_option($d, lacp => 'active');
1366                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1367             } else {
1368                 &$set_ovs_option($d, lacp => undef);
1369                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1370             }
1371             $done->{bond_mode} = 1;
1372
1373             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1374             $done->{ovs_bonds} = 1;
1375         }
1376
1377         $raw .= "\tovs_type $d->{type}\n";
1378         $done->{ovs_type} = 1;
1379
1380         if (my $bridge = $d->{ovs_bridge}) {
1381             if ($ifupdown2) {
1382                 $raw = "auto $iface\n$raw";
1383             } else {
1384                 $raw = "allow-$bridge $iface\n$raw";
1385             }
1386
1387             $raw .= "\tovs_bridge $bridge\n";
1388             $done->{ovs_bridge} = 1;
1389         }
1390
1391         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1392         $done->{mtu} = 1;
1393     }
1394
1395     if ($first_block) {
1396         # print other settings
1397         foreach my $k (sort keys %$d) {
1398            next if $done->{$k};
1399            next if !$d->{$k};
1400            $raw .= "\t$k $d->{$k}\n";
1401         }
1402     }
1403
1404     foreach my $option (@{$d->{"options$suffix"}}) {
1405         $raw .= "\t$option\n";
1406     }
1407
1408     # add comments
1409     my $comments = $d->{"comments$suffix"} || '';
1410     foreach my $cl (split(/\n/, $comments)) {
1411         $raw .= "#$cl\n";
1412     }
1413
1414     $raw .= "\n";
1415
1416     return $raw;
1417 }
1418
1419
1420 sub write_etc_network_interfaces {
1421     my ($filename, $fh, $config) = @_;
1422     my $ifupdown2 = -e '/usr/share/ifupdown2/ifupdown2';
1423     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1424     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1425 }
1426 sub __write_etc_network_interfaces {
1427     my ($config, $ifupdown2) = @_;
1428
1429     my $ifaces = $config->{ifaces};
1430     my @options = @{$config->{options}};
1431
1432     my $used_ports = {};
1433
1434     foreach my $iface (keys %$ifaces) {
1435         my $d = $ifaces->{$iface};
1436
1437         my ($cidr, $cidr6) = (delete $d->{cidr}, delete $d->{cidr6});
1438         $d->{address} //= $cidr;
1439         $d->{address6} //= $cidr6;
1440
1441         my $ports = '';
1442         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1443             $ports .= " $d->{$k}" if $d->{$k};
1444         }
1445
1446         foreach my $p (PVE::Tools::split_list($ports)) {
1447             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1448                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1449             $used_ports->{$p} = $iface;
1450         }
1451     }
1452
1453     # delete unused OVS ports
1454     foreach my $iface (keys %$ifaces) {
1455         my $d = $ifaces->{$iface};
1456         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' || $d->{type} eq 'OVSBond') {
1457             my $brname = $used_ports->{$iface};
1458             if (!$brname || !$ifaces->{$brname}) {
1459                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1460                     $ifaces->{$iface} = {
1461                         type => 'eth',
1462                         exists => 1,
1463                         method => 'manual',
1464                         families => ['inet'],
1465                     };
1466                 } else {
1467                     delete $ifaces->{$iface};
1468                 }
1469                 next;
1470             }
1471             my $bd = $ifaces->{$brname};
1472             if ($bd->{type} ne 'OVSBridge') {
1473                 delete $ifaces->{$iface};
1474                 next;
1475             }
1476         }
1477     }
1478
1479     # create OVS bridge ports
1480     foreach my $iface (keys %$ifaces) {
1481         my $d = $ifaces->{$iface};
1482         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1483             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1484                 my $n = $ifaces->{$p};
1485                 die "OVS bridge '$iface' - unable to find port '$p'\n" if !$n;
1486                 $n->{autostart} = 0;
1487                 if ($n->{type} eq 'eth') {
1488                     $n->{type} = 'OVSPort';
1489                     $n->{ovs_bridge} = $iface;
1490                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1491                     $n->{type} eq 'OVSIntPort') {
1492                     $n->{ovs_bridge} = $iface;
1493                 } else {
1494                     die "interface '$p' is not defined as OVS port/bond\n";
1495                 }
1496
1497                 &$check_mtu($ifaces, $iface, $p);
1498             }
1499         }
1500     }
1501
1502     # check OVS bond ports
1503     foreach my $iface (keys %$ifaces) {
1504         my $d = $ifaces->{$iface};
1505         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1506             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1507                 my $n = $ifaces->{$p};
1508                 $n->{autostart} = 1;
1509                 die "OVS bond '$iface' - unable to find slave '$p'\n" if !$n;
1510                 die "OVS bond '$iface' - wrong interface type on slave '$p' ('$n->{type}' != 'eth')\n"
1511                     if $n->{type} ne 'eth';
1512                 &$check_mtu($ifaces, $iface, $p);
1513             }
1514         }
1515     }
1516
1517     # check bond
1518     foreach my $iface (keys %$ifaces) {
1519         my $d = $ifaces->{$iface};
1520         next if !($d->{type} eq 'bond' && $d->{slaves});
1521
1522         my $bond_primary_is_slave = undef;
1523         foreach my $p (split (/\s+/, $d->{slaves})) {
1524             my $n = $ifaces->{$p};
1525             $n->{autostart} = 1;
1526
1527             die "bond '$iface' - unable to find slave '$p'\n" if !$n;
1528             die "bond '$iface' - wrong interface type on slave '$p' ('$n->{type}' != 'eth or bond')\n"
1529                 if ($n->{type} ne 'eth' && $n->{type} ne 'bond');
1530
1531             $check_mtu->($ifaces, $iface, $p);
1532             $bond_primary_is_slave = 1 if $d->{'bond-primary'} && $d->{'bond-primary'} eq $p;
1533         }
1534         die "bond '$iface' - bond-primary interface is not a slave" if $d->{'bond-primary'} && !$bond_primary_is_slave;
1535     }
1536
1537     # check vxlan
1538     my $vxlans = {};
1539     foreach my $iface (keys %$ifaces) {
1540         my $d = $ifaces->{$iface};
1541
1542         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1543             my $vxlanid = $d->{'vxlan-id'};
1544             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1545             $vxlans->{$vxlanid} = $iface;
1546         }
1547
1548         my $ips = 0;
1549         ++$ips if defined $d->{'vxlan-svcnodeip'};
1550         ++$ips if defined $d->{'vxlan-remoteip'};
1551         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1552         if ($ips > 1) {
1553             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1554         }
1555
1556         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1557             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1558         }
1559         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1560     }
1561
1562     # check vlan
1563     foreach my $iface (keys %$ifaces) {
1564         my $d = $ifaces->{$iface};
1565         if ($d->{type} eq 'vlan') {
1566
1567             my $p = undef;
1568             my $vlanid = undef;
1569
1570             if ($iface =~ m/^(\S+)\.(\d+)$/) {
1571                 $p = $1;
1572                 $vlanid = $2;
1573                 delete $d->{'vlan-raw-device'} if $d->{'vlan-raw-device'};
1574                 delete $d->{'vlan-id'} if $d->{'vlan-id'};
1575
1576             } else {
1577                 die "missing vlan-raw-device option" if !$d->{'vlan-raw-device'};
1578                 $p = $d->{'vlan-raw-device'};
1579
1580                 if ($iface =~ m/^vlan(\d+)$/) {
1581                     $vlanid = $1;
1582                     delete $d->{'vlan-id'} if $d->{'vlan-id'};
1583                 } else {
1584                     die "custom vlan interface name need ifupdown2" if !$ifupdown2;
1585                     die "missing vlan-id option" if !$d->{'vlan-id'};
1586                     $vlanid = $d->{'vlan-id'};
1587                 }
1588             }
1589             my $n = $ifaces->{$p};
1590
1591             die "vlan '$iface' - vlan-id $vlanid should be <= 4094\n" if $vlanid > 4094;
1592             die "vlan '$iface' - unable to find parent '$p'\n"
1593                 if !$n;
1594
1595             if ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
1596                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1597                     "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
1598             }
1599
1600             &$check_mtu($ifaces, $p, $iface);
1601
1602         }
1603     }
1604
1605     # check uplink
1606     my $uplinks = {};
1607     foreach my $iface (keys %$ifaces) {
1608         my $d = $ifaces->{$iface};
1609         if (my $uplinkid = $d->{'uplink-id'}) {
1610             die "iface '$iface' - uplink-id $uplinkid is only allowed on physical and linux bond interfaces\n"
1611                 if $d->{type} ne 'eth' && $d->{type} ne 'bond';
1612
1613             die "iface '$iface' - uplink-id $uplinkid is already assigned on '$uplinks->{$uplinkid}'\n"
1614                 if $uplinks->{$uplinkid};
1615
1616             $uplinks->{$uplinkid} = $iface;
1617         }
1618     }
1619
1620     # check bridgeport option
1621     my $bridgeports = {};
1622     my $bridges = {};
1623     my $ifaces_copy = { %$ifaces };
1624     foreach my $iface (keys %$ifaces_copy) {
1625         my $d = $ifaces_copy->{$iface};
1626         if ($d->{type} eq 'bridge') {
1627             foreach my $p (split (/\s+/, $d->{bridge_ports} // '')) {
1628                 if($p =~ m/(\S+)\.(\d+)$/) {
1629                     my $vlanparent = $1;
1630                     if (!defined($ifaces_copy->{$p})) {
1631                         $ifaces_copy->{$p}->{type} = 'vlan';
1632                         $ifaces_copy->{$p}->{method} = 'manual';
1633                         $ifaces_copy->{$p}->{method6} = 'manual';
1634                         $ifaces_copy->{$p}->{mtu} = $ifaces_copy->{$vlanparent}->{mtu} if defined($ifaces_copy->{$1}->{mtu});
1635                     }
1636                 }
1637                 my $n = $ifaces_copy->{$p};
1638                 die "bridge '$iface' - unable to find bridge port '$p'\n" if !$n;
1639                 die "iface $p - ip address can't be set on interface if bridged in $iface\n"
1640                     if ($n->{method} && $n->{method} eq 'static' && $n->{address} ne '0.0.0.0') ||
1641                        ($n->{method6} && $n->{method6} eq 'static' && $n->{address6} ne '::');
1642                 &$check_mtu($ifaces_copy, $p, $iface);
1643                 $bridgeports->{$p} = $iface;
1644             }
1645             $bridges->{$iface} = $d;
1646         }
1647     }
1648
1649     foreach my $iface (keys %$ifaces) {
1650         my $d = $ifaces->{$iface};
1651
1652         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1653             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1654                 if $d->{$k} && !$bridgeports->{$iface};
1655         }
1656
1657         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1658             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1659         }
1660     }
1661
1662     my $raw = <<'NETWORKDOC';
1663 # network interface settings; autogenerated
1664 # Please do NOT modify this file directly, unless you know what
1665 # you're doing.
1666 #
1667 # If you want to manage parts of the network configuration manually,
1668 # please utilize the 'source' or 'source-directory' directives to do
1669 # so.
1670 # PVE will preserve these directives, but will NOT read its network
1671 # configuration from sourced files, so do not attempt to move any of
1672 # the PVE managed interfaces into external files!
1673
1674 NETWORKDOC
1675
1676     my $printed = {};
1677
1678     my $if_type_hash = {
1679         loopback => 100000,
1680         dummy => 100000,
1681         eth => 200000,
1682         OVSPort => 200000,
1683         OVSIntPort => 300000,
1684         OVSBond => 400000,
1685         bond => 400000,
1686         bridge => 500000,
1687         OVSBridge => 500000,
1688         vlan => 600000,
1689         vxlan => 600000,
1690    };
1691
1692     my $lookup_type_prio = sub {
1693         my ($iface, $ifaces) = @_;
1694
1695         my ($rootiface, @rest) = split(/[.:]/, $iface);
1696         my $childlevel = scalar(@rest);
1697         my $type = $ifaces->{$rootiface}->{type};
1698         return if !$type || $type eq 'unknown';
1699
1700         return $if_type_hash->{$type} + $childlevel
1701     };
1702
1703     foreach my $iface (sort {
1704         my $ref1 = $ifaces->{$a};
1705         my $ref2 = $ifaces->{$b};
1706         my $tp1 = &$lookup_type_prio($a, $ifaces);
1707         my $tp2 = &$lookup_type_prio($b, $ifaces);
1708
1709         # Only recognized types are in relation to each other. If one type
1710         # is unknown then only consider the interfaces' priority attributes.
1711         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1712
1713         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1714         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1715
1716         return $p1 <=> $p2 if $p1 != $p2;
1717
1718         return $a cmp $b;
1719     } keys %$ifaces) {
1720         next if $printed->{$iface};
1721         my $d = $ifaces->{$iface};
1722         my $pri = $d->{priority} // 0;
1723         if (@options && $options[0]->[0] < $pri) {
1724             do {
1725                 $raw .= (shift @options)->[1] . "\n";
1726             } while (@options && $options[0]->[0] < $pri);
1727             $raw .= "\n";
1728         }
1729
1730         $printed->{$iface} = 1;
1731         if ($d->{autostart}) {
1732             if ($d->{type} eq 'OVSBridge' && !$ifupdown2) {
1733                 # cannot use 'auto' for OVS, would add race with systemd ifup@.service
1734                 $raw .= "allow-ovs $iface\n";
1735             } else {
1736                 $raw .= "auto $iface\n";
1737             }
1738         }
1739
1740         # if 'inet6' is the only family
1741         if (scalar($d->{families}->@*) == 1 && $d->{families}[0] eq 'inet6') {
1742             $d->{comments6} = delete $d->{comments};
1743         }
1744
1745         my $i = 0; # some options should be printed only once
1746         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1747     }
1748
1749     $raw .= $_->[1] . "\n" foreach @options;
1750     return $raw;
1751 }
1752
1753 register_file('interfaces', "/etc/network/interfaces",
1754               \&read_etc_network_interfaces,
1755               \&write_etc_network_interfaces);
1756
1757
1758 sub read_iscsi_initiatorname {
1759     my ($filename, $fd) = @_;
1760
1761     while (defined(my $line = <$fd>)) {
1762         if ($line =~ m/^InitiatorName=(\S+)$/) {
1763             return $1;
1764         }
1765     }
1766
1767     return 'undefined';
1768 }
1769
1770 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1771               \&read_iscsi_initiatorname);
1772
1773 sub read_apt_auth {
1774     my ($filename, $fd) = @_;
1775
1776     local $/;
1777
1778     my $raw = defined($fd) ? <$fd> : '';
1779
1780     $raw =~ s/^\s+//;
1781
1782
1783     my @tokens = split(/\s+/, $raw);
1784
1785     my $data = {};
1786
1787     my $machine;
1788     while (defined(my $tok = shift @tokens)) {
1789
1790         $machine = shift @tokens if $tok eq 'machine';
1791         next if !$machine;
1792         $data->{$machine} = {} if !$data->{$machine};
1793
1794         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1795         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1796     };
1797
1798     return $data;
1799 }
1800
1801 my $format_apt_auth_data = sub {
1802     my $data = shift;
1803
1804     my $raw = '';
1805
1806     # sort longer entries first, so machine definitions with higher granularity are preferred
1807     for my $machine (sort { length($b) <=> length($a) || $a cmp $b} keys %$data) {
1808         my $d = $data->{$machine};
1809         next if !defined($d); # allow "deleting" set entries
1810
1811         $raw .= "machine $machine\n";
1812         $raw .= " login $d->{login}\n" if $d->{login};
1813         $raw .= " password $d->{password}\n" if $d->{password};
1814         $raw .= "\n";
1815     }
1816
1817     return $raw;
1818 };
1819
1820 sub write_apt_auth {
1821     my ($filename, $fh, $data) = @_;
1822
1823     my $raw = $format_apt_auth_data->($data);
1824
1825     die "write failed: $!" unless print $fh "$raw\n";
1826
1827     return $data;
1828 }
1829
1830 sub update_apt_auth {
1831     my ($filename, $fh, $data) = @_;
1832
1833     my $orig = read_apt_auth($filename, $fh);
1834
1835     foreach my $machine (keys %$data) {
1836         $orig->{$machine} = $data->{$machine};
1837     }
1838
1839     return $format_apt_auth_data->($orig);
1840 }
1841
1842 register_file(
1843     'apt-auth',
1844     "/etc/apt/auth.conf",
1845     \&read_apt_auth,
1846     \&write_apt_auth,
1847     \&update_apt_auth,
1848     perm => 0640,
1849 );
1850
1851 1;