src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use JSON;
  13 use Net::IP;
  14 use NetAddr::IP qw(:lower);
  15 use POSIX qw(ECONNREFUSED);
  16 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  17
  18 # host network related utility functions
  19
  20 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib[^:.]+)/;
  21
  22 our $ipv4_reverse_mask = [
  23     '0.0.0.0',
  24     '128.0.0.0',
  25     '192.0.0.0',
  26     '224.0.0.0',
  27     '240.0.0.0',
  28     '248.0.0.0',
  29     '252.0.0.0',
  30     '254.0.0.0',
  31     '255.0.0.0',
  32     '255.128.0.0',
  33     '255.192.0.0',
  34     '255.224.0.0',
  35     '255.240.0.0',
  36     '255.248.0.0',
  37     '255.252.0.0',
  38     '255.254.0.0',
  39     '255.255.0.0',
  40     '255.255.128.0',
  41     '255.255.192.0',
  42     '255.255.224.0',
  43     '255.255.240.0',
  44     '255.255.248.0',
  45     '255.255.252.0',
  46     '255.255.254.0',
  47     '255.255.255.0',
  48     '255.255.255.128',
  49     '255.255.255.192',
  50     '255.255.255.224',
  51     '255.255.255.240',
  52     '255.255.255.248',
  53     '255.255.255.252',
  54     '255.255.255.254',
  55     '255.255.255.255',
  56 ];
  57
  58 our $ipv4_mask_hash_localnet = {
  59     '255.0.0.0' => 8,
  60     '255.128.0.0' => 9,
  61     '255.192.0.0' => 10,
  62     '255.224.0.0' => 11,
  63     '255.240.0.0' => 12,
  64     '255.248.0.0' => 13,
  65     '255.252.0.0' => 14,
  66     '255.254.0.0' => 15,
  67     '255.255.0.0' => 16,
  68     '255.255.128.0' => 17,
  69     '255.255.192.0' => 18,
  70     '255.255.224.0' => 19,
  71     '255.255.240.0' => 20,
  72     '255.255.248.0' => 21,
  73     '255.255.252.0' => 22,
  74     '255.255.254.0' => 23,
  75     '255.255.255.0' => 24,
  76     '255.255.255.128' => 25,
  77     '255.255.255.192' => 26,
  78     '255.255.255.224' => 27,
  79     '255.255.255.240' => 28,
  80     '255.255.255.248' => 29,
  81     '255.255.255.252' => 30,
  82     '255.255.255.254' => 31,
  83     '255.255.255.255' => 32,
  84 };
  85
  86 sub setup_tc_rate_limit {
  87     my ($iface, $rate, $burst) = @_;
  88
  89     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  90     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  91     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  92     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  93     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  94
  95     return if !$rate;
  96
  97     # tbf does not work for unknown reason
  98     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  99     # so we use htb instead
 100     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
 101     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 102                 "htb rate ${rate}bps burst ${burst}b");
 103
 104     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 105     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 106                 "prio 50 basic " .
 107                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 108                 "drop");
 109 }
 110
 111 sub tap_rate_limit {
 112     my ($iface, $rate) = @_;
 113
 114     $rate = int($rate*1024*1024) if $rate;
 115     my $burst = 1024*1024;
 116
 117     setup_tc_rate_limit($iface, $rate, $burst);
 118 }
 119
 120 sub read_bridge_mtu {
 121     my ($bridge) = @_;
 122
 123     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 124     die "bridge '$bridge' does not exist\n" if !$mtu;
 125     # avoid insecure dependency;
 126     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 127     $mtu = int($1);
 128
 129     return $mtu;
 130 };
 131
 132 my $parse_tap_device_name = sub {
 133     my ($iface, $noerr) = @_;
 134
 135     my ($vmid, $devid);
 136
 137     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 138         $vmid = $1;
 139         $devid = $2;
 140     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 141         $vmid = $1;
 142         $devid = $2;
 143     } else {
 144         return undef if $noerr;
 145         die "can't create firewall bridge for random interface name '$iface'\n";
 146     }
 147
 148     return ($vmid, $devid);
 149 };
 150
 151 my $compute_fwbr_names = sub {
 152     my ($vmid, $devid) = @_;
 153
 154     my $fwbr = "fwbr${vmid}i${devid}";
 155     # Note: the firewall use 'fwln+' to filter traffic to VMs
 156     my $vethfw = "fwln${vmid}i${devid}";
 157     my $vethfwpeer = "fwpr${vmid}p${devid}";
 158     my $ovsintport = "fwln${vmid}o${devid}";
 159
 160     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 161 };
 162
 163 sub iface_delete($) {
 164     my ($iface) = @_;
 165     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 166         == 0 or die "failed to delete interface '$iface'\n";
 167 }
 168
 169 sub iface_create($$@) {
 170     my ($iface, $type, @args) = @_;
 171     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 172         == 0 or die "failed to create interface '$iface'\n";
 173 }
 174
 175 sub iface_set($@) {
 176     my ($iface, @opts) = @_;
 177     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 178         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 179 }
 180
 181 # helper for nicer error messages:
 182 sub iface_set_master($$) {
 183     my ($iface, $master) = @_;
 184     if (defined($master)) {
 185         eval { iface_set($iface, 'master', $master) };
 186         die "can't enslave '$iface' to '$master'\n" if $@;
 187     } else {
 188         eval { iface_set($iface, 'nomaster') };
 189         die "can't unenslave '$iface'\n" if $@;
 190     }
 191 }
 192
 193 my $cond_create_bridge = sub {
 194     my ($bridge) = @_;
 195
 196     if (! -d "/sys/class/net/$bridge") {
 197         iface_create($bridge, 'bridge');
 198         disable_ipv6($bridge);
 199     }
 200 };
 201
 202 sub disable_ipv6 {
 203     my ($iface) = @_;
 204     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 205     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 206     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 207     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 208     close($fh);
 209 }
 210
 211 my $bridge_add_interface = sub {
 212     my ($bridge, $iface, $tag, $trunks) = @_;
 213
 214     # drop link local address (it can't be used when on a bridge anyway)
 215     disable_ipv6($iface);
 216     iface_set_master($iface, $bridge);
 217
 218    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 219
 220    if ($vlan_aware) {
 221
 222         eval { run_command(['/sbin/bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094']) };
 223         die "failed to remove default vlan tags of $iface - $@\n" if $@;
 224
 225         if ($trunks) {
 226             my @trunks_array = split /;/, $trunks;
 227             foreach my $trunk (@trunks_array) {
 228                 eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $trunk]) };
 229                 die "unable to add vlan $trunk to interface $iface - $@\n" if $@;
 230             }
 231         } elsif (!$tag) {
 232             eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', '2-4094']) };
 233             die "unable to add default vlan tags to interface $iface - $@\n" if $@;
 234         }
 235
 236         $tag = 1 if !$tag;
 237         eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged']) };
 238         die "unable to add vlan $tag to interface $iface - $@\n" if $@;
 239    }
 240 };
 241
 242 my $ovs_bridge_add_port = sub {
 243     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 244
 245     $trunks =~ s/;/,/g if $trunks;
 246
 247     my $cmd = ['/usr/bin/ovs-vsctl'];
 248     # first command
 249     push @$cmd, '--', 'add-port', $bridge, $iface;
 250     push @$cmd, "tag=$tag" if $tag;
 251     push @$cmd, "trunks=". join(',', $trunks) if $trunks;
 252     push @$cmd, "vlan_mode=native-untagged" if $tag && $trunks;
 253
 254     if ($internal) {
 255         # second command
 256         push @$cmd, '--', 'set', 'Interface', $iface, 'type=internal';
 257     }
 258
 259     eval { run_command($cmd) };
 260     die "can't add ovs port '$iface' - $@\n" if $@;
 261
 262     disable_ipv6($iface);
 263 };
 264
 265 my $activate_interface = sub {
 266     my ($iface) = @_;
 267
 268     eval { run_command(['/sbin/ip', 'link', 'set', $iface, 'up']) };
 269     die "can't activate interface '$iface' - $@\n" if $@;
 270 };
 271
 272 sub tap_create {
 273     my ($iface, $bridge) = @_;
 274
 275     die "unable to get bridge setting\n" if !$bridge;
 276
 277     my $bridgemtu = read_bridge_mtu($bridge);
 278
 279     eval {
 280         disable_ipv6($iface);
 281         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 282     };
 283     die "interface activation failed\n" if $@;
 284 }
 285
 286 sub veth_create {
 287     my ($veth, $vethpeer, $bridge, $mac) = @_;
 288
 289     die "unable to get bridge setting\n" if !$bridge;
 290
 291     my $bridgemtu = read_bridge_mtu($bridge);
 292
 293     # create veth pair
 294     if (! -d "/sys/class/net/$veth") {
 295         my $cmd = ['/sbin/ip', 'link', 'add'];
 296         # veth device + MTU
 297         push @$cmd, 'name', $veth;
 298         push @$cmd, 'mtu', $bridgemtu;
 299         push @$cmd, 'type', 'veth';
 300         # peer device + MTU
 301         push @$cmd, 'peer', 'name', $vethpeer, 'mtu', $bridgemtu;
 302
 303         push @$cmd, 'addr', $mac if $mac;
 304
 305         eval { run_command($cmd) };
 306         die "can't create interface $veth - $@\n" if $@;
 307     }
 308
 309     # up vethpair
 310     disable_ipv6($veth);
 311     disable_ipv6($vethpeer);
 312     &$activate_interface($veth);
 313     &$activate_interface($vethpeer);
 314 }
 315
 316 sub veth_delete {
 317     my ($veth) = @_;
 318
 319     if (-d "/sys/class/net/$veth") {
 320         iface_delete($veth);
 321     }
 322     eval { tap_unplug($veth) };
 323 }
 324
 325 my $create_firewall_bridge_linux = sub {
 326     my ($iface, $bridge, $tag, $trunks) = @_;
 327
 328     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 329     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 330
 331     &$cond_create_bridge($fwbr);
 332     &$activate_interface($fwbr);
 333
 334     copy_bridge_config($bridge, $fwbr);
 335     veth_create($vethfw, $vethfwpeer, $bridge);
 336
 337     &$bridge_add_interface($fwbr, $vethfw);
 338     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 339
 340     &$bridge_add_interface($fwbr, $iface);
 341 };
 342
 343 my $create_firewall_bridge_ovs = sub {
 344     my ($iface, $bridge, $tag, $trunks) = @_;
 345
 346     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 347     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 348
 349     my $bridgemtu = read_bridge_mtu($bridge);
 350
 351     &$cond_create_bridge($fwbr);
 352     &$activate_interface($fwbr);
 353
 354     &$bridge_add_interface($fwbr, $iface);
 355
 356     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 357     &$activate_interface($ovsintport);
 358
 359     # set the same mtu for ovs int port
 360     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 361
 362     &$bridge_add_interface($fwbr, $ovsintport);
 363 };
 364
 365 my $cleanup_firewall_bridge = sub {
 366     my ($iface) = @_;
 367
 368     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 369     return if !defined($vmid);
 370     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 371
 372     # cleanup old port config from any openvswitch bridge
 373     if (-d "/sys/class/net/$ovsintport") {
 374         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 375     }
 376
 377     # delete old vethfw interface
 378     veth_delete($vethfw);
 379
 380     # cleanup fwbr bridge
 381     if (-d "/sys/class/net/$fwbr") {
 382         iface_delete($fwbr);
 383     }
 384 };
 385
 386 sub tap_plug {
 387     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 388
 389     #cleanup old port config from any openvswitch bridge
 390     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 391
 392     if (-d "/sys/class/net/$bridge/bridge") {
 393         &$cleanup_firewall_bridge($iface); # remove stale devices
 394
 395         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 396
 397         if (!$vlan_aware) {
 398             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 399             my $newbridge = activate_bridge_vlan($bridge, $tag);
 400             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 401             $bridge = $newbridge;
 402             $tag = undef;
 403         }
 404
 405         if ($firewall) {
 406             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 407         } else {
 408             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 409         }
 410
 411     } else {
 412         &$cleanup_firewall_bridge($iface); # remove stale devices
 413
 414         if ($firewall) {
 415             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 416         } else {
 417             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 418         }
 419     }
 420
 421     tap_rate_limit($iface, $rate);
 422 }
 423
 424 sub tap_unplug {
 425     my ($iface) = @_;
 426
 427     my $path= "/sys/class/net/$iface/brport/bridge";
 428     if (-l $path) {
 429         my $bridge = basename(readlink($path));
 430         #avoid insecure dependency;
 431         ($bridge) = $bridge =~ /(\S+)/;
 432
 433         iface_set_master($iface, undef);
 434     }
 435
 436     &$cleanup_firewall_bridge($iface);
 437     #cleanup old port config from any openvswitch bridge
 438     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 439 }
 440
 441 sub copy_bridge_config {
 442     my ($br0, $br1) = @_;
 443
 444     return if $br0 eq $br1;
 445
 446     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 447                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 448
 449     foreach my $sysname (@$br_configs) {
 450         eval {
 451             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 452             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 453             if ($v0 ne $v1) {
 454                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 455             }
 456         };
 457         warn $@ if $@;
 458     }
 459 }
 460
 461 sub activate_bridge_vlan_slave {
 462     my ($bridgevlan, $iface, $tag) = @_;
 463     my $ifacevlan = "${iface}.$tag";
 464
 465     # create vlan on $iface is not already exist
 466     if (! -d "/sys/class/net/$ifacevlan") {
 467         eval {
 468             my $cmd = ['/sbin/ip', 'link', 'add'];
 469             push @$cmd, 'link', $iface;
 470             push @$cmd, 'name', $ifacevlan;
 471             push @$cmd, 'type', 'vlan', 'id', $tag;
 472             run_command($cmd);
 473         };
 474         die "can't add vlan tag $tag to interface $iface - $@\n" if $@;
 475
 476         # remove ipv6 link-local address before activation
 477         disable_ipv6($ifacevlan);
 478     }
 479
 480     # be sure to have the $ifacevlan up
 481     &$activate_interface($ifacevlan);
 482
 483     # test if $vlaniface is already enslaved in another bridge
 484     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 485     if (-l $path) {
 486         my $tbridge = basename(readlink($path));
 487         if ($tbridge ne $bridgevlan) {
 488             die "interface $ifacevlan already exist in bridge $tbridge\n";
 489         } else {
 490             # Port already attached to bridge: do nothing.
 491             return;
 492         }
 493     }
 494
 495     # add $ifacevlan to the bridge
 496     &$bridge_add_interface($bridgevlan, $ifacevlan);
 497 }
 498
 499 sub activate_bridge_vlan {
 500     my ($bridge, $tag_param) = @_;
 501
 502     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 503
 504     return $bridge if !defined($tag_param); # no vlan, simply return
 505
 506     my $tag = int($tag_param);
 507
 508     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 509
 510     my $bridgevlan = "${bridge}v$tag";
 511
 512     my @ifaces = ();
 513     my $dir = "/sys/class/net/$bridge/brif";
 514     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 515         push @ifaces, $_[0];
 516     });
 517
 518     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 519
 520     lock_network(sub {
 521         # add bridgevlan if it doesn't already exist
 522         if (! -d "/sys/class/net/$bridgevlan") {
 523             iface_create($bridgevlan, 'bridge');
 524         }
 525
 526         # for each physical interface (eth or bridge) bind them to bridge vlan
 527         foreach my $iface (@ifaces) {
 528             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 529         }
 530
 531         #fixme: set other bridge flags
 532
 533         # remove ipv6 link-local address before activation
 534         disable_ipv6($bridgevlan);
 535         # be sure to have the bridge up
 536         &$activate_interface($bridgevlan);
 537     });
 538     return $bridgevlan;
 539 }
 540
 541 sub tcp_ping {
 542     my ($host, $port, $timeout) = @_;
 543
 544     my $refused = 1;
 545
 546     $timeout = 3 if !$timeout; # sane default
 547     if (!$port) {
 548         # Net::Ping defaults to the echo port
 549         $port = 7;
 550     } else {
 551         # Net::Ping's port_number() implies service_check(1)
 552         $refused = 0;
 553     }
 554
 555     my ($sock, $result);
 556     eval {
 557         $result = PVE::Tools::run_with_timeout($timeout, sub {
 558             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 559             $result = $refused if $! == ECONNREFUSED;
 560         });
 561     };
 562     if ($sock) {
 563         $sock->close();
 564         $result = 1;
 565     }
 566     return $result;
 567 }
 568
 569 sub IP_from_cidr {
 570     my ($cidr, $version) = @_;
 571
 572     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 573     my ($ip, $prefix) = ($1, $2);
 574
 575     my $ipobj = Net::IP->new($ip, $version);
 576     return if !$ipobj;
 577
 578     $version = $ipobj->version();
 579
 580     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 581     return if !$binmask;
 582
 583     my $masked_binip = $ipobj->binip() & $binmask;
 584     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 585     return Net::IP->new("$masked_ip/$prefix");
 586 }
 587
 588 sub is_ip_in_cidr {
 589     my ($ip, $cidr, $version) = @_;
 590
 591     my $cidr_obj = IP_from_cidr($cidr, $version);
 592     return undef if !$cidr_obj;
 593
 594     my $ip_obj = Net::IP->new($ip, $version);
 595     return undef if !$ip_obj;
 596
 597     my $overlap = $cidr_obj->overlaps($ip_obj);
 598
 599     return if !defined($overlap);
 600
 601     return $overlap == $Net::IP::IP_B_IN_A_OVERLAP || $overlap == $Net::IP::IP_IDENTICAL;
 602 }
 603
 604 # get all currently configured addresses that have a global scope, i.e., are reachable from the
 605 # outside of the host and thus are neither loopback nor link-local ones
 606 # returns an array ref of: { addr => "IP", cidr => "IP/PREFIXLEN", family => "inet|inet6" }
 607 sub get_reachable_networks {
 608     my $raw = '';
 609     run_command([qw(ip -j addr show up scope global)], outfunc => sub { $raw .= shift });
 610     my $decoded = decode_json($raw);
 611
 612     my $addrs = []; # filter/transform first so that we can sort correctly more easily below
 613     for my $e ($decoded->@*) {
 614         next if !$e->{addr_info} || grep { $_ eq 'LOOPBACK' } $e->{flags}->@*;
 615         push $addrs->@*, grep { scalar(keys $_->%*) } $e->{addr_info}->@*
 616     }
 617     my $res = [];
 618     for my $info (sort { $a->{family} cmp $b->{family} || $a->{local} cmp $b->{local} } $addrs->@*) {
 619         push $res->@*, {
 620             addr => $info->{local},
 621             cidr => "$info->{local}/$info->{prefixlen}",
 622             family => $info->{family},
 623         };
 624     }
 625
 626     return $res;
 627 }
 628
 629 # get one or all local IPs that are not loopback ones, able to pick up the following ones (in order)
 630 # - the hostname primary resolves too, follows gai.conf (admin controlled) and will be prioritised
 631 # - all configured in the interfaces configuration
 632 # - all currently networks known to the kernel in the current (root) namespace
 633 # returns a single address if no parameter is passed, and all found, grouped by type, if `all => 1`
 634 # is passed.
 635 sub get_local_ip {
 636     my (%param) = @_;
 637
 638     my $nodename = PVE::INotify::nodename();
 639     my $resolved_host = eval { get_ip_from_hostname($nodename) };
 640
 641     return $resolved_host if defined($resolved_host) && !$param{all};
 642
 643     my $all = { v4 => {}, v6 => {} }; # hash to avoid duplicates and group by type
 644
 645     my $ifaces = PVE::INotify::read_file('interfaces', 1)->{data}->{ifaces};
 646     for my $if (values $ifaces->%*) {
 647         next if $if->{type} eq 'loopback' || (!defined($if->{address}) && !defined($if->{address6}));
 648         my ($v4, $v6) = ($if->{address}, $if->{address6});
 649
 650         return ($v4 // $v6) if !$param{all}; # prefer v4, admin can override $resolved_host via hosts/gai.conf
 651
 652         $all->{v4}->{$v4} = 1 if defined($v4);
 653         $all->{v6}->{$v6} = 1 if defined($v6);
 654     }
 655
 656     my $live = eval { get_reachable_networks() } // [];
 657     for my $info ($live->@*) {
 658         my $addr = $info->{addr};
 659
 660         return $addr if !$param{all};
 661
 662         if ($info->{family} eq 'inet') {
 663             $all->{v4}->{$addr} = 1;
 664         } else {
 665             $all->{v6}->{$addr} = 1;
 666         }
 667     }
 668
 669     return undef if !$param{all}; # getting here means no early return above triggered -> no IPs
 670
 671     my $res = []; # order gai.conf controlled first, then group v4 and v6, simply lexically sorted
 672     if ($resolved_host) {
 673         push $res->@*, $resolved_host;
 674         delete $all->{v4}->{$resolved_host};
 675         delete $all->{v6}->{$resolved_host};
 676     }
 677     push $res->@*, sort { $a cmp $b } keys $all->{v4}->%*;
 678     push $res->@*, sort { $a cmp $b } keys $all->{v6}->%*;
 679
 680     return $res;
 681 }
 682
 683 sub get_local_ip_from_cidr {
 684     my ($cidr) = @_;
 685
 686     my $IPs = {};
 687     my $i = 1;
 688     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 689         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 690             $IPs->{$1} = $i++ if !exists($IPs->{$1});
 691         }
 692     });
 693
 694     return [ sort { $IPs->{$a} <=> $IPs->{$b} } keys %{$IPs} ];
 695 }
 696
 697 sub addr_to_ip {
 698     my ($addr) = @_;
 699     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 700     die "failed to get numerical host address: $err\n" if $err;
 701     return ($host, $port) if wantarray;
 702     return $host;
 703 }
 704
 705 sub get_ip_from_hostname {
 706     my ($hostname, $noerr) = @_;
 707
 708     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 709     if ($@) {
 710         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 711         return undef;
 712     }
 713
 714     for my $ai (@res) {
 715         my $ip = addr_to_ip($ai->{addr});
 716         if ($ip !~ m/^127\.|^::1$/) {
 717             return wantarray ? ($ip, $ai->{family}) : $ip;
 718         }
 719     }
 720     # NOTE: we only get here if no WAN/LAN IP was found, so this is now the error path!
 721     die "address lookup for '$hostname' did not find any IP address\n" if !$noerr;
 722     return undef;
 723 }
 724
 725 sub lock_network {
 726     my ($code, @param) = @_;
 727     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 728     die $@ if $@;
 729     return $res;
 730 }
 731
 732 # the canonical form of the given IP, i.e. dotted quad for IPv4 and RFC 5952 for IPv6
 733 sub canonical_ip {
 734     my ($ip) = @_;
 735
 736     my $ip_obj = NetAddr::IP->new($ip) or die "invalid IP string '$ip'\n";
 737
 738     return $ip_obj->canon();
 739 }
 740
 741 # List of unique, canonical IPs in the provided list.
 742 # Keeps the original order, filtering later duplicates.
 743 sub unique_ips {
 744     my ($ips) = @_;
 745
 746     my $res = [];
 747     my $seen = {};
 748
 749     for my $ip (@{$ips}) {
 750         $ip = canonical_ip($ip);
 751
 752         next if $seen->{$ip};
 753
 754         $seen->{$ip} = 1;
 755         push @{$res}, $ip;
 756     }
 757
 758     return $res;
 759 }
 760
 761 1;