src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     run_command
  24     dir_glob_foreach
  25     file_get_contents
  26     file_set_contents
  27     AT_FDCWD
  28     O_PATH
  29     $IPV4RE
  30     $IPV6RE
  31 );
  32 use PVE::CpuSet;
  33 use PVE::Network;
  34 use PVE::AccessControl;
  35 use PVE::ProcFSTools;
  36 use PVE::RESTEnvironment;
  37 use PVE::Syscall qw(:fsmount);
  38 use PVE::LXC::Config;
  39 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  40 use PVE::LXC::Tools;
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Monitor;
  43 use PVE::CGroup;
  44
  45 use Time::HiRes qw (gettimeofday);
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         my $lxcmem = int($memory*1024*1024);
 689         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 690
 691         my $lxcswap = int($swap*1024*1024);
 692         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 693     }
 694
 695     if ($cgv1->{cpu}) {
 696         if (my $cpulimit = $conf->{cpulimit}) {
 697             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 698             my $value = int(100000*$cpulimit);
 699             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 700         }
 701
 702         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 703         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 704     } elsif ($cgv2->{cpu}) {
 705         # See PVE::CGroup
 706         if (my $cpulimit = $conf->{cpulimit}) {
 707             my $value = int(100000*$cpulimit);
 708             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 709         }
 710
 711         if (defined(my $shares = $conf->{cpuunits})) {
 712             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 713             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 714         }
 715     }
 716
 717     die "missing 'rootfs' configuration\n"
 718         if !defined($conf->{rootfs});
 719
 720     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 721
 722     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 723
 724     foreach my $k (sort keys %$conf) {
 725         next if $k !~ m/^net(\d+)$/;
 726         my $ind = $1;
 727         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 728         $raw .= "lxc.net.$ind.type = veth\n";
 729         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 730         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 731         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 732
 733         # Keep container from starting with invalid mtu configuration
 734         if (my $mtu = $d->{mtu}) {
 735             my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 736             die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 737                 if ($mtu > $bridge_mtu);
 738
 739             $raw .= "lxc.net.$ind.mtu = $mtu\n";
 740         }
 741
 742         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 743         if ($lxc_major >= 4) {
 744             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 745         }
 746     }
 747
 748     my $had_cpuset = 0;
 749     if (my $lxcconf = $conf->{lxc}) {
 750         foreach my $entry (@$lxcconf) {
 751             my ($k, $v) = @$entry;
 752             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 753             $raw .= "$k = $v\n";
 754         }
 755     }
 756
 757     my $cpuset;
 758     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 759     if (defined($cpuset_cgroup)) {
 760         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 761             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 762     }
 763     my $cores = $conf->{cores};
 764     if (!$had_cpuset && $cores && $cpuset) {
 765         my @members = $cpuset->members();
 766         while (scalar(@members) > $cores) {
 767             my $randidx = int(rand(scalar(@members)));
 768             $cpuset->delete($members[$randidx]);
 769             splice(@members, $randidx, 1); # keep track of the changes
 770         }
 771         my $ver = $cpuset_version == 1 ? '' : '2';
 772         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 773     }
 774
 775     File::Path::mkpath("$dir/rootfs");
 776
 777     PVE::Tools::file_set_contents("$dir/config", $raw);
 778 }
 779
 780 # verify and cleanup nameserver list (replace \0 with ' ')
 781 sub verify_nameserver_list {
 782     my ($nameserver_list) = @_;
 783
 784     my @list = ();
 785     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 786         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 787         push @list, $server;
 788     }
 789
 790     return join(' ', @list);
 791 }
 792
 793 sub verify_searchdomain_list {
 794     my ($searchdomain_list) = @_;
 795
 796     my @list = ();
 797     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 798         # todo: should we add checks for valid dns domains?
 799         push @list, $server;
 800     }
 801
 802     return join(' ', @list);
 803 }
 804
 805 sub get_console_command {
 806     my ($vmid, $conf, $escapechar) = @_;
 807
 808     # '-1' as $escapechar disables keyboard escape sequence
 809     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 810
 811     my $cmode = PVE::LXC::Config->get_cmode($conf);
 812
 813     my $cmd = [];
 814     if ($cmode eq 'console') {
 815         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 816         push @$cmd, '-e', $escapechar if $escapechar;
 817     } elsif ($cmode eq 'tty') {
 818         push @$cmd, 'lxc-console', '-n',  $vmid;
 819         push @$cmd, '-e', $escapechar if $escapechar;
 820     } elsif ($cmode eq 'shell') {
 821         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 822     } else {
 823         die "internal error";
 824     }
 825
 826     return $cmd;
 827 }
 828
 829 sub get_primary_ips {
 830     my ($conf) = @_;
 831
 832     # return data from net0
 833
 834     return undef if !defined($conf->{net0});
 835     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 836
 837     my $ipv4 = $net->{ip};
 838     if ($ipv4) {
 839         if ($ipv4 =~ /^(dhcp|manual)$/) {
 840             $ipv4 = undef
 841         } else {
 842             $ipv4 =~ s!/\d+$!!;
 843         }
 844     }
 845     my $ipv6 = $net->{ip6};
 846     if ($ipv6) {
 847         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 848             $ipv6 = undef;
 849         } else {
 850             $ipv6 =~ s!/\d+$!!;
 851         }
 852     }
 853
 854     return ($ipv4, $ipv6);
 855 }
 856
 857 sub delete_mountpoint_volume {
 858     my ($storage_cfg, $vmid, $volume) = @_;
 859
 860     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 861
 862     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 863
 864     if ($vmid == $owner) {
 865         PVE::Storage::vdisk_free($storage_cfg, $volume);
 866     } else {
 867         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 868     }
 869 }
 870
 871 sub destroy_lxc_container {
 872     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 873
 874     my $volids = {};
 875     my $remove_volume = sub {
 876         my ($ms, $mountpoint) = @_;
 877
 878         my $volume = $mountpoint->{volume};
 879
 880         return if $volids->{$volume};
 881         $volids->{$volume} = 1;
 882
 883         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 884     };
 885     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 886
 887     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 888
 889     if ($purge_unreferenced) { # also remove unreferenced disk
 890         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 891         PVE::Storage::foreach_volid($vmdisks, sub {
 892             my ($volid, $sid, $volname, $d) = @_;
 893             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 894             warn $@ if $@;
 895         });
 896     }
 897
 898     rmdir "/var/lib/lxc/$vmid/rootfs";
 899     unlink "/var/lib/lxc/$vmid/config";
 900     rmdir "/var/lib/lxc/$vmid";
 901     if (defined $replacement_conf) {
 902         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 903     } else {
 904         PVE::LXC::Config->destroy_config($vmid);
 905     }
 906 }
 907
 908 sub vm_stop_cleanup {
 909     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 910
 911     return if $keepActive;
 912
 913     eval {
 914         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 915         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 916     };
 917     warn $@ if $@; # avoid errors - just warn
 918 }
 919
 920 sub update_net {
 921     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 922
 923     if ($newnet->{type} ne 'veth') {
 924         # for when there are physical interfaces
 925         die "cannot update interface of type $newnet->{type}";
 926     }
 927
 928     my $veth = "veth${vmid}i${netid}";
 929     my $eth = $newnet->{name};
 930
 931     if (my $oldnetcfg = $conf->{$opt}) {
 932         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 933
 934         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 935             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 936
 937             PVE::Network::veth_delete($veth);
 938             delete $conf->{$opt};
 939             PVE::LXC::Config->write_config($vmid, $conf);
 940
 941             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 942
 943         } else {
 944             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 945                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 946                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})
 947             ) {
 948
 949                 if ($oldnet->{bridge}) {
 950                     PVE::Network::tap_unplug($veth);
 951                     foreach (qw(bridge tag firewall)) {
 952                         delete $oldnet->{$_};
 953                     }
 954                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 955                     PVE::LXC::Config->write_config($vmid, $conf);
 956                 }
 957
 958                 my ($bridge, $mac, $firewall, $rate) = $newnet->@{'bridge', 'hwaddr', 'firewall', 'rate'};
 959                 if ($have_sdn) {
 960                     PVE::Network::SDN::Zones::tap_plug(
 961                         $veth, $bridge, $newnet->{tag}, $firewall, $newnet->{trunks}, $rate);
 962                     PVE::Network::SDN::Zones::add_bridge_fdb($veth, $mac, $bridge, $firewall);
 963                 } else {
 964                     PVE::Network::tap_plug(
 965                         $veth, $bridge, $newnet->{tag}, $firewall, $newnet->{trunks}, $rate, { mac => $mac });
 966                 }
 967
 968                 # This includes the rate:
 969                 foreach (qw(bridge tag firewall rate)) {
 970                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 971                 }
 972             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 973                 # Rate can be applied on its own but any change above needs to
 974                 # include the rate in tap_plug since OVS resets everything.
 975                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 976                 $oldnet->{rate} = $newnet->{rate}
 977             }
 978             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 979             PVE::LXC::Config->write_config($vmid, $conf);
 980         }
 981     } else {
 982         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 983     }
 984
 985     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 986 }
 987
 988 sub hotplug_net {
 989     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 990
 991     my $veth = "veth${vmid}i${netid}";
 992     my $vethpeer = $veth . "p";
 993     my $eth = $newnet->{name};
 994
 995     if ($have_sdn) {
 996         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 997         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 998         PVE::Network::SDN::Zones::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{bridge}, $newnet->{firewall});
 999     } else {
1000         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1001         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
1002         PVE::Network::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{firewall}); # early returns if brport has learning on
1003     }
1004
1005     # attach peer in container
1006     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1007     PVE::Tools::run_command($cmd);
1008
1009     # link up peer in container
1010     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1011     PVE::Tools::run_command($cmd);
1012
1013     my $done = { type => 'veth' };
1014     foreach (qw(bridge tag firewall hwaddr name)) {
1015         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1016     }
1017     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1018
1019     PVE::LXC::Config->write_config($vmid, $conf);
1020 }
1021
1022 sub update_ipconfig {
1023     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1024
1025     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1026
1027     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1028     my $deleted = [];
1029     my $added = [];
1030     my $nscmd = sub {
1031         my $cmdargs = shift;
1032         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1033     };
1034     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1035
1036     my $change_ip_config = sub {
1037         my ($ipversion) = @_;
1038
1039         my $family_opt = "-$ipversion";
1040         my $suffix = $ipversion == 4 ? '' : $ipversion;
1041         my $gw= "gw$suffix";
1042         my $ip= "ip$suffix";
1043
1044         my $newip = $newnet->{$ip};
1045         my $newgw = $newnet->{$gw};
1046         my $oldip = $optdata->{$ip};
1047         my $oldgw = $optdata->{$gw};
1048
1049         my $change_ip = safe_string_ne($oldip, $newip);
1050         my $change_gw = safe_string_ne($oldgw, $newgw);
1051
1052         return if !$change_ip && !$change_gw;
1053
1054         # step 1: add new IP, if this fails we cancel
1055         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1056         if ($change_ip && $is_real_ip) {
1057             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1058             if (my $err = $@) {
1059                 warn $err;
1060                 return;
1061             }
1062         }
1063
1064         # step 2: replace gateway
1065         #   If this fails we delete the added IP and cancel.
1066         #   If it succeeds we save the config and delete the old IP, ignoring
1067         #   errors. The config is then saved.
1068         # Note: 'ip route replace' can add
1069         if ($change_gw) {
1070             if ($newgw) {
1071                 eval {
1072                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1073                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1074                     }
1075                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1076                 };
1077                 if (my $err = $@) {
1078                     warn $err;
1079                     # the route was not replaced, the old IP is still available
1080                     # rollback (delete new IP) and cancel
1081                     if ($change_ip) {
1082                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1083                         warn $@ if $@; # no need to die here
1084                     }
1085                     return;
1086                 }
1087             } else {
1088                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1089                 # if the route was not deleted, the guest might have deleted it manually
1090                 # warn and continue
1091                 warn $@ if $@;
1092             }
1093             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1094                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1095                 # warn if the route was deleted manually
1096                 warn $@ if $@;
1097             }
1098         }
1099
1100         # from this point on we save the configuration
1101         # step 3: delete old IP ignoring errors
1102         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1103             # We need to enable promote_secondaries, otherwise our newly added
1104             # address will be removed along with the old one.
1105             my $promote = 0;
1106             eval {
1107                 if ($ipversion == 4) {
1108                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1109                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1110                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1111                 }
1112                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1113             };
1114             warn $@ if $@; # no need to die here
1115
1116             if ($ipversion == 4) {
1117                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1118             }
1119         }
1120
1121         foreach my $property ($ip, $gw) {
1122             if ($newnet->{$property}) {
1123                 $optdata->{$property} = $newnet->{$property};
1124             } else {
1125                 delete $optdata->{$property};
1126             }
1127         }
1128         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1129         PVE::LXC::Config->write_config($vmid, $conf);
1130         $lxc_setup->setup_network($conf);
1131     };
1132
1133     &$change_ip_config(4);
1134     &$change_ip_config(6);
1135
1136 }
1137
1138 my $open_namespace = sub {
1139     my ($vmid, $pid, $kind) = @_;
1140     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1141         or die "failed to open $kind namespace of container $vmid: $!\n";
1142     return $fd;
1143 };
1144
1145 my $enter_namespace = sub {
1146     my ($vmid, $pid, $kind, $type) = @_;
1147     my $fd = $open_namespace->($vmid, $pid, $kind);
1148     PVE::Tools::setns(fileno($fd), $type)
1149         or die "failed to enter $kind namespace of container $vmid: $!\n";
1150     close $fd;
1151 };
1152
1153 my $get_container_namespace = sub {
1154     my ($vmid, $pid, $kind) = @_;
1155
1156     my $pidfd;
1157     if (!defined($pid)) {
1158         # Pin the pid while we're grabbing its stuff from /proc
1159         ($pid, $pidfd) = open_lxc_pid($vmid)
1160             or die "failed to open pidfd of container $vmid\'s init process\n";
1161     }
1162
1163     return $open_namespace->($vmid, $pid, $kind);
1164 };
1165
1166 my $do_syncfs = sub {
1167     my ($vmid, $pid, $socket) = @_;
1168
1169     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1170
1171     # Tell the parent process to start reading our /proc/mounts
1172     print {$socket} "go\n";
1173     $socket->flush();
1174
1175     # Receive /proc/self/mounts
1176     my $mountdata = do { local $/ = undef; <$socket> };
1177     close $socket;
1178
1179     my %nosyncfs = (
1180         cgroup => 1,
1181         cgroup2 => 1,
1182         devtmpfs => 1,
1183         devpts => 1,
1184         'fuse.lxcfs' => 1,
1185         fusectl => 1,
1186         mqueue => 1,
1187         proc => 1,
1188         sysfs => 1,
1189         tmpfs => 1,
1190     );
1191
1192     # Now sync all mountpoints...
1193     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1194     foreach my $mp (@$mounts) {
1195         my ($what, $dir, $fs) = @$mp;
1196         next if $nosyncfs{$fs};
1197         eval { PVE::Tools::sync_mountpoint($dir); };
1198         warn $@ if $@;
1199     }
1200 };
1201
1202 sub sync_container_namespace {
1203     my ($vmid) = @_;
1204     my $pid = find_lxc_pid($vmid);
1205
1206     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1207     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1208         or die "failed to create socketpair: $!\n";
1209
1210     my $child = fork();
1211     die "fork failed: $!\n" if !defined($child);
1212
1213     if (!$child) {
1214         eval {
1215             close $pfd;
1216             &$do_syncfs($vmid, $pid, $cfd);
1217         };
1218         if (my $err = $@) {
1219             warn $err;
1220             POSIX::_exit(1);
1221         }
1222         POSIX::_exit(0);
1223     }
1224     close $cfd;
1225     my $go = <$pfd>;
1226     die "failed to enter container namespace\n" if $go ne "go\n";
1227
1228     open my $mounts, '<', "/proc/$child/mounts"
1229         or die "failed to open container's /proc/mounts: $!\n";
1230     my $mountdata = do { local $/ = undef; <$mounts> };
1231     close $mounts;
1232     print {$pfd} $mountdata;
1233     close $pfd;
1234
1235     while (waitpid($child, 0) != $child) {}
1236     die "failed to sync container namespace\n" if $? != 0;
1237 }
1238
1239 sub template_create {
1240     my ($vmid, $conf) = @_;
1241
1242     my $storecfg = PVE::Storage::config();
1243
1244     PVE::LXC::Config->foreach_volume($conf, sub {
1245         my ($ms, $mountpoint) = @_;
1246
1247         my $volid = $mountpoint->{volume};
1248
1249         die "Template feature is not available for '$volid'\n"
1250             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1251     });
1252
1253     PVE::LXC::Config->foreach_volume($conf, sub {
1254         my ($ms, $mountpoint) = @_;
1255
1256         my $volid = $mountpoint->{volume};
1257
1258         PVE::Storage::activate_volumes($storecfg, [$volid]);
1259
1260         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1261         $mountpoint->{volume} = $template_volid;
1262         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1263     });
1264
1265     PVE::LXC::Config->write_config($vmid, $conf);
1266 }
1267
1268 sub check_ct_modify_config_perm {
1269     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1270
1271     return 1 if $authuser eq 'root@pam';
1272     my $storage_cfg = PVE::Storage::config();
1273
1274     my $check = sub {
1275         my ($opt, $delete) = @_;
1276         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1277             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1278         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1279             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1280             return if $delete;
1281             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1282             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1283                 if $data->{type} ne 'volume';
1284             my $volid = $data->{volume};
1285             if ($volid =~ $NEW_DISK_RE) {
1286                 my $sid = $1;
1287                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1288             } else {
1289                 PVE::Storage::check_volume_access(
1290                     $rpcenv,
1291                     $authuser,
1292                     $storage_cfg,
1293                     $vmid,
1294                     $volid,
1295                     'rootdir',
1296                 );
1297             }
1298         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1299             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1300         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1301                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1302             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1303         } elsif ($opt eq 'features') {
1304             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1305                 if !$unprivileged;
1306
1307             my $nesting_changed = 0;
1308             my $other_changed = 0;
1309             if (!$delete) {
1310                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1311                 if (defined($oldconf) && $oldconf->{$opt}) {
1312                     # existing container with features
1313                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1314                     for my $feature ((keys %$old_features, keys %$features)) {
1315                         my $old = $old_features->{$feature} // '';
1316                         my $new = $features->{$feature} // '';
1317                         if ($old ne $new) {
1318                             if ($feature eq 'nesting') {
1319                                 $nesting_changed = 1;
1320                                 next;
1321                             } else {
1322                                 $other_changed = 1;
1323                                 last;
1324                             }
1325                         }
1326                     }
1327                 } else {
1328                     # new container or no features defined
1329                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1330                         $nesting_changed = 1;
1331                     } elsif (scalar(keys %$features) > 0) {
1332                         $other_changed = 1;
1333                     }
1334                 }
1335             } else {
1336                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1337                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1338                     $nesting_changed = 1;
1339                 } elsif (scalar(keys %$features) > 0) {
1340                     $other_changed = 1;
1341                 }
1342             }
1343             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1344                 if $other_changed;
1345             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1346                 if $nesting_changed;
1347         } elsif ($opt eq 'hookscript') {
1348             # For now this is restricted to root@pam
1349             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1350         } elsif ($opt eq 'tags') {
1351             my $old = $oldconf->{$opt};
1352             my $new = $delete ? '' : $newconf->{$opt};
1353             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1354         } else {
1355             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1356         }
1357     };
1358
1359     foreach my $opt (keys %$newconf) {
1360         &$check($opt, 0);
1361     }
1362     foreach my $opt (@$delete) {
1363         &$check($opt, 1);
1364     }
1365
1366     return 1;
1367 }
1368
1369 sub umount_all {
1370     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1371
1372     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1373     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1374
1375     my $res = 1;
1376
1377     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1378         my ($ms, $mountpoint) = @_;
1379
1380         my $volid = $mountpoint->{volume};
1381         my $mount = $mountpoint->{mp};
1382
1383         return if !$volid || !$mount;
1384
1385         my $mount_path = "$rootdir/$mount";
1386         $mount_path =~ s!/+!/!g;
1387
1388         return if !PVE::ProcFSTools::is_mounted($mount_path);
1389
1390         eval {
1391             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1392         };
1393         if (my $err = $@) {
1394             if ($noerr) {
1395                 $res = 0;
1396                 warn $err;
1397             } else {
1398                 die $err;
1399             }
1400         }
1401     });
1402
1403     return $res; # tell caller if (some) umounts failed for the noerr case
1404 }
1405
1406 sub mount_all {
1407     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1408
1409     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1410     File::Path::make_path($rootdir);
1411
1412     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1413     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1414
1415     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1416
1417     eval {
1418         PVE::LXC::Config->foreach_volume($conf, sub {
1419             my ($ms, $mountpoint) = @_;
1420
1421             $mountpoint->{ro} = 0 if $ignore_ro;
1422
1423             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1424         });
1425     };
1426     if (my $err = $@) {
1427         warn "mounting container failed\n";
1428         umount_all($vmid, $storage_cfg, $conf, 1);
1429         die $err;
1430     }
1431
1432     return $rootdir;
1433 }
1434
1435
1436 sub mountpoint_mount_path {
1437     my ($mountpoint, $storage_cfg, $snapname) = @_;
1438
1439     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1440 }
1441
1442 sub query_loopdev {
1443     my ($path) = @_;
1444     my $found;
1445     my $parser = sub {
1446         my $line = shift;
1447         if ($line =~ m@^(/dev/loop\d+):@) {
1448             $found = $1;
1449         }
1450     };
1451     my $cmd = ['losetup', '--associated', $path];
1452     PVE::Tools::run_command($cmd, outfunc => $parser);
1453     return $found;
1454 }
1455
1456 # Run a function with a file attached to a loop device.
1457 # The loop device is always detached afterwards (or set to autoclear).
1458 # Returns the loop device.
1459 sub run_with_loopdev {
1460     my ($func, $file, $readonly) = @_;
1461     my $device = query_loopdev($file);
1462     # Try to reuse an existing device
1463     if ($device) {
1464         # We assume that whoever setup the loop device is responsible for
1465         # detaching it.
1466         &$func($device);
1467         return $device;
1468     }
1469
1470     my $parser = sub {
1471         my $line = shift;
1472         if ($line =~ m@^(/dev/loop\d+)$@) {
1473             $device = $1;
1474         }
1475     };
1476     my $losetup_cmd = [
1477         'losetup',
1478         '--show',
1479         '-f',
1480         $file,
1481     ];
1482     push @$losetup_cmd, '-r' if $readonly;
1483     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1484     die "failed to setup loop device for $file\n" if !$device;
1485     eval { &$func($device); };
1486     my $err = $@;
1487     PVE::Tools::run_command(['losetup', '-d', $device]);
1488     die $err if $err;
1489     return $device;
1490 }
1491
1492 # In scalar mode: returns a file handle to the deepest directory node.
1493 # In list context: returns a list of:
1494 #   * the deepest directory node
1495 #   * the 2nd deepest directory (parent of the above)
1496 #   * directory name of the last directory
1497 # So that the path $2/$3 should lead to $1 afterwards.
1498 sub walk_tree_nofollow($$$;$$) {
1499     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1500
1501     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1502         or die "failed to open start directory $start: $!\n";
1503
1504     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1505 }
1506
1507
1508 sub walk_tree_nofollow_fd($$$$;$$) {
1509     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1510
1511     # splitdir() returns '' for empty components including the leading /
1512     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1513
1514     my $fd = $start_fd;
1515     my $dir = $start_dirname;
1516     my $last_component = undef;
1517     my $second = $fd;
1518     foreach my $component (@comps) {
1519         $dir .= "/$component";
1520         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1521
1522         if (!$next) {
1523             # failed, check for symlinks and try to create the path
1524             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1525             die "cannot open directory $dir: $!\n" if !$mkdir;
1526
1527             # We don't check for errors on mkdirat() here and just try to
1528             # openat() again, since at least one error (EEXIST) is an
1529             # expected possibility if multiple containers start
1530             # simultaneously. If someone else injects a symlink now then
1531             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1532             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1533
1534             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1535             die "failed to create path: $dir: $!\n" if !$next;
1536
1537             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1538                 if defined($rootuid) && defined($rootgid);
1539         }
1540
1541         close $second if defined($last_component) && $second != $start_fd;
1542         $last_component = $component;
1543         $second = $fd;
1544         $fd = $next;
1545     }
1546
1547     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1548     close $second if defined($last_component) && $second != $start_fd;
1549     return $fd;
1550 }
1551
1552 # To guard against symlink attack races against other currently running
1553 # containers with shared recursive bind mount hierarchies we prepare a
1554 # directory handle for the directory we're mounting over to verify the
1555 # mountpoint afterwards.
1556 sub __bindmount_prepare {
1557     my ($hostroot, $dir) = @_;
1558     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1559     return $srcdh;
1560 }
1561
1562 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1563 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1564 # we intended to bind mount.
1565 sub __bindmount_verify {
1566     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1567     my $destdh;
1568     if ($parentfd) {
1569         # Open the mount point path coming from the parent directory since the
1570         # filehandle we would have gotten as first result of walk_tree_nofollow
1571         # earlier is still a handle to the underlying directory instead of the
1572         # mounted path.
1573         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1574         die "failed to open mount point: $!\n" if !$destdh;
1575         if ($ro) {
1576             my $dot = '.';
1577             # no separate function because 99% of the time it's the wrong thing to use.
1578             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1579                 die "failed to mark bind mount read only\n";
1580             }
1581             die "read-only check failed: $!\n" if $! != EROFS;
1582         }
1583     } else {
1584         # For the rootfs we don't have a parentfd so we open the path directly.
1585         # Note that this means bindmounting any prefix of the host's
1586         # /var/lib/lxc/$vmid path into another container is considered a grave
1587         # security error.
1588         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1589         die "failed to open mount point: $!\n" if !$destdh;
1590     }
1591
1592     my ($srcdev, $srcinode) = stat($srcdh);
1593     my ($dstdev, $dstinode) = stat($destdh);
1594     close $srcdh;
1595     close $destdh;
1596
1597     return ($srcdev == $dstdev && $srcinode == $dstinode);
1598 }
1599
1600 # Perform the actual bind mounting:
1601 sub __bindmount_do {
1602     my ($dir, $dest, $ro, @extra_opts) = @_;
1603     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1604     if ($ro) {
1605         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1606         if (my $err = $@) {
1607             warn "bindmount error\n";
1608             # don't leave writable bind-mounts behind...
1609             PVE::Tools::run_command(['umount', $dest]);
1610             die $err;
1611         }
1612     }
1613 }
1614
1615 sub bindmount {
1616     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1617
1618     my $srcdh = __bindmount_prepare('/', $dir);
1619
1620     __bindmount_do($dir, $dest, $ro, @extra_opts);
1621
1622     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1623         PVE::Tools::run_command(['umount', $dest]);
1624         die "detected mount path change at: $dir\n";
1625     }
1626 }
1627
1628 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1629 # from $rootdir and $mount and walk the path from $rootdir to the final
1630 # directory to check for symlinks.
1631 sub __mount_prepare_rootdir {
1632     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1633     $rootdir =~ s!/+!/!g;
1634     $rootdir =~ s!/+$!!;
1635     my $mount_path = "$rootdir/$mount";
1636     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1637     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1638 }
1639
1640 # use $rootdir = undef to just return the corresponding mount path
1641 sub mountpoint_mount {
1642     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1643     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1644 }
1645
1646 sub mountpoint_stage {
1647     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1648     my ($path, $loop, $dev) =
1649         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1650
1651     if (!defined($path)) {
1652         return undef if $! == ENOSYS;
1653         die "failed to mount subvolume: $!\n";
1654     }
1655
1656     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1657     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1658     # point).
1659     my $err;
1660     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1661         or die "open_tree() on mount point failed: $!\n";
1662
1663     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1664 }
1665
1666 sub mountpoint_insert_staged {
1667     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1668
1669     if (!defined($rootdir_fd)) {
1670         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1671             or die "failed to open '.': $!\n";
1672     }
1673
1674     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1675
1676     PVE::Tools::move_mount(
1677         fileno($mount_fd),
1678         '',
1679         fileno($dest_fd),
1680         '',
1681         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1682     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1683 }
1684
1685 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1686 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1687 #   Note that if the kernel does not support the new mount API, this will not perform any action
1688 #   and return `undef` with $! = ENOSYS.
1689 sub __mountpoint_mount {
1690     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1691
1692     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1693         $! = ENOSYS;
1694         return undef;
1695     }
1696
1697     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1698     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1699     # which we use in __bindmount_verify()!
1700     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1701
1702     my $volid = $mountpoint->{volume};
1703     my $type = $mountpoint->{type};
1704     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1705     my $mounted_dev;
1706
1707     return if !$volid || !$mount;
1708
1709     $mount =~ s!/+!/!g;
1710
1711     my $mount_path;
1712     my ($mpfd, $parentfd, $last_dir);
1713
1714     if (defined($rootdir)) {
1715         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1716             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1717     }
1718
1719     if (defined($stage_mount)) {
1720         $mount_path = $rootdir;
1721     }
1722
1723     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1724
1725     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1726
1727     my $optlist = [];
1728
1729     if (my $mountopts = $mountpoint->{mountoptions}) {
1730         my @opts = split(/;/, $mountpoint->{mountoptions});
1731         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1732     }
1733
1734     my $acl = $mountpoint->{acl};
1735     if (defined($acl)) {
1736         push @$optlist, ($acl ? 'acl' : 'noacl');
1737     }
1738
1739     my $optstring = join(',', @$optlist);
1740     my $readonly = $mountpoint->{ro};
1741
1742     my @extra_opts;
1743     @extra_opts = ('-o', $optstring) if $optstring;
1744
1745     if ($storage) {
1746
1747         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1748
1749         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1750
1751         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1752
1753         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1754             PVE::Storage::parse_volname($storage_cfg, $volid);
1755
1756         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1757
1758         if ($format eq 'subvol') {
1759             if ($mount_path) {
1760                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1761                 if (defined($snapname)) {
1762                     $name .= "\@$snapname";
1763                     if ($scfg->{type} eq 'zfspool') {
1764                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1765                     } else {
1766                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1767                     }
1768                 } else {
1769                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1770                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1771                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1772                     }
1773                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1774                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1775                 }
1776             }
1777             return wantarray ? ($path, 0, undef) : $path;
1778         } elsif ($format eq 'raw' || $format eq 'iso') {
1779             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1780             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1781             # Our autodev hook expects the /dev/dm-* device currently
1782             # and will create the /dev/mapper symlink accordingly
1783             $path = Cwd::realpath($path);
1784             die "failed to get device path\n" if !$path;
1785             ($path) = ($path =~ /^(.*)$/s); #untaint
1786             my $domount = sub {
1787                 my ($path) = @_;
1788                 if ($mount_path) {
1789                     if ($format eq 'iso') {
1790                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1791                     } elsif ($isBase || defined($snapname)) {
1792                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1793                     } else {
1794                         if ($quota) {
1795                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1796                         }
1797                         push @extra_opts, '-o', 'ro' if $readonly;
1798                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1799                     }
1800                 }
1801             };
1802             my $use_loopdev = 0;
1803             if ($scfg->{content}->{rootdir}) {
1804                 if ($scfg->{path}) {
1805                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1806                     $use_loopdev = 1;
1807                 } else {
1808                     $mounted_dev = $path;
1809                     &$domount($path);
1810                 }
1811             } else {
1812                 die "storage '$storage' does not support containers\n";
1813             }
1814             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1815         } else {
1816             die "unsupported image format '$format'\n";
1817         }
1818     } elsif ($type eq 'device') {
1819         push @extra_opts, '-o', 'ro' if $readonly;
1820         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1821         # See the NOTE above about devicemapper canonicalization
1822         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1823         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1824         return wantarray ? ($volid, 0, $devpath) : $volid;
1825     } elsif ($type eq 'bind') {
1826         die "directory '$volid' does not exist\n" if ! -d $volid;
1827         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1828         warn "cannot enable quota control for bind mounts\n" if $quota;
1829         return wantarray ? ($volid, 0, undef) : $volid;
1830     }
1831
1832     die "unsupported storage";
1833 }
1834
1835 sub mountpoint_hotplug :prototype($$$$$) {
1836     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1837
1838     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1839
1840     # We do the rest in a fork with an unshared mount namespace, because:
1841     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1842     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1843     #     container's namespace, then mount it.
1844
1845     PVE::Tools::run_fork(sub {
1846         # Pin the container pid longer, we also need to get its monitor/parent:
1847         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1848             or die "failed to open pidfd of container $vmid\'s init process\n";
1849
1850         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1851             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1852
1853         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1854         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1855
1856         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1857         # profile to lower our privileges to the same level we have in the start hook:
1858         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1859             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1860         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1861         # apparmor.
1862
1863         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1864         # namespace for it to remain active there since the container will be able to unmount
1865         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1866         # concern.
1867         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1868         chdir('/')
1869             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1870
1871         my $dir = get_staging_mount_path($opt);
1872
1873         # Now switch our apparmor profile before mounting:
1874         my $data = 'changeprofile /usr/bin/lxc-start';
1875         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1876             die "failed to change apparmor profile: $!\n";
1877         }
1878         # Check errors on close as well:
1879         close($aa_fd)
1880             or die "failed to change apparmor profile (close() failed): $!\n";
1881
1882         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1883
1884         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1885         chdir('/')
1886             or die "failed to change root directory within the container's mount namespace: $!\n";
1887
1888         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1889     });
1890 }
1891
1892 # Create a directory in the mountpoint staging tempfs.
1893 sub get_staging_mount_path($) {
1894     my ($opt) = @_;
1895
1896     my $target = get_staging_tempfs() . "/$opt";
1897     if (!mkdir($target) && $! != EEXIST) {
1898         die "failed to create directory $target: $!\n";
1899     }
1900
1901     return $target;
1902 }
1903
1904 # Mount /run/pve/mountpoints as tmpfs
1905 sub get_staging_tempfs() {
1906     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1907     # mounts to that.
1908     my $target = '/var/lib/lxc/.pve-staged-mounts';
1909     if (!mkdir($target)) {
1910         return $target if $! == EEXIST;
1911         die "failed to create directory $target: $!\n";
1912     }
1913
1914     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1915         or die "failed to mount $target as tmpfs: $!\n";
1916
1917     return $target;
1918 }
1919
1920 sub mkfs {
1921     my ($dev, $rootuid, $rootgid) = @_;
1922
1923     run_command(
1924         [
1925             'mkfs.ext4',
1926             '-O',
1927             'mmp',
1928             '-E',
1929             "root_owner=$rootuid:$rootgid",
1930             $dev,
1931         ],
1932         outfunc => sub {
1933             my $line = shift;
1934             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1935             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1936                 print "$line\n";
1937             }
1938         },
1939         errfunc => sub {
1940             my $line = shift;
1941             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1942         }
1943     );
1944 }
1945
1946 sub format_disk {
1947     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1948
1949     if ($volid =~ m!^/dev/.+!) {
1950         mkfs($volid);
1951         return;
1952     }
1953
1954     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1955
1956     die "cannot format volume '$volid' with no storage\n" if !$storage;
1957
1958     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1959
1960     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1961
1962     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1963
1964     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1965         PVE::Storage::parse_volname($storage_cfg, $volid);
1966
1967     die "cannot format volume '$volid' (format == $format)\n"
1968         if $format ne 'raw';
1969
1970     mkfs($path, $rootuid, $rootgid);
1971 }
1972
1973 sub destroy_disks {
1974     my ($storecfg, $vollist) = @_;
1975
1976     foreach my $volid (@$vollist) {
1977         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1978         warn $@ if $@;
1979     }
1980 }
1981
1982 sub alloc_disk {
1983     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1984
1985     my $needs_chown = 0;
1986     my $volid;
1987
1988     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1989     # fixme: use better naming ct-$vmid-disk-X.raw?
1990
1991     eval {
1992         my $do_format = 0;
1993         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
1994             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
1995                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1996                 $do_format = 1;
1997             } else {
1998                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1999                 $needs_chown = 1;
2000             }
2001         } elsif ($scfg->{type} eq 'zfspool') {
2002             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2003             $needs_chown = 1;
2004         } elsif ($scfg->{content}->{rootdir}) {
2005             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2006             $do_format = 1;
2007         } else {
2008             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2009         }
2010         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2011     };
2012     if (my $err = $@) {
2013         # in case formatting got interrupted:
2014         if (defined($volid)) {
2015             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2016             warn $@ if $@;
2017         }
2018         die $err;
2019     }
2020
2021     return ($volid, $needs_chown);
2022 }
2023
2024 sub create_disks {
2025     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2026
2027     my $vollist = [];
2028
2029     eval {
2030         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2031         my $chown_vollist = [];
2032
2033         PVE::LXC::Config->foreach_volume($settings, sub {
2034             my ($ms, $mountpoint) = @_;
2035
2036             my $volid = $mountpoint->{volume};
2037             my $mp = $mountpoint->{mp};
2038
2039             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2040
2041             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2042                 my ($storeid, $size_gb) = ($1, $2);
2043
2044                 my $size_kb = int(${size_gb}*1024) * 1024;
2045
2046                 my $needs_chown = 0;
2047                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2048                 push @$chown_vollist, $volid if $needs_chown;
2049                 push @$vollist, $volid;
2050                 $mountpoint->{volume} = $volid;
2051                 $mountpoint->{size} = $size_kb * 1024;
2052                 if ($pending) {
2053                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2054                 } else {
2055                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2056                 }
2057             } else {
2058                 # use specified/existing volid/dir/device
2059                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2060             }
2061         });
2062
2063         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2064         foreach my $volid (@$chown_vollist) {
2065             my $path = PVE::Storage::path($storecfg, $volid, undef);
2066             chown($rootuid, $rootgid, $path);
2067         }
2068         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2069     };
2070     # free allocated images on error
2071     if (my $err = $@) {
2072         destroy_disks($storecfg, $vollist);
2073         die $err;
2074     }
2075     return $vollist;
2076 }
2077
2078 sub update_disksize {
2079     my ($vmid, $conf, $all_volumes) = @_;
2080
2081     my $changes;
2082     my $prefix = "CT $vmid:";
2083
2084     my $update_mp = sub {
2085         my ($key, $mp, @param) = @_;
2086         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2087
2088         if (!defined($mp->{size}) || $size != $mp->{size}) {
2089             $changes = 1;
2090             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2091             $mp->{size} = $size;
2092             my $nomp = 1 if ($key eq 'rootfs');
2093             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
2094         }
2095     };
2096
2097     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2098
2099     return $changes;
2100 }
2101
2102 sub update_unused {
2103     my ($vmid, $conf, $all_volumes) = @_;
2104
2105     my $changes;
2106     my $prefix = "CT $vmid:";
2107
2108     # Note: it is allowed to define multiple storage entries with the same path
2109     # (alias), so we need to check both 'volid' and real 'path' (two different
2110     # volid can point to the same path).
2111
2112     # used and unused disks
2113     my $refpath = {};
2114     my $orphans = {};
2115
2116     foreach my $opt (keys %$conf) {
2117         next if ($opt !~ m/^unused\d+$/);
2118         my $vol = $all_volumes->{$conf->{$opt}};
2119         $refpath->{$vol->{path}} = $vol->{volid};
2120     }
2121
2122     foreach my $key (keys %$all_volumes) {
2123         my $vol = $all_volumes->{$key};
2124         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2125         my $path = $vol->{path};
2126
2127         if ($in_use) {
2128             $refpath->{$path} = $key;
2129             delete $orphans->{$path};
2130         } else {
2131             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2132                 $orphans->{$path} = $key;
2133             }
2134         }
2135     }
2136
2137     for my $key (keys %$orphans) {
2138         my $disk = $orphans->{$key};
2139         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2140
2141         if ($unused) {
2142             $changes = 1;
2143             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2144         }
2145     }
2146
2147     return $changes;
2148 }
2149
2150 sub scan_volids {
2151     my ($cfg, $vmid) = @_;
2152
2153     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2154
2155     my $all_volumes = {};
2156     foreach my $storeid (keys %$info) {
2157         foreach my $item (@{$info->{$storeid}}) {
2158             my $volid = $item->{volid};
2159             next if !($volid && $item->{size});
2160             $item->{path} = PVE::Storage::path($cfg, $volid);
2161             $all_volumes->{$volid} = $item;
2162         }
2163     }
2164
2165     return $all_volumes;
2166 }
2167
2168 sub rescan {
2169     my ($vmid, $nolock, $dryrun) = @_;
2170
2171     my $cfg = PVE::Storage::config();
2172
2173     print "rescan volumes...\n";
2174     my $all_volumes = scan_volids($cfg, $vmid);
2175
2176     my $updatefn =  sub {
2177         my ($vmid) = @_;
2178
2179         my $changes;
2180         my $conf = PVE::LXC::Config->load_config($vmid);
2181
2182         PVE::LXC::Config->check_lock($conf);
2183
2184         my $vm_volids = {};
2185         foreach my $volid (keys %$all_volumes) {
2186             my $info = $all_volumes->{$volid};
2187             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2188         }
2189
2190         my $upu = update_unused($vmid, $conf, $vm_volids);
2191         my $upd = update_disksize($vmid, $conf, $vm_volids);
2192         $changes = $upu || $upd;
2193
2194         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2195     };
2196
2197     if (defined($vmid)) {
2198         if ($nolock) {
2199             &$updatefn($vmid);
2200         } else {
2201             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2202         }
2203     } else {
2204         my $vmlist = config_list();
2205         foreach my $vmid (keys %$vmlist) {
2206             if ($nolock) {
2207                 &$updatefn($vmid);
2208             } else {
2209                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2210             }
2211         }
2212     }
2213 }
2214
2215
2216 # bash completion helper
2217
2218 sub complete_os_templates {
2219     my ($cmdname, $pname, $cvalue) = @_;
2220
2221     my $cfg = PVE::Storage::config();
2222
2223     my $storeid;
2224
2225     if ($cvalue =~ m/^([^:]+):/) {
2226         $storeid = $1;
2227     }
2228
2229     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2230     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2231
2232     my $res = [];
2233     foreach my $id (keys %$data) {
2234         foreach my $item (@{$data->{$id}}) {
2235             push @$res, $item->{volid} if defined($item->{volid});
2236         }
2237     }
2238
2239     return $res;
2240 }
2241
2242 my $complete_ctid_full = sub {
2243     my ($running) = @_;
2244
2245     my $idlist = vmstatus();
2246
2247     my $active_hash = list_active_containers();
2248
2249     my $res = [];
2250
2251     foreach my $id (keys %$idlist) {
2252         my $d = $idlist->{$id};
2253         if (defined($running)) {
2254             next if $d->{template};
2255             next if $running && !$active_hash->{$id};
2256             next if !$running && $active_hash->{$id};
2257         }
2258         push @$res, $id;
2259
2260     }
2261     return $res;
2262 };
2263
2264 sub complete_ctid {
2265     return &$complete_ctid_full();
2266 }
2267
2268 sub complete_ctid_stopped {
2269     return &$complete_ctid_full(0);
2270 }
2271
2272 sub complete_ctid_running {
2273     return &$complete_ctid_full(1);
2274 }
2275
2276 sub parse_id_maps {
2277     my ($conf) = @_;
2278
2279     my $id_map = [];
2280     my $rootuid = 0;
2281     my $rootgid = 0;
2282
2283     my $lxc = $conf->{lxc};
2284     foreach my $entry (@$lxc) {
2285         my ($key, $value) = @$entry;
2286         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2287         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2288         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2289             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2290             push @$id_map, [$type, $ct, $host, $length];
2291             if ($ct == 0) {
2292                 $rootuid = $host if $type eq 'u';
2293                 $rootgid = $host if $type eq 'g';
2294             }
2295         } else {
2296             die "failed to parse idmap: $value\n";
2297         }
2298     }
2299
2300     if (!@$id_map && $conf->{unprivileged}) {
2301         # Should we read them from /etc/subuid?
2302         $id_map = [ ['u', '0', '100000', '65536'],
2303                     ['g', '0', '100000', '65536'] ];
2304         $rootuid = $rootgid = 100000;
2305     }
2306
2307     return ($id_map, $rootuid, $rootgid);
2308 }
2309
2310 sub userns_command {
2311     my ($id_map) = @_;
2312     if (@$id_map) {
2313         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2314     }
2315     return [];
2316 }
2317
2318 my sub print_ct_stderr_log {
2319     my ($vmid) = @_;
2320     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2321     return if !$log;
2322
2323     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2324         my $line = $2;
2325         print STDERR "$line\n";
2326     }
2327 }
2328 my sub print_ct_warn_log {
2329     my ($vmid) = @_;
2330     my $log_fn = "/run/pve/ct-$vmid.warnings";
2331     my $log = eval { file_get_contents($log_fn) };
2332     return if !$log;
2333
2334     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2335         PVE::RESTEnvironment::log_warn($1);
2336     }
2337     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2338 }
2339
2340 my sub monitor_state_change($$) {
2341     my ($monitor_socket, $vmid) = @_;
2342     die "no monitor socket\n" if !defined($monitor_socket);
2343
2344     while (1) {
2345         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2346
2347         die "monitor socket: got EOF\n" if !defined($type);
2348
2349         next if $name ne "$vmid" || $type ne 'STATE';
2350
2351         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2352             alarm(0); # don't timeout after seeing the starting state
2353         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2354                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2355                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2356             return 0;
2357         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2358             return 1;
2359         } else {
2360             warn "unexpected message from monitor socket - " .
2361                  "type: '$type' - value: '$value'\n";
2362         }
2363     }
2364 }
2365 my sub monitor_start($$) {
2366     my ($monitor_socket, $vmid) = @_;
2367
2368     my $success = eval {
2369         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2370     };
2371     if (my $err = $@) {
2372         warn "problem with monitor socket, but continuing anyway: $err\n";
2373     } elsif (!$success) {
2374         print_ct_stderr_log($vmid);
2375         die "startup for container '$vmid' failed\n";
2376     }
2377 }
2378
2379 sub vm_start {
2380     my ($vmid, $conf, $skiplock, $debug) = @_;
2381
2382     # apply pending changes while starting
2383     if (scalar(keys %{$conf->{pending}})) {
2384         my $storecfg = PVE::Storage::config();
2385         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2386         PVE::LXC::Config->write_config($vmid, $conf);
2387         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2388     }
2389
2390     update_lxc_config($vmid, $conf);
2391
2392     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2393
2394     if ($skiplock) {
2395         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2396         close($fh);
2397     }
2398
2399     my $storage_cfg = PVE::Storage::config();
2400     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2401
2402     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2403
2404     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2405     warn $@ if $@;
2406
2407     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2408
2409     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2410     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2411
2412     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2413
2414     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2415     eval {
2416         run_command($cmd);
2417
2418         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2419
2420         # if debug is requested, print the log it also when the start succeeded
2421         print_ct_stderr_log($vmid) if $is_debug;
2422
2423         print_ct_warn_log($vmid); # always print warn log, if any
2424     };
2425     if (my $err = $@) {
2426         unlink $skiplock_flag_fn;
2427         die $err;
2428     }
2429     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2430
2431     return;
2432 }
2433
2434 # Helper to stop a container completely and make sure it has stopped completely.
2435 # This is necessary because we want the post-stop hook to have completed its
2436 # unmount-all step, but post-stop happens after lxc puts the container into the
2437 # STOPPED state.
2438 # $kill - if true it will always do an immediate hard-stop
2439 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2440 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2441 sub vm_stop {
2442     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2443
2444     # Open the container's command socket.
2445     my $path = "\0/var/lib/lxc/$vmid/command";
2446     my $sock = IO::Socket::UNIX->new(
2447         Type => SOCK_STREAM(),
2448         Peer => $path,
2449     );
2450     if (!$sock) {
2451         return if $! == ECONNREFUSED; # The container is not running
2452         die "failed to open container ${vmid}'s command socket: $!\n";
2453     }
2454
2455     my $conf = PVE::LXC::Config->load_config($vmid);
2456     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2457
2458     # Stop the container:
2459
2460     my $cmd = ['lxc-stop', '-n', $vmid];
2461
2462     if ($kill) {
2463         push @$cmd, '--kill'; # doesn't allow timeouts
2464     } else {
2465         # lxc-stop uses a default timeout
2466         push @$cmd, '--nokill' if !$kill_after_timeout;
2467
2468         if (defined($shutdown_timeout)) {
2469             push @$cmd, '--timeout', $shutdown_timeout;
2470             # Give run_command 5 extra seconds
2471             $shutdown_timeout += 5;
2472         }
2473     }
2474
2475     eval { run_command($cmd, timeout => $shutdown_timeout) };
2476     if (my $err = $@) {
2477         warn $@ if $@;
2478     }
2479
2480     my $result = <$sock>;
2481
2482     return if !defined $result; # monitor is gone and the ct has stopped.
2483     die "container did not stop\n";
2484 }
2485
2486 sub vm_reboot {
2487     my ($vmid, $timeout, $skiplock) = @_;
2488
2489     PVE::LXC::Config->lock_config($vmid, sub {
2490         return if !check_running($vmid);
2491
2492         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2493
2494         my $conf = PVE::LXC::Config->load_config($vmid);
2495         vm_start($vmid, $conf);
2496     });
2497 }
2498
2499 sub run_unshared {
2500     my ($code) = @_;
2501
2502     return PVE::Tools::run_fork(sub {
2503         # Unshare the mount namespace
2504         die "failed to unshare mount namespace: $!\n"
2505             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2506         run_command(['mount', '--make-rslave', '/']);
2507         return $code->();
2508     });
2509 }
2510
2511 my $copy_volume = sub {
2512     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2513
2514     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2515     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2516
2517     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2518     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2519
2520     my @mounted;
2521     eval {
2522         # mount and copy
2523         mkdir $src;
2524         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2525         push @mounted, $src;
2526         mkdir $dest;
2527         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2528         push @mounted, $dest;
2529
2530         $bwlimit //= 0;
2531
2532         run_command([
2533             'rsync',
2534             '--stats',
2535             '-X',
2536             '-A',
2537             '--numeric-ids',
2538             '-aH',
2539             '--whole-file',
2540             '--sparse',
2541             '--one-file-system',
2542             "--bwlimit=$bwlimit",
2543             "$src/",
2544             $dest
2545         ]);
2546     };
2547     my $err = $@;
2548
2549     # Wait for rsync's children to release dest so that
2550     # consequent file operations (umount, remove) are possible
2551     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2552
2553     foreach my $mount (reverse @mounted) {
2554         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2555         warn "Can't umount $mount\n" if $@;
2556     }
2557
2558     # If this fails they're used as mount points in a concurrent operation
2559     # (which should not happen but there's also no real need to get rid of them).
2560     rmdir $dest;
2561     rmdir $src;
2562
2563     die $err if $err;
2564 };
2565
2566 # Should not be called after unsharing the mount namespace!
2567 sub copy_volume {
2568     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2569
2570     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2571     File::Path::make_path("/var/lib/lxc/$vmid");
2572     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2573     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2574
2575     # get id's for unprivileged container
2576     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2577
2578     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2579     # are visible in this namespace, otherwise the host only sees the empty
2580     # (not-mounted) directory.
2581     my $new_volid;
2582     eval {
2583         # Make sure $mp contains a correct size.
2584         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2585         my $needs_chown;
2586         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2587         if ($needs_chown) {
2588             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2589             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2590             chown($rootuid, $rootgid, $path);
2591         }
2592
2593         run_unshared(sub {
2594             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2595         });
2596     };
2597     if (my $err = $@) {
2598         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2599             if defined($new_volid);
2600         die $err;
2601     }
2602
2603     return $new_volid;
2604 }
2605
2606 sub get_lxc_version() {
2607     my $version;
2608     run_command([qw(lxc-start --version)], outfunc => sub {
2609         my ($line) = @_;
2610         # We only parse out major & minor version numbers.
2611         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2612             $version = [$1, $2];
2613         }
2614     });
2615
2616     die "failed to get lxc version\n" if !defined($version);
2617
2618     # return as a list:
2619     return $version->@*;
2620 }
2621
2622 sub freeze($) {
2623     my ($vmid) = @_;
2624     if (PVE::CGroup::cgroup_mode() == 2) {
2625         PVE::LXC::Command::freeze($vmid, 30);
2626     } else {
2627         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2628     }
2629 }
2630
2631 sub thaw($) {
2632     my ($vmid) = @_;
2633     if (PVE::CGroup::cgroup_mode() == 2) {
2634         PVE::LXC::Command::unfreeze($vmid, 30);
2635     } else {
2636         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2637     }
2638 }
2639
2640 1;