src/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4 use strict;
   5 use warnings;
   6
   7 use Clone qw(clone);
   8 use Digest::SHA;
   9 use Encode qw(encode decode);
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::stat;
  13 use IO::Dir;
  14 use IO::File;
  15 use JSON;
  16 use Linux::Inotify2;
  17 use POSIX;
  18
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::JSONSchema;
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools;
  25
  26 use base 'Exporter';
  27
  28 our @EXPORT_OK = qw(read_file write_file register_file);
  29
  30 my $ccache;
  31 my $ccachemap;
  32 my $ccacheregex;
  33 my $inotify;
  34 my $inotify_pid = 0;
  35 my $versions;
  36 my $shadowfiles = {
  37     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  38 };
  39
  40 # to enable cached operation, you need to call 'inotify_init'
  41 # inotify handles are a limited resource, so use with care (only
  42 # enable the cache if you really need it)
  43
  44 # Note: please close the inotify handle after you fork
  45
  46 sub ccache_default_writer {
  47     my ($filename, $data) = @_;
  48
  49     die "undefined config writer for '$filename' :ERROR";
  50 }
  51
  52 sub ccache_default_parser {
  53     my ($filename, $srcfd) = @_;
  54
  55     die "undefined config reader for '$filename' :ERROR";
  56 }
  57
  58 sub ccache_compute_diff {
  59     my ($filename, $shadow) = @_;
  60
  61     my $diff = '';
  62
  63     my $cmd = ['/usr/bin/diff', '-b', '-N', '-u', $filename, $shadow];
  64     PVE::Tools::run_command($cmd, noerr => 1, outfunc => sub {
  65         my ($line) = @_;
  66         $diff .= decode('UTF-8', $line) . "\n";
  67     });
  68
  69     $diff = undef if !$diff;
  70
  71     return $diff;
  72 }
  73
  74 sub ccache_info {
  75     my ($filename) = @_;
  76
  77     foreach my $uid (keys %$ccacheregex) {
  78         my $ccinfo = $ccacheregex->{$uid};
  79         my $dir = $ccinfo->{dir};
  80         my $regex = $ccinfo->{regex};
  81         if ($filename =~ m|^$dir/+$regex$|) {
  82             if (!$ccache->{$filename}) {
  83                 my $cp = {};
  84                 while (my ($k, $v) = each %$ccinfo) {
  85                     $cp->{$k} = $v;
  86                 }
  87                 $ccache->{$filename} = $cp;
  88             }
  89             return ($ccache->{$filename}, $filename);
  90         }
  91     }
  92
  93     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  94
  95     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  96
  97     return ($ccache->{$filename}, $filename);
  98 }
  99
 100 sub write_file {
 101     my ($fileid, $data, $full) = @_;
 102
 103     my ($ccinfo, $filename) = ccache_info($fileid);
 104
 105     my $writer = $ccinfo->{writer};
 106
 107     my $realname = $filename;
 108
 109     my $shadow;
 110     if ($shadow = $shadowfiles->{$filename}) {
 111         $realname = $shadow;
 112     }
 113
 114     my $perm = $ccinfo->{perm} || 0644;
 115
 116     my $tmpname = "$realname.tmp.$$";
 117
 118     my $res;
 119     eval {
 120         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 121         die "unable to open file '$tmpname' - $!\n" if !$fh;
 122
 123         $res = &$writer($filename, $fh, $data);
 124
 125         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 126     };
 127     my $err = $@;
 128
 129     $ccinfo->{version} = undef;
 130
 131     if ($err) {
 132         unlink $tmpname;
 133         die $err;
 134     }
 135
 136     if (!rename($tmpname, $realname)) {
 137         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 138         unlink $tmpname;
 139         die $msg;
 140     }
 141
 142     my $diff;
 143     if ($shadow && $full) {
 144         $diff = ccache_compute_diff ($filename, $shadow);
 145     }
 146
 147     if ($full) {
 148         return { data => $res, changes => $diff };
 149     }
 150
 151     return $res;
 152 }
 153
 154 sub update_file {
 155     my ($fileid, $data, @args) = @_;
 156
 157     my ($ccinfo, $filename) = ccache_info($fileid);
 158
 159     my $update = $ccinfo->{update};
 160
 161     die "unable to update/merge data" if !$update;
 162
 163     my $lkfn = "$filename.lock";
 164
 165     my $timeout = 10;
 166
 167     my $fd;
 168
 169     my $code = sub {
 170
 171         $fd = IO::File->new ($filename, "r");
 172
 173         my $new = &$update($filename, $fd, $data, @args);
 174
 175         if (defined($new)) {
 176             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 177         } else {
 178             unlink $filename;
 179         }
 180     };
 181
 182     PVE::Tools::lock_file($lkfn, $timeout, $code);
 183     my $err = $@;
 184
 185     close($fd) if defined($fd);
 186
 187     die $err if $err;
 188
 189     return undef;
 190 }
 191
 192 sub discard_changes {
 193     my ($fileid, $full) = @_;
 194
 195     my ($ccinfo, $filename) = ccache_info($fileid);
 196
 197     if (my $copy = $shadowfiles->{$filename}) {
 198         unlink $copy;
 199     }
 200
 201     return read_file ($filename, $full);
 202 }
 203
 204 sub poll_changes {
 205     my ($filename) = @_;
 206
 207     poll() if $inotify; # read new inotify events
 208
 209     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 210
 211     return $versions->{$filename};
 212 }
 213
 214 sub read_file {
 215     my ($fileid, $full) = @_;
 216
 217     my $parser;
 218
 219     my ($ccinfo, $filename) = ccache_info($fileid);
 220
 221     $parser = $ccinfo->{parser};
 222
 223     my $fd;
 224     my $shadow;
 225
 226     my $cver = poll_changes($filename);
 227
 228     if (my $copy = $shadowfiles->{$filename}) {
 229         if ($fd = IO::File->new ($copy, "r")) {
 230             $shadow = $copy;
 231         } else {
 232             $fd = IO::File->new ($filename, "r");
 233         }
 234     } else {
 235         $fd = IO::File->new ($filename, "r");
 236     }
 237
 238     my $acp = $ccinfo->{always_call_parser};
 239
 240     if (!$fd) {
 241         $ccinfo->{version} = undef;
 242         $ccinfo->{data} = undef;
 243         $ccinfo->{diff} = undef;
 244         return undef if !$acp;
 245     }
 246
 247     my $noclone = $ccinfo->{noclone};
 248
 249     # file unchanged?
 250     if (!$ccinfo->{nocache} &&
 251         $inotify && $cver &&
 252         defined ($ccinfo->{data}) &&
 253         defined ($ccinfo->{version}) &&
 254         ($ccinfo->{readonce} ||
 255          ($ccinfo->{version} == $cver))) {
 256
 257         my $ret;
 258         if (!$noclone && ref ($ccinfo->{data})) {
 259             $ret->{data} = clone ($ccinfo->{data});
 260         } else {
 261             $ret->{data} = $ccinfo->{data};
 262         }
 263         $ret->{changes} = $ccinfo->{diff};
 264
 265         return $full ? $ret : $ret->{data};
 266     }
 267
 268     my $diff;
 269
 270     if ($shadow) {
 271         $diff = ccache_compute_diff ($filename, $shadow);
 272     }
 273
 274     my $res = &$parser($filename, $fd);
 275
 276     if (!$ccinfo->{nocache}) {
 277         $ccinfo->{version} = $cver;
 278     }
 279
 280     # we cache data with references, so we always need to
 281     # clone this data. Else the original data may get
 282     # modified.
 283     $ccinfo->{data} = $res;
 284
 285     # also store diff
 286     $ccinfo->{diff} = $diff;
 287
 288     my $ret;
 289     if (!$noclone && ref ($ccinfo->{data})) {
 290         $ret->{data} = clone ($ccinfo->{data});
 291     } else {
 292         $ret->{data} = $ccinfo->{data};
 293     }
 294     $ret->{changes} = $ccinfo->{diff};
 295
 296     return $full ? $ret : $ret->{data};
 297 }
 298
 299 sub parse_ccache_options {
 300     my ($ccinfo, %options) = @_;
 301
 302     foreach my $opt (keys %options) {
 303         my $v = $options{$opt};
 304         if ($opt eq 'readonce') {
 305             $ccinfo->{$opt} = $v;
 306         } elsif ($opt eq 'nocache') {
 307             $ccinfo->{$opt} = $v;
 308         } elsif ($opt eq 'shadow') {
 309             $ccinfo->{$opt} = $v;
 310         } elsif ($opt eq 'perm') {
 311             $ccinfo->{$opt} = $v;
 312         } elsif ($opt eq 'noclone') {
 313             # noclone flag for large read-only data chunks like aplinfo
 314             $ccinfo->{$opt} = $v;
 315         } elsif ($opt eq 'always_call_parser') {
 316             # when set, we call parser even when the file does not exist.
 317             # this allows the parser to return some default
 318             $ccinfo->{$opt} = $v;
 319         } else {
 320             die "internal error - unsupported option '$opt'";
 321         }
 322     }
 323 }
 324
 325 sub register_file {
 326     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 327
 328     die "can't register file '$filename' after inotify_init" if $inotify;
 329
 330     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 331     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 332
 333     my $ccinfo = {};
 334
 335     $ccinfo->{id} = $id;
 336     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 337     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 338     $ccinfo->{update} = $update;
 339
 340     parse_ccache_options($ccinfo, %options);
 341
 342     if ($options{shadow}) {
 343         $shadowfiles->{$filename} = $options{shadow};
 344     }
 345
 346     $ccachemap->{$id} = $filename;
 347     $ccache->{$filename} = $ccinfo;
 348 }
 349
 350 sub register_regex {
 351     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 352
 353     die "can't register regex after inotify_init" if $inotify;
 354
 355     my $uid = "$dir/$regex";
 356     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 357
 358     my $ccinfo = {};
 359
 360     $ccinfo->{dir} = $dir;
 361     $ccinfo->{regex} = $regex;
 362     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 363     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 364     $ccinfo->{update} = $update;
 365
 366     parse_ccache_options($ccinfo, %options);
 367
 368     $ccacheregex->{$uid} = $ccinfo;
 369 }
 370
 371 sub poll {
 372     return if !$inotify;
 373
 374     if ($inotify_pid != $$) {
 375         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 376         $inotify = undef;
 377     } else {
 378         1 while $inotify && $inotify->poll;
 379     }
 380 }
 381
 382 sub flushcache {
 383     foreach my $filename (keys %$ccache) {
 384         $ccache->{$filename}->{version} = undef;
 385         $ccache->{$filename}->{data} = undef;
 386         $ccache->{$filename}->{diff} = undef;
 387     }
 388 }
 389
 390 sub inotify_close {
 391     $inotify = undef;
 392 }
 393
 394 sub inotify_init {
 395
 396     die "only one inotify instance allowed" if $inotify;
 397
 398     $inotify =  Linux::Inotify2->new()
 399         || die "Unable to create new inotify object: $!";
 400
 401     $inotify->blocking (0);
 402
 403     $versions = {};
 404
 405     my $dirhash = {};
 406     foreach my $fn (keys %$ccache) {
 407         my $dir = dirname ($fn);
 408         my $base = basename ($fn);
 409
 410         $dirhash->{$dir}->{$base} = $fn;
 411
 412         if (my $sf = $shadowfiles->{$fn}) {
 413             $base = basename ($sf);
 414             $dir = dirname ($sf);
 415             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 416         }
 417     }
 418
 419     foreach my $uid (keys %$ccacheregex) {
 420         my $ccinfo = $ccacheregex->{$uid};
 421         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 422     }
 423
 424     $inotify_pid = $$;
 425
 426     foreach my $dir (keys %$dirhash) {
 427
 428         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 429         $inotify->watch ($dir, $evlist, sub {
 430             my $e = shift;
 431             my $name = $e->name;
 432
 433             if ($inotify_pid != $$) {
 434                 syslog ('err', "got inotify event in wrong process");
 435             }
 436
 437             if ($e->IN_ISDIR || !$name) {
 438                 return;
 439             }
 440
 441             if ($e->IN_Q_OVERFLOW) {
 442                 syslog ('info', "got inotify overflow - flushing cache");
 443                 flushcache();
 444                 return;
 445             }
 446
 447             if ($e->IN_UNMOUNT) {
 448                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 449                 $inotify = undef;
 450             }
 451             if ($e->IN_IGNORED) {
 452                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 453                 $inotify = undef;
 454             }
 455
 456             if ($dirhash->{$dir}->{_regex}) {
 457                 foreach my $uid (keys %$ccacheregex) {
 458                     my $ccinfo = $ccacheregex->{$uid};
 459                     next if $dir ne $ccinfo->{dir};
 460                     my $regex = $ccinfo->{regex};
 461                     if ($regex && ($name =~ m|^$regex$|)) {
 462
 463                         my $fn = "$dir/$name";
 464                         $versions->{$fn}++;
 465                         #print "VERSION:$fn:$versions->{$fn}\n";
 466                     }
 467                 }
 468             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 469
 470                 $versions->{$fn}++;
 471                 #print "VERSION:$fn:$versions->{$fn}\n";
 472             }
 473         });
 474     }
 475
 476     foreach my $dir (keys %$dirhash) {
 477         foreach my $name (keys %{$dirhash->{$dir}}) {
 478             if ($name eq '_regex') {
 479                 foreach my $uid (keys %$ccacheregex) {
 480                     my $ccinfo = $ccacheregex->{$uid};
 481                     next if $dir ne $ccinfo->{dir};
 482                     my $re = $ccinfo->{regex};
 483                     if (my $fd = IO::Dir->new ($dir)) {
 484                         while (defined(my $de = $fd->read)) {
 485                             if ($de =~ m/^$re$/) {
 486                                 my $fn = "$dir/$de";
 487                                 $versions->{$fn}++; # init with version
 488                                 #print "init:$fn:$versions->{$fn}\n";
 489                             }
 490                         }
 491                     }
 492                 }
 493             } else {
 494                 my $fn = $dirhash->{$dir}->{$name};
 495                 $versions->{$fn}++; # init with version
 496                 #print "init:$fn:$versions->{$fn}\n";
 497             }
 498         }
 499     }
 500 }
 501
 502 my $cached_nodename;
 503
 504 sub nodename {
 505
 506     return $cached_nodename if $cached_nodename;
 507
 508     my ($sysname, $nodename) = POSIX::uname();
 509
 510     $nodename =~ s/\..*$//; # strip domain part, if any
 511
 512     die "unable to read node name\n" if !$nodename;
 513
 514     $cached_nodename = $nodename;
 515
 516     return $cached_nodename;
 517 }
 518
 519 sub read_etc_hostname {
 520     my ($filename, $fd) = @_;
 521
 522     my $hostname = <$fd>;
 523
 524     chomp $hostname;
 525
 526     $hostname =~ s/\..*$//; # strip domain part, if any
 527
 528     return $hostname;
 529 }
 530
 531 sub write_etc_hostname {
 532     my ($filename, $fh, $hostname) = @_;
 533
 534     die "write failed: $!" unless print $fh "$hostname\n";
 535
 536     return $hostname;
 537 }
 538
 539 register_file('hostname', "/etc/hostname",
 540               \&read_etc_hostname,
 541               \&write_etc_hostname);
 542
 543 sub read_etc_hosts {
 544     my ($filename, $fh) = @_;
 545
 546     my $raw = '';
 547     my $data = '';
 548
 549     while (my $line = <$fh>) {
 550         $raw .= $line;
 551         if ($line =~ m/^\s*#/) {
 552             $line = decode('UTF-8', $line);
 553         }
 554         $data .= $line;
 555     }
 556
 557     return {
 558         digest => Digest::SHA::sha1_hex($raw),
 559         data => $data,
 560     }
 561 }
 562
 563 sub write_etc_hosts {
 564     my ($filename, $fh, $hosts, @args) = @_;
 565
 566     # check validity of ips/names
 567     for my $line (split("\n", $hosts)) {
 568         next if $line =~ m/^\s*#/; # comments
 569         next if $line =~ m/^\s*$/; # whitespace/empty lines
 570
 571         my ($ip, @names) = split(/\s+/, $line);
 572
 573         raise_param_exc({ 'data' => "Invalid IP '$ip'" })
 574             if $ip !~ m/^$PVE::Tools::IPRE$/;
 575
 576         for my $name (@names) {
 577             raise_param_exc({ 'data' => "Invalid Hostname '$name'" })
 578                 if $name !~ m/^[.\-a-zA-Z0-9]+$/;
 579         }
 580     }
 581
 582     die "write failed: $!" if !print $fh encode('UTF-8', $hosts);
 583
 584     return $hosts;
 585 }
 586
 587 register_file('etchosts', "/etc/hosts",
 588               \&read_etc_hosts,
 589               \&write_etc_hosts);
 590
 591 sub read_etc_resolv_conf {
 592     my ($filename, $fh) = @_;
 593
 594     my $res = {};
 595
 596     my $nscount = 0;
 597     while (my $line = <$fh>) {
 598         chomp $line;
 599         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 600             $res->{search} = $2;
 601         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
 602             $nscount++;
 603             if ($nscount <= 3) {
 604                 $res->{"dns$nscount"} = $1;
 605             }
 606         }
 607     }
 608
 609     return $res;
 610 }
 611
 612 sub update_etc_resolv_conf {
 613     my ($filename, $fh, $resolv, @args) = @_;
 614
 615     my $data = "";
 616
 617     $data = "search $resolv->{search}\n"
 618         if $resolv->{search};
 619
 620     my $written = {};
 621     foreach my $k ("dns1", "dns2", "dns3") {
 622         my $ns = $resolv->{$k};
 623         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 624             $written->{$ns} = 1;
 625             $data .= "nameserver $ns\n";
 626         }
 627     }
 628
 629     while (my $line = <$fh>) {
 630         next if $line =~ m/^(search|domain|nameserver)\s+/;
 631         $data .= $line
 632     }
 633
 634     return $data;
 635 }
 636
 637 register_file('resolvconf', "/etc/resolv.conf",
 638               \&read_etc_resolv_conf, undef,
 639               \&update_etc_resolv_conf);
 640
 641 sub read_etc_timezone {
 642     my ($filename, $fd) = @_;
 643
 644     my $timezone = <$fd>;
 645
 646     chomp $timezone;
 647
 648     return $timezone;
 649 }
 650
 651 sub write_etc_timezone {
 652     my ($filename, $fh, $timezone) = @_;
 653
 654     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 655
 656     raise_param_exc({ 'timezone' => "No such timezone" })
 657         if (! -f $tzinfo);
 658
 659     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 660
 661     print $fh "$timezone\n";
 662
 663     unlink ("/etc/localtime");
 664     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 665
 666 }
 667
 668 register_file('timezone', "/etc/timezone",
 669               \&read_etc_timezone,
 670               \&write_etc_timezone);
 671
 672 sub read_active_workers {
 673     my ($filename, $fh) = @_;
 674
 675     return [] if !$fh;
 676
 677     my $res = [];
 678     while (defined (my $line = <$fh>)) {
 679         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 680             my $upid = $1;
 681             my $saved = $2;
 682             my $endtime = $4;
 683             my $status = $6;
 684             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 685                 $task->{upid} = $upid;
 686                 $task->{saved} = $saved;
 687                 $task->{endtime} = hex($endtime) if $endtime;
 688                 $task->{status} = $status if $status;
 689                 push @$res, $task;
 690             }
 691         } else {
 692             warn "unable to parse line: $line";
 693         }
 694     }
 695
 696     return $res;
 697
 698 }
 699
 700 sub write_active_workers {
 701     my ($filename, $fh, $tasklist) = @_;
 702
 703     my $raw = '';
 704     foreach my $task (@$tasklist) {
 705         my $upid = $task->{upid};
 706         my $saved = $task->{saved} ? 1 : 0;
 707         if ($task->{endtime}) {
 708             if ($task->{status}) {
 709                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
 710             } else {
 711                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
 712             }
 713         } else {
 714             $raw .= "$upid $saved\n";
 715         }
 716     }
 717
 718     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 719 }
 720
 721 register_file('active', "/var/log/pve/tasks/active",
 722               \&read_active_workers,
 723               \&write_active_workers);
 724
 725
 726 our $bond_modes = {
 727     'balance-rr' => 0,
 728     'active-backup' => 1,
 729     'balance-xor' => 2,
 730     'broadcast' => 3,
 731     '802.3ad' => 4,
 732     'balance-tlb' => 5,
 733     'balance-alb' => 6,
 734 };
 735
 736 my $ovs_bond_modes = {
 737     'active-backup' => 1,
 738     'balance-slb' => 1,
 739     'lacp-balance-slb' => 1,
 740     'lacp-balance-tcp' => 1,
 741 };
 742
 743 #sub get_bond_modes {
 744 #    return $bond_modes;
 745 #}
 746
 747 my $parse_ovs_option = sub {
 748     my ($data) = @_;
 749
 750     my $opts = {};
 751     foreach my $kv (split (/\s+/, $data || '')) {
 752         my ($k, $v) = split('=', $kv, 2);
 753         $opts->{$k} = $v if $k && $v;
 754     }
 755     return $opts;
 756 };
 757
 758 my $set_ovs_option = sub {
 759     my ($d, %params) = @_;
 760
 761     my $opts = &$parse_ovs_option($d->{ovs_options});
 762
 763     foreach my $k (keys %params) {
 764         my $v = $params{$k};
 765         if ($v) {
 766             $opts->{$k} = $v;
 767         } else {
 768             delete $opts->{$k};
 769         }
 770     }
 771
 772     my $res = [];
 773     foreach my $k (keys %$opts) {
 774         push @$res, "$k=$opts->{$k}";
 775     }
 776
 777     if (my $new = join(' ', @$res)) {
 778         $d->{ovs_options} = $new;
 779         return $d->{ovs_options};
 780     } else {
 781         delete $d->{ovs_options};
 782         return undef;
 783     }
 784 };
 785
 786 my $extract_ovs_option = sub {
 787     my ($d, $name) = @_;
 788
 789     my $opts = &$parse_ovs_option($d->{ovs_options});
 790
 791     my $v = delete $opts->{$name};
 792
 793     my $res = [];
 794     foreach my $k (keys %$opts) {
 795         push @$res, "$k=$opts->{$k}";
 796     }
 797
 798     if (my $new = join(' ', @$res)) {
 799         $d->{ovs_options} = $new;
 800     } else {
 801         delete $d->{ovs_options};
 802     }
 803
 804     return $v;
 805 };
 806
 807 my $check_mtu = sub {
 808     my ($ifaces, $parent, $child) = @_;
 809
 810     die "check mtu - missing parent interface\n" if !$parent;
 811     die "check mtu - missing child interface\n" if !$child;
 812
 813     my $cmtu = $ifaces->{$child}->{mtu};
 814     return if !$cmtu;
 815
 816     my $parentdata = $ifaces->{$parent};
 817     my $pmtu = $parentdata->{mtu};
 818     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
 819     $pmtu = 1500 if !$pmtu;
 820
 821     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
 822         if $pmtu < $cmtu;
 823 };
 824
 825 # config => {
 826 #   ifaces => {
 827 #     $ifname => {
 828 #       <optional> exists => BOOL,
 829 #       <optional> active => BOOL,
 830 #       <optional> autostart => BOOL,
 831 #       <auto> priority => INT,
 832 #
 833 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
 834 #
 835 #       families => ["inet", "inet6", ...],
 836 #
 837 #       method => "manual" | "static" | "dhcp" | ... ,
 838 #       address => IP,
 839 #       netmask => SUBNET,
 840 #       broadcast => IP,
 841 #       gateway => IP,
 842 #       comments => [ "..." ],
 843 #
 844 #       method6 => "manual" | "static" | "dhcp" | ... ,
 845 #       address6 => IP,
 846 #       netmask6 => SUBNET,
 847 #       gateway6 => IP,
 848 #       comments6 => [ "..." ],
 849 #
 850 #       <known options>, # like bridge_ports, ovs_*
 851 #
 852 #       # extra/unknown options stored by-family:
 853 #       options => { <inet options>... }
 854 #       options6 => { <inet6 options>... }
 855 #     }
 856 #   },
 857 #   options => [
 858 #     # mappings end up here as well, as we don't need to understand them
 859 #     [priority,line]
 860 #   ]
 861 # }
 862 sub read_etc_network_interfaces {
 863     my ($filename, $fh) = @_;
 864     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
 865     my $active = PVE::ProcFSTools::get_active_network_interfaces();
 866     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
 867 }
 868
 869 sub __read_etc_network_interfaces {
 870     my ($fh, $proc_net_dev, $active_ifaces) = @_;
 871
 872     my $config = {};
 873     my $ifaces = $config->{ifaces} = {};
 874     my $options = $config->{options} = [];
 875
 876     my $options_alternatives = {
 877         'ovs_mtu'     => 'mtu',
 878         'bond-slaves' => 'slaves',
 879         'bond_slaves' => 'slaves',
 880         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
 881         'bond-mode' => 'bond_mode',
 882         'bond-miimon' =>'bond_miimon',
 883         'bridge-vlan-aware' => 'bridge_vlan_aware',
 884         'bridge-fd' => 'bridge_fd',
 885         'bridge-stp' => 'bridge_stp',
 886         'bridge-ports' => 'bridge_ports',
 887         'bridge-vids' => 'bridge_vids'
 888     };
 889
 890     my $line;
 891
 892     if ($proc_net_dev) {
 893         while (defined ($line = <$proc_net_dev>)) {
 894             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
 895                 $ifaces->{$1}->{exists} = 1;
 896             }
 897         }
 898         close($proc_net_dev);
 899     }
 900
 901     # we try to keep order inside the file
 902     my $priority = 2; # 1 is reserved for lo
 903
 904     SECTION: while (defined ($line = <$fh>)) {
 905         chomp ($line);
 906         next if $line =~ m/^\s*#/;
 907         next if $line =~ m/^\s*(allow-hotplug)\s+(.*)$/;
 908
 909         if ($line =~ m/^\s*(allow-auto|auto|allow-ovs)\s+(.*)$/) {
 910
 911             $ifaces->{$_}->{autostart} = 1 for split (/\s+/, $2);
 912
 913         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
 914             my $i = $1;
 915             my $family = $2;
 916             my $f = { method => $3 }; # by family, merged to $d with a $suffix
 917             (my $suffix = $family) =~ s/^inet//;
 918
 919             my $d = $ifaces->{$i} ||= {};
 920             $d->{priority} = $priority++ if !$d->{priority};
 921             push @{$d->{families}}, $family;
 922
 923             while (defined ($line = <$fh>)) {
 924                 $line =~ s/\s+$//; # drop trailing whitespaces
 925
 926                 if ($line =~ m/^\s*#(.*?)\s*$/) {
 927                     $f->{comments} = '' if !$f->{comments};
 928                     my $comment = decode('UTF-8', $1);
 929                     $f->{comments} .= "$comment\n";
 930                 } elsif ($line =~ m/^\s*(?:(?:iface|mapping|auto|source|source-directory)\s|allow-)/) {
 931                     last;
 932                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
 933                     my $option = $1;
 934                     my ($id, $value) = ($2, $3);
 935
 936                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
 937
 938                     my $simple_options = {
 939                         'mtu' => 1,
 940                         'ovs_type' => 1,
 941                         'ovs_options' => 1,
 942                         'ovs_bridge' => 1,
 943                         'ovs_bonds' => 1,
 944                         'ovs_ports' => 1,
 945                         'bridge_fd' => 1,
 946                         'bridge_vids' => 1,
 947                         'bridge-access' => 1,
 948                         'bridge-learning' => 1,
 949                         'bridge-arp-nd-suppress' => 1,
 950                         'bridge-unicast-flood' => 1,
 951                         'bridge-multicast-flood' => 1,
 952                         'bond_miimon' => 1,
 953                         'bond_xmit_hash_policy' => 1,
 954                         'bond-primary' => 1,
 955                         'link-type'   => 1,
 956                         'uplink-id' => 1,
 957                         'vlan-protocol' => 1,
 958                         'vlan-raw-device' => 1,
 959                         'vlan-id' => 1,
 960                         'vxlan-id' => 1,
 961                         'vxlan-svcnodeip' => 1,
 962                         'vxlan-physdev' => 1,
 963                         'vxlan-local-tunnelip' => 1,
 964                     };
 965
 966                     if ($id eq 'address' || $id eq 'netmask' || $id eq 'broadcast' || $id eq 'gateway') {
 967                         $f->{$id} = $value;
 968                     } elsif ($simple_options->{$id}) {
 969                         $d->{$id} = $value;
 970                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 971                         my $devs = {};
 972                         foreach my $p (split (/\s+/, $value)) {
 973                             next if $p eq 'none';
 974                             $devs->{$p} = 1;
 975                         }
 976                         my $str = join (' ', sort keys %{$devs});
 977                         if ($d->{$id}) {
 978                             $d->{$id} .= ' ' . $str if $str;
 979                         } else {
 980                             $d->{$id} = $str || '';
 981                         }
 982                     } elsif ($id eq 'bridge_stp') {
 983                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 984                             $d->{$id} = 'on';
 985                         } else {
 986                             $d->{$id} = 'off';
 987                         }
 988                     } elsif ($id eq 'bridge_vlan_aware') {
 989                         $d->{$id} = 1;
 990                     } elsif ($id eq 'bond_mode') {
 991                         # always use names
 992                         foreach my $bm (keys %$bond_modes) {
 993                             if ($bond_modes->{$bm} eq $value) {
 994                                 $value = $bm;
 995                                 last;
 996                             }
 997                         }
 998                         $d->{$id} = $value;
 999                     } elsif ($id eq 'vxlan-remoteip') {
1000                         push @{$d->{$id}}, $value;
1001                     } else {
1002                         push @{$f->{options}}, $option;
1003                     }
1004                 } else {
1005                     last;
1006                 }
1007             }
1008             $d->{"$_$suffix"} = $f->{$_} for keys $f->%*;
1009             last SECTION if !defined($line);
1010             redo SECTION;
1011         } elsif ($line =~ /\w/) {
1012             push @$options, [$priority++, $line];
1013         }
1014     }
1015
1016     foreach my $ifname (@$active_ifaces) {
1017         if (my $iface = $ifaces->{$ifname}) {
1018             $iface->{active} = 1;
1019         }
1020     }
1021
1022     if (!$ifaces->{lo}) {
1023         $ifaces->{lo} = {
1024             priority => 1,
1025             method => 'loopback',
1026             type => 'loopback',
1027             autostart => 1,
1028         };
1029     }
1030
1031     foreach my $iface (keys %$ifaces) {
1032         my $d = $ifaces->{$iface};
1033         $d->{type} = 'unknown';
1034         if ($iface =~ m/^bond\d+$/) {
1035             if (!$d->{ovs_type}) {
1036                 $d->{type} = 'bond';
1037             } elsif ($d->{ovs_type} eq 'OVSBond') {
1038                 $d->{type} = $d->{ovs_type};
1039                 # translate: ovs_options => bond_mode
1040                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
1041                 my $lacp = &$extract_ovs_option($d, 'lacp');
1042                 if ($lacp && $lacp eq 'active') {
1043                     if ($d->{'bond_mode'} eq 'balance-slb') {
1044                         $d->{'bond_mode'} = 'lacp-balance-slb';
1045                     }
1046                 }
1047                 # Note: balance-tcp needs lacp
1048                 if ($d->{'bond_mode'} eq 'balance-tcp') {
1049                     $d->{'bond_mode'} = 'lacp-balance-tcp';
1050                 }
1051                 my $tag = &$extract_ovs_option($d, 'tag');
1052                 $d->{ovs_tag} = $tag if defined($tag);
1053             }
1054         } elsif ($iface =~ m/^vmbr\d+$/) {
1055             if (!$d->{ovs_type}) {
1056                 $d->{type} = 'bridge';
1057                 if (!defined ($d->{bridge_stp})) {
1058                     $d->{bridge_stp} = 'off';
1059                 }
1060                 if (!defined($d->{bridge_fd}) && $d->{bridge_stp} eq 'off') {
1061                     $d->{bridge_fd} = 0;
1062                 }
1063             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1064                 $d->{type} = $d->{ovs_type};
1065             }
1066         } elsif ($iface =~ m/^(\S+):\d+$/) {
1067             $d->{type} = 'alias';
1068             if (defined ($ifaces->{$1})) {
1069                 $d->{exists} = $ifaces->{$1}->{exists};
1070             } else {
1071                 $ifaces->{$1}->{exists} = 0;
1072                 $d->{exists} = 0;
1073             }
1074         } elsif ($iface =~ m/^(\S+)\.(\d+)$/ || $d->{'vlan-raw-device'}) {
1075             $d->{type} = 'vlan';
1076
1077             my ($dev, $id) = ($1, $2);
1078             $d->{'vlan-raw-device'} = $dev if defined($dev) && !$d->{'vlan-raw-device'};
1079
1080             if (!$id && $iface =~ m/^vlan(\d+)$/) { # VLAN id 0 is not valid, so truthy check it is
1081                 $id = $1;
1082             }
1083             $d->{'vlan-id'} = $id if $id;
1084
1085             my $raw_iface = $d->{'vlan-raw-device'};
1086
1087             if (defined ($ifaces->{$raw_iface})) {
1088                 $d->{exists} = $ifaces->{$raw_iface}->{exists};
1089             } else {
1090                 $ifaces->{$raw_iface}->{exists} = 0;
1091                 $d->{exists} = 0;
1092             }
1093         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1094             if (!$d->{ovs_type}) {
1095                 $d->{type} = 'eth';
1096             } elsif ($d->{ovs_type} eq 'OVSPort') {
1097                 $d->{type} = $d->{ovs_type};
1098                 my $tag = &$extract_ovs_option($d, 'tag');
1099                 $d->{ovs_tag} = $tag if defined($tag);
1100             }
1101         } elsif ($iface =~ m/^lo$/) {
1102             $d->{type} = 'loopback';
1103         } else {
1104             if ($d->{'vxlan-id'}) {
1105                 $d->{type} = 'vxlan';
1106             } elsif (defined($d->{ovs_type})) {
1107                 if ($d->{ovs_type} eq 'OVSIntPort') {
1108                     $d->{type} = $d->{ovs_type};
1109                     my $tag = &$extract_ovs_option($d, 'tag');
1110                     $d->{ovs_tag} = $tag if defined($tag);
1111                 }
1112             } elsif (defined($d->{'link-type'})) {
1113                 $d->{type} = $d->{'link-type'} if $d->{'link-type'} eq 'dummy';
1114             }
1115         }
1116
1117         # map address and netmask to cidr
1118         if (my $addr = $d->{address}) {
1119             if (_address_is_cidr($addr)) {
1120                 $d->{cidr} = $addr;
1121                 my ($baseaddr, $mask) = _cidr_split($addr);
1122                 $d->{address} = $baseaddr;
1123                 $d->{netmask} = $mask;
1124             } elsif (my $cidr = _get_cidr($d->{address}, $d->{netmask})) {
1125                 $d->{cidr} = $cidr;
1126                 (undef, $d->{netmask}) = _cidr_split($cidr);
1127             } else {
1128                 # no mask, else we'd got a cidr above
1129                 $d->{cidr} = $addr ."/32";
1130             }
1131         }
1132
1133         # map address6 and netmask6 to cidr6
1134         if (my $addr6 = $d->{address6}) {
1135             if (_address_is_cidr($addr6)) {
1136                 $d->{cidr6} = $addr6;
1137                 my ($baseaddr, $mask) = _cidr_split($addr6);
1138                 $d->{address6} = $baseaddr;
1139                 $d->{netmask6} = $mask;
1140             } elsif (my $cidr6 = _get_cidr($d->{address6}, $d->{netmask6})) {
1141                 $d->{cidr6} = $cidr6;
1142             } else {
1143                 # no mask, else we'd got a cidr above
1144                 $d->{cidr6} = $addr6 ."/128";
1145             }
1146         }
1147
1148         $d->{method} = 'manual' if !$d->{method};
1149         $d->{method6} = 'manual' if !$d->{method6};
1150
1151         if (my $comments6 = delete $d->{comments6}) {
1152             $d->{comments} = ($d->{comments} // '') . $comments6;
1153         }
1154
1155         $d->{families} ||= ['inet'];
1156     }
1157
1158     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1159     # from the {options} hash for them to be removed correctly.
1160     @$options = grep {defined($_)} map {
1161         my ($pri, $line) = @$_;
1162         if ($line =~ /^allow-ovs\s+(.*)$/) {
1163             undef;
1164         } elsif ($line =~ /^allow-(\S+)\s+(.*)$/) {
1165             my $bridge = $1;
1166             my @ports = split(/\s+/, $2);
1167             if (defined(my $br = $ifaces->{$bridge})) {
1168                 # if this port is part of a bridge, remove it
1169                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1170                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1171             }
1172             # create the allow line for the remaining ports, or delete if empty
1173             if (@ports) {
1174                 [$pri, "allow-$bridge " . join(' ', @ports)];
1175             } else {
1176                 undef;
1177             }
1178         } else {
1179             # don't modify other lines
1180             $_;
1181         }
1182     } @$options;
1183
1184     return $config;
1185 }
1186
1187 sub _address_is_cidr {
1188     my ($addr) = @_;
1189     return $addr =~ /\/\d+$/ ? 1 : 0;
1190 }
1191
1192 sub _cidr_split {
1193     my ($cidr) = @_;
1194     $cidr =~ /^(.+)\/(\d+)$/;
1195     return ($1, $2); # (address, mask)
1196 }
1197
1198 sub _get_cidr {
1199     my ($addr, $mask) = @_;
1200
1201     return $addr if _address_is_cidr($addr);
1202     return undef if !$mask;
1203
1204     if ($mask =~ m/^\d+$/) { # cidr notation
1205         return $addr . "/" . $mask;
1206     } elsif (my $cidrmask = PVE::JSONSchema::get_netmask_bits($mask)) {
1207         return $addr . "/" . $cidrmask;
1208     }
1209     return undef;
1210 }
1211
1212 sub __interface_to_string {
1213     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1214
1215     (my $suffix = $family) =~ s/^inet//;
1216
1217     return '' if !($d && $d->{"method$suffix"});
1218
1219     my $raw = "iface $iface $family " . $d->{"method$suffix"} . "\n";
1220
1221     if (my $addr = $d->{"address$suffix"}) {
1222         if ($addr !~ /\/\d+$/ && $d->{"netmask$suffix"}) {
1223             if ($d->{"netmask$suffix"} =~ m/^\d+$/) {
1224                 $addr .= "/" . $d->{"netmask$suffix"};
1225             } elsif (my $mask = PVE::JSONSchema::get_netmask_bits($d->{"netmask$suffix"})) {
1226                 $addr .= "/" . $mask;
1227             }
1228         }
1229         $raw .= "\taddress ${addr}\n";
1230     }
1231
1232     $raw .= "\tgateway " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1233
1234     my $done = {
1235         type => 1, priority => 1, method => 1, active => 1, exists => 1, comments => 1,
1236         autostart => 1, options => 1, address => 1, netmask => 1, gateway => 1, broadcast => 1,
1237         method6 => 1, families => 1, options6 => 1, comments6 => 1, address6 => 1,
1238         netmask6 => 1, gateway6 => 1, broadcast6 => 1, 'uplink-id' => 1,
1239      };
1240
1241     if (!$first_block) {
1242         # not printing out options
1243     } elsif ($d->{type} eq 'bridge') {
1244
1245         my $ports = $d->{bridge_ports} || 'none';
1246         $ports =~ s/[;,\s]+/ /g;
1247         $raw .= "\tbridge-ports $ports\n";
1248         $done->{bridge_ports} = 1;
1249
1250         my $br_stp = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1251         my $no_stp = $br_stp eq 'off';
1252
1253         $raw .= "\tbridge-stp $br_stp\n";
1254         $done->{bridge_stp} = 1;
1255
1256         # NOTE: forwarding delay must be 2 <= FD <= 30 if STP is enabled
1257         if (defined(my $br_fd = $d->{bridge_fd})) {
1258             if ($no_stp || ($br_fd >= 2 && $br_fd <= 30)) {
1259                 $raw .= "\tbridge-fd $br_fd\n";
1260             } else {
1261                 # only complain if the user actually set a value, but not for default fallback below
1262                 warn "'$iface': ignoring 'bridge_fd' value '$br_fd', outside of allowed range 2-30\n";
1263             }
1264         } elsif ($no_stp) {
1265             $raw .= "\tbridge-fd 0\n";
1266         }
1267         $done->{bridge_fd} = 1;
1268
1269         if( defined($d->{bridge_vlan_aware})) {
1270             $raw .= "\tbridge-vlan-aware yes\n";
1271             my $vlans = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1272             $raw .= "\tbridge-vids $vlans\n";
1273         }
1274         $done->{bridge_vlan_aware} = 1;
1275         $done->{bridge_vids} = 1;
1276
1277         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1278         $done->{mtu} = 1;
1279
1280     } elsif ($d->{type} eq 'bond') {
1281
1282         $d->{slaves} =~ s/[;,\s]+/ /g;
1283         my $slaves = $d->{slaves} || 'none';
1284         $raw .= "\tbond-slaves $slaves\n";
1285         $done->{slaves} = 1;
1286
1287         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1288         $raw .= "\tbond-miimon $v\n";
1289         $done->{'bond_miimon'} = 1;
1290
1291         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1292         $raw .= "\tbond-mode $v\n";
1293         $done->{'bond_mode'} = 1;
1294
1295         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1296             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1297             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1298         }
1299         $done->{'bond_xmit_hash_policy'} = 1;
1300
1301         if ($d->{'bond_mode'} && $d->{'bond_mode'} eq 'active-backup' && $d->{'bond-primary'}) {
1302             $raw .= "\tbond-primary $d->{'bond-primary'}\n";
1303         }
1304         $done->{'bond-primary'} = 1;
1305
1306         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1307         $done->{mtu} = 1;
1308
1309     } elsif ($d->{type} eq 'vlan') {
1310         die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n"
1311             if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
1312
1313     } elsif ($d->{type} eq 'vxlan') {
1314
1315         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1316             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1317             $done->{$k} = 1;
1318         }
1319
1320         if ($d->{'vxlan-remoteip'}) {
1321             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1322                 $raw .= "\tvxlan-remoteip $remoteip\n";
1323             }
1324             $done->{'vxlan-remoteip'} = 1;
1325         }
1326
1327         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1328         $done->{mtu} = 1;
1329
1330     } elsif ($d->{type} eq 'OVSBridge') {
1331
1332         $raw .= "\tovs_type $d->{type}\n";
1333         $done->{ovs_type} = 1;
1334
1335         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1336         $done->{ovs_ports} = 1;
1337
1338         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1339         $done->{mtu} = 1;
1340
1341     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' || $d->{type} eq 'OVSBond') {
1342
1343         $d->{autostart} = 0; # started by the bridge
1344
1345         if (defined($d->{ovs_tag})) {
1346             &$set_ovs_option($d, tag => $d->{ovs_tag});
1347         }
1348         $done->{ovs_tag} = 1;
1349
1350         if ($d->{type} eq 'OVSBond') {
1351
1352             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1353
1354             $ovs_bond_modes->{$d->{bond_mode}} ||
1355                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1356
1357             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1358                 &$set_ovs_option($d, lacp => 'active');
1359                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1360             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1361                 &$set_ovs_option($d, lacp => 'active');
1362                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1363             } else {
1364                 &$set_ovs_option($d, lacp => undef);
1365                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1366             }
1367             $done->{bond_mode} = 1;
1368
1369             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1370             $done->{ovs_bonds} = 1;
1371         }
1372
1373         $raw .= "\tovs_type $d->{type}\n";
1374         $done->{ovs_type} = 1;
1375
1376         if (my $bridge = $d->{ovs_bridge}) {
1377             if ($ifupdown2) {
1378                 $raw = "auto $iface\n$raw";
1379             } else {
1380                 $raw = "allow-$bridge $iface\n$raw";
1381             }
1382
1383             $raw .= "\tovs_bridge $bridge\n";
1384             $done->{ovs_bridge} = 1;
1385         }
1386
1387         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1388         $done->{mtu} = 1;
1389     }
1390
1391     if ($first_block) {
1392         # print other settings
1393         foreach my $k (sort keys %$d) {
1394            next if $done->{$k};
1395            next if !$d->{$k};
1396            $raw .= "\t$k $d->{$k}\n";
1397         }
1398     }
1399
1400     foreach my $option (@{$d->{"options$suffix"}}) {
1401         $raw .= "\t$option\n";
1402     }
1403
1404     # add comments
1405     my $comments = $d->{"comments$suffix"} || '';
1406     foreach my $cl (split(/\n/, $comments)) {
1407         $raw .= "#$cl\n";
1408     }
1409
1410     $raw .= "\n";
1411
1412     return $raw;
1413 }
1414
1415
1416 sub write_etc_network_interfaces {
1417     my ($filename, $fh, $config) = @_;
1418     my $ifupdown2 = -e '/usr/share/ifupdown2/ifupdown2';
1419     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1420     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1421 }
1422 sub __write_etc_network_interfaces {
1423     my ($config, $ifupdown2) = @_;
1424
1425     my $ifaces = $config->{ifaces};
1426     my @options = @{$config->{options}};
1427
1428     my $used_ports = {};
1429
1430     foreach my $iface (keys %$ifaces) {
1431         my $d = $ifaces->{$iface};
1432
1433         my ($cidr, $cidr6) = (delete $d->{cidr}, delete $d->{cidr6});
1434         $d->{address} //= $cidr;
1435         $d->{address6} //= $cidr6;
1436
1437         my $ports = '';
1438         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1439             $ports .= " $d->{$k}" if $d->{$k};
1440         }
1441
1442         foreach my $p (PVE::Tools::split_list($ports)) {
1443             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1444                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1445             $used_ports->{$p} = $iface;
1446         }
1447     }
1448
1449     # delete unused OVS ports
1450     foreach my $iface (keys %$ifaces) {
1451         my $d = $ifaces->{$iface};
1452         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' || $d->{type} eq 'OVSBond') {
1453             my $brname = $used_ports->{$iface};
1454             if (!$brname || !$ifaces->{$brname}) {
1455                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1456                     $ifaces->{$iface} = {
1457                         type => 'eth',
1458                         exists => 1,
1459                         method => 'manual',
1460                         families => ['inet'],
1461                     };
1462                 } else {
1463                     delete $ifaces->{$iface};
1464                 }
1465                 next;
1466             }
1467             my $bd = $ifaces->{$brname};
1468             if ($bd->{type} ne 'OVSBridge') {
1469                 delete $ifaces->{$iface};
1470                 next;
1471             }
1472         }
1473     }
1474
1475     # create OVS bridge ports
1476     foreach my $iface (keys %$ifaces) {
1477         my $d = $ifaces->{$iface};
1478         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1479             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1480                 my $n = $ifaces->{$p};
1481                 die "OVS bridge '$iface' - unable to find port '$p'\n" if !$n;
1482                 $n->{autostart} = 0;
1483                 if ($n->{type} eq 'eth') {
1484                     $n->{type} = 'OVSPort';
1485                     $n->{ovs_bridge} = $iface;
1486                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1487                     $n->{type} eq 'OVSIntPort') {
1488                     $n->{ovs_bridge} = $iface;
1489                 } else {
1490                     die "interface '$p' is not defined as OVS port/bond\n";
1491                 }
1492
1493                 &$check_mtu($ifaces, $iface, $p);
1494             }
1495         }
1496     }
1497
1498     # check OVS bond ports
1499     foreach my $iface (keys %$ifaces) {
1500         my $d = $ifaces->{$iface};
1501         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1502             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1503                 my $n = $ifaces->{$p};
1504                 $n->{autostart} = 1;
1505                 die "OVS bond '$iface' - unable to find slave '$p'\n" if !$n;
1506                 die "OVS bond '$iface' - wrong interface type on slave '$p' ('$n->{type}' != 'eth')\n"
1507                     if $n->{type} ne 'eth';
1508                 &$check_mtu($ifaces, $iface, $p);
1509             }
1510         }
1511     }
1512
1513     # check bond
1514     foreach my $iface (keys %$ifaces) {
1515         my $d = $ifaces->{$iface};
1516         next if !($d->{type} eq 'bond' && $d->{slaves});
1517
1518         my $bond_primary_is_slave = undef;
1519         foreach my $p (split (/\s+/, $d->{slaves})) {
1520             my $n = $ifaces->{$p};
1521             $n->{autostart} = 1;
1522
1523             die "bond '$iface' - unable to find slave '$p'\n" if !$n;
1524             die "bond '$iface' - wrong interface type on slave '$p' ('$n->{type}' != 'eth or bond')\n"
1525                 if ($n->{type} ne 'eth' && $n->{type} ne 'bond');
1526
1527             $check_mtu->($ifaces, $iface, $p);
1528             $bond_primary_is_slave = 1 if $d->{'bond-primary'} && $d->{'bond-primary'} eq $p;
1529         }
1530         die "bond '$iface' - bond-primary interface is not a slave" if $d->{'bond-primary'} && !$bond_primary_is_slave;
1531     }
1532
1533     # check vxlan
1534     my $vxlans = {};
1535     foreach my $iface (keys %$ifaces) {
1536         my $d = $ifaces->{$iface};
1537
1538         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1539             my $vxlanid = $d->{'vxlan-id'};
1540             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1541             $vxlans->{$vxlanid} = $iface;
1542         }
1543
1544         my $ips = 0;
1545         ++$ips if defined $d->{'vxlan-svcnodeip'};
1546         ++$ips if defined $d->{'vxlan-remoteip'};
1547         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1548         if ($ips > 1) {
1549             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1550         }
1551
1552         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1553             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1554         }
1555         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1556     }
1557
1558     # check vlan
1559     foreach my $iface (keys %$ifaces) {
1560         my $d = $ifaces->{$iface};
1561         if ($d->{type} eq 'vlan') {
1562
1563             my $p = undef;
1564             my $vlanid = undef;
1565
1566             if ($iface =~ m/^(\S+)\.(\d+)$/) {
1567                 $p = $1;
1568                 $vlanid = $2;
1569                 delete $d->{'vlan-raw-device'} if $d->{'vlan-raw-device'};
1570                 delete $d->{'vlan-id'} if $d->{'vlan-id'};
1571
1572             } else {
1573                 die "missing vlan-raw-device option" if !$d->{'vlan-raw-device'};
1574                 $p = $d->{'vlan-raw-device'};
1575
1576                 if ($iface =~ m/^vlan(\d+)$/) {
1577                     $vlanid = $1;
1578                     delete $d->{'vlan-id'} if $d->{'vlan-id'};
1579                 } else {
1580                     die "custom vlan interface name need ifupdown2" if !$ifupdown2;
1581                     die "missing vlan-id option" if !$d->{'vlan-id'};
1582                     $vlanid = $d->{'vlan-id'};
1583                 }
1584             }
1585             my $n = $ifaces->{$p};
1586
1587             die "vlan '$iface' - vlan-id $vlanid should be <= 4094\n" if $vlanid > 4094;
1588             die "vlan '$iface' - unable to find parent '$p'\n"
1589                 if !$n;
1590
1591             if ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
1592                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1593                     "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
1594             }
1595
1596             &$check_mtu($ifaces, $p, $iface);
1597
1598         }
1599     }
1600
1601     # check uplink
1602     my $uplinks = {};
1603     foreach my $iface (keys %$ifaces) {
1604         my $d = $ifaces->{$iface};
1605         if (my $uplinkid = $d->{'uplink-id'}) {
1606             die "iface '$iface' - uplink-id $uplinkid is only allowed on physical and linux bond interfaces\n"
1607                 if $d->{type} ne 'eth' && $d->{type} ne 'bond';
1608
1609             die "iface '$iface' - uplink-id $uplinkid is already assigned on '$uplinks->{$uplinkid}'\n"
1610                 if $uplinks->{$uplinkid};
1611
1612             $uplinks->{$uplinkid} = $iface;
1613         }
1614     }
1615
1616     # check bridgeport option
1617     my $bridgeports = {};
1618     my $bridges = {};
1619     my $ifaces_copy = { %$ifaces };
1620     foreach my $iface (keys %$ifaces_copy) {
1621         my $d = $ifaces_copy->{$iface};
1622         if ($d->{type} eq 'bridge') {
1623             foreach my $p (split (/\s+/, $d->{bridge_ports} // '')) {
1624                 if($p =~ m/(\S+)\.(\d+)$/) {
1625                     my $vlanparent = $1;
1626                     if (!defined($ifaces_copy->{$p})) {
1627                         $ifaces_copy->{$p}->{type} = 'vlan';
1628                         $ifaces_copy->{$p}->{method} = 'manual';
1629                         $ifaces_copy->{$p}->{method6} = 'manual';
1630                         $ifaces_copy->{$p}->{mtu} = $ifaces_copy->{$vlanparent}->{mtu} if defined($ifaces_copy->{$1}->{mtu});
1631                     }
1632                 }
1633                 my $n = $ifaces_copy->{$p};
1634                 die "bridge '$iface' - unable to find bridge port '$p'\n" if !$n;
1635                 die "iface $p - ip address can't be set on interface if bridged in $iface\n"
1636                     if ($n->{method} && $n->{method} eq 'static' && $n->{address} ne '0.0.0.0') ||
1637                        ($n->{method6} && $n->{method6} eq 'static' && $n->{address6} ne '::');
1638                 &$check_mtu($ifaces_copy, $p, $iface);
1639                 $bridgeports->{$p} = $iface;
1640             }
1641             $bridges->{$iface} = $d;
1642         }
1643     }
1644
1645     foreach my $iface (keys %$ifaces) {
1646         my $d = $ifaces->{$iface};
1647
1648         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1649             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1650                 if $d->{$k} && !$bridgeports->{$iface};
1651         }
1652
1653         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1654             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1655         }
1656     }
1657
1658     my $raw = <<'NETWORKDOC';
1659 # network interface settings; autogenerated
1660 # Please do NOT modify this file directly, unless you know what
1661 # you're doing.
1662 #
1663 # If you want to manage parts of the network configuration manually,
1664 # please utilize the 'source' or 'source-directory' directives to do
1665 # so.
1666 # PVE will preserve these directives, but will NOT read its network
1667 # configuration from sourced files, so do not attempt to move any of
1668 # the PVE managed interfaces into external files!
1669
1670 NETWORKDOC
1671
1672     my $printed = {};
1673
1674     my $if_type_hash = {
1675         loopback => 100000,
1676         dummy => 100000,
1677         eth => 200000,
1678         OVSPort => 200000,
1679         OVSIntPort => 300000,
1680         OVSBond => 400000,
1681         bond => 400000,
1682         bridge => 500000,
1683         OVSBridge => 500000,
1684         vlan => 600000,
1685         vxlan => 600000,
1686    };
1687
1688     my $lookup_type_prio = sub {
1689         my ($iface, $ifaces) = @_;
1690
1691         my ($rootiface, @rest) = split(/[.:]/, $iface);
1692         my $childlevel = scalar(@rest);
1693         my $type = $ifaces->{$rootiface}->{type};
1694         return if !$type || $type eq 'unknown';
1695
1696         return $if_type_hash->{$type} + $childlevel
1697     };
1698
1699     foreach my $iface (sort {
1700         my $ref1 = $ifaces->{$a};
1701         my $ref2 = $ifaces->{$b};
1702         my $tp1 = &$lookup_type_prio($a, $ifaces);
1703         my $tp2 = &$lookup_type_prio($b, $ifaces);
1704
1705         # Only recognized types are in relation to each other. If one type
1706         # is unknown then only consider the interfaces' priority attributes.
1707         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1708
1709         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1710         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1711
1712         return $p1 <=> $p2 if $p1 != $p2;
1713
1714         return $a cmp $b;
1715     } keys %$ifaces) {
1716         next if $printed->{$iface};
1717         my $d = $ifaces->{$iface};
1718         my $pri = $d->{priority} // 0;
1719         if (@options && $options[0]->[0] < $pri) {
1720             do {
1721                 $raw .= (shift @options)->[1] . "\n";
1722             } while (@options && $options[0]->[0] < $pri);
1723             $raw .= "\n";
1724         }
1725
1726         $printed->{$iface} = 1;
1727         if ($d->{autostart}) {
1728             if ($d->{type} eq 'OVSBridge' && !$ifupdown2) {
1729                 # cannot use 'auto' for OVS, would add race with systemd ifup@.service
1730                 $raw .= "allow-ovs $iface\n";
1731             } else {
1732                 $raw .= "auto $iface\n";
1733             }
1734         }
1735
1736         # if 'inet6' is the only family
1737         if (scalar($d->{families}->@*) == 1 && $d->{families}[0] eq 'inet6') {
1738             $d->{comments6} = delete $d->{comments};
1739         }
1740
1741         my $i = 0; # some options should be printed only once
1742         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1743     }
1744
1745     $raw .= $_->[1] . "\n" foreach @options;
1746     return $raw;
1747 }
1748
1749 register_file('interfaces', "/etc/network/interfaces",
1750               \&read_etc_network_interfaces,
1751               \&write_etc_network_interfaces);
1752
1753
1754 sub read_iscsi_initiatorname {
1755     my ($filename, $fd) = @_;
1756
1757     while (defined(my $line = <$fd>)) {
1758         if ($line =~ m/^InitiatorName=(\S+)$/) {
1759             return $1;
1760         }
1761     }
1762
1763     return 'undefined';
1764 }
1765
1766 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1767               \&read_iscsi_initiatorname);
1768
1769 sub read_apt_auth {
1770     my ($filename, $fd) = @_;
1771
1772     local $/;
1773
1774     my $raw = defined($fd) ? <$fd> : '';
1775
1776     $raw =~ s/^\s+//;
1777
1778
1779     my @tokens = split(/\s+/, $raw);
1780
1781     my $data = {};
1782
1783     my $machine;
1784     while (defined(my $tok = shift @tokens)) {
1785
1786         $machine = shift @tokens if $tok eq 'machine';
1787         next if !$machine;
1788         $data->{$machine} = {} if !$data->{$machine};
1789
1790         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1791         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1792     };
1793
1794     return $data;
1795 }
1796
1797 my $format_apt_auth_data = sub {
1798     my $data = shift;
1799
1800     my $raw = '';
1801
1802     # sort longer entries first, so machine definitions with higher granularity are preferred
1803     for my $machine (sort { length($b) <=> length($a) || $a cmp $b} keys %$data) {
1804         my $d = $data->{$machine};
1805         next if !defined($d); # allow "deleting" set entries
1806
1807         $raw .= "machine $machine\n";
1808         $raw .= " login $d->{login}\n" if $d->{login};
1809         $raw .= " password $d->{password}\n" if $d->{password};
1810         $raw .= "\n";
1811     }
1812
1813     return $raw;
1814 };
1815
1816 sub write_apt_auth {
1817     my ($filename, $fh, $data) = @_;
1818
1819     my $raw = $format_apt_auth_data->($data);
1820
1821     die "write failed: $!" unless print $fh "$raw\n";
1822
1823     return $data;
1824 }
1825
1826 sub update_apt_auth {
1827     my ($filename, $fh, $data) = @_;
1828
1829     my $orig = read_apt_auth($filename, $fh);
1830
1831     foreach my $machine (keys %$data) {
1832         $orig->{$machine} = $data->{$machine};
1833     }
1834
1835     return $format_apt_auth_data->($orig);
1836 }
1837
1838 register_file(
1839     'apt-auth',
1840     "/etc/apt/auth.conf",
1841     \&read_apt_auth,
1842     \&write_apt_auth,
1843     \&update_apt_auth,
1844     perm => 0640,
1845 );
1846
1847 1;