src/PVE/API2/LXC.pm

   1 package PVE::API2::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Tools qw(extract_param run_command);
   8 use PVE::Exception qw(raise raise_param_exc raise_perm_exc);
   9 use PVE::INotify;
  10 use PVE::Cluster qw(cfs_read_file);
  11 use PVE::RRD;
  12 use PVE::DataCenterConfig;
  13 use PVE::AccessControl;
  14 use PVE::Firewall;
  15 use PVE::Storage;
  16 use PVE::RESTHandler;
  17 use PVE::RPCEnvironment;
  18 use PVE::ReplicationConfig;
  19 use PVE::LXC;
  20 use PVE::LXC::Create;
  21 use PVE::LXC::Migrate;
  22 use PVE::GuestHelpers;
  23 use PVE::VZDump::Plugin;
  24 use PVE::API2::LXC::Config;
  25 use PVE::API2::LXC::Status;
  26 use PVE::API2::LXC::Snapshot;
  27 use PVE::JSONSchema qw(get_standard_option);
  28 use base qw(PVE::RESTHandler);
  29
  30 BEGIN {
  31     if (!$ENV{PVE_GENERATING_DOCS}) {
  32         require PVE::HA::Env::PVE2;
  33         import  PVE::HA::Env::PVE2;
  34         require PVE::HA::Config;
  35         import  PVE::HA::Config;
  36     }
  37 }
  38
  39 __PACKAGE__->register_method ({
  40     subclass => "PVE::API2::LXC::Config",
  41     path => '{vmid}/config',
  42 });
  43
  44 __PACKAGE__->register_method ({
  45     subclass => "PVE::API2::LXC::Status",
  46     path => '{vmid}/status',
  47 });
  48
  49 __PACKAGE__->register_method ({
  50     subclass => "PVE::API2::LXC::Snapshot",
  51     path => '{vmid}/snapshot',
  52 });
  53
  54 __PACKAGE__->register_method ({
  55     subclass => "PVE::API2::Firewall::CT",
  56     path => '{vmid}/firewall',
  57 });
  58
  59 __PACKAGE__->register_method({
  60     name => 'vmlist',
  61     path => '',
  62     method => 'GET',
  63     description => "LXC container index (per node).",
  64     permissions => {
  65         description => "Only list CTs where you have VM.Audit permissons on /vms/<vmid>.",
  66         user => 'all',
  67     },
  68     proxyto => 'node',
  69     protected => 1, # /proc files are only readable by root
  70     parameters => {
  71         additionalProperties => 0,
  72         properties => {
  73             node => get_standard_option('pve-node'),
  74         },
  75     },
  76     returns => {
  77         type => 'array',
  78         items => {
  79             type => "object",
  80             properties => $PVE::LXC::vmstatus_return_properties,
  81         },
  82         links => [ { rel => 'child', href => "{vmid}" } ],
  83     },
  84     code => sub {
  85         my ($param) = @_;
  86
  87         my $rpcenv = PVE::RPCEnvironment::get();
  88         my $authuser = $rpcenv->get_user();
  89
  90         my $vmstatus = PVE::LXC::vmstatus();
  91
  92         my $res = [];
  93         foreach my $vmid (keys %$vmstatus) {
  94             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
  95
  96             my $data = $vmstatus->{$vmid};
  97             push @$res, $data;
  98         }
  99
 100         return $res;
 101
 102     }});
 103
 104 __PACKAGE__->register_method({
 105     name => 'create_vm',
 106     path => '',
 107     method => 'POST',
 108     description => "Create or restore a container.",
 109     permissions => {
 110         user => 'all', # check inside
 111         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 112             "For restore, it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 113             "You also need 'Datastore.AllocateSpace' permissions on the storage.",
 114     },
 115     protected => 1,
 116     proxyto => 'node',
 117     parameters => {
 118         additionalProperties => 0,
 119         properties => PVE::LXC::Config->json_config_properties({
 120             node => get_standard_option('pve-node'),
 121             vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 122             ostemplate => {
 123                 description => "The OS template or backup file.",
 124                 type => 'string',
 125                 maxLength => 255,
 126                 completion => \&PVE::LXC::complete_os_templates,
 127             },
 128             password => {
 129                 optional => 1,
 130                 type => 'string',
 131                 description => "Sets root password inside container.",
 132                 minLength => 5,
 133             },
 134             storage => get_standard_option('pve-storage-id', {
 135                 description => "Default Storage.",
 136                 default => 'local',
 137                 optional => 1,
 138                 completion => \&PVE::Storage::complete_storage_enabled,
 139             }),
 140             force => {
 141                 optional => 1,
 142                 type => 'boolean',
 143                 description => "Allow to overwrite existing container.",
 144             },
 145             restore => {
 146                 optional => 1,
 147                 type => 'boolean',
 148                 description => "Mark this as restore task.",
 149             },
 150             unique => {
 151                 optional => 1,
 152                 type => 'boolean',
 153                 description => "Assign a unique random ethernet address.",
 154                 requires => 'restore',
 155             },
 156             pool => {
 157                 optional => 1,
 158                 type => 'string', format => 'pve-poolid',
 159                 description => "Add the VM to the specified pool.",
 160             },
 161             'ignore-unpack-errors' => {
 162                 optional => 1,
 163                 type => 'boolean',
 164                 description => "Ignore errors when extracting the template.",
 165             },
 166             'ssh-public-keys' => {
 167                 optional => 1,
 168                 type => 'string',
 169                 description => "Setup public SSH keys (one key per line, " .
 170                                 "OpenSSH format).",
 171             },
 172             bwlimit => {
 173                 description => "Override I/O bandwidth limit (in KiB/s).",
 174                 optional => 1,
 175                 type => 'number',
 176                 minimum => '0',
 177                 default => 'restore limit from datacenter or storage config',
 178             },
 179             start => {
 180                 optional => 1,
 181                 type => 'boolean',
 182                 default => 0,
 183                 description => "Start the CT after its creation finished successfully.",
 184             },
 185         }),
 186     },
 187     returns => {
 188         type => 'string',
 189     },
 190     code => sub {
 191         my ($param) = @_;
 192
 193         PVE::Cluster::check_cfs_quorum();
 194
 195         my $rpcenv = PVE::RPCEnvironment::get();
 196         my $authuser = $rpcenv->get_user();
 197
 198         my $node = extract_param($param, 'node');
 199         my $vmid = extract_param($param, 'vmid');
 200         my $ignore_unpack_errors = extract_param($param, 'ignore-unpack-errors');
 201         my $bwlimit = extract_param($param, 'bwlimit');
 202         my $start_after_create = extract_param($param, 'start');
 203
 204         my $basecfg_fn = PVE::LXC::Config->config_file($vmid);
 205         my $same_container_exists = -f $basecfg_fn;
 206
 207         # 'unprivileged' is read-only, so we can't pass it to update_pct_config
 208         my $unprivileged = extract_param($param, 'unprivileged');
 209         my $restore = extract_param($param, 'restore');
 210         my $unique = extract_param($param, 'unique');
 211
 212         # used to skip firewall config restore if user lacks permission
 213         my $skip_fw_config_restore = 0;
 214
 215         if ($restore) {
 216             # fixme: limit allowed parameters
 217         }
 218
 219         my $force = extract_param($param, 'force');
 220
 221         if (!($same_container_exists && $restore && $force)) {
 222             PVE::Cluster::check_vmid_unused($vmid);
 223         } else {
 224             die "can't overwrite running container\n" if PVE::LXC::check_running($vmid);
 225             my $conf = PVE::LXC::Config->load_config($vmid);
 226             PVE::LXC::Config->check_protection($conf, "unable to restore CT $vmid");
 227         }
 228
 229         my $password = extract_param($param, 'password');
 230         my $ssh_keys = extract_param($param, 'ssh-public-keys');
 231         PVE::Tools::validate_ssh_public_keys($ssh_keys) if defined($ssh_keys);
 232
 233         my $pool = extract_param($param, 'pool');
 234         if (defined($pool)) {
 235             $rpcenv->check_pool_exist($pool);
 236             $rpcenv->check_perm_modify($authuser, "/pool/$pool");
 237         }
 238
 239         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 240             # OK
 241         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 242             # OK
 243         } elsif ($restore && $force && $same_container_exists &&
 244                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 245             # OK: user has VM.Backup permissions, and want to restore an existing VM
 246
 247             # we don't want to restore a container-provided FW conf in this case
 248             # since the user is lacking permission to configure the container's FW
 249             $skip_fw_config_restore = 1;
 250         } else {
 251             raise_perm_exc();
 252         }
 253
 254         my $ostemplate = extract_param($param, 'ostemplate');
 255         my $storage = extract_param($param, 'storage') // 'local';
 256
 257         PVE::LXC::check_ct_modify_config_perm($rpcenv, $authuser, $vmid, $pool, $param, []);
 258
 259         my $storage_cfg = cfs_read_file("storage.cfg");
 260
 261         my $archive;
 262         if ($ostemplate eq '-') {
 263             die "pipe requires cli environment\n"
 264                 if $rpcenv->{type} ne 'cli';
 265             die "pipe can only be used with restore tasks\n"
 266                 if !$restore;
 267             $archive = '-';
 268             die "restore from pipe requires rootfs parameter\n" if !defined($param->{rootfs});
 269         } else {
 270             PVE::Storage::check_volume_access($rpcenv, $authuser, $storage_cfg, $vmid, $ostemplate);
 271             $archive = $ostemplate;
 272         }
 273
 274         my %used_storages;
 275         my $check_and_activate_storage = sub {
 276             my ($sid) = @_;
 277
 278             my $scfg = PVE::Storage::storage_check_node($storage_cfg, $sid, $node);
 279
 280             raise_param_exc({ storage => "storage '$sid' does not support container directories"})
 281                 if !$scfg->{content}->{rootdir};
 282
 283             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 284
 285             PVE::Storage::activate_storage($storage_cfg, $sid);
 286             $used_storages{$sid} = 1;
 287         };
 288
 289         my $conf = {};
 290
 291         my $is_root = $authuser eq 'root@pam';
 292
 293         my $no_disk_param = {};
 294         my $mp_param = {};
 295         my $storage_only_mode = 1;
 296         foreach my $opt (keys %$param) {
 297             my $value = $param->{$opt};
 298             if ($opt eq 'rootfs' || $opt =~ m/^mp\d+$/) {
 299                 # allow to use simple numbers (add default storage in that case)
 300                 if ($value =~ m/^\d+(\.\d+)?$/) {
 301                     $mp_param->{$opt} = "$storage:$value";
 302                 } else {
 303                     $mp_param->{$opt} = $value;
 304                 }
 305                 $storage_only_mode = 0;
 306             } elsif ($opt =~ m/^unused\d+$/) {
 307                 warn "ignoring '$opt', cannot create/restore with unused volume\n";
 308                 delete $param->{$opt};
 309             } else {
 310                 $no_disk_param->{$opt} = $value;
 311             }
 312         }
 313
 314         die "mount points configured, but 'rootfs' not set - aborting\n"
 315             if !$storage_only_mode && !defined($mp_param->{rootfs});
 316
 317         # check storage access, activate storage
 318         my $delayed_mp_param = {};
 319         PVE::LXC::Config->foreach_volume($mp_param, sub {
 320             my ($ms, $mountpoint) = @_;
 321
 322             my $volid = $mountpoint->{volume};
 323             my $mp = $mountpoint->{mp};
 324
 325             if ($mountpoint->{type} ne 'volume') { # bind or device
 326                 die "Only root can pass arbitrary filesystem paths.\n"
 327                     if !$is_root;
 328             } else {
 329                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 330                 &$check_and_activate_storage($sid);
 331             }
 332         });
 333
 334         # check/activate default storage
 335         &$check_and_activate_storage($storage) if !defined($mp_param->{rootfs});
 336
 337         PVE::LXC::Config->update_pct_config($vmid, $conf, 0, $no_disk_param);
 338
 339         $conf->{unprivileged} = 1 if $unprivileged;
 340
 341         my $emsg = $restore ? "unable to restore CT $vmid -" : "unable to create CT $vmid -";
 342
 343         eval { PVE::LXC::Config->create_and_lock_config($vmid, $force) };
 344         die "$emsg $@" if $@;
 345
 346         my $code = sub {
 347             my $old_conf = PVE::LXC::Config->load_config($vmid);
 348             my $was_template;
 349
 350             my $vollist = [];
 351             eval {
 352                 my $orig_mp_param; # only used if $restore
 353                 if ($restore) {
 354                     die "can't overwrite running container\n" if PVE::LXC::check_running($vmid);
 355                     if ($is_root && $archive ne '-') {
 356                         my $orig_conf;
 357                         ($orig_conf, $orig_mp_param) = PVE::LXC::Create::recover_config($storage_cfg, $archive);
 358                         $was_template = delete $orig_conf->{template};
 359                         # When we're root call 'restore_configuration' with restricted=0,
 360                         # causing it to restore the raw lxc entries, among which there may be
 361                         # 'lxc.idmap' entries. We need to make sure that the extracted contents
 362                         # of the container match up with the restored configuration afterwards:
 363                         $conf->{lxc} = $orig_conf->{lxc};
 364                     }
 365                 }
 366                 if ($storage_only_mode) {
 367                     if ($restore) {
 368                         if (!defined($orig_mp_param)) {
 369                             (undef, $orig_mp_param) = PVE::LXC::Create::recover_config($storage_cfg, $archive);
 370                         }
 371                         $mp_param = $orig_mp_param;
 372                         die "rootfs configuration could not be recovered, please check and specify manually!\n"
 373                             if !defined($mp_param->{rootfs});
 374                         PVE::LXC::Config->foreach_volume($mp_param, sub {
 375                             my ($ms, $mountpoint) = @_;
 376                             my $type = $mountpoint->{type};
 377                             if ($type eq 'volume') {
 378                                 die "unable to detect disk size - please specify $ms (size)\n"
 379                                     if !defined($mountpoint->{size});
 380                                 my $disksize = $mountpoint->{size} / (1024 * 1024 * 1024); # create_disks expects GB as unit size
 381                                 delete $mountpoint->{size};
 382                                 $mountpoint->{volume} = "$storage:$disksize";
 383                                 $mp_param->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
 384                             } else {
 385                                 my $type = $mountpoint->{type};
 386                                 die "restoring rootfs to $type mount is only possible by specifying -rootfs manually!\n"
 387                                     if ($ms eq 'rootfs');
 388                                 die "restoring '$ms' to $type mount is only possible for root\n"
 389                                     if !$is_root;
 390
 391                                 if ($mountpoint->{backup}) {
 392                                     warn "WARNING - unsupported configuration!\n";
 393                                     warn "backup was enabled for $type mount point $ms ('$mountpoint->{mp}')\n";
 394                                     warn "mount point configuration will be restored after archive extraction!\n";
 395                                     warn "contained files will be restored to wrong directory!\n";
 396                                 }
 397                                 delete $mp_param->{$ms}; # actually delay bind/dev mps
 398                                 $delayed_mp_param->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
 399                             }
 400                         });
 401                     } else {
 402                         $mp_param->{rootfs} = "$storage:4"; # defaults to 4GB
 403                     }
 404                 }
 405
 406                 $vollist = PVE::LXC::create_disks($storage_cfg, $vmid, $mp_param, $conf);
 407
 408                 # we always have the 'create' lock so check for more than 1 entry
 409                 if (scalar(keys %$old_conf) > 1) {
 410                     # destroy old container volumes
 411                     PVE::LXC::destroy_lxc_container($storage_cfg, $vmid, $old_conf, { lock => 'create' });
 412                 }
 413
 414                 eval {
 415                     my $rootdir = PVE::LXC::mount_all($vmid, $storage_cfg, $conf, 1);
 416                     $bwlimit = PVE::Storage::get_bandwidth_limit('restore', [keys %used_storages], $bwlimit);
 417                     PVE::LXC::Create::restore_archive($storage_cfg, $archive, $rootdir, $conf, $ignore_unpack_errors, $bwlimit);
 418
 419                     if ($restore) {
 420                         PVE::LXC::Create::restore_configuration($vmid, $storage_cfg, $archive, $rootdir, $conf, !$is_root, $unique, $skip_fw_config_restore);
 421                         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 422                         $lxc_setup->template_fixup($conf);
 423                     } else {
 424                         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 425                         PVE::LXC::Config->write_config($vmid, $conf); # safe config (after OS detection)
 426                         $lxc_setup->post_create_hook($password, $ssh_keys);
 427                     }
 428                 };
 429                 my $err = $@;
 430                 PVE::LXC::umount_all($vmid, $storage_cfg, $conf, $err ? 1 : 0);
 431                 PVE::Storage::deactivate_volumes($storage_cfg, PVE::LXC::Config->get_vm_volumes($conf));
 432                 die $err if $err;
 433                 # set some defaults
 434                 $conf->{hostname} ||= "CT$vmid";
 435                 $conf->{memory} ||= 512;
 436                 $conf->{swap} //= 512;
 437                 foreach my $mp (keys %$delayed_mp_param) {
 438                     $conf->{$mp} = $delayed_mp_param->{$mp};
 439                 }
 440                 # If the template flag was set, we try to convert again to template after restore
 441                 if ($was_template) {
 442                     print STDERR "Convert restored container to template...\n";
 443                     PVE::LXC::template_create($vmid, $conf);
 444                     $conf->{template} = 1;
 445                 }
 446                 PVE::LXC::Config->write_config($vmid, $conf);
 447             };
 448             if (my $err = $@) {
 449                 PVE::LXC::destroy_disks($storage_cfg, $vollist);
 450                 eval { PVE::LXC::Config->destroy_config($vmid) };
 451                 warn $@ if $@;
 452                 die "$emsg $err";
 453             }
 454             PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 455
 456             PVE::API2::LXC::Status->vm_start({ vmid => $vmid, node => $node })
 457                 if $start_after_create;
 458         };
 459
 460         my $workername = $restore ? 'vzrestore' : 'vzcreate';
 461         my $realcmd = sub { PVE::LXC::Config->lock_config($vmid, $code); };
 462
 463         return $rpcenv->fork_worker($workername, $vmid, $authuser, $realcmd);
 464     }});
 465
 466 __PACKAGE__->register_method({
 467     name => 'vmdiridx',
 468     path => '{vmid}',
 469     method => 'GET',
 470     proxyto => 'node',
 471     description => "Directory index",
 472     permissions => {
 473         user => 'all',
 474     },
 475     parameters => {
 476         additionalProperties => 0,
 477         properties => {
 478             node => get_standard_option('pve-node'),
 479             vmid => get_standard_option('pve-vmid'),
 480         },
 481     },
 482     returns => {
 483         type => 'array',
 484         items => {
 485             type => "object",
 486             properties => {
 487                 subdir => { type => 'string' },
 488             },
 489         },
 490         links => [ { rel => 'child', href => "{subdir}" } ],
 491     },
 492     code => sub {
 493         my ($param) = @_;
 494
 495         # test if VM exists
 496         my $conf = PVE::LXC::Config->load_config($param->{vmid});
 497
 498         my $res = [
 499             { subdir => 'config' },
 500             { subdir => 'pending' },
 501             { subdir => 'status' },
 502             { subdir => 'vncproxy' },
 503             { subdir => 'termproxy' },
 504             { subdir => 'vncwebsocket' },
 505             { subdir => 'spiceproxy' },
 506             { subdir => 'migrate' },
 507             { subdir => 'clone' },
 508 #           { subdir => 'initlog' },
 509             { subdir => 'rrd' },
 510             { subdir => 'rrddata' },
 511             { subdir => 'firewall' },
 512             { subdir => 'snapshot' },
 513             { subdir => 'resize' },
 514             ];
 515
 516         return $res;
 517     }});
 518
 519
 520 __PACKAGE__->register_method({
 521     name => 'rrd',
 522     path => '{vmid}/rrd',
 523     method => 'GET',
 524     protected => 1, # fixme: can we avoid that?
 525     permissions => {
 526         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 527     },
 528     description => "Read VM RRD statistics (returns PNG)",
 529     parameters => {
 530         additionalProperties => 0,
 531         properties => {
 532             node => get_standard_option('pve-node'),
 533             vmid => get_standard_option('pve-vmid'),
 534             timeframe => {
 535                 description => "Specify the time frame you are interested in.",
 536                 type => 'string',
 537                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 538             },
 539             ds => {
 540                 description => "The list of datasources you want to display.",
 541                 type => 'string', format => 'pve-configid-list',
 542             },
 543             cf => {
 544                 description => "The RRD consolidation function",
 545                 type => 'string',
 546                 enum => [ 'AVERAGE', 'MAX' ],
 547                 optional => 1,
 548             },
 549         },
 550     },
 551     returns => {
 552         type => "object",
 553         properties => {
 554             filename => { type => 'string' },
 555         },
 556     },
 557     code => sub {
 558         my ($param) = @_;
 559
 560         return PVE::RRD::create_rrd_graph(
 561             "pve2-vm/$param->{vmid}", $param->{timeframe},
 562             $param->{ds}, $param->{cf});
 563
 564     }});
 565
 566 __PACKAGE__->register_method({
 567     name => 'rrddata',
 568     path => '{vmid}/rrddata',
 569     method => 'GET',
 570     protected => 1, # fixme: can we avoid that?
 571     permissions => {
 572         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 573     },
 574     description => "Read VM RRD statistics",
 575     parameters => {
 576         additionalProperties => 0,
 577         properties => {
 578             node => get_standard_option('pve-node'),
 579             vmid => get_standard_option('pve-vmid'),
 580             timeframe => {
 581                 description => "Specify the time frame you are interested in.",
 582                 type => 'string',
 583                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 584             },
 585             cf => {
 586                 description => "The RRD consolidation function",
 587                 type => 'string',
 588                 enum => [ 'AVERAGE', 'MAX' ],
 589                 optional => 1,
 590             },
 591         },
 592     },
 593     returns => {
 594         type => "array",
 595         items => {
 596             type => "object",
 597             properties => {},
 598         },
 599     },
 600     code => sub {
 601         my ($param) = @_;
 602
 603         return PVE::RRD::create_rrd_data(
 604             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 605     }});
 606
 607 __PACKAGE__->register_method({
 608     name => 'destroy_vm',
 609     path => '{vmid}',
 610     method => 'DELETE',
 611     protected => 1,
 612     proxyto => 'node',
 613     description => "Destroy the container (also delete all uses files).",
 614     permissions => {
 615         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
 616     },
 617     parameters => {
 618         additionalProperties => 0,
 619         properties => {
 620             node => get_standard_option('pve-node'),
 621             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid_stopped }),
 622             purge => {
 623                 type => 'boolean',
 624                 description => "Remove vmid from backup cron jobs.",
 625                 optional => 1,
 626             },
 627         },
 628     },
 629     returns => {
 630         type => 'string',
 631     },
 632     code => sub {
 633         my ($param) = @_;
 634
 635         my $rpcenv = PVE::RPCEnvironment::get();
 636         my $authuser = $rpcenv->get_user();
 637         my $vmid = $param->{vmid};
 638
 639         # test if container exists
 640         my $conf = PVE::LXC::Config->load_config($vmid);
 641         my $storage_cfg = cfs_read_file("storage.cfg");
 642         PVE::LXC::Config->check_protection($conf, "can't remove CT $vmid");
 643
 644         my $ha_managed = PVE::HA::Config::service_is_configured("ct:$vmid");
 645
 646         if (!$param->{purge}) {
 647             die "unable to remove CT $vmid - used in HA resources and purge parameter not set.\n"
 648                 if $ha_managed;
 649
 650             # do not allow destroy if there are replication jobs without purge
 651             my $repl_conf = PVE::ReplicationConfig->new();
 652             $repl_conf->check_for_existing_jobs($vmid);
 653         }
 654
 655         my $running_error_msg = "unable to destroy CT $vmid - container is running\n";
 656
 657         die $running_error_msg if PVE::LXC::check_running($vmid); # check early
 658
 659         my $code = sub {
 660             # reload config after lock
 661             $conf = PVE::LXC::Config->load_config($vmid);
 662             PVE::LXC::Config->check_lock($conf);
 663
 664             die $running_error_msg if PVE::LXC::check_running($vmid);
 665
 666             PVE::LXC::destroy_lxc_container($storage_cfg, $vmid, $conf, { lock => 'destroyed' });
 667
 668             PVE::AccessControl::remove_vm_access($vmid);
 669             PVE::Firewall::remove_vmfw_conf($vmid);
 670             if ($param->{purge}) {
 671                 print "purging CT $vmid from related configurations..\n";
 672                 PVE::ReplicationConfig::remove_vmid_jobs($vmid);
 673                 PVE::VZDump::Plugin::remove_vmid_from_backup_jobs($vmid);
 674
 675                 if ($ha_managed) {
 676                     PVE::HA::Config::delete_service_from_config("ct:$vmid");
 677                     print "NOTE: removed CT $vmid from HA resource configuration.\n";
 678                 }
 679             }
 680
 681             # only now remove the zombie config, else we can have reuse race
 682             PVE::LXC::Config->destroy_config($vmid);
 683         };
 684
 685         my $realcmd = sub { PVE::LXC::Config->lock_config($vmid, $code); };
 686
 687         return $rpcenv->fork_worker('vzdestroy', $vmid, $authuser, $realcmd);
 688     }});
 689
 690 my $sslcert;
 691
 692 __PACKAGE__->register_method ({
 693     name => 'vncproxy',
 694     path => '{vmid}/vncproxy',
 695     method => 'POST',
 696     protected => 1,
 697     permissions => {
 698         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 699     },
 700     description => "Creates a TCP VNC proxy connections.",
 701     parameters => {
 702         additionalProperties => 0,
 703         properties => {
 704             node => get_standard_option('pve-node'),
 705             vmid => get_standard_option('pve-vmid'),
 706             websocket => {
 707                 optional => 1,
 708                 type => 'boolean',
 709                 description => "use websocket instead of standard VNC.",
 710             },
 711             width => {
 712                 optional => 1,
 713                 description => "sets the width of the console in pixels.",
 714                 type => 'integer',
 715                 minimum => 16,
 716                 maximum => 4096,
 717             },
 718             height => {
 719                 optional => 1,
 720                 description => "sets the height of the console in pixels.",
 721                 type => 'integer',
 722                 minimum => 16,
 723                 maximum => 2160,
 724             },
 725         },
 726     },
 727     returns => {
 728         additionalProperties => 0,
 729         properties => {
 730             user => { type => 'string' },
 731             ticket => { type => 'string' },
 732             cert => { type => 'string' },
 733             port => { type => 'integer' },
 734             upid => { type => 'string' },
 735         },
 736     },
 737     code => sub {
 738         my ($param) = @_;
 739
 740         my $rpcenv = PVE::RPCEnvironment::get();
 741
 742         my $authuser = $rpcenv->get_user();
 743
 744         my $vmid = $param->{vmid};
 745         my $node = $param->{node};
 746
 747         my $authpath = "/vms/$vmid";
 748
 749         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
 750
 751         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
 752             if !$sslcert;
 753
 754         my ($remip, $family);
 755
 756         if ($node ne PVE::INotify::nodename()) {
 757             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
 758         } else {
 759             $family = PVE::Tools::get_host_address_family($node);
 760         }
 761
 762         my $port = PVE::Tools::next_vnc_port($family);
 763
 764         # NOTE: vncterm VNC traffic is already TLS encrypted,
 765         # so we select the fastest chipher here (or 'none'?)
 766         my $remcmd = $remip ?
 767             ['/usr/bin/ssh', '-e', 'none', '-t', $remip] : [];
 768
 769         my $conf = PVE::LXC::Config->load_config($vmid, $node);
 770         my $concmd = PVE::LXC::get_console_command($vmid, $conf, -1);
 771
 772         my $shcmd = [ '/usr/bin/dtach', '-A',
 773                       "/var/run/dtach/vzctlconsole$vmid",
 774                       '-r', 'winch', '-z', @$concmd];
 775
 776         my $realcmd = sub {
 777             my $upid = shift;
 778
 779             syslog ('info', "starting lxc vnc proxy $upid\n");
 780
 781             my $timeout = 10;
 782
 783             my $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
 784                        '-timeout', $timeout, '-authpath', $authpath,
 785                        '-perm', 'VM.Console'];
 786
 787             if ($param->{width}) {
 788                 push @$cmd, '-width', $param->{width};
 789             }
 790
 791             if ($param->{height}) {
 792                 push @$cmd, '-height', $param->{height};
 793             }
 794
 795             if ($param->{websocket}) {
 796                 $ENV{PVE_VNC_TICKET} = $ticket; # pass ticket to vncterm
 797                 push @$cmd, '-notls', '-listen', 'localhost';
 798             }
 799
 800             push @$cmd, '-c', @$remcmd, @$shcmd;
 801
 802             run_command($cmd, keeplocale => 1);
 803
 804             return;
 805         };
 806
 807         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd);
 808
 809         PVE::Tools::wait_for_vnc_port($port);
 810
 811         return {
 812             user => $authuser,
 813             ticket => $ticket,
 814             port => $port,
 815             upid => $upid,
 816             cert => $sslcert,
 817         };
 818     }});
 819
 820 __PACKAGE__->register_method ({
 821     name => 'termproxy',
 822     path => '{vmid}/termproxy',
 823     method => 'POST',
 824     protected => 1,
 825     permissions => {
 826         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 827     },
 828     description => "Creates a TCP proxy connection.",
 829     parameters => {
 830         additionalProperties => 0,
 831         properties => {
 832             node => get_standard_option('pve-node'),
 833             vmid => get_standard_option('pve-vmid'),
 834         },
 835     },
 836     returns => {
 837         additionalProperties => 0,
 838         properties => {
 839             user => { type => 'string' },
 840             ticket => { type => 'string' },
 841             port => { type => 'integer' },
 842             upid => { type => 'string' },
 843         },
 844     },
 845     code => sub {
 846         my ($param) = @_;
 847
 848         my $rpcenv = PVE::RPCEnvironment::get();
 849
 850         my $authuser = $rpcenv->get_user();
 851
 852         my $vmid = $param->{vmid};
 853         my $node = $param->{node};
 854
 855         my $authpath = "/vms/$vmid";
 856
 857         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
 858
 859         my ($remip, $family);
 860
 861         if ($node ne 'localhost' && $node ne PVE::INotify::nodename()) {
 862             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
 863         } else {
 864             $family = PVE::Tools::get_host_address_family($node);
 865         }
 866
 867         my $port = PVE::Tools::next_vnc_port($family);
 868
 869         my $remcmd = $remip ?
 870             ['/usr/bin/ssh', '-e', 'none', '-t', $remip, '--'] : [];
 871
 872         my $conf = PVE::LXC::Config->load_config($vmid, $node);
 873         my $concmd = PVE::LXC::get_console_command($vmid, $conf, -1);
 874
 875         my $shcmd = [ '/usr/bin/dtach', '-A',
 876                       "/var/run/dtach/vzctlconsole$vmid",
 877                       '-r', 'winch', '-z', @$concmd];
 878
 879         my $realcmd = sub {
 880             my $upid = shift;
 881
 882             syslog ('info', "starting lxc termproxy $upid\n");
 883
 884             my $cmd = ['/usr/bin/termproxy', $port, '--path', $authpath,
 885                        '--perm', 'VM.Console', '--'];
 886             push @$cmd, @$remcmd, @$shcmd;
 887
 888             PVE::Tools::run_command($cmd);
 889         };
 890
 891         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd, 1);
 892
 893         PVE::Tools::wait_for_vnc_port($port);
 894
 895         return {
 896             user => $authuser,
 897             ticket => $ticket,
 898             port => $port,
 899             upid => $upid,
 900         };
 901     }});
 902
 903 __PACKAGE__->register_method({
 904     name => 'vncwebsocket',
 905     path => '{vmid}/vncwebsocket',
 906     method => 'GET',
 907     permissions => {
 908         description => "You also need to pass a valid ticket (vncticket).",
 909         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 910     },
 911     description => "Opens a weksocket for VNC traffic.",
 912     parameters => {
 913         additionalProperties => 0,
 914         properties => {
 915             node => get_standard_option('pve-node'),
 916             vmid => get_standard_option('pve-vmid'),
 917             vncticket => {
 918                 description => "Ticket from previous call to vncproxy.",
 919                 type => 'string',
 920                 maxLength => 512,
 921             },
 922             port => {
 923                 description => "Port number returned by previous vncproxy call.",
 924                 type => 'integer',
 925                 minimum => 5900,
 926                 maximum => 5999,
 927             },
 928         },
 929     },
 930     returns => {
 931         type => "object",
 932         properties => {
 933             port => { type => 'string' },
 934         },
 935     },
 936     code => sub {
 937         my ($param) = @_;
 938
 939         my $rpcenv = PVE::RPCEnvironment::get();
 940
 941         my $authuser = $rpcenv->get_user();
 942
 943         my $authpath = "/vms/$param->{vmid}";
 944
 945         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
 946
 947         my $port = $param->{port};
 948
 949         return { port => $port };
 950     }});
 951
 952 __PACKAGE__->register_method ({
 953     name => 'spiceproxy',
 954     path => '{vmid}/spiceproxy',
 955     method => 'POST',
 956     protected => 1,
 957     proxyto => 'node',
 958     permissions => {
 959         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 960     },
 961     description => "Returns a SPICE configuration to connect to the CT.",
 962     parameters => {
 963         additionalProperties => 0,
 964         properties => {
 965             node => get_standard_option('pve-node'),
 966             vmid => get_standard_option('pve-vmid'),
 967             proxy => get_standard_option('spice-proxy', { optional => 1 }),
 968         },
 969     },
 970     returns => get_standard_option('remote-viewer-config'),
 971     code => sub {
 972         my ($param) = @_;
 973
 974         my $vmid = $param->{vmid};
 975         my $node = $param->{node};
 976         my $proxy = $param->{proxy};
 977
 978         my $authpath = "/vms/$vmid";
 979         my $permissions = 'VM.Console';
 980
 981         my $conf = PVE::LXC::Config->load_config($vmid);
 982
 983         die "CT $vmid not running\n" if !PVE::LXC::check_running($vmid);
 984
 985         my $concmd = PVE::LXC::get_console_command($vmid, $conf);
 986
 987         my $shcmd = ['/usr/bin/dtach', '-A',
 988                      "/var/run/dtach/vzctlconsole$vmid",
 989                      '-r', 'winch', '-z', @$concmd];
 990
 991         my $title = "CT $vmid";
 992
 993         return PVE::API2Tools::run_spiceterm($authpath, $permissions, $vmid, $node, $proxy, $title, $shcmd);
 994     }});
 995
 996
 997 __PACKAGE__->register_method({
 998     name => 'migrate_vm',
 999     path => '{vmid}/migrate',
1000     method => 'POST',
1001     protected => 1,
1002     proxyto => 'node',
1003     description => "Migrate the container to another node. Creates a new migration task.",
1004     permissions => {
1005         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
1006     },
1007     parameters => {
1008         additionalProperties => 0,
1009         properties => {
1010             node => get_standard_option('pve-node'),
1011             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1012             target => get_standard_option('pve-node', {
1013                 description => "Target node.",
1014                 completion => \&PVE::Cluster::complete_migration_target,
1015             }),
1016             online => {
1017                 type => 'boolean',
1018                 description => "Use online/live migration.",
1019                 optional => 1,
1020             },
1021             restart => {
1022                 type => 'boolean',
1023                 description => "Use restart migration",
1024                 optional => 1,
1025             },
1026             timeout => {
1027                 type => 'integer',
1028                 description => "Timeout in seconds for shutdown for restart migration",
1029                 optional => 1,
1030                 default => 180,
1031             },
1032             force => {
1033                 type => 'boolean',
1034                 description => "Force migration despite local bind / device" .
1035                     " mounts. NOTE: deprecated, use 'shared' property of mount point instead.",
1036                 optional => 1,
1037             },
1038             bwlimit => {
1039                 description => "Override I/O bandwidth limit (in KiB/s).",
1040                 optional => 1,
1041                 type => 'number',
1042                 minimum => '0',
1043                 default => 'migrate limit from datacenter or storage config',
1044             },
1045         },
1046     },
1047     returns => {
1048         type => 'string',
1049         description => "the task ID.",
1050     },
1051     code => sub {
1052         my ($param) = @_;
1053
1054         my $rpcenv = PVE::RPCEnvironment::get();
1055
1056         my $authuser = $rpcenv->get_user();
1057
1058         my $target = extract_param($param, 'target');
1059
1060         my $localnode = PVE::INotify::nodename();
1061         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
1062
1063         PVE::Cluster::check_cfs_quorum();
1064
1065         PVE::Cluster::check_node_exists($target);
1066
1067         my $targetip = PVE::Cluster::remote_node_ip($target);
1068
1069         my $vmid = extract_param($param, 'vmid');
1070
1071         # test if VM exists
1072         PVE::LXC::Config->load_config($vmid);
1073
1074         # try to detect errors early
1075         if (PVE::LXC::check_running($vmid)) {
1076             die "can't migrate running container without --online or --restart\n"
1077                 if !$param->{online} && !$param->{restart};
1078         }
1079
1080         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
1081
1082             my $hacmd = sub {
1083                 my $upid = shift;
1084
1085                 my $service = "ct:$vmid";
1086
1087                 my $cmd = ['ha-manager', 'migrate', $service, $target];
1088
1089                 print "Requesting HA migration for CT $vmid to node $target\n";
1090
1091                 PVE::Tools::run_command($cmd);
1092
1093                 return;
1094             };
1095
1096             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
1097
1098         } else {
1099
1100             my $realcmd = sub {
1101                 PVE::LXC::Migrate->migrate($target, $targetip, $vmid, $param);
1102             };
1103
1104             my $worker = sub {
1105                 return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $realcmd);
1106             };
1107
1108             return $rpcenv->fork_worker('vzmigrate', $vmid, $authuser, $worker);
1109         }
1110     }});
1111
1112 __PACKAGE__->register_method({
1113     name => 'vm_feature',
1114     path => '{vmid}/feature',
1115     method => 'GET',
1116     proxyto => 'node',
1117     protected => 1,
1118     description => "Check if feature for virtual machine is available.",
1119     permissions => {
1120         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1121     },
1122     parameters => {
1123         additionalProperties => 0,
1124         properties => {
1125             node => get_standard_option('pve-node'),
1126             vmid => get_standard_option('pve-vmid'),
1127             feature => {
1128                 description => "Feature to check.",
1129                 type => 'string',
1130                 enum => [ 'snapshot', 'clone', 'copy' ],
1131             },
1132             snapname => get_standard_option('pve-snapshot-name', {
1133                 optional => 1,
1134             }),
1135         },
1136     },
1137     returns => {
1138         type => "object",
1139         properties => {
1140             hasFeature => { type => 'boolean' },
1141             #nodes => {
1142                 #type => 'array',
1143                 #items => { type => 'string' },
1144             #}
1145         },
1146     },
1147     code => sub {
1148         my ($param) = @_;
1149
1150         my $node = extract_param($param, 'node');
1151
1152         my $vmid = extract_param($param, 'vmid');
1153
1154         my $snapname = extract_param($param, 'snapname');
1155
1156         my $feature = extract_param($param, 'feature');
1157
1158         my $conf = PVE::LXC::Config->load_config($vmid);
1159
1160         if($snapname){
1161             my $snap = $conf->{snapshots}->{$snapname};
1162             die "snapshot '$snapname' does not exist\n" if !defined($snap);
1163             $conf = $snap;
1164         }
1165         my $storage_cfg = PVE::Storage::config();
1166         #Maybe include later
1167         #my $nodelist = PVE::LXC::shared_nodes($conf, $storage_cfg);
1168         my $hasFeature = PVE::LXC::Config->has_feature($feature, $conf, $storage_cfg, $snapname);
1169
1170         return {
1171             hasFeature => $hasFeature,
1172             #nodes => [ keys %$nodelist ],
1173         };
1174     }});
1175
1176 __PACKAGE__->register_method({
1177     name => 'template',
1178     path => '{vmid}/template',
1179     method => 'POST',
1180     protected => 1,
1181     proxyto => 'node',
1182     description => "Create a Template.",
1183     permissions => {
1184         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
1185         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1186     },
1187     parameters => {
1188         additionalProperties => 0,
1189         properties => {
1190             node => get_standard_option('pve-node'),
1191             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid_stopped }),
1192         },
1193     },
1194     returns => { type => 'null'},
1195     code => sub {
1196         my ($param) = @_;
1197
1198         my $rpcenv = PVE::RPCEnvironment::get();
1199
1200         my $authuser = $rpcenv->get_user();
1201
1202         my $node = extract_param($param, 'node');
1203
1204         my $vmid = extract_param($param, 'vmid');
1205
1206         my $updatefn =  sub {
1207
1208             my $conf = PVE::LXC::Config->load_config($vmid);
1209             PVE::LXC::Config->check_lock($conf);
1210
1211             die "unable to create template, because CT contains snapshots\n"
1212                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
1213
1214             die "you can't convert a template to a template\n"
1215                 if PVE::LXC::Config->is_template($conf);
1216
1217             die "you can't convert a CT to template if the CT is running\n"
1218                 if PVE::LXC::check_running($vmid);
1219
1220             my $realcmd = sub {
1221                 PVE::LXC::template_create($vmid, $conf);
1222
1223                 $conf->{template} = 1;
1224
1225                 PVE::LXC::Config->write_config($vmid, $conf);
1226                 # and remove lxc config
1227                 PVE::LXC::update_lxc_config($vmid, $conf);
1228             };
1229
1230             return $rpcenv->fork_worker('vztemplate', $vmid, $authuser, $realcmd);
1231         };
1232
1233         PVE::LXC::Config->lock_config($vmid, $updatefn);
1234
1235         return undef;
1236     }});
1237
1238 __PACKAGE__->register_method({
1239     name => 'clone_vm',
1240     path => '{vmid}/clone',
1241     method => 'POST',
1242     protected => 1,
1243     proxyto => 'node',
1244     description => "Create a container clone/copy",
1245     permissions => {
1246         description => "You need 'VM.Clone' permissions on /vms/{vmid}, " .
1247             "and 'VM.Allocate' permissions " .
1248             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
1249             "'Datastore.AllocateSpace' on any used storage.",
1250         check =>
1251         [ 'and',
1252           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
1253           [ 'or',
1254             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
1255             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
1256           ],
1257         ]
1258     },
1259     parameters => {
1260         additionalProperties => 0,
1261         properties => {
1262             node => get_standard_option('pve-node'),
1263             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1264             newid => get_standard_option('pve-vmid', {
1265                 completion => \&PVE::Cluster::complete_next_vmid,
1266                 description => 'VMID for the clone.' }),
1267             hostname => {
1268                 optional => 1,
1269                 type => 'string', format => 'dns-name',
1270                 description => "Set a hostname for the new CT.",
1271             },
1272             description => {
1273                 optional => 1,
1274                 type => 'string',
1275                 description => "Description for the new CT.",
1276             },
1277             pool => {
1278                 optional => 1,
1279                 type => 'string', format => 'pve-poolid',
1280                 description => "Add the new CT to the specified pool.",
1281             },
1282             snapname => get_standard_option('pve-snapshot-name', {
1283                 optional => 1,
1284             }),
1285             storage => get_standard_option('pve-storage-id', {
1286                 description => "Target storage for full clone.",
1287                 optional => 1,
1288             }),
1289             full => {
1290                 optional => 1,
1291                 type => 'boolean',
1292                 description => "Create a full copy of all disks. This is always done when " .
1293                     "you clone a normal CT. For CT templates, we try to create a linked clone by default.",
1294             },
1295             target => get_standard_option('pve-node', {
1296                 description => "Target node. Only allowed if the original VM is on shared storage.",
1297                 optional => 1,
1298             }),
1299             bwlimit => {
1300                 description => "Override I/O bandwidth limit (in KiB/s).",
1301                 optional => 1,
1302                 type => 'number',
1303                 minimum => '0',
1304                 default => 'clone limit from datacenter or storage config',
1305             },
1306         },
1307     },
1308     returns => {
1309         type => 'string',
1310     },
1311     code => sub {
1312         my ($param) = @_;
1313
1314         my $rpcenv = PVE::RPCEnvironment::get();
1315
1316         my $authuser = $rpcenv->get_user();
1317
1318         my $node = extract_param($param, 'node');
1319
1320         my $vmid = extract_param($param, 'vmid');
1321
1322         my $newid = extract_param($param, 'newid');
1323
1324         my $pool = extract_param($param, 'pool');
1325
1326         if (defined($pool)) {
1327             $rpcenv->check_pool_exist($pool);
1328         }
1329
1330         my $snapname = extract_param($param, 'snapname');
1331
1332         my $storage = extract_param($param, 'storage');
1333
1334         my $target = extract_param($param, 'target');
1335
1336         my $localnode = PVE::INotify::nodename();
1337
1338         undef $target if $target && ($target eq $localnode || $target eq 'localhost');
1339
1340         PVE::Cluster::check_node_exists($target) if $target;
1341
1342         my $storecfg = PVE::Storage::config();
1343
1344         if ($storage) {
1345             # check if storage is enabled on local node
1346             PVE::Storage::storage_check_enabled($storecfg, $storage);
1347             if ($target) {
1348                 # check if storage is available on target node
1349                 PVE::Storage::storage_check_node($storecfg, $storage, $target);
1350                 # clone only works if target storage is shared
1351                 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1352                 die "can't clone to non-shared storage '$storage'\n" if !$scfg->{shared};
1353             }
1354         }
1355
1356         PVE::Cluster::check_cfs_quorum();
1357
1358         my $conffile;
1359         my $newconf = {};
1360         my $mountpoints = {};
1361         my $fullclone = {};
1362         my $vollist = [];
1363         my $running;
1364
1365         PVE::LXC::Config->lock_config($vmid, sub {
1366             my $src_conf = PVE::LXC::Config->set_lock($vmid, 'disk');
1367
1368             $running = PVE::LXC::check_running($vmid) || 0;
1369
1370             my $full = extract_param($param, 'full');
1371             if (!defined($full)) {
1372                 $full = !PVE::LXC::Config->is_template($src_conf);
1373             }
1374             die "parameter 'storage' not allowed for linked clones\n" if defined($storage) && !$full;
1375
1376             eval {
1377                 die "snapshot '$snapname' does not exist\n"
1378                     if $snapname && !defined($src_conf->{snapshots}->{$snapname});
1379
1380
1381                 my $src_conf = $snapname ? $src_conf->{snapshots}->{$snapname} : $src_conf;
1382
1383                 $conffile = PVE::LXC::Config->config_file($newid);
1384                 die "unable to create CT $newid: config file already exists\n"
1385                     if -f $conffile;
1386
1387                 my $sharedvm = 1;
1388                 foreach my $opt (keys %$src_conf) {
1389                     next if $opt =~ m/^unused\d+$/;
1390
1391                     my $value = $src_conf->{$opt};
1392
1393                     if (($opt eq 'rootfs') || ($opt =~ m/^mp\d+$/)) {
1394                         my $mp = PVE::LXC::Config->parse_volume($opt, $value);
1395
1396                         if ($mp->{type} eq 'volume') {
1397                             my $volid = $mp->{volume};
1398
1399                             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
1400                             $sid = $storage if defined($storage);
1401                             my $scfg = PVE::Storage::storage_config($storecfg, $sid);
1402                             if (!$scfg->{shared}) {
1403                                 $sharedvm = 0;
1404                                 warn "found non-shared volume: $volid\n" if $target;
1405                             }
1406
1407                             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1408
1409                             if ($full) {
1410                                 die "Cannot do full clones on a running container without snapshots\n"
1411                                     if $running && !defined($snapname);
1412                                 $fullclone->{$opt} = 1;
1413                             } else {
1414                                 # not full means clone instead of copy
1415                                 die "Linked clone feature for '$volid' is not available\n"
1416                                     if !PVE::Storage::volume_has_feature($storecfg, 'clone', $volid, $snapname, $running, {'valid_target_formats' => ['raw', 'subvol']});
1417                             }
1418
1419                             $mountpoints->{$opt} = $mp;
1420                             push @$vollist, $volid;
1421
1422                         } else {
1423                             # TODO: allow bind mounts?
1424                             die "unable to clone mountpint '$opt' (type $mp->{type})\n";
1425                         }
1426                     } elsif ($opt =~ m/^net(\d+)$/) {
1427                         # always change MAC! address
1428                         my $dc = PVE::Cluster::cfs_read_file('datacenter.cfg');
1429                         my $net = PVE::LXC::Config->parse_lxc_network($value);
1430                         $net->{hwaddr} = PVE::Tools::random_ether_addr($dc->{mac_prefix});
1431                         $newconf->{$opt} = PVE::LXC::Config->print_lxc_network($net);
1432                     } else {
1433                         # copy everything else
1434                         $newconf->{$opt} = $value;
1435                     }
1436                 }
1437                 die "can't clone CT to node '$target' (CT uses local storage)\n"
1438                     if $target && !$sharedvm;
1439
1440                 # Replace the 'disk' lock with a 'create' lock.
1441                 $newconf->{lock} = 'create';
1442
1443                 delete $newconf->{pending};
1444                 delete $newconf->{template};
1445                 if ($param->{hostname}) {
1446                     $newconf->{hostname} = $param->{hostname};
1447                 }
1448
1449                 if ($param->{description}) {
1450                     $newconf->{description} = $param->{description};
1451                 }
1452
1453                 # create empty/temp config - this fails if CT already exists on other node
1454                 PVE::LXC::Config->write_config($newid, $newconf);
1455             };
1456             if (my $err = $@) {
1457                 eval { PVE::LXC::Config->remove_lock($vmid, 'disk') };
1458                 warn $@ if $@;
1459                 die $err;
1460             }
1461         });
1462
1463         my $update_conf = sub {
1464             my ($key, $value) = @_;
1465             return PVE::LXC::Config->lock_config($newid, sub {
1466                 my $conf = PVE::LXC::Config->load_config($newid);
1467                 die "Lost 'create' config lock, aborting.\n"
1468                     if !PVE::LXC::Config->has_lock($conf, 'create');
1469                 $conf->{$key} = $value;
1470                 PVE::LXC::Config->write_config($newid, $conf);
1471             });
1472         };
1473
1474         my $realcmd = sub {
1475             my ($upid) = @_;
1476
1477             my $newvollist = [];
1478
1479             my $verify_running = PVE::LXC::check_running($vmid) || 0;
1480             die "unexpected state change\n" if $verify_running != $running;
1481
1482             eval {
1483                 local $SIG{INT} =
1484                     local $SIG{TERM} =
1485                     local $SIG{QUIT} =
1486                     local $SIG{HUP} = sub { die "interrupted by signal\n"; };
1487
1488                 PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
1489                 my $bwlimit = extract_param($param, 'bwlimit');
1490
1491                 foreach my $opt (keys %$mountpoints) {
1492                     my $mp = $mountpoints->{$opt};
1493                     my $volid = $mp->{volume};
1494
1495                     my $newvolid;
1496                     if ($fullclone->{$opt}) {
1497                         print "create full clone of mountpoint $opt ($volid)\n";
1498                         my $source_storage = PVE::Storage::parse_volume_id($volid);
1499                         my $target_storage = $storage // $source_storage;
1500                         my $clonelimit = PVE::Storage::get_bandwidth_limit('clone', [$source_storage, $target_storage], $bwlimit);
1501                         $newvolid = PVE::LXC::copy_volume($mp, $newid, $target_storage, $storecfg, $newconf, $snapname, $clonelimit);
1502                     } else {
1503                         print "create linked clone of mount point $opt ($volid)\n";
1504                         $newvolid = PVE::Storage::vdisk_clone($storecfg, $volid, $newid, $snapname);
1505                     }
1506
1507                     push @$newvollist, $newvolid;
1508                     $mp->{volume} = $newvolid;
1509
1510                     $update_conf->($opt, PVE::LXC::Config->print_ct_mountpoint($mp, $opt eq 'rootfs'));
1511                 }
1512
1513                 PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
1514                 PVE::LXC::Config->remove_lock($newid, 'create');
1515
1516                 if ($target) {
1517                     # always deactivate volumes - avoid lvm LVs to be active on several nodes
1518                     PVE::Storage::deactivate_volumes($storecfg, $vollist, $snapname) if !$running;
1519                     PVE::Storage::deactivate_volumes($storecfg, $newvollist);
1520
1521                     my $newconffile = PVE::LXC::Config->config_file($newid, $target);
1522                     die "Failed to move config to node '$target' - rename failed: $!\n"
1523                         if !rename($conffile, $newconffile);
1524                 }
1525             };
1526             my $err = $@;
1527
1528             # Unlock the source config in any case:
1529             eval { PVE::LXC::Config->remove_lock($vmid, 'disk') };
1530             warn $@ if $@;
1531
1532             if ($err) {
1533                 # Now cleanup the config & disks:
1534                 unlink $conffile;
1535
1536                 sleep 1; # some storages like rbd need to wait before release volume - really?
1537
1538                 foreach my $volid (@$newvollist) {
1539                     eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1540                     warn $@ if $@;
1541                 }
1542                 die "clone failed: $err";
1543             }
1544
1545             return;
1546         };
1547
1548         PVE::Firewall::clone_vmfw_conf($vmid, $newid);
1549         return $rpcenv->fork_worker('vzclone', $vmid, $authuser, $realcmd);
1550     }});
1551
1552
1553 __PACKAGE__->register_method({
1554     name => 'resize_vm',
1555     path => '{vmid}/resize',
1556     method => 'PUT',
1557     protected => 1,
1558     proxyto => 'node',
1559     description => "Resize a container mount point.",
1560     permissions => {
1561         check => ['perm', '/vms/{vmid}', ['VM.Config.Disk'], any => 1],
1562     },
1563     parameters => {
1564         additionalProperties => 0,
1565         properties => {
1566             node => get_standard_option('pve-node'),
1567             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1568             disk => {
1569                 type => 'string',
1570                 description => "The disk you want to resize.",
1571                 enum => [PVE::LXC::Config->valid_volume_keys()],
1572             },
1573             size => {
1574                 type => 'string',
1575                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
1576                 description => "The new size. With the '+' sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
1577             },
1578             digest => {
1579                 type => 'string',
1580                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1581                 maxLength => 40,
1582                 optional => 1,
1583             }
1584         },
1585     },
1586     returns => {
1587         type => 'string',
1588         description => "the task ID.",
1589     },
1590     code => sub {
1591         my ($param) = @_;
1592
1593         my $rpcenv = PVE::RPCEnvironment::get();
1594
1595         my $authuser = $rpcenv->get_user();
1596
1597         my $node = extract_param($param, 'node');
1598
1599         my $vmid = extract_param($param, 'vmid');
1600
1601         my $digest = extract_param($param, 'digest');
1602
1603         my $sizestr = extract_param($param, 'size');
1604         my $ext = ($sizestr =~ s/^\+//);
1605         my $newsize = PVE::JSONSchema::parse_size($sizestr);
1606         die "invalid size string" if !defined($newsize);
1607
1608         die "no options specified\n" if !scalar(keys %$param);
1609
1610         PVE::LXC::check_ct_modify_config_perm($rpcenv, $authuser, $vmid, undef, $param, []);
1611
1612         my $storage_cfg = cfs_read_file("storage.cfg");
1613
1614         my $code = sub {
1615
1616             my $conf = PVE::LXC::Config->load_config($vmid);
1617             PVE::LXC::Config->check_lock($conf);
1618
1619             PVE::Tools::assert_if_modified($digest, $conf->{digest});
1620
1621             my $running = PVE::LXC::check_running($vmid);
1622
1623             my $disk = $param->{disk};
1624             my $mp = PVE::LXC::Config->parse_volume($disk, $conf->{$disk});
1625
1626             my $volid = $mp->{volume};
1627
1628             my (undef, undef, $owner, undef, undef, undef, $format) =
1629                 PVE::Storage::parse_volname($storage_cfg, $volid);
1630
1631             die "can't resize mount point owned by another container ($owner)"
1632                 if $vmid != $owner;
1633
1634             die "can't resize volume: $disk if snapshot exists\n"
1635                 if %{$conf->{snapshots}} && $format eq 'qcow2';
1636
1637             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
1638
1639             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
1640
1641             PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1642
1643             my $size = PVE::Storage::volume_size_info($storage_cfg, $volid, 5);
1644
1645             die "Could not determine current size of volume '$volid'\n" if !defined($size);
1646
1647             $newsize += $size if $ext;
1648             $newsize = int($newsize);
1649
1650             die "unable to shrink disk size\n" if $newsize < $size;
1651
1652             return if $size == $newsize;
1653
1654             PVE::Cluster::log_msg('info', $authuser, "update CT $vmid: resize --disk $disk --size $sizestr");
1655             my $realcmd = sub {
1656                 # Note: PVE::Storage::volume_resize doesn't do anything if $running=1, so
1657                 # we pass 0 here (parameter only makes sense for qemu)
1658                 PVE::Storage::volume_resize($storage_cfg, $volid, $newsize, 0);
1659
1660                 $mp->{size} = $newsize;
1661                 $conf->{$disk} = PVE::LXC::Config->print_ct_mountpoint($mp, $disk eq 'rootfs');
1662
1663                 PVE::LXC::Config->write_config($vmid, $conf);
1664
1665                 if ($format eq 'raw') {
1666                     # we need to ensure that the volume is mapped, if not needed this is a NOP
1667                     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1668                     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1669                     if ($running) {
1670
1671                         $mp->{mp} = '/';
1672                         my $use_loopdev = (PVE::LXC::mountpoint_mount_path($mp, $storage_cfg))[1];
1673                         $path = PVE::LXC::query_loopdev($path) if $use_loopdev;
1674                         die "internal error: CT running but mount point not attached to a loop device"
1675                             if !$path;
1676                         PVE::Tools::run_command(['losetup', '--set-capacity', $path]) if $use_loopdev;
1677
1678                         # In order for resize2fs to know that we need online-resizing a mountpoint needs
1679                         # to be visible to it in its namespace.
1680                         # To not interfere with the rest of the system we unshare the current mount namespace,
1681                         # mount over /tmp and then run resize2fs.
1682
1683                         # interestingly we don't need to e2fsck on mounted systems...
1684                         my $quoted = PVE::Tools::shellquote($path);
1685                         my $cmd = "mount --make-rprivate / && mount $quoted /tmp && resize2fs $quoted";
1686                         eval {
1687                             PVE::Tools::run_command(['unshare', '-m', '--', 'sh', '-c', $cmd]);
1688                         };
1689                         warn "Failed to update the container's filesystem: $@\n" if $@;
1690                     } else {
1691                         eval {
1692                             PVE::Tools::run_command(['e2fsck', '-f', '-y', $path]);
1693                             PVE::Tools::run_command(['resize2fs', $path]);
1694                         };
1695                         warn "Failed to update the container's filesystem: $@\n" if $@;
1696
1697                         # always un-map if not running, this is a NOP if not needed
1698                         PVE::Storage::unmap_volume($storage_cfg, $volid);
1699                     }
1700                 }
1701             };
1702
1703             return $rpcenv->fork_worker('resize', $vmid, $authuser, $realcmd);
1704         };
1705
1706         return PVE::LXC::Config->lock_config($vmid, $code);;
1707     }});
1708
1709 __PACKAGE__->register_method({
1710     name => 'move_volume',
1711     path => '{vmid}/move_volume',
1712     method => 'POST',
1713     protected => 1,
1714     proxyto => 'node',
1715     description => "Move a rootfs-/mp-volume to a different storage",
1716     permissions => {
1717         description => "You need 'VM.Config.Disk' permissions on /vms/{vmid}, " .
1718             "and 'Datastore.AllocateSpace' permissions on the storage.",
1719         check =>
1720         [ 'and',
1721           ['perm', '/vms/{vmid}', [ 'VM.Config.Disk' ]],
1722           ['perm', '/storage/{storage}', [ 'Datastore.AllocateSpace' ]],
1723         ],
1724     },
1725     parameters => {
1726         additionalProperties => 0,
1727         properties => {
1728             node => get_standard_option('pve-node'),
1729             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1730             volume => {
1731                 type => 'string',
1732                 enum => [ PVE::LXC::Config->valid_volume_keys() ],
1733                 description => "Volume which will be moved.",
1734             },
1735             storage => get_standard_option('pve-storage-id', {
1736                 description => "Target Storage.",
1737                 completion => \&PVE::Storage::complete_storage_enabled,
1738             }),
1739             delete => {
1740                 type => 'boolean',
1741                 description => "Delete the original volume after successful copy. By default the original is kept as an unused volume entry.",
1742                 optional => 1,
1743                 default => 0,
1744             },
1745             digest => {
1746                 type => 'string',
1747                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1748                 maxLength => 40,
1749                 optional => 1,
1750             },
1751             bwlimit => {
1752                 description => "Override I/O bandwidth limit (in KiB/s).",
1753                 optional => 1,
1754                 type => 'number',
1755                 minimum => '0',
1756                 default => 'clone limit from datacenter or storage config',
1757             },
1758         },
1759     },
1760     returns => {
1761         type => 'string',
1762     },
1763     code => sub {
1764         my ($param) = @_;
1765
1766         my $rpcenv = PVE::RPCEnvironment::get();
1767
1768         my $authuser = $rpcenv->get_user();
1769
1770         my $vmid = extract_param($param, 'vmid');
1771
1772         my $storage = extract_param($param, 'storage');
1773
1774         my $mpkey = extract_param($param, 'volume');
1775
1776         my $lockname = 'disk';
1777
1778         my ($mpdata, $old_volid);
1779
1780         PVE::LXC::Config->lock_config($vmid, sub {
1781             my $conf = PVE::LXC::Config->load_config($vmid);
1782             PVE::LXC::Config->check_lock($conf);
1783
1784             die "cannot move volumes of a running container\n" if PVE::LXC::check_running($vmid);
1785
1786             PVE::LXC::Config->parse_volume($mpkey, $conf->{$mpkey});
1787             $old_volid = $mpdata->{volume};
1788
1789             die "you can't move a volume with snapshots and delete the source\n"
1790                 if $param->{delete} && PVE::LXC::Config->is_volume_in_use_by_snapshots($conf, $old_volid);
1791
1792             PVE::Tools::assert_if_modified($param->{digest}, $conf->{digest});
1793
1794             PVE::LXC::Config->set_lock($vmid, $lockname);
1795         });
1796
1797         my $realcmd = sub {
1798             eval {
1799                 PVE::Cluster::log_msg('info', $authuser, "move volume CT $vmid: move --volume $mpkey --storage $storage");
1800
1801                 my $conf = PVE::LXC::Config->load_config($vmid);
1802                 my $storage_cfg = PVE::Storage::config();
1803
1804                 my $new_volid;
1805
1806                 eval {
1807                     PVE::Storage::activate_volumes($storage_cfg, [ $old_volid ]);
1808                     my $bwlimit = extract_param($param, 'bwlimit');
1809                     my $source_storage = PVE::Storage::parse_volume_id($old_volid);
1810                     my $movelimit = PVE::Storage::get_bandwidth_limit('move', [$source_storage, $storage], $bwlimit);
1811                     $new_volid = PVE::LXC::copy_volume($mpdata, $vmid, $storage, $storage_cfg, $conf, undef, $movelimit);
1812                     if (PVE::LXC::Config->is_template($conf)) {
1813                         PVE::Storage::activate_volumes($storage_cfg, [ $new_volid ]);
1814                         my $template_volid = PVE::Storage::vdisk_create_base($storage_cfg, $new_volid);
1815                         $mpdata->{volume} = $template_volid;
1816                     } else {
1817                         $mpdata->{volume} = $new_volid;
1818                     }
1819
1820                     PVE::LXC::Config->lock_config($vmid, sub {
1821                         my $digest = $conf->{digest};
1822                         $conf = PVE::LXC::Config->load_config($vmid);
1823                         PVE::Tools::assert_if_modified($digest, $conf->{digest});
1824
1825                         $conf->{$mpkey} = PVE::LXC::Config->print_ct_mountpoint($mpdata, $mpkey eq 'rootfs');
1826
1827                         PVE::LXC::Config->add_unused_volume($conf, $old_volid) if !$param->{delete};
1828
1829                         PVE::LXC::Config->write_config($vmid, $conf);
1830                     });
1831
1832                     eval {
1833                         # try to deactivate volumes - avoid lvm LVs to be active on several nodes
1834                         PVE::Storage::deactivate_volumes($storage_cfg, [ $new_volid ])
1835                     };
1836                     warn $@ if $@;
1837                 };
1838                 if (my $err = $@) {
1839                     eval {
1840                         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
1841                             if defined($new_volid);
1842                     };
1843                     warn $@ if $@;
1844                     die $err;
1845                 }
1846
1847                 if ($param->{delete}) {
1848                     eval {
1849                         PVE::Storage::deactivate_volumes($storage_cfg, [ $old_volid ]);
1850                         PVE::Storage::vdisk_free($storage_cfg, $old_volid);
1851                     };
1852                     if (my $err = $@) {
1853                         warn $err;
1854                         PVE::LXC::Config->lock_config($vmid, sub {
1855                             my $conf = PVE::LXC::Config->load_config($vmid);
1856                             PVE::LXC::Config->add_unused_volume($conf, $old_volid);
1857                             PVE::LXC::Config->write_config($vmid, $conf);
1858                         });
1859                     }
1860                 }
1861             };
1862             my $err = $@;
1863             eval { PVE::LXC::Config->remove_lock($vmid, $lockname) };
1864             warn $@ if $@;
1865             die $err if $err;
1866         };
1867         my $task = eval {
1868             $rpcenv->fork_worker('move_volume', $vmid, $authuser, $realcmd);
1869         };
1870         if (my $err = $@) {
1871             eval { PVE::LXC::Config->remove_lock($vmid, $lockname) };
1872             warn $@ if $@;
1873             die $err;
1874         }
1875         return $task;
1876   }});
1877
1878 __PACKAGE__->register_method({
1879     name => 'vm_pending',
1880     path => '{vmid}/pending',
1881     method => 'GET',
1882     proxyto => 'node',
1883     description => 'Get container configuration, including pending changes.',
1884     permissions => {
1885         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1886     },
1887     parameters => {
1888         additionalProperties => 0,
1889         properties => {
1890             node => get_standard_option('pve-node'),
1891             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1892         },
1893     },
1894     returns => {
1895         type => "array",
1896         items => {
1897             type => "object",
1898             properties => {
1899                 key => {
1900                     description => 'Configuration option name.',
1901                     type => 'string',
1902                 },
1903                 value => {
1904                     description => 'Current value.',
1905                     type => 'string',
1906                     optional => 1,
1907                 },
1908                 pending => {
1909                     description => 'Pending value.',
1910                     type => 'string',
1911                     optional => 1,
1912                 },
1913                 delete => {
1914                     description => "Indicates a pending delete request if present and not 0.",
1915                     type => 'integer',
1916                     minimum => 0,
1917                     maximum => 2,
1918                     optional => 1,
1919                 },
1920             },
1921         },
1922     },
1923     code => sub {
1924         my ($param) = @_;
1925
1926         my $conf = PVE::LXC::Config->load_config($param->{vmid});
1927
1928         my $pending_delete_hash = PVE::LXC::Config->parse_pending_delete($conf->{pending}->{delete});
1929
1930         return PVE::GuestHelpers::config_with_pending_array($conf, $pending_delete_hash);
1931     }});
1932
1933 1;