src/PVE/Tools.pm

   1 package PVE::Tools;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Date::Format qw(time2str);
   7 use Digest::MD5;
   8 use Digest::SHA;
   9 use Encode;
  10 use Fcntl qw(:DEFAULT :flock);
  11 use File::Basename;
  12 use File::Path qw(make_path);
  13 use Filesys::Df (); # don't overwrite our df()
  14 use IO::Dir;
  15 use IO::File;
  16 use IO::Handle;
  17 use IO::Pipe;
  18 use IO::Select;
  19 use IO::Socket::IP;
  20 use IPC::Open3;
  21 use JSON;
  22 use POSIX qw(EINTR EEXIST EOPNOTSUPP);
  23 use Scalar::Util 'weaken';
  24 use Socket qw(AF_INET AF_INET6 AI_ALL AI_V4MAPPED AI_CANONNAME SOCK_DGRAM IPPROTO_TCP);
  25 use String::ShellQuote;
  26 use Text::ParseWords;
  27 use Time::HiRes qw(usleep gettimeofday tv_interval alarm);
  28 use URI::Escape;
  29 use base 'Exporter';
  30
  31 use PVE::Syscall;
  32
  33 # avoid warning when parsing long hex values with hex()
  34 no warnings 'portable'; # Support for 64-bit ints required
  35
  36 our @EXPORT_OK = qw(
  37 $IPV6RE
  38 $IPV4RE
  39 lock_file
  40 lock_file_full
  41 run_command
  42 file_set_contents
  43 file_get_contents
  44 file_read_firstline
  45 dir_glob_regex
  46 dir_glob_foreach
  47 split_list
  48 template_replace
  49 safe_print
  50 trim
  51 extract_param
  52 extract_sensitive_params
  53 file_copy
  54 get_host_arch
  55 O_PATH
  56 O_TMPFILE
  57 AT_EMPTY_PATH
  58 AT_FDCWD
  59 CLONE_NEWNS
  60 CLONE_NEWUTS
  61 CLONE_NEWIPC
  62 CLONE_NEWUSER
  63 CLONE_NEWPID
  64 CLONE_NEWNET
  65 );
  66
  67 my $pvelogdir = "/var/log/pve";
  68 my $pvetaskdir = "$pvelogdir/tasks";
  69
  70 mkdir $pvelogdir;
  71 mkdir $pvetaskdir;
  72
  73 my $IPV4OCTET = "(?:25[0-5]|(?:2[0-4]|1[0-9]|[1-9])?[0-9])";
  74 our $IPV4RE = "(?:(?:$IPV4OCTET\\.){3}$IPV4OCTET)";
  75 my $IPV6H16 = "(?:[0-9a-fA-F]{1,4})";
  76 my $IPV6LS32 = "(?:(?:$IPV4RE|$IPV6H16:$IPV6H16))";
  77
  78 our $IPV6RE = "(?:" .
  79     "(?:(?:" .                             "(?:$IPV6H16:){6})$IPV6LS32)|" .
  80     "(?:(?:" .                           "::(?:$IPV6H16:){5})$IPV6LS32)|" .
  81     "(?:(?:(?:" .              "$IPV6H16)?::(?:$IPV6H16:){4})$IPV6LS32)|" .
  82     "(?:(?:(?:(?:$IPV6H16:){0,1}$IPV6H16)?::(?:$IPV6H16:){3})$IPV6LS32)|" .
  83     "(?:(?:(?:(?:$IPV6H16:){0,2}$IPV6H16)?::(?:$IPV6H16:){2})$IPV6LS32)|" .
  84     "(?:(?:(?:(?:$IPV6H16:){0,3}$IPV6H16)?::(?:$IPV6H16:){1})$IPV6LS32)|" .
  85     "(?:(?:(?:(?:$IPV6H16:){0,4}$IPV6H16)?::" .           ")$IPV6LS32)|" .
  86     "(?:(?:(?:(?:$IPV6H16:){0,5}$IPV6H16)?::" .            ")$IPV6H16)|" .
  87     "(?:(?:(?:(?:$IPV6H16:){0,6}$IPV6H16)?::" .                    ")))";
  88
  89 our $IPRE = "(?:$IPV4RE|$IPV6RE)";
  90
  91 our $EMAIL_USER_RE = qr/[\w\+\-\~]+(\.[\w\+\-\~]+)*/;
  92 our $EMAIL_RE = qr/$EMAIL_USER_RE@[a-zA-Z0-9\-]+(\.[a-zA-Z0-9\-]+)*/;
  93
  94 use constant {CLONE_NEWNS   => 0x00020000,
  95               CLONE_NEWUTS  => 0x04000000,
  96               CLONE_NEWIPC  => 0x08000000,
  97               CLONE_NEWUSER => 0x10000000,
  98               CLONE_NEWPID  => 0x20000000,
  99               CLONE_NEWNET  => 0x40000000};
 100
 101 use constant {O_PATH    => 0x00200000,
 102               O_CLOEXEC => 0x00080000,
 103               O_TMPFILE => 0x00400000 | O_DIRECTORY};
 104
 105 use constant {AT_EMPTY_PATH => 0x1000,
 106               AT_FDCWD => -100};
 107
 108 # from <linux/fs.h>
 109 use constant {RENAME_NOREPLACE => (1 << 0),
 110               RENAME_EXCHANGE  => (1 << 1),
 111               RENAME_WHITEOUT  => (1 << 2)};
 112
 113 sub run_with_timeout {
 114     my ($timeout, $code, @param) = @_;
 115
 116     die "got timeout\n" if $timeout <= 0;
 117
 118     my $prev_alarm = alarm 0; # suspend outer alarm early
 119
 120     my $sigcount = 0;
 121     my $got_timeout = 0;
 122
 123     my $res;
 124
 125     eval {
 126         local $SIG{ALRM} = sub { $sigcount++; $got_timeout = 1;  die "got timeout\n"; };
 127         local $SIG{PIPE} = sub { $sigcount++; die "broken pipe\n" };
 128         local $SIG{__DIE__};   # see SA bug 4631
 129
 130         alarm($timeout);
 131
 132         eval { $res = &$code(@param); };
 133
 134         alarm(0); # avoid race conditions
 135
 136         die $@ if $@;
 137     };
 138
 139     my $err = $@;
 140
 141     alarm $prev_alarm;
 142
 143     # this shouldn't happen anymore?
 144     die "unknown error" if $sigcount && !$err; # seems to happen sometimes
 145
 146     # assume that user handles timeout err if called in list context
 147     die $err if $err && (!wantarray || !$got_timeout);
 148
 149     return wantarray ? ($res, $got_timeout) : $res;
 150 }
 151
 152 # flock: we use one file handle per process, so lock file
 153 # can be nested multiple times and succeeds for the same process.
 154 #
 155 # Since this is the only way we lock now and we don't have the old
 156 # 'lock(); code(); unlock();' pattern anymore we do not actually need to
 157 # count how deep we're nesting. Therefore this hash now stores a weak reference
 158 # to a boolean telling us whether we already have a lock.
 159
 160 my $lock_handles =  {};
 161
 162 sub lock_file_full {
 163     my ($filename, $timeout, $shared, $code, @param) = @_;
 164
 165     $timeout = 10 if !$timeout;
 166
 167     my $mode = $shared ? LOCK_SH : LOCK_EX;
 168
 169     my $lockhash = ($lock_handles->{$$} //= {});
 170
 171     # Returns a locked file handle.
 172     my $get_locked_file = sub {
 173         my $fh = IO::File->new(">>$filename")
 174             or die "can't open file - $!\n";
 175
 176         if (!flock($fh, $mode|LOCK_NB)) {
 177             print STDERR "trying to acquire lock...\n";
 178             my $success;
 179             while(1) {
 180                 $success = flock($fh, $mode);
 181                 # try again on EINTR (see bug #273)
 182                 if ($success || ($! != EINTR)) {
 183                     last;
 184                 }
 185             }
 186             if (!$success) {
 187                 print STDERR " failed\n";
 188                 die "can't acquire lock '$filename' - $!\n";
 189             }
 190             print STDERR " OK\n";
 191         }
 192
 193         return $fh;
 194     };
 195
 196     my $res;
 197     my $checkptr = $lockhash->{$filename};
 198     my $check = 0; # This must not go out of scope before running the code.
 199     my $local_fh; # This must stay local
 200     if (!$checkptr || !$$checkptr) {
 201         # We cannot create a weak reference in a single atomic step, so we first
 202         # create a false-value, then create a reference to it, then weaken it,
 203         # and after successfully locking the file we change the boolean value.
 204         #
 205         # The reason for this is that if an outer SIGALRM throws an exception
 206         # between creating the reference and weakening it, a subsequent call to
 207         # lock_file_full() will see a leftover full reference to a valid
 208         # variable. This variable must be 0 in order for said call to attempt to
 209         # lock the file anew.
 210         #
 211         # An externally triggered exception elsewhere in the code will cause the
 212         # weak reference to become 'undef', and since the file handle is only
 213         # stored in the local scope in $local_fh, the file will be closed by
 214         # perl's cleanup routines as well.
 215         #
 216         # This still assumes that an IO::File handle can properly deal with such
 217         # exceptions thrown during its own destruction, but that's up to perls
 218         # guts now.
 219         $lockhash->{$filename} = \$check;
 220         weaken $lockhash->{$filename};
 221         $local_fh = eval { run_with_timeout($timeout, $get_locked_file) };
 222         if ($@) {
 223             $@ = "can't lock file '$filename' - $@";
 224             return undef;
 225         }
 226         $check = 1;
 227     }
 228     $res = eval { &$code(@param); };
 229     return undef if $@;
 230     return $res;
 231 }
 232
 233
 234 sub lock_file {
 235     my ($filename, $timeout, $code, @param) = @_;
 236
 237     return lock_file_full($filename, $timeout, 0, $code, @param);
 238 }
 239
 240 sub file_set_contents {
 241     my ($filename, $data, $perm)  = @_;
 242
 243     $perm = 0644 if !defined($perm);
 244
 245     my $tmpname = "$filename.tmp.$$";
 246
 247     eval {
 248         my ($fh, $tries) = (undef, 0);
 249         while (!$fh && $tries++ < 3) {
 250             $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT|O_EXCL, $perm);
 251             if (!$fh && $! == EEXIST) {
 252                 unlink($tmpname) or die "unable to delete old temp file: $!\n";
 253             }
 254         }
 255         die "unable to open file '$tmpname' - $!\n" if !$fh;
 256         die "unable to write '$tmpname' - $!\n" unless print $fh $data;
 257         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 258     };
 259     my $err = $@;
 260
 261     if ($err) {
 262         unlink $tmpname;
 263         die $err;
 264     }
 265
 266     if (!rename($tmpname, $filename)) {
 267         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 268         unlink $tmpname;
 269         die $msg;
 270     }
 271 }
 272
 273 sub file_get_contents {
 274     my ($filename, $max) = @_;
 275
 276     my $fh = IO::File->new($filename, "r") ||
 277         die "can't open '$filename' - $!\n";
 278
 279     my $content = safe_read_from($fh, $max, 0, $filename);
 280
 281     close $fh;
 282
 283     return $content;
 284 }
 285
 286 sub file_copy {
 287     my ($filename, $dst, $max, $perm) = @_;
 288
 289     file_set_contents ($dst, file_get_contents($filename, $max), $perm);
 290 }
 291
 292 sub file_read_firstline {
 293     my ($filename) = @_;
 294
 295     my $fh = IO::File->new ($filename, "r");
 296     if (!$fh) {
 297         return undef if $! == POSIX::ENOENT;
 298         die "file '$filename' exists but open for reading failed - $!\n";
 299     }
 300     my $res = <$fh>;
 301     chomp $res if $res;
 302     $fh->close;
 303     return $res;
 304 }
 305
 306 sub safe_read_from {
 307     my ($fh, $max, $oneline, $filename) = @_;
 308
 309     # pmxcfs file size limit
 310     $max = 1024 * 1024 if !$max;
 311
 312     my $subject = defined($filename) ? "file '$filename'" : 'input';
 313
 314     my $br = 0;
 315     my $input = '';
 316     my $count;
 317     while ($count = sysread($fh, $input, 8192, $br)) {
 318         $br += $count;
 319         die "$subject too long - aborting\n" if $br > $max;
 320         if ($oneline && $input =~ m/^(.*)\n/) {
 321             $input = $1;
 322             last;
 323         }
 324     }
 325     die "unable to read $subject - $!\n" if !defined($count);
 326
 327     return $input;
 328 }
 329
 330 # The $cmd parameter can be:
 331 #  -) a string
 332 #    This is generally executed by passing it to the shell with the -c option.
 333 #    However, it can be executed in one of two ways, depending on whether
 334 #    there's a pipe involved:
 335 #      *) with pipe: passed explicitly to bash -c, prefixed with:
 336 #          set -o pipefail &&
 337 #      *) without a pipe: passed to perl's open3 which uses 'sh -c'
 338 #      (Note that this may result in two different syntax requirements!)
 339 #      FIXME?
 340 #  -) an array of arguments (strings)
 341 #    Will be executed without interference from a shell. (Parameters are passed
 342 #    as is, no escape sequences of strings will be touched.)
 343 #  -) an array of arrays
 344 #    Each array represents a command, and each command's output is piped into
 345 #    the following command's standard input.
 346 #    For this a shell command string is created with pipe symbols between each
 347 #    command.
 348 #    Each command is a list of strings meant to end up in the final command
 349 #    unchanged. In order to achieve this, every argument is shell-quoted.
 350 #    Quoting can be disabled for a particular argument by turning it into a
 351 #    reference, this allows inserting arbitrary shell options.
 352 #    For instance: the $cmd [ [ 'echo', 'hello', \'>/dev/null' ] ] will not
 353 #    produce any output, while the $cmd [ [ 'echo', 'hello', '>/dev/null' ] ]
 354 #    will literally print: hello >/dev/null
 355 sub run_command {
 356     my ($cmd, %param) = @_;
 357
 358     my $old_umask;
 359     my $cmdstr;
 360
 361     if (my $ref = ref($cmd)) {
 362         if (ref($cmd->[0])) {
 363             $cmdstr = 'set -o pipefail && ';
 364             my $pipe = '';
 365             foreach my $command (@$cmd) {
 366                 # concatenate quoted parameters
 367                 # strings which are passed by reference are NOT shell quoted
 368                 $cmdstr .= $pipe .  join(' ', map { ref($_) ? $$_ : shellquote($_) } @$command);
 369                 $pipe = ' | ';
 370             }
 371             $cmd = [ '/bin/bash', '-c', "$cmdstr" ];
 372         } else {
 373             $cmdstr = cmd2string($cmd);
 374         }
 375     } else {
 376         $cmdstr = $cmd;
 377         if ($cmd =~ m/\|/) {
 378             # see 'man bash' for option pipefail
 379             $cmd = [ '/bin/bash', '-c', "set -o pipefail && $cmd" ];
 380         } else {
 381             $cmd = [ $cmd ];
 382         }
 383     }
 384
 385     my $errmsg;
 386     my $laststderr;
 387     my $timeout;
 388     my $oldtimeout;
 389     my $pid;
 390     my $exitcode = -1;
 391
 392     my $outfunc;
 393     my $errfunc;
 394     my $logfunc;
 395     my $input;
 396     my $output;
 397     my $afterfork;
 398     my $noerr;
 399     my $keeplocale;
 400     my $quiet;
 401
 402     eval {
 403
 404         foreach my $p (keys %param) {
 405             if ($p eq 'timeout') {
 406                 $timeout = $param{$p};
 407             } elsif ($p eq 'umask') {
 408                 $old_umask = umask($param{$p});
 409             } elsif ($p eq 'errmsg') {
 410                 $errmsg = $param{$p};
 411             } elsif ($p eq 'input') {
 412                 $input = $param{$p};
 413             } elsif ($p eq 'output') {
 414                 $output = $param{$p};
 415             } elsif ($p eq 'outfunc') {
 416                 $outfunc = $param{$p};
 417             } elsif ($p eq 'errfunc') {
 418                 $errfunc = $param{$p};
 419             } elsif ($p eq 'logfunc') {
 420                 $logfunc = $param{$p};
 421             } elsif ($p eq 'afterfork') {
 422                 $afterfork = $param{$p};
 423             } elsif ($p eq 'noerr') {
 424                 $noerr = $param{$p};
 425             } elsif ($p eq 'keeplocale') {
 426                 $keeplocale = $param{$p};
 427             } elsif ($p eq 'quiet') {
 428                 $quiet = $param{$p};
 429             } else {
 430                 die "got unknown parameter '$p' for run_command\n";
 431             }
 432         }
 433
 434         if ($errmsg) {
 435             my $origerrfunc = $errfunc;
 436             $errfunc = sub {
 437                 if ($laststderr) {
 438                     if ($origerrfunc) {
 439                         &$origerrfunc("$laststderr\n");
 440                     } else {
 441                         print STDERR "$laststderr\n" if $laststderr;
 442                     }
 443                 }
 444                 $laststderr = shift;
 445             };
 446         }
 447
 448         my $reader = $output && $output =~ m/^>&/ ? $output : IO::File->new();
 449         my $writer = $input && $input =~ m/^<&/ ? $input : IO::File->new();
 450         my $error  = IO::File->new();
 451
 452         my $orig_pid = $$;
 453
 454         eval {
 455             local $ENV{LC_ALL} = 'C' if !$keeplocale;
 456
 457             # suppress LVM warnings like: "File descriptor 3 left open";
 458             local $ENV{LVM_SUPPRESS_FD_WARNINGS} = "1";
 459
 460             $pid = open3($writer, $reader, $error, @$cmd) || die $!;
 461
 462             # if we pipe fron STDIN, open3 closes STDIN, so we get a perl warning like
 463             # "Filehandle STDIN reopened as GENXYZ .. " as soon as we open a new file.
 464             # to avoid that we open /dev/null
 465             if (!ref($writer) && !defined(fileno(STDIN))) {
 466                 POSIX::close(0);
 467                 open(STDIN, '<', '/dev/null');
 468             }
 469         };
 470
 471         my $err = $@;
 472
 473         # catch exec errors
 474         if ($orig_pid != $$) {
 475             warn "ERROR: $err";
 476             POSIX::_exit (1);
 477             kill ('KILL', $$);
 478         }
 479
 480         die $err if $err;
 481
 482         local $SIG{ALRM} = sub { die "got timeout\n"; } if $timeout;
 483         $oldtimeout = alarm($timeout) if $timeout;
 484
 485         &$afterfork() if $afterfork;
 486
 487         if (ref($writer)) {
 488             print $writer $input if defined $input;
 489             close $writer;
 490         }
 491
 492         my $select = IO::Select->new();
 493         $select->add($reader) if ref($reader);
 494         $select->add($error);
 495
 496         my $outlog = '';
 497         my $errlog = '';
 498
 499         my $starttime = time();
 500
 501         while ($select->count) {
 502             my @handles = $select->can_read(1);
 503
 504             foreach my $h (@handles) {
 505                 my $buf = '';
 506                 my $count = sysread ($h, $buf, 4096);
 507                 if (!defined ($count)) {
 508                     my $err = $!;
 509                     kill (9, $pid);
 510                     waitpid ($pid, 0);
 511                     die $err;
 512                 }
 513                 $select->remove ($h) if !$count;
 514                 if ($h eq $reader) {
 515                     if ($outfunc || $logfunc) {
 516                         eval {
 517                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 518                                 my $line = $outlog . $1;
 519                                 $outlog = '';
 520                                 &$outfunc($line) if $outfunc;
 521                                 &$logfunc($line) if $logfunc;
 522                             }
 523                             $outlog .= $buf;
 524                         };
 525                         my $err = $@;
 526                         if ($err) {
 527                             kill (9, $pid);
 528                             waitpid ($pid, 0);
 529                             die $err;
 530                         }
 531                     } elsif (!$quiet) {
 532                         print $buf;
 533                         *STDOUT->flush();
 534                     }
 535                 } elsif ($h eq $error) {
 536                     if ($errfunc || $logfunc) {
 537                         eval {
 538                             while ($buf =~ s/^([^\010\r\n]*)(?:\n|(?:\010)+|\r\n?)//) {
 539                                 my $line = $errlog . $1;
 540                                 $errlog = '';
 541                                 &$errfunc($line) if $errfunc;
 542                                 &$logfunc($line) if $logfunc;
 543                             }
 544                             $errlog .= $buf;
 545                         };
 546                         my $err = $@;
 547                         if ($err) {
 548                             kill (9, $pid);
 549                             waitpid ($pid, 0);
 550                             die $err;
 551                         }
 552                     } elsif (!$quiet) {
 553                         print STDERR $buf;
 554                         *STDERR->flush();
 555                     }
 556                 }
 557             }
 558         }
 559
 560         &$outfunc($outlog) if $outfunc && $outlog;
 561         &$logfunc($outlog) if $logfunc && $outlog;
 562
 563         &$errfunc($errlog) if $errfunc && $errlog;
 564         &$logfunc($errlog) if $logfunc && $errlog;
 565
 566         waitpid ($pid, 0);
 567
 568         if ($? == -1) {
 569             die "failed to execute\n";
 570         } elsif (my $sig = ($? & 127)) {
 571             die "got signal $sig\n";
 572         } elsif ($exitcode = ($? >> 8)) {
 573             if (!($exitcode == 24 && ($cmdstr =~ m|^(\S+/)?rsync\s|))) {
 574                 if ($errmsg && $laststderr) {
 575                     my $lerr = $laststderr;
 576                     $laststderr = undef;
 577                     die "$lerr\n";
 578                 }
 579                 die "exit code $exitcode\n";
 580             }
 581         }
 582
 583         alarm(0);
 584     };
 585
 586     my $err = $@;
 587
 588     alarm(0);
 589
 590     if ($errmsg && $laststderr) {
 591         &$errfunc(undef); # flush laststderr
 592     }
 593
 594     umask ($old_umask) if defined($old_umask);
 595
 596     alarm($oldtimeout) if $oldtimeout;
 597
 598     if ($err) {
 599         if ($pid && ($err eq "got timeout\n")) {
 600             kill (9, $pid);
 601             waitpid ($pid, 0);
 602             die "command '$cmdstr' failed: $err";
 603         }
 604
 605         if ($errmsg) {
 606             $err =~ s/^usermod:\s*// if $cmdstr =~ m|^(\S+/)?usermod\s|;
 607             die "$errmsg: $err";
 608         } elsif(!$noerr) {
 609             die "command '$cmdstr' failed: $err";
 610         }
 611     }
 612
 613     return $exitcode;
 614 }
 615
 616 # Run a command with a tcp socket as standard input.
 617 sub pipe_socket_to_command  {
 618     my ($cmd, $ip, $port) = @_;
 619
 620     my $params = {
 621         Listen => 1,
 622         ReuseAddr => 1,
 623         Proto => &Socket::IPPROTO_TCP,
 624         GetAddrInfoFlags => 0,
 625         LocalAddr => $ip,
 626         LocalPort => $port,
 627     };
 628     my $socket = IO::Socket::IP->new(%$params) or die "failed to open socket: $!\n";
 629
 630     print "$ip\n$port\n"; # tell remote where to connect
 631     *STDOUT->flush();
 632
 633     alarm 0;
 634     local $SIG{ALRM} = sub { die "timed out waiting for client\n" };
 635     alarm 30;
 636     my $client = $socket->accept; # Wait for a client
 637     alarm 0;
 638     close($socket);
 639
 640     # We want that the command talks over the TCP socket and takes
 641     # ownership of it, so that when it closes it the connection is
 642     # terminated, so we need to be able to close the socket. So we
 643     # can't really use PVE::Tools::run_command().
 644     my $pid = fork() // die "fork failed: $!\n";
 645     if (!$pid) {
 646         POSIX::dup2(fileno($client), 0);
 647         POSIX::dup2(fileno($client), 1);
 648         close($client);
 649         exec {$cmd->[0]} @$cmd or do {
 650             warn "exec failed: $!\n";
 651             POSIX::_exit(1);
 652         };
 653     }
 654
 655     close($client);
 656     if (waitpid($pid, 0) != $pid) {
 657         kill(15 => $pid); # if we got interrupted terminate the child
 658         my $count = 0;
 659         while (waitpid($pid, POSIX::WNOHANG) != $pid) {
 660             usleep(100000);
 661             $count++;
 662             kill(9 => $pid), last if $count > 300; # 30 second timeout
 663         }
 664     }
 665     if (my $sig = ($? & 127)) {
 666         die "got signal $sig\n";
 667     } elsif (my $exitcode = ($? >> 8)) {
 668         die "exit code $exitcode\n";
 669     }
 670
 671     return undef;
 672 }
 673
 674 sub split_list {
 675     my $listtxt = shift // '';
 676
 677     return split (/\0/, $listtxt) if $listtxt =~ m/\0/;
 678
 679     $listtxt =~ s/[,;]/ /g;
 680     $listtxt =~ s/^\s+//;
 681
 682     my @data = split (/\s+/, $listtxt);
 683
 684     return @data;
 685 }
 686
 687 sub trim {
 688     my $txt = shift;
 689
 690     return $txt if !defined($txt);
 691
 692     $txt =~ s/^\s+//;
 693     $txt =~ s/\s+$//;
 694
 695     return $txt;
 696 }
 697
 698 # simple uri templates like "/vms/{vmid}"
 699 sub template_replace {
 700     my ($tmpl, $data) = @_;
 701
 702     return $tmpl if !$tmpl;
 703
 704     my $res = '';
 705     while ($tmpl =~ m/([^{]+)?(\{([^}]+)\})?/g) {
 706         $res .= $1 if $1;
 707         $res .= ($data->{$3} || '-') if $2;
 708     }
 709     return $res;
 710 }
 711
 712 sub safe_print {
 713     my ($filename, $fh, $data) = @_;
 714
 715     return if !$data;
 716
 717     my $res = print $fh $data;
 718
 719     die "write to '$filename' failed\n" if !$res;
 720 }
 721
 722 sub debmirrors {
 723
 724     return {
 725         'at' => 'ftp.at.debian.org',
 726         'au' => 'ftp.au.debian.org',
 727         'be' => 'ftp.be.debian.org',
 728         'bg' => 'ftp.bg.debian.org',
 729         'br' => 'ftp.br.debian.org',
 730         'ca' => 'ftp.ca.debian.org',
 731         'ch' => 'ftp.ch.debian.org',
 732         'cl' => 'ftp.cl.debian.org',
 733         'cz' => 'ftp.cz.debian.org',
 734         'de' => 'ftp.de.debian.org',
 735         'dk' => 'ftp.dk.debian.org',
 736         'ee' => 'ftp.ee.debian.org',
 737         'es' => 'ftp.es.debian.org',
 738         'fi' => 'ftp.fi.debian.org',
 739         'fr' => 'ftp.fr.debian.org',
 740         'gr' => 'ftp.gr.debian.org',
 741         'hk' => 'ftp.hk.debian.org',
 742         'hr' => 'ftp.hr.debian.org',
 743         'hu' => 'ftp.hu.debian.org',
 744         'ie' => 'ftp.ie.debian.org',
 745         'is' => 'ftp.is.debian.org',
 746         'it' => 'ftp.it.debian.org',
 747         'jp' => 'ftp.jp.debian.org',
 748         'kr' => 'ftp.kr.debian.org',
 749         'mx' => 'ftp.mx.debian.org',
 750         'nl' => 'ftp.nl.debian.org',
 751         'no' => 'ftp.no.debian.org',
 752         'nz' => 'ftp.nz.debian.org',
 753         'pl' => 'ftp.pl.debian.org',
 754         'pt' => 'ftp.pt.debian.org',
 755         'ro' => 'ftp.ro.debian.org',
 756         'ru' => 'ftp.ru.debian.org',
 757         'se' => 'ftp.se.debian.org',
 758         'si' => 'ftp.si.debian.org',
 759         'sk' => 'ftp.sk.debian.org',
 760         'tr' => 'ftp.tr.debian.org',
 761         'tw' => 'ftp.tw.debian.org',
 762         'gb' => 'ftp.uk.debian.org',
 763         'us' => 'ftp.us.debian.org',
 764     };
 765 }
 766
 767 my $keymaphash =  {
 768     'dk'     => ['Danish', 'da', 'qwerty/dk-latin1.kmap.gz', 'dk', 'nodeadkeys'],
 769     'de'     => ['German', 'de', 'qwertz/de-latin1-nodeadkeys.kmap.gz', 'de', 'nodeadkeys' ],
 770     'de-ch'  => ['Swiss-German', 'de-ch', 'qwertz/sg-latin1.kmap.gz',  'ch', 'de_nodeadkeys' ],
 771     'en-gb'  => ['United Kingdom', 'en-gb', 'qwerty/uk.kmap.gz' , 'gb', undef],
 772     'en-us'  => ['U.S. English', 'en-us', 'qwerty/us-latin1.kmap.gz',  'us', undef ],
 773     'es'     => ['Spanish', 'es', 'qwerty/es.kmap.gz', 'es', 'nodeadkeys'],
 774     #'et'     => [], # Ethopia or Estonia ??
 775     'fi'     => ['Finnish', 'fi', 'qwerty/fi-latin1.kmap.gz', 'fi', 'nodeadkeys'],
 776     #'fo'     => ['Faroe Islands', 'fo', ???, 'fo', 'nodeadkeys'],
 777     'fr'     => ['French', 'fr', 'azerty/fr-latin1.kmap.gz', 'fr', 'nodeadkeys'],
 778     'fr-be'  => ['Belgium-French', 'fr-be', 'azerty/be2-latin1.kmap.gz', 'be', 'nodeadkeys'],
 779     'fr-ca'  => ['Canada-French', 'fr-ca', 'qwerty/cf.kmap.gz', 'ca', 'fr-legacy'],
 780     'fr-ch'  => ['Swiss-French', 'fr-ch', 'qwertz/fr_CH-latin1.kmap.gz', 'ch', 'fr_nodeadkeys'],
 781     #'hr'     => ['Croatia', 'hr', 'qwertz/croat.kmap.gz', 'hr', ??], # latin2?
 782     'hu'     => ['Hungarian', 'hu', 'qwertz/hu.kmap.gz', 'hu', undef],
 783     'is'     => ['Icelandic', 'is', 'qwerty/is-latin1.kmap.gz', 'is', 'nodeadkeys'],
 784     'it'     => ['Italian', 'it', 'qwerty/it2.kmap.gz', 'it', 'nodeadkeys'],
 785     'jp'     => ['Japanese', 'ja', 'qwerty/jp106.kmap.gz', 'jp', undef],
 786     'lt'     => ['Lithuanian', 'lt', 'qwerty/lt.kmap.gz', 'lt', 'std'],
 787     #'lv'     => ['Latvian', 'lv', 'qwerty/lv-latin4.kmap.gz', 'lv', ??], # latin4 or latin7?
 788     'mk'     => ['Macedonian', 'mk', 'qwerty/mk.kmap.gz', 'mk', 'nodeadkeys'],
 789     'nl'     => ['Dutch', 'nl', 'qwerty/nl.kmap.gz', 'nl', undef],
 790     #'nl-be'  => ['Belgium-Dutch', 'nl-be', ?, ?, ?],
 791     'no'   => ['Norwegian', 'no', 'qwerty/no-latin1.kmap.gz', 'no', 'nodeadkeys'],
 792     'pl'     => ['Polish', 'pl', 'qwerty/pl.kmap.gz', 'pl', undef],
 793     'pt'     => ['Portuguese', 'pt', 'qwerty/pt-latin1.kmap.gz', 'pt', 'nodeadkeys'],
 794     'pt-br'  => ['Brazil-Portuguese', 'pt-br', 'qwerty/br-latin1.kmap.gz', 'br', 'nodeadkeys'],
 795     #'ru'     => ['Russian', 'ru', 'qwerty/ru.kmap.gz', 'ru', undef], # don't know?
 796     'si'     => ['Slovenian', 'sl', 'qwertz/slovene.kmap.gz', 'si', undef],
 797     'se'     => ['Swedish', 'sv', 'qwerty/se-latin1.kmap.gz', 'se', 'nodeadkeys'],
 798     #'th'     => [],
 799     'tr'     => ['Turkish', 'tr', 'qwerty/trq.kmap.gz', 'tr', undef],
 800 };
 801
 802 my $kvmkeymaparray = [];
 803 foreach my $lc (sort keys %$keymaphash) {
 804     push @$kvmkeymaparray, $keymaphash->{$lc}->[1];
 805 }
 806
 807 sub kvmkeymaps {
 808     return $keymaphash;
 809 }
 810
 811 sub kvmkeymaplist {
 812     return $kvmkeymaparray;
 813 }
 814
 815 sub extract_param {
 816     my ($param, $key) = @_;
 817
 818     my $res = $param->{$key};
 819     delete $param->{$key};
 820
 821     return $res;
 822 }
 823
 824 # For extracting sensitive keys (e.g. password), to avoid writing them to www-data owned configs
 825 sub extract_sensitive_params :prototype($$$) {
 826     my ($param, $sensitive_list, $delete_list) = @_;
 827
 828     my %delete = map { $_ => 1 } ($delete_list || [])->@*;
 829
 830     my $sensitive = {};
 831     for my $opt (@$sensitive_list) {
 832         # handle deletions as explicitly setting `undef`, so subs which only have $param but not
 833         # $delete_list available can recognize them. Afterwards new values  may override.
 834         if (exists($delete{$opt})) {
 835             $sensitive->{$opt} = undef;
 836         }
 837
 838         if (defined(my $value = extract_param($param, $opt))) {
 839             $sensitive->{$opt} = $value;
 840         }
 841     }
 842
 843     return $sensitive;
 844 }
 845
 846 # Note: we use this to wait until vncterm/spiceterm is ready
 847 sub wait_for_vnc_port {
 848     my ($port, $family, $timeout) = @_;
 849
 850     $timeout = 5 if !$timeout;
 851     my $sleeptime = 0;
 852     my $starttime = [gettimeofday];
 853     my $elapsed;
 854
 855     my $cmd = ['/bin/ss', '-Htln', "sport = :$port"];
 856     push @$cmd, $family == AF_INET6 ? '-6' : '-4' if defined($family);
 857
 858     my $found;
 859     while (($elapsed = tv_interval($starttime)) < $timeout) {
 860         # -Htln = don't print header, tcp, listening sockets only, numeric ports
 861         run_command($cmd, outfunc => sub {
 862             my $line = shift;
 863             if ($line =~ m/^LISTEN\s+\d+\s+\d+\s+\S+:(\d+)\s/) {
 864                 $found = 1 if ($port == $1);
 865             }
 866         });
 867         return 1 if $found;
 868         $sleeptime += 100000 if  $sleeptime < 1000000;
 869         usleep($sleeptime);
 870     }
 871
 872     die "Timeout while waiting for port '$port' to get ready!\n";
 873 }
 874
 875 sub next_unused_port {
 876     my ($range_start, $range_end, $family, $address) = @_;
 877
 878     # We use a file to register allocated ports.
 879     # Those registrations expires after $expiretime.
 880     # We use this to avoid race conditions between
 881     # allocation and use of ports.
 882
 883     my $filename = "/var/tmp/pve-reserved-ports";
 884
 885     my $code = sub {
 886
 887         my $expiretime = 5;
 888         my $ctime = time();
 889
 890         my $ports = {};
 891
 892         if (my $fh = IO::File->new ($filename, "r")) {
 893             while (my $line = <$fh>) {
 894                 if ($line =~ m/^(\d+)\s(\d+)$/) {
 895                     my ($port, $timestamp) = ($1, $2);
 896                     if (($timestamp + $expiretime) > $ctime) {
 897                         $ports->{$port} = $timestamp; # not expired
 898                     }
 899                 }
 900             }
 901         }
 902
 903         my $newport;
 904         my %sockargs = (Listen => 5,
 905                         ReuseAddr => 1,
 906                         Family    => $family,
 907                         Proto     => IPPROTO_TCP,
 908                         GetAddrInfoFlags => 0);
 909         $sockargs{LocalAddr} = $address if defined($address);
 910
 911         for (my $p = $range_start; $p < $range_end; $p++) {
 912             next if $ports->{$p}; # reserved
 913
 914             $sockargs{LocalPort} = $p;
 915             my $sock = IO::Socket::IP->new(%sockargs);
 916
 917             if ($sock) {
 918                 close($sock);
 919                 $newport = $p;
 920                 $ports->{$p} = $ctime;
 921                 last;
 922             }
 923         }
 924
 925         my $data = "";
 926         foreach my $p (keys %$ports) {
 927             $data .= "$p $ports->{$p}\n";
 928         }
 929
 930         file_set_contents($filename, $data);
 931
 932         return $newport;
 933     };
 934
 935     my $p = lock_file('/var/lock/pve-ports.lck', 10, $code);
 936     die $@ if $@;
 937
 938     die "unable to find free port (${range_start}-${range_end})\n" if !$p;
 939
 940     return $p;
 941 }
 942
 943 sub next_migrate_port {
 944     my ($family, $address) = @_;
 945     return next_unused_port(60000, 60050, $family, $address);
 946 }
 947
 948 sub next_vnc_port {
 949     my ($family, $address) = @_;
 950     return next_unused_port(5900, 6000, $family, $address);
 951 }
 952
 953 sub spice_port_range {
 954     return (61000, 61999);
 955 }
 956
 957 sub next_spice_port {
 958     my ($family, $address) = @_;
 959     return next_unused_port(spice_port_range(), $family, $address);
 960 }
 961
 962 sub must_stringify {
 963         my ($value) = @_;
 964         eval { $value = "$value" };
 965         return "error turning value into a string: $@" if $@;
 966         return $value;
 967 }
 968
 969 # sigkill after $timeout  a $sub running in a fork if it can't write a pipe
 970 # the $sub has to return a single scalar
 971 sub run_fork_with_timeout {
 972     my ($timeout, $sub) = @_;
 973
 974     my $res;
 975     my $error;
 976     my $pipe_out = IO::Pipe->new();
 977
 978     # disable pending alarms, save their remaining time
 979     my $prev_alarm = alarm 0;
 980
 981     # avoid leaving a zombie if the parent gets interrupted
 982     my $sig_received;
 983
 984     my $child = fork();
 985     if (!defined($child)) {
 986         die "fork failed: $!\n";
 987         return $res;
 988     }
 989
 990     if (!$child) {
 991         $pipe_out->writer();
 992
 993         eval {
 994             $res = $sub->();
 995             print {$pipe_out} encode_json({ result => $res });
 996             $pipe_out->flush();
 997         };
 998         if (my $err = $@) {
 999             print {$pipe_out} encode_json({ error => must_stringify($err) });
1000             $pipe_out->flush();
1001             POSIX::_exit(1);
1002         }
1003         POSIX::_exit(0);
1004     }
1005
1006     local $SIG{INT} = sub { $sig_received++; };
1007     local $SIG{TERM} = sub {
1008         $error //= "interrupted by unexpected signal\n";
1009         kill('TERM', $child);
1010     };
1011
1012     $pipe_out->reader();
1013
1014     my $readvalues = sub {
1015         local $/ = undef;
1016         my $child_res = decode_json(readline_nointr($pipe_out));
1017         $res = $child_res->{result};
1018         $error = $child_res->{error};
1019     };
1020     my $got_timeout = 0;
1021     eval {
1022         if (defined($timeout)) {
1023             (undef, $got_timeout) = run_with_timeout($timeout, $readvalues);
1024         } else {
1025             $readvalues->();
1026         }
1027     };
1028     warn $@ if $@;
1029     $pipe_out->close();
1030     kill('KILL', $child);
1031     # FIXME: hangs if $child doesn't exits?! (D state)
1032     waitpid($child, 0);
1033
1034     alarm $prev_alarm;
1035     die "interrupted by unexpected signal\n" if $sig_received;
1036
1037     die $error if $error;
1038     return wantarray ? ($res, $got_timeout) : $res;
1039 }
1040
1041 sub run_fork {
1042     my ($code) = @_;
1043     return run_fork_with_timeout(undef, $code);
1044 }
1045
1046 # NOTE: NFS syscall can't be interrupted, so alarm does
1047 # not work to provide timeouts.
1048 # from 'man nfs': "Only SIGKILL can interrupt a pending NFS operation"
1049 # So fork() before using Filesys::Df
1050 sub df {
1051     my ($path, $timeout) = @_;
1052
1053     my $df = sub { return Filesys::Df::df($path, 1) };
1054
1055     my $res = eval { run_fork_with_timeout($timeout, $df) } // {};
1056     warn $@ if $@;
1057
1058     # untaint, but be flexible: PB usage can result in scientific notation
1059     my ($blocks, $used, $bavail) = map { defined($_) ? (/^([\d\.e\-+]+)$/) : 0 }
1060         $res->@{qw(blocks used bavail)};
1061
1062     return {
1063         total => $blocks,
1064         used => $used,
1065         avail => $bavail,
1066     };
1067 }
1068
1069 sub du {
1070     my ($path, $timeout) = @_;
1071
1072     my $size;
1073
1074     $timeout //= 10;
1075
1076     my $parser = sub {
1077         my $line = shift;
1078
1079         if ($line =~ m/^(\d+)\s+total$/) {
1080             $size = $1;
1081         }
1082     };
1083
1084     run_command(['du', '-scb', $path], outfunc => $parser, timeout => $timeout);
1085
1086     return $size;
1087 }
1088
1089 # UPID helper
1090 # We use this to uniquely identify a process.
1091 # An 'Unique Process ID' has the following format:
1092 # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1093
1094 sub upid_encode {
1095     my $d = shift;
1096
1097     # Note: pstart can be > 32bit if uptime > 497 days, so this can result in
1098     # more that 8 characters for pstart
1099     return sprintf("UPID:%s:%08X:%08X:%08X:%s:%s:%s:", $d->{node}, $d->{pid},
1100                    $d->{pstart}, $d->{starttime}, $d->{type}, $d->{id},
1101                    $d->{user});
1102 }
1103
1104 sub upid_decode {
1105     my ($upid, $noerr) = @_;
1106
1107     my $res;
1108     my $filename;
1109
1110     # "UPID:$node:$pid:$pstart:$startime:$dtype:$id:$user"
1111     # Note: allow up to 9 characters for pstart (work until 20 years uptime)
1112     if ($upid =~ m/^UPID:([a-zA-Z0-9]([a-zA-Z0-9\-]*[a-zA-Z0-9])?):([0-9A-Fa-f]{8}):([0-9A-Fa-f]{8,9}):([0-9A-Fa-f]{8}):([^:\s]+):([^:\s]*):([^:\s]+):$/) {
1113         $res->{node} = $1;
1114         $res->{pid} = hex($3);
1115         $res->{pstart} = hex($4);
1116         $res->{starttime} = hex($5);
1117         $res->{type} = $6;
1118         $res->{id} = $7;
1119         $res->{user} = $8;
1120
1121         my $subdir = substr($5, 7, 8);
1122         $filename = "$pvetaskdir/$subdir/$upid";
1123
1124     } else {
1125         return undef if $noerr;
1126         die "unable to parse worker upid '$upid'\n";
1127     }
1128
1129     return wantarray ? ($res, $filename) : $res;
1130 }
1131
1132 sub upid_open {
1133     my ($upid) = @_;
1134
1135     my ($task, $filename) = upid_decode($upid);
1136
1137     my $dirname = dirname($filename);
1138     make_path($dirname);
1139
1140     my $wwwid = getpwnam('www-data') ||
1141         die "getpwnam failed";
1142
1143     my $perm = 0640;
1144
1145     my $outfh = IO::File->new ($filename, O_WRONLY|O_CREAT|O_EXCL, $perm) ||
1146         die "unable to create output file '$filename' - $!\n";
1147     chown $wwwid, -1, $outfh;
1148
1149     return $outfh;
1150 };
1151
1152 sub upid_read_status {
1153     my ($upid) = @_;
1154
1155     my ($task, $filename) = upid_decode($upid);
1156     my $fh = IO::File->new($filename, "r");
1157     return "unable to open file - $!" if !$fh;
1158     my $maxlen = 4096;
1159     sysseek($fh, -$maxlen, 2);
1160     my $readbuf = '';
1161     my $br = sysread($fh, $readbuf, $maxlen);
1162     close($fh);
1163     if ($br) {
1164         return "unable to extract last line"
1165             if $readbuf !~ m/\n?(.+)$/;
1166         my $line = $1;
1167         if ($line =~ m/^TASK OK$/) {
1168             return 'OK';
1169         } elsif ($line =~ m/^TASK ERROR: (.+)$/) {
1170             return $1;
1171         } elsif ($line =~ m/^TASK (WARNINGS: \d+)$/) {
1172             return $1;
1173         } else {
1174             return "unexpected status";
1175         }
1176     }
1177     return "unable to read tail (got $br bytes)";
1178 }
1179
1180 # Check if the status returned by upid_read_status is an error status.
1181 # If the status could not be parsed it's also treated as an error.
1182 sub upid_status_is_error {
1183     my ($status) = @_;
1184
1185     return !($status eq 'OK' || $status =~ m/^WARNINGS: \d+$/);
1186 }
1187
1188 # takes the parsed status and returns the type, either ok, warning, error or unknown
1189 sub upid_normalize_status_type {
1190     my ($status) = @_;
1191
1192     if (!$status) {
1193         return 'unknown';
1194     } elsif ($status eq 'OK') {
1195         return 'ok';
1196     } elsif ($status =~ m/^WARNINGS: \d+$/) {
1197         return 'warning';
1198     } elsif ($status eq 'unexpected status') {
1199         return 'unknown';
1200     } else {
1201         return 'error';
1202     }
1203 }
1204
1205 # useful functions to store comments in config files
1206 sub encode_text {
1207     my ($text) = @_;
1208
1209     # all control and hi-bit characters, and ':'
1210     my $unsafe = "^\x20-\x39\x3b-\x7e";
1211     return uri_escape(Encode::encode("utf8", $text), $unsafe);
1212 }
1213
1214 sub decode_text {
1215     my ($data) = @_;
1216
1217     return Encode::decode("utf8", uri_unescape($data));
1218 }
1219
1220 # NOTE: deprecated - do not use! we now decode all parameters by default
1221 sub decode_utf8_parameters {
1222     my ($param) = @_;
1223
1224     foreach my $p (qw(comment description firstname lastname)) {
1225         $param->{$p} = decode('utf8', $param->{$p}) if $param->{$p};
1226     }
1227
1228     return $param;
1229 }
1230
1231 sub random_ether_addr {
1232     my ($prefix) = @_;
1233
1234     my ($seconds, $microseconds) = gettimeofday;
1235
1236     my $rand = Digest::SHA::sha1($$, rand(), $seconds, $microseconds);
1237
1238     # clear multicast, set local id
1239     vec($rand, 0, 8) = (vec($rand, 0, 8) & 0xfe) | 2;
1240
1241     my $addr = sprintf("%02X:%02X:%02X:%02X:%02X:%02X", unpack("C6", $rand));
1242     if (defined($prefix)) {
1243         $addr = uc($prefix) . substr($addr, length($prefix));
1244     }
1245     return $addr;
1246 }
1247
1248 sub shellquote {
1249     my $str = shift;
1250
1251     return String::ShellQuote::shell_quote($str);
1252 }
1253
1254 sub cmd2string {
1255     my ($cmd) = @_;
1256
1257     die "no arguments" if !$cmd;
1258
1259     return $cmd if !ref($cmd);
1260
1261     my @qa = ();
1262     foreach my $arg (@$cmd) { push @qa, shellquote($arg); }
1263
1264     return join (' ', @qa);
1265 }
1266
1267 # split an shell argument string into an array,
1268 sub split_args {
1269     my ($str) = @_;
1270
1271     return $str ? [ Text::ParseWords::shellwords($str) ] : [];
1272 }
1273
1274 sub dump_logfile_by_filehandle {
1275     my ($fh, $filter, $state) = @_;
1276
1277     my $count = ($state->{count} //= 0);
1278     my $lines = ($state->{lines} //= []);
1279     my $start = ($state->{start} //= 0);
1280     my $limit = ($state->{limit} //= 50);
1281     my $final = ($state->{final} //= 1);
1282     my $read_until_end = ($state->{read_until_end} //= $limit == 0);
1283
1284     my $line;
1285     if ($filter) {
1286         # duplicate code, so that we do not slow down normal path
1287         while (defined($line = <$fh>)) {
1288             if (ref($filter) eq 'CODE') {
1289                 next if !$filter->($line);
1290             } else {
1291                 next if $line !~ m/$filter/;
1292             }
1293             next if $count++ < $start;
1294             if (!$read_until_end) {
1295                 next if $limit <= 0;
1296                 $limit--;
1297             }
1298             chomp $line;
1299             push @$lines, { n => $count, t => $line};
1300         }
1301     } else {
1302         while (defined($line = <$fh>)) {
1303             next if $count++ < $start;
1304             if (!$read_until_end) {
1305                 next if $limit <= 0;
1306                 $limit--;
1307             }
1308             chomp $line;
1309             push @$lines, { n => $count, t => $line};
1310         }
1311     }
1312
1313     # HACK: ExtJS store.guaranteeRange() does not like empty array
1314     # so we add a line
1315     if (!$count && $final) {
1316         $count++;
1317         push @$lines, { n => $count, t => "no content"};
1318     }
1319
1320     $state->{count} = $count;
1321     $state->{limit} = $limit;
1322 }
1323
1324 sub dump_logfile {
1325     my ($filename, $start, $limit, $filter) = @_;
1326
1327     my $fh = IO::File->new($filename, "r");
1328     if (!$fh) {
1329         return (1, { n => 1, t => "unable to open file - $!"});
1330     }
1331
1332     my %state = (
1333         'count' => 0,
1334         'lines' => [],
1335         'start' => $start,
1336         'limit' => $limit,
1337     );
1338
1339     dump_logfile_by_filehandle($fh, $filter, \%state);
1340
1341     close($fh);
1342
1343     return ($state{'count'}, $state{'lines'});
1344 }
1345
1346 sub dump_journal {
1347     my ($start, $limit, $since, $until, $service) = @_;
1348
1349     my $lines = [];
1350     my $count = 0;
1351
1352     $start = 0 if !$start;
1353     $limit = 50 if !$limit;
1354
1355     my $parser = sub {
1356         my $line = shift;
1357
1358         return if $count++ < $start;
1359         return if $limit <= 0;
1360         push @$lines, { n => int($count), t => $line};
1361         $limit--;
1362     };
1363
1364     my $cmd = ['journalctl', '-o', 'short', '--no-pager'];
1365
1366     push @$cmd, '--unit', $service if $service;
1367     push @$cmd, '--since', $since if $since;
1368     push @$cmd, '--until', $until if $until;
1369     run_command($cmd, outfunc => $parser);
1370
1371     # HACK: ExtJS store.guaranteeRange() does not like empty array
1372     # so we add a line
1373     if (!$count) {
1374         $count++;
1375         push @$lines, { n => $count, t => "no content"};
1376     }
1377
1378     return ($count, $lines);
1379 }
1380
1381 sub dir_glob_regex {
1382     my ($dir, $regex) = @_;
1383
1384     my $dh = IO::Dir->new ($dir);
1385     return wantarray ? () : undef if !$dh;
1386
1387     while (defined(my $tmp = $dh->read)) {
1388         if (my @res = $tmp =~ m/^($regex)$/) {
1389             $dh->close;
1390             return wantarray ? @res : $tmp;
1391         }
1392     }
1393     $dh->close;
1394
1395     return wantarray ? () : undef;
1396 }
1397
1398 sub dir_glob_foreach {
1399     my ($dir, $regex, $func) = @_;
1400
1401     my $dh = IO::Dir->new ($dir);
1402     if (defined $dh) {
1403         while (defined(my $tmp = $dh->read)) {
1404             if (my @res = $tmp =~ m/^($regex)$/) {
1405                 &$func (@res);
1406             }
1407         }
1408     }
1409 }
1410
1411 sub assert_if_modified {
1412     my ($digest1, $digest2) = @_;
1413
1414     if ($digest1 && $digest2 && ($digest1 ne $digest2)) {
1415         die "detected modified configuration - file changed by other user? Try again.\n";
1416     }
1417 }
1418
1419 # Digest for short strings
1420 # like FNV32a, but we only return 31 bits (positive numbers)
1421 sub fnv31a {
1422     my ($string) = @_;
1423
1424     my $hval = 0x811c9dc5;
1425
1426     foreach my $c (unpack('C*', $string)) {
1427         $hval ^= $c;
1428         $hval += (
1429             (($hval << 1) ) +
1430             (($hval << 4) ) +
1431             (($hval << 7) ) +
1432             (($hval << 8) ) +
1433             (($hval << 24) ) );
1434         $hval = $hval & 0xffffffff;
1435     }
1436     return $hval & 0x7fffffff;
1437 }
1438
1439 sub fnv31a_hex { return sprintf("%X", fnv31a(@_)); }
1440
1441 sub unpack_sockaddr_in46 {
1442     my ($sin) = @_;
1443     my $family = Socket::sockaddr_family($sin);
1444     my ($port, $host) = ($family == AF_INET6 ? Socket::unpack_sockaddr_in6($sin)
1445                                              : Socket::unpack_sockaddr_in($sin));
1446     return ($family, $port, $host);
1447 }
1448
1449 sub getaddrinfo_all {
1450     my ($hostname, @opts) = @_;
1451     my %hints = (
1452         flags => AI_V4MAPPED | AI_ALL,
1453         @opts,
1454     );
1455     my ($err, @res) = Socket::getaddrinfo($hostname, '0', \%hints);
1456     die "failed to get address info for: $hostname: $err\n" if $err;
1457     return @res;
1458 }
1459
1460 sub get_host_address_family {
1461     my ($hostname, $socktype) = @_;
1462     my @res = getaddrinfo_all($hostname, socktype => $socktype);
1463     return $res[0]->{family};
1464 }
1465
1466 # get the fully qualified domain name of a host
1467 # same logic as hostname(1): The FQDN is the name getaddrinfo(3) returns,
1468 # given a nodename as a parameter
1469 sub get_fqdn {
1470     my ($nodename) = @_;
1471
1472     my $hints = {
1473         flags => AI_CANONNAME,
1474         socktype => SOCK_DGRAM
1475     };
1476
1477     my ($err, @addrs) = Socket::getaddrinfo($nodename, undef, $hints);
1478
1479     die "getaddrinfo: $err" if $err;
1480
1481     return $addrs[0]->{canonname};
1482 }
1483
1484 # Parses any sane kind of host, or host+port pair:
1485 # The port is always optional and thus may be undef.
1486 sub parse_host_and_port {
1487     my ($address) = @_;
1488     if ($address =~ /^($IPV4RE|[[:alnum:]\-.]+)(?::(\d+))?$/ ||             # ipv4 or host with optional ':port'
1489         $address =~ /^\[($IPV6RE|$IPV4RE|[[:alnum:]\-.]+)\](?::(\d+))?$/ || # anything in brackets with optional ':port'
1490         $address =~ /^($IPV6RE)(?:\.(\d+))?$/)                              # ipv6 with optional port separated by dot
1491     {
1492         return ($1, $2, 1); # end with 1 to support simple if(parse...) tests
1493     }
1494     return; # nothing
1495 }
1496
1497 sub setresuid($$$) {
1498     my ($ruid, $euid, $suid) = @_;
1499     return 0 == syscall(PVE::Syscall::setresuid, int($ruid), int($euid), int($suid));
1500 }
1501
1502 sub unshare($) {
1503     my ($flags) = @_;
1504     return 0 == syscall(PVE::Syscall::unshare, int($flags));
1505 }
1506
1507 sub setns($$) {
1508     my ($fileno, $nstype) = @_;
1509     return 0 == syscall(PVE::Syscall::setns, int($fileno), int($nstype));
1510 }
1511
1512 sub syncfs($) {
1513     my ($fileno) = @_;
1514     return 0 == syscall(PVE::Syscall::syncfs, int($fileno));
1515 }
1516
1517 sub fsync($) {
1518     my ($fileno) = @_;
1519     return 0 == syscall(PVE::Syscall::fsync, int($fileno));
1520 }
1521
1522 sub renameat2($$$$$) {
1523     my ($olddirfd, $oldpath, $newdirfd, $newpath, $flags) = @_;
1524     return 0 == syscall(
1525         PVE::Syscall::renameat2,
1526         int($olddirfd),
1527         $oldpath,
1528         int($newdirfd),
1529         $newpath,
1530         int($flags),
1531     );
1532 }
1533
1534 sub sync_mountpoint {
1535     my ($path) = @_;
1536     sysopen my $fd, $path, O_RDONLY|O_CLOEXEC or die "failed to open $path: $!\n";
1537     my $syncfs_err;
1538     if (!syncfs(fileno($fd))) {
1539         $syncfs_err = "$!";
1540     }
1541     close($fd);
1542     die "syncfs '$path' failed - $syncfs_err\n" if defined $syncfs_err;
1543 }
1544
1545 my sub check_mail_addr {
1546     my ($addr) = @_;
1547     die "'$addr' does not look like a valid email address or username\n"
1548         if $addr !~ /^$EMAIL_RE$/ && $addr !~ /^$EMAIL_USER_RE$/;
1549 }
1550
1551 # support sending multi-part mail messages with a text and or a HTML part
1552 # mailto may be a single email string or an array of receivers
1553 sub sendmail {
1554     my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
1555
1556     $mailto = [ $mailto ] if !ref($mailto);
1557
1558     check_mail_addr($_) for $mailto->@*;
1559     my $to_quoted = [ map { shellquote($_) } $mailto->@* ];
1560
1561     $mailfrom = $mailfrom || "root";
1562     check_mail_addr($mailfrom);
1563     my $from_quoted = shellquote($mailfrom);
1564
1565     $author = $author // 'Proxmox VE';
1566
1567     open (my $mail, "|-", "sendmail", "-B", "8BITMIME", "-f", $from_quoted, "--", $to_quoted->@*)
1568         or die "unable to open 'sendmail' - $!";
1569
1570     my $is_multipart = $text && $html;
1571     my $boundary = "----_=_NextPart_001_" . int(time()) . $$; # multipart spec, see rfc 1521
1572
1573     $subject = Encode::encode('MIME-Header', $subject) if $subject =~ /[^[:ascii:]]/;
1574
1575     print $mail "MIME-Version: 1.0\n" if $subject =~ /[^[:ascii:]]/ || $is_multipart;
1576
1577     print $mail "From: $author <$mailfrom>\n";
1578     print $mail "To: " . join(', ', @$mailto) ."\n";
1579     print $mail "Date: " . time2str('%a, %d %b %Y %H:%M:%S %z', time()) . "\n";
1580     print $mail "Subject: $subject\n";
1581
1582     if ($is_multipart) {
1583         print $mail "Content-Type: multipart/alternative;\n";
1584         print $mail "\tboundary=\"$boundary\"\n";
1585         print $mail "\n";
1586         print $mail "This is a multi-part message in MIME format.\n\n";
1587         print $mail "--$boundary\n";
1588     }
1589
1590     if (defined($text)) {
1591         print $mail "Content-Type: text/plain;\n";
1592         print $mail "\tcharset=\"UTF-8\"\n";
1593         print $mail "Content-Transfer-Encoding: 8bit\n";
1594         print $mail "\n";
1595
1596         # avoid 'remove extra line breaks' issue (MS Outlook)
1597         my $fill = '  ';
1598         $text =~ s/^/$fill/gm;
1599
1600         print $mail $text;
1601
1602         print $mail "\n--$boundary\n" if $is_multipart;
1603     }
1604
1605     if (defined($html)) {
1606         print $mail "Content-Type: text/html;\n";
1607         print $mail "\tcharset=\"UTF-8\"\n";
1608         print $mail "Content-Transfer-Encoding: 8bit\n";
1609         print $mail "\n";
1610
1611         print $mail $html;
1612
1613         print $mail "\n--$boundary--\n" if $is_multipart;
1614     }
1615
1616     close($mail);
1617 }
1618
1619 # creates a temporary file that does not shows up on the file system hierarchy.
1620 #
1621 # Uses O_TMPFILE if available, which makes it just an anon inode that never shows up in the FS.
1622 # If O_TMPFILE is not available, which unlikely nowadays (added in 3.11 kernel and all FS relevant
1623 # for us support it) back to open-create + immediate unlink while still holding the file  handle.
1624 #
1625 # TODO: to avoid FS dependent features we could (transparently) switch to memfd_create as backend
1626 sub tempfile {
1627     my ($perm, %opts) = @_;
1628
1629     # default permissions are stricter than with file_set_contents
1630     $perm = 0600 if !defined($perm);
1631
1632     my $dir = $opts{dir};
1633     if (!$dir) {
1634         if (-d "/run/user/$<") {
1635             $dir = "/run/user/$<";
1636         } elsif ($< == 0) {
1637             $dir = "/run";
1638         } else {
1639             $dir = "/tmp";
1640         }
1641     }
1642     my $mode = $opts{mode} // O_RDWR;
1643     $mode |= O_EXCL if !$opts{allow_links};
1644
1645     my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
1646     if (!$fh && $! == EOPNOTSUPP) {
1647         $dir = '/tmp' if !defined($opts{dir});
1648         $dir .= "/.tmpfile.$$";
1649         $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
1650         unlink($dir) if $fh;
1651     }
1652     die "failed to create tempfile: $!\n" if !$fh;
1653     return $fh;
1654 }
1655
1656 # create an (ideally) anon file with the $data as content and return its FD-path and FH
1657 sub tempfile_contents {
1658     my ($data, $perm, %opts) = @_;
1659
1660     my $fh = tempfile($perm, %opts);
1661     eval {
1662         die "unable to write to tempfile: $!\n" if !print {$fh} $data;
1663         die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
1664     };
1665     if (my $err = $@) {
1666         close $fh;
1667         die $err;
1668     }
1669
1670     return ("/proc/$$/fd/".$fh->fileno, $fh);
1671 }
1672
1673 sub validate_ssh_public_keys {
1674     my ($raw) = @_;
1675     my @lines = split(/\n/, $raw);
1676
1677     foreach my $line (@lines) {
1678         next if $line =~ m/^\s*$/;
1679         eval {
1680             my ($filename, $handle) = tempfile_contents($line);
1681             run_command(["ssh-keygen", "-l", "-f", $filename],
1682                         outfunc => sub {}, errfunc => sub {});
1683         };
1684         die "SSH public key validation error\n" if $@;
1685     }
1686 }
1687
1688 sub openat($$$;$) {
1689     my ($dirfd, $pathname, $flags, $mode) = @_;
1690     $dirfd = int($dirfd);
1691     $flags = int($flags);
1692     $mode = int($mode // 0);
1693
1694     my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode);
1695     return undef if $fd < 0;
1696     # sysopen() doesn't deal with numeric file descriptors apparently
1697     # so we need to convert to a mode string for IO::Handle->new_from_fd
1698     my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
1699     my $handle = IO::Handle->new_from_fd($fd, $flagstr);
1700     return $handle if $handle;
1701     my $err = $!; # save error before closing the raw fd
1702     syscall(PVE::Syscall::close, $fd); # close
1703     $! = $err;
1704     return undef;
1705 }
1706
1707 sub mkdirat($$$) {
1708     my ($dirfd, $name, $mode) = @_;
1709     return syscall(PVE::Syscall::mkdirat, int($dirfd), $name, int($mode)) == 0;
1710 }
1711
1712 sub fchownat($$$$$) {
1713     my ($dirfd, $pathname, $owner, $group, $flags) = @_;
1714     return syscall(
1715         PVE::Syscall::fchownat,
1716         int($dirfd),
1717         $pathname,
1718         int($owner),
1719         int($group),
1720         int($flags),
1721     ) == 0;
1722 }
1723
1724 my $salt_starter = time();
1725
1726 sub encrypt_pw {
1727     my ($pw) = @_;
1728
1729     $salt_starter++;
1730     my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
1731
1732     # crypt does not want '+' in salt (see 'man crypt')
1733     $salt =~ s/\+/X/g;
1734
1735     return crypt(encode("utf8", $pw), "\$5\$$salt\$");
1736 }
1737
1738 # intended usage: convert_size($val, "kb" => "gb")
1739 # we round up to the next integer by default
1740 # E.g. `convert_size(1023, "b" => "kb")` returns 1
1741 # use $no_round_up to switch this off, above example would then return 0
1742 # this is also true for converting down e.g. 0.0005 gb to mb returns 1
1743 # (0 if $no_round_up is true)
1744 # allowed formats for value:
1745 # 1234
1746 # 1234.
1747 # 1234.1234
1748 # .1234
1749 sub convert_size {
1750     my ($value, $from, $to, $no_round_up) = @_;
1751
1752     my $units = {
1753         b  => 0,
1754         kb => 1,
1755         mb => 2,
1756         gb => 3,
1757         tb => 4,
1758         pb => 5,
1759     };
1760
1761     die "no value given"
1762         if !defined($value) || $value eq "";
1763
1764     $from = lc($from // ''); $to = lc($to // '');
1765     die "unknown 'from' and/or 'to' units ($from => $to)"
1766         if !defined($units->{$from}) || !defined($units->{$to});
1767
1768     die "value '$value' is not a valid, positive number"
1769         if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
1770
1771     my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
1772
1773     $value *= 2**$shift_amount;
1774     $value++ if !$no_round_up && ($value - int($value)) > 0.0;
1775
1776     return int($value);
1777 }
1778
1779 # uninterruptible readline
1780 # retries on EINTR
1781 sub readline_nointr {
1782     my ($fh) = @_;
1783     my $line;
1784     while (1) {
1785         $line = <$fh>;
1786         last if defined($line) || ($! != EINTR);
1787     }
1788     return $line;
1789 }
1790
1791 my $host_arch;
1792 sub get_host_arch {
1793     $host_arch = (POSIX::uname())[4] if !$host_arch;
1794     return $host_arch;
1795 }
1796
1797 # Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
1798 sub dev_t_major($) {
1799     my ($dev_t) = @_;
1800     return (int($dev_t) & 0xfff00) >> 8;
1801 }
1802
1803 sub dev_t_minor($) {
1804     my ($dev_t) = @_;
1805     $dev_t = int($dev_t);
1806     return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
1807 }
1808
1809 # Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
1810 # Returns the intersection of elements as a single array [a b]
1811 sub array_intersect {
1812     my ($arrays) = @_;
1813
1814     if (!ref($arrays->[0])) {
1815         $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
1816     }
1817
1818     return [] if scalar(@$arrays) == 0;
1819     return $arrays->[0] if scalar(@$arrays) == 1;
1820
1821     my $array_unique = sub {
1822         my %seen = ();
1823         return grep { ! $seen{ $_ }++ } @_;
1824     };
1825
1826     # base idea is to get all unique members from the first array, then
1827     # check the common elements with the next (uniquely made) one, only keep
1828     # those. Repeat for every array and at the end we only have those left
1829     # which exist in all arrays
1830     my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
1831     for my $i (1 .. $#$arrays) {
1832         my %count = ();
1833         # $return_arr is already unique, explicit at before the loop, implicit below.
1834         foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
1835             $count{$element}++;
1836         }
1837         $return_arr = [];
1838         foreach my $element (keys %count) {
1839             push @$return_arr, $element if $count{$element} > 1;
1840         }
1841         last if scalar(@$return_arr) == 0; # empty intersection, early exit
1842     }
1843
1844     return $return_arr;
1845 }
1846
1847 sub open_tree($$$) {
1848     my ($dfd, $pathname, $flags) = @_;
1849     return PVE::Syscall::file_handle_result(syscall(
1850         &PVE::Syscall::open_tree,
1851         int($dfd),
1852         $pathname,
1853         int($flags),
1854     ));
1855 }
1856
1857 sub move_mount($$$$$) {
1858     my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
1859     return 0 == syscall(
1860         &PVE::Syscall::move_mount,
1861         int($from_dirfd),
1862         $from_pathname,
1863         int($to_dirfd),
1864         $to_pathname,
1865         int($flags),
1866     );
1867 }
1868
1869 sub fsopen($$) {
1870     my ($fsname, $flags) = @_;
1871     return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, int($flags)));
1872 }
1873
1874 sub fsmount($$$) {
1875     my ($fd, $flags, $mount_attrs) = @_;
1876     return PVE::Syscall::file_handle_result(syscall(
1877         &PVE::Syscall::fsmount,
1878         int($fd),
1879         int($flags),
1880         int($mount_attrs),
1881     ));
1882 }
1883
1884 sub fspick($$$) {
1885     my ($dirfd, $pathname, $flags) = @_;
1886     return PVE::Syscall::file_handle_result(syscall(
1887         &PVE::Syscall::fspick,
1888         int($dirfd),
1889         $pathname,
1890         int($flags),
1891     ));
1892 }
1893
1894 sub fsconfig($$$$$) {
1895     my ($fd, $command, $key, $value, $aux) = @_;
1896     return 0 == syscall(
1897         &PVE::Syscall::fsconfig,
1898         int($fd),
1899         int($command),
1900         $key,
1901         $value,
1902         int($aux),
1903     );
1904 }
1905
1906 # "raw" mount, old api, not for generic use (as it does not invoke any helpers).
1907 # use for lower level stuff such as bind/remount/... or simple tmpfs mounts
1908 sub mount($$$$$) {
1909     my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
1910     return 0 == syscall(
1911         &PVE::Syscall::mount,
1912         $source,
1913         $target,
1914         $filesystemtype,
1915         int($mountflags),
1916         $data,
1917     );
1918 }
1919
1920 # size is optional and defaults to 256, note that xattr limits are FS specific and that xattrs can
1921 # get arbitrary long. pass `0` for $size in array context to get the actual size of a value
1922 sub getxattr($$;$) {
1923     my ($path_or_handle, $name, $size) = @_;
1924     $size //= 256;
1925     my $buf = pack("x${size}");
1926
1927     my $xattr_size = -1; # the actual size of the xattr, can be zero
1928     if (defined(my $fd = fileno($path_or_handle))) {
1929         $xattr_size = syscall(&PVE::Syscall::fgetxattr, $fd, $name, $buf, int($size));
1930     } else {
1931         $xattr_size = syscall(&PVE::Syscall::getxattr, $path_or_handle, $name, $buf, int($size));
1932     }
1933     if ($xattr_size < 0) {
1934         return undef;
1935     }
1936     $buf = substr($buf, 0, $xattr_size);
1937     return wantarray ? ($buf, $xattr_size) : $buf;
1938 }
1939
1940 # NOTE: can take either a path or an open file handle, i.e., its multiplexing setxattr and fsetxattr
1941 sub setxattr($$$;$) {
1942     my ($path_or_handle, $name, $value, $flags) = @_;
1943     my $size = length($value); # NOTE: seems to get correct length also for wide-characters in text..
1944
1945     if (defined(my $fd = fileno($path_or_handle))) {
1946         return 0 == syscall(
1947             &PVE::Syscall::fsetxattr,
1948             $fd,
1949             $name,
1950             $value,
1951             int($size),
1952             int($flags // 0),
1953         );
1954     } else {
1955         return 0 == syscall(
1956             &PVE::Syscall::setxattr,
1957             $path_or_handle,
1958             $name,
1959             $value,
1960             int($size),
1961             int($flags // 0),
1962         );
1963     }
1964 }
1965
1966 sub safe_compare {
1967     my ($left, $right, $cmp) = @_;
1968
1969     return 0 if !defined($left) && !defined($right);
1970     return -1 if !defined($left);
1971     return 1 if !defined($right);
1972     return $cmp->($left, $right);
1973 }
1974
1975
1976 # opts is a hash ref with the following known properties
1977 #  allow_overwrite - if 1, overwriting existing files is allowed, use with care. Default to false
1978 #  hash_required - if 1, at least one checksum has to be specified otherwise an error will be thrown
1979 #  http_proxy
1980 #  https_proxy
1981 #  verify_certificates - if 0 (false) we tell wget to ignore untrusted TLS certs. Default to true
1982 #  md5sum|sha(1|224|256|384|512)sum - the respective expected checksum string
1983 sub download_file_from_url {
1984     my ($dest, $url, $opts) = @_;
1985
1986     my ($checksum_algorithm, $checksum_expected);
1987     for ('sha512', 'sha384', 'sha256', 'sha224', 'sha1', 'md5') {
1988         if (defined($opts->{"${_}sum"})) {
1989             $checksum_algorithm = $_;
1990             $checksum_expected = $opts->{"${_}sum"};
1991             last;
1992         }
1993     }
1994     die "checksum required but not specified\n" if ($opts->{hash_required} && !$checksum_algorithm);
1995
1996     print "downloading $url to $dest\n";
1997
1998     if (-f $dest) {
1999         if ($checksum_algorithm) {
2000             print "calculating checksum of existing file...";
2001             my $checksum_got = get_file_hash($checksum_algorithm, $dest);
2002
2003             if (lc($checksum_got) eq lc($checksum_expected)) {
2004                 print "OK, got correct file already, no need to download\n";
2005                 return;
2006             } elsif ($opts->{allow_overwrite}) {
2007                 print "checksum mismatch: got '$checksum_got' != expect '$checksum_expected', re-download\n";
2008             } else {
2009                 print "\n";  # the front end expects the error to reside at the last line without any noise
2010                 die "checksum mismatch: got '$checksum_got' != expect '$checksum_expected', aborting\n";
2011             }
2012         } elsif (!$opts->{allow_overwrite}) {
2013             die "refusing to override existing file '$dest'\n";
2014         }
2015     }
2016
2017     my $tmp_download = "$dest.tmp_dwnl.$$";
2018     my $tmp_decomp = "$dest.tmp_dcom.$$";
2019     eval {
2020         local $SIG{INT} = sub {
2021             unlink $tmp_download or warn "could not cleanup temporary file: $!"
2022                 if -e $tmp_download;
2023             unlink $tmp_decomp or warn "could not cleanup temporary file: $!"
2024                 if $opts->{decompression_command} && -e $tmp_decomp;
2025             die "got interrupted by signal\n";
2026         };
2027
2028         { # limit the scope of the ENV change
2029             local %ENV;
2030             if ($opts->{http_proxy}) {
2031                 $ENV{http_proxy} = $opts->{http_proxy};
2032             }
2033             if ($opts->{https_proxy}) {
2034                 $ENV{https_proxy} = $opts->{https_proxy};
2035             }
2036
2037             my $cmd = ['wget', '--progress=dot:giga', '-O', $tmp_download, $url];
2038
2039             if (!($opts->{verify_certificates} // 1)) { # default to true
2040                 push @$cmd, '--no-check-certificate';
2041             }
2042
2043             run_command($cmd, errmsg => "download failed");
2044         }
2045
2046         if ($checksum_algorithm) {
2047             print "calculating checksum...";
2048
2049             my $checksum_got = get_file_hash($checksum_algorithm, $tmp_download);
2050
2051             if (lc($checksum_got) eq lc($checksum_expected)) {
2052                 print "OK, checksum verified\n";
2053             } else {
2054                 print "\n";  # the front end expects the error to reside at the last line without any noise
2055                 die "checksum mismatch: got '$checksum_got' != expect '$checksum_expected'\n";
2056             }
2057         }
2058
2059         if (my $cmd = $opts->{decompression_command}) {
2060             push @$cmd, $tmp_download;
2061             my $fh;
2062             if (!open($fh, ">", "$tmp_decomp")) {
2063                 die "cant open temporary file $tmp_decomp for decompresson: $!\n";
2064             }
2065             print "decompressing $tmp_download to $tmp_decomp\n";
2066             run_command($cmd, output => '>&'.fileno($fh));
2067             unlink $tmp_download;
2068             rename($tmp_decomp, $dest) or die "unable to rename temporary file: $!\n";
2069         } else {
2070             rename($tmp_download, $dest) or die "unable to rename temporary file: $!\n";
2071         }
2072     };
2073     if (my $err = $@) {
2074         unlink $tmp_download or warn "could not cleanup temporary file: $!"
2075             if -e $tmp_download;
2076         unlink $tmp_decomp or warn "could not cleanup temporary file: $!"
2077             if $opts->{decompression_command} && -e $tmp_decomp;
2078         die $err;
2079     }
2080
2081     print "download of '$url' to '$dest' finished\n";
2082 }
2083
2084 sub get_file_hash {
2085     my ($algorithm, $filename) = @_;
2086
2087     my $algorithm_map = {
2088         'md5' => sub { Digest::MD5->new },
2089         'sha1' => sub { Digest::SHA->new(1) },
2090         'sha224' => sub { Digest::SHA->new(224) },
2091         'sha256' => sub { Digest::SHA->new(256) },
2092         'sha384' => sub { Digest::SHA->new(384) },
2093         'sha512' => sub { Digest::SHA->new(512) },
2094     };
2095
2096     my $digester = $algorithm_map->{$algorithm}->() or die "unknown algorithm '$algorithm'\n";
2097
2098     open(my $fh, '<', $filename) or die "unable to open '$filename': $!\n";
2099     binmode($fh);
2100
2101     my $digest = $digester->addfile($fh)->hexdigest;
2102
2103     return lc($digest);
2104 }
2105
2106 1;