src/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4 use strict;
   5 use warnings;
   6
   7 use Clone qw(clone);
   8 use Digest::SHA;
   9 use Encode qw(encode decode);
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::stat;
  13 use IO::Dir;
  14 use IO::File;
  15 use JSON;
  16 use Linux::Inotify2;
  17 use POSIX;
  18
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::JSONSchema;
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools;
  25
  26 use base 'Exporter';
  27
  28 our @EXPORT_OK = qw(read_file write_file register_file);
  29
  30 my $ccache;
  31 my $ccachemap;
  32 my $ccacheregex;
  33 my $inotify;
  34 my $inotify_pid = 0;
  35 my $versions;
  36 my $shadowfiles = {
  37     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  38 };
  39
  40 # to enable cached operation, you need to call 'inotify_init'
  41 # inotify handles are a limited resource, so use with care (only
  42 # enable the cache if you really need it)
  43
  44 # Note: please close the inotify handle after you fork
  45
  46 sub ccache_default_writer {
  47     my ($filename, $data) = @_;
  48
  49     die "undefined config writer for '$filename' :ERROR";
  50 }
  51
  52 sub ccache_default_parser {
  53     my ($filename, $srcfd) = @_;
  54
  55     die "undefined config reader for '$filename' :ERROR";
  56 }
  57
  58 sub ccache_compute_diff {
  59     my ($filename, $shadow) = @_;
  60
  61     my $diff = '';
  62
  63     my $cmd = ['/usr/bin/diff', '-b', '-N', '-u', $filename, $shadow];
  64     PVE::Tools::run_command($cmd, noerr => 1, outfunc => sub {
  65         my ($line) = @_;
  66         $diff .= decode('UTF-8', $line) . "\n";
  67     });
  68
  69     $diff = undef if !$diff;
  70
  71     return $diff;
  72 }
  73
  74 sub ccache_info {
  75     my ($filename) = @_;
  76
  77     foreach my $uid (keys %$ccacheregex) {
  78         my $ccinfo = $ccacheregex->{$uid};
  79         my $dir = $ccinfo->{dir};
  80         my $regex = $ccinfo->{regex};
  81         if ($filename =~ m|^$dir/+$regex$|) {
  82             if (!$ccache->{$filename}) {
  83                 my $cp = {};
  84                 while (my ($k, $v) = each %$ccinfo) {
  85                     $cp->{$k} = $v;
  86                 }
  87                 $ccache->{$filename} = $cp;
  88             }
  89             return ($ccache->{$filename}, $filename);
  90         }
  91     }
  92
  93     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  94
  95     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  96
  97     return ($ccache->{$filename}, $filename);
  98 }
  99
 100 sub write_file {
 101     my ($fileid, $data, $full) = @_;
 102
 103     my ($ccinfo, $filename) = ccache_info($fileid);
 104
 105     my $writer = $ccinfo->{writer};
 106
 107     my $realname = $filename;
 108
 109     my $shadow;
 110     if ($shadow = $shadowfiles->{$filename}) {
 111         $realname = $shadow;
 112     }
 113
 114     my $perm = $ccinfo->{perm} || 0644;
 115
 116     my $tmpname = "$realname.tmp.$$";
 117
 118     my $res;
 119     eval {
 120         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 121         die "unable to open file '$tmpname' - $!\n" if !$fh;
 122
 123         $res = &$writer($filename, $fh, $data);
 124
 125         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 126     };
 127     my $err = $@;
 128
 129     $ccinfo->{version} = undef;
 130
 131     if ($err) {
 132         unlink $tmpname;
 133         die $err;
 134     }
 135
 136     if (!rename($tmpname, $realname)) {
 137         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 138         unlink $tmpname;
 139         die $msg;
 140     }
 141
 142     my $diff;
 143     if ($shadow && $full) {
 144         $diff = ccache_compute_diff ($filename, $shadow);
 145     }
 146
 147     if ($full) {
 148         return { data => $res, changes => $diff };
 149     }
 150
 151     return $res;
 152 }
 153
 154 sub update_file {
 155     my ($fileid, $data, @args) = @_;
 156
 157     my ($ccinfo, $filename) = ccache_info($fileid);
 158
 159     my $update = $ccinfo->{update};
 160
 161     die "unable to update/merge data" if !$update;
 162
 163     my $lkfn = "$filename.lock";
 164
 165     my $timeout = 10;
 166
 167     my $fd;
 168
 169     my $code = sub {
 170
 171         $fd = IO::File->new ($filename, "r");
 172
 173         my $new = &$update($filename, $fd, $data, @args);
 174
 175         if (defined($new)) {
 176             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 177         } else {
 178             unlink $filename;
 179         }
 180     };
 181
 182     PVE::Tools::lock_file($lkfn, $timeout, $code);
 183     my $err = $@;
 184
 185     close($fd) if defined($fd);
 186
 187     die $err if $err;
 188
 189     return undef;
 190 }
 191
 192 sub discard_changes {
 193     my ($fileid, $full) = @_;
 194
 195     my ($ccinfo, $filename) = ccache_info($fileid);
 196
 197     if (my $copy = $shadowfiles->{$filename}) {
 198         unlink $copy;
 199     }
 200
 201     return read_file ($filename, $full);
 202 }
 203
 204 sub poll_changes {
 205     my ($filename) = @_;
 206
 207     poll() if $inotify; # read new inotify events
 208
 209     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 210
 211     return $versions->{$filename};
 212 }
 213
 214 sub read_file {
 215     my ($fileid, $full) = @_;
 216
 217     my $parser;
 218
 219     my ($ccinfo, $filename) = ccache_info($fileid);
 220
 221     $parser = $ccinfo->{parser};
 222
 223     my $fd;
 224     my $shadow;
 225
 226     my $cver = poll_changes($filename);
 227
 228     if (my $copy = $shadowfiles->{$filename}) {
 229         if ($fd = IO::File->new ($copy, "r")) {
 230             $shadow = $copy;
 231         } else {
 232             $fd = IO::File->new ($filename, "r");
 233         }
 234     } else {
 235         $fd = IO::File->new ($filename, "r");
 236     }
 237
 238     my $acp = $ccinfo->{always_call_parser};
 239
 240     if (!$fd) {
 241         $ccinfo->{version} = undef;
 242         $ccinfo->{data} = undef;
 243         $ccinfo->{diff} = undef;
 244         return undef if !$acp;
 245     }
 246
 247     my $noclone = $ccinfo->{noclone};
 248
 249     # file unchanged?
 250     if (!$ccinfo->{nocache} &&
 251         $inotify && $cver &&
 252         defined ($ccinfo->{data}) &&
 253         defined ($ccinfo->{version}) &&
 254         ($ccinfo->{readonce} ||
 255          ($ccinfo->{version} == $cver))) {
 256
 257         my $ret;
 258         if (!$noclone && ref ($ccinfo->{data})) {
 259             $ret->{data} = clone ($ccinfo->{data});
 260         } else {
 261             $ret->{data} = $ccinfo->{data};
 262         }
 263         $ret->{changes} = $ccinfo->{diff};
 264
 265         return $full ? $ret : $ret->{data};
 266     }
 267
 268     my $diff;
 269
 270     if ($shadow) {
 271         $diff = ccache_compute_diff ($filename, $shadow);
 272     }
 273
 274     my $res = &$parser($filename, $fd);
 275
 276     if (!$ccinfo->{nocache}) {
 277         $ccinfo->{version} = $cver;
 278     }
 279
 280     # we cache data with references, so we always need to
 281     # clone this data. Else the original data may get
 282     # modified.
 283     $ccinfo->{data} = $res;
 284
 285     # also store diff
 286     $ccinfo->{diff} = $diff;
 287
 288     my $ret;
 289     if (!$noclone && ref ($ccinfo->{data})) {
 290         $ret->{data} = clone ($ccinfo->{data});
 291     } else {
 292         $ret->{data} = $ccinfo->{data};
 293     }
 294     $ret->{changes} = $ccinfo->{diff};
 295
 296     return $full ? $ret : $ret->{data};
 297 }
 298
 299 sub parse_ccache_options {
 300     my ($ccinfo, %options) = @_;
 301
 302     foreach my $opt (keys %options) {
 303         my $v = $options{$opt};
 304         if ($opt eq 'readonce') {
 305             $ccinfo->{$opt} = $v;
 306         } elsif ($opt eq 'nocache') {
 307             $ccinfo->{$opt} = $v;
 308         } elsif ($opt eq 'shadow') {
 309             $ccinfo->{$opt} = $v;
 310         } elsif ($opt eq 'perm') {
 311             $ccinfo->{$opt} = $v;
 312         } elsif ($opt eq 'noclone') {
 313             # noclone flag for large read-only data chunks like aplinfo
 314             $ccinfo->{$opt} = $v;
 315         } elsif ($opt eq 'always_call_parser') {
 316             # when set, we call parser even when the file does not exist.
 317             # this allows the parser to return some default
 318             $ccinfo->{$opt} = $v;
 319         } else {
 320             die "internal error - unsupported option '$opt'";
 321         }
 322     }
 323 }
 324
 325 sub register_file {
 326     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 327
 328     die "can't register file '$filename' after inotify_init" if $inotify;
 329
 330     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 331     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 332
 333     my $ccinfo = {};
 334
 335     $ccinfo->{id} = $id;
 336     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 337     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 338     $ccinfo->{update} = $update;
 339
 340     parse_ccache_options($ccinfo, %options);
 341
 342     if ($options{shadow}) {
 343         $shadowfiles->{$filename} = $options{shadow};
 344     }
 345
 346     $ccachemap->{$id} = $filename;
 347     $ccache->{$filename} = $ccinfo;
 348 }
 349
 350 sub register_regex {
 351     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 352
 353     die "can't register regex after inotify_init" if $inotify;
 354
 355     my $uid = "$dir/$regex";
 356     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 357
 358     my $ccinfo = {};
 359
 360     $ccinfo->{dir} = $dir;
 361     $ccinfo->{regex} = $regex;
 362     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 363     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 364     $ccinfo->{update} = $update;
 365
 366     parse_ccache_options($ccinfo, %options);
 367
 368     $ccacheregex->{$uid} = $ccinfo;
 369 }
 370
 371 sub poll {
 372     return if !$inotify;
 373
 374     if ($inotify_pid != $$) {
 375         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 376         $inotify = undef;
 377     } else {
 378         1 while $inotify && $inotify->poll;
 379     }
 380 }
 381
 382 sub flushcache {
 383     foreach my $filename (keys %$ccache) {
 384         $ccache->{$filename}->{version} = undef;
 385         $ccache->{$filename}->{data} = undef;
 386         $ccache->{$filename}->{diff} = undef;
 387     }
 388 }
 389
 390 sub inotify_close {
 391     $inotify = undef;
 392 }
 393
 394 sub inotify_init {
 395
 396     die "only one inotify instance allowed" if $inotify;
 397
 398     $inotify =  Linux::Inotify2->new()
 399         || die "Unable to create new inotify object: $!";
 400
 401     $inotify->blocking (0);
 402
 403     $versions = {};
 404
 405     my $dirhash = {};
 406     foreach my $fn (keys %$ccache) {
 407         my $dir = dirname ($fn);
 408         my $base = basename ($fn);
 409
 410         $dirhash->{$dir}->{$base} = $fn;
 411
 412         if (my $sf = $shadowfiles->{$fn}) {
 413             $base = basename ($sf);
 414             $dir = dirname ($sf);
 415             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 416         }
 417     }
 418
 419     foreach my $uid (keys %$ccacheregex) {
 420         my $ccinfo = $ccacheregex->{$uid};
 421         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 422     }
 423
 424     $inotify_pid = $$;
 425
 426     foreach my $dir (keys %$dirhash) {
 427
 428         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 429         $inotify->watch ($dir, $evlist, sub {
 430             my $e = shift;
 431             my $name = $e->name;
 432
 433             if ($inotify_pid != $$) {
 434                 syslog ('err', "got inotify event in wrong process");
 435             }
 436
 437             if ($e->IN_ISDIR || !$name) {
 438                 return;
 439             }
 440
 441             if ($e->IN_Q_OVERFLOW) {
 442                 syslog ('info', "got inotify overflow - flushing cache");
 443                 flushcache();
 444                 return;
 445             }
 446
 447             if ($e->IN_UNMOUNT) {
 448                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 449                 $inotify = undef;
 450             }
 451             if ($e->IN_IGNORED) {
 452                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 453                 $inotify = undef;
 454             }
 455
 456             if ($dirhash->{$dir}->{_regex}) {
 457                 foreach my $uid (keys %$ccacheregex) {
 458                     my $ccinfo = $ccacheregex->{$uid};
 459                     next if $dir ne $ccinfo->{dir};
 460                     my $regex = $ccinfo->{regex};
 461                     if ($regex && ($name =~ m|^$regex$|)) {
 462
 463                         my $fn = "$dir/$name";
 464                         $versions->{$fn}++;
 465                         #print "VERSION:$fn:$versions->{$fn}\n";
 466                     }
 467                 }
 468             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 469
 470                 $versions->{$fn}++;
 471                 #print "VERSION:$fn:$versions->{$fn}\n";
 472             }
 473         });
 474     }
 475
 476     foreach my $dir (keys %$dirhash) {
 477         foreach my $name (keys %{$dirhash->{$dir}}) {
 478             if ($name eq '_regex') {
 479                 foreach my $uid (keys %$ccacheregex) {
 480                     my $ccinfo = $ccacheregex->{$uid};
 481                     next if $dir ne $ccinfo->{dir};
 482                     my $re = $ccinfo->{regex};
 483                     if (my $fd = IO::Dir->new ($dir)) {
 484                         while (defined(my $de = $fd->read)) {
 485                             if ($de =~ m/^$re$/) {
 486                                 my $fn = "$dir/$de";
 487                                 $versions->{$fn}++; # init with version
 488                                 #print "init:$fn:$versions->{$fn}\n";
 489                             }
 490                         }
 491                     }
 492                 }
 493             } else {
 494                 my $fn = $dirhash->{$dir}->{$name};
 495                 $versions->{$fn}++; # init with version
 496                 #print "init:$fn:$versions->{$fn}\n";
 497             }
 498         }
 499     }
 500 }
 501
 502 my $cached_nodename;
 503
 504 sub nodename {
 505
 506     return $cached_nodename if $cached_nodename;
 507
 508     my ($sysname, $nodename) = POSIX::uname();
 509
 510     $nodename =~ s/\..*$//; # strip domain part, if any
 511
 512     die "unable to read node name\n" if !$nodename;
 513
 514     $cached_nodename = $nodename;
 515
 516     return $cached_nodename;
 517 }
 518
 519 sub read_etc_hostname {
 520     my ($filename, $fd) = @_;
 521
 522     my $hostname = <$fd>;
 523
 524     chomp $hostname;
 525
 526     $hostname =~ s/\..*$//; # strip domain part, if any
 527
 528     return $hostname;
 529 }
 530
 531 sub write_etc_hostname {
 532     my ($filename, $fh, $hostname) = @_;
 533
 534     die "write failed: $!" unless print $fh "$hostname\n";
 535
 536     return $hostname;
 537 }
 538
 539 register_file('hostname', "/etc/hostname",
 540               \&read_etc_hostname,
 541               \&write_etc_hostname);
 542
 543 sub read_etc_hosts {
 544     my ($filename, $fh) = @_;
 545
 546     my $raw = '';
 547     my $data = '';
 548
 549     while (my $line = <$fh>) {
 550         $raw .= $line;
 551         if ($line =~ m/^\s*#/) {
 552             $line = decode('UTF-8', $line);
 553         }
 554         $data .= $line;
 555     }
 556
 557     return {
 558         digest => Digest::SHA::sha1_hex($raw),
 559         data => $data,
 560     }
 561 }
 562
 563 sub write_etc_hosts {
 564     my ($filename, $fh, $hosts, @args) = @_;
 565
 566     # check validity of ips/names
 567     for my $line (split("\n", $hosts)) {
 568         next if $line =~ m/^\s*#/; # comments
 569         next if $line =~ m/^\s*$/; # whitespace/empty lines
 570
 571         my ($ip, @names) = split(/\s+/, $line);
 572
 573         raise_param_exc({ 'data' => "Invalid IP '$ip'" })
 574             if $ip !~ m/^$PVE::Tools::IPRE$/;
 575
 576         for my $name (@names) {
 577             raise_param_exc({ 'data' => "Invalid Hostname '$name'" })
 578                 if $name !~ m/^[.\-a-zA-Z0-9]+$/;
 579         }
 580     }
 581
 582     die "write failed: $!" if !print $fh encode('UTF-8', $hosts);
 583
 584     return $hosts;
 585 }
 586
 587 register_file('etchosts', "/etc/hosts",
 588               \&read_etc_hosts,
 589               \&write_etc_hosts);
 590
 591 sub read_etc_resolv_conf {
 592     my ($filename, $fh) = @_;
 593
 594     my $res = {};
 595
 596     my $nscount = 0;
 597     while (my $line = <$fh>) {
 598         chomp $line;
 599         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 600             $res->{search} = $2;
 601         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
 602             $nscount++;
 603             if ($nscount <= 3) {
 604                 $res->{"dns$nscount"} = $1;
 605             }
 606         }
 607     }
 608
 609     return $res;
 610 }
 611
 612 sub update_etc_resolv_conf {
 613     my ($filename, $fh, $resolv, @args) = @_;
 614
 615     my $data = "";
 616
 617     $data = "search $resolv->{search}\n"
 618         if $resolv->{search};
 619
 620     my $written = {};
 621     foreach my $k ("dns1", "dns2", "dns3") {
 622         my $ns = $resolv->{$k};
 623         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 624             $written->{$ns} = 1;
 625             $data .= "nameserver $ns\n";
 626         }
 627     }
 628
 629     while (my $line = <$fh>) {
 630         next if $line =~ m/^(search|domain|nameserver)\s+/;
 631         $data .= $line
 632     }
 633
 634     return $data;
 635 }
 636
 637 register_file('resolvconf', "/etc/resolv.conf",
 638               \&read_etc_resolv_conf, undef,
 639               \&update_etc_resolv_conf);
 640
 641 sub read_etc_timezone {
 642     my ($filename, $fd) = @_;
 643
 644     my $timezone = <$fd>;
 645
 646     chomp $timezone;
 647
 648     return $timezone;
 649 }
 650
 651 sub write_etc_timezone {
 652     my ($filename, $fh, $timezone) = @_;
 653
 654     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 655
 656     raise_param_exc({ 'timezone' => "No such timezone" })
 657         if (! -f $tzinfo);
 658
 659     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 660
 661     print $fh "$timezone\n";
 662
 663     unlink ("/etc/localtime");
 664     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 665
 666 }
 667
 668 register_file('timezone', "/etc/timezone",
 669               \&read_etc_timezone,
 670               \&write_etc_timezone);
 671
 672 sub read_active_workers {
 673     my ($filename, $fh) = @_;
 674
 675     return [] if !$fh;
 676
 677     my $res = [];
 678     while (defined (my $line = <$fh>)) {
 679         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 680             my $upid = $1;
 681             my $saved = $2;
 682             my $endtime = $4;
 683             my $status = $6;
 684             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 685                 $task->{upid} = $upid;
 686                 $task->{saved} = $saved;
 687                 $task->{endtime} = hex($endtime) if $endtime;
 688                 $task->{status} = $status if $status;
 689                 push @$res, $task;
 690             }
 691         } else {
 692             warn "unable to parse line: $line";
 693         }
 694     }
 695
 696     return $res;
 697
 698 }
 699
 700 sub write_active_workers {
 701     my ($filename, $fh, $tasklist) = @_;
 702
 703     my $raw = '';
 704     foreach my $task (@$tasklist) {
 705         my $upid = $task->{upid};
 706         my $saved = $task->{saved} ? 1 : 0;
 707         if ($task->{endtime}) {
 708             if ($task->{status}) {
 709                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
 710             } else {
 711                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
 712             }
 713         } else {
 714             $raw .= "$upid $saved\n";
 715         }
 716     }
 717
 718     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 719 }
 720
 721 register_file('active', "/var/log/pve/tasks/active",
 722               \&read_active_workers,
 723               \&write_active_workers);
 724
 725
 726 our $bond_modes = { 'balance-rr' => 0,
 727                    'active-backup' => 1,
 728                    'balance-xor' => 2,
 729                    'broadcast' => 3,
 730                    '802.3ad' => 4,
 731                    'balance-tlb' => 5,
 732                    'balance-alb' => 6,
 733                };
 734
 735 my $ovs_bond_modes = {
 736     'active-backup' => 1,
 737     'balance-slb' => 1,
 738     'lacp-balance-slb' => 1,
 739     'lacp-balance-tcp' => 1,
 740 };
 741
 742 #sub get_bond_modes {
 743 #    return $bond_modes;
 744 #}
 745
 746 my $parse_ovs_option = sub {
 747     my ($data) = @_;
 748
 749     my $opts = {};
 750     foreach my $kv (split (/\s+/, $data || '')) {
 751         my ($k, $v) = split('=', $kv, 2);
 752         $opts->{$k} = $v if $k && $v;
 753     }
 754     return $opts;
 755 };
 756
 757 my $set_ovs_option = sub {
 758     my ($d, %params) = @_;
 759
 760     my $opts = &$parse_ovs_option($d->{ovs_options});
 761
 762     foreach my $k (keys %params) {
 763         my $v = $params{$k};
 764         if ($v) {
 765             $opts->{$k} = $v;
 766         } else {
 767             delete $opts->{$k};
 768         }
 769     }
 770
 771     my $res = [];
 772     foreach my $k (keys %$opts) {
 773         push @$res, "$k=$opts->{$k}";
 774     }
 775
 776     if (my $new = join(' ', @$res)) {
 777         $d->{ovs_options} = $new;
 778         return $d->{ovs_options};
 779     } else {
 780         delete $d->{ovs_options};
 781         return undef;
 782     }
 783 };
 784
 785 my $extract_ovs_option = sub {
 786     my ($d, $name) = @_;
 787
 788     my $opts = &$parse_ovs_option($d->{ovs_options});
 789
 790     my $v = delete $opts->{$name};
 791
 792     my $res = [];
 793     foreach my $k (keys %$opts) {
 794         push @$res, "$k=$opts->{$k}";
 795     }
 796
 797     if (my $new = join(' ', @$res)) {
 798         $d->{ovs_options} = $new;
 799     } else {
 800         delete $d->{ovs_options};
 801     }
 802
 803     return $v;
 804 };
 805
 806 my $check_mtu = sub {
 807     my ($ifaces, $parent, $child) = @_;
 808
 809     die "check mtu - missing parent interface\n" if !$parent;
 810     die "check mtu - missing child interface\n" if !$child;
 811
 812     my $cmtu = $ifaces->{$child}->{mtu};
 813     return if !$cmtu;
 814
 815     my $parentdata = $ifaces->{$parent};
 816     my $pmtu = $parentdata->{mtu};
 817     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
 818     $pmtu = 1500 if !$pmtu;
 819
 820     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
 821         if $pmtu < $cmtu;
 822 };
 823
 824 # config => {
 825 #   ifaces => {
 826 #     $ifname => {
 827 #       <optional> exists => BOOL,
 828 #       <optional> active => BOOL,
 829 #       <optional> autostart => BOOL,
 830 #       <auto> priority => INT,
 831 #
 832 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
 833 #
 834 #       families => ["inet", "inet6", ...],
 835 #
 836 #       method => "manual" | "static" | "dhcp" | ... ,
 837 #       address => IP,
 838 #       netmask => SUBNET,
 839 #       broadcast => IP,
 840 #       gateway => IP,
 841 #       comments => [ "..." ],
 842 #
 843 #       method6 => "manual" | "static" | "dhcp" | ... ,
 844 #       address6 => IP,
 845 #       netmask6 => SUBNET,
 846 #       gateway6 => IP,
 847 #       comments6 => [ "..." ],
 848 #
 849 #       <known options>, # like bridge_ports, ovs_*
 850 #
 851 #       # extra/unknown options stored by-family:
 852 #       options => { <inet options>... }
 853 #       options6 => { <inet6 options>... }
 854 #     }
 855 #   },
 856 #   options => [
 857 #     # mappings end up here as well, as we don't need to understand them
 858 #     [priority,line]
 859 #   ]
 860 # }
 861 sub read_etc_network_interfaces {
 862     my ($filename, $fh) = @_;
 863     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
 864     my $active = PVE::ProcFSTools::get_active_network_interfaces();
 865     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
 866 }
 867
 868 sub __read_etc_network_interfaces {
 869     my ($fh, $proc_net_dev, $active_ifaces) = @_;
 870
 871     my $config = {};
 872     my $ifaces = $config->{ifaces} = {};
 873     my $options = $config->{options} = [];
 874
 875     my $options_alternatives = {
 876         'ovs_mtu'     => 'mtu',
 877         'bond-slaves' => 'slaves',
 878         'bond_slaves' => 'slaves',
 879         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
 880         'bond-mode' => 'bond_mode',
 881         'bond-miimon' =>'bond_miimon',
 882         'bridge-vlan-aware' => 'bridge_vlan_aware',
 883         'bridge-fd' => 'bridge_fd',
 884         'bridge-stp' => 'bridge_stp',
 885         'bridge-ports' => 'bridge_ports',
 886         'bridge-vids' => 'bridge_vids'
 887     };
 888
 889     my $line;
 890
 891     if ($proc_net_dev) {
 892         while (defined ($line = <$proc_net_dev>)) {
 893             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
 894                 $ifaces->{$1}->{exists} = 1;
 895             }
 896         }
 897         close($proc_net_dev);
 898     }
 899
 900     # we try to keep order inside the file
 901     my $priority = 2; # 1 is reserved for lo
 902
 903     SECTION: while (defined ($line = <$fh>)) {
 904         chomp ($line);
 905         next if $line =~ m/^\s*#/;
 906         next if $line =~ m/^\s*(allow-hotplug)\s+(.*)$/;
 907
 908         if ($line =~ m/^\s*(auto|allow-ovs)\s+(.*)$/) {
 909             my @aa = split (/\s+/, $2);
 910
 911             foreach my $a (@aa) {
 912                 $ifaces->{$a}->{autostart} = 1;
 913             }
 914
 915         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
 916             my $i = $1;
 917             my $family = $2;
 918             my $f = { method => $3 }; # by family, merged to $d with a $suffix
 919             (my $suffix = $family) =~ s/^inet//;
 920
 921             my $d = $ifaces->{$i} ||= {};
 922             $d->{priority} = $priority++ if !$d->{priority};
 923             push @{$d->{families}}, $family;
 924
 925             while (defined ($line = <$fh>)) {
 926                 chomp $line;
 927                 if ($line =~ m/^\s*#(.*?)\s*$/) {
 928                     $f->{comments} = '' if !$f->{comments};
 929                     my $comment = decode('UTF-8', $1);
 930                     $f->{comments} .= "$comment\n";
 931                 } elsif ($line =~ m/^\s*(?:iface\s
 932                                           |mapping\s
 933                                           |auto\s
 934                                           |allow-
 935                                           |source\s
 936                                           |source-directory\s
 937                                         )/x) {
 938                     last;
 939                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
 940                     my $option = $1;
 941                     my ($id, $value) = ($2, $3);
 942
 943                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
 944
 945                     my $simple_options = {
 946                         'mtu' => 1,
 947                         'ovs_type' => 1,
 948                         'ovs_options' => 1,
 949                         'ovs_bridge' => 1,
 950                         'ovs_bonds' => 1,
 951                         'ovs_ports' => 1,
 952                         'bridge_fd' => 1,
 953                         'bridge_vids' => 1,
 954                         'bridge-access' => 1,
 955                         'bridge-learning' => 1,
 956                         'bridge-arp-nd-suppress' => 1,
 957                         'bridge-unicast-flood' => 1,
 958                         'bridge-multicast-flood' => 1,
 959                         'bond_miimon' => 1,
 960                         'bond_xmit_hash_policy' => 1,
 961                         'bond-primary' => 1,
 962                         'uplink-id' => 1,
 963                         'vlan-protocol' => 1,
 964                         'vlan-raw-device' => 1,
 965                         'vlan-id' => 1,
 966                         'vxlan-id' => 1,
 967                         'vxlan-svcnodeip' => 1,
 968                         'vxlan-physdev' => 1,
 969                         'vxlan-local-tunnelip' => 1 };
 970
 971                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
 972                         $f->{$id} = $value;
 973                     } elsif ($simple_options->{$id}) {
 974                         $d->{$id} = $value;
 975                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 976                         my $devs = {};
 977                         foreach my $p (split (/\s+/, $value)) {
 978                             next if $p eq 'none';
 979                             $devs->{$p} = 1;
 980                         }
 981                         my $str = join (' ', sort keys %{$devs});
 982                         if ($d->{$id}) {
 983                             $d->{$id} .= ' ' . $str if $str;
 984                         } else {
 985                             $d->{$id} = $str || '';
 986                         }
 987                     } elsif ($id eq 'bridge_stp') {
 988                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 989                             $d->{$id} = 'on';
 990                         } else {
 991                             $d->{$id} = 'off';
 992                         }
 993                     } elsif ($id eq 'bridge_vlan_aware') {
 994                         $d->{$id} = 1;
 995                     } elsif ($id eq 'bond_mode') {
 996                         # always use names
 997                         foreach my $bm (keys %$bond_modes) {
 998                             my $id = $bond_modes->{$bm};
 999                             if ($id eq $value) {
1000                                 $value = $bm;
1001                                 last;
1002                             }
1003                         }
1004                         $d->{$id} = $value;
1005                     } elsif ($id eq 'vxlan-remoteip') {
1006                         push @{$d->{$id}}, $value;
1007                     } else {
1008                         push @{$f->{options}}, $option;
1009                     }
1010                 } else {
1011                     last;
1012                 }
1013             }
1014             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
1015             last SECTION if !defined($line);
1016             redo SECTION;
1017         } elsif ($line =~ /\w/) {
1018             push @$options, [$priority++, $line];
1019         }
1020     }
1021
1022     foreach my $ifname (@$active_ifaces) {
1023         if (my $iface = $ifaces->{$ifname}) {
1024             $iface->{active} = 1;
1025         }
1026     }
1027
1028     if (!$ifaces->{lo}) {
1029         $ifaces->{lo}->{priority} = 1;
1030         $ifaces->{lo}->{method} = 'loopback';
1031         $ifaces->{lo}->{type} = 'loopback';
1032         $ifaces->{lo}->{autostart} = 1;
1033     }
1034
1035     foreach my $iface (keys %$ifaces) {
1036         my $d = $ifaces->{$iface};
1037         $d->{type} = 'unknown';
1038         if ($iface =~ m/^bond\d+$/) {
1039             if (!$d->{ovs_type}) {
1040                 $d->{type} = 'bond';
1041             } elsif ($d->{ovs_type} eq 'OVSBond') {
1042                 $d->{type} = $d->{ovs_type};
1043                 # translate: ovs_options => bond_mode
1044                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
1045                 my $lacp = &$extract_ovs_option($d, 'lacp');
1046                 if ($lacp && $lacp eq 'active') {
1047                     if ($d->{'bond_mode'} eq 'balance-slb') {
1048                         $d->{'bond_mode'} = 'lacp-balance-slb';
1049                     }
1050                 }
1051                 # Note: balance-tcp needs lacp
1052                 if ($d->{'bond_mode'} eq 'balance-tcp') {
1053                     $d->{'bond_mode'} = 'lacp-balance-tcp';
1054                 }
1055                 my $tag = &$extract_ovs_option($d, 'tag');
1056                 $d->{ovs_tag} = $tag if defined($tag);
1057             }
1058         } elsif ($iface =~ m/^vmbr\d+$/) {
1059             if (!$d->{ovs_type}) {
1060                 $d->{type} = 'bridge';
1061
1062                 if (!defined ($d->{bridge_fd})) {
1063                     $d->{bridge_fd} = 0;
1064                 }
1065                 if (!defined ($d->{bridge_stp})) {
1066                     $d->{bridge_stp} = 'off';
1067                 }
1068             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1069                 $d->{type} = $d->{ovs_type};
1070             }
1071         } elsif ($iface =~ m/^(\S+):\d+$/) {
1072             $d->{type} = 'alias';
1073             if (defined ($ifaces->{$1})) {
1074                 $d->{exists} = $ifaces->{$1}->{exists};
1075             } else {
1076                 $ifaces->{$1}->{exists} = 0;
1077                 $d->{exists} = 0;
1078             }
1079         } elsif ($iface =~ m/^(\S+)\.\d+$/ || $d->{'vlan-raw-device'}) {
1080             $d->{type} = 'vlan';
1081
1082             my $raw_iface = $d->{'vlan-raw-device'} ? $d->{'vlan-raw-device'} : $1;
1083             if (defined ($ifaces->{$raw_iface})) {
1084                 $d->{exists} = $ifaces->{$raw_iface}->{exists};
1085             } else {
1086                 $ifaces->{$raw_iface}->{exists} = 0;
1087                 $d->{exists} = 0;
1088             }
1089         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1090             if (!$d->{ovs_type}) {
1091                 $d->{type} = 'eth';
1092             } elsif ($d->{ovs_type} eq 'OVSPort') {
1093                 $d->{type} = $d->{ovs_type};
1094                 my $tag = &$extract_ovs_option($d, 'tag');
1095                 $d->{ovs_tag} = $tag if defined($tag);
1096             }
1097         } elsif ($iface =~ m/^lo$/) {
1098             $d->{type} = 'loopback';
1099         } else {
1100             if ($d->{'vxlan-id'}) {
1101                 $d->{type} = 'vxlan';
1102             } elsif (defined($d->{ovs_type})) {
1103                 if ($d->{ovs_type} eq 'OVSIntPort') {
1104                     $d->{type} = $d->{ovs_type};
1105                     my $tag = &$extract_ovs_option($d, 'tag');
1106                     $d->{ovs_tag} = $tag if defined($tag);
1107                 }
1108             }
1109         }
1110
1111         # map address and netmask to cidr
1112         if (my $addr = $d->{address}) {
1113             if (_address_is_cidr($addr)) {
1114                 $d->{cidr} = $addr;
1115                 my ($baseaddr, $mask) = _cidr_split($addr);
1116                 $d->{address} = $baseaddr;
1117                 $d->{netmask} = $mask;
1118             } elsif (my $cidr = _get_cidr($d->{address}, $d->{netmask})) {
1119                 $d->{cidr} = $cidr;
1120                 (undef, $d->{netmask}) = _cidr_split($cidr);
1121             } else {
1122                 # no mask, else we'd got a cidr above
1123                 $d->{cidr} = $addr ."/32";
1124             }
1125         }
1126
1127         # map address6 and netmask6 to cidr6
1128         if (my $addr6 = $d->{address6}) {
1129             if (_address_is_cidr($addr6)) {
1130                 $d->{cidr6} = $addr6;
1131                 my ($baseaddr, $mask) = _cidr_split($addr6);
1132                 $d->{address6} = $baseaddr;
1133                 $d->{netmask6} = $mask;
1134             } elsif (my $cidr6 = _get_cidr($d->{address6}, $d->{netmask6})) {
1135                 $d->{cidr6} = $cidr6;
1136             } else {
1137                 # no mask, else we'd got a cidr above
1138                 $d->{cidr6} = $addr6 ."/128";
1139             }
1140         }
1141
1142         $d->{method} = 'manual' if !$d->{method};
1143         $d->{method6} = 'manual' if !$d->{method6};
1144
1145         $d->{families} ||= ['inet'];
1146     }
1147
1148     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1149     # from the {options} hash for them to be removed correctly.
1150     @$options = grep {defined($_)} map {
1151         my ($pri, $line) = @$_;
1152         if ($line =~ /^allow-ovs\s+(.*)$/) {
1153             undef;
1154         } elsif ($line =~ /^allow-(\S+)\s+(.*)$/) {
1155             my $bridge = $1;
1156             my @ports = split(/\s+/, $2);
1157             if (defined(my $br = $ifaces->{$bridge})) {
1158                 # if this port is part of a bridge, remove it
1159                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1160                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1161             }
1162             # create the allow line for the remaining ports, or delete if empty
1163             if (@ports) {
1164                 [$pri, "allow-$bridge " . join(' ', @ports)];
1165             } else {
1166                 undef;
1167             }
1168         } else {
1169             # don't modify other lines
1170             $_;
1171         }
1172     } @$options;
1173
1174     return $config;
1175 }
1176
1177 sub _address_is_cidr {
1178     my ($addr) = @_;
1179     return $addr =~ /\/\d+$/ ? 1 : 0;
1180 }
1181
1182 sub _cidr_split {
1183     my ($cidr) = @_;
1184     $cidr =~ /^(.+)\/(\d+)$/;
1185     return ($1, $2); # (address, mask)
1186 }
1187
1188 sub _get_cidr {
1189     my ($addr, $mask) = @_;
1190
1191     return $addr if _address_is_cidr($addr);
1192     return undef if !$mask;
1193
1194     if ($mask =~ m/^\d+$/) { # cidr notation
1195         return $addr . "/" . $mask;
1196     } elsif (my $cidrmask = PVE::JSONSchema::get_netmask_bits($mask)) {
1197         return $addr . "/" . $cidrmask;
1198     }
1199     return undef;
1200 }
1201
1202 sub __interface_to_string {
1203     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1204
1205     (my $suffix = $family) =~ s/^inet//;
1206
1207     return '' if !($d && $d->{"method$suffix"});
1208
1209     my $raw = '';
1210
1211     $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1212
1213     if (my $addr = $d->{"address$suffix"}) {
1214
1215         if ($addr !~ /\/\d+$/ && $d->{"netmask$suffix"}) {
1216             if ($d->{"netmask$suffix"} =~ m/^\d+$/) {
1217                 $addr .= "/" . $d->{"netmask$suffix"};
1218             } elsif (my $mask = PVE::JSONSchema::get_netmask_bits($d->{"netmask$suffix"})) {
1219                 $addr .= "/" . $mask;
1220             }
1221         }
1222
1223         $raw .= "\taddress " . $addr . "\n";
1224     }
1225
1226     $raw .= "\tgateway " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1227
1228     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1229                  comments => 1, autostart => 1, options => 1,
1230                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1231                  method6 => 1, families => 1, options6 => 1,
1232                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1, 'uplink-id' => 1 };
1233
1234     if (!$first_block) {
1235         # not printing out options
1236     } elsif ($d->{type} eq 'bridge') {
1237
1238         $d->{bridge_ports} =~ s/[;,\s]+/ /g;
1239         my $ports = $d->{bridge_ports} || 'none';
1240         $raw .= "\tbridge-ports $ports\n";
1241         $done->{bridge_ports} = 1;
1242
1243         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1244         $raw .= "\tbridge-stp $v\n";
1245         $done->{bridge_stp} = 1;
1246
1247         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1248         $raw .= "\tbridge-fd $v\n";
1249         $done->{bridge_fd} = 1;
1250
1251         if( defined($d->{bridge_vlan_aware})) {
1252             $raw .= "\tbridge-vlan-aware yes\n";
1253             $v = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1254             $raw .= "\tbridge-vids $v\n";
1255         }
1256         $done->{bridge_vlan_aware} = 1;
1257         $done->{bridge_vids} = 1;
1258
1259         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1260         $done->{mtu} = 1;
1261
1262     } elsif ($d->{type} eq 'bond') {
1263
1264         $d->{slaves} =~ s/[;,\s]+/ /g;
1265         my $slaves = $d->{slaves} || 'none';
1266         $raw .= "\tbond-slaves $slaves\n";
1267         $done->{slaves} = 1;
1268
1269         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1270         $raw .= "\tbond-miimon $v\n";
1271         $done->{'bond_miimon'} = 1;
1272
1273         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1274         $raw .= "\tbond-mode $v\n";
1275         $done->{'bond_mode'} = 1;
1276
1277         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1278             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1279             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1280         }
1281         $done->{'bond_xmit_hash_policy'} = 1;
1282
1283         if ($d->{'bond_mode'} && $d->{'bond_mode'} eq 'active-backup' && $d->{'bond-primary'}) {
1284             $raw .= "\tbond-primary $d->{'bond-primary'}\n";
1285         }
1286         $done->{'bond-primary'} = 1;
1287
1288         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1289         $done->{mtu} = 1;
1290
1291     } elsif ($d->{type} eq 'vlan') {
1292         die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n"
1293             if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
1294
1295     } elsif ($d->{type} eq 'vxlan') {
1296
1297         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1298             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1299             $done->{$k} = 1;
1300         }
1301
1302         if ($d->{'vxlan-remoteip'}) {
1303             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1304                 $raw .= "\tvxlan-remoteip $remoteip\n";
1305             }
1306             $done->{'vxlan-remoteip'} = 1;
1307         }
1308
1309         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1310         $done->{mtu} = 1;
1311
1312     } elsif ($d->{type} eq 'OVSBridge') {
1313
1314         $raw .= "\tovs_type $d->{type}\n";
1315         $done->{ovs_type} = 1;
1316
1317         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1318         $done->{ovs_ports} = 1;
1319
1320         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1321         $done->{mtu} = 1;
1322
1323     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1324              $d->{type} eq 'OVSBond') {
1325
1326         $d->{autostart} = 0; # started by the bridge
1327
1328         if (defined($d->{ovs_tag})) {
1329             &$set_ovs_option($d, tag => $d->{ovs_tag});
1330         }
1331         $done->{ovs_tag} = 1;
1332
1333         if ($d->{type} eq 'OVSBond') {
1334
1335             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1336
1337             $ovs_bond_modes->{$d->{bond_mode}} ||
1338                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1339
1340             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1341                 &$set_ovs_option($d, lacp => 'active');
1342                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1343             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1344                 &$set_ovs_option($d, lacp => 'active');
1345                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1346             } else {
1347                 &$set_ovs_option($d, lacp => undef);
1348                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1349             }
1350             $done->{bond_mode} = 1;
1351
1352             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1353             $done->{ovs_bonds} = 1;
1354         }
1355
1356         $raw .= "\tovs_type $d->{type}\n";
1357         $done->{ovs_type} = 1;
1358
1359         if (my $bridge = $d->{ovs_bridge}) {
1360             if ($ifupdown2) {
1361                 $raw = "auto $iface\n$raw";
1362             } else {
1363                 $raw = "allow-$bridge $iface\n$raw";
1364             }
1365
1366             $raw .= "\tovs_bridge $bridge\n";
1367             $done->{ovs_bridge} = 1;
1368         }
1369
1370         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1371         $done->{mtu} = 1;
1372     }
1373
1374     if ($first_block) {
1375         # print other settings
1376         foreach my $k (sort keys %$d) {
1377            next if $done->{$k};
1378            next if !$d->{$k};
1379            $raw .= "\t$k $d->{$k}\n";
1380         }
1381     }
1382
1383     foreach my $option (@{$d->{"options$suffix"}}) {
1384         $raw .= "\t$option\n";
1385     }
1386
1387     # add comments
1388     my $comments = $d->{"comments$suffix"} || '';
1389     foreach my $cl (split(/\n/, $comments)) {
1390         $raw .= "#$cl\n";
1391     }
1392
1393     $raw .= "\n";
1394
1395     return $raw;
1396 }
1397
1398
1399 sub write_etc_network_interfaces {
1400     my ($filename, $fh, $config) = @_;
1401     my $ifupdown2 = -e '/usr/share/ifupdown2/ifupdown2';
1402     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1403     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1404 }
1405 sub __write_etc_network_interfaces {
1406     my ($config, $ifupdown2) = @_;
1407
1408     my $ifaces = $config->{ifaces};
1409     my @options = @{$config->{options}};
1410
1411     my $used_ports = {};
1412
1413     foreach my $iface (keys %$ifaces) {
1414         my $d = $ifaces->{$iface};
1415
1416         delete $d->{cidr};
1417         delete $d->{cidr6};
1418
1419         my $ports = '';
1420         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1421             $ports .= " $d->{$k}" if $d->{$k};
1422         }
1423
1424         foreach my $p (PVE::Tools::split_list($ports)) {
1425             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1426                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1427             $used_ports->{$p} = $iface;
1428         }
1429     }
1430
1431     # delete unused OVS ports
1432     foreach my $iface (keys %$ifaces) {
1433         my $d = $ifaces->{$iface};
1434         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1435             $d->{type} eq 'OVSBond') {
1436             my $brname = $used_ports->{$iface};
1437             if (!$brname || !$ifaces->{$brname}) {
1438                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1439                     $ifaces->{$iface} = {
1440                         type => 'eth',
1441                         exists => 1,
1442                         method => 'manual',
1443                         families => ['inet'],
1444                     };
1445                 } else {
1446                     delete $ifaces->{$iface};
1447                 }
1448                 next;
1449             }
1450             my $bd = $ifaces->{$brname};
1451             if ($bd->{type} ne 'OVSBridge') {
1452                 delete $ifaces->{$iface};
1453                 next;
1454             }
1455         }
1456     }
1457
1458     # create OVS bridge ports
1459     foreach my $iface (keys %$ifaces) {
1460         my $d = $ifaces->{$iface};
1461         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1462             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1463                 my $n = $ifaces->{$p};
1464                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1465                     if !$n;
1466                 $n->{autostart} = 0;
1467                 if ($n->{type} eq 'eth') {
1468                     $n->{type} = 'OVSPort';
1469                     $n->{ovs_bridge} = $iface;
1470                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1471                     $n->{type} eq 'OVSIntPort') {
1472                     $n->{ovs_bridge} = $iface;
1473                 } else {
1474                     die "interface '$p' is not defined as OVS port/bond\n";
1475                 }
1476
1477                 &$check_mtu($ifaces, $iface, $p);
1478             }
1479         }
1480     }
1481
1482     # check OVS bond ports
1483     foreach my $iface (keys %$ifaces) {
1484         my $d = $ifaces->{$iface};
1485         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1486             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1487                 my $n = $ifaces->{$p};
1488                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1489                     if !$n;
1490                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1491                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1492                 &$check_mtu($ifaces, $iface, $p);
1493             }
1494         }
1495     }
1496
1497     # check bond
1498     foreach my $iface (keys %$ifaces) {
1499         my $d = $ifaces->{$iface};
1500         if ($d->{type} eq 'bond' && $d->{slaves}) {
1501             my $bond_primary_is_slave = undef;
1502             foreach my $p (split (/\s+/, $d->{slaves})) {
1503                 my $n = $ifaces->{$p};
1504
1505                 die "bond '$iface' - unable to find slave '$p'\n"
1506                     if !$n;
1507                 die "bond '$iface' - wrong interface type on slave '$p' " .
1508                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1509                 &$check_mtu($ifaces, $iface, $p);
1510                 $bond_primary_is_slave = 1 if $d->{'bond-primary'} && $d->{'bond-primary'} eq $p;
1511             }
1512             die "bond '$iface' - bond-primary interface is not a slave" if $d->{'bond-primary'} && !$bond_primary_is_slave;
1513         }
1514     }
1515
1516     # check vxlan
1517     my $vxlans = {};
1518     foreach my $iface (keys %$ifaces) {
1519         my $d = $ifaces->{$iface};
1520
1521         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1522             my $vxlanid = $d->{'vxlan-id'};
1523             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1524             $vxlans->{$vxlanid} = $iface;
1525         }
1526
1527         my $ips = 0;
1528         ++$ips if defined $d->{'vxlan-svcnodeip'};
1529         ++$ips if defined $d->{'vxlan-remoteip'};
1530         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1531         if ($ips > 1) {
1532             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1533         }
1534
1535         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1536             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1537         }
1538         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1539     }
1540
1541     # check vlan
1542     foreach my $iface (keys %$ifaces) {
1543         my $d = $ifaces->{$iface};
1544         if ($d->{type} eq 'vlan') {
1545
1546             my $p = undef;
1547             my $vlanid = undef;
1548
1549             if ($iface =~ m/^(\S+)\.(\d+)$/) {
1550                 $p = $1;
1551                 $vlanid = $2;
1552                 delete $d->{'vlan-raw-device'} if $d->{'vlan-raw-device'};
1553             } else {
1554                 die "missing vlan-raw-device option" if !$d->{'vlan-raw-device'};
1555                 $p = $d->{'vlan-raw-device'};
1556
1557                 if ($iface =~ m/^vlan(\d+)$/) {
1558                     $vlanid = $1;
1559                     delete $d->{'vlan-id'} if $d->{'vlan-id'};
1560                 } else {
1561                     die "custom vlan interface name need ifupdown2" if !$ifupdown2;
1562                     die "missing vlan-id option" if !$d->{'vlan-id'};
1563                     $vlanid = $d->{'vlan-id'};
1564                 }
1565             }
1566             my $n = $ifaces->{$p};
1567
1568             die "vlan '$iface' - vlan-id $vlanid should be <= 4094\n" if $vlanid > 4094;
1569             die "vlan '$iface' - unable to find parent '$p'\n"
1570                 if !$n;
1571
1572             if ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
1573                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1574                     "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
1575             }
1576
1577             &$check_mtu($ifaces, $p, $iface);
1578
1579         }
1580     }
1581
1582     # check uplink
1583     my $uplinks = {};
1584     foreach my $iface (keys %$ifaces) {
1585         my $d = $ifaces->{$iface};
1586         if (my $uplinkid = $d->{'uplink-id'}) {
1587             die "iface '$iface' - uplink-id $uplinkid is only allowed on physical and linux bond interfaces\n"
1588                 if $d->{type} ne 'eth' && $d->{type} ne 'bond';
1589
1590             die "iface '$iface' - uplink-id $uplinkid is already assigned on '$uplinks->{$uplinkid}'\n"
1591                 if $uplinks->{$uplinkid};
1592
1593             $uplinks->{$uplinkid} = $iface;
1594         }
1595     }
1596
1597     # check bridgeport option
1598     my $bridgeports = {};
1599     my $bridges = {};
1600     my $ifaces_copy = { %$ifaces };
1601     foreach my $iface (keys %$ifaces_copy) {
1602         my $d = $ifaces_copy->{$iface};
1603         if ($d->{type} eq 'bridge') {
1604             foreach my $p (split (/\s+/, $d->{bridge_ports})) {
1605                 if($p =~ m/(\S+)\.(\d+)$/) {
1606                     my $vlanparent = $1;
1607                     if (!defined($ifaces_copy->{$p})) {
1608                         $ifaces_copy->{$p}->{type} = 'vlan';
1609                         $ifaces_copy->{$p}->{method} = 'manual';
1610                         $ifaces_copy->{$p}->{method6} = 'manual';
1611                         $ifaces_copy->{$p}->{mtu} = $ifaces_copy->{$vlanparent}->{mtu} if defined($ifaces_copy->{$1}->{mtu});
1612                     }
1613                 }
1614                 my $n = $ifaces_copy->{$p};
1615                 die "bridge '$iface' - unable to find bridge port '$p'\n" if !$n;
1616                 die "iface $p - ip address can't be set on interface if bridged in $iface\n"
1617                     if ($n->{method} && $n->{method} eq 'static' && $n->{address} ne '0.0.0.0') ||
1618                        ($n->{method6} && $n->{method6} eq 'static' && $n->{address} ne '::');
1619                 &$check_mtu($ifaces_copy, $p, $iface);
1620                 $bridgeports->{$p} = $iface;
1621             }
1622             $bridges->{$iface} = $d;
1623         }
1624     }
1625
1626     foreach my $iface (keys %$ifaces) {
1627         my $d = $ifaces->{$iface};
1628
1629         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1630             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1631                 if $d->{$k} && !$bridgeports->{$iface};
1632         }
1633
1634         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1635             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1636         }
1637     }
1638
1639     my $raw = <<'NETWORKDOC';
1640 # network interface settings; autogenerated
1641 # Please do NOT modify this file directly, unless you know what
1642 # you're doing.
1643 #
1644 # If you want to manage parts of the network configuration manually,
1645 # please utilize the 'source' or 'source-directory' directives to do
1646 # so.
1647 # PVE will preserve these directives, but will NOT read its network
1648 # configuration from sourced files, so do not attempt to move any of
1649 # the PVE managed interfaces into external files!
1650
1651 NETWORKDOC
1652
1653     my $printed = {};
1654
1655     my $if_type_hash = {
1656         loopback => 100000,
1657         eth => 200000,
1658         OVSPort => 200000,
1659         OVSIntPort => 300000,
1660         OVSBond => 400000,
1661         bond => 400000,
1662         bridge => 500000,
1663         OVSBridge => 500000,
1664         vlan => 600000,
1665         vxlan => 600000,
1666    };
1667
1668     my $lookup_type_prio = sub {
1669         my ($iface, $ifaces) = @_;
1670
1671         my ($rootiface, @rest) = split(/[.:]/, $iface);
1672         my $childlevel = scalar(@rest);
1673         my $n = $ifaces->{$rootiface};
1674
1675         my $pri = $if_type_hash->{$n->{type}} + $childlevel
1676             if $n->{type} && $n->{type} ne 'unknown';
1677
1678         return $pri;
1679     };
1680
1681     foreach my $iface (sort {
1682         my $ref1 = $ifaces->{$a};
1683         my $ref2 = $ifaces->{$b};
1684         my $tp1 = &$lookup_type_prio($a, $ifaces);
1685         my $tp2 = &$lookup_type_prio($b, $ifaces);
1686
1687         # Only recognized types are in relation to each other. If one type
1688         # is unknown then only consider the interfaces' priority attributes.
1689         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1690
1691         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1692         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1693
1694         return $p1 <=> $p2 if $p1 != $p2;
1695
1696         return $a cmp $b;
1697     } keys %$ifaces) {
1698         next if $printed->{$iface};
1699         my $d = $ifaces->{$iface};
1700         my $pri = $d->{priority} // 0;
1701         if (@options && $options[0]->[0] < $pri) {
1702             do {
1703                 $raw .= (shift @options)->[1] . "\n";
1704             } while (@options && $options[0]->[0] < $pri);
1705             $raw .= "\n";
1706         }
1707
1708         $printed->{$iface} = 1;
1709         if ($d->{autostart}) {
1710             if ($d->{type} eq 'OVSBridge' && !$ifupdown2) {
1711                 # cannot use 'auto' for OVS, would add race with systemd ifup@.service
1712                 $raw .= "allow-ovs $iface\n";
1713             } else {
1714                 $raw .= "auto $iface\n";
1715             }
1716         }
1717
1718         my $i = 0; # some options should be printed only once
1719         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1720     }
1721
1722     $raw .= $_->[1] . "\n" foreach @options;
1723     return $raw;
1724 }
1725
1726 register_file('interfaces', "/etc/network/interfaces",
1727               \&read_etc_network_interfaces,
1728               \&write_etc_network_interfaces);
1729
1730
1731 sub read_iscsi_initiatorname {
1732     my ($filename, $fd) = @_;
1733
1734     while (defined(my $line = <$fd>)) {
1735         if ($line =~ m/^InitiatorName=(\S+)$/) {
1736             return $1;
1737         }
1738     }
1739
1740     return 'undefined';
1741 }
1742
1743 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1744               \&read_iscsi_initiatorname);
1745
1746 sub read_apt_auth {
1747     my ($filename, $fd) = @_;
1748
1749     local $/;
1750
1751     my $raw = defined($fd) ? <$fd> : '';
1752
1753     $raw =~ s/^\s+//;
1754
1755
1756     my @tokens = split(/\s+/, $raw);
1757
1758     my $data = {};
1759
1760     my $machine;
1761     while (defined(my $tok = shift @tokens)) {
1762
1763         $machine = shift @tokens if $tok eq 'machine';
1764         next if !$machine;
1765         $data->{$machine} = {} if !$data->{$machine};
1766
1767         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1768         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1769     };
1770
1771     return $data;
1772 }
1773
1774 my $format_apt_auth_data = sub {
1775     my $data = shift;
1776
1777     my $raw = '';
1778
1779     foreach my $machine (sort keys %$data) {
1780         my $d = $data->{$machine};
1781         $raw .= "machine $machine\n";
1782         $raw .= " login $d->{login}\n" if $d->{login};
1783         $raw .= " password $d->{password}\n" if $d->{password};
1784         $raw .= "\n";
1785     }
1786
1787     return $raw;
1788 };
1789
1790 sub write_apt_auth {
1791     my ($filename, $fh, $data) = @_;
1792
1793     my $raw = &$format_apt_auth_data($data);
1794
1795     die "write failed: $!" unless print $fh "$raw\n";
1796
1797     return $data;
1798 }
1799
1800 sub update_apt_auth {
1801     my ($filename, $fh, $data) = @_;
1802
1803     my $orig = read_apt_auth($filename, $fh);
1804
1805     foreach my $machine (keys %$data) {
1806         $orig->{$machine} = $data->{$machine};
1807     }
1808
1809     return &$format_apt_auth_data($orig);
1810 }
1811
1812 register_file('apt-auth', "/etc/apt/auth.conf",
1813               \&read_apt_auth, \&write_apt_auth,
1814               \&update_apt_auth, perm => 0640);
1815
1816 1;