src/PVE/SectionConfig.pm

   1 package PVE::SectionConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp;
   7 use Digest::SHA;
   8
   9 use PVE::Exception qw(raise_param_exc);
  10 use PVE::JSONSchema qw(get_standard_option);
  11
  12 my $defaultData = {
  13     options => {},
  14     plugins => {},
  15     plugindata => {},
  16     propertyList => {},
  17 };
  18
  19 sub private {
  20     die "overwrite me";
  21     return $defaultData;
  22 }
  23
  24 sub register {
  25     my ($class) = @_;
  26
  27     my $type = $class->type();
  28     my $pdata = $class->private();
  29
  30     die "duplicate plugin registration (type = $type)"
  31         if defined($pdata->{plugins}->{$type});
  32
  33     my $plugindata = $class->plugindata();
  34     $pdata->{plugindata}->{$type} = $plugindata;
  35     $pdata->{plugins}->{$type} = $class;
  36 }
  37
  38 sub type {
  39     die "overwrite me";
  40 }
  41
  42 sub properties {
  43     return {};
  44 }
  45
  46 sub options {
  47     return {};
  48 }
  49
  50 sub plugindata {
  51     return {};
  52 }
  53
  54 sub createSchema {
  55     my ($class, $skip_type) = @_;
  56
  57     my $pdata = $class->private();
  58     my $propertyList = $pdata->{propertyList};
  59     my $plugins = $pdata->{plugins};
  60
  61     my $props = {};
  62
  63     my $copy_property = sub {
  64         my ($src) = @_;
  65
  66         my $res = {};
  67         foreach my $k (keys %$src) {
  68             $res->{$k} = $src->{$k};
  69         }
  70
  71         return $res;
  72     };
  73
  74     foreach my $p (keys %$propertyList) {
  75         next if $skip_type && $p eq 'type';
  76
  77         if (!$propertyList->{$p}->{optional}) {
  78             $props->{$p} = $propertyList->{$p};
  79             next;
  80         }
  81
  82         my $required = 1;
  83
  84         my $copts = $class->options();
  85         $required = 0 if defined($copts->{$p}) && $copts->{$p}->{optional};
  86
  87         foreach my $t (keys %$plugins) {
  88             my $opts = $pdata->{options}->{$t} || {};
  89             $required = 0 if !defined($opts->{$p}) || $opts->{$p}->{optional};
  90         }
  91
  92         if ($required) {
  93             # make a copy, because we modify the optional property
  94             my $res = &$copy_property($propertyList->{$p});
  95             $res->{optional} = 0;
  96             $props->{$p} = $res;
  97         } else {
  98             $props->{$p} = $propertyList->{$p};
  99         }
 100     }
 101
 102     return {
 103         type => "object",
 104         additionalProperties => 0,
 105         properties => $props,
 106     };
 107 }
 108
 109 sub updateSchema {
 110     my ($class, $single_class) = @_;
 111
 112     my $pdata = $class->private();
 113     my $propertyList = $pdata->{propertyList};
 114     my $plugins = $pdata->{plugins};
 115
 116     my $props = {};
 117
 118     my $filter_type = $class->type() if $single_class;
 119
 120     foreach my $p (keys %$propertyList) {
 121         next if $p eq 'type';
 122
 123         my $copts = $class->options();
 124
 125         next if defined($filter_type) && !defined($copts->{$p});
 126
 127         if (!$propertyList->{$p}->{optional}) {
 128             $props->{$p} = $propertyList->{$p};
 129             next;
 130         }
 131
 132         my $modifyable = 0;
 133
 134         $modifyable = 1 if defined($copts->{$p}) && !$copts->{$p}->{fixed};
 135
 136         foreach my $t (keys %$plugins) {
 137             my $opts = $pdata->{options}->{$t} || {};
 138             next if !defined($opts->{$p});
 139             $modifyable = 1 if !$opts->{$p}->{fixed};
 140         }
 141         next if !$modifyable;
 142
 143         $props->{$p} = $propertyList->{$p};
 144     }
 145
 146     $props->{digest} = get_standard_option('pve-config-digest');
 147
 148     $props->{delete} = {
 149         type => 'string', format => 'pve-configid-list',
 150         description => "A list of settings you want to delete.",
 151         maxLength => 4096,
 152         optional => 1,
 153     };
 154
 155     return {
 156         type => "object",
 157         additionalProperties => 0,
 158         properties => $props,
 159     };
 160 }
 161
 162 sub init {
 163     my ($class) = @_;
 164
 165     my $pdata = $class->private();
 166
 167     foreach my $k (qw(options plugins plugindata propertyList)) {
 168         $pdata->{$k} = {} if !$pdata->{$k};
 169     }
 170
 171     my $plugins = $pdata->{plugins};
 172     my $propertyList = $pdata->{propertyList};
 173
 174     foreach my $type (keys %$plugins) {
 175         my $props = $plugins->{$type}->properties();
 176         foreach my $p (keys %$props) {
 177             die "duplicate property '$p'" if defined($propertyList->{$p});
 178             my $res = $propertyList->{$p} = {};
 179             my $data = $props->{$p};
 180             for my $a (keys %$data) {
 181                 $res->{$a} = $data->{$a};
 182             }
 183             $res->{optional} = 1;
 184         }
 185     }
 186
 187     foreach my $type (keys %$plugins) {
 188         my $opts = $plugins->{$type}->options();
 189         foreach my $p (keys %$opts) {
 190             die "undefined property '$p'" if !$propertyList->{$p};
 191         }
 192         $pdata->{options}->{$type} = $opts;
 193     }
 194
 195     $propertyList->{type}->{type} = 'string';
 196     $propertyList->{type}->{enum} = [sort keys %$plugins];
 197 }
 198
 199 sub lookup {
 200     my ($class, $type) = @_;
 201
 202     croak "cannot lookup undefined type!" if !defined($type);
 203
 204     my $pdata = $class->private();
 205     my $plugin = $pdata->{plugins}->{$type};
 206
 207     die "unknown section type '$type'\n" if !$plugin;
 208
 209     return $plugin;
 210 }
 211
 212 sub lookup_types {
 213     my ($class) = @_;
 214
 215     my $pdata = $class->private();
 216
 217     return [ sort keys %{$pdata->{plugins}} ];
 218 }
 219
 220 sub decode_value {
 221     my ($class, $type, $key, $value) = @_;
 222
 223     return $value;
 224 }
 225
 226 sub encode_value {
 227     my ($class, $type, $key, $value) = @_;
 228
 229     return $value;
 230 }
 231
 232 sub check_value {
 233     my ($class, $type, $key, $value, $storeid, $skipSchemaCheck) = @_;
 234
 235     my $pdata = $class->private();
 236
 237     return $value if $key eq 'type' && $type eq $value;
 238
 239     my $opts = $pdata->{options}->{$type};
 240     die "unknown section type '$type'\n" if !$opts;
 241
 242     die "unexpected property '$key'\n" if !defined($opts->{$key});
 243
 244     my $schema = $pdata->{propertyList}->{$key};
 245     die "unknown property type\n" if !$schema;
 246
 247     my $ct = $schema->{type};
 248
 249     $value = 1 if $ct eq 'boolean' && !defined($value);
 250
 251     die "got undefined value\n" if !defined($value);
 252
 253     die "property contains a line feed\n" if $value =~ m/[\n\r]/;
 254
 255     if (!$skipSchemaCheck) {
 256         my $errors = {};
 257         PVE::JSONSchema::check_prop($value, $schema, '', $errors);
 258         if (scalar(keys %$errors)) {
 259             die "$errors->{$key}\n" if $errors->{$key};
 260             die "$errors->{_root}\n" if $errors->{_root};
 261             die "unknown error\n";
 262         }
 263     }
 264
 265     if ($ct eq 'boolean' || $ct eq 'integer' || $ct eq 'number') {
 266         return $value + 0; # convert to number
 267     }
 268
 269     return $value;
 270 }
 271
 272 sub parse_section_header {
 273     my ($class, $line) = @_;
 274
 275     if ($line =~ m/^(\S+):\s*(\S+)\s*$/) {
 276         my ($type, $sectionId) = ($1, $2);
 277         my $errmsg = undef; # set if you want to skip whole section
 278         my $config = {}; # to return additional attributes
 279         return ($type, $sectionId, $errmsg, $config);
 280     }
 281     return undef;
 282 }
 283
 284 sub format_section_header {
 285     my ($class, $type, $sectionId, $scfg, $done_hash) = @_;
 286
 287     return "$type: $sectionId\n";
 288 }
 289
 290
 291 sub parse_config {
 292     my ($class, $filename, $raw, $allow_unknown) = @_;
 293
 294     my $pdata = $class->private();
 295
 296     my $ids = {};
 297     my $order = {};
 298
 299     $raw = '' if !defined($raw);
 300
 301     my $digest = Digest::SHA::sha1_hex($raw);
 302
 303     my $pri = 1;
 304
 305     my $lineno = 0;
 306     my @lines = split(/\n/, $raw);
 307     my $nextline = sub {
 308         while (defined(my $line = shift @lines)) {
 309             $lineno++;
 310             return $line if ($line !~ /^\s*#/);
 311         }
 312     };
 313
 314     my $errors = [];
 315     while (@lines) {
 316         my $line = $nextline->();
 317         next if !$line;
 318
 319         my $errprefix = "file $filename line $lineno";
 320
 321         my ($type, $sectionId, $errmsg, $config) = $class->parse_section_header($line);
 322         if ($config) {
 323             my $skip = 0;
 324             my $unknown = 0;
 325
 326             my $plugin;
 327
 328             if ($errmsg) {
 329                 $skip = 1;
 330                 chomp $errmsg;
 331                 warn "$errprefix (skip section '$sectionId'): $errmsg\n";
 332             } elsif (!$type) {
 333                 $skip = 1;
 334                 warn "$errprefix (skip section '$sectionId'): missing type - internal error\n";
 335             } else {
 336                 if (!($plugin = $pdata->{plugins}->{$type})) {
 337                     if ($allow_unknown) {
 338                         $unknown = 1;
 339                     } else {
 340                         $skip = 1;
 341                         warn "$errprefix (skip section '$sectionId'): unsupported type '$type'\n";
 342                     }
 343                 }
 344             }
 345
 346             while ($line = $nextline->()) {
 347                 next if $skip; # skip
 348
 349                 $errprefix = "file $filename line $lineno";
 350
 351                 if ($line =~ m/^\s+(\S+)(\s+(.*\S))?\s*$/) {
 352                     my ($k, $v) = ($1, $3);
 353
 354                     eval {
 355                         die "duplicate attribute\n" if defined($config->{$k});
 356                         if (!$unknown) {
 357                             $v = $plugin->check_value($type, $k, $v, $sectionId);
 358                         }
 359                         $config->{$k} = $v;
 360                     };
 361                     if (my $err = $@) {
 362                         warn "$errprefix (section '$sectionId') - unable to parse value of '$k': $err";
 363                         push @$errors, {
 364                             context => $errprefix,
 365                             section => $sectionId,
 366                             key => $k,
 367                             err => $err,
 368                         };
 369                     }
 370
 371                 } else {
 372                     warn "$errprefix (section '$sectionId') - ignore config line: $line\n";
 373                 }
 374             }
 375
 376             if ($unknown) {
 377                 $config->{type} = $type;
 378                 $ids->{$sectionId} = $config;
 379                 $order->{$sectionId} = $pri++;
 380             } elsif (!$skip && $type && $plugin && $config) {
 381                 $config->{type} = $type;
 382                 if (!$unknown) {
 383                     $config = eval { $config = $plugin->check_config($sectionId, $config, 1, 1); };
 384                     warn "$errprefix (skip section '$sectionId'): $@" if $@;
 385                 }
 386                 $ids->{$sectionId} = $config;
 387                 $order->{$sectionId} = $pri++;
 388             }
 389
 390         } else {
 391             warn "$errprefix - ignore config line: $line\n";
 392         }
 393     }
 394
 395     my $cfg = {
 396         ids => $ids,
 397         order => $order,
 398         digest => $digest
 399     };
 400     $cfg->{errors} = $errors if scalar(@$errors) > 0;
 401
 402     return $cfg;
 403 }
 404
 405 sub check_config {
 406     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 407
 408     my $type = $class->type();
 409     my $pdata = $class->private();
 410     my $opts = $pdata->{options}->{$type};
 411
 412     my $settings = { type => $type };
 413
 414     foreach my $k (keys %$config) {
 415         my $value = $config->{$k};
 416
 417         die "can't change value of fixed parameter '$k'\n"
 418             if !$create && defined($opts->{$k}) && $opts->{$k}->{fixed};
 419
 420         if (defined($value)) {
 421             my $tmp = $class->check_value($type, $k, $value, $sectionId, $skipSchemaCheck);
 422             $settings->{$k} = $class->decode_value($type, $k, $tmp);
 423         } else {
 424             die "got undefined value for option '$k'\n";
 425         }
 426     }
 427
 428     if ($create) {
 429         # check if we have a value for all required options
 430         foreach my $k (keys %$opts) {
 431             next if $opts->{$k}->{optional};
 432             die "missing value for required option '$k'\n"
 433                 if !defined($config->{$k});
 434         }
 435     }
 436
 437     return $settings;
 438 }
 439
 440 my $format_config_line = sub {
 441     my ($schema, $key, $value) = @_;
 442
 443     my $ct = $schema->{type};
 444
 445     die "property '$key' contains a line feed\n"
 446         if ($key =~ m/[\n\r]/) || ($value =~ m/[\n\r]/);
 447
 448     if ($ct eq 'boolean') {
 449         return "\t$key " . ($value ? 1 : 0) . "\n"
 450             if defined($value);
 451     } else {
 452         return "\t$key $value\n" if "$value" ne '';
 453     }
 454 };
 455
 456 sub write_config {
 457     my ($class, $filename, $cfg, $allow_unknown) = @_;
 458
 459     my $pdata = $class->private();
 460     my $propertyList = $pdata->{propertyList};
 461
 462     my $out = '';
 463
 464     my $ids = $cfg->{ids};
 465     my $order = $cfg->{order};
 466
 467     my $maxpri = 0;
 468     foreach my $sectionId (keys %$ids) {
 469         my $pri = $order->{$sectionId};
 470         $maxpri = $pri if $pri && $pri > $maxpri;
 471     }
 472     foreach my $sectionId (keys %$ids) {
 473         if (!defined ($order->{$sectionId})) {
 474             $order->{$sectionId} = ++$maxpri;
 475         }
 476     }
 477
 478     foreach my $sectionId (sort {$order->{$a} <=> $order->{$b}} keys %$ids) {
 479         my $scfg = $ids->{$sectionId};
 480         my $type = $scfg->{type};
 481         my $opts = $pdata->{options}->{$type};
 482
 483         die "unknown section type '$type'\n" if !$opts && !$allow_unknown;
 484
 485         my $done_hash = {};
 486
 487         my $data = $class->format_section_header($type, $sectionId, $scfg, $done_hash);
 488
 489         if (!$opts && $allow_unknown) {
 490             $done_hash->{type} = 1;
 491             my @first = exists($scfg->{comment}) ? ('comment') : ();
 492             for my $k (@first, sort keys %$scfg) {
 493                 next if defined($done_hash->{$k});
 494                 $done_hash->{$k} = 1;
 495                 my $v = $scfg->{$k};
 496                 $data .= "\t$k $v\n";
 497             }
 498             $out .= "$data\n";
 499             next;
 500         }
 501
 502
 503         if ($scfg->{comment} && !$done_hash->{comment}) {
 504             my $k = 'comment';
 505             my $v = $class->encode_value($type, $k, $scfg->{$k});
 506             $data .= &$format_config_line($propertyList->{$k}, $k, $v);
 507         }
 508
 509         $data .= "\tdisable\n" if $scfg->{disable} && !$done_hash->{disable};
 510
 511         $done_hash->{comment} = 1;
 512         $done_hash->{disable} = 1;
 513
 514         my @option_keys = sort keys %$opts;
 515         foreach my $k (@option_keys) {
 516             next if defined($done_hash->{$k});
 517             next if $opts->{$k}->{optional};
 518             $done_hash->{$k} = 1;
 519             my $v = $scfg->{$k};
 520             die "section '$sectionId' - missing value for required option '$k'\n"
 521                 if !defined ($v);
 522             $v = $class->encode_value($type, $k, $v);
 523             $data .= &$format_config_line($propertyList->{$k}, $k, $v);
 524         }
 525
 526         foreach my $k (@option_keys) {
 527             next if defined($done_hash->{$k});
 528             my $v = $scfg->{$k};
 529             next if !defined($v);
 530             $v = $class->encode_value($type, $k, $v);
 531             $data .= &$format_config_line($propertyList->{$k}, $k, $v);
 532         }
 533
 534         $out .= "$data\n";
 535     }
 536
 537     return $out;
 538 }
 539
 540 sub assert_if_modified {
 541     my ($cfg, $digest) = @_;
 542
 543     PVE::Tools::assert_if_modified($cfg->{digest}, $digest);
 544 }
 545
 546 1;