src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16 use IO::Poll qw(POLLIN POLLHUP);
  17
  18 use PVE::Exception qw(raise_perm_exc);
  19 use PVE::Storage;
  20 use PVE::SafeSyslog;
  21 use PVE::INotify;
  22 use PVE::JSONSchema qw(get_standard_option);
  23 use PVE::Tools qw(
  24     run_command
  25     dir_glob_foreach
  26     file_get_contents
  27     file_set_contents
  28     AT_FDCWD
  29     O_PATH
  30     $IPV4RE
  31     $IPV6RE
  32 );
  33 use PVE::CpuSet;
  34 use PVE::Network;
  35 use PVE::AccessControl;
  36 use PVE::ProcFSTools;
  37 use PVE::RESTEnvironment;
  38 use PVE::Syscall qw(:fsmount);
  39 use PVE::LXC::Config;
  40 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  41 use PVE::LXC::Tools;
  42 use PVE::LXC::CGroup;
  43 use PVE::LXC::Monitor;
  44 use PVE::CGroup;
  45
  46 use Time::HiRes qw (gettimeofday);
  47 my $have_sdn;
  48 eval {
  49     require PVE::Network::SDN::Zones;
  50     $have_sdn = 1;
  51 };
  52
  53 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  54
  55 my $nodename = PVE::INotify::nodename();
  56
  57 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  58
  59 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  60
  61 sub config_list {
  62     my $vmlist = PVE::Cluster::get_vmlist();
  63     my $res = {};
  64     return $res if !$vmlist || !$vmlist->{ids};
  65     my $ids = $vmlist->{ids};
  66
  67     foreach my $vmid (keys %$ids) {
  68         next if !$vmid; # skip CT0
  69         my $d = $ids->{$vmid};
  70         next if !$d->{node} || $d->{node} ne $nodename;
  71         next if !$d->{type} || $d->{type} ne 'lxc';
  72         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  73     }
  74     return $res;
  75 }
  76
  77 # container status helpers
  78
  79 sub list_active_containers {
  80
  81     my $filename = "/proc/net/unix";
  82
  83     # similar test is used by lcxcontainers.c: list_active_containers
  84     my $res = {};
  85
  86     my $fh = IO::File->new ($filename, "r");
  87     return $res if !$fh;
  88
  89     while (defined(my $line = <$fh>)) {
  90         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  91             my $path = $1;
  92             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  93                 $res->{$1} = 1;
  94             }
  95         }
  96     }
  97
  98     close($fh);
  99
 100     return $res;
 101 }
 102
 103 # warning: this is slow
 104 sub check_running {
 105     my ($vmid) = @_;
 106
 107     my $active_hash = list_active_containers();
 108
 109     return 1 if defined($active_hash->{$vmid});
 110
 111     return undef;
 112 }
 113
 114 sub get_container_disk_usage {
 115     my ($vmid, $pid) = @_;
 116
 117     return PVE::Tools::df("/proc/$pid/root/", 1);
 118 }
 119
 120 my $last_proc_vmid_stat;
 121
 122 our $vmstatus_return_properties = {
 123     vmid => get_standard_option('pve-vmid'),
 124     status => {
 125         description => "LXC Container status.",
 126         type => 'string',
 127         enum => ['stopped', 'running'],
 128     },
 129     maxmem => {
 130         description => "Maximum memory in bytes.",
 131         type => 'integer',
 132         optional => 1,
 133         renderer => 'bytes',
 134     },
 135     maxswap => {
 136         description => "Maximum SWAP memory in bytes.",
 137         type => 'integer',
 138         optional => 1,
 139         renderer => 'bytes',
 140     },
 141     maxdisk => {
 142         description => "Root disk size in bytes.",
 143         type => 'integer',
 144         optional => 1,
 145         renderer => 'bytes',
 146     },
 147     name => {
 148         description => "Container name.",
 149         type => 'string',
 150         optional => 1,
 151     },
 152     uptime => {
 153         description => "Uptime.",
 154         type => 'integer',
 155         optional => 1,
 156         renderer => 'duration',
 157     },
 158     cpus => {
 159         description => "Maximum usable CPUs.",
 160         type => 'number',
 161         optional => 1,
 162     },
 163     lock => {
 164         description => "The current config lock, if any.",
 165         type => 'string',
 166         optional => 1,
 167     },
 168     tags => {
 169         description => "The current configured tags, if any.",
 170         type => 'string',
 171         optional => 1,
 172     }
 173 };
 174
 175 sub vmstatus {
 176     my ($opt_vmid) = @_;
 177
 178     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 179
 180     my $active_hash = list_active_containers();
 181
 182     my $cpucount = $cpuinfo->{cpus} || 1;
 183
 184     my $cdtime = gettimeofday;
 185
 186     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 187     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 188
 189     my $unprivileged = {};
 190
 191     foreach my $vmid (keys %$list) {
 192         my $d = $list->{$vmid};
 193
 194         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 195         warn $@ if $@; # ignore errors (consider them stopped)
 196
 197         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 198
 199         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 200         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 201
 202         $unprivileged->{$vmid} = $conf->{unprivileged};
 203
 204         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 205         $d->{name} =~ s/[\s]//g;
 206
 207         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 208         $d->{cpus} = $cpucount if !$d->{cpus};
 209
 210         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 211
 212         if ($d->{pid}) {
 213             my $res = get_container_disk_usage($vmid, $d->{pid});
 214             $d->{disk} = int($res->{used});
 215             $d->{maxdisk} = int($res->{total});
 216         } else {
 217             $d->{disk} = 0;
 218             # use 4GB by default ??
 219             if (my $rootfs = $conf->{rootfs}) {
 220                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 221                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 222             } else {
 223                 $d->{maxdisk} = 4*1024*1024*1024;
 224             }
 225         }
 226
 227         $d->{mem} = 0;
 228         $d->{swap} = 0;
 229         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 230         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 231
 232         $d->{uptime} = 0;
 233         $d->{cpu} = 0;
 234
 235         $d->{netout} = 0;
 236         $d->{netin} = 0;
 237
 238         $d->{diskread} = 0;
 239         $d->{diskwrite} = 0;
 240
 241         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 242         $d->{lock} = $conf->{lock} if $conf->{lock};
 243     }
 244
 245     foreach my $vmid (keys %$list) {
 246         my $d = $list->{$vmid};
 247         my $pid = $d->{pid};
 248
 249         next if !$pid; # skip stopped CTs
 250
 251         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 252         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 253
 254         my $unpriv = $unprivileged->{$vmid};
 255
 256         my $cgroups = PVE::LXC::CGroup->new($vmid);
 257
 258         if (defined(my $mem = $cgroups->get_memory_stat())) {
 259             $d->{mem} = int($mem->{mem});
 260             $d->{swap} = int($mem->{swap});
 261         } else {
 262             $d->{mem} = 0;
 263             $d->{swap} = 0;
 264         }
 265
 266         if (defined(my $blkio = $cgroups->get_io_stats())) {
 267             $d->{diskread} = int($blkio->{diskread});
 268             $d->{diskwrite} = int($blkio->{diskwrite});
 269         } else {
 270             $d->{diskread} = 0;
 271             $d->{diskwrite} = 0;
 272         }
 273
 274         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 275             # Total time (in milliseconds) used up by the cpu.
 276             my $used_ms = $cpu->{utime} + $cpu->{stime};
 277
 278             my $old = $last_proc_vmid_stat->{$vmid};
 279             if (!$old) {
 280                 $last_proc_vmid_stat->{$vmid} = {
 281                     time => $cdtime,
 282                     used => $used_ms,
 283                     cpu => 0,
 284                 };
 285                 next;
 286             }
 287
 288             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 289             if ($delta_ms > 1000.0) {
 290                 my $delta_used_ms = $used_ms - $old->{used};
 291                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 292                 $last_proc_vmid_stat->{$vmid} = {
 293                     time => $cdtime,
 294                     used => $used_ms,
 295                     cpu => $d->{cpu},
 296                 };
 297             } else {
 298                 $d->{cpu} = $old->{cpu};
 299             }
 300         } else {
 301             $d->{cpu} = 0;
 302         }
 303     }
 304
 305     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 306
 307     foreach my $dev (keys %$netdev) {
 308         next if $dev !~ m/^veth([1-9]\d*)i/;
 309         my $vmid = $1;
 310         my $d = $list->{$vmid};
 311
 312         next if !$d;
 313
 314         $d->{netout} += $netdev->{$dev}->{receive};
 315         $d->{netin} += $netdev->{$dev}->{transmit};
 316
 317     }
 318
 319     return $list;
 320 }
 321
 322 sub find_lxc_console_pids {
 323
 324     my $res = {};
 325
 326     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 327         my ($pid) = @_;
 328
 329         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 330         return if !$cmdline;
 331
 332         my @args = split(/\0/, $cmdline);
 333
 334         # search for lxc-console -n <vmid>
 335         return if scalar(@args) != 3;
 336         return if $args[1] ne '-n';
 337         return if $args[2] !~ m/^\d+$/;
 338         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 339
 340         my $vmid = $args[2];
 341
 342         push @{$res->{$vmid}}, $pid;
 343     });
 344
 345     return $res;
 346 }
 347
 348 sub find_lxc_pid {
 349     my ($vmid) = @_;
 350
 351     my $pid = undef;
 352     my $parser = sub {
 353         my $line = shift;
 354         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 355     };
 356     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 357
 358     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 359
 360     return $pid;
 361 }
 362
 363 sub open_pid_fd($) {
 364     my ($pid) = @_;
 365     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 366         or die "failed to open /proc/$pid pid fd\n";
 367     return $fd;
 368 }
 369
 370 sub open_lxc_pid {
 371     my ($vmid) = @_;
 372
 373     # Find the pid and open:
 374     my $pid = find_lxc_pid($vmid);
 375     my $fd = open_pid_fd($pid);
 376
 377     # Verify:
 378     my $pid2 = find_lxc_pid($vmid);
 379
 380     return () if $pid != $pid2;
 381     return ($pid, $fd);
 382 }
 383
 384 sub open_ppid {
 385     my ($pid) = @_;
 386
 387     # Find the parent pid via proc and open it:
 388     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 389     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 390
 391     my $fd = open_pid_fd($ppid);
 392
 393     # Verify:
 394     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 395     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 396
 397     return () if $ppid != $ppid2;
 398     return ($ppid, $fd);
 399 }
 400
 401 # Note: we cannot use Net:IP, because that only allows strict
 402 # CIDR networks
 403 sub parse_ipv4_cidr {
 404     my ($cidr, $noerr) = @_;
 405
 406     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 407         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 408     }
 409
 410     return undef if $noerr;
 411
 412     die "unable to parse ipv4 address/mask\n";
 413 }
 414
 415 # With seccomp trap to userspace we now have the ability to optionally forward
 416 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 417 #
 418 # This means that there are cases where we need to create an extra seccomp
 419 # profile for the container to load.
 420 #
 421 # This returns a configuration snippet added to the raw lxc config.
 422 sub make_seccomp_config {
 423     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 424     # User-configured profile has precedence, note that the user's entry would
 425     # be written 'after' this line anyway...
 426     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 427         # Warn the user if this conflicts with a feature:
 428         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 429         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 430             if length($warn) > 0;
 431         return '';
 432     }
 433
 434     # Privileged containers keep using the default (which is already part of
 435     # the files included via lxc.include, so we don't need to write it out,
 436     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 437     # well)
 438     return '' if !$unprivileged;
 439
 440     my $rules = {
 441         keyctl => ['errno 38'],
 442
 443         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 444         # Particularly, without the mount option to enable rmdir removing snapshots, user
 445         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 446         # horrible, so for now, just disable this entirely:
 447         #
 448         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 449         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 450         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 451     };
 452
 453     my $raw_conf = '';
 454
 455     # Unprivileged containers will get keyctl() disabled by default as a
 456     # workaround for systemd-networkd behavior. But we have an option to
 457     # explicitly enable it:
 458     if ($features->{keyctl}) {
 459         delete $rules->{keyctl};
 460     }
 461
 462     # By default, unprivileged containers cannot use `mknod` at all.
 463     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 464     # but for now this is experimental, so it has to be enabled via a feature
 465     # flag.
 466     # Note that we only handle block and char devices (like lxd), the rest we
 467     # leave up to the kernel. We may in the future remove this if seccomp gets
 468     # a way to tell the kernel to "continue" a syscall.
 469     if ($features->{mknod}) {
 470         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 471         if (!$ok) {
 472             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 473         }
 474
 475         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 476         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 477
 478         $rules->{mknod} = [
 479             # condition: (mode & S_IFMT) == S_IFCHR
 480             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 481             # condition: (mode & S_IFMT) == S_IFBLK
 482             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 483         ];
 484         $rules->{mknodat} = [
 485             # condition: (mode & S_IFMT) == S_IFCHR
 486             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 487             # condition: (mode & S_IFMT) == S_IFBLK
 488             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 489         ];
 490     }
 491
 492     # Now build the custom seccomp rule text...
 493     my $extra_rules = join("\n", map {
 494         my $syscall = $_;
 495         map { "$syscall $_" } $rules->{$syscall}->@*
 496     } sort keys %$rules) . "\n";
 497
 498     return $raw_conf if $extra_rules eq "\n";
 499
 500     # We still have the "most common" config readily available, so don't write
 501     # out that one:
 502     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 503         # we have no extra $raw_conf and use the same we had in pve 6.1:
 504         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 505     }
 506
 507     # Write the rule file to the container's config path:
 508     my $rule_file = "$conf_dir/rules.seccomp";
 509     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 510         . $extra_rules;
 511     file_set_contents($rule_file, $rule_data);
 512     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 513
 514     return $raw_conf;
 515 }
 516
 517 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 518 # automatically. The default should be equivalent to the old
 519 # `lxc-container-default-cgns` profile.
 520 #
 521 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 522 # additional lines into the profile. We can use that to allow mounting specific
 523 # file systems.
 524 sub make_apparmor_config {
 525     my ($conf, $unprivileged, $features) = @_;
 526
 527     # user-configured profile has precedence, but first we go through our own
 528     # code to figure out whether we should warn the user:
 529
 530     my $raw = "lxc.apparmor.profile = generated\n";
 531     my @profile_uses;
 532
 533     if ($features->{fuse}) {
 534         # For the informational warning:
 535         push @profile_uses, 'features:fuse';
 536     }
 537
 538     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 539     # apparmor lines, create an apparmor namespace for the container, but also
 540     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 541     # lxcfs mounted over them, because that would prevent the container from
 542     # mounting new instances of them for nested containers.
 543     if ($features->{nesting}) {
 544         push @profile_uses, 'features:nesting';
 545         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 546     } else {
 547         # In the default profile in /etc/apparmor.d we patch this in because
 548         # otherwise a container can for example run `chown` on /sys, breaking
 549         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 550         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 551         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 552         # Preferably we could use the 'remount' flag but this does not sit well
 553         # with apparmor_parser currently:
 554         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 555     }
 556
 557     if (my $mount = $features->{mount}) {
 558         push @profile_uses, 'features:mount';
 559         foreach my $fs (PVE::Tools::split_list($mount)) {
 560             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 561         }
 562     }
 563
 564     # More to come?
 565
 566     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 567         if (length(my $used = join(', ', @profile_uses))) {
 568             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 569         }
 570         return '';
 571     }
 572
 573     return $raw;
 574 }
 575
 576 sub update_lxc_config {
 577     my ($vmid, $conf) = @_;
 578
 579     my $dir = "/var/lib/lxc/$vmid";
 580
 581     if ($conf->{template}) {
 582
 583         unlink "$dir/config";
 584
 585         return;
 586     }
 587
 588     my ($lxc_major, $lxc_minor) = get_lxc_version();
 589
 590     my $raw = '';
 591
 592     if ($lxc_major >= 4) {
 593         # Explicitly don't use relative directories, which is the default, but
 594         # note that we do this mostly because they are only applied for *some*
 595         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 596         # so we also don't need to worry about the new monitor cgroup to
 597         # confuse systemd.
 598         $raw .= "lxc.cgroup.relative = 0\n";
 599
 600         # To make things easier, let's keep our previous cgroup layout and
 601         # simply move the monitor outside:
 602         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 603         # cgroup namespace separation for stronger limits:
 604         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 605         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 606     }
 607
 608     die "missing 'arch' - internal error" if !$conf->{arch};
 609     $raw .= "lxc.arch = $conf->{arch}\n";
 610
 611     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 612     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 613
 614     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 615
 616     File::Path::mkpath($dir);
 617
 618     my $cfgpath = '/usr/share/lxc/config';
 619     my $inc = "$cfgpath/$ostype.common.conf";
 620     $inc ="$cfgpath/common.conf" if !-f $inc;
 621     $raw .= "lxc.include = $inc\n";
 622     if ($unprivileged) {
 623         $inc = "$cfgpath/$ostype.userns.conf";
 624         $inc = "$cfgpath/userns.conf" if !-f $inc;
 625         $raw .= "lxc.include = $inc\n";
 626     }
 627
 628     my $features = PVE::LXC::Config->parse_features($conf->{features});
 629
 630     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 631     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 632     if ($features->{fuse}) {
 633         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 634         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 635     }
 636
 637     if ($unprivileged && !$features->{force_rw_sys}) {
 638         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 639         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 640         $raw .= "lxc.mount.auto = sys:mixed\n";
 641     }
 642
 643     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 644     # cannot be exposed to the container with r/w access (cgroup perms).
 645     # When this is enabled mounts will still remain in the monitor's namespace
 646     # after the container unmounted them and thus will not detach from their
 647     # files while the container is running!
 648     $raw .= "lxc.monitor.unshare = 1\n";
 649
 650     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 651
 652     # Should we read them from /etc/subuid?
 653     if ($unprivileged && !$custom_idmap) {
 654         $raw .= "lxc.idmap = u 0 100000 65536\n";
 655         $raw .= "lxc.idmap = g 0 100000 65536\n";
 656     }
 657
 658     if (!PVE::LXC::Config->has_dev_console($conf)) {
 659         $raw .= "lxc.console.path = none\n";
 660         if ($cgv1->{devices}) {
 661             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 662         } elsif (defined($cgv2)) {
 663             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 664         }
 665     }
 666
 667     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 668     $raw .= "lxc.tty.max = $ttycount\n";
 669
 670     # some init scripts expect a linux terminal (turnkey).
 671     $raw .= "lxc.environment = TERM=linux\n";
 672
 673     my $utsname = $conf->{hostname} || "CT$vmid";
 674     $raw .= "lxc.uts.name = $utsname\n";
 675
 676     if ($cgv1->{memory}) {
 677         my $memory = $conf->{memory} || 512;
 678         my $swap = $conf->{swap} // 0;
 679
 680         my $lxcmem = int($memory*1024*1024);
 681         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 682
 683         my $lxcswap = int(($memory + $swap)*1024*1024);
 684         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 685     } elsif ($cgv2->{memory}) {
 686         my $memory = $conf->{memory} || 512;
 687         my $swap = $conf->{swap} // 0;
 688
 689         my $lxcmem = int($memory*1024*1024);
 690         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 691
 692         my $lxcswap = int($swap*1024*1024);
 693         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 694     }
 695
 696     if ($cgv1->{cpu}) {
 697         if (my $cpulimit = $conf->{cpulimit}) {
 698             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 699             my $value = int(100000*$cpulimit);
 700             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 701         }
 702
 703         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 704         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 705     } elsif ($cgv2->{cpu}) {
 706         # See PVE::CGroup
 707         if (my $cpulimit = $conf->{cpulimit}) {
 708             my $value = int(100000*$cpulimit);
 709             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 710         }
 711
 712         if (defined(my $shares = $conf->{cpuunits})) {
 713             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 714             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 715         }
 716     }
 717
 718     die "missing 'rootfs' configuration\n"
 719         if !defined($conf->{rootfs});
 720
 721     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 722
 723     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 724
 725     foreach my $k (sort keys %$conf) {
 726         next if $k !~ m/^net(\d+)$/;
 727         my $ind = $1;
 728         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 729         $raw .= "lxc.net.$ind.type = veth\n";
 730         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 731         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 732         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 733
 734         # Keep container from starting with invalid mtu configuration
 735         if (my $mtu = $d->{mtu}) {
 736             my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 737             die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 738                 if ($mtu > $bridge_mtu);
 739
 740             $raw .= "lxc.net.$ind.mtu = $mtu\n";
 741         }
 742
 743         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 744         if ($lxc_major >= 4) {
 745             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 746         }
 747     }
 748
 749     my $had_cpuset = 0;
 750     if (my $lxcconf = $conf->{lxc}) {
 751         foreach my $entry (@$lxcconf) {
 752             my ($k, $v) = @$entry;
 753             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 754             $raw .= "$k = $v\n";
 755         }
 756     }
 757
 758     my $cpuset;
 759     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 760     if (defined($cpuset_cgroup)) {
 761         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 762             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 763     }
 764     my $cores = $conf->{cores};
 765     if (!$had_cpuset && $cores && $cpuset) {
 766         my @members = $cpuset->members();
 767         while (scalar(@members) > $cores) {
 768             my $randidx = int(rand(scalar(@members)));
 769             $cpuset->delete($members[$randidx]);
 770             splice(@members, $randidx, 1); # keep track of the changes
 771         }
 772         my $ver = $cpuset_version == 1 ? '' : '2';
 773         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 774     }
 775
 776     File::Path::mkpath("$dir/rootfs");
 777
 778     PVE::Tools::file_set_contents("$dir/config", $raw);
 779 }
 780
 781 # verify and cleanup nameserver list (replace \0 with ' ')
 782 sub verify_nameserver_list {
 783     my ($nameserver_list) = @_;
 784
 785     my @list = ();
 786     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 787         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 788         push @list, $server;
 789     }
 790
 791     return join(' ', @list);
 792 }
 793
 794 sub verify_searchdomain_list {
 795     my ($searchdomain_list) = @_;
 796
 797     my @list = ();
 798     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 799         # todo: should we add checks for valid dns domains?
 800         push @list, $server;
 801     }
 802
 803     return join(' ', @list);
 804 }
 805
 806 sub get_console_command {
 807     my ($vmid, $conf, $escapechar) = @_;
 808
 809     # '-1' as $escapechar disables keyboard escape sequence
 810     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 811
 812     my $cmode = PVE::LXC::Config->get_cmode($conf);
 813
 814     my $cmd = [];
 815     if ($cmode eq 'console') {
 816         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 817         push @$cmd, '-e', $escapechar if $escapechar;
 818     } elsif ($cmode eq 'tty') {
 819         push @$cmd, 'lxc-console', '-n',  $vmid;
 820         push @$cmd, '-e', $escapechar if $escapechar;
 821     } elsif ($cmode eq 'shell') {
 822         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 823     } else {
 824         die "internal error";
 825     }
 826
 827     return $cmd;
 828 }
 829
 830 sub get_primary_ips {
 831     my ($conf) = @_;
 832
 833     # return data from net0
 834
 835     return undef if !defined($conf->{net0});
 836     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 837
 838     my $ipv4 = $net->{ip};
 839     if ($ipv4) {
 840         if ($ipv4 =~ /^(dhcp|manual)$/) {
 841             $ipv4 = undef
 842         } else {
 843             $ipv4 =~ s!/\d+$!!;
 844         }
 845     }
 846     my $ipv6 = $net->{ip6};
 847     if ($ipv6) {
 848         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 849             $ipv6 = undef;
 850         } else {
 851             $ipv6 =~ s!/\d+$!!;
 852         }
 853     }
 854
 855     return ($ipv4, $ipv6);
 856 }
 857
 858 sub delete_mountpoint_volume {
 859     my ($storage_cfg, $vmid, $volume) = @_;
 860
 861     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 862
 863     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 864
 865     if ($vmid == $owner) {
 866         PVE::Storage::vdisk_free($storage_cfg, $volume);
 867     } else {
 868         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 869     }
 870 }
 871
 872 sub destroy_lxc_container {
 873     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 874
 875     my $volids = {};
 876     my $remove_volume = sub {
 877         my ($ms, $mountpoint) = @_;
 878
 879         my $volume = $mountpoint->{volume};
 880
 881         return if $volids->{$volume};
 882         $volids->{$volume} = 1;
 883
 884         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 885     };
 886     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 887
 888     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 889
 890     if ($purge_unreferenced) { # also remove unreferenced disk
 891         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 892         PVE::Storage::foreach_volid($vmdisks, sub {
 893             my ($volid, $sid, $volname, $d) = @_;
 894             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 895             warn $@ if $@;
 896         });
 897     }
 898
 899     rmdir "/var/lib/lxc/$vmid/rootfs";
 900     unlink "/var/lib/lxc/$vmid/config";
 901     rmdir "/var/lib/lxc/$vmid";
 902     if (defined $replacement_conf) {
 903         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 904     } else {
 905         PVE::LXC::Config->destroy_config($vmid);
 906     }
 907 }
 908
 909 sub vm_stop_cleanup {
 910     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 911
 912     return if $keepActive;
 913
 914     eval {
 915         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 916         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 917     };
 918     warn $@ if $@; # avoid errors - just warn
 919 }
 920
 921 sub net_tap_plug : prototype($$) {
 922     my ($iface, $net) = @_;
 923
 924     if (defined($net->{link_down})) {
 925         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 926         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 927         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 928         return;
 929     }
 930
 931     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 932         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 933
 934     if ($have_sdn) {
 935         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 936         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge, $firewall);
 937     } else {
 938         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 939     }
 940
 941     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 942 }
 943
 944 sub update_net {
 945     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 946
 947     if ($newnet->{type} ne 'veth') {
 948         # for when there are physical interfaces
 949         die "cannot update interface of type $newnet->{type}";
 950     }
 951
 952     my $veth = "veth${vmid}i${netid}";
 953     my $eth = $newnet->{name};
 954
 955     if (my $oldnetcfg = $conf->{$opt}) {
 956         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 957
 958         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 959             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 960
 961             PVE::Network::veth_delete($veth);
 962             delete $conf->{$opt};
 963             PVE::LXC::Config->write_config($vmid, $conf);
 964
 965             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 966
 967         } else {
 968             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 969                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 970                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 971                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 972             ) {
 973
 974                 if ($oldnet->{bridge}) {
 975                     PVE::Network::tap_unplug($veth);
 976                     foreach (qw(bridge tag firewall)) {
 977                         delete $oldnet->{$_};
 978                     }
 979                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 980                     PVE::LXC::Config->write_config($vmid, $conf);
 981                 }
 982
 983                 PVE::LXC::net_tap_plug($veth, $newnet);
 984
 985                 # This includes the rate:
 986                 foreach (qw(bridge tag firewall rate link_down)) {
 987                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 988                 }
 989             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 990                 # Rate can be applied on its own but any change above needs to
 991                 # include the rate in tap_plug since OVS resets everything.
 992                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 993                 $oldnet->{rate} = $newnet->{rate}
 994             }
 995             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 996             PVE::LXC::Config->write_config($vmid, $conf);
 997         }
 998     } else {
 999         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1000     }
1001
1002     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1003 }
1004
1005 sub hotplug_net {
1006     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1007
1008     my $veth = "veth${vmid}i${netid}";
1009     my $vethpeer = $veth . "p";
1010     my $eth = $newnet->{name};
1011
1012     if ($have_sdn) {
1013         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1014     } else {
1015         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1016     }
1017
1018     PVE::LXC::net_tap_plug($veth, $newnet);
1019
1020     # attach peer in container
1021     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1022     PVE::Tools::run_command($cmd);
1023
1024     # link up peer in container
1025     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1026     PVE::Tools::run_command($cmd);
1027
1028     my $done = { type => 'veth' };
1029     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1030         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1031     }
1032     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1033
1034     PVE::LXC::Config->write_config($vmid, $conf);
1035 }
1036
1037 sub update_ipconfig {
1038     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1039
1040     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1041
1042     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1043     my $deleted = [];
1044     my $added = [];
1045     my $nscmd = sub {
1046         my $cmdargs = shift;
1047         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1048     };
1049     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1050
1051     my $change_ip_config = sub {
1052         my ($ipversion) = @_;
1053
1054         my $family_opt = "-$ipversion";
1055         my $suffix = $ipversion == 4 ? '' : $ipversion;
1056         my $gw= "gw$suffix";
1057         my $ip= "ip$suffix";
1058
1059         my $newip = $newnet->{$ip};
1060         my $newgw = $newnet->{$gw};
1061         my $oldip = $optdata->{$ip};
1062         my $oldgw = $optdata->{$gw};
1063
1064         my $change_ip = safe_string_ne($oldip, $newip);
1065         my $change_gw = safe_string_ne($oldgw, $newgw);
1066
1067         return if !$change_ip && !$change_gw;
1068
1069         # step 1: add new IP, if this fails we cancel
1070         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1071         if ($change_ip && $is_real_ip) {
1072             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1073             if (my $err = $@) {
1074                 warn $err;
1075                 return;
1076             }
1077         }
1078
1079         # step 2: replace gateway
1080         #   If this fails we delete the added IP and cancel.
1081         #   If it succeeds we save the config and delete the old IP, ignoring
1082         #   errors. The config is then saved.
1083         # Note: 'ip route replace' can add
1084         if ($change_gw) {
1085             if ($newgw) {
1086                 eval {
1087                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1088                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1089                     }
1090                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1091                 };
1092                 if (my $err = $@) {
1093                     warn $err;
1094                     # the route was not replaced, the old IP is still available
1095                     # rollback (delete new IP) and cancel
1096                     if ($change_ip) {
1097                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1098                         warn $@ if $@; # no need to die here
1099                     }
1100                     return;
1101                 }
1102             } else {
1103                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1104                 # if the route was not deleted, the guest might have deleted it manually
1105                 # warn and continue
1106                 warn $@ if $@;
1107             }
1108             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1109                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1110                 # warn if the route was deleted manually
1111                 warn $@ if $@;
1112             }
1113         }
1114
1115         # from this point on we save the configuration
1116         # step 3: delete old IP ignoring errors
1117         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1118             # We need to enable promote_secondaries, otherwise our newly added
1119             # address will be removed along with the old one.
1120             my $promote = 0;
1121             eval {
1122                 if ($ipversion == 4) {
1123                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1124                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1125                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1126                 }
1127                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1128             };
1129             warn $@ if $@; # no need to die here
1130
1131             if ($ipversion == 4) {
1132                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1133             }
1134         }
1135
1136         foreach my $property ($ip, $gw) {
1137             if ($newnet->{$property}) {
1138                 $optdata->{$property} = $newnet->{$property};
1139             } else {
1140                 delete $optdata->{$property};
1141             }
1142         }
1143         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1144         PVE::LXC::Config->write_config($vmid, $conf);
1145         $lxc_setup->setup_network($conf);
1146     };
1147
1148     &$change_ip_config(4);
1149     &$change_ip_config(6);
1150
1151 }
1152
1153 my $open_namespace = sub {
1154     my ($vmid, $pid, $kind) = @_;
1155     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1156         or die "failed to open $kind namespace of container $vmid: $!\n";
1157     return $fd;
1158 };
1159
1160 my $enter_namespace = sub {
1161     my ($vmid, $pid, $kind, $type) = @_;
1162     my $fd = $open_namespace->($vmid, $pid, $kind);
1163     PVE::Tools::setns(fileno($fd), $type)
1164         or die "failed to enter $kind namespace of container $vmid: $!\n";
1165     close $fd;
1166 };
1167
1168 my $get_container_namespace = sub {
1169     my ($vmid, $pid, $kind) = @_;
1170
1171     my $pidfd;
1172     if (!defined($pid)) {
1173         # Pin the pid while we're grabbing its stuff from /proc
1174         ($pid, $pidfd) = open_lxc_pid($vmid)
1175             or die "failed to open pidfd of container $vmid\'s init process\n";
1176     }
1177
1178     return $open_namespace->($vmid, $pid, $kind);
1179 };
1180
1181 my $do_syncfs = sub {
1182     my ($vmid, $pid, $socket) = @_;
1183
1184     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1185
1186     # Tell the parent process to start reading our /proc/mounts
1187     print {$socket} "go\n";
1188     $socket->flush();
1189
1190     # Receive /proc/self/mounts
1191     my $mountdata = do { local $/ = undef; <$socket> };
1192     close $socket;
1193
1194     my %nosyncfs = (
1195         cgroup => 1,
1196         cgroup2 => 1,
1197         devtmpfs => 1,
1198         devpts => 1,
1199         'fuse.lxcfs' => 1,
1200         fusectl => 1,
1201         mqueue => 1,
1202         proc => 1,
1203         sysfs => 1,
1204         tmpfs => 1,
1205     );
1206
1207     # Now sync all mountpoints...
1208     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1209     foreach my $mp (@$mounts) {
1210         my ($what, $dir, $fs) = @$mp;
1211         next if $nosyncfs{$fs};
1212         eval { PVE::Tools::sync_mountpoint($dir); };
1213         warn $@ if $@;
1214     }
1215 };
1216
1217 sub sync_container_namespace {
1218     my ($vmid) = @_;
1219     my $pid = find_lxc_pid($vmid);
1220
1221     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1222     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1223         or die "failed to create socketpair: $!\n";
1224
1225     my $child = fork();
1226     die "fork failed: $!\n" if !defined($child);
1227
1228     if (!$child) {
1229         eval {
1230             close $pfd;
1231             &$do_syncfs($vmid, $pid, $cfd);
1232         };
1233         if (my $err = $@) {
1234             warn $err;
1235             POSIX::_exit(1);
1236         }
1237         POSIX::_exit(0);
1238     }
1239     close $cfd;
1240     my $go = <$pfd>;
1241     die "failed to enter container namespace\n" if $go ne "go\n";
1242
1243     open my $mounts, '<', "/proc/$child/mounts"
1244         or die "failed to open container's /proc/mounts: $!\n";
1245     my $mountdata = do { local $/ = undef; <$mounts> };
1246     close $mounts;
1247     print {$pfd} $mountdata;
1248     close $pfd;
1249
1250     while (waitpid($child, 0) != $child) {}
1251     die "failed to sync container namespace\n" if $? != 0;
1252 }
1253
1254 sub template_create {
1255     my ($vmid, $conf) = @_;
1256
1257     my $storecfg = PVE::Storage::config();
1258
1259     PVE::LXC::Config->foreach_volume($conf, sub {
1260         my ($ms, $mountpoint) = @_;
1261
1262         my $volid = $mountpoint->{volume};
1263
1264         die "Template feature is not available for '$volid'\n"
1265             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1266     });
1267
1268     PVE::LXC::Config->foreach_volume($conf, sub {
1269         my ($ms, $mountpoint) = @_;
1270
1271         my $volid = $mountpoint->{volume};
1272
1273         PVE::Storage::activate_volumes($storecfg, [$volid]);
1274
1275         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1276         $mountpoint->{volume} = $template_volid;
1277         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1278     });
1279
1280     PVE::LXC::Config->write_config($vmid, $conf);
1281 }
1282
1283 sub check_ct_modify_config_perm {
1284     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1285
1286     return 1 if $authuser eq 'root@pam';
1287     my $storage_cfg = PVE::Storage::config();
1288
1289     my $check = sub {
1290         my ($opt, $delete) = @_;
1291         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1292             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1293         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1294             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1295             return if $delete;
1296             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1297             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1298                 if $data->{type} ne 'volume';
1299             my $volid = $data->{volume};
1300             if ($volid =~ $NEW_DISK_RE) {
1301                 my $sid = $1;
1302                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1303             } else {
1304                 PVE::Storage::check_volume_access(
1305                     $rpcenv,
1306                     $authuser,
1307                     $storage_cfg,
1308                     $vmid,
1309                     $volid,
1310                     'rootdir',
1311                 );
1312             }
1313         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1314             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1315         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1316                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1317             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1318         } elsif ($opt eq 'features') {
1319             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1320                 if !$unprivileged;
1321
1322             my $nesting_changed = 0;
1323             my $other_changed = 0;
1324             if (!$delete) {
1325                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1326                 if (defined($oldconf) && $oldconf->{$opt}) {
1327                     # existing container with features
1328                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1329                     for my $feature ((keys %$old_features, keys %$features)) {
1330                         my $old = $old_features->{$feature} // '';
1331                         my $new = $features->{$feature} // '';
1332                         if ($old ne $new) {
1333                             if ($feature eq 'nesting') {
1334                                 $nesting_changed = 1;
1335                                 next;
1336                             } else {
1337                                 $other_changed = 1;
1338                                 last;
1339                             }
1340                         }
1341                     }
1342                 } else {
1343                     # new container or no features defined
1344                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1345                         $nesting_changed = 1;
1346                     } elsif (scalar(keys %$features) > 0) {
1347                         $other_changed = 1;
1348                     }
1349                 }
1350             } else {
1351                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1352                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1353                     $nesting_changed = 1;
1354                 } elsif (scalar(keys %$features) > 0) {
1355                     $other_changed = 1;
1356                 }
1357             }
1358             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1359                 if $other_changed;
1360             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1361                 if $nesting_changed;
1362         } elsif ($opt eq 'hookscript') {
1363             # For now this is restricted to root@pam
1364             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1365         } elsif ($opt eq 'tags') {
1366             my $old = $oldconf->{$opt};
1367             my $new = $delete ? '' : $newconf->{$opt};
1368             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1369         } else {
1370             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1371         }
1372     };
1373
1374     foreach my $opt (keys %$newconf) {
1375         &$check($opt, 0);
1376     }
1377     foreach my $opt (@$delete) {
1378         &$check($opt, 1);
1379     }
1380
1381     return 1;
1382 }
1383
1384 sub umount_all {
1385     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1386
1387     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1388     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1389
1390     my $res = 1;
1391
1392     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1393         my ($ms, $mountpoint) = @_;
1394
1395         my $volid = $mountpoint->{volume};
1396         my $mount = $mountpoint->{mp};
1397
1398         return if !$volid || !$mount;
1399
1400         my $mount_path = "$rootdir/$mount";
1401         $mount_path =~ s!/+!/!g;
1402
1403         return if !PVE::ProcFSTools::is_mounted($mount_path);
1404
1405         eval {
1406             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1407         };
1408         if (my $err = $@) {
1409             if ($noerr) {
1410                 $res = 0;
1411                 warn $err;
1412             } else {
1413                 die $err;
1414             }
1415         }
1416     });
1417
1418     return $res; # tell caller if (some) umounts failed for the noerr case
1419 }
1420
1421 sub mount_all {
1422     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1423
1424     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1425     File::Path::make_path($rootdir);
1426
1427     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1428     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1429
1430     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1431
1432     eval {
1433         PVE::LXC::Config->foreach_volume($conf, sub {
1434             my ($ms, $mountpoint) = @_;
1435
1436             $mountpoint->{ro} = 0 if $ignore_ro;
1437
1438             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1439         });
1440     };
1441     if (my $err = $@) {
1442         warn "mounting container failed\n";
1443         umount_all($vmid, $storage_cfg, $conf, 1);
1444         die $err;
1445     }
1446
1447     return $rootdir;
1448 }
1449
1450
1451 sub mountpoint_mount_path {
1452     my ($mountpoint, $storage_cfg, $snapname) = @_;
1453
1454     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1455 }
1456
1457 sub query_loopdev {
1458     my ($path) = @_;
1459     my $found;
1460     my $parser = sub {
1461         my $line = shift;
1462         if ($line =~ m@^(/dev/loop\d+):@) {
1463             $found = $1;
1464         }
1465     };
1466     my $cmd = ['losetup', '--associated', $path];
1467     PVE::Tools::run_command($cmd, outfunc => $parser);
1468     return $found;
1469 }
1470
1471 # Run a function with a file attached to a loop device.
1472 # The loop device is always detached afterwards (or set to autoclear).
1473 # Returns the loop device.
1474 sub run_with_loopdev {
1475     my ($func, $file, $readonly) = @_;
1476     my $device = query_loopdev($file);
1477     # Try to reuse an existing device
1478     if ($device) {
1479         # We assume that whoever setup the loop device is responsible for
1480         # detaching it.
1481         &$func($device);
1482         return $device;
1483     }
1484
1485     my $parser = sub {
1486         my $line = shift;
1487         if ($line =~ m@^(/dev/loop\d+)$@) {
1488             $device = $1;
1489         }
1490     };
1491     my $losetup_cmd = [
1492         'losetup',
1493         '--show',
1494         '-f',
1495         $file,
1496     ];
1497     push @$losetup_cmd, '-r' if $readonly;
1498     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1499     die "failed to setup loop device for $file\n" if !$device;
1500     eval { &$func($device); };
1501     my $err = $@;
1502     PVE::Tools::run_command(['losetup', '-d', $device]);
1503     die $err if $err;
1504     return $device;
1505 }
1506
1507 # In scalar mode: returns a file handle to the deepest directory node.
1508 # In list context: returns a list of:
1509 #   * the deepest directory node
1510 #   * the 2nd deepest directory (parent of the above)
1511 #   * directory name of the last directory
1512 # So that the path $2/$3 should lead to $1 afterwards.
1513 sub walk_tree_nofollow($$$;$$) {
1514     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1515
1516     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1517         or die "failed to open start directory $start: $!\n";
1518
1519     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1520 }
1521
1522
1523 sub walk_tree_nofollow_fd($$$$;$$) {
1524     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1525
1526     # splitdir() returns '' for empty components including the leading /
1527     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1528
1529     my $fd = $start_fd;
1530     my $dir = $start_dirname;
1531     my $last_component = undef;
1532     my $second = $fd;
1533     foreach my $component (@comps) {
1534         $dir .= "/$component";
1535         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1536
1537         if (!$next) {
1538             # failed, check for symlinks and try to create the path
1539             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1540             die "cannot open directory $dir: $!\n" if !$mkdir;
1541
1542             # We don't check for errors on mkdirat() here and just try to
1543             # openat() again, since at least one error (EEXIST) is an
1544             # expected possibility if multiple containers start
1545             # simultaneously. If someone else injects a symlink now then
1546             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1547             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1548
1549             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1550             die "failed to create path: $dir: $!\n" if !$next;
1551
1552             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1553                 if defined($rootuid) && defined($rootgid);
1554         }
1555
1556         close $second if defined($last_component) && $second != $start_fd;
1557         $last_component = $component;
1558         $second = $fd;
1559         $fd = $next;
1560     }
1561
1562     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1563     close $second if defined($last_component) && $second != $start_fd;
1564     return $fd;
1565 }
1566
1567 # To guard against symlink attack races against other currently running
1568 # containers with shared recursive bind mount hierarchies we prepare a
1569 # directory handle for the directory we're mounting over to verify the
1570 # mountpoint afterwards.
1571 sub __bindmount_prepare {
1572     my ($hostroot, $dir) = @_;
1573     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1574     return $srcdh;
1575 }
1576
1577 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1578 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1579 # we intended to bind mount.
1580 sub __bindmount_verify {
1581     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1582     my $destdh;
1583     if ($parentfd) {
1584         # Open the mount point path coming from the parent directory since the
1585         # filehandle we would have gotten as first result of walk_tree_nofollow
1586         # earlier is still a handle to the underlying directory instead of the
1587         # mounted path.
1588         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1589         die "failed to open mount point: $!\n" if !$destdh;
1590         if ($ro) {
1591             my $dot = '.';
1592             # no separate function because 99% of the time it's the wrong thing to use.
1593             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1594                 die "failed to mark bind mount read only\n";
1595             }
1596             die "read-only check failed: $!\n" if $! != EROFS;
1597         }
1598     } else {
1599         # For the rootfs we don't have a parentfd so we open the path directly.
1600         # Note that this means bindmounting any prefix of the host's
1601         # /var/lib/lxc/$vmid path into another container is considered a grave
1602         # security error.
1603         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1604         die "failed to open mount point: $!\n" if !$destdh;
1605     }
1606
1607     my ($srcdev, $srcinode) = stat($srcdh);
1608     my ($dstdev, $dstinode) = stat($destdh);
1609     close $srcdh;
1610     close $destdh;
1611
1612     return ($srcdev == $dstdev && $srcinode == $dstinode);
1613 }
1614
1615 # Perform the actual bind mounting:
1616 sub __bindmount_do {
1617     my ($dir, $dest, $ro, @extra_opts) = @_;
1618     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1619     if ($ro) {
1620         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1621         if (my $err = $@) {
1622             warn "bindmount error\n";
1623             # don't leave writable bind-mounts behind...
1624             PVE::Tools::run_command(['umount', $dest]);
1625             die $err;
1626         }
1627     }
1628 }
1629
1630 sub bindmount {
1631     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1632
1633     my $srcdh = __bindmount_prepare('/', $dir);
1634
1635     __bindmount_do($dir, $dest, $ro, @extra_opts);
1636
1637     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1638         PVE::Tools::run_command(['umount', $dest]);
1639         die "detected mount path change at: $dir\n";
1640     }
1641 }
1642
1643 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1644 # from $rootdir and $mount and walk the path from $rootdir to the final
1645 # directory to check for symlinks.
1646 sub __mount_prepare_rootdir {
1647     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1648     $rootdir =~ s!/+!/!g;
1649     $rootdir =~ s!/+$!!;
1650     my $mount_path = "$rootdir/$mount";
1651     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1652     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1653 }
1654
1655 # use $rootdir = undef to just return the corresponding mount path
1656 sub mountpoint_mount {
1657     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1658     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1659 }
1660
1661 sub mountpoint_stage {
1662     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1663     my ($path, $loop, $dev) =
1664         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1665
1666     if (!defined($path)) {
1667         return undef if $! == ENOSYS;
1668         die "failed to mount subvolume: $!\n";
1669     }
1670
1671     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1672     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1673     # point).
1674     my $err;
1675     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1676         or die "open_tree() on mount point failed: $!\n";
1677
1678     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1679 }
1680
1681 sub mountpoint_insert_staged {
1682     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1683
1684     if (!defined($rootdir_fd)) {
1685         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1686             or die "failed to open '.': $!\n";
1687     }
1688
1689     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1690
1691     PVE::Tools::move_mount(
1692         fileno($mount_fd),
1693         '',
1694         fileno($dest_fd),
1695         '',
1696         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1697     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1698 }
1699
1700 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1701 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1702 #   Note that if the kernel does not support the new mount API, this will not perform any action
1703 #   and return `undef` with $! = ENOSYS.
1704 sub __mountpoint_mount {
1705     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1706
1707     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1708         $! = ENOSYS;
1709         return undef;
1710     }
1711
1712     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1713     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1714     # which we use in __bindmount_verify()!
1715     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1716
1717     my $volid = $mountpoint->{volume};
1718     my $type = $mountpoint->{type};
1719     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1720     my $mounted_dev;
1721
1722     return if !$volid || !$mount;
1723
1724     $mount =~ s!/+!/!g;
1725
1726     my $mount_path;
1727     my ($mpfd, $parentfd, $last_dir);
1728
1729     if (defined($rootdir)) {
1730         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1731             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1732     }
1733
1734     if (defined($stage_mount)) {
1735         $mount_path = $rootdir;
1736     }
1737
1738     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1739
1740     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1741
1742     my $optlist = [];
1743
1744     if (my $mountopts = $mountpoint->{mountoptions}) {
1745         my @opts = split(/;/, $mountpoint->{mountoptions});
1746         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1747     }
1748
1749     my $acl = $mountpoint->{acl};
1750     if (defined($acl)) {
1751         push @$optlist, ($acl ? 'acl' : 'noacl');
1752     }
1753
1754     my $optstring = join(',', @$optlist);
1755     my $readonly = $mountpoint->{ro};
1756
1757     my @extra_opts;
1758     @extra_opts = ('-o', $optstring) if $optstring;
1759
1760     if ($storage) {
1761
1762         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1763
1764         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1765
1766         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1767
1768         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1769             PVE::Storage::parse_volname($storage_cfg, $volid);
1770
1771         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1772
1773         if ($format eq 'subvol') {
1774             if ($mount_path) {
1775                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1776                 if (defined($snapname)) {
1777                     $name .= "\@$snapname";
1778                     if ($scfg->{type} eq 'zfspool') {
1779                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1780                     } else {
1781                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1782                     }
1783                 } else {
1784                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1785                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1786                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1787                     }
1788                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1789                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1790                 }
1791             }
1792             return wantarray ? ($path, 0, undef) : $path;
1793         } elsif ($format eq 'raw' || $format eq 'iso') {
1794             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1795             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1796             # Our autodev hook expects the /dev/dm-* device currently
1797             # and will create the /dev/mapper symlink accordingly
1798             $path = Cwd::realpath($path);
1799             die "failed to get device path\n" if !$path;
1800             ($path) = ($path =~ /^(.*)$/s); #untaint
1801             my $domount = sub {
1802                 my ($path) = @_;
1803                 if ($mount_path) {
1804                     if ($format eq 'iso') {
1805                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1806                     } elsif ($isBase || defined($snapname)) {
1807                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1808                     } else {
1809                         if ($quota) {
1810                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1811                         }
1812                         push @extra_opts, '-o', 'ro' if $readonly;
1813                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1814                     }
1815                 }
1816             };
1817             my $use_loopdev = 0;
1818             if ($scfg->{content}->{rootdir}) {
1819                 if ($scfg->{path}) {
1820                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1821                     $use_loopdev = 1;
1822                 } else {
1823                     $mounted_dev = $path;
1824                     &$domount($path);
1825                 }
1826             } else {
1827                 die "storage '$storage' does not support containers\n";
1828             }
1829             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1830         } else {
1831             die "unsupported image format '$format'\n";
1832         }
1833     } elsif ($type eq 'device') {
1834         push @extra_opts, '-o', 'ro' if $readonly;
1835         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1836         # See the NOTE above about devicemapper canonicalization
1837         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1838         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1839         return wantarray ? ($volid, 0, $devpath) : $volid;
1840     } elsif ($type eq 'bind') {
1841         die "directory '$volid' does not exist\n" if ! -d $volid;
1842         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1843         warn "cannot enable quota control for bind mounts\n" if $quota;
1844         return wantarray ? ($volid, 0, undef) : $volid;
1845     }
1846
1847     die "unsupported storage";
1848 }
1849
1850 sub mountpoint_hotplug :prototype($$$$$) {
1851     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1852
1853     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1854
1855     # We do the rest in a fork with an unshared mount namespace, because:
1856     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1857     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1858     #     container's namespace, then mount it.
1859
1860     PVE::Tools::run_fork(sub {
1861         # Pin the container pid longer, we also need to get its monitor/parent:
1862         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1863             or die "failed to open pidfd of container $vmid\'s init process\n";
1864
1865         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1866             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1867
1868         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1869         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1870
1871         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1872         # profile to lower our privileges to the same level we have in the start hook:
1873         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1874             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1875         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1876         # apparmor.
1877
1878         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1879         # namespace for it to remain active there since the container will be able to unmount
1880         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1881         # concern.
1882         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1883         chdir('/')
1884             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1885
1886         my $dir = get_staging_mount_path($opt);
1887
1888         # Now switch our apparmor profile before mounting:
1889         my $data = 'changeprofile /usr/bin/lxc-start';
1890         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1891             die "failed to change apparmor profile: $!\n";
1892         }
1893         # Check errors on close as well:
1894         close($aa_fd)
1895             or die "failed to change apparmor profile (close() failed): $!\n";
1896
1897         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1898
1899         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1900         chdir('/')
1901             or die "failed to change root directory within the container's mount namespace: $!\n";
1902
1903         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1904     });
1905 }
1906
1907 # Create a directory in the mountpoint staging tempfs.
1908 sub get_staging_mount_path($) {
1909     my ($opt) = @_;
1910
1911     my $target = get_staging_tempfs() . "/$opt";
1912     if (!mkdir($target) && $! != EEXIST) {
1913         die "failed to create directory $target: $!\n";
1914     }
1915
1916     return $target;
1917 }
1918
1919 # Mount /run/pve/mountpoints as tmpfs
1920 sub get_staging_tempfs() {
1921     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1922     # mounts to that.
1923     my $target = '/var/lib/lxc/.pve-staged-mounts';
1924     if (!mkdir($target)) {
1925         return $target if $! == EEXIST;
1926         die "failed to create directory $target: $!\n";
1927     }
1928
1929     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1930         or die "failed to mount $target as tmpfs: $!\n";
1931
1932     return $target;
1933 }
1934
1935 sub mkfs {
1936     my ($dev, $rootuid, $rootgid) = @_;
1937
1938     run_command(
1939         [
1940             'mkfs.ext4',
1941             '-O',
1942             'mmp',
1943             '-E',
1944             "root_owner=$rootuid:$rootgid",
1945             $dev,
1946         ],
1947         outfunc => sub {
1948             my $line = shift;
1949             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1950             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1951                 print "$line\n";
1952             }
1953         },
1954         errfunc => sub {
1955             my $line = shift;
1956             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1957         }
1958     );
1959 }
1960
1961 sub format_disk {
1962     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1963
1964     if ($volid =~ m!^/dev/.+!) {
1965         mkfs($volid);
1966         return;
1967     }
1968
1969     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1970
1971     die "cannot format volume '$volid' with no storage\n" if !$storage;
1972
1973     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1974
1975     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1976
1977     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1978
1979     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1980         PVE::Storage::parse_volname($storage_cfg, $volid);
1981
1982     die "cannot format volume '$volid' (format == $format)\n"
1983         if $format ne 'raw';
1984
1985     mkfs($path, $rootuid, $rootgid);
1986 }
1987
1988 sub destroy_disks {
1989     my ($storecfg, $vollist) = @_;
1990
1991     foreach my $volid (@$vollist) {
1992         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1993         warn $@ if $@;
1994     }
1995 }
1996
1997 sub alloc_disk {
1998     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1999
2000     my $needs_chown = 0;
2001     my $volid;
2002
2003     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2004     # fixme: use better naming ct-$vmid-disk-X.raw?
2005
2006     eval {
2007         my $do_format = 0;
2008         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2009             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2010                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2011                 $do_format = 1;
2012             } else {
2013                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2014                 $needs_chown = 1;
2015             }
2016         } elsif ($scfg->{type} eq 'zfspool') {
2017             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2018             $needs_chown = 1;
2019         } elsif ($scfg->{content}->{rootdir}) {
2020             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2021             $do_format = 1;
2022         } else {
2023             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2024         }
2025         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2026     };
2027     if (my $err = $@) {
2028         # in case formatting got interrupted:
2029         if (defined($volid)) {
2030             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2031             warn $@ if $@;
2032         }
2033         die $err;
2034     }
2035
2036     return ($volid, $needs_chown);
2037 }
2038
2039 sub create_disks {
2040     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2041
2042     my $vollist = [];
2043
2044     eval {
2045         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2046         my $chown_vollist = [];
2047
2048         PVE::LXC::Config->foreach_volume($settings, sub {
2049             my ($ms, $mountpoint) = @_;
2050
2051             my $volid = $mountpoint->{volume};
2052             my $mp = $mountpoint->{mp};
2053
2054             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2055
2056             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2057                 my ($storeid, $size_gb) = ($1, $2);
2058
2059                 my $size_kb = int(${size_gb}*1024) * 1024;
2060
2061                 my $needs_chown = 0;
2062                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2063                 push @$chown_vollist, $volid if $needs_chown;
2064                 push @$vollist, $volid;
2065                 $mountpoint->{volume} = $volid;
2066                 $mountpoint->{size} = $size_kb * 1024;
2067                 if ($pending) {
2068                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2069                 } else {
2070                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2071                 }
2072             } else {
2073                 # use specified/existing volid/dir/device
2074                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2075             }
2076         });
2077
2078         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2079         foreach my $volid (@$chown_vollist) {
2080             my $path = PVE::Storage::path($storecfg, $volid, undef);
2081             chown($rootuid, $rootgid, $path);
2082         }
2083         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2084     };
2085     # free allocated images on error
2086     if (my $err = $@) {
2087         destroy_disks($storecfg, $vollist);
2088         die $err;
2089     }
2090     return $vollist;
2091 }
2092
2093 sub update_disksize {
2094     my ($vmid, $conf, $all_volumes) = @_;
2095
2096     my $changes;
2097     my $prefix = "CT $vmid:";
2098
2099     my $update_mp = sub {
2100         my ($key, $mp, @param) = @_;
2101         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2102
2103         if (!defined($mp->{size}) || $size != $mp->{size}) {
2104             $changes = 1;
2105             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2106             $mp->{size} = $size;
2107             my $nomp = 1 if ($key eq 'rootfs');
2108             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
2109         }
2110     };
2111
2112     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2113
2114     return $changes;
2115 }
2116
2117 sub update_unused {
2118     my ($vmid, $conf, $all_volumes) = @_;
2119
2120     my $changes;
2121     my $prefix = "CT $vmid:";
2122
2123     # Note: it is allowed to define multiple storage entries with the same path
2124     # (alias), so we need to check both 'volid' and real 'path' (two different
2125     # volid can point to the same path).
2126
2127     # used and unused disks
2128     my $refpath = {};
2129     my $orphans = {};
2130
2131     foreach my $opt (keys %$conf) {
2132         next if ($opt !~ m/^unused\d+$/);
2133         my $vol = $all_volumes->{$conf->{$opt}};
2134         $refpath->{$vol->{path}} = $vol->{volid};
2135     }
2136
2137     foreach my $key (keys %$all_volumes) {
2138         my $vol = $all_volumes->{$key};
2139         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2140         my $path = $vol->{path};
2141
2142         if ($in_use) {
2143             $refpath->{$path} = $key;
2144             delete $orphans->{$path};
2145         } else {
2146             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2147                 $orphans->{$path} = $key;
2148             }
2149         }
2150     }
2151
2152     for my $key (keys %$orphans) {
2153         my $disk = $orphans->{$key};
2154         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2155
2156         if ($unused) {
2157             $changes = 1;
2158             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2159         }
2160     }
2161
2162     return $changes;
2163 }
2164
2165 sub scan_volids {
2166     my ($cfg, $vmid) = @_;
2167
2168     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2169
2170     my $all_volumes = {};
2171     foreach my $storeid (keys %$info) {
2172         foreach my $item (@{$info->{$storeid}}) {
2173             my $volid = $item->{volid};
2174             next if !($volid && $item->{size});
2175             $item->{path} = PVE::Storage::path($cfg, $volid);
2176             $all_volumes->{$volid} = $item;
2177         }
2178     }
2179
2180     return $all_volumes;
2181 }
2182
2183 sub rescan {
2184     my ($vmid, $nolock, $dryrun) = @_;
2185
2186     my $cfg = PVE::Storage::config();
2187
2188     print "rescan volumes...\n";
2189     my $all_volumes = scan_volids($cfg, $vmid);
2190
2191     my $updatefn =  sub {
2192         my ($vmid) = @_;
2193
2194         my $changes;
2195         my $conf = PVE::LXC::Config->load_config($vmid);
2196
2197         PVE::LXC::Config->check_lock($conf);
2198
2199         my $vm_volids = {};
2200         foreach my $volid (keys %$all_volumes) {
2201             my $info = $all_volumes->{$volid};
2202             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2203         }
2204
2205         my $upu = update_unused($vmid, $conf, $vm_volids);
2206         my $upd = update_disksize($vmid, $conf, $vm_volids);
2207         $changes = $upu || $upd;
2208
2209         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2210     };
2211
2212     if (defined($vmid)) {
2213         if ($nolock) {
2214             &$updatefn($vmid);
2215         } else {
2216             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2217         }
2218     } else {
2219         my $vmlist = config_list();
2220         foreach my $vmid (keys %$vmlist) {
2221             if ($nolock) {
2222                 &$updatefn($vmid);
2223             } else {
2224                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2225             }
2226         }
2227     }
2228 }
2229
2230
2231 # bash completion helper
2232
2233 sub complete_os_templates {
2234     my ($cmdname, $pname, $cvalue) = @_;
2235
2236     my $cfg = PVE::Storage::config();
2237
2238     my $storeid;
2239
2240     if ($cvalue =~ m/^([^:]+):/) {
2241         $storeid = $1;
2242     }
2243
2244     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2245     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2246
2247     my $res = [];
2248     foreach my $id (keys %$data) {
2249         foreach my $item (@{$data->{$id}}) {
2250             push @$res, $item->{volid} if defined($item->{volid});
2251         }
2252     }
2253
2254     return $res;
2255 }
2256
2257 my $complete_ctid_full = sub {
2258     my ($running) = @_;
2259
2260     my $idlist = vmstatus();
2261
2262     my $active_hash = list_active_containers();
2263
2264     my $res = [];
2265
2266     foreach my $id (keys %$idlist) {
2267         my $d = $idlist->{$id};
2268         if (defined($running)) {
2269             next if $d->{template};
2270             next if $running && !$active_hash->{$id};
2271             next if !$running && $active_hash->{$id};
2272         }
2273         push @$res, $id;
2274
2275     }
2276     return $res;
2277 };
2278
2279 sub complete_ctid {
2280     return &$complete_ctid_full();
2281 }
2282
2283 sub complete_ctid_stopped {
2284     return &$complete_ctid_full(0);
2285 }
2286
2287 sub complete_ctid_running {
2288     return &$complete_ctid_full(1);
2289 }
2290
2291 sub parse_id_maps {
2292     my ($conf) = @_;
2293
2294     my $id_map = [];
2295     my $rootuid = 0;
2296     my $rootgid = 0;
2297
2298     my $lxc = $conf->{lxc};
2299     foreach my $entry (@$lxc) {
2300         my ($key, $value) = @$entry;
2301         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2302         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2303         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2304             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2305             push @$id_map, [$type, $ct, $host, $length];
2306             if ($ct == 0) {
2307                 $rootuid = $host if $type eq 'u';
2308                 $rootgid = $host if $type eq 'g';
2309             }
2310         } else {
2311             die "failed to parse idmap: $value\n";
2312         }
2313     }
2314
2315     if (!@$id_map && $conf->{unprivileged}) {
2316         # Should we read them from /etc/subuid?
2317         $id_map = [ ['u', '0', '100000', '65536'],
2318                     ['g', '0', '100000', '65536'] ];
2319         $rootuid = $rootgid = 100000;
2320     }
2321
2322     return ($id_map, $rootuid, $rootgid);
2323 }
2324
2325 sub userns_command {
2326     my ($id_map) = @_;
2327     if (@$id_map) {
2328         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2329     }
2330     return [];
2331 }
2332
2333 my sub print_ct_stderr_log {
2334     my ($vmid) = @_;
2335     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2336     return if !$log;
2337
2338     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2339         my $line = $2;
2340         print STDERR "$line\n";
2341     }
2342 }
2343 my sub print_ct_warn_log {
2344     my ($vmid) = @_;
2345     my $log_fn = "/run/pve/ct-$vmid.warnings";
2346     my $log = eval { file_get_contents($log_fn) };
2347     return if !$log;
2348
2349     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2350         PVE::RESTEnvironment::log_warn($1);
2351     }
2352     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2353 }
2354
2355 my sub monitor_state_change($$) {
2356     my ($monitor_socket, $vmid) = @_;
2357     die "no monitor socket\n" if !defined($monitor_socket);
2358
2359     while (1) {
2360         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2361
2362         die "monitor socket: got EOF\n" if !defined($type);
2363
2364         next if $name ne "$vmid" || $type ne 'STATE';
2365
2366         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2367             alarm(0); # don't timeout after seeing the starting state
2368         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2369                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2370                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2371             return 0;
2372         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2373             return 1;
2374         } else {
2375             warn "unexpected message from monitor socket - " .
2376                  "type: '$type' - value: '$value'\n";
2377         }
2378     }
2379 }
2380 my sub monitor_start($$) {
2381     my ($monitor_socket, $vmid) = @_;
2382
2383     my $success = eval {
2384         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2385     };
2386     if (my $err = $@) {
2387         warn "problem with monitor socket, but continuing anyway: $err\n";
2388     } elsif (!$success) {
2389         print_ct_stderr_log($vmid);
2390         die "startup for container '$vmid' failed\n";
2391     }
2392 }
2393
2394 sub vm_start {
2395     my ($vmid, $conf, $skiplock, $debug) = @_;
2396
2397     # apply pending changes while starting
2398     if (scalar(keys %{$conf->{pending}})) {
2399         my $storecfg = PVE::Storage::config();
2400         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2401         PVE::LXC::Config->write_config($vmid, $conf);
2402         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2403     }
2404
2405     update_lxc_config($vmid, $conf);
2406
2407     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2408
2409     if ($skiplock) {
2410         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2411         close($fh);
2412     }
2413
2414     my $storage_cfg = PVE::Storage::config();
2415     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2416
2417     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2418
2419     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2420     warn $@ if $@;
2421
2422     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2423
2424     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2425     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2426
2427     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2428
2429     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2430     eval {
2431         run_command($cmd);
2432
2433         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2434
2435         # if debug is requested, print the log it also when the start succeeded
2436         print_ct_stderr_log($vmid) if $is_debug;
2437
2438         print_ct_warn_log($vmid); # always print warn log, if any
2439     };
2440     if (my $err = $@) {
2441         unlink $skiplock_flag_fn;
2442         die $err;
2443     }
2444     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2445
2446     return;
2447 }
2448
2449 # Helper to stop a container completely and make sure it has stopped completely.
2450 # This is necessary because we want the post-stop hook to have completed its
2451 # unmount-all step, but post-stop happens after lxc puts the container into the
2452 # STOPPED state.
2453 # $kill - if true it will always do an immediate hard-stop
2454 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2455 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2456 sub vm_stop {
2457     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2458
2459     # Open the container's command socket.
2460     my $path = "\0/var/lib/lxc/$vmid/command";
2461     my $sock = IO::Socket::UNIX->new(
2462         Type => SOCK_STREAM(),
2463         Peer => $path,
2464     );
2465     if (!$sock) {
2466         return if $! == ECONNREFUSED; # The container is not running
2467         die "failed to open container ${vmid}'s command socket: $!\n";
2468     }
2469
2470     my $conf = PVE::LXC::Config->load_config($vmid);
2471     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2472
2473     # Stop the container:
2474
2475     my $cmd = ['lxc-stop', '-n', $vmid];
2476
2477     if ($kill) {
2478         push @$cmd, '--kill'; # doesn't allow timeouts
2479     } else {
2480         # lxc-stop uses a default timeout
2481         push @$cmd, '--nokill' if !$kill_after_timeout;
2482
2483         if (defined($shutdown_timeout)) {
2484             push @$cmd, '--timeout', $shutdown_timeout;
2485             # Give run_command 5 extra seconds
2486             $shutdown_timeout += 5;
2487         }
2488     }
2489
2490     eval { run_command($cmd, timeout => $shutdown_timeout) };
2491
2492     # Wait until the command socket is closed.
2493     # In case the lxc-stop call failed, reading from the command socket may block forever,
2494     # so poll with another timeout to avoid freezing the shutdown task.
2495     if (my $err = $@) {
2496         warn $err if $err;
2497
2498         my $poll = IO::Poll->new();
2499         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2500         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2501         return if ($poll->events($sock) & POLLHUP);
2502     } else {
2503         my $result = <$sock>;
2504         return if !defined $result; # monitor is gone and the ct has stopped.
2505     }
2506
2507     die "container did not stop\n";
2508 }
2509
2510 sub vm_reboot {
2511     my ($vmid, $timeout, $skiplock) = @_;
2512
2513     PVE::LXC::Config->lock_config($vmid, sub {
2514         return if !check_running($vmid);
2515
2516         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2517
2518         my $conf = PVE::LXC::Config->load_config($vmid);
2519         vm_start($vmid, $conf);
2520     });
2521 }
2522
2523 sub run_unshared {
2524     my ($code) = @_;
2525
2526     return PVE::Tools::run_fork(sub {
2527         # Unshare the mount namespace
2528         die "failed to unshare mount namespace: $!\n"
2529             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2530         run_command(['mount', '--make-rslave', '/']);
2531         return $code->();
2532     });
2533 }
2534
2535 my $copy_volume = sub {
2536     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2537
2538     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2539     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2540
2541     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2542     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2543
2544     my @mounted;
2545     eval {
2546         # mount and copy
2547         mkdir $src;
2548         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2549         push @mounted, $src;
2550         mkdir $dest;
2551         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2552         push @mounted, $dest;
2553
2554         $bwlimit //= 0;
2555
2556         run_command([
2557             'rsync',
2558             '--stats',
2559             '-X',
2560             '-A',
2561             '--numeric-ids',
2562             '-aH',
2563             '--whole-file',
2564             '--sparse',
2565             '--one-file-system',
2566             "--bwlimit=$bwlimit",
2567             "$src/",
2568             $dest
2569         ]);
2570     };
2571     my $err = $@;
2572
2573     # Wait for rsync's children to release dest so that
2574     # consequent file operations (umount, remove) are possible
2575     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2576
2577     foreach my $mount (reverse @mounted) {
2578         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2579         warn "Can't umount $mount\n" if $@;
2580     }
2581
2582     # If this fails they're used as mount points in a concurrent operation
2583     # (which should not happen but there's also no real need to get rid of them).
2584     rmdir $dest;
2585     rmdir $src;
2586
2587     die $err if $err;
2588 };
2589
2590 # Should not be called after unsharing the mount namespace!
2591 sub copy_volume {
2592     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2593
2594     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2595     File::Path::make_path("/var/lib/lxc/$vmid");
2596     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2597     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2598
2599     # get id's for unprivileged container
2600     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2601
2602     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2603     # are visible in this namespace, otherwise the host only sees the empty
2604     # (not-mounted) directory.
2605     my $new_volid;
2606     eval {
2607         # Make sure $mp contains a correct size.
2608         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2609         my $needs_chown;
2610         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2611         if ($needs_chown) {
2612             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2613             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2614             chown($rootuid, $rootgid, $path);
2615         }
2616
2617         run_unshared(sub {
2618             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2619         });
2620     };
2621     if (my $err = $@) {
2622         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2623             if defined($new_volid);
2624         die $err;
2625     }
2626
2627     return $new_volid;
2628 }
2629
2630 sub get_lxc_version() {
2631     my $version;
2632     run_command([qw(lxc-start --version)], outfunc => sub {
2633         my ($line) = @_;
2634         # We only parse out major & minor version numbers.
2635         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2636             $version = [$1, $2];
2637         }
2638     });
2639
2640     die "failed to get lxc version\n" if !defined($version);
2641
2642     # return as a list:
2643     return $version->@*;
2644 }
2645
2646 sub freeze($) {
2647     my ($vmid) = @_;
2648     if (PVE::CGroup::cgroup_mode() == 2) {
2649         PVE::LXC::Command::freeze($vmid, 30);
2650     } else {
2651         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2652     }
2653 }
2654
2655 sub thaw($) {
2656     my ($vmid) = @_;
2657     if (PVE::CGroup::cgroup_mode() == 2) {
2658         PVE::LXC::Command::unfreeze($vmid, 30);
2659     } else {
2660         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2661     }
2662 }
2663
2664 1;