src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw();
   7 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED EEXIST);
   8 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
   9 use File::Path;
  10 use File::Spec;
  11 use IO::Poll qw(POLLIN POLLHUP);
  12 use IO::Socket::UNIX;
  13 use POSIX qw(EINTR);
  14 use Socket;
  15 use Time::HiRes qw (gettimeofday);
  16
  17 use PVE::AccessControl;
  18 use PVE::CGroup;
  19 use PVE::CpuSet;
  20 use PVE::Exception qw(raise_perm_exc);
  21 use PVE::GuestHelpers qw(check_vnet_access safe_string_ne safe_num_ne safe_boolean_ne);
  22 use PVE::INotify;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use PVE::Network;
  25 use PVE::ProcFSTools;
  26 use PVE::RESTEnvironment;
  27 use PVE::SafeSyslog;
  28 use PVE::Storage;
  29 use PVE::Tools qw(
  30     run_command
  31     dir_glob_foreach
  32     file_get_contents
  33     file_set_contents
  34     AT_FDCWD
  35     O_PATH
  36     $IPV4RE
  37     $IPV6RE
  38 );
  39 use PVE::Syscall qw(:fsmount);
  40
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Config;
  43 use PVE::LXC::Monitor;
  44 use PVE::LXC::Tools;
  45
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     require PVE::Network::SDN::Vnets;
  50     $have_sdn = 1;
  51 };
  52
  53 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  54
  55 my $nodename = PVE::INotify::nodename();
  56
  57 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  58
  59 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  60
  61 sub config_list {
  62     my $vmlist = PVE::Cluster::get_vmlist();
  63     my $res = {};
  64     return $res if !$vmlist || !$vmlist->{ids};
  65     my $ids = $vmlist->{ids};
  66
  67     foreach my $vmid (keys %$ids) {
  68         next if !$vmid; # skip CT0
  69         my $d = $ids->{$vmid};
  70         next if !$d->{node} || $d->{node} ne $nodename;
  71         next if !$d->{type} || $d->{type} ne 'lxc';
  72         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  73     }
  74     return $res;
  75 }
  76
  77 # container status helpers
  78
  79 sub list_active_containers {
  80
  81     my $filename = "/proc/net/unix";
  82
  83     # similar test is used by lcxcontainers.c: list_active_containers
  84     my $res = {};
  85
  86     my $fh = IO::File->new ($filename, "r");
  87     return $res if !$fh;
  88
  89     while (defined(my $line = <$fh>)) {
  90         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  91             my $path = $1;
  92             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  93                 $res->{$1} = 1;
  94             }
  95         }
  96     }
  97
  98     close($fh);
  99
 100     return $res;
 101 }
 102
 103 # warning: this is slow
 104 sub check_running {
 105     my ($vmid) = @_;
 106
 107     my $active_hash = list_active_containers();
 108
 109     return 1 if defined($active_hash->{$vmid});
 110
 111     return undef;
 112 }
 113
 114 sub get_container_disk_usage {
 115     my ($vmid, $pid) = @_;
 116
 117     return PVE::Tools::df("/proc/$pid/root/", 1);
 118 }
 119
 120 my $last_proc_vmid_stat;
 121
 122 our $vmstatus_return_properties = {
 123     vmid => get_standard_option('pve-vmid'),
 124     status => {
 125         description => "LXC Container status.",
 126         type => 'string',
 127         enum => ['stopped', 'running'],
 128     },
 129     maxmem => {
 130         description => "Maximum memory in bytes.",
 131         type => 'integer',
 132         optional => 1,
 133         renderer => 'bytes',
 134     },
 135     maxswap => {
 136         description => "Maximum SWAP memory in bytes.",
 137         type => 'integer',
 138         optional => 1,
 139         renderer => 'bytes',
 140     },
 141     maxdisk => {
 142         description => "Root disk size in bytes.",
 143         type => 'integer',
 144         optional => 1,
 145         renderer => 'bytes',
 146     },
 147     name => {
 148         description => "Container name.",
 149         type => 'string',
 150         optional => 1,
 151     },
 152     uptime => {
 153         description => "Uptime.",
 154         type => 'integer',
 155         optional => 1,
 156         renderer => 'duration',
 157     },
 158     cpus => {
 159         description => "Maximum usable CPUs.",
 160         type => 'number',
 161         optional => 1,
 162     },
 163     lock => {
 164         description => "The current config lock, if any.",
 165         type => 'string',
 166         optional => 1,
 167     },
 168     tags => {
 169         description => "The current configured tags, if any.",
 170         type => 'string',
 171         optional => 1,
 172     }
 173 };
 174
 175 sub vmstatus {
 176     my ($opt_vmid) = @_;
 177
 178     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 179
 180     my $active_hash = list_active_containers();
 181
 182     my $cpucount = $cpuinfo->{cpus} || 1;
 183
 184     my $cdtime = gettimeofday;
 185
 186     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 187     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 188
 189     my $unprivileged = {};
 190
 191     foreach my $vmid (keys %$list) {
 192         my $d = $list->{$vmid};
 193
 194         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 195         warn $@ if $@; # ignore errors (consider them stopped)
 196
 197         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 198
 199         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 200         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 201
 202         $unprivileged->{$vmid} = $conf->{unprivileged};
 203
 204         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 205         $d->{name} =~ s/[\s]//g;
 206
 207         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 208         $d->{cpus} = $cpucount if !$d->{cpus};
 209
 210         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 211
 212         if ($d->{pid}) {
 213             my $res = get_container_disk_usage($vmid, $d->{pid});
 214             $d->{disk} = int($res->{used});
 215             $d->{maxdisk} = int($res->{total});
 216         } else {
 217             $d->{disk} = 0;
 218             # use 4GB by default ??
 219             if (my $rootfs = $conf->{rootfs}) {
 220                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 221                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 222             } else {
 223                 $d->{maxdisk} = 4*1024*1024*1024;
 224             }
 225         }
 226
 227         $d->{mem} = 0;
 228         $d->{swap} = 0;
 229         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 230         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 231
 232         $d->{uptime} = 0;
 233         $d->{cpu} = 0;
 234
 235         $d->{netout} = 0;
 236         $d->{netin} = 0;
 237
 238         $d->{diskread} = 0;
 239         $d->{diskwrite} = 0;
 240
 241         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 242         $d->{lock} = $conf->{lock} if $conf->{lock};
 243     }
 244
 245     foreach my $vmid (keys %$list) {
 246         my $d = $list->{$vmid};
 247         my $pid = $d->{pid};
 248
 249         next if !$pid; # skip stopped CTs
 250
 251         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 252         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 253
 254         my $unpriv = $unprivileged->{$vmid};
 255
 256         my $cgroups = PVE::LXC::CGroup->new($vmid);
 257
 258         if (defined(my $mem = $cgroups->get_memory_stat())) {
 259             $d->{mem} = int($mem->{mem});
 260             $d->{swap} = int($mem->{swap});
 261         } else {
 262             $d->{mem} = 0;
 263             $d->{swap} = 0;
 264         }
 265
 266         if (defined(my $blkio = $cgroups->get_io_stats())) {
 267             $d->{diskread} = int($blkio->{diskread});
 268             $d->{diskwrite} = int($blkio->{diskwrite});
 269         } else {
 270             $d->{diskread} = 0;
 271             $d->{diskwrite} = 0;
 272         }
 273
 274         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 275             # Total time (in milliseconds) used up by the cpu.
 276             my $used_ms = $cpu->{utime} + $cpu->{stime};
 277
 278             my $old = $last_proc_vmid_stat->{$vmid};
 279             if (!$old) {
 280                 $last_proc_vmid_stat->{$vmid} = {
 281                     time => $cdtime,
 282                     used => $used_ms,
 283                     cpu => 0,
 284                 };
 285                 next;
 286             }
 287
 288             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 289             if ($delta_ms > 1000.0) {
 290                 my $delta_used_ms = $used_ms - $old->{used};
 291                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 292                 $last_proc_vmid_stat->{$vmid} = {
 293                     time => $cdtime,
 294                     used => $used_ms,
 295                     cpu => $d->{cpu},
 296                 };
 297             } else {
 298                 $d->{cpu} = $old->{cpu};
 299             }
 300         } else {
 301             $d->{cpu} = 0;
 302         }
 303     }
 304
 305     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 306
 307     foreach my $dev (keys %$netdev) {
 308         next if $dev !~ m/^veth([1-9]\d*)i/;
 309         my $vmid = $1;
 310         my $d = $list->{$vmid};
 311
 312         next if !$d;
 313
 314         $d->{netout} += $netdev->{$dev}->{receive};
 315         $d->{netin} += $netdev->{$dev}->{transmit};
 316
 317     }
 318
 319     return $list;
 320 }
 321
 322 sub find_lxc_console_pids {
 323
 324     my $res = {};
 325
 326     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 327         my ($pid) = @_;
 328
 329         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 330         return if !$cmdline;
 331
 332         my @args = split(/\0/, $cmdline);
 333
 334         # search for lxc-console -n <vmid>
 335         return if scalar(@args) != 3;
 336         return if $args[1] ne '-n';
 337         return if $args[2] !~ m/^\d+$/;
 338         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 339
 340         my $vmid = $args[2];
 341
 342         push @{$res->{$vmid}}, $pid;
 343     });
 344
 345     return $res;
 346 }
 347
 348 sub find_lxc_pid {
 349     my ($vmid) = @_;
 350
 351     my $pid = undef;
 352     my $parser = sub {
 353         my $line = shift;
 354         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 355     };
 356     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 357
 358     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 359
 360     return $pid;
 361 }
 362
 363 sub open_pid_fd($) {
 364     my ($pid) = @_;
 365     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 366         or die "failed to open /proc/$pid pid fd\n";
 367     return $fd;
 368 }
 369
 370 sub open_lxc_pid {
 371     my ($vmid) = @_;
 372
 373     # Find the pid and open:
 374     my $pid = find_lxc_pid($vmid);
 375     my $fd = open_pid_fd($pid);
 376
 377     # Verify:
 378     my $pid2 = find_lxc_pid($vmid);
 379
 380     return () if $pid != $pid2;
 381     return ($pid, $fd);
 382 }
 383
 384 sub open_ppid {
 385     my ($pid) = @_;
 386
 387     # Find the parent pid via proc and open it:
 388     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 389     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 390
 391     my $fd = open_pid_fd($ppid);
 392
 393     # Verify:
 394     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 395     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 396
 397     return () if $ppid != $ppid2;
 398     return ($ppid, $fd);
 399 }
 400
 401 # Note: we cannot use Net:IP, because that only allows strict
 402 # CIDR networks
 403 sub parse_ipv4_cidr {
 404     my ($cidr, $noerr) = @_;
 405
 406     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 407         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 408     }
 409
 410     return undef if $noerr;
 411
 412     die "unable to parse ipv4 address/mask\n";
 413 }
 414
 415 # With seccomp trap to userspace we now have the ability to optionally forward
 416 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 417 #
 418 # This means that there are cases where we need to create an extra seccomp
 419 # profile for the container to load.
 420 #
 421 # This returns a configuration snippet added to the raw lxc config.
 422 sub make_seccomp_config {
 423     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 424     # User-configured profile has precedence, note that the user's entry would
 425     # be written 'after' this line anyway...
 426     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 427         # Warn the user if this conflicts with a feature:
 428         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 429         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 430             if length($warn) > 0;
 431         return '';
 432     }
 433
 434     # Privileged containers keep using the default (which is already part of
 435     # the files included via lxc.include, so we don't need to write it out,
 436     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 437     # well)
 438     return '' if !$unprivileged;
 439
 440     my $rules = {
 441         keyctl => ['errno 38'],
 442
 443         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 444         # Particularly, without the mount option to enable rmdir removing snapshots, user
 445         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 446         # horrible, so for now, just disable this entirely:
 447         #
 448         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 449         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 450         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 451     };
 452
 453     my $raw_conf = '';
 454
 455     # Unprivileged containers will get keyctl() disabled by default as a
 456     # workaround for systemd-networkd behavior. But we have an option to
 457     # explicitly enable it:
 458     if ($features->{keyctl}) {
 459         delete $rules->{keyctl};
 460     }
 461
 462     # By default, unprivileged containers cannot use `mknod` at all.
 463     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 464     # but for now this is experimental, so it has to be enabled via a feature
 465     # flag.
 466     # Note that we only handle block and char devices (like lxd), the rest we
 467     # leave up to the kernel. We may in the future remove this if seccomp gets
 468     # a way to tell the kernel to "continue" a syscall.
 469     if ($features->{mknod}) {
 470         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 471         if (!$ok) {
 472             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 473         }
 474
 475         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 476         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 477
 478         $rules->{mknod} = [
 479             # condition: (mode & S_IFMT) == S_IFCHR
 480             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 481             # condition: (mode & S_IFMT) == S_IFBLK
 482             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 483         ];
 484         $rules->{mknodat} = [
 485             # condition: (mode & S_IFMT) == S_IFCHR
 486             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 487             # condition: (mode & S_IFMT) == S_IFBLK
 488             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 489         ];
 490     }
 491
 492     # Now build the custom seccomp rule text...
 493     my $extra_rules = join("\n", map {
 494         my $syscall = $_;
 495         map { "$syscall $_" } $rules->{$syscall}->@*
 496     } sort keys %$rules) . "\n";
 497
 498     return $raw_conf if $extra_rules eq "\n";
 499
 500     # We still have the "most common" config readily available, so don't write
 501     # out that one:
 502     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 503         # we have no extra $raw_conf and use the same we had in pve 6.1:
 504         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 505     }
 506
 507     # Write the rule file to the container's config path:
 508     my $rule_file = "$conf_dir/rules.seccomp";
 509     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 510         . $extra_rules;
 511     file_set_contents($rule_file, $rule_data);
 512     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 513
 514     return $raw_conf;
 515 }
 516
 517 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 518 # automatically. The default should be equivalent to the old
 519 # `lxc-container-default-cgns` profile.
 520 #
 521 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 522 # additional lines into the profile. We can use that to allow mounting specific
 523 # file systems.
 524 sub make_apparmor_config {
 525     my ($conf, $unprivileged, $features) = @_;
 526
 527     # user-configured profile has precedence, but first we go through our own
 528     # code to figure out whether we should warn the user:
 529
 530     my $raw = "lxc.apparmor.profile = generated\n";
 531     my @profile_uses;
 532
 533     if ($features->{fuse}) {
 534         # For the informational warning:
 535         push @profile_uses, 'features:fuse';
 536     }
 537
 538     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 539     # apparmor lines, create an apparmor namespace for the container, but also
 540     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 541     # lxcfs mounted over them, because that would prevent the container from
 542     # mounting new instances of them for nested containers.
 543     if ($features->{nesting}) {
 544         push @profile_uses, 'features:nesting';
 545         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 546     } else {
 547         # In the default profile in /etc/apparmor.d we patch this in because
 548         # otherwise a container can for example run `chown` on /sys, breaking
 549         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 550         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 551         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 552         # Preferably we could use the 'remount' flag but this does not sit well
 553         # with apparmor_parser currently:
 554         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 555     }
 556
 557     if (my $mount = $features->{mount}) {
 558         push @profile_uses, 'features:mount';
 559         foreach my $fs (PVE::Tools::split_list($mount)) {
 560             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 561         }
 562     }
 563
 564     # More to come?
 565
 566     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 567         if (length(my $used = join(', ', @profile_uses))) {
 568             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 569         }
 570         return '';
 571     }
 572
 573     return $raw;
 574 }
 575
 576 sub update_lxc_config {
 577     my ($vmid, $conf) = @_;
 578
 579     my $dir = "/var/lib/lxc/$vmid";
 580
 581     if ($conf->{template}) {
 582
 583         unlink "$dir/config";
 584
 585         return;
 586     }
 587
 588     my ($lxc_major, $lxc_minor) = get_lxc_version();
 589
 590     my $raw = '';
 591
 592     if ($lxc_major >= 4) {
 593         # Explicitly don't use relative directories, which is the default, but
 594         # note that we do this mostly because they are only applied for *some*
 595         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 596         # so we also don't need to worry about the new monitor cgroup to
 597         # confuse systemd.
 598         $raw .= "lxc.cgroup.relative = 0\n";
 599
 600         # To make things easier, let's keep our previous cgroup layout and
 601         # simply move the monitor outside:
 602         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 603         # cgroup namespace separation for stronger limits:
 604         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 605         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 606     }
 607
 608     die "missing 'arch' - internal error" if !$conf->{arch};
 609     $raw .= "lxc.arch = $conf->{arch}\n";
 610
 611     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 612     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 613
 614     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 615
 616     File::Path::mkpath($dir);
 617
 618     my $cfgpath = '/usr/share/lxc/config';
 619     my $inc = "$cfgpath/$ostype.common.conf";
 620     $inc ="$cfgpath/common.conf" if !-f $inc;
 621     $raw .= "lxc.include = $inc\n";
 622     if ($unprivileged) {
 623         $inc = "$cfgpath/$ostype.userns.conf";
 624         $inc = "$cfgpath/userns.conf" if !-f $inc;
 625         $raw .= "lxc.include = $inc\n";
 626     }
 627
 628     my $features = PVE::LXC::Config->parse_features($conf->{features});
 629
 630     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 631     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 632     if ($features->{fuse}) {
 633         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 634         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 635     }
 636
 637     if ($unprivileged && !$features->{force_rw_sys}) {
 638         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 639         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 640         $raw .= "lxc.mount.auto = sys:mixed\n";
 641     }
 642
 643     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 644     # cannot be exposed to the container with r/w access (cgroup perms).
 645     # When this is enabled mounts will still remain in the monitor's namespace
 646     # after the container unmounted them and thus will not detach from their
 647     # files while the container is running!
 648     $raw .= "lxc.monitor.unshare = 1\n";
 649
 650     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 651
 652     # Should we read them from /etc/subuid?
 653     if ($unprivileged && !$custom_idmap) {
 654         $raw .= "lxc.idmap = u 0 100000 65536\n";
 655         $raw .= "lxc.idmap = g 0 100000 65536\n";
 656     }
 657
 658     if (!PVE::LXC::Config->has_dev_console($conf)) {
 659         $raw .= "lxc.console.path = none\n";
 660         if ($cgv1->{devices}) {
 661             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 662         } elsif (defined($cgv2)) {
 663             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 664         }
 665     }
 666
 667     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 668     $raw .= "lxc.tty.max = $ttycount\n";
 669
 670     # some init scripts expect a linux terminal (turnkey).
 671     $raw .= "lxc.environment = TERM=linux\n";
 672
 673     my $utsname = $conf->{hostname} || "CT$vmid";
 674     $raw .= "lxc.uts.name = $utsname\n";
 675
 676     if ($cgv1->{memory}) {
 677         my $memory = $conf->{memory} || 512;
 678         my $swap = $conf->{swap} // 0;
 679
 680         my $lxcmem = int($memory*1024*1024);
 681         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 682
 683         my $lxcswap = int(($memory + $swap)*1024*1024);
 684         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 685     } elsif ($cgv2->{memory}) {
 686         my $memory = $conf->{memory} || 512;
 687         my $swap = $conf->{swap} // 0;
 688
 689         # cgroup memory usage is limited by the hard 'max' limit (OOM-killer enforced) and the soft
 690         # 'high' limit (cgroup processes get throttled and put under heavy reclaim pressure).
 691         my ($lxc_mem_max, $lxc_mem_high) = PVE::LXC::Config::calculate_memory_constraints($memory);
 692         $raw .= "lxc.cgroup2.memory.max = $lxc_mem_max\n";
 693         $raw .= "lxc.cgroup2.memory.high = $lxc_mem_high\n";
 694
 695         my $lxcswap = int($swap*1024*1024);
 696         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 697     }
 698
 699     if ($cgv1->{cpu}) {
 700         if (my $cpulimit = $conf->{cpulimit}) {
 701             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 702             my $value = int(100000*$cpulimit);
 703             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 704         }
 705
 706         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 707         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 708     } elsif ($cgv2->{cpu}) {
 709         # See PVE::CGroup
 710         if (my $cpulimit = $conf->{cpulimit}) {
 711             my $value = int(100000*$cpulimit);
 712             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 713         }
 714
 715         if (defined(my $shares = $conf->{cpuunits})) {
 716             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 717             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 718         }
 719     }
 720
 721     die "missing 'rootfs' configuration\n"
 722         if !defined($conf->{rootfs});
 723
 724     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 725
 726     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 727
 728     foreach my $k (sort keys %$conf) {
 729         next if $k !~ m/^net(\d+)$/;
 730         my $ind = $1;
 731         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 732         $raw .= "lxc.net.$ind.type = veth\n";
 733         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 734         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 735         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 736
 737         my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 738         my $mtu = $d->{mtu} || $bridge_mtu;
 739
 740         # Keep container from starting with invalid mtu configuration
 741         die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 742             if ($mtu > $bridge_mtu);
 743
 744         $raw .= "lxc.net.$ind.mtu = $mtu\n";
 745
 746         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 747         if ($lxc_major >= 4) {
 748             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 749         }
 750     }
 751
 752     my $had_cpuset = 0;
 753     if (my $lxcconf = $conf->{lxc}) {
 754         foreach my $entry (@$lxcconf) {
 755             my ($k, $v) = @$entry;
 756             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 757             $raw .= "$k = $v\n";
 758         }
 759     }
 760
 761     my $cpuset;
 762     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 763     if (defined($cpuset_cgroup)) {
 764         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 765             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 766     }
 767     my $cores = $conf->{cores};
 768     if (!$had_cpuset && $cores && $cpuset) {
 769         my @members = $cpuset->members();
 770         while (scalar(@members) > $cores) {
 771             my $randidx = int(rand(scalar(@members)));
 772             $cpuset->delete($members[$randidx]);
 773             splice(@members, $randidx, 1); # keep track of the changes
 774         }
 775         my $ver = $cpuset_version == 1 ? '' : '2';
 776         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 777     }
 778
 779     File::Path::mkpath("$dir/rootfs");
 780
 781     PVE::Tools::file_set_contents("$dir/config", $raw);
 782 }
 783
 784 # verify and cleanup nameserver list (replace \0 with ' ')
 785 sub verify_nameserver_list {
 786     my ($nameserver_list) = @_;
 787
 788     my @list = ();
 789     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 790         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 791         push @list, $server;
 792     }
 793
 794     return join(' ', @list);
 795 }
 796
 797 sub verify_searchdomain_list {
 798     my ($searchdomain_list) = @_;
 799
 800     my @list = ();
 801     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 802         # todo: should we add checks for valid dns domains?
 803         push @list, $server;
 804     }
 805
 806     return join(' ', @list);
 807 }
 808
 809 sub get_console_command {
 810     my ($vmid, $conf, $escapechar) = @_;
 811
 812     # '-1' as $escapechar disables keyboard escape sequence
 813     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 814
 815     my $cmode = PVE::LXC::Config->get_cmode($conf);
 816
 817     my $cmd = [];
 818     if ($cmode eq 'console') {
 819         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 820         push @$cmd, '-e', $escapechar if $escapechar;
 821     } elsif ($cmode eq 'tty') {
 822         push @$cmd, 'lxc-console', '-n',  $vmid;
 823         push @$cmd, '-e', $escapechar if $escapechar;
 824     } elsif ($cmode eq 'shell') {
 825         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 826     } else {
 827         die "internal error";
 828     }
 829
 830     return $cmd;
 831 }
 832
 833 sub get_primary_ips {
 834     my ($conf) = @_;
 835
 836     # return data from net0
 837
 838     return undef if !defined($conf->{net0});
 839     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 840
 841     my $ipv4 = $net->{ip};
 842     if ($ipv4) {
 843         if ($ipv4 =~ /^(dhcp|manual)$/) {
 844             $ipv4 = undef
 845         } else {
 846             $ipv4 =~ s!/\d+$!!;
 847         }
 848     }
 849     my $ipv6 = $net->{ip6};
 850     if ($ipv6) {
 851         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 852             $ipv6 = undef;
 853         } else {
 854             $ipv6 =~ s!/\d+$!!;
 855         }
 856     }
 857
 858     return ($ipv4, $ipv6);
 859 }
 860
 861 sub delete_mountpoint_volume {
 862     my ($storage_cfg, $vmid, $volume) = @_;
 863
 864     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 865
 866     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 867
 868     if ($vmid == $owner) {
 869         PVE::Storage::vdisk_free($storage_cfg, $volume);
 870     } else {
 871         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 872     }
 873 }
 874
 875 sub destroy_lxc_container {
 876     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 877
 878     my $volids = {};
 879     my $remove_volume = sub {
 880         my ($ms, $mountpoint) = @_;
 881
 882         my $volume = $mountpoint->{volume};
 883
 884         return if $volids->{$volume};
 885         $volids->{$volume} = 1;
 886
 887         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 888     };
 889     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 890
 891     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 892
 893     if ($purge_unreferenced) { # also remove unreferenced disk
 894         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 895         PVE::Storage::foreach_volid($vmdisks, sub {
 896             my ($volid, $sid, $volname, $d) = @_;
 897             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 898             warn $@ if $@;
 899         });
 900     }
 901
 902     delete_ifaces_ipams_ips($conf, $vmid);
 903
 904     rmdir "/var/lib/lxc/$vmid/rootfs";
 905     unlink "/var/lib/lxc/$vmid/config";
 906     rmdir "/var/lib/lxc/$vmid";
 907     if (defined $replacement_conf) {
 908         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 909     } else {
 910         PVE::LXC::Config->destroy_config($vmid);
 911     }
 912 }
 913
 914 sub vm_stop_cleanup {
 915     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 916
 917     return if $keepActive;
 918
 919     eval {
 920         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 921         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 922     };
 923     warn $@ if $@; # avoid errors - just warn
 924 }
 925
 926 sub net_tap_plug : prototype($$) {
 927     my ($iface, $net) = @_;
 928
 929     if (defined($net->{link_down})) {
 930         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 931         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 932         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 933         return;
 934     }
 935
 936     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 937         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 938
 939     if ($have_sdn) {
 940         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 941         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge);
 942     } else {
 943         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 944     }
 945
 946     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 947 }
 948
 949 sub update_net {
 950     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 951
 952     if ($newnet->{type} ne 'veth') {
 953         # for when there are physical interfaces
 954         die "cannot update interface of type $newnet->{type}";
 955     }
 956
 957     my $veth = "veth${vmid}i${netid}";
 958     my $eth = $newnet->{name};
 959
 960     if (my $oldnetcfg = $conf->{$opt}) {
 961         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 962
 963         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 964             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 965
 966             PVE::Network::veth_delete($veth);
 967
 968             if ($have_sdn && safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr})) {
 969                 eval { PVE::Network::SDN::Vnets::del_ips_from_mac($oldnet->{bridge}, $oldnet->{hwaddr}, $conf->{hostname}) };
 970                 warn $@ if $@;
 971
 972                 PVE::Network::SDN::Vnets::add_next_free_cidr($newnet->{bridge}, $conf->{hostname}, $newnet->{hwaddr}, $vmid, undef, 1);
 973                 PVE::Network::SDN::Vnets::add_dhcp_mapping($newnet->{bridge}, $newnet->{hwaddr});
 974             }
 975
 976             delete $conf->{$opt};
 977             PVE::LXC::Config->write_config($vmid, $conf);
 978
 979             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 980
 981         } else {
 982             my $bridge_changed = safe_string_ne($oldnet->{bridge}, $newnet->{bridge});
 983
 984             if ($bridge_changed ||
 985                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 986                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 987                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 988             ) {
 989                 if ($oldnet->{bridge}) {
 990                     my $oldbridge = $oldnet->{bridge};
 991
 992                     PVE::Network::tap_unplug($veth);
 993                     foreach (qw(bridge tag firewall)) {
 994                         delete $oldnet->{$_};
 995                     }
 996                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 997                     PVE::LXC::Config->write_config($vmid, $conf);
 998
 999                     if ($have_sdn && $bridge_changed) {
1000                         eval { PVE::Network::SDN::Vnets::del_ips_from_mac($oldbridge, $oldnet->{hwaddr}, $conf->{hostname}) };
1001                         warn $@ if $@;
1002                     }
1003                 }
1004
1005                 if ($have_sdn && $bridge_changed) {
1006                     PVE::Network::SDN::Vnets::add_next_free_cidr($newnet->{bridge}, $conf->{hostname}, $newnet->{hwaddr}, $vmid, undef, 1);
1007                 }
1008                 PVE::LXC::net_tap_plug($veth, $newnet);
1009
1010                 # This includes the rate:
1011                 foreach (qw(bridge tag firewall rate link_down)) {
1012                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
1013                 }
1014             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
1015                 # Rate can be applied on its own but any change above needs to
1016                 # include the rate in tap_plug since OVS resets everything.
1017                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
1018                 $oldnet->{rate} = $newnet->{rate}
1019             }
1020             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
1021             PVE::LXC::Config->write_config($vmid, $conf);
1022         }
1023     } else {
1024         PVE::Network::SDN::Vnets::add_next_free_cidr($newnet->{bridge}, $conf->{hostname}, $newnet->{hwaddr}, $vmid, undef, 1);
1025         PVE::Network::SDN::Vnets::add_dhcp_mapping($newnet->{bridge}, $newnet->{hwaddr});
1026
1027         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1028     }
1029
1030     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1031 }
1032
1033 sub hotplug_net {
1034     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1035
1036     my $veth = "veth${vmid}i${netid}";
1037     my $vethpeer = $veth . "p";
1038     my $eth = $newnet->{name};
1039
1040     if ($have_sdn) {
1041         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1042     } else {
1043         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1044     }
1045
1046     PVE::LXC::net_tap_plug($veth, $newnet);
1047
1048     # attach peer in container
1049     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1050     PVE::Tools::run_command($cmd);
1051
1052     # link up peer in container
1053     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1054     PVE::Tools::run_command($cmd);
1055
1056     my $done = { type => 'veth' };
1057     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1058         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1059     }
1060     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1061
1062     PVE::LXC::Config->write_config($vmid, $conf);
1063 }
1064
1065 sub get_interfaces {
1066     my ($vmid) = @_;
1067
1068     my $pid = eval { find_lxc_pid($vmid); };
1069     return if $@;
1070
1071     my $output;
1072     # enters the network namespace of the container and executes 'ip a'
1073     run_command(['nsenter', '-t', $pid, '--net', '--', 'ip', '--json', 'a'],
1074         outfunc => sub { $output .= shift; });
1075
1076     my $config = JSON::decode_json($output);
1077
1078     my $res;
1079     for my $interface ($config->@*) {
1080         my $obj = { name => $interface->{ifname} };
1081         for my $ip ($interface->{addr_info}->@*) {
1082             $obj->{$ip->{family}} = $ip->{local} . "/" . $ip->{prefixlen};
1083         }
1084         $obj->{hwaddr} = $interface->{address};
1085         push @$res, $obj
1086     }
1087
1088     return $res;
1089 }
1090
1091 sub update_ipconfig {
1092     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1093
1094     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1095
1096     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1097     my $deleted = [];
1098     my $added = [];
1099     my $nscmd = sub {
1100         my $cmdargs = shift;
1101         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1102     };
1103     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1104
1105     my $change_ip_config = sub {
1106         my ($ipversion) = @_;
1107
1108         my $family_opt = "-$ipversion";
1109         my $suffix = $ipversion == 4 ? '' : $ipversion;
1110         my $gw= "gw$suffix";
1111         my $ip= "ip$suffix";
1112
1113         my $newip = $newnet->{$ip};
1114         my $newgw = $newnet->{$gw};
1115         my $oldip = $optdata->{$ip};
1116         my $oldgw = $optdata->{$gw};
1117
1118         my $change_ip = safe_string_ne($oldip, $newip);
1119         my $change_gw = safe_string_ne($oldgw, $newgw);
1120
1121         return if !$change_ip && !$change_gw;
1122
1123         # step 1: add new IP, if this fails we cancel
1124         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1125         if ($change_ip && $is_real_ip) {
1126             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1127             if (my $err = $@) {
1128                 warn $err;
1129                 return;
1130             }
1131         }
1132
1133         # step 2: replace gateway
1134         #   If this fails we delete the added IP and cancel.
1135         #   If it succeeds we save the config and delete the old IP, ignoring
1136         #   errors. The config is then saved.
1137         # Note: 'ip route replace' can add
1138         if ($change_gw) {
1139             if ($newgw) {
1140                 eval {
1141                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1142                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1143                     }
1144                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1145                 };
1146                 if (my $err = $@) {
1147                     warn $err;
1148                     # the route was not replaced, the old IP is still available
1149                     # rollback (delete new IP) and cancel
1150                     if ($change_ip) {
1151                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1152                         warn $@ if $@; # no need to die here
1153                     }
1154                     return;
1155                 }
1156             } else {
1157                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1158                 # if the route was not deleted, the guest might have deleted it manually
1159                 # warn and continue
1160                 warn $@ if $@;
1161             }
1162             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1163                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1164                 # warn if the route was deleted manually
1165                 warn $@ if $@;
1166             }
1167         }
1168
1169         # from this point on we save the configuration
1170         # step 3: delete old IP ignoring errors
1171         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1172             # We need to enable promote_secondaries, otherwise our newly added
1173             # address will be removed along with the old one.
1174             my $promote = 0;
1175             eval {
1176                 if ($ipversion == 4) {
1177                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1178                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1179                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1180                 }
1181                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1182             };
1183             warn $@ if $@; # no need to die here
1184
1185             if ($ipversion == 4) {
1186                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1187             }
1188         }
1189
1190         foreach my $property ($ip, $gw) {
1191             if ($newnet->{$property}) {
1192                 $optdata->{$property} = $newnet->{$property};
1193             } else {
1194                 delete $optdata->{$property};
1195             }
1196         }
1197         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1198         PVE::LXC::Config->write_config($vmid, $conf);
1199         $lxc_setup->setup_network($conf);
1200     };
1201
1202     &$change_ip_config(4);
1203     &$change_ip_config(6);
1204
1205 }
1206
1207 my $open_namespace = sub {
1208     my ($vmid, $pid, $kind) = @_;
1209     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1210         or die "failed to open $kind namespace of container $vmid: $!\n";
1211     return $fd;
1212 };
1213
1214 my $enter_namespace = sub {
1215     my ($vmid, $pid, $kind, $type) = @_;
1216     my $fd = $open_namespace->($vmid, $pid, $kind);
1217     PVE::Tools::setns(fileno($fd), $type)
1218         or die "failed to enter $kind namespace of container $vmid: $!\n";
1219     close $fd;
1220 };
1221
1222 my $get_container_namespace = sub {
1223     my ($vmid, $pid, $kind) = @_;
1224
1225     my $pidfd;
1226     if (!defined($pid)) {
1227         # Pin the pid while we're grabbing its stuff from /proc
1228         ($pid, $pidfd) = open_lxc_pid($vmid)
1229             or die "failed to open pidfd of container $vmid\'s init process\n";
1230     }
1231
1232     return $open_namespace->($vmid, $pid, $kind);
1233 };
1234
1235 my $do_syncfs = sub {
1236     my ($vmid, $pid, $socket) = @_;
1237
1238     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1239
1240     # Tell the parent process to start reading our /proc/mounts
1241     print {$socket} "go\n";
1242     $socket->flush();
1243
1244     # Receive /proc/self/mounts
1245     my $mountdata = do { local $/ = undef; <$socket> };
1246     close $socket;
1247
1248     my %nosyncfs = (
1249         cgroup => 1,
1250         cgroup2 => 1,
1251         devtmpfs => 1,
1252         devpts => 1,
1253         'fuse.lxcfs' => 1,
1254         fusectl => 1,
1255         mqueue => 1,
1256         proc => 1,
1257         sysfs => 1,
1258         tmpfs => 1,
1259     );
1260
1261     # Now sync all mountpoints...
1262     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1263     foreach my $mp (@$mounts) {
1264         my ($what, $dir, $fs) = @$mp;
1265         next if $nosyncfs{$fs};
1266         eval { PVE::Tools::sync_mountpoint($dir); };
1267         warn $@ if $@;
1268     }
1269 };
1270
1271 sub sync_container_namespace {
1272     my ($vmid) = @_;
1273     my $pid = find_lxc_pid($vmid);
1274
1275     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1276     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1277         or die "failed to create socketpair: $!\n";
1278
1279     my $child = fork();
1280     die "fork failed: $!\n" if !defined($child);
1281
1282     if (!$child) {
1283         eval {
1284             close $pfd;
1285             &$do_syncfs($vmid, $pid, $cfd);
1286         };
1287         if (my $err = $@) {
1288             warn $err;
1289             POSIX::_exit(1);
1290         }
1291         POSIX::_exit(0);
1292     }
1293     close $cfd;
1294     my $go = <$pfd>;
1295     die "failed to enter container namespace\n" if $go ne "go\n";
1296
1297     open my $mounts, '<', "/proc/$child/mounts"
1298         or die "failed to open container's /proc/mounts: $!\n";
1299     my $mountdata = do { local $/ = undef; <$mounts> };
1300     close $mounts;
1301     print {$pfd} $mountdata;
1302     close $pfd;
1303
1304     while (waitpid($child, 0) != $child) {}
1305     die "failed to sync container namespace\n" if $? != 0;
1306 }
1307
1308 sub template_create {
1309     my ($vmid, $conf) = @_;
1310
1311     my $storecfg = PVE::Storage::config();
1312
1313     PVE::LXC::Config->foreach_volume($conf, sub {
1314         my ($ms, $mountpoint) = @_;
1315
1316         my $volid = $mountpoint->{volume};
1317
1318         die "Template feature is not available for '$volid'\n"
1319             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1320     });
1321
1322     PVE::LXC::Config->foreach_volume($conf, sub {
1323         my ($ms, $mountpoint) = @_;
1324
1325         my $volid = $mountpoint->{volume};
1326
1327         PVE::Storage::activate_volumes($storecfg, [$volid]);
1328
1329         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1330         $mountpoint->{volume} = $template_volid;
1331         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1332     });
1333
1334     PVE::LXC::Config->write_config($vmid, $conf);
1335 }
1336
1337 sub check_ct_modify_config_perm {
1338     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1339
1340     return 1 if $authuser eq 'root@pam';
1341     my $storage_cfg = PVE::Storage::config();
1342
1343     my $check = sub {
1344         my ($opt, $delete) = @_;
1345         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1346             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1347         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1348             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1349             return if $delete;
1350             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1351             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1352                 if $data->{type} ne 'volume';
1353             my $volid = $data->{volume};
1354             if ($volid =~ $NEW_DISK_RE) {
1355                 my $sid = $1;
1356                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1357             } else {
1358                 PVE::Storage::check_volume_access(
1359                     $rpcenv,
1360                     $authuser,
1361                     $storage_cfg,
1362                     $vmid,
1363                     $volid,
1364                     'rootdir',
1365                 );
1366             }
1367         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1368             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1369         } elsif ($opt =~ m/^net\d+$/) {
1370             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1371             check_bridge_access($rpcenv, $authuser, $oldconf->{$opt}) if $oldconf->{$opt};
1372             check_bridge_access($rpcenv, $authuser, $newconf->{$opt}) if $newconf->{$opt};
1373         } elsif ($opt eq 'nameserver' || $opt eq 'searchdomain' || $opt eq 'hostname') {
1374             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1375         } elsif ($opt eq 'features') {
1376             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1377                 if !$unprivileged;
1378
1379             my $nesting_changed = 0;
1380             my $other_changed = 0;
1381             if (!$delete) {
1382                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1383                 if (defined($oldconf) && $oldconf->{$opt}) {
1384                     # existing container with features
1385                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1386                     for my $feature ((keys %$old_features, keys %$features)) {
1387                         my $old = $old_features->{$feature} // '';
1388                         my $new = $features->{$feature} // '';
1389                         if ($old ne $new) {
1390                             if ($feature eq 'nesting') {
1391                                 $nesting_changed = 1;
1392                                 next;
1393                             } else {
1394                                 $other_changed = 1;
1395                                 last;
1396                             }
1397                         }
1398                     }
1399                 } else {
1400                     # new container or no features defined
1401                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1402                         $nesting_changed = 1;
1403                     } elsif (scalar(keys %$features) > 0) {
1404                         $other_changed = 1;
1405                     }
1406                 }
1407             } else {
1408                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1409                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1410                     $nesting_changed = 1;
1411                 } elsif (scalar(keys %$features) > 0) {
1412                     $other_changed = 1;
1413                 }
1414             }
1415             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1416                 if $other_changed;
1417             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1418                 if $nesting_changed;
1419         } elsif ($opt eq 'hookscript') {
1420             # For now this is restricted to root@pam
1421             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1422         } elsif ($opt eq 'tags') {
1423             my $old = $oldconf->{$opt};
1424             my $new = $delete ? '' : $newconf->{$opt};
1425             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1426         } else {
1427             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1428         }
1429     };
1430
1431     foreach my $opt (keys %$newconf) {
1432         &$check($opt, 0);
1433     }
1434     foreach my $opt (@$delete) {
1435         &$check($opt, 1);
1436     }
1437
1438     return 1;
1439 }
1440
1441 sub check_bridge_access {
1442     my ($rpcenv, $authuser, $raw) = @_;
1443
1444     return 1 if $authuser eq 'root@pam';
1445
1446     my $net = PVE::LXC::Config->parse_lxc_network($raw);
1447     my ($bridge, $tag, $trunks) = $net->@{'bridge', 'tag', 'trunks'};
1448     check_vnet_access($rpcenv, $authuser, $bridge, $tag, $trunks);
1449
1450     return 1;
1451 };
1452
1453 sub umount_all {
1454     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1455
1456     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1457     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1458
1459     my $res = 1;
1460
1461     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1462         my ($ms, $mountpoint) = @_;
1463
1464         my $volid = $mountpoint->{volume};
1465         my $mount = $mountpoint->{mp};
1466
1467         return if !$volid || !$mount;
1468
1469         my $mount_path = "$rootdir/$mount";
1470         $mount_path =~ s!/+!/!g;
1471
1472         return if !PVE::ProcFSTools::is_mounted($mount_path);
1473
1474         eval {
1475             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1476         };
1477         if (my $err = $@) {
1478             if ($noerr) {
1479                 $res = 0;
1480                 warn $err;
1481             } else {
1482                 die $err;
1483             }
1484         }
1485     });
1486
1487     return $res; # tell caller if (some) umounts failed for the noerr case
1488 }
1489
1490 sub mount_all {
1491     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1492
1493     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1494     File::Path::make_path($rootdir);
1495
1496     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1497     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1498
1499     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1500
1501     eval {
1502         PVE::LXC::Config->foreach_volume($conf, sub {
1503             my ($ms, $mountpoint) = @_;
1504
1505             $mountpoint->{ro} = 0 if $ignore_ro;
1506
1507             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1508         });
1509     };
1510     if (my $err = $@) {
1511         warn "mounting container failed\n";
1512         umount_all($vmid, $storage_cfg, $conf, 1);
1513         die $err;
1514     }
1515
1516     return $rootdir;
1517 }
1518
1519
1520 sub mountpoint_mount_path {
1521     my ($mountpoint, $storage_cfg, $snapname) = @_;
1522
1523     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1524 }
1525
1526 sub query_loopdev {
1527     my ($path) = @_;
1528     my $found;
1529     my $parser = sub {
1530         my $line = shift;
1531         if ($line =~ m@^(/dev/loop\d+):@) {
1532             $found = $1;
1533         }
1534     };
1535     my $cmd = ['losetup', '--associated', $path];
1536     PVE::Tools::run_command($cmd, outfunc => $parser);
1537     return $found;
1538 }
1539
1540 # Run a function with a file attached to a loop device.
1541 # The loop device is always detached afterwards (or set to autoclear).
1542 # Returns the loop device.
1543 sub run_with_loopdev {
1544     my ($func, $file, $readonly) = @_;
1545     my $device = query_loopdev($file);
1546     # Try to reuse an existing device
1547     if ($device) {
1548         # We assume that whoever setup the loop device is responsible for
1549         # detaching it.
1550         &$func($device);
1551         return $device;
1552     }
1553
1554     my $parser = sub {
1555         my $line = shift;
1556         if ($line =~ m@^(/dev/loop\d+)$@) {
1557             $device = $1;
1558         }
1559     };
1560     my $losetup_cmd = [
1561         'losetup',
1562         '--show',
1563         '-f',
1564         $file,
1565     ];
1566     push @$losetup_cmd, '-r' if $readonly;
1567     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1568     die "failed to setup loop device for $file\n" if !$device;
1569     eval { &$func($device); };
1570     my $err = $@;
1571     PVE::Tools::run_command(['losetup', '-d', $device]);
1572     die $err if $err;
1573     return $device;
1574 }
1575
1576 # In scalar mode: returns a file handle to the deepest directory node.
1577 # In list context: returns a list of:
1578 #   * the deepest directory node
1579 #   * the 2nd deepest directory (parent of the above)
1580 #   * directory name of the last directory
1581 # So that the path $2/$3 should lead to $1 afterwards.
1582 sub walk_tree_nofollow($$$;$$) {
1583     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1584
1585     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1586         or die "failed to open start directory $start: $!\n";
1587
1588     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1589 }
1590
1591
1592 sub walk_tree_nofollow_fd($$$$;$$) {
1593     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1594
1595     # splitdir() returns '' for empty components including the leading /
1596     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1597
1598     my $fd = $start_fd;
1599     my $dir = $start_dirname;
1600     my $last_component = undef;
1601     my $second = $fd;
1602     foreach my $component (@comps) {
1603         $dir .= "/$component";
1604         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1605
1606         if (!$next) {
1607             # failed, check for symlinks and try to create the path
1608             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1609             die "cannot open directory $dir: $!\n" if !$mkdir;
1610
1611             # We don't check for errors on mkdirat() here and just try to
1612             # openat() again, since at least one error (EEXIST) is an
1613             # expected possibility if multiple containers start
1614             # simultaneously. If someone else injects a symlink now then
1615             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1616             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1617
1618             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1619             die "failed to create path: $dir: $!\n" if !$next;
1620
1621             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1622                 if defined($rootuid) && defined($rootgid);
1623         }
1624
1625         close $second if defined($last_component) && $second != $start_fd;
1626         $last_component = $component;
1627         $second = $fd;
1628         $fd = $next;
1629     }
1630
1631     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1632     close $second if defined($last_component) && $second != $start_fd;
1633     return $fd;
1634 }
1635
1636 # To guard against symlink attack races against other currently running
1637 # containers with shared recursive bind mount hierarchies we prepare a
1638 # directory handle for the directory we're mounting over to verify the
1639 # mountpoint afterwards.
1640 sub __bindmount_prepare {
1641     my ($hostroot, $dir) = @_;
1642     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1643     return $srcdh;
1644 }
1645
1646 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1647 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1648 # we intended to bind mount.
1649 sub __bindmount_verify {
1650     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1651     my $destdh;
1652     if ($parentfd) {
1653         # Open the mount point path coming from the parent directory since the
1654         # filehandle we would have gotten as first result of walk_tree_nofollow
1655         # earlier is still a handle to the underlying directory instead of the
1656         # mounted path.
1657         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1658         die "failed to open mount point: $!\n" if !$destdh;
1659         if ($ro) {
1660             my $dot = '.';
1661             # no separate function because 99% of the time it's the wrong thing to use.
1662             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1663                 die "failed to mark bind mount read only\n";
1664             }
1665             die "read-only check failed: $!\n" if $! != EROFS;
1666         }
1667     } else {
1668         # For the rootfs we don't have a parentfd so we open the path directly.
1669         # Note that this means bindmounting any prefix of the host's
1670         # /var/lib/lxc/$vmid path into another container is considered a grave
1671         # security error.
1672         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1673         die "failed to open mount point: $!\n" if !$destdh;
1674     }
1675
1676     my ($srcdev, $srcinode) = stat($srcdh);
1677     my ($dstdev, $dstinode) = stat($destdh);
1678     close $srcdh;
1679     close $destdh;
1680
1681     return ($srcdev == $dstdev && $srcinode == $dstinode);
1682 }
1683
1684 # Perform the actual bind mounting:
1685 sub __bindmount_do {
1686     my ($dir, $dest, $ro, @extra_opts) = @_;
1687     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1688     if ($ro) {
1689         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1690         if (my $err = $@) {
1691             warn "bindmount error\n";
1692             # don't leave writable bind-mounts behind...
1693             PVE::Tools::run_command(['umount', $dest]);
1694             die $err;
1695         }
1696     }
1697 }
1698
1699 sub bindmount {
1700     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1701
1702     my $srcdh = __bindmount_prepare('/', $dir);
1703
1704     __bindmount_do($dir, $dest, $ro, @extra_opts);
1705
1706     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1707         PVE::Tools::run_command(['umount', $dest]);
1708         die "detected mount path change at: $dir\n";
1709     }
1710 }
1711
1712 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1713 # from $rootdir and $mount and walk the path from $rootdir to the final
1714 # directory to check for symlinks.
1715 sub __mount_prepare_rootdir {
1716     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1717     $rootdir =~ s!/+!/!g;
1718     $rootdir =~ s!/+$!!;
1719     my $mount_path = "$rootdir/$mount";
1720     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1721     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1722 }
1723
1724 # use $rootdir = undef to just return the corresponding mount path
1725 sub mountpoint_mount {
1726     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1727     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1728 }
1729
1730 sub mountpoint_stage {
1731     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1732     my ($path, $loop, $dev) =
1733         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1734
1735     if (!defined($path)) {
1736         die "failed to mount subvolume: $!\n";
1737     }
1738
1739     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1740     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1741     # point).
1742     my $err;
1743     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1744         or die "open_tree() on mount point failed: $!\n";
1745
1746     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1747 }
1748
1749 sub mountpoint_insert_staged {
1750     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1751
1752     if (!defined($rootdir_fd)) {
1753         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1754             or die "failed to open '.': $!\n";
1755     }
1756
1757     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1758
1759     PVE::Tools::move_mount(
1760         fileno($mount_fd),
1761         '',
1762         fileno($dest_fd),
1763         '',
1764         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1765     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1766 }
1767
1768 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1769 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1770 sub __mountpoint_mount {
1771     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1772
1773     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1774     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1775     # which we use in __bindmount_verify()!
1776     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1777
1778     my $volid = $mountpoint->{volume};
1779     my $type = $mountpoint->{type};
1780     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1781     my $mounted_dev;
1782
1783     return if !$volid || !$mount;
1784
1785     $mount =~ s!/+!/!g;
1786
1787     my $mount_path;
1788     my ($mpfd, $parentfd, $last_dir);
1789
1790     if (defined($rootdir)) {
1791         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1792             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1793     }
1794
1795     if (defined($stage_mount)) {
1796         $mount_path = $rootdir;
1797     }
1798
1799     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1800
1801     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1802
1803     my $optlist = [];
1804
1805     if (my $mountopts = $mountpoint->{mountoptions}) {
1806         my @opts = split(/;/, $mountpoint->{mountoptions});
1807         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1808     }
1809
1810     my $acl = $mountpoint->{acl};
1811     if (defined($acl)) {
1812         push @$optlist, ($acl ? 'acl' : 'noacl');
1813     }
1814
1815     my $optstring = join(',', @$optlist);
1816     my $readonly = $mountpoint->{ro};
1817
1818     my @extra_opts;
1819     @extra_opts = ('-o', $optstring) if $optstring;
1820
1821     if ($storage) {
1822
1823         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1824
1825         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1826
1827         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1828
1829         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1830             PVE::Storage::parse_volname($storage_cfg, $volid);
1831
1832         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1833
1834         if ($format eq 'subvol') {
1835             if ($mount_path) {
1836                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1837                 if (defined($snapname)) {
1838                     $name .= "\@$snapname";
1839                     if ($scfg->{type} eq 'zfspool') {
1840                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1841                     } else {
1842                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1843                     }
1844                 } else {
1845                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1846                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1847                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1848                     }
1849                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1850                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1851                 }
1852             }
1853             return wantarray ? ($path, 0, undef) : $path;
1854         } elsif ($format eq 'raw' || $format eq 'iso') {
1855             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1856             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1857             # Our autodev hook expects the /dev/dm-* device currently
1858             # and will create the /dev/mapper symlink accordingly
1859             $path = Cwd::realpath($path);
1860             die "failed to get device path\n" if !$path;
1861             ($path) = ($path =~ /^(.*)$/s); #untaint
1862             my $domount = sub {
1863                 my ($path) = @_;
1864                 if ($mount_path) {
1865                     if ($format eq 'iso') {
1866                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1867                     } elsif ($isBase || defined($snapname)) {
1868                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1869                     } else {
1870                         if ($quota) {
1871                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1872                         }
1873                         push @extra_opts, '-o', 'ro' if $readonly;
1874                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1875                     }
1876                 }
1877             };
1878             my $use_loopdev = 0;
1879             if ($scfg->{content}->{rootdir}) {
1880                 if ($scfg->{path}) {
1881                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1882                     $use_loopdev = 1;
1883                 } else {
1884                     $mounted_dev = $path;
1885                     &$domount($path);
1886                 }
1887             } else {
1888                 die "storage '$storage' does not support containers\n";
1889             }
1890             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1891         } else {
1892             die "unsupported image format '$format'\n";
1893         }
1894     } elsif ($type eq 'device') {
1895         push @extra_opts, '-o', 'ro' if $readonly;
1896         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1897         # See the NOTE above about devicemapper canonicalization
1898         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1899         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1900         return wantarray ? ($volid, 0, $devpath) : $volid;
1901     } elsif ($type eq 'bind') {
1902         die "directory '$volid' does not exist\n" if ! -d $volid;
1903         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1904         warn "cannot enable quota control for bind mounts\n" if $quota;
1905         return wantarray ? ($volid, 0, undef) : $volid;
1906     }
1907
1908     die "unsupported storage";
1909 }
1910
1911 sub mountpoint_hotplug :prototype($$$$$) {
1912     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1913
1914     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1915
1916     # We do the rest in a fork with an unshared mount namespace, because:
1917     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1918     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1919     #     container's namespace, then mount it.
1920
1921     PVE::Tools::run_fork(sub {
1922         # Pin the container pid longer, we also need to get its monitor/parent:
1923         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1924             or die "failed to open pidfd of container $vmid\'s init process\n";
1925
1926         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1927             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1928
1929         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1930         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1931
1932         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1933         # profile to lower our privileges to the same level we have in the start hook:
1934         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1935             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1936         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1937         # apparmor.
1938
1939         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1940         # namespace for it to remain active there since the container will be able to unmount
1941         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1942         # concern.
1943         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1944         chdir('/')
1945             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1946
1947         my $dir = get_staging_mount_path($opt);
1948
1949         # Now switch our apparmor profile before mounting:
1950         my $data = 'changeprofile /usr/bin/lxc-start';
1951         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1952             die "failed to change apparmor profile: $!\n";
1953         }
1954         # Check errors on close as well:
1955         close($aa_fd)
1956             or die "failed to change apparmor profile (close() failed): $!\n";
1957
1958         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1959
1960         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1961         chdir('/')
1962             or die "failed to change root directory within the container's mount namespace: $!\n";
1963
1964         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1965     });
1966 }
1967
1968 # Create a directory in the mountpoint staging tempfs.
1969 sub get_staging_mount_path($) {
1970     my ($opt) = @_;
1971
1972     my $target = get_staging_tempfs() . "/$opt";
1973     if (!mkdir($target) && $! != EEXIST) {
1974         die "failed to create directory $target: $!\n";
1975     }
1976
1977     return $target;
1978 }
1979
1980 # Mount tmpfs for mount point staging and return the path.
1981 sub get_staging_tempfs() {
1982     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1983     # mounts to that.
1984     my $target = '/var/lib/lxc/.pve-staged-mounts';
1985     if (!mkdir($target)) {
1986         return $target if $! == EEXIST;
1987         die "failed to create directory $target: $!\n";
1988     }
1989
1990     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1991         or die "failed to mount $target as tmpfs: $!\n";
1992
1993     return $target;
1994 }
1995
1996 sub mkfs {
1997     my ($dev, $rootuid, $rootgid) = @_;
1998
1999     run_command(
2000         [
2001             'mkfs.ext4',
2002             '-O',
2003             'mmp',
2004             '-E',
2005             "root_owner=$rootuid:$rootgid",
2006             $dev,
2007         ],
2008         outfunc => sub {
2009             my $line = shift;
2010             # a hack to print only the relevant stuff, i.e., the one which could help on repair
2011             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
2012                 print "$line\n";
2013             }
2014         },
2015         errfunc => sub {
2016             my $line = shift;
2017             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
2018         }
2019     );
2020 }
2021
2022 sub format_disk {
2023     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
2024
2025     if ($volid =~ m!^/dev/.+!) {
2026         mkfs($volid);
2027         return;
2028     }
2029
2030     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2031
2032     die "cannot format volume '$volid' with no storage\n" if !$storage;
2033
2034     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
2035
2036     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
2037
2038     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
2039
2040     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
2041         PVE::Storage::parse_volname($storage_cfg, $volid);
2042
2043     die "cannot format volume '$volid' (format == $format)\n"
2044         if $format ne 'raw';
2045
2046     mkfs($path, $rootuid, $rootgid);
2047 }
2048
2049 sub destroy_disks {
2050     my ($storecfg, $vollist) = @_;
2051
2052     foreach my $volid (@$vollist) {
2053         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2054         warn $@ if $@;
2055     }
2056 }
2057
2058 sub alloc_disk {
2059     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
2060
2061     my $needs_chown = 0;
2062     my $volid;
2063
2064     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2065     # fixme: use better naming ct-$vmid-disk-X.raw?
2066
2067     eval {
2068         my $do_format = 0;
2069         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2070             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2071                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2072                 $do_format = 1;
2073             } else {
2074                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2075                 $needs_chown = 1;
2076             }
2077         } elsif ($scfg->{type} eq 'zfspool') {
2078             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2079             $needs_chown = 1;
2080         } elsif ($scfg->{content}->{rootdir}) {
2081             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2082             $do_format = 1;
2083         } else {
2084             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2085         }
2086         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2087     };
2088     if (my $err = $@) {
2089         # in case formatting got interrupted:
2090         if (defined($volid)) {
2091             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2092             warn $@ if $@;
2093         }
2094         die $err;
2095     }
2096
2097     return ($volid, $needs_chown);
2098 }
2099
2100 sub create_disks {
2101     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2102
2103     my $vollist = [];
2104
2105     eval {
2106         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2107         my $chown_vollist = [];
2108
2109         PVE::LXC::Config->foreach_volume($settings, sub {
2110             my ($ms, $mountpoint) = @_;
2111
2112             my $volid = $mountpoint->{volume};
2113             my $mp = $mountpoint->{mp};
2114
2115             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2116
2117             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2118                 my ($storeid, $size_gb) = ($1, $2);
2119
2120                 my $size_kb = int(${size_gb}*1024) * 1024;
2121
2122                 my $needs_chown = 0;
2123                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2124                 push @$chown_vollist, $volid if $needs_chown;
2125                 push @$vollist, $volid;
2126                 $mountpoint->{volume} = $volid;
2127                 $mountpoint->{size} = $size_kb * 1024;
2128                 if ($pending) {
2129                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2130                 } else {
2131                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2132                 }
2133             } else {
2134                 # use specified/existing volid/dir/device
2135                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2136             }
2137         });
2138
2139         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2140         foreach my $volid (@$chown_vollist) {
2141             my $path = PVE::Storage::path($storecfg, $volid, undef);
2142             chown($rootuid, $rootgid, $path);
2143         }
2144         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2145     };
2146     # free allocated images on error
2147     if (my $err = $@) {
2148         destroy_disks($storecfg, $vollist);
2149         die $err;
2150     }
2151     return $vollist;
2152 }
2153
2154 sub update_disksize {
2155     my ($vmid, $conf, $all_volumes) = @_;
2156
2157     my $changes;
2158     my $prefix = "CT $vmid:";
2159
2160     my $update_mp = sub {
2161         my ($key, $mp, @param) = @_;
2162         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2163
2164         if (!defined($mp->{size}) || $size != $mp->{size}) {
2165             $changes = 1;
2166             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2167             $mp->{size} = $size;
2168             my $no_mp = $key eq 'rootfs'; # rootfs is handled different from other mount points
2169             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $no_mp);
2170         }
2171     };
2172
2173     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2174
2175     return $changes;
2176 }
2177
2178 sub update_unused {
2179     my ($vmid, $conf, $all_volumes) = @_;
2180
2181     my $changes;
2182     my $prefix = "CT $vmid:";
2183
2184     # Note: it is allowed to define multiple storage entries with the same path
2185     # (alias), so we need to check both 'volid' and real 'path' (two different
2186     # volid can point to the same path).
2187
2188     # used and unused disks
2189     my $refpath = {};
2190     my $orphans = {};
2191
2192     foreach my $opt (keys %$conf) {
2193         next if ($opt !~ m/^unused\d+$/);
2194         my $vol = $all_volumes->{$conf->{$opt}};
2195         $refpath->{$vol->{path}} = $vol->{volid};
2196     }
2197
2198     foreach my $key (keys %$all_volumes) {
2199         my $vol = $all_volumes->{$key};
2200         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2201         my $path = $vol->{path};
2202
2203         if ($in_use) {
2204             $refpath->{$path} = $key;
2205             delete $orphans->{$path};
2206         } else {
2207             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2208                 $orphans->{$path} = $key;
2209             }
2210         }
2211     }
2212
2213     for my $key (keys %$orphans) {
2214         my $disk = $orphans->{$key};
2215         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2216
2217         if ($unused) {
2218             $changes = 1;
2219             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2220         }
2221     }
2222
2223     return $changes;
2224 }
2225
2226 sub scan_volids {
2227     my ($cfg, $vmid) = @_;
2228
2229     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2230
2231     my $all_volumes = {};
2232     foreach my $storeid (keys %$info) {
2233         foreach my $item (@{$info->{$storeid}}) {
2234             my $volid = $item->{volid};
2235             next if !($volid && $item->{size});
2236             $item->{path} = PVE::Storage::path($cfg, $volid);
2237             $all_volumes->{$volid} = $item;
2238         }
2239     }
2240
2241     return $all_volumes;
2242 }
2243
2244 sub rescan {
2245     my ($vmid, $nolock, $dryrun) = @_;
2246
2247     my $cfg = PVE::Storage::config();
2248
2249     print "rescan volumes...\n";
2250     my $all_volumes = scan_volids($cfg, $vmid);
2251
2252     my $updatefn =  sub {
2253         my ($vmid) = @_;
2254
2255         my $changes;
2256         my $conf = PVE::LXC::Config->load_config($vmid);
2257
2258         PVE::LXC::Config->check_lock($conf);
2259
2260         my $vm_volids = {};
2261         foreach my $volid (keys %$all_volumes) {
2262             my $info = $all_volumes->{$volid};
2263             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2264         }
2265
2266         my $upu = update_unused($vmid, $conf, $vm_volids);
2267         my $upd = update_disksize($vmid, $conf, $vm_volids);
2268         $changes = $upu || $upd;
2269
2270         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2271     };
2272
2273     if (defined($vmid)) {
2274         if ($nolock) {
2275             &$updatefn($vmid);
2276         } else {
2277             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2278         }
2279     } else {
2280         my $vmlist = config_list();
2281         foreach my $vmid (keys %$vmlist) {
2282             if ($nolock) {
2283                 &$updatefn($vmid);
2284             } else {
2285                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2286             }
2287         }
2288     }
2289 }
2290
2291
2292 # bash completion helper
2293
2294 sub complete_os_templates {
2295     my ($cmdname, $pname, $cvalue) = @_;
2296
2297     my $cfg = PVE::Storage::config();
2298
2299     my $storeid;
2300
2301     if ($cvalue =~ m/^([^:]+):/) {
2302         $storeid = $1;
2303     }
2304
2305     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2306     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2307
2308     my $res = [];
2309     foreach my $id (keys %$data) {
2310         foreach my $item (@{$data->{$id}}) {
2311             push @$res, $item->{volid} if defined($item->{volid});
2312         }
2313     }
2314
2315     return $res;
2316 }
2317
2318 my $complete_ctid_full = sub {
2319     my ($running) = @_;
2320
2321     my $idlist = vmstatus();
2322
2323     my $active_hash = list_active_containers();
2324
2325     my $res = [];
2326
2327     foreach my $id (keys %$idlist) {
2328         my $d = $idlist->{$id};
2329         if (defined($running)) {
2330             next if $d->{template};
2331             next if $running && !$active_hash->{$id};
2332             next if !$running && $active_hash->{$id};
2333         }
2334         push @$res, $id;
2335
2336     }
2337     return $res;
2338 };
2339
2340 sub complete_ctid {
2341     return &$complete_ctid_full();
2342 }
2343
2344 sub complete_ctid_stopped {
2345     return &$complete_ctid_full(0);
2346 }
2347
2348 sub complete_ctid_running {
2349     return &$complete_ctid_full(1);
2350 }
2351
2352 sub parse_id_maps {
2353     my ($conf) = @_;
2354
2355     my $id_map = [];
2356     my $rootuid = 0;
2357     my $rootgid = 0;
2358
2359     my $lxc = $conf->{lxc};
2360     foreach my $entry (@$lxc) {
2361         my ($key, $value) = @$entry;
2362
2363         next if $key ne 'lxc.idmap';
2364
2365         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2366             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2367             push @$id_map, [$type, $ct, $host, $length];
2368             if ($ct == 0) {
2369                 $rootuid = $host if $type eq 'u';
2370                 $rootgid = $host if $type eq 'g';
2371             }
2372         } else {
2373             die "failed to parse idmap: $value\n";
2374         }
2375     }
2376
2377     if (!@$id_map && $conf->{unprivileged}) {
2378         # Should we read them from /etc/subuid?
2379         $id_map = [ ['u', '0', '100000', '65536'],
2380                     ['g', '0', '100000', '65536'] ];
2381         $rootuid = $rootgid = 100000;
2382     }
2383
2384     return ($id_map, $rootuid, $rootgid);
2385 }
2386
2387 sub validate_id_maps {
2388     my ($id_map) = @_;
2389
2390     # $mappings->{$type}->{$side} = [ { line => $line, start => $start, count => $count }, ... ]
2391     #   $type: either "u" or "g"
2392     #   $side: either "container" or "host"
2393     #   $line: index of this mapping in @$id_map
2394     #   $start, $count: interval of this mapping
2395     my $mappings = { u => {}, g => {} };
2396     for (my $i = 0; $i < scalar(@$id_map); $i++) {
2397         my ($type, $ct_start, $host_start, $count) = $id_map->[$i]->@*;
2398         my $sides = $mappings->{$type};
2399         push $sides->{host}->@*, { line => $i, start => $host_start, count => $count };
2400         push $sides->{container}->@*, { line => $i, start => $ct_start, count => $count };
2401     }
2402
2403     # find the first conflict between two consecutive mappings when sorted by their start id
2404     for my $type (qw(u g)) {
2405         for my $side (qw(container host)) {
2406             my @entries = sort { $a->{start} <=> $b->{start} } $mappings->{$type}->{$side}->@*;
2407             for my $idx (1..scalar(@entries) - 1) {
2408                 my $previous = $entries[$idx - 1];
2409                 my $current = $entries[$idx];
2410                 if ($previous->{start} + $previous->{count} > $current->{start}) {
2411                     my $conflict = $current->{start};
2412                     my @previous_line = $id_map->[$previous->{line}]->@*;
2413                     my @current_line = $id_map->[$current->{line}]->@*;
2414                     die "invalid map entry '@current_line': $side ${type}id $conflict "
2415                        ."is also mapped by entry '@previous_line'\n";
2416                 }
2417             }
2418         }
2419     }
2420 }
2421
2422 sub userns_command {
2423     my ($id_map) = @_;
2424     if (@$id_map) {
2425         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2426     }
2427     return [];
2428 }
2429
2430 my sub print_ct_stderr_log {
2431     my ($vmid) = @_;
2432     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2433     return if !$log;
2434
2435     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2436         my $line = $2;
2437         print STDERR "$line\n";
2438     }
2439 }
2440 my sub print_ct_warn_log {
2441     my ($vmid) = @_;
2442     my $log_fn = "/run/pve/ct-$vmid.warnings";
2443     my $log = eval { file_get_contents($log_fn) };
2444     return if !$log;
2445
2446     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2447         PVE::RESTEnvironment::log_warn($1);
2448     }
2449     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2450 }
2451
2452 my sub monitor_state_change($$) {
2453     my ($monitor_socket, $vmid) = @_;
2454     die "no monitor socket\n" if !defined($monitor_socket);
2455
2456     while (1) {
2457         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2458
2459         die "monitor socket: got EOF\n" if !defined($type);
2460
2461         next if $name ne "$vmid" || $type ne 'STATE';
2462
2463         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2464             alarm(0); # don't timeout after seeing the starting state
2465         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2466                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2467                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2468             return 0;
2469         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2470             return 1;
2471         } else {
2472             warn "unexpected message from monitor socket - " .
2473                  "type: '$type' - value: '$value'\n";
2474         }
2475     }
2476 }
2477 my sub monitor_start($$) {
2478     my ($monitor_socket, $vmid) = @_;
2479
2480     my $success = eval {
2481         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2482     };
2483     if (my $err = $@) {
2484         warn "problem with monitor socket, but continuing anyway: $err\n";
2485     } elsif (!$success) {
2486         print_ct_stderr_log($vmid);
2487         die "startup for container '$vmid' failed\n";
2488     }
2489 }
2490
2491 sub vm_start {
2492     my ($vmid, $conf, $skiplock, $debug) = @_;
2493
2494     # apply pending changes while starting
2495     if (scalar(keys %{$conf->{pending}})) {
2496         my $storecfg = PVE::Storage::config();
2497         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2498         PVE::LXC::Config->write_config($vmid, $conf);
2499         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2500     }
2501
2502     update_lxc_config($vmid, $conf);
2503
2504     eval {
2505         my ($id_map, undef, undef) = PVE::LXC::parse_id_maps($conf);
2506         PVE::LXC::validate_id_maps($id_map);
2507     };
2508     warn "lxc.idmap: $@" if $@;
2509
2510     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2511
2512     if ($skiplock) {
2513         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2514         close($fh);
2515     }
2516
2517     my $storage_cfg = PVE::Storage::config();
2518     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2519
2520     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2521
2522     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2523     warn $@ if $@;
2524
2525     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2526
2527     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2528     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2529
2530     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2531
2532     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2533     eval {
2534         run_command($cmd);
2535
2536         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2537
2538         # if debug is requested, print the log it also when the start succeeded
2539         print_ct_stderr_log($vmid) if $is_debug;
2540
2541         print_ct_warn_log($vmid); # always print warn log, if any
2542     };
2543     if (my $err = $@) {
2544         unlink $skiplock_flag_fn;
2545         die $err;
2546     }
2547     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2548
2549     return;
2550 }
2551
2552 # Helper to stop a container completely and make sure it has stopped completely.
2553 # This is necessary because we want the post-stop hook to have completed its
2554 # unmount-all step, but post-stop happens after lxc puts the container into the
2555 # STOPPED state.
2556 # $kill - if true it will always do an immediate hard-stop
2557 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2558 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2559 sub vm_stop {
2560     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2561
2562     # Open the container's command socket.
2563     my $path = "\0/var/lib/lxc/$vmid/command";
2564     my $sock = IO::Socket::UNIX->new(
2565         Type => SOCK_STREAM(),
2566         Peer => $path,
2567     );
2568     if (!$sock) {
2569         return if $! == ECONNREFUSED; # The container is not running
2570         die "failed to open container ${vmid}'s command socket: $!\n";
2571     }
2572
2573     my $conf = PVE::LXC::Config->load_config($vmid);
2574     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2575
2576     # Stop the container:
2577
2578     my $cmd = ['lxc-stop', '-n', $vmid];
2579
2580     if ($kill) {
2581         push @$cmd, '--kill'; # doesn't allow timeouts
2582     } else {
2583         # lxc-stop uses a default timeout
2584         push @$cmd, '--nokill' if !$kill_after_timeout;
2585
2586         if (defined($shutdown_timeout)) {
2587             push @$cmd, '--timeout', $shutdown_timeout;
2588             # Give run_command 5 extra seconds
2589             $shutdown_timeout += 5;
2590         }
2591     }
2592
2593     eval { run_command($cmd, timeout => $shutdown_timeout) };
2594
2595     # Wait until the command socket is closed.
2596     # In case the lxc-stop call failed, reading from the command socket may block forever,
2597     # so poll with another timeout to avoid freezing the shutdown task.
2598     if (my $err = $@) {
2599         warn $err if $err;
2600
2601         my $poll = IO::Poll->new();
2602         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2603         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2604         return if ($poll->events($sock) & POLLHUP);
2605     } else {
2606         my $result = <$sock>;
2607         return if !defined $result; # monitor is gone and the ct has stopped.
2608     }
2609
2610     die "container did not stop\n";
2611 }
2612
2613 sub vm_reboot {
2614     my ($vmid, $timeout, $skiplock) = @_;
2615
2616     PVE::LXC::Config->lock_config($vmid, sub {
2617         return if !check_running($vmid);
2618
2619         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2620
2621         my $conf = PVE::LXC::Config->load_config($vmid);
2622         vm_start($vmid, $conf);
2623     });
2624 }
2625
2626 sub run_unshared {
2627     my ($code) = @_;
2628
2629     return PVE::Tools::run_fork(sub {
2630         # Unshare the mount namespace
2631         die "failed to unshare mount namespace: $!\n"
2632             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2633         run_command(['mount', '--make-rslave', '/']);
2634         return $code->();
2635     });
2636 }
2637
2638 my $copy_volume = sub {
2639     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2640
2641     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2642     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2643
2644     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2645     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2646
2647     my @mounted;
2648     eval {
2649         # mount and copy
2650         mkdir $src;
2651         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2652         push @mounted, $src;
2653         mkdir $dest;
2654         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2655         push @mounted, $dest;
2656
2657         $bwlimit //= 0;
2658
2659         run_command([
2660             'rsync',
2661             '--stats',
2662             '-X',
2663             '-A',
2664             '--numeric-ids',
2665             '-aH',
2666             '--whole-file',
2667             '--sparse',
2668             '--one-file-system',
2669             "--bwlimit=$bwlimit",
2670             "$src/",
2671             $dest
2672         ]);
2673     };
2674     my $err = $@;
2675
2676     # Wait for rsync's children to release dest so that
2677     # consequent file operations (umount, remove) are possible
2678     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2679
2680     foreach my $mount (reverse @mounted) {
2681         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2682         warn "Can't umount $mount\n" if $@;
2683     }
2684
2685     # If this fails they're used as mount points in a concurrent operation
2686     # (which should not happen but there's also no real need to get rid of them).
2687     rmdir $dest;
2688     rmdir $src;
2689
2690     die $err if $err;
2691 };
2692
2693 # Should not be called after unsharing the mount namespace!
2694 sub copy_volume {
2695     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2696
2697     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2698     File::Path::make_path("/var/lib/lxc/$vmid");
2699     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2700     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2701
2702     # get id's for unprivileged container
2703     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2704
2705     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2706     # are visible in this namespace, otherwise the host only sees the empty
2707     # (not-mounted) directory.
2708     my $new_volid;
2709     eval {
2710         # Make sure $mp contains a correct size.
2711         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2712         my $needs_chown;
2713         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2714         if ($needs_chown) {
2715             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2716             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2717             chown($rootuid, $rootgid, $path);
2718         }
2719
2720         run_unshared(sub {
2721             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2722         });
2723     };
2724     if (my $err = $@) {
2725         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2726             if defined($new_volid);
2727         die $err;
2728     }
2729
2730     return $new_volid;
2731 }
2732
2733 sub get_lxc_version() {
2734     my $version;
2735     run_command([qw(lxc-start --version)], outfunc => sub {
2736         my ($line) = @_;
2737         # We only parse out major & minor version numbers.
2738         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2739             $version = [$1, $2];
2740         }
2741     });
2742
2743     die "failed to get lxc version\n" if !defined($version);
2744
2745     # return as a list:
2746     return $version->@*;
2747 }
2748
2749 sub freeze($) {
2750     my ($vmid) = @_;
2751     if (PVE::CGroup::cgroup_mode() == 2) {
2752         PVE::LXC::Command::freeze($vmid, 30);
2753     } else {
2754         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2755     }
2756 }
2757
2758 sub thaw($) {
2759     my ($vmid) = @_;
2760     if (PVE::CGroup::cgroup_mode() == 2) {
2761         PVE::LXC::Command::unfreeze($vmid, 30);
2762     } else {
2763         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2764     }
2765 }
2766
2767 sub create_ifaces_ipams_ips {
2768     my ($conf, $vmid) = @_;
2769
2770     return if !$have_sdn;
2771
2772     for my $opt (keys %$conf) {
2773         next if $opt !~ m/^net(\d+)$/;
2774         my $net = PVE::QemuServer::parse_net($conf->{$opt});
2775         next if $net->{type} ne 'veth';
2776         PVE::Network::SDN::Vnets::add_next_free_cidr($net->{bridge}, $conf->{hostname}, $net->{hwaddr}, $vmid, undef, 1);
2777     }
2778 }
2779
2780 sub delete_ifaces_ipams_ips {
2781     my ($conf, $vmid) = @_;
2782
2783     return if !$have_sdn;
2784
2785     for my $opt (keys %$conf) {
2786         next if $opt !~ m/^net(\d+)$/;
2787         my $net = PVE::QemuServer::parse_net($conf->{$opt});
2788         eval { PVE::Network::SDN::Vnets::del_ips_from_mac($net->{bridge}, $net->{hwaddr}, $conf->{hostname}) };
2789         warn $@ if $@;
2790     }
2791 }
2792
2793 1;