src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw();
   7 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
   8 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
   9 use File::Path;
  10 use File::Spec;
  11 use IO::Poll qw(POLLIN POLLHUP);
  12 use IO::Socket::UNIX;
  13 use POSIX qw(EINTR);
  14 use Socket;
  15 use Time::HiRes qw (gettimeofday);
  16
  17 use PVE::AccessControl;
  18 use PVE::CGroup;
  19 use PVE::CpuSet;
  20 use PVE::Exception qw(raise_perm_exc);
  21 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  22 use PVE::INotify;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use PVE::Network;
  25 use PVE::ProcFSTools;
  26 use PVE::RESTEnvironment;
  27 use PVE::SafeSyslog;
  28 use PVE::Storage;
  29 use PVE::Tools qw(
  30     run_command
  31     dir_glob_foreach
  32     file_get_contents
  33     file_set_contents
  34     AT_FDCWD
  35     O_PATH
  36     $IPV4RE
  37     $IPV6RE
  38 );
  39 use PVE::Syscall qw(:fsmount);
  40
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Config;
  43 use PVE::LXC::Monitor;
  44 use PVE::LXC::Tools;
  45
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         my $lxcmem = int($memory*1024*1024);
 689         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 690
 691         my $lxcswap = int($swap*1024*1024);
 692         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 693     }
 694
 695     if ($cgv1->{cpu}) {
 696         if (my $cpulimit = $conf->{cpulimit}) {
 697             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 698             my $value = int(100000*$cpulimit);
 699             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 700         }
 701
 702         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 703         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 704     } elsif ($cgv2->{cpu}) {
 705         # See PVE::CGroup
 706         if (my $cpulimit = $conf->{cpulimit}) {
 707             my $value = int(100000*$cpulimit);
 708             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 709         }
 710
 711         if (defined(my $shares = $conf->{cpuunits})) {
 712             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 713             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 714         }
 715     }
 716
 717     die "missing 'rootfs' configuration\n"
 718         if !defined($conf->{rootfs});
 719
 720     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 721
 722     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 723
 724     foreach my $k (sort keys %$conf) {
 725         next if $k !~ m/^net(\d+)$/;
 726         my $ind = $1;
 727         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 728         $raw .= "lxc.net.$ind.type = veth\n";
 729         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 730         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 731         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 732
 733         # Keep container from starting with invalid mtu configuration
 734         if (my $mtu = $d->{mtu}) {
 735             my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 736             die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 737                 if ($mtu > $bridge_mtu);
 738
 739             $raw .= "lxc.net.$ind.mtu = $mtu\n";
 740         }
 741
 742         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 743         if ($lxc_major >= 4) {
 744             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 745         }
 746     }
 747
 748     my $had_cpuset = 0;
 749     if (my $lxcconf = $conf->{lxc}) {
 750         foreach my $entry (@$lxcconf) {
 751             my ($k, $v) = @$entry;
 752             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 753             $raw .= "$k = $v\n";
 754         }
 755     }
 756
 757     my $cpuset;
 758     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 759     if (defined($cpuset_cgroup)) {
 760         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 761             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 762     }
 763     my $cores = $conf->{cores};
 764     if (!$had_cpuset && $cores && $cpuset) {
 765         my @members = $cpuset->members();
 766         while (scalar(@members) > $cores) {
 767             my $randidx = int(rand(scalar(@members)));
 768             $cpuset->delete($members[$randidx]);
 769             splice(@members, $randidx, 1); # keep track of the changes
 770         }
 771         my $ver = $cpuset_version == 1 ? '' : '2';
 772         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 773     }
 774
 775     File::Path::mkpath("$dir/rootfs");
 776
 777     PVE::Tools::file_set_contents("$dir/config", $raw);
 778 }
 779
 780 # verify and cleanup nameserver list (replace \0 with ' ')
 781 sub verify_nameserver_list {
 782     my ($nameserver_list) = @_;
 783
 784     my @list = ();
 785     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 786         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 787         push @list, $server;
 788     }
 789
 790     return join(' ', @list);
 791 }
 792
 793 sub verify_searchdomain_list {
 794     my ($searchdomain_list) = @_;
 795
 796     my @list = ();
 797     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 798         # todo: should we add checks for valid dns domains?
 799         push @list, $server;
 800     }
 801
 802     return join(' ', @list);
 803 }
 804
 805 sub get_console_command {
 806     my ($vmid, $conf, $escapechar) = @_;
 807
 808     # '-1' as $escapechar disables keyboard escape sequence
 809     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 810
 811     my $cmode = PVE::LXC::Config->get_cmode($conf);
 812
 813     my $cmd = [];
 814     if ($cmode eq 'console') {
 815         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 816         push @$cmd, '-e', $escapechar if $escapechar;
 817     } elsif ($cmode eq 'tty') {
 818         push @$cmd, 'lxc-console', '-n',  $vmid;
 819         push @$cmd, '-e', $escapechar if $escapechar;
 820     } elsif ($cmode eq 'shell') {
 821         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 822     } else {
 823         die "internal error";
 824     }
 825
 826     return $cmd;
 827 }
 828
 829 sub get_primary_ips {
 830     my ($conf) = @_;
 831
 832     # return data from net0
 833
 834     return undef if !defined($conf->{net0});
 835     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 836
 837     my $ipv4 = $net->{ip};
 838     if ($ipv4) {
 839         if ($ipv4 =~ /^(dhcp|manual)$/) {
 840             $ipv4 = undef
 841         } else {
 842             $ipv4 =~ s!/\d+$!!;
 843         }
 844     }
 845     my $ipv6 = $net->{ip6};
 846     if ($ipv6) {
 847         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 848             $ipv6 = undef;
 849         } else {
 850             $ipv6 =~ s!/\d+$!!;
 851         }
 852     }
 853
 854     return ($ipv4, $ipv6);
 855 }
 856
 857 sub delete_mountpoint_volume {
 858     my ($storage_cfg, $vmid, $volume) = @_;
 859
 860     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 861
 862     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 863
 864     if ($vmid == $owner) {
 865         PVE::Storage::vdisk_free($storage_cfg, $volume);
 866     } else {
 867         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 868     }
 869 }
 870
 871 sub destroy_lxc_container {
 872     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 873
 874     my $volids = {};
 875     my $remove_volume = sub {
 876         my ($ms, $mountpoint) = @_;
 877
 878         my $volume = $mountpoint->{volume};
 879
 880         return if $volids->{$volume};
 881         $volids->{$volume} = 1;
 882
 883         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 884     };
 885     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 886
 887     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 888
 889     if ($purge_unreferenced) { # also remove unreferenced disk
 890         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 891         PVE::Storage::foreach_volid($vmdisks, sub {
 892             my ($volid, $sid, $volname, $d) = @_;
 893             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 894             warn $@ if $@;
 895         });
 896     }
 897
 898     rmdir "/var/lib/lxc/$vmid/rootfs";
 899     unlink "/var/lib/lxc/$vmid/config";
 900     rmdir "/var/lib/lxc/$vmid";
 901     if (defined $replacement_conf) {
 902         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 903     } else {
 904         PVE::LXC::Config->destroy_config($vmid);
 905     }
 906 }
 907
 908 sub vm_stop_cleanup {
 909     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 910
 911     return if $keepActive;
 912
 913     eval {
 914         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 915         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 916     };
 917     warn $@ if $@; # avoid errors - just warn
 918 }
 919
 920 sub net_tap_plug : prototype($$) {
 921     my ($iface, $net) = @_;
 922
 923     if (defined($net->{link_down})) {
 924         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 925         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 926         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 927         return;
 928     }
 929
 930     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 931         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 932
 933     if ($have_sdn) {
 934         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 935         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge, $firewall);
 936     } else {
 937         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 938     }
 939
 940     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 941 }
 942
 943 sub update_net {
 944     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 945
 946     if ($newnet->{type} ne 'veth') {
 947         # for when there are physical interfaces
 948         die "cannot update interface of type $newnet->{type}";
 949     }
 950
 951     my $veth = "veth${vmid}i${netid}";
 952     my $eth = $newnet->{name};
 953
 954     if (my $oldnetcfg = $conf->{$opt}) {
 955         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 956
 957         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 958             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 959
 960             PVE::Network::veth_delete($veth);
 961             delete $conf->{$opt};
 962             PVE::LXC::Config->write_config($vmid, $conf);
 963
 964             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 965
 966         } else {
 967             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 968                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 969                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 970                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 971             ) {
 972
 973                 if ($oldnet->{bridge}) {
 974                     PVE::Network::tap_unplug($veth);
 975                     foreach (qw(bridge tag firewall)) {
 976                         delete $oldnet->{$_};
 977                     }
 978                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 979                     PVE::LXC::Config->write_config($vmid, $conf);
 980                 }
 981
 982                 PVE::LXC::net_tap_plug($veth, $newnet);
 983
 984                 # This includes the rate:
 985                 foreach (qw(bridge tag firewall rate link_down)) {
 986                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 987                 }
 988             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 989                 # Rate can be applied on its own but any change above needs to
 990                 # include the rate in tap_plug since OVS resets everything.
 991                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 992                 $oldnet->{rate} = $newnet->{rate}
 993             }
 994             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 995             PVE::LXC::Config->write_config($vmid, $conf);
 996         }
 997     } else {
 998         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 999     }
1000
1001     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1002 }
1003
1004 sub hotplug_net {
1005     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1006
1007     my $veth = "veth${vmid}i${netid}";
1008     my $vethpeer = $veth . "p";
1009     my $eth = $newnet->{name};
1010
1011     if ($have_sdn) {
1012         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1013     } else {
1014         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1015     }
1016
1017     PVE::LXC::net_tap_plug($veth, $newnet);
1018
1019     # attach peer in container
1020     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1021     PVE::Tools::run_command($cmd);
1022
1023     # link up peer in container
1024     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1025     PVE::Tools::run_command($cmd);
1026
1027     my $done = { type => 'veth' };
1028     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1029         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1030     }
1031     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1032
1033     PVE::LXC::Config->write_config($vmid, $conf);
1034 }
1035
1036 sub update_ipconfig {
1037     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1038
1039     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1040
1041     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1042     my $deleted = [];
1043     my $added = [];
1044     my $nscmd = sub {
1045         my $cmdargs = shift;
1046         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1047     };
1048     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1049
1050     my $change_ip_config = sub {
1051         my ($ipversion) = @_;
1052
1053         my $family_opt = "-$ipversion";
1054         my $suffix = $ipversion == 4 ? '' : $ipversion;
1055         my $gw= "gw$suffix";
1056         my $ip= "ip$suffix";
1057
1058         my $newip = $newnet->{$ip};
1059         my $newgw = $newnet->{$gw};
1060         my $oldip = $optdata->{$ip};
1061         my $oldgw = $optdata->{$gw};
1062
1063         my $change_ip = safe_string_ne($oldip, $newip);
1064         my $change_gw = safe_string_ne($oldgw, $newgw);
1065
1066         return if !$change_ip && !$change_gw;
1067
1068         # step 1: add new IP, if this fails we cancel
1069         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1070         if ($change_ip && $is_real_ip) {
1071             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1072             if (my $err = $@) {
1073                 warn $err;
1074                 return;
1075             }
1076         }
1077
1078         # step 2: replace gateway
1079         #   If this fails we delete the added IP and cancel.
1080         #   If it succeeds we save the config and delete the old IP, ignoring
1081         #   errors. The config is then saved.
1082         # Note: 'ip route replace' can add
1083         if ($change_gw) {
1084             if ($newgw) {
1085                 eval {
1086                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1087                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1088                     }
1089                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1090                 };
1091                 if (my $err = $@) {
1092                     warn $err;
1093                     # the route was not replaced, the old IP is still available
1094                     # rollback (delete new IP) and cancel
1095                     if ($change_ip) {
1096                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1097                         warn $@ if $@; # no need to die here
1098                     }
1099                     return;
1100                 }
1101             } else {
1102                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1103                 # if the route was not deleted, the guest might have deleted it manually
1104                 # warn and continue
1105                 warn $@ if $@;
1106             }
1107             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1108                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1109                 # warn if the route was deleted manually
1110                 warn $@ if $@;
1111             }
1112         }
1113
1114         # from this point on we save the configuration
1115         # step 3: delete old IP ignoring errors
1116         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1117             # We need to enable promote_secondaries, otherwise our newly added
1118             # address will be removed along with the old one.
1119             my $promote = 0;
1120             eval {
1121                 if ($ipversion == 4) {
1122                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1123                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1124                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1125                 }
1126                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1127             };
1128             warn $@ if $@; # no need to die here
1129
1130             if ($ipversion == 4) {
1131                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1132             }
1133         }
1134
1135         foreach my $property ($ip, $gw) {
1136             if ($newnet->{$property}) {
1137                 $optdata->{$property} = $newnet->{$property};
1138             } else {
1139                 delete $optdata->{$property};
1140             }
1141         }
1142         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1143         PVE::LXC::Config->write_config($vmid, $conf);
1144         $lxc_setup->setup_network($conf);
1145     };
1146
1147     &$change_ip_config(4);
1148     &$change_ip_config(6);
1149
1150 }
1151
1152 my $open_namespace = sub {
1153     my ($vmid, $pid, $kind) = @_;
1154     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1155         or die "failed to open $kind namespace of container $vmid: $!\n";
1156     return $fd;
1157 };
1158
1159 my $enter_namespace = sub {
1160     my ($vmid, $pid, $kind, $type) = @_;
1161     my $fd = $open_namespace->($vmid, $pid, $kind);
1162     PVE::Tools::setns(fileno($fd), $type)
1163         or die "failed to enter $kind namespace of container $vmid: $!\n";
1164     close $fd;
1165 };
1166
1167 my $get_container_namespace = sub {
1168     my ($vmid, $pid, $kind) = @_;
1169
1170     my $pidfd;
1171     if (!defined($pid)) {
1172         # Pin the pid while we're grabbing its stuff from /proc
1173         ($pid, $pidfd) = open_lxc_pid($vmid)
1174             or die "failed to open pidfd of container $vmid\'s init process\n";
1175     }
1176
1177     return $open_namespace->($vmid, $pid, $kind);
1178 };
1179
1180 my $do_syncfs = sub {
1181     my ($vmid, $pid, $socket) = @_;
1182
1183     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1184
1185     # Tell the parent process to start reading our /proc/mounts
1186     print {$socket} "go\n";
1187     $socket->flush();
1188
1189     # Receive /proc/self/mounts
1190     my $mountdata = do { local $/ = undef; <$socket> };
1191     close $socket;
1192
1193     my %nosyncfs = (
1194         cgroup => 1,
1195         cgroup2 => 1,
1196         devtmpfs => 1,
1197         devpts => 1,
1198         'fuse.lxcfs' => 1,
1199         fusectl => 1,
1200         mqueue => 1,
1201         proc => 1,
1202         sysfs => 1,
1203         tmpfs => 1,
1204     );
1205
1206     # Now sync all mountpoints...
1207     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1208     foreach my $mp (@$mounts) {
1209         my ($what, $dir, $fs) = @$mp;
1210         next if $nosyncfs{$fs};
1211         eval { PVE::Tools::sync_mountpoint($dir); };
1212         warn $@ if $@;
1213     }
1214 };
1215
1216 sub sync_container_namespace {
1217     my ($vmid) = @_;
1218     my $pid = find_lxc_pid($vmid);
1219
1220     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1221     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1222         or die "failed to create socketpair: $!\n";
1223
1224     my $child = fork();
1225     die "fork failed: $!\n" if !defined($child);
1226
1227     if (!$child) {
1228         eval {
1229             close $pfd;
1230             &$do_syncfs($vmid, $pid, $cfd);
1231         };
1232         if (my $err = $@) {
1233             warn $err;
1234             POSIX::_exit(1);
1235         }
1236         POSIX::_exit(0);
1237     }
1238     close $cfd;
1239     my $go = <$pfd>;
1240     die "failed to enter container namespace\n" if $go ne "go\n";
1241
1242     open my $mounts, '<', "/proc/$child/mounts"
1243         or die "failed to open container's /proc/mounts: $!\n";
1244     my $mountdata = do { local $/ = undef; <$mounts> };
1245     close $mounts;
1246     print {$pfd} $mountdata;
1247     close $pfd;
1248
1249     while (waitpid($child, 0) != $child) {}
1250     die "failed to sync container namespace\n" if $? != 0;
1251 }
1252
1253 sub template_create {
1254     my ($vmid, $conf) = @_;
1255
1256     my $storecfg = PVE::Storage::config();
1257
1258     PVE::LXC::Config->foreach_volume($conf, sub {
1259         my ($ms, $mountpoint) = @_;
1260
1261         my $volid = $mountpoint->{volume};
1262
1263         die "Template feature is not available for '$volid'\n"
1264             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1265     });
1266
1267     PVE::LXC::Config->foreach_volume($conf, sub {
1268         my ($ms, $mountpoint) = @_;
1269
1270         my $volid = $mountpoint->{volume};
1271
1272         PVE::Storage::activate_volumes($storecfg, [$volid]);
1273
1274         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1275         $mountpoint->{volume} = $template_volid;
1276         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1277     });
1278
1279     PVE::LXC::Config->write_config($vmid, $conf);
1280 }
1281
1282 sub check_ct_modify_config_perm {
1283     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1284
1285     return 1 if $authuser eq 'root@pam';
1286     my $storage_cfg = PVE::Storage::config();
1287
1288     my $check = sub {
1289         my ($opt, $delete) = @_;
1290         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1291             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1292         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1293             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1294             return if $delete;
1295             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1296             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1297                 if $data->{type} ne 'volume';
1298             my $volid = $data->{volume};
1299             if ($volid =~ $NEW_DISK_RE) {
1300                 my $sid = $1;
1301                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1302             } else {
1303                 PVE::Storage::check_volume_access(
1304                     $rpcenv,
1305                     $authuser,
1306                     $storage_cfg,
1307                     $vmid,
1308                     $volid,
1309                     'rootdir',
1310                 );
1311             }
1312         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1313             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1314         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1315                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1316             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1317         } elsif ($opt eq 'features') {
1318             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1319                 if !$unprivileged;
1320
1321             my $nesting_changed = 0;
1322             my $other_changed = 0;
1323             if (!$delete) {
1324                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1325                 if (defined($oldconf) && $oldconf->{$opt}) {
1326                     # existing container with features
1327                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1328                     for my $feature ((keys %$old_features, keys %$features)) {
1329                         my $old = $old_features->{$feature} // '';
1330                         my $new = $features->{$feature} // '';
1331                         if ($old ne $new) {
1332                             if ($feature eq 'nesting') {
1333                                 $nesting_changed = 1;
1334                                 next;
1335                             } else {
1336                                 $other_changed = 1;
1337                                 last;
1338                             }
1339                         }
1340                     }
1341                 } else {
1342                     # new container or no features defined
1343                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1344                         $nesting_changed = 1;
1345                     } elsif (scalar(keys %$features) > 0) {
1346                         $other_changed = 1;
1347                     }
1348                 }
1349             } else {
1350                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1351                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1352                     $nesting_changed = 1;
1353                 } elsif (scalar(keys %$features) > 0) {
1354                     $other_changed = 1;
1355                 }
1356             }
1357             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1358                 if $other_changed;
1359             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1360                 if $nesting_changed;
1361         } elsif ($opt eq 'hookscript') {
1362             # For now this is restricted to root@pam
1363             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1364         } elsif ($opt eq 'tags') {
1365             my $old = $oldconf->{$opt};
1366             my $new = $delete ? '' : $newconf->{$opt};
1367             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1368         } else {
1369             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1370         }
1371     };
1372
1373     foreach my $opt (keys %$newconf) {
1374         &$check($opt, 0);
1375     }
1376     foreach my $opt (@$delete) {
1377         &$check($opt, 1);
1378     }
1379
1380     return 1;
1381 }
1382
1383 sub umount_all {
1384     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1385
1386     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1387     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1388
1389     my $res = 1;
1390
1391     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1392         my ($ms, $mountpoint) = @_;
1393
1394         my $volid = $mountpoint->{volume};
1395         my $mount = $mountpoint->{mp};
1396
1397         return if !$volid || !$mount;
1398
1399         my $mount_path = "$rootdir/$mount";
1400         $mount_path =~ s!/+!/!g;
1401
1402         return if !PVE::ProcFSTools::is_mounted($mount_path);
1403
1404         eval {
1405             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1406         };
1407         if (my $err = $@) {
1408             if ($noerr) {
1409                 $res = 0;
1410                 warn $err;
1411             } else {
1412                 die $err;
1413             }
1414         }
1415     });
1416
1417     return $res; # tell caller if (some) umounts failed for the noerr case
1418 }
1419
1420 sub mount_all {
1421     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1422
1423     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1424     File::Path::make_path($rootdir);
1425
1426     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1427     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1428
1429     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1430
1431     eval {
1432         PVE::LXC::Config->foreach_volume($conf, sub {
1433             my ($ms, $mountpoint) = @_;
1434
1435             $mountpoint->{ro} = 0 if $ignore_ro;
1436
1437             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1438         });
1439     };
1440     if (my $err = $@) {
1441         warn "mounting container failed\n";
1442         umount_all($vmid, $storage_cfg, $conf, 1);
1443         die $err;
1444     }
1445
1446     return $rootdir;
1447 }
1448
1449
1450 sub mountpoint_mount_path {
1451     my ($mountpoint, $storage_cfg, $snapname) = @_;
1452
1453     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1454 }
1455
1456 sub query_loopdev {
1457     my ($path) = @_;
1458     my $found;
1459     my $parser = sub {
1460         my $line = shift;
1461         if ($line =~ m@^(/dev/loop\d+):@) {
1462             $found = $1;
1463         }
1464     };
1465     my $cmd = ['losetup', '--associated', $path];
1466     PVE::Tools::run_command($cmd, outfunc => $parser);
1467     return $found;
1468 }
1469
1470 # Run a function with a file attached to a loop device.
1471 # The loop device is always detached afterwards (or set to autoclear).
1472 # Returns the loop device.
1473 sub run_with_loopdev {
1474     my ($func, $file, $readonly) = @_;
1475     my $device = query_loopdev($file);
1476     # Try to reuse an existing device
1477     if ($device) {
1478         # We assume that whoever setup the loop device is responsible for
1479         # detaching it.
1480         &$func($device);
1481         return $device;
1482     }
1483
1484     my $parser = sub {
1485         my $line = shift;
1486         if ($line =~ m@^(/dev/loop\d+)$@) {
1487             $device = $1;
1488         }
1489     };
1490     my $losetup_cmd = [
1491         'losetup',
1492         '--show',
1493         '-f',
1494         $file,
1495     ];
1496     push @$losetup_cmd, '-r' if $readonly;
1497     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1498     die "failed to setup loop device for $file\n" if !$device;
1499     eval { &$func($device); };
1500     my $err = $@;
1501     PVE::Tools::run_command(['losetup', '-d', $device]);
1502     die $err if $err;
1503     return $device;
1504 }
1505
1506 # In scalar mode: returns a file handle to the deepest directory node.
1507 # In list context: returns a list of:
1508 #   * the deepest directory node
1509 #   * the 2nd deepest directory (parent of the above)
1510 #   * directory name of the last directory
1511 # So that the path $2/$3 should lead to $1 afterwards.
1512 sub walk_tree_nofollow($$$;$$) {
1513     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1514
1515     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1516         or die "failed to open start directory $start: $!\n";
1517
1518     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1519 }
1520
1521
1522 sub walk_tree_nofollow_fd($$$$;$$) {
1523     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1524
1525     # splitdir() returns '' for empty components including the leading /
1526     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1527
1528     my $fd = $start_fd;
1529     my $dir = $start_dirname;
1530     my $last_component = undef;
1531     my $second = $fd;
1532     foreach my $component (@comps) {
1533         $dir .= "/$component";
1534         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1535
1536         if (!$next) {
1537             # failed, check for symlinks and try to create the path
1538             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1539             die "cannot open directory $dir: $!\n" if !$mkdir;
1540
1541             # We don't check for errors on mkdirat() here and just try to
1542             # openat() again, since at least one error (EEXIST) is an
1543             # expected possibility if multiple containers start
1544             # simultaneously. If someone else injects a symlink now then
1545             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1546             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1547
1548             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1549             die "failed to create path: $dir: $!\n" if !$next;
1550
1551             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1552                 if defined($rootuid) && defined($rootgid);
1553         }
1554
1555         close $second if defined($last_component) && $second != $start_fd;
1556         $last_component = $component;
1557         $second = $fd;
1558         $fd = $next;
1559     }
1560
1561     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1562     close $second if defined($last_component) && $second != $start_fd;
1563     return $fd;
1564 }
1565
1566 # To guard against symlink attack races against other currently running
1567 # containers with shared recursive bind mount hierarchies we prepare a
1568 # directory handle for the directory we're mounting over to verify the
1569 # mountpoint afterwards.
1570 sub __bindmount_prepare {
1571     my ($hostroot, $dir) = @_;
1572     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1573     return $srcdh;
1574 }
1575
1576 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1577 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1578 # we intended to bind mount.
1579 sub __bindmount_verify {
1580     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1581     my $destdh;
1582     if ($parentfd) {
1583         # Open the mount point path coming from the parent directory since the
1584         # filehandle we would have gotten as first result of walk_tree_nofollow
1585         # earlier is still a handle to the underlying directory instead of the
1586         # mounted path.
1587         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1588         die "failed to open mount point: $!\n" if !$destdh;
1589         if ($ro) {
1590             my $dot = '.';
1591             # no separate function because 99% of the time it's the wrong thing to use.
1592             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1593                 die "failed to mark bind mount read only\n";
1594             }
1595             die "read-only check failed: $!\n" if $! != EROFS;
1596         }
1597     } else {
1598         # For the rootfs we don't have a parentfd so we open the path directly.
1599         # Note that this means bindmounting any prefix of the host's
1600         # /var/lib/lxc/$vmid path into another container is considered a grave
1601         # security error.
1602         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1603         die "failed to open mount point: $!\n" if !$destdh;
1604     }
1605
1606     my ($srcdev, $srcinode) = stat($srcdh);
1607     my ($dstdev, $dstinode) = stat($destdh);
1608     close $srcdh;
1609     close $destdh;
1610
1611     return ($srcdev == $dstdev && $srcinode == $dstinode);
1612 }
1613
1614 # Perform the actual bind mounting:
1615 sub __bindmount_do {
1616     my ($dir, $dest, $ro, @extra_opts) = @_;
1617     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1618     if ($ro) {
1619         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1620         if (my $err = $@) {
1621             warn "bindmount error\n";
1622             # don't leave writable bind-mounts behind...
1623             PVE::Tools::run_command(['umount', $dest]);
1624             die $err;
1625         }
1626     }
1627 }
1628
1629 sub bindmount {
1630     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1631
1632     my $srcdh = __bindmount_prepare('/', $dir);
1633
1634     __bindmount_do($dir, $dest, $ro, @extra_opts);
1635
1636     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1637         PVE::Tools::run_command(['umount', $dest]);
1638         die "detected mount path change at: $dir\n";
1639     }
1640 }
1641
1642 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1643 # from $rootdir and $mount and walk the path from $rootdir to the final
1644 # directory to check for symlinks.
1645 sub __mount_prepare_rootdir {
1646     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1647     $rootdir =~ s!/+!/!g;
1648     $rootdir =~ s!/+$!!;
1649     my $mount_path = "$rootdir/$mount";
1650     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1651     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1652 }
1653
1654 # use $rootdir = undef to just return the corresponding mount path
1655 sub mountpoint_mount {
1656     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1657     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1658 }
1659
1660 sub mountpoint_stage {
1661     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1662     my ($path, $loop, $dev) =
1663         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1664
1665     if (!defined($path)) {
1666         return undef if $! == ENOSYS;
1667         die "failed to mount subvolume: $!\n";
1668     }
1669
1670     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1671     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1672     # point).
1673     my $err;
1674     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1675         or die "open_tree() on mount point failed: $!\n";
1676
1677     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1678 }
1679
1680 sub mountpoint_insert_staged {
1681     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1682
1683     if (!defined($rootdir_fd)) {
1684         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1685             or die "failed to open '.': $!\n";
1686     }
1687
1688     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1689
1690     PVE::Tools::move_mount(
1691         fileno($mount_fd),
1692         '',
1693         fileno($dest_fd),
1694         '',
1695         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1696     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1697 }
1698
1699 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1700 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1701 #   Note that if the kernel does not support the new mount API, this will not perform any action
1702 #   and return `undef` with $! = ENOSYS.
1703 sub __mountpoint_mount {
1704     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1705
1706     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1707         $! = ENOSYS;
1708         return undef;
1709     }
1710
1711     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1712     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1713     # which we use in __bindmount_verify()!
1714     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1715
1716     my $volid = $mountpoint->{volume};
1717     my $type = $mountpoint->{type};
1718     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1719     my $mounted_dev;
1720
1721     return if !$volid || !$mount;
1722
1723     $mount =~ s!/+!/!g;
1724
1725     my $mount_path;
1726     my ($mpfd, $parentfd, $last_dir);
1727
1728     if (defined($rootdir)) {
1729         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1730             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1731     }
1732
1733     if (defined($stage_mount)) {
1734         $mount_path = $rootdir;
1735     }
1736
1737     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1738
1739     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1740
1741     my $optlist = [];
1742
1743     if (my $mountopts = $mountpoint->{mountoptions}) {
1744         my @opts = split(/;/, $mountpoint->{mountoptions});
1745         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1746     }
1747
1748     my $acl = $mountpoint->{acl};
1749     if (defined($acl)) {
1750         push @$optlist, ($acl ? 'acl' : 'noacl');
1751     }
1752
1753     my $optstring = join(',', @$optlist);
1754     my $readonly = $mountpoint->{ro};
1755
1756     my @extra_opts;
1757     @extra_opts = ('-o', $optstring) if $optstring;
1758
1759     if ($storage) {
1760
1761         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1762
1763         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1764
1765         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1766
1767         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1768             PVE::Storage::parse_volname($storage_cfg, $volid);
1769
1770         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1771
1772         if ($format eq 'subvol') {
1773             if ($mount_path) {
1774                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1775                 if (defined($snapname)) {
1776                     $name .= "\@$snapname";
1777                     if ($scfg->{type} eq 'zfspool') {
1778                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1779                     } else {
1780                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1781                     }
1782                 } else {
1783                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1784                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1785                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1786                     }
1787                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1788                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1789                 }
1790             }
1791             return wantarray ? ($path, 0, undef) : $path;
1792         } elsif ($format eq 'raw' || $format eq 'iso') {
1793             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1794             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1795             # Our autodev hook expects the /dev/dm-* device currently
1796             # and will create the /dev/mapper symlink accordingly
1797             $path = Cwd::realpath($path);
1798             die "failed to get device path\n" if !$path;
1799             ($path) = ($path =~ /^(.*)$/s); #untaint
1800             my $domount = sub {
1801                 my ($path) = @_;
1802                 if ($mount_path) {
1803                     if ($format eq 'iso') {
1804                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1805                     } elsif ($isBase || defined($snapname)) {
1806                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1807                     } else {
1808                         if ($quota) {
1809                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1810                         }
1811                         push @extra_opts, '-o', 'ro' if $readonly;
1812                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1813                     }
1814                 }
1815             };
1816             my $use_loopdev = 0;
1817             if ($scfg->{content}->{rootdir}) {
1818                 if ($scfg->{path}) {
1819                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1820                     $use_loopdev = 1;
1821                 } else {
1822                     $mounted_dev = $path;
1823                     &$domount($path);
1824                 }
1825             } else {
1826                 die "storage '$storage' does not support containers\n";
1827             }
1828             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1829         } else {
1830             die "unsupported image format '$format'\n";
1831         }
1832     } elsif ($type eq 'device') {
1833         push @extra_opts, '-o', 'ro' if $readonly;
1834         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1835         # See the NOTE above about devicemapper canonicalization
1836         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1837         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1838         return wantarray ? ($volid, 0, $devpath) : $volid;
1839     } elsif ($type eq 'bind') {
1840         die "directory '$volid' does not exist\n" if ! -d $volid;
1841         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1842         warn "cannot enable quota control for bind mounts\n" if $quota;
1843         return wantarray ? ($volid, 0, undef) : $volid;
1844     }
1845
1846     die "unsupported storage";
1847 }
1848
1849 sub mountpoint_hotplug :prototype($$$$$) {
1850     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1851
1852     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1853
1854     # We do the rest in a fork with an unshared mount namespace, because:
1855     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1856     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1857     #     container's namespace, then mount it.
1858
1859     PVE::Tools::run_fork(sub {
1860         # Pin the container pid longer, we also need to get its monitor/parent:
1861         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1862             or die "failed to open pidfd of container $vmid\'s init process\n";
1863
1864         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1865             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1866
1867         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1868         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1869
1870         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1871         # profile to lower our privileges to the same level we have in the start hook:
1872         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1873             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1874         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1875         # apparmor.
1876
1877         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1878         # namespace for it to remain active there since the container will be able to unmount
1879         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1880         # concern.
1881         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1882         chdir('/')
1883             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1884
1885         my $dir = get_staging_mount_path($opt);
1886
1887         # Now switch our apparmor profile before mounting:
1888         my $data = 'changeprofile /usr/bin/lxc-start';
1889         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1890             die "failed to change apparmor profile: $!\n";
1891         }
1892         # Check errors on close as well:
1893         close($aa_fd)
1894             or die "failed to change apparmor profile (close() failed): $!\n";
1895
1896         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1897
1898         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1899         chdir('/')
1900             or die "failed to change root directory within the container's mount namespace: $!\n";
1901
1902         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1903     });
1904 }
1905
1906 # Create a directory in the mountpoint staging tempfs.
1907 sub get_staging_mount_path($) {
1908     my ($opt) = @_;
1909
1910     my $target = get_staging_tempfs() . "/$opt";
1911     if (!mkdir($target) && $! != EEXIST) {
1912         die "failed to create directory $target: $!\n";
1913     }
1914
1915     return $target;
1916 }
1917
1918 # Mount /run/pve/mountpoints as tmpfs
1919 sub get_staging_tempfs() {
1920     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1921     # mounts to that.
1922     my $target = '/var/lib/lxc/.pve-staged-mounts';
1923     if (!mkdir($target)) {
1924         return $target if $! == EEXIST;
1925         die "failed to create directory $target: $!\n";
1926     }
1927
1928     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1929         or die "failed to mount $target as tmpfs: $!\n";
1930
1931     return $target;
1932 }
1933
1934 sub mkfs {
1935     my ($dev, $rootuid, $rootgid) = @_;
1936
1937     run_command(
1938         [
1939             'mkfs.ext4',
1940             '-O',
1941             'mmp',
1942             '-E',
1943             "root_owner=$rootuid:$rootgid",
1944             $dev,
1945         ],
1946         outfunc => sub {
1947             my $line = shift;
1948             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1949             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1950                 print "$line\n";
1951             }
1952         },
1953         errfunc => sub {
1954             my $line = shift;
1955             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1956         }
1957     );
1958 }
1959
1960 sub format_disk {
1961     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1962
1963     if ($volid =~ m!^/dev/.+!) {
1964         mkfs($volid);
1965         return;
1966     }
1967
1968     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1969
1970     die "cannot format volume '$volid' with no storage\n" if !$storage;
1971
1972     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1973
1974     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1975
1976     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1977
1978     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1979         PVE::Storage::parse_volname($storage_cfg, $volid);
1980
1981     die "cannot format volume '$volid' (format == $format)\n"
1982         if $format ne 'raw';
1983
1984     mkfs($path, $rootuid, $rootgid);
1985 }
1986
1987 sub destroy_disks {
1988     my ($storecfg, $vollist) = @_;
1989
1990     foreach my $volid (@$vollist) {
1991         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1992         warn $@ if $@;
1993     }
1994 }
1995
1996 sub alloc_disk {
1997     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1998
1999     my $needs_chown = 0;
2000     my $volid;
2001
2002     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2003     # fixme: use better naming ct-$vmid-disk-X.raw?
2004
2005     eval {
2006         my $do_format = 0;
2007         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2008             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2009                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2010                 $do_format = 1;
2011             } else {
2012                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2013                 $needs_chown = 1;
2014             }
2015         } elsif ($scfg->{type} eq 'zfspool') {
2016             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2017             $needs_chown = 1;
2018         } elsif ($scfg->{content}->{rootdir}) {
2019             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2020             $do_format = 1;
2021         } else {
2022             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2023         }
2024         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2025     };
2026     if (my $err = $@) {
2027         # in case formatting got interrupted:
2028         if (defined($volid)) {
2029             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2030             warn $@ if $@;
2031         }
2032         die $err;
2033     }
2034
2035     return ($volid, $needs_chown);
2036 }
2037
2038 sub create_disks {
2039     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2040
2041     my $vollist = [];
2042
2043     eval {
2044         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2045         my $chown_vollist = [];
2046
2047         PVE::LXC::Config->foreach_volume($settings, sub {
2048             my ($ms, $mountpoint) = @_;
2049
2050             my $volid = $mountpoint->{volume};
2051             my $mp = $mountpoint->{mp};
2052
2053             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2054
2055             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2056                 my ($storeid, $size_gb) = ($1, $2);
2057
2058                 my $size_kb = int(${size_gb}*1024) * 1024;
2059
2060                 my $needs_chown = 0;
2061                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2062                 push @$chown_vollist, $volid if $needs_chown;
2063                 push @$vollist, $volid;
2064                 $mountpoint->{volume} = $volid;
2065                 $mountpoint->{size} = $size_kb * 1024;
2066                 if ($pending) {
2067                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2068                 } else {
2069                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2070                 }
2071             } else {
2072                 # use specified/existing volid/dir/device
2073                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2074             }
2075         });
2076
2077         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2078         foreach my $volid (@$chown_vollist) {
2079             my $path = PVE::Storage::path($storecfg, $volid, undef);
2080             chown($rootuid, $rootgid, $path);
2081         }
2082         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2083     };
2084     # free allocated images on error
2085     if (my $err = $@) {
2086         destroy_disks($storecfg, $vollist);
2087         die $err;
2088     }
2089     return $vollist;
2090 }
2091
2092 sub update_disksize {
2093     my ($vmid, $conf, $all_volumes) = @_;
2094
2095     my $changes;
2096     my $prefix = "CT $vmid:";
2097
2098     my $update_mp = sub {
2099         my ($key, $mp, @param) = @_;
2100         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2101
2102         if (!defined($mp->{size}) || $size != $mp->{size}) {
2103             $changes = 1;
2104             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2105             $mp->{size} = $size;
2106             my $no_mp = $key eq 'rootfs'; # rootfs is handled different from other mount points
2107             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $no_mp);
2108         }
2109     };
2110
2111     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2112
2113     return $changes;
2114 }
2115
2116 sub update_unused {
2117     my ($vmid, $conf, $all_volumes) = @_;
2118
2119     my $changes;
2120     my $prefix = "CT $vmid:";
2121
2122     # Note: it is allowed to define multiple storage entries with the same path
2123     # (alias), so we need to check both 'volid' and real 'path' (two different
2124     # volid can point to the same path).
2125
2126     # used and unused disks
2127     my $refpath = {};
2128     my $orphans = {};
2129
2130     foreach my $opt (keys %$conf) {
2131         next if ($opt !~ m/^unused\d+$/);
2132         my $vol = $all_volumes->{$conf->{$opt}};
2133         $refpath->{$vol->{path}} = $vol->{volid};
2134     }
2135
2136     foreach my $key (keys %$all_volumes) {
2137         my $vol = $all_volumes->{$key};
2138         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2139         my $path = $vol->{path};
2140
2141         if ($in_use) {
2142             $refpath->{$path} = $key;
2143             delete $orphans->{$path};
2144         } else {
2145             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2146                 $orphans->{$path} = $key;
2147             }
2148         }
2149     }
2150
2151     for my $key (keys %$orphans) {
2152         my $disk = $orphans->{$key};
2153         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2154
2155         if ($unused) {
2156             $changes = 1;
2157             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2158         }
2159     }
2160
2161     return $changes;
2162 }
2163
2164 sub scan_volids {
2165     my ($cfg, $vmid) = @_;
2166
2167     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2168
2169     my $all_volumes = {};
2170     foreach my $storeid (keys %$info) {
2171         foreach my $item (@{$info->{$storeid}}) {
2172             my $volid = $item->{volid};
2173             next if !($volid && $item->{size});
2174             $item->{path} = PVE::Storage::path($cfg, $volid);
2175             $all_volumes->{$volid} = $item;
2176         }
2177     }
2178
2179     return $all_volumes;
2180 }
2181
2182 sub rescan {
2183     my ($vmid, $nolock, $dryrun) = @_;
2184
2185     my $cfg = PVE::Storage::config();
2186
2187     print "rescan volumes...\n";
2188     my $all_volumes = scan_volids($cfg, $vmid);
2189
2190     my $updatefn =  sub {
2191         my ($vmid) = @_;
2192
2193         my $changes;
2194         my $conf = PVE::LXC::Config->load_config($vmid);
2195
2196         PVE::LXC::Config->check_lock($conf);
2197
2198         my $vm_volids = {};
2199         foreach my $volid (keys %$all_volumes) {
2200             my $info = $all_volumes->{$volid};
2201             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2202         }
2203
2204         my $upu = update_unused($vmid, $conf, $vm_volids);
2205         my $upd = update_disksize($vmid, $conf, $vm_volids);
2206         $changes = $upu || $upd;
2207
2208         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2209     };
2210
2211     if (defined($vmid)) {
2212         if ($nolock) {
2213             &$updatefn($vmid);
2214         } else {
2215             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2216         }
2217     } else {
2218         my $vmlist = config_list();
2219         foreach my $vmid (keys %$vmlist) {
2220             if ($nolock) {
2221                 &$updatefn($vmid);
2222             } else {
2223                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2224             }
2225         }
2226     }
2227 }
2228
2229
2230 # bash completion helper
2231
2232 sub complete_os_templates {
2233     my ($cmdname, $pname, $cvalue) = @_;
2234
2235     my $cfg = PVE::Storage::config();
2236
2237     my $storeid;
2238
2239     if ($cvalue =~ m/^([^:]+):/) {
2240         $storeid = $1;
2241     }
2242
2243     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2244     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2245
2246     my $res = [];
2247     foreach my $id (keys %$data) {
2248         foreach my $item (@{$data->{$id}}) {
2249             push @$res, $item->{volid} if defined($item->{volid});
2250         }
2251     }
2252
2253     return $res;
2254 }
2255
2256 my $complete_ctid_full = sub {
2257     my ($running) = @_;
2258
2259     my $idlist = vmstatus();
2260
2261     my $active_hash = list_active_containers();
2262
2263     my $res = [];
2264
2265     foreach my $id (keys %$idlist) {
2266         my $d = $idlist->{$id};
2267         if (defined($running)) {
2268             next if $d->{template};
2269             next if $running && !$active_hash->{$id};
2270             next if !$running && $active_hash->{$id};
2271         }
2272         push @$res, $id;
2273
2274     }
2275     return $res;
2276 };
2277
2278 sub complete_ctid {
2279     return &$complete_ctid_full();
2280 }
2281
2282 sub complete_ctid_stopped {
2283     return &$complete_ctid_full(0);
2284 }
2285
2286 sub complete_ctid_running {
2287     return &$complete_ctid_full(1);
2288 }
2289
2290 sub parse_id_maps {
2291     my ($conf) = @_;
2292
2293     my $id_map = [];
2294     my $rootuid = 0;
2295     my $rootgid = 0;
2296
2297     my $lxc = $conf->{lxc};
2298     foreach my $entry (@$lxc) {
2299         my ($key, $value) = @$entry;
2300         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2301         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2302         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2303             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2304             push @$id_map, [$type, $ct, $host, $length];
2305             if ($ct == 0) {
2306                 $rootuid = $host if $type eq 'u';
2307                 $rootgid = $host if $type eq 'g';
2308             }
2309         } else {
2310             die "failed to parse idmap: $value\n";
2311         }
2312     }
2313
2314     if (!@$id_map && $conf->{unprivileged}) {
2315         # Should we read them from /etc/subuid?
2316         $id_map = [ ['u', '0', '100000', '65536'],
2317                     ['g', '0', '100000', '65536'] ];
2318         $rootuid = $rootgid = 100000;
2319     }
2320
2321     return ($id_map, $rootuid, $rootgid);
2322 }
2323
2324 sub userns_command {
2325     my ($id_map) = @_;
2326     if (@$id_map) {
2327         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2328     }
2329     return [];
2330 }
2331
2332 my sub print_ct_stderr_log {
2333     my ($vmid) = @_;
2334     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2335     return if !$log;
2336
2337     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2338         my $line = $2;
2339         print STDERR "$line\n";
2340     }
2341 }
2342 my sub print_ct_warn_log {
2343     my ($vmid) = @_;
2344     my $log_fn = "/run/pve/ct-$vmid.warnings";
2345     my $log = eval { file_get_contents($log_fn) };
2346     return if !$log;
2347
2348     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2349         PVE::RESTEnvironment::log_warn($1);
2350     }
2351     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2352 }
2353
2354 my sub monitor_state_change($$) {
2355     my ($monitor_socket, $vmid) = @_;
2356     die "no monitor socket\n" if !defined($monitor_socket);
2357
2358     while (1) {
2359         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2360
2361         die "monitor socket: got EOF\n" if !defined($type);
2362
2363         next if $name ne "$vmid" || $type ne 'STATE';
2364
2365         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2366             alarm(0); # don't timeout after seeing the starting state
2367         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2368                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2369                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2370             return 0;
2371         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2372             return 1;
2373         } else {
2374             warn "unexpected message from monitor socket - " .
2375                  "type: '$type' - value: '$value'\n";
2376         }
2377     }
2378 }
2379 my sub monitor_start($$) {
2380     my ($monitor_socket, $vmid) = @_;
2381
2382     my $success = eval {
2383         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2384     };
2385     if (my $err = $@) {
2386         warn "problem with monitor socket, but continuing anyway: $err\n";
2387     } elsif (!$success) {
2388         print_ct_stderr_log($vmid);
2389         die "startup for container '$vmid' failed\n";
2390     }
2391 }
2392
2393 sub vm_start {
2394     my ($vmid, $conf, $skiplock, $debug) = @_;
2395
2396     # apply pending changes while starting
2397     if (scalar(keys %{$conf->{pending}})) {
2398         my $storecfg = PVE::Storage::config();
2399         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2400         PVE::LXC::Config->write_config($vmid, $conf);
2401         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2402     }
2403
2404     update_lxc_config($vmid, $conf);
2405
2406     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2407
2408     if ($skiplock) {
2409         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2410         close($fh);
2411     }
2412
2413     my $storage_cfg = PVE::Storage::config();
2414     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2415
2416     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2417
2418     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2419     warn $@ if $@;
2420
2421     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2422
2423     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2424     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2425
2426     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2427
2428     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2429     eval {
2430         run_command($cmd);
2431
2432         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2433
2434         # if debug is requested, print the log it also when the start succeeded
2435         print_ct_stderr_log($vmid) if $is_debug;
2436
2437         print_ct_warn_log($vmid); # always print warn log, if any
2438     };
2439     if (my $err = $@) {
2440         unlink $skiplock_flag_fn;
2441         die $err;
2442     }
2443     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2444
2445     return;
2446 }
2447
2448 # Helper to stop a container completely and make sure it has stopped completely.
2449 # This is necessary because we want the post-stop hook to have completed its
2450 # unmount-all step, but post-stop happens after lxc puts the container into the
2451 # STOPPED state.
2452 # $kill - if true it will always do an immediate hard-stop
2453 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2454 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2455 sub vm_stop {
2456     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2457
2458     # Open the container's command socket.
2459     my $path = "\0/var/lib/lxc/$vmid/command";
2460     my $sock = IO::Socket::UNIX->new(
2461         Type => SOCK_STREAM(),
2462         Peer => $path,
2463     );
2464     if (!$sock) {
2465         return if $! == ECONNREFUSED; # The container is not running
2466         die "failed to open container ${vmid}'s command socket: $!\n";
2467     }
2468
2469     my $conf = PVE::LXC::Config->load_config($vmid);
2470     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2471
2472     # Stop the container:
2473
2474     my $cmd = ['lxc-stop', '-n', $vmid];
2475
2476     if ($kill) {
2477         push @$cmd, '--kill'; # doesn't allow timeouts
2478     } else {
2479         # lxc-stop uses a default timeout
2480         push @$cmd, '--nokill' if !$kill_after_timeout;
2481
2482         if (defined($shutdown_timeout)) {
2483             push @$cmd, '--timeout', $shutdown_timeout;
2484             # Give run_command 5 extra seconds
2485             $shutdown_timeout += 5;
2486         }
2487     }
2488
2489     eval { run_command($cmd, timeout => $shutdown_timeout) };
2490
2491     # Wait until the command socket is closed.
2492     # In case the lxc-stop call failed, reading from the command socket may block forever,
2493     # so poll with another timeout to avoid freezing the shutdown task.
2494     if (my $err = $@) {
2495         warn $err if $err;
2496
2497         my $poll = IO::Poll->new();
2498         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2499         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2500         return if ($poll->events($sock) & POLLHUP);
2501     } else {
2502         my $result = <$sock>;
2503         return if !defined $result; # monitor is gone and the ct has stopped.
2504     }
2505
2506     die "container did not stop\n";
2507 }
2508
2509 sub vm_reboot {
2510     my ($vmid, $timeout, $skiplock) = @_;
2511
2512     PVE::LXC::Config->lock_config($vmid, sub {
2513         return if !check_running($vmid);
2514
2515         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2516
2517         my $conf = PVE::LXC::Config->load_config($vmid);
2518         vm_start($vmid, $conf);
2519     });
2520 }
2521
2522 sub run_unshared {
2523     my ($code) = @_;
2524
2525     return PVE::Tools::run_fork(sub {
2526         # Unshare the mount namespace
2527         die "failed to unshare mount namespace: $!\n"
2528             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2529         run_command(['mount', '--make-rslave', '/']);
2530         return $code->();
2531     });
2532 }
2533
2534 my $copy_volume = sub {
2535     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2536
2537     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2538     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2539
2540     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2541     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2542
2543     my @mounted;
2544     eval {
2545         # mount and copy
2546         mkdir $src;
2547         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2548         push @mounted, $src;
2549         mkdir $dest;
2550         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2551         push @mounted, $dest;
2552
2553         $bwlimit //= 0;
2554
2555         run_command([
2556             'rsync',
2557             '--stats',
2558             '-X',
2559             '-A',
2560             '--numeric-ids',
2561             '-aH',
2562             '--whole-file',
2563             '--sparse',
2564             '--one-file-system',
2565             "--bwlimit=$bwlimit",
2566             "$src/",
2567             $dest
2568         ]);
2569     };
2570     my $err = $@;
2571
2572     # Wait for rsync's children to release dest so that
2573     # consequent file operations (umount, remove) are possible
2574     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2575
2576     foreach my $mount (reverse @mounted) {
2577         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2578         warn "Can't umount $mount\n" if $@;
2579     }
2580
2581     # If this fails they're used as mount points in a concurrent operation
2582     # (which should not happen but there's also no real need to get rid of them).
2583     rmdir $dest;
2584     rmdir $src;
2585
2586     die $err if $err;
2587 };
2588
2589 # Should not be called after unsharing the mount namespace!
2590 sub copy_volume {
2591     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2592
2593     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2594     File::Path::make_path("/var/lib/lxc/$vmid");
2595     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2596     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2597
2598     # get id's for unprivileged container
2599     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2600
2601     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2602     # are visible in this namespace, otherwise the host only sees the empty
2603     # (not-mounted) directory.
2604     my $new_volid;
2605     eval {
2606         # Make sure $mp contains a correct size.
2607         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2608         my $needs_chown;
2609         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2610         if ($needs_chown) {
2611             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2612             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2613             chown($rootuid, $rootgid, $path);
2614         }
2615
2616         run_unshared(sub {
2617             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2618         });
2619     };
2620     if (my $err = $@) {
2621         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2622             if defined($new_volid);
2623         die $err;
2624     }
2625
2626     return $new_volid;
2627 }
2628
2629 sub get_lxc_version() {
2630     my $version;
2631     run_command([qw(lxc-start --version)], outfunc => sub {
2632         my ($line) = @_;
2633         # We only parse out major & minor version numbers.
2634         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2635             $version = [$1, $2];
2636         }
2637     });
2638
2639     die "failed to get lxc version\n" if !defined($version);
2640
2641     # return as a list:
2642     return $version->@*;
2643 }
2644
2645 sub freeze($) {
2646     my ($vmid) = @_;
2647     if (PVE::CGroup::cgroup_mode() == 2) {
2648         PVE::LXC::Command::freeze($vmid, 30);
2649     } else {
2650         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2651     }
2652 }
2653
2654 sub thaw($) {
2655     my ($vmid) = @_;
2656     if (PVE::CGroup::cgroup_mode() == 2) {
2657         PVE::LXC::Command::unfreeze($vmid, 30);
2658     } else {
2659         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2660     }
2661 }
2662
2663 1;