src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw();
   7 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
   8 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
   9 use File::Path;
  10 use File::Spec;
  11 use IO::Poll qw(POLLIN POLLHUP);
  12 use IO::Socket::UNIX;
  13 use POSIX qw(EINTR);
  14 use Socket;
  15 use Time::HiRes qw (gettimeofday);
  16
  17 use PVE::AccessControl;
  18 use PVE::CGroup;
  19 use PVE::CpuSet;
  20 use PVE::Exception qw(raise_perm_exc);
  21 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  22 use PVE::INotify;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use PVE::Network;
  25 use PVE::ProcFSTools;
  26 use PVE::RESTEnvironment;
  27 use PVE::SafeSyslog;
  28 use PVE::Storage;
  29 use PVE::Tools qw(
  30     run_command
  31     dir_glob_foreach
  32     file_get_contents
  33     file_set_contents
  34     AT_FDCWD
  35     O_PATH
  36     $IPV4RE
  37     $IPV6RE
  38 );
  39 use PVE::Syscall qw(:fsmount);
  40
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Config;
  43 use PVE::LXC::Monitor;
  44 use PVE::LXC::Tools;
  45
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         # cgroup memory usage is limited by the hard 'max' limit (OOM-killer enforced) and the soft
 689         # 'high' limit (cgroup processes get throttled and put under heavy reclaim pressure).
 690         my $lxc_mem_max = int($memory * 1024 * 1024);
 691         $raw .= "lxc.cgroup2.memory.max = $lxc_mem_max\n";
 692         # Set the high to 1016/1024 (~99.2%) of the 'max' hard limit clamped to 128 MiB max, to
 693         # scale it for the lower range while having a decent 2^x based rest for 2^y memory configs.
 694         my $lxc_mem_high = $memory >= 16 * 1024 ? int(($memory - 128) * 1024 * 1024) : int($memory * 1024 * 1016);
 695         $raw .= "lxc.cgroup2.memory.high = $lxc_mem_high\n";
 696
 697         my $lxcswap = int($swap*1024*1024);
 698         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 699     }
 700
 701     if ($cgv1->{cpu}) {
 702         if (my $cpulimit = $conf->{cpulimit}) {
 703             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 704             my $value = int(100000*$cpulimit);
 705             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 706         }
 707
 708         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 709         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 710     } elsif ($cgv2->{cpu}) {
 711         # See PVE::CGroup
 712         if (my $cpulimit = $conf->{cpulimit}) {
 713             my $value = int(100000*$cpulimit);
 714             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 715         }
 716
 717         if (defined(my $shares = $conf->{cpuunits})) {
 718             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 719             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 720         }
 721     }
 722
 723     die "missing 'rootfs' configuration\n"
 724         if !defined($conf->{rootfs});
 725
 726     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 727
 728     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 729
 730     foreach my $k (sort keys %$conf) {
 731         next if $k !~ m/^net(\d+)$/;
 732         my $ind = $1;
 733         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 734         $raw .= "lxc.net.$ind.type = veth\n";
 735         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 736         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 737         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 738
 739         # Keep container from starting with invalid mtu configuration
 740         if (my $mtu = $d->{mtu}) {
 741             my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 742             die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 743                 if ($mtu > $bridge_mtu);
 744
 745             $raw .= "lxc.net.$ind.mtu = $mtu\n";
 746         }
 747
 748         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 749         if ($lxc_major >= 4) {
 750             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 751         }
 752     }
 753
 754     my $had_cpuset = 0;
 755     if (my $lxcconf = $conf->{lxc}) {
 756         foreach my $entry (@$lxcconf) {
 757             my ($k, $v) = @$entry;
 758             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 759             $raw .= "$k = $v\n";
 760         }
 761     }
 762
 763     my $cpuset;
 764     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 765     if (defined($cpuset_cgroup)) {
 766         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 767             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 768     }
 769     my $cores = $conf->{cores};
 770     if (!$had_cpuset && $cores && $cpuset) {
 771         my @members = $cpuset->members();
 772         while (scalar(@members) > $cores) {
 773             my $randidx = int(rand(scalar(@members)));
 774             $cpuset->delete($members[$randidx]);
 775             splice(@members, $randidx, 1); # keep track of the changes
 776         }
 777         my $ver = $cpuset_version == 1 ? '' : '2';
 778         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 779     }
 780
 781     File::Path::mkpath("$dir/rootfs");
 782
 783     PVE::Tools::file_set_contents("$dir/config", $raw);
 784 }
 785
 786 # verify and cleanup nameserver list (replace \0 with ' ')
 787 sub verify_nameserver_list {
 788     my ($nameserver_list) = @_;
 789
 790     my @list = ();
 791     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 792         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 793         push @list, $server;
 794     }
 795
 796     return join(' ', @list);
 797 }
 798
 799 sub verify_searchdomain_list {
 800     my ($searchdomain_list) = @_;
 801
 802     my @list = ();
 803     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 804         # todo: should we add checks for valid dns domains?
 805         push @list, $server;
 806     }
 807
 808     return join(' ', @list);
 809 }
 810
 811 sub get_console_command {
 812     my ($vmid, $conf, $escapechar) = @_;
 813
 814     # '-1' as $escapechar disables keyboard escape sequence
 815     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 816
 817     my $cmode = PVE::LXC::Config->get_cmode($conf);
 818
 819     my $cmd = [];
 820     if ($cmode eq 'console') {
 821         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 822         push @$cmd, '-e', $escapechar if $escapechar;
 823     } elsif ($cmode eq 'tty') {
 824         push @$cmd, 'lxc-console', '-n',  $vmid;
 825         push @$cmd, '-e', $escapechar if $escapechar;
 826     } elsif ($cmode eq 'shell') {
 827         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 828     } else {
 829         die "internal error";
 830     }
 831
 832     return $cmd;
 833 }
 834
 835 sub get_primary_ips {
 836     my ($conf) = @_;
 837
 838     # return data from net0
 839
 840     return undef if !defined($conf->{net0});
 841     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 842
 843     my $ipv4 = $net->{ip};
 844     if ($ipv4) {
 845         if ($ipv4 =~ /^(dhcp|manual)$/) {
 846             $ipv4 = undef
 847         } else {
 848             $ipv4 =~ s!/\d+$!!;
 849         }
 850     }
 851     my $ipv6 = $net->{ip6};
 852     if ($ipv6) {
 853         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 854             $ipv6 = undef;
 855         } else {
 856             $ipv6 =~ s!/\d+$!!;
 857         }
 858     }
 859
 860     return ($ipv4, $ipv6);
 861 }
 862
 863 sub delete_mountpoint_volume {
 864     my ($storage_cfg, $vmid, $volume) = @_;
 865
 866     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 867
 868     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 869
 870     if ($vmid == $owner) {
 871         PVE::Storage::vdisk_free($storage_cfg, $volume);
 872     } else {
 873         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 874     }
 875 }
 876
 877 sub destroy_lxc_container {
 878     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 879
 880     my $volids = {};
 881     my $remove_volume = sub {
 882         my ($ms, $mountpoint) = @_;
 883
 884         my $volume = $mountpoint->{volume};
 885
 886         return if $volids->{$volume};
 887         $volids->{$volume} = 1;
 888
 889         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 890     };
 891     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 892
 893     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 894
 895     if ($purge_unreferenced) { # also remove unreferenced disk
 896         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 897         PVE::Storage::foreach_volid($vmdisks, sub {
 898             my ($volid, $sid, $volname, $d) = @_;
 899             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 900             warn $@ if $@;
 901         });
 902     }
 903
 904     rmdir "/var/lib/lxc/$vmid/rootfs";
 905     unlink "/var/lib/lxc/$vmid/config";
 906     rmdir "/var/lib/lxc/$vmid";
 907     if (defined $replacement_conf) {
 908         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 909     } else {
 910         PVE::LXC::Config->destroy_config($vmid);
 911     }
 912 }
 913
 914 sub vm_stop_cleanup {
 915     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 916
 917     return if $keepActive;
 918
 919     eval {
 920         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 921         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 922     };
 923     warn $@ if $@; # avoid errors - just warn
 924 }
 925
 926 sub net_tap_plug : prototype($$) {
 927     my ($iface, $net) = @_;
 928
 929     if (defined($net->{link_down})) {
 930         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 931         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 932         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 933         return;
 934     }
 935
 936     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 937         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 938
 939     if ($have_sdn) {
 940         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 941         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge, $firewall);
 942     } else {
 943         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 944     }
 945
 946     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 947 }
 948
 949 sub update_net {
 950     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 951
 952     if ($newnet->{type} ne 'veth') {
 953         # for when there are physical interfaces
 954         die "cannot update interface of type $newnet->{type}";
 955     }
 956
 957     my $veth = "veth${vmid}i${netid}";
 958     my $eth = $newnet->{name};
 959
 960     if (my $oldnetcfg = $conf->{$opt}) {
 961         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 962
 963         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 964             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 965
 966             PVE::Network::veth_delete($veth);
 967             delete $conf->{$opt};
 968             PVE::LXC::Config->write_config($vmid, $conf);
 969
 970             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 971
 972         } else {
 973             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 974                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 975                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 976                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 977             ) {
 978
 979                 if ($oldnet->{bridge}) {
 980                     PVE::Network::tap_unplug($veth);
 981                     foreach (qw(bridge tag firewall)) {
 982                         delete $oldnet->{$_};
 983                     }
 984                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 985                     PVE::LXC::Config->write_config($vmid, $conf);
 986                 }
 987
 988                 PVE::LXC::net_tap_plug($veth, $newnet);
 989
 990                 # This includes the rate:
 991                 foreach (qw(bridge tag firewall rate link_down)) {
 992                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 993                 }
 994             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 995                 # Rate can be applied on its own but any change above needs to
 996                 # include the rate in tap_plug since OVS resets everything.
 997                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 998                 $oldnet->{rate} = $newnet->{rate}
 999             }
1000             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
1001             PVE::LXC::Config->write_config($vmid, $conf);
1002         }
1003     } else {
1004         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1005     }
1006
1007     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1008 }
1009
1010 sub hotplug_net {
1011     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1012
1013     my $veth = "veth${vmid}i${netid}";
1014     my $vethpeer = $veth . "p";
1015     my $eth = $newnet->{name};
1016
1017     if ($have_sdn) {
1018         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1019     } else {
1020         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1021     }
1022
1023     PVE::LXC::net_tap_plug($veth, $newnet);
1024
1025     # attach peer in container
1026     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1027     PVE::Tools::run_command($cmd);
1028
1029     # link up peer in container
1030     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1031     PVE::Tools::run_command($cmd);
1032
1033     my $done = { type => 'veth' };
1034     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1035         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1036     }
1037     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1038
1039     PVE::LXC::Config->write_config($vmid, $conf);
1040 }
1041
1042 sub update_ipconfig {
1043     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1044
1045     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1046
1047     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1048     my $deleted = [];
1049     my $added = [];
1050     my $nscmd = sub {
1051         my $cmdargs = shift;
1052         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1053     };
1054     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1055
1056     my $change_ip_config = sub {
1057         my ($ipversion) = @_;
1058
1059         my $family_opt = "-$ipversion";
1060         my $suffix = $ipversion == 4 ? '' : $ipversion;
1061         my $gw= "gw$suffix";
1062         my $ip= "ip$suffix";
1063
1064         my $newip = $newnet->{$ip};
1065         my $newgw = $newnet->{$gw};
1066         my $oldip = $optdata->{$ip};
1067         my $oldgw = $optdata->{$gw};
1068
1069         my $change_ip = safe_string_ne($oldip, $newip);
1070         my $change_gw = safe_string_ne($oldgw, $newgw);
1071
1072         return if !$change_ip && !$change_gw;
1073
1074         # step 1: add new IP, if this fails we cancel
1075         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1076         if ($change_ip && $is_real_ip) {
1077             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1078             if (my $err = $@) {
1079                 warn $err;
1080                 return;
1081             }
1082         }
1083
1084         # step 2: replace gateway
1085         #   If this fails we delete the added IP and cancel.
1086         #   If it succeeds we save the config and delete the old IP, ignoring
1087         #   errors. The config is then saved.
1088         # Note: 'ip route replace' can add
1089         if ($change_gw) {
1090             if ($newgw) {
1091                 eval {
1092                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1093                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1094                     }
1095                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1096                 };
1097                 if (my $err = $@) {
1098                     warn $err;
1099                     # the route was not replaced, the old IP is still available
1100                     # rollback (delete new IP) and cancel
1101                     if ($change_ip) {
1102                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1103                         warn $@ if $@; # no need to die here
1104                     }
1105                     return;
1106                 }
1107             } else {
1108                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1109                 # if the route was not deleted, the guest might have deleted it manually
1110                 # warn and continue
1111                 warn $@ if $@;
1112             }
1113             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1114                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1115                 # warn if the route was deleted manually
1116                 warn $@ if $@;
1117             }
1118         }
1119
1120         # from this point on we save the configuration
1121         # step 3: delete old IP ignoring errors
1122         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1123             # We need to enable promote_secondaries, otherwise our newly added
1124             # address will be removed along with the old one.
1125             my $promote = 0;
1126             eval {
1127                 if ($ipversion == 4) {
1128                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1129                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1130                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1131                 }
1132                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1133             };
1134             warn $@ if $@; # no need to die here
1135
1136             if ($ipversion == 4) {
1137                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1138             }
1139         }
1140
1141         foreach my $property ($ip, $gw) {
1142             if ($newnet->{$property}) {
1143                 $optdata->{$property} = $newnet->{$property};
1144             } else {
1145                 delete $optdata->{$property};
1146             }
1147         }
1148         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1149         PVE::LXC::Config->write_config($vmid, $conf);
1150         $lxc_setup->setup_network($conf);
1151     };
1152
1153     &$change_ip_config(4);
1154     &$change_ip_config(6);
1155
1156 }
1157
1158 my $open_namespace = sub {
1159     my ($vmid, $pid, $kind) = @_;
1160     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1161         or die "failed to open $kind namespace of container $vmid: $!\n";
1162     return $fd;
1163 };
1164
1165 my $enter_namespace = sub {
1166     my ($vmid, $pid, $kind, $type) = @_;
1167     my $fd = $open_namespace->($vmid, $pid, $kind);
1168     PVE::Tools::setns(fileno($fd), $type)
1169         or die "failed to enter $kind namespace of container $vmid: $!\n";
1170     close $fd;
1171 };
1172
1173 my $get_container_namespace = sub {
1174     my ($vmid, $pid, $kind) = @_;
1175
1176     my $pidfd;
1177     if (!defined($pid)) {
1178         # Pin the pid while we're grabbing its stuff from /proc
1179         ($pid, $pidfd) = open_lxc_pid($vmid)
1180             or die "failed to open pidfd of container $vmid\'s init process\n";
1181     }
1182
1183     return $open_namespace->($vmid, $pid, $kind);
1184 };
1185
1186 my $do_syncfs = sub {
1187     my ($vmid, $pid, $socket) = @_;
1188
1189     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1190
1191     # Tell the parent process to start reading our /proc/mounts
1192     print {$socket} "go\n";
1193     $socket->flush();
1194
1195     # Receive /proc/self/mounts
1196     my $mountdata = do { local $/ = undef; <$socket> };
1197     close $socket;
1198
1199     my %nosyncfs = (
1200         cgroup => 1,
1201         cgroup2 => 1,
1202         devtmpfs => 1,
1203         devpts => 1,
1204         'fuse.lxcfs' => 1,
1205         fusectl => 1,
1206         mqueue => 1,
1207         proc => 1,
1208         sysfs => 1,
1209         tmpfs => 1,
1210     );
1211
1212     # Now sync all mountpoints...
1213     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1214     foreach my $mp (@$mounts) {
1215         my ($what, $dir, $fs) = @$mp;
1216         next if $nosyncfs{$fs};
1217         eval { PVE::Tools::sync_mountpoint($dir); };
1218         warn $@ if $@;
1219     }
1220 };
1221
1222 sub sync_container_namespace {
1223     my ($vmid) = @_;
1224     my $pid = find_lxc_pid($vmid);
1225
1226     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1227     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1228         or die "failed to create socketpair: $!\n";
1229
1230     my $child = fork();
1231     die "fork failed: $!\n" if !defined($child);
1232
1233     if (!$child) {
1234         eval {
1235             close $pfd;
1236             &$do_syncfs($vmid, $pid, $cfd);
1237         };
1238         if (my $err = $@) {
1239             warn $err;
1240             POSIX::_exit(1);
1241         }
1242         POSIX::_exit(0);
1243     }
1244     close $cfd;
1245     my $go = <$pfd>;
1246     die "failed to enter container namespace\n" if $go ne "go\n";
1247
1248     open my $mounts, '<', "/proc/$child/mounts"
1249         or die "failed to open container's /proc/mounts: $!\n";
1250     my $mountdata = do { local $/ = undef; <$mounts> };
1251     close $mounts;
1252     print {$pfd} $mountdata;
1253     close $pfd;
1254
1255     while (waitpid($child, 0) != $child) {}
1256     die "failed to sync container namespace\n" if $? != 0;
1257 }
1258
1259 sub template_create {
1260     my ($vmid, $conf) = @_;
1261
1262     my $storecfg = PVE::Storage::config();
1263
1264     PVE::LXC::Config->foreach_volume($conf, sub {
1265         my ($ms, $mountpoint) = @_;
1266
1267         my $volid = $mountpoint->{volume};
1268
1269         die "Template feature is not available for '$volid'\n"
1270             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1271     });
1272
1273     PVE::LXC::Config->foreach_volume($conf, sub {
1274         my ($ms, $mountpoint) = @_;
1275
1276         my $volid = $mountpoint->{volume};
1277
1278         PVE::Storage::activate_volumes($storecfg, [$volid]);
1279
1280         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1281         $mountpoint->{volume} = $template_volid;
1282         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1283     });
1284
1285     PVE::LXC::Config->write_config($vmid, $conf);
1286 }
1287
1288 sub check_ct_modify_config_perm {
1289     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1290
1291     return 1 if $authuser eq 'root@pam';
1292     my $storage_cfg = PVE::Storage::config();
1293
1294     my $check = sub {
1295         my ($opt, $delete) = @_;
1296         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1297             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1298         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1299             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1300             return if $delete;
1301             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1302             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1303                 if $data->{type} ne 'volume';
1304             my $volid = $data->{volume};
1305             if ($volid =~ $NEW_DISK_RE) {
1306                 my $sid = $1;
1307                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1308             } else {
1309                 PVE::Storage::check_volume_access(
1310                     $rpcenv,
1311                     $authuser,
1312                     $storage_cfg,
1313                     $vmid,
1314                     $volid,
1315                     'rootdir',
1316                 );
1317             }
1318         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1319             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1320         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1321                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1322             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1323         } elsif ($opt eq 'features') {
1324             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1325                 if !$unprivileged;
1326
1327             my $nesting_changed = 0;
1328             my $other_changed = 0;
1329             if (!$delete) {
1330                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1331                 if (defined($oldconf) && $oldconf->{$opt}) {
1332                     # existing container with features
1333                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1334                     for my $feature ((keys %$old_features, keys %$features)) {
1335                         my $old = $old_features->{$feature} // '';
1336                         my $new = $features->{$feature} // '';
1337                         if ($old ne $new) {
1338                             if ($feature eq 'nesting') {
1339                                 $nesting_changed = 1;
1340                                 next;
1341                             } else {
1342                                 $other_changed = 1;
1343                                 last;
1344                             }
1345                         }
1346                     }
1347                 } else {
1348                     # new container or no features defined
1349                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1350                         $nesting_changed = 1;
1351                     } elsif (scalar(keys %$features) > 0) {
1352                         $other_changed = 1;
1353                     }
1354                 }
1355             } else {
1356                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1357                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1358                     $nesting_changed = 1;
1359                 } elsif (scalar(keys %$features) > 0) {
1360                     $other_changed = 1;
1361                 }
1362             }
1363             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1364                 if $other_changed;
1365             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1366                 if $nesting_changed;
1367         } elsif ($opt eq 'hookscript') {
1368             # For now this is restricted to root@pam
1369             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1370         } elsif ($opt eq 'tags') {
1371             my $old = $oldconf->{$opt};
1372             my $new = $delete ? '' : $newconf->{$opt};
1373             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1374         } else {
1375             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1376         }
1377     };
1378
1379     foreach my $opt (keys %$newconf) {
1380         &$check($opt, 0);
1381     }
1382     foreach my $opt (@$delete) {
1383         &$check($opt, 1);
1384     }
1385
1386     return 1;
1387 }
1388
1389 sub umount_all {
1390     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1391
1392     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1393     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1394
1395     my $res = 1;
1396
1397     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1398         my ($ms, $mountpoint) = @_;
1399
1400         my $volid = $mountpoint->{volume};
1401         my $mount = $mountpoint->{mp};
1402
1403         return if !$volid || !$mount;
1404
1405         my $mount_path = "$rootdir/$mount";
1406         $mount_path =~ s!/+!/!g;
1407
1408         return if !PVE::ProcFSTools::is_mounted($mount_path);
1409
1410         eval {
1411             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1412         };
1413         if (my $err = $@) {
1414             if ($noerr) {
1415                 $res = 0;
1416                 warn $err;
1417             } else {
1418                 die $err;
1419             }
1420         }
1421     });
1422
1423     return $res; # tell caller if (some) umounts failed for the noerr case
1424 }
1425
1426 sub mount_all {
1427     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1428
1429     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1430     File::Path::make_path($rootdir);
1431
1432     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1433     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1434
1435     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1436
1437     eval {
1438         PVE::LXC::Config->foreach_volume($conf, sub {
1439             my ($ms, $mountpoint) = @_;
1440
1441             $mountpoint->{ro} = 0 if $ignore_ro;
1442
1443             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1444         });
1445     };
1446     if (my $err = $@) {
1447         warn "mounting container failed\n";
1448         umount_all($vmid, $storage_cfg, $conf, 1);
1449         die $err;
1450     }
1451
1452     return $rootdir;
1453 }
1454
1455
1456 sub mountpoint_mount_path {
1457     my ($mountpoint, $storage_cfg, $snapname) = @_;
1458
1459     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1460 }
1461
1462 sub query_loopdev {
1463     my ($path) = @_;
1464     my $found;
1465     my $parser = sub {
1466         my $line = shift;
1467         if ($line =~ m@^(/dev/loop\d+):@) {
1468             $found = $1;
1469         }
1470     };
1471     my $cmd = ['losetup', '--associated', $path];
1472     PVE::Tools::run_command($cmd, outfunc => $parser);
1473     return $found;
1474 }
1475
1476 # Run a function with a file attached to a loop device.
1477 # The loop device is always detached afterwards (or set to autoclear).
1478 # Returns the loop device.
1479 sub run_with_loopdev {
1480     my ($func, $file, $readonly) = @_;
1481     my $device = query_loopdev($file);
1482     # Try to reuse an existing device
1483     if ($device) {
1484         # We assume that whoever setup the loop device is responsible for
1485         # detaching it.
1486         &$func($device);
1487         return $device;
1488     }
1489
1490     my $parser = sub {
1491         my $line = shift;
1492         if ($line =~ m@^(/dev/loop\d+)$@) {
1493             $device = $1;
1494         }
1495     };
1496     my $losetup_cmd = [
1497         'losetup',
1498         '--show',
1499         '-f',
1500         $file,
1501     ];
1502     push @$losetup_cmd, '-r' if $readonly;
1503     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1504     die "failed to setup loop device for $file\n" if !$device;
1505     eval { &$func($device); };
1506     my $err = $@;
1507     PVE::Tools::run_command(['losetup', '-d', $device]);
1508     die $err if $err;
1509     return $device;
1510 }
1511
1512 # In scalar mode: returns a file handle to the deepest directory node.
1513 # In list context: returns a list of:
1514 #   * the deepest directory node
1515 #   * the 2nd deepest directory (parent of the above)
1516 #   * directory name of the last directory
1517 # So that the path $2/$3 should lead to $1 afterwards.
1518 sub walk_tree_nofollow($$$;$$) {
1519     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1520
1521     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1522         or die "failed to open start directory $start: $!\n";
1523
1524     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1525 }
1526
1527
1528 sub walk_tree_nofollow_fd($$$$;$$) {
1529     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1530
1531     # splitdir() returns '' for empty components including the leading /
1532     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1533
1534     my $fd = $start_fd;
1535     my $dir = $start_dirname;
1536     my $last_component = undef;
1537     my $second = $fd;
1538     foreach my $component (@comps) {
1539         $dir .= "/$component";
1540         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1541
1542         if (!$next) {
1543             # failed, check for symlinks and try to create the path
1544             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1545             die "cannot open directory $dir: $!\n" if !$mkdir;
1546
1547             # We don't check for errors on mkdirat() here and just try to
1548             # openat() again, since at least one error (EEXIST) is an
1549             # expected possibility if multiple containers start
1550             # simultaneously. If someone else injects a symlink now then
1551             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1552             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1553
1554             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1555             die "failed to create path: $dir: $!\n" if !$next;
1556
1557             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1558                 if defined($rootuid) && defined($rootgid);
1559         }
1560
1561         close $second if defined($last_component) && $second != $start_fd;
1562         $last_component = $component;
1563         $second = $fd;
1564         $fd = $next;
1565     }
1566
1567     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1568     close $second if defined($last_component) && $second != $start_fd;
1569     return $fd;
1570 }
1571
1572 # To guard against symlink attack races against other currently running
1573 # containers with shared recursive bind mount hierarchies we prepare a
1574 # directory handle for the directory we're mounting over to verify the
1575 # mountpoint afterwards.
1576 sub __bindmount_prepare {
1577     my ($hostroot, $dir) = @_;
1578     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1579     return $srcdh;
1580 }
1581
1582 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1583 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1584 # we intended to bind mount.
1585 sub __bindmount_verify {
1586     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1587     my $destdh;
1588     if ($parentfd) {
1589         # Open the mount point path coming from the parent directory since the
1590         # filehandle we would have gotten as first result of walk_tree_nofollow
1591         # earlier is still a handle to the underlying directory instead of the
1592         # mounted path.
1593         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1594         die "failed to open mount point: $!\n" if !$destdh;
1595         if ($ro) {
1596             my $dot = '.';
1597             # no separate function because 99% of the time it's the wrong thing to use.
1598             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1599                 die "failed to mark bind mount read only\n";
1600             }
1601             die "read-only check failed: $!\n" if $! != EROFS;
1602         }
1603     } else {
1604         # For the rootfs we don't have a parentfd so we open the path directly.
1605         # Note that this means bindmounting any prefix of the host's
1606         # /var/lib/lxc/$vmid path into another container is considered a grave
1607         # security error.
1608         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1609         die "failed to open mount point: $!\n" if !$destdh;
1610     }
1611
1612     my ($srcdev, $srcinode) = stat($srcdh);
1613     my ($dstdev, $dstinode) = stat($destdh);
1614     close $srcdh;
1615     close $destdh;
1616
1617     return ($srcdev == $dstdev && $srcinode == $dstinode);
1618 }
1619
1620 # Perform the actual bind mounting:
1621 sub __bindmount_do {
1622     my ($dir, $dest, $ro, @extra_opts) = @_;
1623     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1624     if ($ro) {
1625         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1626         if (my $err = $@) {
1627             warn "bindmount error\n";
1628             # don't leave writable bind-mounts behind...
1629             PVE::Tools::run_command(['umount', $dest]);
1630             die $err;
1631         }
1632     }
1633 }
1634
1635 sub bindmount {
1636     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1637
1638     my $srcdh = __bindmount_prepare('/', $dir);
1639
1640     __bindmount_do($dir, $dest, $ro, @extra_opts);
1641
1642     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1643         PVE::Tools::run_command(['umount', $dest]);
1644         die "detected mount path change at: $dir\n";
1645     }
1646 }
1647
1648 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1649 # from $rootdir and $mount and walk the path from $rootdir to the final
1650 # directory to check for symlinks.
1651 sub __mount_prepare_rootdir {
1652     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1653     $rootdir =~ s!/+!/!g;
1654     $rootdir =~ s!/+$!!;
1655     my $mount_path = "$rootdir/$mount";
1656     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1657     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1658 }
1659
1660 # use $rootdir = undef to just return the corresponding mount path
1661 sub mountpoint_mount {
1662     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1663     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1664 }
1665
1666 sub mountpoint_stage {
1667     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1668     my ($path, $loop, $dev) =
1669         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1670
1671     if (!defined($path)) {
1672         return undef if $! == ENOSYS;
1673         die "failed to mount subvolume: $!\n";
1674     }
1675
1676     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1677     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1678     # point).
1679     my $err;
1680     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1681         or die "open_tree() on mount point failed: $!\n";
1682
1683     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1684 }
1685
1686 sub mountpoint_insert_staged {
1687     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1688
1689     if (!defined($rootdir_fd)) {
1690         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1691             or die "failed to open '.': $!\n";
1692     }
1693
1694     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1695
1696     PVE::Tools::move_mount(
1697         fileno($mount_fd),
1698         '',
1699         fileno($dest_fd),
1700         '',
1701         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1702     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1703 }
1704
1705 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1706 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1707 #   Note that if the kernel does not support the new mount API, this will not perform any action
1708 #   and return `undef` with $! = ENOSYS.
1709 sub __mountpoint_mount {
1710     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1711
1712     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1713         $! = ENOSYS;
1714         return undef;
1715     }
1716
1717     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1718     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1719     # which we use in __bindmount_verify()!
1720     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1721
1722     my $volid = $mountpoint->{volume};
1723     my $type = $mountpoint->{type};
1724     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1725     my $mounted_dev;
1726
1727     return if !$volid || !$mount;
1728
1729     $mount =~ s!/+!/!g;
1730
1731     my $mount_path;
1732     my ($mpfd, $parentfd, $last_dir);
1733
1734     if (defined($rootdir)) {
1735         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1736             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1737     }
1738
1739     if (defined($stage_mount)) {
1740         $mount_path = $rootdir;
1741     }
1742
1743     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1744
1745     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1746
1747     my $optlist = [];
1748
1749     if (my $mountopts = $mountpoint->{mountoptions}) {
1750         my @opts = split(/;/, $mountpoint->{mountoptions});
1751         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1752     }
1753
1754     my $acl = $mountpoint->{acl};
1755     if (defined($acl)) {
1756         push @$optlist, ($acl ? 'acl' : 'noacl');
1757     }
1758
1759     my $optstring = join(',', @$optlist);
1760     my $readonly = $mountpoint->{ro};
1761
1762     my @extra_opts;
1763     @extra_opts = ('-o', $optstring) if $optstring;
1764
1765     if ($storage) {
1766
1767         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1768
1769         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1770
1771         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1772
1773         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1774             PVE::Storage::parse_volname($storage_cfg, $volid);
1775
1776         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1777
1778         if ($format eq 'subvol') {
1779             if ($mount_path) {
1780                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1781                 if (defined($snapname)) {
1782                     $name .= "\@$snapname";
1783                     if ($scfg->{type} eq 'zfspool') {
1784                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1785                     } else {
1786                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1787                     }
1788                 } else {
1789                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1790                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1791                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1792                     }
1793                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1794                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1795                 }
1796             }
1797             return wantarray ? ($path, 0, undef) : $path;
1798         } elsif ($format eq 'raw' || $format eq 'iso') {
1799             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1800             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1801             # Our autodev hook expects the /dev/dm-* device currently
1802             # and will create the /dev/mapper symlink accordingly
1803             $path = Cwd::realpath($path);
1804             die "failed to get device path\n" if !$path;
1805             ($path) = ($path =~ /^(.*)$/s); #untaint
1806             my $domount = sub {
1807                 my ($path) = @_;
1808                 if ($mount_path) {
1809                     if ($format eq 'iso') {
1810                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1811                     } elsif ($isBase || defined($snapname)) {
1812                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1813                     } else {
1814                         if ($quota) {
1815                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1816                         }
1817                         push @extra_opts, '-o', 'ro' if $readonly;
1818                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1819                     }
1820                 }
1821             };
1822             my $use_loopdev = 0;
1823             if ($scfg->{content}->{rootdir}) {
1824                 if ($scfg->{path}) {
1825                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1826                     $use_loopdev = 1;
1827                 } else {
1828                     $mounted_dev = $path;
1829                     &$domount($path);
1830                 }
1831             } else {
1832                 die "storage '$storage' does not support containers\n";
1833             }
1834             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1835         } else {
1836             die "unsupported image format '$format'\n";
1837         }
1838     } elsif ($type eq 'device') {
1839         push @extra_opts, '-o', 'ro' if $readonly;
1840         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1841         # See the NOTE above about devicemapper canonicalization
1842         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1843         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1844         return wantarray ? ($volid, 0, $devpath) : $volid;
1845     } elsif ($type eq 'bind') {
1846         die "directory '$volid' does not exist\n" if ! -d $volid;
1847         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1848         warn "cannot enable quota control for bind mounts\n" if $quota;
1849         return wantarray ? ($volid, 0, undef) : $volid;
1850     }
1851
1852     die "unsupported storage";
1853 }
1854
1855 sub mountpoint_hotplug :prototype($$$$$) {
1856     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1857
1858     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1859
1860     # We do the rest in a fork with an unshared mount namespace, because:
1861     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1862     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1863     #     container's namespace, then mount it.
1864
1865     PVE::Tools::run_fork(sub {
1866         # Pin the container pid longer, we also need to get its monitor/parent:
1867         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1868             or die "failed to open pidfd of container $vmid\'s init process\n";
1869
1870         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1871             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1872
1873         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1874         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1875
1876         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1877         # profile to lower our privileges to the same level we have in the start hook:
1878         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1879             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1880         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1881         # apparmor.
1882
1883         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1884         # namespace for it to remain active there since the container will be able to unmount
1885         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1886         # concern.
1887         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1888         chdir('/')
1889             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1890
1891         my $dir = get_staging_mount_path($opt);
1892
1893         # Now switch our apparmor profile before mounting:
1894         my $data = 'changeprofile /usr/bin/lxc-start';
1895         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1896             die "failed to change apparmor profile: $!\n";
1897         }
1898         # Check errors on close as well:
1899         close($aa_fd)
1900             or die "failed to change apparmor profile (close() failed): $!\n";
1901
1902         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1903
1904         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1905         chdir('/')
1906             or die "failed to change root directory within the container's mount namespace: $!\n";
1907
1908         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1909     });
1910 }
1911
1912 # Create a directory in the mountpoint staging tempfs.
1913 sub get_staging_mount_path($) {
1914     my ($opt) = @_;
1915
1916     my $target = get_staging_tempfs() . "/$opt";
1917     if (!mkdir($target) && $! != EEXIST) {
1918         die "failed to create directory $target: $!\n";
1919     }
1920
1921     return $target;
1922 }
1923
1924 # Mount /run/pve/mountpoints as tmpfs
1925 sub get_staging_tempfs() {
1926     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1927     # mounts to that.
1928     my $target = '/var/lib/lxc/.pve-staged-mounts';
1929     if (!mkdir($target)) {
1930         return $target if $! == EEXIST;
1931         die "failed to create directory $target: $!\n";
1932     }
1933
1934     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1935         or die "failed to mount $target as tmpfs: $!\n";
1936
1937     return $target;
1938 }
1939
1940 sub mkfs {
1941     my ($dev, $rootuid, $rootgid) = @_;
1942
1943     run_command(
1944         [
1945             'mkfs.ext4',
1946             '-O',
1947             'mmp',
1948             '-E',
1949             "root_owner=$rootuid:$rootgid",
1950             $dev,
1951         ],
1952         outfunc => sub {
1953             my $line = shift;
1954             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1955             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1956                 print "$line\n";
1957             }
1958         },
1959         errfunc => sub {
1960             my $line = shift;
1961             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1962         }
1963     );
1964 }
1965
1966 sub format_disk {
1967     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1968
1969     if ($volid =~ m!^/dev/.+!) {
1970         mkfs($volid);
1971         return;
1972     }
1973
1974     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1975
1976     die "cannot format volume '$volid' with no storage\n" if !$storage;
1977
1978     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1979
1980     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1981
1982     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1983
1984     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1985         PVE::Storage::parse_volname($storage_cfg, $volid);
1986
1987     die "cannot format volume '$volid' (format == $format)\n"
1988         if $format ne 'raw';
1989
1990     mkfs($path, $rootuid, $rootgid);
1991 }
1992
1993 sub destroy_disks {
1994     my ($storecfg, $vollist) = @_;
1995
1996     foreach my $volid (@$vollist) {
1997         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1998         warn $@ if $@;
1999     }
2000 }
2001
2002 sub alloc_disk {
2003     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
2004
2005     my $needs_chown = 0;
2006     my $volid;
2007
2008     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2009     # fixme: use better naming ct-$vmid-disk-X.raw?
2010
2011     eval {
2012         my $do_format = 0;
2013         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2014             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2015                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2016                 $do_format = 1;
2017             } else {
2018                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2019                 $needs_chown = 1;
2020             }
2021         } elsif ($scfg->{type} eq 'zfspool') {
2022             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2023             $needs_chown = 1;
2024         } elsif ($scfg->{content}->{rootdir}) {
2025             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2026             $do_format = 1;
2027         } else {
2028             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2029         }
2030         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2031     };
2032     if (my $err = $@) {
2033         # in case formatting got interrupted:
2034         if (defined($volid)) {
2035             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2036             warn $@ if $@;
2037         }
2038         die $err;
2039     }
2040
2041     return ($volid, $needs_chown);
2042 }
2043
2044 sub create_disks {
2045     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2046
2047     my $vollist = [];
2048
2049     eval {
2050         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2051         my $chown_vollist = [];
2052
2053         PVE::LXC::Config->foreach_volume($settings, sub {
2054             my ($ms, $mountpoint) = @_;
2055
2056             my $volid = $mountpoint->{volume};
2057             my $mp = $mountpoint->{mp};
2058
2059             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2060
2061             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2062                 my ($storeid, $size_gb) = ($1, $2);
2063
2064                 my $size_kb = int(${size_gb}*1024) * 1024;
2065
2066                 my $needs_chown = 0;
2067                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2068                 push @$chown_vollist, $volid if $needs_chown;
2069                 push @$vollist, $volid;
2070                 $mountpoint->{volume} = $volid;
2071                 $mountpoint->{size} = $size_kb * 1024;
2072                 if ($pending) {
2073                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2074                 } else {
2075                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2076                 }
2077             } else {
2078                 # use specified/existing volid/dir/device
2079                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2080             }
2081         });
2082
2083         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2084         foreach my $volid (@$chown_vollist) {
2085             my $path = PVE::Storage::path($storecfg, $volid, undef);
2086             chown($rootuid, $rootgid, $path);
2087         }
2088         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2089     };
2090     # free allocated images on error
2091     if (my $err = $@) {
2092         destroy_disks($storecfg, $vollist);
2093         die $err;
2094     }
2095     return $vollist;
2096 }
2097
2098 sub update_disksize {
2099     my ($vmid, $conf, $all_volumes) = @_;
2100
2101     my $changes;
2102     my $prefix = "CT $vmid:";
2103
2104     my $update_mp = sub {
2105         my ($key, $mp, @param) = @_;
2106         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2107
2108         if (!defined($mp->{size}) || $size != $mp->{size}) {
2109             $changes = 1;
2110             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2111             $mp->{size} = $size;
2112             my $no_mp = $key eq 'rootfs'; # rootfs is handled different from other mount points
2113             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $no_mp);
2114         }
2115     };
2116
2117     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2118
2119     return $changes;
2120 }
2121
2122 sub update_unused {
2123     my ($vmid, $conf, $all_volumes) = @_;
2124
2125     my $changes;
2126     my $prefix = "CT $vmid:";
2127
2128     # Note: it is allowed to define multiple storage entries with the same path
2129     # (alias), so we need to check both 'volid' and real 'path' (two different
2130     # volid can point to the same path).
2131
2132     # used and unused disks
2133     my $refpath = {};
2134     my $orphans = {};
2135
2136     foreach my $opt (keys %$conf) {
2137         next if ($opt !~ m/^unused\d+$/);
2138         my $vol = $all_volumes->{$conf->{$opt}};
2139         $refpath->{$vol->{path}} = $vol->{volid};
2140     }
2141
2142     foreach my $key (keys %$all_volumes) {
2143         my $vol = $all_volumes->{$key};
2144         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2145         my $path = $vol->{path};
2146
2147         if ($in_use) {
2148             $refpath->{$path} = $key;
2149             delete $orphans->{$path};
2150         } else {
2151             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2152                 $orphans->{$path} = $key;
2153             }
2154         }
2155     }
2156
2157     for my $key (keys %$orphans) {
2158         my $disk = $orphans->{$key};
2159         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2160
2161         if ($unused) {
2162             $changes = 1;
2163             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2164         }
2165     }
2166
2167     return $changes;
2168 }
2169
2170 sub scan_volids {
2171     my ($cfg, $vmid) = @_;
2172
2173     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2174
2175     my $all_volumes = {};
2176     foreach my $storeid (keys %$info) {
2177         foreach my $item (@{$info->{$storeid}}) {
2178             my $volid = $item->{volid};
2179             next if !($volid && $item->{size});
2180             $item->{path} = PVE::Storage::path($cfg, $volid);
2181             $all_volumes->{$volid} = $item;
2182         }
2183     }
2184
2185     return $all_volumes;
2186 }
2187
2188 sub rescan {
2189     my ($vmid, $nolock, $dryrun) = @_;
2190
2191     my $cfg = PVE::Storage::config();
2192
2193     print "rescan volumes...\n";
2194     my $all_volumes = scan_volids($cfg, $vmid);
2195
2196     my $updatefn =  sub {
2197         my ($vmid) = @_;
2198
2199         my $changes;
2200         my $conf = PVE::LXC::Config->load_config($vmid);
2201
2202         PVE::LXC::Config->check_lock($conf);
2203
2204         my $vm_volids = {};
2205         foreach my $volid (keys %$all_volumes) {
2206             my $info = $all_volumes->{$volid};
2207             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2208         }
2209
2210         my $upu = update_unused($vmid, $conf, $vm_volids);
2211         my $upd = update_disksize($vmid, $conf, $vm_volids);
2212         $changes = $upu || $upd;
2213
2214         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2215     };
2216
2217     if (defined($vmid)) {
2218         if ($nolock) {
2219             &$updatefn($vmid);
2220         } else {
2221             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2222         }
2223     } else {
2224         my $vmlist = config_list();
2225         foreach my $vmid (keys %$vmlist) {
2226             if ($nolock) {
2227                 &$updatefn($vmid);
2228             } else {
2229                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2230             }
2231         }
2232     }
2233 }
2234
2235
2236 # bash completion helper
2237
2238 sub complete_os_templates {
2239     my ($cmdname, $pname, $cvalue) = @_;
2240
2241     my $cfg = PVE::Storage::config();
2242
2243     my $storeid;
2244
2245     if ($cvalue =~ m/^([^:]+):/) {
2246         $storeid = $1;
2247     }
2248
2249     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2250     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2251
2252     my $res = [];
2253     foreach my $id (keys %$data) {
2254         foreach my $item (@{$data->{$id}}) {
2255             push @$res, $item->{volid} if defined($item->{volid});
2256         }
2257     }
2258
2259     return $res;
2260 }
2261
2262 my $complete_ctid_full = sub {
2263     my ($running) = @_;
2264
2265     my $idlist = vmstatus();
2266
2267     my $active_hash = list_active_containers();
2268
2269     my $res = [];
2270
2271     foreach my $id (keys %$idlist) {
2272         my $d = $idlist->{$id};
2273         if (defined($running)) {
2274             next if $d->{template};
2275             next if $running && !$active_hash->{$id};
2276             next if !$running && $active_hash->{$id};
2277         }
2278         push @$res, $id;
2279
2280     }
2281     return $res;
2282 };
2283
2284 sub complete_ctid {
2285     return &$complete_ctid_full();
2286 }
2287
2288 sub complete_ctid_stopped {
2289     return &$complete_ctid_full(0);
2290 }
2291
2292 sub complete_ctid_running {
2293     return &$complete_ctid_full(1);
2294 }
2295
2296 sub parse_id_maps {
2297     my ($conf) = @_;
2298
2299     my $id_map = [];
2300     my $rootuid = 0;
2301     my $rootgid = 0;
2302
2303     my $lxc = $conf->{lxc};
2304     foreach my $entry (@$lxc) {
2305         my ($key, $value) = @$entry;
2306         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2307         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2308         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2309             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2310             push @$id_map, [$type, $ct, $host, $length];
2311             if ($ct == 0) {
2312                 $rootuid = $host if $type eq 'u';
2313                 $rootgid = $host if $type eq 'g';
2314             }
2315         } else {
2316             die "failed to parse idmap: $value\n";
2317         }
2318     }
2319
2320     if (!@$id_map && $conf->{unprivileged}) {
2321         # Should we read them from /etc/subuid?
2322         $id_map = [ ['u', '0', '100000', '65536'],
2323                     ['g', '0', '100000', '65536'] ];
2324         $rootuid = $rootgid = 100000;
2325     }
2326
2327     return ($id_map, $rootuid, $rootgid);
2328 }
2329
2330 sub userns_command {
2331     my ($id_map) = @_;
2332     if (@$id_map) {
2333         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2334     }
2335     return [];
2336 }
2337
2338 my sub print_ct_stderr_log {
2339     my ($vmid) = @_;
2340     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2341     return if !$log;
2342
2343     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2344         my $line = $2;
2345         print STDERR "$line\n";
2346     }
2347 }
2348 my sub print_ct_warn_log {
2349     my ($vmid) = @_;
2350     my $log_fn = "/run/pve/ct-$vmid.warnings";
2351     my $log = eval { file_get_contents($log_fn) };
2352     return if !$log;
2353
2354     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2355         PVE::RESTEnvironment::log_warn($1);
2356     }
2357     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2358 }
2359
2360 my sub monitor_state_change($$) {
2361     my ($monitor_socket, $vmid) = @_;
2362     die "no monitor socket\n" if !defined($monitor_socket);
2363
2364     while (1) {
2365         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2366
2367         die "monitor socket: got EOF\n" if !defined($type);
2368
2369         next if $name ne "$vmid" || $type ne 'STATE';
2370
2371         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2372             alarm(0); # don't timeout after seeing the starting state
2373         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2374                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2375                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2376             return 0;
2377         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2378             return 1;
2379         } else {
2380             warn "unexpected message from monitor socket - " .
2381                  "type: '$type' - value: '$value'\n";
2382         }
2383     }
2384 }
2385 my sub monitor_start($$) {
2386     my ($monitor_socket, $vmid) = @_;
2387
2388     my $success = eval {
2389         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2390     };
2391     if (my $err = $@) {
2392         warn "problem with monitor socket, but continuing anyway: $err\n";
2393     } elsif (!$success) {
2394         print_ct_stderr_log($vmid);
2395         die "startup for container '$vmid' failed\n";
2396     }
2397 }
2398
2399 sub vm_start {
2400     my ($vmid, $conf, $skiplock, $debug) = @_;
2401
2402     # apply pending changes while starting
2403     if (scalar(keys %{$conf->{pending}})) {
2404         my $storecfg = PVE::Storage::config();
2405         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2406         PVE::LXC::Config->write_config($vmid, $conf);
2407         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2408     }
2409
2410     update_lxc_config($vmid, $conf);
2411
2412     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2413
2414     if ($skiplock) {
2415         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2416         close($fh);
2417     }
2418
2419     my $storage_cfg = PVE::Storage::config();
2420     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2421
2422     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2423
2424     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2425     warn $@ if $@;
2426
2427     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2428
2429     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2430     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2431
2432     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2433
2434     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2435     eval {
2436         run_command($cmd);
2437
2438         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2439
2440         # if debug is requested, print the log it also when the start succeeded
2441         print_ct_stderr_log($vmid) if $is_debug;
2442
2443         print_ct_warn_log($vmid); # always print warn log, if any
2444     };
2445     if (my $err = $@) {
2446         unlink $skiplock_flag_fn;
2447         die $err;
2448     }
2449     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2450
2451     return;
2452 }
2453
2454 # Helper to stop a container completely and make sure it has stopped completely.
2455 # This is necessary because we want the post-stop hook to have completed its
2456 # unmount-all step, but post-stop happens after lxc puts the container into the
2457 # STOPPED state.
2458 # $kill - if true it will always do an immediate hard-stop
2459 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2460 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2461 sub vm_stop {
2462     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2463
2464     # Open the container's command socket.
2465     my $path = "\0/var/lib/lxc/$vmid/command";
2466     my $sock = IO::Socket::UNIX->new(
2467         Type => SOCK_STREAM(),
2468         Peer => $path,
2469     );
2470     if (!$sock) {
2471         return if $! == ECONNREFUSED; # The container is not running
2472         die "failed to open container ${vmid}'s command socket: $!\n";
2473     }
2474
2475     my $conf = PVE::LXC::Config->load_config($vmid);
2476     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2477
2478     # Stop the container:
2479
2480     my $cmd = ['lxc-stop', '-n', $vmid];
2481
2482     if ($kill) {
2483         push @$cmd, '--kill'; # doesn't allow timeouts
2484     } else {
2485         # lxc-stop uses a default timeout
2486         push @$cmd, '--nokill' if !$kill_after_timeout;
2487
2488         if (defined($shutdown_timeout)) {
2489             push @$cmd, '--timeout', $shutdown_timeout;
2490             # Give run_command 5 extra seconds
2491             $shutdown_timeout += 5;
2492         }
2493     }
2494
2495     eval { run_command($cmd, timeout => $shutdown_timeout) };
2496
2497     # Wait until the command socket is closed.
2498     # In case the lxc-stop call failed, reading from the command socket may block forever,
2499     # so poll with another timeout to avoid freezing the shutdown task.
2500     if (my $err = $@) {
2501         warn $err if $err;
2502
2503         my $poll = IO::Poll->new();
2504         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2505         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2506         return if ($poll->events($sock) & POLLHUP);
2507     } else {
2508         my $result = <$sock>;
2509         return if !defined $result; # monitor is gone and the ct has stopped.
2510     }
2511
2512     die "container did not stop\n";
2513 }
2514
2515 sub vm_reboot {
2516     my ($vmid, $timeout, $skiplock) = @_;
2517
2518     PVE::LXC::Config->lock_config($vmid, sub {
2519         return if !check_running($vmid);
2520
2521         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2522
2523         my $conf = PVE::LXC::Config->load_config($vmid);
2524         vm_start($vmid, $conf);
2525     });
2526 }
2527
2528 sub run_unshared {
2529     my ($code) = @_;
2530
2531     return PVE::Tools::run_fork(sub {
2532         # Unshare the mount namespace
2533         die "failed to unshare mount namespace: $!\n"
2534             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2535         run_command(['mount', '--make-rslave', '/']);
2536         return $code->();
2537     });
2538 }
2539
2540 my $copy_volume = sub {
2541     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2542
2543     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2544     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2545
2546     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2547     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2548
2549     my @mounted;
2550     eval {
2551         # mount and copy
2552         mkdir $src;
2553         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2554         push @mounted, $src;
2555         mkdir $dest;
2556         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2557         push @mounted, $dest;
2558
2559         $bwlimit //= 0;
2560
2561         run_command([
2562             'rsync',
2563             '--stats',
2564             '-X',
2565             '-A',
2566             '--numeric-ids',
2567             '-aH',
2568             '--whole-file',
2569             '--sparse',
2570             '--one-file-system',
2571             "--bwlimit=$bwlimit",
2572             "$src/",
2573             $dest
2574         ]);
2575     };
2576     my $err = $@;
2577
2578     # Wait for rsync's children to release dest so that
2579     # consequent file operations (umount, remove) are possible
2580     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2581
2582     foreach my $mount (reverse @mounted) {
2583         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2584         warn "Can't umount $mount\n" if $@;
2585     }
2586
2587     # If this fails they're used as mount points in a concurrent operation
2588     # (which should not happen but there's also no real need to get rid of them).
2589     rmdir $dest;
2590     rmdir $src;
2591
2592     die $err if $err;
2593 };
2594
2595 # Should not be called after unsharing the mount namespace!
2596 sub copy_volume {
2597     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2598
2599     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2600     File::Path::make_path("/var/lib/lxc/$vmid");
2601     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2602     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2603
2604     # get id's for unprivileged container
2605     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2606
2607     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2608     # are visible in this namespace, otherwise the host only sees the empty
2609     # (not-mounted) directory.
2610     my $new_volid;
2611     eval {
2612         # Make sure $mp contains a correct size.
2613         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2614         my $needs_chown;
2615         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2616         if ($needs_chown) {
2617             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2618             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2619             chown($rootuid, $rootgid, $path);
2620         }
2621
2622         run_unshared(sub {
2623             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2624         });
2625     };
2626     if (my $err = $@) {
2627         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2628             if defined($new_volid);
2629         die $err;
2630     }
2631
2632     return $new_volid;
2633 }
2634
2635 sub get_lxc_version() {
2636     my $version;
2637     run_command([qw(lxc-start --version)], outfunc => sub {
2638         my ($line) = @_;
2639         # We only parse out major & minor version numbers.
2640         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2641             $version = [$1, $2];
2642         }
2643     });
2644
2645     die "failed to get lxc version\n" if !defined($version);
2646
2647     # return as a list:
2648     return $version->@*;
2649 }
2650
2651 sub freeze($) {
2652     my ($vmid) = @_;
2653     if (PVE::CGroup::cgroup_mode() == 2) {
2654         PVE::LXC::Command::freeze($vmid, 30);
2655     } else {
2656         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2657     }
2658 }
2659
2660 sub thaw($) {
2661     my ($vmid) = @_;
2662     if (PVE::CGroup::cgroup_mode() == 2) {
2663         PVE::LXC::Command::unfreeze($vmid, 30);
2664     } else {
2665         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2666     }
2667 }
2668
2669 1;