dee9a3e9b2b6a48b0780b5a76feda425b269e5c1
[pve-common.git] / src / PVE / INotify.pm
1 package PVE::INotify;
2
3 # todo: maybe we do not need update_file() ?
4
5 use strict;
6 use warnings;
7
8 use POSIX;
9 use IO::File;
10 use IO::Dir;
11 use File::stat;
12 use File::Basename;
13 use Fcntl qw(:DEFAULT :flock);
14 use PVE::SafeSyslog;
15 use PVE::Exception qw(raise_param_exc);
16 use PVE::Network;
17 use PVE::Tools;
18 use PVE::ProcFSTools;
19 use Clone qw(clone);
20 use Linux::Inotify2;
21 use base 'Exporter';
22 use JSON; 
23
24 our @EXPORT_OK = qw(read_file write_file register_file);
25
26 my $ccache;
27 my $ccachemap;
28 my $ccacheregex;
29 my $inotify;
30 my $inotify_pid = 0;
31 my $versions;
32 my $shadowfiles = {
33     '/etc/network/interfaces' => '/etc/network/interfaces.new',
34 };
35
36 # to enable cached operation, you need to call 'inotify_init'
37 # inotify handles are a limited resource, so use with care (only
38 # enable the cache if you really need it)
39
40 # Note: please close the inotify handle after you fork
41
42 sub ccache_default_writer {
43     my ($filename, $data) = @_;
44
45     die "undefined config writer for '$filename' :ERROR";
46 }
47
48 sub ccache_default_parser {
49     my ($filename, $srcfd) = @_;
50
51     die "undefined config reader for '$filename' :ERROR";
52 }
53
54 sub ccache_compute_diff {
55     my ($filename, $shadow) = @_;
56
57     my $diff = '';
58
59     open (TMP, "diff -b -N -u '$filename' '$shadow'|");
60         
61     while (my $line = <TMP>) {
62         $diff .= $line;
63     }
64
65     close (TMP);
66
67     $diff = undef if !$diff;
68
69     return $diff;
70 }
71
72 sub ccache_info {
73     my ($filename) = @_;
74
75     foreach my $uid (keys %$ccacheregex) {
76         my $ccinfo = $ccacheregex->{$uid};
77         my $dir = $ccinfo->{dir};
78         my $regex = $ccinfo->{regex};
79         if ($filename =~ m|^$dir/+$regex$|) {
80             if (!$ccache->{$filename}) {
81                 my $cp = {};
82                 while (my ($k, $v) = each %$ccinfo) {
83                     $cp->{$k} = $v;
84                 }
85                 $ccache->{$filename} = $cp;
86             } 
87             return ($ccache->{$filename}, $filename);
88         }
89     }
90  
91     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
92
93     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
94    
95     return ($ccache->{$filename}, $filename);
96 }
97
98 sub write_file {
99     my ($fileid, $data, $full) = @_;
100
101     my ($ccinfo, $filename) = ccache_info($fileid);
102
103     my $writer = $ccinfo->{writer};
104
105     my $realname = $filename;
106
107     my $shadow;
108     if ($shadow = $shadowfiles->{$filename}) {
109         $realname = $shadow;
110     }
111
112     my $perm = $ccinfo->{perm} || 0644;
113
114     my $tmpname = "$realname.tmp.$$";
115
116     my $res;
117     eval {
118         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
119         die "unable to open file '$tmpname' - $!\n" if !$fh;
120
121         $res = &$writer($filename, $fh, $data);
122
123         die "closing file '$tmpname' failed - $!\n" unless close $fh;
124     };
125     my $err = $@;
126
127     $ccinfo->{version} = undef;
128
129     if ($err) {
130         unlink $tmpname;
131         die $err;
132     }
133
134     if (!rename($tmpname, $realname)) {
135         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
136         unlink $tmpname;
137         die $msg;       
138     }
139
140     my $diff;
141     if ($shadow && $full) {
142         $diff = ccache_compute_diff ($filename, $shadow);
143     }
144
145     if ($full) {
146         return { data => $res, changes => $diff };
147     }
148
149     return $res;
150 }
151
152 sub update_file {
153     my ($fileid, $data, @args) = @_;
154
155     my ($ccinfo, $filename) = ccache_info($fileid);
156
157     my $update = $ccinfo->{update};
158
159     die "unable to update/merge data" if !$update;
160
161     my $lkfn = "$filename.lock";
162
163     my $timeout = 10;
164
165     my $fd;
166
167     my $code = sub {
168
169         $fd = IO::File->new ($filename, "r");
170         
171         my $new = &$update($filename, $fd, $data, @args);
172
173         if (defined($new)) {
174             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
175         } else {
176             unlink $filename;
177         }
178     };
179
180     PVE::Tools::lock_file($lkfn, $timeout, $code);
181     my $err = $@;
182
183     close($fd) if defined($fd);
184
185     die $err if $err;
186
187     return undef;
188 }
189
190 sub discard_changes {
191     my ($fileid, $full) = @_;
192
193     my ($ccinfo, $filename) = ccache_info($fileid);
194
195     if (my $copy = $shadowfiles->{$filename}) {
196         unlink $copy;
197     }
198
199     return read_file ($filename, $full);
200 }
201
202 sub poll_changes {
203     my ($filename) = @_;
204
205     poll() if $inotify; # read new inotify events
206
207     $versions->{$filename} = 0 if !defined ($versions->{$filename});
208
209     return $versions->{$filename};
210 }
211
212 sub read_file {
213     my ($fileid, $full) = @_;
214
215     my $parser;
216
217     my ($ccinfo, $filename) = ccache_info($fileid);
218      
219     $parser = $ccinfo->{parser};
220  
221     my $fd;
222     my $shadow;
223
224     my $cver = poll_changes($filename);
225
226     if (my $copy = $shadowfiles->{$filename}) {
227         if ($fd = IO::File->new ($copy, "r")) {
228             $shadow = $copy;
229         } else {
230             $fd = IO::File->new ($filename, "r");
231         }
232     } else {
233         $fd = IO::File->new ($filename, "r");
234     }
235
236     my $acp = $ccinfo->{always_call_parser};
237
238     if (!$fd) {
239         $ccinfo->{version} = undef;
240         $ccinfo->{data} = undef; 
241         $ccinfo->{diff} = undef;
242         return undef if !$acp;
243     }
244
245     my $noclone = $ccinfo->{noclone};
246
247     # file unchanged?
248     if (!$ccinfo->{nocache} &&
249         $inotify && $cver &&
250         defined ($ccinfo->{data}) &&
251         defined ($ccinfo->{version}) &&
252         ($ccinfo->{readonce} ||
253          ($ccinfo->{version} == $cver))) {
254
255         my $ret;
256         if (!$noclone && ref ($ccinfo->{data})) {
257             $ret->{data} = clone ($ccinfo->{data});
258         } else {
259             $ret->{data} = $ccinfo->{data};
260         }
261         $ret->{changes} = $ccinfo->{diff};
262         
263         return $full ? $ret : $ret->{data};
264     }
265
266     my $diff;
267
268     if ($shadow) {
269         $diff = ccache_compute_diff ($filename, $shadow);
270     }
271
272     my $res = &$parser($filename, $fd);
273
274     if (!$ccinfo->{nocache}) {
275         $ccinfo->{version} = $cver;
276     }
277
278     # we cache data with references, so we always need to
279     # clone this data. Else the original data may get
280     # modified.
281     $ccinfo->{data} = $res;
282
283     # also store diff
284     $ccinfo->{diff} = $diff;
285
286     my $ret;
287     if (!$noclone && ref ($ccinfo->{data})) {
288         $ret->{data} = clone ($ccinfo->{data});
289     } else {
290         $ret->{data} = $ccinfo->{data};
291     }
292     $ret->{changes} = $ccinfo->{diff};
293
294     return $full ? $ret : $ret->{data};
295 }    
296
297 sub parse_ccache_options {
298     my ($ccinfo, %options) = @_;
299
300     foreach my $opt (keys %options) {
301         my $v = $options{$opt};
302         if ($opt eq 'readonce') {
303             $ccinfo->{$opt} = $v;
304         } elsif ($opt eq 'nocache') {
305             $ccinfo->{$opt} = $v;
306         } elsif ($opt eq 'shadow') {
307             $ccinfo->{$opt} = $v;
308         } elsif ($opt eq 'perm') {
309             $ccinfo->{$opt} = $v;
310         } elsif ($opt eq 'noclone') {
311             # noclone flag for large read-only data chunks like aplinfo
312             $ccinfo->{$opt} = $v;
313         } elsif ($opt eq 'always_call_parser') {
314             # when set, we call parser even when the file does not exists.
315             # this allows the parser to return some default
316             $ccinfo->{$opt} = $v;
317         } else {
318             die "internal error - unsupported option '$opt'";
319         }
320     }
321 }
322
323 sub register_file {
324     my ($id, $filename, $parser, $writer, $update, %options) = @_;
325
326     die "can't register file '$filename' after inotify_init" if $inotify;
327
328     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
329     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
330
331     my $ccinfo = {};
332
333     $ccinfo->{id} = $id;
334     $ccinfo->{parser} = $parser || \&ccache_default_parser;
335     $ccinfo->{writer} = $writer || \&ccache_default_writer;
336     $ccinfo->{update} = $update;
337
338     parse_ccache_options($ccinfo, %options);
339     
340     if ($options{shadow}) {
341         $shadowfiles->{$filename} = $options{shadow};
342     }
343
344     $ccachemap->{$id} = $filename;
345     $ccache->{$filename} = $ccinfo;
346 }
347
348 sub register_regex {
349     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
350
351     die "can't register regex after inotify_init" if $inotify;
352
353     my $uid = "$dir/$regex";
354     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
355  
356     my $ccinfo = {};
357
358     $ccinfo->{dir} = $dir;
359     $ccinfo->{regex} = $regex;
360     $ccinfo->{parser} = $parser || \&ccache_default_parser;
361     $ccinfo->{writer} = $writer || \&ccache_default_writer;
362     $ccinfo->{update} = $update;
363
364     parse_ccache_options($ccinfo, %options);
365
366     $ccacheregex->{$uid} = $ccinfo;
367 }
368
369 sub poll {
370     return if !$inotify;
371
372     if ($inotify_pid != $$) {
373         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
374         $inotify = undef;
375     } else {
376         1 while $inotify && $inotify->poll;
377     }
378 }
379
380 sub flushcache {
381     foreach my $filename (keys %$ccache) {
382         $ccache->{$filename}->{version} = undef;
383         $ccache->{$filename}->{data} = undef;
384         $ccache->{$filename}->{diff} = undef;
385     }
386 }
387
388 sub inotify_close {
389     $inotify = undef;
390 }
391
392 sub inotify_init {
393
394     die "only one inotify instance allowed" if $inotify;
395
396     $inotify =  Linux::Inotify2->new()
397         || die "Unable to create new inotify object: $!";
398
399     $inotify->blocking (0);
400
401     $versions = {};
402
403     my $dirhash = {};
404     foreach my $fn (keys %$ccache) {
405         my $dir = dirname ($fn);
406         my $base = basename ($fn);
407
408         $dirhash->{$dir}->{$base} = $fn;
409
410         if (my $sf = $shadowfiles->{$fn}) {
411             $base = basename ($sf);
412             $dir = dirname ($sf);
413             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
414         }
415     }
416
417     foreach my $uid (keys %$ccacheregex) {
418         my $ccinfo = $ccacheregex->{$uid};
419         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;       
420     }
421
422     $inotify_pid = $$;
423
424     foreach my $dir (keys %$dirhash) {
425
426         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
427         $inotify->watch ($dir, $evlist, sub {
428             my $e = shift;
429             my $name = $e->name;
430
431             if ($inotify_pid != $$) {
432                 syslog ('err', "got inotify event in wrong process");
433             }
434
435             if ($e->IN_ISDIR || !$name) {
436                 return;
437             }
438
439             if ($e->IN_Q_OVERFLOW) {
440                 syslog ('info', "got inotify overflow - flushing cache");
441                 flushcache();
442                 return;
443             }
444
445             if ($e->IN_UNMOUNT) {
446                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
447                 $inotify = undef;
448             }
449             if ($e->IN_IGNORED) { 
450                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
451                 $inotify = undef;
452             }
453
454             if ($dirhash->{$dir}->{_regex}) {
455                 foreach my $uid (keys %$ccacheregex) {
456                     my $ccinfo = $ccacheregex->{$uid};
457                     next if $dir ne $ccinfo->{dir};
458                     my $regex = $ccinfo->{regex};
459                     if ($regex && ($name =~ m|^$regex$|)) {
460
461                         my $fn = "$dir/$name";
462                         $versions->{$fn}++;
463                         #print "VERSION:$fn:$versions->{$fn}\n";
464                     }
465                 }
466             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
467
468                 $versions->{$fn}++;
469                 #print "VERSION:$fn:$versions->{$fn}\n";
470             }
471         });
472     }
473
474     foreach my $dir (keys %$dirhash) {
475         foreach my $name (keys %{$dirhash->{$dir}}) {
476             if ($name eq '_regex') {
477                 foreach my $uid (keys %$ccacheregex) {
478                     my $ccinfo = $ccacheregex->{$uid};
479                     next if $dir ne $ccinfo->{dir};
480                     my $re = $ccinfo->{regex};
481                     if (my $fd = IO::Dir->new ($dir)) {
482                         while (defined(my $de = $fd->read)) { 
483                             if ($de =~ m/^$re$/) {
484                                 my $fn = "$dir/$de";
485                                 $versions->{$fn}++; # init with version
486                                 #print "init:$fn:$versions->{$fn}\n";
487                             }
488                         }
489                     }
490                 }
491             } else {
492                 my $fn = $dirhash->{$dir}->{$name};
493                 $versions->{$fn}++; # init with version
494                 #print "init:$fn:$versions->{$fn}\n";
495             }
496         }
497     }
498 }
499
500 my $cached_nodename;
501
502 sub nodename {
503
504     return $cached_nodename if $cached_nodename;
505
506     my ($sysname, $nodename) = POSIX::uname();
507
508     $nodename =~ s/\..*$//; # strip domain part, if any
509
510     die "unable to read node name\n" if !$nodename;
511
512     $cached_nodename = $nodename;
513
514     return $cached_nodename;
515 }
516
517 sub read_etc_hostname {
518     my ($filename, $fd) = @_;
519
520     my $hostname = <$fd>;
521
522     chomp $hostname;
523
524     $hostname =~ s/\..*$//; # strip domain part, if any
525
526     return $hostname;
527 }
528
529 sub write_etc_hostname {
530     my ($filename, $fh, $hostname) = @_;
531
532     die "write failed: $!" unless print $fh "$hostname\n";
533
534     return $hostname;
535 }
536
537 register_file('hostname', "/etc/hostname",  
538               \&read_etc_hostname, 
539               \&write_etc_hostname);
540
541 sub read_etc_resolv_conf {
542     my ($filename, $fh) = @_;
543
544     my $res = {};
545
546     my $nscount = 0;
547     while (my $line = <$fh>) {
548         chomp $line;
549         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
550             $res->{search} = $2;
551         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
552             $nscount++;
553             if ($nscount <= 3) {
554                 $res->{"dns$nscount"} = $1;
555             }
556         }
557     }
558
559     return $res;
560 }
561
562 sub update_etc_resolv_conf {
563     my ($filename, $fh, $resolv, @args) = @_;
564
565     my $data = "";
566
567     $data = "search $resolv->{search}\n"
568         if $resolv->{search};
569
570     my $written = {};
571     foreach my $k ("dns1", "dns2", "dns3") {
572         my $ns = $resolv->{$k};
573         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
574             $written->{$ns} = 1;
575             $data .= "nameserver $ns\n";
576         }
577     }
578
579     while (my $line = <$fh>) {
580         next if $line =~ m/^(search|domain|nameserver)\s+/;
581         $data .= $line
582     }
583     
584     return $data;
585 }
586
587 register_file('resolvconf', "/etc/resolv.conf", 
588               \&read_etc_resolv_conf, undef, 
589               \&update_etc_resolv_conf);
590
591 sub read_etc_timezone {
592     my ($filename, $fd) = @_;
593
594     my $timezone = <$fd>;
595
596     chomp $timezone;
597
598     return $timezone;
599 }
600
601 sub write_etc_timezone {
602     my ($filename, $fh, $timezone) = @_;
603
604     my $tzinfo = "/usr/share/zoneinfo/$timezone";
605
606     raise_param_exc({ 'timezone' => "No such timezone" })
607         if (! -f $tzinfo);
608
609     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
610
611     print $fh "$timezone\n";
612
613     unlink ("/etc/localtime");
614     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
615
616 }
617
618 register_file('timezone', "/etc/timezone", 
619               \&read_etc_timezone, 
620               \&write_etc_timezone);
621
622 sub read_active_workers {
623     my ($filename, $fh) = @_;
624
625     return [] if !$fh;
626
627     my $res = []; 
628     while (defined (my $line = <$fh>)) {
629         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
630             my $upid = $1;
631             my $saved = $2;
632             my $endtime = $4;
633             my $status = $6;
634             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
635                 $task->{upid} = $upid;
636                 $task->{saved} = $saved;
637                 $task->{endtime} = hex($endtime) if $endtime;
638                 $task->{status} = $status if $status;
639                 push @$res, $task;
640             }
641         } else {
642             warn "unable to parse line: $line";
643         }
644     }
645
646     return $res;
647
648 }
649
650 sub write_active_workers {
651     my ($filename, $fh, $tasklist) = @_;
652
653     my $raw = '';
654     foreach my $task (@$tasklist) {
655         my $upid = $task->{upid};
656         my $saved = $task->{saved} ? 1 : 0;
657         if ($task->{endtime}) {
658             if ($task->{status}) {
659                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
660             } else {
661                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
662             }
663         } else {
664             $raw .= "$upid $saved\n";
665         }
666     }
667
668     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
669 }
670
671 register_file('active', "/var/log/pve/tasks/active", 
672               \&read_active_workers,
673               \&write_active_workers);
674
675
676 our $bond_modes = { 'balance-rr' => 0,
677                    'active-backup' => 1,
678                    'balance-xor' => 2,
679                    'broadcast' => 3,
680                    '802.3ad' => 4,
681                    'balance-tlb' => 5,
682                    'balance-alb' => 6,
683                };
684
685 my $ovs_bond_modes = {
686     'active-backup' => 1,
687     'balance-slb' => 1,
688     'lacp-balance-slb' => 1,
689     'lacp-balance-tcp' => 1, 
690 };
691
692 #sub get_bond_modes {
693 #    return $bond_modes;
694 #}
695
696 my $parse_ovs_option = sub {
697     my ($data) = @_;
698
699     my $opts = {};
700     foreach my $kv (split (/\s+/, $data || '')) {
701         my ($k, $v) = split('=', $kv, 2);
702         $opts->{$k} = $v if $k && $v;
703     }
704     return $opts;
705 };
706
707 my $set_ovs_option = sub {
708     my ($d, %params) = @_;
709
710     my $opts = &$parse_ovs_option($d->{ovs_options});
711
712     foreach my $k (keys %params) {
713         my $v = $params{$k};
714         if ($v) {
715             $opts->{$k} = $v;
716         } else {
717             delete $opts->{$k};
718         }
719     }
720
721     my $res = [];
722     foreach my $k (keys %$opts) {
723         push @$res, "$k=$opts->{$k}";
724     }
725
726     if (my $new = join(' ', @$res)) {
727         $d->{ovs_options} = $new;
728         return $d->{ovs_options};
729     } else {
730         delete $d->{ovs_options};
731         return undef;
732     }
733 };
734
735 my $extract_ovs_option = sub {
736     my ($d, $name) = @_;
737
738     my $opts = &$parse_ovs_option($d->{ovs_options});
739
740     my $v = delete $opts->{$name};
741
742     my $res = [];
743     foreach my $k (keys %$opts) {
744         push @$res, "$k=$opts->{$k}";
745     }
746
747     if (my $new = join(' ', @$res)) {
748         $d->{ovs_options} = $new;
749     } else {
750         delete $d->{ovs_options};
751     }
752
753     return $v;
754 };
755
756 my $check_mtu = sub {
757     my ($ifaces, $parent, $child) = @_;
758
759     die "check mtu - missing parent interface\n" if !$parent;
760     die "check mtu - missing child interface\n" if !$child;
761
762     my $cmtu = $ifaces->{$child}->{mtu};
763     return if !$cmtu;
764
765     my $parentdata = $ifaces->{$parent};
766     my $pmtu = $parentdata->{mtu};
767     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
768     $pmtu = 1500 if !$pmtu;
769
770     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
771         if $pmtu < $cmtu;
772 };
773
774 # config => {
775 #   ifaces => {
776 #     $ifname => {
777 #       <optional> exists => BOOL,
778 #       <optional> active => BOOL,
779 #       <optional> autostart => BOOL,
780 #       <auto> priority => INT,
781 #
782 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
783 #
784 #       families => ["inet", "inet6", ...],
785 #
786 #       method => "manual" | "static" | "dhcp" | ... ,
787 #       address => IP,
788 #       netmask => SUBNET,
789 #       broadcast => IP,
790 #       gateway => IP,
791 #       comments => [ "..." ],
792 #
793 #       method6 => "manual" | "static" | "dhcp" | ... ,
794 #       address6 => IP,
795 #       netmask6 => SUBNET,
796 #       gateway6 => IP,
797 #       comments6 => [ "..." ],
798 #
799 #       <known options>, # like bridge_ports, ovs_*
800 #
801 #       # extra/unknown options stored by-family:
802 #       options => { <inet options>... }
803 #       options6 => { <inet6 options>... }
804 #     }
805 #   },
806 #   options => [
807 #     # mappings end up here as well, as we don't need to understand them
808 #     [priority,line]
809 #   ]
810 # }
811 sub read_etc_network_interfaces {
812     my ($filename, $fh) = @_;
813     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
814     my $active = PVE::ProcFSTools::get_active_network_interfaces();
815     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
816 }
817
818 sub __read_etc_network_interfaces {
819     my ($fh, $proc_net_dev, $active_ifaces) = @_;
820
821     my $config = {};
822     my $ifaces = $config->{ifaces} = {};
823     my $options = $config->{options} = [];
824
825     my $options_alternatives = {
826         'bond-slaves' => 'slaves',
827         'bond_slaves' => 'slaves',
828         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
829         'bond-mode' => 'bond_mode',
830         'bond-miimon' =>'bond_miimon',
831         'bridge-vlan-aware' => 'bridge_vlan_aware',
832         'bridge-fd' => 'bridge_fd',
833         'bridge-stp' => 'bridge_stp',
834         'bridge-ports' => 'bridge_ports',
835         'bridge-vids' => 'bridge_vids'
836     };
837
838     my $line;
839
840     if ($proc_net_dev) {
841         while (defined ($line = <$proc_net_dev>)) {
842             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
843                 $ifaces->{$1}->{exists} = 1;
844             }
845         }
846         close($proc_net_dev);
847     }
848
849     # we try to keep order inside the file
850     my $priority = 2; # 1 is reserved for lo 
851
852     SECTION: while (defined ($line = <$fh>)) {
853         chomp ($line);
854         next if $line =~ m/^\s*#/;
855  
856         if ($line =~ m/^\s*auto\s+(.*)$/) {
857             my @aa = split (/\s+/, $1);
858
859             foreach my $a (@aa) {
860                 $ifaces->{$a}->{autostart} = 1;
861             }
862
863         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
864             my $i = $1;
865             my $family = $2;
866             my $f = { method => $3 }; # by family, merged to $d with a $suffix
867             (my $suffix = $family) =~ s/^inet//;
868
869             my $d = $ifaces->{$i} ||= {};
870             $d->{priority} = $priority++ if !$d->{priority};
871             push @{$d->{families}}, $family;
872
873             while (defined ($line = <$fh>)) {
874                 chomp $line;
875                 if ($line =~ m/^\s*#(.*?)\s*$/) {
876                     $f->{comments} = '' if !$f->{comments};
877                     my $comment = decode('UTF-8', $1);
878                     $f->{comments} .= "$comment\n";
879                 } elsif ($line =~ m/^\s*(?:iface\s
880                                           |mapping\s
881                                           |auto\s
882                                           |allow-
883                                           |source\s
884                                           |source-directory\s
885                                         )/x) {
886                     last;
887                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
888                     my $option = $1;
889                     my ($id, $value) = ($2, $3);
890
891                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
892
893                     my $simple_options = {
894                         'mtu' => 1,
895                         'ovs_type' => 1,
896                         'ovs_options' => 1,
897                         'ovs_bridge' => 1,
898                         'ovs_bonds' => 1,
899                         'ovs_ports' => 1,
900                         'bridge_fd' => 1,
901                         'bridge_vids' => 1,
902                         'bridge-access' => 1,
903                         'bridge-learning' => 1,
904                         'bridge-arp-nd-suppress' => 1,
905                         'bridge-unicast-flood' => 1,
906                         'bridge-multicast-flood' => 1,
907                         'bond_miimon' => 1,
908                         'bond_xmit_hash_policy' => 1,
909                         'vxlan-id' => 1,
910                         'vxlan-svcnodeip' => 1,
911                         'vxlan-physdev' => 1,
912                         'vxlan-local-tunnelip' => 1 };
913
914                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
915                         $f->{$id} = $value;
916                     } elsif ($simple_options->{$id}) {
917                         $d->{$id} = $value;
918                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
919                         my $devs = {};
920                         foreach my $p (split (/\s+/, $value)) {
921                             next if $p eq 'none';
922                             $devs->{$p} = 1;
923                         }
924                         my $str = join (' ', sort keys %{$devs});
925                         if ($d->{$id}) {
926                             $d->{$id} .= ' ' . $str if $str;
927                         } else {
928                             $d->{$id} = $str || '';
929                         }
930                     } elsif ($id eq 'bridge_stp') {
931                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
932                             $d->{$id} = 'on';
933                         } else {
934                             $d->{$id} = 'off';
935                         }
936                     } elsif ($id eq 'bridge_vlan_aware') {
937                         $d->{$id} = 1;
938                     } elsif ($id eq 'bond_mode') {
939                         # always use names
940                         foreach my $bm (keys %$bond_modes) {
941                             my $id = $bond_modes->{$bm};
942                             if ($id eq $value) {
943                                 $value = $bm;
944                                 last;
945                             }
946                         }
947                         $d->{$id} = $value;
948                     } elsif ($id eq 'vxlan-remoteip') {
949                         push @{$d->{$id}}, $value;
950                     } else {
951                         push @{$f->{options}}, $option;
952                     }
953                 } else {
954                     last;
955                 }
956             }
957             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
958             last SECTION if !defined($line);
959             redo SECTION;
960         } elsif ($line =~ /\w/) {
961             push @$options, [$priority++, $line];
962         }
963     }
964
965     foreach my $ifname (@$active_ifaces) {
966         if (my $iface = $ifaces->{$ifname}) {
967             $iface->{active} = 1;
968         }
969     }
970
971     if (!$ifaces->{lo}) {
972         $ifaces->{lo}->{priority} = 1;
973         $ifaces->{lo}->{method} = 'loopback';
974         $ifaces->{lo}->{type} = 'loopback';
975         $ifaces->{lo}->{autostart} = 1;
976     }
977
978     foreach my $iface (keys %$ifaces) {
979         my $d = $ifaces->{$iface};
980         if ($iface =~ m/^bond\d+$/) {
981             if (!$d->{ovs_type}) {
982                 $d->{type} = 'bond';
983             } elsif ($d->{ovs_type} eq 'OVSBond') {
984                 $d->{type} = $d->{ovs_type};
985                 # translate: ovs_options => bond_mode
986                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
987                 my $lacp = &$extract_ovs_option($d, 'lacp');
988                 if ($lacp && $lacp eq 'active') {
989                     if ($d->{'bond_mode'} eq 'balance-slb') {
990                         $d->{'bond_mode'} = 'lacp-balance-slb';
991                     }
992                 }
993                 # Note: balance-tcp needs lacp
994                 if ($d->{'bond_mode'} eq 'balance-tcp') {
995                     $d->{'bond_mode'} = 'lacp-balance-tcp';
996                 }
997                 my $tag = &$extract_ovs_option($d, 'tag');
998                 $d->{ovs_tag} = $tag if defined($tag);
999             } else {
1000                 $d->{type} = 'unknown';
1001             }
1002         } elsif ($iface =~ m/^vmbr\d+$/) {
1003             if (!$d->{ovs_type}) {
1004                 $d->{type} = 'bridge';
1005
1006                 if (!defined ($d->{bridge_fd})) {
1007                     $d->{bridge_fd} = 0;
1008                 }
1009                 if (!defined ($d->{bridge_stp})) {
1010                     $d->{bridge_stp} = 'off';
1011                 }
1012             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1013                 $d->{type} = $d->{ovs_type};
1014             } else {
1015                 $d->{type} = 'unknown';
1016             }
1017         } elsif ($iface =~ m/^(\S+):\d+$/) {
1018             $d->{type} = 'alias';
1019             if (defined ($ifaces->{$1})) {
1020                 $d->{exists} = $ifaces->{$1}->{exists};
1021             } else {
1022                 $ifaces->{$1}->{exists} = 0;
1023                 $d->{exists} = 0;
1024             }
1025         } elsif ($iface =~ m/^(\S+)\.\d+$/) {
1026             $d->{type} = 'vlan';
1027             if (defined ($ifaces->{$1})) {
1028                 $d->{exists} = $ifaces->{$1}->{exists};
1029             } else {
1030                 $ifaces->{$1}->{exists} = 0;
1031                 $d->{exists} = 0;
1032             }
1033         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1034             if (!$d->{ovs_type}) {
1035                 $d->{type} = 'eth';
1036             } elsif ($d->{ovs_type} eq 'OVSPort') {
1037                 $d->{type} = $d->{ovs_type};
1038                 my $tag = &$extract_ovs_option($d, 'tag');
1039                 $d->{ovs_tag} = $tag if defined($tag);
1040             } else {
1041                 $d->{type} = 'unknown';
1042             }
1043         } elsif ($iface =~ m/^lo$/) {
1044             $d->{type} = 'loopback';
1045         } else {
1046             if ($d->{'vxlan-id'}) {
1047                 $d->{type} = 'vxlan';
1048             } elsif (!$d->{ovs_type}) {
1049                 $d->{type} = 'unknown';
1050             } elsif ($d->{ovs_type} eq 'OVSIntPort') {
1051                 $d->{type} = $d->{ovs_type};
1052                 my $tag = &$extract_ovs_option($d, 'tag');
1053                 $d->{ovs_tag} = $tag if defined($tag);
1054             }
1055         }
1056
1057         $d->{method} = 'manual' if !$d->{method};
1058         $d->{method6} = 'manual' if !$d->{method6};
1059
1060         $d->{families} ||= ['inet'];
1061     }
1062
1063     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1064     # from the {options} hash for them to be removed correctly.
1065     @$options = grep {defined($_)} map {
1066         my ($pri, $line) = @$_;
1067         if ($line =~ /^allow-(\S+)\s+(.*)$/) {
1068             my $bridge = $1;
1069             my @ports = split(/\s+/, $2);
1070             if (defined(my $br = $ifaces->{$bridge})) {
1071                 # if this port is part of a bridge, remove it
1072                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1073                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1074             }
1075             # create the allow line for the remaining ports, or delete if empty
1076             if (@ports) {
1077                 [$pri, "allow-$bridge " . join(' ', @ports)];
1078             } else {
1079                 undef;
1080             }
1081         } else {
1082             # don't modify other lines
1083             $_;
1084         }
1085     } @$options;
1086
1087     return $config;
1088 }
1089
1090 sub __interface_to_string {
1091     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1092
1093     (my $suffix = $family) =~ s/^inet//;
1094
1095     return '' if !($d && $d->{"method$suffix"});
1096
1097     my $raw = '';
1098
1099     $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1100     $raw .= "\taddress  " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
1101     $raw .= "\tnetmask  " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
1102     $raw .= "\tgateway  " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1103     $raw .= "\tbroadcast  " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
1104
1105     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1106                  comments => 1, autostart => 1, options => 1,
1107                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1108                  method6 => 1, families => 1, options6 => 1,
1109                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1 };
1110
1111     if (!$first_block) {
1112         # not printing out options
1113     } elsif ($d->{type} eq 'bridge') {
1114
1115         $d->{bridge_ports} =~ s/[;,\s]+/ /g;
1116         my $ports = $d->{bridge_ports} || 'none';
1117         $raw .= "\tbridge-ports $ports\n";
1118         $done->{bridge_ports} = 1;
1119
1120         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1121         $raw .= "\tbridge-stp $v\n";
1122         $done->{bridge_stp} = 1;
1123
1124         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1125         $raw .= "\tbridge-fd $v\n";
1126         $done->{bridge_fd} = 1;
1127
1128         if( defined($d->{bridge_vlan_aware})) {
1129             $raw .= "\tbridge-vlan-aware yes\n";
1130             $v = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1131             $raw .= "\tbridge-vids $v\n";
1132         }
1133         $done->{bridge_vlan_aware} = 1;
1134         $done->{bridge_vids} = 1;
1135     
1136     } elsif ($d->{type} eq 'bond') {
1137
1138         $d->{slaves} =~ s/[;,\s]+/ /g;
1139         my $slaves = $d->{slaves} || 'none';
1140         $raw .= "\tbond-slaves $slaves\n";
1141         $done->{slaves} = 1;
1142
1143         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1144         $raw .= "\tbond-miimon $v\n";
1145         $done->{'bond_miimon'} = 1;
1146
1147         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1148         $raw .= "\tbond-mode $v\n";
1149         $done->{'bond_mode'} = 1;
1150
1151         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1152             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1153             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1154         }
1155         $done->{'bond_xmit_hash_policy'} = 1;
1156     } elsif ($d->{type} eq 'vxlan') {
1157
1158         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1159             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1160             $done->{$k} = 1;
1161         }
1162
1163         if ($d->{'vxlan-remoteip'}) {
1164             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1165                 $raw .= "\tvxlan-remoteip $remoteip\n";
1166             }
1167             $done->{'vxlan-remoteip'} = 1;
1168         }
1169     } elsif ($d->{type} eq 'OVSBridge') {
1170
1171         $raw .= "\tovs_type $d->{type}\n";
1172         $done->{ovs_type} = 1;
1173
1174         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1175         $done->{ovs_ports} = 1;
1176     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1177              $d->{type} eq 'OVSBond') {
1178
1179         $d->{autostart} = 0; # started by the bridge
1180
1181         if (defined($d->{ovs_tag})) {
1182             &$set_ovs_option($d, tag => $d->{ovs_tag});
1183         }
1184         $done->{ovs_tag} = 1;
1185
1186         if ($d->{type} eq 'OVSBond') {
1187
1188             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1189
1190             $ovs_bond_modes->{$d->{bond_mode}} ||
1191                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1192
1193             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1194                 &$set_ovs_option($d, lacp => 'active');
1195                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1196             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1197                 &$set_ovs_option($d, lacp => 'active');
1198                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1199             } else {
1200                 &$set_ovs_option($d, lacp => undef);
1201                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1202             }
1203             $done->{bond_mode} = 1;
1204
1205             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1206             $done->{ovs_bonds} = 1;
1207         }
1208
1209         $raw .= "\tovs_type $d->{type}\n";
1210         $done->{ovs_type} = 1;
1211
1212         if ($d->{ovs_bridge}) {
1213
1214             if ($ifupdown2) {
1215                 $raw = "auto $iface\n$raw";
1216             } else {
1217                 $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
1218             }
1219
1220             $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
1221             $done->{ovs_bridge} = 1;
1222         }
1223     }
1224
1225     if ($first_block) {
1226         # print other settings
1227         foreach my $k (sort keys %$d) {
1228            next if $done->{$k};
1229            next if !$d->{$k};
1230            $raw .= "\t$k $d->{$k}\n";
1231         }
1232     }
1233
1234     foreach my $option (@{$d->{"options$suffix"}}) {
1235         $raw .= "\t$option\n";
1236     }
1237
1238     # add comments
1239     my $comments = $d->{"comments$suffix"} || '';
1240     foreach my $cl (split(/\n/, $comments)) {
1241         $raw .= "#$cl\n";
1242     }
1243
1244     $raw .= "\n";
1245
1246     return $raw;
1247 }
1248
1249
1250 sub write_etc_network_interfaces {
1251     my ($filename, $fh, $config) = @_;
1252     my $ifupdown2 = -e '/usr/share/ifupdown2';
1253     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1254     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1255 }
1256 sub __write_etc_network_interfaces {
1257     my ($config, $ifupdown2) = @_;
1258
1259     my $ifaces = $config->{ifaces};
1260     my @options = @{$config->{options}};
1261
1262     my $used_ports = {};
1263
1264     foreach my $iface (keys %$ifaces) {
1265         my $d = $ifaces->{$iface};
1266
1267         my $ports = '';
1268         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1269             $ports .= " $d->{$k}" if $d->{$k};
1270         }
1271
1272         foreach my $p (PVE::Tools::split_list($ports)) {
1273             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1274                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1275             $used_ports->{$p} = $iface;
1276         }
1277     }
1278
1279     # delete unused OVS ports
1280     foreach my $iface (keys %$ifaces) {
1281         my $d = $ifaces->{$iface};
1282         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1283             $d->{type} eq 'OVSBond') {
1284             my $brname = $used_ports->{$iface};
1285             if (!$brname || !$ifaces->{$brname}) {
1286                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1287                     $ifaces->{$iface} = { type => 'eth',
1288                                           exists => 1,
1289                                           method => 'manual',
1290                                           families => ['inet'] };
1291                 } else {
1292                     delete $ifaces->{$iface};
1293                 }
1294                 next;
1295             }
1296             my $bd = $ifaces->{$brname};
1297             if ($bd->{type} ne 'OVSBridge') {
1298                 delete $ifaces->{$iface};
1299                 next;
1300             }
1301         }
1302     }
1303
1304     # create OVS bridge ports
1305     foreach my $iface (keys %$ifaces) {
1306         my $d = $ifaces->{$iface};
1307         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1308             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1309                 my $n = $ifaces->{$p};
1310                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1311                     if !$n;
1312                 $n->{autostart} = 0;
1313                 if ($n->{type} eq 'eth') {
1314                     $n->{type} = 'OVSPort';
1315                     $n->{ovs_bridge} = $iface;
1316                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1317                     $n->{type} eq 'OVSIntPort') {
1318                     $n->{ovs_bridge} = $iface;
1319                 } else {
1320                     die "interface '$p' is not defined as OVS port/bond\n";
1321                 }
1322
1323                 &$check_mtu($ifaces, $iface, $p);
1324             }
1325         }
1326     }
1327
1328     # check OVS bond ports
1329     foreach my $iface (keys %$ifaces) {
1330         my $d = $ifaces->{$iface};
1331         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1332             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1333                 my $n = $ifaces->{$p};
1334                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1335                     if !$n;
1336                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1337                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1338                 &$check_mtu($ifaces, $iface, $p);
1339             }
1340         }
1341     }
1342
1343     # check bond
1344     foreach my $iface (keys %$ifaces) {
1345         my $d = $ifaces->{$iface};
1346         if ($d->{type} eq 'bond' && $d->{slaves}) {
1347             foreach my $p (split (/\s+/, $d->{slaves})) {
1348                 my $n = $ifaces->{$p};
1349
1350                 die "bond '$iface' - unable to find slave '$p'\n"
1351                     if !$n;
1352                 die "bond '$iface' - wrong interface type on slave '$p' " .
1353                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1354                 &$check_mtu($ifaces, $iface, $p);
1355             }
1356         }
1357     }
1358
1359     # check vxlan
1360     my $vxlans = {};
1361     foreach my $iface (keys %$ifaces) {
1362         my $d = $ifaces->{$iface};
1363
1364         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1365             my $vxlanid = $d->{'vxlan-id'};
1366             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1367             $vxlans->{$vxlanid} = $iface;
1368         }
1369
1370         my $ips = 0;
1371         ++$ips if defined $d->{'vxlan-svcnodeip'};
1372         ++$ips if defined $d->{'vxlan-remoteip'};
1373         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1374         if ($ips > 1) {
1375             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1376         }
1377
1378         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1379             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1380         }
1381         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1382     }
1383
1384     # check vlan
1385     foreach my $iface (keys %$ifaces) {
1386         my $d = $ifaces->{$iface};
1387         if ($d->{type} eq 'vlan' && $iface =~ m/^(\S+)\.\d+$/) {
1388             my $p = $1;
1389             my $n = $ifaces->{$p};
1390
1391             die "vlan '$iface' - unable to find parent '$p'\n"
1392                 if !$n;
1393
1394             if ($n->{type} eq 'bridge' && !$n->{bridge_vlan_aware}) {
1395                 die "vlan '$iface' - bridge vlan aware is not enabled on parent '$p'\n";
1396             } elsif ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond') {
1397                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1398                     "('$n->{type}' != 'eth|bond|bridge' )\n";
1399             }
1400             &$check_mtu($ifaces, $p, $iface);
1401         }
1402     }
1403
1404     # check bridgeport option
1405     my $bridgeports = {};
1406     my $bridges = {};
1407     foreach my $iface (keys %$ifaces) {
1408         my $d = $ifaces->{$iface};
1409         if ($d->{type} eq 'bridge') {
1410             foreach my $p (split (/\s+/, $d->{bridge_ports})) {
1411                 $p =~ s/\.\d+$//;
1412                 my $n = $ifaces->{$p};
1413                 die "bridge '$iface' - unable to find bridge port '$p'\n"
1414                     if !$n;
1415                 &$check_mtu($ifaces, $iface, $p);
1416                 $bridgeports->{$p} = $iface;
1417             }
1418             $bridges->{$iface} = $d;
1419         }
1420     }
1421
1422     foreach my $iface (keys %$ifaces) {
1423         my $d = $ifaces->{$iface};
1424
1425         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1426             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1427                 if $d->{$k} && !$bridgeports->{$iface};
1428         }
1429
1430         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1431             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1432         }
1433     }
1434
1435     my $raw = <<'NETWORKDOC';
1436 # network interface settings; autogenerated
1437 # Please do NOT modify this file directly, unless you know what
1438 # you're doing.
1439 #
1440 # If you want to manage part of the network configuration manually,
1441 # please utilize the 'source' or 'source-directory' directives to do
1442 # so.
1443 # PVE will preserve these directives, but will NOT its network
1444 # configuration from sourced files, so do not attempt to move any of
1445 # the PVE managed interfaces into external files!
1446
1447 NETWORKDOC
1448
1449     my $printed = {};
1450
1451     my $if_type_hash = {
1452         loopback => 100000,
1453         eth => 200000,
1454         bond => 300000,
1455         bridge => 400000,
1456         vxlan => 500000,
1457    };
1458
1459     my $lookup_type_prio = sub {
1460         my $iface = shift;
1461
1462         my $child = 0;
1463         if ($iface =~ m/^(\S+)(\.|:)\d+$/) {
1464             $iface = $1;
1465             $child = 1;
1466         }
1467
1468         my $pri;
1469         if ($iface eq 'lo') {
1470             $pri = $if_type_hash->{loopback};
1471         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1472             $pri = $if_type_hash->{eth} + $child;
1473         } elsif ($iface =~ m/^bond\d+$/) {
1474             $pri = $if_type_hash->{bond} + $child;
1475         } elsif ($iface =~ m/^vmbr\d+$/) {
1476             $pri = $if_type_hash->{bridge} + $child;
1477         }
1478
1479         return $pri;
1480     };
1481
1482     foreach my $iface (sort {
1483         my $ref1 = $ifaces->{$a};
1484         my $ref2 = $ifaces->{$b};
1485         my $tp1 = &$lookup_type_prio($a);
1486         my $tp2 = &$lookup_type_prio($b);
1487
1488         # Only recognized types are in relation to each other. If one type
1489         # is unknown then only consider the interfaces' priority attributes.
1490         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1491
1492         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1493         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1494
1495         return $p1 <=> $p2 if $p1 != $p2;
1496
1497         return $a cmp $b;
1498     } keys %$ifaces) {
1499         next if $printed->{$iface};
1500
1501         my $d = $ifaces->{$iface};
1502         my $pri = $d->{priority} // 0;
1503         if (@options && $options[0]->[0] < $pri) {
1504             do {
1505                 $raw .= (shift @options)->[1] . "\n";
1506             } while (@options && $options[0]->[0] < $pri);
1507             $raw .= "\n";
1508         }
1509
1510         $printed->{$iface} = 1;
1511         $raw .= "auto $iface\n" if $d->{autostart};
1512         my $i = 0; # some options should be printed only once
1513         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1514     }
1515
1516     $raw .= $_->[1] . "\n" foreach @options;
1517     return $raw;
1518 }
1519
1520 register_file('interfaces', "/etc/network/interfaces",
1521               \&read_etc_network_interfaces,
1522               \&write_etc_network_interfaces);
1523
1524
1525 sub read_iscsi_initiatorname {
1526     my ($filename, $fd) = @_;
1527
1528     while (defined(my $line = <$fd>)) {
1529         if ($line =~ m/^InitiatorName=(\S+)$/) {
1530             return $1;
1531         }
1532     }
1533
1534     return 'undefined';
1535 }
1536
1537 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",  
1538               \&read_iscsi_initiatorname);
1539
1540 sub read_apt_auth {
1541     my ($filename, $fd) = @_;
1542
1543     local $/;
1544
1545     my $raw = defined($fd) ? <$fd> : '';
1546
1547     $raw =~ s/^\s+//;
1548
1549  
1550     my @tokens = split(/\s+/, $raw);
1551
1552     my $data = {};
1553
1554     my $machine;
1555     while (defined(my $tok = shift @tokens)) {
1556
1557         $machine = shift @tokens if $tok eq 'machine';
1558         next if !$machine;
1559         $data->{$machine} = {} if !$data->{$machine};
1560
1561         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1562         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1563     };
1564
1565     return $data;
1566 }
1567
1568 my $format_apt_auth_data = sub {
1569     my $data = shift;
1570
1571     my $raw = '';
1572
1573     foreach my $machine (sort keys %$data) {
1574         my $d = $data->{$machine};
1575         $raw .= "machine $machine\n";
1576         $raw .= " login $d->{login}\n" if $d->{login};
1577         $raw .= " password $d->{password}\n" if $d->{password};
1578         $raw .= "\n";
1579     }
1580
1581     return $raw;
1582 };
1583
1584 sub write_apt_auth {
1585     my ($filename, $fh, $data) = @_;
1586
1587     my $raw = &$format_apt_auth_data($data);
1588
1589     die "write failed: $!" unless print $fh "$raw\n";
1590    
1591     return $data;
1592 }
1593
1594 sub update_apt_auth {
1595     my ($filename, $fh, $data) = @_;
1596
1597     my $orig = read_apt_auth($filename, $fh);
1598
1599     foreach my $machine (keys %$data) {
1600         $orig->{$machine} = $data->{$machine};
1601     }
1602
1603     return &$format_apt_auth_data($orig);
1604 }
1605
1606 register_file('apt-auth', "/etc/apt/auth.conf",  
1607               \&read_apt_auth, \&write_apt_auth,
1608               \&update_apt_auth, perm => 0640);
1609
1610 1;