src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw();
   7 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED EEXIST);
   8 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
   9 use File::Path;
  10 use File::Spec;
  11 use IO::Poll qw(POLLIN POLLHUP);
  12 use IO::Socket::UNIX;
  13 use POSIX qw(EINTR);
  14 use Socket;
  15 use Time::HiRes qw (gettimeofday);
  16
  17 use PVE::AccessControl;
  18 use PVE::CGroup;
  19 use PVE::CpuSet;
  20 use PVE::Exception qw(raise_perm_exc);
  21 use PVE::GuestHelpers qw(check_vnet_access safe_string_ne safe_num_ne safe_boolean_ne);
  22 use PVE::INotify;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use PVE::Network;
  25 use PVE::ProcFSTools;
  26 use PVE::RESTEnvironment;
  27 use PVE::SafeSyslog;
  28 use PVE::Storage;
  29 use PVE::Tools qw(
  30     run_command
  31     dir_glob_foreach
  32     file_get_contents
  33     file_set_contents
  34     AT_FDCWD
  35     O_PATH
  36     $IPV4RE
  37     $IPV6RE
  38 );
  39 use PVE::Syscall qw(:fsmount);
  40
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Config;
  43 use PVE::LXC::Monitor;
  44 use PVE::LXC::Tools;
  45
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         # cgroup memory usage is limited by the hard 'max' limit (OOM-killer enforced) and the soft
 689         # 'high' limit (cgroup processes get throttled and put under heavy reclaim pressure).
 690         my ($lxc_mem_max, $lxc_mem_high) = PVE::LXC::Config::calculate_memory_constraints($memory);
 691         $raw .= "lxc.cgroup2.memory.max = $lxc_mem_max\n";
 692         $raw .= "lxc.cgroup2.memory.high = $lxc_mem_high\n";
 693
 694         my $lxcswap = int($swap*1024*1024);
 695         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 696     }
 697
 698     if ($cgv1->{cpu}) {
 699         if (my $cpulimit = $conf->{cpulimit}) {
 700             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 701             my $value = int(100000*$cpulimit);
 702             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 703         }
 704
 705         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 706         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 707     } elsif ($cgv2->{cpu}) {
 708         # See PVE::CGroup
 709         if (my $cpulimit = $conf->{cpulimit}) {
 710             my $value = int(100000*$cpulimit);
 711             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 712         }
 713
 714         if (defined(my $shares = $conf->{cpuunits})) {
 715             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 716             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 717         }
 718     }
 719
 720     die "missing 'rootfs' configuration\n"
 721         if !defined($conf->{rootfs});
 722
 723     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 724
 725     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 726
 727     foreach my $k (sort keys %$conf) {
 728         next if $k !~ m/^net(\d+)$/;
 729         my $ind = $1;
 730         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 731         $raw .= "lxc.net.$ind.type = veth\n";
 732         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 733         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 734         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 735
 736         my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 737         my $mtu = $d->{mtu} || $bridge_mtu;
 738
 739         # Keep container from starting with invalid mtu configuration
 740         die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 741             if ($mtu > $bridge_mtu);
 742
 743         $raw .= "lxc.net.$ind.mtu = $mtu\n";
 744
 745         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 746         if ($lxc_major >= 4) {
 747             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 748         }
 749     }
 750
 751     my $had_cpuset = 0;
 752     if (my $lxcconf = $conf->{lxc}) {
 753         foreach my $entry (@$lxcconf) {
 754             my ($k, $v) = @$entry;
 755             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 756             $raw .= "$k = $v\n";
 757         }
 758     }
 759
 760     my $cpuset;
 761     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 762     if (defined($cpuset_cgroup)) {
 763         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 764             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 765     }
 766     my $cores = $conf->{cores};
 767     if (!$had_cpuset && $cores && $cpuset) {
 768         my @members = $cpuset->members();
 769         while (scalar(@members) > $cores) {
 770             my $randidx = int(rand(scalar(@members)));
 771             $cpuset->delete($members[$randidx]);
 772             splice(@members, $randidx, 1); # keep track of the changes
 773         }
 774         my $ver = $cpuset_version == 1 ? '' : '2';
 775         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 776     }
 777
 778     File::Path::mkpath("$dir/rootfs");
 779
 780     PVE::Tools::file_set_contents("$dir/config", $raw);
 781 }
 782
 783 # verify and cleanup nameserver list (replace \0 with ' ')
 784 sub verify_nameserver_list {
 785     my ($nameserver_list) = @_;
 786
 787     my @list = ();
 788     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 789         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 790         push @list, $server;
 791     }
 792
 793     return join(' ', @list);
 794 }
 795
 796 sub verify_searchdomain_list {
 797     my ($searchdomain_list) = @_;
 798
 799     my @list = ();
 800     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 801         # todo: should we add checks for valid dns domains?
 802         push @list, $server;
 803     }
 804
 805     return join(' ', @list);
 806 }
 807
 808 sub get_console_command {
 809     my ($vmid, $conf, $escapechar) = @_;
 810
 811     # '-1' as $escapechar disables keyboard escape sequence
 812     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 813
 814     my $cmode = PVE::LXC::Config->get_cmode($conf);
 815
 816     my $cmd = [];
 817     if ($cmode eq 'console') {
 818         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 819         push @$cmd, '-e', $escapechar if $escapechar;
 820     } elsif ($cmode eq 'tty') {
 821         push @$cmd, 'lxc-console', '-n',  $vmid;
 822         push @$cmd, '-e', $escapechar if $escapechar;
 823     } elsif ($cmode eq 'shell') {
 824         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 825     } else {
 826         die "internal error";
 827     }
 828
 829     return $cmd;
 830 }
 831
 832 sub get_primary_ips {
 833     my ($conf) = @_;
 834
 835     # return data from net0
 836
 837     return undef if !defined($conf->{net0});
 838     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 839
 840     my $ipv4 = $net->{ip};
 841     if ($ipv4) {
 842         if ($ipv4 =~ /^(dhcp|manual)$/) {
 843             $ipv4 = undef
 844         } else {
 845             $ipv4 =~ s!/\d+$!!;
 846         }
 847     }
 848     my $ipv6 = $net->{ip6};
 849     if ($ipv6) {
 850         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 851             $ipv6 = undef;
 852         } else {
 853             $ipv6 =~ s!/\d+$!!;
 854         }
 855     }
 856
 857     return ($ipv4, $ipv6);
 858 }
 859
 860 sub delete_mountpoint_volume {
 861     my ($storage_cfg, $vmid, $volume) = @_;
 862
 863     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 864
 865     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 866
 867     if ($vmid == $owner) {
 868         PVE::Storage::vdisk_free($storage_cfg, $volume);
 869     } else {
 870         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 871     }
 872 }
 873
 874 sub destroy_lxc_container {
 875     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 876
 877     my $volids = {};
 878     my $remove_volume = sub {
 879         my ($ms, $mountpoint) = @_;
 880
 881         my $volume = $mountpoint->{volume};
 882
 883         return if $volids->{$volume};
 884         $volids->{$volume} = 1;
 885
 886         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 887     };
 888     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 889
 890     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 891
 892     if ($purge_unreferenced) { # also remove unreferenced disk
 893         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 894         PVE::Storage::foreach_volid($vmdisks, sub {
 895             my ($volid, $sid, $volname, $d) = @_;
 896             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 897             warn $@ if $@;
 898         });
 899     }
 900
 901     rmdir "/var/lib/lxc/$vmid/rootfs";
 902     unlink "/var/lib/lxc/$vmid/config";
 903     rmdir "/var/lib/lxc/$vmid";
 904     if (defined $replacement_conf) {
 905         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 906     } else {
 907         PVE::LXC::Config->destroy_config($vmid);
 908     }
 909 }
 910
 911 sub vm_stop_cleanup {
 912     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 913
 914     return if $keepActive;
 915
 916     eval {
 917         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 918         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 919     };
 920     warn $@ if $@; # avoid errors - just warn
 921 }
 922
 923 sub net_tap_plug : prototype($$) {
 924     my ($iface, $net) = @_;
 925
 926     if (defined($net->{link_down})) {
 927         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 928         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 929         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 930         return;
 931     }
 932
 933     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 934         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 935
 936     if ($have_sdn) {
 937         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 938         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge);
 939     } else {
 940         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 941     }
 942
 943     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 944 }
 945
 946 sub update_net {
 947     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 948
 949     if ($newnet->{type} ne 'veth') {
 950         # for when there are physical interfaces
 951         die "cannot update interface of type $newnet->{type}";
 952     }
 953
 954     my $veth = "veth${vmid}i${netid}";
 955     my $eth = $newnet->{name};
 956
 957     if (my $oldnetcfg = $conf->{$opt}) {
 958         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 959
 960         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 961             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 962
 963             PVE::Network::veth_delete($veth);
 964             delete $conf->{$opt};
 965             PVE::LXC::Config->write_config($vmid, $conf);
 966
 967             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 968
 969         } else {
 970             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 971                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 972                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 973                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 974             ) {
 975
 976                 if ($oldnet->{bridge}) {
 977                     PVE::Network::tap_unplug($veth);
 978                     foreach (qw(bridge tag firewall)) {
 979                         delete $oldnet->{$_};
 980                     }
 981                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 982                     PVE::LXC::Config->write_config($vmid, $conf);
 983                 }
 984
 985                 PVE::LXC::net_tap_plug($veth, $newnet);
 986
 987                 # This includes the rate:
 988                 foreach (qw(bridge tag firewall rate link_down)) {
 989                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 990                 }
 991             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 992                 # Rate can be applied on its own but any change above needs to
 993                 # include the rate in tap_plug since OVS resets everything.
 994                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 995                 $oldnet->{rate} = $newnet->{rate}
 996             }
 997             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 998             PVE::LXC::Config->write_config($vmid, $conf);
 999         }
1000     } else {
1001         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1002     }
1003
1004     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1005 }
1006
1007 sub hotplug_net {
1008     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1009
1010     my $veth = "veth${vmid}i${netid}";
1011     my $vethpeer = $veth . "p";
1012     my $eth = $newnet->{name};
1013
1014     if ($have_sdn) {
1015         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1016     } else {
1017         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1018     }
1019
1020     PVE::LXC::net_tap_plug($veth, $newnet);
1021
1022     # attach peer in container
1023     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1024     PVE::Tools::run_command($cmd);
1025
1026     # link up peer in container
1027     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1028     PVE::Tools::run_command($cmd);
1029
1030     my $done = { type => 'veth' };
1031     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1032         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1033     }
1034     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1035
1036     PVE::LXC::Config->write_config($vmid, $conf);
1037 }
1038
1039 sub update_ipconfig {
1040     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1041
1042     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1043
1044     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1045     my $deleted = [];
1046     my $added = [];
1047     my $nscmd = sub {
1048         my $cmdargs = shift;
1049         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1050     };
1051     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1052
1053     my $change_ip_config = sub {
1054         my ($ipversion) = @_;
1055
1056         my $family_opt = "-$ipversion";
1057         my $suffix = $ipversion == 4 ? '' : $ipversion;
1058         my $gw= "gw$suffix";
1059         my $ip= "ip$suffix";
1060
1061         my $newip = $newnet->{$ip};
1062         my $newgw = $newnet->{$gw};
1063         my $oldip = $optdata->{$ip};
1064         my $oldgw = $optdata->{$gw};
1065
1066         my $change_ip = safe_string_ne($oldip, $newip);
1067         my $change_gw = safe_string_ne($oldgw, $newgw);
1068
1069         return if !$change_ip && !$change_gw;
1070
1071         # step 1: add new IP, if this fails we cancel
1072         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1073         if ($change_ip && $is_real_ip) {
1074             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1075             if (my $err = $@) {
1076                 warn $err;
1077                 return;
1078             }
1079         }
1080
1081         # step 2: replace gateway
1082         #   If this fails we delete the added IP and cancel.
1083         #   If it succeeds we save the config and delete the old IP, ignoring
1084         #   errors. The config is then saved.
1085         # Note: 'ip route replace' can add
1086         if ($change_gw) {
1087             if ($newgw) {
1088                 eval {
1089                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1090                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1091                     }
1092                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1093                 };
1094                 if (my $err = $@) {
1095                     warn $err;
1096                     # the route was not replaced, the old IP is still available
1097                     # rollback (delete new IP) and cancel
1098                     if ($change_ip) {
1099                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1100                         warn $@ if $@; # no need to die here
1101                     }
1102                     return;
1103                 }
1104             } else {
1105                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1106                 # if the route was not deleted, the guest might have deleted it manually
1107                 # warn and continue
1108                 warn $@ if $@;
1109             }
1110             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1111                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1112                 # warn if the route was deleted manually
1113                 warn $@ if $@;
1114             }
1115         }
1116
1117         # from this point on we save the configuration
1118         # step 3: delete old IP ignoring errors
1119         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1120             # We need to enable promote_secondaries, otherwise our newly added
1121             # address will be removed along with the old one.
1122             my $promote = 0;
1123             eval {
1124                 if ($ipversion == 4) {
1125                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1126                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1127                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1128                 }
1129                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1130             };
1131             warn $@ if $@; # no need to die here
1132
1133             if ($ipversion == 4) {
1134                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1135             }
1136         }
1137
1138         foreach my $property ($ip, $gw) {
1139             if ($newnet->{$property}) {
1140                 $optdata->{$property} = $newnet->{$property};
1141             } else {
1142                 delete $optdata->{$property};
1143             }
1144         }
1145         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1146         PVE::LXC::Config->write_config($vmid, $conf);
1147         $lxc_setup->setup_network($conf);
1148     };
1149
1150     &$change_ip_config(4);
1151     &$change_ip_config(6);
1152
1153 }
1154
1155 my $open_namespace = sub {
1156     my ($vmid, $pid, $kind) = @_;
1157     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1158         or die "failed to open $kind namespace of container $vmid: $!\n";
1159     return $fd;
1160 };
1161
1162 my $enter_namespace = sub {
1163     my ($vmid, $pid, $kind, $type) = @_;
1164     my $fd = $open_namespace->($vmid, $pid, $kind);
1165     PVE::Tools::setns(fileno($fd), $type)
1166         or die "failed to enter $kind namespace of container $vmid: $!\n";
1167     close $fd;
1168 };
1169
1170 my $get_container_namespace = sub {
1171     my ($vmid, $pid, $kind) = @_;
1172
1173     my $pidfd;
1174     if (!defined($pid)) {
1175         # Pin the pid while we're grabbing its stuff from /proc
1176         ($pid, $pidfd) = open_lxc_pid($vmid)
1177             or die "failed to open pidfd of container $vmid\'s init process\n";
1178     }
1179
1180     return $open_namespace->($vmid, $pid, $kind);
1181 };
1182
1183 my $do_syncfs = sub {
1184     my ($vmid, $pid, $socket) = @_;
1185
1186     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1187
1188     # Tell the parent process to start reading our /proc/mounts
1189     print {$socket} "go\n";
1190     $socket->flush();
1191
1192     # Receive /proc/self/mounts
1193     my $mountdata = do { local $/ = undef; <$socket> };
1194     close $socket;
1195
1196     my %nosyncfs = (
1197         cgroup => 1,
1198         cgroup2 => 1,
1199         devtmpfs => 1,
1200         devpts => 1,
1201         'fuse.lxcfs' => 1,
1202         fusectl => 1,
1203         mqueue => 1,
1204         proc => 1,
1205         sysfs => 1,
1206         tmpfs => 1,
1207     );
1208
1209     # Now sync all mountpoints...
1210     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1211     foreach my $mp (@$mounts) {
1212         my ($what, $dir, $fs) = @$mp;
1213         next if $nosyncfs{$fs};
1214         eval { PVE::Tools::sync_mountpoint($dir); };
1215         warn $@ if $@;
1216     }
1217 };
1218
1219 sub sync_container_namespace {
1220     my ($vmid) = @_;
1221     my $pid = find_lxc_pid($vmid);
1222
1223     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1224     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1225         or die "failed to create socketpair: $!\n";
1226
1227     my $child = fork();
1228     die "fork failed: $!\n" if !defined($child);
1229
1230     if (!$child) {
1231         eval {
1232             close $pfd;
1233             &$do_syncfs($vmid, $pid, $cfd);
1234         };
1235         if (my $err = $@) {
1236             warn $err;
1237             POSIX::_exit(1);
1238         }
1239         POSIX::_exit(0);
1240     }
1241     close $cfd;
1242     my $go = <$pfd>;
1243     die "failed to enter container namespace\n" if $go ne "go\n";
1244
1245     open my $mounts, '<', "/proc/$child/mounts"
1246         or die "failed to open container's /proc/mounts: $!\n";
1247     my $mountdata = do { local $/ = undef; <$mounts> };
1248     close $mounts;
1249     print {$pfd} $mountdata;
1250     close $pfd;
1251
1252     while (waitpid($child, 0) != $child) {}
1253     die "failed to sync container namespace\n" if $? != 0;
1254 }
1255
1256 sub template_create {
1257     my ($vmid, $conf) = @_;
1258
1259     my $storecfg = PVE::Storage::config();
1260
1261     PVE::LXC::Config->foreach_volume($conf, sub {
1262         my ($ms, $mountpoint) = @_;
1263
1264         my $volid = $mountpoint->{volume};
1265
1266         die "Template feature is not available for '$volid'\n"
1267             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1268     });
1269
1270     PVE::LXC::Config->foreach_volume($conf, sub {
1271         my ($ms, $mountpoint) = @_;
1272
1273         my $volid = $mountpoint->{volume};
1274
1275         PVE::Storage::activate_volumes($storecfg, [$volid]);
1276
1277         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1278         $mountpoint->{volume} = $template_volid;
1279         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1280     });
1281
1282     PVE::LXC::Config->write_config($vmid, $conf);
1283 }
1284
1285 sub check_ct_modify_config_perm {
1286     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1287
1288     return 1 if $authuser eq 'root@pam';
1289     my $storage_cfg = PVE::Storage::config();
1290
1291     my $check = sub {
1292         my ($opt, $delete) = @_;
1293         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1294             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1295         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1296             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1297             return if $delete;
1298             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1299             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1300                 if $data->{type} ne 'volume';
1301             my $volid = $data->{volume};
1302             if ($volid =~ $NEW_DISK_RE) {
1303                 my $sid = $1;
1304                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1305             } else {
1306                 PVE::Storage::check_volume_access(
1307                     $rpcenv,
1308                     $authuser,
1309                     $storage_cfg,
1310                     $vmid,
1311                     $volid,
1312                     'rootdir',
1313                 );
1314             }
1315         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1316             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1317         } elsif ($opt =~ m/^net\d+$/) {
1318             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1319             check_bridge_access($rpcenv, $authuser, $oldconf->{$opt}) if $oldconf->{$opt};
1320             check_bridge_access($rpcenv, $authuser, $newconf->{$opt}) if $newconf->{$opt};
1321         } elsif ($opt eq 'nameserver' || $opt eq 'searchdomain' || $opt eq 'hostname') {
1322             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1323         } elsif ($opt eq 'features') {
1324             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1325                 if !$unprivileged;
1326
1327             my $nesting_changed = 0;
1328             my $other_changed = 0;
1329             if (!$delete) {
1330                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1331                 if (defined($oldconf) && $oldconf->{$opt}) {
1332                     # existing container with features
1333                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1334                     for my $feature ((keys %$old_features, keys %$features)) {
1335                         my $old = $old_features->{$feature} // '';
1336                         my $new = $features->{$feature} // '';
1337                         if ($old ne $new) {
1338                             if ($feature eq 'nesting') {
1339                                 $nesting_changed = 1;
1340                                 next;
1341                             } else {
1342                                 $other_changed = 1;
1343                                 last;
1344                             }
1345                         }
1346                     }
1347                 } else {
1348                     # new container or no features defined
1349                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1350                         $nesting_changed = 1;
1351                     } elsif (scalar(keys %$features) > 0) {
1352                         $other_changed = 1;
1353                     }
1354                 }
1355             } else {
1356                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1357                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1358                     $nesting_changed = 1;
1359                 } elsif (scalar(keys %$features) > 0) {
1360                     $other_changed = 1;
1361                 }
1362             }
1363             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1364                 if $other_changed;
1365             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1366                 if $nesting_changed;
1367         } elsif ($opt eq 'hookscript') {
1368             # For now this is restricted to root@pam
1369             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1370         } elsif ($opt eq 'tags') {
1371             my $old = $oldconf->{$opt};
1372             my $new = $delete ? '' : $newconf->{$opt};
1373             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1374         } else {
1375             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1376         }
1377     };
1378
1379     foreach my $opt (keys %$newconf) {
1380         &$check($opt, 0);
1381     }
1382     foreach my $opt (@$delete) {
1383         &$check($opt, 1);
1384     }
1385
1386     return 1;
1387 }
1388
1389 sub check_bridge_access {
1390     my ($rpcenv, $authuser, $raw) = @_;
1391
1392     return 1 if $authuser eq 'root@pam';
1393
1394     my $net = PVE::LXC::Config->parse_lxc_network($raw);
1395     my ($bridge, $tag, $trunks) = $net->@{'bridge', 'tag', 'trunks'};
1396     check_vnet_access($rpcenv, $authuser, $bridge, $tag, $trunks);
1397
1398     return 1;
1399 };
1400
1401 sub umount_all {
1402     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1403
1404     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1405     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1406
1407     my $res = 1;
1408
1409     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1410         my ($ms, $mountpoint) = @_;
1411
1412         my $volid = $mountpoint->{volume};
1413         my $mount = $mountpoint->{mp};
1414
1415         return if !$volid || !$mount;
1416
1417         my $mount_path = "$rootdir/$mount";
1418         $mount_path =~ s!/+!/!g;
1419
1420         return if !PVE::ProcFSTools::is_mounted($mount_path);
1421
1422         eval {
1423             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1424         };
1425         if (my $err = $@) {
1426             if ($noerr) {
1427                 $res = 0;
1428                 warn $err;
1429             } else {
1430                 die $err;
1431             }
1432         }
1433     });
1434
1435     return $res; # tell caller if (some) umounts failed for the noerr case
1436 }
1437
1438 sub mount_all {
1439     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1440
1441     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1442     File::Path::make_path($rootdir);
1443
1444     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1445     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1446
1447     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1448
1449     eval {
1450         PVE::LXC::Config->foreach_volume($conf, sub {
1451             my ($ms, $mountpoint) = @_;
1452
1453             $mountpoint->{ro} = 0 if $ignore_ro;
1454
1455             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1456         });
1457     };
1458     if (my $err = $@) {
1459         warn "mounting container failed\n";
1460         umount_all($vmid, $storage_cfg, $conf, 1);
1461         die $err;
1462     }
1463
1464     return $rootdir;
1465 }
1466
1467
1468 sub mountpoint_mount_path {
1469     my ($mountpoint, $storage_cfg, $snapname) = @_;
1470
1471     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1472 }
1473
1474 sub query_loopdev {
1475     my ($path) = @_;
1476     my $found;
1477     my $parser = sub {
1478         my $line = shift;
1479         if ($line =~ m@^(/dev/loop\d+):@) {
1480             $found = $1;
1481         }
1482     };
1483     my $cmd = ['losetup', '--associated', $path];
1484     PVE::Tools::run_command($cmd, outfunc => $parser);
1485     return $found;
1486 }
1487
1488 # Run a function with a file attached to a loop device.
1489 # The loop device is always detached afterwards (or set to autoclear).
1490 # Returns the loop device.
1491 sub run_with_loopdev {
1492     my ($func, $file, $readonly) = @_;
1493     my $device = query_loopdev($file);
1494     # Try to reuse an existing device
1495     if ($device) {
1496         # We assume that whoever setup the loop device is responsible for
1497         # detaching it.
1498         &$func($device);
1499         return $device;
1500     }
1501
1502     my $parser = sub {
1503         my $line = shift;
1504         if ($line =~ m@^(/dev/loop\d+)$@) {
1505             $device = $1;
1506         }
1507     };
1508     my $losetup_cmd = [
1509         'losetup',
1510         '--show',
1511         '-f',
1512         $file,
1513     ];
1514     push @$losetup_cmd, '-r' if $readonly;
1515     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1516     die "failed to setup loop device for $file\n" if !$device;
1517     eval { &$func($device); };
1518     my $err = $@;
1519     PVE::Tools::run_command(['losetup', '-d', $device]);
1520     die $err if $err;
1521     return $device;
1522 }
1523
1524 # In scalar mode: returns a file handle to the deepest directory node.
1525 # In list context: returns a list of:
1526 #   * the deepest directory node
1527 #   * the 2nd deepest directory (parent of the above)
1528 #   * directory name of the last directory
1529 # So that the path $2/$3 should lead to $1 afterwards.
1530 sub walk_tree_nofollow($$$;$$) {
1531     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1532
1533     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1534         or die "failed to open start directory $start: $!\n";
1535
1536     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1537 }
1538
1539
1540 sub walk_tree_nofollow_fd($$$$;$$) {
1541     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1542
1543     # splitdir() returns '' for empty components including the leading /
1544     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1545
1546     my $fd = $start_fd;
1547     my $dir = $start_dirname;
1548     my $last_component = undef;
1549     my $second = $fd;
1550     foreach my $component (@comps) {
1551         $dir .= "/$component";
1552         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1553
1554         if (!$next) {
1555             # failed, check for symlinks and try to create the path
1556             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1557             die "cannot open directory $dir: $!\n" if !$mkdir;
1558
1559             # We don't check for errors on mkdirat() here and just try to
1560             # openat() again, since at least one error (EEXIST) is an
1561             # expected possibility if multiple containers start
1562             # simultaneously. If someone else injects a symlink now then
1563             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1564             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1565
1566             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1567             die "failed to create path: $dir: $!\n" if !$next;
1568
1569             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1570                 if defined($rootuid) && defined($rootgid);
1571         }
1572
1573         close $second if defined($last_component) && $second != $start_fd;
1574         $last_component = $component;
1575         $second = $fd;
1576         $fd = $next;
1577     }
1578
1579     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1580     close $second if defined($last_component) && $second != $start_fd;
1581     return $fd;
1582 }
1583
1584 # To guard against symlink attack races against other currently running
1585 # containers with shared recursive bind mount hierarchies we prepare a
1586 # directory handle for the directory we're mounting over to verify the
1587 # mountpoint afterwards.
1588 sub __bindmount_prepare {
1589     my ($hostroot, $dir) = @_;
1590     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1591     return $srcdh;
1592 }
1593
1594 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1595 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1596 # we intended to bind mount.
1597 sub __bindmount_verify {
1598     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1599     my $destdh;
1600     if ($parentfd) {
1601         # Open the mount point path coming from the parent directory since the
1602         # filehandle we would have gotten as first result of walk_tree_nofollow
1603         # earlier is still a handle to the underlying directory instead of the
1604         # mounted path.
1605         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1606         die "failed to open mount point: $!\n" if !$destdh;
1607         if ($ro) {
1608             my $dot = '.';
1609             # no separate function because 99% of the time it's the wrong thing to use.
1610             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1611                 die "failed to mark bind mount read only\n";
1612             }
1613             die "read-only check failed: $!\n" if $! != EROFS;
1614         }
1615     } else {
1616         # For the rootfs we don't have a parentfd so we open the path directly.
1617         # Note that this means bindmounting any prefix of the host's
1618         # /var/lib/lxc/$vmid path into another container is considered a grave
1619         # security error.
1620         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1621         die "failed to open mount point: $!\n" if !$destdh;
1622     }
1623
1624     my ($srcdev, $srcinode) = stat($srcdh);
1625     my ($dstdev, $dstinode) = stat($destdh);
1626     close $srcdh;
1627     close $destdh;
1628
1629     return ($srcdev == $dstdev && $srcinode == $dstinode);
1630 }
1631
1632 # Perform the actual bind mounting:
1633 sub __bindmount_do {
1634     my ($dir, $dest, $ro, @extra_opts) = @_;
1635     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1636     if ($ro) {
1637         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1638         if (my $err = $@) {
1639             warn "bindmount error\n";
1640             # don't leave writable bind-mounts behind...
1641             PVE::Tools::run_command(['umount', $dest]);
1642             die $err;
1643         }
1644     }
1645 }
1646
1647 sub bindmount {
1648     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1649
1650     my $srcdh = __bindmount_prepare('/', $dir);
1651
1652     __bindmount_do($dir, $dest, $ro, @extra_opts);
1653
1654     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1655         PVE::Tools::run_command(['umount', $dest]);
1656         die "detected mount path change at: $dir\n";
1657     }
1658 }
1659
1660 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1661 # from $rootdir and $mount and walk the path from $rootdir to the final
1662 # directory to check for symlinks.
1663 sub __mount_prepare_rootdir {
1664     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1665     $rootdir =~ s!/+!/!g;
1666     $rootdir =~ s!/+$!!;
1667     my $mount_path = "$rootdir/$mount";
1668     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1669     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1670 }
1671
1672 # use $rootdir = undef to just return the corresponding mount path
1673 sub mountpoint_mount {
1674     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1675     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1676 }
1677
1678 sub mountpoint_stage {
1679     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1680     my ($path, $loop, $dev) =
1681         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1682
1683     if (!defined($path)) {
1684         die "failed to mount subvolume: $!\n";
1685     }
1686
1687     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1688     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1689     # point).
1690     my $err;
1691     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1692         or die "open_tree() on mount point failed: $!\n";
1693
1694     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1695 }
1696
1697 sub mountpoint_insert_staged {
1698     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1699
1700     if (!defined($rootdir_fd)) {
1701         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1702             or die "failed to open '.': $!\n";
1703     }
1704
1705     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1706
1707     PVE::Tools::move_mount(
1708         fileno($mount_fd),
1709         '',
1710         fileno($dest_fd),
1711         '',
1712         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1713     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1714 }
1715
1716 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1717 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1718 sub __mountpoint_mount {
1719     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1720
1721     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1722     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1723     # which we use in __bindmount_verify()!
1724     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1725
1726     my $volid = $mountpoint->{volume};
1727     my $type = $mountpoint->{type};
1728     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1729     my $mounted_dev;
1730
1731     return if !$volid || !$mount;
1732
1733     $mount =~ s!/+!/!g;
1734
1735     my $mount_path;
1736     my ($mpfd, $parentfd, $last_dir);
1737
1738     if (defined($rootdir)) {
1739         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1740             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1741     }
1742
1743     if (defined($stage_mount)) {
1744         $mount_path = $rootdir;
1745     }
1746
1747     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1748
1749     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1750
1751     my $optlist = [];
1752
1753     if (my $mountopts = $mountpoint->{mountoptions}) {
1754         my @opts = split(/;/, $mountpoint->{mountoptions});
1755         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1756     }
1757
1758     my $acl = $mountpoint->{acl};
1759     if (defined($acl)) {
1760         push @$optlist, ($acl ? 'acl' : 'noacl');
1761     }
1762
1763     my $optstring = join(',', @$optlist);
1764     my $readonly = $mountpoint->{ro};
1765
1766     my @extra_opts;
1767     @extra_opts = ('-o', $optstring) if $optstring;
1768
1769     if ($storage) {
1770
1771         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1772
1773         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1774
1775         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1776
1777         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1778             PVE::Storage::parse_volname($storage_cfg, $volid);
1779
1780         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1781
1782         if ($format eq 'subvol') {
1783             if ($mount_path) {
1784                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1785                 if (defined($snapname)) {
1786                     $name .= "\@$snapname";
1787                     if ($scfg->{type} eq 'zfspool') {
1788                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1789                     } else {
1790                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1791                     }
1792                 } else {
1793                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1794                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1795                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1796                     }
1797                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1798                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1799                 }
1800             }
1801             return wantarray ? ($path, 0, undef) : $path;
1802         } elsif ($format eq 'raw' || $format eq 'iso') {
1803             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1804             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1805             # Our autodev hook expects the /dev/dm-* device currently
1806             # and will create the /dev/mapper symlink accordingly
1807             $path = Cwd::realpath($path);
1808             die "failed to get device path\n" if !$path;
1809             ($path) = ($path =~ /^(.*)$/s); #untaint
1810             my $domount = sub {
1811                 my ($path) = @_;
1812                 if ($mount_path) {
1813                     if ($format eq 'iso') {
1814                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1815                     } elsif ($isBase || defined($snapname)) {
1816                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1817                     } else {
1818                         if ($quota) {
1819                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1820                         }
1821                         push @extra_opts, '-o', 'ro' if $readonly;
1822                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1823                     }
1824                 }
1825             };
1826             my $use_loopdev = 0;
1827             if ($scfg->{content}->{rootdir}) {
1828                 if ($scfg->{path}) {
1829                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1830                     $use_loopdev = 1;
1831                 } else {
1832                     $mounted_dev = $path;
1833                     &$domount($path);
1834                 }
1835             } else {
1836                 die "storage '$storage' does not support containers\n";
1837             }
1838             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1839         } else {
1840             die "unsupported image format '$format'\n";
1841         }
1842     } elsif ($type eq 'device') {
1843         push @extra_opts, '-o', 'ro' if $readonly;
1844         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1845         # See the NOTE above about devicemapper canonicalization
1846         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1847         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1848         return wantarray ? ($volid, 0, $devpath) : $volid;
1849     } elsif ($type eq 'bind') {
1850         die "directory '$volid' does not exist\n" if ! -d $volid;
1851         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1852         warn "cannot enable quota control for bind mounts\n" if $quota;
1853         return wantarray ? ($volid, 0, undef) : $volid;
1854     }
1855
1856     die "unsupported storage";
1857 }
1858
1859 sub mountpoint_hotplug :prototype($$$$$) {
1860     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1861
1862     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1863
1864     # We do the rest in a fork with an unshared mount namespace, because:
1865     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1866     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1867     #     container's namespace, then mount it.
1868
1869     PVE::Tools::run_fork(sub {
1870         # Pin the container pid longer, we also need to get its monitor/parent:
1871         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1872             or die "failed to open pidfd of container $vmid\'s init process\n";
1873
1874         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1875             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1876
1877         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1878         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1879
1880         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1881         # profile to lower our privileges to the same level we have in the start hook:
1882         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1883             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1884         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1885         # apparmor.
1886
1887         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1888         # namespace for it to remain active there since the container will be able to unmount
1889         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1890         # concern.
1891         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1892         chdir('/')
1893             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1894
1895         my $dir = get_staging_mount_path($opt);
1896
1897         # Now switch our apparmor profile before mounting:
1898         my $data = 'changeprofile /usr/bin/lxc-start';
1899         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1900             die "failed to change apparmor profile: $!\n";
1901         }
1902         # Check errors on close as well:
1903         close($aa_fd)
1904             or die "failed to change apparmor profile (close() failed): $!\n";
1905
1906         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1907
1908         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1909         chdir('/')
1910             or die "failed to change root directory within the container's mount namespace: $!\n";
1911
1912         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1913     });
1914 }
1915
1916 # Create a directory in the mountpoint staging tempfs.
1917 sub get_staging_mount_path($) {
1918     my ($opt) = @_;
1919
1920     my $target = get_staging_tempfs() . "/$opt";
1921     if (!mkdir($target) && $! != EEXIST) {
1922         die "failed to create directory $target: $!\n";
1923     }
1924
1925     return $target;
1926 }
1927
1928 # Mount tmpfs for mount point staging and return the path.
1929 sub get_staging_tempfs() {
1930     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1931     # mounts to that.
1932     my $target = '/var/lib/lxc/.pve-staged-mounts';
1933     if (!mkdir($target)) {
1934         return $target if $! == EEXIST;
1935         die "failed to create directory $target: $!\n";
1936     }
1937
1938     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1939         or die "failed to mount $target as tmpfs: $!\n";
1940
1941     return $target;
1942 }
1943
1944 sub mkfs {
1945     my ($dev, $rootuid, $rootgid) = @_;
1946
1947     run_command(
1948         [
1949             'mkfs.ext4',
1950             '-O',
1951             'mmp',
1952             '-E',
1953             "root_owner=$rootuid:$rootgid",
1954             $dev,
1955         ],
1956         outfunc => sub {
1957             my $line = shift;
1958             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1959             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1960                 print "$line\n";
1961             }
1962         },
1963         errfunc => sub {
1964             my $line = shift;
1965             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1966         }
1967     );
1968 }
1969
1970 sub format_disk {
1971     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1972
1973     if ($volid =~ m!^/dev/.+!) {
1974         mkfs($volid);
1975         return;
1976     }
1977
1978     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1979
1980     die "cannot format volume '$volid' with no storage\n" if !$storage;
1981
1982     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1983
1984     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1985
1986     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1987
1988     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1989         PVE::Storage::parse_volname($storage_cfg, $volid);
1990
1991     die "cannot format volume '$volid' (format == $format)\n"
1992         if $format ne 'raw';
1993
1994     mkfs($path, $rootuid, $rootgid);
1995 }
1996
1997 sub destroy_disks {
1998     my ($storecfg, $vollist) = @_;
1999
2000     foreach my $volid (@$vollist) {
2001         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2002         warn $@ if $@;
2003     }
2004 }
2005
2006 sub alloc_disk {
2007     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
2008
2009     my $needs_chown = 0;
2010     my $volid;
2011
2012     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2013     # fixme: use better naming ct-$vmid-disk-X.raw?
2014
2015     eval {
2016         my $do_format = 0;
2017         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2018             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2019                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2020                 $do_format = 1;
2021             } else {
2022                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2023                 $needs_chown = 1;
2024             }
2025         } elsif ($scfg->{type} eq 'zfspool') {
2026             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2027             $needs_chown = 1;
2028         } elsif ($scfg->{content}->{rootdir}) {
2029             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2030             $do_format = 1;
2031         } else {
2032             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2033         }
2034         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2035     };
2036     if (my $err = $@) {
2037         # in case formatting got interrupted:
2038         if (defined($volid)) {
2039             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2040             warn $@ if $@;
2041         }
2042         die $err;
2043     }
2044
2045     return ($volid, $needs_chown);
2046 }
2047
2048 sub create_disks {
2049     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2050
2051     my $vollist = [];
2052
2053     eval {
2054         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2055         my $chown_vollist = [];
2056
2057         PVE::LXC::Config->foreach_volume($settings, sub {
2058             my ($ms, $mountpoint) = @_;
2059
2060             my $volid = $mountpoint->{volume};
2061             my $mp = $mountpoint->{mp};
2062
2063             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2064
2065             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2066                 my ($storeid, $size_gb) = ($1, $2);
2067
2068                 my $size_kb = int(${size_gb}*1024) * 1024;
2069
2070                 my $needs_chown = 0;
2071                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2072                 push @$chown_vollist, $volid if $needs_chown;
2073                 push @$vollist, $volid;
2074                 $mountpoint->{volume} = $volid;
2075                 $mountpoint->{size} = $size_kb * 1024;
2076                 if ($pending) {
2077                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2078                 } else {
2079                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2080                 }
2081             } else {
2082                 # use specified/existing volid/dir/device
2083                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2084             }
2085         });
2086
2087         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2088         foreach my $volid (@$chown_vollist) {
2089             my $path = PVE::Storage::path($storecfg, $volid, undef);
2090             chown($rootuid, $rootgid, $path);
2091         }
2092         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2093     };
2094     # free allocated images on error
2095     if (my $err = $@) {
2096         destroy_disks($storecfg, $vollist);
2097         die $err;
2098     }
2099     return $vollist;
2100 }
2101
2102 sub update_disksize {
2103     my ($vmid, $conf, $all_volumes) = @_;
2104
2105     my $changes;
2106     my $prefix = "CT $vmid:";
2107
2108     my $update_mp = sub {
2109         my ($key, $mp, @param) = @_;
2110         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2111
2112         if (!defined($mp->{size}) || $size != $mp->{size}) {
2113             $changes = 1;
2114             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2115             $mp->{size} = $size;
2116             my $no_mp = $key eq 'rootfs'; # rootfs is handled different from other mount points
2117             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $no_mp);
2118         }
2119     };
2120
2121     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2122
2123     return $changes;
2124 }
2125
2126 sub update_unused {
2127     my ($vmid, $conf, $all_volumes) = @_;
2128
2129     my $changes;
2130     my $prefix = "CT $vmid:";
2131
2132     # Note: it is allowed to define multiple storage entries with the same path
2133     # (alias), so we need to check both 'volid' and real 'path' (two different
2134     # volid can point to the same path).
2135
2136     # used and unused disks
2137     my $refpath = {};
2138     my $orphans = {};
2139
2140     foreach my $opt (keys %$conf) {
2141         next if ($opt !~ m/^unused\d+$/);
2142         my $vol = $all_volumes->{$conf->{$opt}};
2143         $refpath->{$vol->{path}} = $vol->{volid};
2144     }
2145
2146     foreach my $key (keys %$all_volumes) {
2147         my $vol = $all_volumes->{$key};
2148         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2149         my $path = $vol->{path};
2150
2151         if ($in_use) {
2152             $refpath->{$path} = $key;
2153             delete $orphans->{$path};
2154         } else {
2155             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2156                 $orphans->{$path} = $key;
2157             }
2158         }
2159     }
2160
2161     for my $key (keys %$orphans) {
2162         my $disk = $orphans->{$key};
2163         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2164
2165         if ($unused) {
2166             $changes = 1;
2167             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2168         }
2169     }
2170
2171     return $changes;
2172 }
2173
2174 sub scan_volids {
2175     my ($cfg, $vmid) = @_;
2176
2177     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2178
2179     my $all_volumes = {};
2180     foreach my $storeid (keys %$info) {
2181         foreach my $item (@{$info->{$storeid}}) {
2182             my $volid = $item->{volid};
2183             next if !($volid && $item->{size});
2184             $item->{path} = PVE::Storage::path($cfg, $volid);
2185             $all_volumes->{$volid} = $item;
2186         }
2187     }
2188
2189     return $all_volumes;
2190 }
2191
2192 sub rescan {
2193     my ($vmid, $nolock, $dryrun) = @_;
2194
2195     my $cfg = PVE::Storage::config();
2196
2197     print "rescan volumes...\n";
2198     my $all_volumes = scan_volids($cfg, $vmid);
2199
2200     my $updatefn =  sub {
2201         my ($vmid) = @_;
2202
2203         my $changes;
2204         my $conf = PVE::LXC::Config->load_config($vmid);
2205
2206         PVE::LXC::Config->check_lock($conf);
2207
2208         my $vm_volids = {};
2209         foreach my $volid (keys %$all_volumes) {
2210             my $info = $all_volumes->{$volid};
2211             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2212         }
2213
2214         my $upu = update_unused($vmid, $conf, $vm_volids);
2215         my $upd = update_disksize($vmid, $conf, $vm_volids);
2216         $changes = $upu || $upd;
2217
2218         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2219     };
2220
2221     if (defined($vmid)) {
2222         if ($nolock) {
2223             &$updatefn($vmid);
2224         } else {
2225             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2226         }
2227     } else {
2228         my $vmlist = config_list();
2229         foreach my $vmid (keys %$vmlist) {
2230             if ($nolock) {
2231                 &$updatefn($vmid);
2232             } else {
2233                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2234             }
2235         }
2236     }
2237 }
2238
2239
2240 # bash completion helper
2241
2242 sub complete_os_templates {
2243     my ($cmdname, $pname, $cvalue) = @_;
2244
2245     my $cfg = PVE::Storage::config();
2246
2247     my $storeid;
2248
2249     if ($cvalue =~ m/^([^:]+):/) {
2250         $storeid = $1;
2251     }
2252
2253     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2254     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2255
2256     my $res = [];
2257     foreach my $id (keys %$data) {
2258         foreach my $item (@{$data->{$id}}) {
2259             push @$res, $item->{volid} if defined($item->{volid});
2260         }
2261     }
2262
2263     return $res;
2264 }
2265
2266 my $complete_ctid_full = sub {
2267     my ($running) = @_;
2268
2269     my $idlist = vmstatus();
2270
2271     my $active_hash = list_active_containers();
2272
2273     my $res = [];
2274
2275     foreach my $id (keys %$idlist) {
2276         my $d = $idlist->{$id};
2277         if (defined($running)) {
2278             next if $d->{template};
2279             next if $running && !$active_hash->{$id};
2280             next if !$running && $active_hash->{$id};
2281         }
2282         push @$res, $id;
2283
2284     }
2285     return $res;
2286 };
2287
2288 sub complete_ctid {
2289     return &$complete_ctid_full();
2290 }
2291
2292 sub complete_ctid_stopped {
2293     return &$complete_ctid_full(0);
2294 }
2295
2296 sub complete_ctid_running {
2297     return &$complete_ctid_full(1);
2298 }
2299
2300 sub parse_id_maps {
2301     my ($conf) = @_;
2302
2303     my $id_map = [];
2304     my $rootuid = 0;
2305     my $rootgid = 0;
2306
2307     my $lxc = $conf->{lxc};
2308     foreach my $entry (@$lxc) {
2309         my ($key, $value) = @$entry;
2310
2311         next if $key ne 'lxc.idmap';
2312
2313         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2314             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2315             push @$id_map, [$type, $ct, $host, $length];
2316             if ($ct == 0) {
2317                 $rootuid = $host if $type eq 'u';
2318                 $rootgid = $host if $type eq 'g';
2319             }
2320         } else {
2321             die "failed to parse idmap: $value\n";
2322         }
2323     }
2324
2325     if (!@$id_map && $conf->{unprivileged}) {
2326         # Should we read them from /etc/subuid?
2327         $id_map = [ ['u', '0', '100000', '65536'],
2328                     ['g', '0', '100000', '65536'] ];
2329         $rootuid = $rootgid = 100000;
2330     }
2331
2332     return ($id_map, $rootuid, $rootgid);
2333 }
2334
2335 sub validate_id_maps {
2336     my ($id_map) = @_;
2337
2338     # $mappings->{$type}->{$side} = [ { line => $line, start => $start, count => $count }, ... ]
2339     #   $type: either "u" or "g"
2340     #   $side: either "container" or "host"
2341     #   $line: index of this mapping in @$id_map
2342     #   $start, $count: interval of this mapping
2343     my $mappings = { u => {}, g => {} };
2344     for (my $i = 0; $i < scalar(@$id_map); $i++) {
2345         my ($type, $ct_start, $host_start, $count) = $id_map->[$i]->@*;
2346         my $sides = $mappings->{$type};
2347         push $sides->{host}->@*, { line => $i, start => $host_start, count => $count };
2348         push $sides->{container}->@*, { line => $i, start => $ct_start, count => $count };
2349     }
2350
2351     # find the first conflict between two consecutive mappings when sorted by their start id
2352     for my $type (qw(u g)) {
2353         for my $side (qw(container host)) {
2354             my @entries = sort { $a->{start} <=> $b->{start} } $mappings->{$type}->{$side}->@*;
2355             for my $idx (1..scalar(@entries) - 1) {
2356                 my $previous = $entries[$idx - 1];
2357                 my $current = $entries[$idx];
2358                 if ($previous->{start} + $previous->{count} > $current->{start}) {
2359                     my $conflict = $current->{start};
2360                     my @previous_line = $id_map->[$previous->{line}]->@*;
2361                     my @current_line = $id_map->[$current->{line}]->@*;
2362                     die "invalid map entry '@current_line': $side ${type}id $conflict "
2363                        ."is also mapped by entry '@previous_line'\n";
2364                 }
2365             }
2366         }
2367     }
2368 }
2369
2370 sub userns_command {
2371     my ($id_map) = @_;
2372     if (@$id_map) {
2373         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2374     }
2375     return [];
2376 }
2377
2378 my sub print_ct_stderr_log {
2379     my ($vmid) = @_;
2380     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2381     return if !$log;
2382
2383     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2384         my $line = $2;
2385         print STDERR "$line\n";
2386     }
2387 }
2388 my sub print_ct_warn_log {
2389     my ($vmid) = @_;
2390     my $log_fn = "/run/pve/ct-$vmid.warnings";
2391     my $log = eval { file_get_contents($log_fn) };
2392     return if !$log;
2393
2394     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2395         PVE::RESTEnvironment::log_warn($1);
2396     }
2397     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2398 }
2399
2400 my sub monitor_state_change($$) {
2401     my ($monitor_socket, $vmid) = @_;
2402     die "no monitor socket\n" if !defined($monitor_socket);
2403
2404     while (1) {
2405         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2406
2407         die "monitor socket: got EOF\n" if !defined($type);
2408
2409         next if $name ne "$vmid" || $type ne 'STATE';
2410
2411         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2412             alarm(0); # don't timeout after seeing the starting state
2413         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2414                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2415                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2416             return 0;
2417         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2418             return 1;
2419         } else {
2420             warn "unexpected message from monitor socket - " .
2421                  "type: '$type' - value: '$value'\n";
2422         }
2423     }
2424 }
2425 my sub monitor_start($$) {
2426     my ($monitor_socket, $vmid) = @_;
2427
2428     my $success = eval {
2429         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2430     };
2431     if (my $err = $@) {
2432         warn "problem with monitor socket, but continuing anyway: $err\n";
2433     } elsif (!$success) {
2434         print_ct_stderr_log($vmid);
2435         die "startup for container '$vmid' failed\n";
2436     }
2437 }
2438
2439 sub vm_start {
2440     my ($vmid, $conf, $skiplock, $debug) = @_;
2441
2442     # apply pending changes while starting
2443     if (scalar(keys %{$conf->{pending}})) {
2444         my $storecfg = PVE::Storage::config();
2445         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2446         PVE::LXC::Config->write_config($vmid, $conf);
2447         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2448     }
2449
2450     update_lxc_config($vmid, $conf);
2451
2452     eval {
2453         my ($id_map, undef, undef) = PVE::LXC::parse_id_maps($conf);
2454         PVE::LXC::validate_id_maps($id_map);
2455     };
2456     warn "lxc.idmap: $@" if $@;
2457
2458     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2459
2460     if ($skiplock) {
2461         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2462         close($fh);
2463     }
2464
2465     my $storage_cfg = PVE::Storage::config();
2466     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2467
2468     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2469
2470     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2471     warn $@ if $@;
2472
2473     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2474
2475     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2476     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2477
2478     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2479
2480     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2481     eval {
2482         run_command($cmd);
2483
2484         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2485
2486         # if debug is requested, print the log it also when the start succeeded
2487         print_ct_stderr_log($vmid) if $is_debug;
2488
2489         print_ct_warn_log($vmid); # always print warn log, if any
2490     };
2491     if (my $err = $@) {
2492         unlink $skiplock_flag_fn;
2493         die $err;
2494     }
2495     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2496
2497     return;
2498 }
2499
2500 # Helper to stop a container completely and make sure it has stopped completely.
2501 # This is necessary because we want the post-stop hook to have completed its
2502 # unmount-all step, but post-stop happens after lxc puts the container into the
2503 # STOPPED state.
2504 # $kill - if true it will always do an immediate hard-stop
2505 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2506 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2507 sub vm_stop {
2508     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2509
2510     # Open the container's command socket.
2511     my $path = "\0/var/lib/lxc/$vmid/command";
2512     my $sock = IO::Socket::UNIX->new(
2513         Type => SOCK_STREAM(),
2514         Peer => $path,
2515     );
2516     if (!$sock) {
2517         return if $! == ECONNREFUSED; # The container is not running
2518         die "failed to open container ${vmid}'s command socket: $!\n";
2519     }
2520
2521     my $conf = PVE::LXC::Config->load_config($vmid);
2522     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2523
2524     # Stop the container:
2525
2526     my $cmd = ['lxc-stop', '-n', $vmid];
2527
2528     if ($kill) {
2529         push @$cmd, '--kill'; # doesn't allow timeouts
2530     } else {
2531         # lxc-stop uses a default timeout
2532         push @$cmd, '--nokill' if !$kill_after_timeout;
2533
2534         if (defined($shutdown_timeout)) {
2535             push @$cmd, '--timeout', $shutdown_timeout;
2536             # Give run_command 5 extra seconds
2537             $shutdown_timeout += 5;
2538         }
2539     }
2540
2541     eval { run_command($cmd, timeout => $shutdown_timeout) };
2542
2543     # Wait until the command socket is closed.
2544     # In case the lxc-stop call failed, reading from the command socket may block forever,
2545     # so poll with another timeout to avoid freezing the shutdown task.
2546     if (my $err = $@) {
2547         warn $err if $err;
2548
2549         my $poll = IO::Poll->new();
2550         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2551         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2552         return if ($poll->events($sock) & POLLHUP);
2553     } else {
2554         my $result = <$sock>;
2555         return if !defined $result; # monitor is gone and the ct has stopped.
2556     }
2557
2558     die "container did not stop\n";
2559 }
2560
2561 sub vm_reboot {
2562     my ($vmid, $timeout, $skiplock) = @_;
2563
2564     PVE::LXC::Config->lock_config($vmid, sub {
2565         return if !check_running($vmid);
2566
2567         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2568
2569         my $conf = PVE::LXC::Config->load_config($vmid);
2570         vm_start($vmid, $conf);
2571     });
2572 }
2573
2574 sub run_unshared {
2575     my ($code) = @_;
2576
2577     return PVE::Tools::run_fork(sub {
2578         # Unshare the mount namespace
2579         die "failed to unshare mount namespace: $!\n"
2580             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2581         run_command(['mount', '--make-rslave', '/']);
2582         return $code->();
2583     });
2584 }
2585
2586 my $copy_volume = sub {
2587     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2588
2589     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2590     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2591
2592     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2593     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2594
2595     my @mounted;
2596     eval {
2597         # mount and copy
2598         mkdir $src;
2599         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2600         push @mounted, $src;
2601         mkdir $dest;
2602         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2603         push @mounted, $dest;
2604
2605         $bwlimit //= 0;
2606
2607         run_command([
2608             'rsync',
2609             '--stats',
2610             '-X',
2611             '-A',
2612             '--numeric-ids',
2613             '-aH',
2614             '--whole-file',
2615             '--sparse',
2616             '--one-file-system',
2617             "--bwlimit=$bwlimit",
2618             "$src/",
2619             $dest
2620         ]);
2621     };
2622     my $err = $@;
2623
2624     # Wait for rsync's children to release dest so that
2625     # consequent file operations (umount, remove) are possible
2626     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2627
2628     foreach my $mount (reverse @mounted) {
2629         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2630         warn "Can't umount $mount\n" if $@;
2631     }
2632
2633     # If this fails they're used as mount points in a concurrent operation
2634     # (which should not happen but there's also no real need to get rid of them).
2635     rmdir $dest;
2636     rmdir $src;
2637
2638     die $err if $err;
2639 };
2640
2641 # Should not be called after unsharing the mount namespace!
2642 sub copy_volume {
2643     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2644
2645     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2646     File::Path::make_path("/var/lib/lxc/$vmid");
2647     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2648     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2649
2650     # get id's for unprivileged container
2651     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2652
2653     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2654     # are visible in this namespace, otherwise the host only sees the empty
2655     # (not-mounted) directory.
2656     my $new_volid;
2657     eval {
2658         # Make sure $mp contains a correct size.
2659         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2660         my $needs_chown;
2661         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2662         if ($needs_chown) {
2663             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2664             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2665             chown($rootuid, $rootgid, $path);
2666         }
2667
2668         run_unshared(sub {
2669             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2670         });
2671     };
2672     if (my $err = $@) {
2673         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2674             if defined($new_volid);
2675         die $err;
2676     }
2677
2678     return $new_volid;
2679 }
2680
2681 sub get_lxc_version() {
2682     my $version;
2683     run_command([qw(lxc-start --version)], outfunc => sub {
2684         my ($line) = @_;
2685         # We only parse out major & minor version numbers.
2686         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2687             $version = [$1, $2];
2688         }
2689     });
2690
2691     die "failed to get lxc version\n" if !defined($version);
2692
2693     # return as a list:
2694     return $version->@*;
2695 }
2696
2697 sub freeze($) {
2698     my ($vmid) = @_;
2699     if (PVE::CGroup::cgroup_mode() == 2) {
2700         PVE::LXC::Command::freeze($vmid, 30);
2701     } else {
2702         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2703     }
2704 }
2705
2706 sub thaw($) {
2707     my ($vmid) = @_;
2708     if (PVE::CGroup::cgroup_mode() == 2) {
2709         PVE::LXC::Command::unfreeze($vmid, 30);
2710     } else {
2711         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2712     }
2713 }
2714
2715 1;