src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw();
   7 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED EEXIST);
   8 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
   9 use File::Path;
  10 use File::Spec;
  11 use IO::Poll qw(POLLIN POLLHUP);
  12 use IO::Socket::UNIX;
  13 use POSIX qw(EINTR);
  14 use Socket;
  15 use Time::HiRes qw (gettimeofday);
  16
  17 use PVE::AccessControl;
  18 use PVE::CGroup;
  19 use PVE::CpuSet;
  20 use PVE::Exception qw(raise_perm_exc);
  21 use PVE::GuestHelpers qw(check_vnet_access safe_string_ne safe_num_ne safe_boolean_ne);
  22 use PVE::INotify;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use PVE::Network;
  25 use PVE::ProcFSTools;
  26 use PVE::RESTEnvironment;
  27 use PVE::SafeSyslog;
  28 use PVE::Storage;
  29 use PVE::Tools qw(
  30     run_command
  31     dir_glob_foreach
  32     file_get_contents
  33     file_set_contents
  34     AT_FDCWD
  35     O_PATH
  36     $IPV4RE
  37     $IPV6RE
  38 );
  39 use PVE::Syscall qw(:fsmount);
  40
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Config;
  43 use PVE::LXC::Monitor;
  44 use PVE::LXC::Tools;
  45
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         # cgroup memory usage is limited by the hard 'max' limit (OOM-killer enforced) and the soft
 689         # 'high' limit (cgroup processes get throttled and put under heavy reclaim pressure).
 690         my ($lxc_mem_max, $lxc_mem_high) = PVE::LXC::Config::calculate_memory_constraints($memory);
 691         $raw .= "lxc.cgroup2.memory.max = $lxc_mem_max\n";
 692         $raw .= "lxc.cgroup2.memory.high = $lxc_mem_high\n";
 693
 694         my $lxcswap = int($swap*1024*1024);
 695         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 696     }
 697
 698     if ($cgv1->{cpu}) {
 699         if (my $cpulimit = $conf->{cpulimit}) {
 700             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 701             my $value = int(100000*$cpulimit);
 702             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 703         }
 704
 705         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 706         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 707     } elsif ($cgv2->{cpu}) {
 708         # See PVE::CGroup
 709         if (my $cpulimit = $conf->{cpulimit}) {
 710             my $value = int(100000*$cpulimit);
 711             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 712         }
 713
 714         if (defined(my $shares = $conf->{cpuunits})) {
 715             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 716             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 717         }
 718     }
 719
 720     die "missing 'rootfs' configuration\n"
 721         if !defined($conf->{rootfs});
 722
 723     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 724
 725     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 726
 727     foreach my $k (sort keys %$conf) {
 728         next if $k !~ m/^net(\d+)$/;
 729         my $ind = $1;
 730         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 731         $raw .= "lxc.net.$ind.type = veth\n";
 732         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 733         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 734         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 735
 736         my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 737         my $mtu = $d->{mtu} || $bridge_mtu;
 738
 739         # Keep container from starting with invalid mtu configuration
 740         die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 741             if ($mtu > $bridge_mtu);
 742
 743         $raw .= "lxc.net.$ind.mtu = $mtu\n";
 744
 745         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 746         if ($lxc_major >= 4) {
 747             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 748         }
 749     }
 750
 751     my $had_cpuset = 0;
 752     if (my $lxcconf = $conf->{lxc}) {
 753         foreach my $entry (@$lxcconf) {
 754             my ($k, $v) = @$entry;
 755             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 756             $raw .= "$k = $v\n";
 757         }
 758     }
 759
 760     my $cpuset;
 761     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 762     if (defined($cpuset_cgroup)) {
 763         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 764             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 765     }
 766     my $cores = $conf->{cores};
 767     if (!$had_cpuset && $cores && $cpuset) {
 768         my @members = $cpuset->members();
 769         while (scalar(@members) > $cores) {
 770             my $randidx = int(rand(scalar(@members)));
 771             $cpuset->delete($members[$randidx]);
 772             splice(@members, $randidx, 1); # keep track of the changes
 773         }
 774         my $ver = $cpuset_version == 1 ? '' : '2';
 775         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 776     }
 777
 778     File::Path::mkpath("$dir/rootfs");
 779
 780     PVE::Tools::file_set_contents("$dir/config", $raw);
 781 }
 782
 783 # verify and cleanup nameserver list (replace \0 with ' ')
 784 sub verify_nameserver_list {
 785     my ($nameserver_list) = @_;
 786
 787     my @list = ();
 788     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 789         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 790         push @list, $server;
 791     }
 792
 793     return join(' ', @list);
 794 }
 795
 796 sub verify_searchdomain_list {
 797     my ($searchdomain_list) = @_;
 798
 799     my @list = ();
 800     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 801         # todo: should we add checks for valid dns domains?
 802         push @list, $server;
 803     }
 804
 805     return join(' ', @list);
 806 }
 807
 808 sub get_console_command {
 809     my ($vmid, $conf, $escapechar) = @_;
 810
 811     # '-1' as $escapechar disables keyboard escape sequence
 812     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 813
 814     my $cmode = PVE::LXC::Config->get_cmode($conf);
 815
 816     my $cmd = [];
 817     if ($cmode eq 'console') {
 818         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 819         push @$cmd, '-e', $escapechar if $escapechar;
 820     } elsif ($cmode eq 'tty') {
 821         push @$cmd, 'lxc-console', '-n',  $vmid;
 822         push @$cmd, '-e', $escapechar if $escapechar;
 823     } elsif ($cmode eq 'shell') {
 824         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 825     } else {
 826         die "internal error";
 827     }
 828
 829     return $cmd;
 830 }
 831
 832 sub get_primary_ips {
 833     my ($conf) = @_;
 834
 835     # return data from net0
 836
 837     return undef if !defined($conf->{net0});
 838     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 839
 840     my $ipv4 = $net->{ip};
 841     if ($ipv4) {
 842         if ($ipv4 =~ /^(dhcp|manual)$/) {
 843             $ipv4 = undef
 844         } else {
 845             $ipv4 =~ s!/\d+$!!;
 846         }
 847     }
 848     my $ipv6 = $net->{ip6};
 849     if ($ipv6) {
 850         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 851             $ipv6 = undef;
 852         } else {
 853             $ipv6 =~ s!/\d+$!!;
 854         }
 855     }
 856
 857     return ($ipv4, $ipv6);
 858 }
 859
 860 sub delete_mountpoint_volume {
 861     my ($storage_cfg, $vmid, $volume) = @_;
 862
 863     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 864
 865     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 866
 867     if ($vmid == $owner) {
 868         PVE::Storage::vdisk_free($storage_cfg, $volume);
 869     } else {
 870         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 871     }
 872 }
 873
 874 sub destroy_lxc_container {
 875     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 876
 877     my $volids = {};
 878     my $remove_volume = sub {
 879         my ($ms, $mountpoint) = @_;
 880
 881         my $volume = $mountpoint->{volume};
 882
 883         return if $volids->{$volume};
 884         $volids->{$volume} = 1;
 885
 886         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 887     };
 888     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 889
 890     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 891
 892     if ($purge_unreferenced) { # also remove unreferenced disk
 893         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 894         PVE::Storage::foreach_volid($vmdisks, sub {
 895             my ($volid, $sid, $volname, $d) = @_;
 896             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 897             warn $@ if $@;
 898         });
 899     }
 900
 901     rmdir "/var/lib/lxc/$vmid/rootfs";
 902     unlink "/var/lib/lxc/$vmid/config";
 903     rmdir "/var/lib/lxc/$vmid";
 904     if (defined $replacement_conf) {
 905         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 906     } else {
 907         PVE::LXC::Config->destroy_config($vmid);
 908     }
 909 }
 910
 911 sub vm_stop_cleanup {
 912     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 913
 914     return if $keepActive;
 915
 916     eval {
 917         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 918         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 919     };
 920     warn $@ if $@; # avoid errors - just warn
 921 }
 922
 923 sub net_tap_plug : prototype($$) {
 924     my ($iface, $net) = @_;
 925
 926     if (defined($net->{link_down})) {
 927         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 928         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 929         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 930         return;
 931     }
 932
 933     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 934         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 935
 936     if ($have_sdn) {
 937         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 938         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge);
 939     } else {
 940         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 941     }
 942
 943     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 944 }
 945
 946 sub update_net {
 947     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 948
 949     if ($newnet->{type} ne 'veth') {
 950         # for when there are physical interfaces
 951         die "cannot update interface of type $newnet->{type}";
 952     }
 953
 954     my $veth = "veth${vmid}i${netid}";
 955     my $eth = $newnet->{name};
 956
 957     if (my $oldnetcfg = $conf->{$opt}) {
 958         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 959
 960         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 961             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 962
 963             PVE::Network::veth_delete($veth);
 964
 965             if ($have_sdn) {
 966                 eval { PVE::Network::SDN::Vnets::del_ips_from_mac($oldnet->{bridge}, $oldnet->{hwaddr}, $conf->{hostname}) };
 967                 warn $@ if $@;
 968             }
 969
 970             delete $conf->{$opt};
 971             PVE::LXC::Config->write_config($vmid, $conf);
 972
 973             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 974
 975         } else {
 976             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 977                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 978                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 979                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 980             ) {
 981
 982                 if ($oldnet->{bridge}) {
 983
 984                     PVE::Network::tap_unplug($veth);
 985                     foreach (qw(bridge tag firewall)) {
 986                         delete $oldnet->{$_};
 987                     }
 988                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 989                     PVE::LXC::Config->write_config($vmid, $conf);
 990
 991                     if ($have_sdn) {
 992                         eval { PVE::Network::SDN::Vnets::del_ips_from_mac($oldnet->{bridge}, $oldnet->{hwaddr}, $conf->{hostname}) };
 993                         warn $@ if $@;
 994                     }
 995                 }
 996
 997                 if ($have_sdn) {
 998                     PVE::Network::SDN::Vnets::add_next_free_cidr($newnet->{bridge}, $conf->{hostname}, $newnet->{hwaddr}, $vmid, undef, 1);
 999                 }
1000                 PVE::LXC::net_tap_plug($veth, $newnet);
1001
1002                 # This includes the rate:
1003                 foreach (qw(bridge tag firewall rate link_down)) {
1004                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
1005                 }
1006             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
1007                 # Rate can be applied on its own but any change above needs to
1008                 # include the rate in tap_plug since OVS resets everything.
1009                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
1010                 $oldnet->{rate} = $newnet->{rate}
1011             }
1012             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
1013             PVE::LXC::Config->write_config($vmid, $conf);
1014         }
1015     } else {
1016         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1017     }
1018
1019     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1020 }
1021
1022 sub hotplug_net {
1023     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1024
1025     my $veth = "veth${vmid}i${netid}";
1026     my $vethpeer = $veth . "p";
1027     my $eth = $newnet->{name};
1028
1029     if ($have_sdn) {
1030         PVE::Network::SDN::Vnets::add_next_free_cidr($newnet->{bridge}, $conf->{hostname}, $newnet->{hwaddr}, $vmid, undef, 1);
1031         PVE::Network::SDN::Vnets::add_dhcp_mapping($newnet->{bridge}, $newnet->{hwaddr});
1032         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1033     } else {
1034         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1035     }
1036
1037     PVE::LXC::net_tap_plug($veth, $newnet);
1038
1039     # attach peer in container
1040     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1041     PVE::Tools::run_command($cmd);
1042
1043     # link up peer in container
1044     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1045     PVE::Tools::run_command($cmd);
1046
1047     my $done = { type => 'veth' };
1048     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1049         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1050     }
1051     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1052
1053     PVE::LXC::Config->write_config($vmid, $conf);
1054 }
1055
1056 sub get_interfaces {
1057     my ($vmid) = @_;
1058
1059     my $pid = eval { find_lxc_pid($vmid); };
1060     return if $@;
1061
1062     my $output;
1063     # enters the network namespace of the container and executes 'ip a'
1064     run_command(['nsenter', '-t', $pid, '--net', '--', 'ip', '--json', 'a'],
1065         outfunc => sub { $output .= shift; });
1066
1067     my $config = JSON::decode_json($output);
1068
1069     my $res;
1070     for my $interface ($config->@*) {
1071         my $obj = { name => $interface->{ifname} };
1072         for my $ip ($interface->{addr_info}->@*) {
1073             $obj->{$ip->{family}} = $ip->{local} . "/" . $ip->{prefixlen};
1074         }
1075         $obj->{hwaddr} = $interface->{address};
1076         push @$res, $obj
1077     }
1078
1079     return $res;
1080 }
1081
1082 sub update_ipconfig {
1083     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1084
1085     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1086
1087     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1088     my $deleted = [];
1089     my $added = [];
1090     my $nscmd = sub {
1091         my $cmdargs = shift;
1092         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1093     };
1094     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1095
1096     my $change_ip_config = sub {
1097         my ($ipversion) = @_;
1098
1099         my $family_opt = "-$ipversion";
1100         my $suffix = $ipversion == 4 ? '' : $ipversion;
1101         my $gw= "gw$suffix";
1102         my $ip= "ip$suffix";
1103
1104         my $newip = $newnet->{$ip};
1105         my $newgw = $newnet->{$gw};
1106         my $oldip = $optdata->{$ip};
1107         my $oldgw = $optdata->{$gw};
1108
1109         my $change_ip = safe_string_ne($oldip, $newip);
1110         my $change_gw = safe_string_ne($oldgw, $newgw);
1111
1112         return if !$change_ip && !$change_gw;
1113
1114         # step 1: add new IP, if this fails we cancel
1115         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1116         if ($change_ip && $is_real_ip) {
1117             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1118             if (my $err = $@) {
1119                 warn $err;
1120                 return;
1121             }
1122         }
1123
1124         # step 2: replace gateway
1125         #   If this fails we delete the added IP and cancel.
1126         #   If it succeeds we save the config and delete the old IP, ignoring
1127         #   errors. The config is then saved.
1128         # Note: 'ip route replace' can add
1129         if ($change_gw) {
1130             if ($newgw) {
1131                 eval {
1132                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1133                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1134                     }
1135                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1136                 };
1137                 if (my $err = $@) {
1138                     warn $err;
1139                     # the route was not replaced, the old IP is still available
1140                     # rollback (delete new IP) and cancel
1141                     if ($change_ip) {
1142                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1143                         warn $@ if $@; # no need to die here
1144                     }
1145                     return;
1146                 }
1147             } else {
1148                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1149                 # if the route was not deleted, the guest might have deleted it manually
1150                 # warn and continue
1151                 warn $@ if $@;
1152             }
1153             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1154                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1155                 # warn if the route was deleted manually
1156                 warn $@ if $@;
1157             }
1158         }
1159
1160         # from this point on we save the configuration
1161         # step 3: delete old IP ignoring errors
1162         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1163             # We need to enable promote_secondaries, otherwise our newly added
1164             # address will be removed along with the old one.
1165             my $promote = 0;
1166             eval {
1167                 if ($ipversion == 4) {
1168                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1169                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1170                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1171                 }
1172                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1173             };
1174             warn $@ if $@; # no need to die here
1175
1176             if ($ipversion == 4) {
1177                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1178             }
1179         }
1180
1181         foreach my $property ($ip, $gw) {
1182             if ($newnet->{$property}) {
1183                 $optdata->{$property} = $newnet->{$property};
1184             } else {
1185                 delete $optdata->{$property};
1186             }
1187         }
1188         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1189         PVE::LXC::Config->write_config($vmid, $conf);
1190         $lxc_setup->setup_network($conf);
1191     };
1192
1193     &$change_ip_config(4);
1194     &$change_ip_config(6);
1195
1196 }
1197
1198 my $open_namespace = sub {
1199     my ($vmid, $pid, $kind) = @_;
1200     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1201         or die "failed to open $kind namespace of container $vmid: $!\n";
1202     return $fd;
1203 };
1204
1205 my $enter_namespace = sub {
1206     my ($vmid, $pid, $kind, $type) = @_;
1207     my $fd = $open_namespace->($vmid, $pid, $kind);
1208     PVE::Tools::setns(fileno($fd), $type)
1209         or die "failed to enter $kind namespace of container $vmid: $!\n";
1210     close $fd;
1211 };
1212
1213 my $get_container_namespace = sub {
1214     my ($vmid, $pid, $kind) = @_;
1215
1216     my $pidfd;
1217     if (!defined($pid)) {
1218         # Pin the pid while we're grabbing its stuff from /proc
1219         ($pid, $pidfd) = open_lxc_pid($vmid)
1220             or die "failed to open pidfd of container $vmid\'s init process\n";
1221     }
1222
1223     return $open_namespace->($vmid, $pid, $kind);
1224 };
1225
1226 my $do_syncfs = sub {
1227     my ($vmid, $pid, $socket) = @_;
1228
1229     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1230
1231     # Tell the parent process to start reading our /proc/mounts
1232     print {$socket} "go\n";
1233     $socket->flush();
1234
1235     # Receive /proc/self/mounts
1236     my $mountdata = do { local $/ = undef; <$socket> };
1237     close $socket;
1238
1239     my %nosyncfs = (
1240         cgroup => 1,
1241         cgroup2 => 1,
1242         devtmpfs => 1,
1243         devpts => 1,
1244         'fuse.lxcfs' => 1,
1245         fusectl => 1,
1246         mqueue => 1,
1247         proc => 1,
1248         sysfs => 1,
1249         tmpfs => 1,
1250     );
1251
1252     # Now sync all mountpoints...
1253     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1254     foreach my $mp (@$mounts) {
1255         my ($what, $dir, $fs) = @$mp;
1256         next if $nosyncfs{$fs};
1257         eval { PVE::Tools::sync_mountpoint($dir); };
1258         warn $@ if $@;
1259     }
1260 };
1261
1262 sub sync_container_namespace {
1263     my ($vmid) = @_;
1264     my $pid = find_lxc_pid($vmid);
1265
1266     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1267     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1268         or die "failed to create socketpair: $!\n";
1269
1270     my $child = fork();
1271     die "fork failed: $!\n" if !defined($child);
1272
1273     if (!$child) {
1274         eval {
1275             close $pfd;
1276             &$do_syncfs($vmid, $pid, $cfd);
1277         };
1278         if (my $err = $@) {
1279             warn $err;
1280             POSIX::_exit(1);
1281         }
1282         POSIX::_exit(0);
1283     }
1284     close $cfd;
1285     my $go = <$pfd>;
1286     die "failed to enter container namespace\n" if $go ne "go\n";
1287
1288     open my $mounts, '<', "/proc/$child/mounts"
1289         or die "failed to open container's /proc/mounts: $!\n";
1290     my $mountdata = do { local $/ = undef; <$mounts> };
1291     close $mounts;
1292     print {$pfd} $mountdata;
1293     close $pfd;
1294
1295     while (waitpid($child, 0) != $child) {}
1296     die "failed to sync container namespace\n" if $? != 0;
1297 }
1298
1299 sub template_create {
1300     my ($vmid, $conf) = @_;
1301
1302     my $storecfg = PVE::Storage::config();
1303
1304     PVE::LXC::Config->foreach_volume($conf, sub {
1305         my ($ms, $mountpoint) = @_;
1306
1307         my $volid = $mountpoint->{volume};
1308
1309         die "Template feature is not available for '$volid'\n"
1310             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1311     });
1312
1313     PVE::LXC::Config->foreach_volume($conf, sub {
1314         my ($ms, $mountpoint) = @_;
1315
1316         my $volid = $mountpoint->{volume};
1317
1318         PVE::Storage::activate_volumes($storecfg, [$volid]);
1319
1320         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1321         $mountpoint->{volume} = $template_volid;
1322         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1323     });
1324
1325     PVE::LXC::Config->write_config($vmid, $conf);
1326 }
1327
1328 sub check_ct_modify_config_perm {
1329     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1330
1331     return 1 if $authuser eq 'root@pam';
1332     my $storage_cfg = PVE::Storage::config();
1333
1334     my $check = sub {
1335         my ($opt, $delete) = @_;
1336         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1337             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1338         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1339             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1340             return if $delete;
1341             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1342             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1343                 if $data->{type} ne 'volume';
1344             my $volid = $data->{volume};
1345             if ($volid =~ $NEW_DISK_RE) {
1346                 my $sid = $1;
1347                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1348             } else {
1349                 PVE::Storage::check_volume_access(
1350                     $rpcenv,
1351                     $authuser,
1352                     $storage_cfg,
1353                     $vmid,
1354                     $volid,
1355                     'rootdir',
1356                 );
1357             }
1358         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1359             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1360         } elsif ($opt =~ m/^net\d+$/) {
1361             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1362             check_bridge_access($rpcenv, $authuser, $oldconf->{$opt}) if $oldconf->{$opt};
1363             check_bridge_access($rpcenv, $authuser, $newconf->{$opt}) if $newconf->{$opt};
1364         } elsif ($opt eq 'nameserver' || $opt eq 'searchdomain' || $opt eq 'hostname') {
1365             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1366         } elsif ($opt eq 'features') {
1367             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1368                 if !$unprivileged;
1369
1370             my $nesting_changed = 0;
1371             my $other_changed = 0;
1372             if (!$delete) {
1373                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1374                 if (defined($oldconf) && $oldconf->{$opt}) {
1375                     # existing container with features
1376                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1377                     for my $feature ((keys %$old_features, keys %$features)) {
1378                         my $old = $old_features->{$feature} // '';
1379                         my $new = $features->{$feature} // '';
1380                         if ($old ne $new) {
1381                             if ($feature eq 'nesting') {
1382                                 $nesting_changed = 1;
1383                                 next;
1384                             } else {
1385                                 $other_changed = 1;
1386                                 last;
1387                             }
1388                         }
1389                     }
1390                 } else {
1391                     # new container or no features defined
1392                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1393                         $nesting_changed = 1;
1394                     } elsif (scalar(keys %$features) > 0) {
1395                         $other_changed = 1;
1396                     }
1397                 }
1398             } else {
1399                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1400                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1401                     $nesting_changed = 1;
1402                 } elsif (scalar(keys %$features) > 0) {
1403                     $other_changed = 1;
1404                 }
1405             }
1406             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1407                 if $other_changed;
1408             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1409                 if $nesting_changed;
1410         } elsif ($opt eq 'hookscript') {
1411             # For now this is restricted to root@pam
1412             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1413         } elsif ($opt eq 'tags') {
1414             my $old = $oldconf->{$opt};
1415             my $new = $delete ? '' : $newconf->{$opt};
1416             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1417         } else {
1418             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1419         }
1420     };
1421
1422     foreach my $opt (keys %$newconf) {
1423         &$check($opt, 0);
1424     }
1425     foreach my $opt (@$delete) {
1426         &$check($opt, 1);
1427     }
1428
1429     return 1;
1430 }
1431
1432 sub check_bridge_access {
1433     my ($rpcenv, $authuser, $raw) = @_;
1434
1435     return 1 if $authuser eq 'root@pam';
1436
1437     my $net = PVE::LXC::Config->parse_lxc_network($raw);
1438     my ($bridge, $tag, $trunks) = $net->@{'bridge', 'tag', 'trunks'};
1439     check_vnet_access($rpcenv, $authuser, $bridge, $tag, $trunks);
1440
1441     return 1;
1442 };
1443
1444 sub umount_all {
1445     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1446
1447     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1448     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1449
1450     my $res = 1;
1451
1452     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1453         my ($ms, $mountpoint) = @_;
1454
1455         my $volid = $mountpoint->{volume};
1456         my $mount = $mountpoint->{mp};
1457
1458         return if !$volid || !$mount;
1459
1460         my $mount_path = "$rootdir/$mount";
1461         $mount_path =~ s!/+!/!g;
1462
1463         return if !PVE::ProcFSTools::is_mounted($mount_path);
1464
1465         eval {
1466             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1467         };
1468         if (my $err = $@) {
1469             if ($noerr) {
1470                 $res = 0;
1471                 warn $err;
1472             } else {
1473                 die $err;
1474             }
1475         }
1476     });
1477
1478     return $res; # tell caller if (some) umounts failed for the noerr case
1479 }
1480
1481 sub mount_all {
1482     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1483
1484     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1485     File::Path::make_path($rootdir);
1486
1487     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1488     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1489
1490     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1491
1492     eval {
1493         PVE::LXC::Config->foreach_volume($conf, sub {
1494             my ($ms, $mountpoint) = @_;
1495
1496             $mountpoint->{ro} = 0 if $ignore_ro;
1497
1498             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1499         });
1500     };
1501     if (my $err = $@) {
1502         warn "mounting container failed\n";
1503         umount_all($vmid, $storage_cfg, $conf, 1);
1504         die $err;
1505     }
1506
1507     return $rootdir;
1508 }
1509
1510
1511 sub mountpoint_mount_path {
1512     my ($mountpoint, $storage_cfg, $snapname) = @_;
1513
1514     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1515 }
1516
1517 sub query_loopdev {
1518     my ($path) = @_;
1519     my $found;
1520     my $parser = sub {
1521         my $line = shift;
1522         if ($line =~ m@^(/dev/loop\d+):@) {
1523             $found = $1;
1524         }
1525     };
1526     my $cmd = ['losetup', '--associated', $path];
1527     PVE::Tools::run_command($cmd, outfunc => $parser);
1528     return $found;
1529 }
1530
1531 # Run a function with a file attached to a loop device.
1532 # The loop device is always detached afterwards (or set to autoclear).
1533 # Returns the loop device.
1534 sub run_with_loopdev {
1535     my ($func, $file, $readonly) = @_;
1536     my $device = query_loopdev($file);
1537     # Try to reuse an existing device
1538     if ($device) {
1539         # We assume that whoever setup the loop device is responsible for
1540         # detaching it.
1541         &$func($device);
1542         return $device;
1543     }
1544
1545     my $parser = sub {
1546         my $line = shift;
1547         if ($line =~ m@^(/dev/loop\d+)$@) {
1548             $device = $1;
1549         }
1550     };
1551     my $losetup_cmd = [
1552         'losetup',
1553         '--show',
1554         '-f',
1555         $file,
1556     ];
1557     push @$losetup_cmd, '-r' if $readonly;
1558     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1559     die "failed to setup loop device for $file\n" if !$device;
1560     eval { &$func($device); };
1561     my $err = $@;
1562     PVE::Tools::run_command(['losetup', '-d', $device]);
1563     die $err if $err;
1564     return $device;
1565 }
1566
1567 # In scalar mode: returns a file handle to the deepest directory node.
1568 # In list context: returns a list of:
1569 #   * the deepest directory node
1570 #   * the 2nd deepest directory (parent of the above)
1571 #   * directory name of the last directory
1572 # So that the path $2/$3 should lead to $1 afterwards.
1573 sub walk_tree_nofollow($$$;$$) {
1574     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1575
1576     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1577         or die "failed to open start directory $start: $!\n";
1578
1579     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1580 }
1581
1582
1583 sub walk_tree_nofollow_fd($$$$;$$) {
1584     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1585
1586     # splitdir() returns '' for empty components including the leading /
1587     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1588
1589     my $fd = $start_fd;
1590     my $dir = $start_dirname;
1591     my $last_component = undef;
1592     my $second = $fd;
1593     foreach my $component (@comps) {
1594         $dir .= "/$component";
1595         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1596
1597         if (!$next) {
1598             # failed, check for symlinks and try to create the path
1599             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1600             die "cannot open directory $dir: $!\n" if !$mkdir;
1601
1602             # We don't check for errors on mkdirat() here and just try to
1603             # openat() again, since at least one error (EEXIST) is an
1604             # expected possibility if multiple containers start
1605             # simultaneously. If someone else injects a symlink now then
1606             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1607             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1608
1609             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1610             die "failed to create path: $dir: $!\n" if !$next;
1611
1612             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1613                 if defined($rootuid) && defined($rootgid);
1614         }
1615
1616         close $second if defined($last_component) && $second != $start_fd;
1617         $last_component = $component;
1618         $second = $fd;
1619         $fd = $next;
1620     }
1621
1622     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1623     close $second if defined($last_component) && $second != $start_fd;
1624     return $fd;
1625 }
1626
1627 # To guard against symlink attack races against other currently running
1628 # containers with shared recursive bind mount hierarchies we prepare a
1629 # directory handle for the directory we're mounting over to verify the
1630 # mountpoint afterwards.
1631 sub __bindmount_prepare {
1632     my ($hostroot, $dir) = @_;
1633     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1634     return $srcdh;
1635 }
1636
1637 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1638 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1639 # we intended to bind mount.
1640 sub __bindmount_verify {
1641     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1642     my $destdh;
1643     if ($parentfd) {
1644         # Open the mount point path coming from the parent directory since the
1645         # filehandle we would have gotten as first result of walk_tree_nofollow
1646         # earlier is still a handle to the underlying directory instead of the
1647         # mounted path.
1648         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1649         die "failed to open mount point: $!\n" if !$destdh;
1650         if ($ro) {
1651             my $dot = '.';
1652             # no separate function because 99% of the time it's the wrong thing to use.
1653             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1654                 die "failed to mark bind mount read only\n";
1655             }
1656             die "read-only check failed: $!\n" if $! != EROFS;
1657         }
1658     } else {
1659         # For the rootfs we don't have a parentfd so we open the path directly.
1660         # Note that this means bindmounting any prefix of the host's
1661         # /var/lib/lxc/$vmid path into another container is considered a grave
1662         # security error.
1663         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1664         die "failed to open mount point: $!\n" if !$destdh;
1665     }
1666
1667     my ($srcdev, $srcinode) = stat($srcdh);
1668     my ($dstdev, $dstinode) = stat($destdh);
1669     close $srcdh;
1670     close $destdh;
1671
1672     return ($srcdev == $dstdev && $srcinode == $dstinode);
1673 }
1674
1675 # Perform the actual bind mounting:
1676 sub __bindmount_do {
1677     my ($dir, $dest, $ro, @extra_opts) = @_;
1678     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1679     if ($ro) {
1680         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1681         if (my $err = $@) {
1682             warn "bindmount error\n";
1683             # don't leave writable bind-mounts behind...
1684             PVE::Tools::run_command(['umount', $dest]);
1685             die $err;
1686         }
1687     }
1688 }
1689
1690 sub bindmount {
1691     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1692
1693     my $srcdh = __bindmount_prepare('/', $dir);
1694
1695     __bindmount_do($dir, $dest, $ro, @extra_opts);
1696
1697     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1698         PVE::Tools::run_command(['umount', $dest]);
1699         die "detected mount path change at: $dir\n";
1700     }
1701 }
1702
1703 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1704 # from $rootdir and $mount and walk the path from $rootdir to the final
1705 # directory to check for symlinks.
1706 sub __mount_prepare_rootdir {
1707     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1708     $rootdir =~ s!/+!/!g;
1709     $rootdir =~ s!/+$!!;
1710     my $mount_path = "$rootdir/$mount";
1711     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1712     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1713 }
1714
1715 # use $rootdir = undef to just return the corresponding mount path
1716 sub mountpoint_mount {
1717     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1718     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1719 }
1720
1721 sub mountpoint_stage {
1722     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1723     my ($path, $loop, $dev) =
1724         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1725
1726     if (!defined($path)) {
1727         die "failed to mount subvolume: $!\n";
1728     }
1729
1730     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1731     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1732     # point).
1733     my $err;
1734     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1735         or die "open_tree() on mount point failed: $!\n";
1736
1737     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1738 }
1739
1740 sub mountpoint_insert_staged {
1741     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1742
1743     if (!defined($rootdir_fd)) {
1744         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1745             or die "failed to open '.': $!\n";
1746     }
1747
1748     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1749
1750     PVE::Tools::move_mount(
1751         fileno($mount_fd),
1752         '',
1753         fileno($dest_fd),
1754         '',
1755         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1756     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1757 }
1758
1759 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1760 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1761 sub __mountpoint_mount {
1762     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1763
1764     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1765     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1766     # which we use in __bindmount_verify()!
1767     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1768
1769     my $volid = $mountpoint->{volume};
1770     my $type = $mountpoint->{type};
1771     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1772     my $mounted_dev;
1773
1774     return if !$volid || !$mount;
1775
1776     $mount =~ s!/+!/!g;
1777
1778     my $mount_path;
1779     my ($mpfd, $parentfd, $last_dir);
1780
1781     if (defined($rootdir)) {
1782         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1783             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1784     }
1785
1786     if (defined($stage_mount)) {
1787         $mount_path = $rootdir;
1788     }
1789
1790     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1791
1792     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1793
1794     my $optlist = [];
1795
1796     if (my $mountopts = $mountpoint->{mountoptions}) {
1797         my @opts = split(/;/, $mountpoint->{mountoptions});
1798         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1799     }
1800
1801     my $acl = $mountpoint->{acl};
1802     if (defined($acl)) {
1803         push @$optlist, ($acl ? 'acl' : 'noacl');
1804     }
1805
1806     my $optstring = join(',', @$optlist);
1807     my $readonly = $mountpoint->{ro};
1808
1809     my @extra_opts;
1810     @extra_opts = ('-o', $optstring) if $optstring;
1811
1812     if ($storage) {
1813
1814         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1815
1816         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1817
1818         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1819
1820         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1821             PVE::Storage::parse_volname($storage_cfg, $volid);
1822
1823         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1824
1825         if ($format eq 'subvol') {
1826             if ($mount_path) {
1827                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1828                 if (defined($snapname)) {
1829                     $name .= "\@$snapname";
1830                     if ($scfg->{type} eq 'zfspool') {
1831                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1832                     } else {
1833                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1834                     }
1835                 } else {
1836                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1837                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1838                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1839                     }
1840                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1841                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1842                 }
1843             }
1844             return wantarray ? ($path, 0, undef) : $path;
1845         } elsif ($format eq 'raw' || $format eq 'iso') {
1846             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1847             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1848             # Our autodev hook expects the /dev/dm-* device currently
1849             # and will create the /dev/mapper symlink accordingly
1850             $path = Cwd::realpath($path);
1851             die "failed to get device path\n" if !$path;
1852             ($path) = ($path =~ /^(.*)$/s); #untaint
1853             my $domount = sub {
1854                 my ($path) = @_;
1855                 if ($mount_path) {
1856                     if ($format eq 'iso') {
1857                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1858                     } elsif ($isBase || defined($snapname)) {
1859                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1860                     } else {
1861                         if ($quota) {
1862                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1863                         }
1864                         push @extra_opts, '-o', 'ro' if $readonly;
1865                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1866                     }
1867                 }
1868             };
1869             my $use_loopdev = 0;
1870             if ($scfg->{content}->{rootdir}) {
1871                 if ($scfg->{path}) {
1872                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1873                     $use_loopdev = 1;
1874                 } else {
1875                     $mounted_dev = $path;
1876                     &$domount($path);
1877                 }
1878             } else {
1879                 die "storage '$storage' does not support containers\n";
1880             }
1881             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1882         } else {
1883             die "unsupported image format '$format'\n";
1884         }
1885     } elsif ($type eq 'device') {
1886         push @extra_opts, '-o', 'ro' if $readonly;
1887         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1888         # See the NOTE above about devicemapper canonicalization
1889         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1890         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1891         return wantarray ? ($volid, 0, $devpath) : $volid;
1892     } elsif ($type eq 'bind') {
1893         die "directory '$volid' does not exist\n" if ! -d $volid;
1894         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1895         warn "cannot enable quota control for bind mounts\n" if $quota;
1896         return wantarray ? ($volid, 0, undef) : $volid;
1897     }
1898
1899     die "unsupported storage";
1900 }
1901
1902 sub mountpoint_hotplug :prototype($$$$$) {
1903     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1904
1905     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1906
1907     # We do the rest in a fork with an unshared mount namespace, because:
1908     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1909     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1910     #     container's namespace, then mount it.
1911
1912     PVE::Tools::run_fork(sub {
1913         # Pin the container pid longer, we also need to get its monitor/parent:
1914         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1915             or die "failed to open pidfd of container $vmid\'s init process\n";
1916
1917         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1918             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1919
1920         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1921         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1922
1923         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1924         # profile to lower our privileges to the same level we have in the start hook:
1925         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1926             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1927         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1928         # apparmor.
1929
1930         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1931         # namespace for it to remain active there since the container will be able to unmount
1932         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1933         # concern.
1934         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1935         chdir('/')
1936             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1937
1938         my $dir = get_staging_mount_path($opt);
1939
1940         # Now switch our apparmor profile before mounting:
1941         my $data = 'changeprofile /usr/bin/lxc-start';
1942         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1943             die "failed to change apparmor profile: $!\n";
1944         }
1945         # Check errors on close as well:
1946         close($aa_fd)
1947             or die "failed to change apparmor profile (close() failed): $!\n";
1948
1949         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1950
1951         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1952         chdir('/')
1953             or die "failed to change root directory within the container's mount namespace: $!\n";
1954
1955         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1956     });
1957 }
1958
1959 # Create a directory in the mountpoint staging tempfs.
1960 sub get_staging_mount_path($) {
1961     my ($opt) = @_;
1962
1963     my $target = get_staging_tempfs() . "/$opt";
1964     if (!mkdir($target) && $! != EEXIST) {
1965         die "failed to create directory $target: $!\n";
1966     }
1967
1968     return $target;
1969 }
1970
1971 # Mount tmpfs for mount point staging and return the path.
1972 sub get_staging_tempfs() {
1973     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1974     # mounts to that.
1975     my $target = '/var/lib/lxc/.pve-staged-mounts';
1976     if (!mkdir($target)) {
1977         return $target if $! == EEXIST;
1978         die "failed to create directory $target: $!\n";
1979     }
1980
1981     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1982         or die "failed to mount $target as tmpfs: $!\n";
1983
1984     return $target;
1985 }
1986
1987 sub mkfs {
1988     my ($dev, $rootuid, $rootgid) = @_;
1989
1990     run_command(
1991         [
1992             'mkfs.ext4',
1993             '-O',
1994             'mmp',
1995             '-E',
1996             "root_owner=$rootuid:$rootgid",
1997             $dev,
1998         ],
1999         outfunc => sub {
2000             my $line = shift;
2001             # a hack to print only the relevant stuff, i.e., the one which could help on repair
2002             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
2003                 print "$line\n";
2004             }
2005         },
2006         errfunc => sub {
2007             my $line = shift;
2008             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
2009         }
2010     );
2011 }
2012
2013 sub format_disk {
2014     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
2015
2016     if ($volid =~ m!^/dev/.+!) {
2017         mkfs($volid);
2018         return;
2019     }
2020
2021     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2022
2023     die "cannot format volume '$volid' with no storage\n" if !$storage;
2024
2025     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
2026
2027     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
2028
2029     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
2030
2031     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
2032         PVE::Storage::parse_volname($storage_cfg, $volid);
2033
2034     die "cannot format volume '$volid' (format == $format)\n"
2035         if $format ne 'raw';
2036
2037     mkfs($path, $rootuid, $rootgid);
2038 }
2039
2040 sub destroy_disks {
2041     my ($storecfg, $vollist) = @_;
2042
2043     foreach my $volid (@$vollist) {
2044         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2045         warn $@ if $@;
2046     }
2047 }
2048
2049 sub alloc_disk {
2050     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
2051
2052     my $needs_chown = 0;
2053     my $volid;
2054
2055     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2056     # fixme: use better naming ct-$vmid-disk-X.raw?
2057
2058     eval {
2059         my $do_format = 0;
2060         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2061             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2062                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2063                 $do_format = 1;
2064             } else {
2065                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2066                 $needs_chown = 1;
2067             }
2068         } elsif ($scfg->{type} eq 'zfspool') {
2069             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2070             $needs_chown = 1;
2071         } elsif ($scfg->{content}->{rootdir}) {
2072             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2073             $do_format = 1;
2074         } else {
2075             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2076         }
2077         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2078     };
2079     if (my $err = $@) {
2080         # in case formatting got interrupted:
2081         if (defined($volid)) {
2082             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2083             warn $@ if $@;
2084         }
2085         die $err;
2086     }
2087
2088     return ($volid, $needs_chown);
2089 }
2090
2091 sub create_disks {
2092     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2093
2094     my $vollist = [];
2095
2096     eval {
2097         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2098         my $chown_vollist = [];
2099
2100         PVE::LXC::Config->foreach_volume($settings, sub {
2101             my ($ms, $mountpoint) = @_;
2102
2103             my $volid = $mountpoint->{volume};
2104             my $mp = $mountpoint->{mp};
2105
2106             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2107
2108             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2109                 my ($storeid, $size_gb) = ($1, $2);
2110
2111                 my $size_kb = int(${size_gb}*1024) * 1024;
2112
2113                 my $needs_chown = 0;
2114                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2115                 push @$chown_vollist, $volid if $needs_chown;
2116                 push @$vollist, $volid;
2117                 $mountpoint->{volume} = $volid;
2118                 $mountpoint->{size} = $size_kb * 1024;
2119                 if ($pending) {
2120                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2121                 } else {
2122                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2123                 }
2124             } else {
2125                 # use specified/existing volid/dir/device
2126                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2127             }
2128         });
2129
2130         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2131         foreach my $volid (@$chown_vollist) {
2132             my $path = PVE::Storage::path($storecfg, $volid, undef);
2133             chown($rootuid, $rootgid, $path);
2134         }
2135         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2136     };
2137     # free allocated images on error
2138     if (my $err = $@) {
2139         destroy_disks($storecfg, $vollist);
2140         die $err;
2141     }
2142     return $vollist;
2143 }
2144
2145 sub update_disksize {
2146     my ($vmid, $conf, $all_volumes) = @_;
2147
2148     my $changes;
2149     my $prefix = "CT $vmid:";
2150
2151     my $update_mp = sub {
2152         my ($key, $mp, @param) = @_;
2153         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2154
2155         if (!defined($mp->{size}) || $size != $mp->{size}) {
2156             $changes = 1;
2157             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2158             $mp->{size} = $size;
2159             my $no_mp = $key eq 'rootfs'; # rootfs is handled different from other mount points
2160             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $no_mp);
2161         }
2162     };
2163
2164     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2165
2166     return $changes;
2167 }
2168
2169 sub update_unused {
2170     my ($vmid, $conf, $all_volumes) = @_;
2171
2172     my $changes;
2173     my $prefix = "CT $vmid:";
2174
2175     # Note: it is allowed to define multiple storage entries with the same path
2176     # (alias), so we need to check both 'volid' and real 'path' (two different
2177     # volid can point to the same path).
2178
2179     # used and unused disks
2180     my $refpath = {};
2181     my $orphans = {};
2182
2183     foreach my $opt (keys %$conf) {
2184         next if ($opt !~ m/^unused\d+$/);
2185         my $vol = $all_volumes->{$conf->{$opt}};
2186         $refpath->{$vol->{path}} = $vol->{volid};
2187     }
2188
2189     foreach my $key (keys %$all_volumes) {
2190         my $vol = $all_volumes->{$key};
2191         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2192         my $path = $vol->{path};
2193
2194         if ($in_use) {
2195             $refpath->{$path} = $key;
2196             delete $orphans->{$path};
2197         } else {
2198             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2199                 $orphans->{$path} = $key;
2200             }
2201         }
2202     }
2203
2204     for my $key (keys %$orphans) {
2205         my $disk = $orphans->{$key};
2206         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2207
2208         if ($unused) {
2209             $changes = 1;
2210             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2211         }
2212     }
2213
2214     return $changes;
2215 }
2216
2217 sub scan_volids {
2218     my ($cfg, $vmid) = @_;
2219
2220     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2221
2222     my $all_volumes = {};
2223     foreach my $storeid (keys %$info) {
2224         foreach my $item (@{$info->{$storeid}}) {
2225             my $volid = $item->{volid};
2226             next if !($volid && $item->{size});
2227             $item->{path} = PVE::Storage::path($cfg, $volid);
2228             $all_volumes->{$volid} = $item;
2229         }
2230     }
2231
2232     return $all_volumes;
2233 }
2234
2235 sub rescan {
2236     my ($vmid, $nolock, $dryrun) = @_;
2237
2238     my $cfg = PVE::Storage::config();
2239
2240     print "rescan volumes...\n";
2241     my $all_volumes = scan_volids($cfg, $vmid);
2242
2243     my $updatefn =  sub {
2244         my ($vmid) = @_;
2245
2246         my $changes;
2247         my $conf = PVE::LXC::Config->load_config($vmid);
2248
2249         PVE::LXC::Config->check_lock($conf);
2250
2251         my $vm_volids = {};
2252         foreach my $volid (keys %$all_volumes) {
2253             my $info = $all_volumes->{$volid};
2254             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2255         }
2256
2257         my $upu = update_unused($vmid, $conf, $vm_volids);
2258         my $upd = update_disksize($vmid, $conf, $vm_volids);
2259         $changes = $upu || $upd;
2260
2261         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2262     };
2263
2264     if (defined($vmid)) {
2265         if ($nolock) {
2266             &$updatefn($vmid);
2267         } else {
2268             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2269         }
2270     } else {
2271         my $vmlist = config_list();
2272         foreach my $vmid (keys %$vmlist) {
2273             if ($nolock) {
2274                 &$updatefn($vmid);
2275             } else {
2276                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2277             }
2278         }
2279     }
2280 }
2281
2282
2283 # bash completion helper
2284
2285 sub complete_os_templates {
2286     my ($cmdname, $pname, $cvalue) = @_;
2287
2288     my $cfg = PVE::Storage::config();
2289
2290     my $storeid;
2291
2292     if ($cvalue =~ m/^([^:]+):/) {
2293         $storeid = $1;
2294     }
2295
2296     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2297     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2298
2299     my $res = [];
2300     foreach my $id (keys %$data) {
2301         foreach my $item (@{$data->{$id}}) {
2302             push @$res, $item->{volid} if defined($item->{volid});
2303         }
2304     }
2305
2306     return $res;
2307 }
2308
2309 my $complete_ctid_full = sub {
2310     my ($running) = @_;
2311
2312     my $idlist = vmstatus();
2313
2314     my $active_hash = list_active_containers();
2315
2316     my $res = [];
2317
2318     foreach my $id (keys %$idlist) {
2319         my $d = $idlist->{$id};
2320         if (defined($running)) {
2321             next if $d->{template};
2322             next if $running && !$active_hash->{$id};
2323             next if !$running && $active_hash->{$id};
2324         }
2325         push @$res, $id;
2326
2327     }
2328     return $res;
2329 };
2330
2331 sub complete_ctid {
2332     return &$complete_ctid_full();
2333 }
2334
2335 sub complete_ctid_stopped {
2336     return &$complete_ctid_full(0);
2337 }
2338
2339 sub complete_ctid_running {
2340     return &$complete_ctid_full(1);
2341 }
2342
2343 sub parse_id_maps {
2344     my ($conf) = @_;
2345
2346     my $id_map = [];
2347     my $rootuid = 0;
2348     my $rootgid = 0;
2349
2350     my $lxc = $conf->{lxc};
2351     foreach my $entry (@$lxc) {
2352         my ($key, $value) = @$entry;
2353
2354         next if $key ne 'lxc.idmap';
2355
2356         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2357             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2358             push @$id_map, [$type, $ct, $host, $length];
2359             if ($ct == 0) {
2360                 $rootuid = $host if $type eq 'u';
2361                 $rootgid = $host if $type eq 'g';
2362             }
2363         } else {
2364             die "failed to parse idmap: $value\n";
2365         }
2366     }
2367
2368     if (!@$id_map && $conf->{unprivileged}) {
2369         # Should we read them from /etc/subuid?
2370         $id_map = [ ['u', '0', '100000', '65536'],
2371                     ['g', '0', '100000', '65536'] ];
2372         $rootuid = $rootgid = 100000;
2373     }
2374
2375     return ($id_map, $rootuid, $rootgid);
2376 }
2377
2378 sub validate_id_maps {
2379     my ($id_map) = @_;
2380
2381     # $mappings->{$type}->{$side} = [ { line => $line, start => $start, count => $count }, ... ]
2382     #   $type: either "u" or "g"
2383     #   $side: either "container" or "host"
2384     #   $line: index of this mapping in @$id_map
2385     #   $start, $count: interval of this mapping
2386     my $mappings = { u => {}, g => {} };
2387     for (my $i = 0; $i < scalar(@$id_map); $i++) {
2388         my ($type, $ct_start, $host_start, $count) = $id_map->[$i]->@*;
2389         my $sides = $mappings->{$type};
2390         push $sides->{host}->@*, { line => $i, start => $host_start, count => $count };
2391         push $sides->{container}->@*, { line => $i, start => $ct_start, count => $count };
2392     }
2393
2394     # find the first conflict between two consecutive mappings when sorted by their start id
2395     for my $type (qw(u g)) {
2396         for my $side (qw(container host)) {
2397             my @entries = sort { $a->{start} <=> $b->{start} } $mappings->{$type}->{$side}->@*;
2398             for my $idx (1..scalar(@entries) - 1) {
2399                 my $previous = $entries[$idx - 1];
2400                 my $current = $entries[$idx];
2401                 if ($previous->{start} + $previous->{count} > $current->{start}) {
2402                     my $conflict = $current->{start};
2403                     my @previous_line = $id_map->[$previous->{line}]->@*;
2404                     my @current_line = $id_map->[$current->{line}]->@*;
2405                     die "invalid map entry '@current_line': $side ${type}id $conflict "
2406                        ."is also mapped by entry '@previous_line'\n";
2407                 }
2408             }
2409         }
2410     }
2411 }
2412
2413 sub userns_command {
2414     my ($id_map) = @_;
2415     if (@$id_map) {
2416         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2417     }
2418     return [];
2419 }
2420
2421 my sub print_ct_stderr_log {
2422     my ($vmid) = @_;
2423     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2424     return if !$log;
2425
2426     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2427         my $line = $2;
2428         print STDERR "$line\n";
2429     }
2430 }
2431 my sub print_ct_warn_log {
2432     my ($vmid) = @_;
2433     my $log_fn = "/run/pve/ct-$vmid.warnings";
2434     my $log = eval { file_get_contents($log_fn) };
2435     return if !$log;
2436
2437     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2438         PVE::RESTEnvironment::log_warn($1);
2439     }
2440     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2441 }
2442
2443 my sub monitor_state_change($$) {
2444     my ($monitor_socket, $vmid) = @_;
2445     die "no monitor socket\n" if !defined($monitor_socket);
2446
2447     while (1) {
2448         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2449
2450         die "monitor socket: got EOF\n" if !defined($type);
2451
2452         next if $name ne "$vmid" || $type ne 'STATE';
2453
2454         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2455             alarm(0); # don't timeout after seeing the starting state
2456         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2457                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2458                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2459             return 0;
2460         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2461             return 1;
2462         } else {
2463             warn "unexpected message from monitor socket - " .
2464                  "type: '$type' - value: '$value'\n";
2465         }
2466     }
2467 }
2468 my sub monitor_start($$) {
2469     my ($monitor_socket, $vmid) = @_;
2470
2471     my $success = eval {
2472         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2473     };
2474     if (my $err = $@) {
2475         warn "problem with monitor socket, but continuing anyway: $err\n";
2476     } elsif (!$success) {
2477         print_ct_stderr_log($vmid);
2478         die "startup for container '$vmid' failed\n";
2479     }
2480 }
2481
2482 sub vm_start {
2483     my ($vmid, $conf, $skiplock, $debug) = @_;
2484
2485     # apply pending changes while starting
2486     if (scalar(keys %{$conf->{pending}})) {
2487         my $storecfg = PVE::Storage::config();
2488         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2489         PVE::LXC::Config->write_config($vmid, $conf);
2490         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2491     }
2492
2493     update_lxc_config($vmid, $conf);
2494
2495     eval {
2496         my ($id_map, undef, undef) = PVE::LXC::parse_id_maps($conf);
2497         PVE::LXC::validate_id_maps($id_map);
2498     };
2499     warn "lxc.idmap: $@" if $@;
2500
2501     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2502
2503     if ($skiplock) {
2504         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2505         close($fh);
2506     }
2507
2508     my $storage_cfg = PVE::Storage::config();
2509     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2510
2511     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2512
2513     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2514     warn $@ if $@;
2515
2516     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2517
2518     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2519     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2520
2521     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2522
2523     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2524     eval {
2525         run_command($cmd);
2526
2527         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2528
2529         # if debug is requested, print the log it also when the start succeeded
2530         print_ct_stderr_log($vmid) if $is_debug;
2531
2532         print_ct_warn_log($vmid); # always print warn log, if any
2533     };
2534     if (my $err = $@) {
2535         unlink $skiplock_flag_fn;
2536         die $err;
2537     }
2538     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2539
2540     return;
2541 }
2542
2543 # Helper to stop a container completely and make sure it has stopped completely.
2544 # This is necessary because we want the post-stop hook to have completed its
2545 # unmount-all step, but post-stop happens after lxc puts the container into the
2546 # STOPPED state.
2547 # $kill - if true it will always do an immediate hard-stop
2548 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2549 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2550 sub vm_stop {
2551     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2552
2553     # Open the container's command socket.
2554     my $path = "\0/var/lib/lxc/$vmid/command";
2555     my $sock = IO::Socket::UNIX->new(
2556         Type => SOCK_STREAM(),
2557         Peer => $path,
2558     );
2559     if (!$sock) {
2560         return if $! == ECONNREFUSED; # The container is not running
2561         die "failed to open container ${vmid}'s command socket: $!\n";
2562     }
2563
2564     my $conf = PVE::LXC::Config->load_config($vmid);
2565     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2566
2567     # Stop the container:
2568
2569     my $cmd = ['lxc-stop', '-n', $vmid];
2570
2571     if ($kill) {
2572         push @$cmd, '--kill'; # doesn't allow timeouts
2573     } else {
2574         # lxc-stop uses a default timeout
2575         push @$cmd, '--nokill' if !$kill_after_timeout;
2576
2577         if (defined($shutdown_timeout)) {
2578             push @$cmd, '--timeout', $shutdown_timeout;
2579             # Give run_command 5 extra seconds
2580             $shutdown_timeout += 5;
2581         }
2582     }
2583
2584     eval { run_command($cmd, timeout => $shutdown_timeout) };
2585
2586     # Wait until the command socket is closed.
2587     # In case the lxc-stop call failed, reading from the command socket may block forever,
2588     # so poll with another timeout to avoid freezing the shutdown task.
2589     if (my $err = $@) {
2590         warn $err if $err;
2591
2592         my $poll = IO::Poll->new();
2593         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2594         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2595         return if ($poll->events($sock) & POLLHUP);
2596     } else {
2597         my $result = <$sock>;
2598         return if !defined $result; # monitor is gone and the ct has stopped.
2599     }
2600
2601     die "container did not stop\n";
2602 }
2603
2604 sub vm_reboot {
2605     my ($vmid, $timeout, $skiplock) = @_;
2606
2607     PVE::LXC::Config->lock_config($vmid, sub {
2608         return if !check_running($vmid);
2609
2610         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2611
2612         my $conf = PVE::LXC::Config->load_config($vmid);
2613         vm_start($vmid, $conf);
2614     });
2615 }
2616
2617 sub run_unshared {
2618     my ($code) = @_;
2619
2620     return PVE::Tools::run_fork(sub {
2621         # Unshare the mount namespace
2622         die "failed to unshare mount namespace: $!\n"
2623             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2624         run_command(['mount', '--make-rslave', '/']);
2625         return $code->();
2626     });
2627 }
2628
2629 my $copy_volume = sub {
2630     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2631
2632     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2633     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2634
2635     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2636     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2637
2638     my @mounted;
2639     eval {
2640         # mount and copy
2641         mkdir $src;
2642         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2643         push @mounted, $src;
2644         mkdir $dest;
2645         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2646         push @mounted, $dest;
2647
2648         $bwlimit //= 0;
2649
2650         run_command([
2651             'rsync',
2652             '--stats',
2653             '-X',
2654             '-A',
2655             '--numeric-ids',
2656             '-aH',
2657             '--whole-file',
2658             '--sparse',
2659             '--one-file-system',
2660             "--bwlimit=$bwlimit",
2661             "$src/",
2662             $dest
2663         ]);
2664     };
2665     my $err = $@;
2666
2667     # Wait for rsync's children to release dest so that
2668     # consequent file operations (umount, remove) are possible
2669     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2670
2671     foreach my $mount (reverse @mounted) {
2672         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2673         warn "Can't umount $mount\n" if $@;
2674     }
2675
2676     # If this fails they're used as mount points in a concurrent operation
2677     # (which should not happen but there's also no real need to get rid of them).
2678     rmdir $dest;
2679     rmdir $src;
2680
2681     die $err if $err;
2682 };
2683
2684 # Should not be called after unsharing the mount namespace!
2685 sub copy_volume {
2686     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2687
2688     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2689     File::Path::make_path("/var/lib/lxc/$vmid");
2690     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2691     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2692
2693     # get id's for unprivileged container
2694     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2695
2696     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2697     # are visible in this namespace, otherwise the host only sees the empty
2698     # (not-mounted) directory.
2699     my $new_volid;
2700     eval {
2701         # Make sure $mp contains a correct size.
2702         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2703         my $needs_chown;
2704         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2705         if ($needs_chown) {
2706             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2707             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2708             chown($rootuid, $rootgid, $path);
2709         }
2710
2711         run_unshared(sub {
2712             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2713         });
2714     };
2715     if (my $err = $@) {
2716         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2717             if defined($new_volid);
2718         die $err;
2719     }
2720
2721     return $new_volid;
2722 }
2723
2724 sub get_lxc_version() {
2725     my $version;
2726     run_command([qw(lxc-start --version)], outfunc => sub {
2727         my ($line) = @_;
2728         # We only parse out major & minor version numbers.
2729         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2730             $version = [$1, $2];
2731         }
2732     });
2733
2734     die "failed to get lxc version\n" if !defined($version);
2735
2736     # return as a list:
2737     return $version->@*;
2738 }
2739
2740 sub freeze($) {
2741     my ($vmid) = @_;
2742     if (PVE::CGroup::cgroup_mode() == 2) {
2743         PVE::LXC::Command::freeze($vmid, 30);
2744     } else {
2745         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2746     }
2747 }
2748
2749 sub thaw($) {
2750     my ($vmid) = @_;
2751     if (PVE::CGroup::cgroup_mode() == 2) {
2752         PVE::LXC::Command::unfreeze($vmid, 30);
2753     } else {
2754         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2755     }
2756 }
2757
2758 1;