src/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::File;
  10 use IO::Dir;
  11 use File::stat;
  12 use File::Basename;
  13 use Fcntl qw(:DEFAULT :flock);
  14 use PVE::SafeSyslog;
  15 use PVE::Exception qw(raise_param_exc);
  16 use PVE::Tools;
  17 use Storable qw(dclone);
  18 use Linux::Inotify2;
  19 use base 'Exporter';
  20 use JSON;
  21
  22 our @EXPORT_OK = qw(read_file write_file register_file);
  23
  24 my $ccache;
  25 my $ccachemap;
  26 my $ccacheregex;
  27 my $inotify;
  28 my $inotify_pid = 0;
  29 my $versions;
  30 my $shadowfiles = {
  31     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  32 };
  33
  34 # to enable cached operation, you need to call 'inotify_init'
  35 # inotify handles are a limited resource, so use with care (only
  36 # enable the cache if you really need it)
  37
  38 # Note: please close the inotify handle after you fork
  39
  40 sub ccache_default_writer {
  41     my ($filename, $data) = @_;
  42
  43     die "undefined config writer for '$filename' :ERROR";
  44 }
  45
  46 sub ccache_default_parser {
  47     my ($filename, $srcfd) = @_;
  48
  49     die "undefined config reader for '$filename' :ERROR";
  50 }
  51
  52 sub ccache_compute_diff {
  53     my ($filename, $shadow) = @_;
  54
  55     my $diff = '';
  56
  57     open (TMP, "diff -b -N -u '$filename' '$shadow'|");
  58
  59     while (my $line = <TMP>) {
  60         $diff .= $line;
  61     }
  62
  63     close (TMP);
  64
  65     $diff = undef if !$diff;
  66
  67     return $diff;
  68 }
  69
  70 sub ccache_info {
  71     my ($filename) = @_;
  72
  73     foreach my $uid (keys %$ccacheregex) {
  74         my $ccinfo = $ccacheregex->{$uid};
  75         my $dir = $ccinfo->{dir};
  76         my $regex = $ccinfo->{regex};
  77         if ($filename =~ m|^$dir/+$regex$|) {
  78             if (!$ccache->{$filename}) {
  79                 my $cp = {};
  80                 while (my ($k, $v) = each %$ccinfo) {
  81                     $cp->{$k} = $v;
  82                 }
  83                 $ccache->{$filename} = $cp;
  84             }
  85             return ($ccache->{$filename}, $filename);
  86         }
  87     }
  88
  89     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  90
  91     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  92
  93     return ($ccache->{$filename}, $filename);
  94 }
  95
  96 sub write_file {
  97     my ($fileid, $data, $full) = @_;
  98
  99     my ($ccinfo, $filename) = ccache_info($fileid);
 100
 101     my $writer = $ccinfo->{writer};
 102
 103     my $realname = $filename;
 104
 105     my $shadow;
 106     if ($shadow = $shadowfiles->{$filename}) {
 107         $realname = $shadow;
 108     }
 109
 110     my $perm = $ccinfo->{perm} || 0644;
 111
 112     my $tmpname = "$realname.tmp.$$";
 113
 114     my $res;
 115     eval {
 116         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 117         die "unable to open file '$tmpname' - $!\n" if !$fh;
 118
 119         $res = &$writer($filename, $fh, $data);
 120
 121         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 122     };
 123     my $err = $@;
 124
 125     $ccinfo->{version} = undef;
 126
 127     if ($err) {
 128         unlink $tmpname;
 129         die $err;
 130     }
 131
 132     if (!rename($tmpname, $realname)) {
 133         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 134         unlink $tmpname;
 135         die $msg;
 136     }
 137
 138     my $diff;
 139     if ($shadow && $full) {
 140         $diff = ccache_compute_diff ($filename, $shadow);
 141     }
 142
 143     if ($full) {
 144         return { data => $res, changes => $diff };
 145     }
 146
 147     return $res;
 148 }
 149
 150 sub update_file {
 151     my ($fileid, $data, @args) = @_;
 152
 153     my ($ccinfo, $filename) = ccache_info($fileid);
 154
 155     my $update = $ccinfo->{update};
 156
 157     die "unable to update/merge data" if !$update;
 158
 159     my $lkfn = "$filename.lock";
 160
 161     my $timeout = 10;
 162
 163     my $fd;
 164
 165     my $code = sub {
 166
 167         $fd = IO::File->new ($filename, "r");
 168
 169         my $new = &$update($filename, $fd, $data, @args);
 170
 171         if (defined($new)) {
 172             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 173         } else {
 174             unlink $filename;
 175         }
 176     };
 177
 178     PVE::Tools::lock_file($lkfn, $timeout, $code);
 179     my $err = $@;
 180
 181     close($fd) if defined($fd);
 182
 183     die $err if $err;
 184
 185     return undef;
 186 }
 187
 188 sub discard_changes {
 189     my ($fileid, $full) = @_;
 190
 191     my ($ccinfo, $filename) = ccache_info($fileid);
 192
 193     if (my $copy = $shadowfiles->{$filename}) {
 194         unlink $copy;
 195     }
 196
 197     return read_file ($filename, $full);
 198 }
 199
 200 sub read_file {
 201     my ($fileid, $full) = @_;
 202
 203     my $parser;
 204
 205     my ($ccinfo, $filename) = ccache_info($fileid);
 206
 207     $parser = $ccinfo->{parser};
 208
 209     my $fd;
 210     my $shadow;
 211
 212     poll() if $inotify; # read new inotify events
 213
 214     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 215
 216     my $cver = $versions->{$filename};
 217
 218     if (my $copy = $shadowfiles->{$filename}) {
 219         if ($fd = IO::File->new ($copy, "r")) {
 220             $shadow = $copy;
 221         } else {
 222             $fd = IO::File->new ($filename, "r");
 223         }
 224     } else {
 225         $fd = IO::File->new ($filename, "r");
 226     }
 227
 228     my $acp = $ccinfo->{always_call_parser};
 229
 230     if (!$fd) {
 231         $ccinfo->{version} = undef;
 232         $ccinfo->{data} = undef;
 233         $ccinfo->{diff} = undef;
 234         return undef if !$acp;
 235     }
 236
 237     my $noclone = $ccinfo->{noclone};
 238
 239     # file unchanged?
 240     if (!$ccinfo->{nocache} &&
 241         $inotify && $versions->{$filename} &&
 242         defined ($ccinfo->{data}) &&
 243         defined ($ccinfo->{version}) &&
 244         ($ccinfo->{readonce} ||
 245          ($ccinfo->{version} == $versions->{$filename}))) {
 246
 247         my $ret;
 248         if (!$noclone && ref ($ccinfo->{data})) {
 249             $ret->{data} = dclone ($ccinfo->{data});
 250         } else {
 251             $ret->{data} = $ccinfo->{data};
 252         }
 253         $ret->{changes} = $ccinfo->{diff};
 254
 255         return $full ? $ret : $ret->{data};
 256     }
 257
 258     my $diff;
 259
 260     if ($shadow) {
 261         $diff = ccache_compute_diff ($filename, $shadow);
 262     }
 263
 264     my $res = &$parser($filename, $fd);
 265
 266     if (!$ccinfo->{nocache}) {
 267         $ccinfo->{version} = $cver;
 268     }
 269
 270     # we cache data with references, so we always need to
 271     # dclone this data. Else the original data may get
 272     # modified.
 273     $ccinfo->{data} = $res;
 274
 275     # also store diff
 276     $ccinfo->{diff} = $diff;
 277
 278     my $ret;
 279     if (!$noclone && ref ($ccinfo->{data})) {
 280         $ret->{data} = dclone ($ccinfo->{data});
 281     } else {
 282         $ret->{data} = $ccinfo->{data};
 283     }
 284     $ret->{changes} = $ccinfo->{diff};
 285
 286     return $full ? $ret : $ret->{data};
 287 }
 288
 289 sub parse_ccache_options {
 290     my ($ccinfo, %options) = @_;
 291
 292     foreach my $opt (keys %options) {
 293         my $v = $options{$opt};
 294         if ($opt eq 'readonce') {
 295             $ccinfo->{$opt} = $v;
 296         } elsif ($opt eq 'nocache') {
 297             $ccinfo->{$opt} = $v;
 298         } elsif ($opt eq 'shadow') {
 299             $ccinfo->{$opt} = $v;
 300         } elsif ($opt eq 'perm') {
 301             $ccinfo->{$opt} = $v;
 302         } elsif ($opt eq 'noclone') {
 303             # noclone flag for large read-only data chunks like aplinfo
 304             $ccinfo->{$opt} = $v;
 305         } elsif ($opt eq 'always_call_parser') {
 306             # when set, we call parser even when the file does not exists.
 307             # this allows the parser to return some default
 308             $ccinfo->{$opt} = $v;
 309         } else {
 310             die "internal error - unsupported option '$opt'";
 311         }
 312     }
 313 }
 314
 315 sub register_file {
 316     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 317
 318     die "can't register file '$filename' after inotify_init" if $inotify;
 319
 320     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 321     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 322
 323     my $ccinfo = {};
 324
 325     $ccinfo->{id} = $id;
 326     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 327     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 328     $ccinfo->{update} = $update;
 329
 330     parse_ccache_options($ccinfo, %options);
 331
 332     if ($options{shadow}) {
 333         $shadowfiles->{$filename} = $options{shadow};
 334     }
 335
 336     $ccachemap->{$id} = $filename;
 337     $ccache->{$filename} = $ccinfo;
 338 }
 339
 340 sub register_regex {
 341     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 342
 343     die "can't register regex after initify_init" if $inotify;
 344
 345     my $uid = "$dir/$regex";
 346     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 347
 348     my $ccinfo = {};
 349
 350     $ccinfo->{dir} = $dir;
 351     $ccinfo->{regex} = $regex;
 352     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 353     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 354     $ccinfo->{update} = $update;
 355
 356     parse_ccache_options($ccinfo, %options);
 357
 358     $ccacheregex->{$uid} = $ccinfo;
 359 }
 360
 361 sub poll {
 362     return if !$inotify;
 363
 364     if ($inotify_pid != $$) {
 365         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 366         $inotify = undef;
 367     } else {
 368         1 while $inotify && $inotify->poll;
 369     }
 370 }
 371
 372 sub flushcache {
 373     foreach my $filename (keys %$ccache) {
 374         $ccache->{$filename}->{version} = undef;
 375         $ccache->{$filename}->{data} = undef;
 376         $ccache->{$filename}->{diff} = undef;
 377     }
 378 }
 379
 380 sub inotify_close {
 381     $inotify = undef;
 382 }
 383
 384 sub inotify_init {
 385
 386     die "only one inotify instance allowed" if $inotify;
 387
 388     $inotify =  Linux::Inotify2->new()
 389         || die "Unable to create new inotify object: $!";
 390
 391     $inotify->blocking (0);
 392
 393     $versions = {};
 394
 395     my $dirhash = {};
 396     foreach my $fn (keys %$ccache) {
 397         my $dir = dirname ($fn);
 398         my $base = basename ($fn);
 399
 400         $dirhash->{$dir}->{$base} = $fn;
 401
 402         if (my $sf = $shadowfiles->{$fn}) {
 403             $base = basename ($sf);
 404             $dir = dirname ($sf);
 405             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 406         }
 407     }
 408
 409     foreach my $uid (keys %$ccacheregex) {
 410         my $ccinfo = $ccacheregex->{$uid};
 411         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 412     }
 413
 414     $inotify_pid = $$;
 415
 416     foreach my $dir (keys %$dirhash) {
 417
 418         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 419         $inotify->watch ($dir, $evlist, sub {
 420             my $e = shift;
 421             my $name = $e->name;
 422
 423             if ($inotify_pid != $$) {
 424                 syslog ('err', "got inotify event in wrong process");
 425             }
 426
 427             if ($e->IN_ISDIR || !$name) {
 428                 return;
 429             }
 430
 431             if ($e->IN_Q_OVERFLOW) {
 432                 syslog ('info', "got inotify overflow - flushing cache");
 433                 flushcache();
 434                 return;
 435             }
 436
 437             if ($e->IN_UNMOUNT) {
 438                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 439                 $inotify = undef;
 440             }
 441             if ($e->IN_IGNORED) {
 442                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 443                 $inotify = undef;
 444             }
 445
 446             if ($dirhash->{$dir}->{_regex}) {
 447                 foreach my $uid (keys %$ccacheregex) {
 448                     my $ccinfo = $ccacheregex->{$uid};
 449                     next if $dir ne $ccinfo->{dir};
 450                     my $regex = $ccinfo->{regex};
 451                     if ($regex && ($name =~ m|^$regex$|)) {
 452
 453                         my $fn = "$dir/$name";
 454                         $versions->{$fn}++;
 455                         #print "VERSION:$fn:$versions->{$fn}\n";
 456                     }
 457                 }
 458             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 459
 460                 $versions->{$fn}++;
 461                 #print "VERSION:$fn:$versions->{$fn}\n";
 462             }
 463         });
 464     }
 465
 466     foreach my $dir (keys %$dirhash) {
 467         foreach my $name (keys %{$dirhash->{$dir}}) {
 468             if ($name eq '_regex') {
 469                 foreach my $uid (keys %$ccacheregex) {
 470                     my $ccinfo = $ccacheregex->{$uid};
 471                     next if $dir ne $ccinfo->{dir};
 472                     my $re = $ccinfo->{regex};
 473                     if (my $fd = IO::Dir->new ($dir)) {
 474                         while (defined(my $de = $fd->read)) {
 475                             if ($de =~ m/^$re$/) {
 476                                 my $fn = "$dir/$de";
 477                                 $versions->{$fn}++; # init with version
 478                                 #print "init:$fn:$versions->{$fn}\n";
 479                             }
 480                         }
 481                     }
 482                 }
 483             } else {
 484                 my $fn = $dirhash->{$dir}->{$name};
 485                 $versions->{$fn}++; # init with version
 486                 #print "init:$fn:$versions->{$fn}\n";
 487             }
 488         }
 489     }
 490 }
 491
 492 my $cached_nodename;
 493
 494 sub nodename {
 495
 496     return $cached_nodename if $cached_nodename;
 497
 498     my ($sysname, $nodename) = POSIX::uname();
 499
 500     $nodename =~ s/\..*$//; # strip domain part, if any
 501
 502     die "unable to read node name\n" if !$nodename;
 503
 504     $cached_nodename = $nodename;
 505
 506     return $cached_nodename;
 507 }
 508
 509 sub read_etc_hostname {
 510     my ($filename, $fd) = @_;
 511
 512     my $hostname = <$fd>;
 513
 514     chomp $hostname;
 515
 516     $hostname =~ s/\..*$//; # strip domain part, if any
 517
 518     return $hostname;
 519 }
 520
 521 sub write_etc_hostname {
 522     my ($filename, $fh, $hostname) = @_;
 523
 524     die "write failed: $!" unless print $fh "$hostname\n";
 525
 526     return $hostname;
 527 }
 528
 529 register_file('hostname', "/etc/hostname",
 530               \&read_etc_hostname,
 531               \&write_etc_hostname);
 532
 533 sub read_etc_resolv_conf {
 534     my ($filename, $fh) = @_;
 535
 536     my $res = {};
 537
 538     my $nscount = 0;
 539     while (my $line = <$fh>) {
 540         chomp $line;
 541         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 542             $res->{search} = $2;
 543         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
 544             $nscount++;
 545             if ($nscount <= 3) {
 546                 $res->{"dns$nscount"} = $1;
 547             }
 548         }
 549     }
 550
 551     return $res;
 552 }
 553
 554 sub update_etc_resolv_conf {
 555     my ($filename, $fh, $resolv, @args) = @_;
 556
 557     my $data = "";
 558
 559     $data = "search $resolv->{search}\n"
 560         if $resolv->{search};
 561
 562     my $written = {};
 563     foreach my $k ("dns1", "dns2", "dns3") {
 564         my $ns = $resolv->{$k};
 565         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 566             $written->{$ns} = 1;
 567             $data .= "nameserver $ns\n";
 568         }
 569     }
 570
 571     while (my $line = <$fh>) {
 572         next if $line =~ m/^(search|domain|nameserver)\s+/;
 573         $data .= $line
 574     }
 575
 576     return $data;
 577 }
 578
 579 register_file('resolvconf', "/etc/resolv.conf",
 580               \&read_etc_resolv_conf, undef,
 581               \&update_etc_resolv_conf);
 582
 583 sub read_etc_timezone {
 584     my ($filename, $fd) = @_;
 585
 586     my $timezone = <$fd>;
 587
 588     chomp $timezone;
 589
 590     return $timezone;
 591 }
 592
 593 sub write_etc_timezone {
 594     my ($filename, $fh, $timezone) = @_;
 595
 596     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 597
 598     raise_param_exc({ 'timezone' => "No such timezone" })
 599         if (! -f $tzinfo);
 600
 601     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 602
 603     print $fh "$timezone\n";
 604
 605     unlink ("/etc/localtime");
 606     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 607
 608 }
 609
 610 register_file('timezone', "/etc/timezone",
 611               \&read_etc_timezone,
 612               \&write_etc_timezone);
 613
 614 sub read_active_workers {
 615     my ($filename, $fh) = @_;
 616
 617     return [] if !$fh;
 618
 619     my $res = [];
 620     while (defined (my $line = <$fh>)) {
 621         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 622             my $upid = $1;
 623             my $saved = $2;
 624             my $endtime = $4;
 625             my $status = $6;
 626             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 627                 $task->{upid} = $upid;
 628                 $task->{saved} = $saved;
 629                 $task->{endtime} = hex($endtime) if $endtime;
 630                 $task->{status} = $status if $status;
 631                 push @$res, $task;
 632             }
 633         } else {
 634             warn "unable to parse line: $line";
 635         }
 636     }
 637
 638     return $res;
 639
 640 }
 641
 642 sub write_active_workers {
 643     my ($filename, $fh, $tasklist) = @_;
 644
 645     my $raw = '';
 646     foreach my $task (@$tasklist) {
 647         my $upid = $task->{upid};
 648         my $saved = $task->{saved} ? 1 : 0;
 649         if ($task->{endtime}) {
 650             if ($task->{status}) {
 651                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
 652             } else {
 653                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
 654             }
 655         } else {
 656             $raw .= "$upid $saved\n";
 657         }
 658     }
 659
 660     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 661 }
 662
 663 register_file('active', "/var/log/pve/tasks/active",
 664               \&read_active_workers,
 665               \&write_active_workers);
 666
 667
 668 my $bond_modes = { 'balance-rr' => 0,
 669                    'active-backup' => 1,
 670                    'balance-xor' => 2,
 671                    'broadcast' => 3,
 672                    '802.3ad' => 4,
 673                    'balance-tlb' => 5,
 674                    'balance-alb' => 6,
 675                };
 676
 677 my $ovs_bond_modes = {
 678     'active-backup' => 1,
 679     'balance-slb' => 1,
 680     'lacp-balance-slb' => 1,
 681     'lacp-balance-tcp' => 1,
 682 };
 683
 684 #sub get_bond_modes {
 685 #    return $bond_modes;
 686 #}
 687
 688 my $parse_ovs_option = sub {
 689     my ($data) = @_;
 690
 691     my $opts = {};
 692     foreach my $kv (split (/\s+/, $data || '')) {
 693         my ($k, $v) = split('=', $kv, 2);
 694         $opts->{$k} = $v if $k && $v;
 695     }
 696     return $opts;
 697 };
 698
 699 my $set_ovs_option = sub {
 700     my ($d, %params) = @_;
 701
 702     my $opts = &$parse_ovs_option($d->{ovs_options});
 703
 704     foreach my $k (keys %params) {
 705         my $v = $params{$k};
 706         if ($v) {
 707             $opts->{$k} = $v;
 708         } else {
 709             delete $opts->{$k};
 710         }
 711     }
 712
 713     my $res = [];
 714     foreach my $k (keys %$opts) {
 715         push @$res, "$k=$opts->{$k}";
 716     }
 717
 718     if (my $new = join(' ', @$res)) {
 719         $d->{ovs_options} = $new;
 720         return $d->{ovs_options};
 721     } else {
 722         delete $d->{ovs_options};
 723         return undef;
 724     }
 725 };
 726
 727 my $extract_ovs_option = sub {
 728     my ($d, $name) = @_;
 729
 730     my $opts = &$parse_ovs_option($d->{ovs_options});
 731
 732     my $v = delete $opts->{$name};
 733
 734     my $res = [];
 735     foreach my $k (keys %$opts) {
 736         push @$res, "$k=$opts->{$k}";
 737     }
 738
 739     if (my $new = join(' ', @$res)) {
 740         $d->{ovs_options} = $new;
 741     } else {
 742         delete $d->{ovs_options};
 743     }
 744
 745     return $v;
 746 };
 747
 748 # config => {
 749 #   ifaces => {
 750 #     $ifname => {
 751 #       <optional> exists => BOOL,
 752 #       <optional> active => BOOL,
 753 #       <optional> autostart => BOOL,
 754 #       <auto> priority => INT,
 755 #
 756 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
 757 #
 758 #       families => ["inet", "inet6", ...],
 759 #
 760 #       method => "manual" | "static" | "dhcp" | ... ,
 761 #       address => IP,
 762 #       netmask => SUBNET,
 763 #       broadcast => IP,
 764 #       gateway => IP,
 765 #       comments => [ "..." ],
 766 #
 767 #       method6 => "manual" | "static" | "dhcp" | ... ,
 768 #       address6 => IP,
 769 #       netmask6 => SUBNET,
 770 #       gateway6 => IP,
 771 #       comments6 => [ "..." ],
 772 #
 773 #       <known options>, # like bridge_ports, ovs_*
 774 #
 775 #       # extra/unknown options stored by-family:
 776 #       options => { <inet options>... }
 777 #       options6 => { <inet6 options>... }
 778 #     }
 779 #   },
 780 #   options => [
 781 #     # mappings end up here as well, as we don't need to understand them
 782 #     [priority,line]
 783 #   ]
 784 # }
 785 sub read_etc_network_interfaces {
 786     my ($filename, $fh) = @_;
 787     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
 788     my $active = PVE::Network::get_active_interfaces();
 789     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
 790 }
 791
 792 sub __read_etc_network_interfaces {
 793     my ($fh, $proc_net_dev, $active_ifaces) = @_;
 794
 795     my $config = {};
 796     my $ifaces = $config->{ifaces} = {};
 797     my $options = $config->{options} = [];
 798
 799     my $line;
 800
 801     if ($proc_net_dev) {
 802         while (defined ($line = <$proc_net_dev>)) {
 803             if ($line =~ m/^\s*(eth\d+):.*/) {
 804                 $ifaces->{$1}->{exists} = 1;
 805             }
 806         }
 807         close($proc_net_dev);
 808     }
 809
 810     # we try to keep order inside the file
 811     my $priority = 2; # 1 is reserved for lo
 812
 813     SECTION: while (defined ($line = <$fh>)) {
 814         chomp ($line);
 815         next if $line =~ m/^\s*#/;
 816
 817         if ($line =~ m/^\s*auto\s+(.*)$/) {
 818             my @aa = split (/\s+/, $1);
 819
 820             foreach my $a (@aa) {
 821                 $ifaces->{$a}->{autostart} = 1;
 822             }
 823
 824         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
 825             my $i = $1;
 826             my $family = $2;
 827             my $f = { method => $3 }; # by family, merged to $d with a $suffix
 828             (my $suffix = $family) =~ s/^inet//;
 829
 830             my $d = $ifaces->{$i} ||= {};
 831             $d->{priority} = $priority++ if !$d->{priority};
 832             push @{$d->{families}}, $family;
 833
 834             while (defined ($line = <$fh>)) {
 835                 chomp $line;
 836                 if ($line =~ m/^\s*#(.*?)\s*$/) {
 837                     # NOTE: we use 'comments' instead of 'comment' to
 838                     # avoid automatic utf8 conversion
 839                     $f->{comments} = '' if !$f->{comments};
 840                     $f->{comments} .= "$1\n";
 841                 } elsif ($line =~ m/^\s*(?:iface\s
 842                                           |mapping\s
 843                                           |auto\s
 844                                           |allow-
 845                                           |source\s
 846                                           |source-directory\s
 847                                         )/x) {
 848                     last;
 849                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
 850                     my $option = $1;
 851                     my ($id, $value) = ($2, $3);
 852                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
 853                         $f->{$id} = $value;
 854                     } elsif ($id eq 'ovs_type' || $id eq 'ovs_options'|| $id eq 'ovs_bridge' ||
 855                              $id eq 'ovs_bonds' || $id eq 'ovs_ports') {
 856                         $d->{$id} = $value;
 857                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 858                         my $devs = {};
 859                         foreach my $p (split (/\s+/, $value)) {
 860                             next if $p eq 'none';
 861                             $devs->{$p} = 1;
 862                         }
 863                         my $str = join (' ', sort keys %{$devs});
 864                         if ($d->{$id}) {
 865                             $d->{$id} .= ' ' . $str if $str;
 866                         } else {
 867                             $d->{$id} = $str || '';
 868                         }
 869                     } elsif ($id eq 'bridge_stp') {
 870                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 871                             $d->{$id} = 'on';
 872                         } else {
 873                             $d->{$id} = 'off';
 874                         }
 875                     } elsif ($id eq 'bridge_fd') {
 876                         $d->{$id} = $value;
 877                     } elsif ($id eq 'bridge_vlan_aware') {
 878                         $d->{$id} = 1;
 879                     } elsif ($id eq 'bond_miimon') {
 880                         $d->{$id} = $value;
 881                     } elsif ($id eq 'bond_xmit_hash_policy') {
 882                         $d->{$id} = $value;
 883                     } elsif ($id eq 'bond_mode') {
 884                         # always use names
 885                         foreach my $bm (keys %$bond_modes) {
 886                             my $id = $bond_modes->{$bm};
 887                             if ($id eq $value) {
 888                                 $value = $bm;
 889                                 last;
 890                             }
 891                         }
 892                         $d->{$id} = $value;
 893                     } else {
 894                         push @{$f->{options}}, $option;
 895                     }
 896                 } else {
 897                     last;
 898                 }
 899             }
 900             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
 901             last SECTION if !defined($line);
 902             redo SECTION;
 903         } elsif ($line =~ /\w/) {
 904             push @$options, [$priority++, $line];
 905         }
 906     }
 907
 908     foreach my $ifname (@$active_ifaces) {
 909         if (my $iface = $ifaces->{$ifname}) {
 910             $iface->{active} = 1;
 911         }
 912     }
 913
 914     if (!$ifaces->{lo}) {
 915         $ifaces->{lo}->{priority} = 1;
 916         $ifaces->{lo}->{method} = 'loopback';
 917         $ifaces->{lo}->{type} = 'loopback';
 918         $ifaces->{lo}->{autostart} = 1;
 919     }
 920
 921     foreach my $iface (keys %$ifaces) {
 922         my $d = $ifaces->{$iface};
 923         if ($iface =~ m/^bond\d+$/) {
 924             if (!$d->{ovs_type}) {
 925                 $d->{type} = 'bond';
 926             } elsif ($d->{ovs_type} eq 'OVSBond') {
 927                 $d->{type} = $d->{ovs_type};
 928                 # translate: ovs_options => bond_mode
 929                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
 930                 my $lacp = &$extract_ovs_option($d, 'lacp');
 931                 if ($lacp && $lacp eq 'active') {
 932                     if ($d->{'bond_mode'} eq 'balance-slb') {
 933                         $d->{'bond_mode'} = 'lacp-balance-slb';
 934                     }
 935                 }
 936                 # Note: balance-tcp needs lacp
 937                 if ($d->{'bond_mode'} eq 'balance-tcp') {
 938                     $d->{'bond_mode'} = 'lacp-balance-tcp';
 939                 }
 940                 my $tag = &$extract_ovs_option($d, 'tag');
 941                 $d->{ovs_tag} = $tag if defined($tag);
 942             } else {
 943                 $d->{type} = 'unknown';
 944             }
 945         } elsif ($iface =~ m/^vmbr\d+$/) {
 946             if (!$d->{ovs_type}) {
 947                 $d->{type} = 'bridge';
 948
 949                 if (!defined ($d->{bridge_fd})) {
 950                     $d->{bridge_fd} = 0;
 951                 }
 952                 if (!defined ($d->{bridge_stp})) {
 953                     $d->{bridge_stp} = 'off';
 954                 }
 955             } elsif ($d->{ovs_type} eq 'OVSBridge') {
 956                 $d->{type} = $d->{ovs_type};
 957             } else {
 958                 $d->{type} = 'unknown';
 959             }
 960         } elsif ($iface =~ m/^(\S+):\d+$/) {
 961             $d->{type} = 'alias';
 962             if (defined ($ifaces->{$1})) {
 963                 $d->{exists} = $ifaces->{$1}->{exists};
 964             } else {
 965                 $ifaces->{$1}->{exists} = 0;
 966                 $d->{exists} = 0;
 967             }
 968         } elsif ($iface =~ m/^(\S+)\.\d+$/) {
 969             $d->{type} = 'vlan';
 970             if (defined ($ifaces->{$1})) {
 971                 $d->{exists} = $ifaces->{$1}->{exists};
 972             } else {
 973                 $ifaces->{$1}->{exists} = 0;
 974                 $d->{exists} = 0;
 975             }
 976         } elsif ($iface =~ m/^eth\d+$/) {
 977             if (!$d->{ovs_type}) {
 978                 $d->{type} = 'eth';
 979             } elsif ($d->{ovs_type} eq 'OVSPort') {
 980                 $d->{type} = $d->{ovs_type};
 981                 my $tag = &$extract_ovs_option($d, 'tag');
 982                 $d->{ovs_tag} = $tag if defined($tag);
 983             } else {
 984                 $d->{type} = 'unknown';
 985             }
 986         } elsif ($iface =~ m/^lo$/) {
 987             $d->{type} = 'loopback';
 988         } else {
 989             if (!$d->{ovs_type}) {
 990                 $d->{type} = 'unknown';
 991             } elsif ($d->{ovs_type} eq 'OVSIntPort') {
 992                 $d->{type} = $d->{ovs_type};
 993                 my $tag = &$extract_ovs_option($d, 'tag');
 994                 $d->{ovs_tag} = $tag if defined($tag);
 995             }
 996         }
 997
 998         $d->{method} = 'manual' if !$d->{method};
 999         $d->{method6} = 'manual' if !$d->{method6};
1000
1001         $d->{families} ||= ['inet'];
1002     }
1003
1004     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1005     # from the {options} hash for them to be removed correctly.
1006     @$options = grep {defined($_)} map {
1007         my ($pri, $line) = @$_;
1008         if ($line =~ /^allow-(\S+)\s+(.*)$/) {
1009             my $bridge = $1;
1010             my @ports = split(/\s+/, $2);
1011             if (defined(my $br = $ifaces->{$bridge})) {
1012                 # if this port is part of a bridge, remove it
1013                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1014                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1015             }
1016             # create the allow line for the remaining ports, or delete if empty
1017             if (@ports) {
1018                 [$pri, "allow-$bridge " . join(' ', @ports)];
1019             } else {
1020                 undef;
1021             }
1022         } else {
1023             # don't modify other lines
1024             $_;
1025         }
1026     } @$options;
1027
1028     return $config;
1029 }
1030
1031 sub __interface_to_string {
1032     my ($iface, $d, $family, $first_block) = @_;
1033
1034     (my $suffix = $family) =~ s/^inet//;
1035
1036     return '' if !($d && $d->{"method$suffix"});
1037
1038     my $raw = '';
1039
1040     $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1041     $raw .= "\taddress  " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
1042     $raw .= "\tnetmask  " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
1043     $raw .= "\tgateway  " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1044     $raw .= "\tbroadcast  " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
1045
1046     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1047                  comments => 1, autostart => 1, options => 1,
1048                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1049                  method6 => 1, families => 1, options6 => 1,
1050                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1 };
1051
1052     if (!$first_block) {
1053         # not printing out options
1054     } elsif ($d->{type} eq 'bridge') {
1055
1056         my $ports = $d->{bridge_ports} || 'none';
1057         $raw .= "\tbridge_ports $ports\n";
1058         $done->{bridge_ports} = 1;
1059
1060         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1061         $raw .= "\tbridge_stp $v\n";
1062         $done->{bridge_stp} = 1;
1063
1064         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1065         $raw .= "\tbridge_fd $v\n";
1066         $done->{bridge_fd} = 1;
1067
1068         if( defined($d->{bridge_vlan_aware})) {
1069             $raw .= "\tbridge_vlan_aware yes\n";
1070         }
1071         $done->{bridge_vlan_aware} = 1;
1072
1073     } elsif ($d->{type} eq 'bond') {
1074
1075         my $slaves = $d->{slaves} || 'none';
1076         $raw .= "\tslaves $slaves\n";
1077         $done->{slaves} = 1;
1078
1079         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1080         $raw .= "\tbond_miimon $v\n";
1081         $done->{'bond_miimon'} = 1;
1082
1083         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1084         $raw .= "\tbond_mode $v\n";
1085         $done->{'bond_mode'} = 1;
1086
1087         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1088             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1089             $raw .= "\tbond_xmit_hash_policy $d->{'bond_xmit_hash_policy'}\n";
1090         }
1091         $done->{'bond_xmit_hash_policy'} = 1;
1092
1093     } elsif ($d->{type} eq 'OVSBridge') {
1094
1095         $raw .= "\tovs_type $d->{type}\n";
1096         $done->{ovs_type} = 1;
1097
1098         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1099         $done->{ovs_ports} = 1;
1100     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1101              $d->{type} eq 'OVSBond') {
1102
1103         $d->{autostart} = 0; # started by the bridge
1104
1105         if (defined($d->{ovs_tag})) {
1106             &$set_ovs_option($d, tag => $d->{ovs_tag});
1107         }
1108         $done->{ovs_tag} = 1;
1109
1110         if ($d->{type} eq 'OVSBond') {
1111
1112             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1113
1114             $ovs_bond_modes->{$d->{bond_mode}} ||
1115                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1116
1117             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1118                 &$set_ovs_option($d, lacp => 'active');
1119                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1120             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1121                 &$set_ovs_option($d, lacp => 'active');
1122                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1123             } else {
1124                 &$set_ovs_option($d, lacp => undef);
1125                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1126             }
1127             $done->{bond_mode} = 1;
1128
1129             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1130             $done->{ovs_bonds} = 1;
1131         }
1132
1133         $raw .= "\tovs_type $d->{type}\n";
1134         $done->{ovs_type} = 1;
1135
1136         if ($d->{ovs_bridge}) {
1137             $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
1138             $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
1139             $done->{ovs_bridge} = 1;
1140         }
1141     }
1142
1143     if ($first_block) {
1144         # print other settings
1145         foreach my $k (keys %$d) {
1146            next if $done->{$k};
1147            next if !$d->{$k};
1148            $raw .= "\t$k $d->{$k}\n";
1149         }
1150     }
1151
1152     foreach my $option (@{$d->{"options$suffix"}}) {
1153         $raw .= "\t$option\n";
1154     }
1155
1156     # add comments
1157     my $comments = $d->{"comments$suffix"} || '';
1158     foreach my $cl (split(/\n/, $comments)) {
1159         $raw .= "#$cl\n";
1160     }
1161
1162     $raw .= "\n";
1163
1164     return $raw;
1165 }
1166
1167
1168 sub write_etc_network_interfaces {
1169     my ($filename, $fh, $config) = @_;
1170     my $raw = __write_etc_network_interfaces($config);
1171     PVE::Tools::safe_print($filename, $fh, $raw);
1172 }
1173 sub __write_etc_network_interfaces {
1174     my ($config) = @_;
1175
1176     my $ifaces = $config->{ifaces};
1177     my @options = @{$config->{options}};
1178
1179     my $used_ports = {};
1180
1181     foreach my $iface (keys %$ifaces) {
1182         my $d = $ifaces->{$iface};
1183
1184         my $ports = '';
1185         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1186             $ports .= " $d->{$k}" if $d->{$k};
1187         }
1188
1189         foreach my $p (PVE::Tools::split_list($ports)) {
1190             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1191                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1192             $used_ports->{$p} = $iface;
1193         }
1194     }
1195
1196     # delete unused OVS ports
1197     foreach my $iface (keys %$ifaces) {
1198         my $d = $ifaces->{$iface};
1199         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1200             $d->{type} eq 'OVSBond') {
1201             my $brname = $used_ports->{$iface};
1202             if (!$brname || !$ifaces->{$brname}) {
1203                 if ($iface =~ /^eth/) {
1204                     $ifaces->{$iface} = { type => 'eth',
1205                                           exists => 1,
1206                                           method => 'manual',
1207                                           families => ['inet'] };
1208                 } else {
1209                     delete $ifaces->{$iface};
1210                 }
1211                 next;
1212             }
1213             my $bd = $ifaces->{$brname};
1214             if ($bd->{type} ne 'OVSBridge') {
1215                 delete $ifaces->{$iface};
1216                 next;
1217             }
1218         }
1219     }
1220
1221     # create OVS bridge ports
1222     foreach my $iface (keys %$ifaces) {
1223         my $d = $ifaces->{$iface};
1224         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1225             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1226                 my $n = $ifaces->{$p};
1227                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1228                     if !$n;
1229                 $n->{autostart} = 0;
1230                 if ($n->{type} eq 'eth') {
1231                     $n->{type} = 'OVSPort';
1232                     $n->{ovs_bridge} = $iface;
1233                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1234                     $n->{type} eq 'OVSIntPort') {
1235                     $n->{ovs_bridge} = $iface;
1236                 } else {
1237                     die "interface '$p' is not defined as OVS port/bond\n";
1238                 }
1239             }
1240         }
1241     }
1242
1243     # check OVS bond ports
1244     foreach my $iface (keys %$ifaces) {
1245         my $d = $ifaces->{$iface};
1246         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1247             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1248                 my $n = $ifaces->{$p};
1249                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1250                     if !$n;
1251                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1252                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1253             }
1254         }
1255     }
1256
1257     my $raw = <<'NETWORKDOC';
1258 # network interface settings; autogenerated
1259 # Please do NOT modify this file directly, unless you know what
1260 # you're doing.
1261 #
1262 # If you want to manage part of the network configuration manually,
1263 # please utilize the 'source' or 'source-directory' directives to do
1264 # so.
1265 # PVE will preserve these directives, but will NOT its network
1266 # configuration from sourced files, so do not attempt to move any of
1267 # the PVE managed interfaces into external files!
1268
1269 NETWORKDOC
1270
1271     my $printed = {};
1272
1273     my $if_type_hash = {
1274         loopback => 100000,
1275         eth => 200000,
1276         bond => 300000,
1277         bridge => 400000,
1278    };
1279
1280     my $lookup_type_prio = sub {
1281         my $iface = shift;
1282
1283         my $child = 0;
1284         if ($iface =~ m/^(\S+)(\.|:)\d+$/) {
1285             $iface = $1;
1286             $child = 1;
1287         }
1288
1289         my $pri;
1290         if ($iface eq 'lo') {
1291             $pri = $if_type_hash->{loopback};
1292         } elsif ($iface =~ m/^eth\d+$/) {
1293             $pri = $if_type_hash->{eth} + $child;
1294         } elsif ($iface =~ m/^bond\d+$/) {
1295             $pri = $if_type_hash->{bond} + $child;
1296         } elsif ($iface =~ m/^vmbr\d+$/) {
1297             $pri = $if_type_hash->{bridge} + $child;
1298         }
1299
1300         return $pri;
1301     };
1302
1303     foreach my $iface (sort {
1304         my $ref1 = $ifaces->{$a};
1305         my $ref2 = $ifaces->{$b};
1306         my $tp1 = &$lookup_type_prio($a);
1307         my $tp2 = &$lookup_type_prio($b);
1308
1309         # Only recognized types are in relation to each other. If one type
1310         # is unknown then only consider the interfaces' priority attributes.
1311         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1312
1313         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1314         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1315
1316         return $p1 <=> $p2 if $p1 != $p2;
1317
1318         return $a cmp $b;
1319     } keys %$ifaces) {
1320         next if $printed->{$iface};
1321
1322         my $d = $ifaces->{$iface};
1323         my $pri = $d->{priority} // 0;
1324         if (@options && $options[0]->[0] < $pri) {
1325             do {
1326                 $raw .= (shift @options)->[1] . "\n";
1327             } while (@options && $options[0]->[0] < $pri);
1328             $raw .= "\n";
1329         }
1330
1331         $printed->{$iface} = 1;
1332         $raw .= "auto $iface\n" if $d->{autostart};
1333         my $i = 0; # some options should be printed only once
1334         $raw .= __interface_to_string($iface, $d, $_, !$i++) foreach @{$d->{families}};
1335     }
1336
1337     $raw .= $_->[1] . "\n" foreach @options;
1338     return $raw;
1339 }
1340
1341 register_file('interfaces', "/etc/network/interfaces",
1342               \&read_etc_network_interfaces,
1343               \&write_etc_network_interfaces);
1344
1345
1346 sub read_iscsi_initiatorname {
1347     my ($filename, $fd) = @_;
1348
1349     while (defined(my $line = <$fd>)) {
1350         if ($line =~ m/^InitiatorName=(\S+)$/) {
1351             return $1;
1352         }
1353     }
1354
1355     return 'undefined';
1356 }
1357
1358 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1359               \&read_iscsi_initiatorname);
1360
1361 sub read_apt_auth {
1362     my ($filename, $fd) = @_;
1363
1364     local $/;
1365
1366     my $raw = defined($fd) ? <$fd> : '';
1367
1368     $raw =~ s/^\s+//;
1369
1370
1371     my @tokens = split(/\s+/, $raw);
1372
1373     my $data = {};
1374
1375     my $machine;
1376     while (defined(my $tok = shift @tokens)) {
1377
1378         $machine = shift @tokens if $tok eq 'machine';
1379         next if !$machine;
1380         $data->{$machine} = {} if !$data->{$machine};
1381
1382         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1383         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1384     };
1385
1386     return $data;
1387 }
1388
1389 my $format_apt_auth_data = sub {
1390     my $data = shift;
1391
1392     my $raw = '';
1393
1394     foreach my $machine (sort keys %$data) {
1395         my $d = $data->{$machine};
1396         $raw .= "machine $machine\n";
1397         $raw .= " login $d->{login}\n" if $d->{login};
1398         $raw .= " password $d->{password}\n" if $d->{password};
1399         $raw .= "\n";
1400     }
1401
1402     return $raw;
1403 };
1404
1405 sub write_apt_auth {
1406     my ($filename, $fh, $data) = @_;
1407
1408     my $raw = &$format_apt_auth_data($data);
1409
1410     die "write failed: $!" unless print $fh "$raw\n";
1411
1412     return $data;
1413 }
1414
1415 sub update_apt_auth {
1416     my ($filename, $fh, $data) = @_;
1417
1418     my $orig = read_apt_auth($filename, $fh);
1419
1420     foreach my $machine (keys %$data) {
1421         $orig->{$machine} = $data->{$machine};
1422     }
1423
1424     return &$format_apt_auth_data($orig);
1425 }
1426
1427 register_file('apt-auth', "/etc/apt/auth.conf",
1428               \&read_apt_auth, \&write_apt_auth,
1429               \&update_apt_auth, perm => 0640);
1430
1431 1;