src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     run_command
  24     dir_glob_foreach
  25     file_get_contents
  26     file_set_contents
  27     AT_FDCWD
  28     O_PATH
  29     $IPV4RE
  30     $IPV6RE
  31 );
  32 use PVE::RPCEnvironment;
  33 use PVE::CpuSet;
  34 use PVE::Network;
  35 use PVE::AccessControl;
  36 use PVE::ProcFSTools;
  37 use PVE::Syscall qw(:fsmount);
  38 use PVE::LXC::Config;
  39 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  40 use PVE::LXC::Tools;
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Monitor;
  43 use PVE::CGroup;
  44
  45 use Time::HiRes qw (gettimeofday);
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         my $lxcmem = int($memory*1024*1024);
 689         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 690
 691         my $lxcswap = int($swap*1024*1024);
 692         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 693     }
 694
 695     if ($cgv1->{cpu}) {
 696         if (my $cpulimit = $conf->{cpulimit}) {
 697             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 698             my $value = int(100000*$cpulimit);
 699             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 700         }
 701
 702         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 703         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 704     } elsif ($cgv2->{cpu}) {
 705         # See PVE::CGroup
 706         if (my $cpulimit = $conf->{cpulimit}) {
 707             my $value = int(100000*$cpulimit);
 708             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 709         }
 710
 711         if (defined(my $shares = $conf->{cpuunits})) {
 712             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 713             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 714         }
 715     }
 716
 717     die "missing 'rootfs' configuration\n"
 718         if !defined($conf->{rootfs});
 719
 720     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 721
 722     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 723
 724     foreach my $k (sort keys %$conf) {
 725         next if $k !~ m/^net(\d+)$/;
 726         my $ind = $1;
 727         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 728         $raw .= "lxc.net.$ind.type = veth\n";
 729         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 730         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 731         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 732         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 733
 734         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 735         if ($lxc_major >= 4) {
 736             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 737         }
 738     }
 739
 740     my $had_cpuset = 0;
 741     if (my $lxcconf = $conf->{lxc}) {
 742         foreach my $entry (@$lxcconf) {
 743             my ($k, $v) = @$entry;
 744             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 745             $raw .= "$k = $v\n";
 746         }
 747     }
 748
 749     my $cpuset;
 750     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 751     if (defined($cpuset_cgroup)) {
 752         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 753             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 754     }
 755     my $cores = $conf->{cores};
 756     if (!$had_cpuset && $cores && $cpuset) {
 757         my @members = $cpuset->members();
 758         while (scalar(@members) > $cores) {
 759             my $randidx = int(rand(scalar(@members)));
 760             $cpuset->delete($members[$randidx]);
 761             splice(@members, $randidx, 1); # keep track of the changes
 762         }
 763         my $ver = $cpuset_version == 1 ? '' : '2';
 764         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 765     }
 766
 767     File::Path::mkpath("$dir/rootfs");
 768
 769     PVE::Tools::file_set_contents("$dir/config", $raw);
 770 }
 771
 772 # verify and cleanup nameserver list (replace \0 with ' ')
 773 sub verify_nameserver_list {
 774     my ($nameserver_list) = @_;
 775
 776     my @list = ();
 777     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 778         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 779         push @list, $server;
 780     }
 781
 782     return join(' ', @list);
 783 }
 784
 785 sub verify_searchdomain_list {
 786     my ($searchdomain_list) = @_;
 787
 788     my @list = ();
 789     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 790         # todo: should we add checks for valid dns domains?
 791         push @list, $server;
 792     }
 793
 794     return join(' ', @list);
 795 }
 796
 797 sub get_console_command {
 798     my ($vmid, $conf, $escapechar) = @_;
 799
 800     # '-1' as $escapechar disables keyboard escape sequence
 801     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 802
 803     my $cmode = PVE::LXC::Config->get_cmode($conf);
 804
 805     my $cmd = [];
 806     if ($cmode eq 'console') {
 807         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 808         push @$cmd, '-e', $escapechar if $escapechar;
 809     } elsif ($cmode eq 'tty') {
 810         push @$cmd, 'lxc-console', '-n',  $vmid;
 811         push @$cmd, '-e', $escapechar if $escapechar;
 812     } elsif ($cmode eq 'shell') {
 813         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 814     } else {
 815         die "internal error";
 816     }
 817
 818     return $cmd;
 819 }
 820
 821 sub get_primary_ips {
 822     my ($conf) = @_;
 823
 824     # return data from net0
 825
 826     return undef if !defined($conf->{net0});
 827     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 828
 829     my $ipv4 = $net->{ip};
 830     if ($ipv4) {
 831         if ($ipv4 =~ /^(dhcp|manual)$/) {
 832             $ipv4 = undef
 833         } else {
 834             $ipv4 =~ s!/\d+$!!;
 835         }
 836     }
 837     my $ipv6 = $net->{ip6};
 838     if ($ipv6) {
 839         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 840             $ipv6 = undef;
 841         } else {
 842             $ipv6 =~ s!/\d+$!!;
 843         }
 844     }
 845
 846     return ($ipv4, $ipv6);
 847 }
 848
 849 sub delete_mountpoint_volume {
 850     my ($storage_cfg, $vmid, $volume) = @_;
 851
 852     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 853
 854     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 855
 856     if ($vmid == $owner) {
 857         PVE::Storage::vdisk_free($storage_cfg, $volume);
 858     } else {
 859         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 860     }
 861 }
 862
 863 sub destroy_lxc_container {
 864     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 865
 866     my $volids = {};
 867     my $remove_volume = sub {
 868         my ($ms, $mountpoint) = @_;
 869
 870         my $volume = $mountpoint->{volume};
 871
 872         return if $volids->{$volume};
 873         $volids->{$volume} = 1;
 874
 875         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 876     };
 877     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 878
 879     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 880
 881     if ($purge_unreferenced) { # also remove unreferenced disk
 882         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 883         PVE::Storage::foreach_volid($vmdisks, sub {
 884             my ($volid, $sid, $volname, $d) = @_;
 885             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 886             warn $@ if $@;
 887         });
 888     }
 889
 890     rmdir "/var/lib/lxc/$vmid/rootfs";
 891     unlink "/var/lib/lxc/$vmid/config";
 892     rmdir "/var/lib/lxc/$vmid";
 893     if (defined $replacement_conf) {
 894         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 895     } else {
 896         PVE::LXC::Config->destroy_config($vmid);
 897     }
 898 }
 899
 900 sub vm_stop_cleanup {
 901     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 902
 903     return if $keepActive;
 904
 905     eval {
 906         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 907         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 908     };
 909     warn $@ if $@; # avoid errors - just warn
 910 }
 911
 912 sub update_net {
 913     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 914
 915     if ($newnet->{type} ne 'veth') {
 916         # for when there are physical interfaces
 917         die "cannot update interface of type $newnet->{type}";
 918     }
 919
 920     my $veth = "veth${vmid}i${netid}";
 921     my $eth = $newnet->{name};
 922
 923     if (my $oldnetcfg = $conf->{$opt}) {
 924         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 925
 926         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 927             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 928
 929             PVE::Network::veth_delete($veth);
 930             delete $conf->{$opt};
 931             PVE::LXC::Config->write_config($vmid, $conf);
 932
 933             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 934
 935         } else {
 936             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 937                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 938                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 939
 940                 if ($oldnet->{bridge}) {
 941                     PVE::Network::tap_unplug($veth);
 942                     foreach (qw(bridge tag firewall)) {
 943                         delete $oldnet->{$_};
 944                     }
 945                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 946                     PVE::LXC::Config->write_config($vmid, $conf);
 947                 }
 948
 949                 if ($have_sdn) {
 950                     PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 951                     PVE::Network::SDN::Zones::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{bridge}, $newnet->{firewall});
 952                 } else {
 953                     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 954                     PVE::Network::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{firewall}); # early returns if brport has learning on
 955                 }
 956
 957                 # This includes the rate:
 958                 foreach (qw(bridge tag firewall rate)) {
 959                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 960                 }
 961             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 962                 # Rate can be applied on its own but any change above needs to
 963                 # include the rate in tap_plug since OVS resets everything.
 964                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 965                 $oldnet->{rate} = $newnet->{rate}
 966             }
 967             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 968             PVE::LXC::Config->write_config($vmid, $conf);
 969         }
 970     } else {
 971         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 972     }
 973
 974     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 975 }
 976
 977 sub hotplug_net {
 978     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 979
 980     my $veth = "veth${vmid}i${netid}";
 981     my $vethpeer = $veth . "p";
 982     my $eth = $newnet->{name};
 983
 984     if ($have_sdn) {
 985         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 986         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 987         PVE::Network::SDN::Zones::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{bridge}, $newnet->{firewall});
 988     } else {
 989         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 990         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 991         PVE::Network::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{firewall}); # early returns if brport has learning on
 992     }
 993
 994     # attach peer in container
 995     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 996     PVE::Tools::run_command($cmd);
 997
 998     # link up peer in container
 999     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1000     PVE::Tools::run_command($cmd);
1001
1002     my $done = { type => 'veth' };
1003     foreach (qw(bridge tag firewall hwaddr name)) {
1004         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1005     }
1006     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1007
1008     PVE::LXC::Config->write_config($vmid, $conf);
1009 }
1010
1011 sub update_ipconfig {
1012     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1013
1014     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1015
1016     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1017     my $deleted = [];
1018     my $added = [];
1019     my $nscmd = sub {
1020         my $cmdargs = shift;
1021         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1022     };
1023     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1024
1025     my $change_ip_config = sub {
1026         my ($ipversion) = @_;
1027
1028         my $family_opt = "-$ipversion";
1029         my $suffix = $ipversion == 4 ? '' : $ipversion;
1030         my $gw= "gw$suffix";
1031         my $ip= "ip$suffix";
1032
1033         my $newip = $newnet->{$ip};
1034         my $newgw = $newnet->{$gw};
1035         my $oldip = $optdata->{$ip};
1036         my $oldgw = $optdata->{$gw};
1037
1038         my $change_ip = safe_string_ne($oldip, $newip);
1039         my $change_gw = safe_string_ne($oldgw, $newgw);
1040
1041         return if !$change_ip && !$change_gw;
1042
1043         # step 1: add new IP, if this fails we cancel
1044         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1045         if ($change_ip && $is_real_ip) {
1046             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1047             if (my $err = $@) {
1048                 warn $err;
1049                 return;
1050             }
1051         }
1052
1053         # step 2: replace gateway
1054         #   If this fails we delete the added IP and cancel.
1055         #   If it succeeds we save the config and delete the old IP, ignoring
1056         #   errors. The config is then saved.
1057         # Note: 'ip route replace' can add
1058         if ($change_gw) {
1059             if ($newgw) {
1060                 eval {
1061                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1062                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1063                     }
1064                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1065                 };
1066                 if (my $err = $@) {
1067                     warn $err;
1068                     # the route was not replaced, the old IP is still available
1069                     # rollback (delete new IP) and cancel
1070                     if ($change_ip) {
1071                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1072                         warn $@ if $@; # no need to die here
1073                     }
1074                     return;
1075                 }
1076             } else {
1077                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1078                 # if the route was not deleted, the guest might have deleted it manually
1079                 # warn and continue
1080                 warn $@ if $@;
1081             }
1082             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1083                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1084                 # warn if the route was deleted manually
1085                 warn $@ if $@;
1086             }
1087         }
1088
1089         # from this point on we save the configuration
1090         # step 3: delete old IP ignoring errors
1091         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1092             # We need to enable promote_secondaries, otherwise our newly added
1093             # address will be removed along with the old one.
1094             my $promote = 0;
1095             eval {
1096                 if ($ipversion == 4) {
1097                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1098                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1099                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1100                 }
1101                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1102             };
1103             warn $@ if $@; # no need to die here
1104
1105             if ($ipversion == 4) {
1106                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1107             }
1108         }
1109
1110         foreach my $property ($ip, $gw) {
1111             if ($newnet->{$property}) {
1112                 $optdata->{$property} = $newnet->{$property};
1113             } else {
1114                 delete $optdata->{$property};
1115             }
1116         }
1117         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1118         PVE::LXC::Config->write_config($vmid, $conf);
1119         $lxc_setup->setup_network($conf);
1120     };
1121
1122     &$change_ip_config(4);
1123     &$change_ip_config(6);
1124
1125 }
1126
1127 my $open_namespace = sub {
1128     my ($vmid, $pid, $kind) = @_;
1129     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1130         or die "failed to open $kind namespace of container $vmid: $!\n";
1131     return $fd;
1132 };
1133
1134 my $enter_namespace = sub {
1135     my ($vmid, $pid, $kind, $type) = @_;
1136     my $fd = $open_namespace->($vmid, $pid, $kind);
1137     PVE::Tools::setns(fileno($fd), $type)
1138         or die "failed to enter $kind namespace of container $vmid: $!\n";
1139     close $fd;
1140 };
1141
1142 my $get_container_namespace = sub {
1143     my ($vmid, $pid, $kind) = @_;
1144
1145     my $pidfd;
1146     if (!defined($pid)) {
1147         # Pin the pid while we're grabbing its stuff from /proc
1148         ($pid, $pidfd) = open_lxc_pid($vmid)
1149             or die "failed to open pidfd of container $vmid\'s init process\n";
1150     }
1151
1152     return $open_namespace->($vmid, $pid, $kind);
1153 };
1154
1155 my $do_syncfs = sub {
1156     my ($vmid, $pid, $socket) = @_;
1157
1158     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1159
1160     # Tell the parent process to start reading our /proc/mounts
1161     print {$socket} "go\n";
1162     $socket->flush();
1163
1164     # Receive /proc/self/mounts
1165     my $mountdata = do { local $/ = undef; <$socket> };
1166     close $socket;
1167
1168     my %nosyncfs = (
1169         cgroup => 1,
1170         cgroup2 => 1,
1171         devtmpfs => 1,
1172         devpts => 1,
1173         'fuse.lxcfs' => 1,
1174         fusectl => 1,
1175         mqueue => 1,
1176         proc => 1,
1177         sysfs => 1,
1178         tmpfs => 1,
1179     );
1180
1181     # Now sync all mountpoints...
1182     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1183     foreach my $mp (@$mounts) {
1184         my ($what, $dir, $fs) = @$mp;
1185         next if $nosyncfs{$fs};
1186         eval { PVE::Tools::sync_mountpoint($dir); };
1187         warn $@ if $@;
1188     }
1189 };
1190
1191 sub sync_container_namespace {
1192     my ($vmid) = @_;
1193     my $pid = find_lxc_pid($vmid);
1194
1195     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1196     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1197         or die "failed to create socketpair: $!\n";
1198
1199     my $child = fork();
1200     die "fork failed: $!\n" if !defined($child);
1201
1202     if (!$child) {
1203         eval {
1204             close $pfd;
1205             &$do_syncfs($vmid, $pid, $cfd);
1206         };
1207         if (my $err = $@) {
1208             warn $err;
1209             POSIX::_exit(1);
1210         }
1211         POSIX::_exit(0);
1212     }
1213     close $cfd;
1214     my $go = <$pfd>;
1215     die "failed to enter container namespace\n" if $go ne "go\n";
1216
1217     open my $mounts, '<', "/proc/$child/mounts"
1218         or die "failed to open container's /proc/mounts: $!\n";
1219     my $mountdata = do { local $/ = undef; <$mounts> };
1220     close $mounts;
1221     print {$pfd} $mountdata;
1222     close $pfd;
1223
1224     while (waitpid($child, 0) != $child) {}
1225     die "failed to sync container namespace\n" if $? != 0;
1226 }
1227
1228 sub template_create {
1229     my ($vmid, $conf) = @_;
1230
1231     my $storecfg = PVE::Storage::config();
1232
1233     PVE::LXC::Config->foreach_volume($conf, sub {
1234         my ($ms, $mountpoint) = @_;
1235
1236         my $volid = $mountpoint->{volume};
1237
1238         die "Template feature is not available for '$volid'\n"
1239             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1240     });
1241
1242     PVE::LXC::Config->foreach_volume($conf, sub {
1243         my ($ms, $mountpoint) = @_;
1244
1245         my $volid = $mountpoint->{volume};
1246
1247         PVE::Storage::activate_volumes($storecfg, [$volid]);
1248
1249         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1250         $mountpoint->{volume} = $template_volid;
1251         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1252     });
1253
1254     PVE::LXC::Config->write_config($vmid, $conf);
1255 }
1256
1257 sub check_ct_modify_config_perm {
1258     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1259
1260     return 1 if $authuser eq 'root@pam';
1261     my $storage_cfg = PVE::Storage::config();
1262
1263     my $check = sub {
1264         my ($opt, $delete) = @_;
1265         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1266             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1267         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1268             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1269             return if $delete;
1270             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1271             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1272                 if $data->{type} ne 'volume';
1273             my $volid = $data->{volume};
1274             if ($volid =~ $NEW_DISK_RE) {
1275                 my $sid = $1;
1276                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1277             } else {
1278                 PVE::Storage::check_volume_access(
1279                     $rpcenv,
1280                     $authuser,
1281                     $storage_cfg,
1282                     $vmid,
1283                     $volid,
1284                     'rootdir',
1285                 );
1286             }
1287         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1288             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1289         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1290                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1291             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1292         } elsif ($opt eq 'features') {
1293             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1294                 if !$unprivileged;
1295
1296             my $nesting_changed = 0;
1297             my $other_changed = 0;
1298             if (!$delete) {
1299                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1300                 if (defined($oldconf) && $oldconf->{$opt}) {
1301                     # existing container with features
1302                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1303                     for my $feature ((keys %$old_features, keys %$features)) {
1304                         my $old = $old_features->{$feature} // '';
1305                         my $new = $features->{$feature} // '';
1306                         if ($old ne $new) {
1307                             if ($feature eq 'nesting') {
1308                                 $nesting_changed = 1;
1309                                 next;
1310                             } else {
1311                                 $other_changed = 1;
1312                                 last;
1313                             }
1314                         }
1315                     }
1316                 } else {
1317                     # new container or no features defined
1318                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1319                         $nesting_changed = 1;
1320                     } elsif (scalar(keys %$features) > 0) {
1321                         $other_changed = 1;
1322                     }
1323                 }
1324             } else {
1325                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1326                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1327                     $nesting_changed = 1;
1328                 } elsif (scalar(keys %$features) > 0) {
1329                     $other_changed = 1;
1330                 }
1331             }
1332             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1333                 if $other_changed;
1334             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1335                 if $nesting_changed;
1336         } elsif ($opt eq 'hookscript') {
1337             # For now this is restricted to root@pam
1338             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1339         } else {
1340             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1341         }
1342     };
1343
1344     foreach my $opt (keys %$newconf) {
1345         &$check($opt, 0);
1346     }
1347     foreach my $opt (@$delete) {
1348         &$check($opt, 1);
1349     }
1350
1351     return 1;
1352 }
1353
1354 sub umount_all {
1355     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1356
1357     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1358     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1359
1360     my $res = 1;
1361
1362     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1363         my ($ms, $mountpoint) = @_;
1364
1365         my $volid = $mountpoint->{volume};
1366         my $mount = $mountpoint->{mp};
1367
1368         return if !$volid || !$mount;
1369
1370         my $mount_path = "$rootdir/$mount";
1371         $mount_path =~ s!/+!/!g;
1372
1373         return if !PVE::ProcFSTools::is_mounted($mount_path);
1374
1375         eval {
1376             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1377         };
1378         if (my $err = $@) {
1379             if ($noerr) {
1380                 $res = 0;
1381                 warn $err;
1382             } else {
1383                 die $err;
1384             }
1385         }
1386     });
1387
1388     return $res; # tell caller if (some) umounts failed for the noerr case
1389 }
1390
1391 sub mount_all {
1392     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1393
1394     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1395     File::Path::make_path($rootdir);
1396
1397     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1398     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1399
1400     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1401
1402     eval {
1403         PVE::LXC::Config->foreach_volume($conf, sub {
1404             my ($ms, $mountpoint) = @_;
1405
1406             $mountpoint->{ro} = 0 if $ignore_ro;
1407
1408             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1409         });
1410     };
1411     if (my $err = $@) {
1412         warn "mounting container failed\n";
1413         umount_all($vmid, $storage_cfg, $conf, 1);
1414         die $err;
1415     }
1416
1417     return $rootdir;
1418 }
1419
1420
1421 sub mountpoint_mount_path {
1422     my ($mountpoint, $storage_cfg, $snapname) = @_;
1423
1424     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1425 }
1426
1427 sub query_loopdev {
1428     my ($path) = @_;
1429     my $found;
1430     my $parser = sub {
1431         my $line = shift;
1432         if ($line =~ m@^(/dev/loop\d+):@) {
1433             $found = $1;
1434         }
1435     };
1436     my $cmd = ['losetup', '--associated', $path];
1437     PVE::Tools::run_command($cmd, outfunc => $parser);
1438     return $found;
1439 }
1440
1441 # Run a function with a file attached to a loop device.
1442 # The loop device is always detached afterwards (or set to autoclear).
1443 # Returns the loop device.
1444 sub run_with_loopdev {
1445     my ($func, $file, $readonly) = @_;
1446     my $device = query_loopdev($file);
1447     # Try to reuse an existing device
1448     if ($device) {
1449         # We assume that whoever setup the loop device is responsible for
1450         # detaching it.
1451         &$func($device);
1452         return $device;
1453     }
1454
1455     my $parser = sub {
1456         my $line = shift;
1457         if ($line =~ m@^(/dev/loop\d+)$@) {
1458             $device = $1;
1459         }
1460     };
1461     my $losetup_cmd = [
1462         'losetup',
1463         '--show',
1464         '-f',
1465         $file,
1466     ];
1467     push @$losetup_cmd, '-r' if $readonly;
1468     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1469     die "failed to setup loop device for $file\n" if !$device;
1470     eval { &$func($device); };
1471     my $err = $@;
1472     PVE::Tools::run_command(['losetup', '-d', $device]);
1473     die $err if $err;
1474     return $device;
1475 }
1476
1477 # In scalar mode: returns a file handle to the deepest directory node.
1478 # In list context: returns a list of:
1479 #   * the deepest directory node
1480 #   * the 2nd deepest directory (parent of the above)
1481 #   * directory name of the last directory
1482 # So that the path $2/$3 should lead to $1 afterwards.
1483 sub walk_tree_nofollow($$$;$$) {
1484     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1485
1486     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1487         or die "failed to open start directory $start: $!\n";
1488
1489     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1490 }
1491
1492
1493 sub walk_tree_nofollow_fd($$$$;$$) {
1494     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1495
1496     # splitdir() returns '' for empty components including the leading /
1497     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1498
1499     my $fd = $start_fd;
1500     my $dir = $start_dirname;
1501     my $last_component = undef;
1502     my $second = $fd;
1503     foreach my $component (@comps) {
1504         $dir .= "/$component";
1505         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1506
1507         if (!$next) {
1508             # failed, check for symlinks and try to create the path
1509             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1510             die "cannot open directory $dir: $!\n" if !$mkdir;
1511
1512             # We don't check for errors on mkdirat() here and just try to
1513             # openat() again, since at least one error (EEXIST) is an
1514             # expected possibility if multiple containers start
1515             # simultaneously. If someone else injects a symlink now then
1516             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1517             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1518
1519             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1520             die "failed to create path: $dir: $!\n" if !$next;
1521
1522             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1523                 if defined($rootuid) && defined($rootgid);
1524         }
1525
1526         close $second if defined($last_component) && $second != $start_fd;
1527         $last_component = $component;
1528         $second = $fd;
1529         $fd = $next;
1530     }
1531
1532     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1533     close $second if defined($last_component) && $second != $start_fd;
1534     return $fd;
1535 }
1536
1537 # To guard against symlink attack races against other currently running
1538 # containers with shared recursive bind mount hierarchies we prepare a
1539 # directory handle for the directory we're mounting over to verify the
1540 # mountpoint afterwards.
1541 sub __bindmount_prepare {
1542     my ($hostroot, $dir) = @_;
1543     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1544     return $srcdh;
1545 }
1546
1547 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1548 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1549 # we intended to bind mount.
1550 sub __bindmount_verify {
1551     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1552     my $destdh;
1553     if ($parentfd) {
1554         # Open the mount point path coming from the parent directory since the
1555         # filehandle we would have gotten as first result of walk_tree_nofollow
1556         # earlier is still a handle to the underlying directory instead of the
1557         # mounted path.
1558         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1559         die "failed to open mount point: $!\n" if !$destdh;
1560         if ($ro) {
1561             my $dot = '.';
1562             # no separate function because 99% of the time it's the wrong thing to use.
1563             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1564                 die "failed to mark bind mount read only\n";
1565             }
1566             die "read-only check failed: $!\n" if $! != EROFS;
1567         }
1568     } else {
1569         # For the rootfs we don't have a parentfd so we open the path directly.
1570         # Note that this means bindmounting any prefix of the host's
1571         # /var/lib/lxc/$vmid path into another container is considered a grave
1572         # security error.
1573         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1574         die "failed to open mount point: $!\n" if !$destdh;
1575     }
1576
1577     my ($srcdev, $srcinode) = stat($srcdh);
1578     my ($dstdev, $dstinode) = stat($destdh);
1579     close $srcdh;
1580     close $destdh;
1581
1582     return ($srcdev == $dstdev && $srcinode == $dstinode);
1583 }
1584
1585 # Perform the actual bind mounting:
1586 sub __bindmount_do {
1587     my ($dir, $dest, $ro, @extra_opts) = @_;
1588     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1589     if ($ro) {
1590         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1591         if (my $err = $@) {
1592             warn "bindmount error\n";
1593             # don't leave writable bind-mounts behind...
1594             PVE::Tools::run_command(['umount', $dest]);
1595             die $err;
1596         }
1597     }
1598 }
1599
1600 sub bindmount {
1601     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1602
1603     my $srcdh = __bindmount_prepare('/', $dir);
1604
1605     __bindmount_do($dir, $dest, $ro, @extra_opts);
1606
1607     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1608         PVE::Tools::run_command(['umount', $dest]);
1609         die "detected mount path change at: $dir\n";
1610     }
1611 }
1612
1613 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1614 # from $rootdir and $mount and walk the path from $rootdir to the final
1615 # directory to check for symlinks.
1616 sub __mount_prepare_rootdir {
1617     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1618     $rootdir =~ s!/+!/!g;
1619     $rootdir =~ s!/+$!!;
1620     my $mount_path = "$rootdir/$mount";
1621     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1622     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1623 }
1624
1625 # use $rootdir = undef to just return the corresponding mount path
1626 sub mountpoint_mount {
1627     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1628     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1629 }
1630
1631 sub mountpoint_stage {
1632     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1633     my ($path, $loop, $dev) =
1634         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1635
1636     if (!defined($path)) {
1637         return undef if $! == ENOSYS;
1638         die "failed to mount subvolume: $!\n";
1639     }
1640
1641     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1642     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1643     # point).
1644     my $err;
1645     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1646         or die "open_tree() on mount point failed: $!\n";
1647
1648     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1649 }
1650
1651 sub mountpoint_insert_staged {
1652     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1653
1654     if (!defined($rootdir_fd)) {
1655         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1656             or die "failed to open '.': $!\n";
1657     }
1658
1659     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1660
1661     PVE::Tools::move_mount(
1662         fileno($mount_fd),
1663         '',
1664         fileno($dest_fd),
1665         '',
1666         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1667     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1668 }
1669
1670 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1671 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1672 #   Note that if the kernel does not support the new mount API, this will not perform any action
1673 #   and return `undef` with $! = ENOSYS.
1674 sub __mountpoint_mount {
1675     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1676
1677     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1678         $! = ENOSYS;
1679         return undef;
1680     }
1681
1682     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1683     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1684     # which we use in __bindmount_verify()!
1685     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1686
1687     my $volid = $mountpoint->{volume};
1688     my $type = $mountpoint->{type};
1689     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1690     my $mounted_dev;
1691
1692     return if !$volid || !$mount;
1693
1694     $mount =~ s!/+!/!g;
1695
1696     my $mount_path;
1697     my ($mpfd, $parentfd, $last_dir);
1698
1699     if (defined($rootdir)) {
1700         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1701             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1702     }
1703
1704     if (defined($stage_mount)) {
1705         $mount_path = $rootdir;
1706     }
1707
1708     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1709
1710     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1711
1712     my $optlist = [];
1713
1714     if (my $mountopts = $mountpoint->{mountoptions}) {
1715         my @opts = split(/;/, $mountpoint->{mountoptions});
1716         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1717     }
1718
1719     my $acl = $mountpoint->{acl};
1720     if (defined($acl)) {
1721         push @$optlist, ($acl ? 'acl' : 'noacl');
1722     }
1723
1724     my $optstring = join(',', @$optlist);
1725     my $readonly = $mountpoint->{ro};
1726
1727     my @extra_opts;
1728     @extra_opts = ('-o', $optstring) if $optstring;
1729
1730     if ($storage) {
1731
1732         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1733
1734         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1735
1736         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1737
1738         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1739             PVE::Storage::parse_volname($storage_cfg, $volid);
1740
1741         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1742
1743         if ($format eq 'subvol') {
1744             if ($mount_path) {
1745                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1746                 if (defined($snapname)) {
1747                     $name .= "\@$snapname";
1748                     if ($scfg->{type} eq 'zfspool') {
1749                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1750                     } else {
1751                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1752                     }
1753                 } else {
1754                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1755                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1756                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1757                     }
1758                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1759                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1760                 }
1761             }
1762             return wantarray ? ($path, 0, undef) : $path;
1763         } elsif ($format eq 'raw' || $format eq 'iso') {
1764             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1765             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1766             # Our autodev hook expects the /dev/dm-* device currently
1767             # and will create the /dev/mapper symlink accordingly
1768             $path = Cwd::realpath($path);
1769             die "failed to get device path\n" if !$path;
1770             ($path) = ($path =~ /^(.*)$/s); #untaint
1771             my $domount = sub {
1772                 my ($path) = @_;
1773                 if ($mount_path) {
1774                     if ($format eq 'iso') {
1775                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1776                     } elsif ($isBase || defined($snapname)) {
1777                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1778                     } else {
1779                         if ($quota) {
1780                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1781                         }
1782                         push @extra_opts, '-o', 'ro' if $readonly;
1783                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1784                     }
1785                 }
1786             };
1787             my $use_loopdev = 0;
1788             if ($scfg->{content}->{rootdir}) {
1789                 if ($scfg->{path}) {
1790                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1791                     $use_loopdev = 1;
1792                 } else {
1793                     $mounted_dev = $path;
1794                     &$domount($path);
1795                 }
1796             } else {
1797                 die "storage '$storage' does not support containers\n";
1798             }
1799             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1800         } else {
1801             die "unsupported image format '$format'\n";
1802         }
1803     } elsif ($type eq 'device') {
1804         push @extra_opts, '-o', 'ro' if $readonly;
1805         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1806         # See the NOTE above about devicemapper canonicalization
1807         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1808         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1809         return wantarray ? ($volid, 0, $devpath) : $volid;
1810     } elsif ($type eq 'bind') {
1811         die "directory '$volid' does not exist\n" if ! -d $volid;
1812         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1813         warn "cannot enable quota control for bind mounts\n" if $quota;
1814         return wantarray ? ($volid, 0, undef) : $volid;
1815     }
1816
1817     die "unsupported storage";
1818 }
1819
1820 sub mountpoint_hotplug :prototype($$$$$) {
1821     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1822
1823     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1824
1825     # We do the rest in a fork with an unshared mount namespace, because:
1826     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1827     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1828     #     container's namespace, then mount it.
1829
1830     PVE::Tools::run_fork(sub {
1831         # Pin the container pid longer, we also need to get its monitor/parent:
1832         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1833             or die "failed to open pidfd of container $vmid\'s init process\n";
1834
1835         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1836             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1837
1838         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1839         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1840
1841         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1842         # profile to lower our privileges to the same level we have in the start hook:
1843         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1844             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1845         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1846         # apparmor.
1847
1848         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1849         # namespace for it to remain active there since the container will be able to unmount
1850         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1851         # concern.
1852         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1853         chdir('/')
1854             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1855
1856         my $dir = get_staging_mount_path($opt);
1857
1858         # Now switch our apparmor profile before mounting:
1859         my $data = 'changeprofile /usr/bin/lxc-start';
1860         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1861             die "failed to change apparmor profile: $!\n";
1862         }
1863         # Check errors on close as well:
1864         close($aa_fd)
1865             or die "failed to change apparmor profile (close() failed): $!\n";
1866
1867         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1868
1869         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1870         chdir('/')
1871             or die "failed to change root directory within the container's mount namespace: $!\n";
1872
1873         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1874     });
1875 }
1876
1877 # Create a directory in the mountpoint staging tempfs.
1878 sub get_staging_mount_path($) {
1879     my ($opt) = @_;
1880
1881     my $target = get_staging_tempfs() . "/$opt";
1882     if (!mkdir($target) && $! != EEXIST) {
1883         die "failed to create directory $target: $!\n";
1884     }
1885
1886     return $target;
1887 }
1888
1889 # Mount /run/pve/mountpoints as tmpfs
1890 sub get_staging_tempfs() {
1891     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1892     # mounts to that.
1893     my $target = '/var/lib/lxc/.pve-staged-mounts';
1894     if (!mkdir($target)) {
1895         return $target if $! == EEXIST;
1896         die "failed to create directory $target: $!\n";
1897     }
1898
1899     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1900         or die "failed to mount $target as tmpfs: $!\n";
1901
1902     return $target;
1903 }
1904
1905 sub mkfs {
1906     my ($dev, $rootuid, $rootgid) = @_;
1907
1908     run_command(
1909         [
1910             'mkfs.ext4',
1911             '-O',
1912             'mmp',
1913             '-E',
1914             "root_owner=$rootuid:$rootgid",
1915             $dev,
1916         ],
1917         outfunc => sub {
1918             my $line = shift;
1919             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1920             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1921                 print "$line\n";
1922             }
1923         },
1924         errfunc => sub {
1925             my $line = shift;
1926             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1927         }
1928     );
1929 }
1930
1931 sub format_disk {
1932     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1933
1934     if ($volid =~ m!^/dev/.+!) {
1935         mkfs($volid);
1936         return;
1937     }
1938
1939     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1940
1941     die "cannot format volume '$volid' with no storage\n" if !$storage;
1942
1943     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1944
1945     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1946
1947     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1948
1949     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1950         PVE::Storage::parse_volname($storage_cfg, $volid);
1951
1952     die "cannot format volume '$volid' (format == $format)\n"
1953         if $format ne 'raw';
1954
1955     mkfs($path, $rootuid, $rootgid);
1956 }
1957
1958 sub destroy_disks {
1959     my ($storecfg, $vollist) = @_;
1960
1961     foreach my $volid (@$vollist) {
1962         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1963         warn $@ if $@;
1964     }
1965 }
1966
1967 sub alloc_disk {
1968     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1969
1970     my $needs_chown = 0;
1971     my $volid;
1972
1973     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1974     # fixme: use better naming ct-$vmid-disk-X.raw?
1975
1976     eval {
1977         my $do_format = 0;
1978         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
1979             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
1980                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1981                 $do_format = 1;
1982             } else {
1983                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1984                 $needs_chown = 1;
1985             }
1986         } elsif ($scfg->{type} eq 'zfspool') {
1987             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1988             $needs_chown = 1;
1989         } elsif ($scfg->{content}->{rootdir}) {
1990             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1991             $do_format = 1;
1992         } else {
1993             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
1994         }
1995         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1996     };
1997     if (my $err = $@) {
1998         # in case formatting got interrupted:
1999         if (defined($volid)) {
2000             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2001             warn $@ if $@;
2002         }
2003         die $err;
2004     }
2005
2006     return ($volid, $needs_chown);
2007 }
2008
2009 sub create_disks {
2010     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2011
2012     my $vollist = [];
2013
2014     eval {
2015         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2016         my $chown_vollist = [];
2017
2018         PVE::LXC::Config->foreach_volume($settings, sub {
2019             my ($ms, $mountpoint) = @_;
2020
2021             my $volid = $mountpoint->{volume};
2022             my $mp = $mountpoint->{mp};
2023
2024             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2025
2026             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2027                 my ($storeid, $size_gb) = ($1, $2);
2028
2029                 my $size_kb = int(${size_gb}*1024) * 1024;
2030
2031                 my $needs_chown = 0;
2032                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2033                 push @$chown_vollist, $volid if $needs_chown;
2034                 push @$vollist, $volid;
2035                 $mountpoint->{volume} = $volid;
2036                 $mountpoint->{size} = $size_kb * 1024;
2037                 if ($pending) {
2038                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2039                 } else {
2040                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2041                 }
2042             } else {
2043                 # use specified/existing volid/dir/device
2044                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2045             }
2046         });
2047
2048         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2049         foreach my $volid (@$chown_vollist) {
2050             my $path = PVE::Storage::path($storecfg, $volid, undef);
2051             chown($rootuid, $rootgid, $path);
2052         }
2053         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2054     };
2055     # free allocated images on error
2056     if (my $err = $@) {
2057         destroy_disks($storecfg, $vollist);
2058         die $err;
2059     }
2060     return $vollist;
2061 }
2062
2063 sub update_disksize {
2064     my ($vmid, $conf, $all_volumes) = @_;
2065
2066     my $changes;
2067     my $prefix = "CT $vmid:";
2068
2069     my $update_mp = sub {
2070         my ($key, $mp, @param) = @_;
2071         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2072
2073         if (!defined($mp->{size}) || $size != $mp->{size}) {
2074             $changes = 1;
2075             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2076             $mp->{size} = $size;
2077             my $nomp = 1 if ($key eq 'rootfs');
2078             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
2079         }
2080     };
2081
2082     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2083
2084     return $changes;
2085 }
2086
2087 sub update_unused {
2088     my ($vmid, $conf, $all_volumes) = @_;
2089
2090     my $changes;
2091     my $prefix = "CT $vmid:";
2092
2093     # Note: it is allowed to define multiple storage entries with the same path
2094     # (alias), so we need to check both 'volid' and real 'path' (two different
2095     # volid can point to the same path).
2096
2097     # used and unused disks
2098     my $refpath = {};
2099     my $orphans = {};
2100
2101     foreach my $opt (keys %$conf) {
2102         next if ($opt !~ m/^unused\d+$/);
2103         my $vol = $all_volumes->{$conf->{$opt}};
2104         $refpath->{$vol->{path}} = $vol->{volid};
2105     }
2106
2107     foreach my $key (keys %$all_volumes) {
2108         my $vol = $all_volumes->{$key};
2109         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2110         my $path = $vol->{path};
2111
2112         if ($in_use) {
2113             $refpath->{$path} = $key;
2114             delete $orphans->{$path};
2115         } else {
2116             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2117                 $orphans->{$path} = $key;
2118             }
2119         }
2120     }
2121
2122     for my $key (keys %$orphans) {
2123         my $disk = $orphans->{$key};
2124         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2125
2126         if ($unused) {
2127             $changes = 1;
2128             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2129         }
2130     }
2131
2132     return $changes;
2133 }
2134
2135 sub scan_volids {
2136     my ($cfg, $vmid) = @_;
2137
2138     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2139
2140     my $all_volumes = {};
2141     foreach my $storeid (keys %$info) {
2142         foreach my $item (@{$info->{$storeid}}) {
2143             my $volid = $item->{volid};
2144             next if !($volid && $item->{size});
2145             $item->{path} = PVE::Storage::path($cfg, $volid);
2146             $all_volumes->{$volid} = $item;
2147         }
2148     }
2149
2150     return $all_volumes;
2151 }
2152
2153 sub rescan {
2154     my ($vmid, $nolock, $dryrun) = @_;
2155
2156     my $cfg = PVE::Storage::config();
2157
2158     print "rescan volumes...\n";
2159     my $all_volumes = scan_volids($cfg, $vmid);
2160
2161     my $updatefn =  sub {
2162         my ($vmid) = @_;
2163
2164         my $changes;
2165         my $conf = PVE::LXC::Config->load_config($vmid);
2166
2167         PVE::LXC::Config->check_lock($conf);
2168
2169         my $vm_volids = {};
2170         foreach my $volid (keys %$all_volumes) {
2171             my $info = $all_volumes->{$volid};
2172             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2173         }
2174
2175         my $upu = update_unused($vmid, $conf, $vm_volids);
2176         my $upd = update_disksize($vmid, $conf, $vm_volids);
2177         $changes = $upu || $upd;
2178
2179         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2180     };
2181
2182     if (defined($vmid)) {
2183         if ($nolock) {
2184             &$updatefn($vmid);
2185         } else {
2186             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2187         }
2188     } else {
2189         my $vmlist = config_list();
2190         foreach my $vmid (keys %$vmlist) {
2191             if ($nolock) {
2192                 &$updatefn($vmid);
2193             } else {
2194                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2195             }
2196         }
2197     }
2198 }
2199
2200
2201 # bash completion helper
2202
2203 sub complete_os_templates {
2204     my ($cmdname, $pname, $cvalue) = @_;
2205
2206     my $cfg = PVE::Storage::config();
2207
2208     my $storeid;
2209
2210     if ($cvalue =~ m/^([^:]+):/) {
2211         $storeid = $1;
2212     }
2213
2214     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2215     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2216
2217     my $res = [];
2218     foreach my $id (keys %$data) {
2219         foreach my $item (@{$data->{$id}}) {
2220             push @$res, $item->{volid} if defined($item->{volid});
2221         }
2222     }
2223
2224     return $res;
2225 }
2226
2227 my $complete_ctid_full = sub {
2228     my ($running) = @_;
2229
2230     my $idlist = vmstatus();
2231
2232     my $active_hash = list_active_containers();
2233
2234     my $res = [];
2235
2236     foreach my $id (keys %$idlist) {
2237         my $d = $idlist->{$id};
2238         if (defined($running)) {
2239             next if $d->{template};
2240             next if $running && !$active_hash->{$id};
2241             next if !$running && $active_hash->{$id};
2242         }
2243         push @$res, $id;
2244
2245     }
2246     return $res;
2247 };
2248
2249 sub complete_ctid {
2250     return &$complete_ctid_full();
2251 }
2252
2253 sub complete_ctid_stopped {
2254     return &$complete_ctid_full(0);
2255 }
2256
2257 sub complete_ctid_running {
2258     return &$complete_ctid_full(1);
2259 }
2260
2261 sub parse_id_maps {
2262     my ($conf) = @_;
2263
2264     my $id_map = [];
2265     my $rootuid = 0;
2266     my $rootgid = 0;
2267
2268     my $lxc = $conf->{lxc};
2269     foreach my $entry (@$lxc) {
2270         my ($key, $value) = @$entry;
2271         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2272         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2273         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2274             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2275             push @$id_map, [$type, $ct, $host, $length];
2276             if ($ct == 0) {
2277                 $rootuid = $host if $type eq 'u';
2278                 $rootgid = $host if $type eq 'g';
2279             }
2280         } else {
2281             die "failed to parse idmap: $value\n";
2282         }
2283     }
2284
2285     if (!@$id_map && $conf->{unprivileged}) {
2286         # Should we read them from /etc/subuid?
2287         $id_map = [ ['u', '0', '100000', '65536'],
2288                     ['g', '0', '100000', '65536'] ];
2289         $rootuid = $rootgid = 100000;
2290     }
2291
2292     return ($id_map, $rootuid, $rootgid);
2293 }
2294
2295 sub userns_command {
2296     my ($id_map) = @_;
2297     if (@$id_map) {
2298         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2299     }
2300     return [];
2301 }
2302
2303 my sub print_ct_stderr_log {
2304     my ($vmid) = @_;
2305     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2306     return if !$log;
2307
2308     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2309         my $line = $2;
2310         print STDERR "$line\n";
2311     }
2312 }
2313 my sub print_ct_warn_log {
2314     my ($vmid) = @_;
2315     my $log_fn = "/run/pve/ct-$vmid.warnings";
2316     my $log = eval { file_get_contents($log_fn) };
2317     return if !$log;
2318
2319     my $rpcenv = eval { PVE::RPCEnvironment::get() };
2320
2321     my $warn_fn = $rpcenv ? sub { $rpcenv->warn($_[0]) } : sub { print STDERR "WARN: $_[0]\n" };
2322
2323     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2324         my $line = $1;
2325         $warn_fn->($line);
2326     }
2327     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2328 }
2329
2330 my sub monitor_state_change($$) {
2331     my ($monitor_socket, $vmid) = @_;
2332     die "no monitor socket\n" if !defined($monitor_socket);
2333
2334     while (1) {
2335         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2336
2337         die "monitor socket: got EOF\n" if !defined($type);
2338
2339         next if $name ne "$vmid" || $type ne 'STATE';
2340
2341         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2342             alarm(0); # don't timeout after seeing the starting state
2343         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2344                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2345                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2346             return 0;
2347         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2348             return 1;
2349         } else {
2350             warn "unexpected message from monitor socket - " .
2351                  "type: '$type' - value: '$value'\n";
2352         }
2353     }
2354 }
2355 my sub monitor_start($$) {
2356     my ($monitor_socket, $vmid) = @_;
2357
2358     my $success = eval {
2359         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2360     };
2361     if (my $err = $@) {
2362         warn "problem with monitor socket, but continuing anyway: $err\n";
2363     } elsif (!$success) {
2364         print_ct_stderr_log($vmid);
2365         die "startup for container '$vmid' failed\n";
2366     }
2367 }
2368
2369 sub vm_start {
2370     my ($vmid, $conf, $skiplock, $debug) = @_;
2371
2372     # apply pending changes while starting
2373     if (scalar(keys %{$conf->{pending}})) {
2374         my $storecfg = PVE::Storage::config();
2375         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2376         PVE::LXC::Config->write_config($vmid, $conf);
2377         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2378     }
2379
2380     update_lxc_config($vmid, $conf);
2381
2382     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2383
2384     if ($skiplock) {
2385         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2386         close($fh);
2387     }
2388
2389     my $storage_cfg = PVE::Storage::config();
2390     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2391
2392     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2393
2394     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2395     warn $@ if $@;
2396
2397     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2398
2399     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2400     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2401
2402     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2403
2404     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2405     eval {
2406         run_command($cmd);
2407
2408         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2409
2410         # if debug is requested, print the log it also when the start succeeded
2411         print_ct_stderr_log($vmid) if $is_debug;
2412
2413         print_ct_warn_log($vmid); # always print warn log, if any
2414     };
2415     if (my $err = $@) {
2416         unlink $skiplock_flag_fn;
2417         die $err;
2418     }
2419     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2420
2421     return;
2422 }
2423
2424 # Helper to stop a container completely and make sure it has stopped completely.
2425 # This is necessary because we want the post-stop hook to have completed its
2426 # unmount-all step, but post-stop happens after lxc puts the container into the
2427 # STOPPED state.
2428 # $kill - if true it will always do an immediate hard-stop
2429 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2430 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2431 sub vm_stop {
2432     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2433
2434     # Open the container's command socket.
2435     my $path = "\0/var/lib/lxc/$vmid/command";
2436     my $sock = IO::Socket::UNIX->new(
2437         Type => SOCK_STREAM(),
2438         Peer => $path,
2439     );
2440     if (!$sock) {
2441         return if $! == ECONNREFUSED; # The container is not running
2442         die "failed to open container ${vmid}'s command socket: $!\n";
2443     }
2444
2445     my $conf = PVE::LXC::Config->load_config($vmid);
2446     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2447
2448     # Stop the container:
2449
2450     my $cmd = ['lxc-stop', '-n', $vmid];
2451
2452     if ($kill) {
2453         push @$cmd, '--kill'; # doesn't allow timeouts
2454     } else {
2455         # lxc-stop uses a default timeout
2456         push @$cmd, '--nokill' if !$kill_after_timeout;
2457
2458         if (defined($shutdown_timeout)) {
2459             push @$cmd, '--timeout', $shutdown_timeout;
2460             # Give run_command 5 extra seconds
2461             $shutdown_timeout += 5;
2462         }
2463     }
2464
2465     eval { run_command($cmd, timeout => $shutdown_timeout) };
2466     if (my $err = $@) {
2467         warn $@ if $@;
2468     }
2469
2470     my $result = <$sock>;
2471
2472     return if !defined $result; # monitor is gone and the ct has stopped.
2473     die "container did not stop\n";
2474 }
2475
2476 sub vm_reboot {
2477     my ($vmid, $timeout, $skiplock) = @_;
2478
2479     PVE::LXC::Config->lock_config($vmid, sub {
2480         return if !check_running($vmid);
2481
2482         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2483
2484         my $conf = PVE::LXC::Config->load_config($vmid);
2485         vm_start($vmid, $conf);
2486     });
2487 }
2488
2489 sub run_unshared {
2490     my ($code) = @_;
2491
2492     return PVE::Tools::run_fork(sub {
2493         # Unshare the mount namespace
2494         die "failed to unshare mount namespace: $!\n"
2495             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2496         run_command(['mount', '--make-rslave', '/']);
2497         return $code->();
2498     });
2499 }
2500
2501 my $copy_volume = sub {
2502     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2503
2504     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2505     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2506
2507     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2508     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2509
2510     my @mounted;
2511     eval {
2512         # mount and copy
2513         mkdir $src;
2514         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2515         push @mounted, $src;
2516         mkdir $dest;
2517         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2518         push @mounted, $dest;
2519
2520         $bwlimit //= 0;
2521
2522         run_command([
2523             'rsync',
2524             '--stats',
2525             '-X',
2526             '-A',
2527             '--numeric-ids',
2528             '-aH',
2529             '--whole-file',
2530             '--sparse',
2531             '--one-file-system',
2532             "--bwlimit=$bwlimit",
2533             "$src/",
2534             $dest
2535         ]);
2536     };
2537     my $err = $@;
2538
2539     # Wait for rsync's children to release dest so that
2540     # consequent file operations (umount, remove) are possible
2541     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2542
2543     foreach my $mount (reverse @mounted) {
2544         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2545         warn "Can't umount $mount\n" if $@;
2546     }
2547
2548     # If this fails they're used as mount points in a concurrent operation
2549     # (which should not happen but there's also no real need to get rid of them).
2550     rmdir $dest;
2551     rmdir $src;
2552
2553     die $err if $err;
2554 };
2555
2556 # Should not be called after unsharing the mount namespace!
2557 sub copy_volume {
2558     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2559
2560     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2561     File::Path::make_path("/var/lib/lxc/$vmid");
2562     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2563     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2564
2565     # get id's for unprivileged container
2566     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2567
2568     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2569     # are visible in this namespace, otherwise the host only sees the empty
2570     # (not-mounted) directory.
2571     my $new_volid;
2572     eval {
2573         # Make sure $mp contains a correct size.
2574         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2575         my $needs_chown;
2576         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2577         if ($needs_chown) {
2578             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2579             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2580             chown($rootuid, $rootgid, $path);
2581         }
2582
2583         run_unshared(sub {
2584             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2585         });
2586     };
2587     if (my $err = $@) {
2588         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2589             if defined($new_volid);
2590         die $err;
2591     }
2592
2593     return $new_volid;
2594 }
2595
2596 sub get_lxc_version() {
2597     my $version;
2598     run_command([qw(lxc-start --version)], outfunc => sub {
2599         my ($line) = @_;
2600         # We only parse out major & minor version numbers.
2601         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2602             $version = [$1, $2];
2603         }
2604     });
2605
2606     die "failed to get lxc version\n" if !defined($version);
2607
2608     # return as a list:
2609     return $version->@*;
2610 }
2611
2612 sub freeze($) {
2613     my ($vmid) = @_;
2614     if (PVE::CGroup::cgroup_mode() == 2) {
2615         PVE::LXC::Command::freeze($vmid, 30);
2616     } else {
2617         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2618     }
2619 }
2620
2621 sub thaw($) {
2622     my ($vmid) = @_;
2623     if (PVE::CGroup::cgroup_mode() == 2) {
2624         PVE::LXC::Command::unfreeze($vmid, 30);
2625     } else {
2626         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2627     }
2628 }
2629
2630 1;