src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     dir_glob_foreach file_get_contents file_set_contents lock_file
  24     lock_file_full AT_FDCWD O_PATH $IPV4RE $IPV6RE
  25 );
  26 use PVE::CpuSet;
  27 use PVE::Network;
  28 use PVE::AccessControl;
  29 use PVE::ProcFSTools;
  30 use PVE::Syscall qw(:fsmount);
  31 use PVE::LXC::Config;
  32 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  33 use PVE::LXC::Tools;
  34
  35 use Time::HiRes qw (gettimeofday);
  36 my $have_sdn;
  37 eval {
  38     require PVE::Network::SDN::Zones;
  39     $have_sdn = 1;
  40 };
  41
  42 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  43
  44 my $nodename = PVE::INotify::nodename();
  45
  46 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  47
  48 sub config_list {
  49     my $vmlist = PVE::Cluster::get_vmlist();
  50     my $res = {};
  51     return $res if !$vmlist || !$vmlist->{ids};
  52     my $ids = $vmlist->{ids};
  53
  54     foreach my $vmid (keys %$ids) {
  55         next if !$vmid; # skip CT0
  56         my $d = $ids->{$vmid};
  57         next if !$d->{node} || $d->{node} ne $nodename;
  58         next if !$d->{type} || $d->{type} ne 'lxc';
  59         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  60     }
  61     return $res;
  62 }
  63
  64 # container status helpers
  65
  66 sub list_active_containers {
  67
  68     my $filename = "/proc/net/unix";
  69
  70     # similar test is used by lcxcontainers.c: list_active_containers
  71     my $res = {};
  72
  73     my $fh = IO::File->new ($filename, "r");
  74     return $res if !$fh;
  75
  76     while (defined(my $line = <$fh>)) {
  77         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  78             my $path = $1;
  79             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  80                 $res->{$1} = 1;
  81             }
  82         }
  83     }
  84
  85     close($fh);
  86
  87     return $res;
  88 }
  89
  90 # warning: this is slow
  91 sub check_running {
  92     my ($vmid) = @_;
  93
  94     my $active_hash = list_active_containers();
  95
  96     return 1 if defined($active_hash->{$vmid});
  97
  98     return undef;
  99 }
 100
 101 sub get_container_disk_usage {
 102     my ($vmid, $pid) = @_;
 103
 104     return PVE::Tools::df("/proc/$pid/root/", 1);
 105 }
 106
 107 my $last_proc_vmid_stat;
 108
 109 my $parse_cpuacct_stat = sub {
 110     my ($vmid, $unprivileged) = @_;
 111
 112     my $raw = read_cgroup_value('cpuacct', $vmid, $unprivileged, 'cpuacct.stat', 1);
 113
 114     my $stat = {};
 115
 116     if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
 117
 118         $stat->{utime} = $1;
 119         $stat->{stime} = $2;
 120
 121     }
 122
 123     return $stat;
 124 };
 125
 126 our $vmstatus_return_properties = {
 127     vmid => get_standard_option('pve-vmid'),
 128     status => {
 129         description => "LXC Container status.",
 130         type => 'string',
 131         enum => ['stopped', 'running'],
 132     },
 133     maxmem => {
 134         description => "Maximum memory in bytes.",
 135         type => 'integer',
 136         optional => 1,
 137         renderer => 'bytes',
 138     },
 139     maxswap => {
 140         description => "Maximum SWAP memory in bytes.",
 141         type => 'integer',
 142         optional => 1,
 143         renderer => 'bytes',
 144     },
 145     maxdisk => {
 146         description => "Root disk size in bytes.",
 147         type => 'integer',
 148         optional => 1,
 149         renderer => 'bytes',
 150     },
 151     name => {
 152         description => "Container name.",
 153         type => 'string',
 154         optional => 1,
 155     },
 156     uptime => {
 157         description => "Uptime.",
 158         type => 'integer',
 159         optional => 1,
 160         renderer => 'duration',
 161     },
 162     cpus => {
 163         description => "Maximum usable CPUs.",
 164         type => 'number',
 165         optional => 1,
 166     },
 167     lock => {
 168         description => "The current config lock, if any.",
 169         type => 'string',
 170         optional => 1,
 171     },
 172     tags => {
 173         description => "The current configured tags, if any.",
 174         type => 'string',
 175         optional => 1,
 176     }
 177 };
 178
 179 sub vmstatus {
 180     my ($opt_vmid) = @_;
 181
 182     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
 183
 184     my $active_hash = list_active_containers();
 185
 186     my $cpucount = $cpuinfo->{cpus} || 1;
 187
 188     my $cdtime = gettimeofday;
 189
 190     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 191     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 192
 193     my $unprivileged = {};
 194
 195     foreach my $vmid (keys %$list) {
 196         my $d = $list->{$vmid};
 197
 198         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 199         warn $@ if $@; # ignore errors (consider them stopped)
 200
 201         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 202
 203         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 204         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 205
 206         $unprivileged->{$vmid} = $conf->{unprivileged};
 207
 208         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 209         $d->{name} =~ s/[\s]//g;
 210
 211         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 212         $d->{cpus} = $cpucount if !$d->{cpus};
 213
 214         $d->{lock} = $conf->{lock} || '';
 215         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 216
 217         if ($d->{pid}) {
 218             my $res = get_container_disk_usage($vmid, $d->{pid});
 219             $d->{disk} = $res->{used};
 220             $d->{maxdisk} = $res->{total};
 221         } else {
 222             $d->{disk} = 0;
 223             # use 4GB by default ??
 224             if (my $rootfs = $conf->{rootfs}) {
 225                 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
 226                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 227             } else {
 228                 $d->{maxdisk} = 4*1024*1024*1024;
 229             }
 230         }
 231
 232         $d->{mem} = 0;
 233         $d->{swap} = 0;
 234         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 235         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 236
 237         $d->{uptime} = 0;
 238         $d->{cpu} = 0;
 239
 240         $d->{netout} = 0;
 241         $d->{netin} = 0;
 242
 243         $d->{diskread} = 0;
 244         $d->{diskwrite} = 0;
 245
 246         $d->{template} = PVE::LXC::Config->is_template($conf);
 247         $d->{lock} = $conf->{lock} if $conf->{lock};
 248     }
 249
 250     foreach my $vmid (keys %$list) {
 251         my $d = $list->{$vmid};
 252         my $pid = $d->{pid};
 253
 254         next if !$pid; # skip stopped CTs
 255
 256         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 257         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 258
 259         my $unpriv = $unprivileged->{$vmid};
 260
 261         if (-d '/sys/fs/cgroup/memory') {
 262             my $memory_stat = read_cgroup_list('memory', $vmid, $unpriv, 'memory.stat');
 263             my $mem_usage_in_bytes = read_cgroup_value('memory', $vmid, $unpriv, 'memory.usage_in_bytes');
 264
 265             $d->{mem} = $mem_usage_in_bytes - $memory_stat->{total_cache};
 266             $d->{swap} = read_cgroup_value('memory', $vmid, $unpriv, 'memory.memsw.usage_in_bytes') - $mem_usage_in_bytes;
 267         } else {
 268             $d->{mem} = 0;
 269             $d->{swap} = 0;
 270         }
 271
 272         if (-d '/sys/fs/cgroup/blkio') {
 273             my $blkio_bytes = read_cgroup_value('blkio', $vmid, 0, 'blkio.throttle.io_service_bytes', 1); # don't check if unpriv
 274             my @bytes = split(/\n/, $blkio_bytes);
 275             foreach my $byte (@bytes) {
 276                 if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 277                     $d->{diskread} += $2 if $key eq 'Read';
 278                     $d->{diskwrite} += $2 if $key eq 'Write';
 279                 }
 280             }
 281         } else {
 282             $d->{diskread} = 0;
 283             $d->{diskwrite} = 0;
 284         }
 285
 286         if (-d '/sys/fs/cgroup/cpuacct') {
 287             my $pstat = $parse_cpuacct_stat->($vmid, $unpriv);
 288
 289             my $used = $pstat->{utime} + $pstat->{stime};
 290
 291             my $old = $last_proc_vmid_stat->{$vmid};
 292             if (!$old) {
 293                 $last_proc_vmid_stat->{$vmid} = {
 294                     time => $cdtime,
 295                     used => $used,
 296                     cpu => 0,
 297                 };
 298                 next;
 299             }
 300
 301             my $dtime = ($cdtime -  $old->{time}) * $cpucount * $cpuinfo->{user_hz};
 302
 303             if ($dtime > 1000) {
 304                 my $dutime = $used -  $old->{used};
 305
 306                 $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
 307                 $last_proc_vmid_stat->{$vmid} = {
 308                     time => $cdtime,
 309                     used => $used,
 310                     cpu => $d->{cpu},
 311                 };
 312             } else {
 313                 $d->{cpu} = $old->{cpu};
 314             }
 315         } else {
 316             $d->{cpu} = 0;
 317         }
 318     }
 319
 320     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 321
 322     foreach my $dev (keys %$netdev) {
 323         next if $dev !~ m/^veth([1-9]\d*)i/;
 324         my $vmid = $1;
 325         my $d = $list->{$vmid};
 326
 327         next if !$d;
 328
 329         $d->{netout} += $netdev->{$dev}->{receive};
 330         $d->{netin} += $netdev->{$dev}->{transmit};
 331
 332     }
 333
 334     return $list;
 335 }
 336
 337 sub read_cgroup_list($$$$) {
 338     my ($group, $vmid, $unprivileged, $name) = @_;
 339
 340     my $content = read_cgroup_value($group, $vmid, $unprivileged, $name, 1);
 341
 342     return { split(/\s+/, $content) };
 343 }
 344
 345 sub read_cgroup_value($$$$$) {
 346     my ($group, $vmid, $unprivileged, $name, $full) = @_;
 347
 348     my $nsdir = $unprivileged ? '' : 'ns/';
 349     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/${nsdir}$name";
 350
 351     return PVE::Tools::file_get_contents($path) if $full;
 352
 353     return PVE::Tools::file_read_firstline($path);
 354 }
 355
 356 sub write_cgroup_value {
 357    my ($group, $vmid, $name, $value) = @_;
 358
 359    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 360    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 361
 362 }
 363
 364 sub find_lxc_console_pids {
 365
 366     my $res = {};
 367
 368     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 369         my ($pid) = @_;
 370
 371         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 372         return if !$cmdline;
 373
 374         my @args = split(/\0/, $cmdline);
 375
 376         # search for lxc-console -n <vmid>
 377         return if scalar(@args) != 3;
 378         return if $args[1] ne '-n';
 379         return if $args[2] !~ m/^\d+$/;
 380         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 381
 382         my $vmid = $args[2];
 383
 384         push @{$res->{$vmid}}, $pid;
 385     });
 386
 387     return $res;
 388 }
 389
 390 sub find_lxc_pid {
 391     my ($vmid) = @_;
 392
 393     my $pid = undef;
 394     my $parser = sub {
 395         my $line = shift;
 396         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 397     };
 398     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 399
 400     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 401
 402     return $pid;
 403 }
 404
 405 sub open_pid_fd($) {
 406     my ($pid) = @_;
 407     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 408         or die "failed to open /proc/$pid pid fd\n";
 409     return $fd;
 410 }
 411
 412 sub open_lxc_pid {
 413     my ($vmid) = @_;
 414
 415     # Find the pid and open:
 416     my $pid = find_lxc_pid($vmid);
 417     my $fd = open_pid_fd($pid);
 418
 419     # Verify:
 420     my $pid2 = find_lxc_pid($vmid);
 421
 422     return () if $pid != $pid2;
 423     return ($pid, $fd);
 424 }
 425
 426 sub open_ppid {
 427     my ($pid) = @_;
 428
 429     # Find the parent pid via proc and open it:
 430     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 431     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 432
 433     my $fd = open_pid_fd($ppid);
 434
 435     # Verify:
 436     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 437     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 438
 439     return () if $ppid != $ppid2;
 440     return ($ppid, $fd);
 441 }
 442
 443 # Note: we cannot use Net:IP, because that only allows strict
 444 # CIDR networks
 445 sub parse_ipv4_cidr {
 446     my ($cidr, $noerr) = @_;
 447
 448     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 449         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 450     }
 451
 452     return undef if $noerr;
 453
 454     die "unable to parse ipv4 address/mask\n";
 455 }
 456
 457 sub get_cgroup_subsystems {
 458         my $v1 = {};
 459         my $v2 = 0;
 460         my $data = PVE::Tools::file_get_contents('/proc/self/cgroup');
 461         while ($data =~ /^\d+:([^:\n]*):.*$/gm) {
 462                 my $type = $1;
 463                 if (length($type)) {
 464                         $v1->{$_} = 1 foreach split(/,/, $type);
 465                 } else {
 466                         $v2 = 1;
 467                 }
 468         }
 469         return wantarray ? ($v1, $v2) : $v1;
 470 }
 471
 472 # With seccomp trap to userspace we now have the ability to optionally forward
 473 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 474 #
 475 # This means that there are cases where we need to create an extra seccomp
 476 # profile for the container to load.
 477 #
 478 # This returns a configuration snippet added to the raw lxc config.
 479 sub make_seccomp_config {
 480     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 481     # User-configured profile has precedence, note that the user's entry would
 482     # be written 'after' this line anyway...
 483     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 484         # Warn the user if this conflicts with a feature:
 485         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 486         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 487             if length($warn) > 0;
 488         return '';
 489     }
 490
 491     # Privileged containers keep using the default (which is already part of
 492     # the files included via lxc.include, so we don't need to write it out,
 493     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 494     # well)
 495     return '' if !$unprivileged;
 496
 497     my $rules = {
 498         keyctl => ['errno 38'],
 499     };
 500
 501     my $raw_conf = '';
 502
 503     # Unprivileged containers will get keyctl() disabled by default as a
 504     # workaround for systemd-networkd behavior. But we have an option to
 505     # explicitly enable it:
 506     if ($features->{keyctl}) {
 507         delete $rules->{keyctl};
 508     }
 509
 510     # By default, unprivileged containers cannot use `mknod` at all.
 511     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 512     # but for now this is experimental, so it has to be enabled via a feature
 513     # flag.
 514     # Note that we only handle block and char devices (like lxd), the rest we
 515     # leave up to the kernel. We may in the future remove this if seccomp gets
 516     # a way to tell the kernel to "continue" a syscall.
 517     if ($features->{mknod}) {
 518         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 519         if (!$ok) {
 520             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 521         }
 522
 523         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 524         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 525
 526         $rules->{mknod} = [
 527             # condition: (mode & S_IFMT) == S_IFCHR
 528             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 529             # condition: (mode & S_IFMT) == S_IFBLK
 530             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 531         ];
 532         $rules->{mknodat} = [
 533             # condition: (mode & S_IFMT) == S_IFCHR
 534             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 535             # condition: (mode & S_IFMT) == S_IFBLK
 536             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 537         ];
 538     }
 539
 540     # Now build the custom seccomp rule text...
 541     my $extra_rules = join("\n", map {
 542         my $syscall = $_;
 543         map { "$syscall $_" } $rules->{$syscall}->@*
 544     } sort keys %$rules) . "\n";
 545
 546     return $raw_conf if $extra_rules eq "\n";
 547
 548     # We still have the "most common" config readily available, so don't write
 549     # out that one:
 550     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 551         # we have no extra $raw_conf and use the same we had in pve 6.1:
 552         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 553     }
 554
 555     # Write the rule file to the container's config path:
 556     my $rule_file = "$conf_dir/rules.seccomp";
 557     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 558         . $extra_rules;
 559     file_set_contents($rule_file, $rule_data);
 560     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 561
 562     return $raw_conf;
 563 }
 564
 565 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 566 # automatically. The default should be equivalent to the old
 567 # `lxc-container-default-cgns` profile.
 568 #
 569 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 570 # additional lines into the profile. We can use that to allow mounting specific
 571 # file systems.
 572 sub make_apparmor_config {
 573     my ($conf, $unprivileged, $features) = @_;
 574
 575     # user-configured profile has precedence, but first we go through our own
 576     # code to figure out whether we should warn the user:
 577
 578     my $raw = "lxc.apparmor.profile = generated\n";
 579     my @profile_uses;
 580
 581     if ($features->{fuse}) {
 582         # For the informational warning:
 583         push @profile_uses, 'features:fuse';
 584     }
 585
 586     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 587     # apparmor lines, create an apparmor namespace for the container, but also
 588     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 589     # lxcfs mounted over them, because that would prevent the container from
 590     # mounting new instances of them for nested containers.
 591     if ($features->{nesting}) {
 592         push @profile_uses, 'features:nesting';
 593         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 594     } else {
 595         # In the default profile in /etc/apparmor.d we patch this in because
 596         # otherwise a container can for example run `chown` on /sys, breaking
 597         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 598         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 599         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 600         # Preferably we could use the 'remount' flag but this does not sit well
 601         # with apparmor_parser currently:
 602         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 603     }
 604
 605     if (my $mount = $features->{mount}) {
 606         push @profile_uses, 'features:mount';
 607         foreach my $fs (PVE::Tools::split_list($mount)) {
 608             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 609         }
 610     }
 611
 612     # More to come?
 613
 614     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 615         if (length(my $used = join(', ', @profile_uses))) {
 616             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 617         }
 618         return '';
 619     }
 620
 621     return $raw;
 622 }
 623
 624 sub update_lxc_config {
 625     my ($vmid, $conf) = @_;
 626
 627     my $dir = "/var/lib/lxc/$vmid";
 628
 629     if ($conf->{template}) {
 630
 631         unlink "$dir/config";
 632
 633         return;
 634     }
 635
 636     my $raw = '';
 637
 638     die "missing 'arch' - internal error" if !$conf->{arch};
 639     $raw .= "lxc.arch = $conf->{arch}\n";
 640
 641     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 642     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 643
 644     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 645
 646     my $cfgpath = '/usr/share/lxc/config';
 647     my $inc = "$cfgpath/$ostype.common.conf";
 648     $inc ="$cfgpath/common.conf" if !-f $inc;
 649     $raw .= "lxc.include = $inc\n";
 650     if ($unprivileged) {
 651         $inc = "$cfgpath/$ostype.userns.conf";
 652         $inc = "$cfgpath/userns.conf" if !-f $inc;
 653         $raw .= "lxc.include = $inc\n";
 654     }
 655
 656     my $features = PVE::LXC::Config->parse_features($conf->{features});
 657
 658     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 659     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 660     if ($features->{fuse}) {
 661         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 662         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 663     }
 664
 665     if ($unprivileged && !$features->{force_rw_sys}) {
 666         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 667         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 668         $raw .= "lxc.mount.auto = sys:mixed\n";
 669     }
 670
 671     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 672     # cannot be exposed to the container with r/w access (cgroup perms).
 673     # When this is enabled mounts will still remain in the monitor's namespace
 674     # after the container unmounted them and thus will not detach from their
 675     # files while the container is running!
 676     $raw .= "lxc.monitor.unshare = 1\n";
 677
 678     my $cgv1 = get_cgroup_subsystems();
 679
 680     # Should we read them from /etc/subuid?
 681     if ($unprivileged && !$custom_idmap) {
 682         $raw .= "lxc.idmap = u 0 100000 65536\n";
 683         $raw .= "lxc.idmap = g 0 100000 65536\n";
 684     }
 685
 686     if (!PVE::LXC::Config->has_dev_console($conf)) {
 687         $raw .= "lxc.console.path = none\n";
 688         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
 689     }
 690
 691     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 692     $raw .= "lxc.tty.max = $ttycount\n";
 693
 694     # some init scripts expect a linux terminal (turnkey).
 695     $raw .= "lxc.environment = TERM=linux\n";
 696
 697     my $utsname = $conf->{hostname} || "CT$vmid";
 698     $raw .= "lxc.uts.name = $utsname\n";
 699
 700     if ($cgv1->{memory}) {
 701         my $memory = $conf->{memory} || 512;
 702         my $swap = $conf->{swap} // 0;
 703
 704         my $lxcmem = int($memory*1024*1024);
 705         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 706
 707         my $lxcswap = int(($memory + $swap)*1024*1024);
 708         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 709     }
 710
 711     if ($cgv1->{cpu}) {
 712         if (my $cpulimit = $conf->{cpulimit}) {
 713             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 714             my $value = int(100000*$cpulimit);
 715             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 716         }
 717
 718         my $shares = $conf->{cpuunits} || 1024;
 719         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 720     }
 721
 722     die "missing 'rootfs' configuration\n"
 723         if !defined($conf->{rootfs});
 724
 725     my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 726
 727     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 728
 729     foreach my $k (sort keys %$conf) {
 730         next if $k !~ m/^net(\d+)$/;
 731         my $ind = $1;
 732         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 733         $raw .= "lxc.net.$ind.type = veth\n";
 734         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 735         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 736         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 737         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 738     }
 739
 740     if ($cgv1->{cpuset}) {
 741         my $had_cpuset = 0;
 742         if (my $lxcconf = $conf->{lxc}) {
 743             foreach my $entry (@$lxcconf) {
 744                 my ($k, $v) = @$entry;
 745                 $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus';
 746                 $raw .= "$k = $v\n";
 747             }
 748         }
 749
 750         my $cores = $conf->{cores};
 751         if (!$had_cpuset && $cores) {
 752             my $cpuset = eval { PVE::CpuSet->new_from_cgroup('lxc', 'effective_cpus') };
 753             $cpuset = PVE::CpuSet->new_from_cgroup('', 'effective_cpus') if !$cpuset;
 754             my @members = $cpuset->members();
 755             while (scalar(@members) > $cores) {
 756                 my $randidx = int(rand(scalar(@members)));
 757                 $cpuset->delete($members[$randidx]);
 758                 splice(@members, $randidx, 1); # keep track of the changes
 759             }
 760             $raw .= "lxc.cgroup.cpuset.cpus = ".$cpuset->short_string()."\n";
 761         }
 762     }
 763
 764     File::Path::mkpath("$dir/rootfs");
 765
 766     PVE::Tools::file_set_contents("$dir/config", $raw);
 767 }
 768
 769 # verify and cleanup nameserver list (replace \0 with ' ')
 770 sub verify_nameserver_list {
 771     my ($nameserver_list) = @_;
 772
 773     my @list = ();
 774     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 775         PVE::JSONSchema::pve_verify_ip($server);
 776         push @list, $server;
 777     }
 778
 779     return join(' ', @list);
 780 }
 781
 782 sub verify_searchdomain_list {
 783     my ($searchdomain_list) = @_;
 784
 785     my @list = ();
 786     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 787         # todo: should we add checks for valid dns domains?
 788         push @list, $server;
 789     }
 790
 791     return join(' ', @list);
 792 }
 793
 794 sub get_console_command {
 795     my ($vmid, $conf, $escapechar) = @_;
 796
 797     # '-1' as $escapechar disables keyboard escape sequence
 798     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 799
 800     my $cmode = PVE::LXC::Config->get_cmode($conf);
 801
 802     my $cmd = [];
 803     if ($cmode eq 'console') {
 804         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 805         push @$cmd, '-e', $escapechar if $escapechar;
 806     } elsif ($cmode eq 'tty') {
 807         push @$cmd, 'lxc-console', '-n',  $vmid;
 808         push @$cmd, '-e', $escapechar if $escapechar;
 809     } elsif ($cmode eq 'shell') {
 810         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 811     } else {
 812         die "internal error";
 813     }
 814
 815     return $cmd;
 816 }
 817
 818 sub get_primary_ips {
 819     my ($conf) = @_;
 820
 821     # return data from net0
 822
 823     return undef if !defined($conf->{net0});
 824     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 825
 826     my $ipv4 = $net->{ip};
 827     if ($ipv4) {
 828         if ($ipv4 =~ /^(dhcp|manual)$/) {
 829             $ipv4 = undef
 830         } else {
 831             $ipv4 =~ s!/\d+$!!;
 832         }
 833     }
 834     my $ipv6 = $net->{ip6};
 835     if ($ipv6) {
 836         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 837             $ipv6 = undef;
 838         } else {
 839             $ipv6 =~ s!/\d+$!!;
 840         }
 841     }
 842
 843     return ($ipv4, $ipv6);
 844 }
 845
 846 sub delete_mountpoint_volume {
 847     my ($storage_cfg, $vmid, $volume) = @_;
 848
 849     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 850
 851     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 852
 853     if ($vmid == $owner) {
 854         PVE::Storage::vdisk_free($storage_cfg, $volume);
 855     } else {
 856         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 857     }
 858 }
 859
 860 sub destroy_lxc_container {
 861     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 862
 863     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 864         my ($ms, $mountpoint) = @_;
 865         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 866     });
 867
 868     rmdir "/var/lib/lxc/$vmid/rootfs";
 869     unlink "/var/lib/lxc/$vmid/config";
 870     rmdir "/var/lib/lxc/$vmid";
 871     if (defined $replacement_conf) {
 872         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 873     } else {
 874         PVE::LXC::Config->destroy_config($vmid);
 875     }
 876 }
 877
 878 sub vm_stop_cleanup {
 879     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 880
 881     return if $keepActive;
 882
 883     eval {
 884         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 885         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 886     };
 887     warn $@ if $@; # avoid errors - just warn
 888 }
 889
 890 sub update_net {
 891     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 892
 893     if ($newnet->{type} ne 'veth') {
 894         # for when there are physical interfaces
 895         die "cannot update interface of type $newnet->{type}";
 896     }
 897
 898     my $veth = "veth${vmid}i${netid}";
 899     my $eth = $newnet->{name};
 900
 901     if (my $oldnetcfg = $conf->{$opt}) {
 902         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 903
 904         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 905             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 906
 907             PVE::Network::veth_delete($veth);
 908             delete $conf->{$opt};
 909             PVE::LXC::Config->write_config($vmid, $conf);
 910
 911             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 912
 913         } else {
 914             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 915                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 916                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 917
 918                 if ($oldnet->{bridge}) {
 919                     PVE::Network::tap_unplug($veth);
 920                     foreach (qw(bridge tag firewall)) {
 921                         delete $oldnet->{$_};
 922                     }
 923                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 924                     PVE::LXC::Config->write_config($vmid, $conf);
 925                 }
 926
 927                 if ($have_sdn) {
 928                     PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 929                 } else {
 930                     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 931                 }
 932
 933                 # This includes the rate:
 934                 foreach (qw(bridge tag firewall rate)) {
 935                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 936                 }
 937             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 938                 # Rate can be applied on its own but any change above needs to
 939                 # include the rate in tap_plug since OVS resets everything.
 940                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 941                 $oldnet->{rate} = $newnet->{rate}
 942             }
 943             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 944             PVE::LXC::Config->write_config($vmid, $conf);
 945         }
 946     } else {
 947         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 948     }
 949
 950     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 951 }
 952
 953 sub hotplug_net {
 954     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 955
 956     my $veth = "veth${vmid}i${netid}";
 957     my $vethpeer = $veth . "p";
 958     my $eth = $newnet->{name};
 959
 960     if ($have_sdn) {
 961         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 962         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 963     } else {
 964         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 965         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 966     }
 967
 968     # attach peer in container
 969     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 970     PVE::Tools::run_command($cmd);
 971
 972     # link up peer in container
 973     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 974     PVE::Tools::run_command($cmd);
 975
 976     my $done = { type => 'veth' };
 977     foreach (qw(bridge tag firewall hwaddr name)) {
 978         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 979     }
 980     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 981
 982     PVE::LXC::Config->write_config($vmid, $conf);
 983 }
 984
 985 sub update_ipconfig {
 986     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 987
 988     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 989
 990     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 991     my $deleted = [];
 992     my $added = [];
 993     my $nscmd = sub {
 994         my $cmdargs = shift;
 995         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 996     };
 997     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 998
 999     my $change_ip_config = sub {
1000         my ($ipversion) = @_;
1001
1002         my $family_opt = "-$ipversion";
1003         my $suffix = $ipversion == 4 ? '' : $ipversion;
1004         my $gw= "gw$suffix";
1005         my $ip= "ip$suffix";
1006
1007         my $newip = $newnet->{$ip};
1008         my $newgw = $newnet->{$gw};
1009         my $oldip = $optdata->{$ip};
1010         my $oldgw = $optdata->{$gw};
1011
1012         my $change_ip = safe_string_ne($oldip, $newip);
1013         my $change_gw = safe_string_ne($oldgw, $newgw);
1014
1015         return if !$change_ip && !$change_gw;
1016
1017         # step 1: add new IP, if this fails we cancel
1018         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1019         if ($change_ip && $is_real_ip) {
1020             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1021             if (my $err = $@) {
1022                 warn $err;
1023                 return;
1024             }
1025         }
1026
1027         # step 2: replace gateway
1028         #   If this fails we delete the added IP and cancel.
1029         #   If it succeeds we save the config and delete the old IP, ignoring
1030         #   errors. The config is then saved.
1031         # Note: 'ip route replace' can add
1032         if ($change_gw) {
1033             if ($newgw) {
1034                 eval {
1035                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1036                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1037                     }
1038                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1039                 };
1040                 if (my $err = $@) {
1041                     warn $err;
1042                     # the route was not replaced, the old IP is still available
1043                     # rollback (delete new IP) and cancel
1044                     if ($change_ip) {
1045                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1046                         warn $@ if $@; # no need to die here
1047                     }
1048                     return;
1049                 }
1050             } else {
1051                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1052                 # if the route was not deleted, the guest might have deleted it manually
1053                 # warn and continue
1054                 warn $@ if $@;
1055             }
1056             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1057                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1058                 # warn if the route was deleted manually
1059                 warn $@ if $@;
1060             }
1061         }
1062
1063         # from this point on we save the configuration
1064         # step 3: delete old IP ignoring errors
1065         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1066             # We need to enable promote_secondaries, otherwise our newly added
1067             # address will be removed along with the old one.
1068             my $promote = 0;
1069             eval {
1070                 if ($ipversion == 4) {
1071                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1072                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1073                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1074                 }
1075                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1076             };
1077             warn $@ if $@; # no need to die here
1078
1079             if ($ipversion == 4) {
1080                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1081             }
1082         }
1083
1084         foreach my $property ($ip, $gw) {
1085             if ($newnet->{$property}) {
1086                 $optdata->{$property} = $newnet->{$property};
1087             } else {
1088                 delete $optdata->{$property};
1089             }
1090         }
1091         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1092         PVE::LXC::Config->write_config($vmid, $conf);
1093         $lxc_setup->setup_network($conf);
1094     };
1095
1096     &$change_ip_config(4);
1097     &$change_ip_config(6);
1098
1099 }
1100
1101 my $open_namespace = sub {
1102     my ($vmid, $pid, $kind) = @_;
1103     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1104         or die "failed to open $kind namespace of container $vmid: $!\n";
1105     return $fd;
1106 };
1107
1108 my $enter_namespace = sub {
1109     my ($vmid, $pid, $kind, $type) = @_;
1110     my $fd = $open_namespace->($vmid, $pid, $kind);
1111     PVE::Tools::setns(fileno($fd), $type)
1112         or die "failed to enter $kind namespace of container $vmid: $!\n";
1113     close $fd;
1114 };
1115
1116 my $get_container_namespace = sub {
1117     my ($vmid, $pid, $kind) = @_;
1118
1119     my $pidfd;
1120     if (!defined($pid)) {
1121         # Pin the pid while we're grabbing its stuff from /proc
1122         ($pid, $pidfd) = open_lxc_pid($vmid)
1123             or die "failed to open pidfd of container $vmid\'s init process\n";
1124     }
1125
1126     return $open_namespace->($vmid, $pid, $kind);
1127 };
1128
1129 my $do_syncfs = sub {
1130     my ($vmid, $pid, $socket) = @_;
1131
1132     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1133
1134     # Tell the parent process to start reading our /proc/mounts
1135     print {$socket} "go\n";
1136     $socket->flush();
1137
1138     # Receive /proc/self/mounts
1139     my $mountdata = do { local $/ = undef; <$socket> };
1140     close $socket;
1141
1142     # Now sync all mountpoints...
1143     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1144     foreach my $mp (@$mounts) {
1145         my ($what, $dir, $fs) = @$mp;
1146         next if $fs eq 'fuse.lxcfs';
1147         eval { PVE::Tools::sync_mountpoint($dir); };
1148         warn $@ if $@;
1149     }
1150 };
1151
1152 sub sync_container_namespace {
1153     my ($vmid) = @_;
1154     my $pid = find_lxc_pid($vmid);
1155
1156     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1157     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1158         or die "failed to create socketpair: $!\n";
1159
1160     my $child = fork();
1161     die "fork failed: $!\n" if !defined($child);
1162
1163     if (!$child) {
1164         eval {
1165             close $pfd;
1166             &$do_syncfs($vmid, $pid, $cfd);
1167         };
1168         if (my $err = $@) {
1169             warn $err;
1170             POSIX::_exit(1);
1171         }
1172         POSIX::_exit(0);
1173     }
1174     close $cfd;
1175     my $go = <$pfd>;
1176     die "failed to enter container namespace\n" if $go ne "go\n";
1177
1178     open my $mounts, '<', "/proc/$child/mounts"
1179         or die "failed to open container's /proc/mounts: $!\n";
1180     my $mountdata = do { local $/ = undef; <$mounts> };
1181     close $mounts;
1182     print {$pfd} $mountdata;
1183     close $pfd;
1184
1185     while (waitpid($child, 0) != $child) {}
1186     die "failed to sync container namespace\n" if $? != 0;
1187 }
1188
1189 sub template_create {
1190     my ($vmid, $conf) = @_;
1191
1192     my $storecfg = PVE::Storage::config();
1193
1194     PVE::LXC::Config->foreach_mountpoint($conf, sub {
1195         my ($ms, $mountpoint) = @_;
1196
1197         my $volid = $mountpoint->{volume};
1198
1199         die "Template feature is not available for '$volid'\n"
1200             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1201     });
1202
1203     PVE::LXC::Config->foreach_mountpoint($conf, sub {
1204         my ($ms, $mountpoint) = @_;
1205
1206         my $volid = $mountpoint->{volume};
1207
1208         PVE::Storage::activate_volumes($storecfg, [$volid]);
1209
1210         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1211         $mountpoint->{volume} = $template_volid;
1212         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1213     });
1214
1215     PVE::LXC::Config->write_config($vmid, $conf);
1216 }
1217
1218 sub check_ct_modify_config_perm {
1219     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1220
1221     return 1 if $authuser eq 'root@pam';
1222
1223     my $check = sub {
1224         my ($opt, $delete) = @_;
1225         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1226             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1227         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1228             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1229             return if $delete;
1230             my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
1231                                         : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
1232             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1233                 if $data->{type} ne 'volume';
1234         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1235             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1236         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1237                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1238             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1239         } elsif ($opt eq 'features') {
1240             # For now this is restricted to root@pam
1241             raise_perm_exc("changing feature flags is only allowed for root\@pam");
1242         } elsif ($opt eq 'hookscript') {
1243             # For now this is restricted to root@pam
1244             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1245         } else {
1246             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1247         }
1248     };
1249
1250     foreach my $opt (keys %$newconf) {
1251         &$check($opt, 0);
1252     }
1253     foreach my $opt (@$delete) {
1254         &$check($opt, 1);
1255     }
1256
1257     return 1;
1258 }
1259
1260 sub umount_all {
1261     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1262
1263     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1264     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1265
1266     my $res = 1;
1267
1268     PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
1269         my ($ms, $mountpoint) = @_;
1270
1271         my $volid = $mountpoint->{volume};
1272         my $mount = $mountpoint->{mp};
1273
1274         return if !$volid || !$mount;
1275
1276         my $mount_path = "$rootdir/$mount";
1277         $mount_path =~ s!/+!/!g;
1278
1279         return if !PVE::ProcFSTools::is_mounted($mount_path);
1280
1281         eval {
1282             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1283         };
1284         if (my $err = $@) {
1285             if ($noerr) {
1286                 $res = 0;
1287                 warn $err;
1288             } else {
1289                 die $err;
1290             }
1291         }
1292     });
1293
1294     return $res; # tell caller if (some) umounts failed for the noerr case
1295 }
1296
1297 sub mount_all {
1298     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1299
1300     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1301     File::Path::make_path($rootdir);
1302
1303     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1304     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1305
1306     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1307
1308     eval {
1309         PVE::LXC::Config->foreach_mountpoint($conf, sub {
1310             my ($ms, $mountpoint) = @_;
1311
1312             $mountpoint->{ro} = 0 if $ignore_ro;
1313
1314             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1315         });
1316     };
1317     if (my $err = $@) {
1318         warn "mounting container failed\n";
1319         umount_all($vmid, $storage_cfg, $conf, 1);
1320         die $err;
1321     }
1322
1323     return $rootdir;
1324 }
1325
1326
1327 sub mountpoint_mount_path {
1328     my ($mountpoint, $storage_cfg, $snapname) = @_;
1329
1330     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1331 }
1332
1333 sub query_loopdev {
1334     my ($path) = @_;
1335     my $found;
1336     my $parser = sub {
1337         my $line = shift;
1338         if ($line =~ m@^(/dev/loop\d+):@) {
1339             $found = $1;
1340         }
1341     };
1342     my $cmd = ['losetup', '--associated', $path];
1343     PVE::Tools::run_command($cmd, outfunc => $parser);
1344     return $found;
1345 }
1346
1347 # Run a function with a file attached to a loop device.
1348 # The loop device is always detached afterwards (or set to autoclear).
1349 # Returns the loop device.
1350 sub run_with_loopdev {
1351     my ($func, $file, $readonly) = @_;
1352     my $device = query_loopdev($file);
1353     # Try to reuse an existing device
1354     if ($device) {
1355         # We assume that whoever setup the loop device is responsible for
1356         # detaching it.
1357         &$func($device);
1358         return $device;
1359     }
1360
1361     my $parser = sub {
1362         my $line = shift;
1363         if ($line =~ m@^(/dev/loop\d+)$@) {
1364             $device = $1;
1365         }
1366     };
1367     my $losetup_cmd = [
1368         'losetup',
1369         '--show',
1370         '-f',
1371         $file,
1372     ];
1373     push @$losetup_cmd, '-r' if $readonly;
1374     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1375     die "failed to setup loop device for $file\n" if !$device;
1376     eval { &$func($device); };
1377     my $err = $@;
1378     PVE::Tools::run_command(['losetup', '-d', $device]);
1379     die $err if $err;
1380     return $device;
1381 }
1382
1383 # In scalar mode: returns a file handle to the deepest directory node.
1384 # In list context: returns a list of:
1385 #   * the deepest directory node
1386 #   * the 2nd deepest directory (parent of the above)
1387 #   * directory name of the last directory
1388 # So that the path $2/$3 should lead to $1 afterwards.
1389 sub walk_tree_nofollow($$$;$$) {
1390     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1391
1392     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1393         or die "failed to open start directory $start: $!\n";
1394
1395     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1396 }
1397
1398
1399 sub walk_tree_nofollow_fd($$$$;$$) {
1400     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1401
1402     # splitdir() returns '' for empty components including the leading /
1403     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1404
1405     my $fd = $start_fd;
1406     my $dir = $start_dirname;
1407     my $last_component = undef;
1408     my $second = $fd;
1409     foreach my $component (@comps) {
1410         $dir .= "/$component";
1411         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1412
1413         if (!$next) {
1414             # failed, check for symlinks and try to create the path
1415             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1416             die "cannot open directory $dir: $!\n" if !$mkdir;
1417
1418             # We don't check for errors on mkdirat() here and just try to
1419             # openat() again, since at least one error (EEXIST) is an
1420             # expected possibility if multiple containers start
1421             # simultaneously. If someone else injects a symlink now then
1422             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1423             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1424
1425             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1426             die "failed to create path: $dir: $!\n" if !$next;
1427
1428             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1429                 if defined($rootuid) && defined($rootgid);
1430         }
1431
1432         close $second if defined($last_component) && $second != $start_fd;
1433         $last_component = $component;
1434         $second = $fd;
1435         $fd = $next;
1436     }
1437
1438     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1439     close $second if defined($last_component) && $second != $start_fd;
1440     return $fd;
1441 }
1442
1443 # To guard against symlink attack races against other currently running
1444 # containers with shared recursive bind mount hierarchies we prepare a
1445 # directory handle for the directory we're mounting over to verify the
1446 # mountpoint afterwards.
1447 sub __bindmount_prepare {
1448     my ($hostroot, $dir) = @_;
1449     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1450     return $srcdh;
1451 }
1452
1453 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1454 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1455 # we intended to bind mount.
1456 sub __bindmount_verify {
1457     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1458     my $destdh;
1459     if ($parentfd) {
1460         # Open the mount point path coming from the parent directory since the
1461         # filehandle we would have gotten as first result of walk_tree_nofollow
1462         # earlier is still a handle to the underlying directory instead of the
1463         # mounted path.
1464         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1465         die "failed to open mount point: $!\n" if !$destdh;
1466         if ($ro) {
1467             my $dot = '.';
1468             # no separate function because 99% of the time it's the wrong thing to use.
1469             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1470                 die "failed to mark bind mount read only\n";
1471             }
1472             die "read-only check failed: $!\n" if $! != EROFS;
1473         }
1474     } else {
1475         # For the rootfs we don't have a parentfd so we open the path directly.
1476         # Note that this means bindmounting any prefix of the host's
1477         # /var/lib/lxc/$vmid path into another container is considered a grave
1478         # security error.
1479         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1480         die "failed to open mount point: $!\n" if !$destdh;
1481     }
1482
1483     my ($srcdev, $srcinode) = stat($srcdh);
1484     my ($dstdev, $dstinode) = stat($destdh);
1485     close $srcdh;
1486     close $destdh;
1487
1488     return ($srcdev == $dstdev && $srcinode == $dstinode);
1489 }
1490
1491 # Perform the actual bind mounting:
1492 sub __bindmount_do {
1493     my ($dir, $dest, $ro, @extra_opts) = @_;
1494     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1495     if ($ro) {
1496         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1497         if (my $err = $@) {
1498             warn "bindmount error\n";
1499             # don't leave writable bind-mounts behind...
1500             PVE::Tools::run_command(['umount', $dest]);
1501             die $err;
1502         }
1503     }
1504 }
1505
1506 sub bindmount {
1507     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1508
1509     my $srcdh = __bindmount_prepare('/', $dir);
1510
1511     __bindmount_do($dir, $dest, $ro, @extra_opts);
1512
1513     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1514         PVE::Tools::run_command(['umount', $dest]);
1515         die "detected mount path change at: $dir\n";
1516     }
1517 }
1518
1519 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1520 # from $rootdir and $mount and walk the path from $rootdir to the final
1521 # directory to check for symlinks.
1522 sub __mount_prepare_rootdir {
1523     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1524     $rootdir =~ s!/+!/!g;
1525     $rootdir =~ s!/+$!!;
1526     my $mount_path = "$rootdir/$mount";
1527     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1528     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1529 }
1530
1531 # use $rootdir = undef to just return the corresponding mount path
1532 sub mountpoint_mount {
1533     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1534     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1535 }
1536
1537 sub mountpoint_stage {
1538     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1539     my ($path, $loop, $dev) =
1540         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1541
1542     if (!defined($path)) {
1543         return undef if $! == ENOSYS;
1544         die "failed to mount subvolume: $!\n";
1545     }
1546
1547     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1548     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1549     # point).
1550     my $err;
1551     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1552         or die "open_tree() on mount point failed: $!\n";
1553
1554     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1555 }
1556
1557 sub mountpoint_insert_staged {
1558     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1559
1560     if (!defined($rootdir_fd)) {
1561         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1562             or die "failed to open '.': $!\n";
1563     }
1564
1565     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1566
1567     PVE::Tools::move_mount(
1568         fileno($mount_fd),
1569         '',
1570         fileno($dest_fd),
1571         '',
1572         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1573     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1574 }
1575
1576 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1577 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1578 #   Note that if the kernel does not support the new mount API, this will not perform any action
1579 #   and return `undef` with $! = ENOSYS.
1580 sub __mountpoint_mount {
1581     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1582
1583     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1584         $! = ENOSYS;
1585         return undef;
1586     }
1587
1588     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1589     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1590     # which we use in __bindmount_verify()!
1591     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1592
1593     my $volid = $mountpoint->{volume};
1594     my $type = $mountpoint->{type};
1595     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1596     my $mounted_dev;
1597
1598     return if !$volid || !$mount;
1599
1600     $mount =~ s!/+!/!g;
1601
1602     my $mount_path;
1603     my ($mpfd, $parentfd, $last_dir);
1604
1605     if (defined($rootdir)) {
1606         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1607             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1608     }
1609
1610     if (defined($stage_mount)) {
1611         $mount_path = $rootdir;
1612     }
1613
1614     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1615
1616     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1617
1618     my $optlist = [];
1619
1620     if (my $mountopts = $mountpoint->{mountoptions}) {
1621         my @opts = split(/;/, $mountpoint->{mountoptions});
1622         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1623     }
1624
1625     my $acl = $mountpoint->{acl};
1626     if (defined($acl)) {
1627         push @$optlist, ($acl ? 'acl' : 'noacl');
1628     }
1629
1630     my $optstring = join(',', @$optlist);
1631     my $readonly = $mountpoint->{ro};
1632
1633     my @extra_opts;
1634     @extra_opts = ('-o', $optstring) if $optstring;
1635
1636     if ($storage) {
1637
1638         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1639
1640         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1641
1642         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1643
1644         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1645             PVE::Storage::parse_volname($storage_cfg, $volid);
1646
1647         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1648
1649         if ($format eq 'subvol') {
1650             if ($mount_path) {
1651                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1652                 if (defined($snapname)) {
1653                     $name .= "\@$snapname";
1654                     if ($scfg->{type} eq 'zfspool') {
1655                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1656                     } else {
1657                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1658                     }
1659                 } else {
1660                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1661                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1662                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1663                     }
1664                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1665                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1666                 }
1667             }
1668             return wantarray ? ($path, 0, undef) : $path;
1669         } elsif ($format eq 'raw' || $format eq 'iso') {
1670             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1671             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1672             # Our autodev hook expects the /dev/dm-* device currently
1673             # and will create the /dev/mapper symlink accordingly
1674             $path = Cwd::realpath($path);
1675             die "failed to get device path\n" if !$path;
1676             ($path) = ($path =~ /^(.*)$/s); #untaint
1677             my $domount = sub {
1678                 my ($path) = @_;
1679                 if ($mount_path) {
1680                     if ($format eq 'iso') {
1681                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1682                     } elsif ($isBase || defined($snapname)) {
1683                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1684                     } else {
1685                         if ($quota) {
1686                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1687                         }
1688                         push @extra_opts, '-o', 'ro' if $readonly;
1689                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1690                     }
1691                 }
1692             };
1693             my $use_loopdev = 0;
1694             if ($scfg->{path}) {
1695                 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1696                 $use_loopdev = 1;
1697             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1698                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1699                 $mounted_dev = $path;
1700                 &$domount($path);
1701             } else {
1702                 die "unsupported storage type '$scfg->{type}'\n";
1703             }
1704             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1705         } else {
1706             die "unsupported image format '$format'\n";
1707         }
1708     } elsif ($type eq 'device') {
1709         push @extra_opts, '-o', 'ro' if $readonly;
1710         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1711         # See the NOTE above about devicemapper canonicalization
1712         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1713         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1714         return wantarray ? ($volid, 0, $devpath) : $volid;
1715     } elsif ($type eq 'bind') {
1716         die "directory '$volid' does not exist\n" if ! -d $volid;
1717         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1718         warn "cannot enable quota control for bind mounts\n" if $quota;
1719         return wantarray ? ($volid, 0, undef) : $volid;
1720     }
1721
1722     die "unsupported storage";
1723 }
1724
1725 sub mountpoint_hotplug($$$) {
1726     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1727
1728     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1729
1730     # We do the rest in a fork with an unshared mount namespace, because:
1731     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1732     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1733     #     container's namespace, then mount it.
1734
1735     PVE::Tools::run_fork(sub {
1736         # Pin the container pid longer, we also need to get its monitor/parent:
1737         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1738             or die "failed to open pidfd of container $vmid\'s init process\n";
1739
1740         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1741             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1742
1743         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1744         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1745
1746         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1747         # profile to lower our privileges to the same level we have in the start hook:
1748         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1749             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1750         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1751         # apparmor.
1752
1753         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1754         # namespace for it to remain active there since the container will be able to unmount
1755         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1756         # concern.
1757         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1758         chdir('/')
1759             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1760
1761         my $dir = get_staging_mount_path($opt);
1762
1763         # Now switch our apparmor profile before mounting:
1764         my $data = 'changeprofile /usr/bin/lxc-start';
1765         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1766             die "failed to change apparmor profile: $!\n";
1767         }
1768         # Check errors on close as well:
1769         close($aa_fd)
1770             or die "failed to change apparmor profile (close() failed): $!\n";
1771
1772         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1773
1774         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1775         chdir('/')
1776             or die "failed to change root directory within the container's mount namespace: $!\n";
1777
1778         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1779     });
1780 }
1781
1782 # Create a directory in the mountpoint staging tempfs.
1783 sub get_staging_mount_path($) {
1784     my ($opt) = @_;
1785
1786     my $target = get_staging_tempfs() . "/$opt";
1787     if (!mkdir($target) && $! != EEXIST) {
1788         die "failed to create directory $target: $!\n";
1789     }
1790
1791     return $target;
1792 }
1793
1794 # Mount /run/pve/mountpoints as tmpfs
1795 sub get_staging_tempfs() {
1796     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1797     # mounts to that.
1798     my $target = '/var/lib/lxc/.pve-staged-mounts';
1799     if (!mkdir($target)) {
1800         return $target if $! == EEXIST;
1801         die "failed to create directory $target: $!\n";
1802     }
1803
1804     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1805         or die "failed to mount $target as tmpfs: $!\n";
1806
1807     return $target;
1808 }
1809
1810 sub mkfs {
1811     my ($dev, $rootuid, $rootgid) = @_;
1812
1813     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1814                              '-E', "root_owner=$rootuid:$rootgid",
1815                              $dev]);
1816 }
1817
1818 sub format_disk {
1819     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1820
1821     if ($volid =~ m!^/dev/.+!) {
1822         mkfs($volid);
1823         return;
1824     }
1825
1826     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1827
1828     die "cannot format volume '$volid' with no storage\n" if !$storage;
1829
1830     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1831
1832     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1833
1834     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1835
1836     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1837         PVE::Storage::parse_volname($storage_cfg, $volid);
1838
1839     die "cannot format volume '$volid' (format == $format)\n"
1840         if $format ne 'raw';
1841
1842     mkfs($path, $rootuid, $rootgid);
1843 }
1844
1845 sub destroy_disks {
1846     my ($storecfg, $vollist) = @_;
1847
1848     foreach my $volid (@$vollist) {
1849         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1850         warn $@ if $@;
1851     }
1852 }
1853
1854 sub alloc_disk {
1855     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1856
1857     my $needs_chown = 0;
1858     my $volid;
1859
1860     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1861     # fixme: use better naming ct-$vmid-disk-X.raw?
1862
1863     eval {
1864         my $do_format = 0;
1865         if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1866             if ($size_kb > 0) {
1867                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1868                                                    undef, $size_kb);
1869                 $do_format = 1;
1870             } else {
1871                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1872                                                    undef, 0);
1873                 $needs_chown = 1;
1874             }
1875         } elsif ($scfg->{type} eq 'zfspool') {
1876
1877             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1878                                                undef, $size_kb);
1879             $needs_chown = 1;
1880         } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1881
1882             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1883             $do_format = 1;
1884
1885         } elsif ($scfg->{type} eq 'rbd') {
1886
1887             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1888             $do_format = 1;
1889         } else {
1890             die "unable to create containers on storage type '$scfg->{type}'\n";
1891         }
1892         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1893     };
1894     if (my $err = $@) {
1895         # in case formatting got interrupted:
1896         if (defined($volid)) {
1897             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1898             warn $@ if $@;
1899         }
1900         die $err;
1901     }
1902
1903     return ($volid, $needs_chown);
1904 }
1905
1906 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1907 sub create_disks {
1908     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1909
1910     my $vollist = [];
1911
1912     eval {
1913         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1914         my $chown_vollist = [];
1915
1916         PVE::LXC::Config->foreach_mountpoint($settings, sub {
1917             my ($ms, $mountpoint) = @_;
1918
1919             my $volid = $mountpoint->{volume};
1920             my $mp = $mountpoint->{mp};
1921
1922             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1923
1924             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1925                 my ($storeid, $size_gb) = ($1, $2);
1926
1927                 my $size_kb = int(${size_gb}*1024) * 1024;
1928
1929                 my $needs_chown = 0;
1930                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1931                 push @$chown_vollist, $volid if $needs_chown;
1932                 push @$vollist, $volid;
1933                 $mountpoint->{volume} = $volid;
1934                 $mountpoint->{size} = $size_kb * 1024;
1935                 if ($pending) {
1936                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1937                 } else {
1938                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1939                 }
1940             } else {
1941                 # use specified/existing volid/dir/device
1942                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1943             }
1944         });
1945
1946         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1947         foreach my $volid (@$chown_vollist) {
1948             my $path = PVE::Storage::path($storecfg, $volid, undef);
1949             chown($rootuid, $rootgid, $path);
1950         }
1951         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1952     };
1953     # free allocated images on error
1954     if (my $err = $@) {
1955         destroy_disks($storecfg, $vollist);
1956         die $err;
1957     }
1958     return $vollist;
1959 }
1960
1961 sub update_disksize {
1962     my ($vmid, $conf, $all_volumes) = @_;
1963
1964     my $changes;
1965     my $prefix = "CT $vmid:";
1966
1967     my $update_mp = sub {
1968         my ($key, $mp, @param) = @_;
1969         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1970
1971         if (!defined($mp->{size}) || $size != $mp->{size}) {
1972             $changes = 1;
1973             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1974             $mp->{size} = $size;
1975             my $nomp = 1 if ($key eq 'rootfs');
1976             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1977         }
1978     };
1979
1980     PVE::LXC::Config->foreach_mountpoint($conf, $update_mp);
1981
1982     return $changes;
1983 }
1984
1985 sub update_unused {
1986     my ($vmid, $conf, $all_volumes) = @_;
1987
1988     my $changes;
1989     my $prefix = "CT $vmid:";
1990
1991     # Note: it is allowed to define multiple storage entries with the same path
1992     # (alias), so we need to check both 'volid' and real 'path' (two different
1993     # volid can point to the same path).
1994
1995     # used and unused disks
1996     my $refpath = {};
1997     my $orphans = {};
1998
1999     foreach my $opt (keys %$conf) {
2000         next if ($opt !~ m/^unused\d+$/);
2001         my $vol = $all_volumes->{$conf->{$opt}};
2002         $refpath->{$vol->{path}} = $vol->{volid};
2003     }
2004
2005     foreach my $key (keys %$all_volumes) {
2006         my $vol = $all_volumes->{$key};
2007         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2008         my $path = $vol->{path};
2009
2010         if ($in_use) {
2011             $refpath->{$path} = $key;
2012             delete $orphans->{$path};
2013         } else {
2014             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2015                 $orphans->{$path} = $key;
2016             }
2017         }
2018     }
2019
2020     for my $key (keys %$orphans) {
2021         my $disk = $orphans->{$key};
2022         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2023
2024         if ($unused) {
2025             $changes = 1;
2026             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2027         }
2028     }
2029
2030     return $changes;
2031 }
2032
2033 sub scan_volids {
2034     my ($cfg, $vmid) = @_;
2035
2036     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid);
2037
2038     my $all_volumes = {};
2039     foreach my $storeid (keys %$info) {
2040         foreach my $item (@{$info->{$storeid}}) {
2041             my $volid = $item->{volid};
2042             next if !($volid && $item->{size});
2043             $item->{path} = PVE::Storage::path($cfg, $volid);
2044             $all_volumes->{$volid} = $item;
2045         }
2046     }
2047
2048     return $all_volumes;
2049 }
2050
2051 sub rescan {
2052     my ($vmid, $nolock, $dryrun) = @_;
2053
2054     my $cfg = PVE::Storage::config();
2055
2056     # FIXME: Remove once our RBD plugin can handle CT and VM on a single storage
2057     # see: https://pve.proxmox.com/pipermail/pve-devel/2018-July/032900.html
2058     foreach my $stor (keys %{$cfg->{ids}}) {
2059         delete($cfg->{ids}->{$stor}) if !$cfg->{ids}->{$stor}->{content}->{rootdir};
2060     }
2061
2062     print "rescan volumes...\n";
2063     my $all_volumes = scan_volids($cfg, $vmid);
2064
2065     my $updatefn =  sub {
2066         my ($vmid) = @_;
2067
2068         my $changes;
2069         my $conf = PVE::LXC::Config->load_config($vmid);
2070
2071         PVE::LXC::Config->check_lock($conf);
2072
2073         my $vm_volids = {};
2074         foreach my $volid (keys %$all_volumes) {
2075             my $info = $all_volumes->{$volid};
2076             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2077         }
2078
2079         my $upu = update_unused($vmid, $conf, $vm_volids);
2080         my $upd = update_disksize($vmid, $conf, $vm_volids);
2081         $changes = $upu || $upd;
2082
2083         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2084     };
2085
2086     if (defined($vmid)) {
2087         if ($nolock) {
2088             &$updatefn($vmid);
2089         } else {
2090             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2091         }
2092     } else {
2093         my $vmlist = config_list();
2094         foreach my $vmid (keys %$vmlist) {
2095             if ($nolock) {
2096                 &$updatefn($vmid);
2097             } else {
2098                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2099             }
2100         }
2101     }
2102 }
2103
2104
2105 # bash completion helper
2106
2107 sub complete_os_templates {
2108     my ($cmdname, $pname, $cvalue) = @_;
2109
2110     my $cfg = PVE::Storage::config();
2111
2112     my $storeid;
2113
2114     if ($cvalue =~ m/^([^:]+):/) {
2115         $storeid = $1;
2116     }
2117
2118     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2119     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2120
2121     my $res = [];
2122     foreach my $id (keys %$data) {
2123         foreach my $item (@{$data->{$id}}) {
2124             push @$res, $item->{volid} if defined($item->{volid});
2125         }
2126     }
2127
2128     return $res;
2129 }
2130
2131 my $complete_ctid_full = sub {
2132     my ($running) = @_;
2133
2134     my $idlist = vmstatus();
2135
2136     my $active_hash = list_active_containers();
2137
2138     my $res = [];
2139
2140     foreach my $id (keys %$idlist) {
2141         my $d = $idlist->{$id};
2142         if (defined($running)) {
2143             next if $d->{template};
2144             next if $running && !$active_hash->{$id};
2145             next if !$running && $active_hash->{$id};
2146         }
2147         push @$res, $id;
2148
2149     }
2150     return $res;
2151 };
2152
2153 sub complete_ctid {
2154     return &$complete_ctid_full();
2155 }
2156
2157 sub complete_ctid_stopped {
2158     return &$complete_ctid_full(0);
2159 }
2160
2161 sub complete_ctid_running {
2162     return &$complete_ctid_full(1);
2163 }
2164
2165 sub parse_id_maps {
2166     my ($conf) = @_;
2167
2168     my $id_map = [];
2169     my $rootuid = 0;
2170     my $rootgid = 0;
2171
2172     my $lxc = $conf->{lxc};
2173     foreach my $entry (@$lxc) {
2174         my ($key, $value) = @$entry;
2175         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2176         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2177         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2178             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2179             push @$id_map, [$type, $ct, $host, $length];
2180             if ($ct == 0) {
2181                 $rootuid = $host if $type eq 'u';
2182                 $rootgid = $host if $type eq 'g';
2183             }
2184         } else {
2185             die "failed to parse idmap: $value\n";
2186         }
2187     }
2188
2189     if (!@$id_map && $conf->{unprivileged}) {
2190         # Should we read them from /etc/subuid?
2191         $id_map = [ ['u', '0', '100000', '65536'],
2192                     ['g', '0', '100000', '65536'] ];
2193         $rootuid = $rootgid = 100000;
2194     }
2195
2196     return ($id_map, $rootuid, $rootgid);
2197 }
2198
2199 sub userns_command {
2200     my ($id_map) = @_;
2201     if (@$id_map) {
2202         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2203     }
2204     return [];
2205 }
2206
2207 sub vm_start {
2208     my ($vmid, $conf, $skiplock) = @_;
2209
2210     # apply pending changes while starting
2211     if (scalar(keys %{$conf->{pending}})) {
2212         my $storecfg = PVE::Storage::config();
2213         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2214         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2215     }
2216
2217     update_lxc_config($vmid, $conf);
2218
2219     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2220
2221     if ($skiplock) {
2222         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2223         close($fh);
2224     }
2225
2226     my $cmd = ['systemctl', 'start', "pve-container\@$vmid"];
2227
2228     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2229     eval { PVE::Tools::run_command($cmd); };
2230     if (my $err = $@) {
2231         unlink $skiplock_flag_fn;
2232         die $err;
2233     }
2234     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2235
2236     return;
2237 }
2238
2239 # Helper to stop a container completely and make sure it has stopped completely.
2240 # This is necessary because we want the post-stop hook to have completed its
2241 # unmount-all step, but post-stop happens after lxc puts the container into the
2242 # STOPPED state.
2243 # $kill - if true it will always do an immediate hard-stop
2244 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2245 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2246 sub vm_stop {
2247     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2248
2249     # Open the container's command socket.
2250     my $path = "\0/var/lib/lxc/$vmid/command";
2251     my $sock = IO::Socket::UNIX->new(
2252         Type => SOCK_STREAM(),
2253         Peer => $path,
2254     );
2255     if (!$sock) {
2256         return if $! == ECONNREFUSED; # The container is not running
2257         die "failed to open container ${vmid}'s command socket: $!\n";
2258     }
2259
2260     my $conf = PVE::LXC::Config->load_config($vmid);
2261     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2262
2263     # Stop the container:
2264
2265     my $cmd = ['lxc-stop', '-n', $vmid];
2266
2267     if ($kill) {
2268         push @$cmd, '--kill'; # doesn't allow timeouts
2269     } else {
2270         # lxc-stop uses a default timeout
2271         push @$cmd, '--nokill' if !$kill_after_timeout;
2272
2273         if (defined($shutdown_timeout)) {
2274             push @$cmd, '--timeout', $shutdown_timeout;
2275             # Give run_command 5 extra seconds
2276             $shutdown_timeout += 5;
2277         }
2278     }
2279
2280     eval { PVE::Tools::run_command($cmd, timeout => $shutdown_timeout) };
2281     if (my $err = $@) {
2282         warn $@ if $@;
2283     }
2284
2285     my $result = <$sock>;
2286
2287     return if !defined $result; # monitor is gone and the ct has stopped.
2288     die "container did not stop\n";
2289 }
2290
2291 sub vm_reboot {
2292     my ($vmid, $timeout, $skiplock) = @_;
2293
2294     PVE::LXC::Config->lock_config($vmid, sub {
2295         return if !check_running($vmid);
2296
2297         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2298
2299         my $conf = PVE::LXC::Config->load_config($vmid);
2300         vm_start($vmid, $conf);
2301     });
2302 }
2303
2304 sub run_unshared {
2305     my ($code) = @_;
2306
2307     return PVE::Tools::run_fork(sub {
2308         # Unshare the mount namespace
2309         die "failed to unshare mount namespace: $!\n"
2310             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2311         PVE::Tools::run_command(['mount', '--make-rslave', '/']);
2312         return $code->();
2313     });
2314 }
2315
2316 my $copy_volume = sub {
2317     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2318
2319     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2320     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2321
2322     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2323     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2324
2325     my @mounted;
2326     eval {
2327         # mount and copy
2328         mkdir $src;
2329         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2330         push @mounted, $src;
2331         mkdir $dest;
2332         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2333         push @mounted, $dest;
2334
2335         $bwlimit //= 0;
2336
2337         PVE::Tools::run_command(['/usr/bin/rsync', '--stats', '-X', '-A', '--numeric-ids',
2338                                  '-aH', '--whole-file', '--sparse', '--one-file-system',
2339                                  "--bwlimit=$bwlimit", "$src/", $dest]);
2340     };
2341     my $err = $@;
2342
2343     # Wait for rsync's children to release dest so that
2344     # consequent file operations (umount, remove) are possible
2345     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2346
2347     foreach my $mount (reverse @mounted) {
2348         eval { PVE::Tools::run_command(['/bin/umount', $mount], errfunc => sub{})};
2349         warn "Can't umount $mount\n" if $@;
2350     }
2351
2352     # If this fails they're used as mount points in a concurrent operation
2353     # (which should not happen but there's also no real need to get rid of them).
2354     rmdir $dest;
2355     rmdir $src;
2356
2357     die $err if $err;
2358 };
2359
2360 # Should not be called after unsharing the mount namespace!
2361 sub copy_volume {
2362     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2363
2364     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2365     File::Path::make_path("/var/lib/lxc/$vmid");
2366     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2367     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2368
2369     # get id's for unprivileged container
2370     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2371
2372     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2373     # are visible in this namespace, otherwise the host only sees the empty
2374     # (not-mounted) directory.
2375     my $new_volid;
2376     eval {
2377         # Make sure $mp contains a correct size.
2378         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2379         my $needs_chown;
2380         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2381         if ($needs_chown) {
2382             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2383             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2384             chown($rootuid, $rootgid, $path);
2385         }
2386
2387         run_unshared(sub {
2388             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2389         });
2390     };
2391     if (my $err = $@) {
2392         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2393             if defined($new_volid);
2394         die $err;
2395     }
2396
2397     return $new_volid;
2398 }
2399
2400 1;