src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use Net::IP;
  13 use POSIX qw(ECONNREFUSED);
  14 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  15
  16 # host network related utility functions
  17
  18 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib\d+)/;
  19
  20 our $ipv4_reverse_mask = [
  21     '0.0.0.0',
  22     '128.0.0.0',
  23     '192.0.0.0',
  24     '224.0.0.0',
  25     '240.0.0.0',
  26     '248.0.0.0',
  27     '252.0.0.0',
  28     '254.0.0.0',
  29     '255.0.0.0',
  30     '255.128.0.0',
  31     '255.192.0.0',
  32     '255.224.0.0',
  33     '255.240.0.0',
  34     '255.248.0.0',
  35     '255.252.0.0',
  36     '255.254.0.0',
  37     '255.255.0.0',
  38     '255.255.128.0',
  39     '255.255.192.0',
  40     '255.255.224.0',
  41     '255.255.240.0',
  42     '255.255.248.0',
  43     '255.255.252.0',
  44     '255.255.254.0',
  45     '255.255.255.0',
  46     '255.255.255.128',
  47     '255.255.255.192',
  48     '255.255.255.224',
  49     '255.255.255.240',
  50     '255.255.255.248',
  51     '255.255.255.252',
  52     '255.255.255.254',
  53     '255.255.255.255',
  54 ];
  55
  56 our $ipv4_mask_hash_localnet = {
  57     '255.0.0.0' => 8,
  58     '255.128.0.0' => 9,
  59     '255.192.0.0' => 10,
  60     '255.224.0.0' => 11,
  61     '255.240.0.0' => 12,
  62     '255.248.0.0' => 13,
  63     '255.252.0.0' => 14,
  64     '255.254.0.0' => 15,
  65     '255.255.0.0' => 16,
  66     '255.255.128.0' => 17,
  67     '255.255.192.0' => 18,
  68     '255.255.224.0' => 19,
  69     '255.255.240.0' => 20,
  70     '255.255.248.0' => 21,
  71     '255.255.252.0' => 22,
  72     '255.255.254.0' => 23,
  73     '255.255.255.0' => 24,
  74     '255.255.255.128' => 25,
  75     '255.255.255.192' => 26,
  76     '255.255.255.224' => 27,
  77     '255.255.255.240' => 28,
  78     '255.255.255.248' => 29,
  79     '255.255.255.252' => 30,
  80     '255.255.255.254' => 31,
  81     '255.255.255.255' => 32,
  82 };
  83
  84 sub setup_tc_rate_limit {
  85     my ($iface, $rate, $burst) = @_;
  86
  87     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  88     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  89     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  90     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  91     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  92
  93     return if !$rate;
  94
  95     # tbf does not work for unknown reason
  96     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  97     # so we use htb instead
  98     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  99     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 100                 "htb rate ${rate}bps burst ${burst}b");
 101
 102     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 103     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 104                 "prio 50 basic " .
 105                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 106                 "drop");
 107 }
 108
 109 sub tap_rate_limit {
 110     my ($iface, $rate) = @_;
 111
 112     $rate = int($rate*1024*1024) if $rate;
 113     my $burst = 1024*1024;
 114
 115     setup_tc_rate_limit($iface, $rate, $burst);
 116 }
 117
 118 my $read_bridge_mtu = sub {
 119     my ($bridge) = @_;
 120
 121     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 122     die "bridge '$bridge' does not exist\n" if !$mtu;
 123     # avoid insecure dependency;
 124     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 125     $mtu = int($1);
 126
 127     return $mtu;
 128 };
 129
 130 my $parse_tap_device_name = sub {
 131     my ($iface, $noerr) = @_;
 132
 133     my ($vmid, $devid);
 134
 135     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 136         $vmid = $1;
 137         $devid = $2;
 138     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 139         $vmid = $1;
 140         $devid = $2;
 141     } else {
 142         return undef if $noerr;
 143         die "can't create firewall bridge for random interface name '$iface'\n";
 144     }
 145
 146     return ($vmid, $devid);
 147 };
 148
 149 my $compute_fwbr_names = sub {
 150     my ($vmid, $devid) = @_;
 151
 152     my $fwbr = "fwbr${vmid}i${devid}";
 153     # Note: the firewall use 'fwln+' to filter traffic to VMs
 154     my $vethfw = "fwln${vmid}i${devid}";
 155     my $vethfwpeer = "fwpr${vmid}p${devid}";
 156     my $ovsintport = "fwln${vmid}o${devid}";
 157
 158     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 159 };
 160
 161 sub iface_delete($) {
 162     my ($iface) = @_;
 163     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 164         == 0 or die "failed to delete interface '$iface'\n";
 165 }
 166
 167 sub iface_create($$@) {
 168     my ($iface, $type, @args) = @_;
 169     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 170         == 0 or die "failed to create interface '$iface'\n";
 171 }
 172
 173 sub iface_set($@) {
 174     my ($iface, @opts) = @_;
 175     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 176         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 177 }
 178
 179 # helper for nicer error messages:
 180 sub iface_set_master($$) {
 181     my ($iface, $master) = @_;
 182     if (defined($master)) {
 183         eval { iface_set($iface, 'master', $master) };
 184         die "can't enslave '$iface' to '$master'\n" if $@;
 185     } else {
 186         eval { iface_set($iface, 'nomaster') };
 187         die "can't unenslave '$iface'\n" if $@;
 188     }
 189 }
 190
 191 my $cond_create_bridge = sub {
 192     my ($bridge) = @_;
 193
 194     if (! -d "/sys/class/net/$bridge") {
 195         iface_create($bridge, 'bridge');
 196         disable_ipv6($bridge);
 197     }
 198 };
 199
 200 sub disable_ipv6 {
 201     my ($iface) = @_;
 202     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 203     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 204     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 205     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 206     close($fh);
 207 }
 208
 209 my $bridge_add_interface = sub {
 210     my ($bridge, $iface, $tag, $trunks) = @_;
 211
 212     # drop link local address (it can't be used when on a bridge anyway)
 213     disable_ipv6($iface);
 214     iface_set_master($iface, $bridge);
 215
 216    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 217
 218    if ($vlan_aware) {
 219         if ($tag) {
 220             eval { run_command(['/sbin/bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094']) };
 221             die "failed to remove default vlan tags of $iface - $@\n" if $@;
 222
 223             eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged']) };
 224             die "unable to add vlan $tag to interface $iface - $@\n" if $@;
 225
 226             warn "Caution: Setting VLAN ID 1 on a VLAN aware bridge may be dangerous\n" if $tag == 1;
 227         } else {
 228             eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', '2-4094']) };
 229             die "unable to add default vlan tags to interface $iface - $@\n"
 230                 if $@ && !$trunks;
 231         }
 232
 233         if ($trunks) {
 234             my @trunks_array = split /;/, $trunks;
 235             foreach my $trunk (@trunks_array) {
 236                 eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $trunk]) };
 237                 die "unable to add vlan $trunk to interface $iface - $@\n" if $@;
 238             }
 239         }
 240    }
 241 };
 242
 243 my $ovs_bridge_add_port = sub {
 244     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 245
 246     $trunks =~ s/;/,/g if $trunks;
 247
 248     my $cmd = ['/usr/bin/ovs-vsctl'];
 249     # first command
 250     push @$cmd, '--', 'add-port', $bridge, $iface;
 251     push @$cmd, "tag=$tag" if $tag;
 252     push @$cmd, "trunks=". join(',', $trunks) if $trunks;
 253     push @$cmd, "vlan_mode=native-untagged" if $tag && $trunks;
 254
 255     if ($internal) {
 256         # second command
 257         push @$cmd, '--', 'set', 'Interface', $iface, 'type=internal';
 258     }
 259
 260     eval { run_command($cmd) };
 261     die "can't add ovs port '$iface' - $@\n" if $@;
 262
 263     disable_ipv6($iface);
 264 };
 265
 266 my $activate_interface = sub {
 267     my ($iface) = @_;
 268
 269     eval { run_command(['/sbin/ip', 'link', 'set', $iface, 'up']) };
 270     die "can't activate interface '$iface' - $@\n" if $@;
 271 };
 272
 273 sub tap_create {
 274     my ($iface, $bridge) = @_;
 275
 276     die "unable to get bridge setting\n" if !$bridge;
 277
 278     my $bridgemtu = &$read_bridge_mtu($bridge);
 279
 280     eval {
 281         disable_ipv6($iface);
 282         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 283     };
 284     die "interface activation failed\n" if $@;
 285 }
 286
 287 sub veth_create {
 288     my ($veth, $vethpeer, $bridge, $mac) = @_;
 289
 290     die "unable to get bridge setting\n" if !$bridge;
 291
 292     my $bridgemtu = &$read_bridge_mtu($bridge);
 293
 294     # create veth pair
 295     if (! -d "/sys/class/net/$veth") {
 296         my $cmd = ['/sbin/ip', 'link', 'add'];
 297         # veth device + MTU
 298         push @$cmd, 'name', $veth;
 299         push @$cmd, 'mtu', $bridgemtu;
 300         push @$cmd, 'type', 'veth';
 301         # peer device + MTU
 302         push @$cmd, 'peer', 'name', $vethpeer, 'mtu', $bridgemtu;
 303
 304         push @$cmd, 'addr', $mac if $mac;
 305
 306         eval { run_command($cmd) };
 307         die "can't create interface $veth - $@\n" if $@;
 308     }
 309
 310     # up vethpair
 311     disable_ipv6($veth);
 312     disable_ipv6($vethpeer);
 313     &$activate_interface($veth);
 314     &$activate_interface($vethpeer);
 315 }
 316
 317 sub veth_delete {
 318     my ($veth) = @_;
 319
 320     if (-d "/sys/class/net/$veth") {
 321         iface_delete($veth);
 322     }
 323     eval { tap_unplug($veth) };
 324 }
 325
 326 my $create_firewall_bridge_linux = sub {
 327     my ($iface, $bridge, $tag, $trunks) = @_;
 328
 329     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 330     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 331
 332     &$cond_create_bridge($fwbr);
 333     &$activate_interface($fwbr);
 334
 335     copy_bridge_config($bridge, $fwbr);
 336     veth_create($vethfw, $vethfwpeer, $bridge);
 337
 338     &$bridge_add_interface($fwbr, $vethfw);
 339     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 340
 341     &$bridge_add_interface($fwbr, $iface);
 342 };
 343
 344 my $create_firewall_bridge_ovs = sub {
 345     my ($iface, $bridge, $tag, $trunks) = @_;
 346
 347     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 348     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 349
 350     my $bridgemtu = &$read_bridge_mtu($bridge);
 351
 352     &$cond_create_bridge($fwbr);
 353     &$activate_interface($fwbr);
 354
 355     &$bridge_add_interface($fwbr, $iface);
 356
 357     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 358     &$activate_interface($ovsintport);
 359
 360     # set the same mtu for ovs int port
 361     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 362
 363     &$bridge_add_interface($fwbr, $ovsintport);
 364 };
 365
 366 my $cleanup_firewall_bridge = sub {
 367     my ($iface) = @_;
 368
 369     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 370     return if !defined($vmid);
 371     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 372
 373     # cleanup old port config from any openvswitch bridge
 374     if (-d "/sys/class/net/$ovsintport") {
 375         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 376     }
 377
 378     # delete old vethfw interface
 379     veth_delete($vethfw);
 380
 381     # cleanup fwbr bridge
 382     if (-d "/sys/class/net/$fwbr") {
 383         iface_delete($fwbr);
 384     }
 385 };
 386
 387 sub tap_plug {
 388     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 389
 390     #cleanup old port config from any openvswitch bridge
 391     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 392
 393     if (-d "/sys/class/net/$bridge/bridge") {
 394         &$cleanup_firewall_bridge($iface); # remove stale devices
 395
 396         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 397
 398         if (!$vlan_aware) {
 399             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 400             my $newbridge = activate_bridge_vlan($bridge, $tag);
 401             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 402             $bridge = $newbridge;
 403             $tag = undef;
 404         }
 405
 406         if ($firewall) {
 407             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 408         } else {
 409             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 410         }
 411
 412     } else {
 413         &$cleanup_firewall_bridge($iface); # remove stale devices
 414
 415         if ($firewall) {
 416             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 417         } else {
 418             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 419         }
 420     }
 421
 422     tap_rate_limit($iface, $rate);
 423 }
 424
 425 sub tap_unplug {
 426     my ($iface) = @_;
 427
 428     my $path= "/sys/class/net/$iface/brport/bridge";
 429     if (-l $path) {
 430         my $bridge = basename(readlink($path));
 431         #avoid insecure dependency;
 432         ($bridge) = $bridge =~ /(\S+)/;
 433
 434         iface_set_master($iface, undef);
 435     }
 436
 437     &$cleanup_firewall_bridge($iface);
 438     #cleanup old port config from any openvswitch bridge
 439     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 440 }
 441
 442 sub copy_bridge_config {
 443     my ($br0, $br1) = @_;
 444
 445     return if $br0 eq $br1;
 446
 447     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 448                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 449
 450     foreach my $sysname (@$br_configs) {
 451         eval {
 452             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 453             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 454             if ($v0 ne $v1) {
 455                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 456             }
 457         };
 458         warn $@ if $@;
 459     }
 460 }
 461
 462 sub activate_bridge_vlan_slave {
 463     my ($bridgevlan, $iface, $tag) = @_;
 464     my $ifacevlan = "${iface}.$tag";
 465
 466     # create vlan on $iface is not already exist
 467     if (! -d "/sys/class/net/$ifacevlan") {
 468         eval {
 469             my $cmd = ['/sbin/ip', 'link', 'add'];
 470             push @$cmd, 'link', $iface;
 471             push @$cmd, 'name', $ifacevlan;
 472             push @$cmd, 'type', 'vlan', 'id', $tag;
 473             run_command($cmd);
 474         };
 475         die "can't add vlan tag $tag to interface $iface - $@\n" if $@;
 476
 477         # remove ipv6 link-local address before activation
 478         disable_ipv6($ifacevlan);
 479     }
 480
 481     # be sure to have the $ifacevlan up
 482     &$activate_interface($ifacevlan);
 483
 484     # test if $vlaniface is already enslaved in another bridge
 485     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 486     if (-l $path) {
 487         my $tbridge = basename(readlink($path));
 488         if ($tbridge ne $bridgevlan) {
 489             die "interface $ifacevlan already exist in bridge $tbridge\n";
 490         } else {
 491             # Port already attached to bridge: do nothing.
 492             return;
 493         }
 494     }
 495
 496     # add $ifacevlan to the bridge
 497     &$bridge_add_interface($bridgevlan, $ifacevlan);
 498 }
 499
 500 sub activate_bridge_vlan {
 501     my ($bridge, $tag_param) = @_;
 502
 503     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 504
 505     return $bridge if !defined($tag_param); # no vlan, simply return
 506
 507     my $tag = int($tag_param);
 508
 509     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 510
 511     my $bridgevlan = "${bridge}v$tag";
 512
 513     my @ifaces = ();
 514     my $dir = "/sys/class/net/$bridge/brif";
 515     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 516         push @ifaces, $_[0];
 517     });
 518
 519     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 520
 521     lock_network(sub {
 522         # add bridgevlan if it doesn't already exist
 523         if (! -d "/sys/class/net/$bridgevlan") {
 524             iface_create($bridgevlan, 'bridge');
 525         }
 526
 527         # for each physical interface (eth or bridge) bind them to bridge vlan
 528         foreach my $iface (@ifaces) {
 529             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 530         }
 531
 532         #fixme: set other bridge flags
 533
 534         # remove ipv6 link-local address before activation
 535         disable_ipv6($bridgevlan);
 536         # be sure to have the bridge up
 537         &$activate_interface($bridgevlan);
 538     });
 539     return $bridgevlan;
 540 }
 541
 542 sub tcp_ping {
 543     my ($host, $port, $timeout) = @_;
 544
 545     my $refused = 1;
 546
 547     $timeout = 3 if !$timeout; # sane default
 548     if (!$port) {
 549         # Net::Ping defaults to the echo port
 550         $port = 7;
 551     } else {
 552         # Net::Ping's port_number() implies service_check(1)
 553         $refused = 0;
 554     }
 555
 556     my ($sock, $result);
 557     eval {
 558         $result = PVE::Tools::run_with_timeout($timeout, sub {
 559             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 560             $result = $refused if $! == ECONNREFUSED;
 561         });
 562     };
 563     if ($sock) {
 564         $sock->close();
 565         $result = 1;
 566     }
 567     return $result;
 568 }
 569
 570 sub IP_from_cidr {
 571     my ($cidr, $version) = @_;
 572
 573     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 574     my ($ip, $prefix) = ($1, $2);
 575
 576     my $ipobj = Net::IP->new($ip, $version);
 577     return if !$ipobj;
 578
 579     $version = $ipobj->version();
 580
 581     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 582     return if !$binmask;
 583
 584     my $masked_binip = $ipobj->binip() & $binmask;
 585     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 586     return Net::IP->new("$masked_ip/$prefix");
 587 }
 588
 589 sub is_ip_in_cidr {
 590     my ($ip, $cidr, $version) = @_;
 591
 592     my $cidr_obj = IP_from_cidr($cidr, $version);
 593     return undef if !$cidr_obj;
 594
 595     my $ip_obj = Net::IP->new($ip, $version);
 596     return undef if !$ip_obj;
 597
 598     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
 599 }
 600
 601
 602 sub get_local_ip_from_cidr {
 603     my ($cidr) = @_;
 604
 605     my $IPs = [];
 606     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 607         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 608             push @$IPs, $1;
 609         }
 610     });
 611
 612     return $IPs;
 613 }
 614
 615 sub addr_to_ip {
 616     my ($addr) = @_;
 617     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 618     die "failed to get numerical host address: $err\n" if $err;
 619     return ($host, $port) if wantarray;
 620     return $host;
 621 }
 622
 623 sub get_ip_from_hostname {
 624     my ($hostname, $noerr) = @_;
 625
 626     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 627     if ($@) {
 628         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 629         return undef;
 630     }
 631
 632     my ($ip, $family);
 633     for my $ai (@res) {
 634         $family = $ai->{family};
 635         my $tmpip = addr_to_ip($ai->{addr});
 636         if ($tmpip !~ m/^127\.|^::1$/) {
 637             $ip = $tmpip;
 638             last;
 639         }
 640     }
 641     if (!defined($ip) ) {
 642         die "hostname lookup '$hostname' failed - got local IP address '$ip'\n" if !$noerr;
 643         return undef;
 644     }
 645
 646     return wantarray ? ($ip, $family) : $ip;
 647 }
 648
 649 sub lock_network {
 650     my ($code, @param) = @_;
 651     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 652     die $@ if $@;
 653     return $res;
 654 }
 655
 656 1;