src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     run_command
  24     dir_glob_foreach
  25     file_get_contents
  26     file_set_contents
  27     AT_FDCWD
  28     O_PATH
  29     $IPV4RE
  30     $IPV6RE
  31 );
  32 use PVE::RPCEnvironment;
  33 use PVE::CpuSet;
  34 use PVE::Network;
  35 use PVE::AccessControl;
  36 use PVE::ProcFSTools;
  37 use PVE::Syscall qw(:fsmount);
  38 use PVE::LXC::Config;
  39 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  40 use PVE::LXC::Tools;
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Monitor;
  43 use PVE::CGroup;
  44
  45 use Time::HiRes qw (gettimeofday);
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         my $lxcmem = int($memory*1024*1024);
 689         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 690
 691         my $lxcswap = int($swap*1024*1024);
 692         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 693     }
 694
 695     if ($cgv1->{cpu}) {
 696         if (my $cpulimit = $conf->{cpulimit}) {
 697             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 698             my $value = int(100000*$cpulimit);
 699             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 700         }
 701
 702         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 703         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 704     } elsif ($cgv2->{cpu}) {
 705         # See PVE::CGroup
 706         if (my $cpulimit = $conf->{cpulimit}) {
 707             my $value = int(100000*$cpulimit);
 708             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 709         }
 710
 711         if (defined(my $shares = $conf->{cpuunits})) {
 712             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 713             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 714         }
 715     }
 716
 717     die "missing 'rootfs' configuration\n"
 718         if !defined($conf->{rootfs});
 719
 720     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 721
 722     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 723
 724     foreach my $k (sort keys %$conf) {
 725         next if $k !~ m/^net(\d+)$/;
 726         my $ind = $1;
 727         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 728         $raw .= "lxc.net.$ind.type = veth\n";
 729         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 730         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 731         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 732         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 733
 734         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 735         if ($lxc_major >= 4) {
 736             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 737         }
 738     }
 739
 740     my $had_cpuset = 0;
 741     if (my $lxcconf = $conf->{lxc}) {
 742         foreach my $entry (@$lxcconf) {
 743             my ($k, $v) = @$entry;
 744             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 745             $raw .= "$k = $v\n";
 746         }
 747     }
 748
 749     my $cpuset;
 750     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 751     if (defined($cpuset_cgroup)) {
 752         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 753             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 754     }
 755     my $cores = $conf->{cores};
 756     if (!$had_cpuset && $cores && $cpuset) {
 757         my @members = $cpuset->members();
 758         while (scalar(@members) > $cores) {
 759             my $randidx = int(rand(scalar(@members)));
 760             $cpuset->delete($members[$randidx]);
 761             splice(@members, $randidx, 1); # keep track of the changes
 762         }
 763         my $ver = $cpuset_version == 1 ? '' : '2';
 764         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 765     }
 766
 767     File::Path::mkpath("$dir/rootfs");
 768
 769     PVE::Tools::file_set_contents("$dir/config", $raw);
 770 }
 771
 772 # verify and cleanup nameserver list (replace \0 with ' ')
 773 sub verify_nameserver_list {
 774     my ($nameserver_list) = @_;
 775
 776     my @list = ();
 777     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 778         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 779         push @list, $server;
 780     }
 781
 782     return join(' ', @list);
 783 }
 784
 785 sub verify_searchdomain_list {
 786     my ($searchdomain_list) = @_;
 787
 788     my @list = ();
 789     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 790         # todo: should we add checks for valid dns domains?
 791         push @list, $server;
 792     }
 793
 794     return join(' ', @list);
 795 }
 796
 797 sub get_console_command {
 798     my ($vmid, $conf, $escapechar) = @_;
 799
 800     # '-1' as $escapechar disables keyboard escape sequence
 801     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 802
 803     my $cmode = PVE::LXC::Config->get_cmode($conf);
 804
 805     my $cmd = [];
 806     if ($cmode eq 'console') {
 807         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 808         push @$cmd, '-e', $escapechar if $escapechar;
 809     } elsif ($cmode eq 'tty') {
 810         push @$cmd, 'lxc-console', '-n',  $vmid;
 811         push @$cmd, '-e', $escapechar if $escapechar;
 812     } elsif ($cmode eq 'shell') {
 813         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 814     } else {
 815         die "internal error";
 816     }
 817
 818     return $cmd;
 819 }
 820
 821 sub get_primary_ips {
 822     my ($conf) = @_;
 823
 824     # return data from net0
 825
 826     return undef if !defined($conf->{net0});
 827     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 828
 829     my $ipv4 = $net->{ip};
 830     if ($ipv4) {
 831         if ($ipv4 =~ /^(dhcp|manual)$/) {
 832             $ipv4 = undef
 833         } else {
 834             $ipv4 =~ s!/\d+$!!;
 835         }
 836     }
 837     my $ipv6 = $net->{ip6};
 838     if ($ipv6) {
 839         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 840             $ipv6 = undef;
 841         } else {
 842             $ipv6 =~ s!/\d+$!!;
 843         }
 844     }
 845
 846     return ($ipv4, $ipv6);
 847 }
 848
 849 sub delete_mountpoint_volume {
 850     my ($storage_cfg, $vmid, $volume) = @_;
 851
 852     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 853
 854     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 855
 856     if ($vmid == $owner) {
 857         PVE::Storage::vdisk_free($storage_cfg, $volume);
 858     } else {
 859         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 860     }
 861 }
 862
 863 sub destroy_lxc_container {
 864     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 865
 866     my $volids = {};
 867     my $remove_volume = sub {
 868         my ($ms, $mountpoint) = @_;
 869
 870         my $volume = $mountpoint->{volume};
 871
 872         return if $volids->{$volume};
 873         $volids->{$volume} = 1;
 874
 875         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 876     };
 877     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 878
 879     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 880
 881     if ($purge_unreferenced) { # also remove unreferenced disk
 882         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 883         PVE::Storage::foreach_volid($vmdisks, sub {
 884             my ($volid, $sid, $volname, $d) = @_;
 885             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 886             warn $@ if $@;
 887         });
 888     }
 889
 890     rmdir "/var/lib/lxc/$vmid/rootfs";
 891     unlink "/var/lib/lxc/$vmid/config";
 892     rmdir "/var/lib/lxc/$vmid";
 893     if (defined $replacement_conf) {
 894         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 895     } else {
 896         PVE::LXC::Config->destroy_config($vmid);
 897     }
 898 }
 899
 900 sub vm_stop_cleanup {
 901     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 902
 903     return if $keepActive;
 904
 905     eval {
 906         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 907         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 908     };
 909     warn $@ if $@; # avoid errors - just warn
 910 }
 911
 912 sub update_net {
 913     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 914
 915     if ($newnet->{type} ne 'veth') {
 916         # for when there are physical interfaces
 917         die "cannot update interface of type $newnet->{type}";
 918     }
 919
 920     my $veth = "veth${vmid}i${netid}";
 921     my $eth = $newnet->{name};
 922
 923     if (my $oldnetcfg = $conf->{$opt}) {
 924         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 925
 926         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 927             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 928
 929             PVE::Network::veth_delete($veth);
 930             delete $conf->{$opt};
 931             PVE::LXC::Config->write_config($vmid, $conf);
 932
 933             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 934
 935         } else {
 936             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 937                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 938                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 939
 940                 if ($oldnet->{bridge}) {
 941                     PVE::Network::tap_unplug($veth);
 942                     foreach (qw(bridge tag firewall)) {
 943                         delete $oldnet->{$_};
 944                     }
 945                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 946                     PVE::LXC::Config->write_config($vmid, $conf);
 947                 }
 948
 949                 if ($have_sdn) {
 950                     PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 951                 } else {
 952                     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 953                 }
 954
 955                 # This includes the rate:
 956                 foreach (qw(bridge tag firewall rate)) {
 957                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 958                 }
 959             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 960                 # Rate can be applied on its own but any change above needs to
 961                 # include the rate in tap_plug since OVS resets everything.
 962                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 963                 $oldnet->{rate} = $newnet->{rate}
 964             }
 965             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 966             PVE::LXC::Config->write_config($vmid, $conf);
 967         }
 968     } else {
 969         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 970     }
 971
 972     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 973 }
 974
 975 sub hotplug_net {
 976     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 977
 978     my $veth = "veth${vmid}i${netid}";
 979     my $vethpeer = $veth . "p";
 980     my $eth = $newnet->{name};
 981
 982     if ($have_sdn) {
 983         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 984         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 985     } else {
 986         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 987         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 988     }
 989
 990     # attach peer in container
 991     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 992     PVE::Tools::run_command($cmd);
 993
 994     # link up peer in container
 995     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 996     PVE::Tools::run_command($cmd);
 997
 998     my $done = { type => 'veth' };
 999     foreach (qw(bridge tag firewall hwaddr name)) {
1000         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1001     }
1002     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1003
1004     PVE::LXC::Config->write_config($vmid, $conf);
1005 }
1006
1007 sub update_ipconfig {
1008     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1009
1010     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1011
1012     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1013     my $deleted = [];
1014     my $added = [];
1015     my $nscmd = sub {
1016         my $cmdargs = shift;
1017         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1018     };
1019     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1020
1021     my $change_ip_config = sub {
1022         my ($ipversion) = @_;
1023
1024         my $family_opt = "-$ipversion";
1025         my $suffix = $ipversion == 4 ? '' : $ipversion;
1026         my $gw= "gw$suffix";
1027         my $ip= "ip$suffix";
1028
1029         my $newip = $newnet->{$ip};
1030         my $newgw = $newnet->{$gw};
1031         my $oldip = $optdata->{$ip};
1032         my $oldgw = $optdata->{$gw};
1033
1034         my $change_ip = safe_string_ne($oldip, $newip);
1035         my $change_gw = safe_string_ne($oldgw, $newgw);
1036
1037         return if !$change_ip && !$change_gw;
1038
1039         # step 1: add new IP, if this fails we cancel
1040         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1041         if ($change_ip && $is_real_ip) {
1042             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1043             if (my $err = $@) {
1044                 warn $err;
1045                 return;
1046             }
1047         }
1048
1049         # step 2: replace gateway
1050         #   If this fails we delete the added IP and cancel.
1051         #   If it succeeds we save the config and delete the old IP, ignoring
1052         #   errors. The config is then saved.
1053         # Note: 'ip route replace' can add
1054         if ($change_gw) {
1055             if ($newgw) {
1056                 eval {
1057                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1058                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1059                     }
1060                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1061                 };
1062                 if (my $err = $@) {
1063                     warn $err;
1064                     # the route was not replaced, the old IP is still available
1065                     # rollback (delete new IP) and cancel
1066                     if ($change_ip) {
1067                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1068                         warn $@ if $@; # no need to die here
1069                     }
1070                     return;
1071                 }
1072             } else {
1073                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1074                 # if the route was not deleted, the guest might have deleted it manually
1075                 # warn and continue
1076                 warn $@ if $@;
1077             }
1078             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1079                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1080                 # warn if the route was deleted manually
1081                 warn $@ if $@;
1082             }
1083         }
1084
1085         # from this point on we save the configuration
1086         # step 3: delete old IP ignoring errors
1087         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1088             # We need to enable promote_secondaries, otherwise our newly added
1089             # address will be removed along with the old one.
1090             my $promote = 0;
1091             eval {
1092                 if ($ipversion == 4) {
1093                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1094                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1095                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1096                 }
1097                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1098             };
1099             warn $@ if $@; # no need to die here
1100
1101             if ($ipversion == 4) {
1102                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1103             }
1104         }
1105
1106         foreach my $property ($ip, $gw) {
1107             if ($newnet->{$property}) {
1108                 $optdata->{$property} = $newnet->{$property};
1109             } else {
1110                 delete $optdata->{$property};
1111             }
1112         }
1113         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1114         PVE::LXC::Config->write_config($vmid, $conf);
1115         $lxc_setup->setup_network($conf);
1116     };
1117
1118     &$change_ip_config(4);
1119     &$change_ip_config(6);
1120
1121 }
1122
1123 my $open_namespace = sub {
1124     my ($vmid, $pid, $kind) = @_;
1125     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1126         or die "failed to open $kind namespace of container $vmid: $!\n";
1127     return $fd;
1128 };
1129
1130 my $enter_namespace = sub {
1131     my ($vmid, $pid, $kind, $type) = @_;
1132     my $fd = $open_namespace->($vmid, $pid, $kind);
1133     PVE::Tools::setns(fileno($fd), $type)
1134         or die "failed to enter $kind namespace of container $vmid: $!\n";
1135     close $fd;
1136 };
1137
1138 my $get_container_namespace = sub {
1139     my ($vmid, $pid, $kind) = @_;
1140
1141     my $pidfd;
1142     if (!defined($pid)) {
1143         # Pin the pid while we're grabbing its stuff from /proc
1144         ($pid, $pidfd) = open_lxc_pid($vmid)
1145             or die "failed to open pidfd of container $vmid\'s init process\n";
1146     }
1147
1148     return $open_namespace->($vmid, $pid, $kind);
1149 };
1150
1151 my $do_syncfs = sub {
1152     my ($vmid, $pid, $socket) = @_;
1153
1154     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1155
1156     # Tell the parent process to start reading our /proc/mounts
1157     print {$socket} "go\n";
1158     $socket->flush();
1159
1160     # Receive /proc/self/mounts
1161     my $mountdata = do { local $/ = undef; <$socket> };
1162     close $socket;
1163
1164     my %nosyncfs = (
1165         cgroup => 1,
1166         cgroup2 => 1,
1167         devtmpfs => 1,
1168         devpts => 1,
1169         'fuse.lxcfs' => 1,
1170         fusectl => 1,
1171         mqueue => 1,
1172         proc => 1,
1173         sysfs => 1,
1174         tmpfs => 1,
1175     );
1176
1177     # Now sync all mountpoints...
1178     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1179     foreach my $mp (@$mounts) {
1180         my ($what, $dir, $fs) = @$mp;
1181         next if $nosyncfs{$fs};
1182         eval { PVE::Tools::sync_mountpoint($dir); };
1183         warn $@ if $@;
1184     }
1185 };
1186
1187 sub sync_container_namespace {
1188     my ($vmid) = @_;
1189     my $pid = find_lxc_pid($vmid);
1190
1191     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1192     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1193         or die "failed to create socketpair: $!\n";
1194
1195     my $child = fork();
1196     die "fork failed: $!\n" if !defined($child);
1197
1198     if (!$child) {
1199         eval {
1200             close $pfd;
1201             &$do_syncfs($vmid, $pid, $cfd);
1202         };
1203         if (my $err = $@) {
1204             warn $err;
1205             POSIX::_exit(1);
1206         }
1207         POSIX::_exit(0);
1208     }
1209     close $cfd;
1210     my $go = <$pfd>;
1211     die "failed to enter container namespace\n" if $go ne "go\n";
1212
1213     open my $mounts, '<', "/proc/$child/mounts"
1214         or die "failed to open container's /proc/mounts: $!\n";
1215     my $mountdata = do { local $/ = undef; <$mounts> };
1216     close $mounts;
1217     print {$pfd} $mountdata;
1218     close $pfd;
1219
1220     while (waitpid($child, 0) != $child) {}
1221     die "failed to sync container namespace\n" if $? != 0;
1222 }
1223
1224 sub template_create {
1225     my ($vmid, $conf) = @_;
1226
1227     my $storecfg = PVE::Storage::config();
1228
1229     PVE::LXC::Config->foreach_volume($conf, sub {
1230         my ($ms, $mountpoint) = @_;
1231
1232         my $volid = $mountpoint->{volume};
1233
1234         die "Template feature is not available for '$volid'\n"
1235             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1236     });
1237
1238     PVE::LXC::Config->foreach_volume($conf, sub {
1239         my ($ms, $mountpoint) = @_;
1240
1241         my $volid = $mountpoint->{volume};
1242
1243         PVE::Storage::activate_volumes($storecfg, [$volid]);
1244
1245         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1246         $mountpoint->{volume} = $template_volid;
1247         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1248     });
1249
1250     PVE::LXC::Config->write_config($vmid, $conf);
1251 }
1252
1253 sub check_ct_modify_config_perm {
1254     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1255
1256     return 1 if $authuser eq 'root@pam';
1257     my $storage_cfg = PVE::Storage::config();
1258
1259     my $check = sub {
1260         my ($opt, $delete) = @_;
1261         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1262             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1263         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1264             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1265             return if $delete;
1266             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1267             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1268                 if $data->{type} ne 'volume';
1269             my $volid = $data->{volume};
1270             if ($volid =~ $NEW_DISK_RE) {
1271                 my $sid = $1;
1272                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1273             } else {
1274                 PVE::Storage::check_volume_access(
1275                     $rpcenv,
1276                     $authuser,
1277                     $storage_cfg,
1278                     $vmid,
1279                     $volid,
1280                     'rootdir',
1281                 );
1282             }
1283         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1284             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1285         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1286                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1287             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1288         } elsif ($opt eq 'features') {
1289             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1290                 if !$unprivileged;
1291
1292             my $nesting_changed = 0;
1293             my $other_changed = 0;
1294             if (!$delete) {
1295                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1296                 if (defined($oldconf) && $oldconf->{$opt}) {
1297                     # existing container with features
1298                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1299                     for my $feature ((keys %$old_features, keys %$features)) {
1300                         my $old = $old_features->{$feature} // '';
1301                         my $new = $features->{$feature} // '';
1302                         if ($old ne $new) {
1303                             if ($feature eq 'nesting') {
1304                                 $nesting_changed = 1;
1305                                 next;
1306                             } else {
1307                                 $other_changed = 1;
1308                                 last;
1309                             }
1310                         }
1311                     }
1312                 } else {
1313                     # new container or no features defined
1314                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1315                         $nesting_changed = 1;
1316                     } elsif (scalar(keys %$features) > 0) {
1317                         $other_changed = 1;
1318                     }
1319                 }
1320             } else {
1321                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1322                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1323                     $nesting_changed = 1;
1324                 } elsif (scalar(keys %$features) > 0) {
1325                     $other_changed = 1;
1326                 }
1327             }
1328             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1329                 if $other_changed;
1330             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1331                 if $nesting_changed;
1332         } elsif ($opt eq 'hookscript') {
1333             # For now this is restricted to root@pam
1334             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1335         } else {
1336             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1337         }
1338     };
1339
1340     foreach my $opt (keys %$newconf) {
1341         &$check($opt, 0);
1342     }
1343     foreach my $opt (@$delete) {
1344         &$check($opt, 1);
1345     }
1346
1347     return 1;
1348 }
1349
1350 sub umount_all {
1351     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1352
1353     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1354     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1355
1356     my $res = 1;
1357
1358     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1359         my ($ms, $mountpoint) = @_;
1360
1361         my $volid = $mountpoint->{volume};
1362         my $mount = $mountpoint->{mp};
1363
1364         return if !$volid || !$mount;
1365
1366         my $mount_path = "$rootdir/$mount";
1367         $mount_path =~ s!/+!/!g;
1368
1369         return if !PVE::ProcFSTools::is_mounted($mount_path);
1370
1371         eval {
1372             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1373         };
1374         if (my $err = $@) {
1375             if ($noerr) {
1376                 $res = 0;
1377                 warn $err;
1378             } else {
1379                 die $err;
1380             }
1381         }
1382     });
1383
1384     return $res; # tell caller if (some) umounts failed for the noerr case
1385 }
1386
1387 sub mount_all {
1388     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1389
1390     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1391     File::Path::make_path($rootdir);
1392
1393     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1394     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1395
1396     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1397
1398     eval {
1399         PVE::LXC::Config->foreach_volume($conf, sub {
1400             my ($ms, $mountpoint) = @_;
1401
1402             $mountpoint->{ro} = 0 if $ignore_ro;
1403
1404             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1405         });
1406     };
1407     if (my $err = $@) {
1408         warn "mounting container failed\n";
1409         umount_all($vmid, $storage_cfg, $conf, 1);
1410         die $err;
1411     }
1412
1413     return $rootdir;
1414 }
1415
1416
1417 sub mountpoint_mount_path {
1418     my ($mountpoint, $storage_cfg, $snapname) = @_;
1419
1420     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1421 }
1422
1423 sub query_loopdev {
1424     my ($path) = @_;
1425     my $found;
1426     my $parser = sub {
1427         my $line = shift;
1428         if ($line =~ m@^(/dev/loop\d+):@) {
1429             $found = $1;
1430         }
1431     };
1432     my $cmd = ['losetup', '--associated', $path];
1433     PVE::Tools::run_command($cmd, outfunc => $parser);
1434     return $found;
1435 }
1436
1437 # Run a function with a file attached to a loop device.
1438 # The loop device is always detached afterwards (or set to autoclear).
1439 # Returns the loop device.
1440 sub run_with_loopdev {
1441     my ($func, $file, $readonly) = @_;
1442     my $device = query_loopdev($file);
1443     # Try to reuse an existing device
1444     if ($device) {
1445         # We assume that whoever setup the loop device is responsible for
1446         # detaching it.
1447         &$func($device);
1448         return $device;
1449     }
1450
1451     my $parser = sub {
1452         my $line = shift;
1453         if ($line =~ m@^(/dev/loop\d+)$@) {
1454             $device = $1;
1455         }
1456     };
1457     my $losetup_cmd = [
1458         'losetup',
1459         '--show',
1460         '-f',
1461         $file,
1462     ];
1463     push @$losetup_cmd, '-r' if $readonly;
1464     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1465     die "failed to setup loop device for $file\n" if !$device;
1466     eval { &$func($device); };
1467     my $err = $@;
1468     PVE::Tools::run_command(['losetup', '-d', $device]);
1469     die $err if $err;
1470     return $device;
1471 }
1472
1473 # In scalar mode: returns a file handle to the deepest directory node.
1474 # In list context: returns a list of:
1475 #   * the deepest directory node
1476 #   * the 2nd deepest directory (parent of the above)
1477 #   * directory name of the last directory
1478 # So that the path $2/$3 should lead to $1 afterwards.
1479 sub walk_tree_nofollow($$$;$$) {
1480     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1481
1482     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1483         or die "failed to open start directory $start: $!\n";
1484
1485     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1486 }
1487
1488
1489 sub walk_tree_nofollow_fd($$$$;$$) {
1490     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1491
1492     # splitdir() returns '' for empty components including the leading /
1493     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1494
1495     my $fd = $start_fd;
1496     my $dir = $start_dirname;
1497     my $last_component = undef;
1498     my $second = $fd;
1499     foreach my $component (@comps) {
1500         $dir .= "/$component";
1501         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1502
1503         if (!$next) {
1504             # failed, check for symlinks and try to create the path
1505             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1506             die "cannot open directory $dir: $!\n" if !$mkdir;
1507
1508             # We don't check for errors on mkdirat() here and just try to
1509             # openat() again, since at least one error (EEXIST) is an
1510             # expected possibility if multiple containers start
1511             # simultaneously. If someone else injects a symlink now then
1512             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1513             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1514
1515             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1516             die "failed to create path: $dir: $!\n" if !$next;
1517
1518             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1519                 if defined($rootuid) && defined($rootgid);
1520         }
1521
1522         close $second if defined($last_component) && $second != $start_fd;
1523         $last_component = $component;
1524         $second = $fd;
1525         $fd = $next;
1526     }
1527
1528     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1529     close $second if defined($last_component) && $second != $start_fd;
1530     return $fd;
1531 }
1532
1533 # To guard against symlink attack races against other currently running
1534 # containers with shared recursive bind mount hierarchies we prepare a
1535 # directory handle for the directory we're mounting over to verify the
1536 # mountpoint afterwards.
1537 sub __bindmount_prepare {
1538     my ($hostroot, $dir) = @_;
1539     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1540     return $srcdh;
1541 }
1542
1543 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1544 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1545 # we intended to bind mount.
1546 sub __bindmount_verify {
1547     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1548     my $destdh;
1549     if ($parentfd) {
1550         # Open the mount point path coming from the parent directory since the
1551         # filehandle we would have gotten as first result of walk_tree_nofollow
1552         # earlier is still a handle to the underlying directory instead of the
1553         # mounted path.
1554         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1555         die "failed to open mount point: $!\n" if !$destdh;
1556         if ($ro) {
1557             my $dot = '.';
1558             # no separate function because 99% of the time it's the wrong thing to use.
1559             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1560                 die "failed to mark bind mount read only\n";
1561             }
1562             die "read-only check failed: $!\n" if $! != EROFS;
1563         }
1564     } else {
1565         # For the rootfs we don't have a parentfd so we open the path directly.
1566         # Note that this means bindmounting any prefix of the host's
1567         # /var/lib/lxc/$vmid path into another container is considered a grave
1568         # security error.
1569         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1570         die "failed to open mount point: $!\n" if !$destdh;
1571     }
1572
1573     my ($srcdev, $srcinode) = stat($srcdh);
1574     my ($dstdev, $dstinode) = stat($destdh);
1575     close $srcdh;
1576     close $destdh;
1577
1578     return ($srcdev == $dstdev && $srcinode == $dstinode);
1579 }
1580
1581 # Perform the actual bind mounting:
1582 sub __bindmount_do {
1583     my ($dir, $dest, $ro, @extra_opts) = @_;
1584     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1585     if ($ro) {
1586         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1587         if (my $err = $@) {
1588             warn "bindmount error\n";
1589             # don't leave writable bind-mounts behind...
1590             PVE::Tools::run_command(['umount', $dest]);
1591             die $err;
1592         }
1593     }
1594 }
1595
1596 sub bindmount {
1597     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1598
1599     my $srcdh = __bindmount_prepare('/', $dir);
1600
1601     __bindmount_do($dir, $dest, $ro, @extra_opts);
1602
1603     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1604         PVE::Tools::run_command(['umount', $dest]);
1605         die "detected mount path change at: $dir\n";
1606     }
1607 }
1608
1609 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1610 # from $rootdir and $mount and walk the path from $rootdir to the final
1611 # directory to check for symlinks.
1612 sub __mount_prepare_rootdir {
1613     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1614     $rootdir =~ s!/+!/!g;
1615     $rootdir =~ s!/+$!!;
1616     my $mount_path = "$rootdir/$mount";
1617     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1618     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1619 }
1620
1621 # use $rootdir = undef to just return the corresponding mount path
1622 sub mountpoint_mount {
1623     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1624     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1625 }
1626
1627 sub mountpoint_stage {
1628     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1629     my ($path, $loop, $dev) =
1630         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1631
1632     if (!defined($path)) {
1633         return undef if $! == ENOSYS;
1634         die "failed to mount subvolume: $!\n";
1635     }
1636
1637     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1638     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1639     # point).
1640     my $err;
1641     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1642         or die "open_tree() on mount point failed: $!\n";
1643
1644     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1645 }
1646
1647 sub mountpoint_insert_staged {
1648     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1649
1650     if (!defined($rootdir_fd)) {
1651         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1652             or die "failed to open '.': $!\n";
1653     }
1654
1655     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1656
1657     PVE::Tools::move_mount(
1658         fileno($mount_fd),
1659         '',
1660         fileno($dest_fd),
1661         '',
1662         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1663     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1664 }
1665
1666 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1667 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1668 #   Note that if the kernel does not support the new mount API, this will not perform any action
1669 #   and return `undef` with $! = ENOSYS.
1670 sub __mountpoint_mount {
1671     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1672
1673     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1674         $! = ENOSYS;
1675         return undef;
1676     }
1677
1678     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1679     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1680     # which we use in __bindmount_verify()!
1681     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1682
1683     my $volid = $mountpoint->{volume};
1684     my $type = $mountpoint->{type};
1685     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1686     my $mounted_dev;
1687
1688     return if !$volid || !$mount;
1689
1690     $mount =~ s!/+!/!g;
1691
1692     my $mount_path;
1693     my ($mpfd, $parentfd, $last_dir);
1694
1695     if (defined($rootdir)) {
1696         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1697             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1698     }
1699
1700     if (defined($stage_mount)) {
1701         $mount_path = $rootdir;
1702     }
1703
1704     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1705
1706     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1707
1708     my $optlist = [];
1709
1710     if (my $mountopts = $mountpoint->{mountoptions}) {
1711         my @opts = split(/;/, $mountpoint->{mountoptions});
1712         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1713     }
1714
1715     my $acl = $mountpoint->{acl};
1716     if (defined($acl)) {
1717         push @$optlist, ($acl ? 'acl' : 'noacl');
1718     }
1719
1720     my $optstring = join(',', @$optlist);
1721     my $readonly = $mountpoint->{ro};
1722
1723     my @extra_opts;
1724     @extra_opts = ('-o', $optstring) if $optstring;
1725
1726     if ($storage) {
1727
1728         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1729
1730         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1731
1732         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1733
1734         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1735             PVE::Storage::parse_volname($storage_cfg, $volid);
1736
1737         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1738
1739         if ($format eq 'subvol') {
1740             if ($mount_path) {
1741                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1742                 if (defined($snapname)) {
1743                     $name .= "\@$snapname";
1744                     if ($scfg->{type} eq 'zfspool') {
1745                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1746                     } else {
1747                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1748                     }
1749                 } else {
1750                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1751                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1752                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1753                     }
1754                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1755                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1756                 }
1757             }
1758             return wantarray ? ($path, 0, undef) : $path;
1759         } elsif ($format eq 'raw' || $format eq 'iso') {
1760             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1761             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1762             # Our autodev hook expects the /dev/dm-* device currently
1763             # and will create the /dev/mapper symlink accordingly
1764             $path = Cwd::realpath($path);
1765             die "failed to get device path\n" if !$path;
1766             ($path) = ($path =~ /^(.*)$/s); #untaint
1767             my $domount = sub {
1768                 my ($path) = @_;
1769                 if ($mount_path) {
1770                     if ($format eq 'iso') {
1771                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1772                     } elsif ($isBase || defined($snapname)) {
1773                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1774                     } else {
1775                         if ($quota) {
1776                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1777                         }
1778                         push @extra_opts, '-o', 'ro' if $readonly;
1779                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1780                     }
1781                 }
1782             };
1783             my $use_loopdev = 0;
1784             if ($scfg->{content}->{rootdir}) {
1785                 if ($scfg->{path}) {
1786                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1787                     $use_loopdev = 1;
1788                 } else {
1789                     $mounted_dev = $path;
1790                     &$domount($path);
1791                 }
1792             } else {
1793                 die "storage '$storage' does not support containers\n";
1794             }
1795             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1796         } else {
1797             die "unsupported image format '$format'\n";
1798         }
1799     } elsif ($type eq 'device') {
1800         push @extra_opts, '-o', 'ro' if $readonly;
1801         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1802         # See the NOTE above about devicemapper canonicalization
1803         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1804         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1805         return wantarray ? ($volid, 0, $devpath) : $volid;
1806     } elsif ($type eq 'bind') {
1807         die "directory '$volid' does not exist\n" if ! -d $volid;
1808         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1809         warn "cannot enable quota control for bind mounts\n" if $quota;
1810         return wantarray ? ($volid, 0, undef) : $volid;
1811     }
1812
1813     die "unsupported storage";
1814 }
1815
1816 sub mountpoint_hotplug :prototype($$$$$) {
1817     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1818
1819     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1820
1821     # We do the rest in a fork with an unshared mount namespace, because:
1822     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1823     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1824     #     container's namespace, then mount it.
1825
1826     PVE::Tools::run_fork(sub {
1827         # Pin the container pid longer, we also need to get its monitor/parent:
1828         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1829             or die "failed to open pidfd of container $vmid\'s init process\n";
1830
1831         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1832             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1833
1834         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1835         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1836
1837         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1838         # profile to lower our privileges to the same level we have in the start hook:
1839         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1840             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1841         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1842         # apparmor.
1843
1844         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1845         # namespace for it to remain active there since the container will be able to unmount
1846         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1847         # concern.
1848         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1849         chdir('/')
1850             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1851
1852         my $dir = get_staging_mount_path($opt);
1853
1854         # Now switch our apparmor profile before mounting:
1855         my $data = 'changeprofile /usr/bin/lxc-start';
1856         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1857             die "failed to change apparmor profile: $!\n";
1858         }
1859         # Check errors on close as well:
1860         close($aa_fd)
1861             or die "failed to change apparmor profile (close() failed): $!\n";
1862
1863         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1864
1865         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1866         chdir('/')
1867             or die "failed to change root directory within the container's mount namespace: $!\n";
1868
1869         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1870     });
1871 }
1872
1873 # Create a directory in the mountpoint staging tempfs.
1874 sub get_staging_mount_path($) {
1875     my ($opt) = @_;
1876
1877     my $target = get_staging_tempfs() . "/$opt";
1878     if (!mkdir($target) && $! != EEXIST) {
1879         die "failed to create directory $target: $!\n";
1880     }
1881
1882     return $target;
1883 }
1884
1885 # Mount /run/pve/mountpoints as tmpfs
1886 sub get_staging_tempfs() {
1887     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1888     # mounts to that.
1889     my $target = '/var/lib/lxc/.pve-staged-mounts';
1890     if (!mkdir($target)) {
1891         return $target if $! == EEXIST;
1892         die "failed to create directory $target: $!\n";
1893     }
1894
1895     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1896         or die "failed to mount $target as tmpfs: $!\n";
1897
1898     return $target;
1899 }
1900
1901 sub mkfs {
1902     my ($dev, $rootuid, $rootgid) = @_;
1903
1904     run_command(
1905         [
1906             'mkfs.ext4',
1907             '-O',
1908             'mmp',
1909             '-E',
1910             "root_owner=$rootuid:$rootgid",
1911             $dev,
1912         ],
1913         outfunc => sub {
1914             my $line = shift;
1915             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1916             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1917                 print "$line\n";
1918             }
1919         },
1920         errfunc => sub {
1921             my $line = shift;
1922             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1923         }
1924     );
1925 }
1926
1927 sub format_disk {
1928     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1929
1930     if ($volid =~ m!^/dev/.+!) {
1931         mkfs($volid);
1932         return;
1933     }
1934
1935     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1936
1937     die "cannot format volume '$volid' with no storage\n" if !$storage;
1938
1939     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1940
1941     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1942
1943     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1944
1945     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1946         PVE::Storage::parse_volname($storage_cfg, $volid);
1947
1948     die "cannot format volume '$volid' (format == $format)\n"
1949         if $format ne 'raw';
1950
1951     mkfs($path, $rootuid, $rootgid);
1952 }
1953
1954 sub destroy_disks {
1955     my ($storecfg, $vollist) = @_;
1956
1957     foreach my $volid (@$vollist) {
1958         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1959         warn $@ if $@;
1960     }
1961 }
1962
1963 sub alloc_disk {
1964     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1965
1966     my $needs_chown = 0;
1967     my $volid;
1968
1969     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1970     # fixme: use better naming ct-$vmid-disk-X.raw?
1971
1972     eval {
1973         my $do_format = 0;
1974         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
1975             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
1976                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1977                 $do_format = 1;
1978             } else {
1979                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1980                 $needs_chown = 1;
1981             }
1982         } elsif ($scfg->{type} eq 'zfspool') {
1983             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1984             $needs_chown = 1;
1985         } elsif ($scfg->{content}->{rootdir}) {
1986             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1987             $do_format = 1;
1988         } else {
1989             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
1990         }
1991         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1992     };
1993     if (my $err = $@) {
1994         # in case formatting got interrupted:
1995         if (defined($volid)) {
1996             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1997             warn $@ if $@;
1998         }
1999         die $err;
2000     }
2001
2002     return ($volid, $needs_chown);
2003 }
2004
2005 sub create_disks {
2006     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2007
2008     my $vollist = [];
2009
2010     eval {
2011         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2012         my $chown_vollist = [];
2013
2014         PVE::LXC::Config->foreach_volume($settings, sub {
2015             my ($ms, $mountpoint) = @_;
2016
2017             my $volid = $mountpoint->{volume};
2018             my $mp = $mountpoint->{mp};
2019
2020             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2021
2022             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2023                 my ($storeid, $size_gb) = ($1, $2);
2024
2025                 my $size_kb = int(${size_gb}*1024) * 1024;
2026
2027                 my $needs_chown = 0;
2028                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2029                 push @$chown_vollist, $volid if $needs_chown;
2030                 push @$vollist, $volid;
2031                 $mountpoint->{volume} = $volid;
2032                 $mountpoint->{size} = $size_kb * 1024;
2033                 if ($pending) {
2034                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2035                 } else {
2036                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2037                 }
2038             } else {
2039                 # use specified/existing volid/dir/device
2040                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2041             }
2042         });
2043
2044         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2045         foreach my $volid (@$chown_vollist) {
2046             my $path = PVE::Storage::path($storecfg, $volid, undef);
2047             chown($rootuid, $rootgid, $path);
2048         }
2049         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2050     };
2051     # free allocated images on error
2052     if (my $err = $@) {
2053         destroy_disks($storecfg, $vollist);
2054         die $err;
2055     }
2056     return $vollist;
2057 }
2058
2059 sub update_disksize {
2060     my ($vmid, $conf, $all_volumes) = @_;
2061
2062     my $changes;
2063     my $prefix = "CT $vmid:";
2064
2065     my $update_mp = sub {
2066         my ($key, $mp, @param) = @_;
2067         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2068
2069         if (!defined($mp->{size}) || $size != $mp->{size}) {
2070             $changes = 1;
2071             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2072             $mp->{size} = $size;
2073             my $nomp = 1 if ($key eq 'rootfs');
2074             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
2075         }
2076     };
2077
2078     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2079
2080     return $changes;
2081 }
2082
2083 sub update_unused {
2084     my ($vmid, $conf, $all_volumes) = @_;
2085
2086     my $changes;
2087     my $prefix = "CT $vmid:";
2088
2089     # Note: it is allowed to define multiple storage entries with the same path
2090     # (alias), so we need to check both 'volid' and real 'path' (two different
2091     # volid can point to the same path).
2092
2093     # used and unused disks
2094     my $refpath = {};
2095     my $orphans = {};
2096
2097     foreach my $opt (keys %$conf) {
2098         next if ($opt !~ m/^unused\d+$/);
2099         my $vol = $all_volumes->{$conf->{$opt}};
2100         $refpath->{$vol->{path}} = $vol->{volid};
2101     }
2102
2103     foreach my $key (keys %$all_volumes) {
2104         my $vol = $all_volumes->{$key};
2105         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2106         my $path = $vol->{path};
2107
2108         if ($in_use) {
2109             $refpath->{$path} = $key;
2110             delete $orphans->{$path};
2111         } else {
2112             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2113                 $orphans->{$path} = $key;
2114             }
2115         }
2116     }
2117
2118     for my $key (keys %$orphans) {
2119         my $disk = $orphans->{$key};
2120         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2121
2122         if ($unused) {
2123             $changes = 1;
2124             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2125         }
2126     }
2127
2128     return $changes;
2129 }
2130
2131 sub scan_volids {
2132     my ($cfg, $vmid) = @_;
2133
2134     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2135
2136     my $all_volumes = {};
2137     foreach my $storeid (keys %$info) {
2138         foreach my $item (@{$info->{$storeid}}) {
2139             my $volid = $item->{volid};
2140             next if !($volid && $item->{size});
2141             $item->{path} = PVE::Storage::path($cfg, $volid);
2142             $all_volumes->{$volid} = $item;
2143         }
2144     }
2145
2146     return $all_volumes;
2147 }
2148
2149 sub rescan {
2150     my ($vmid, $nolock, $dryrun) = @_;
2151
2152     my $cfg = PVE::Storage::config();
2153
2154     print "rescan volumes...\n";
2155     my $all_volumes = scan_volids($cfg, $vmid);
2156
2157     my $updatefn =  sub {
2158         my ($vmid) = @_;
2159
2160         my $changes;
2161         my $conf = PVE::LXC::Config->load_config($vmid);
2162
2163         PVE::LXC::Config->check_lock($conf);
2164
2165         my $vm_volids = {};
2166         foreach my $volid (keys %$all_volumes) {
2167             my $info = $all_volumes->{$volid};
2168             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2169         }
2170
2171         my $upu = update_unused($vmid, $conf, $vm_volids);
2172         my $upd = update_disksize($vmid, $conf, $vm_volids);
2173         $changes = $upu || $upd;
2174
2175         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2176     };
2177
2178     if (defined($vmid)) {
2179         if ($nolock) {
2180             &$updatefn($vmid);
2181         } else {
2182             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2183         }
2184     } else {
2185         my $vmlist = config_list();
2186         foreach my $vmid (keys %$vmlist) {
2187             if ($nolock) {
2188                 &$updatefn($vmid);
2189             } else {
2190                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2191             }
2192         }
2193     }
2194 }
2195
2196
2197 # bash completion helper
2198
2199 sub complete_os_templates {
2200     my ($cmdname, $pname, $cvalue) = @_;
2201
2202     my $cfg = PVE::Storage::config();
2203
2204     my $storeid;
2205
2206     if ($cvalue =~ m/^([^:]+):/) {
2207         $storeid = $1;
2208     }
2209
2210     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2211     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2212
2213     my $res = [];
2214     foreach my $id (keys %$data) {
2215         foreach my $item (@{$data->{$id}}) {
2216             push @$res, $item->{volid} if defined($item->{volid});
2217         }
2218     }
2219
2220     return $res;
2221 }
2222
2223 my $complete_ctid_full = sub {
2224     my ($running) = @_;
2225
2226     my $idlist = vmstatus();
2227
2228     my $active_hash = list_active_containers();
2229
2230     my $res = [];
2231
2232     foreach my $id (keys %$idlist) {
2233         my $d = $idlist->{$id};
2234         if (defined($running)) {
2235             next if $d->{template};
2236             next if $running && !$active_hash->{$id};
2237             next if !$running && $active_hash->{$id};
2238         }
2239         push @$res, $id;
2240
2241     }
2242     return $res;
2243 };
2244
2245 sub complete_ctid {
2246     return &$complete_ctid_full();
2247 }
2248
2249 sub complete_ctid_stopped {
2250     return &$complete_ctid_full(0);
2251 }
2252
2253 sub complete_ctid_running {
2254     return &$complete_ctid_full(1);
2255 }
2256
2257 sub parse_id_maps {
2258     my ($conf) = @_;
2259
2260     my $id_map = [];
2261     my $rootuid = 0;
2262     my $rootgid = 0;
2263
2264     my $lxc = $conf->{lxc};
2265     foreach my $entry (@$lxc) {
2266         my ($key, $value) = @$entry;
2267         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2268         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2269         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2270             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2271             push @$id_map, [$type, $ct, $host, $length];
2272             if ($ct == 0) {
2273                 $rootuid = $host if $type eq 'u';
2274                 $rootgid = $host if $type eq 'g';
2275             }
2276         } else {
2277             die "failed to parse idmap: $value\n";
2278         }
2279     }
2280
2281     if (!@$id_map && $conf->{unprivileged}) {
2282         # Should we read them from /etc/subuid?
2283         $id_map = [ ['u', '0', '100000', '65536'],
2284                     ['g', '0', '100000', '65536'] ];
2285         $rootuid = $rootgid = 100000;
2286     }
2287
2288     return ($id_map, $rootuid, $rootgid);
2289 }
2290
2291 sub userns_command {
2292     my ($id_map) = @_;
2293     if (@$id_map) {
2294         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2295     }
2296     return [];
2297 }
2298
2299 my sub print_ct_stderr_log {
2300     my ($vmid) = @_;
2301     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2302     return if !$log;
2303
2304     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2305         my $line = $2;
2306         print STDERR "$line\n";
2307     }
2308 }
2309 my sub print_ct_warn_log {
2310     my ($vmid) = @_;
2311     my $log_fn = "/run/pve/ct-$vmid.warnings";
2312     my $log = eval { file_get_contents($log_fn) };
2313     return if !$log;
2314
2315     my $rpcenv = eval { PVE::RPCEnvironment::get() };
2316
2317     my $warn_fn = $rpcenv ? sub { $rpcenv->warn($_[0]) } : sub { print STDERR "WARN: $_[0]\n" };
2318
2319     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2320         my $line = $1;
2321         $warn_fn->($line);
2322     }
2323     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2324 }
2325
2326 my sub monitor_state_change($$) {
2327     my ($monitor_socket, $vmid) = @_;
2328     die "no monitor socket\n" if !defined($monitor_socket);
2329
2330     while (1) {
2331         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2332
2333         die "monitor socket: got EOF\n" if !defined($type);
2334
2335         next if $name ne "$vmid" || $type ne 'STATE';
2336
2337         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2338             alarm(0); # don't timeout after seeing the starting state
2339         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2340                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2341                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2342             return 0;
2343         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2344             return 1;
2345         } else {
2346             warn "unexpected message from monitor socket - " .
2347                  "type: '$type' - value: '$value'\n";
2348         }
2349     }
2350 }
2351 my sub monitor_start($$) {
2352     my ($monitor_socket, $vmid) = @_;
2353
2354     my $success = eval {
2355         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2356     };
2357     if (my $err = $@) {
2358         warn "problem with monitor socket, but continuing anyway: $err\n";
2359     } elsif (!$success) {
2360         print_ct_stderr_log($vmid);
2361         die "startup for container '$vmid' failed\n";
2362     }
2363 }
2364
2365 sub vm_start {
2366     my ($vmid, $conf, $skiplock, $debug) = @_;
2367
2368     # apply pending changes while starting
2369     if (scalar(keys %{$conf->{pending}})) {
2370         my $storecfg = PVE::Storage::config();
2371         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2372         PVE::LXC::Config->write_config($vmid, $conf);
2373         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2374     }
2375
2376     update_lxc_config($vmid, $conf);
2377
2378     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2379
2380     if ($skiplock) {
2381         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2382         close($fh);
2383     }
2384
2385     my $storage_cfg = PVE::Storage::config();
2386     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2387
2388     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2389
2390     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2391     warn $@ if $@;
2392
2393     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2394
2395     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2396     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2397
2398     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2399
2400     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2401     eval {
2402         run_command($cmd);
2403
2404         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2405
2406         # if debug is requested, print the log it also when the start succeeded
2407         print_ct_stderr_log($vmid) if $is_debug;
2408
2409         print_ct_warn_log($vmid); # always print warn log, if any
2410     };
2411     if (my $err = $@) {
2412         unlink $skiplock_flag_fn;
2413         die $err;
2414     }
2415     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2416
2417     return;
2418 }
2419
2420 # Helper to stop a container completely and make sure it has stopped completely.
2421 # This is necessary because we want the post-stop hook to have completed its
2422 # unmount-all step, but post-stop happens after lxc puts the container into the
2423 # STOPPED state.
2424 # $kill - if true it will always do an immediate hard-stop
2425 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2426 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2427 sub vm_stop {
2428     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2429
2430     # Open the container's command socket.
2431     my $path = "\0/var/lib/lxc/$vmid/command";
2432     my $sock = IO::Socket::UNIX->new(
2433         Type => SOCK_STREAM(),
2434         Peer => $path,
2435     );
2436     if (!$sock) {
2437         return if $! == ECONNREFUSED; # The container is not running
2438         die "failed to open container ${vmid}'s command socket: $!\n";
2439     }
2440
2441     my $conf = PVE::LXC::Config->load_config($vmid);
2442     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2443
2444     # Stop the container:
2445
2446     my $cmd = ['lxc-stop', '-n', $vmid];
2447
2448     if ($kill) {
2449         push @$cmd, '--kill'; # doesn't allow timeouts
2450     } else {
2451         # lxc-stop uses a default timeout
2452         push @$cmd, '--nokill' if !$kill_after_timeout;
2453
2454         if (defined($shutdown_timeout)) {
2455             push @$cmd, '--timeout', $shutdown_timeout;
2456             # Give run_command 5 extra seconds
2457             $shutdown_timeout += 5;
2458         }
2459     }
2460
2461     eval { run_command($cmd, timeout => $shutdown_timeout) };
2462     if (my $err = $@) {
2463         warn $@ if $@;
2464     }
2465
2466     my $result = <$sock>;
2467
2468     return if !defined $result; # monitor is gone and the ct has stopped.
2469     die "container did not stop\n";
2470 }
2471
2472 sub vm_reboot {
2473     my ($vmid, $timeout, $skiplock) = @_;
2474
2475     PVE::LXC::Config->lock_config($vmid, sub {
2476         return if !check_running($vmid);
2477
2478         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2479
2480         my $conf = PVE::LXC::Config->load_config($vmid);
2481         vm_start($vmid, $conf);
2482     });
2483 }
2484
2485 sub run_unshared {
2486     my ($code) = @_;
2487
2488     return PVE::Tools::run_fork(sub {
2489         # Unshare the mount namespace
2490         die "failed to unshare mount namespace: $!\n"
2491             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2492         run_command(['mount', '--make-rslave', '/']);
2493         return $code->();
2494     });
2495 }
2496
2497 my $copy_volume = sub {
2498     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2499
2500     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2501     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2502
2503     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2504     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2505
2506     my @mounted;
2507     eval {
2508         # mount and copy
2509         mkdir $src;
2510         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2511         push @mounted, $src;
2512         mkdir $dest;
2513         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2514         push @mounted, $dest;
2515
2516         $bwlimit //= 0;
2517
2518         run_command([
2519             'rsync',
2520             '--stats',
2521             '-X',
2522             '-A',
2523             '--numeric-ids',
2524             '-aH',
2525             '--whole-file',
2526             '--sparse',
2527             '--one-file-system',
2528             "--bwlimit=$bwlimit",
2529             "$src/",
2530             $dest
2531         ]);
2532     };
2533     my $err = $@;
2534
2535     # Wait for rsync's children to release dest so that
2536     # consequent file operations (umount, remove) are possible
2537     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2538
2539     foreach my $mount (reverse @mounted) {
2540         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2541         warn "Can't umount $mount\n" if $@;
2542     }
2543
2544     # If this fails they're used as mount points in a concurrent operation
2545     # (which should not happen but there's also no real need to get rid of them).
2546     rmdir $dest;
2547     rmdir $src;
2548
2549     die $err if $err;
2550 };
2551
2552 # Should not be called after unsharing the mount namespace!
2553 sub copy_volume {
2554     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2555
2556     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2557     File::Path::make_path("/var/lib/lxc/$vmid");
2558     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2559     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2560
2561     # get id's for unprivileged container
2562     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2563
2564     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2565     # are visible in this namespace, otherwise the host only sees the empty
2566     # (not-mounted) directory.
2567     my $new_volid;
2568     eval {
2569         # Make sure $mp contains a correct size.
2570         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2571         my $needs_chown;
2572         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2573         if ($needs_chown) {
2574             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2575             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2576             chown($rootuid, $rootgid, $path);
2577         }
2578
2579         run_unshared(sub {
2580             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2581         });
2582     };
2583     if (my $err = $@) {
2584         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2585             if defined($new_volid);
2586         die $err;
2587     }
2588
2589     return $new_volid;
2590 }
2591
2592 sub get_lxc_version() {
2593     my $version;
2594     run_command([qw(lxc-start --version)], outfunc => sub {
2595         my ($line) = @_;
2596         # We only parse out major & minor version numbers.
2597         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2598             $version = [$1, $2];
2599         }
2600     });
2601
2602     die "failed to get lxc version\n" if !defined($version);
2603
2604     # return as a list:
2605     return $version->@*;
2606 }
2607
2608 sub freeze($) {
2609     my ($vmid) = @_;
2610     if (PVE::CGroup::cgroup_mode() == 2) {
2611         PVE::LXC::Command::freeze($vmid, 30);
2612     } else {
2613         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2614     }
2615 }
2616
2617 sub thaw($) {
2618     my ($vmid) = @_;
2619     if (PVE::CGroup::cgroup_mode() == 2) {
2620         PVE::LXC::Command::unfreeze($vmid, 30);
2621     } else {
2622         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2623     }
2624 }
2625
2626 1;