src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     run_command
  24     dir_glob_foreach
  25     file_get_contents
  26     file_set_contents
  27     AT_FDCWD
  28     O_PATH
  29     $IPV4RE
  30     $IPV6RE
  31 );
  32 use PVE::CpuSet;
  33 use PVE::Network;
  34 use PVE::AccessControl;
  35 use PVE::ProcFSTools;
  36 use PVE::Syscall qw(:fsmount);
  37 use PVE::LXC::Config;
  38 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  39 use PVE::LXC::Tools;
  40 use PVE::LXC::CGroup;
  41 use PVE::LXC::Monitor;
  42 use PVE::CGroup;
  43
  44 use Time::HiRes qw (gettimeofday);
  45 my $have_sdn;
  46 eval {
  47     require PVE::Network::SDN::Zones;
  48     $have_sdn = 1;
  49 };
  50
  51 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  52
  53 my $nodename = PVE::INotify::nodename();
  54
  55 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  56
  57 sub config_list {
  58     my $vmlist = PVE::Cluster::get_vmlist();
  59     my $res = {};
  60     return $res if !$vmlist || !$vmlist->{ids};
  61     my $ids = $vmlist->{ids};
  62
  63     foreach my $vmid (keys %$ids) {
  64         next if !$vmid; # skip CT0
  65         my $d = $ids->{$vmid};
  66         next if !$d->{node} || $d->{node} ne $nodename;
  67         next if !$d->{type} || $d->{type} ne 'lxc';
  68         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  69     }
  70     return $res;
  71 }
  72
  73 # container status helpers
  74
  75 sub list_active_containers {
  76
  77     my $filename = "/proc/net/unix";
  78
  79     # similar test is used by lcxcontainers.c: list_active_containers
  80     my $res = {};
  81
  82     my $fh = IO::File->new ($filename, "r");
  83     return $res if !$fh;
  84
  85     while (defined(my $line = <$fh>)) {
  86         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  87             my $path = $1;
  88             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  89                 $res->{$1} = 1;
  90             }
  91         }
  92     }
  93
  94     close($fh);
  95
  96     return $res;
  97 }
  98
  99 # warning: this is slow
 100 sub check_running {
 101     my ($vmid) = @_;
 102
 103     my $active_hash = list_active_containers();
 104
 105     return 1 if defined($active_hash->{$vmid});
 106
 107     return undef;
 108 }
 109
 110 sub get_container_disk_usage {
 111     my ($vmid, $pid) = @_;
 112
 113     return PVE::Tools::df("/proc/$pid/root/", 1);
 114 }
 115
 116 my $last_proc_vmid_stat;
 117
 118 our $vmstatus_return_properties = {
 119     vmid => get_standard_option('pve-vmid'),
 120     status => {
 121         description => "LXC Container status.",
 122         type => 'string',
 123         enum => ['stopped', 'running'],
 124     },
 125     maxmem => {
 126         description => "Maximum memory in bytes.",
 127         type => 'integer',
 128         optional => 1,
 129         renderer => 'bytes',
 130     },
 131     maxswap => {
 132         description => "Maximum SWAP memory in bytes.",
 133         type => 'integer',
 134         optional => 1,
 135         renderer => 'bytes',
 136     },
 137     maxdisk => {
 138         description => "Root disk size in bytes.",
 139         type => 'integer',
 140         optional => 1,
 141         renderer => 'bytes',
 142     },
 143     name => {
 144         description => "Container name.",
 145         type => 'string',
 146         optional => 1,
 147     },
 148     uptime => {
 149         description => "Uptime.",
 150         type => 'integer',
 151         optional => 1,
 152         renderer => 'duration',
 153     },
 154     cpus => {
 155         description => "Maximum usable CPUs.",
 156         type => 'number',
 157         optional => 1,
 158     },
 159     lock => {
 160         description => "The current config lock, if any.",
 161         type => 'string',
 162         optional => 1,
 163     },
 164     tags => {
 165         description => "The current configured tags, if any.",
 166         type => 'string',
 167         optional => 1,
 168     }
 169 };
 170
 171 sub vmstatus {
 172     my ($opt_vmid) = @_;
 173
 174     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
 175
 176     my $active_hash = list_active_containers();
 177
 178     my $cpucount = $cpuinfo->{cpus} || 1;
 179
 180     my $cdtime = gettimeofday;
 181
 182     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 183     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 184
 185     my $unprivileged = {};
 186
 187     foreach my $vmid (keys %$list) {
 188         my $d = $list->{$vmid};
 189
 190         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 191         warn $@ if $@; # ignore errors (consider them stopped)
 192
 193         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 194
 195         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 196         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 197
 198         $unprivileged->{$vmid} = $conf->{unprivileged};
 199
 200         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 201         $d->{name} =~ s/[\s]//g;
 202
 203         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 204         $d->{cpus} = $cpucount if !$d->{cpus};
 205
 206         $d->{lock} = $conf->{lock} || '';
 207         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 208
 209         if ($d->{pid}) {
 210             my $res = get_container_disk_usage($vmid, $d->{pid});
 211             $d->{disk} = $res->{used};
 212             $d->{maxdisk} = $res->{total};
 213         } else {
 214             $d->{disk} = 0;
 215             # use 4GB by default ??
 216             if (my $rootfs = $conf->{rootfs}) {
 217                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 218                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 219             } else {
 220                 $d->{maxdisk} = 4*1024*1024*1024;
 221             }
 222         }
 223
 224         $d->{mem} = 0;
 225         $d->{swap} = 0;
 226         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 227         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 228
 229         $d->{uptime} = 0;
 230         $d->{cpu} = 0;
 231
 232         $d->{netout} = 0;
 233         $d->{netin} = 0;
 234
 235         $d->{diskread} = 0;
 236         $d->{diskwrite} = 0;
 237
 238         $d->{template} = PVE::LXC::Config->is_template($conf);
 239         $d->{lock} = $conf->{lock} if $conf->{lock};
 240     }
 241
 242     foreach my $vmid (keys %$list) {
 243         my $d = $list->{$vmid};
 244         my $pid = $d->{pid};
 245
 246         next if !$pid; # skip stopped CTs
 247
 248         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 249         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 250
 251         my $unpriv = $unprivileged->{$vmid};
 252
 253         my $cgroups = PVE::LXC::CGroup->new($vmid);
 254
 255         if (defined(my $mem = $cgroups->get_memory_stat())) {
 256             $d->{mem} = $mem->{mem};
 257             $d->{swap} = $mem->{swap};
 258         } else {
 259             $d->{mem} = 0;
 260             $d->{swap} = 0;
 261         }
 262
 263         if (defined(my $blkio = $cgroups->get_io_stats())) {
 264             $d->{diskread} = $blkio->{diskread};
 265             $d->{diskwrite} = $blkio->{diskwrite};
 266         } else {
 267             $d->{diskread} = 0;
 268             $d->{diskwrite} = 0;
 269         }
 270
 271         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 272             # Total time (in milliseconds) used up by the cpu.
 273             my $used_ms = $cpu->{utime} + $cpu->{stime};
 274
 275             my $old = $last_proc_vmid_stat->{$vmid};
 276             if (!$old) {
 277                 $last_proc_vmid_stat->{$vmid} = {
 278                     time => $cdtime,
 279                     used => $used_ms,
 280                     cpu => 0,
 281                 };
 282                 next;
 283             }
 284
 285             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 286             if ($delta_ms > 1000.0) {
 287                 my $delta_used_ms = $used_ms - $old->{used};
 288                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 289                 $last_proc_vmid_stat->{$vmid} = {
 290                     time => $cdtime,
 291                     used => $used_ms,
 292                     cpu => $d->{cpu},
 293                 };
 294             } else {
 295                 $d->{cpu} = $old->{cpu};
 296             }
 297         } else {
 298             $d->{cpu} = 0;
 299         }
 300     }
 301
 302     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 303
 304     foreach my $dev (keys %$netdev) {
 305         next if $dev !~ m/^veth([1-9]\d*)i/;
 306         my $vmid = $1;
 307         my $d = $list->{$vmid};
 308
 309         next if !$d;
 310
 311         $d->{netout} += $netdev->{$dev}->{receive};
 312         $d->{netin} += $netdev->{$dev}->{transmit};
 313
 314     }
 315
 316     return $list;
 317 }
 318
 319 sub find_lxc_console_pids {
 320
 321     my $res = {};
 322
 323     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 324         my ($pid) = @_;
 325
 326         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 327         return if !$cmdline;
 328
 329         my @args = split(/\0/, $cmdline);
 330
 331         # search for lxc-console -n <vmid>
 332         return if scalar(@args) != 3;
 333         return if $args[1] ne '-n';
 334         return if $args[2] !~ m/^\d+$/;
 335         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 336
 337         my $vmid = $args[2];
 338
 339         push @{$res->{$vmid}}, $pid;
 340     });
 341
 342     return $res;
 343 }
 344
 345 sub find_lxc_pid {
 346     my ($vmid) = @_;
 347
 348     my $pid = undef;
 349     my $parser = sub {
 350         my $line = shift;
 351         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 352     };
 353     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 354
 355     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 356
 357     return $pid;
 358 }
 359
 360 sub open_pid_fd($) {
 361     my ($pid) = @_;
 362     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 363         or die "failed to open /proc/$pid pid fd\n";
 364     return $fd;
 365 }
 366
 367 sub open_lxc_pid {
 368     my ($vmid) = @_;
 369
 370     # Find the pid and open:
 371     my $pid = find_lxc_pid($vmid);
 372     my $fd = open_pid_fd($pid);
 373
 374     # Verify:
 375     my $pid2 = find_lxc_pid($vmid);
 376
 377     return () if $pid != $pid2;
 378     return ($pid, $fd);
 379 }
 380
 381 sub open_ppid {
 382     my ($pid) = @_;
 383
 384     # Find the parent pid via proc and open it:
 385     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 386     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 387
 388     my $fd = open_pid_fd($ppid);
 389
 390     # Verify:
 391     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 392     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 393
 394     return () if $ppid != $ppid2;
 395     return ($ppid, $fd);
 396 }
 397
 398 # Note: we cannot use Net:IP, because that only allows strict
 399 # CIDR networks
 400 sub parse_ipv4_cidr {
 401     my ($cidr, $noerr) = @_;
 402
 403     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 404         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 405     }
 406
 407     return undef if $noerr;
 408
 409     die "unable to parse ipv4 address/mask\n";
 410 }
 411
 412 # Deprecated. Use `PVE::CGroup::get_cgroup_controllers()` instead.
 413 sub get_cgroup_subsystems {
 414     PVE::CGroup::get_v1_controllers();
 415 }
 416
 417 # With seccomp trap to userspace we now have the ability to optionally forward
 418 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 419 #
 420 # This means that there are cases where we need to create an extra seccomp
 421 # profile for the container to load.
 422 #
 423 # This returns a configuration snippet added to the raw lxc config.
 424 sub make_seccomp_config {
 425     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 426     # User-configured profile has precedence, note that the user's entry would
 427     # be written 'after' this line anyway...
 428     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 429         # Warn the user if this conflicts with a feature:
 430         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 431         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 432             if length($warn) > 0;
 433         return '';
 434     }
 435
 436     # Privileged containers keep using the default (which is already part of
 437     # the files included via lxc.include, so we don't need to write it out,
 438     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 439     # well)
 440     return '' if !$unprivileged;
 441
 442     my $rules = {
 443         keyctl => ['errno 38'],
 444     };
 445
 446     my $raw_conf = '';
 447
 448     # Unprivileged containers will get keyctl() disabled by default as a
 449     # workaround for systemd-networkd behavior. But we have an option to
 450     # explicitly enable it:
 451     if ($features->{keyctl}) {
 452         delete $rules->{keyctl};
 453     }
 454
 455     # By default, unprivileged containers cannot use `mknod` at all.
 456     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 457     # but for now this is experimental, so it has to be enabled via a feature
 458     # flag.
 459     # Note that we only handle block and char devices (like lxd), the rest we
 460     # leave up to the kernel. We may in the future remove this if seccomp gets
 461     # a way to tell the kernel to "continue" a syscall.
 462     if ($features->{mknod}) {
 463         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 464         if (!$ok) {
 465             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 466         }
 467
 468         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 469         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 470
 471         $rules->{mknod} = [
 472             # condition: (mode & S_IFMT) == S_IFCHR
 473             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 474             # condition: (mode & S_IFMT) == S_IFBLK
 475             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 476         ];
 477         $rules->{mknodat} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483     }
 484
 485     # Now build the custom seccomp rule text...
 486     my $extra_rules = join("\n", map {
 487         my $syscall = $_;
 488         map { "$syscall $_" } $rules->{$syscall}->@*
 489     } sort keys %$rules) . "\n";
 490
 491     return $raw_conf if $extra_rules eq "\n";
 492
 493     # We still have the "most common" config readily available, so don't write
 494     # out that one:
 495     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 496         # we have no extra $raw_conf and use the same we had in pve 6.1:
 497         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 498     }
 499
 500     # Write the rule file to the container's config path:
 501     my $rule_file = "$conf_dir/rules.seccomp";
 502     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 503         . $extra_rules;
 504     file_set_contents($rule_file, $rule_data);
 505     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 506
 507     return $raw_conf;
 508 }
 509
 510 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 511 # automatically. The default should be equivalent to the old
 512 # `lxc-container-default-cgns` profile.
 513 #
 514 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 515 # additional lines into the profile. We can use that to allow mounting specific
 516 # file systems.
 517 sub make_apparmor_config {
 518     my ($conf, $unprivileged, $features) = @_;
 519
 520     # user-configured profile has precedence, but first we go through our own
 521     # code to figure out whether we should warn the user:
 522
 523     my $raw = "lxc.apparmor.profile = generated\n";
 524     my @profile_uses;
 525
 526     if ($features->{fuse}) {
 527         # For the informational warning:
 528         push @profile_uses, 'features:fuse';
 529     }
 530
 531     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 532     # apparmor lines, create an apparmor namespace for the container, but also
 533     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 534     # lxcfs mounted over them, because that would prevent the container from
 535     # mounting new instances of them for nested containers.
 536     if ($features->{nesting}) {
 537         push @profile_uses, 'features:nesting';
 538         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 539     } else {
 540         # In the default profile in /etc/apparmor.d we patch this in because
 541         # otherwise a container can for example run `chown` on /sys, breaking
 542         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 543         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 544         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 545         # Preferably we could use the 'remount' flag but this does not sit well
 546         # with apparmor_parser currently:
 547         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 548     }
 549
 550     if (my $mount = $features->{mount}) {
 551         push @profile_uses, 'features:mount';
 552         foreach my $fs (PVE::Tools::split_list($mount)) {
 553             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 554         }
 555     }
 556
 557     # More to come?
 558
 559     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 560         if (length(my $used = join(', ', @profile_uses))) {
 561             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 562         }
 563         return '';
 564     }
 565
 566     return $raw;
 567 }
 568
 569 sub update_lxc_config {
 570     my ($vmid, $conf) = @_;
 571
 572     my $dir = "/var/lib/lxc/$vmid";
 573
 574     if ($conf->{template}) {
 575
 576         unlink "$dir/config";
 577
 578         return;
 579     }
 580
 581     my ($lxc_major, $lxc_minor) = get_lxc_version();
 582
 583     my $raw = '';
 584
 585     if ($lxc_major >= 4) {
 586         # Explicitly don't use relative directories, which is the default, but
 587         # note that we do this mostly because they are only applied for *some*
 588         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 589         # so we also don't need to worry about the new monitor cgroup to
 590         # confuse systemd.
 591         $raw .= "lxc.cgroup.relative = 0\n";
 592
 593         # To make things easier, let's keep our previous cgroup layout and
 594         # simply move the monitor outside:
 595         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 596         # cgroup namespace separation for stronger limits:
 597         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 598         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 599     }
 600
 601     die "missing 'arch' - internal error" if !$conf->{arch};
 602     $raw .= "lxc.arch = $conf->{arch}\n";
 603
 604     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 605     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 606
 607     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 608
 609     my $cfgpath = '/usr/share/lxc/config';
 610     my $inc = "$cfgpath/$ostype.common.conf";
 611     $inc ="$cfgpath/common.conf" if !-f $inc;
 612     $raw .= "lxc.include = $inc\n";
 613     if ($unprivileged) {
 614         $inc = "$cfgpath/$ostype.userns.conf";
 615         $inc = "$cfgpath/userns.conf" if !-f $inc;
 616         $raw .= "lxc.include = $inc\n";
 617     }
 618
 619     my $features = PVE::LXC::Config->parse_features($conf->{features});
 620
 621     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 622     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 623     if ($features->{fuse}) {
 624         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 625         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 626     }
 627
 628     if ($unprivileged && !$features->{force_rw_sys}) {
 629         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 630         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 631         $raw .= "lxc.mount.auto = sys:mixed\n";
 632     }
 633
 634     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 635     # cannot be exposed to the container with r/w access (cgroup perms).
 636     # When this is enabled mounts will still remain in the monitor's namespace
 637     # after the container unmounted them and thus will not detach from their
 638     # files while the container is running!
 639     $raw .= "lxc.monitor.unshare = 1\n";
 640
 641     my $cgv1 = get_cgroup_subsystems();
 642
 643     # Should we read them from /etc/subuid?
 644     if ($unprivileged && !$custom_idmap) {
 645         $raw .= "lxc.idmap = u 0 100000 65536\n";
 646         $raw .= "lxc.idmap = g 0 100000 65536\n";
 647     }
 648
 649     if (!PVE::LXC::Config->has_dev_console($conf)) {
 650         $raw .= "lxc.console.path = none\n";
 651         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
 652     }
 653
 654     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 655     $raw .= "lxc.tty.max = $ttycount\n";
 656
 657     # some init scripts expect a linux terminal (turnkey).
 658     $raw .= "lxc.environment = TERM=linux\n";
 659
 660     my $utsname = $conf->{hostname} || "CT$vmid";
 661     $raw .= "lxc.uts.name = $utsname\n";
 662
 663     if ($cgv1->{memory}) {
 664         my $memory = $conf->{memory} || 512;
 665         my $swap = $conf->{swap} // 0;
 666
 667         my $lxcmem = int($memory*1024*1024);
 668         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 669
 670         my $lxcswap = int(($memory + $swap)*1024*1024);
 671         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 672     }
 673
 674     if ($cgv1->{cpu}) {
 675         if (my $cpulimit = $conf->{cpulimit}) {
 676             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 677             my $value = int(100000*$cpulimit);
 678             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 679         }
 680
 681         my $shares = $conf->{cpuunits} || 1024;
 682         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 683     }
 684
 685     die "missing 'rootfs' configuration\n"
 686         if !defined($conf->{rootfs});
 687
 688     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 689
 690     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 691
 692     foreach my $k (sort keys %$conf) {
 693         next if $k !~ m/^net(\d+)$/;
 694         my $ind = $1;
 695         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 696         $raw .= "lxc.net.$ind.type = veth\n";
 697         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 698         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 699         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 700         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 701
 702         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 703         if ($lxc_major >= 4) {
 704             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 705         }
 706     }
 707
 708     my $had_cpuset = 0;
 709     if (my $lxcconf = $conf->{lxc}) {
 710         foreach my $entry (@$lxcconf) {
 711             my ($k, $v) = @$entry;
 712             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 713             $raw .= "$k = $v\n";
 714         }
 715     }
 716
 717     my $cpuset;
 718     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 719     if (defined($cpuset_cgroup)) {
 720         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 721             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 722     }
 723     my $cores = $conf->{cores};
 724     if (!$had_cpuset && $cores && $cpuset) {
 725         my @members = $cpuset->members();
 726         while (scalar(@members) > $cores) {
 727             my $randidx = int(rand(scalar(@members)));
 728             $cpuset->delete($members[$randidx]);
 729             splice(@members, $randidx, 1); # keep track of the changes
 730         }
 731         my $ver = $cpuset_version == 1 ? '' : '2';
 732         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 733     }
 734
 735     File::Path::mkpath("$dir/rootfs");
 736
 737     PVE::Tools::file_set_contents("$dir/config", $raw);
 738 }
 739
 740 # verify and cleanup nameserver list (replace \0 with ' ')
 741 sub verify_nameserver_list {
 742     my ($nameserver_list) = @_;
 743
 744     my @list = ();
 745     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 746         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 747         push @list, $server;
 748     }
 749
 750     return join(' ', @list);
 751 }
 752
 753 sub verify_searchdomain_list {
 754     my ($searchdomain_list) = @_;
 755
 756     my @list = ();
 757     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 758         # todo: should we add checks for valid dns domains?
 759         push @list, $server;
 760     }
 761
 762     return join(' ', @list);
 763 }
 764
 765 sub get_console_command {
 766     my ($vmid, $conf, $escapechar) = @_;
 767
 768     # '-1' as $escapechar disables keyboard escape sequence
 769     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 770
 771     my $cmode = PVE::LXC::Config->get_cmode($conf);
 772
 773     my $cmd = [];
 774     if ($cmode eq 'console') {
 775         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 776         push @$cmd, '-e', $escapechar if $escapechar;
 777     } elsif ($cmode eq 'tty') {
 778         push @$cmd, 'lxc-console', '-n',  $vmid;
 779         push @$cmd, '-e', $escapechar if $escapechar;
 780     } elsif ($cmode eq 'shell') {
 781         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 782     } else {
 783         die "internal error";
 784     }
 785
 786     return $cmd;
 787 }
 788
 789 sub get_primary_ips {
 790     my ($conf) = @_;
 791
 792     # return data from net0
 793
 794     return undef if !defined($conf->{net0});
 795     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 796
 797     my $ipv4 = $net->{ip};
 798     if ($ipv4) {
 799         if ($ipv4 =~ /^(dhcp|manual)$/) {
 800             $ipv4 = undef
 801         } else {
 802             $ipv4 =~ s!/\d+$!!;
 803         }
 804     }
 805     my $ipv6 = $net->{ip6};
 806     if ($ipv6) {
 807         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 808             $ipv6 = undef;
 809         } else {
 810             $ipv6 =~ s!/\d+$!!;
 811         }
 812     }
 813
 814     return ($ipv4, $ipv6);
 815 }
 816
 817 sub delete_mountpoint_volume {
 818     my ($storage_cfg, $vmid, $volume) = @_;
 819
 820     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 821
 822     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 823
 824     if ($vmid == $owner) {
 825         PVE::Storage::vdisk_free($storage_cfg, $volume);
 826     } else {
 827         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 828     }
 829 }
 830
 831 sub destroy_lxc_container {
 832     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 833
 834     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, sub {
 835         my ($ms, $mountpoint) = @_;
 836         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 837     });
 838
 839     rmdir "/var/lib/lxc/$vmid/rootfs";
 840     unlink "/var/lib/lxc/$vmid/config";
 841     rmdir "/var/lib/lxc/$vmid";
 842     if (defined $replacement_conf) {
 843         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 844     } else {
 845         PVE::LXC::Config->destroy_config($vmid);
 846     }
 847 }
 848
 849 sub vm_stop_cleanup {
 850     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 851
 852     return if $keepActive;
 853
 854     eval {
 855         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 856         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 857     };
 858     warn $@ if $@; # avoid errors - just warn
 859 }
 860
 861 sub update_net {
 862     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 863
 864     if ($newnet->{type} ne 'veth') {
 865         # for when there are physical interfaces
 866         die "cannot update interface of type $newnet->{type}";
 867     }
 868
 869     my $veth = "veth${vmid}i${netid}";
 870     my $eth = $newnet->{name};
 871
 872     if (my $oldnetcfg = $conf->{$opt}) {
 873         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 874
 875         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 876             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 877
 878             PVE::Network::veth_delete($veth);
 879             delete $conf->{$opt};
 880             PVE::LXC::Config->write_config($vmid, $conf);
 881
 882             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 883
 884         } else {
 885             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 886                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 887                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 888
 889                 if ($oldnet->{bridge}) {
 890                     PVE::Network::tap_unplug($veth);
 891                     foreach (qw(bridge tag firewall)) {
 892                         delete $oldnet->{$_};
 893                     }
 894                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 895                     PVE::LXC::Config->write_config($vmid, $conf);
 896                 }
 897
 898                 if ($have_sdn) {
 899                     PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 900                 } else {
 901                     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 902                 }
 903
 904                 # This includes the rate:
 905                 foreach (qw(bridge tag firewall rate)) {
 906                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 907                 }
 908             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 909                 # Rate can be applied on its own but any change above needs to
 910                 # include the rate in tap_plug since OVS resets everything.
 911                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 912                 $oldnet->{rate} = $newnet->{rate}
 913             }
 914             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 915             PVE::LXC::Config->write_config($vmid, $conf);
 916         }
 917     } else {
 918         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 919     }
 920
 921     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 922 }
 923
 924 sub hotplug_net {
 925     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 926
 927     my $veth = "veth${vmid}i${netid}";
 928     my $vethpeer = $veth . "p";
 929     my $eth = $newnet->{name};
 930
 931     if ($have_sdn) {
 932         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 933         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 934     } else {
 935         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 936         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 937     }
 938
 939     # attach peer in container
 940     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 941     PVE::Tools::run_command($cmd);
 942
 943     # link up peer in container
 944     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 945     PVE::Tools::run_command($cmd);
 946
 947     my $done = { type => 'veth' };
 948     foreach (qw(bridge tag firewall hwaddr name)) {
 949         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 950     }
 951     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 952
 953     PVE::LXC::Config->write_config($vmid, $conf);
 954 }
 955
 956 sub update_ipconfig {
 957     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 958
 959     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 960
 961     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 962     my $deleted = [];
 963     my $added = [];
 964     my $nscmd = sub {
 965         my $cmdargs = shift;
 966         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 967     };
 968     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 969
 970     my $change_ip_config = sub {
 971         my ($ipversion) = @_;
 972
 973         my $family_opt = "-$ipversion";
 974         my $suffix = $ipversion == 4 ? '' : $ipversion;
 975         my $gw= "gw$suffix";
 976         my $ip= "ip$suffix";
 977
 978         my $newip = $newnet->{$ip};
 979         my $newgw = $newnet->{$gw};
 980         my $oldip = $optdata->{$ip};
 981         my $oldgw = $optdata->{$gw};
 982
 983         my $change_ip = safe_string_ne($oldip, $newip);
 984         my $change_gw = safe_string_ne($oldgw, $newgw);
 985
 986         return if !$change_ip && !$change_gw;
 987
 988         # step 1: add new IP, if this fails we cancel
 989         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 990         if ($change_ip && $is_real_ip) {
 991             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 992             if (my $err = $@) {
 993                 warn $err;
 994                 return;
 995             }
 996         }
 997
 998         # step 2: replace gateway
 999         #   If this fails we delete the added IP and cancel.
1000         #   If it succeeds we save the config and delete the old IP, ignoring
1001         #   errors. The config is then saved.
1002         # Note: 'ip route replace' can add
1003         if ($change_gw) {
1004             if ($newgw) {
1005                 eval {
1006                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1007                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1008                     }
1009                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1010                 };
1011                 if (my $err = $@) {
1012                     warn $err;
1013                     # the route was not replaced, the old IP is still available
1014                     # rollback (delete new IP) and cancel
1015                     if ($change_ip) {
1016                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1017                         warn $@ if $@; # no need to die here
1018                     }
1019                     return;
1020                 }
1021             } else {
1022                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1023                 # if the route was not deleted, the guest might have deleted it manually
1024                 # warn and continue
1025                 warn $@ if $@;
1026             }
1027             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1028                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1029                 # warn if the route was deleted manually
1030                 warn $@ if $@;
1031             }
1032         }
1033
1034         # from this point on we save the configuration
1035         # step 3: delete old IP ignoring errors
1036         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1037             # We need to enable promote_secondaries, otherwise our newly added
1038             # address will be removed along with the old one.
1039             my $promote = 0;
1040             eval {
1041                 if ($ipversion == 4) {
1042                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1043                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1044                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1045                 }
1046                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1047             };
1048             warn $@ if $@; # no need to die here
1049
1050             if ($ipversion == 4) {
1051                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1052             }
1053         }
1054
1055         foreach my $property ($ip, $gw) {
1056             if ($newnet->{$property}) {
1057                 $optdata->{$property} = $newnet->{$property};
1058             } else {
1059                 delete $optdata->{$property};
1060             }
1061         }
1062         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1063         PVE::LXC::Config->write_config($vmid, $conf);
1064         $lxc_setup->setup_network($conf);
1065     };
1066
1067     &$change_ip_config(4);
1068     &$change_ip_config(6);
1069
1070 }
1071
1072 my $open_namespace = sub {
1073     my ($vmid, $pid, $kind) = @_;
1074     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1075         or die "failed to open $kind namespace of container $vmid: $!\n";
1076     return $fd;
1077 };
1078
1079 my $enter_namespace = sub {
1080     my ($vmid, $pid, $kind, $type) = @_;
1081     my $fd = $open_namespace->($vmid, $pid, $kind);
1082     PVE::Tools::setns(fileno($fd), $type)
1083         or die "failed to enter $kind namespace of container $vmid: $!\n";
1084     close $fd;
1085 };
1086
1087 my $get_container_namespace = sub {
1088     my ($vmid, $pid, $kind) = @_;
1089
1090     my $pidfd;
1091     if (!defined($pid)) {
1092         # Pin the pid while we're grabbing its stuff from /proc
1093         ($pid, $pidfd) = open_lxc_pid($vmid)
1094             or die "failed to open pidfd of container $vmid\'s init process\n";
1095     }
1096
1097     return $open_namespace->($vmid, $pid, $kind);
1098 };
1099
1100 my $do_syncfs = sub {
1101     my ($vmid, $pid, $socket) = @_;
1102
1103     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1104
1105     # Tell the parent process to start reading our /proc/mounts
1106     print {$socket} "go\n";
1107     $socket->flush();
1108
1109     # Receive /proc/self/mounts
1110     my $mountdata = do { local $/ = undef; <$socket> };
1111     close $socket;
1112
1113     my %nosyncfs = (
1114         cgroup => 1,
1115         cgroup2 => 1,
1116         devtmpfs => 1,
1117         devpts => 1,
1118         'fuse.lxcfs' => 1,
1119         fusectl => 1,
1120         mqueue => 1,
1121         proc => 1,
1122         sysfs => 1,
1123         tmpfs => 1,
1124     );
1125
1126     # Now sync all mountpoints...
1127     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1128     foreach my $mp (@$mounts) {
1129         my ($what, $dir, $fs) = @$mp;
1130         next if $nosyncfs{$fs};
1131         eval { PVE::Tools::sync_mountpoint($dir); };
1132         warn $@ if $@;
1133     }
1134 };
1135
1136 sub sync_container_namespace {
1137     my ($vmid) = @_;
1138     my $pid = find_lxc_pid($vmid);
1139
1140     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1141     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1142         or die "failed to create socketpair: $!\n";
1143
1144     my $child = fork();
1145     die "fork failed: $!\n" if !defined($child);
1146
1147     if (!$child) {
1148         eval {
1149             close $pfd;
1150             &$do_syncfs($vmid, $pid, $cfd);
1151         };
1152         if (my $err = $@) {
1153             warn $err;
1154             POSIX::_exit(1);
1155         }
1156         POSIX::_exit(0);
1157     }
1158     close $cfd;
1159     my $go = <$pfd>;
1160     die "failed to enter container namespace\n" if $go ne "go\n";
1161
1162     open my $mounts, '<', "/proc/$child/mounts"
1163         or die "failed to open container's /proc/mounts: $!\n";
1164     my $mountdata = do { local $/ = undef; <$mounts> };
1165     close $mounts;
1166     print {$pfd} $mountdata;
1167     close $pfd;
1168
1169     while (waitpid($child, 0) != $child) {}
1170     die "failed to sync container namespace\n" if $? != 0;
1171 }
1172
1173 sub template_create {
1174     my ($vmid, $conf) = @_;
1175
1176     my $storecfg = PVE::Storage::config();
1177
1178     PVE::LXC::Config->foreach_volume($conf, sub {
1179         my ($ms, $mountpoint) = @_;
1180
1181         my $volid = $mountpoint->{volume};
1182
1183         die "Template feature is not available for '$volid'\n"
1184             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1185     });
1186
1187     PVE::LXC::Config->foreach_volume($conf, sub {
1188         my ($ms, $mountpoint) = @_;
1189
1190         my $volid = $mountpoint->{volume};
1191
1192         PVE::Storage::activate_volumes($storecfg, [$volid]);
1193
1194         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1195         $mountpoint->{volume} = $template_volid;
1196         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1197     });
1198
1199     PVE::LXC::Config->write_config($vmid, $conf);
1200 }
1201
1202 sub check_ct_modify_config_perm {
1203     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1204
1205     return 1 if $authuser eq 'root@pam';
1206
1207     my $check = sub {
1208         my ($opt, $delete) = @_;
1209         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1210             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1211         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1212             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1213             return if $delete;
1214             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1215             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1216                 if $data->{type} ne 'volume';
1217         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1218             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1219         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1220                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1221             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1222         } elsif ($opt eq 'features') {
1223             # For now this is restricted to root@pam
1224             raise_perm_exc("changing feature flags is only allowed for root\@pam");
1225         } elsif ($opt eq 'hookscript') {
1226             # For now this is restricted to root@pam
1227             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1228         } else {
1229             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1230         }
1231     };
1232
1233     foreach my $opt (keys %$newconf) {
1234         &$check($opt, 0);
1235     }
1236     foreach my $opt (@$delete) {
1237         &$check($opt, 1);
1238     }
1239
1240     return 1;
1241 }
1242
1243 sub umount_all {
1244     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1245
1246     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1247     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1248
1249     my $res = 1;
1250
1251     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1252         my ($ms, $mountpoint) = @_;
1253
1254         my $volid = $mountpoint->{volume};
1255         my $mount = $mountpoint->{mp};
1256
1257         return if !$volid || !$mount;
1258
1259         my $mount_path = "$rootdir/$mount";
1260         $mount_path =~ s!/+!/!g;
1261
1262         return if !PVE::ProcFSTools::is_mounted($mount_path);
1263
1264         eval {
1265             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1266         };
1267         if (my $err = $@) {
1268             if ($noerr) {
1269                 $res = 0;
1270                 warn $err;
1271             } else {
1272                 die $err;
1273             }
1274         }
1275     });
1276
1277     return $res; # tell caller if (some) umounts failed for the noerr case
1278 }
1279
1280 sub mount_all {
1281     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1282
1283     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1284     File::Path::make_path($rootdir);
1285
1286     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1287     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1288
1289     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1290
1291     eval {
1292         PVE::LXC::Config->foreach_volume($conf, sub {
1293             my ($ms, $mountpoint) = @_;
1294
1295             $mountpoint->{ro} = 0 if $ignore_ro;
1296
1297             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1298         });
1299     };
1300     if (my $err = $@) {
1301         warn "mounting container failed\n";
1302         umount_all($vmid, $storage_cfg, $conf, 1);
1303         die $err;
1304     }
1305
1306     return $rootdir;
1307 }
1308
1309
1310 sub mountpoint_mount_path {
1311     my ($mountpoint, $storage_cfg, $snapname) = @_;
1312
1313     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1314 }
1315
1316 sub query_loopdev {
1317     my ($path) = @_;
1318     my $found;
1319     my $parser = sub {
1320         my $line = shift;
1321         if ($line =~ m@^(/dev/loop\d+):@) {
1322             $found = $1;
1323         }
1324     };
1325     my $cmd = ['losetup', '--associated', $path];
1326     PVE::Tools::run_command($cmd, outfunc => $parser);
1327     return $found;
1328 }
1329
1330 # Run a function with a file attached to a loop device.
1331 # The loop device is always detached afterwards (or set to autoclear).
1332 # Returns the loop device.
1333 sub run_with_loopdev {
1334     my ($func, $file, $readonly) = @_;
1335     my $device = query_loopdev($file);
1336     # Try to reuse an existing device
1337     if ($device) {
1338         # We assume that whoever setup the loop device is responsible for
1339         # detaching it.
1340         &$func($device);
1341         return $device;
1342     }
1343
1344     my $parser = sub {
1345         my $line = shift;
1346         if ($line =~ m@^(/dev/loop\d+)$@) {
1347             $device = $1;
1348         }
1349     };
1350     my $losetup_cmd = [
1351         'losetup',
1352         '--show',
1353         '-f',
1354         $file,
1355     ];
1356     push @$losetup_cmd, '-r' if $readonly;
1357     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1358     die "failed to setup loop device for $file\n" if !$device;
1359     eval { &$func($device); };
1360     my $err = $@;
1361     PVE::Tools::run_command(['losetup', '-d', $device]);
1362     die $err if $err;
1363     return $device;
1364 }
1365
1366 # In scalar mode: returns a file handle to the deepest directory node.
1367 # In list context: returns a list of:
1368 #   * the deepest directory node
1369 #   * the 2nd deepest directory (parent of the above)
1370 #   * directory name of the last directory
1371 # So that the path $2/$3 should lead to $1 afterwards.
1372 sub walk_tree_nofollow($$$;$$) {
1373     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1374
1375     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1376         or die "failed to open start directory $start: $!\n";
1377
1378     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1379 }
1380
1381
1382 sub walk_tree_nofollow_fd($$$$;$$) {
1383     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1384
1385     # splitdir() returns '' for empty components including the leading /
1386     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1387
1388     my $fd = $start_fd;
1389     my $dir = $start_dirname;
1390     my $last_component = undef;
1391     my $second = $fd;
1392     foreach my $component (@comps) {
1393         $dir .= "/$component";
1394         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1395
1396         if (!$next) {
1397             # failed, check for symlinks and try to create the path
1398             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1399             die "cannot open directory $dir: $!\n" if !$mkdir;
1400
1401             # We don't check for errors on mkdirat() here and just try to
1402             # openat() again, since at least one error (EEXIST) is an
1403             # expected possibility if multiple containers start
1404             # simultaneously. If someone else injects a symlink now then
1405             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1406             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1407
1408             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1409             die "failed to create path: $dir: $!\n" if !$next;
1410
1411             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1412                 if defined($rootuid) && defined($rootgid);
1413         }
1414
1415         close $second if defined($last_component) && $second != $start_fd;
1416         $last_component = $component;
1417         $second = $fd;
1418         $fd = $next;
1419     }
1420
1421     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1422     close $second if defined($last_component) && $second != $start_fd;
1423     return $fd;
1424 }
1425
1426 # To guard against symlink attack races against other currently running
1427 # containers with shared recursive bind mount hierarchies we prepare a
1428 # directory handle for the directory we're mounting over to verify the
1429 # mountpoint afterwards.
1430 sub __bindmount_prepare {
1431     my ($hostroot, $dir) = @_;
1432     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1433     return $srcdh;
1434 }
1435
1436 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1437 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1438 # we intended to bind mount.
1439 sub __bindmount_verify {
1440     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1441     my $destdh;
1442     if ($parentfd) {
1443         # Open the mount point path coming from the parent directory since the
1444         # filehandle we would have gotten as first result of walk_tree_nofollow
1445         # earlier is still a handle to the underlying directory instead of the
1446         # mounted path.
1447         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1448         die "failed to open mount point: $!\n" if !$destdh;
1449         if ($ro) {
1450             my $dot = '.';
1451             # no separate function because 99% of the time it's the wrong thing to use.
1452             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1453                 die "failed to mark bind mount read only\n";
1454             }
1455             die "read-only check failed: $!\n" if $! != EROFS;
1456         }
1457     } else {
1458         # For the rootfs we don't have a parentfd so we open the path directly.
1459         # Note that this means bindmounting any prefix of the host's
1460         # /var/lib/lxc/$vmid path into another container is considered a grave
1461         # security error.
1462         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1463         die "failed to open mount point: $!\n" if !$destdh;
1464     }
1465
1466     my ($srcdev, $srcinode) = stat($srcdh);
1467     my ($dstdev, $dstinode) = stat($destdh);
1468     close $srcdh;
1469     close $destdh;
1470
1471     return ($srcdev == $dstdev && $srcinode == $dstinode);
1472 }
1473
1474 # Perform the actual bind mounting:
1475 sub __bindmount_do {
1476     my ($dir, $dest, $ro, @extra_opts) = @_;
1477     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1478     if ($ro) {
1479         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1480         if (my $err = $@) {
1481             warn "bindmount error\n";
1482             # don't leave writable bind-mounts behind...
1483             PVE::Tools::run_command(['umount', $dest]);
1484             die $err;
1485         }
1486     }
1487 }
1488
1489 sub bindmount {
1490     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1491
1492     my $srcdh = __bindmount_prepare('/', $dir);
1493
1494     __bindmount_do($dir, $dest, $ro, @extra_opts);
1495
1496     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1497         PVE::Tools::run_command(['umount', $dest]);
1498         die "detected mount path change at: $dir\n";
1499     }
1500 }
1501
1502 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1503 # from $rootdir and $mount and walk the path from $rootdir to the final
1504 # directory to check for symlinks.
1505 sub __mount_prepare_rootdir {
1506     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1507     $rootdir =~ s!/+!/!g;
1508     $rootdir =~ s!/+$!!;
1509     my $mount_path = "$rootdir/$mount";
1510     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1511     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1512 }
1513
1514 # use $rootdir = undef to just return the corresponding mount path
1515 sub mountpoint_mount {
1516     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1517     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1518 }
1519
1520 sub mountpoint_stage {
1521     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1522     my ($path, $loop, $dev) =
1523         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1524
1525     if (!defined($path)) {
1526         return undef if $! == ENOSYS;
1527         die "failed to mount subvolume: $!\n";
1528     }
1529
1530     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1531     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1532     # point).
1533     my $err;
1534     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1535         or die "open_tree() on mount point failed: $!\n";
1536
1537     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1538 }
1539
1540 sub mountpoint_insert_staged {
1541     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1542
1543     if (!defined($rootdir_fd)) {
1544         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1545             or die "failed to open '.': $!\n";
1546     }
1547
1548     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1549
1550     PVE::Tools::move_mount(
1551         fileno($mount_fd),
1552         '',
1553         fileno($dest_fd),
1554         '',
1555         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1556     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1557 }
1558
1559 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1560 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1561 #   Note that if the kernel does not support the new mount API, this will not perform any action
1562 #   and return `undef` with $! = ENOSYS.
1563 sub __mountpoint_mount {
1564     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1565
1566     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1567         $! = ENOSYS;
1568         return undef;
1569     }
1570
1571     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1572     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1573     # which we use in __bindmount_verify()!
1574     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1575
1576     my $volid = $mountpoint->{volume};
1577     my $type = $mountpoint->{type};
1578     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1579     my $mounted_dev;
1580
1581     return if !$volid || !$mount;
1582
1583     $mount =~ s!/+!/!g;
1584
1585     my $mount_path;
1586     my ($mpfd, $parentfd, $last_dir);
1587
1588     if (defined($rootdir)) {
1589         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1590             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1591     }
1592
1593     if (defined($stage_mount)) {
1594         $mount_path = $rootdir;
1595     }
1596
1597     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1598
1599     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1600
1601     my $optlist = [];
1602
1603     if (my $mountopts = $mountpoint->{mountoptions}) {
1604         my @opts = split(/;/, $mountpoint->{mountoptions});
1605         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1606     }
1607
1608     my $acl = $mountpoint->{acl};
1609     if (defined($acl)) {
1610         push @$optlist, ($acl ? 'acl' : 'noacl');
1611     }
1612
1613     my $optstring = join(',', @$optlist);
1614     my $readonly = $mountpoint->{ro};
1615
1616     my @extra_opts;
1617     @extra_opts = ('-o', $optstring) if $optstring;
1618
1619     if ($storage) {
1620
1621         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1622
1623         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1624
1625         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1626
1627         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1628             PVE::Storage::parse_volname($storage_cfg, $volid);
1629
1630         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1631
1632         if ($format eq 'subvol') {
1633             if ($mount_path) {
1634                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1635                 if (defined($snapname)) {
1636                     $name .= "\@$snapname";
1637                     if ($scfg->{type} eq 'zfspool') {
1638                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1639                     } else {
1640                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1641                     }
1642                 } else {
1643                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1644                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1645                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1646                     }
1647                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1648                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1649                 }
1650             }
1651             return wantarray ? ($path, 0, undef) : $path;
1652         } elsif ($format eq 'raw' || $format eq 'iso') {
1653             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1654             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1655             # Our autodev hook expects the /dev/dm-* device currently
1656             # and will create the /dev/mapper symlink accordingly
1657             $path = Cwd::realpath($path);
1658             die "failed to get device path\n" if !$path;
1659             ($path) = ($path =~ /^(.*)$/s); #untaint
1660             my $domount = sub {
1661                 my ($path) = @_;
1662                 if ($mount_path) {
1663                     if ($format eq 'iso') {
1664                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1665                     } elsif ($isBase || defined($snapname)) {
1666                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1667                     } else {
1668                         if ($quota) {
1669                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1670                         }
1671                         push @extra_opts, '-o', 'ro' if $readonly;
1672                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1673                     }
1674                 }
1675             };
1676             my $use_loopdev = 0;
1677             if ($scfg->{path}) {
1678                 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1679                 $use_loopdev = 1;
1680             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1681                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1682                 $mounted_dev = $path;
1683                 &$domount($path);
1684             } else {
1685                 die "unsupported storage type '$scfg->{type}'\n";
1686             }
1687             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1688         } else {
1689             die "unsupported image format '$format'\n";
1690         }
1691     } elsif ($type eq 'device') {
1692         push @extra_opts, '-o', 'ro' if $readonly;
1693         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1694         # See the NOTE above about devicemapper canonicalization
1695         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1696         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1697         return wantarray ? ($volid, 0, $devpath) : $volid;
1698     } elsif ($type eq 'bind') {
1699         die "directory '$volid' does not exist\n" if ! -d $volid;
1700         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1701         warn "cannot enable quota control for bind mounts\n" if $quota;
1702         return wantarray ? ($volid, 0, undef) : $volid;
1703     }
1704
1705     die "unsupported storage";
1706 }
1707
1708 sub mountpoint_hotplug($$$) {
1709     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1710
1711     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1712
1713     # We do the rest in a fork with an unshared mount namespace, because:
1714     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1715     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1716     #     container's namespace, then mount it.
1717
1718     PVE::Tools::run_fork(sub {
1719         # Pin the container pid longer, we also need to get its monitor/parent:
1720         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1721             or die "failed to open pidfd of container $vmid\'s init process\n";
1722
1723         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1724             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1725
1726         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1727         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1728
1729         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1730         # profile to lower our privileges to the same level we have in the start hook:
1731         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1732             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1733         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1734         # apparmor.
1735
1736         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1737         # namespace for it to remain active there since the container will be able to unmount
1738         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1739         # concern.
1740         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1741         chdir('/')
1742             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1743
1744         my $dir = get_staging_mount_path($opt);
1745
1746         # Now switch our apparmor profile before mounting:
1747         my $data = 'changeprofile /usr/bin/lxc-start';
1748         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1749             die "failed to change apparmor profile: $!\n";
1750         }
1751         # Check errors on close as well:
1752         close($aa_fd)
1753             or die "failed to change apparmor profile (close() failed): $!\n";
1754
1755         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1756
1757         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1758         chdir('/')
1759             or die "failed to change root directory within the container's mount namespace: $!\n";
1760
1761         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1762     });
1763 }
1764
1765 # Create a directory in the mountpoint staging tempfs.
1766 sub get_staging_mount_path($) {
1767     my ($opt) = @_;
1768
1769     my $target = get_staging_tempfs() . "/$opt";
1770     if (!mkdir($target) && $! != EEXIST) {
1771         die "failed to create directory $target: $!\n";
1772     }
1773
1774     return $target;
1775 }
1776
1777 # Mount /run/pve/mountpoints as tmpfs
1778 sub get_staging_tempfs() {
1779     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1780     # mounts to that.
1781     my $target = '/var/lib/lxc/.pve-staged-mounts';
1782     if (!mkdir($target)) {
1783         return $target if $! == EEXIST;
1784         die "failed to create directory $target: $!\n";
1785     }
1786
1787     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1788         or die "failed to mount $target as tmpfs: $!\n";
1789
1790     return $target;
1791 }
1792
1793 sub mkfs {
1794     my ($dev, $rootuid, $rootgid) = @_;
1795
1796     run_command(['mkfs.ext4', '-O', 'mmp',
1797                              '-E', "root_owner=$rootuid:$rootgid",
1798                              $dev]);
1799 }
1800
1801 sub format_disk {
1802     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1803
1804     if ($volid =~ m!^/dev/.+!) {
1805         mkfs($volid);
1806         return;
1807     }
1808
1809     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1810
1811     die "cannot format volume '$volid' with no storage\n" if !$storage;
1812
1813     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1814
1815     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1816
1817     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1818
1819     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1820         PVE::Storage::parse_volname($storage_cfg, $volid);
1821
1822     die "cannot format volume '$volid' (format == $format)\n"
1823         if $format ne 'raw';
1824
1825     mkfs($path, $rootuid, $rootgid);
1826 }
1827
1828 sub destroy_disks {
1829     my ($storecfg, $vollist) = @_;
1830
1831     foreach my $volid (@$vollist) {
1832         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1833         warn $@ if $@;
1834     }
1835 }
1836
1837 sub alloc_disk {
1838     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1839
1840     my $needs_chown = 0;
1841     my $volid;
1842
1843     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1844     # fixme: use better naming ct-$vmid-disk-X.raw?
1845
1846     eval {
1847         my $do_format = 0;
1848         if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1849             if ($size_kb > 0) {
1850                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1851                                                    undef, $size_kb);
1852                 $do_format = 1;
1853             } else {
1854                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1855                                                    undef, 0);
1856                 $needs_chown = 1;
1857             }
1858         } elsif ($scfg->{type} eq 'zfspool') {
1859
1860             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1861                                                undef, $size_kb);
1862             $needs_chown = 1;
1863         } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1864
1865             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1866             $do_format = 1;
1867
1868         } elsif ($scfg->{type} eq 'rbd') {
1869
1870             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1871             $do_format = 1;
1872         } else {
1873             die "unable to create containers on storage type '$scfg->{type}'\n";
1874         }
1875         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1876     };
1877     if (my $err = $@) {
1878         # in case formatting got interrupted:
1879         if (defined($volid)) {
1880             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1881             warn $@ if $@;
1882         }
1883         die $err;
1884     }
1885
1886     return ($volid, $needs_chown);
1887 }
1888
1889 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1890 sub create_disks {
1891     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1892
1893     my $vollist = [];
1894
1895     eval {
1896         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1897         my $chown_vollist = [];
1898
1899         PVE::LXC::Config->foreach_volume($settings, sub {
1900             my ($ms, $mountpoint) = @_;
1901
1902             my $volid = $mountpoint->{volume};
1903             my $mp = $mountpoint->{mp};
1904
1905             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1906
1907             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1908                 my ($storeid, $size_gb) = ($1, $2);
1909
1910                 my $size_kb = int(${size_gb}*1024) * 1024;
1911
1912                 my $needs_chown = 0;
1913                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1914                 push @$chown_vollist, $volid if $needs_chown;
1915                 push @$vollist, $volid;
1916                 $mountpoint->{volume} = $volid;
1917                 $mountpoint->{size} = $size_kb * 1024;
1918                 if ($pending) {
1919                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1920                 } else {
1921                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1922                 }
1923             } else {
1924                 # use specified/existing volid/dir/device
1925                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1926             }
1927         });
1928
1929         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1930         foreach my $volid (@$chown_vollist) {
1931             my $path = PVE::Storage::path($storecfg, $volid, undef);
1932             chown($rootuid, $rootgid, $path);
1933         }
1934         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1935     };
1936     # free allocated images on error
1937     if (my $err = $@) {
1938         destroy_disks($storecfg, $vollist);
1939         die $err;
1940     }
1941     return $vollist;
1942 }
1943
1944 sub update_disksize {
1945     my ($vmid, $conf, $all_volumes) = @_;
1946
1947     my $changes;
1948     my $prefix = "CT $vmid:";
1949
1950     my $update_mp = sub {
1951         my ($key, $mp, @param) = @_;
1952         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1953
1954         if (!defined($mp->{size}) || $size != $mp->{size}) {
1955             $changes = 1;
1956             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1957             $mp->{size} = $size;
1958             my $nomp = 1 if ($key eq 'rootfs');
1959             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1960         }
1961     };
1962
1963     PVE::LXC::Config->foreach_volume($conf, $update_mp);
1964
1965     return $changes;
1966 }
1967
1968 sub update_unused {
1969     my ($vmid, $conf, $all_volumes) = @_;
1970
1971     my $changes;
1972     my $prefix = "CT $vmid:";
1973
1974     # Note: it is allowed to define multiple storage entries with the same path
1975     # (alias), so we need to check both 'volid' and real 'path' (two different
1976     # volid can point to the same path).
1977
1978     # used and unused disks
1979     my $refpath = {};
1980     my $orphans = {};
1981
1982     foreach my $opt (keys %$conf) {
1983         next if ($opt !~ m/^unused\d+$/);
1984         my $vol = $all_volumes->{$conf->{$opt}};
1985         $refpath->{$vol->{path}} = $vol->{volid};
1986     }
1987
1988     foreach my $key (keys %$all_volumes) {
1989         my $vol = $all_volumes->{$key};
1990         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
1991         my $path = $vol->{path};
1992
1993         if ($in_use) {
1994             $refpath->{$path} = $key;
1995             delete $orphans->{$path};
1996         } else {
1997             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
1998                 $orphans->{$path} = $key;
1999             }
2000         }
2001     }
2002
2003     for my $key (keys %$orphans) {
2004         my $disk = $orphans->{$key};
2005         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2006
2007         if ($unused) {
2008             $changes = 1;
2009             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2010         }
2011     }
2012
2013     return $changes;
2014 }
2015
2016 sub scan_volids {
2017     my ($cfg, $vmid) = @_;
2018
2019     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid);
2020
2021     my $all_volumes = {};
2022     foreach my $storeid (keys %$info) {
2023         foreach my $item (@{$info->{$storeid}}) {
2024             my $volid = $item->{volid};
2025             next if !($volid && $item->{size});
2026             $item->{path} = PVE::Storage::path($cfg, $volid);
2027             $all_volumes->{$volid} = $item;
2028         }
2029     }
2030
2031     return $all_volumes;
2032 }
2033
2034 sub rescan {
2035     my ($vmid, $nolock, $dryrun) = @_;
2036
2037     my $cfg = PVE::Storage::config();
2038
2039     # FIXME: Remove once our RBD plugin can handle CT and VM on a single storage
2040     # see: https://pve.proxmox.com/pipermail/pve-devel/2018-July/032900.html
2041     foreach my $stor (keys %{$cfg->{ids}}) {
2042         delete($cfg->{ids}->{$stor}) if !$cfg->{ids}->{$stor}->{content}->{rootdir};
2043     }
2044
2045     print "rescan volumes...\n";
2046     my $all_volumes = scan_volids($cfg, $vmid);
2047
2048     my $updatefn =  sub {
2049         my ($vmid) = @_;
2050
2051         my $changes;
2052         my $conf = PVE::LXC::Config->load_config($vmid);
2053
2054         PVE::LXC::Config->check_lock($conf);
2055
2056         my $vm_volids = {};
2057         foreach my $volid (keys %$all_volumes) {
2058             my $info = $all_volumes->{$volid};
2059             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2060         }
2061
2062         my $upu = update_unused($vmid, $conf, $vm_volids);
2063         my $upd = update_disksize($vmid, $conf, $vm_volids);
2064         $changes = $upu || $upd;
2065
2066         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2067     };
2068
2069     if (defined($vmid)) {
2070         if ($nolock) {
2071             &$updatefn($vmid);
2072         } else {
2073             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2074         }
2075     } else {
2076         my $vmlist = config_list();
2077         foreach my $vmid (keys %$vmlist) {
2078             if ($nolock) {
2079                 &$updatefn($vmid);
2080             } else {
2081                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2082             }
2083         }
2084     }
2085 }
2086
2087
2088 # bash completion helper
2089
2090 sub complete_os_templates {
2091     my ($cmdname, $pname, $cvalue) = @_;
2092
2093     my $cfg = PVE::Storage::config();
2094
2095     my $storeid;
2096
2097     if ($cvalue =~ m/^([^:]+):/) {
2098         $storeid = $1;
2099     }
2100
2101     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2102     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2103
2104     my $res = [];
2105     foreach my $id (keys %$data) {
2106         foreach my $item (@{$data->{$id}}) {
2107             push @$res, $item->{volid} if defined($item->{volid});
2108         }
2109     }
2110
2111     return $res;
2112 }
2113
2114 my $complete_ctid_full = sub {
2115     my ($running) = @_;
2116
2117     my $idlist = vmstatus();
2118
2119     my $active_hash = list_active_containers();
2120
2121     my $res = [];
2122
2123     foreach my $id (keys %$idlist) {
2124         my $d = $idlist->{$id};
2125         if (defined($running)) {
2126             next if $d->{template};
2127             next if $running && !$active_hash->{$id};
2128             next if !$running && $active_hash->{$id};
2129         }
2130         push @$res, $id;
2131
2132     }
2133     return $res;
2134 };
2135
2136 sub complete_ctid {
2137     return &$complete_ctid_full();
2138 }
2139
2140 sub complete_ctid_stopped {
2141     return &$complete_ctid_full(0);
2142 }
2143
2144 sub complete_ctid_running {
2145     return &$complete_ctid_full(1);
2146 }
2147
2148 sub parse_id_maps {
2149     my ($conf) = @_;
2150
2151     my $id_map = [];
2152     my $rootuid = 0;
2153     my $rootgid = 0;
2154
2155     my $lxc = $conf->{lxc};
2156     foreach my $entry (@$lxc) {
2157         my ($key, $value) = @$entry;
2158         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2159         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2160         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2161             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2162             push @$id_map, [$type, $ct, $host, $length];
2163             if ($ct == 0) {
2164                 $rootuid = $host if $type eq 'u';
2165                 $rootgid = $host if $type eq 'g';
2166             }
2167         } else {
2168             die "failed to parse idmap: $value\n";
2169         }
2170     }
2171
2172     if (!@$id_map && $conf->{unprivileged}) {
2173         # Should we read them from /etc/subuid?
2174         $id_map = [ ['u', '0', '100000', '65536'],
2175                     ['g', '0', '100000', '65536'] ];
2176         $rootuid = $rootgid = 100000;
2177     }
2178
2179     return ($id_map, $rootuid, $rootgid);
2180 }
2181
2182 sub userns_command {
2183     my ($id_map) = @_;
2184     if (@$id_map) {
2185         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2186     }
2187     return [];
2188 }
2189
2190 my sub print_ct_stderr_log {
2191     my ($vmid) = @_;
2192     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2193     return if !$log;
2194
2195     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2196         my $line = $2;
2197         print STDERR "$line\n";
2198     }
2199 }
2200
2201 my sub monitor_state_change($$) {
2202     my ($monitor_socket, $vmid) = @_;
2203     die "no monitor socket\n" if !defined($monitor_socket);
2204
2205     while (1) {
2206         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2207
2208         die "monitor socket: got EOF\n" if !defined($type);
2209
2210         next if $name ne "$vmid" || $type ne 'STATE';
2211
2212         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2213             alarm(0); # don't timeout after seeing the starting state
2214         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2215                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2216                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2217             return 0;
2218         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2219             return 1;
2220         } else {
2221             warn "unexpected message from monitor socket - " .
2222                  "type: '$type' - value: '$value'\n";
2223         }
2224     }
2225 }
2226 my sub monitor_start($$) {
2227     my ($monitor_socket, $vmid) = @_;
2228
2229     my $success = eval {
2230         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2231     };
2232     if (my $err = $@) {
2233         warn "problem with monitor socket, but continuing anyway: $err\n";
2234     } elsif (!$success) {
2235         print_ct_stderr_log($vmid);
2236         die "startup for container '$vmid' failed\n";
2237     }
2238 }
2239
2240 sub vm_start {
2241     my ($vmid, $conf, $skiplock, $debug) = @_;
2242
2243     # apply pending changes while starting
2244     if (scalar(keys %{$conf->{pending}})) {
2245         my $storecfg = PVE::Storage::config();
2246         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2247         PVE::LXC::Config->write_config($vmid, $conf);
2248         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2249     }
2250
2251     update_lxc_config($vmid, $conf);
2252
2253     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2254
2255     if ($skiplock) {
2256         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2257         close($fh);
2258     }
2259
2260     my $storage_cfg = PVE::Storage::config();
2261     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2262
2263     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2264
2265     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2266     warn $@ if $@;
2267
2268     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2269
2270     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2271     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2272
2273     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2274
2275     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2276     eval {
2277         run_command($cmd);
2278
2279         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2280
2281         # if debug is requested, print the log it also when the start succeeded
2282         print_ct_stderr_log($vmid) if $is_debug;
2283     };
2284     if (my $err = $@) {
2285         unlink $skiplock_flag_fn;
2286         die $err;
2287     }
2288     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2289
2290     return;
2291 }
2292
2293 # Helper to stop a container completely and make sure it has stopped completely.
2294 # This is necessary because we want the post-stop hook to have completed its
2295 # unmount-all step, but post-stop happens after lxc puts the container into the
2296 # STOPPED state.
2297 # $kill - if true it will always do an immediate hard-stop
2298 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2299 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2300 sub vm_stop {
2301     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2302
2303     # Open the container's command socket.
2304     my $path = "\0/var/lib/lxc/$vmid/command";
2305     my $sock = IO::Socket::UNIX->new(
2306         Type => SOCK_STREAM(),
2307         Peer => $path,
2308     );
2309     if (!$sock) {
2310         return if $! == ECONNREFUSED; # The container is not running
2311         die "failed to open container ${vmid}'s command socket: $!\n";
2312     }
2313
2314     my $conf = PVE::LXC::Config->load_config($vmid);
2315     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2316
2317     # Stop the container:
2318
2319     my $cmd = ['lxc-stop', '-n', $vmid];
2320
2321     if ($kill) {
2322         push @$cmd, '--kill'; # doesn't allow timeouts
2323     } else {
2324         # lxc-stop uses a default timeout
2325         push @$cmd, '--nokill' if !$kill_after_timeout;
2326
2327         if (defined($shutdown_timeout)) {
2328             push @$cmd, '--timeout', $shutdown_timeout;
2329             # Give run_command 5 extra seconds
2330             $shutdown_timeout += 5;
2331         }
2332     }
2333
2334     eval { run_command($cmd, timeout => $shutdown_timeout) };
2335     if (my $err = $@) {
2336         warn $@ if $@;
2337     }
2338
2339     my $result = <$sock>;
2340
2341     return if !defined $result; # monitor is gone and the ct has stopped.
2342     die "container did not stop\n";
2343 }
2344
2345 sub vm_reboot {
2346     my ($vmid, $timeout, $skiplock) = @_;
2347
2348     PVE::LXC::Config->lock_config($vmid, sub {
2349         return if !check_running($vmid);
2350
2351         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2352
2353         my $conf = PVE::LXC::Config->load_config($vmid);
2354         vm_start($vmid, $conf);
2355     });
2356 }
2357
2358 sub run_unshared {
2359     my ($code) = @_;
2360
2361     return PVE::Tools::run_fork(sub {
2362         # Unshare the mount namespace
2363         die "failed to unshare mount namespace: $!\n"
2364             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2365         run_command(['mount', '--make-rslave', '/']);
2366         return $code->();
2367     });
2368 }
2369
2370 my $copy_volume = sub {
2371     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2372
2373     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2374     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2375
2376     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2377     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2378
2379     my @mounted;
2380     eval {
2381         # mount and copy
2382         mkdir $src;
2383         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2384         push @mounted, $src;
2385         mkdir $dest;
2386         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2387         push @mounted, $dest;
2388
2389         $bwlimit //= 0;
2390
2391         run_command([
2392             'rsync',
2393             '--stats',
2394             '-X',
2395             '-A',
2396             '--numeric-ids',
2397             '-aH',
2398             '--whole-file',
2399             '--sparse',
2400             '--one-file-system',
2401             "--bwlimit=$bwlimit",
2402             "$src/",
2403             $dest
2404         ]);
2405     };
2406     my $err = $@;
2407
2408     # Wait for rsync's children to release dest so that
2409     # consequent file operations (umount, remove) are possible
2410     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2411
2412     foreach my $mount (reverse @mounted) {
2413         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2414         warn "Can't umount $mount\n" if $@;
2415     }
2416
2417     # If this fails they're used as mount points in a concurrent operation
2418     # (which should not happen but there's also no real need to get rid of them).
2419     rmdir $dest;
2420     rmdir $src;
2421
2422     die $err if $err;
2423 };
2424
2425 # Should not be called after unsharing the mount namespace!
2426 sub copy_volume {
2427     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2428
2429     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2430     File::Path::make_path("/var/lib/lxc/$vmid");
2431     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2432     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2433
2434     # get id's for unprivileged container
2435     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2436
2437     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2438     # are visible in this namespace, otherwise the host only sees the empty
2439     # (not-mounted) directory.
2440     my $new_volid;
2441     eval {
2442         # Make sure $mp contains a correct size.
2443         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2444         my $needs_chown;
2445         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2446         if ($needs_chown) {
2447             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2448             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2449             chown($rootuid, $rootgid, $path);
2450         }
2451
2452         run_unshared(sub {
2453             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2454         });
2455     };
2456     if (my $err = $@) {
2457         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2458             if defined($new_volid);
2459         die $err;
2460     }
2461
2462     return $new_volid;
2463 }
2464
2465 sub get_lxc_version() {
2466     my $version;
2467     run_command([qw(lxc-start --version)], outfunc => sub {
2468         my ($line) = @_;
2469         # We only parse out major & minor version numbers.
2470         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2471             $version = [$1, $2];
2472         }
2473     });
2474
2475     die "failed to get lxc version\n" if !defined($version);
2476
2477     # return as a list:
2478     return $version->@*;
2479 }
2480
2481 sub freeze($) {
2482     my ($vmid) = @_;
2483     PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2484 }
2485
2486 sub thaw($) {
2487     my ($vmid) = @_;
2488     PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2489 }
2490
2491 1;