src/PVE/PBSClient.pm

   1 package PVE::PBSClient;
   2 # utility functions for interaction with Proxmox Backup client CLI executable
   3
   4 use strict;
   5 use warnings;
   6
   7 use Fcntl qw(F_GETFD F_SETFD FD_CLOEXEC);
   8 use IO::File;
   9 use JSON;
  10 use POSIX qw(strftime ENOENT);
  11
  12 use PVE::JSONSchema qw(get_standard_option);
  13 use PVE::Tools qw(run_command file_set_contents file_get_contents file_read_firstline);
  14
  15 sub new {
  16     my ($class, $scfg, $storeid, $sdir) = @_;
  17
  18     die "no section config provided\n" if ref($scfg) eq '';
  19     die "undefined store id\n" if !defined($storeid);
  20
  21     my $secret_dir = $sdir // '/etc/pve/priv/storage';
  22
  23     my $self = bless {
  24         scfg => $scfg,
  25         storeid => $storeid,
  26         secret_dir => $secret_dir
  27     }, $class;
  28     return $self;
  29 }
  30
  31 my sub password_file_name {
  32     my ($self) = @_;
  33
  34     return "$self->{secret_dir}/$self->{storeid}.pw";
  35 }
  36
  37 sub set_password {
  38     my ($self, $password) = @_;
  39
  40     my $pwfile = $self->password_file_name();
  41     mkdir $self->{secret_dir};
  42
  43     PVE::Tools::file_set_contents($pwfile, "$password\n", 0600);
  44 };
  45
  46 sub delete_password {
  47     my ($self) = @_;
  48
  49     my $pwfile = $self->password_file_name();
  50
  51     unlink $pwfile;
  52 };
  53
  54 sub get_password {
  55     my ($self) = @_;
  56
  57     my $pwfile = $self->password_file_name();
  58
  59     return PVE::Tools::file_read_firstline($pwfile);
  60 }
  61
  62 sub encryption_key_file_name {
  63     my ($self) = @_;
  64
  65     return "$self->{secret_dir}/$self->{storeid}.enc";
  66 };
  67
  68 sub set_encryption_key {
  69     my ($self, $key) = @_;
  70
  71     my $encfile = $self->encryption_key_file_name();
  72     mkdir $self->{secret_dir};
  73
  74     PVE::Tools::file_set_contents($encfile, "$key\n", 0600);
  75 };
  76
  77 sub delete_encryption_key {
  78     my ($self) = @_;
  79
  80     my $encfile = $self->encryption_key_file_name();
  81
  82     if (!unlink $encfile) {
  83         return if $! == ENOENT;
  84         die "failed to delete encryption key! $!\n";
  85     }
  86 };
  87
  88 # Returns a file handle if there is an encryption key, or `undef` if there is not. Dies on error.
  89 my sub open_encryption_key {
  90     my ($self) = @_;
  91
  92     my $encryption_key_file = $self->encryption_key_file_name();
  93
  94     my $keyfd;
  95     if (!open($keyfd, '<', $encryption_key_file)) {
  96         return undef if $! == ENOENT;
  97         die "failed to open encryption key: $encryption_key_file: $!\n";
  98     }
  99
 100     return $keyfd;
 101 }
 102
 103 my $USE_CRYPT_PARAMS = {
 104     backup => 1,
 105     restore => 1,
 106     'upload-log' => 1,
 107 };
 108
 109 my sub do_raw_client_cmd {
 110     my ($self, $client_cmd, $param, %opts) = @_;
 111
 112     my $use_crypto = $USE_CRYPT_PARAMS->{$client_cmd};
 113
 114     my $client_exe = '/usr/bin/proxmox-backup-client';
 115     die "executable not found '$client_exe'! Proxmox backup client not installed?\n"
 116         if ! -x $client_exe;
 117
 118     my $scfg = $self->{scfg};
 119     my $server = $scfg->{server};
 120     my $datastore = $scfg->{datastore};
 121     my $username = $scfg->{username} // 'root@pam';
 122
 123     my $userns_cmd = delete $opts{userns_cmd};
 124
 125     my $cmd = [];
 126
 127     push @$cmd, @$userns_cmd if defined($userns_cmd);
 128
 129     push @$cmd, $client_exe, $client_cmd;
 130
 131     # This must live in the top scope to not get closed before the `run_command`
 132     my $keyfd;
 133     if ($use_crypto) {
 134         if (defined($keyfd = $self->open_encryption_key())) {
 135             my $flags = fcntl($keyfd, F_GETFD, 0)
 136                 // die "failed to get file descriptor flags: $!\n";
 137             fcntl($keyfd, F_SETFD, $flags & ~FD_CLOEXEC)
 138                 or die "failed to remove FD_CLOEXEC from encryption key file descriptor\n";
 139             push @$cmd, '--crypt-mode=encrypt', '--keyfd='.fileno($keyfd);
 140         } else {
 141             push @$cmd, '--crypt-mode=none';
 142         }
 143     }
 144
 145     push @$cmd, @$param if defined($param);
 146
 147     push @$cmd, "--repository", "$username\@$server:$datastore";
 148
 149     local $ENV{PBS_PASSWORD} = $self->get_password();
 150
 151     local $ENV{PBS_FINGERPRINT} = $scfg->{fingerprint};
 152
 153     # no ascii-art on task logs
 154     local $ENV{PROXMOX_OUTPUT_NO_BORDER} = 1;
 155     local $ENV{PROXMOX_OUTPUT_NO_HEADER} = 1;
 156
 157     if (my $logfunc = $opts{logfunc}) {
 158         $logfunc->("run: " . join(' ', @$cmd));
 159     }
 160
 161     run_command($cmd, %opts);
 162 }
 163
 164 my sub run_raw_client_cmd {
 165     my ($self, $client_cmd, $param, %opts) = @_;
 166     return $self->do_raw_client_cmd($client_cmd, $param, %opts);
 167 }
 168
 169 my sub run_client_cmd {
 170     my ($self, $client_cmd, $param, $no_output) = @_;
 171
 172     my $json_str = '';
 173     my $outfunc = sub { $json_str .= "$_[0]\n" };
 174
 175     $param = [] if !defined($param);
 176     $param = [ $param ] if !ref($param);
 177
 178     $param = [@$param, '--output-format=json'] if !$no_output;
 179
 180     $self->do_raw_client_cmd(
 181         $client_cmd,
 182         $param,
 183         outfunc => $outfunc,
 184         errmsg => 'proxmox-backup-client failed'
 185     );
 186
 187     return undef if $no_output;
 188
 189     my $res = decode_json($json_str);
 190
 191     return $res;
 192 }
 193
 194 sub autogen_encryption_key {
 195     my ($self) = @_;
 196     my $encfile = $self->encryption_key_file_name();
 197     run_command(['proxmox-backup-client', 'key', 'create', '--kdf', 'none', $encfile]);
 198 };
 199
 200 sub get_snapshots {
 201     my ($self, $opts) = @_;
 202
 203     my $param = [];
 204     if (defined($opts->{group})) {
 205         push @$param, $opts->{group};
 206     }
 207
 208     return $self->run_client_cmd("snapshots", $param);
 209 };
 210
 211 sub backup_tree {
 212     my ($self, $opts) = @_;
 213
 214     my $type = delete $opts->{type};
 215     die "backup-type not provided\n" if !defined($type);
 216     my $id = delete $opts->{id};
 217     die "backup-id not provided\n" if !defined($id);
 218     my $root = delete $opts->{root};
 219     die "root dir not provided\n" if !defined($root);
 220     my $pxarname = delete $opts->{pxarname};
 221     die "archive name not provided\n" if !defined($pxarname);
 222     my $time = delete $opts->{time};
 223
 224     my $param = [];
 225
 226     push @$param, "$pxarname.pxar:$root";
 227     push @$param, '--backup-type', $type;
 228     push @$param, '--backup-id', $id;
 229     push @$param, '--backup-time', $time if defined($time);
 230
 231     return $self->run_raw_client_cmd('backup', $param, %$opts);
 232 };
 233
 234 sub restore_pxar {
 235     my ($self, $opts) = @_;
 236
 237     my $snapshot = delete $opts->{snapshot};
 238     die "snapshot not provided\n" if !defined($snapshot);
 239     my $pxarname = delete $opts->{pxarname};
 240     die "archive name not provided\n" if !defined($pxarname);
 241     my $target = delete $opts->{target};
 242     die "restore-target not provided\n" if !defined($target);
 243     #my $time = delete $opts->{time};
 244
 245     my $param = [];
 246
 247     push @$param, "$snapshot";
 248     push @$param, "$pxarname.pxar";
 249     push @$param, "$target";
 250     push @$param, "--allow-existing-dirs", 0;
 251
 252     return $self->run_raw_client_cmd('restore', $param, %$opts);
 253 };
 254
 255 sub forget_snapshot {
 256     my ($self, $snapshot) = @_;
 257
 258     die "snapshot not provided\n" if !defined($snapshot);
 259
 260     my $param = [];
 261
 262     push @$param, "$snapshot";
 263
 264     return $self->run_raw_client_cmd('forget', $param);
 265 };
 266
 267 sub prune_group {
 268     my ($self, $opts, $prune_opts, $group) = @_;
 269
 270     die "group not provided\n" if !defined($group);
 271
 272     # do nothing if no keep options specified for remote
 273     return [] if scalar(keys %$prune_opts) == 0;
 274
 275     my $param = [];
 276
 277     push @$param, "--quiet";
 278
 279     if (defined($opts->{'dry-run'}) && $opts->{'dry-run'}) {
 280         push @$param, "--dry-run", $opts->{'dry-run'};
 281     }
 282
 283     foreach my $keep_opt (keys %$prune_opts) {
 284         push @$param, "--$keep_opt", $prune_opts->{$keep_opt};
 285     }
 286     push @$param, "$group";
 287
 288     return $self->run_client_cmd('prune', $param);
 289 };
 290
 291 sub status {
 292     my ($self) = @_;
 293
 294     my $total = 0;
 295     my $free = 0;
 296     my $used = 0;
 297     my $active = 0;
 298
 299     eval {
 300         my $res = $self->run_client_cmd("status");
 301
 302         $active = 1;
 303         $total = $res->{total};
 304         $used = $res->{used};
 305         $free = $res->{avail};
 306     };
 307     if (my $err = $@) {
 308         warn $err;
 309     }
 310
 311     return ($total, $free, $used, $active);
 312 };
 313
 314 1;