]> git.proxmox.com Git - pve-container.git/blob - src/PVE/LXC.pm
add mknod feature flag
[pve-container.git] / src / PVE / LXC.pm
1 package PVE::LXC;
2
3 use strict;
4 use warnings;
5
6 use POSIX qw(EINTR);
7
8 use Socket;
9
10 use File::Path;
11 use File::Spec;
12 use Cwd qw();
13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
15 use IO::Socket::UNIX;
16
17 use PVE::Exception qw(raise_perm_exc);
18 use PVE::Storage;
19 use PVE::SafeSyslog;
20 use PVE::INotify;
21 use PVE::JSONSchema qw(get_standard_option);
22 use PVE::Tools qw(
23 dir_glob_foreach file_get_contents file_set_contents lock_file
24 lock_file_full AT_FDCWD O_PATH $IPV4RE $IPV6RE
25 );
26 use PVE::CpuSet;
27 use PVE::Network;
28 use PVE::AccessControl;
29 use PVE::ProcFSTools;
30 use PVE::Syscall qw(:fsmount);
31 use PVE::LXC::Config;
32 use PVE::GuestHelpers;
33 use PVE::LXC::Tools;
34
35 use Time::HiRes qw (gettimeofday);
36
37 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
38
39 my $nodename = PVE::INotify::nodename();
40
41 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
42
43 sub config_list {
44 my $vmlist = PVE::Cluster::get_vmlist();
45 my $res = {};
46 return $res if !$vmlist || !$vmlist->{ids};
47 my $ids = $vmlist->{ids};
48
49 foreach my $vmid (keys %$ids) {
50 next if !$vmid; # skip CT0
51 my $d = $ids->{$vmid};
52 next if !$d->{node} || $d->{node} ne $nodename;
53 next if !$d->{type} || $d->{type} ne 'lxc';
54 $res->{$vmid} = { type => 'lxc', vmid => $vmid };
55 }
56 return $res;
57 }
58
59 # container status helpers
60
61 sub list_active_containers {
62
63 my $filename = "/proc/net/unix";
64
65 # similar test is used by lcxcontainers.c: list_active_containers
66 my $res = {};
67
68 my $fh = IO::File->new ($filename, "r");
69 return $res if !$fh;
70
71 while (defined(my $line = <$fh>)) {
72 if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
73 my $path = $1;
74 if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
75 $res->{$1} = 1;
76 }
77 }
78 }
79
80 close($fh);
81
82 return $res;
83 }
84
85 # warning: this is slow
86 sub check_running {
87 my ($vmid) = @_;
88
89 my $active_hash = list_active_containers();
90
91 return 1 if defined($active_hash->{$vmid});
92
93 return undef;
94 }
95
96 sub get_container_disk_usage {
97 my ($vmid, $pid) = @_;
98
99 return PVE::Tools::df("/proc/$pid/root/", 1);
100 }
101
102 my $last_proc_vmid_stat;
103
104 my $parse_cpuacct_stat = sub {
105 my ($vmid, $unprivileged) = @_;
106
107 my $raw = read_cgroup_value('cpuacct', $vmid, $unprivileged, 'cpuacct.stat', 1);
108
109 my $stat = {};
110
111 if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
112
113 $stat->{utime} = $1;
114 $stat->{stime} = $2;
115
116 }
117
118 return $stat;
119 };
120
121 our $vmstatus_return_properties = {
122 vmid => get_standard_option('pve-vmid'),
123 status => {
124 description => "LXC Container status.",
125 type => 'string',
126 enum => ['stopped', 'running'],
127 },
128 maxmem => {
129 description => "Maximum memory in bytes.",
130 type => 'integer',
131 optional => 1,
132 renderer => 'bytes',
133 },
134 maxswap => {
135 description => "Maximum SWAP memory in bytes.",
136 type => 'integer',
137 optional => 1,
138 renderer => 'bytes',
139 },
140 maxdisk => {
141 description => "Root disk size in bytes.",
142 type => 'integer',
143 optional => 1,
144 renderer => 'bytes',
145 },
146 name => {
147 description => "Container name.",
148 type => 'string',
149 optional => 1,
150 },
151 uptime => {
152 description => "Uptime.",
153 type => 'integer',
154 optional => 1,
155 renderer => 'duration',
156 },
157 cpus => {
158 description => "Maximum usable CPUs.",
159 type => 'number',
160 optional => 1,
161 },
162 lock => {
163 description => "The current config lock, if any.",
164 type => 'string',
165 optional => 1,
166 },
167 tags => {
168 description => "The current configured tags, if any.",
169 type => 'string',
170 optional => 1,
171 }
172 };
173
174 sub vmstatus {
175 my ($opt_vmid) = @_;
176
177 my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
178
179 my $active_hash = list_active_containers();
180
181 my $cpucount = $cpuinfo->{cpus} || 1;
182
183 my $cdtime = gettimeofday;
184
185 my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
186 my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
187
188 my $unprivileged = {};
189
190 foreach my $vmid (keys %$list) {
191 my $d = $list->{$vmid};
192
193 eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
194 warn $@ if $@; # ignore errors (consider them stopped)
195
196 $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
197
198 my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
199 my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
200
201 $unprivileged->{$vmid} = $conf->{unprivileged};
202
203 $d->{name} = $conf->{'hostname'} || "CT$vmid";
204 $d->{name} =~ s/[\s]//g;
205
206 $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
207 $d->{cpus} = $cpucount if !$d->{cpus};
208
209 $d->{lock} = $conf->{lock} || '';
210 $d->{tags} = $conf->{tags} if defined($conf->{tags});
211
212 if ($d->{pid}) {
213 my $res = get_container_disk_usage($vmid, $d->{pid});
214 $d->{disk} = $res->{used};
215 $d->{maxdisk} = $res->{total};
216 } else {
217 $d->{disk} = 0;
218 # use 4GB by default ??
219 if (my $rootfs = $conf->{rootfs}) {
220 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
221 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
222 } else {
223 $d->{maxdisk} = 4*1024*1024*1024;
224 }
225 }
226
227 $d->{mem} = 0;
228 $d->{swap} = 0;
229 $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
230 $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
231
232 $d->{uptime} = 0;
233 $d->{cpu} = 0;
234
235 $d->{netout} = 0;
236 $d->{netin} = 0;
237
238 $d->{diskread} = 0;
239 $d->{diskwrite} = 0;
240
241 $d->{template} = PVE::LXC::Config->is_template($conf);
242 $d->{lock} = $conf->{lock} if $conf->{lock};
243 }
244
245 foreach my $vmid (keys %$list) {
246 my $d = $list->{$vmid};
247 my $pid = $d->{pid};
248
249 next if !$pid; # skip stopped CTs
250
251 my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
252 $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
253
254 my $unpriv = $unprivileged->{$vmid};
255
256 if (-d '/sys/fs/cgroup/memory') {
257 my $memory_stat = read_cgroup_list('memory', $vmid, $unpriv, 'memory.stat');
258 my $mem_usage_in_bytes = read_cgroup_value('memory', $vmid, $unpriv, 'memory.usage_in_bytes');
259
260 $d->{mem} = $mem_usage_in_bytes - $memory_stat->{total_cache};
261 $d->{swap} = read_cgroup_value('memory', $vmid, $unpriv, 'memory.memsw.usage_in_bytes') - $mem_usage_in_bytes;
262 } else {
263 $d->{mem} = 0;
264 $d->{swap} = 0;
265 }
266
267 if (-d '/sys/fs/cgroup/blkio') {
268 my $blkio_bytes = read_cgroup_value('blkio', $vmid, 0, 'blkio.throttle.io_service_bytes', 1); # don't check if unpriv
269 my @bytes = split(/\n/, $blkio_bytes);
270 foreach my $byte (@bytes) {
271 if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
272 $d->{diskread} += $2 if $key eq 'Read';
273 $d->{diskwrite} += $2 if $key eq 'Write';
274 }
275 }
276 } else {
277 $d->{diskread} = 0;
278 $d->{diskwrite} = 0;
279 }
280
281 if (-d '/sys/fs/cgroup/cpuacct') {
282 my $pstat = $parse_cpuacct_stat->($vmid, $unpriv);
283
284 my $used = $pstat->{utime} + $pstat->{stime};
285
286 my $old = $last_proc_vmid_stat->{$vmid};
287 if (!$old) {
288 $last_proc_vmid_stat->{$vmid} = {
289 time => $cdtime,
290 used => $used,
291 cpu => 0,
292 };
293 next;
294 }
295
296 my $dtime = ($cdtime - $old->{time}) * $cpucount * $cpuinfo->{user_hz};
297
298 if ($dtime > 1000) {
299 my $dutime = $used - $old->{used};
300
301 $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
302 $last_proc_vmid_stat->{$vmid} = {
303 time => $cdtime,
304 used => $used,
305 cpu => $d->{cpu},
306 };
307 } else {
308 $d->{cpu} = $old->{cpu};
309 }
310 } else {
311 $d->{cpu} = 0;
312 }
313 }
314
315 my $netdev = PVE::ProcFSTools::read_proc_net_dev();
316
317 foreach my $dev (keys %$netdev) {
318 next if $dev !~ m/^veth([1-9]\d*)i/;
319 my $vmid = $1;
320 my $d = $list->{$vmid};
321
322 next if !$d;
323
324 $d->{netout} += $netdev->{$dev}->{receive};
325 $d->{netin} += $netdev->{$dev}->{transmit};
326
327 }
328
329 return $list;
330 }
331
332 sub read_cgroup_list($$$$) {
333 my ($group, $vmid, $unprivileged, $name) = @_;
334
335 my $content = read_cgroup_value($group, $vmid, $unprivileged, $name, 1);
336
337 return { split(/\s+/, $content) };
338 }
339
340 sub read_cgroup_value($$$$$) {
341 my ($group, $vmid, $unprivileged, $name, $full) = @_;
342
343 my $nsdir = $unprivileged ? '' : 'ns/';
344 my $path = "/sys/fs/cgroup/$group/lxc/$vmid/${nsdir}$name";
345
346 return PVE::Tools::file_get_contents($path) if $full;
347
348 return PVE::Tools::file_read_firstline($path);
349 }
350
351 sub write_cgroup_value {
352 my ($group, $vmid, $name, $value) = @_;
353
354 my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
355 PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
356
357 }
358
359 sub find_lxc_console_pids {
360
361 my $res = {};
362
363 PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
364 my ($pid) = @_;
365
366 my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
367 return if !$cmdline;
368
369 my @args = split(/\0/, $cmdline);
370
371 # search for lxc-console -n <vmid>
372 return if scalar(@args) != 3;
373 return if $args[1] ne '-n';
374 return if $args[2] !~ m/^\d+$/;
375 return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
376
377 my $vmid = $args[2];
378
379 push @{$res->{$vmid}}, $pid;
380 });
381
382 return $res;
383 }
384
385 sub find_lxc_pid {
386 my ($vmid) = @_;
387
388 my $pid = undef;
389 my $parser = sub {
390 my $line = shift;
391 $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
392 };
393 PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
394
395 die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
396
397 return $pid;
398 }
399
400 sub open_pid_fd($) {
401 my ($pid) = @_;
402 sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
403 or die "failed to open /proc/$pid pid fd\n";
404 return $fd;
405 }
406
407 sub open_lxc_pid {
408 my ($vmid) = @_;
409
410 # Find the pid and open:
411 my $pid = find_lxc_pid($vmid);
412 my $fd = open_pid_fd($pid);
413
414 # Verify:
415 my $pid2 = find_lxc_pid($vmid);
416
417 return () if $pid != $pid2;
418 return ($pid, $fd);
419 }
420
421 sub open_ppid {
422 my ($pid) = @_;
423
424 # Find the parent pid via proc and open it:
425 my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
426 my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
427
428 my $fd = open_pid_fd($ppid);
429
430 # Verify:
431 $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
432 my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
433
434 return () if $ppid != $ppid2;
435 return ($ppid, $fd);
436 }
437
438 # Note: we cannot use Net:IP, because that only allows strict
439 # CIDR networks
440 sub parse_ipv4_cidr {
441 my ($cidr, $noerr) = @_;
442
443 if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) && ($2 <= 32)) {
444 return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
445 }
446
447 return undef if $noerr;
448
449 die "unable to parse ipv4 address/mask\n";
450 }
451
452 sub get_cgroup_subsystems {
453 my $v1 = {};
454 my $v2 = 0;
455 my $data = PVE::Tools::file_get_contents('/proc/self/cgroup');
456 while ($data =~ /^\d+:([^:\n]*):.*$/gm) {
457 my $type = $1;
458 if (length($type)) {
459 $v1->{$_} = 1 foreach split(/,/, $type);
460 } else {
461 $v2 = 1;
462 }
463 }
464 return wantarray ? ($v1, $v2) : $v1;
465 }
466
467 # With seccomp trap to userspace we now have the ability to optionally forward
468 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
469 #
470 # This means that there are cases where we need to create an extra seccomp
471 # profile for the container to load.
472 #
473 # This returns a configuration snippet added to the raw lxc config.
474 sub make_seccomp_config {
475 my ($conf, $conf_dir, $unprivileged, $features) = @_;
476 # User-configured profile has precedence, note that the user's entry would
477 # be written 'after' this line anyway...
478 if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
479 # Warn the user if this conflicts with a feature:
480 my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
481 warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
482 if length($warn) > 0;
483 return '';
484 }
485
486 # Privileged containers keep using the default (which is already part of
487 # the files included via lxc.include, so we don't need to write it out,
488 # that way it stays admin-configurable via /usr/share/lxc/config/... as
489 # well)
490 return '' if !$unprivileged;
491
492 my $rules = {
493 keyctl => ['errno 38'],
494 };
495
496 my $raw_conf = '';
497
498 # Unprivileged containers will get keyctl() disabled by default as a
499 # workaround for systemd-networkd behavior. But we have an option to
500 # explicitly enable it:
501 if ($features->{keyctl}) {
502 delete $rules->{keyctl};
503 }
504
505 # By default, unprivileged containers cannot use `mknod` at all.
506 # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
507 # but for now this is experimental, so it has to be enabled via a feature
508 # flag.
509 # Note that we only handle block and char devices (like lxd), the rest we
510 # leave up to the kernel. We may in the future remove this if seccomp gets
511 # a way to tell the kernel to "continue" a syscall.
512 if ($features->{mknod}) {
513 $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
514
515 $rules->{mknod} = [
516 # condition: (mode & S_IFMT) == S_IFCHR
517 'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
518 # condition: (mode & S_IFMT) == S_IFBLK
519 'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
520 ];
521 $rules->{mknodat} = [
522 # condition: (mode & S_IFMT) == S_IFCHR
523 'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
524 # condition: (mode & S_IFMT) == S_IFBLK
525 'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
526 ];
527 }
528
529 # Now build the custom seccomp rule text...
530 my $extra_rules = join("\n", map {
531 my $syscall = $_;
532 map { "$syscall $_" } $rules->{$syscall}->@*
533 } sort keys %$rules) . "\n";
534
535 return $raw_conf if $extra_rules eq "\n";
536
537 # We still have the "most common" config readily available, so don't write
538 # out that one:
539 if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
540 # we have no extra $raw_conf and use the same we had in pve 6.1:
541 return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
542 }
543
544 # Write the rule file to the container's config path:
545 my $rule_file = "$conf_dir/rules.seccomp";
546 my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
547 . $extra_rules;
548 file_set_contents($rule_file, $rule_data);
549 $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
550
551 return $raw_conf;
552 }
553
554 # Since lxc-3.0.2 we can have lxc generate a profile for the container
555 # automatically. The default should be equivalent to the old
556 # `lxc-container-default-cgns` profile.
557 #
558 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
559 # additional lines into the profile. We can use that to allow mounting specific
560 # file systems.
561 sub make_apparmor_config {
562 my ($conf, $unprivileged, $features) = @_;
563
564 # user-configured profile has precedence, but first we go through our own
565 # code to figure out whether we should warn the user:
566
567 my $raw = "lxc.apparmor.profile = generated\n";
568 my @profile_uses;
569
570 if ($features->{fuse}) {
571 # For the informational warning:
572 push @profile_uses, 'features:fuse';
573 }
574
575 # There's lxc.apparmor.allow_nesting now, which will add the necessary
576 # apparmor lines, create an apparmor namespace for the container, but also
577 # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
578 # lxcfs mounted over them, because that would prevent the container from
579 # mounting new instances of them for nested containers.
580 if ($features->{nesting}) {
581 push @profile_uses, 'features:nesting';
582 $raw .= "lxc.apparmor.allow_nesting = 1\n"
583 } else {
584 # In the default profile in /etc/apparmor.d we patch this in because
585 # otherwise a container can for example run `chown` on /sys, breaking
586 # access to it for non-CAP_DAC_OVERRIDE tools on the host:
587 $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
588 $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
589 # Preferably we could use the 'remount' flag but this does not sit well
590 # with apparmor_parser currently:
591 # mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
592 }
593
594 if (my $mount = $features->{mount}) {
595 push @profile_uses, 'features:mount';
596 foreach my $fs (PVE::Tools::split_list($mount)) {
597 $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
598 }
599 }
600
601 # More to come?
602
603 if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
604 if (length(my $used = join(', ', @profile_uses))) {
605 warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
606 }
607 return '';
608 }
609
610 return $raw;
611 }
612
613 sub update_lxc_config {
614 my ($vmid, $conf) = @_;
615
616 my $dir = "/var/lib/lxc/$vmid";
617
618 if ($conf->{template}) {
619
620 unlink "$dir/config";
621
622 return;
623 }
624
625 my $raw = '';
626
627 die "missing 'arch' - internal error" if !$conf->{arch};
628 $raw .= "lxc.arch = $conf->{arch}\n";
629
630 my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
631 my $unprivileged = $conf->{unprivileged} || $custom_idmap;
632
633 my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
634
635 my $cfgpath = '/usr/share/lxc/config';
636 my $inc = "$cfgpath/$ostype.common.conf";
637 $inc ="$cfgpath/common.conf" if !-f $inc;
638 $raw .= "lxc.include = $inc\n";
639 if ($unprivileged) {
640 $inc = "$cfgpath/$ostype.userns.conf";
641 $inc = "$cfgpath/userns.conf" if !-f $inc;
642 $raw .= "lxc.include = $inc\n";
643 }
644
645 my $features = PVE::LXC::Config->parse_features($conf->{features});
646
647 $raw .= make_seccomp_config($conf, $dir, $unprivileged, $features);
648 $raw .= make_apparmor_config($conf, $unprivileged, $features);
649 if ($features->{fuse}) {
650 $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
651 $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
652 }
653
654 # WARNING: DO NOT REMOVE this without making sure that loop device nodes
655 # cannot be exposed to the container with r/w access (cgroup perms).
656 # When this is enabled mounts will still remain in the monitor's namespace
657 # after the container unmounted them and thus will not detach from their
658 # files while the container is running!
659 $raw .= "lxc.monitor.unshare = 1\n";
660
661 my $cgv1 = get_cgroup_subsystems();
662
663 # Should we read them from /etc/subuid?
664 if ($unprivileged && !$custom_idmap) {
665 $raw .= "lxc.idmap = u 0 100000 65536\n";
666 $raw .= "lxc.idmap = g 0 100000 65536\n";
667 }
668
669 if (!PVE::LXC::Config->has_dev_console($conf)) {
670 $raw .= "lxc.console.path = none\n";
671 $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
672 }
673
674 my $ttycount = PVE::LXC::Config->get_tty_count($conf);
675 $raw .= "lxc.tty.max = $ttycount\n";
676
677 # some init scripts expect a linux terminal (turnkey).
678 $raw .= "lxc.environment = TERM=linux\n";
679
680 my $utsname = $conf->{hostname} || "CT$vmid";
681 $raw .= "lxc.uts.name = $utsname\n";
682
683 if ($cgv1->{memory}) {
684 my $memory = $conf->{memory} || 512;
685 my $swap = $conf->{swap} // 0;
686
687 my $lxcmem = int($memory*1024*1024);
688 $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
689
690 my $lxcswap = int(($memory + $swap)*1024*1024);
691 $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
692 }
693
694 if ($cgv1->{cpu}) {
695 if (my $cpulimit = $conf->{cpulimit}) {
696 $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
697 my $value = int(100000*$cpulimit);
698 $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
699 }
700
701 my $shares = $conf->{cpuunits} || 1024;
702 $raw .= "lxc.cgroup.cpu.shares = $shares\n";
703 }
704
705 die "missing 'rootfs' configuration\n"
706 if !defined($conf->{rootfs});
707
708 my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
709
710 $raw .= "lxc.rootfs.path = $dir/rootfs\n";
711
712 foreach my $k (sort keys %$conf) {
713 next if $k !~ m/^net(\d+)$/;
714 my $ind = $1;
715 my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
716 $raw .= "lxc.net.$ind.type = veth\n";
717 $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
718 $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
719 $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
720 $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
721 }
722
723 if ($cgv1->{cpuset}) {
724 my $had_cpuset = 0;
725 if (my $lxcconf = $conf->{lxc}) {
726 foreach my $entry (@$lxcconf) {
727 my ($k, $v) = @$entry;
728 $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus';
729 $raw .= "$k = $v\n";
730 }
731 }
732
733 my $cores = $conf->{cores};
734 if (!$had_cpuset && $cores) {
735 my $cpuset = eval { PVE::CpuSet->new_from_cgroup('lxc', 'effective_cpus') };
736 $cpuset = PVE::CpuSet->new_from_cgroup('', 'effective_cpus') if !$cpuset;
737 my @members = $cpuset->members();
738 while (scalar(@members) > $cores) {
739 my $randidx = int(rand(scalar(@members)));
740 $cpuset->delete($members[$randidx]);
741 splice(@members, $randidx, 1); # keep track of the changes
742 }
743 $raw .= "lxc.cgroup.cpuset.cpus = ".$cpuset->short_string()."\n";
744 }
745 }
746
747 File::Path::mkpath("$dir/rootfs");
748
749 PVE::Tools::file_set_contents("$dir/config", $raw);
750 }
751
752 # verify and cleanup nameserver list (replace \0 with ' ')
753 sub verify_nameserver_list {
754 my ($nameserver_list) = @_;
755
756 my @list = ();
757 foreach my $server (PVE::Tools::split_list($nameserver_list)) {
758 PVE::JSONSchema::pve_verify_ip($server);
759 push @list, $server;
760 }
761
762 return join(' ', @list);
763 }
764
765 sub verify_searchdomain_list {
766 my ($searchdomain_list) = @_;
767
768 my @list = ();
769 foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
770 # todo: should we add checks for valid dns domains?
771 push @list, $server;
772 }
773
774 return join(' ', @list);
775 }
776
777 sub get_console_command {
778 my ($vmid, $conf, $escapechar) = @_;
779
780 # '-1' as $escapechar disables keyboard escape sequence
781 # any other passed char (a-z) will result in <Ctrl+$escapechar q>
782
783 my $cmode = PVE::LXC::Config->get_cmode($conf);
784
785 my $cmd = [];
786 if ($cmode eq 'console') {
787 push @$cmd, 'lxc-console', '-n', $vmid, '-t', 0;
788 push @$cmd, '-e', $escapechar if $escapechar;
789 } elsif ($cmode eq 'tty') {
790 push @$cmd, 'lxc-console', '-n', $vmid;
791 push @$cmd, '-e', $escapechar if $escapechar;
792 } elsif ($cmode eq 'shell') {
793 push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
794 } else {
795 die "internal error";
796 }
797
798 return $cmd;
799 }
800
801 sub get_primary_ips {
802 my ($conf) = @_;
803
804 # return data from net0
805
806 return undef if !defined($conf->{net0});
807 my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
808
809 my $ipv4 = $net->{ip};
810 if ($ipv4) {
811 if ($ipv4 =~ /^(dhcp|manual)$/) {
812 $ipv4 = undef
813 } else {
814 $ipv4 =~ s!/\d+$!!;
815 }
816 }
817 my $ipv6 = $net->{ip6};
818 if ($ipv6) {
819 if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
820 $ipv6 = undef;
821 } else {
822 $ipv6 =~ s!/\d+$!!;
823 }
824 }
825
826 return ($ipv4, $ipv6);
827 }
828
829 sub delete_mountpoint_volume {
830 my ($storage_cfg, $vmid, $volume) = @_;
831
832 return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
833
834 my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
835
836 if ($vmid == $owner) {
837 PVE::Storage::vdisk_free($storage_cfg, $volume);
838 } else {
839 warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
840 }
841 }
842
843 sub destroy_lxc_container {
844 my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
845
846 PVE::LXC::Config->foreach_mountpoint($conf, sub {
847 my ($ms, $mountpoint) = @_;
848 delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
849 });
850
851 rmdir "/var/lib/lxc/$vmid/rootfs";
852 unlink "/var/lib/lxc/$vmid/config";
853 rmdir "/var/lib/lxc/$vmid";
854 if (defined $replacement_conf) {
855 PVE::LXC::Config->write_config($vmid, $replacement_conf);
856 } else {
857 PVE::LXC::Config->destroy_config($vmid);
858 }
859 }
860
861 sub vm_stop_cleanup {
862 my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
863
864 return if $keepActive;
865
866 eval {
867 my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
868 PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
869 };
870 warn $@ if $@; # avoid errors - just warn
871 }
872
873 my $safe_num_ne = sub {
874 my ($a, $b) = @_;
875
876 return 0 if !defined($a) && !defined($b);
877 return 1 if !defined($a);
878 return 1 if !defined($b);
879
880 return $a != $b;
881 };
882
883 my $safe_string_ne = sub {
884 my ($a, $b) = @_;
885
886 return 0 if !defined($a) && !defined($b);
887 return 1 if !defined($a);
888 return 1 if !defined($b);
889
890 return $a ne $b;
891 };
892
893 sub update_net {
894 my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
895
896 if ($newnet->{type} ne 'veth') {
897 # for when there are physical interfaces
898 die "cannot update interface of type $newnet->{type}";
899 }
900
901 my $veth = "veth${vmid}i${netid}";
902 my $eth = $newnet->{name};
903
904 if (my $oldnetcfg = $conf->{$opt}) {
905 my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
906
907 if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
908 &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
909
910 PVE::Network::veth_delete($veth);
911 delete $conf->{$opt};
912 PVE::LXC::Config->write_config($vmid, $conf);
913
914 hotplug_net($vmid, $conf, $opt, $newnet, $netid);
915
916 } else {
917 if (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
918 &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
919 &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
920
921 if ($oldnet->{bridge}) {
922 PVE::Network::tap_unplug($veth);
923 foreach (qw(bridge tag firewall)) {
924 delete $oldnet->{$_};
925 }
926 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
927 PVE::LXC::Config->write_config($vmid, $conf);
928 }
929
930 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
931 # This includes the rate:
932 foreach (qw(bridge tag firewall rate)) {
933 $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
934 }
935 } elsif (&$safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
936 # Rate can be applied on its own but any change above needs to
937 # include the rate in tap_plug since OVS resets everything.
938 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
939 $oldnet->{rate} = $newnet->{rate}
940 }
941 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
942 PVE::LXC::Config->write_config($vmid, $conf);
943 }
944 } else {
945 hotplug_net($vmid, $conf, $opt, $newnet, $netid);
946 }
947
948 update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
949 }
950
951 sub hotplug_net {
952 my ($vmid, $conf, $opt, $newnet, $netid) = @_;
953
954 my $veth = "veth${vmid}i${netid}";
955 my $vethpeer = $veth . "p";
956 my $eth = $newnet->{name};
957
958 PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
959 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
960
961 # attach peer in container
962 my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
963 PVE::Tools::run_command($cmd);
964
965 # link up peer in container
966 $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up' ];
967 PVE::Tools::run_command($cmd);
968
969 my $done = { type => 'veth' };
970 foreach (qw(bridge tag firewall hwaddr name)) {
971 $done->{$_} = $newnet->{$_} if $newnet->{$_};
972 }
973 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
974
975 PVE::LXC::Config->write_config($vmid, $conf);
976 }
977
978 sub update_ipconfig {
979 my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
980
981 my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
982
983 my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
984 my $deleted = [];
985 my $added = [];
986 my $nscmd = sub {
987 my $cmdargs = shift;
988 PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
989 };
990 my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
991
992 my $change_ip_config = sub {
993 my ($ipversion) = @_;
994
995 my $family_opt = "-$ipversion";
996 my $suffix = $ipversion == 4 ? '' : $ipversion;
997 my $gw= "gw$suffix";
998 my $ip= "ip$suffix";
999
1000 my $newip = $newnet->{$ip};
1001 my $newgw = $newnet->{$gw};
1002 my $oldip = $optdata->{$ip};
1003 my $oldgw = $optdata->{$gw};
1004
1005 my $change_ip = &$safe_string_ne($oldip, $newip);
1006 my $change_gw = &$safe_string_ne($oldgw, $newgw);
1007
1008 return if !$change_ip && !$change_gw;
1009
1010 # step 1: add new IP, if this fails we cancel
1011 my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1012 if ($change_ip && $is_real_ip) {
1013 eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1014 if (my $err = $@) {
1015 warn $err;
1016 return;
1017 }
1018 }
1019
1020 # step 2: replace gateway
1021 # If this fails we delete the added IP and cancel.
1022 # If it succeeds we save the config and delete the old IP, ignoring
1023 # errors. The config is then saved.
1024 # Note: 'ip route replace' can add
1025 if ($change_gw) {
1026 if ($newgw) {
1027 eval {
1028 if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1029 &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1030 }
1031 &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1032 };
1033 if (my $err = $@) {
1034 warn $err;
1035 # the route was not replaced, the old IP is still available
1036 # rollback (delete new IP) and cancel
1037 if ($change_ip) {
1038 eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1039 warn $@ if $@; # no need to die here
1040 }
1041 return;
1042 }
1043 } else {
1044 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1045 # if the route was not deleted, the guest might have deleted it manually
1046 # warn and continue
1047 warn $@ if $@;
1048 }
1049 if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1050 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1051 # warn if the route was deleted manually
1052 warn $@ if $@;
1053 }
1054 }
1055
1056 # from this point on we save the configuration
1057 # step 3: delete old IP ignoring errors
1058 if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1059 # We need to enable promote_secondaries, otherwise our newly added
1060 # address will be removed along with the old one.
1061 my $promote = 0;
1062 eval {
1063 if ($ipversion == 4) {
1064 &$nscmd({ outfunc => sub { $promote = int(shift) } },
1065 'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1066 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1067 }
1068 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1069 };
1070 warn $@ if $@; # no need to die here
1071
1072 if ($ipversion == 4) {
1073 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1074 }
1075 }
1076
1077 foreach my $property ($ip, $gw) {
1078 if ($newnet->{$property}) {
1079 $optdata->{$property} = $newnet->{$property};
1080 } else {
1081 delete $optdata->{$property};
1082 }
1083 }
1084 $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1085 PVE::LXC::Config->write_config($vmid, $conf);
1086 $lxc_setup->setup_network($conf);
1087 };
1088
1089 &$change_ip_config(4);
1090 &$change_ip_config(6);
1091
1092 }
1093
1094 my $open_namespace = sub {
1095 my ($vmid, $pid, $kind) = @_;
1096 sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1097 or die "failed to open $kind namespace of container $vmid: $!\n";
1098 return $fd;
1099 };
1100
1101 my $enter_namespace = sub {
1102 my ($vmid, $pid, $kind, $type) = @_;
1103 my $fd = $open_namespace->($vmid, $pid, $kind);
1104 PVE::Tools::setns(fileno($fd), $type)
1105 or die "failed to enter $kind namespace of container $vmid: $!\n";
1106 close $fd;
1107 };
1108
1109 my $get_container_namespace = sub {
1110 my ($vmid, $pid, $kind) = @_;
1111
1112 my $pidfd;
1113 if (!defined($pid)) {
1114 # Pin the pid while we're grabbing its stuff from /proc
1115 ($pid, $pidfd) = open_lxc_pid($vmid)
1116 or die "failed to open pidfd of container $vmid\'s init process\n";
1117 }
1118
1119 return $open_namespace->($vmid, $pid, $kind);
1120 };
1121
1122 my $do_syncfs = sub {
1123 my ($vmid, $pid, $socket) = @_;
1124
1125 &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1126
1127 # Tell the parent process to start reading our /proc/mounts
1128 print {$socket} "go\n";
1129 $socket->flush();
1130
1131 # Receive /proc/self/mounts
1132 my $mountdata = do { local $/ = undef; <$socket> };
1133 close $socket;
1134
1135 # Now sync all mountpoints...
1136 my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1137 foreach my $mp (@$mounts) {
1138 my ($what, $dir, $fs) = @$mp;
1139 next if $fs eq 'fuse.lxcfs';
1140 eval { PVE::Tools::sync_mountpoint($dir); };
1141 warn $@ if $@;
1142 }
1143 };
1144
1145 sub sync_container_namespace {
1146 my ($vmid) = @_;
1147 my $pid = find_lxc_pid($vmid);
1148
1149 # SOCK_DGRAM is nicer for barriers but cannot be slurped
1150 socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1151 or die "failed to create socketpair: $!\n";
1152
1153 my $child = fork();
1154 die "fork failed: $!\n" if !defined($child);
1155
1156 if (!$child) {
1157 eval {
1158 close $pfd;
1159 &$do_syncfs($vmid, $pid, $cfd);
1160 };
1161 if (my $err = $@) {
1162 warn $err;
1163 POSIX::_exit(1);
1164 }
1165 POSIX::_exit(0);
1166 }
1167 close $cfd;
1168 my $go = <$pfd>;
1169 die "failed to enter container namespace\n" if $go ne "go\n";
1170
1171 open my $mounts, '<', "/proc/$child/mounts"
1172 or die "failed to open container's /proc/mounts: $!\n";
1173 my $mountdata = do { local $/ = undef; <$mounts> };
1174 close $mounts;
1175 print {$pfd} $mountdata;
1176 close $pfd;
1177
1178 while (waitpid($child, 0) != $child) {}
1179 die "failed to sync container namespace\n" if $? != 0;
1180 }
1181
1182 sub template_create {
1183 my ($vmid, $conf) = @_;
1184
1185 my $storecfg = PVE::Storage::config();
1186
1187 PVE::LXC::Config->foreach_mountpoint($conf, sub {
1188 my ($ms, $mountpoint) = @_;
1189
1190 my $volid = $mountpoint->{volume};
1191
1192 die "Template feature is not available for '$volid'\n"
1193 if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1194 });
1195
1196 PVE::LXC::Config->foreach_mountpoint($conf, sub {
1197 my ($ms, $mountpoint) = @_;
1198
1199 my $volid = $mountpoint->{volume};
1200
1201 PVE::Storage::activate_volumes($storecfg, [$volid]);
1202
1203 my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1204 $mountpoint->{volume} = $template_volid;
1205 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1206 });
1207
1208 PVE::LXC::Config->write_config($vmid, $conf);
1209 }
1210
1211 sub check_ct_modify_config_perm {
1212 my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1213
1214 return 1 if $authuser eq 'root@pam';
1215
1216 my $check = sub {
1217 my ($opt, $delete) = @_;
1218 if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1219 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1220 } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1221 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1222 return if $delete;
1223 my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
1224 : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
1225 raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1226 if $data->{type} ne 'volume';
1227 } elsif ($opt eq 'memory' || $opt eq 'swap') {
1228 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1229 } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1230 $opt eq 'searchdomain' || $opt eq 'hostname') {
1231 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1232 } elsif ($opt eq 'features') {
1233 # For now this is restricted to root@pam
1234 raise_perm_exc("changing feature flags is only allowed for root\@pam");
1235 } elsif ($opt eq 'hookscript') {
1236 # For now this is restricted to root@pam
1237 raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1238 } else {
1239 $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1240 }
1241 };
1242
1243 foreach my $opt (keys %$newconf) {
1244 &$check($opt, 0);
1245 }
1246 foreach my $opt (@$delete) {
1247 &$check($opt, 1);
1248 }
1249
1250 return 1;
1251 }
1252
1253 sub umount_all {
1254 my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1255
1256 my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1257 my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1258
1259 my $res = 1;
1260
1261 PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
1262 my ($ms, $mountpoint) = @_;
1263
1264 my $volid = $mountpoint->{volume};
1265 my $mount = $mountpoint->{mp};
1266
1267 return if !$volid || !$mount;
1268
1269 my $mount_path = "$rootdir/$mount";
1270 $mount_path =~ s!/+!/!g;
1271
1272 return if !PVE::ProcFSTools::is_mounted($mount_path);
1273
1274 eval {
1275 PVE::Tools::run_command(['umount', '-d', $mount_path]);
1276 };
1277 if (my $err = $@) {
1278 if ($noerr) {
1279 $res = 0;
1280 warn $err;
1281 } else {
1282 die $err;
1283 }
1284 }
1285 });
1286
1287 return $res; # tell caller if (some) umounts failed for the noerr case
1288 }
1289
1290 sub mount_all {
1291 my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1292
1293 my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1294 File::Path::make_path($rootdir);
1295
1296 my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1297 PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1298
1299 my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1300
1301 eval {
1302 PVE::LXC::Config->foreach_mountpoint($conf, sub {
1303 my ($ms, $mountpoint) = @_;
1304
1305 $mountpoint->{ro} = 0 if $ignore_ro;
1306
1307 mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1308 });
1309 };
1310 if (my $err = $@) {
1311 warn "mounting container failed\n";
1312 umount_all($vmid, $storage_cfg, $conf, 1);
1313 die $err;
1314 }
1315
1316 return $rootdir;
1317 }
1318
1319
1320 sub mountpoint_mount_path {
1321 my ($mountpoint, $storage_cfg, $snapname) = @_;
1322
1323 return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1324 }
1325
1326 sub query_loopdev {
1327 my ($path) = @_;
1328 my $found;
1329 my $parser = sub {
1330 my $line = shift;
1331 if ($line =~ m@^(/dev/loop\d+):@) {
1332 $found = $1;
1333 }
1334 };
1335 my $cmd = ['losetup', '--associated', $path];
1336 PVE::Tools::run_command($cmd, outfunc => $parser);
1337 return $found;
1338 }
1339
1340 # Run a function with a file attached to a loop device.
1341 # The loop device is always detached afterwards (or set to autoclear).
1342 # Returns the loop device.
1343 sub run_with_loopdev {
1344 my ($func, $file, $readonly) = @_;
1345 my $device = query_loopdev($file);
1346 # Try to reuse an existing device
1347 if ($device) {
1348 # We assume that whoever setup the loop device is responsible for
1349 # detaching it.
1350 &$func($device);
1351 return $device;
1352 }
1353
1354 my $parser = sub {
1355 my $line = shift;
1356 if ($line =~ m@^(/dev/loop\d+)$@) {
1357 $device = $1;
1358 }
1359 };
1360 my $losetup_cmd = [
1361 'losetup',
1362 '--show',
1363 '-f',
1364 $file,
1365 ];
1366 push @$losetup_cmd, '-r' if $readonly;
1367 PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1368 die "failed to setup loop device for $file\n" if !$device;
1369 eval { &$func($device); };
1370 my $err = $@;
1371 PVE::Tools::run_command(['losetup', '-d', $device]);
1372 die $err if $err;
1373 return $device;
1374 }
1375
1376 # In scalar mode: returns a file handle to the deepest directory node.
1377 # In list context: returns a list of:
1378 # * the deepest directory node
1379 # * the 2nd deepest directory (parent of the above)
1380 # * directory name of the last directory
1381 # So that the path $2/$3 should lead to $1 afterwards.
1382 sub walk_tree_nofollow($$$;$$) {
1383 my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1384
1385 sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1386 or die "failed to open start directory $start: $!\n";
1387
1388 return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1389 }
1390
1391
1392 sub walk_tree_nofollow_fd($$$$;$$) {
1393 my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1394
1395 # splitdir() returns '' for empty components including the leading /
1396 my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1397
1398 my $fd = $start_fd;
1399 my $dir = $start_dirname;
1400 my $last_component = undef;
1401 my $second = $fd;
1402 foreach my $component (@comps) {
1403 $dir .= "/$component";
1404 my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1405
1406 if (!$next) {
1407 # failed, check for symlinks and try to create the path
1408 die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1409 die "cannot open directory $dir: $!\n" if !$mkdir;
1410
1411 # We don't check for errors on mkdirat() here and just try to
1412 # openat() again, since at least one error (EEXIST) is an
1413 # expected possibility if multiple containers start
1414 # simultaneously. If someone else injects a symlink now then
1415 # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1416 PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1417
1418 $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1419 die "failed to create path: $dir: $!\n" if !$next;
1420
1421 PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1422 if defined($rootuid) && defined($rootgid);
1423 }
1424
1425 close $second if defined($last_component) && $second != $start_fd;
1426 $last_component = $component;
1427 $second = $fd;
1428 $fd = $next;
1429 }
1430
1431 return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1432 close $second if defined($last_component) && $second != $start_fd;
1433 return $fd;
1434 }
1435
1436 # To guard against symlink attack races against other currently running
1437 # containers with shared recursive bind mount hierarchies we prepare a
1438 # directory handle for the directory we're mounting over to verify the
1439 # mountpoint afterwards.
1440 sub __bindmount_prepare {
1441 my ($hostroot, $dir) = @_;
1442 my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1443 return $srcdh;
1444 }
1445
1446 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1447 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1448 # we intended to bind mount.
1449 sub __bindmount_verify {
1450 my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1451 my $destdh;
1452 if ($parentfd) {
1453 # Open the mount point path coming from the parent directory since the
1454 # filehandle we would have gotten as first result of walk_tree_nofollow
1455 # earlier is still a handle to the underlying directory instead of the
1456 # mounted path.
1457 $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1458 die "failed to open mount point: $!\n" if !$destdh;
1459 if ($ro) {
1460 my $dot = '.';
1461 # no separate function because 99% of the time it's the wrong thing to use.
1462 if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1463 die "failed to mark bind mount read only\n";
1464 }
1465 die "read-only check failed: $!\n" if $! != EROFS;
1466 }
1467 } else {
1468 # For the rootfs we don't have a parentfd so we open the path directly.
1469 # Note that this means bindmounting any prefix of the host's
1470 # /var/lib/lxc/$vmid path into another container is considered a grave
1471 # security error.
1472 sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1473 die "failed to open mount point: $!\n" if !$destdh;
1474 }
1475
1476 my ($srcdev, $srcinode) = stat($srcdh);
1477 my ($dstdev, $dstinode) = stat($destdh);
1478 close $srcdh;
1479 close $destdh;
1480
1481 return ($srcdev == $dstdev && $srcinode == $dstinode);
1482 }
1483
1484 # Perform the actual bind mounting:
1485 sub __bindmount_do {
1486 my ($dir, $dest, $ro, @extra_opts) = @_;
1487 PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1488 if ($ro) {
1489 eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1490 if (my $err = $@) {
1491 warn "bindmount error\n";
1492 # don't leave writable bind-mounts behind...
1493 PVE::Tools::run_command(['umount', $dest]);
1494 die $err;
1495 }
1496 }
1497 }
1498
1499 sub bindmount {
1500 my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1501
1502 my $srcdh = __bindmount_prepare('/', $dir);
1503
1504 __bindmount_do($dir, $dest, $ro, @extra_opts);
1505
1506 if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1507 PVE::Tools::run_command(['umount', $dest]);
1508 die "detected mount path change at: $dir\n";
1509 }
1510 }
1511
1512 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1513 # from $rootdir and $mount and walk the path from $rootdir to the final
1514 # directory to check for symlinks.
1515 sub __mount_prepare_rootdir {
1516 my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1517 $rootdir =~ s!/+!/!g;
1518 $rootdir =~ s!/+$!!;
1519 my $mount_path = "$rootdir/$mount";
1520 my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1521 return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1522 }
1523
1524 # use $rootdir = undef to just return the corresponding mount path
1525 sub mountpoint_mount {
1526 my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1527 return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1528 }
1529
1530 sub mountpoint_stage {
1531 my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1532 my ($path, $loop, $dev) =
1533 __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1534
1535 if (!defined($path)) {
1536 return undef if $! == ENOSYS;
1537 die "failed to mount subvolume: $!\n";
1538 }
1539
1540 # We clone the mount point and leave it there in order to keep them connected to eg. loop
1541 # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1542 # point).
1543 my $err;
1544 my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1545 or die "open_tree() on mount point failed: $!\n";
1546
1547 return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1548 }
1549
1550 sub mountpoint_insert_staged {
1551 my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1552
1553 if (!defined($rootdir_fd)) {
1554 sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1555 or die "failed to open '.': $!\n";
1556 }
1557
1558 my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1559
1560 PVE::Tools::move_mount(
1561 fileno($mount_fd),
1562 '',
1563 fileno($dest_fd),
1564 '',
1565 &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1566 ) or die "failed to move '$opt' into container hierarchy: $!\n";
1567 }
1568
1569 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1570 # can then open a file descriptor to it which can be used with the `move_mount` syscall.
1571 # Note that if the kernel does not support the new mount API, this will not perform any action
1572 # and return `undef` with $! = ENOSYS.
1573 sub __mountpoint_mount {
1574 my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1575
1576 if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1577 $! = ENOSYS;
1578 return undef;
1579 }
1580
1581 # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1582 # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1583 # which we use in __bindmount_verify()!
1584 my $mount = $stage_mount ? '/': $mountpoint->{mp};
1585
1586 my $volid = $mountpoint->{volume};
1587 my $type = $mountpoint->{type};
1588 my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1589 my $mounted_dev;
1590
1591 return if !$volid || !$mount;
1592
1593 $mount =~ s!/+!/!g;
1594
1595 my $mount_path;
1596 my ($mpfd, $parentfd, $last_dir);
1597
1598 if (defined($rootdir)) {
1599 ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1600 __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1601 }
1602
1603 if (defined($stage_mount)) {
1604 $mount_path = $rootdir;
1605 }
1606
1607 my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1608
1609 die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1610
1611 my $optlist = [];
1612
1613 if (my $mountopts = $mountpoint->{mountoptions}) {
1614 my @opts = split(/;/, $mountpoint->{mountoptions});
1615 push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1616 }
1617
1618 my $acl = $mountpoint->{acl};
1619 if (defined($acl)) {
1620 push @$optlist, ($acl ? 'acl' : 'noacl');
1621 }
1622
1623 my $optstring = join(',', @$optlist);
1624 my $readonly = $mountpoint->{ro};
1625
1626 my @extra_opts;
1627 @extra_opts = ('-o', $optstring) if $optstring;
1628
1629 if ($storage) {
1630
1631 my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1632
1633 my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1634
1635 $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1636
1637 my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1638 PVE::Storage::parse_volname($storage_cfg, $volid);
1639
1640 $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1641
1642 if ($format eq 'subvol') {
1643 if ($mount_path) {
1644 if ($snapname) {
1645 if ($scfg->{type} eq 'zfspool') {
1646 my $path_arg = $path;
1647 $path_arg =~ s!^/+!!;
1648 PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', $path_arg, $mount_path]);
1649 } else {
1650 die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1651 }
1652 } else {
1653 if (defined($acl) && $scfg->{type} eq 'zfspool') {
1654 my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1655 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1656 $name .= "\@$snapname" if defined($snapname);
1657 PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1658 }
1659 bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1660 warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1661 }
1662 }
1663 return wantarray ? ($path, 0, undef) : $path;
1664 } elsif ($format eq 'raw' || $format eq 'iso') {
1665 # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1666 # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1667 # Our autodev hook expects the /dev/dm-* device currently
1668 # and will create the /dev/mapper symlink accordingly
1669 $path = Cwd::realpath($path);
1670 die "failed to get device path\n" if !$path;
1671 ($path) = ($path =~ /^(.*)$/s); #untaint
1672 my $domount = sub {
1673 my ($path) = @_;
1674 if ($mount_path) {
1675 if ($format eq 'iso') {
1676 PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1677 } elsif ($isBase || defined($snapname)) {
1678 PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1679 } else {
1680 if ($quota) {
1681 push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1682 }
1683 push @extra_opts, '-o', 'ro' if $readonly;
1684 PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1685 }
1686 }
1687 };
1688 my $use_loopdev = 0;
1689 if ($scfg->{path}) {
1690 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1691 $use_loopdev = 1;
1692 } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1693 $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1694 $mounted_dev = $path;
1695 &$domount($path);
1696 } else {
1697 die "unsupported storage type '$scfg->{type}'\n";
1698 }
1699 return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1700 } else {
1701 die "unsupported image format '$format'\n";
1702 }
1703 } elsif ($type eq 'device') {
1704 push @extra_opts, '-o', 'ro' if $readonly;
1705 push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1706 # See the NOTE above about devicemapper canonicalization
1707 my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1708 PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1709 return wantarray ? ($volid, 0, $devpath) : $volid;
1710 } elsif ($type eq 'bind') {
1711 die "directory '$volid' does not exist\n" if ! -d $volid;
1712 bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1713 warn "cannot enable quota control for bind mounts\n" if $quota;
1714 return wantarray ? ($volid, 0, undef) : $volid;
1715 }
1716
1717 die "unsupported storage";
1718 }
1719
1720 sub mountpoint_hotplug($$$) {
1721 my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1722
1723 my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1724
1725 # We do the rest in a fork with an unshared mount namespace, because:
1726 # -) change our papparmor profile to that of /usr/bin/lxc-start
1727 # -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1728 # container's namespace, then mount it.
1729
1730 PVE::Tools::run_fork(sub {
1731 # Pin the container pid longer, we also need to get its monitor/parent:
1732 my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1733 or die "failed to open pidfd of container $vmid\'s init process\n";
1734
1735 my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1736 or die "failed to open pidfd of container $vmid\'s monitor process\n";
1737
1738 my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1739 my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1740
1741 # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1742 # profile to lower our privileges to the same level we have in the start hook:
1743 sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1744 or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1745 # But switch namespaces first, to make sure the namespace switches aren't blocked by
1746 # apparmor.
1747
1748 # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1749 # namespace for it to remain active there since the container will be able to unmount
1750 # hotplugged mount points and thereby potentially free up loop devices, which is a security
1751 # concern.
1752 PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1753 chdir('/')
1754 or die "failed to change root directory within the monitor's mount namespace: $!\n";
1755
1756 my $dir = get_staging_mount_path($opt);
1757
1758 # Now switch our apparmor profile before mounting:
1759 my $data = 'changeprofile /usr/bin/lxc-start';
1760 if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1761 die "failed to change apparmor profile: $!\n";
1762 }
1763 # Check errors on close as well:
1764 close($aa_fd)
1765 or die "failed to change apparmor profile (close() failed): $!\n";
1766
1767 my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1768
1769 PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1770 chdir('/')
1771 or die "failed to change root directory within the container's mount namespace: $!\n";
1772
1773 mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1774 });
1775 }
1776
1777 # Create a directory in the mountpoint staging tempfs.
1778 sub get_staging_mount_path($) {
1779 my ($opt) = @_;
1780
1781 my $target = get_staging_tempfs() . "/$opt";
1782 if (!mkdir($target) && $! != EEXIST) {
1783 die "failed to create directory $target: $!\n";
1784 }
1785
1786 return $target;
1787 }
1788
1789 # Mount /run/pve/mountpoints as tmpfs
1790 sub get_staging_tempfs() {
1791 # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1792 # mounts to that.
1793 my $target = '/var/lib/lxc/.pve-staged-mounts';
1794 if (!mkdir($target)) {
1795 return $target if $! == EEXIST;
1796 die "failed to create directory $target: $!\n";
1797 }
1798
1799 PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1800 or die "failed to mount $target as tmpfs: $!\n";
1801
1802 return $target;
1803 }
1804
1805 sub mkfs {
1806 my ($dev, $rootuid, $rootgid) = @_;
1807
1808 PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1809 '-E', "root_owner=$rootuid:$rootgid",
1810 $dev]);
1811 }
1812
1813 sub format_disk {
1814 my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1815
1816 if ($volid =~ m!^/dev/.+!) {
1817 mkfs($volid);
1818 return;
1819 }
1820
1821 my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1822
1823 die "cannot format volume '$volid' with no storage\n" if !$storage;
1824
1825 PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1826
1827 my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1828
1829 $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1830
1831 my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1832 PVE::Storage::parse_volname($storage_cfg, $volid);
1833
1834 die "cannot format volume '$volid' (format == $format)\n"
1835 if $format ne 'raw';
1836
1837 mkfs($path, $rootuid, $rootgid);
1838 }
1839
1840 sub destroy_disks {
1841 my ($storecfg, $vollist) = @_;
1842
1843 foreach my $volid (@$vollist) {
1844 eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1845 warn $@ if $@;
1846 }
1847 }
1848
1849 sub alloc_disk {
1850 my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1851
1852 my $needs_chown = 0;
1853 my $volid;
1854
1855 my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1856 # fixme: use better naming ct-$vmid-disk-X.raw?
1857
1858 eval {
1859 my $do_format = 0;
1860 if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1861 if ($size_kb > 0) {
1862 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1863 undef, $size_kb);
1864 $do_format = 1;
1865 } else {
1866 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1867 undef, 0);
1868 $needs_chown = 1;
1869 }
1870 } elsif ($scfg->{type} eq 'zfspool') {
1871
1872 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1873 undef, $size_kb);
1874 $needs_chown = 1;
1875 } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1876
1877 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1878 $do_format = 1;
1879
1880 } elsif ($scfg->{type} eq 'rbd') {
1881
1882 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1883 $do_format = 1;
1884 } else {
1885 die "unable to create containers on storage type '$scfg->{type}'\n";
1886 }
1887 format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1888 };
1889 if (my $err = $@) {
1890 # in case formatting got interrupted:
1891 if (defined($volid)) {
1892 eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1893 warn $@ if $@;
1894 }
1895 die $err;
1896 }
1897
1898 return ($volid, $needs_chown);
1899 }
1900
1901 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1902 sub create_disks {
1903 my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1904
1905 my $vollist = [];
1906
1907 eval {
1908 my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1909 my $chown_vollist = [];
1910
1911 PVE::LXC::Config->foreach_mountpoint($settings, sub {
1912 my ($ms, $mountpoint) = @_;
1913
1914 my $volid = $mountpoint->{volume};
1915 my $mp = $mountpoint->{mp};
1916
1917 my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1918
1919 if ($storage && ($volid =~ $NEW_DISK_RE)) {
1920 my ($storeid, $size_gb) = ($1, $2);
1921
1922 my $size_kb = int(${size_gb}*1024) * 1024;
1923
1924 my $needs_chown = 0;
1925 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1926 push @$chown_vollist, $volid if $needs_chown;
1927 push @$vollist, $volid;
1928 $mountpoint->{volume} = $volid;
1929 $mountpoint->{size} = $size_kb * 1024;
1930 if ($pending) {
1931 $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1932 } else {
1933 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1934 }
1935 } else {
1936 # use specified/existing volid/dir/device
1937 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1938 }
1939 });
1940
1941 PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1942 foreach my $volid (@$chown_vollist) {
1943 my $path = PVE::Storage::path($storecfg, $volid, undef);
1944 chown($rootuid, $rootgid, $path);
1945 }
1946 PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1947 };
1948 # free allocated images on error
1949 if (my $err = $@) {
1950 destroy_disks($storecfg, $vollist);
1951 die $err;
1952 }
1953 return $vollist;
1954 }
1955
1956 sub update_disksize {
1957 my ($vmid, $conf, $all_volumes) = @_;
1958
1959 my $changes;
1960 my $prefix = "CT $vmid:";
1961
1962 my $update_mp = sub {
1963 my ($key, $mp, @param) = @_;
1964 my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1965
1966 if (!defined($mp->{size}) || $size != $mp->{size}) {
1967 $changes = 1;
1968 print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1969 $mp->{size} = $size;
1970 my $nomp = 1 if ($key eq 'rootfs');
1971 $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1972 }
1973 };
1974
1975 PVE::LXC::Config->foreach_mountpoint($conf, $update_mp);
1976
1977 return $changes;
1978 }
1979
1980 sub update_unused {
1981 my ($vmid, $conf, $all_volumes) = @_;
1982
1983 my $changes;
1984 my $prefix = "CT $vmid:";
1985
1986 # Note: it is allowed to define multiple storage entries with the same path
1987 # (alias), so we need to check both 'volid' and real 'path' (two different
1988 # volid can point to the same path).
1989
1990 # used and unused disks
1991 my $refpath = {};
1992 my $orphans = {};
1993
1994 foreach my $opt (keys %$conf) {
1995 next if ($opt !~ m/^unused\d+$/);
1996 my $vol = $all_volumes->{$conf->{$opt}};
1997 $refpath->{$vol->{path}} = $vol->{volid};
1998 }
1999
2000 foreach my $key (keys %$all_volumes) {
2001 my $vol = $all_volumes->{$key};
2002 my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2003 my $path = $vol->{path};
2004
2005 if ($in_use) {
2006 $refpath->{$path} = $key;
2007 delete $orphans->{$path};
2008 } else {
2009 if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2010 $orphans->{$path} = $key;
2011 }
2012 }
2013 }
2014
2015 for my $key (keys %$orphans) {
2016 my $disk = $orphans->{$key};
2017 my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2018
2019 if ($unused) {
2020 $changes = 1;
2021 print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2022 }
2023 }
2024
2025 return $changes;
2026 }
2027
2028 sub scan_volids {
2029 my ($cfg, $vmid) = @_;
2030
2031 my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid);
2032
2033 my $all_volumes = {};
2034 foreach my $storeid (keys %$info) {
2035 foreach my $item (@{$info->{$storeid}}) {
2036 my $volid = $item->{volid};
2037 next if !($volid && $item->{size});
2038 $item->{path} = PVE::Storage::path($cfg, $volid);
2039 $all_volumes->{$volid} = $item;
2040 }
2041 }
2042
2043 return $all_volumes;
2044 }
2045
2046 sub rescan {
2047 my ($vmid, $nolock, $dryrun) = @_;
2048
2049 my $cfg = PVE::Storage::config();
2050
2051 # FIXME: Remove once our RBD plugin can handle CT and VM on a single storage
2052 # see: https://pve.proxmox.com/pipermail/pve-devel/2018-July/032900.html
2053 foreach my $stor (keys %{$cfg->{ids}}) {
2054 delete($cfg->{ids}->{$stor}) if !$cfg->{ids}->{$stor}->{content}->{rootdir};
2055 }
2056
2057 print "rescan volumes...\n";
2058 my $all_volumes = scan_volids($cfg, $vmid);
2059
2060 my $updatefn = sub {
2061 my ($vmid) = @_;
2062
2063 my $changes;
2064 my $conf = PVE::LXC::Config->load_config($vmid);
2065
2066 PVE::LXC::Config->check_lock($conf);
2067
2068 my $vm_volids = {};
2069 foreach my $volid (keys %$all_volumes) {
2070 my $info = $all_volumes->{$volid};
2071 $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2072 }
2073
2074 my $upu = update_unused($vmid, $conf, $vm_volids);
2075 my $upd = update_disksize($vmid, $conf, $vm_volids);
2076 $changes = $upu || $upd;
2077
2078 PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2079 };
2080
2081 if (defined($vmid)) {
2082 if ($nolock) {
2083 &$updatefn($vmid);
2084 } else {
2085 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2086 }
2087 } else {
2088 my $vmlist = config_list();
2089 foreach my $vmid (keys %$vmlist) {
2090 if ($nolock) {
2091 &$updatefn($vmid);
2092 } else {
2093 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2094 }
2095 }
2096 }
2097 }
2098
2099
2100 # bash completion helper
2101
2102 sub complete_os_templates {
2103 my ($cmdname, $pname, $cvalue) = @_;
2104
2105 my $cfg = PVE::Storage::config();
2106
2107 my $storeid;
2108
2109 if ($cvalue =~ m/^([^:]+):/) {
2110 $storeid = $1;
2111 }
2112
2113 my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2114 my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2115
2116 my $res = [];
2117 foreach my $id (keys %$data) {
2118 foreach my $item (@{$data->{$id}}) {
2119 push @$res, $item->{volid} if defined($item->{volid});
2120 }
2121 }
2122
2123 return $res;
2124 }
2125
2126 my $complete_ctid_full = sub {
2127 my ($running) = @_;
2128
2129 my $idlist = vmstatus();
2130
2131 my $active_hash = list_active_containers();
2132
2133 my $res = [];
2134
2135 foreach my $id (keys %$idlist) {
2136 my $d = $idlist->{$id};
2137 if (defined($running)) {
2138 next if $d->{template};
2139 next if $running && !$active_hash->{$id};
2140 next if !$running && $active_hash->{$id};
2141 }
2142 push @$res, $id;
2143
2144 }
2145 return $res;
2146 };
2147
2148 sub complete_ctid {
2149 return &$complete_ctid_full();
2150 }
2151
2152 sub complete_ctid_stopped {
2153 return &$complete_ctid_full(0);
2154 }
2155
2156 sub complete_ctid_running {
2157 return &$complete_ctid_full(1);
2158 }
2159
2160 sub parse_id_maps {
2161 my ($conf) = @_;
2162
2163 my $id_map = [];
2164 my $rootuid = 0;
2165 my $rootgid = 0;
2166
2167 my $lxc = $conf->{lxc};
2168 foreach my $entry (@$lxc) {
2169 my ($key, $value) = @$entry;
2170 # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2171 next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2172 if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2173 my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2174 push @$id_map, [$type, $ct, $host, $length];
2175 if ($ct == 0) {
2176 $rootuid = $host if $type eq 'u';
2177 $rootgid = $host if $type eq 'g';
2178 }
2179 } else {
2180 die "failed to parse idmap: $value\n";
2181 }
2182 }
2183
2184 if (!@$id_map && $conf->{unprivileged}) {
2185 # Should we read them from /etc/subuid?
2186 $id_map = [ ['u', '0', '100000', '65536'],
2187 ['g', '0', '100000', '65536'] ];
2188 $rootuid = $rootgid = 100000;
2189 }
2190
2191 return ($id_map, $rootuid, $rootgid);
2192 }
2193
2194 sub userns_command {
2195 my ($id_map) = @_;
2196 if (@$id_map) {
2197 return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2198 }
2199 return [];
2200 }
2201
2202 sub vm_start {
2203 my ($vmid, $conf, $skiplock) = @_;
2204
2205 # apply pending changes while starting
2206 if (scalar(keys %{$conf->{pending}})) {
2207 my $storecfg = PVE::Storage::config();
2208 PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2209 $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2210 }
2211
2212 update_lxc_config($vmid, $conf);
2213
2214 my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2215
2216 if ($skiplock) {
2217 open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2218 close($fh);
2219 }
2220
2221 my $cmd = ['systemctl', 'start', "pve-container\@$vmid"];
2222
2223 PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2224 eval { PVE::Tools::run_command($cmd); };
2225 if (my $err = $@) {
2226 unlink $skiplock_flag_fn;
2227 die $err;
2228 }
2229 PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2230
2231 return;
2232 }
2233
2234 # Helper to stop a container completely and make sure it has stopped completely.
2235 # This is necessary because we want the post-stop hook to have completed its
2236 # unmount-all step, but post-stop happens after lxc puts the container into the
2237 # STOPPED state.
2238 # $kill - if true it will always do an immediate hard-stop
2239 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2240 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2241 sub vm_stop {
2242 my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2243
2244 # Open the container's command socket.
2245 my $path = "\0/var/lib/lxc/$vmid/command";
2246 my $sock = IO::Socket::UNIX->new(
2247 Type => SOCK_STREAM(),
2248 Peer => $path,
2249 );
2250 if (!$sock) {
2251 return if $! == ECONNREFUSED; # The container is not running
2252 die "failed to open container ${vmid}'s command socket: $!\n";
2253 }
2254
2255 my $conf = PVE::LXC::Config->load_config($vmid);
2256 PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2257
2258 # Stop the container:
2259
2260 my $cmd = ['lxc-stop', '-n', $vmid];
2261
2262 if ($kill) {
2263 push @$cmd, '--kill'; # doesn't allow timeouts
2264 } else {
2265 # lxc-stop uses a default timeout
2266 push @$cmd, '--nokill' if !$kill_after_timeout;
2267
2268 if (defined($shutdown_timeout)) {
2269 push @$cmd, '--timeout', $shutdown_timeout;
2270 # Give run_command 5 extra seconds
2271 $shutdown_timeout += 5;
2272 }
2273 }
2274
2275 eval { PVE::Tools::run_command($cmd, timeout => $shutdown_timeout) };
2276 if (my $err = $@) {
2277 warn $@ if $@;
2278 }
2279
2280 my $result = <$sock>;
2281
2282 return if !defined $result; # monitor is gone and the ct has stopped.
2283 die "container did not stop\n";
2284 }
2285
2286 sub vm_reboot {
2287 my ($vmid, $timeout, $skiplock) = @_;
2288
2289 PVE::LXC::Config->lock_config($vmid, sub {
2290 return if !check_running($vmid);
2291
2292 vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2293
2294 my $conf = PVE::LXC::Config->load_config($vmid);
2295 vm_start($vmid, $conf);
2296 });
2297 }
2298
2299 sub run_unshared {
2300 my ($code) = @_;
2301
2302 return PVE::Tools::run_fork(sub {
2303 # Unshare the mount namespace
2304 die "failed to unshare mount namespace: $!\n"
2305 if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2306 PVE::Tools::run_command(['mount', '--make-rslave', '/']);
2307 return $code->();
2308 });
2309 }
2310
2311 my $copy_volume = sub {
2312 my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid) = @_;
2313
2314 my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2315 $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2316
2317 my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2318 $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2319
2320 my @mounted;
2321 eval {
2322 # mount and copy
2323 mkdir $src;
2324 mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2325 push @mounted, $src;
2326 mkdir $dest;
2327 mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2328 push @mounted, $dest;
2329
2330 $bwlimit //= 0;
2331
2332 PVE::Tools::run_command(['/usr/bin/rsync', '--stats', '-X', '-A', '--numeric-ids',
2333 '-aH', '--whole-file', '--sparse', '--one-file-system',
2334 "--bwlimit=$bwlimit", "$src/", $dest]);
2335 };
2336 my $err = $@;
2337
2338 # Wait for rsync's children to release dest so that
2339 # consequent file operations (umount, remove) are possible
2340 while ((system {"fuser"} "fuser", "-s", $dest) == 0) {sleep 1};
2341
2342 foreach my $mount (reverse @mounted) {
2343 eval { PVE::Tools::run_command(['/bin/umount', $mount], errfunc => sub{})};
2344 warn "Can't umount $mount\n" if $@;
2345 }
2346
2347 # If this fails they're used as mount points in a concurrent operation
2348 # (which should not happen but there's also no real need to get rid of them).
2349 rmdir $dest;
2350 rmdir $src;
2351
2352 die $err if $err;
2353 };
2354
2355 # Should not be called after unsharing the mount namespace!
2356 sub copy_volume {
2357 my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2358
2359 die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2360 File::Path::make_path("/var/lib/lxc/$vmid");
2361 my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2362 my $src = "/var/lib/lxc/$vmid/.copy-volume-2";
2363
2364 # get id's for unprivileged container
2365 my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2366
2367 # Allocate the disk before unsharing in order to make sure zfs subvolumes
2368 # are visible in this namespace, otherwise the host only sees the empty
2369 # (not-mounted) directory.
2370 my $new_volid;
2371 eval {
2372 # Make sure $mp contains a correct size.
2373 $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2374 my $needs_chown;
2375 ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2376 if ($needs_chown) {
2377 PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2378 my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2379 chown($rootuid, $rootgid, $path);
2380 }
2381
2382 run_unshared(sub {
2383 $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2384 });
2385 };
2386 if (my $err = $@) {
2387 PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2388 if defined($new_volid);
2389 die $err;
2390 }
2391
2392 return $new_volid;
2393 }
2394
2395 1;