src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Date::Format qw(time2str);
   7 use Digest::MD5;
   8 use Digest::SHA;
   9 use Encode;
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::Path qw(make_path);
  13 use Filesys::Df (); # don't overwrite our df()
  14 use IO::Dir;
  15 use IO::File;
  16 use IO::Handle;
  17 use IO::Pipe;
  18 use IO::Select;
  19 use IO::Socket::IP;
  20 use IPC::Open3;
  21 use JSON;
  22 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
  23 use Scalar::Util 'weaken';
  24 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM IPPROTO_TCP);
  25 use String::ShellQuote;
  26 use Text::ParseWords;
  27 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  28 use URI::Escape;
  29 use base 'Exporter';
  30
  31 use PVE::Syscall;
  32
  33 # avoid warning when parsing long hex values with hex()
  34 no warnings 'portable'; # Support for 64-bit ints required
  35
  36 our @EXPORT_OK = qw(
  37 $IPV6RE
  38 $IPV4RE
  39 lock_file
  40 lock_file_full
  41 run_command
  42 file_set_contents
  43 file_get_contents
  44 file_read_firstline
  45 dir_glob_regex
  46 dir_glob_foreach
  47 split_list
  48 template_replace
  49 safe_print
  50 trim
  51 extract_param
  52 extract_sensitive_params
  53 file_copy
  54 get_host_arch
  55 O_PATH
  56 O_TMPFILE
  57 AT_EMPTY_PATH
  58 AT_FDCWD
  59 CLONE_NEWNS
  60 CLONE_NEWUTS
  61 CLONE_NEWIPC
  62 CLONE_NEWUSER
  63 CLONE_NEWPID
  64 CLONE_NEWNET
  65 );
  66
  67 my $pvelogdir = "/var/log/pve";
  68 my $pvetaskdir = "$pvelogdir/tasks";
  69
  70 mkdir $pvelogdir;
  71 mkdir $pvetaskdir;
  72
  73 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  74 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  75 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  76 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  77
  78 our $IPV6RE = "(?:" .
  79     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  80     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  81     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  84     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  85     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  86     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  87     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  88
  89 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  90
  91 our $EMAIL_USER_RE = qr/[\w\+\-\~]+(\.[\w\+\-\~]+)*/;
  92 our $EMAIL_RE = qr/$EMAIL_USER_RE@[a-zA-Z0-9\-]+(\.[a-zA-Z0-9\-]+)*/;
  93
  94 use constant {CLONE_NEWNS   => 0x00020000,
  95               CLONE_NEWUTS  => 0x04000000,
  96               CLONE_NEWIPC  => 0x08000000,
  97               CLONE_NEWUSER => 0x10000000,
  98               CLONE_NEWPID  => 0x20000000,
  99               CLONE_NEWNET  => 0x40000000};
 100
 101 use constant {O_PATH    => 0x00200000,
 102               O_CLOEXEC => 0x00080000,
 103               O_TMPFILE => 0x00400000 | O_DIRECTORY};
 104
 105 use constant {AT_EMPTY_PATH => 0x1000,
 106               AT_FDCWD => -100};
 107
 108 # from <linux/fs.h>
 109 use constant {RENAME_NOREPLACE => (1 << 0),
 110               RENAME_EXCHANGE  => (1 << 1),
 111               RENAME_WHITEOUT  => (1 << 2)};
 112
 113 sub run_with_timeout {
 114     my ($timeout, $code, @param) = @_;
 115
 116     die "got timeout\n" if $timeout <= 0;
 117
 118     my $prev_alarm = alarm 0; # suspend outer alarm early
 119
 120     my $sigcount = 0;
 121     my $got_timeout = 0;
 122
 123     my $res;
 124
 125     eval {
 126         local $SIG{ALRM} = sub { $sigcount++; $got_timeout = 1;  die "got timeout\n"; };
 127         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 128         local $SIG{__DIE__};   # see SA bug 4631
 129
 130         alarm($timeout);
 131
 132         eval { $res = &$code(@param); };
 133
 134         alarm(0); # avoid race conditions
 135
 136         die $@ if $@;
 137     };
 138
 139     my $err = $@;
 140
 141     alarm $prev_alarm;
 142
 143     # this shouldn't happen anymore?
 144     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 145
 146     # assume that user handles timeout err if called in list context
 147     die $err if $err && (!wantarray || !$got_timeout);
 148
 149     return wantarray ? ($res, $got_timeout) : $res;
 150 }
 151
 152 # flock: we use one file handle per process, so lock file
 153 # can be nested multiple times and succeeds for the same process.
 154 #
 155 # Since this is the only way we lock now and we don't have the old
 156 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 157 # count how deep we're nesting. Therefore this hash now stores a weak reference
 158 # to a boolean telling us whether we already have a lock.
 159
 160 my $lock_handles =  {};
 161
 162 sub lock_file_full {
 163     my ($filename, $timeout, $shared, $code, @param) = @_;
 164
 165     $timeout = 10 if !$timeout;
 166
 167     my $mode = $shared ? LOCK_SH : LOCK_EX;
 168
 169     my $lockhash = ($lock_handles->{$$} //= {});
 170
 171     # Returns a locked file handle.
 172     my $get_locked_file = sub {
 173         my $fh = IO::File->new(">>$filename")
 174             or die "can't open file - $!\n";
 175
 176         if (!flock($fh, $mode|LOCK_NB)) {
 177             print STDERR "trying to acquire lock...\n";
 178             my $success;
 179             while(1) {
 180                 $success = flock($fh, $mode);
 181                 # try again on EINTR (see bug #273)
 182                 if ($success || ($! != EINTR)) {
 183                     last;
 184                 }
 185             }
 186             if (!$success) {
 187                 print STDERR " failed\n";
 188                 die "can't acquire lock '$filename' - $!\n";
 189             }
 190             print STDERR " OK\n";
 191         }
 192
 193         return $fh;
 194     };
 195
 196     my $res;
 197     my $checkptr = $lockhash->{$filename};
 198     my $check = 0; # This must not go out of scope before running the code.
 199     my $local_fh; # This must stay local
 200     if (!$checkptr || !$$checkptr) {
 201         # We cannot create a weak reference in a single atomic step, so we first
 202         # create a false-value, then create a reference to it, then weaken it,
 203         # and after successfully locking the file we change the boolean value.
 204         #
 205         # The reason for this is that if an outer SIGALRM throws an exception
 206         # between creating the reference and weakening it, a subsequent call to
 207         # lock_file_full() will see a leftover full reference to a valid
 208         # variable. This variable must be 0 in order for said call to attempt to
 209         # lock the file anew.
 210         #
 211         # An externally triggered exception elsewhere in the code will cause the
 212         # weak reference to become 'undef', and since the file handle is only
 213         # stored in the local scope in $local_fh, the file will be closed by
 214         # perl's cleanup routines as well.
 215         #
 216         # This still assumes that an IO::File handle can properly deal with such
 217         # exceptions thrown during its own destruction, but that's up to perls
 218         # guts now.
 219         $lockhash->{$filename} = \$check;
 220         weaken $lockhash->{$filename};
 221         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 222         if ($@) {
 223             $@ = "can't lock file '$filename' - $@";
 224             return undef;
 225         }
 226         $check = 1;
 227     }
 228     $res = eval { &$code(@param); };
 229     return undef if $@;
 230     return $res;
 231 }
 232
 233
 234 sub lock_file {
 235     my ($filename, $timeout, $code, @param) = @_;
 236
 237     return lock_file_full($filename, $timeout, 0, $code, @param);
 238 }
 239
 240 sub file_set_contents {
 241     my ($filename, $data, $perm, $force_utf8)  = @_;
 242
 243     $perm = 0644 if !defined($perm);
 244
 245     my $tmpname = "$filename.tmp.$$";
 246
 247     eval {
 248         my ($fh, $tries) = (undef, 0);
 249         while (!$fh && $tries++ < 3) {
 250             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 251             if (!$fh && $! == EEXIST) {
 252                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 253             }
 254         }
 255         die "unable to open file '$tmpname' - $!\n" if !$fh;
 256
 257         binmode($fh, ":encoding(UTF-8)") if $force_utf8;
 258
 259         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 260         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 261     };
 262     my $err = $@;
 263
 264     if ($err) {
 265         unlink $tmpname;
 266         die $err;
 267     }
 268
 269     if (!rename($tmpname, $filename)) {
 270         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 271         unlink $tmpname;
 272         die $msg;
 273     }
 274 }
 275
 276 sub file_get_contents {
 277     my ($filename, $max) = @_;
 278
 279     my $fh = IO::File->new($filename, "r") ||
 280         die "can't open '$filename' - $!\n";
 281
 282     my $content = safe_read_from($fh, $max, 0, $filename);
 283
 284     close $fh;
 285
 286     return $content;
 287 }
 288
 289 sub file_copy {
 290     my ($filename, $dst, $max, $perm) = @_;
 291
 292     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 293 }
 294
 295 sub file_read_firstline {
 296     my ($filename) = @_;
 297
 298     my $fh = IO::File->new ($filename, "r");
 299     if (!$fh) {
 300         return undef if $! == POSIX::ENOENT;
 301         die "file '$filename' exists but open for reading failed - $!\n";
 302     }
 303     my $res = <$fh>;
 304     chomp $res if $res;
 305     $fh->close;
 306     return $res;
 307 }
 308
 309 sub safe_read_from {
 310     my ($fh, $max, $oneline, $filename) = @_;
 311
 312     # pmxcfs file size limit
 313     $max = 1024 * 1024 if !$max;
 314
 315     my $subject = defined($filename) ? "file '$filename'" : 'input';
 316
 317     my $br = 0;
 318     my $input = '';
 319     my $count;
 320     while ($count = sysread($fh, $input, 8192, $br)) {
 321         $br += $count;
 322         die "$subject too long - aborting\n" if $br > $max;
 323         if ($oneline && $input =~ m/^(.*)\n/) {
 324             $input = $1;
 325             last;
 326         }
 327     }
 328     die "unable to read $subject - $!\n" if !defined($count);
 329
 330     return $input;
 331 }
 332
 333 # The $cmd parameter can be:
 334 #  -) a string
 335 #    This is generally executed by passing it to the shell with the -c option.
 336 #    However, it can be executed in one of two ways, depending on whether
 337 #    there's a pipe involved:
 338 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 339 #          set -o pipefail &&
 340 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 341 #      (Note that this may result in two different syntax requirements!)
 342 #      FIXME?
 343 #  -) an array of arguments (strings)
 344 #    Will be executed without interference from a shell. (Parameters are passed
 345 #    as is, no escape sequences of strings will be touched.)
 346 #  -) an array of arrays
 347 #    Each array represents a command, and each command's output is piped into
 348 #    the following command's standard input.
 349 #    For this a shell command string is created with pipe symbols between each
 350 #    command.
 351 #    Each command is a list of strings meant to end up in the final command
 352 #    unchanged. In order to achieve this, every argument is shell-quoted.
 353 #    Quoting can be disabled for a particular argument by turning it into a
 354 #    reference, this allows inserting arbitrary shell options.
 355 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 356 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 357 #    will literally print: hello >/dev/null
 358 sub run_command {
 359     my ($cmd, %param) = @_;
 360
 361     my $old_umask;
 362     my $cmdstr;
 363
 364     if (my $ref = ref($cmd)) {
 365         if (ref($cmd->[0])) {
 366             $cmdstr = 'set -o pipefail && ';
 367             my $pipe = '';
 368             foreach my $command (@$cmd) {
 369                 # concatenate quoted parameters
 370                 # strings which are passed by reference are NOT shell quoted
 371                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 372                 $pipe = ' | ';
 373             }
 374             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 375         } else {
 376             $cmdstr = cmd2string($cmd);
 377         }
 378     } else {
 379         $cmdstr = $cmd;
 380         if ($cmd =~ m/\|/) {
 381             # see 'man bash' for option pipefail
 382             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 383         } else {
 384             $cmd = [ $cmd ];
 385         }
 386     }
 387
 388     my $errmsg;
 389     my $laststderr;
 390     my $timeout;
 391     my $oldtimeout;
 392     my $pid;
 393     my $exitcode = -1;
 394
 395     my $outfunc;
 396     my $errfunc;
 397     my $logfunc;
 398     my $input;
 399     my $output;
 400     my $afterfork;
 401     my $noerr;
 402     my $keeplocale;
 403     my $quiet;
 404
 405     eval {
 406
 407         foreach my $p (keys %param) {
 408             if ($p eq 'timeout') {
 409                 $timeout = $param{$p};
 410             } elsif ($p eq 'umask') {
 411                 $old_umask = umask($param{$p});
 412             } elsif ($p eq 'errmsg') {
 413                 $errmsg = $param{$p};
 414             } elsif ($p eq 'input') {
 415                 $input = $param{$p};
 416             } elsif ($p eq 'output') {
 417                 $output = $param{$p};
 418             } elsif ($p eq 'outfunc') {
 419                 $outfunc = $param{$p};
 420             } elsif ($p eq 'errfunc') {
 421                 $errfunc = $param{$p};
 422             } elsif ($p eq 'logfunc') {
 423                 $logfunc = $param{$p};
 424             } elsif ($p eq 'afterfork') {
 425                 $afterfork = $param{$p};
 426             } elsif ($p eq 'noerr') {
 427                 $noerr = $param{$p};
 428             } elsif ($p eq 'keeplocale') {
 429                 $keeplocale = $param{$p};
 430             } elsif ($p eq 'quiet') {
 431                 $quiet = $param{$p};
 432             } else {
 433                 die "got unknown parameter '$p' for run_command\n";
 434             }
 435         }
 436
 437         if ($errmsg) {
 438             my $origerrfunc = $errfunc;
 439             $errfunc = sub {
 440                 if ($laststderr) {
 441                     if ($origerrfunc) {
 442                         &$origerrfunc("$laststderr\n");
 443                     } else {
 444                         print STDERR "$laststderr\n" if $laststderr;
 445                     }
 446                 }
 447                 $laststderr = shift;
 448             };
 449         }
 450
 451         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 452         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 453         my $error  = IO::File->new();
 454
 455         my $orig_pid = $$;
 456
 457         eval {
 458             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 459
 460             # suppress LVM warnings like: "File descriptor 3 left open";
 461             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 462
 463             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 464
 465             # if we pipe fron STDIN, open3 closes STDIN, so we get a perl warning like
 466             # "Filehandle STDIN reopened as GENXYZ .. " as soon as we open a new file.
 467             # to avoid that we open /dev/null
 468             if (!ref($writer) && !defined(fileno(STDIN))) {
 469                 POSIX::close(0);
 470                 open(STDIN, '<', '/dev/null');
 471             }
 472         };
 473
 474         my $err = $@;
 475
 476         # catch exec errors
 477         if ($orig_pid != $$) {
 478             warn "ERROR: $err";
 479             POSIX::_exit (1);
 480             kill ('KILL', $$);
 481         }
 482
 483         die $err if $err;
 484
 485         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 486         $oldtimeout = alarm($timeout) if $timeout;
 487
 488         &$afterfork() if $afterfork;
 489
 490         if (ref($writer)) {
 491             print $writer $input if defined $input;
 492             close $writer;
 493         }
 494
 495         my $select = IO::Select->new();
 496         $select->add($reader) if ref($reader);
 497         $select->add($error);
 498
 499         my $outlog = '';
 500         my $errlog = '';
 501
 502         my $starttime = time();
 503
 504         while ($select->count) {
 505             my @handles = $select->can_read(1);
 506
 507             foreach my $h (@handles) {
 508                 my $buf = '';
 509                 my $count = sysread ($h, $buf, 4096);
 510                 if (!defined ($count)) {
 511                     my $err = $!;
 512                     kill (9, $pid);
 513                     waitpid ($pid, 0);
 514                     die $err;
 515                 }
 516                 $select->remove ($h) if !$count;
 517                 if ($h eq $reader) {
 518                     if ($outfunc || $logfunc) {
 519                         eval {
 520                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 521                                 my $line = $outlog . $1;
 522                                 $outlog = '';
 523                                 &$outfunc($line) if $outfunc;
 524                                 &$logfunc($line) if $logfunc;
 525                             }
 526                             $outlog .= $buf;
 527                         };
 528                         my $err = $@;
 529                         if ($err) {
 530                             kill (9, $pid);
 531                             waitpid ($pid, 0);
 532                             die $err;
 533                         }
 534                     } elsif (!$quiet) {
 535                         print $buf;
 536                         *STDOUT->flush();
 537                     }
 538                 } elsif ($h eq $error) {
 539                     if ($errfunc || $logfunc) {
 540                         eval {
 541                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 542                                 my $line = $errlog . $1;
 543                                 $errlog = '';
 544                                 &$errfunc($line) if $errfunc;
 545                                 &$logfunc($line) if $logfunc;
 546                             }
 547                             $errlog .= $buf;
 548                         };
 549                         my $err = $@;
 550                         if ($err) {
 551                             kill (9, $pid);
 552                             waitpid ($pid, 0);
 553                             die $err;
 554                         }
 555                     } elsif (!$quiet) {
 556                         print STDERR $buf;
 557                         *STDERR->flush();
 558                     }
 559                 }
 560             }
 561         }
 562
 563         &$outfunc($outlog) if $outfunc && $outlog;
 564         &$logfunc($outlog) if $logfunc && $outlog;
 565
 566         &$errfunc($errlog) if $errfunc && $errlog;
 567         &$logfunc($errlog) if $logfunc && $errlog;
 568
 569         waitpid ($pid, 0);
 570
 571         if ($? == -1) {
 572             die "failed to execute\n";
 573         } elsif (my $sig = ($? & 127)) {
 574             die "got signal $sig\n";
 575         } elsif ($exitcode = ($? >> 8)) {
 576             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 577                 if ($errmsg && $laststderr) {
 578                     my $lerr = $laststderr;
 579                     $laststderr = undef;
 580                     die "$lerr\n";
 581                 }
 582                 die "exit code $exitcode\n";
 583             }
 584         }
 585
 586         alarm(0);
 587     };
 588
 589     my $err = $@;
 590
 591     alarm(0);
 592
 593     if ($errmsg && $laststderr) {
 594         &$errfunc(undef); # flush laststderr
 595     }
 596
 597     umask ($old_umask) if defined($old_umask);
 598
 599     alarm($oldtimeout) if $oldtimeout;
 600
 601     if ($err) {
 602         if ($pid && ($err eq "got timeout\n")) {
 603             kill (9, $pid);
 604             waitpid ($pid, 0);
 605             die "command '$cmdstr' failed: $err";
 606         }
 607
 608         if ($errmsg) {
 609             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 610             die "$errmsg: $err";
 611         } elsif(!$noerr) {
 612             die "command '$cmdstr' failed: $err";
 613         }
 614     }
 615
 616     return $exitcode;
 617 }
 618
 619 # Run a command with a tcp socket as standard input.
 620 sub pipe_socket_to_command  {
 621     my ($cmd, $ip, $port) = @_;
 622
 623     my $params = {
 624         Listen => 1,
 625         ReuseAddr => 1,
 626         Proto => &Socket::IPPROTO_TCP,
 627         GetAddrInfoFlags => 0,
 628         LocalAddr => $ip,
 629         LocalPort => $port,
 630     };
 631     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 632
 633     print "$ip\n$port\n"; # tell remote where to connect
 634     *STDOUT->flush();
 635
 636     alarm 0;
 637     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 638     alarm 30;
 639     my $client = $socket->accept; # Wait for a client
 640     alarm 0;
 641     close($socket);
 642
 643     # We want that the command talks over the TCP socket and takes
 644     # ownership of it, so that when it closes it the connection is
 645     # terminated, so we need to be able to close the socket. So we
 646     # can't really use PVE::Tools::run_command().
 647     my $pid = fork() // die "fork failed: $!\n";
 648     if (!$pid) {
 649         POSIX::dup2(fileno($client), 0);
 650         POSIX::dup2(fileno($client), 1);
 651         close($client);
 652         exec {$cmd->[0]} @$cmd or do {
 653             warn "exec failed: $!\n";
 654             POSIX::_exit(1);
 655         };
 656     }
 657
 658     close($client);
 659     if (waitpid($pid, 0) != $pid) {
 660         kill(15 => $pid); # if we got interrupted terminate the child
 661         my $count = 0;
 662         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 663             usleep(100000);
 664             $count++;
 665             kill(9 => $pid), last if $count > 300; # 30 second timeout
 666         }
 667     }
 668     if (my $sig = ($? & 127)) {
 669         die "got signal $sig\n";
 670     } elsif (my $exitcode = ($? >> 8)) {
 671         die "exit code $exitcode\n";
 672     }
 673
 674     return undef;
 675 }
 676
 677 sub split_list {
 678     my $listtxt = shift // '';
 679
 680     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 681
 682     $listtxt =~ s/[,;]/ /g;
 683     $listtxt =~ s/^\s+//;
 684
 685     my @data = split (/\s+/, $listtxt);
 686
 687     return @data;
 688 }
 689
 690 sub trim {
 691     my $txt = shift;
 692
 693     return $txt if !defined($txt);
 694
 695     $txt =~ s/^\s+//;
 696     $txt =~ s/\s+$//;
 697
 698     return $txt;
 699 }
 700
 701 # simple uri templates like "/vms/{vmid}"
 702 sub template_replace {
 703     my ($tmpl, $data) = @_;
 704
 705     return $tmpl if !$tmpl;
 706
 707     my $res = '';
 708     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 709         $res .= $1 if $1;
 710         $res .= ($data->{$3} || '-') if $2;
 711     }
 712     return $res;
 713 }
 714
 715 sub safe_print {
 716     my ($filename, $fh, $data) = @_;
 717
 718     return if !$data;
 719
 720     my $res = print $fh $data;
 721
 722     die "write to '$filename' failed\n" if !$res;
 723 }
 724
 725 sub debmirrors {
 726
 727     return {
 728         'at' => 'ftp.at.debian.org',
 729         'au' => 'ftp.au.debian.org',
 730         'be' => 'ftp.be.debian.org',
 731         'bg' => 'ftp.bg.debian.org',
 732         'br' => 'ftp.br.debian.org',
 733         'ca' => 'ftp.ca.debian.org',
 734         'ch' => 'ftp.ch.debian.org',
 735         'cl' => 'ftp.cl.debian.org',
 736         'cz' => 'ftp.cz.debian.org',
 737         'de' => 'ftp.de.debian.org',
 738         'dk' => 'ftp.dk.debian.org',
 739         'ee' => 'ftp.ee.debian.org',
 740         'es' => 'ftp.es.debian.org',
 741         'fi' => 'ftp.fi.debian.org',
 742         'fr' => 'ftp.fr.debian.org',
 743         'gr' => 'ftp.gr.debian.org',
 744         'hk' => 'ftp.hk.debian.org',
 745         'hr' => 'ftp.hr.debian.org',
 746         'hu' => 'ftp.hu.debian.org',
 747         'ie' => 'ftp.ie.debian.org',
 748         'is' => 'ftp.is.debian.org',
 749         'it' => 'ftp.it.debian.org',
 750         'jp' => 'ftp.jp.debian.org',
 751         'kr' => 'ftp.kr.debian.org',
 752         'mx' => 'ftp.mx.debian.org',
 753         'nl' => 'ftp.nl.debian.org',
 754         'no' => 'ftp.no.debian.org',
 755         'nz' => 'ftp.nz.debian.org',
 756         'pl' => 'ftp.pl.debian.org',
 757         'pt' => 'ftp.pt.debian.org',
 758         'ro' => 'ftp.ro.debian.org',
 759         'ru' => 'ftp.ru.debian.org',
 760         'se' => 'ftp.se.debian.org',
 761         'si' => 'ftp.si.debian.org',
 762         'sk' => 'ftp.sk.debian.org',
 763         'tr' => 'ftp.tr.debian.org',
 764         'tw' => 'ftp.tw.debian.org',
 765         'gb' => 'ftp.uk.debian.org',
 766         'us' => 'ftp.us.debian.org',
 767     };
 768 }
 769
 770 my $keymaphash =  {
 771     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 772     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 773     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 774     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 775     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 776     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 777     #'et'     => [], # Ethopia or Estonia ??
 778     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 779     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 780     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 781     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 782     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 783     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 784     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 785     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 786     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 787     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 788     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 789     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 790     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 791     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 792     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 793     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 794     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 795     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 796     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 797     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 798     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 799     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 800     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 801     #'th'     => [],
 802     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 803 };
 804
 805 my $kvmkeymaparray = [];
 806 foreach my $lc (sort keys %$keymaphash) {
 807     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 808 }
 809
 810 sub kvmkeymaps {
 811     return $keymaphash;
 812 }
 813
 814 sub kvmkeymaplist {
 815     return $kvmkeymaparray;
 816 }
 817
 818 sub extract_param {
 819     my ($param, $key) = @_;
 820
 821     my $res = $param->{$key};
 822     delete $param->{$key};
 823
 824     return $res;
 825 }
 826
 827 # For extracting sensitive keys (e.g. password), to avoid writing them to www-data owned configs
 828 sub extract_sensitive_params :prototype($$$) {
 829     my ($param, $sensitive_list, $delete_list) = @_;
 830
 831     my %delete = map { $_ => 1 } ($delete_list || [])->@*;
 832
 833     my $sensitive = {};
 834     for my $opt (@$sensitive_list) {
 835         # handle deletions as explicitly setting `undef`, so subs which only have $param but not
 836         # $delete_list available can recognize them. Afterwards new values  may override.
 837         if (exists($delete{$opt})) {
 838             $sensitive->{$opt} = undef;
 839         }
 840
 841         if (defined(my $value = extract_param($param, $opt))) {
 842             $sensitive->{$opt} = $value;
 843         }
 844     }
 845
 846     return $sensitive;
 847 }
 848
 849 # Note: we use this to wait until vncterm/spiceterm is ready
 850 sub wait_for_vnc_port {
 851     my ($port, $family, $timeout) = @_;
 852
 853     $timeout = 5 if !$timeout;
 854     my $sleeptime = 0;
 855     my $starttime = [gettimeofday];
 856     my $elapsed;
 857
 858     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 859     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 860
 861     my $found;
 862     while (($elapsed = tv_interval($starttime)) < $timeout) {
 863         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 864         run_command($cmd, outfunc => sub {
 865             my $line = shift;
 866             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 867                 $found = 1 if ($port == $1);
 868             }
 869         });
 870         return 1 if $found;
 871         $sleeptime += 100000 if  $sleeptime < 1000000;
 872         usleep($sleeptime);
 873     }
 874
 875     die "Timeout while waiting for port '$port' to get ready!\n";
 876 }
 877
 878 sub next_unused_port {
 879     my ($range_start, $range_end, $family, $address) = @_;
 880
 881     # We use a file to register allocated ports.
 882     # Those registrations expires after $expiretime.
 883     # We use this to avoid race conditions between
 884     # allocation and use of ports.
 885
 886     my $filename = "/var/tmp/pve-reserved-ports";
 887
 888     my $code = sub {
 889
 890         my $expiretime = 5;
 891         my $ctime = time();
 892
 893         my $ports = {};
 894
 895         if (my $fh = IO::File->new ($filename, "r")) {
 896             while (my $line = <$fh>) {
 897                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 898                     my ($port, $timestamp) = ($1, $2);
 899                     if (($timestamp + $expiretime) > $ctime) {
 900                         $ports->{$port} = $timestamp; # not expired
 901                     }
 902                 }
 903             }
 904         }
 905
 906         my $newport;
 907         my %sockargs = (Listen => 5,
 908                         ReuseAddr => 1,
 909                         Family    => $family,
 910                         Proto     => IPPROTO_TCP,
 911                         GetAddrInfoFlags => 0);
 912         $sockargs{LocalAddr} = $address if defined($address);
 913
 914         for (my $p = $range_start; $p < $range_end; $p++) {
 915             next if $ports->{$p}; # reserved
 916
 917             $sockargs{LocalPort} = $p;
 918             my $sock = IO::Socket::IP->new(%sockargs);
 919
 920             if ($sock) {
 921                 close($sock);
 922                 $newport = $p;
 923                 $ports->{$p} = $ctime;
 924                 last;
 925             }
 926         }
 927
 928         my $data = "";
 929         foreach my $p (keys %$ports) {
 930             $data .= "$p $ports->{$p}\n";
 931         }
 932
 933         file_set_contents($filename, $data);
 934
 935         return $newport;
 936     };
 937
 938     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 939     die $@ if $@;
 940
 941     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 942
 943     return $p;
 944 }
 945
 946 sub next_migrate_port {
 947     my ($family, $address) = @_;
 948     return next_unused_port(60000, 60050, $family, $address);
 949 }
 950
 951 sub next_vnc_port {
 952     my ($family, $address) = @_;
 953     return next_unused_port(5900, 6000, $family, $address);
 954 }
 955
 956 sub spice_port_range {
 957     return (61000, 61999);
 958 }
 959
 960 sub next_spice_port {
 961     my ($family, $address) = @_;
 962     return next_unused_port(spice_port_range(), $family, $address);
 963 }
 964
 965 sub must_stringify {
 966         my ($value) = @_;
 967         eval { $value = "$value" };
 968         return "error turning value into a string: $@" if $@;
 969         return $value;
 970 }
 971
 972 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 973 # the $sub has to return a single scalar
 974 sub run_fork_with_timeout {
 975     my ($timeout, $sub) = @_;
 976
 977     my $res;
 978     my $error;
 979     my $pipe_out = IO::Pipe->new();
 980
 981     # disable pending alarms, save their remaining time
 982     my $prev_alarm = alarm 0;
 983
 984     # avoid leaving a zombie if the parent gets interrupted
 985     my $sig_received;
 986
 987     my $child = fork();
 988     if (!defined($child)) {
 989         die "fork failed: $!\n";
 990         return $res;
 991     }
 992
 993     if (!$child) {
 994         $pipe_out->writer();
 995
 996         eval {
 997             $res = $sub->();
 998             print {$pipe_out} encode_json({ result => $res });
 999             $pipe_out->flush();
1000         };
1001         if (my $err = $@) {
1002             print {$pipe_out} encode_json({ error => must_stringify($err) });
1003             $pipe_out->flush();
1004             POSIX::_exit(1);
1005         }
1006         POSIX::_exit(0);
1007     }
1008
1009     local $SIG{INT} = sub { $sig_received++; };
1010     local $SIG{TERM} = sub {
1011         $error //= "interrupted by unexpected signal\n";
1012         kill('TERM', $child);
1013     };
1014
1015     $pipe_out->reader();
1016
1017     my $readvalues = sub {
1018         local $/ = undef;
1019         my $child_res = decode_json(readline_nointr($pipe_out));
1020         $res = $child_res->{result};
1021         $error = $child_res->{error};
1022     };
1023
1024     my $got_timeout = 0;
1025     my $wantarray = wantarray; # so it can be queried inside eval
1026     eval {
1027         if (defined($timeout)) {
1028             if ($wantarray) {
1029                 (undef, $got_timeout) = run_with_timeout($timeout, $readvalues);
1030             } else {
1031                 run_with_timeout($timeout, $readvalues);
1032             }
1033         } else {
1034             $readvalues->();
1035         }
1036     };
1037     warn $@ if $@;
1038     $pipe_out->close();
1039     kill('KILL', $child);
1040     # FIXME: hangs if $child doesn't exits?! (D state)
1041     waitpid($child, 0);
1042
1043     alarm $prev_alarm;
1044     die "interrupted by unexpected signal\n" if $sig_received;
1045
1046     die $error if $error;
1047     return wantarray ? ($res, $got_timeout) : $res;
1048 }
1049
1050 sub run_fork {
1051     my ($code) = @_;
1052     return run_fork_with_timeout(undef, $code);
1053 }
1054
1055 # NOTE: NFS syscall can't be interrupted, so alarm does
1056 # not work to provide timeouts.
1057 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1058 # So fork() before using Filesys::Df
1059 sub df {
1060     my ($path, $timeout) = @_;
1061
1062     my $df = sub { return Filesys::Df::df($path, 1) };
1063
1064     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1065     warn $@ if $@;
1066
1067     # untaint, but be flexible: PB usage can result in scientific notation
1068     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1069         $res->@{qw(blocks used bavail)};
1070
1071     return {
1072         total => $blocks,
1073         used => $used,
1074         avail => $bavail,
1075     };
1076 }
1077
1078 sub du {
1079     my ($path, $timeout) = @_;
1080
1081     my $size;
1082
1083     $timeout //= 10;
1084
1085     my $parser = sub {
1086         my $line = shift;
1087
1088         if ($line =~ m/^(\d+)\s+total$/) {
1089             $size = $1;
1090         }
1091     };
1092
1093     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1094
1095     return $size;
1096 }
1097
1098 # UPID helper
1099 # We use this to uniquely identify a process.
1100 # An 'Unique Process ID' has the following format:
1101 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1102
1103 sub upid_encode {
1104     my $d = shift;
1105
1106     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1107     # more that 8 characters for pstart
1108     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1109                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1110                    $d->{user});
1111 }
1112
1113 sub upid_decode {
1114     my ($upid, $noerr) = @_;
1115
1116     my $res;
1117     my $filename;
1118
1119     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1120     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1121     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1122         $res->{node} = $1;
1123         $res->{pid} = hex($3);
1124         $res->{pstart} = hex($4);
1125         $res->{starttime} = hex($5);
1126         $res->{type} = $6;
1127         $res->{id} = $7;
1128         $res->{user} = $8;
1129
1130         my $subdir = substr($5, 7, 8);
1131         $filename = "$pvetaskdir/$subdir/$upid";
1132
1133     } else {
1134         return undef if $noerr;
1135         die "unable to parse worker upid '$upid'\n";
1136     }
1137
1138     return wantarray ? ($res, $filename) : $res;
1139 }
1140
1141 sub upid_open {
1142     my ($upid) = @_;
1143
1144     my ($task, $filename) = upid_decode($upid);
1145
1146     my $dirname = dirname($filename);
1147     make_path($dirname);
1148
1149     my $wwwid = getpwnam('www-data') ||
1150         die "getpwnam failed";
1151
1152     my $perm = 0640;
1153
1154     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1155         die "unable to create output file '$filename' - $!\n";
1156     chown $wwwid, -1, $outfh;
1157
1158     return $outfh;
1159 };
1160
1161 sub upid_read_status {
1162     my ($upid) = @_;
1163
1164     my ($task, $filename) = upid_decode($upid);
1165     my $fh = IO::File->new($filename, "r");
1166     return "unable to open file - $!" if !$fh;
1167     my $maxlen = 4096;
1168     sysseek($fh, -$maxlen, 2);
1169     my $readbuf = '';
1170     my $br = sysread($fh, $readbuf, $maxlen);
1171     close($fh);
1172     if ($br) {
1173         return "unable to extract last line"
1174             if $readbuf !~ m/\n?(.+)$/;
1175         my $line = $1;
1176         if ($line =~ m/^TASK OK$/) {
1177             return 'OK';
1178         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1179             return $1;
1180         } elsif ($line =~ m/^TASK (WARNINGS: \d+)$/) {
1181             return $1;
1182         } else {
1183             return "unexpected status";
1184         }
1185     }
1186     return "unable to read tail (got $br bytes)";
1187 }
1188
1189 # Check if the status returned by upid_read_status is an error status.
1190 # If the status could not be parsed it's also treated as an error.
1191 sub upid_status_is_error {
1192     my ($status) = @_;
1193
1194     return !($status eq 'OK' || $status =~ m/^WARNINGS: \d+$/);
1195 }
1196
1197 # takes the parsed status and returns the type, either ok, warning, error or unknown
1198 sub upid_normalize_status_type {
1199     my ($status) = @_;
1200
1201     if (!$status) {
1202         return 'unknown';
1203     } elsif ($status eq 'OK') {
1204         return 'ok';
1205     } elsif ($status =~ m/^WARNINGS: \d+$/) {
1206         return 'warning';
1207     } elsif ($status eq 'unexpected status') {
1208         return 'unknown';
1209     } else {
1210         return 'error';
1211     }
1212 }
1213
1214 # useful functions to store comments in config files
1215 sub encode_text {
1216     my ($text) = @_;
1217
1218     # all control and hi-bit characters, and ':'
1219     my $unsafe = "^\x20-\x39\x3b-\x7e";
1220     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1221 }
1222
1223 sub decode_text {
1224     my ($data) = @_;
1225
1226     return Encode::decode("utf8", uri_unescape($data));
1227 }
1228
1229 # NOTE: deprecated - do not use! we now decode all parameters by default
1230 sub decode_utf8_parameters {
1231     my ($param) = @_;
1232
1233     foreach my $p (qw(comment description firstname lastname)) {
1234         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1235     }
1236
1237     return $param;
1238 }
1239
1240 sub random_ether_addr {
1241     my ($prefix) = @_;
1242
1243     my ($seconds, $microseconds) = gettimeofday;
1244
1245     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1246
1247     # clear multicast, set local id
1248     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1249
1250     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1251     if (defined($prefix)) {
1252         $addr = uc($prefix) . substr($addr, length($prefix));
1253     }
1254     return $addr;
1255 }
1256
1257 sub shellquote {
1258     my $str = shift;
1259
1260     return String::ShellQuote::shell_quote($str);
1261 }
1262
1263 sub cmd2string {
1264     my ($cmd) = @_;
1265
1266     die "no arguments" if !$cmd;
1267
1268     return $cmd if !ref($cmd);
1269
1270     my @qa = ();
1271     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1272
1273     return join (' ', @qa);
1274 }
1275
1276 # split an shell argument string into an array,
1277 sub split_args {
1278     my ($str) = @_;
1279
1280     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1281 }
1282
1283 sub dump_logfile_by_filehandle {
1284     my ($fh, $filter, $state) = @_;
1285
1286     my $count = ($state->{count} //= 0);
1287     my $lines = ($state->{lines} //= []);
1288     my $start = ($state->{start} //= 0);
1289     my $limit = ($state->{limit} //= 50);
1290     my $final = ($state->{final} //= 1);
1291     my $read_until_end = ($state->{read_until_end} //= $limit == 0);
1292
1293     my $line;
1294     if ($filter) {
1295         # duplicate code, so that we do not slow down normal path
1296         while (defined($line = <$fh>)) {
1297             if (ref($filter) eq 'CODE') {
1298                 next if !$filter->($line);
1299             } else {
1300                 next if $line !~ m/$filter/;
1301             }
1302             next if $count++ < $start;
1303             if (!$read_until_end) {
1304                 next if $limit <= 0;
1305                 $limit--;
1306             }
1307             chomp $line;
1308             push @$lines, { n => $count, t => $line};
1309         }
1310     } else {
1311         while (defined($line = <$fh>)) {
1312             next if $count++ < $start;
1313             if (!$read_until_end) {
1314                 next if $limit <= 0;
1315                 $limit--;
1316             }
1317             chomp $line;
1318             push @$lines, { n => $count, t => $line};
1319         }
1320     }
1321
1322     # HACK: ExtJS store.guaranteeRange() does not like empty array
1323     # so we add a line
1324     if (!$count && $final) {
1325         $count++;
1326         push @$lines, { n => $count, t => "no content"};
1327     }
1328
1329     $state->{count} = $count;
1330     $state->{limit} = $limit;
1331 }
1332
1333 sub dump_logfile {
1334     my ($filename, $start, $limit, $filter) = @_;
1335
1336     my $fh = IO::File->new($filename, "r");
1337     if (!$fh) {
1338         return (1, { n => 1, t => "unable to open file - $!"});
1339     }
1340
1341     my %state = (
1342         'count' => 0,
1343         'lines' => [],
1344         'start' => $start,
1345         'limit' => $limit,
1346     );
1347
1348     dump_logfile_by_filehandle($fh, $filter, \%state);
1349
1350     close($fh);
1351
1352     return ($state{'count'}, $state{'lines'});
1353 }
1354
1355 sub dump_journal {
1356     my ($start, $limit, $since, $until, $service) = @_;
1357
1358     my $lines = [];
1359     my $count = 0;
1360
1361     $start = 0 if !$start;
1362     $limit = 50 if !$limit;
1363
1364     my $parser = sub {
1365         my $line = shift;
1366
1367         return if $count++ < $start;
1368         return if $limit <= 0;
1369         push @$lines, { n => int($count), t => $line};
1370         $limit--;
1371     };
1372
1373     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1374
1375     push @$cmd, '--unit', $service if $service;
1376     push @$cmd, '--since', $since if $since;
1377     push @$cmd, '--until', $until if $until;
1378     run_command($cmd, outfunc => $parser);
1379
1380     # HACK: ExtJS store.guaranteeRange() does not like empty array
1381     # so we add a line
1382     if (!$count) {
1383         $count++;
1384         push @$lines, { n => $count, t => "no content"};
1385     }
1386
1387     return ($count, $lines);
1388 }
1389
1390 sub dir_glob_regex {
1391     my ($dir, $regex) = @_;
1392
1393     my $dh = IO::Dir->new ($dir);
1394     return wantarray ? () : undef if !$dh;
1395
1396     while (defined(my $tmp = $dh->read)) {
1397         if (my @res = $tmp =~ m/^($regex)$/) {
1398             $dh->close;
1399             return wantarray ? @res : $tmp;
1400         }
1401     }
1402     $dh->close;
1403
1404     return wantarray ? () : undef;
1405 }
1406
1407 sub dir_glob_foreach {
1408     my ($dir, $regex, $func) = @_;
1409
1410     my $dh = IO::Dir->new ($dir);
1411     if (defined $dh) {
1412         while (defined(my $tmp = $dh->read)) {
1413             if (my @res = $tmp =~ m/^($regex)$/) {
1414                 &$func (@res);
1415             }
1416         }
1417     }
1418 }
1419
1420 sub assert_if_modified {
1421     my ($digest1, $digest2) = @_;
1422
1423     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1424         die "detected modified configuration - file changed by other user? Try again.\n";
1425     }
1426 }
1427
1428 # Digest for short strings
1429 # like FNV32a, but we only return 31 bits (positive numbers)
1430 sub fnv31a {
1431     my ($string) = @_;
1432
1433     my $hval = 0x811c9dc5;
1434
1435     foreach my $c (unpack('C*', $string)) {
1436         $hval ^= $c;
1437         $hval += (
1438             (($hval << 1) ) +
1439             (($hval << 4) ) +
1440             (($hval << 7) ) +
1441             (($hval << 8) ) +
1442             (($hval << 24) ) );
1443         $hval = $hval & 0xffffffff;
1444     }
1445     return $hval & 0x7fffffff;
1446 }
1447
1448 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1449
1450 sub unpack_sockaddr_in46 {
1451     my ($sin) = @_;
1452     my $family = Socket::sockaddr_family($sin);
1453     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1454                                              : Socket::unpack_sockaddr_in($sin));
1455     return ($family, $port, $host);
1456 }
1457
1458 sub getaddrinfo_all {
1459     my ($hostname, @opts) = @_;
1460     my %hints = (
1461         flags => AI_V4MAPPED | AI_ALL,
1462         @opts,
1463     );
1464     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1465     die "failed to get address info for: $hostname: $err\n" if $err;
1466     return @res;
1467 }
1468
1469 sub get_host_address_family {
1470     my ($hostname, $socktype) = @_;
1471     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1472     return $res[0]->{family};
1473 }
1474
1475 # get the fully qualified domain name of a host
1476 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1477 # given a nodename as a parameter
1478 sub get_fqdn {
1479     my ($nodename) = @_;
1480
1481     my $hints = {
1482         flags => AI_CANONNAME,
1483         socktype => SOCK_DGRAM
1484     };
1485
1486     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1487
1488     die "getaddrinfo: $err" if $err;
1489
1490     return $addrs[0]->{canonname};
1491 }
1492
1493 # Parses any sane kind of host, or host+port pair:
1494 # The port is always optional and thus may be undef.
1495 sub parse_host_and_port {
1496     my ($address) = @_;
1497     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1498         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1499         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1500     {
1501         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1502     }
1503     return; # nothing
1504 }
1505
1506 sub setresuid($$$) {
1507     my ($ruid, $euid, $suid) = @_;
1508     return 0 == syscall(PVE::Syscall::setresuid, int($ruid), int($euid), int($suid));
1509 }
1510
1511 sub unshare($) {
1512     my ($flags) = @_;
1513     return 0 == syscall(PVE::Syscall::unshare, int($flags));
1514 }
1515
1516 sub setns($$) {
1517     my ($fileno, $nstype) = @_;
1518     return 0 == syscall(PVE::Syscall::setns, int($fileno), int($nstype));
1519 }
1520
1521 sub syncfs($) {
1522     my ($fileno) = @_;
1523     return 0 == syscall(PVE::Syscall::syncfs, int($fileno));
1524 }
1525
1526 sub fsync($) {
1527     my ($fileno) = @_;
1528     return 0 == syscall(PVE::Syscall::fsync, int($fileno));
1529 }
1530
1531 sub renameat2($$$$$) {
1532     my ($olddirfd, $oldpath, $newdirfd, $newpath, $flags) = @_;
1533     return 0 == syscall(
1534         PVE::Syscall::renameat2,
1535         int($olddirfd),
1536         $oldpath,
1537         int($newdirfd),
1538         $newpath,
1539         int($flags),
1540     );
1541 }
1542
1543 sub sync_mountpoint {
1544     my ($path) = @_;
1545     sysopen my $fd, $path, O_RDONLY|O_CLOEXEC or die "failed to open $path: $!\n";
1546     my $syncfs_err;
1547     if (!syncfs(fileno($fd))) {
1548         $syncfs_err = "$!";
1549     }
1550     close($fd);
1551     die "syncfs '$path' failed - $syncfs_err\n" if defined $syncfs_err;
1552 }
1553
1554 my sub check_mail_addr {
1555     my ($addr) = @_;
1556     die "'$addr' does not look like a valid email address or username\n"
1557         if $addr !~ /^$EMAIL_RE$/ && $addr !~ /^$EMAIL_USER_RE$/;
1558 }
1559
1560 # support sending multi-part mail messages with a text and or a HTML part
1561 # mailto may be a single email string or an array of receivers
1562 sub sendmail {
1563     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1564
1565     $mailto = [ $mailto ] if !ref($mailto);
1566
1567     check_mail_addr($_) for $mailto->@*;
1568     my $to_quoted = [ map { shellquote($_) } $mailto->@* ];
1569
1570     $mailfrom = $mailfrom || "root";
1571     check_mail_addr($mailfrom);
1572     my $from_quoted = shellquote($mailfrom);
1573
1574     $author = $author // 'Proxmox VE';
1575
1576     open (my $mail, "|-", "sendmail", "-B", "8BITMIME", "-f", $from_quoted, "--", $to_quoted->@*)
1577         or die "unable to open 'sendmail' - $!";
1578
1579     my $is_multipart = $text && $html;
1580     my $boundary = "----_=_NextPart_001_" . int(time()) . $$; # multipart spec, see rfc 1521
1581
1582     $subject = Encode::encode('MIME-Header', $subject) if $subject =~ /[^[:ascii:]]/;
1583
1584     print $mail "MIME-Version: 1.0\n" if $subject =~ /[^[:ascii:]]/ || $is_multipart;
1585
1586     print $mail "From: $author <$mailfrom>\n";
1587     print $mail "To: " . join(', ', @$mailto) ."\n";
1588     print $mail "Date: " . time2str('%a, %d %b %Y %H:%M:%S %z', time()) . "\n";
1589     print $mail "Subject: $subject\n";
1590
1591     if ($is_multipart) {
1592         print $mail "Content-Type: multipart/alternative;\n";
1593         print $mail "\tboundary=\"$boundary\"\n";
1594         print $mail "\n";
1595         print $mail "This is a multi-part message in MIME format.\n\n";
1596         print $mail "--$boundary\n";
1597     }
1598
1599     if (defined($text)) {
1600         print $mail "Content-Type: text/plain;\n";
1601         print $mail "Auto-Submitted: auto-generated;\n";
1602         print $mail "\tcharset=\"UTF-8\"\n";
1603         print $mail "Content-Transfer-Encoding: 8bit\n";
1604         print $mail "\n";
1605
1606         # avoid 'remove extra line breaks' issue (MS Outlook)
1607         my $fill = '  ';
1608         $text =~ s/^/$fill/gm;
1609
1610         print $mail $text;
1611
1612         print $mail "\n--$boundary\n" if $is_multipart;
1613     }
1614
1615     if (defined($html)) {
1616         print $mail "Content-Type: text/html;\n";
1617         print $mail "Auto-Submitted: auto-generated;\n";
1618         print $mail "\tcharset=\"UTF-8\"\n";
1619         print $mail "Content-Transfer-Encoding: 8bit\n";
1620         print $mail "\n";
1621
1622         print $mail $html;
1623
1624         print $mail "\n--$boundary--\n" if $is_multipart;
1625     }
1626
1627     close($mail);
1628 }
1629
1630 # creates a temporary file that does not shows up on the file system hierarchy.
1631 #
1632 # Uses O_TMPFILE if available, which makes it just an anon inode that never shows up in the FS.
1633 # If O_TMPFILE is not available, which unlikely nowadays (added in 3.11 kernel and all FS relevant
1634 # for us support it) back to open-create + immediate unlink while still holding the file  handle.
1635 #
1636 # TODO: to avoid FS dependent features we could (transparently) switch to memfd_create as backend
1637 sub tempfile {
1638     my ($perm, %opts) = @_;
1639
1640     # default permissions are stricter than with file_set_contents
1641     $perm = 0600 if !defined($perm);
1642
1643     my $dir = $opts{dir};
1644     if (!$dir) {
1645         if (-d "/run/user/$<") {
1646             $dir = "/run/user/$<";
1647         } elsif ($< == 0) {
1648             $dir = "/run";
1649         } else {
1650             $dir = "/tmp";
1651         }
1652     }
1653     my $mode = $opts{mode} // O_RDWR;
1654     $mode |= O_EXCL if !$opts{allow_links};
1655
1656     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1657     if (!$fh && $! == EOPNOTSUPP) {
1658         $dir = '/tmp' if !defined($opts{dir});
1659         $dir .= "/.tmpfile.$$";
1660         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1661         unlink($dir) if $fh;
1662     }
1663     die "failed to create tempfile: $!\n" if !$fh;
1664     return $fh;
1665 }
1666
1667 # create an (ideally) anon file with the $data as content and return its FD-path and FH
1668 sub tempfile_contents {
1669     my ($data, $perm, %opts) = @_;
1670
1671     my $fh = tempfile($perm, %opts);
1672     eval {
1673         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1674         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1675     };
1676     if (my $err = $@) {
1677         close $fh;
1678         die $err;
1679     }
1680
1681     return ("/proc/$$/fd/".$fh->fileno, $fh);
1682 }
1683
1684 sub validate_ssh_public_keys {
1685     my ($raw) = @_;
1686     my @lines = split(/\n/, $raw);
1687
1688     foreach my $line (@lines) {
1689         next if $line =~ m/^\s*$/;
1690         eval {
1691             my ($filename, $handle) = tempfile_contents($line);
1692             run_command(["ssh-keygen", "-l", "-f", $filename],
1693                         outfunc => sub {}, errfunc => sub {});
1694         };
1695         die "SSH public key validation error\n" if $@;
1696     }
1697 }
1698
1699 sub openat($$$;$) {
1700     my ($dirfd, $pathname, $flags, $mode) = @_;
1701     $dirfd = int($dirfd);
1702     $flags = int($flags);
1703     $mode = int($mode // 0);
1704
1705     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode);
1706     return undef if $fd < 0;
1707     # sysopen() doesn't deal with numeric file descriptors apparently
1708     # so we need to convert to a mode string for IO::Handle->new_from_fd
1709     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1710     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1711     return $handle if $handle;
1712     my $err = $!; # save error before closing the raw fd
1713     syscall(PVE::Syscall::close, $fd); # close
1714     $! = $err;
1715     return undef;
1716 }
1717
1718 sub mkdirat($$$) {
1719     my ($dirfd, $name, $mode) = @_;
1720     return syscall(PVE::Syscall::mkdirat, int($dirfd), $name, int($mode)) == 0;
1721 }
1722
1723 sub fchownat($$$$$) {
1724     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1725     return syscall(
1726         PVE::Syscall::fchownat,
1727         int($dirfd),
1728         $pathname,
1729         int($owner),
1730         int($group),
1731         int($flags),
1732     ) == 0;
1733 }
1734
1735 my $salt_starter = time();
1736
1737 sub encrypt_pw {
1738     my ($pw) = @_;
1739
1740     $salt_starter++;
1741     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1742
1743     # crypt does not want '+' in salt (see 'man crypt')
1744     $salt =~ s/\+/X/g;
1745
1746     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1747 }
1748
1749 # intended usage: convert_size($val, "kb" => "gb")
1750 # we round up to the next integer by default
1751 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1752 # use $no_round_up to switch this off, above example would then return 0
1753 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1754 # (0 if $no_round_up is true)
1755 # allowed formats for value:
1756 # 1234
1757 # 1234.
1758 # 1234.1234
1759 # .1234
1760 sub convert_size {
1761     my ($value, $from, $to, $no_round_up) = @_;
1762
1763     my $units = {
1764         b  => 0,
1765         kb => 1,
1766         mb => 2,
1767         gb => 3,
1768         tb => 4,
1769         pb => 5,
1770     };
1771
1772     die "no value given"
1773         if !defined($value) || $value eq "";
1774
1775     $from = lc($from // ''); $to = lc($to // '');
1776     die "unknown 'from' and/or 'to' units ($from => $to)"
1777         if !defined($units->{$from}) || !defined($units->{$to});
1778
1779     die "value '$value' is not a valid, positive number"
1780         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1781
1782     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1783
1784     $value *= 2**$shift_amount;
1785     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1786
1787     return int($value);
1788 }
1789
1790 # uninterruptible readline
1791 # retries on EINTR
1792 sub readline_nointr {
1793     my ($fh) = @_;
1794     my $line;
1795     while (1) {
1796         $line = <$fh>;
1797         last if defined($line) || ($! != EINTR);
1798     }
1799     return $line;
1800 }
1801
1802 my $host_arch;
1803 sub get_host_arch {
1804     $host_arch = (POSIX::uname())[4] if !$host_arch;
1805     return $host_arch;
1806 }
1807
1808 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1809 sub dev_t_major($) {
1810     my ($dev_t) = @_;
1811     return (int($dev_t) & 0xfff00) >> 8;
1812 }
1813
1814 sub dev_t_minor($) {
1815     my ($dev_t) = @_;
1816     $dev_t = int($dev_t);
1817     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1818 }
1819
1820 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1821 # Returns the intersection of elements as a single array [a b]
1822 sub array_intersect {
1823     my ($arrays) = @_;
1824
1825     if (!ref($arrays->[0])) {
1826         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1827     }
1828
1829     return [] if scalar(@$arrays) == 0;
1830     return $arrays->[0] if scalar(@$arrays) == 1;
1831
1832     my $array_unique = sub {
1833         my %seen = ();
1834         return grep { ! $seen{ $_ }++ } @_;
1835     };
1836
1837     # base idea is to get all unique members from the first array, then
1838     # check the common elements with the next (uniquely made) one, only keep
1839     # those. Repeat for every array and at the end we only have those left
1840     # which exist in all arrays
1841     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1842     for my $i (1 .. $#$arrays) {
1843         my %count = ();
1844         # $return_arr is already unique, explicit at before the loop, implicit below.
1845         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1846             $count{$element}++;
1847         }
1848         $return_arr = [];
1849         foreach my $element (keys %count) {
1850             push @$return_arr, $element if $count{$element} > 1;
1851         }
1852         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1853     }
1854
1855     return $return_arr;
1856 }
1857
1858 sub open_tree($$$) {
1859     my ($dfd, $pathname, $flags) = @_;
1860     return PVE::Syscall::file_handle_result(syscall(
1861         &PVE::Syscall::open_tree,
1862         int($dfd),
1863         $pathname,
1864         int($flags),
1865     ));
1866 }
1867
1868 sub move_mount($$$$$) {
1869     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1870     return 0 == syscall(
1871         &PVE::Syscall::move_mount,
1872         int($from_dirfd),
1873         $from_pathname,
1874         int($to_dirfd),
1875         $to_pathname,
1876         int($flags),
1877     );
1878 }
1879
1880 sub fsopen($$) {
1881     my ($fsname, $flags) = @_;
1882     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, int($flags)));
1883 }
1884
1885 sub fsmount($$$) {
1886     my ($fd, $flags, $mount_attrs) = @_;
1887     return PVE::Syscall::file_handle_result(syscall(
1888         &PVE::Syscall::fsmount,
1889         int($fd),
1890         int($flags),
1891         int($mount_attrs),
1892     ));
1893 }
1894
1895 sub fspick($$$) {
1896     my ($dirfd, $pathname, $flags) = @_;
1897     return PVE::Syscall::file_handle_result(syscall(
1898         &PVE::Syscall::fspick,
1899         int($dirfd),
1900         $pathname,
1901         int($flags),
1902     ));
1903 }
1904
1905 sub fsconfig($$$$$) {
1906     my ($fd, $command, $key, $value, $aux) = @_;
1907     return 0 == syscall(
1908         &PVE::Syscall::fsconfig,
1909         int($fd),
1910         int($command),
1911         $key,
1912         $value,
1913         int($aux),
1914     );
1915 }
1916
1917 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1918 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1919 sub mount($$$$$) {
1920     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1921     return 0 == syscall(
1922         &PVE::Syscall::mount,
1923         $source,
1924         $target,
1925         $filesystemtype,
1926         int($mountflags),
1927         $data,
1928     );
1929 }
1930
1931 # size is optional and defaults to 256, note that xattr limits are FS specific and that xattrs can
1932 # get arbitrary long. pass `0` for $size in array context to get the actual size of a value
1933 sub getxattr($$;$) {
1934     my ($path_or_handle, $name, $size) = @_;
1935     $size //= 256;
1936     my $buf = pack("x${size}");
1937
1938     my $xattr_size = -1; # the actual size of the xattr, can be zero
1939     if (defined(my $fd = fileno($path_or_handle))) {
1940         $xattr_size = syscall(&PVE::Syscall::fgetxattr, $fd, $name, $buf, int($size));
1941     } else {
1942         $xattr_size = syscall(&PVE::Syscall::getxattr, $path_or_handle, $name, $buf, int($size));
1943     }
1944     if ($xattr_size < 0) {
1945         return undef;
1946     }
1947     $buf = substr($buf, 0, $xattr_size);
1948     return wantarray ? ($buf, $xattr_size) : $buf;
1949 }
1950
1951 # NOTE: can take either a path or an open file handle, i.e., its multiplexing setxattr and fsetxattr
1952 sub setxattr($$$;$) {
1953     my ($path_or_handle, $name, $value, $flags) = @_;
1954     my $size = length($value); # NOTE: seems to get correct length also for wide-characters in text..
1955
1956     if (defined(my $fd = fileno($path_or_handle))) {
1957         return 0 == syscall(
1958             &PVE::Syscall::fsetxattr,
1959             $fd,
1960             $name,
1961             $value,
1962             int($size),
1963             int($flags // 0),
1964         );
1965     } else {
1966         return 0 == syscall(
1967             &PVE::Syscall::setxattr,
1968             $path_or_handle,
1969             $name,
1970             $value,
1971             int($size),
1972             int($flags // 0),
1973         );
1974     }
1975 }
1976
1977 sub safe_compare {
1978     my ($left, $right, $cmp) = @_;
1979
1980     return 0 if !defined($left) && !defined($right);
1981     return -1 if !defined($left);
1982     return 1 if !defined($right);
1983     return $cmp->($left, $right);
1984 }
1985
1986
1987 # opts is a hash ref with the following known properties
1988 #  allow_overwrite - if 1, overwriting existing files is allowed, use with care. Default to false
1989 #  hash_required - if 1, at least one checksum has to be specified otherwise an error will be thrown
1990 #  http_proxy
1991 #  https_proxy
1992 #  verify_certificates - if 0 (false) we tell wget to ignore untrusted TLS certs. Default to true
1993 #  md5sum|sha(1|224|256|384|512)sum - the respective expected checksum string
1994 sub download_file_from_url {
1995     my ($dest, $url, $opts) = @_;
1996
1997     my ($checksum_algorithm, $checksum_expected);
1998     for ('sha512', 'sha384', 'sha256', 'sha224', 'sha1', 'md5') {
1999         if (defined($opts->{"${_}sum"})) {
2000             $checksum_algorithm = $_;
2001             $checksum_expected = $opts->{"${_}sum"};
2002             last;
2003         }
2004     }
2005     die "checksum required but not specified\n" if ($opts->{hash_required} && !$checksum_algorithm);
2006
2007     print "downloading $url to $dest\n";
2008
2009     if (-f $dest) {
2010         if ($checksum_algorithm) {
2011             print "calculating checksum of existing file...";
2012             my $checksum_got = get_file_hash($checksum_algorithm, $dest);
2013
2014             if (lc($checksum_got) eq lc($checksum_expected)) {
2015                 print "OK, got correct file already, no need to download\n";
2016                 return;
2017             } elsif ($opts->{allow_overwrite}) {
2018                 print "checksum mismatch: got '$checksum_got' != expect '$checksum_expected', re-download\n";
2019             } else {
2020                 print "\n";  # the front end expects the error to reside at the last line without any noise
2021                 die "checksum mismatch: got '$checksum_got' != expect '$checksum_expected', aborting\n";
2022             }
2023         } elsif (!$opts->{allow_overwrite}) {
2024             die "refusing to override existing file '$dest'\n";
2025         }
2026     }
2027
2028     my $tmp_download = "$dest.tmp_dwnl.$$";
2029     my $tmp_decomp = "$dest.tmp_dcom.$$";
2030     eval {
2031         local $SIG{INT} = sub {
2032             unlink $tmp_download or warn "could not cleanup temporary file: $!"
2033                 if -e $tmp_download;
2034             unlink $tmp_decomp or warn "could not cleanup temporary file: $!"
2035                 if $opts->{decompression_command} && -e $tmp_decomp;
2036             die "got interrupted by signal\n";
2037         };
2038
2039         { # limit the scope of the ENV change
2040             local %ENV;
2041             if ($opts->{http_proxy}) {
2042                 $ENV{http_proxy} = $opts->{http_proxy};
2043             }
2044             if ($opts->{https_proxy}) {
2045                 $ENV{https_proxy} = $opts->{https_proxy};
2046             }
2047
2048             my $cmd = ['wget', '--progress=dot:giga', '-O', $tmp_download, $url];
2049
2050             if (!($opts->{verify_certificates} // 1)) { # default to true
2051                 push @$cmd, '--no-check-certificate';
2052             }
2053
2054             run_command($cmd, errmsg => "download failed");
2055         }
2056
2057         if ($checksum_algorithm) {
2058             print "calculating checksum...";
2059
2060             my $checksum_got = get_file_hash($checksum_algorithm, $tmp_download);
2061
2062             if (lc($checksum_got) eq lc($checksum_expected)) {
2063                 print "OK, checksum verified\n";
2064             } else {
2065                 print "\n";  # the front end expects the error to reside at the last line without any noise
2066                 die "checksum mismatch: got '$checksum_got' != expect '$checksum_expected'\n";
2067             }
2068         }
2069
2070         if (my $cmd = $opts->{decompression_command}) {
2071             push @$cmd, $tmp_download;
2072             my $fh;
2073             if (!open($fh, ">", "$tmp_decomp")) {
2074                 die "cant open temporary file $tmp_decomp for decompresson: $!\n";
2075             }
2076             print "decompressing $tmp_download to $tmp_decomp\n";
2077             run_command($cmd, output => '>&'.fileno($fh));
2078             unlink $tmp_download;
2079             rename($tmp_decomp, $dest) or die "unable to rename temporary file: $!\n";
2080         } else {
2081             rename($tmp_download, $dest) or die "unable to rename temporary file: $!\n";
2082         }
2083     };
2084     if (my $err = $@) {
2085         unlink $tmp_download or warn "could not cleanup temporary file: $!"
2086             if -e $tmp_download;
2087         unlink $tmp_decomp or warn "could not cleanup temporary file: $!"
2088             if $opts->{decompression_command} && -e $tmp_decomp;
2089         die $err;
2090     }
2091
2092     print "download of '$url' to '$dest' finished\n";
2093 }
2094
2095 sub get_file_hash {
2096     my ($algorithm, $filename) = @_;
2097
2098     my $algorithm_map = {
2099         'md5' => sub { Digest::MD5->new },
2100         'sha1' => sub { Digest::SHA->new(1) },
2101         'sha224' => sub { Digest::SHA->new(224) },
2102         'sha256' => sub { Digest::SHA->new(256) },
2103         'sha384' => sub { Digest::SHA->new(384) },
2104         'sha512' => sub { Digest::SHA->new(512) },
2105     };
2106
2107     my $digester = $algorithm_map->{$algorithm}->() or die "unknown algorithm '$algorithm'\n";
2108
2109     open(my $fh, '<', $filename) or die "unable to open '$filename': $!\n";
2110     binmode($fh);
2111
2112     my $digest = $digester->addfile($fh)->hexdigest;
2113
2114     return lc($digest);
2115 }
2116
2117 1;