550da09a609ddcf39f7999cc384bb312515192ed
[pve-common.git] / src / PVE / Tools.pm
1 package PVE::Tools;
2
3 use strict;
4 use warnings;
5 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
6 use IO::Socket::IP;
7 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM
8               IPPROTO_TCP);
9 use IO::Select;
10 use File::Basename;
11 use File::Path qw(make_path);
12 use Filesys::Df (); # don't overwrite our df()
13 use IO::Pipe;
14 use IO::File;
15 use IO::Dir;
16 use IO::Handle;
17 use IPC::Open3;
18 use Fcntl qw(:DEFAULT :flock);
19 use base 'Exporter';
20 use URI::Escape;
21 use Encode;
22 use Digest::SHA;
23 use JSON;
24 use Text::ParseWords;
25 use String::ShellQuote;
26 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
27 use Scalar::Util 'weaken';
28 use PVE::Syscall;
29
30 # avoid warning when parsing long hex values with hex()
31 no warnings 'portable'; # Support for 64-bit ints required
32
33 our @EXPORT_OK = qw(
34 $IPV6RE
35 $IPV4RE
36 lock_file
37 lock_file_full
38 run_command
39 file_set_contents
40 file_get_contents
41 file_read_firstline
42 dir_glob_regex
43 dir_glob_foreach
44 split_list
45 template_replace
46 safe_print
47 trim
48 extract_param
49 file_copy
50 O_PATH
51 O_TMPFILE
52 );
53
54 my $pvelogdir = "/var/log/pve";
55 my $pvetaskdir = "$pvelogdir/tasks";
56
57 mkdir $pvelogdir;
58 mkdir $pvetaskdir;
59
60 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
61 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
62 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
63 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
64
65 our $IPV6RE = "(?:" .
66     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
67     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
68     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
69     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
70     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
71     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
72     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
73     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
74     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
75
76 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
77
78 use constant {CLONE_NEWNS   => 0x00020000,
79               CLONE_NEWUTS  => 0x04000000,
80               CLONE_NEWIPC  => 0x08000000,
81               CLONE_NEWUSER => 0x10000000,
82               CLONE_NEWPID  => 0x20000000,
83               CLONE_NEWNET  => 0x40000000};
84
85 use constant {O_PATH    => 0x00200000,
86               O_TMPFILE => 0x00410000}; # This includes O_DIRECTORY
87
88 use constant {AT_EMPTY_PATH => 0x1000};
89
90 sub run_with_timeout {
91     my ($timeout, $code, @param) = @_;
92
93     die "got timeout\n" if $timeout <= 0;
94
95     my $prev_alarm = alarm 0; # suspend outer alarm early
96
97     my $sigcount = 0;
98
99     my $res;
100
101     eval {
102         local $SIG{ALRM} = sub { $sigcount++; die "got timeout\n"; };
103         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
104         local $SIG{__DIE__};   # see SA bug 4631
105
106         alarm($timeout);
107
108         eval { $res = &$code(@param); };
109
110         alarm(0); # avoid race conditions
111
112         die $@ if $@;
113     };
114
115     my $err = $@;
116
117     alarm $prev_alarm;
118
119     # this shouldn't happen anymore?
120     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
121
122     die $err if $err;
123
124     return $res;
125 }
126
127 # flock: we use one file handle per process, so lock file
128 # can be nested multiple times and succeeds for the same process.
129 #
130 # Since this is the only way we lock now and we don't have the old
131 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
132 # count how deep we're nesting. Therefore this hash now stores a weak reference
133 # to a boolean telling us whether we already have a lock.
134
135 my $lock_handles =  {};
136
137 sub lock_file_full {
138     my ($filename, $timeout, $shared, $code, @param) = @_;
139
140     $timeout = 10 if !$timeout;
141
142     my $mode = $shared ? LOCK_SH : LOCK_EX;
143
144     my $lockhash = ($lock_handles->{$$} //= {});
145
146     # Returns a locked file handle.
147     my $get_locked_file = sub {
148         my $fh = IO::File->new(">>$filename")
149             or die "can't open file - $!\n";
150
151         if (!flock($fh, $mode|LOCK_NB)) {
152             print STDERR "trying to acquire lock...\n";
153             my $success;
154             while(1) {
155                 $success = flock($fh, $mode);
156                 # try again on EINTR (see bug #273)
157                 if ($success || ($! != EINTR)) {
158                     last;
159                 }
160             }
161             if (!$success) {
162                 print STDERR " failed\n";
163                 die "can't acquire lock '$filename' - $!\n";
164             }
165             print STDERR " OK\n";
166         }
167
168         return $fh;
169     };
170
171     my $res;
172     my $checkptr = $lockhash->{$filename};
173     my $check = 0; # This must not go out of scope before running the code.
174     my $local_fh; # This must stay local
175     if (!$checkptr || !$$checkptr) {
176         # We cannot create a weak reference in a single atomic step, so we first
177         # create a false-value, then create a reference to it, then weaken it,
178         # and after successfully locking the file we change the boolean value.
179         #
180         # The reason for this is that if an outer SIGALRM throws an exception
181         # between creating the reference and weakening it, a subsequent call to
182         # lock_file_full() will see a leftover full reference to a valid
183         # variable. This variable must be 0 in order for said call to attempt to
184         # lock the file anew.
185         #
186         # An externally triggered exception elsewhere in the code will cause the
187         # weak reference to become 'undef', and since the file handle is only
188         # stored in the local scope in $local_fh, the file will be closed by
189         # perl's cleanup routines as well.
190         #
191         # This still assumes that an IO::File handle can properly deal with such
192         # exceptions thrown during its own destruction, but that's up to perls
193         # guts now.
194         $lockhash->{$filename} = \$check;
195         weaken $lockhash->{$filename};
196         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
197         if ($@) {
198             $@ = "can't lock file '$filename' - $@";
199             return undef;
200         }
201         $check = 1;
202     }
203     $res = eval { &$code(@param); };
204     return undef if $@;
205     return $res;
206 }
207
208
209 sub lock_file {
210     my ($filename, $timeout, $code, @param) = @_;
211
212     return lock_file_full($filename, $timeout, 0, $code, @param);
213 }
214
215 sub file_set_contents {
216     my ($filename, $data, $perm)  = @_;
217
218     $perm = 0644 if !defined($perm);
219
220     my $tmpname = "$filename.tmp.$$";
221
222     eval {
223         my ($fh, $tries) = (undef, 0);
224         while (!$fh && $tries++ < 3) {
225             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
226             if (!$fh && $! == EEXIST) {
227                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
228             }
229         }
230         die "unable to open file '$tmpname' - $!\n" if !$fh;
231         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
232         die "closing file '$tmpname' failed - $!\n" unless close $fh;
233     };
234     my $err = $@;
235
236     if ($err) {
237         unlink $tmpname;
238         die $err;
239     }
240
241     if (!rename($tmpname, $filename)) {
242         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
243         unlink $tmpname;
244         die $msg;
245     }
246 }
247
248 sub file_get_contents {
249     my ($filename, $max) = @_;
250
251     my $fh = IO::File->new($filename, "r") ||
252         die "can't open '$filename' - $!\n";
253
254     my $content = safe_read_from($fh, $max, 0, $filename);
255
256     close $fh;
257
258     return $content;
259 }
260
261 sub file_copy {
262     my ($filename, $dst, $max, $perm) = @_;
263
264     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
265 }
266
267 sub file_read_firstline {
268     my ($filename) = @_;
269
270     my $fh = IO::File->new ($filename, "r");
271     return undef if !$fh;
272     my $res = <$fh>;
273     chomp $res if $res;
274     $fh->close;
275     return $res;
276 }
277
278 sub safe_read_from {
279     my ($fh, $max, $oneline, $filename) = @_;
280
281     $max = 32768 if !$max;
282
283     my $subject = defined($filename) ? "file '$filename'" : 'input';
284
285     my $br = 0;
286     my $input = '';
287     my $count;
288     while ($count = sysread($fh, $input, 8192, $br)) {
289         $br += $count;
290         die "$subject too long - aborting\n" if $br > $max;
291         if ($oneline && $input =~ m/^(.*)\n/) {
292             $input = $1;
293             last;
294         }
295     }
296     die "unable to read $subject - $!\n" if !defined($count);
297
298     return $input;
299 }
300
301 # The $cmd parameter can be:
302 #  -) a string
303 #    This is generally executed by passing it to the shell with the -c option.
304 #    However, it can be executed in one of two ways, depending on whether
305 #    there's a pipe involved:
306 #      *) with pipe: passed explicitly to bash -c, prefixed with:
307 #          set -o pipefail &&
308 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
309 #      (Note that this may result in two different syntax requirements!)
310 #      FIXME?
311 #  -) an array of arguments (strings)
312 #    Will be executed without interference from a shell. (Parameters are passed
313 #    as is, no escape sequences of strings will be touched.)
314 #  -) an array of arrays
315 #    Each array represents a command, and each command's output is piped into
316 #    the following command's standard input.
317 #    For this a shell command string is created with pipe symbols between each
318 #    command.
319 #    Each command is a list of strings meant to end up in the final command
320 #    unchanged. In order to achieve this, every argument is shell-quoted.
321 #    Quoting can be disabled for a particular argument by turning it into a
322 #    reference, this allows inserting arbitrary shell options.
323 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
324 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
325 #    will literally print: hello >/dev/null
326 sub run_command {
327     my ($cmd, %param) = @_;
328
329     my $old_umask;
330     my $cmdstr;
331
332     if (my $ref = ref($cmd)) {
333         if (ref($cmd->[0])) {
334             $cmdstr = 'set -o pipefail && ';
335             my $pipe = '';
336             foreach my $command (@$cmd) {
337                 # concatenate quoted parameters
338                 # strings which are passed by reference are NOT shell quoted
339                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
340                 $pipe = ' | ';
341             }
342             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
343         } else {
344             $cmdstr = cmd2string($cmd);
345         }
346     } else {
347         $cmdstr = $cmd;
348         if ($cmd =~ m/\|/) {
349             # see 'man bash' for option pipefail
350             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
351         } else {
352             $cmd = [ $cmd ];
353         }
354     }
355
356     my $errmsg;
357     my $laststderr;
358     my $timeout;
359     my $oldtimeout;
360     my $pid;
361     my $exitcode = -1;
362
363     my $outfunc;
364     my $errfunc;
365     my $logfunc;
366     my $input;
367     my $output;
368     my $afterfork;
369     my $noerr;
370     my $keeplocale;
371     my $quiet;
372
373     eval {
374
375         foreach my $p (keys %param) {
376             if ($p eq 'timeout') {
377                 $timeout = $param{$p};
378             } elsif ($p eq 'umask') {
379                 $old_umask = umask($param{$p});
380             } elsif ($p eq 'errmsg') {
381                 $errmsg = $param{$p};
382             } elsif ($p eq 'input') {
383                 $input = $param{$p};
384             } elsif ($p eq 'output') {
385                 $output = $param{$p};
386             } elsif ($p eq 'outfunc') {
387                 $outfunc = $param{$p};
388             } elsif ($p eq 'errfunc') {
389                 $errfunc = $param{$p};
390             } elsif ($p eq 'logfunc') {
391                 $logfunc = $param{$p};
392             } elsif ($p eq 'afterfork') {
393                 $afterfork = $param{$p};
394             } elsif ($p eq 'noerr') {
395                 $noerr = $param{$p};
396             } elsif ($p eq 'keeplocale') {
397                 $keeplocale = $param{$p};
398             } elsif ($p eq 'quiet') {
399                 $quiet = $param{$p};
400             } else {
401                 die "got unknown parameter '$p' for run_command\n";
402             }
403         }
404
405         if ($errmsg) {
406             my $origerrfunc = $errfunc;
407             $errfunc = sub {
408                 if ($laststderr) {
409                     if ($origerrfunc) {
410                         &$origerrfunc("$laststderr\n");
411                     } else {
412                         print STDERR "$laststderr\n" if $laststderr;
413                     }
414                 }
415                 $laststderr = shift;
416             };
417         }
418
419         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
420         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
421         my $error  = IO::File->new();
422
423         my $orig_pid = $$;
424
425         eval {
426             local $ENV{LC_ALL} = 'C' if !$keeplocale;
427
428             # suppress LVM warnings like: "File descriptor 3 left open";
429             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
430
431             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
432
433             # if we pipe fron STDIN, open3 closes STDIN, so we we
434             # a perl warning "Filehandle STDIN reopened as GENXYZ .. "
435             # as soon as we open a new file.
436             # to avoid that we open /dev/null
437             if (!ref($writer) && !defined(fileno(STDIN))) {
438                 POSIX::close(0);
439                 open(STDIN, "</dev/null");
440             }
441         };
442
443         my $err = $@;
444
445         # catch exec errors
446         if ($orig_pid != $$) {
447             warn "ERROR: $err";
448             POSIX::_exit (1);
449             kill ('KILL', $$);
450         }
451
452         die $err if $err;
453
454         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
455         $oldtimeout = alarm($timeout) if $timeout;
456
457         &$afterfork() if $afterfork;
458
459         if (ref($writer)) {
460             print $writer $input if defined $input;
461             close $writer;
462         }
463
464         my $select = new IO::Select;
465         $select->add($reader) if ref($reader);
466         $select->add($error);
467
468         my $outlog = '';
469         my $errlog = '';
470
471         my $starttime = time();
472
473         while ($select->count) {
474             my @handles = $select->can_read(1);
475
476             foreach my $h (@handles) {
477                 my $buf = '';
478                 my $count = sysread ($h, $buf, 4096);
479                 if (!defined ($count)) {
480                     my $err = $!;
481                     kill (9, $pid);
482                     waitpid ($pid, 0);
483                     die $err;
484                 }
485                 $select->remove ($h) if !$count;
486                 if ($h eq $reader) {
487                     if ($outfunc || $logfunc) {
488                         eval {
489                             $outlog .= $buf;
490                             while ($outlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
491                                 my $line = $1;
492                                 &$outfunc($line) if $outfunc;
493                                 &$logfunc($line) if $logfunc;
494                             }
495                         };
496                         my $err = $@;
497                         if ($err) {
498                             kill (9, $pid);
499                             waitpid ($pid, 0);
500                             die $err;
501                         }
502                     } elsif (!$quiet) {
503                         print $buf;
504                         *STDOUT->flush();
505                     }
506                 } elsif ($h eq $error) {
507                     if ($errfunc || $logfunc) {
508                         eval {
509                             $errlog .= $buf;
510                             while ($errlog =~ s/^([^\010\r\n]*)(\r|\n|(\010)+|\r\n)//s) {
511                                 my $line = $1;
512                                 &$errfunc($line) if $errfunc;
513                                 &$logfunc($line) if $logfunc;
514                             }
515                         };
516                         my $err = $@;
517                         if ($err) {
518                             kill (9, $pid);
519                             waitpid ($pid, 0);
520                             die $err;
521                         }
522                     } elsif (!$quiet) {
523                         print STDERR $buf;
524                         *STDERR->flush();
525                     }
526                 }
527             }
528         }
529
530         &$outfunc($outlog) if $outfunc && $outlog;
531         &$logfunc($outlog) if $logfunc && $outlog;
532
533         &$errfunc($errlog) if $errfunc && $errlog;
534         &$logfunc($errlog) if $logfunc && $errlog;
535
536         waitpid ($pid, 0);
537
538         if ($? == -1) {
539             die "failed to execute\n";
540         } elsif (my $sig = ($? & 127)) {
541             die "got signal $sig\n";
542         } elsif ($exitcode = ($? >> 8)) {
543             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
544                 if ($errmsg && $laststderr) {
545                     my $lerr = $laststderr;
546                     $laststderr = undef;
547                     die "$lerr\n";
548                 }
549                 die "exit code $exitcode\n";
550             }
551         }
552
553         alarm(0);
554     };
555
556     my $err = $@;
557
558     alarm(0);
559
560     if ($errmsg && $laststderr) {
561         &$errfunc(undef); # flush laststderr
562     }
563
564     umask ($old_umask) if defined($old_umask);
565
566     alarm($oldtimeout) if $oldtimeout;
567
568     if ($err) {
569         if ($pid && ($err eq "got timeout\n")) {
570             kill (9, $pid);
571             waitpid ($pid, 0);
572             die "command '$cmdstr' failed: $err";
573         }
574
575         if ($errmsg) {
576             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
577             die "$errmsg: $err";
578         } elsif(!$noerr) {
579             die "command '$cmdstr' failed: $err";
580         }
581     }
582
583     return $exitcode;
584 }
585
586 # Run a command with a tcp socket as standard input.
587 sub pipe_socket_to_command  {
588     my ($cmd, $ip, $port) = @_;
589
590     my $params = {
591         Listen => 1,
592         ReuseAddr => 1,
593         Proto => &Socket::IPPROTO_TCP,
594         GetAddrInfoFlags => 0,
595         LocalAddr => $ip,
596         LocalPort => $port,
597     };
598     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
599
600     print "$ip\n$port\n"; # tell remote where to connect
601     *STDOUT->flush();
602
603     alarm 0;
604     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
605     alarm 30;
606     my $client = $socket->accept; # Wait for a client
607     alarm 0;
608     close($socket);
609
610     # We want that the command talks over the TCP socket and takes
611     # ownership of it, so that when it closes it the connection is
612     # terminated, so we need to be able to close the socket. So we
613     # can't really use PVE::Tools::run_command().
614     my $pid = fork() // die "fork failed: $!\n";
615     if (!$pid) {
616         POSIX::dup2(fileno($client), 0);
617         POSIX::dup2(fileno($client), 1);
618         close($client);
619         exec {$cmd->[0]} @$cmd or do {
620             warn "exec failed: $!\n";
621             POSIX::_exit(1);
622         };
623     }
624
625     close($client);
626     if (waitpid($pid, 0) != $pid) {
627         kill(15 => $pid); # if we got interrupted terminate the child
628         my $count = 0;
629         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
630             usleep(100000);
631             $count++;
632             kill(9 => $pid), last if $count > 300; # 30 second timeout
633         }
634     }
635     if (my $sig = ($? & 127)) {
636         die "got signal $sig\n";
637     } elsif (my $exitcode = ($? >> 8)) {
638         die "exit code $exitcode\n";
639     }
640
641     return undef;
642 }
643
644 sub split_list {
645     my $listtxt = shift // '';
646
647     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
648
649     $listtxt =~ s/[,;]/ /g;
650     $listtxt =~ s/^\s+//;
651
652     my @data = split (/\s+/, $listtxt);
653
654     return @data;
655 }
656
657 sub trim {
658     my $txt = shift;
659
660     return $txt if !defined($txt);
661
662     $txt =~ s/^\s+//;
663     $txt =~ s/\s+$//;
664
665     return $txt;
666 }
667
668 # simple uri templates like "/vms/{vmid}"
669 sub template_replace {
670     my ($tmpl, $data) = @_;
671
672     return $tmpl if !$tmpl;
673
674     my $res = '';
675     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
676         $res .= $1 if $1;
677         $res .= ($data->{$3} || '-') if $2;
678     }
679     return $res;
680 }
681
682 sub safe_print {
683     my ($filename, $fh, $data) = @_;
684
685     return if !$data;
686
687     my $res = print $fh $data;
688
689     die "write to '$filename' failed\n" if !$res;
690 }
691
692 sub debmirrors {
693
694     return {
695         'at' => 'ftp.at.debian.org',
696         'au' => 'ftp.au.debian.org',
697         'be' => 'ftp.be.debian.org',
698         'bg' => 'ftp.bg.debian.org',
699         'br' => 'ftp.br.debian.org',
700         'ca' => 'ftp.ca.debian.org',
701         'ch' => 'ftp.ch.debian.org',
702         'cl' => 'ftp.cl.debian.org',
703         'cz' => 'ftp.cz.debian.org',
704         'de' => 'ftp.de.debian.org',
705         'dk' => 'ftp.dk.debian.org',
706         'ee' => 'ftp.ee.debian.org',
707         'es' => 'ftp.es.debian.org',
708         'fi' => 'ftp.fi.debian.org',
709         'fr' => 'ftp.fr.debian.org',
710         'gr' => 'ftp.gr.debian.org',
711         'hk' => 'ftp.hk.debian.org',
712         'hr' => 'ftp.hr.debian.org',
713         'hu' => 'ftp.hu.debian.org',
714         'ie' => 'ftp.ie.debian.org',
715         'is' => 'ftp.is.debian.org',
716         'it' => 'ftp.it.debian.org',
717         'jp' => 'ftp.jp.debian.org',
718         'kr' => 'ftp.kr.debian.org',
719         'mx' => 'ftp.mx.debian.org',
720         'nl' => 'ftp.nl.debian.org',
721         'no' => 'ftp.no.debian.org',
722         'nz' => 'ftp.nz.debian.org',
723         'pl' => 'ftp.pl.debian.org',
724         'pt' => 'ftp.pt.debian.org',
725         'ro' => 'ftp.ro.debian.org',
726         'ru' => 'ftp.ru.debian.org',
727         'se' => 'ftp.se.debian.org',
728         'si' => 'ftp.si.debian.org',
729         'sk' => 'ftp.sk.debian.org',
730         'tr' => 'ftp.tr.debian.org',
731         'tw' => 'ftp.tw.debian.org',
732         'gb' => 'ftp.uk.debian.org',
733         'us' => 'ftp.us.debian.org',
734     };
735 }
736
737 my $keymaphash =  {
738     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
739     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
740     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
741     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
742     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
743     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
744     #'et'     => [], # Ethopia or Estonia ??
745     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
746     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
747     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
748     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
749     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
750     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
751     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
752     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
753     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
754     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
755     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
756     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
757     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
758     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
759     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
760     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
761     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
762     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
763     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
764     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
765     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
766     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
767     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
768     #'th'     => [],
769     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
770 };
771
772 my $kvmkeymaparray = [];
773 foreach my $lc (sort keys %$keymaphash) {
774     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
775 }
776
777 sub kvmkeymaps {
778     return $keymaphash;
779 }
780
781 sub kvmkeymaplist {
782     return $kvmkeymaparray;
783 }
784
785 sub extract_param {
786     my ($param, $key) = @_;
787
788     my $res = $param->{$key};
789     delete $param->{$key};
790
791     return $res;
792 }
793
794 # Note: we use this to wait until vncterm/spiceterm is ready
795 sub wait_for_vnc_port {
796     my ($port, $family, $timeout) = @_;
797
798     $timeout = 5 if !$timeout;
799     my $sleeptime = 0;
800     my $starttime = [gettimeofday];
801     my $elapsed;
802
803     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
804     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
805
806     my $found;
807     while (($elapsed = tv_interval($starttime)) < $timeout) {
808         # -Htln = don't print header, tcp, listening sockets only, numeric ports
809         run_command($cmd, outfunc => sub {
810             my $line = shift;
811             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
812                 $found = 1 if ($port == $1);
813             }
814         });
815         return 1 if $found;
816         $sleeptime += 100000 if  $sleeptime < 1000000;
817         usleep($sleeptime);
818     }
819
820     die "Timeout while waiting for port '$port' to get ready!\n";
821 }
822
823 sub next_unused_port {
824     my ($range_start, $range_end, $family, $address) = @_;
825
826     # We use a file to register allocated ports.
827     # Those registrations expires after $expiretime.
828     # We use this to avoid race conditions between
829     # allocation and use of ports.
830
831     my $filename = "/var/tmp/pve-reserved-ports";
832
833     my $code = sub {
834
835         my $expiretime = 5;
836         my $ctime = time();
837
838         my $ports = {};
839
840         if (my $fh = IO::File->new ($filename, "r")) {
841             while (my $line = <$fh>) {
842                 if ($line =~ m/^(\d+)\s(\d+)$/) {
843                     my ($port, $timestamp) = ($1, $2);
844                     if (($timestamp + $expiretime) > $ctime) {
845                         $ports->{$port} = $timestamp; # not expired
846                     }
847                 }
848             }
849         }
850
851         my $newport;
852         my %sockargs = (Listen => 5,
853                         ReuseAddr => 1,
854                         Family    => $family,
855                         Proto     => IPPROTO_TCP,
856                         GetAddrInfoFlags => 0);
857         $sockargs{LocalAddr} = $address if defined($address);
858
859         for (my $p = $range_start; $p < $range_end; $p++) {
860             next if $ports->{$p}; # reserved
861
862             $sockargs{LocalPort} = $p;
863             my $sock = IO::Socket::IP->new(%sockargs);
864
865             if ($sock) {
866                 close($sock);
867                 $newport = $p;
868                 $ports->{$p} = $ctime;
869                 last;
870             }
871         }
872
873         my $data = "";
874         foreach my $p (keys %$ports) {
875             $data .= "$p $ports->{$p}\n";
876         }
877
878         file_set_contents($filename, $data);
879
880         return $newport;
881     };
882
883     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
884     die $@ if $@;
885
886     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
887
888     return $p;
889 }
890
891 sub next_migrate_port {
892     my ($family, $address) = @_;
893     return next_unused_port(60000, 60050, $family, $address);
894 }
895
896 sub next_vnc_port {
897     my ($family, $address) = @_;
898     return next_unused_port(5900, 6000, $family, $address);
899 }
900
901 sub next_spice_port {
902     my ($family, $address) = @_;
903     return next_unused_port(61000, 61099, $family, $address);
904 }
905
906 sub must_stringify {
907         my ($value) = @_;
908         eval { $value = "$value" };
909         return "error turning value into a string: $@" if $@;
910         return $value;
911 }
912
913 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
914 # the $sub has to return a single scalar
915 sub run_fork_with_timeout {
916     my ($timeout, $sub) = @_;
917
918     my $res;
919     my $error;
920     my $pipe_out = IO::Pipe->new();
921
922     # disable pending alarms, save their remaining time
923     my $prev_alarm = alarm 0;
924
925     # avoid leaving a zombie if the parent gets interrupted
926     my $sig_received;
927
928     my $child = fork();
929     if (!defined($child)) {
930         die "fork failed: $!\n";
931         return $res;
932     }
933
934     if (!$child) {
935         $pipe_out->writer();
936
937         eval {
938             $res = $sub->();
939             print {$pipe_out} encode_json({ result => $res });
940             $pipe_out->flush();
941         };
942         if (my $err = $@) {
943             print {$pipe_out} encode_json({ error => must_stringify($err) });
944             $pipe_out->flush();
945             POSIX::_exit(1);
946         }
947         POSIX::_exit(0);
948     }
949
950     local $SIG{INT} = sub { $sig_received++; };
951     local $SIG{TERM} = sub {
952         $error //= "interrupted by unexpected signal\n";
953         kill('TERM', $child);
954     };
955
956     $pipe_out->reader();
957
958     my $readvalues = sub {
959         local $/ = undef;
960         my $child_res = decode_json(readline_nointr($pipe_out));
961         $res = $child_res->{result};
962         $error = $child_res->{error};
963     };
964     eval {
965         if (defined($timeout)) {
966             run_with_timeout($timeout, $readvalues);
967         } else {
968             $readvalues->();
969         }
970     };
971     warn $@ if $@;
972     $pipe_out->close();
973     kill('KILL', $child);
974     waitpid($child, 0);
975
976     alarm $prev_alarm;
977     die "interrupted by unexpected signal\n" if $sig_received;
978
979     die $error if $error;
980     return $res;
981 }
982
983 sub run_fork {
984     my ($code) = @_;
985     return run_fork_with_timeout(undef, $code);
986 }
987
988 # NOTE: NFS syscall can't be interrupted, so alarm does
989 # not work to provide timeouts.
990 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
991 # So fork() before using Filesys::Df
992 sub df {
993     my ($path, $timeout) = @_;
994
995     my $df = sub { return Filesys::Df::df($path, 1) };
996
997     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
998     warn $@ if $@;
999
1000     # untaint the values
1001     my ($blocks, $used, $bavail) = map { defined($_) ? (/^(\d+)$/) : 0 }
1002         $res->@{qw(blocks used bavail)};
1003
1004     return {
1005         total => $blocks,
1006         used => $used,
1007         avail => $bavail,
1008     };
1009 }
1010
1011 sub du {
1012     my ($path, $timeout) = @_;
1013
1014     my $size;
1015
1016     $timeout //= 10;
1017
1018     my $parser = sub {
1019         my $line = shift;
1020
1021         if ($line =~ m/^(\d+)\s+total$/) {
1022             $size = $1;
1023         }
1024     };
1025
1026     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1027
1028     return $size;
1029 }
1030
1031 # UPID helper
1032 # We use this to uniquely identify a process.
1033 # An 'Unique Process ID' has the following format:
1034 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1035
1036 sub upid_encode {
1037     my $d = shift;
1038
1039     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1040     # more that 8 characters for pstart
1041     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1042                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1043                    $d->{user});
1044 }
1045
1046 sub upid_decode {
1047     my ($upid, $noerr) = @_;
1048
1049     my $res;
1050     my $filename;
1051
1052     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1053     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1054     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1055         $res->{node} = $1;
1056         $res->{pid} = hex($3);
1057         $res->{pstart} = hex($4);
1058         $res->{starttime} = hex($5);
1059         $res->{type} = $6;
1060         $res->{id} = $7;
1061         $res->{user} = $8;
1062
1063         my $subdir = substr($5, 7, 8);
1064         $filename = "$pvetaskdir/$subdir/$upid";
1065
1066     } else {
1067         return undef if $noerr;
1068         die "unable to parse worker upid '$upid'\n";
1069     }
1070
1071     return wantarray ? ($res, $filename) : $res;
1072 }
1073
1074 sub upid_open {
1075     my ($upid) = @_;
1076
1077     my ($task, $filename) = upid_decode($upid);
1078
1079     my $dirname = dirname($filename);
1080     make_path($dirname);
1081
1082     my $wwwid = getpwnam('www-data') ||
1083         die "getpwnam failed";
1084
1085     my $perm = 0640;
1086
1087     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1088         die "unable to create output file '$filename' - $!\n";
1089     chown $wwwid, -1, $outfh;
1090
1091     return $outfh;
1092 };
1093
1094 sub upid_read_status {
1095     my ($upid) = @_;
1096
1097     my ($task, $filename) = upid_decode($upid);
1098     my $fh = IO::File->new($filename, "r");
1099     return "unable to open file - $!" if !$fh;
1100     my $maxlen = 4096;
1101     sysseek($fh, -$maxlen, 2);
1102     my $readbuf = '';
1103     my $br = sysread($fh, $readbuf, $maxlen);
1104     close($fh);
1105     if ($br) {
1106         return "unable to extract last line"
1107             if $readbuf !~ m/\n?(.+)$/;
1108         my $line = $1;
1109         if ($line =~ m/^TASK OK$/) {
1110             return 'OK';
1111         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1112             return $1;
1113         } else {
1114             return "unexpected status";
1115         }
1116     }
1117     return "unable to read tail (got $br bytes)";
1118 }
1119
1120 # useful functions to store comments in config files
1121 sub encode_text {
1122     my ($text) = @_;
1123
1124     # all control and hi-bit characters, and ':'
1125     my $unsafe = "^\x20-\x39\x3b-\x7e";
1126     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1127 }
1128
1129 sub decode_text {
1130     my ($data) = @_;
1131
1132     return Encode::decode("utf8", uri_unescape($data));
1133 }
1134
1135 # depreciated - do not use!
1136 # we now decode all parameters by default
1137 sub decode_utf8_parameters {
1138     my ($param) = @_;
1139
1140     foreach my $p (qw(comment description firstname lastname)) {
1141         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1142     }
1143
1144     return $param;
1145 }
1146
1147 sub random_ether_addr {
1148     my ($prefix) = @_;
1149
1150     my ($seconds, $microseconds) = gettimeofday;
1151
1152     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1153
1154     # clear multicast, set local id
1155     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1156
1157     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1158     if (defined($prefix)) {
1159         $addr = uc($prefix) . substr($addr, length($prefix));
1160     }
1161     return $addr;
1162 }
1163
1164 sub shellquote {
1165     my $str = shift;
1166
1167     return String::ShellQuote::shell_quote($str);
1168 }
1169
1170 sub cmd2string {
1171     my ($cmd) = @_;
1172
1173     die "no arguments" if !$cmd;
1174
1175     return $cmd if !ref($cmd);
1176
1177     my @qa = ();
1178     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1179
1180     return join (' ', @qa);
1181 }
1182
1183 # split an shell argument string into an array,
1184 sub split_args {
1185     my ($str) = @_;
1186
1187     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1188 }
1189
1190 sub dump_logfile {
1191     my ($filename, $start, $limit, $filter) = @_;
1192
1193     my $lines = [];
1194     my $count = 0;
1195
1196     my $fh = IO::File->new($filename, "r");
1197     if (!$fh) {
1198         $count++;
1199         push @$lines, { n => $count, t => "unable to open file - $!"};
1200         return ($count, $lines);
1201     }
1202
1203     $start = 0 if !$start;
1204     $limit = 50 if !$limit;
1205
1206     my $line;
1207
1208     if ($filter) {
1209         # duplicate code, so that we do not slow down normal path
1210         while (defined($line = <$fh>)) {
1211             next if $line !~ m/$filter/;
1212             next if $count++ < $start;
1213             next if $limit <= 0;
1214             chomp $line;
1215             push @$lines, { n => $count, t => $line};
1216             $limit--;
1217         }
1218     } else {
1219         while (defined($line = <$fh>)) {
1220             next if $count++ < $start;
1221             next if $limit <= 0;
1222             chomp $line;
1223             push @$lines, { n => $count, t => $line};
1224             $limit--;
1225         }
1226     }
1227
1228     close($fh);
1229
1230     # HACK: ExtJS store.guaranteeRange() does not like empty array
1231     # so we add a line
1232     if (!$count) {
1233         $count++;
1234         push @$lines, { n => $count, t => "no content"};
1235     }
1236
1237     return ($count, $lines);
1238 }
1239
1240 sub dump_journal {
1241     my ($start, $limit, $since, $until, $service) = @_;
1242
1243     my $lines = [];
1244     my $count = 0;
1245
1246     $start = 0 if !$start;
1247     $limit = 50 if !$limit;
1248
1249     my $parser = sub {
1250         my $line = shift;
1251
1252         return if $count++ < $start;
1253         return if $limit <= 0;
1254         push @$lines, { n => int($count), t => $line};
1255         $limit--;
1256     };
1257
1258     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1259
1260     push @$cmd, '--unit', $service if $service;
1261     push @$cmd, '--since', $since if $since;
1262     push @$cmd, '--until', $until if $until;
1263     run_command($cmd, outfunc => $parser);
1264
1265     # HACK: ExtJS store.guaranteeRange() does not like empty array
1266     # so we add a line
1267     if (!$count) {
1268         $count++;
1269         push @$lines, { n => $count, t => "no content"};
1270     }
1271
1272     return ($count, $lines);
1273 }
1274
1275 sub dir_glob_regex {
1276     my ($dir, $regex) = @_;
1277
1278     my $dh = IO::Dir->new ($dir);
1279     return wantarray ? () : undef if !$dh;
1280
1281     while (defined(my $tmp = $dh->read)) {
1282         if (my @res = $tmp =~ m/^($regex)$/) {
1283             $dh->close;
1284             return wantarray ? @res : $tmp;
1285         }
1286     }
1287     $dh->close;
1288
1289     return wantarray ? () : undef;
1290 }
1291
1292 sub dir_glob_foreach {
1293     my ($dir, $regex, $func) = @_;
1294
1295     my $dh = IO::Dir->new ($dir);
1296     if (defined $dh) {
1297         while (defined(my $tmp = $dh->read)) {
1298             if (my @res = $tmp =~ m/^($regex)$/) {
1299                 &$func (@res);
1300             }
1301         }
1302     }
1303 }
1304
1305 sub assert_if_modified {
1306     my ($digest1, $digest2) = @_;
1307
1308     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1309         die "detected modified configuration - file changed by other user? Try again.\n";
1310     }
1311 }
1312
1313 # Digest for short strings
1314 # like FNV32a, but we only return 31 bits (positive numbers)
1315 sub fnv31a {
1316     my ($string) = @_;
1317
1318     my $hval = 0x811c9dc5;
1319
1320     foreach my $c (unpack('C*', $string)) {
1321         $hval ^= $c;
1322         $hval += (
1323             (($hval << 1) ) +
1324             (($hval << 4) ) +
1325             (($hval << 7) ) +
1326             (($hval << 8) ) +
1327             (($hval << 24) ) );
1328         $hval = $hval & 0xffffffff;
1329     }
1330     return $hval & 0x7fffffff;
1331 }
1332
1333 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1334
1335 sub unpack_sockaddr_in46 {
1336     my ($sin) = @_;
1337     my $family = Socket::sockaddr_family($sin);
1338     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1339                                              : Socket::unpack_sockaddr_in($sin));
1340     return ($family, $port, $host);
1341 }
1342
1343 sub getaddrinfo_all {
1344     my ($hostname, @opts) = @_;
1345     my %hints = ( flags => AI_V4MAPPED | AI_ALL,
1346                   @opts );
1347     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1348     die "failed to get address info for: $hostname: $err\n" if $err;
1349     return @res;
1350 }
1351
1352 sub get_host_address_family {
1353     my ($hostname, $socktype) = @_;
1354     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1355     return $res[0]->{family};
1356 }
1357
1358 # get the fully qualified domain name of a host
1359 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1360 # given a nodename as a parameter
1361 sub get_fqdn {
1362     my ($nodename) = @_;
1363
1364     my $hints = {
1365         flags => AI_CANONNAME,
1366         socktype => SOCK_DGRAM
1367     };
1368
1369     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1370
1371     die "getaddrinfo: $err" if $err;
1372
1373     return $addrs[0]->{canonname};
1374 }
1375
1376 # Parses any sane kind of host, or host+port pair:
1377 # The port is always optional and thus may be undef.
1378 sub parse_host_and_port {
1379     my ($address) = @_;
1380     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1381         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1382         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1383     {
1384         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1385     }
1386     return; # nothing
1387 }
1388
1389 sub setresuid($$$) {
1390     my ($ruid, $euid, $suid) = @_;
1391     return 0 == syscall(PVE::Syscall::setresuid, $ruid, $euid, $suid);
1392 }
1393
1394 sub unshare($) {
1395     my ($flags) = @_;
1396     return 0 == syscall(PVE::Syscall::unshare, $flags);
1397 }
1398
1399 sub setns($$) {
1400     my ($fileno, $nstype) = @_;
1401     return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
1402 }
1403
1404 sub syncfs($) {
1405     my ($fileno) = @_;
1406     return 0 == syscall(PVE::Syscall::syncfs, $fileno);
1407 }
1408
1409 sub fsync($) {
1410     my ($fileno) = @_;
1411     return 0 == syscall(PVE::Syscall::fsync, $fileno);
1412 }
1413
1414 sub sync_mountpoint {
1415     my ($path) = @_;
1416     sysopen my $fd, $path, O_PATH or die "failed to open $path: $!\n";
1417     my $result = syncfs(fileno($fd));
1418     close($fd);
1419     return $result;
1420 }
1421
1422 # support sending multi-part mail messages with a text and or a HTML part
1423 # mailto may be a single email string or an array of receivers
1424 sub sendmail {
1425     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1426     my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
1427
1428     $mailto = [ $mailto ] if !ref($mailto);
1429
1430     foreach (@$mailto) {
1431         die "illegal character in mailto address\n"
1432             if ($_ =~ $mail_re);
1433     }
1434
1435     my $rcvrtxt = join (', ', @$mailto);
1436
1437     $mailfrom = $mailfrom || "root";
1438     die "illegal character in mailfrom address\n"
1439         if $mailfrom =~ $mail_re;
1440
1441     $author = $author || 'Proxmox VE';
1442
1443     open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, @$mailto) ||
1444         die "unable to open 'sendmail' - $!";
1445
1446     # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
1447     my $boundary = "----_=_NextPart_001_".int(time).$$;
1448
1449     print MAIL "Content-Type: multipart/alternative;\n";
1450     print MAIL "\tboundary=\"$boundary\"\n";
1451     print MAIL "MIME-Version: 1.0\n";
1452
1453     print MAIL "FROM: $author <$mailfrom>\n";
1454     print MAIL "TO: $rcvrtxt\n";
1455     print MAIL "SUBJECT: $subject\n";
1456     print MAIL "\n";
1457     print MAIL "This is a multi-part message in MIME format.\n\n";
1458     print MAIL "--$boundary\n";
1459
1460     if (defined($text)) {
1461         print MAIL "Content-Type: text/plain;\n";
1462         print MAIL "\tcharset=\"UTF8\"\n";
1463         print MAIL "Content-Transfer-Encoding: 8bit\n";
1464         print MAIL "\n";
1465
1466         # avoid 'remove extra line breaks' issue (MS Outlook)
1467         my $fill = '  ';
1468         $text =~ s/^/$fill/gm;
1469
1470         print MAIL $text;
1471
1472         print MAIL "\n--$boundary\n";
1473     }
1474
1475     if (defined($html)) {
1476         print MAIL "Content-Type: text/html;\n";
1477         print MAIL "\tcharset=\"UTF8\"\n";
1478         print MAIL "Content-Transfer-Encoding: 8bit\n";
1479         print MAIL "\n";
1480
1481         print MAIL $html;
1482
1483         print MAIL "\n--$boundary--\n";
1484     }
1485
1486     close(MAIL);
1487 }
1488
1489 sub tempfile {
1490     my ($perm, %opts) = @_;
1491
1492     # default permissions are stricter than with file_set_contents
1493     $perm = 0600 if !defined($perm);
1494
1495     my $dir = $opts{dir} // '/run';
1496     my $mode = $opts{mode} // O_RDWR;
1497     $mode |= O_EXCL if !$opts{allow_links};
1498
1499     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1500     if (!$fh && $! == EOPNOTSUPP) {
1501         $dir = '/tmp' if !defined($opts{dir});
1502         $dir .= "/.tmpfile.$$";
1503         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1504         unlink($dir) if $fh;
1505     }
1506     die "failed to create tempfile: $!\n" if !$fh;
1507     return $fh;
1508 }
1509
1510 sub tempfile_contents {
1511     my ($data, $perm, %opts) = @_;
1512
1513     my $fh = tempfile($perm, %opts);
1514     eval {
1515         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1516         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1517     };
1518     if (my $err = $@) {
1519         close $fh;
1520         die $err;
1521     }
1522
1523     return ("/proc/$$/fd/".$fh->fileno, $fh);
1524 }
1525
1526 sub validate_ssh_public_keys {
1527     my ($raw) = @_;
1528     my @lines = split(/\n/, $raw);
1529
1530     foreach my $line (@lines) {
1531         next if $line =~ m/^\s*$/;
1532         eval {
1533             my ($filename, $handle) = tempfile_contents($line);
1534             run_command(["ssh-keygen", "-l", "-f", $filename],
1535                         outfunc => sub {}, errfunc => sub {});
1536         };
1537         die "SSH public key validation error\n" if $@;
1538     }
1539 }
1540
1541 sub openat($$$;$) {
1542     my ($dirfd, $pathname, $flags, $mode) = @_;
1543     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
1544     return undef if $fd < 0;
1545     # sysopen() doesn't deal with numeric file descriptors apparently
1546     # so we need to convert to a mode string for IO::Handle->new_from_fd
1547     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1548     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1549     return $handle if $handle;
1550     my $err = $!; # save error before closing the raw fd
1551     syscall(PVE::Syscall::close, $fd); # close
1552     $! = $err;
1553     return undef;
1554 }
1555
1556 sub mkdirat($$$) {
1557     my ($dirfd, $name, $mode) = @_;
1558     return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
1559 }
1560
1561 sub fchownat($$$$$) {
1562     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1563     return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
1564 }
1565
1566 my $salt_starter = time();
1567
1568 sub encrypt_pw {
1569     my ($pw) = @_;
1570
1571     $salt_starter++;
1572     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1573
1574     # crypt does not want '+' in salt (see 'man crypt')
1575     $salt =~ s/\+/X/g;
1576
1577     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1578 }
1579
1580 # intended usage: convert_size($val, "kb" => "gb")
1581 # we round up to the next integer by default
1582 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1583 # use $no_round_up to switch this off, above example would then return 0
1584 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1585 # (0 if $no_round_up is true)
1586 # allowed formats for value:
1587 # 1234
1588 # 1234.
1589 # 1234.1234
1590 # .1234
1591 sub convert_size {
1592     my ($value, $from, $to, $no_round_up) = @_;
1593
1594     my $units = {
1595         b  => 0,
1596         kb => 1,
1597         mb => 2,
1598         gb => 3,
1599         tb => 4,
1600         pb => 5,
1601     };
1602
1603     die "no value given"
1604         if !defined($value) || $value eq "";
1605
1606     $from = lc($from // ''); $to = lc($to // '');
1607     die "unknown 'from' and/or 'to' units ($from => $to)"
1608         if !defined($units->{$from}) || !defined($units->{$to});
1609
1610     die "value '$value' is not a valid, positive number"
1611         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1612
1613     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1614
1615     $value *= 2**$shift_amount;
1616     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1617
1618     return int($value);
1619 }
1620
1621 # uninterruptible readline
1622 # retries on EINTR
1623 sub readline_nointr {
1624     my ($fh) = @_;
1625     my $line;
1626     while (1) {
1627         $line = <$fh>;
1628         last if defined($line) || ($! != EINTR);
1629     }
1630     return $line;
1631 }
1632
1633 sub get_host_arch {
1634
1635     my @uname = POSIX::uname();
1636     my $machine = $uname[4];
1637
1638     if ($machine eq 'x86_64') {
1639         return 'amd64';
1640     } elsif ($machine eq 'aarch64') {
1641         return 'arm64';
1642     } else {
1643         die "unsupported host architecture '$machine'\n";
1644     }
1645 }
1646
1647 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1648 sub dev_t_major($) {
1649     my ($dev_t) = @_;
1650     return (int($dev_t) & 0xfff00) >> 8;
1651 }
1652
1653 sub dev_t_minor($) {
1654     my ($dev_t) = @_;
1655     $dev_t = int($dev_t);
1656     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1657 }
1658
1659 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1660 # Returns the intersection of elements as a single array [a b]
1661 sub array_intersect {
1662     my ($arrays) = @_;
1663
1664     if (!ref($arrays->[0])) {
1665         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1666     }
1667
1668     return [] if scalar(@$arrays) == 0;
1669     return $arrays->[0] if scalar(@$arrays) == 1;
1670
1671     my $array_unique = sub {
1672         my %seen = ();
1673         return grep { ! $seen{ $_ }++ } @_;
1674     };
1675
1676     # base idea is to get all unique members from the first array, then
1677     # check the common elements with the next (uniquely made) one, only keep
1678     # those. Repeat for every array and at the end we only have those left
1679     # which exist in all arrays
1680     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1681     for my $i (1 .. $#$arrays) {
1682         my %count = ();
1683         # $return_arr is already unique, explicit at before the loop, implicit below.
1684         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1685             $count{$element}++;
1686         }
1687         $return_arr = [];
1688         foreach my $element (keys %count) {
1689             push @$return_arr, $element if $count{$element} > 1;
1690         }
1691         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1692     }
1693
1694     return $return_arr;
1695 }
1696
1697
1698 1;