src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use Net::IP;
  13 use POSIX qw(ECONNREFUSED);
  14 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  15
  16 # host network related utility functions
  17
  18 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib\d+)/;
  19
  20 our $ipv4_reverse_mask = [
  21     '0.0.0.0',
  22     '128.0.0.0',
  23     '192.0.0.0',
  24     '224.0.0.0',
  25     '240.0.0.0',
  26     '248.0.0.0',
  27     '252.0.0.0',
  28     '254.0.0.0',
  29     '255.0.0.0',
  30     '255.128.0.0',
  31     '255.192.0.0',
  32     '255.224.0.0',
  33     '255.240.0.0',
  34     '255.248.0.0',
  35     '255.252.0.0',
  36     '255.254.0.0',
  37     '255.255.0.0',
  38     '255.255.128.0',
  39     '255.255.192.0',
  40     '255.255.224.0',
  41     '255.255.240.0',
  42     '255.255.248.0',
  43     '255.255.252.0',
  44     '255.255.254.0',
  45     '255.255.255.0',
  46     '255.255.255.128',
  47     '255.255.255.192',
  48     '255.255.255.224',
  49     '255.255.255.240',
  50     '255.255.255.248',
  51     '255.255.255.252',
  52     '255.255.255.254',
  53     '255.255.255.255',
  54 ];
  55
  56 our $ipv4_mask_hash_localnet = {
  57     '255.0.0.0' => 8,
  58     '255.128.0.0' => 9,
  59     '255.192.0.0' => 10,
  60     '255.224.0.0' => 11,
  61     '255.240.0.0' => 12,
  62     '255.248.0.0' => 13,
  63     '255.252.0.0' => 14,
  64     '255.254.0.0' => 15,
  65     '255.255.0.0' => 16,
  66     '255.255.128.0' => 17,
  67     '255.255.192.0' => 18,
  68     '255.255.224.0' => 19,
  69     '255.255.240.0' => 20,
  70     '255.255.248.0' => 21,
  71     '255.255.252.0' => 22,
  72     '255.255.254.0' => 23,
  73     '255.255.255.0' => 24,
  74     '255.255.255.128' => 25,
  75     '255.255.255.192' => 26,
  76     '255.255.255.224' => 27,
  77     '255.255.255.240' => 28,
  78     '255.255.255.248' => 29,
  79     '255.255.255.252' => 30,
  80     '255.255.255.254' => 31,
  81     '255.255.255.255' => 32,
  82 };
  83
  84 sub setup_tc_rate_limit {
  85     my ($iface, $rate, $burst, $debug) = @_;
  86
  87     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  88     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  89     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  90     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  91     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  92
  93     return if !$rate;
  94
  95     # tbf does not work for unknown reason
  96     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  97     # so we use htb instead
  98     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  99     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 100                 "htb rate ${rate}bps burst ${burst}b");
 101
 102     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 103     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 104                 "prio 50 basic " .
 105                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 106                 "drop");
 107
 108     if ($debug) {
 109         print "DEBUG tc settings\n";
 110         system("/sbin/tc qdisc ls dev $iface");
 111         system("/sbin/tc class ls dev $iface");
 112         system("/sbin/tc filter ls dev $iface parent ffff:");
 113     }
 114 }
 115
 116 sub tap_rate_limit {
 117     my ($iface, $rate) = @_;
 118
 119     my $debug = 0;
 120     $rate = int($rate*1024*1024) if $rate;
 121     my $burst = 1024*1024;
 122
 123     setup_tc_rate_limit($iface, $rate, $burst, $debug);
 124 }
 125
 126 my $read_bridge_mtu = sub {
 127     my ($bridge) = @_;
 128
 129     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 130     die "bridge '$bridge' does not exist\n" if !$mtu;
 131     # avoid insecure dependency;
 132     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 133     $mtu = int($1);
 134
 135     return $mtu;
 136 };
 137
 138 my $parse_tap_device_name = sub {
 139     my ($iface, $noerr) = @_;
 140
 141     my ($vmid, $devid);
 142
 143     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 144         $vmid = $1;
 145         $devid = $2;
 146     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 147         $vmid = $1;
 148         $devid = $2;
 149     } else {
 150         return undef if $noerr;
 151         die "can't create firewall bridge for random interface name '$iface'\n";
 152     }
 153
 154     return ($vmid, $devid);
 155 };
 156
 157 my $compute_fwbr_names = sub {
 158     my ($vmid, $devid) = @_;
 159
 160     my $fwbr = "fwbr${vmid}i${devid}";
 161     # Note: the firewall use 'fwln+' to filter traffic to VMs
 162     my $vethfw = "fwln${vmid}i${devid}";
 163     my $vethfwpeer = "fwpr${vmid}p${devid}";
 164     my $ovsintport = "fwln${vmid}o${devid}";
 165
 166     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 167 };
 168
 169 sub iface_delete($) {
 170     my ($iface) = @_;
 171     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 172         == 0 or die "failed to delete interface '$iface'\n";
 173 }
 174
 175 sub iface_create($$@) {
 176     my ($iface, $type, @args) = @_;
 177     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 178         == 0 or die "failed to create interface '$iface'\n";
 179 }
 180
 181 sub iface_set($@) {
 182     my ($iface, @opts) = @_;
 183     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 184         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 185 }
 186
 187 # helper for nicer error messages:
 188 sub iface_set_master($$) {
 189     my ($iface, $master) = @_;
 190     if (defined($master)) {
 191         eval { iface_set($iface, 'master', $master) };
 192         die "can't enslave '$iface' to '$master'\n" if $@;
 193     } else {
 194         eval { iface_set($iface, 'nomaster') };
 195         die "can't unenslave '$iface'\n" if $@;
 196     }
 197 }
 198
 199 my $cond_create_bridge = sub {
 200     my ($bridge) = @_;
 201
 202     if (! -d "/sys/class/net/$bridge") {
 203         iface_create($bridge, 'bridge');
 204         disable_ipv6($bridge);
 205     }
 206 };
 207
 208 sub disable_ipv6 {
 209     my ($iface) = @_;
 210     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 211     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 212     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 213     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 214     close($fh);
 215 }
 216
 217 my $bridge_add_interface = sub {
 218     my ($bridge, $iface, $tag, $trunks) = @_;
 219
 220     # drop link local address (it can't be used when on a bridge anyway)
 221     disable_ipv6($iface);
 222     iface_set_master($iface, $bridge);
 223
 224    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 225
 226    if ($vlan_aware) {
 227         if ($tag) {
 228             system({'/sbin/bridge'} 'bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094') == 0
 229                 or die "failed to remove default vlan tags of $iface\n";
 230             system({'/sbin/bridge'} 'bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged') == 0
 231                 or die "unable to add vlan $tag to interface $iface\n";
 232
 233             warn "Caution: Setting VLAN ID 1 on a VLAN aware bridge may be dangerous\n" if $tag == 1;
 234         } else {
 235             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
 236             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
 237         }
 238
 239         if ($trunks) {
 240             my @trunks_array = split /;/, $trunks;
 241             foreach my $trunk (@trunks_array) {
 242                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
 243                 die "unable to add vlan $trunk to interface $iface\n";
 244             }
 245         }
 246    }
 247 };
 248
 249 my $ovs_bridge_add_port = sub {
 250     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 251
 252     $trunks =~ s/;/,/g if $trunks;
 253
 254     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 255     $cmd .= " tag=$tag" if $tag;
 256     $cmd .= " trunks=". join(',', $trunks) if $trunks;
 257     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
 258
 259     $cmd .= " -- set Interface $iface type=internal" if $internal;
 260     system($cmd) == 0 ||
 261         die "can't add ovs port '$iface'\n";
 262     disable_ipv6($iface);
 263 };
 264
 265 my $activate_interface = sub {
 266     my ($iface) = @_;
 267
 268     system("/sbin/ip link set $iface up") == 0 ||
 269         die "can't activate interface '$iface'\n";
 270 };
 271
 272 sub tap_create {
 273     my ($iface, $bridge) = @_;
 274
 275     my $have_sdn;
 276     eval {
 277         require PVE::Network::SDN::Zones;
 278         $have_sdn = 1;
 279     };
 280
 281     if ($have_sdn) {
 282         my ($bridgesdn, undef) = PVE::Network::SDN::Zones::get_bridge_vlan($bridge);
 283         $bridge = $bridgesdn if $bridgesdn;
 284     }
 285
 286     die "unable to get bridge setting\n" if !$bridge;
 287
 288     my $bridgemtu = &$read_bridge_mtu($bridge);
 289
 290     eval {
 291         disable_ipv6($iface);
 292         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 293     };
 294     die "interface activation failed\n" if $@;
 295 }
 296
 297 sub veth_create {
 298     my ($veth, $vethpeer, $bridge, $mac) = @_;
 299
 300     my $have_sdn;
 301     eval {
 302         require PVE::Network::SDN::Zones;
 303         $have_sdn = 1;
 304     };
 305
 306     if ($have_sdn) {
 307         my ($bridgesdn, undef) = PVE::Network::SDN::Zones::get_bridge_vlan($bridge);
 308         $bridge = $bridgesdn if $bridgesdn;
 309     }
 310
 311     die "unable to get bridge setting\n" if !$bridge;
 312
 313     my $bridgemtu = &$read_bridge_mtu($bridge);
 314
 315     # create veth pair
 316     if (! -d "/sys/class/net/$veth") {
 317         my $cmd = "/sbin/ip link add name $veth mtu $bridgemtu type veth peer name $vethpeer mtu $bridgemtu";
 318         $cmd .= " addr $mac" if $mac;
 319         system($cmd) == 0 || die "can't create interface $veth\n";
 320     }
 321
 322     # up vethpair
 323     disable_ipv6($veth);
 324     disable_ipv6($vethpeer);
 325     &$activate_interface($veth);
 326     &$activate_interface($vethpeer);
 327 }
 328
 329 sub veth_delete {
 330     my ($veth) = @_;
 331
 332     if (-d "/sys/class/net/$veth") {
 333         iface_delete($veth);
 334     }
 335     eval { tap_unplug($veth) };
 336 }
 337
 338 my $create_firewall_bridge_linux = sub {
 339     my ($iface, $bridge, $tag, $trunks) = @_;
 340
 341     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 342     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 343
 344     &$cond_create_bridge($fwbr);
 345     &$activate_interface($fwbr);
 346
 347     copy_bridge_config($bridge, $fwbr);
 348     veth_create($vethfw, $vethfwpeer, $bridge);
 349
 350     &$bridge_add_interface($fwbr, $vethfw);
 351     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 352
 353     &$bridge_add_interface($fwbr, $iface);
 354 };
 355
 356 my $create_firewall_bridge_ovs = sub {
 357     my ($iface, $bridge, $tag, $trunks) = @_;
 358
 359     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 360     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 361
 362     my $bridgemtu = &$read_bridge_mtu($bridge);
 363
 364     &$cond_create_bridge($fwbr);
 365     &$activate_interface($fwbr);
 366
 367     &$bridge_add_interface($fwbr, $iface);
 368
 369     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 370     &$activate_interface($ovsintport);
 371
 372     # set the same mtu for ovs int port
 373     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 374
 375     &$bridge_add_interface($fwbr, $ovsintport);
 376 };
 377
 378 my $cleanup_firewall_bridge = sub {
 379     my ($iface) = @_;
 380
 381     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 382     return if !defined($vmid);
 383     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 384
 385     # cleanup old port config from any openvswitch bridge
 386     if (-d "/sys/class/net/$ovsintport") {
 387         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 388     }
 389
 390     # delete old vethfw interface
 391     veth_delete($vethfw);
 392
 393     # cleanup fwbr bridge
 394     if (-d "/sys/class/net/$fwbr") {
 395         iface_delete($fwbr);
 396     }
 397 };
 398
 399 sub tap_plug {
 400     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 401
 402     my $have_sdn;
 403     eval {
 404         require PVE::Network::SDN::Zones;
 405         $have_sdn = 1;
 406     };
 407
 408     if ($have_sdn) {
 409         my ($bridgesdn, $tag) = PVE::Network::SDN::Zones::get_bridge_vlan($bridge);
 410         $bridge = $bridgesdn if $bridgesdn;
 411         $trunks = undef;
 412     }
 413
 414     #cleanup old port config from any openvswitch bridge
 415     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 416
 417     if (-d "/sys/class/net/$bridge/bridge") {
 418         &$cleanup_firewall_bridge($iface); # remove stale devices
 419
 420         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 421
 422         if (!$vlan_aware) {
 423             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 424             my $newbridge = activate_bridge_vlan($bridge, $tag);
 425             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 426             $bridge = $newbridge;
 427             $tag = undef;
 428         }
 429
 430         if ($firewall) {
 431             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 432         } else {
 433             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 434         }
 435
 436     } else {
 437         &$cleanup_firewall_bridge($iface); # remove stale devices
 438
 439         if ($firewall) {
 440             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 441         } else {
 442             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 443         }
 444     }
 445
 446     tap_rate_limit($iface, $rate);
 447 }
 448
 449 sub tap_unplug {
 450     my ($iface) = @_;
 451
 452     my $path= "/sys/class/net/$iface/brport/bridge";
 453     if (-l $path) {
 454         my $bridge = basename(readlink($path));
 455         #avoid insecure dependency;
 456         ($bridge) = $bridge =~ /(\S+)/;
 457
 458         iface_set_master($iface, undef);
 459     }
 460
 461     &$cleanup_firewall_bridge($iface);
 462     #cleanup old port config from any openvswitch bridge
 463     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 464 }
 465
 466 sub copy_bridge_config {
 467     my ($br0, $br1) = @_;
 468
 469     return if $br0 eq $br1;
 470
 471     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 472                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 473
 474     foreach my $sysname (@$br_configs) {
 475         eval {
 476             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 477             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 478             if ($v0 ne $v1) {
 479                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 480             }
 481         };
 482         warn $@ if $@;
 483     }
 484 }
 485
 486 sub activate_bridge_vlan_slave {
 487     my ($bridgevlan, $iface, $tag) = @_;
 488     my $ifacevlan = "${iface}.$tag";
 489
 490     # create vlan on $iface is not already exist
 491     if (! -d "/sys/class/net/$ifacevlan") {
 492         system("/sbin/ip link add link $iface name $ifacevlan type vlan id $tag") == 0 ||
 493             die "can't add vlan tag $tag to interface $iface\n";
 494
 495         # remove ipv6 link-local address before activation
 496         disable_ipv6($ifacevlan);
 497     }
 498
 499     # be sure to have the $ifacevlan up
 500     &$activate_interface($ifacevlan);
 501
 502     # test if $vlaniface is already enslaved in another bridge
 503     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 504     if (-l $path) {
 505         my $tbridge = basename(readlink($path));
 506         if ($tbridge ne $bridgevlan) {
 507             die "interface $ifacevlan already exist in bridge $tbridge\n";
 508         } else {
 509             # Port already attached to bridge: do nothing.
 510             return;
 511         }
 512     }
 513
 514     # add $ifacevlan to the bridge
 515     &$bridge_add_interface($bridgevlan, $ifacevlan);
 516 }
 517
 518 sub activate_bridge_vlan {
 519     my ($bridge, $tag_param) = @_;
 520
 521     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 522
 523     return $bridge if !defined($tag_param); # no vlan, simply return
 524
 525     my $tag = int($tag_param);
 526
 527     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 528
 529     my $bridgevlan = "${bridge}v$tag";
 530
 531     my @ifaces = ();
 532     my $dir = "/sys/class/net/$bridge/brif";
 533     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 534         push @ifaces, $_[0];
 535     });
 536
 537     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 538
 539     lock_network(sub {
 540         # add bridgevlan if it doesn't already exist
 541         if (! -d "/sys/class/net/$bridgevlan") {
 542             iface_create($bridgevlan, 'bridge');
 543         }
 544
 545         # for each physical interface (eth or bridge) bind them to bridge vlan
 546         foreach my $iface (@ifaces) {
 547             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 548         }
 549
 550         #fixme: set other bridge flags
 551
 552         # remove ipv6 link-local address before activation
 553         disable_ipv6($bridgevlan);
 554         # be sure to have the bridge up
 555         &$activate_interface($bridgevlan);
 556     });
 557     return $bridgevlan;
 558 }
 559
 560 sub tcp_ping {
 561     my ($host, $port, $timeout) = @_;
 562
 563     my $refused = 1;
 564
 565     $timeout = 3 if !$timeout; # sane default
 566     if (!$port) {
 567         # Net::Ping defaults to the echo port
 568         $port = 7;
 569     } else {
 570         # Net::Ping's port_number() implies service_check(1)
 571         $refused = 0;
 572     }
 573
 574     my ($sock, $result);
 575     eval {
 576         $result = PVE::Tools::run_with_timeout($timeout, sub {
 577             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 578             $result = $refused if $! == ECONNREFUSED;
 579         });
 580     };
 581     if ($sock) {
 582         $sock->close();
 583         $result = 1;
 584     }
 585     return $result;
 586 }
 587
 588 sub IP_from_cidr {
 589     my ($cidr, $version) = @_;
 590
 591     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 592     my ($ip, $prefix) = ($1, $2);
 593
 594     my $ipobj = Net::IP->new($ip, $version);
 595     return if !$ipobj;
 596
 597     $version = $ipobj->version();
 598
 599     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 600     return if !$binmask;
 601
 602     my $masked_binip = $ipobj->binip() & $binmask;
 603     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 604     return Net::IP->new("$masked_ip/$prefix");
 605 }
 606
 607 sub is_ip_in_cidr {
 608     my ($ip, $cidr, $version) = @_;
 609
 610     my $cidr_obj = IP_from_cidr($cidr, $version);
 611     return undef if !$cidr_obj;
 612
 613     my $ip_obj = Net::IP->new($ip, $version);
 614     return undef if !$ip_obj;
 615
 616     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
 617 }
 618
 619
 620 sub get_local_ip_from_cidr {
 621     my ($cidr) = @_;
 622
 623     my $IPs = [];
 624     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 625         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 626             push @$IPs, $1;
 627         }
 628     });
 629
 630     return $IPs;
 631 }
 632
 633 sub addr_to_ip {
 634     my ($addr) = @_;
 635     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 636     die "failed to get numerical host address: $err\n" if $err;
 637     return ($host, $port) if wantarray;
 638     return $host;
 639 }
 640
 641 sub get_ip_from_hostname {
 642     my ($hostname, $noerr) = @_;
 643
 644     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 645     if ($@) {
 646         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 647         return undef;
 648     }
 649
 650     my ($ip, $family);
 651     for my $ai (@res) {
 652         $family = $ai->{family};
 653         my $tmpip = addr_to_ip($ai->{addr});
 654         if ($tmpip !~ m/^127\.|^::1$/) {
 655             $ip = $tmpip;
 656             last;
 657         }
 658     }
 659     if (!defined($ip) ) {
 660         die "hostname lookup '$hostname' failed - got local IP address '$ip'\n" if !$noerr;
 661         return undef;
 662     }
 663
 664     return wantarray ? ($ip, $family) : $ip;
 665 }
 666
 667 sub lock_network {
 668     my ($code, @param) = @_;
 669     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 670     die $@ if $@;
 671     return $res;
 672 }
 673
 674 1;