src/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4 use strict;
   5 use warnings;
   6
   7 use Clone qw(clone);
   8 use Digest::SHA;
   9 use Encode qw(encode decode);
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::stat;
  13 use IO::Dir;
  14 use IO::File;
  15 use JSON;
  16 use Linux::Inotify2;
  17 use POSIX;
  18
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::JSONSchema;
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools;
  25
  26 use base 'Exporter';
  27
  28 our @EXPORT_OK = qw(read_file write_file register_file);
  29
  30 my $ccache;
  31 my $ccachemap;
  32 my $ccacheregex;
  33 my $inotify;
  34 my $inotify_pid = 0;
  35 my $versions;
  36 my $shadowfiles = {
  37     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  38 };
  39
  40 # to enable cached operation, you need to call 'inotify_init'
  41 # inotify handles are a limited resource, so use with care (only
  42 # enable the cache if you really need it)
  43
  44 # Note: please close the inotify handle after you fork
  45
  46 sub ccache_default_writer {
  47     my ($filename, $data) = @_;
  48
  49     die "undefined config writer for '$filename' :ERROR";
  50 }
  51
  52 sub ccache_default_parser {
  53     my ($filename, $srcfd) = @_;
  54
  55     die "undefined config reader for '$filename' :ERROR";
  56 }
  57
  58 sub ccache_compute_diff {
  59     my ($filename, $shadow) = @_;
  60
  61     my $diff = '';
  62
  63     my $cmd = ['/usr/bin/diff', '-b', '-N', '-u', $filename, $shadow];
  64     PVE::Tools::run_command($cmd, noerr => 1, outfunc => sub {
  65         my ($line) = @_;
  66         $diff .= decode('UTF-8', $line) . "\n";
  67     });
  68
  69     $diff = undef if !$diff;
  70
  71     return $diff;
  72 }
  73
  74 sub ccache_info {
  75     my ($filename) = @_;
  76
  77     foreach my $uid (keys %$ccacheregex) {
  78         my $ccinfo = $ccacheregex->{$uid};
  79         my $dir = $ccinfo->{dir};
  80         my $regex = $ccinfo->{regex};
  81         if ($filename =~ m|^$dir/+$regex$|) {
  82             if (!$ccache->{$filename}) {
  83                 my $cp = {};
  84                 while (my ($k, $v) = each %$ccinfo) {
  85                     $cp->{$k} = $v;
  86                 }
  87                 $ccache->{$filename} = $cp;
  88             }
  89             return ($ccache->{$filename}, $filename);
  90         }
  91     }
  92
  93     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  94
  95     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  96
  97     return ($ccache->{$filename}, $filename);
  98 }
  99
 100 sub write_file {
 101     my ($fileid, $data, $full) = @_;
 102
 103     my ($ccinfo, $filename) = ccache_info($fileid);
 104
 105     my $writer = $ccinfo->{writer};
 106
 107     my $realname = $filename;
 108
 109     my $shadow;
 110     if ($shadow = $shadowfiles->{$filename}) {
 111         $realname = $shadow;
 112     }
 113
 114     my $perm = $ccinfo->{perm} || 0644;
 115
 116     my $tmpname = "$realname.tmp.$$";
 117
 118     my $res;
 119     eval {
 120         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 121         die "unable to open file '$tmpname' - $!\n" if !$fh;
 122
 123         $res = &$writer($filename, $fh, $data);
 124
 125         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 126     };
 127     my $err = $@;
 128
 129     $ccinfo->{version} = undef;
 130
 131     if ($err) {
 132         unlink $tmpname;
 133         die $err;
 134     }
 135
 136     if (!rename($tmpname, $realname)) {
 137         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 138         unlink $tmpname;
 139         die $msg;
 140     }
 141
 142     my $diff;
 143     if ($shadow && $full) {
 144         $diff = ccache_compute_diff ($filename, $shadow);
 145     }
 146
 147     if ($full) {
 148         return { data => $res, changes => $diff };
 149     }
 150
 151     return $res;
 152 }
 153
 154 sub update_file {
 155     my ($fileid, $data, @args) = @_;
 156
 157     my ($ccinfo, $filename) = ccache_info($fileid);
 158
 159     my $update = $ccinfo->{update};
 160
 161     die "unable to update/merge data" if !$update;
 162
 163     my $lkfn = "$filename.lock";
 164
 165     my $timeout = 10;
 166
 167     my $fd;
 168
 169     my $code = sub {
 170
 171         $fd = IO::File->new ($filename, "r");
 172
 173         my $new = &$update($filename, $fd, $data, @args);
 174
 175         if (defined($new)) {
 176             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 177         } else {
 178             unlink $filename;
 179         }
 180     };
 181
 182     PVE::Tools::lock_file($lkfn, $timeout, $code);
 183     my $err = $@;
 184
 185     close($fd) if defined($fd);
 186
 187     die $err if $err;
 188
 189     return undef;
 190 }
 191
 192 sub discard_changes {
 193     my ($fileid, $full) = @_;
 194
 195     my ($ccinfo, $filename) = ccache_info($fileid);
 196
 197     if (my $copy = $shadowfiles->{$filename}) {
 198         unlink $copy;
 199     }
 200
 201     return read_file ($filename, $full);
 202 }
 203
 204 sub poll_changes {
 205     my ($filename) = @_;
 206
 207     poll() if $inotify; # read new inotify events
 208
 209     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 210
 211     return $versions->{$filename};
 212 }
 213
 214 sub read_file {
 215     my ($fileid, $full) = @_;
 216
 217     my $parser;
 218
 219     my ($ccinfo, $filename) = ccache_info($fileid);
 220
 221     $parser = $ccinfo->{parser};
 222
 223     my $fd;
 224     my $shadow;
 225
 226     my $cver = poll_changes($filename);
 227
 228     if (my $copy = $shadowfiles->{$filename}) {
 229         if ($fd = IO::File->new ($copy, "r")) {
 230             $shadow = $copy;
 231         } else {
 232             $fd = IO::File->new ($filename, "r");
 233         }
 234     } else {
 235         $fd = IO::File->new ($filename, "r");
 236     }
 237
 238     my $acp = $ccinfo->{always_call_parser};
 239
 240     if (!$fd) {
 241         $ccinfo->{version} = undef;
 242         $ccinfo->{data} = undef;
 243         $ccinfo->{diff} = undef;
 244         return undef if !$acp;
 245     }
 246
 247     my $noclone = $ccinfo->{noclone};
 248
 249     # file unchanged?
 250     if (!$ccinfo->{nocache} &&
 251         $inotify && $cver &&
 252         defined ($ccinfo->{data}) &&
 253         defined ($ccinfo->{version}) &&
 254         ($ccinfo->{readonce} ||
 255          ($ccinfo->{version} == $cver))) {
 256
 257         my $ret;
 258         if (!$noclone && ref ($ccinfo->{data})) {
 259             $ret->{data} = clone ($ccinfo->{data});
 260         } else {
 261             $ret->{data} = $ccinfo->{data};
 262         }
 263         $ret->{changes} = $ccinfo->{diff};
 264
 265         return $full ? $ret : $ret->{data};
 266     }
 267
 268     my $diff;
 269
 270     if ($shadow) {
 271         $diff = ccache_compute_diff ($filename, $shadow);
 272     }
 273
 274     my $res = &$parser($filename, $fd);
 275
 276     if (!$ccinfo->{nocache}) {
 277         $ccinfo->{version} = $cver;
 278     }
 279
 280     # we cache data with references, so we always need to
 281     # clone this data. Else the original data may get
 282     # modified.
 283     $ccinfo->{data} = $res;
 284
 285     # also store diff
 286     $ccinfo->{diff} = $diff;
 287
 288     my $ret;
 289     if (!$noclone && ref ($ccinfo->{data})) {
 290         $ret->{data} = clone ($ccinfo->{data});
 291     } else {
 292         $ret->{data} = $ccinfo->{data};
 293     }
 294     $ret->{changes} = $ccinfo->{diff};
 295
 296     return $full ? $ret : $ret->{data};
 297 }
 298
 299 sub parse_ccache_options {
 300     my ($ccinfo, %options) = @_;
 301
 302     foreach my $opt (keys %options) {
 303         my $v = $options{$opt};
 304         if ($opt eq 'readonce') {
 305             $ccinfo->{$opt} = $v;
 306         } elsif ($opt eq 'nocache') {
 307             $ccinfo->{$opt} = $v;
 308         } elsif ($opt eq 'shadow') {
 309             $ccinfo->{$opt} = $v;
 310         } elsif ($opt eq 'perm') {
 311             $ccinfo->{$opt} = $v;
 312         } elsif ($opt eq 'noclone') {
 313             # noclone flag for large read-only data chunks like aplinfo
 314             $ccinfo->{$opt} = $v;
 315         } elsif ($opt eq 'always_call_parser') {
 316             # when set, we call parser even when the file does not exist.
 317             # this allows the parser to return some default
 318             $ccinfo->{$opt} = $v;
 319         } else {
 320             die "internal error - unsupported option '$opt'";
 321         }
 322     }
 323 }
 324
 325 sub register_file {
 326     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 327
 328     die "can't register file '$filename' after inotify_init" if $inotify;
 329
 330     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 331     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 332
 333     my $ccinfo = {};
 334
 335     $ccinfo->{id} = $id;
 336     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 337     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 338     $ccinfo->{update} = $update;
 339
 340     parse_ccache_options($ccinfo, %options);
 341
 342     if ($options{shadow}) {
 343         $shadowfiles->{$filename} = $options{shadow};
 344     }
 345
 346     $ccachemap->{$id} = $filename;
 347     $ccache->{$filename} = $ccinfo;
 348 }
 349
 350 sub register_regex {
 351     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 352
 353     die "can't register regex after inotify_init" if $inotify;
 354
 355     my $uid = "$dir/$regex";
 356     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 357
 358     my $ccinfo = {};
 359
 360     $ccinfo->{dir} = $dir;
 361     $ccinfo->{regex} = $regex;
 362     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 363     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 364     $ccinfo->{update} = $update;
 365
 366     parse_ccache_options($ccinfo, %options);
 367
 368     $ccacheregex->{$uid} = $ccinfo;
 369 }
 370
 371 sub poll {
 372     return if !$inotify;
 373
 374     if ($inotify_pid != $$) {
 375         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 376         $inotify = undef;
 377     } else {
 378         1 while $inotify && $inotify->poll;
 379     }
 380 }
 381
 382 sub flushcache {
 383     foreach my $filename (keys %$ccache) {
 384         $ccache->{$filename}->{version} = undef;
 385         $ccache->{$filename}->{data} = undef;
 386         $ccache->{$filename}->{diff} = undef;
 387     }
 388 }
 389
 390 sub inotify_close {
 391     $inotify = undef;
 392 }
 393
 394 sub inotify_init {
 395
 396     die "only one inotify instance allowed" if $inotify;
 397
 398     $inotify =  Linux::Inotify2->new()
 399         || die "Unable to create new inotify object: $!";
 400
 401     $inotify->blocking (0);
 402
 403     $versions = {};
 404
 405     my $dirhash = {};
 406     foreach my $fn (keys %$ccache) {
 407         my $dir = dirname ($fn);
 408         my $base = basename ($fn);
 409
 410         $dirhash->{$dir}->{$base} = $fn;
 411
 412         if (my $sf = $shadowfiles->{$fn}) {
 413             $base = basename ($sf);
 414             $dir = dirname ($sf);
 415             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 416         }
 417     }
 418
 419     foreach my $uid (keys %$ccacheregex) {
 420         my $ccinfo = $ccacheregex->{$uid};
 421         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 422     }
 423
 424     $inotify_pid = $$;
 425
 426     foreach my $dir (keys %$dirhash) {
 427
 428         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 429         $inotify->watch ($dir, $evlist, sub {
 430             my $e = shift;
 431             my $name = $e->name;
 432
 433             if ($inotify_pid != $$) {
 434                 syslog ('err', "got inotify event in wrong process");
 435             }
 436
 437             if ($e->IN_ISDIR || !$name) {
 438                 return;
 439             }
 440
 441             if ($e->IN_Q_OVERFLOW) {
 442                 syslog ('info', "got inotify overflow - flushing cache");
 443                 flushcache();
 444                 return;
 445             }
 446
 447             if ($e->IN_UNMOUNT) {
 448                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 449                 $inotify = undef;
 450             }
 451             if ($e->IN_IGNORED) {
 452                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 453                 $inotify = undef;
 454             }
 455
 456             if ($dirhash->{$dir}->{_regex}) {
 457                 foreach my $uid (keys %$ccacheregex) {
 458                     my $ccinfo = $ccacheregex->{$uid};
 459                     next if $dir ne $ccinfo->{dir};
 460                     my $regex = $ccinfo->{regex};
 461                     if ($regex && ($name =~ m|^$regex$|)) {
 462
 463                         my $fn = "$dir/$name";
 464                         $versions->{$fn}++;
 465                         #print "VERSION:$fn:$versions->{$fn}\n";
 466                     }
 467                 }
 468             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 469
 470                 $versions->{$fn}++;
 471                 #print "VERSION:$fn:$versions->{$fn}\n";
 472             }
 473         });
 474     }
 475
 476     foreach my $dir (keys %$dirhash) {
 477         foreach my $name (keys %{$dirhash->{$dir}}) {
 478             if ($name eq '_regex') {
 479                 foreach my $uid (keys %$ccacheregex) {
 480                     my $ccinfo = $ccacheregex->{$uid};
 481                     next if $dir ne $ccinfo->{dir};
 482                     my $re = $ccinfo->{regex};
 483                     if (my $fd = IO::Dir->new ($dir)) {
 484                         while (defined(my $de = $fd->read)) {
 485                             if ($de =~ m/^$re$/) {
 486                                 my $fn = "$dir/$de";
 487                                 $versions->{$fn}++; # init with version
 488                                 #print "init:$fn:$versions->{$fn}\n";
 489                             }
 490                         }
 491                     }
 492                 }
 493             } else {
 494                 my $fn = $dirhash->{$dir}->{$name};
 495                 $versions->{$fn}++; # init with version
 496                 #print "init:$fn:$versions->{$fn}\n";
 497             }
 498         }
 499     }
 500 }
 501
 502 my $cached_nodename;
 503
 504 sub nodename {
 505
 506     return $cached_nodename if $cached_nodename;
 507
 508     my ($sysname, $nodename) = POSIX::uname();
 509
 510     $nodename =~ s/\..*$//; # strip domain part, if any
 511
 512     die "unable to read node name\n" if !$nodename;
 513
 514     $cached_nodename = $nodename;
 515
 516     return $cached_nodename;
 517 }
 518
 519 sub read_etc_hostname {
 520     my ($filename, $fd) = @_;
 521
 522     my $hostname = <$fd>;
 523
 524     chomp $hostname;
 525
 526     $hostname =~ s/\..*$//; # strip domain part, if any
 527
 528     return $hostname;
 529 }
 530
 531 sub write_etc_hostname {
 532     my ($filename, $fh, $hostname) = @_;
 533
 534     die "write failed: $!" unless print $fh "$hostname\n";
 535
 536     return $hostname;
 537 }
 538
 539 register_file('hostname', "/etc/hostname",
 540               \&read_etc_hostname,
 541               \&write_etc_hostname);
 542
 543 sub read_etc_hosts {
 544     my ($filename, $fh) = @_;
 545
 546     my $raw = '';
 547     my $data = '';
 548
 549     while (my $line = <$fh>) {
 550         $raw .= $line;
 551         if ($line =~ m/^\s*#/) {
 552             $line = decode('UTF-8', $line);
 553         }
 554         $data .= $line;
 555     }
 556
 557     return {
 558         digest => Digest::SHA::sha1_hex($raw),
 559         data => $data,
 560     }
 561 }
 562
 563 sub write_etc_hosts {
 564     my ($filename, $fh, $hosts, @args) = @_;
 565
 566     # check validity of ips/names
 567     for my $line (split("\n", $hosts)) {
 568         next if $line =~ m/^\s*#/; # comments
 569         next if $line =~ m/^\s*$/; # whitespace/empty lines
 570
 571         my ($ip, @names) = split(/\s+/, $line);
 572
 573         raise_param_exc({ 'data' => "Invalid IP '$ip'" })
 574             if $ip !~ m/^$PVE::Tools::IPRE$/;
 575
 576         for my $name (@names) {
 577             raise_param_exc({ 'data' => "Invalid Hostname '$name'" })
 578                 if $name !~ m/^[.\-a-zA-Z0-9]+$/;
 579         }
 580     }
 581
 582     die "write failed: $!" if !print $fh encode('UTF-8', $hosts);
 583
 584     return $hosts;
 585 }
 586
 587 register_file('etchosts', "/etc/hosts",
 588               \&read_etc_hosts,
 589               \&write_etc_hosts);
 590
 591 sub read_etc_resolv_conf {
 592     my ($filename, $fh) = @_;
 593
 594     my $res = {};
 595
 596     my $nscount = 0;
 597     while (my $line = <$fh>) {
 598         chomp $line;
 599         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 600             $res->{search} = $2;
 601         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
 602             $nscount++;
 603             if ($nscount <= 3) {
 604                 $res->{"dns$nscount"} = $1;
 605             }
 606         }
 607     }
 608
 609     return $res;
 610 }
 611
 612 sub update_etc_resolv_conf {
 613     my ($filename, $fh, $resolv, @args) = @_;
 614
 615     my $data = "";
 616
 617     $data = "search $resolv->{search}\n"
 618         if $resolv->{search};
 619
 620     my $written = {};
 621     foreach my $k ("dns1", "dns2", "dns3") {
 622         my $ns = $resolv->{$k};
 623         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 624             $written->{$ns} = 1;
 625             $data .= "nameserver $ns\n";
 626         }
 627     }
 628
 629     while (my $line = <$fh>) {
 630         next if $line =~ m/^(search|domain|nameserver)\s+/;
 631         $data .= $line
 632     }
 633
 634     return $data;
 635 }
 636
 637 register_file('resolvconf', "/etc/resolv.conf",
 638               \&read_etc_resolv_conf, undef,
 639               \&update_etc_resolv_conf);
 640
 641 sub read_etc_timezone {
 642     my ($filename, $fd) = @_;
 643
 644     my $timezone = <$fd>;
 645
 646     chomp $timezone;
 647
 648     return $timezone;
 649 }
 650
 651 sub write_etc_timezone {
 652     my ($filename, $fh, $timezone) = @_;
 653
 654     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 655
 656     raise_param_exc({ 'timezone' => "No such timezone" })
 657         if (! -f $tzinfo);
 658
 659     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 660
 661     print $fh "$timezone\n";
 662
 663     unlink ("/etc/localtime");
 664     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 665
 666 }
 667
 668 register_file('timezone', "/etc/timezone",
 669               \&read_etc_timezone,
 670               \&write_etc_timezone);
 671
 672 sub read_active_workers {
 673     my ($filename, $fh) = @_;
 674
 675     return [] if !$fh;
 676
 677     my $res = [];
 678     while (defined (my $line = <$fh>)) {
 679         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 680             my $upid = $1;
 681             my $saved = $2;
 682             my $endtime = $4;
 683             my $status = $6;
 684             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 685                 $task->{upid} = $upid;
 686                 $task->{saved} = $saved;
 687                 $task->{endtime} = hex($endtime) if $endtime;
 688                 $task->{status} = $status if $status;
 689                 push @$res, $task;
 690             }
 691         } else {
 692             warn "unable to parse line: $line";
 693         }
 694     }
 695
 696     return $res;
 697
 698 }
 699
 700 sub write_active_workers {
 701     my ($filename, $fh, $tasklist) = @_;
 702
 703     my $raw = '';
 704     foreach my $task (@$tasklist) {
 705         my $upid = $task->{upid};
 706         my $saved = $task->{saved} ? 1 : 0;
 707         if ($task->{endtime}) {
 708             if ($task->{status}) {
 709                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
 710             } else {
 711                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
 712             }
 713         } else {
 714             $raw .= "$upid $saved\n";
 715         }
 716     }
 717
 718     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 719 }
 720
 721 register_file('active', "/var/log/pve/tasks/active",
 722               \&read_active_workers,
 723               \&write_active_workers);
 724
 725
 726 our $bond_modes = {
 727     'balance-rr' => 0,
 728     'active-backup' => 1,
 729     'balance-xor' => 2,
 730     'broadcast' => 3,
 731     '802.3ad' => 4,
 732     'balance-tlb' => 5,
 733     'balance-alb' => 6,
 734 };
 735
 736 my $ovs_bond_modes = {
 737     'active-backup' => 1,
 738     'balance-slb' => 1,
 739     'lacp-balance-slb' => 1,
 740     'lacp-balance-tcp' => 1,
 741 };
 742
 743 #sub get_bond_modes {
 744 #    return $bond_modes;
 745 #}
 746
 747 my $parse_ovs_option = sub {
 748     my ($data) = @_;
 749
 750     my $opts = {};
 751     foreach my $kv (split (/\s+/, $data || '')) {
 752         my ($k, $v) = split('=', $kv, 2);
 753         $opts->{$k} = $v if $k && $v;
 754     }
 755     return $opts;
 756 };
 757
 758 my $set_ovs_option = sub {
 759     my ($d, %params) = @_;
 760
 761     my $opts = &$parse_ovs_option($d->{ovs_options});
 762
 763     foreach my $k (keys %params) {
 764         my $v = $params{$k};
 765         if ($v) {
 766             $opts->{$k} = $v;
 767         } else {
 768             delete $opts->{$k};
 769         }
 770     }
 771
 772     my $res = [];
 773     foreach my $k (keys %$opts) {
 774         push @$res, "$k=$opts->{$k}";
 775     }
 776
 777     if (my $new = join(' ', @$res)) {
 778         $d->{ovs_options} = $new;
 779         return $d->{ovs_options};
 780     } else {
 781         delete $d->{ovs_options};
 782         return undef;
 783     }
 784 };
 785
 786 my $extract_ovs_option = sub {
 787     my ($d, $name) = @_;
 788
 789     my $opts = &$parse_ovs_option($d->{ovs_options});
 790
 791     my $v = delete $opts->{$name};
 792
 793     my $res = [];
 794     foreach my $k (keys %$opts) {
 795         push @$res, "$k=$opts->{$k}";
 796     }
 797
 798     if (my $new = join(' ', @$res)) {
 799         $d->{ovs_options} = $new;
 800     } else {
 801         delete $d->{ovs_options};
 802     }
 803
 804     return $v;
 805 };
 806
 807 my $check_mtu = sub {
 808     my ($ifaces, $parent, $child) = @_;
 809
 810     die "check mtu - missing parent interface\n" if !$parent;
 811     die "check mtu - missing child interface\n" if !$child;
 812
 813     my $cmtu = $ifaces->{$child}->{mtu};
 814     return if !$cmtu;
 815
 816     my $parentdata = $ifaces->{$parent};
 817     my $pmtu = $parentdata->{mtu};
 818     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
 819     $pmtu = 1500 if !$pmtu;
 820
 821     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
 822         if $pmtu < $cmtu;
 823 };
 824
 825 # config => {
 826 #   ifaces => {
 827 #     $ifname => {
 828 #       <optional> exists => BOOL,
 829 #       <optional> active => BOOL,
 830 #       <optional> autostart => BOOL,
 831 #       <auto> priority => INT,
 832 #
 833 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
 834 #
 835 #       families => ["inet", "inet6", ...],
 836 #
 837 #       method => "manual" | "static" | "dhcp" | ... ,
 838 #       address => IP,
 839 #       netmask => SUBNET,
 840 #       broadcast => IP,
 841 #       gateway => IP,
 842 #       comments => [ "..." ],
 843 #
 844 #       method6 => "manual" | "static" | "dhcp" | ... ,
 845 #       address6 => IP,
 846 #       netmask6 => SUBNET,
 847 #       gateway6 => IP,
 848 #       comments6 => [ "..." ],
 849 #
 850 #       <known options>, # like bridge_ports, ovs_*
 851 #
 852 #       # extra/unknown options stored by-family:
 853 #       options => { <inet options>... }
 854 #       options6 => { <inet6 options>... }
 855 #     }
 856 #   },
 857 #   options => [
 858 #     # mappings end up here as well, as we don't need to understand them
 859 #     [priority,line]
 860 #   ]
 861 # }
 862 sub read_etc_network_interfaces {
 863     my ($filename, $fh) = @_;
 864     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
 865     my $active = PVE::ProcFSTools::get_active_network_interfaces();
 866     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
 867 }
 868
 869 sub __read_etc_network_interfaces {
 870     my ($fh, $proc_net_dev, $active_ifaces) = @_;
 871
 872     my $config = {};
 873     my $ifaces = $config->{ifaces} = {};
 874     my $options = $config->{options} = [];
 875
 876     my $options_alternatives = {
 877         'ovs_mtu'     => 'mtu',
 878         'bond-slaves' => 'slaves',
 879         'bond_slaves' => 'slaves',
 880         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
 881         'bond-mode' => 'bond_mode',
 882         'bond-miimon' =>'bond_miimon',
 883         'bridge-vlan-aware' => 'bridge_vlan_aware',
 884         'bridge-fd' => 'bridge_fd',
 885         'bridge-stp' => 'bridge_stp',
 886         'bridge-ports' => 'bridge_ports',
 887         'bridge-vids' => 'bridge_vids'
 888     };
 889
 890     my $line;
 891
 892     if ($proc_net_dev) {
 893         while (defined ($line = <$proc_net_dev>)) {
 894             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
 895                 $ifaces->{$1}->{exists} = 1;
 896             }
 897         }
 898         close($proc_net_dev);
 899     }
 900
 901     # we try to keep order inside the file
 902     my $priority = 2; # 1 is reserved for lo
 903
 904     SECTION: while (defined ($line = <$fh>)) {
 905         chomp ($line);
 906         next if $line =~ m/^\s*#/;
 907         next if $line =~ m/^\s*(allow-hotplug)\s+(.*)$/;
 908
 909         if ($line =~ m/^\s*(auto|allow-ovs)\s+(.*)$/) {
 910             my @aa = split (/\s+/, $2);
 911
 912             foreach my $a (@aa) {
 913                 $ifaces->{$a}->{autostart} = 1;
 914             }
 915
 916         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
 917             my $i = $1;
 918             my $family = $2;
 919             my $f = { method => $3 }; # by family, merged to $d with a $suffix
 920             (my $suffix = $family) =~ s/^inet//;
 921
 922             my $d = $ifaces->{$i} ||= {};
 923             $d->{priority} = $priority++ if !$d->{priority};
 924             push @{$d->{families}}, $family;
 925
 926             while (defined ($line = <$fh>)) {
 927                 $line =~ s/\s+$//; # drop trailing whitespaces
 928
 929                 if ($line =~ m/^\s*#(.*?)\s*$/) {
 930                     $f->{comments} = '' if !$f->{comments};
 931                     my $comment = decode('UTF-8', $1);
 932                     $f->{comments} .= "$comment\n";
 933                 } elsif ($line =~ m/^\s*(?:iface\s
 934                                           |mapping\s
 935                                           |auto\s
 936                                           |allow-
 937                                           |source\s
 938                                           |source-directory\s
 939                                         )/x) {
 940                     last;
 941                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
 942                     my $option = $1;
 943                     my ($id, $value) = ($2, $3);
 944
 945                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
 946
 947                     my $simple_options = {
 948                         'mtu' => 1,
 949                         'ovs_type' => 1,
 950                         'ovs_options' => 1,
 951                         'ovs_bridge' => 1,
 952                         'ovs_bonds' => 1,
 953                         'ovs_ports' => 1,
 954                         'bridge_fd' => 1,
 955                         'bridge_vids' => 1,
 956                         'bridge-access' => 1,
 957                         'bridge-learning' => 1,
 958                         'bridge-arp-nd-suppress' => 1,
 959                         'bridge-unicast-flood' => 1,
 960                         'bridge-multicast-flood' => 1,
 961                         'bond_miimon' => 1,
 962                         'bond_xmit_hash_policy' => 1,
 963                         'bond-primary' => 1,
 964                         'link-type'   => 1,
 965                         'uplink-id' => 1,
 966                         'vlan-protocol' => 1,
 967                         'vlan-raw-device' => 1,
 968                         'vlan-id' => 1,
 969                         'vxlan-id' => 1,
 970                         'vxlan-svcnodeip' => 1,
 971                         'vxlan-physdev' => 1,
 972                         'vxlan-local-tunnelip' => 1 };
 973
 974                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
 975                         $f->{$id} = $value;
 976                     } elsif ($simple_options->{$id}) {
 977                         $d->{$id} = $value;
 978                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 979                         my $devs = {};
 980                         foreach my $p (split (/\s+/, $value)) {
 981                             next if $p eq 'none';
 982                             $devs->{$p} = 1;
 983                         }
 984                         my $str = join (' ', sort keys %{$devs});
 985                         if ($d->{$id}) {
 986                             $d->{$id} .= ' ' . $str if $str;
 987                         } else {
 988                             $d->{$id} = $str || '';
 989                         }
 990                     } elsif ($id eq 'bridge_stp') {
 991                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 992                             $d->{$id} = 'on';
 993                         } else {
 994                             $d->{$id} = 'off';
 995                         }
 996                     } elsif ($id eq 'bridge_vlan_aware') {
 997                         $d->{$id} = 1;
 998                     } elsif ($id eq 'bond_mode') {
 999                         # always use names
1000                         foreach my $bm (keys %$bond_modes) {
1001                             my $id = $bond_modes->{$bm};
1002                             if ($id eq $value) {
1003                                 $value = $bm;
1004                                 last;
1005                             }
1006                         }
1007                         $d->{$id} = $value;
1008                     } elsif ($id eq 'vxlan-remoteip') {
1009                         push @{$d->{$id}}, $value;
1010                     } else {
1011                         push @{$f->{options}}, $option;
1012                     }
1013                 } else {
1014                     last;
1015                 }
1016             }
1017             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
1018             last SECTION if !defined($line);
1019             redo SECTION;
1020         } elsif ($line =~ /\w/) {
1021             push @$options, [$priority++, $line];
1022         }
1023     }
1024
1025     foreach my $ifname (@$active_ifaces) {
1026         if (my $iface = $ifaces->{$ifname}) {
1027             $iface->{active} = 1;
1028         }
1029     }
1030
1031     if (!$ifaces->{lo}) {
1032         $ifaces->{lo}->{priority} = 1;
1033         $ifaces->{lo}->{method} = 'loopback';
1034         $ifaces->{lo}->{type} = 'loopback';
1035         $ifaces->{lo}->{autostart} = 1;
1036     }
1037
1038     foreach my $iface (keys %$ifaces) {
1039         my $d = $ifaces->{$iface};
1040         $d->{type} = 'unknown';
1041         if ($iface =~ m/^bond\d+$/) {
1042             if (!$d->{ovs_type}) {
1043                 $d->{type} = 'bond';
1044             } elsif ($d->{ovs_type} eq 'OVSBond') {
1045                 $d->{type} = $d->{ovs_type};
1046                 # translate: ovs_options => bond_mode
1047                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
1048                 my $lacp = &$extract_ovs_option($d, 'lacp');
1049                 if ($lacp && $lacp eq 'active') {
1050                     if ($d->{'bond_mode'} eq 'balance-slb') {
1051                         $d->{'bond_mode'} = 'lacp-balance-slb';
1052                     }
1053                 }
1054                 # Note: balance-tcp needs lacp
1055                 if ($d->{'bond_mode'} eq 'balance-tcp') {
1056                     $d->{'bond_mode'} = 'lacp-balance-tcp';
1057                 }
1058                 my $tag = &$extract_ovs_option($d, 'tag');
1059                 $d->{ovs_tag} = $tag if defined($tag);
1060             }
1061         } elsif ($iface =~ m/^vmbr\d+$/) {
1062             if (!$d->{ovs_type}) {
1063                 $d->{type} = 'bridge';
1064                 if (!defined ($d->{bridge_stp})) {
1065                     $d->{bridge_stp} = 'off';
1066                 }
1067                 if (!defined($d->{bridge_fd}) && $d->{bridge_stp} eq 'off') {
1068                     $d->{bridge_fd} = 0;
1069                 }
1070             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1071                 $d->{type} = $d->{ovs_type};
1072             }
1073         } elsif ($iface =~ m/^(\S+):\d+$/) {
1074             $d->{type} = 'alias';
1075             if (defined ($ifaces->{$1})) {
1076                 $d->{exists} = $ifaces->{$1}->{exists};
1077             } else {
1078                 $ifaces->{$1}->{exists} = 0;
1079                 $d->{exists} = 0;
1080             }
1081         } elsif ($iface =~ m/^(\S+)\.(\d+)$/ || $d->{'vlan-raw-device'}) {
1082             $d->{type} = 'vlan';
1083
1084             my ($dev, $id) = ($1, $2);
1085             $d->{'vlan-raw-device'} = $dev if defined($dev) && !$d->{'vlan-raw-device'};
1086
1087             if (!$id && $iface =~ m/^vlan(\d+)$/) { # VLAN id 0 is not valid, so truthy check it is
1088                 $id = $1;
1089             }
1090             $d->{'vlan-id'} = $id if $id;
1091
1092             my $raw_iface = $d->{'vlan-raw-device'};
1093
1094             if (defined ($ifaces->{$raw_iface})) {
1095                 $d->{exists} = $ifaces->{$raw_iface}->{exists};
1096             } else {
1097                 $ifaces->{$raw_iface}->{exists} = 0;
1098                 $d->{exists} = 0;
1099             }
1100         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1101             if (!$d->{ovs_type}) {
1102                 $d->{type} = 'eth';
1103             } elsif ($d->{ovs_type} eq 'OVSPort') {
1104                 $d->{type} = $d->{ovs_type};
1105                 my $tag = &$extract_ovs_option($d, 'tag');
1106                 $d->{ovs_tag} = $tag if defined($tag);
1107             }
1108         } elsif ($iface =~ m/^lo$/) {
1109             $d->{type} = 'loopback';
1110         } else {
1111             if ($d->{'vxlan-id'}) {
1112                 $d->{type} = 'vxlan';
1113             } elsif (defined($d->{ovs_type})) {
1114                 if ($d->{ovs_type} eq 'OVSIntPort') {
1115                     $d->{type} = $d->{ovs_type};
1116                     my $tag = &$extract_ovs_option($d, 'tag');
1117                     $d->{ovs_tag} = $tag if defined($tag);
1118                 }
1119             } elsif (defined($d->{'link-type'})) {
1120                 $d->{type} = $d->{'link-type'} if $d->{'link-type'} eq 'dummy';
1121             }
1122         }
1123
1124         # map address and netmask to cidr
1125         if (my $addr = $d->{address}) {
1126             if (_address_is_cidr($addr)) {
1127                 $d->{cidr} = $addr;
1128                 my ($baseaddr, $mask) = _cidr_split($addr);
1129                 $d->{address} = $baseaddr;
1130                 $d->{netmask} = $mask;
1131             } elsif (my $cidr = _get_cidr($d->{address}, $d->{netmask})) {
1132                 $d->{cidr} = $cidr;
1133                 (undef, $d->{netmask}) = _cidr_split($cidr);
1134             } else {
1135                 # no mask, else we'd got a cidr above
1136                 $d->{cidr} = $addr ."/32";
1137             }
1138         }
1139
1140         # map address6 and netmask6 to cidr6
1141         if (my $addr6 = $d->{address6}) {
1142             if (_address_is_cidr($addr6)) {
1143                 $d->{cidr6} = $addr6;
1144                 my ($baseaddr, $mask) = _cidr_split($addr6);
1145                 $d->{address6} = $baseaddr;
1146                 $d->{netmask6} = $mask;
1147             } elsif (my $cidr6 = _get_cidr($d->{address6}, $d->{netmask6})) {
1148                 $d->{cidr6} = $cidr6;
1149             } else {
1150                 # no mask, else we'd got a cidr above
1151                 $d->{cidr6} = $addr6 ."/128";
1152             }
1153         }
1154
1155         $d->{method} = 'manual' if !$d->{method};
1156         $d->{method6} = 'manual' if !$d->{method6};
1157
1158         if (my $comments6 = delete $d->{comments6}) {
1159             $d->{comments} = ($d->{comments} // '') . $comments6;
1160         }
1161
1162         $d->{families} ||= ['inet'];
1163     }
1164
1165     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1166     # from the {options} hash for them to be removed correctly.
1167     @$options = grep {defined($_)} map {
1168         my ($pri, $line) = @$_;
1169         if ($line =~ /^allow-ovs\s+(.*)$/) {
1170             undef;
1171         } elsif ($line =~ /^allow-(\S+)\s+(.*)$/) {
1172             my $bridge = $1;
1173             my @ports = split(/\s+/, $2);
1174             if (defined(my $br = $ifaces->{$bridge})) {
1175                 # if this port is part of a bridge, remove it
1176                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1177                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1178             }
1179             # create the allow line for the remaining ports, or delete if empty
1180             if (@ports) {
1181                 [$pri, "allow-$bridge " . join(' ', @ports)];
1182             } else {
1183                 undef;
1184             }
1185         } else {
1186             # don't modify other lines
1187             $_;
1188         }
1189     } @$options;
1190
1191     return $config;
1192 }
1193
1194 sub _address_is_cidr {
1195     my ($addr) = @_;
1196     return $addr =~ /\/\d+$/ ? 1 : 0;
1197 }
1198
1199 sub _cidr_split {
1200     my ($cidr) = @_;
1201     $cidr =~ /^(.+)\/(\d+)$/;
1202     return ($1, $2); # (address, mask)
1203 }
1204
1205 sub _get_cidr {
1206     my ($addr, $mask) = @_;
1207
1208     return $addr if _address_is_cidr($addr);
1209     return undef if !$mask;
1210
1211     if ($mask =~ m/^\d+$/) { # cidr notation
1212         return $addr . "/" . $mask;
1213     } elsif (my $cidrmask = PVE::JSONSchema::get_netmask_bits($mask)) {
1214         return $addr . "/" . $cidrmask;
1215     }
1216     return undef;
1217 }
1218
1219 sub __interface_to_string {
1220     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1221
1222     (my $suffix = $family) =~ s/^inet//;
1223
1224     return '' if !($d && $d->{"method$suffix"});
1225
1226     my $raw = "iface $iface $family " . $d->{"method$suffix"} . "\n";
1227
1228     if (my $addr = $d->{"address$suffix"}) {
1229         if ($addr !~ /\/\d+$/ && $d->{"netmask$suffix"}) {
1230             if ($d->{"netmask$suffix"} =~ m/^\d+$/) {
1231                 $addr .= "/" . $d->{"netmask$suffix"};
1232             } elsif (my $mask = PVE::JSONSchema::get_netmask_bits($d->{"netmask$suffix"})) {
1233                 $addr .= "/" . $mask;
1234             }
1235         }
1236         $raw .= "\taddress ${addr}\n";
1237     }
1238
1239     $raw .= "\tgateway " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1240
1241     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1242                  comments => 1, autostart => 1, options => 1,
1243                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1244                  method6 => 1, families => 1, options6 => 1, comments6 => 1,
1245                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1, 'uplink-id' => 1 };
1246
1247     if (!$first_block) {
1248         # not printing out options
1249     } elsif ($d->{type} eq 'bridge') {
1250
1251         my $ports = $d->{bridge_ports} || 'none';
1252         $ports =~ s/[;,\s]+/ /g;
1253         $raw .= "\tbridge-ports $ports\n";
1254         $done->{bridge_ports} = 1;
1255
1256         my $br_stp = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1257         my $no_stp = $br_stp eq 'off';
1258
1259         $raw .= "\tbridge-stp $br_stp\n";
1260         $done->{bridge_stp} = 1;
1261
1262         # NOTE: forwarding delay must be 2 <= FD <= 30 if STP is enabled
1263         if (defined(my $br_fd = $d->{bridge_fd})) {
1264             if ($no_stp || ($br_fd >= 2 && $br_fd <= 30)) {
1265                 $raw .= "\tbridge-fd $br_fd\n";
1266             } else {
1267                 # only complain if the user actually set a value, but not for default fallback below
1268                 warn "'$iface': ignoring 'bridge_fd' value '$br_fd', outside of allowed range 2-30\n";
1269             }
1270         } elsif ($no_stp) {
1271             $raw .= "\tbridge-fd 0\n";
1272         }
1273         $done->{bridge_fd} = 1;
1274
1275         if( defined($d->{bridge_vlan_aware})) {
1276             $raw .= "\tbridge-vlan-aware yes\n";
1277             my $vlans = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1278             $raw .= "\tbridge-vids $vlans\n";
1279         }
1280         $done->{bridge_vlan_aware} = 1;
1281         $done->{bridge_vids} = 1;
1282
1283         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1284         $done->{mtu} = 1;
1285
1286     } elsif ($d->{type} eq 'bond') {
1287
1288         $d->{slaves} =~ s/[;,\s]+/ /g;
1289         my $slaves = $d->{slaves} || 'none';
1290         $raw .= "\tbond-slaves $slaves\n";
1291         $done->{slaves} = 1;
1292
1293         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1294         $raw .= "\tbond-miimon $v\n";
1295         $done->{'bond_miimon'} = 1;
1296
1297         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1298         $raw .= "\tbond-mode $v\n";
1299         $done->{'bond_mode'} = 1;
1300
1301         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1302             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1303             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1304         }
1305         $done->{'bond_xmit_hash_policy'} = 1;
1306
1307         if ($d->{'bond_mode'} && $d->{'bond_mode'} eq 'active-backup' && $d->{'bond-primary'}) {
1308             $raw .= "\tbond-primary $d->{'bond-primary'}\n";
1309         }
1310         $done->{'bond-primary'} = 1;
1311
1312         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1313         $done->{mtu} = 1;
1314
1315     } elsif ($d->{type} eq 'vlan') {
1316         die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n"
1317             if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
1318
1319     } elsif ($d->{type} eq 'vxlan') {
1320
1321         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1322             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1323             $done->{$k} = 1;
1324         }
1325
1326         if ($d->{'vxlan-remoteip'}) {
1327             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1328                 $raw .= "\tvxlan-remoteip $remoteip\n";
1329             }
1330             $done->{'vxlan-remoteip'} = 1;
1331         }
1332
1333         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1334         $done->{mtu} = 1;
1335
1336     } elsif ($d->{type} eq 'OVSBridge') {
1337
1338         $raw .= "\tovs_type $d->{type}\n";
1339         $done->{ovs_type} = 1;
1340
1341         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1342         $done->{ovs_ports} = 1;
1343
1344         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1345         $done->{mtu} = 1;
1346
1347     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1348              $d->{type} eq 'OVSBond') {
1349
1350         $d->{autostart} = 0; # started by the bridge
1351
1352         if (defined($d->{ovs_tag})) {
1353             &$set_ovs_option($d, tag => $d->{ovs_tag});
1354         }
1355         $done->{ovs_tag} = 1;
1356
1357         if ($d->{type} eq 'OVSBond') {
1358
1359             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1360
1361             $ovs_bond_modes->{$d->{bond_mode}} ||
1362                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1363
1364             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1365                 &$set_ovs_option($d, lacp => 'active');
1366                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1367             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1368                 &$set_ovs_option($d, lacp => 'active');
1369                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1370             } else {
1371                 &$set_ovs_option($d, lacp => undef);
1372                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1373             }
1374             $done->{bond_mode} = 1;
1375
1376             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1377             $done->{ovs_bonds} = 1;
1378         }
1379
1380         $raw .= "\tovs_type $d->{type}\n";
1381         $done->{ovs_type} = 1;
1382
1383         if (my $bridge = $d->{ovs_bridge}) {
1384             if ($ifupdown2) {
1385                 $raw = "auto $iface\n$raw";
1386             } else {
1387                 $raw = "allow-$bridge $iface\n$raw";
1388             }
1389
1390             $raw .= "\tovs_bridge $bridge\n";
1391             $done->{ovs_bridge} = 1;
1392         }
1393
1394         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1395         $done->{mtu} = 1;
1396     }
1397
1398     if ($first_block) {
1399         # print other settings
1400         foreach my $k (sort keys %$d) {
1401            next if $done->{$k};
1402            next if !$d->{$k};
1403            $raw .= "\t$k $d->{$k}\n";
1404         }
1405     }
1406
1407     foreach my $option (@{$d->{"options$suffix"}}) {
1408         $raw .= "\t$option\n";
1409     }
1410
1411     # add comments
1412     my $comments = $d->{"comments$suffix"} || '';
1413     foreach my $cl (split(/\n/, $comments)) {
1414         $raw .= "#$cl\n";
1415     }
1416
1417     $raw .= "\n";
1418
1419     return $raw;
1420 }
1421
1422
1423 sub write_etc_network_interfaces {
1424     my ($filename, $fh, $config) = @_;
1425     my $ifupdown2 = -e '/usr/share/ifupdown2/ifupdown2';
1426     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1427     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1428 }
1429 sub __write_etc_network_interfaces {
1430     my ($config, $ifupdown2) = @_;
1431
1432     my $ifaces = $config->{ifaces};
1433     my @options = @{$config->{options}};
1434
1435     my $used_ports = {};
1436
1437     foreach my $iface (keys %$ifaces) {
1438         my $d = $ifaces->{$iface};
1439
1440         my ($cidr, $cidr6) = (delete $d->{cidr}, delete $d->{cidr6});
1441         $d->{address} //= $cidr;
1442         $d->{address6} //= $cidr6;
1443
1444         my $ports = '';
1445         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1446             $ports .= " $d->{$k}" if $d->{$k};
1447         }
1448
1449         foreach my $p (PVE::Tools::split_list($ports)) {
1450             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1451                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1452             $used_ports->{$p} = $iface;
1453         }
1454     }
1455
1456     # delete unused OVS ports
1457     foreach my $iface (keys %$ifaces) {
1458         my $d = $ifaces->{$iface};
1459         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1460             $d->{type} eq 'OVSBond') {
1461             my $brname = $used_ports->{$iface};
1462             if (!$brname || !$ifaces->{$brname}) {
1463                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1464                     $ifaces->{$iface} = {
1465                         type => 'eth',
1466                         exists => 1,
1467                         method => 'manual',
1468                         families => ['inet'],
1469                     };
1470                 } else {
1471                     delete $ifaces->{$iface};
1472                 }
1473                 next;
1474             }
1475             my $bd = $ifaces->{$brname};
1476             if ($bd->{type} ne 'OVSBridge') {
1477                 delete $ifaces->{$iface};
1478                 next;
1479             }
1480         }
1481     }
1482
1483     # create OVS bridge ports
1484     foreach my $iface (keys %$ifaces) {
1485         my $d = $ifaces->{$iface};
1486         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1487             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1488                 my $n = $ifaces->{$p};
1489                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1490                     if !$n;
1491                 $n->{autostart} = 0;
1492                 if ($n->{type} eq 'eth') {
1493                     $n->{type} = 'OVSPort';
1494                     $n->{ovs_bridge} = $iface;
1495                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1496                     $n->{type} eq 'OVSIntPort') {
1497                     $n->{ovs_bridge} = $iface;
1498                 } else {
1499                     die "interface '$p' is not defined as OVS port/bond\n";
1500                 }
1501
1502                 &$check_mtu($ifaces, $iface, $p);
1503             }
1504         }
1505     }
1506
1507     # check OVS bond ports
1508     foreach my $iface (keys %$ifaces) {
1509         my $d = $ifaces->{$iface};
1510         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1511             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1512                 my $n = $ifaces->{$p};
1513                 $n->{autostart} = 1;
1514                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1515                     if !$n;
1516                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1517                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1518                 &$check_mtu($ifaces, $iface, $p);
1519             }
1520         }
1521     }
1522
1523     # check bond
1524     foreach my $iface (keys %$ifaces) {
1525         my $d = $ifaces->{$iface};
1526         next if !($d->{type} eq 'bond' && $d->{slaves});
1527
1528         my $bond_primary_is_slave = undef;
1529         foreach my $p (split (/\s+/, $d->{slaves})) {
1530             my $n = $ifaces->{$p};
1531             $n->{autostart} = 1;
1532
1533             die "bond '$iface' - unable to find slave '$p'\n" if !$n;
1534             die "bond '$iface' - wrong interface type on slave '$p' ('$n->{type}' != 'eth or bond')\n"
1535                 if ($n->{type} ne 'eth' && $n->{type} ne 'bond');
1536
1537             $check_mtu->($ifaces, $iface, $p);
1538             $bond_primary_is_slave = 1 if $d->{'bond-primary'} && $d->{'bond-primary'} eq $p;
1539         }
1540         die "bond '$iface' - bond-primary interface is not a slave" if $d->{'bond-primary'} && !$bond_primary_is_slave;
1541     }
1542
1543     # check vxlan
1544     my $vxlans = {};
1545     foreach my $iface (keys %$ifaces) {
1546         my $d = $ifaces->{$iface};
1547
1548         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1549             my $vxlanid = $d->{'vxlan-id'};
1550             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1551             $vxlans->{$vxlanid} = $iface;
1552         }
1553
1554         my $ips = 0;
1555         ++$ips if defined $d->{'vxlan-svcnodeip'};
1556         ++$ips if defined $d->{'vxlan-remoteip'};
1557         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1558         if ($ips > 1) {
1559             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1560         }
1561
1562         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1563             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1564         }
1565         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1566     }
1567
1568     # check vlan
1569     foreach my $iface (keys %$ifaces) {
1570         my $d = $ifaces->{$iface};
1571         if ($d->{type} eq 'vlan') {
1572
1573             my $p = undef;
1574             my $vlanid = undef;
1575
1576             if ($iface =~ m/^(\S+)\.(\d+)$/) {
1577                 $p = $1;
1578                 $vlanid = $2;
1579                 delete $d->{'vlan-raw-device'} if $d->{'vlan-raw-device'};
1580                 delete $d->{'vlan-id'} if $d->{'vlan-id'};
1581
1582             } else {
1583                 die "missing vlan-raw-device option" if !$d->{'vlan-raw-device'};
1584                 $p = $d->{'vlan-raw-device'};
1585
1586                 if ($iface =~ m/^vlan(\d+)$/) {
1587                     $vlanid = $1;
1588                     delete $d->{'vlan-id'} if $d->{'vlan-id'};
1589                 } else {
1590                     die "custom vlan interface name need ifupdown2" if !$ifupdown2;
1591                     die "missing vlan-id option" if !$d->{'vlan-id'};
1592                     $vlanid = $d->{'vlan-id'};
1593                 }
1594             }
1595             my $n = $ifaces->{$p};
1596
1597             die "vlan '$iface' - vlan-id $vlanid should be <= 4094\n" if $vlanid > 4094;
1598             die "vlan '$iface' - unable to find parent '$p'\n"
1599                 if !$n;
1600
1601             if ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
1602                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1603                     "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
1604             }
1605
1606             &$check_mtu($ifaces, $p, $iface);
1607
1608         }
1609     }
1610
1611     # check uplink
1612     my $uplinks = {};
1613     foreach my $iface (keys %$ifaces) {
1614         my $d = $ifaces->{$iface};
1615         if (my $uplinkid = $d->{'uplink-id'}) {
1616             die "iface '$iface' - uplink-id $uplinkid is only allowed on physical and linux bond interfaces\n"
1617                 if $d->{type} ne 'eth' && $d->{type} ne 'bond';
1618
1619             die "iface '$iface' - uplink-id $uplinkid is already assigned on '$uplinks->{$uplinkid}'\n"
1620                 if $uplinks->{$uplinkid};
1621
1622             $uplinks->{$uplinkid} = $iface;
1623         }
1624     }
1625
1626     # check bridgeport option
1627     my $bridgeports = {};
1628     my $bridges = {};
1629     my $ifaces_copy = { %$ifaces };
1630     foreach my $iface (keys %$ifaces_copy) {
1631         my $d = $ifaces_copy->{$iface};
1632         if ($d->{type} eq 'bridge') {
1633             foreach my $p (split (/\s+/, $d->{bridge_ports} // '')) {
1634                 if($p =~ m/(\S+)\.(\d+)$/) {
1635                     my $vlanparent = $1;
1636                     if (!defined($ifaces_copy->{$p})) {
1637                         $ifaces_copy->{$p}->{type} = 'vlan';
1638                         $ifaces_copy->{$p}->{method} = 'manual';
1639                         $ifaces_copy->{$p}->{method6} = 'manual';
1640                         $ifaces_copy->{$p}->{mtu} = $ifaces_copy->{$vlanparent}->{mtu} if defined($ifaces_copy->{$1}->{mtu});
1641                     }
1642                 }
1643                 my $n = $ifaces_copy->{$p};
1644                 die "bridge '$iface' - unable to find bridge port '$p'\n" if !$n;
1645                 die "iface $p - ip address can't be set on interface if bridged in $iface\n"
1646                     if ($n->{method} && $n->{method} eq 'static' && $n->{address} ne '0.0.0.0') ||
1647                        ($n->{method6} && $n->{method6} eq 'static' && $n->{address6} ne '::');
1648                 &$check_mtu($ifaces_copy, $p, $iface);
1649                 $bridgeports->{$p} = $iface;
1650             }
1651             $bridges->{$iface} = $d;
1652         }
1653     }
1654
1655     foreach my $iface (keys %$ifaces) {
1656         my $d = $ifaces->{$iface};
1657
1658         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1659             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1660                 if $d->{$k} && !$bridgeports->{$iface};
1661         }
1662
1663         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1664             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1665         }
1666     }
1667
1668     my $raw = <<'NETWORKDOC';
1669 # network interface settings; autogenerated
1670 # Please do NOT modify this file directly, unless you know what
1671 # you're doing.
1672 #
1673 # If you want to manage parts of the network configuration manually,
1674 # please utilize the 'source' or 'source-directory' directives to do
1675 # so.
1676 # PVE will preserve these directives, but will NOT read its network
1677 # configuration from sourced files, so do not attempt to move any of
1678 # the PVE managed interfaces into external files!
1679
1680 NETWORKDOC
1681
1682     my $printed = {};
1683
1684     my $if_type_hash = {
1685         loopback => 100000,
1686         dummy => 100000,
1687         eth => 200000,
1688         OVSPort => 200000,
1689         OVSIntPort => 300000,
1690         OVSBond => 400000,
1691         bond => 400000,
1692         bridge => 500000,
1693         OVSBridge => 500000,
1694         vlan => 600000,
1695         vxlan => 600000,
1696    };
1697
1698     my $lookup_type_prio = sub {
1699         my ($iface, $ifaces) = @_;
1700
1701         my ($rootiface, @rest) = split(/[.:]/, $iface);
1702         my $childlevel = scalar(@rest);
1703         my $type = $ifaces->{$rootiface}->{type};
1704         return if !$type || $type eq 'unknown';
1705
1706         return $if_type_hash->{$type} + $childlevel
1707     };
1708
1709     foreach my $iface (sort {
1710         my $ref1 = $ifaces->{$a};
1711         my $ref2 = $ifaces->{$b};
1712         my $tp1 = &$lookup_type_prio($a, $ifaces);
1713         my $tp2 = &$lookup_type_prio($b, $ifaces);
1714
1715         # Only recognized types are in relation to each other. If one type
1716         # is unknown then only consider the interfaces' priority attributes.
1717         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1718
1719         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1720         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1721
1722         return $p1 <=> $p2 if $p1 != $p2;
1723
1724         return $a cmp $b;
1725     } keys %$ifaces) {
1726         next if $printed->{$iface};
1727         my $d = $ifaces->{$iface};
1728         my $pri = $d->{priority} // 0;
1729         if (@options && $options[0]->[0] < $pri) {
1730             do {
1731                 $raw .= (shift @options)->[1] . "\n";
1732             } while (@options && $options[0]->[0] < $pri);
1733             $raw .= "\n";
1734         }
1735
1736         $printed->{$iface} = 1;
1737         if ($d->{autostart}) {
1738             if ($d->{type} eq 'OVSBridge' && !$ifupdown2) {
1739                 # cannot use 'auto' for OVS, would add race with systemd ifup@.service
1740                 $raw .= "allow-ovs $iface\n";
1741             } else {
1742                 $raw .= "auto $iface\n";
1743             }
1744         }
1745
1746         # if 'inet6' is the only family
1747         if (scalar($d->{families}->@*) == 1 && $d->{families}[0] eq 'inet6') {
1748             $d->{comments6} = delete $d->{comments};
1749         }
1750
1751         my $i = 0; # some options should be printed only once
1752         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1753     }
1754
1755     $raw .= $_->[1] . "\n" foreach @options;
1756     return $raw;
1757 }
1758
1759 register_file('interfaces', "/etc/network/interfaces",
1760               \&read_etc_network_interfaces,
1761               \&write_etc_network_interfaces);
1762
1763
1764 sub read_iscsi_initiatorname {
1765     my ($filename, $fd) = @_;
1766
1767     while (defined(my $line = <$fd>)) {
1768         if ($line =~ m/^InitiatorName=(\S+)$/) {
1769             return $1;
1770         }
1771     }
1772
1773     return 'undefined';
1774 }
1775
1776 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1777               \&read_iscsi_initiatorname);
1778
1779 sub read_apt_auth {
1780     my ($filename, $fd) = @_;
1781
1782     local $/;
1783
1784     my $raw = defined($fd) ? <$fd> : '';
1785
1786     $raw =~ s/^\s+//;
1787
1788
1789     my @tokens = split(/\s+/, $raw);
1790
1791     my $data = {};
1792
1793     my $machine;
1794     while (defined(my $tok = shift @tokens)) {
1795
1796         $machine = shift @tokens if $tok eq 'machine';
1797         next if !$machine;
1798         $data->{$machine} = {} if !$data->{$machine};
1799
1800         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1801         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1802     };
1803
1804     return $data;
1805 }
1806
1807 my $format_apt_auth_data = sub {
1808     my $data = shift;
1809
1810     my $raw = '';
1811
1812     # sort longer entries first, so machine definitions with higher granularity are preferred
1813     for my $machine (sort { length($b) <=> length($a) || $a cmp $b} keys %$data) {
1814         my $d = $data->{$machine};
1815         next if !defined($d); # allow "deleting" set entries
1816
1817         $raw .= "machine $machine\n";
1818         $raw .= " login $d->{login}\n" if $d->{login};
1819         $raw .= " password $d->{password}\n" if $d->{password};
1820         $raw .= "\n";
1821     }
1822
1823     return $raw;
1824 };
1825
1826 sub write_apt_auth {
1827     my ($filename, $fh, $data) = @_;
1828
1829     my $raw = $format_apt_auth_data->($data);
1830
1831     die "write failed: $!" unless print $fh "$raw\n";
1832
1833     return $data;
1834 }
1835
1836 sub update_apt_auth {
1837     my ($filename, $fh, $data) = @_;
1838
1839     my $orig = read_apt_auth($filename, $fh);
1840
1841     foreach my $machine (keys %$data) {
1842         $orig->{$machine} = $data->{$machine};
1843     }
1844
1845     return $format_apt_auth_data->($orig);
1846 }
1847
1848 register_file(
1849     'apt-auth',
1850     "/etc/apt/auth.conf",
1851     \&read_apt_auth,
1852     \&write_apt_auth,
1853     \&update_apt_auth,
1854     perm => 0640,
1855 );
1856
1857 1;