src/PVE/SectionConfig.pm

   1 package PVE::SectionConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp;
   7 use Digest::SHA;
   8
   9 use PVE::Exception qw(raise_param_exc);
  10 use PVE::JSONSchema qw(get_standard_option);
  11
  12 my $defaultData = {
  13     options => {},
  14     plugins => {},
  15     plugindata => {},
  16     propertyList => {},
  17 };
  18
  19 sub private {
  20     die "overwrite me";
  21     return $defaultData;
  22 }
  23
  24 sub register {
  25     my ($class) = @_;
  26
  27     my $type = $class->type();
  28     my $pdata = $class->private();
  29
  30     die "duplicate plugin registration (type = $type)"
  31         if defined($pdata->{plugins}->{$type});
  32
  33     my $plugindata = $class->plugindata();
  34     $pdata->{plugindata}->{$type} = $plugindata;
  35     $pdata->{plugins}->{$type} = $class;
  36 }
  37
  38 sub type {
  39     die "overwrite me";
  40 }
  41
  42 sub properties {
  43     return {};
  44 }
  45
  46 sub options {
  47     return {};
  48 }
  49
  50 sub plugindata {
  51     return {};
  52 }
  53
  54 sub createSchema {
  55     my ($class, $skip_type, $base) = @_;
  56
  57     my $pdata = $class->private();
  58     my $propertyList = $pdata->{propertyList};
  59     my $plugins = $pdata->{plugins};
  60
  61     my $props = $base || {};
  62
  63     my $copy_property = sub {
  64         my ($src) = @_;
  65
  66         my $res = {};
  67         foreach my $k (keys %$src) {
  68             $res->{$k} = $src->{$k};
  69         }
  70
  71         return $res;
  72     };
  73
  74     foreach my $p (keys %$propertyList) {
  75         next if $skip_type && $p eq 'type';
  76
  77         if (!$propertyList->{$p}->{optional}) {
  78             $props->{$p} = $propertyList->{$p};
  79             next;
  80         }
  81
  82         my $required = 1;
  83
  84         my $copts = $class->options();
  85         $required = 0 if defined($copts->{$p}) && $copts->{$p}->{optional};
  86
  87         foreach my $t (keys %$plugins) {
  88             my $opts = $pdata->{options}->{$t} || {};
  89             $required = 0 if !defined($opts->{$p}) || $opts->{$p}->{optional};
  90         }
  91
  92         if ($required) {
  93             # make a copy, because we modify the optional property
  94             my $res = &$copy_property($propertyList->{$p});
  95             $res->{optional} = 0;
  96             $props->{$p} = $res;
  97         } else {
  98             $props->{$p} = $propertyList->{$p};
  99         }
 100     }
 101
 102     return {
 103         type => "object",
 104         additionalProperties => 0,
 105         properties => $props,
 106     };
 107 }
 108
 109 sub updateSchema {
 110     my ($class, $single_class, $base) = @_;
 111
 112     my $pdata = $class->private();
 113     my $propertyList = $pdata->{propertyList};
 114     my $plugins = $pdata->{plugins};
 115
 116     my $props = $base || {};
 117
 118     my $filter_type = $single_class ? $class->type() : undef;
 119
 120     foreach my $p (keys %$propertyList) {
 121         next if $p eq 'type';
 122
 123         my $copts = $class->options();
 124
 125         next if defined($filter_type) && !defined($copts->{$p});
 126
 127         if (!$propertyList->{$p}->{optional}) {
 128             $props->{$p} = $propertyList->{$p};
 129             next;
 130         }
 131
 132         my $modifyable = 0;
 133
 134         $modifyable = 1 if defined($copts->{$p}) && !$copts->{$p}->{fixed};
 135
 136         foreach my $t (keys %$plugins) {
 137             my $opts = $pdata->{options}->{$t} || {};
 138             next if !defined($opts->{$p});
 139             $modifyable = 1 if !$opts->{$p}->{fixed};
 140         }
 141         next if !$modifyable;
 142
 143         $props->{$p} = $propertyList->{$p};
 144     }
 145
 146     $props->{digest} = get_standard_option('pve-config-digest');
 147
 148     $props->{delete} = {
 149         type => 'string', format => 'pve-configid-list',
 150         description => "A list of settings you want to delete.",
 151         maxLength => 4096,
 152         optional => 1,
 153     };
 154
 155     return {
 156         type => "object",
 157         additionalProperties => 0,
 158         properties => $props,
 159     };
 160 }
 161
 162 sub init {
 163     my ($class) = @_;
 164
 165     my $pdata = $class->private();
 166
 167     foreach my $k (qw(options plugins plugindata propertyList)) {
 168         $pdata->{$k} = {} if !$pdata->{$k};
 169     }
 170
 171     my $plugins = $pdata->{plugins};
 172     my $propertyList = $pdata->{propertyList};
 173
 174     foreach my $type (keys %$plugins) {
 175         my $props = $plugins->{$type}->properties();
 176         foreach my $p (keys %$props) {
 177             die "duplicate property '$p'" if defined($propertyList->{$p});
 178             my $res = $propertyList->{$p} = {};
 179             my $data = $props->{$p};
 180             for my $a (keys %$data) {
 181                 $res->{$a} = $data->{$a};
 182             }
 183             $res->{optional} = 1;
 184         }
 185     }
 186
 187     foreach my $type (keys %$plugins) {
 188         my $opts = $plugins->{$type}->options();
 189         foreach my $p (keys %$opts) {
 190             die "undefined property '$p'" if !$propertyList->{$p};
 191         }
 192         $pdata->{options}->{$type} = $opts;
 193     }
 194
 195     $propertyList->{type}->{type} = 'string';
 196     $propertyList->{type}->{enum} = [sort keys %$plugins];
 197 }
 198
 199 sub lookup {
 200     my ($class, $type) = @_;
 201
 202     croak "cannot lookup undefined type!" if !defined($type);
 203
 204     my $pdata = $class->private();
 205     my $plugin = $pdata->{plugins}->{$type};
 206
 207     die "unknown section type '$type'\n" if !$plugin;
 208
 209     return $plugin;
 210 }
 211
 212 sub lookup_types {
 213     my ($class) = @_;
 214
 215     my $pdata = $class->private();
 216
 217     return [ sort keys %{$pdata->{plugins}} ];
 218 }
 219
 220 sub decode_value {
 221     my ($class, $type, $key, $value) = @_;
 222
 223     return $value;
 224 }
 225
 226 sub encode_value {
 227     my ($class, $type, $key, $value) = @_;
 228
 229     return $value;
 230 }
 231
 232 sub check_value {
 233     my ($class, $type, $key, $value, $storeid, $skipSchemaCheck) = @_;
 234
 235     my $pdata = $class->private();
 236
 237     return $value if $key eq 'type' && $type eq $value;
 238
 239     my $opts = $pdata->{options}->{$type};
 240     die "unknown section type '$type'\n" if !$opts;
 241
 242     die "unexpected property '$key'\n" if !defined($opts->{$key});
 243
 244     my $schema = $pdata->{propertyList}->{$key};
 245     die "unknown property type\n" if !$schema;
 246
 247     my $ct = $schema->{type};
 248
 249     $value = 1 if $ct eq 'boolean' && !defined($value);
 250
 251     die "got undefined value\n" if !defined($value);
 252
 253     die "property contains a line feed\n" if $value =~ m/[\n\r]/;
 254
 255     if (!$skipSchemaCheck) {
 256         my $errors = {};
 257
 258         my $checkschema = $schema;
 259
 260         if ($ct eq 'array') {
 261             die "no item schema for array" if !defined($schema->{items});
 262             $checkschema = $schema->{items};
 263         }
 264
 265         PVE::JSONSchema::check_prop($value, $checkschema, '', $errors);
 266         if (scalar(keys %$errors)) {
 267             die "$errors->{$key}\n" if $errors->{$key};
 268             die "$errors->{_root}\n" if $errors->{_root};
 269             die "unknown error\n";
 270         }
 271     }
 272
 273     if ($ct eq 'boolean' || $ct eq 'integer' || $ct eq 'number') {
 274         return $value + 0; # convert to number
 275     }
 276
 277     return $value;
 278 }
 279
 280 sub parse_section_header {
 281     my ($class, $line) = @_;
 282
 283     if ($line =~ m/^(\S+):\s*(\S+)\s*$/) {
 284         my ($type, $sectionId) = ($1, $2);
 285         my $errmsg = undef; # set if you want to skip whole section
 286         my $config = {}; # to return additional attributes
 287         return ($type, $sectionId, $errmsg, $config);
 288     }
 289     return undef;
 290 }
 291
 292 sub format_section_header {
 293     my ($class, $type, $sectionId, $scfg, $done_hash) = @_;
 294
 295     return "$type: $sectionId\n";
 296 }
 297
 298
 299 sub parse_config {
 300     my ($class, $filename, $raw, $allow_unknown) = @_;
 301
 302     my $pdata = $class->private();
 303
 304     my $ids = {};
 305     my $order = {};
 306
 307     $raw = '' if !defined($raw);
 308
 309     my $digest = Digest::SHA::sha1_hex($raw);
 310
 311     my $pri = 1;
 312
 313     my $lineno = 0;
 314     my @lines = split(/\n/, $raw);
 315     my $nextline = sub {
 316         while (defined(my $line = shift @lines)) {
 317             $lineno++;
 318             return $line if ($line !~ /^\s*#/);
 319         }
 320     };
 321
 322     my $is_array = sub {
 323         my ($type, $key) = @_;
 324
 325         my $schema = $pdata->{propertyList}->{$key};
 326         die "unknown property type\n" if !$schema;
 327
 328         return $schema->{type} eq 'array';
 329     };
 330
 331     my $errors = [];
 332     while (@lines) {
 333         my $line = $nextline->();
 334         next if !$line;
 335
 336         my $errprefix = "file $filename line $lineno";
 337
 338         my ($type, $sectionId, $errmsg, $config) = $class->parse_section_header($line);
 339         if ($config) {
 340             my $skip = 0;
 341             my $unknown = 0;
 342
 343             my $plugin;
 344
 345             if ($errmsg) {
 346                 $skip = 1;
 347                 chomp $errmsg;
 348                 warn "$errprefix (skip section '$sectionId'): $errmsg\n";
 349             } elsif (!$type) {
 350                 $skip = 1;
 351                 warn "$errprefix (skip section '$sectionId'): missing type - internal error\n";
 352             } else {
 353                 if (!($plugin = $pdata->{plugins}->{$type})) {
 354                     if ($allow_unknown) {
 355                         $unknown = 1;
 356                     } else {
 357                         $skip = 1;
 358                         warn "$errprefix (skip section '$sectionId'): unsupported type '$type'\n";
 359                     }
 360                 }
 361             }
 362
 363             while ($line = $nextline->()) {
 364                 next if $skip; # skip
 365
 366                 $errprefix = "file $filename line $lineno";
 367
 368                 if ($line =~ m/^\s+(\S+)(\s+(.*\S))?\s*$/) {
 369                     my ($k, $v) = ($1, $3);
 370
 371                     eval {
 372                         if ($is_array->($type, $k)) {
 373                             if (!$unknown) {
 374                                 $v = $plugin->check_value($type, $k, $v, $sectionId);
 375                             }
 376                             $config->{$k} = [] if !defined($config->{$k});
 377                             push $config->{$k}->@*, $v;
 378                         } else {
 379                             die "duplicate attribute\n" if defined($config->{$k});
 380                             if (!$unknown) {
 381                                 $v = $plugin->check_value($type, $k, $v, $sectionId);
 382                             }
 383                             $config->{$k} = $v;
 384                         }
 385                     };
 386                     if (my $err = $@) {
 387                         warn "$errprefix (section '$sectionId') - unable to parse value of '$k': $err";
 388                         push @$errors, {
 389                             context => $errprefix,
 390                             section => $sectionId,
 391                             key => $k,
 392                             err => $err,
 393                         };
 394                     }
 395
 396                 } else {
 397                     warn "$errprefix (section '$sectionId') - ignore config line: $line\n";
 398                 }
 399             }
 400
 401             if ($unknown) {
 402                 $config->{type} = $type;
 403                 $ids->{$sectionId} = $config;
 404                 $order->{$sectionId} = $pri++;
 405             } elsif (!$skip && $type && $plugin && $config) {
 406                 $config->{type} = $type;
 407                 if (!$unknown) {
 408                     $config = eval { $config = $plugin->check_config($sectionId, $config, 1, 1); };
 409                     warn "$errprefix (skip section '$sectionId'): $@" if $@;
 410                 }
 411                 $ids->{$sectionId} = $config;
 412                 $order->{$sectionId} = $pri++;
 413             }
 414
 415         } else {
 416             warn "$errprefix - ignore config line: $line\n";
 417         }
 418     }
 419
 420     my $cfg = {
 421         ids => $ids,
 422         order => $order,
 423         digest => $digest
 424     };
 425     $cfg->{errors} = $errors if scalar(@$errors) > 0;
 426
 427     return $cfg;
 428 }
 429
 430 sub check_config {
 431     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 432
 433     my $type = $class->type();
 434     my $pdata = $class->private();
 435     my $opts = $pdata->{options}->{$type};
 436
 437     my $settings = { type => $type };
 438
 439     foreach my $k (keys %$config) {
 440         my $value = $config->{$k};
 441
 442         die "can't change value of fixed parameter '$k'\n"
 443             if !$create && defined($opts->{$k}) && $opts->{$k}->{fixed};
 444
 445         if (defined($value)) {
 446             my $tmp = $class->check_value($type, $k, $value, $sectionId, $skipSchemaCheck);
 447             $settings->{$k} = $class->decode_value($type, $k, $tmp);
 448         } else {
 449             die "got undefined value for option '$k'\n";
 450         }
 451     }
 452
 453     if ($create) {
 454         # check if we have a value for all required options
 455         foreach my $k (keys %$opts) {
 456             next if $opts->{$k}->{optional};
 457             die "missing value for required option '$k'\n"
 458                 if !defined($config->{$k});
 459         }
 460     }
 461
 462     return $settings;
 463 }
 464
 465 my $format_config_line = sub {
 466     my ($schema, $key, $value) = @_;
 467
 468     my $ct = $schema->{type};
 469
 470     die "property '$key' contains a line feed\n"
 471         if ($key =~ m/[\n\r]/) || ($value =~ m/[\n\r]/);
 472
 473     if ($ct eq 'boolean') {
 474         return "\t$key " . ($value ? 1 : 0) . "\n"
 475             if defined($value);
 476     } elsif ($ct eq 'array') {
 477         die "property '$key' is not an array" if ref($value) ne 'ARRAY';
 478         my $result = '';
 479         for my $line ($value->@*) {
 480             $result .= "\t$key $line\n" if $value ne '';
 481         }
 482         return $result;
 483     } else {
 484         return "\t$key $value\n" if "$value" ne '';
 485     }
 486 };
 487
 488 sub write_config {
 489     my ($class, $filename, $cfg, $allow_unknown) = @_;
 490
 491     my $pdata = $class->private();
 492     my $propertyList = $pdata->{propertyList};
 493
 494     my $out = '';
 495
 496     my $ids = $cfg->{ids};
 497     my $order = $cfg->{order};
 498
 499     my $maxpri = 0;
 500     foreach my $sectionId (keys %$ids) {
 501         my $pri = $order->{$sectionId};
 502         $maxpri = $pri if $pri && $pri > $maxpri;
 503     }
 504     foreach my $sectionId (keys %$ids) {
 505         if (!defined ($order->{$sectionId})) {
 506             $order->{$sectionId} = ++$maxpri;
 507         }
 508     }
 509
 510     foreach my $sectionId (sort {$order->{$a} <=> $order->{$b}} keys %$ids) {
 511         my $scfg = $ids->{$sectionId};
 512         my $type = $scfg->{type};
 513         my $opts = $pdata->{options}->{$type};
 514
 515         die "unknown section type '$type'\n" if !$opts && !$allow_unknown;
 516
 517         my $done_hash = {};
 518
 519         my $data = $class->format_section_header($type, $sectionId, $scfg, $done_hash);
 520
 521         if (!$opts && $allow_unknown) {
 522             $done_hash->{type} = 1;
 523             my @first = exists($scfg->{comment}) ? ('comment') : ();
 524             for my $k (@first, sort keys %$scfg) {
 525                 next if defined($done_hash->{$k});
 526                 $done_hash->{$k} = 1;
 527                 my $v = $scfg->{$k};
 528                 $data .= "\t$k $v\n";
 529             }
 530             $out .= "$data\n";
 531             next;
 532         }
 533
 534
 535         if ($scfg->{comment} && !$done_hash->{comment}) {
 536             my $k = 'comment';
 537             my $v = $class->encode_value($type, $k, $scfg->{$k});
 538             $data .= &$format_config_line($propertyList->{$k}, $k, $v);
 539         }
 540
 541         $data .= "\tdisable\n" if $scfg->{disable} && !$done_hash->{disable};
 542
 543         $done_hash->{comment} = 1;
 544         $done_hash->{disable} = 1;
 545
 546         my @option_keys = sort keys %$opts;
 547         foreach my $k (@option_keys) {
 548             next if defined($done_hash->{$k});
 549             next if $opts->{$k}->{optional};
 550             $done_hash->{$k} = 1;
 551             my $v = $scfg->{$k};
 552             die "section '$sectionId' - missing value for required option '$k'\n"
 553                 if !defined ($v);
 554             $v = $class->encode_value($type, $k, $v);
 555             $data .= &$format_config_line($propertyList->{$k}, $k, $v);
 556         }
 557
 558         foreach my $k (@option_keys) {
 559             next if defined($done_hash->{$k});
 560             my $v = $scfg->{$k};
 561             next if !defined($v);
 562             $v = $class->encode_value($type, $k, $v);
 563             $data .= &$format_config_line($propertyList->{$k}, $k, $v);
 564         }
 565
 566         $out .= "$data\n";
 567     }
 568
 569     return $out;
 570 }
 571
 572 sub assert_if_modified {
 573     my ($cfg, $digest) = @_;
 574
 575     PVE::Tools::assert_if_modified($cfg->{digest}, $digest);
 576 }
 577
 578 sub delete_from_config {
 579     my ($config, $option_schema, $new_options, $to_delete) = @_;
 580
 581     for my $k ($to_delete->@*) {
 582         my $d = $option_schema->{$k} || die "no such option '$k'\n";
 583         die "unable to delete required option '$k'\n" if !$d->{optional};
 584         die "unable to delete fixed option '$k'\n" if $d->{fixed};
 585         die "cannot set and delete property '$k' at the same time!\n"
 586             if defined($new_options->{$k});
 587         delete $config->{$k};
 588     }
 589
 590     return $config;
 591 }
 592
 593 1;