src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use JSON;
  13 use Net::IP;
  14 use NetAddr::IP qw(:lower);
  15 use POSIX qw(ECONNREFUSED);
  16 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  17
  18 # host network related utility functions
  19
  20 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib[^:.]+)/;
  21
  22 our $ipv4_reverse_mask = [
  23     '0.0.0.0',
  24     '128.0.0.0',
  25     '192.0.0.0',
  26     '224.0.0.0',
  27     '240.0.0.0',
  28     '248.0.0.0',
  29     '252.0.0.0',
  30     '254.0.0.0',
  31     '255.0.0.0',
  32     '255.128.0.0',
  33     '255.192.0.0',
  34     '255.224.0.0',
  35     '255.240.0.0',
  36     '255.248.0.0',
  37     '255.252.0.0',
  38     '255.254.0.0',
  39     '255.255.0.0',
  40     '255.255.128.0',
  41     '255.255.192.0',
  42     '255.255.224.0',
  43     '255.255.240.0',
  44     '255.255.248.0',
  45     '255.255.252.0',
  46     '255.255.254.0',
  47     '255.255.255.0',
  48     '255.255.255.128',
  49     '255.255.255.192',
  50     '255.255.255.224',
  51     '255.255.255.240',
  52     '255.255.255.248',
  53     '255.255.255.252',
  54     '255.255.255.254',
  55     '255.255.255.255',
  56 ];
  57
  58 our $ipv4_mask_hash_localnet = {
  59     '255.0.0.0' => 8,
  60     '255.128.0.0' => 9,
  61     '255.192.0.0' => 10,
  62     '255.224.0.0' => 11,
  63     '255.240.0.0' => 12,
  64     '255.248.0.0' => 13,
  65     '255.252.0.0' => 14,
  66     '255.254.0.0' => 15,
  67     '255.255.0.0' => 16,
  68     '255.255.128.0' => 17,
  69     '255.255.192.0' => 18,
  70     '255.255.224.0' => 19,
  71     '255.255.240.0' => 20,
  72     '255.255.248.0' => 21,
  73     '255.255.252.0' => 22,
  74     '255.255.254.0' => 23,
  75     '255.255.255.0' => 24,
  76     '255.255.255.128' => 25,
  77     '255.255.255.192' => 26,
  78     '255.255.255.224' => 27,
  79     '255.255.255.240' => 28,
  80     '255.255.255.248' => 29,
  81     '255.255.255.252' => 30,
  82     '255.255.255.254' => 31,
  83     '255.255.255.255' => 32,
  84 };
  85
  86 sub setup_tc_rate_limit {
  87     my ($iface, $rate, $burst) = @_;
  88
  89     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  90     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  91     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  92     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  93     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  94
  95     return if !$rate;
  96
  97     # tbf does not work for unknown reason
  98     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  99     # so we use htb instead
 100     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
 101     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 102                 "htb rate ${rate}bps burst ${burst}b");
 103
 104     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 105     run_command(
 106         "/sbin/tc filter add dev $iface parent ffff: prio 50 basic police rate ${rate}bps burst ${burst}b mtu 64kb drop");
 107
 108     return;
 109 }
 110
 111 sub tap_rate_limit {
 112     my ($iface, $rate) = @_;
 113
 114     $rate = int($rate*1024*1024) if $rate;
 115     my $burst = 1024*1024;
 116
 117     setup_tc_rate_limit($iface, $rate, $burst);
 118
 119     return;
 120 }
 121
 122 sub read_bridge_mtu {
 123     my ($bridge) = @_;
 124
 125     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 126     die "bridge '$bridge' does not exist\n" if !$mtu;
 127
 128     if ($mtu =~ /^(\d+)$/) { # avoid insecure dependency (untaint)
 129         $mtu = int($1);
 130     } else {
 131         die "unexpeted error: unable to parse mtu value '$mtu' as integer\n";
 132     }
 133
 134     return $mtu;
 135 }
 136
 137 my $parse_tap_device_name = sub {
 138     my ($iface, $noerr) = @_;
 139
 140     my ($vmid, $devid);
 141
 142     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 143         $vmid = $1;
 144         $devid = $2;
 145     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 146         $vmid = $1;
 147         $devid = $2;
 148     } else {
 149         return if $noerr;
 150         die "can't create firewall bridge for random interface name '$iface'\n";
 151     }
 152
 153     return ($vmid, $devid);
 154 };
 155
 156 my $compute_fwbr_names = sub {
 157     my ($vmid, $devid) = @_;
 158
 159     my $fwbr = "fwbr${vmid}i${devid}";
 160     # Note: the firewall use 'fwln+' to filter traffic to VMs
 161     my $vethfw = "fwln${vmid}i${devid}";
 162     my $vethfwpeer = "fwpr${vmid}p${devid}";
 163     my $ovsintport = "fwln${vmid}o${devid}";
 164
 165     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 166 };
 167
 168 sub iface_delete :prototype($) {
 169     my ($iface) = @_;
 170     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 171         == 0 or die "failed to delete interface '$iface'\n";
 172     return;
 173 }
 174
 175 sub iface_create :prototype($$@) {
 176     my ($iface, $type, @args) = @_;
 177     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 178         == 0 or die "failed to create interface '$iface'\n";
 179     return;
 180 }
 181
 182 sub iface_set :prototype($@) {
 183     my ($iface, @opts) = @_;
 184     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 185         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 186     return;
 187 }
 188
 189 # helper for nicer error messages:
 190 sub iface_set_master :prototype($$) {
 191     my ($iface, $master) = @_;
 192     if (defined($master)) {
 193         eval { iface_set($iface, 'master', $master) };
 194         die "can't enslave '$iface' to '$master'\n" if $@;
 195     } else {
 196         eval { iface_set($iface, 'nomaster') };
 197         die "can't unenslave '$iface'\n" if $@;
 198     }
 199     return;
 200 }
 201
 202 my $cond_create_bridge = sub {
 203     my ($bridge) = @_;
 204
 205     if (! -d "/sys/class/net/$bridge") {
 206         iface_create($bridge, 'bridge');
 207         disable_ipv6($bridge);
 208     }
 209 };
 210
 211 sub disable_ipv6 {
 212     my ($iface) = @_;
 213     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 214     return if !-e $file; # ipv6 might be completely disabled
 215     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 216     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 217     close($fh);
 218     return;
 219 }
 220
 221 my $bridge_disable_interface_learning = sub {
 222     my ($iface) = @_;
 223
 224     PVE::ProcFSTools::write_proc_entry("/sys/class/net/$iface/brport/unicast_flood", "0");
 225     PVE::ProcFSTools::write_proc_entry("/sys/class/net/$iface/brport/learning", "0");
 226
 227 };
 228
 229 my $bridge_add_interface = sub {
 230     my ($bridge, $iface, $tag, $trunks) = @_;
 231
 232     my $bridgemtu = read_bridge_mtu($bridge);
 233     eval { run_command(['/sbin/ip', 'link', 'set', $iface, 'mtu', $bridgemtu]) };
 234
 235     # drop link local address (it can't be used when on a bridge anyway)
 236     disable_ipv6($iface);
 237     iface_set_master($iface, $bridge);
 238
 239    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 240
 241    if ($vlan_aware) {
 242
 243         eval { run_command(['/sbin/bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094']) };
 244         die "failed to remove default vlan tags of $iface - $@\n" if $@;
 245
 246         if ($trunks) {
 247             my @trunks_array = split /;/, $trunks;
 248             foreach my $trunk (@trunks_array) {
 249                 eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $trunk]) };
 250                 die "unable to add vlan $trunk to interface $iface - $@\n" if $@;
 251             }
 252         } elsif (!$tag) {
 253             eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', '2-4094']) };
 254             die "unable to add default vlan tags to interface $iface - $@\n" if $@;
 255         }
 256
 257         $tag = 1 if !$tag;
 258         eval { run_command(['/sbin/bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged']) };
 259         die "unable to add vlan $tag to interface $iface - $@\n" if $@;
 260    }
 261 };
 262
 263 my $ovs_bridge_add_port = sub {
 264     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 265
 266     $trunks =~ s/;/,/g if $trunks;
 267
 268     my $cmd = ['/usr/bin/ovs-vsctl'];
 269     # first command
 270     push @$cmd, '--', 'add-port', $bridge, $iface;
 271     push @$cmd, "tag=$tag" if $tag;
 272     push @$cmd, "trunks=". join(',', $trunks) if $trunks;
 273     push @$cmd, "vlan_mode=native-untagged" if $tag && $trunks;
 274
 275     my $bridgemtu = read_bridge_mtu($bridge);
 276     push @$cmd, '--', 'set', 'Interface', $iface, "mtu_request=$bridgemtu";
 277
 278     if ($internal) {
 279         # second command
 280         push @$cmd, '--', 'set', 'Interface', $iface, 'type=internal';
 281     }
 282
 283     eval { run_command($cmd) };
 284     die "can't add ovs port '$iface' - $@\n" if $@;
 285
 286     disable_ipv6($iface);
 287 };
 288
 289 my $activate_interface = sub {
 290     my ($iface, $mtu) = @_;
 291
 292     my $cmd = ['/sbin/ip', 'link', 'set', $iface, 'up'];
 293     push @$cmd, ('mtu', $mtu) if $mtu;
 294
 295     eval { run_command($cmd) };
 296     die "can't activate interface '$iface' - $@\n" if $@;
 297 };
 298
 299 sub add_bridge_fdb {
 300     my ($iface, $mac) = @_;
 301
 302     my $learning = PVE::Tools::file_read_firstline("/sys/class/net/$iface/brport/learning");
 303     return if !defined($learning) || $learning == 1;
 304
 305     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 306     return if !defined($vmid);
 307
 308     run_command(['/sbin/bridge', 'fdb', 'append', $mac, 'dev', $iface, 'master', 'static']);
 309
 310     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 311
 312     if (-d "/sys/class/net/$vethfwpeer") {
 313         run_command(['/sbin/bridge', 'fdb', 'append', $mac, 'dev', $vethfwpeer, 'master', 'static']);
 314     }
 315
 316     return;
 317 }
 318
 319 sub del_bridge_fdb {
 320     my ($iface, $mac) = @_;
 321
 322     my $learning = PVE::Tools::file_read_firstline("/sys/class/net/$iface/brport/learning");
 323     return if !defined($learning) || $learning == 1;
 324
 325     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 326     return if !defined($vmid);
 327
 328     run_command(['/sbin/bridge', 'fdb', 'del', $mac, 'dev', $iface, 'master', 'static']);
 329
 330     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 331
 332     if (-d "/sys/class/net/$vethfwpeer") {
 333         run_command(['/sbin/bridge', 'fdb', 'del', $mac, 'dev', $vethfwpeer, 'master', 'static']);
 334     }
 335
 336     return;
 337 }
 338
 339 sub tap_create {
 340     my ($iface, $bridge) = @_;
 341
 342     die "unable to get bridge setting\n" if !$bridge;
 343
 344     my $bridgemtu = read_bridge_mtu($bridge);
 345
 346     eval {
 347         disable_ipv6($iface);
 348         run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 349     };
 350     die "interface activation failed\n" if $@;
 351     return;
 352 }
 353
 354 sub veth_create {
 355     my ($veth, $vethpeer, $bridge, $mac) = @_;
 356
 357     die "unable to get bridge setting\n" if !$bridge;
 358
 359     my $bridgemtu = read_bridge_mtu($bridge);
 360
 361     # create veth pair
 362     if (! -d "/sys/class/net/$veth") {
 363         my $cmd = ['/sbin/ip', 'link', 'add'];
 364         # veth device + MTU
 365         push @$cmd, 'name', $veth;
 366         push @$cmd, 'mtu', $bridgemtu;
 367         push @$cmd, 'type', 'veth';
 368         # peer device + MTU
 369         push @$cmd, 'peer', 'name', $vethpeer, 'mtu', $bridgemtu;
 370
 371         push @$cmd, 'addr', $mac if $mac;
 372
 373         eval { run_command($cmd) };
 374         die "can't create interface $veth - $@\n" if $@;
 375     }
 376
 377     # up vethpair
 378     disable_ipv6($veth);
 379     disable_ipv6($vethpeer);
 380     &$activate_interface($veth, $bridgemtu);
 381     &$activate_interface($vethpeer, $bridgemtu);
 382
 383     return;
 384 }
 385
 386 sub veth_delete {
 387     my ($veth) = @_;
 388
 389     if (-d "/sys/class/net/$veth") {
 390         iface_delete($veth);
 391     }
 392     eval { tap_unplug($veth) };
 393     return;
 394 }
 395
 396 my $create_firewall_bridge_linux = sub {
 397     my ($iface, $bridge, $tag, $trunks, $no_learning) = @_;
 398
 399     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 400     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 401
 402     my $bridgemtu = read_bridge_mtu($bridge);
 403
 404     &$cond_create_bridge($fwbr);
 405     &$activate_interface($fwbr, $bridgemtu);
 406
 407     copy_bridge_config($bridge, $fwbr);
 408     veth_create($vethfw, $vethfwpeer, $bridge);
 409
 410     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 411     &$bridge_disable_interface_learning($vethfwpeer) if $no_learning;
 412     &$bridge_add_interface($fwbr, $vethfw);
 413
 414     &$bridge_add_interface($fwbr, $iface);
 415 };
 416
 417 my $create_firewall_bridge_ovs = sub {
 418     my ($iface, $bridge, $tag, $trunks, $no_learning) = @_;
 419
 420     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 421     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 422
 423     my $bridgemtu = read_bridge_mtu($bridge);
 424
 425     &$cond_create_bridge($fwbr);
 426     &$activate_interface($fwbr, $bridgemtu);
 427
 428     &$bridge_add_interface($fwbr, $iface);
 429
 430     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 431     &$activate_interface($ovsintport, $bridgemtu);
 432
 433     &$bridge_add_interface($fwbr, $ovsintport);
 434     &$bridge_disable_interface_learning($ovsintport) if $no_learning;
 435 };
 436
 437 my $cleanup_firewall_bridge = sub {
 438     my ($iface) = @_;
 439
 440     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 441     return if !defined($vmid);
 442     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 443
 444     # cleanup old port config from any openvswitch bridge
 445     if (-d "/sys/class/net/$ovsintport") {
 446         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 447     }
 448
 449     # delete old vethfw interface
 450     veth_delete($vethfw);
 451
 452     # cleanup fwbr bridge
 453     if (-d "/sys/class/net/$fwbr") {
 454         iface_delete($fwbr);
 455     }
 456 };
 457
 458 sub tap_plug {
 459     my ($iface, $bridge, $tag, $firewall, $trunks, $rate, $opts) = @_;
 460
 461     $opts = {} if !defined($opts);
 462     $opts = { learning => $opts } if !ref($opts); # FIXME: backward compat, drop with PVE 8.0
 463
 464     if (!defined($opts->{learning})) { # auto-detect
 465         $opts = {} if !defined($opts);
 466         my $interfaces_config = PVE::INotify::read_file('interfaces');
 467         my $bridge = $interfaces_config->{ifaces}->{$bridge};
 468         $opts->{learning} = !($bridge && $bridge->{'bridge-disable-mac-learning'}); # default learning to on
 469     }
 470     my $no_learning = !$opts->{learning};
 471
 472     # cleanup old port config from any openvswitch bridge
 473     eval {
 474         run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {});
 475     };
 476
 477     if (-d "/sys/class/net/$bridge/bridge") {
 478         &$cleanup_firewall_bridge($iface); # remove stale devices
 479
 480         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 481
 482         if (!$vlan_aware) {
 483             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 484             my $newbridge = activate_bridge_vlan($bridge, $tag);
 485             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 486             $bridge = $newbridge;
 487             $tag = undef;
 488         }
 489
 490         if ($firewall) {
 491             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks, $no_learning);
 492         } else {
 493             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 494         }
 495         if ($no_learning) {
 496             $bridge_disable_interface_learning->($iface);
 497             add_bridge_fdb($iface, $opts->{mac}) if defined($opts->{mac});
 498         }
 499
 500     } else {
 501         &$cleanup_firewall_bridge($iface); # remove stale devices
 502
 503         if ($firewall) {
 504             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks, $no_learning);
 505         } else {
 506             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 507         }
 508     }
 509
 510     tap_rate_limit($iface, $rate);
 511
 512     return;
 513 }
 514
 515 sub tap_unplug {
 516     my ($iface) = @_;
 517
 518     my $path = "/sys/class/net/$iface/brport/bridge";
 519     if (-l $path) {
 520         my $bridge = basename(readlink($path));
 521         #avoid insecure dependency;
 522         ($bridge) = $bridge =~ /(\S+)/;
 523
 524         iface_set_master($iface, undef);
 525     }
 526
 527     &$cleanup_firewall_bridge($iface);
 528     #cleanup old port config from any openvswitch bridge
 529     eval { run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 530
 531     return;
 532 }
 533
 534 sub copy_bridge_config {
 535     my ($br0, $br1) = @_;
 536
 537     return if $br0 eq $br1;
 538
 539     my $br_configs = [
 540         'ageing_time', 'stp_state', 'priority', 'forward_delay',
 541         'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier',
 542     ];
 543
 544     foreach my $sysname (@$br_configs) {
 545         eval {
 546             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 547             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 548             if ($v0 ne $v1) {
 549                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 550             }
 551         };
 552         warn $@ if $@;
 553     }
 554     return;
 555 }
 556
 557 sub activate_bridge_vlan_slave {
 558     my ($bridgevlan, $iface, $tag) = @_;
 559     my $ifacevlan = "${iface}.$tag";
 560
 561     # create vlan on $iface is not already exist
 562     if (! -d "/sys/class/net/$ifacevlan") {
 563         eval {
 564             my $cmd = ['/sbin/ip', 'link', 'add'];
 565             push @$cmd, 'link', $iface;
 566             push @$cmd, 'name', $ifacevlan;
 567             push @$cmd, 'type', 'vlan', 'id', $tag;
 568             run_command($cmd);
 569         };
 570         die "can't add vlan tag $tag to interface $iface - $@\n" if $@;
 571
 572         # remove ipv6 link-local address before activation
 573         disable_ipv6($ifacevlan);
 574     }
 575
 576     # be sure to have the $ifacevlan up
 577     &$activate_interface($ifacevlan);
 578
 579     # test if $vlaniface is already enslaved in another bridge
 580     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 581     if (-l $path) {
 582         my $tbridge = basename(readlink($path));
 583         if ($tbridge ne $bridgevlan) {
 584             die "interface $ifacevlan already exist in bridge $tbridge\n";
 585         } else {
 586             # Port already attached to bridge: do nothing.
 587             return;
 588         }
 589     }
 590
 591     # add $ifacevlan to the bridge
 592     &$bridge_add_interface($bridgevlan, $ifacevlan);
 593     return;
 594 }
 595
 596 sub activate_bridge_vlan {
 597     my ($bridge, $tag_param) = @_;
 598
 599     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 600
 601     return $bridge if !defined($tag_param); # no vlan, simply return
 602
 603     my $tag = int($tag_param);
 604
 605     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 606
 607     my $bridgevlan = "${bridge}v$tag";
 608
 609     my @ifaces = ();
 610     my $dir = "/sys/class/net/$bridge/brif";
 611     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 612         push @ifaces, $_[0];
 613     });
 614
 615     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 616
 617     lock_network(sub {
 618         # add bridgevlan if it doesn't already exist
 619         if (! -d "/sys/class/net/$bridgevlan") {
 620             iface_create($bridgevlan, 'bridge');
 621         }
 622
 623         my $bridgemtu = read_bridge_mtu($bridge);
 624         eval { run_command(['/sbin/ip', 'link', 'set', $bridgevlan, 'mtu', $bridgemtu]) };
 625
 626         # for each physical interface (eth or bridge) bind them to bridge vlan
 627         foreach my $iface (@ifaces) {
 628             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 629         }
 630
 631         #fixme: set other bridge flags
 632
 633         # remove ipv6 link-local address before activation
 634         disable_ipv6($bridgevlan);
 635         # be sure to have the bridge up
 636         &$activate_interface($bridgevlan);
 637     });
 638     return $bridgevlan;
 639 }
 640
 641 sub tcp_ping {
 642     my ($host, $port, $timeout) = @_;
 643
 644     my $refused = 1;
 645
 646     $timeout = 3 if !$timeout; # sane default
 647     if (!$port) {
 648         # Net::Ping defaults to the echo port
 649         $port = 7;
 650     } else {
 651         # Net::Ping's port_number() implies service_check(1)
 652         $refused = 0;
 653     }
 654
 655     my ($sock, $result);
 656     eval {
 657         $result = PVE::Tools::run_with_timeout($timeout, sub {
 658             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 659             $result = $refused if $! == ECONNREFUSED;
 660         });
 661     };
 662     if ($sock) {
 663         $sock->close();
 664         $result = 1;
 665     }
 666     return $result;
 667 }
 668
 669 sub IP_from_cidr {
 670     my ($cidr, $version) = @_;
 671
 672     my ($ip, $prefix) = $cidr =~ m!^(\S+?)/(\S+)$! or return;
 673
 674     my $ipobj = Net::IP->new($ip, $version);
 675     return if !$ipobj;
 676
 677     $version = $ipobj->version();
 678
 679     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 680     return if !$binmask;
 681
 682     my $masked_binip = $ipobj->binip() & $binmask;
 683     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 684     return Net::IP->new("$masked_ip/$prefix");
 685 }
 686
 687 sub is_ip_in_cidr {
 688     my ($ip, $cidr, $version) = @_;
 689
 690     my $cidr_obj = IP_from_cidr($cidr, $version);
 691     return if !$cidr_obj;
 692
 693     my $ip_obj = Net::IP->new($ip, $version);
 694     return if !$ip_obj;
 695
 696     my $overlap = $cidr_obj->overlaps($ip_obj);
 697     return if !defined($overlap);
 698
 699     return $overlap == $Net::IP::IP_B_IN_A_OVERLAP || $overlap == $Net::IP::IP_IDENTICAL;
 700 }
 701
 702 # get all currently configured addresses that have a global scope, i.e., are reachable from the
 703 # outside of the host and thus are neither loopback nor link-local ones
 704 # returns an array ref of: { addr => "IP", cidr => "IP/PREFIXLEN", family => "inet|inet6" }
 705 sub get_reachable_networks {
 706     my $raw = '';
 707     run_command([qw(ip -j addr show up scope global)], outfunc => sub { $raw .= shift });
 708     my $decoded = decode_json($raw);
 709
 710     my $addrs = []; # filter/transform first so that we can sort correctly more easily below
 711     for my $e ($decoded->@*) {
 712         next if !$e->{addr_info} || grep { $_ eq 'LOOPBACK' } $e->{flags}->@*;
 713         push $addrs->@*, grep { scalar(keys $_->%*) } $e->{addr_info}->@*
 714     }
 715     my $res = [];
 716     for my $info (sort { $a->{family} cmp $b->{family} || $a->{local} cmp $b->{local} } $addrs->@*) {
 717         push $res->@*, {
 718             addr => $info->{local},
 719             cidr => "$info->{local}/$info->{prefixlen}",
 720             family => $info->{family},
 721         };
 722     }
 723
 724     return $res;
 725 }
 726
 727 # get one or all local IPs that are not loopback ones, able to pick up the following ones (in order)
 728 # - the hostname primary resolves too, follows gai.conf (admin controlled) and will be prioritised
 729 # - all configured in the interfaces configuration
 730 # - all currently networks known to the kernel in the current (root) namespace
 731 # returns a single address if no parameter is passed, and all found, grouped by type, if `all => 1`
 732 # is passed.
 733 sub get_local_ip {
 734     my (%param) = @_;
 735
 736     my $nodename = PVE::INotify::nodename();
 737     my $resolved_host = eval { get_ip_from_hostname($nodename) };
 738
 739     return $resolved_host if defined($resolved_host) && !$param{all};
 740
 741     my $all = { v4 => {}, v6 => {} }; # hash to avoid duplicates and group by type
 742
 743     my $interaces_cfg = PVE::INotify::read_file('interfaces', 1) || {};
 744     for my $if (values $interaces_cfg->{data}->{ifaces}->%*) {
 745         next if $if->{type} eq 'loopback' || (!defined($if->{address}) && !defined($if->{address6}));
 746         my ($v4, $v6) = ($if->{address}, $if->{address6});
 747
 748         return ($v4 // $v6) if !$param{all}; # prefer v4, admin can override $resolved_host via hosts/gai.conf
 749
 750         $all->{v4}->{$v4} = 1 if defined($v4);
 751         $all->{v6}->{$v6} = 1 if defined($v6);
 752     }
 753
 754     my $live = eval { get_reachable_networks() } // [];
 755     for my $info ($live->@*) {
 756         my $addr = $info->{addr};
 757
 758         return $addr if !$param{all};
 759
 760         if ($info->{family} eq 'inet') {
 761             $all->{v4}->{$addr} = 1;
 762         } else {
 763             $all->{v6}->{$addr} = 1;
 764         }
 765     }
 766
 767     return if !$param{all}; # getting here means no early return above triggered -> no IPs
 768
 769     my $res = []; # order gai.conf controlled first, then group v4 and v6, simply lexically sorted
 770     if ($resolved_host) {
 771         push $res->@*, $resolved_host;
 772         delete $all->{v4}->{$resolved_host};
 773         delete $all->{v6}->{$resolved_host};
 774     }
 775     push $res->@*, sort { $a cmp $b } keys $all->{v4}->%*;
 776     push $res->@*, sort { $a cmp $b } keys $all->{v6}->%*;
 777
 778     return $res;
 779 }
 780
 781 sub get_local_ip_from_cidr {
 782     my ($cidr) = @_;
 783
 784     my $IPs = {};
 785     my $i = 1;
 786     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 787         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 788             $IPs->{$1} = $i++ if !exists($IPs->{$1});
 789         }
 790     });
 791
 792     return [ sort { $IPs->{$a} <=> $IPs->{$b} } keys %{$IPs} ];
 793 }
 794
 795 sub addr_to_ip {
 796     my ($addr) = @_;
 797     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 798     die "failed to get numerical host address: $err\n" if $err;
 799     return ($host, $port) if wantarray;
 800     return $host;
 801 }
 802
 803 sub get_ip_from_hostname {
 804     my ($hostname, $noerr) = @_;
 805
 806     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 807     if ($@) {
 808         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 809         return;
 810     }
 811
 812     for my $ai (@res) {
 813         my $ip = addr_to_ip($ai->{addr});
 814         if ($ip !~ m/^127\.|^::1$/) {
 815             return wantarray ? ($ip, $ai->{family}) : $ip;
 816         }
 817     }
 818     # NOTE: we only get here if no WAN/LAN IP was found, so this is now the error path!
 819     die "address lookup for '$hostname' did not find any IP address\n" if !$noerr;
 820     return;
 821 }
 822
 823 sub lock_network {
 824     my ($code, @param) = @_;
 825     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 826     die $@ if $@;
 827     return $res;
 828 }
 829
 830 # the canonical form of the given IP, i.e. dotted quad for IPv4 and RFC 5952 for IPv6
 831 sub canonical_ip {
 832     my ($ip) = @_;
 833
 834     my $ip_obj = NetAddr::IP->new($ip) or die "invalid IP string '$ip'\n";
 835
 836     return $ip_obj->canon();
 837 }
 838
 839 # List of unique, canonical IPs in the provided list.
 840 # Keeps the original order, filtering later duplicates.
 841 sub unique_ips {
 842     my ($ips) = @_;
 843
 844     my $res = [];
 845     my $seen = {};
 846
 847     for my $ip (@{$ips}) {
 848         $ip = canonical_ip($ip);
 849
 850         next if $seen->{$ip};
 851
 852         $seen->{$ip} = 1;
 853         push @{$res}, $ip;
 854     }
 855
 856     return $res;
 857 }
 858
 859 1;