src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::Tools qw($IPV6RE $IPV4RE dir_glob_foreach lock_file lock_file_full O_PATH);
  22 use PVE::CpuSet;
  23 use PVE::Network;
  24 use PVE::AccessControl;
  25 use PVE::ProcFSTools;
  26 use PVE::Syscall;
  27 use PVE::LXC::Config;
  28 use Time::HiRes qw (gettimeofday);
  29
  30 my $nodename = PVE::INotify::nodename();
  31
  32 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  33
  34 sub config_list {
  35     my $vmlist = PVE::Cluster::get_vmlist();
  36     my $res = {};
  37     return $res if !$vmlist || !$vmlist->{ids};
  38     my $ids = $vmlist->{ids};
  39
  40     foreach my $vmid (keys %$ids) {
  41         next if !$vmid; # skip CT0
  42         my $d = $ids->{$vmid};
  43         next if !$d->{node} || $d->{node} ne $nodename;
  44         next if !$d->{type} || $d->{type} ne 'lxc';
  45         $res->{$vmid}->{type} = 'lxc';
  46     }
  47     return $res;
  48 }
  49
  50 sub destroy_config {
  51     my ($vmid) = @_;
  52
  53     unlink PVE::LXC::Config->config_file($vmid, $nodename);
  54 }
  55
  56 # container status helpers
  57
  58 sub list_active_containers {
  59
  60     my $filename = "/proc/net/unix";
  61
  62     # similar test is used by lcxcontainers.c: list_active_containers
  63     my $res = {};
  64
  65     my $fh = IO::File->new ($filename, "r");
  66     return $res if !$fh;
  67
  68     while (defined(my $line = <$fh>)) {
  69         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  70             my $path = $1;
  71             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  72                 $res->{$1} = 1;
  73             }
  74         }
  75     }
  76
  77     close($fh);
  78
  79     return $res;
  80 }
  81
  82 # warning: this is slow
  83 sub check_running {
  84     my ($vmid) = @_;
  85
  86     my $active_hash = list_active_containers();
  87
  88     return 1 if defined($active_hash->{$vmid});
  89
  90     return undef;
  91 }
  92
  93 sub get_container_disk_usage {
  94     my ($vmid, $pid) = @_;
  95
  96     return PVE::Tools::df("/proc/$pid/root/", 1);
  97 }
  98
  99 my $last_proc_vmid_stat;
 100
 101 my $parse_cpuacct_stat = sub {
 102     my ($vmid, $unprivileged) = @_;
 103
 104     my $raw = read_cgroup_value('cpuacct', $vmid, $unprivileged, 'cpuacct.stat', 1);
 105
 106     my $stat = {};
 107
 108     if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
 109
 110         $stat->{utime} = $1;
 111         $stat->{stime} = $2;
 112
 113     }
 114
 115     return $stat;
 116 };
 117
 118 sub vmstatus {
 119     my ($opt_vmid) = @_;
 120
 121     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc' }} : config_list();
 122
 123     my $active_hash = list_active_containers();
 124
 125     my $cpucount = $cpuinfo->{cpus} || 1;
 126
 127     my $cdtime = gettimeofday;
 128
 129     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 130     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 131
 132     my $unprivileged = {};
 133
 134     foreach my $vmid (keys %$list) {
 135         my $d = $list->{$vmid};
 136
 137         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 138         warn $@ if $@; # ignore errors (consider them stopped)
 139
 140         $d->{status} = $d->{pid} ? 'running' : 'stopped';
 141
 142         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 143         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 144
 145         $unprivileged->{$vmid} = $conf->{unprivileged};
 146
 147         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 148         $d->{name} =~ s/[\s]//g;
 149
 150         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 151         $d->{cpus} = $cpucount if !$d->{cpus};
 152
 153         $d->{lock} = $conf->{lock} || '';
 154
 155         if ($d->{pid}) {
 156             my $res = get_container_disk_usage($vmid, $d->{pid});
 157             $d->{disk} = $res->{used};
 158             $d->{maxdisk} = $res->{total};
 159         } else {
 160             $d->{disk} = 0;
 161             # use 4GB by default ??
 162             if (my $rootfs = $conf->{rootfs}) {
 163                 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
 164                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 165             } else {
 166                 $d->{maxdisk} = 4*1024*1024*1024;
 167             }
 168         }
 169
 170         $d->{mem} = 0;
 171         $d->{swap} = 0;
 172         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 173         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 174
 175         $d->{uptime} = 0;
 176         $d->{cpu} = 0;
 177
 178         $d->{netout} = 0;
 179         $d->{netin} = 0;
 180
 181         $d->{diskread} = 0;
 182         $d->{diskwrite} = 0;
 183
 184         $d->{template} = PVE::LXC::Config->is_template($conf);
 185     }
 186
 187     foreach my $vmid (keys %$list) {
 188         my $d = $list->{$vmid};
 189         my $pid = $d->{pid};
 190
 191         next if !$pid; # skip stopped CTs
 192
 193         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 194         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 195
 196         my $unpriv = $unprivileged->{$vmid};
 197
 198         my $memory_stat = read_cgroup_list('memory', $vmid, $unpriv, 'memory.stat');
 199         my $mem_usage_in_bytes = read_cgroup_value('memory', $vmid, $unpriv, 'memory.usage_in_bytes');
 200
 201         $d->{mem} = $mem_usage_in_bytes - $memory_stat->{total_cache};
 202         $d->{swap} = read_cgroup_value('memory', $vmid, $unpriv, 'memory.memsw.usage_in_bytes') - $mem_usage_in_bytes;
 203
 204         my $blkio_bytes = read_cgroup_value('blkio', $vmid, $unpriv, 'blkio.throttle.io_service_bytes', 1);
 205         my @bytes = split(/\n/, $blkio_bytes);
 206         foreach my $byte (@bytes) {
 207             if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 208                 $d->{diskread} += $2 if $key eq 'Read';
 209                 $d->{diskwrite} += $2 if $key eq 'Write';
 210             }
 211         }
 212
 213         my $pstat = $parse_cpuacct_stat->($vmid, $unpriv);
 214
 215         my $used = $pstat->{utime} + $pstat->{stime};
 216
 217         my $old = $last_proc_vmid_stat->{$vmid};
 218         if (!$old) {
 219             $last_proc_vmid_stat->{$vmid} = {
 220                 time => $cdtime,
 221                 used => $used,
 222                 cpu => 0,
 223             };
 224             next;
 225         }
 226
 227         my $dtime = ($cdtime -  $old->{time}) * $cpucount * $cpuinfo->{user_hz};
 228
 229         if ($dtime > 1000) {
 230             my $dutime = $used -  $old->{used};
 231
 232             $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
 233             $last_proc_vmid_stat->{$vmid} = {
 234                 time => $cdtime,
 235                 used => $used,
 236                 cpu => $d->{cpu},
 237             };
 238         } else {
 239             $d->{cpu} = $old->{cpu};
 240         }
 241     }
 242
 243     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 244
 245     foreach my $dev (keys %$netdev) {
 246         next if $dev !~ m/^veth([1-9]\d*)i/;
 247         my $vmid = $1;
 248         my $d = $list->{$vmid};
 249
 250         next if !$d;
 251
 252         $d->{netout} += $netdev->{$dev}->{receive};
 253         $d->{netin} += $netdev->{$dev}->{transmit};
 254
 255     }
 256
 257     return $list;
 258 }
 259
 260 sub read_cgroup_list($$$$) {
 261     my ($group, $vmid, $unprivileged, $name) = @_;
 262
 263     my $content = read_cgroup_value($group, $vmid, $unprivileged, $name, 1);
 264
 265     return { split(/\s+/, $content) };
 266 }
 267
 268 sub read_cgroup_value($$$$$) {
 269     my ($group, $vmid, $unprivileged, $name, $full) = @_;
 270
 271     my $nsdir = $unprivileged ? '' : 'ns/';
 272     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/${nsdir}$name";
 273
 274     return PVE::Tools::file_get_contents($path) if $full;
 275
 276     return PVE::Tools::file_read_firstline($path);
 277 }
 278
 279 sub write_cgroup_value {
 280    my ($group, $vmid, $name, $value) = @_;
 281
 282    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 283    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 284
 285 }
 286
 287 sub find_lxc_console_pids {
 288
 289     my $res = {};
 290
 291     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 292         my ($pid) = @_;
 293
 294         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 295         return if !$cmdline;
 296
 297         my @args = split(/\0/, $cmdline);
 298
 299         # search for lxc-console -n <vmid>
 300         return if scalar(@args) != 3;
 301         return if $args[1] ne '-n';
 302         return if $args[2] !~ m/^\d+$/;
 303         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 304
 305         my $vmid = $args[2];
 306
 307         push @{$res->{$vmid}}, $pid;
 308     });
 309
 310     return $res;
 311 }
 312
 313 sub find_lxc_pid {
 314     my ($vmid) = @_;
 315
 316     my $pid = undef;
 317     my $parser = sub {
 318         my $line = shift;
 319         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 320     };
 321     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 322
 323     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 324
 325     return $pid;
 326 }
 327
 328 # Note: we cannot use Net:IP, because that only allows strict
 329 # CIDR networks
 330 sub parse_ipv4_cidr {
 331     my ($cidr, $noerr) = @_;
 332
 333     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 334         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 335     }
 336
 337     return undef if $noerr;
 338
 339     die "unable to parse ipv4 address/mask\n";
 340 }
 341
 342
 343 sub update_lxc_config {
 344     my ($vmid, $conf) = @_;
 345
 346     my $dir = "/var/lib/lxc/$vmid";
 347
 348     if ($conf->{template}) {
 349
 350         unlink "$dir/config";
 351
 352         return;
 353     }
 354
 355     my $raw = '';
 356
 357     die "missing 'arch' - internal error" if !$conf->{arch};
 358     $raw .= "lxc.arch = $conf->{arch}\n";
 359
 360     my $unprivileged = $conf->{unprivileged};
 361     my $custom_idmap = grep { $_->[0] eq 'lxc.idmap' } @{$conf->{lxc}};
 362
 363     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 364
 365     my $cfgpath = '/usr/share/lxc/config';
 366     my $inc = "$cfgpath/$ostype.common.conf";
 367     $inc ="$cfgpath/common.conf" if !-f $inc;
 368     $raw .= "lxc.include = $inc\n";
 369     if ($unprivileged || $custom_idmap) {
 370         $inc = "$cfgpath/$ostype.userns.conf";
 371         $inc = "$cfgpath/userns.conf" if !-f $inc;
 372         $raw .= "lxc.include = $inc\n";
 373         $raw .= "lxc.seccomp.profile = $cfgpath/pve-userns.seccomp\n";
 374     }
 375
 376     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 377     # cannot be exposed to the container with r/w access (cgroup perms).
 378     # When this is enabled mounts will still remain in the monitor's namespace
 379     # after the container unmounted them and thus will not detach from their
 380     # files while the container is running!
 381     $raw .= "lxc.monitor.unshare = 1\n";
 382
 383     # Should we read them from /etc/subuid?
 384     if ($unprivileged && !$custom_idmap) {
 385         $raw .= "lxc.idmap = u 0 100000 65536\n";
 386         $raw .= "lxc.idmap = g 0 100000 65536\n";
 387     }
 388
 389     if (!PVE::LXC::Config->has_dev_console($conf)) {
 390         $raw .= "lxc.console.path = none\n";
 391         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 392     }
 393
 394     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 395     $raw .= "lxc.tty.max = $ttycount\n";
 396
 397     # some init scripts expect a linux terminal (turnkey).
 398     $raw .= "lxc.environment = TERM=linux\n";
 399
 400     my $utsname = $conf->{hostname} || "CT$vmid";
 401     $raw .= "lxc.uts.name = $utsname\n";
 402
 403     my $memory = $conf->{memory} || 512;
 404     my $swap = $conf->{swap} // 0;
 405
 406     my $lxcmem = int($memory*1024*1024);
 407     $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 408
 409     my $lxcswap = int(($memory + $swap)*1024*1024);
 410     $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 411
 412     if (my $cpulimit = $conf->{cpulimit}) {
 413         $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 414         my $value = int(100000*$cpulimit);
 415         $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 416     }
 417
 418     my $shares = $conf->{cpuunits} || 1024;
 419     $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 420
 421     die "missing 'rootfs' configuration\n"
 422         if !defined($conf->{rootfs});
 423
 424     my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 425
 426     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 427
 428     foreach my $k (sort keys %$conf) {
 429         next if $k !~ m/^net(\d+)$/;
 430         my $ind = $1;
 431         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 432         $raw .= "lxc.net.$ind.type = veth\n";
 433         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 434         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 435         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 436         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 437     }
 438
 439     my $had_cpuset = 0;
 440     if (my $lxcconf = $conf->{lxc}) {
 441         foreach my $entry (@$lxcconf) {
 442             my ($k, $v) = @$entry;
 443             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus';
 444             $raw .= "$k = $v\n";
 445         }
 446     }
 447
 448     my $cores = $conf->{cores};
 449     if (!$had_cpuset && $cores) {
 450         my $cpuset = eval { PVE::CpuSet->new_from_cgroup('lxc', 'effective_cpus') };
 451         $cpuset = PVE::CpuSet->new_from_cgroup('', 'effective_cpus') if !$cpuset;
 452         my @members = $cpuset->members();
 453         while (scalar(@members) > $cores) {
 454             my $randidx = int(rand(scalar(@members)));
 455             $cpuset->delete($members[$randidx]);
 456             splice(@members, $randidx, 1); # keep track of the changes
 457         }
 458         $raw .= "lxc.cgroup.cpuset.cpus = ".$cpuset->short_string()."\n";
 459     }
 460
 461     File::Path::mkpath("$dir/rootfs");
 462
 463     PVE::Tools::file_set_contents("$dir/config", $raw);
 464 }
 465
 466 # verify and cleanup nameserver list (replace \0 with ' ')
 467 sub verify_nameserver_list {
 468     my ($nameserver_list) = @_;
 469
 470     my @list = ();
 471     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 472         PVE::JSONSchema::pve_verify_ip($server);
 473         push @list, $server;
 474     }
 475
 476     return join(' ', @list);
 477 }
 478
 479 sub verify_searchdomain_list {
 480     my ($searchdomain_list) = @_;
 481
 482     my @list = ();
 483     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 484         # todo: should we add checks for valid dns domains?
 485         push @list, $server;
 486     }
 487
 488     return join(' ', @list);
 489 }
 490
 491 sub get_console_command {
 492     my ($vmid, $conf, $noescapechar) = @_;
 493
 494     my $cmode = PVE::LXC::Config->get_cmode($conf);
 495
 496     my $cmd = [];
 497     if ($cmode eq 'console') {
 498         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 499         push @$cmd, '-e', -1 if $noescapechar;
 500     } elsif ($cmode eq 'tty') {
 501         push @$cmd, 'lxc-console', '-n',  $vmid;
 502         push @$cmd, '-e', -1 if $noescapechar;
 503     } elsif ($cmode eq 'shell') {
 504         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 505     } else {
 506         die "internal error";
 507     }
 508
 509     return $cmd;
 510 }
 511
 512 sub get_primary_ips {
 513     my ($conf) = @_;
 514
 515     # return data from net0
 516
 517     return undef if !defined($conf->{net0});
 518     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 519
 520     my $ipv4 = $net->{ip};
 521     if ($ipv4) {
 522         if ($ipv4 =~ /^(dhcp|manual)$/) {
 523             $ipv4 = undef
 524         } else {
 525             $ipv4 =~ s!/\d+$!!;
 526         }
 527     }
 528     my $ipv6 = $net->{ip6};
 529     if ($ipv6) {
 530         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 531             $ipv6 = undef;
 532         } else {
 533             $ipv6 =~ s!/\d+$!!;
 534         }
 535     }
 536
 537     return ($ipv4, $ipv6);
 538 }
 539
 540 sub delete_mountpoint_volume {
 541     my ($storage_cfg, $vmid, $volume) = @_;
 542
 543     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 544
 545     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 546     PVE::Storage::vdisk_free($storage_cfg, $volume) if $vmid == $owner;
 547 }
 548
 549 sub destroy_lxc_container {
 550     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 551
 552     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 553         my ($ms, $mountpoint) = @_;
 554         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 555     });
 556
 557     rmdir "/var/lib/lxc/$vmid/rootfs";
 558     unlink "/var/lib/lxc/$vmid/config";
 559     rmdir "/var/lib/lxc/$vmid";
 560     if (defined $replacement_conf) {
 561         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 562     } else {
 563         destroy_config($vmid);
 564     }
 565
 566     #my $cmd = ['lxc-destroy', '-n', $vmid ];
 567     #PVE::Tools::run_command($cmd);
 568 }
 569
 570 sub vm_stop_cleanup {
 571     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 572
 573     eval {
 574         if (!$keepActive) {
 575
 576             my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 577             PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 578         }
 579     };
 580     warn $@ if $@; # avoid errors - just warn
 581 }
 582
 583 my $safe_num_ne = sub {
 584     my ($a, $b) = @_;
 585
 586     return 0 if !defined($a) && !defined($b);
 587     return 1 if !defined($a);
 588     return 1 if !defined($b);
 589
 590     return $a != $b;
 591 };
 592
 593 my $safe_string_ne = sub {
 594     my ($a, $b) = @_;
 595
 596     return 0 if !defined($a) && !defined($b);
 597     return 1 if !defined($a);
 598     return 1 if !defined($b);
 599
 600     return $a ne $b;
 601 };
 602
 603 sub update_net {
 604     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 605
 606     if ($newnet->{type} ne 'veth') {
 607         # for when there are physical interfaces
 608         die "cannot update interface of type $newnet->{type}";
 609     }
 610
 611     my $veth = "veth${vmid}i${netid}";
 612     my $eth = $newnet->{name};
 613
 614     if (my $oldnetcfg = $conf->{$opt}) {
 615         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 616
 617         if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 618             &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
 619
 620             PVE::Network::veth_delete($veth);
 621             delete $conf->{$opt};
 622             PVE::LXC::Config->write_config($vmid, $conf);
 623
 624             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 625
 626         } else {
 627             if (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 628                 &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 629                 &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 630
 631                 if ($oldnet->{bridge}) {
 632                     PVE::Network::tap_unplug($veth);
 633                     foreach (qw(bridge tag firewall)) {
 634                         delete $oldnet->{$_};
 635                     }
 636                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 637                     PVE::LXC::Config->write_config($vmid, $conf);
 638                 }
 639
 640                 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 641                 # This includes the rate:
 642                 foreach (qw(bridge tag firewall rate)) {
 643                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 644                 }
 645             } elsif (&$safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 646                 # Rate can be applied on its own but any change above needs to
 647                 # include the rate in tap_plug since OVS resets everything.
 648                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 649                 $oldnet->{rate} = $newnet->{rate}
 650             }
 651             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 652             PVE::LXC::Config->write_config($vmid, $conf);
 653         }
 654     } else {
 655         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 656     }
 657
 658     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 659 }
 660
 661 sub hotplug_net {
 662     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 663
 664     my $veth = "veth${vmid}i${netid}";
 665     my $vethpeer = $veth . "p";
 666     my $eth = $newnet->{name};
 667
 668     PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 669     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 670
 671     # attach peer in container
 672     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 673     PVE::Tools::run_command($cmd);
 674
 675     # link up peer in container
 676     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 677     PVE::Tools::run_command($cmd);
 678
 679     my $done = { type => 'veth' };
 680     foreach (qw(bridge tag firewall hwaddr name)) {
 681         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 682     }
 683     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 684
 685     PVE::LXC::Config->write_config($vmid, $conf);
 686 }
 687
 688 sub update_ipconfig {
 689     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 690
 691     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 692
 693     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 694     my $deleted = [];
 695     my $added = [];
 696     my $nscmd = sub {
 697         my $cmdargs = shift;
 698         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 699     };
 700     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 701
 702     my $change_ip_config = sub {
 703         my ($ipversion) = @_;
 704
 705         my $family_opt = "-$ipversion";
 706         my $suffix = $ipversion == 4 ? '' : $ipversion;
 707         my $gw= "gw$suffix";
 708         my $ip= "ip$suffix";
 709
 710         my $newip = $newnet->{$ip};
 711         my $newgw = $newnet->{$gw};
 712         my $oldip = $optdata->{$ip};
 713
 714         my $change_ip = &$safe_string_ne($oldip, $newip);
 715         my $change_gw = &$safe_string_ne($optdata->{$gw}, $newgw);
 716
 717         return if !$change_ip && !$change_gw;
 718
 719         # step 1: add new IP, if this fails we cancel
 720         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 721         if ($change_ip && $is_real_ip) {
 722             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 723             if (my $err = $@) {
 724                 warn $err;
 725                 return;
 726             }
 727         }
 728
 729         # step 2: replace gateway
 730         #   If this fails we delete the added IP and cancel.
 731         #   If it succeeds we save the config and delete the old IP, ignoring
 732         #   errors. The config is then saved.
 733         # Note: 'ip route replace' can add
 734         if ($change_gw) {
 735             if ($newgw) {
 736                 eval {
 737                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
 738                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
 739                     }
 740                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
 741                 };
 742                 if (my $err = $@) {
 743                     warn $err;
 744                     # the route was not replaced, the old IP is still available
 745                     # rollback (delete new IP) and cancel
 746                     if ($change_ip) {
 747                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
 748                         warn $@ if $@; # no need to die here
 749                     }
 750                     return;
 751                 }
 752             } else {
 753                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
 754                 # if the route was not deleted, the guest might have deleted it manually
 755                 # warn and continue
 756                 warn $@ if $@;
 757             }
 758         }
 759
 760         # from this point on we save the configuration
 761         # step 3: delete old IP ignoring errors
 762         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
 763             # We need to enable promote_secondaries, otherwise our newly added
 764             # address will be removed along with the old one.
 765             my $promote = 0;
 766             eval {
 767                 if ($ipversion == 4) {
 768                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
 769                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
 770                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
 771                 }
 772                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
 773             };
 774             warn $@ if $@; # no need to die here
 775
 776             if ($ipversion == 4) {
 777                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
 778             }
 779         }
 780
 781         foreach my $property ($ip, $gw) {
 782             if ($newnet->{$property}) {
 783                 $optdata->{$property} = $newnet->{$property};
 784             } else {
 785                 delete $optdata->{$property};
 786             }
 787         }
 788         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
 789         PVE::LXC::Config->write_config($vmid, $conf);
 790         $lxc_setup->setup_network($conf);
 791     };
 792
 793     &$change_ip_config(4);
 794     &$change_ip_config(6);
 795
 796 }
 797
 798 my $enter_namespace = sub {
 799     my ($vmid, $pid, $which, $type) = @_;
 800     sysopen my $fd, "/proc/$pid/ns/$which", O_RDONLY
 801         or die "failed to open $which namespace of container $vmid: $!\n";
 802     PVE::Tools::setns(fileno($fd), $type)
 803         or die "failed to enter $which namespace of container $vmid: $!\n";
 804     close $fd;
 805 };
 806
 807 my $do_syncfs = sub {
 808     my ($vmid, $pid, $socket) = @_;
 809
 810     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
 811
 812     # Tell the parent process to start reading our /proc/mounts
 813     print {$socket} "go\n";
 814     $socket->flush();
 815
 816     # Receive /proc/self/mounts
 817     my $mountdata = do { local $/ = undef; <$socket> };
 818     close $socket;
 819
 820     # Now sync all mountpoints...
 821     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
 822     foreach my $mp (@$mounts) {
 823         my ($what, $dir, $fs) = @$mp;
 824         next if $fs eq 'fuse.lxcfs';
 825         eval { PVE::Tools::sync_mountpoint($dir); };
 826         warn $@ if $@;
 827     }
 828 };
 829
 830 sub sync_container_namespace {
 831     my ($vmid) = @_;
 832     my $pid = find_lxc_pid($vmid);
 833
 834     # SOCK_DGRAM is nicer for barriers but cannot be slurped
 835     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
 836         or die "failed to create socketpair: $!\n";
 837
 838     my $child = fork();
 839     die "fork failed: $!\n" if !defined($child);
 840
 841     if (!$child) {
 842         eval {
 843             close $pfd;
 844             &$do_syncfs($vmid, $pid, $cfd);
 845         };
 846         if (my $err = $@) {
 847             warn $err;
 848             POSIX::_exit(1);
 849         }
 850         POSIX::_exit(0);
 851     }
 852     close $cfd;
 853     my $go = <$pfd>;
 854     die "failed to enter container namespace\n" if $go ne "go\n";
 855
 856     open my $mounts, '<', "/proc/$child/mounts"
 857         or die "failed to open container's /proc/mounts: $!\n";
 858     my $mountdata = do { local $/ = undef; <$mounts> };
 859     close $mounts;
 860     print {$pfd} $mountdata;
 861     close $pfd;
 862
 863     while (waitpid($child, 0) != $child) {}
 864     die "failed to sync container namespace\n" if $? != 0;
 865 }
 866
 867 sub template_create {
 868     my ($vmid, $conf) = @_;
 869
 870     my $storecfg = PVE::Storage::config();
 871
 872     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 873         my ($ms, $mountpoint) = @_;
 874
 875         my $volid = $mountpoint->{volume};
 876
 877         die "Template feature is not available for '$volid'\n"
 878             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
 879     });
 880
 881     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 882         my ($ms, $mountpoint) = @_;
 883
 884         my $volid = $mountpoint->{volume};
 885
 886         PVE::Storage::activate_volumes($storecfg, [$volid]);
 887
 888         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
 889         $mountpoint->{volume} = $template_volid;
 890         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
 891     });
 892
 893     PVE::LXC::Config->write_config($vmid, $conf);
 894 }
 895
 896 sub check_ct_modify_config_perm {
 897     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
 898
 899     return 1 if $authuser eq 'root@pam';
 900
 901     my $check = sub {
 902         my ($opt, $delete) = @_;
 903         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
 904             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
 905         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
 906             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
 907             return if $delete;
 908             my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
 909                                         : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
 910             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
 911                 if $data->{type} ne 'volume';
 912         } elsif ($opt eq 'memory' || $opt eq 'swap') {
 913             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
 914         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
 915                  $opt eq 'searchdomain' || $opt eq 'hostname') {
 916             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
 917         } else {
 918             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 919         }
 920     };
 921
 922     foreach my $opt (keys %$newconf) {
 923         &$check($opt, 0);
 924     }
 925     foreach my $opt (@$delete) {
 926         &$check($opt, 1);
 927     }
 928
 929     return 1;
 930 }
 931
 932 sub umount_all {
 933     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
 934
 935     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
 936     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
 937
 938     PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
 939         my ($ms, $mountpoint) = @_;
 940
 941         my $volid = $mountpoint->{volume};
 942         my $mount = $mountpoint->{mp};
 943
 944         return if !$volid || !$mount;
 945
 946         my $mount_path = "$rootdir/$mount";
 947         $mount_path =~ s!/+!/!g;
 948
 949         return if !PVE::ProcFSTools::is_mounted($mount_path);
 950
 951         eval {
 952             PVE::Tools::run_command(['umount', '-d', $mount_path]);
 953         };
 954         if (my $err = $@) {
 955             if ($noerr) {
 956                 warn $err;
 957             } else {
 958                 die $err;
 959             }
 960         }
 961     });
 962 }
 963
 964 sub mount_all {
 965     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
 966
 967     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
 968     File::Path::make_path($rootdir);
 969
 970     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
 971     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
 972
 973     eval {
 974         PVE::LXC::Config->foreach_mountpoint($conf, sub {
 975             my ($ms, $mountpoint) = @_;
 976
 977             $mountpoint->{ro} = 0 if $ignore_ro;
 978
 979             mountpoint_mount($mountpoint, $rootdir, $storage_cfg);
 980         });
 981     };
 982     if (my $err = $@) {
 983         warn "mounting container failed\n";
 984         umount_all($vmid, $storage_cfg, $conf, 1);
 985         die $err;
 986     }
 987
 988     return $rootdir;
 989 }
 990
 991
 992 sub mountpoint_mount_path {
 993     my ($mountpoint, $storage_cfg, $snapname) = @_;
 994
 995     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
 996 }
 997
 998 sub query_loopdev {
 999     my ($path) = @_;
1000     my $found;
1001     my $parser = sub {
1002         my $line = shift;
1003         if ($line =~ m@^(/dev/loop\d+):@) {
1004             $found = $1;
1005         }
1006     };
1007     my $cmd = ['losetup', '--associated', $path];
1008     PVE::Tools::run_command($cmd, outfunc => $parser);
1009     return $found;
1010 }
1011
1012 # Run a function with a file attached to a loop device.
1013 # The loop device is always detached afterwards (or set to autoclear).
1014 # Returns the loop device.
1015 sub run_with_loopdev {
1016     my ($func, $file) = @_;
1017     my $device = query_loopdev($file);
1018     # Try to reuse an existing device
1019     if ($device) {
1020         # We assume that whoever setup the loop device is responsible for
1021         # detaching it.
1022         &$func($device);
1023         return $device;
1024     }
1025
1026     my $parser = sub {
1027         my $line = shift;
1028         if ($line =~ m@^(/dev/loop\d+)$@) {
1029             $device = $1;
1030         }
1031     };
1032     PVE::Tools::run_command(['losetup', '--show', '-f', $file], outfunc => $parser);
1033     die "failed to setup loop device for $file\n" if !$device;
1034     eval { &$func($device); };
1035     my $err = $@;
1036     PVE::Tools::run_command(['losetup', '-d', $device]);
1037     die $err if $err;
1038     return $device;
1039 }
1040
1041 # In scalar mode: returns a file handle to the deepest directory node.
1042 # In list context: returns a list of:
1043 #   * the deepest directory node
1044 #   * the 2nd deepest directory (parent of the above)
1045 #   * directory name of the last directory
1046 # So that the path $2/$3 should lead to $1 afterwards.
1047 sub walk_tree_nofollow($$$) {
1048     my ($start, $subdir, $mkdir) = @_;
1049
1050     # splitdir() returns '' for empty components including the leading /
1051     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1052
1053     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1054         or die "failed to open start directory $start: $!\n";
1055
1056     my $dir = $start;
1057     my $last_component = undef;
1058     my $second = $fd;
1059     foreach my $component (@comps) {
1060         $dir .= "/$component";
1061         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1062
1063         if (!$next) {
1064             # failed, check for symlinks and try to create the path
1065             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1066             die "cannot open directory $dir: $!\n" if !$mkdir;
1067
1068             # We don't check for errors on mkdirat() here and just try to
1069             # openat() again, since at least one error (EEXIST) is an
1070             # expected possibility if multiple containers start
1071             # simultaneously. If someone else injects a symlink now then
1072             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1073             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1074
1075             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1076             die "failed to create path: $dir: $!\n" if !$next;
1077         }
1078
1079         close $second if defined($last_component);
1080         $last_component = $component;
1081         $second = $fd;
1082         $fd = $next;
1083     }
1084
1085     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1086     close $second if defined($last_component);
1087     return $fd;
1088 }
1089
1090 # To guard against symlink attack races against other currently running
1091 # containers with shared recursive bind mount hierarchies we prepare a
1092 # directory handle for the directory we're mounting over to verify the
1093 # mountpoint afterwards.
1094 sub __bindmount_prepare {
1095     my ($hostroot, $dir) = @_;
1096     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1097     return $srcdh;
1098 }
1099
1100 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1101 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1102 # we intended to bind mount.
1103 sub __bindmount_verify {
1104     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1105     my $destdh;
1106     if ($parentfd) {
1107         # Open the mount point path coming from the parent directory since the
1108         # filehandle we would have gotten as first result of walk_tree_nofollow
1109         # earlier is still a handle to the underlying directory instead of the
1110         # mounted path.
1111         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1112         die "failed to open mount point: $!\n" if !$destdh;
1113         if ($ro) {
1114             my $dot = '.';
1115             # no separate function because 99% of the time it's the wrong thing to use.
1116             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1117                 die "failed to mark bind mount read only\n";
1118             }
1119             die "read-only check failed: $!\n" if $! != EROFS;
1120         }
1121     } else {
1122         # For the rootfs we don't have a parentfd so we open the path directly.
1123         # Note that this means bindmounting any prefix of the host's
1124         # /var/lib/lxc/$vmid path into another container is considered a grave
1125         # security error.
1126         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1127         die "failed to open mount point: $!\n" if !$destdh;
1128     }
1129
1130     my ($srcdev, $srcinode) = stat($srcdh);
1131     my ($dstdev, $dstinode) = stat($destdh);
1132     close $srcdh;
1133     close $destdh;
1134
1135     return ($srcdev == $dstdev && $srcinode == $dstinode);
1136 }
1137
1138 # Perform the actual bind mounting:
1139 sub __bindmount_do {
1140     my ($dir, $dest, $ro, @extra_opts) = @_;
1141     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1142     if ($ro) {
1143         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1144         if (my $err = $@) {
1145             warn "bindmount error\n";
1146             # don't leave writable bind-mounts behind...
1147             PVE::Tools::run_command(['umount', $dest]);
1148             die $err;
1149         }
1150     }
1151 }
1152
1153 sub bindmount {
1154     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1155
1156     my $srcdh = __bindmount_prepare('/', $dir);
1157
1158     __bindmount_do($dir, $dest, $ro, @extra_opts);
1159
1160     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1161         PVE::Tools::run_command(['umount', $dest]);
1162         die "detected mount path change at: $dir\n";
1163     }
1164 }
1165
1166 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1167 # from $rootdir and $mount and walk the path from $rootdir to the final
1168 # directory to check for symlinks.
1169 sub __mount_prepare_rootdir {
1170     my ($rootdir, $mount) = @_;
1171     $rootdir =~ s!/+!/!g;
1172     $rootdir =~ s!/+$!!;
1173     my $mount_path = "$rootdir/$mount";
1174     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1);
1175     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1176 }
1177
1178 # use $rootdir = undef to just return the corresponding mount path
1179 sub mountpoint_mount {
1180     my ($mountpoint, $rootdir, $storage_cfg, $snapname) = @_;
1181
1182     my $volid = $mountpoint->{volume};
1183     my $mount = $mountpoint->{mp};
1184     my $type = $mountpoint->{type};
1185     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1186     my $mounted_dev;
1187
1188     return if !$volid || !$mount;
1189
1190     $mount =~ s!/+!/!g;
1191
1192     my $mount_path;
1193     my ($mpfd, $parentfd, $last_dir);
1194
1195     if (defined($rootdir)) {
1196         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1197             __mount_prepare_rootdir($rootdir, $mount);
1198     }
1199
1200     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1201
1202     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1203
1204     my $optstring = '';
1205     my $acl = $mountpoint->{acl};
1206     if (defined($acl)) {
1207         $optstring .= ($acl ? 'acl' : 'noacl');
1208     }
1209     my $readonly = $mountpoint->{ro};
1210
1211     my @extra_opts = ('-o', $optstring) if $optstring;
1212
1213     if ($storage) {
1214
1215         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1216
1217         # early sanity checks:
1218         # we otherwise call realpath on the rbd url
1219         die "containers on rbd storage without krbd are not supported\n"
1220             if $scfg->{type} eq 'rbd' && !$scfg->{krbd};
1221
1222         my $path = PVE::Storage::path($storage_cfg, $volid, $snapname);
1223
1224         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1225             PVE::Storage::parse_volname($storage_cfg, $volid);
1226
1227         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1228
1229         if ($format eq 'subvol') {
1230             if ($mount_path) {
1231                 if ($snapname) {
1232                     if ($scfg->{type} eq 'zfspool') {
1233                         my $path_arg = $path;
1234                         $path_arg =~ s!^/+!!;
1235                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', $path_arg, $mount_path]);
1236                     } else {
1237                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1238                     }
1239                 } else {
1240                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1241                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1242                         my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1243                         $name .= "\@$snapname" if defined($snapname);
1244                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1245                     }
1246                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1247                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1248                 }
1249             }
1250             return wantarray ? ($path, 0, undef) : $path;
1251         } elsif ($format eq 'raw' || $format eq 'iso') {
1252             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1253             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1254             # Our autodev hook expects the /dev/dm-* device currently
1255             # and will create the /dev/mapper symlink accordingly
1256             $path = Cwd::realpath($path);
1257             die "failed to get device path\n" if !$path;
1258             ($path) = ($path =~ /^(.*)$/s); #untaint
1259             my $domount = sub {
1260                 my ($path) = @_;
1261                 if ($mount_path) {
1262                     if ($format eq 'iso') {
1263                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1264                     } elsif ($isBase || defined($snapname)) {
1265                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1266                     } else {
1267                         if ($quota) {
1268                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1269                         }
1270                         push @extra_opts, '-o', 'ro' if $readonly;
1271                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1272                     }
1273                 }
1274             };
1275             my $use_loopdev = 0;
1276             if ($scfg->{path}) {
1277                 $mounted_dev = run_with_loopdev($domount, $path);
1278                 $use_loopdev = 1;
1279             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1280                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1281                 $mounted_dev = $path;
1282                 &$domount($path);
1283             } else {
1284                 die "unsupported storage type '$scfg->{type}'\n";
1285             }
1286             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1287         } else {
1288             die "unsupported image format '$format'\n";
1289         }
1290     } elsif ($type eq 'device') {
1291         push @extra_opts, '-o', 'ro' if $readonly;
1292         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1293         # See the NOTE above about devicemapper canonicalization
1294         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1295         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1296         return wantarray ? ($volid, 0, $devpath) : $volid;
1297     } elsif ($type eq 'bind') {
1298         die "directory '$volid' does not exist\n" if ! -d $volid;
1299         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1300         warn "cannot enable quota control for bind mounts\n" if $quota;
1301         return wantarray ? ($volid, 0, undef) : $volid;
1302     }
1303
1304     die "unsupported storage";
1305 }
1306
1307 sub mkfs {
1308     my ($dev, $rootuid, $rootgid) = @_;
1309
1310     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1311                              '-E', "root_owner=$rootuid:$rootgid",
1312                              $dev]);
1313 }
1314
1315 sub format_disk {
1316     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1317
1318     if ($volid =~ m!^/dev/.+!) {
1319         mkfs($volid);
1320         return;
1321     }
1322
1323     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1324
1325     die "cannot format volume '$volid' with no storage\n" if !$storage;
1326
1327     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1328
1329     my $path = PVE::Storage::path($storage_cfg, $volid);
1330
1331     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1332         PVE::Storage::parse_volname($storage_cfg, $volid);
1333
1334     die "cannot format volume '$volid' (format == $format)\n"
1335         if $format ne 'raw';
1336
1337     mkfs($path, $rootuid, $rootgid);
1338 }
1339
1340 sub destroy_disks {
1341     my ($storecfg, $vollist) = @_;
1342
1343     foreach my $volid (@$vollist) {
1344         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1345         warn $@ if $@;
1346     }
1347 }
1348
1349 sub alloc_disk {
1350     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1351
1352     my $needs_chown = 0;
1353     my $volid;
1354
1355     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1356     # fixme: use better naming ct-$vmid-disk-X.raw?
1357
1358     eval {
1359         my $do_format = 0;
1360         if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1361             if ($size_kb > 0) {
1362                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1363                                                    undef, $size_kb);
1364                 $do_format = 1;
1365             } else {
1366                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1367                                                    undef, 0);
1368                 $needs_chown = 1;
1369             }
1370         } elsif ($scfg->{type} eq 'zfspool') {
1371
1372             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1373                                                undef, $size_kb);
1374             $needs_chown = 1;
1375         } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1376
1377             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1378             $do_format = 1;
1379
1380         } elsif ($scfg->{type} eq 'rbd') {
1381
1382             die "krbd option must be enabled on storage type '$scfg->{type}'\n" if !$scfg->{krbd};
1383             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1384             $do_format = 1;
1385         } else {
1386             die "unable to create containers on storage type '$scfg->{type}'\n";
1387         }
1388         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1389     };
1390     if (my $err = $@) {
1391         # in case formatting got interrupted:
1392         if (defined($volid)) {
1393             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1394             warn $@ if $@;
1395         }
1396         die $err;
1397     }
1398
1399     return ($volid, $needs_chown);
1400 }
1401
1402 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1403 sub create_disks {
1404     my ($storecfg, $vmid, $settings, $conf) = @_;
1405
1406     my $vollist = [];
1407
1408     eval {
1409         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1410         my $chown_vollist = [];
1411
1412         PVE::LXC::Config->foreach_mountpoint($settings, sub {
1413             my ($ms, $mountpoint) = @_;
1414
1415             my $volid = $mountpoint->{volume};
1416             my $mp = $mountpoint->{mp};
1417
1418             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1419
1420             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1421                 my ($storeid, $size_gb) = ($1, $2);
1422
1423                 my $size_kb = int(${size_gb}*1024) * 1024;
1424
1425                 my $needs_chown = 0;
1426                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1427                 push @$chown_vollist, $volid if $needs_chown;
1428                 push @$vollist, $volid;
1429                 $mountpoint->{volume} = $volid;
1430                 $mountpoint->{size} = $size_kb * 1024;
1431                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1432             } else {
1433                 # use specified/existing volid/dir/device
1434                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1435             }
1436         });
1437
1438         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1439         foreach my $volid (@$chown_vollist) {
1440             my $path = PVE::Storage::path($storecfg, $volid, undef);
1441             chown($rootuid, $rootgid, $path);
1442         }
1443         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1444     };
1445     # free allocated images on error
1446     if (my $err = $@) {
1447         destroy_disks($storecfg, $vollist);
1448         die $err;
1449     }
1450     return $vollist;
1451 }
1452
1453 # bash completion helper
1454
1455 sub complete_os_templates {
1456     my ($cmdname, $pname, $cvalue) = @_;
1457
1458     my $cfg = PVE::Storage::config();
1459
1460     my $storeid;
1461
1462     if ($cvalue =~ m/^([^:]+):/) {
1463         $storeid = $1;
1464     }
1465
1466     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
1467     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
1468
1469     my $res = [];
1470     foreach my $id (keys %$data) {
1471         foreach my $item (@{$data->{$id}}) {
1472             push @$res, $item->{volid} if defined($item->{volid});
1473         }
1474     }
1475
1476     return $res;
1477 }
1478
1479 my $complete_ctid_full = sub {
1480     my ($running) = @_;
1481
1482     my $idlist = vmstatus();
1483
1484     my $active_hash = list_active_containers();
1485
1486     my $res = [];
1487
1488     foreach my $id (keys %$idlist) {
1489         my $d = $idlist->{$id};
1490         if (defined($running)) {
1491             next if $d->{template};
1492             next if $running && !$active_hash->{$id};
1493             next if !$running && $active_hash->{$id};
1494         }
1495         push @$res, $id;
1496
1497     }
1498     return $res;
1499 };
1500
1501 sub complete_ctid {
1502     return &$complete_ctid_full();
1503 }
1504
1505 sub complete_ctid_stopped {
1506     return &$complete_ctid_full(0);
1507 }
1508
1509 sub complete_ctid_running {
1510     return &$complete_ctid_full(1);
1511 }
1512
1513 sub parse_id_maps {
1514     my ($conf) = @_;
1515
1516     my $id_map = [];
1517     my $rootuid = 0;
1518     my $rootgid = 0;
1519
1520     my $lxc = $conf->{lxc};
1521     foreach my $entry (@$lxc) {
1522         my ($key, $value) = @$entry;
1523         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
1524         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
1525         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
1526             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
1527             push @$id_map, [$type, $ct, $host, $length];
1528             if ($ct == 0) {
1529                 $rootuid = $host if $type eq 'u';
1530                 $rootgid = $host if $type eq 'g';
1531             }
1532         } else {
1533             die "failed to parse idmap: $value\n";
1534         }
1535     }
1536
1537     if (!@$id_map && $conf->{unprivileged}) {
1538         # Should we read them from /etc/subuid?
1539         $id_map = [ ['u', '0', '100000', '65536'],
1540                     ['g', '0', '100000', '65536'] ];
1541         $rootuid = $rootgid = 100000;
1542     }
1543
1544     return ($id_map, $rootuid, $rootgid);
1545 }
1546
1547 sub userns_command {
1548     my ($id_map) = @_;
1549     if (@$id_map) {
1550         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
1551     }
1552     return [];
1553 }
1554
1555 sub vm_start {
1556     my ($vmid, $conf, $skiplock) = @_;
1557
1558     update_lxc_config($vmid, $conf);
1559
1560     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
1561
1562     if ($skiplock) {
1563         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
1564         close($fh);
1565     }
1566
1567     my $cmd = ['systemctl', 'start', "pve-container\@$vmid"];
1568
1569     eval { PVE::Tools::run_command($cmd); };
1570     if (my $err = $@) {
1571         unlink $skiplock_flag_fn;
1572         die $err;
1573     }
1574
1575     return;
1576 }
1577
1578 # Helper to stop a container completely and make sure it has stopped completely.
1579 # This is necessary because we want the post-stop hook to have completed its
1580 # unmount-all step, but post-stop happens after lxc puts the container into the
1581 # STOPPED state.
1582 sub vm_stop {
1583     my ($vmid, $kill, $shutdown_timeout, $exit_timeout) = @_;
1584
1585     # Open the container's command socket.
1586     my $path = "\0/var/lib/lxc/$vmid/command";
1587     my $sock = IO::Socket::UNIX->new(
1588         Type => SOCK_STREAM(),
1589         Peer => $path,
1590     );
1591     if (!$sock) {
1592         return if $! == ECONNREFUSED; # The container is not running
1593         die "failed to open container ${vmid}'s command socket: $!\n";
1594     }
1595
1596     # Stop the container:
1597
1598     my $cmd = ['lxc-stop', '-n', $vmid];
1599
1600     if ($kill) {
1601         push @$cmd, '--kill'; # doesn't allow timeouts
1602     } elsif (defined($shutdown_timeout)) {
1603         push @$cmd, '--timeout', $shutdown_timeout;
1604         # Give run_command 5 extra seconds
1605         $shutdown_timeout += 5;
1606     }
1607
1608     eval { PVE::Tools::run_command($cmd, timeout => $shutdown_timeout) };
1609     if (my $err = $@) {
1610         warn $@ if $@;
1611     }
1612
1613     my $result = 1;
1614     my $wait = sub { $result = <$sock>; };
1615     if (defined($exit_timeout)) {
1616         PVE::Tools::run_with_timeout($exit_timeout, $wait);
1617     } else {
1618         $wait->();
1619     }
1620
1621     return if !defined $result; # monitor is gone and the ct has stopped.
1622     die "container did not stop\n";
1623 }
1624
1625 sub run_unshared {
1626     my ($code) = @_;
1627
1628     return PVE::Tools::run_fork(sub {
1629         # Unshare the mount namespace
1630         die "failed to unshare mount namespace: $!\n"
1631             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
1632         PVE::Tools::run_command(['mount', '--make-rslave', '/']);
1633         return $code->();
1634     });
1635 }
1636
1637 my $copy_volume = sub {
1638     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname) = @_;
1639
1640     my $src_mp = { volume => $src_volid, mp => '/' };
1641     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
1642
1643     my $dst_mp = { volume => $dst_volid, mp => '/' };
1644     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
1645
1646     my @mounted;
1647     eval {
1648         # mount and copy
1649         mkdir $src;
1650         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname);
1651         push @mounted, $src;
1652         mkdir $dest;
1653         mountpoint_mount($dst_mp, $dest, $storage_cfg);
1654         push @mounted, $dest;
1655
1656         PVE::Tools::run_command(['/usr/bin/rsync', '--stats', '-X', '-A', '--numeric-ids',
1657                                  '-aH', '--whole-file', '--sparse', '--one-file-system',
1658                                  "$src/", $dest]);
1659     };
1660     my $err = $@;
1661     foreach my $mount (reverse @mounted) {
1662         eval { PVE::Tools::run_command(['/bin/umount', '--lazy', $mount], errfunc => sub{})};
1663         warn "Can't umount $mount\n" if $@;
1664     }
1665
1666     # If this fails they're used as mount points in a concurrent operation
1667     # (which should not happen but there's also no real need to get rid of them).
1668     rmdir $dest;
1669     rmdir $src;
1670
1671     die $err if $err;
1672 };
1673
1674 # Should not be called after unsharing the mount namespace!
1675 sub copy_volume {
1676     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname) = @_;
1677
1678     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
1679     File::Path::make_path("/var/lib/lxc/$vmid");
1680     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
1681     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
1682
1683     # get id's for unprivileged container
1684     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1685
1686     # Allocate the disk before unsharing in order to make sure zfs subvolumes
1687     # are visible in this namespace, otherwise the host only sees the empty
1688     # (not-mounted) directory.
1689     my $new_volid;
1690     eval {
1691         # Make sure $mp contains a correct size.
1692         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
1693         my $needs_chown;
1694         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
1695         if ($needs_chown) {
1696             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
1697             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
1698             chown($rootuid, $rootgid, $path);
1699         }
1700
1701         run_unshared(sub {
1702             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname);
1703         });
1704     };
1705     if (my $err = $@) {
1706         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
1707             if defined($new_volid);
1708         die $err;
1709     }
1710
1711     return $new_volid;
1712 }
1713
1714 1;