src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     run_command
  24     dir_glob_foreach
  25     file_get_contents
  26     file_set_contents
  27     AT_FDCWD
  28     O_PATH
  29     $IPV4RE
  30     $IPV6RE
  31 );
  32 use PVE::RPCEnvironment;
  33 use PVE::CpuSet;
  34 use PVE::Network;
  35 use PVE::AccessControl;
  36 use PVE::ProcFSTools;
  37 use PVE::Syscall qw(:fsmount);
  38 use PVE::LXC::Config;
  39 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  40 use PVE::LXC::Tools;
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Monitor;
  43 use PVE::CGroup;
  44
  45 use Time::HiRes qw (gettimeofday);
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         my $lxcmem = int($memory*1024*1024);
 689         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 690
 691         my $lxcswap = int($swap*1024*1024);
 692         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 693     }
 694
 695     if ($cgv1->{cpu}) {
 696         if (my $cpulimit = $conf->{cpulimit}) {
 697             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 698             my $value = int(100000*$cpulimit);
 699             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 700         }
 701
 702         my $shares = $conf->{cpuunits} || 1024;
 703         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 704     } elsif ($cgv2->{cpu}) {
 705         # See PVE::CGroup
 706         if (my $cpulimit = $conf->{cpulimit}) {
 707             my $value = int(100000*$cpulimit);
 708             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 709         }
 710
 711         if (defined(my $shares = $conf->{cpuunits})) {
 712             die "cpu weight (shares) must be in range [1, 10000]\n"
 713                 if $shares < 1 || $shares > 10000;
 714             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 715         }
 716     }
 717
 718     die "missing 'rootfs' configuration\n"
 719         if !defined($conf->{rootfs});
 720
 721     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 722
 723     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 724
 725     foreach my $k (sort keys %$conf) {
 726         next if $k !~ m/^net(\d+)$/;
 727         my $ind = $1;
 728         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 729         $raw .= "lxc.net.$ind.type = veth\n";
 730         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 731         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 732         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 733         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 734
 735         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 736         if ($lxc_major >= 4) {
 737             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 738         }
 739     }
 740
 741     my $had_cpuset = 0;
 742     if (my $lxcconf = $conf->{lxc}) {
 743         foreach my $entry (@$lxcconf) {
 744             my ($k, $v) = @$entry;
 745             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 746             $raw .= "$k = $v\n";
 747         }
 748     }
 749
 750     my $cpuset;
 751     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 752     if (defined($cpuset_cgroup)) {
 753         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 754             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 755     }
 756     my $cores = $conf->{cores};
 757     if (!$had_cpuset && $cores && $cpuset) {
 758         my @members = $cpuset->members();
 759         while (scalar(@members) > $cores) {
 760             my $randidx = int(rand(scalar(@members)));
 761             $cpuset->delete($members[$randidx]);
 762             splice(@members, $randidx, 1); # keep track of the changes
 763         }
 764         my $ver = $cpuset_version == 1 ? '' : '2';
 765         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 766     }
 767
 768     File::Path::mkpath("$dir/rootfs");
 769
 770     PVE::Tools::file_set_contents("$dir/config", $raw);
 771 }
 772
 773 # verify and cleanup nameserver list (replace \0 with ' ')
 774 sub verify_nameserver_list {
 775     my ($nameserver_list) = @_;
 776
 777     my @list = ();
 778     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 779         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 780         push @list, $server;
 781     }
 782
 783     return join(' ', @list);
 784 }
 785
 786 sub verify_searchdomain_list {
 787     my ($searchdomain_list) = @_;
 788
 789     my @list = ();
 790     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 791         # todo: should we add checks for valid dns domains?
 792         push @list, $server;
 793     }
 794
 795     return join(' ', @list);
 796 }
 797
 798 sub get_console_command {
 799     my ($vmid, $conf, $escapechar) = @_;
 800
 801     # '-1' as $escapechar disables keyboard escape sequence
 802     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 803
 804     my $cmode = PVE::LXC::Config->get_cmode($conf);
 805
 806     my $cmd = [];
 807     if ($cmode eq 'console') {
 808         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 809         push @$cmd, '-e', $escapechar if $escapechar;
 810     } elsif ($cmode eq 'tty') {
 811         push @$cmd, 'lxc-console', '-n',  $vmid;
 812         push @$cmd, '-e', $escapechar if $escapechar;
 813     } elsif ($cmode eq 'shell') {
 814         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 815     } else {
 816         die "internal error";
 817     }
 818
 819     return $cmd;
 820 }
 821
 822 sub get_primary_ips {
 823     my ($conf) = @_;
 824
 825     # return data from net0
 826
 827     return undef if !defined($conf->{net0});
 828     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 829
 830     my $ipv4 = $net->{ip};
 831     if ($ipv4) {
 832         if ($ipv4 =~ /^(dhcp|manual)$/) {
 833             $ipv4 = undef
 834         } else {
 835             $ipv4 =~ s!/\d+$!!;
 836         }
 837     }
 838     my $ipv6 = $net->{ip6};
 839     if ($ipv6) {
 840         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 841             $ipv6 = undef;
 842         } else {
 843             $ipv6 =~ s!/\d+$!!;
 844         }
 845     }
 846
 847     return ($ipv4, $ipv6);
 848 }
 849
 850 sub delete_mountpoint_volume {
 851     my ($storage_cfg, $vmid, $volume) = @_;
 852
 853     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 854
 855     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 856
 857     if ($vmid == $owner) {
 858         PVE::Storage::vdisk_free($storage_cfg, $volume);
 859     } else {
 860         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 861     }
 862 }
 863
 864 sub destroy_lxc_container {
 865     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 866
 867     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, sub {
 868         my ($ms, $mountpoint) = @_;
 869         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 870     });
 871
 872     if ($purge_unreferenced) { # also remove unreferenced disk
 873         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 874         PVE::Storage::foreach_volid($vmdisks, sub {
 875             my ($volid, $sid, $volname, $d) = @_;
 876             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 877             warn $@ if $@;
 878         });
 879     }
 880
 881     rmdir "/var/lib/lxc/$vmid/rootfs";
 882     unlink "/var/lib/lxc/$vmid/config";
 883     rmdir "/var/lib/lxc/$vmid";
 884     if (defined $replacement_conf) {
 885         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 886     } else {
 887         PVE::LXC::Config->destroy_config($vmid);
 888     }
 889 }
 890
 891 sub vm_stop_cleanup {
 892     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 893
 894     return if $keepActive;
 895
 896     eval {
 897         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 898         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 899     };
 900     warn $@ if $@; # avoid errors - just warn
 901 }
 902
 903 sub update_net {
 904     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 905
 906     if ($newnet->{type} ne 'veth') {
 907         # for when there are physical interfaces
 908         die "cannot update interface of type $newnet->{type}";
 909     }
 910
 911     my $veth = "veth${vmid}i${netid}";
 912     my $eth = $newnet->{name};
 913
 914     if (my $oldnetcfg = $conf->{$opt}) {
 915         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 916
 917         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 918             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 919
 920             PVE::Network::veth_delete($veth);
 921             delete $conf->{$opt};
 922             PVE::LXC::Config->write_config($vmid, $conf);
 923
 924             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 925
 926         } else {
 927             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 928                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 929                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 930
 931                 if ($oldnet->{bridge}) {
 932                     PVE::Network::tap_unplug($veth);
 933                     foreach (qw(bridge tag firewall)) {
 934                         delete $oldnet->{$_};
 935                     }
 936                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 937                     PVE::LXC::Config->write_config($vmid, $conf);
 938                 }
 939
 940                 if ($have_sdn) {
 941                     PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 942                 } else {
 943                     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 944                 }
 945
 946                 # This includes the rate:
 947                 foreach (qw(bridge tag firewall rate)) {
 948                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 949                 }
 950             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 951                 # Rate can be applied on its own but any change above needs to
 952                 # include the rate in tap_plug since OVS resets everything.
 953                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 954                 $oldnet->{rate} = $newnet->{rate}
 955             }
 956             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 957             PVE::LXC::Config->write_config($vmid, $conf);
 958         }
 959     } else {
 960         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 961     }
 962
 963     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 964 }
 965
 966 sub hotplug_net {
 967     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 968
 969     my $veth = "veth${vmid}i${netid}";
 970     my $vethpeer = $veth . "p";
 971     my $eth = $newnet->{name};
 972
 973     if ($have_sdn) {
 974         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 975         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 976     } else {
 977         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 978         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 979     }
 980
 981     # attach peer in container
 982     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 983     PVE::Tools::run_command($cmd);
 984
 985     # link up peer in container
 986     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 987     PVE::Tools::run_command($cmd);
 988
 989     my $done = { type => 'veth' };
 990     foreach (qw(bridge tag firewall hwaddr name)) {
 991         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 992     }
 993     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 994
 995     PVE::LXC::Config->write_config($vmid, $conf);
 996 }
 997
 998 sub update_ipconfig {
 999     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1000
1001     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1002
1003     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1004     my $deleted = [];
1005     my $added = [];
1006     my $nscmd = sub {
1007         my $cmdargs = shift;
1008         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1009     };
1010     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1011
1012     my $change_ip_config = sub {
1013         my ($ipversion) = @_;
1014
1015         my $family_opt = "-$ipversion";
1016         my $suffix = $ipversion == 4 ? '' : $ipversion;
1017         my $gw= "gw$suffix";
1018         my $ip= "ip$suffix";
1019
1020         my $newip = $newnet->{$ip};
1021         my $newgw = $newnet->{$gw};
1022         my $oldip = $optdata->{$ip};
1023         my $oldgw = $optdata->{$gw};
1024
1025         my $change_ip = safe_string_ne($oldip, $newip);
1026         my $change_gw = safe_string_ne($oldgw, $newgw);
1027
1028         return if !$change_ip && !$change_gw;
1029
1030         # step 1: add new IP, if this fails we cancel
1031         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1032         if ($change_ip && $is_real_ip) {
1033             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1034             if (my $err = $@) {
1035                 warn $err;
1036                 return;
1037             }
1038         }
1039
1040         # step 2: replace gateway
1041         #   If this fails we delete the added IP and cancel.
1042         #   If it succeeds we save the config and delete the old IP, ignoring
1043         #   errors. The config is then saved.
1044         # Note: 'ip route replace' can add
1045         if ($change_gw) {
1046             if ($newgw) {
1047                 eval {
1048                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1049                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1050                     }
1051                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1052                 };
1053                 if (my $err = $@) {
1054                     warn $err;
1055                     # the route was not replaced, the old IP is still available
1056                     # rollback (delete new IP) and cancel
1057                     if ($change_ip) {
1058                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1059                         warn $@ if $@; # no need to die here
1060                     }
1061                     return;
1062                 }
1063             } else {
1064                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1065                 # if the route was not deleted, the guest might have deleted it manually
1066                 # warn and continue
1067                 warn $@ if $@;
1068             }
1069             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1070                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1071                 # warn if the route was deleted manually
1072                 warn $@ if $@;
1073             }
1074         }
1075
1076         # from this point on we save the configuration
1077         # step 3: delete old IP ignoring errors
1078         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1079             # We need to enable promote_secondaries, otherwise our newly added
1080             # address will be removed along with the old one.
1081             my $promote = 0;
1082             eval {
1083                 if ($ipversion == 4) {
1084                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1085                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1086                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1087                 }
1088                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1089             };
1090             warn $@ if $@; # no need to die here
1091
1092             if ($ipversion == 4) {
1093                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1094             }
1095         }
1096
1097         foreach my $property ($ip, $gw) {
1098             if ($newnet->{$property}) {
1099                 $optdata->{$property} = $newnet->{$property};
1100             } else {
1101                 delete $optdata->{$property};
1102             }
1103         }
1104         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1105         PVE::LXC::Config->write_config($vmid, $conf);
1106         $lxc_setup->setup_network($conf);
1107     };
1108
1109     &$change_ip_config(4);
1110     &$change_ip_config(6);
1111
1112 }
1113
1114 my $open_namespace = sub {
1115     my ($vmid, $pid, $kind) = @_;
1116     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1117         or die "failed to open $kind namespace of container $vmid: $!\n";
1118     return $fd;
1119 };
1120
1121 my $enter_namespace = sub {
1122     my ($vmid, $pid, $kind, $type) = @_;
1123     my $fd = $open_namespace->($vmid, $pid, $kind);
1124     PVE::Tools::setns(fileno($fd), $type)
1125         or die "failed to enter $kind namespace of container $vmid: $!\n";
1126     close $fd;
1127 };
1128
1129 my $get_container_namespace = sub {
1130     my ($vmid, $pid, $kind) = @_;
1131
1132     my $pidfd;
1133     if (!defined($pid)) {
1134         # Pin the pid while we're grabbing its stuff from /proc
1135         ($pid, $pidfd) = open_lxc_pid($vmid)
1136             or die "failed to open pidfd of container $vmid\'s init process\n";
1137     }
1138
1139     return $open_namespace->($vmid, $pid, $kind);
1140 };
1141
1142 my $do_syncfs = sub {
1143     my ($vmid, $pid, $socket) = @_;
1144
1145     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1146
1147     # Tell the parent process to start reading our /proc/mounts
1148     print {$socket} "go\n";
1149     $socket->flush();
1150
1151     # Receive /proc/self/mounts
1152     my $mountdata = do { local $/ = undef; <$socket> };
1153     close $socket;
1154
1155     my %nosyncfs = (
1156         cgroup => 1,
1157         cgroup2 => 1,
1158         devtmpfs => 1,
1159         devpts => 1,
1160         'fuse.lxcfs' => 1,
1161         fusectl => 1,
1162         mqueue => 1,
1163         proc => 1,
1164         sysfs => 1,
1165         tmpfs => 1,
1166     );
1167
1168     # Now sync all mountpoints...
1169     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1170     foreach my $mp (@$mounts) {
1171         my ($what, $dir, $fs) = @$mp;
1172         next if $nosyncfs{$fs};
1173         eval { PVE::Tools::sync_mountpoint($dir); };
1174         warn $@ if $@;
1175     }
1176 };
1177
1178 sub sync_container_namespace {
1179     my ($vmid) = @_;
1180     my $pid = find_lxc_pid($vmid);
1181
1182     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1183     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1184         or die "failed to create socketpair: $!\n";
1185
1186     my $child = fork();
1187     die "fork failed: $!\n" if !defined($child);
1188
1189     if (!$child) {
1190         eval {
1191             close $pfd;
1192             &$do_syncfs($vmid, $pid, $cfd);
1193         };
1194         if (my $err = $@) {
1195             warn $err;
1196             POSIX::_exit(1);
1197         }
1198         POSIX::_exit(0);
1199     }
1200     close $cfd;
1201     my $go = <$pfd>;
1202     die "failed to enter container namespace\n" if $go ne "go\n";
1203
1204     open my $mounts, '<', "/proc/$child/mounts"
1205         or die "failed to open container's /proc/mounts: $!\n";
1206     my $mountdata = do { local $/ = undef; <$mounts> };
1207     close $mounts;
1208     print {$pfd} $mountdata;
1209     close $pfd;
1210
1211     while (waitpid($child, 0) != $child) {}
1212     die "failed to sync container namespace\n" if $? != 0;
1213 }
1214
1215 sub template_create {
1216     my ($vmid, $conf) = @_;
1217
1218     my $storecfg = PVE::Storage::config();
1219
1220     PVE::LXC::Config->foreach_volume($conf, sub {
1221         my ($ms, $mountpoint) = @_;
1222
1223         my $volid = $mountpoint->{volume};
1224
1225         die "Template feature is not available for '$volid'\n"
1226             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1227     });
1228
1229     PVE::LXC::Config->foreach_volume($conf, sub {
1230         my ($ms, $mountpoint) = @_;
1231
1232         my $volid = $mountpoint->{volume};
1233
1234         PVE::Storage::activate_volumes($storecfg, [$volid]);
1235
1236         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1237         $mountpoint->{volume} = $template_volid;
1238         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1239     });
1240
1241     PVE::LXC::Config->write_config($vmid, $conf);
1242 }
1243
1244 sub check_ct_modify_config_perm {
1245     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1246
1247     return 1 if $authuser eq 'root@pam';
1248     my $storage_cfg = PVE::Storage::config();
1249
1250     my $check = sub {
1251         my ($opt, $delete) = @_;
1252         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1253             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1254         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1255             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1256             return if $delete;
1257             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1258             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1259                 if $data->{type} ne 'volume';
1260             my $volid = $data->{volume};
1261             if ($volid =~ $NEW_DISK_RE) {
1262                 my $sid = $1;
1263                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1264             } else {
1265                 PVE::Storage::check_volume_access($rpcenv, $authuser, $storage_cfg, $vmid, $volid);
1266             }
1267         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1268             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1269         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1270                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1271             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1272         } elsif ($opt eq 'features') {
1273             # For now this is restricted to root@pam
1274             raise_perm_exc("changing feature flags is only allowed for root\@pam");
1275         } elsif ($opt eq 'hookscript') {
1276             # For now this is restricted to root@pam
1277             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1278         } else {
1279             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1280         }
1281     };
1282
1283     foreach my $opt (keys %$newconf) {
1284         &$check($opt, 0);
1285     }
1286     foreach my $opt (@$delete) {
1287         &$check($opt, 1);
1288     }
1289
1290     return 1;
1291 }
1292
1293 sub umount_all {
1294     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1295
1296     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1297     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1298
1299     my $res = 1;
1300
1301     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1302         my ($ms, $mountpoint) = @_;
1303
1304         my $volid = $mountpoint->{volume};
1305         my $mount = $mountpoint->{mp};
1306
1307         return if !$volid || !$mount;
1308
1309         my $mount_path = "$rootdir/$mount";
1310         $mount_path =~ s!/+!/!g;
1311
1312         return if !PVE::ProcFSTools::is_mounted($mount_path);
1313
1314         eval {
1315             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1316         };
1317         if (my $err = $@) {
1318             if ($noerr) {
1319                 $res = 0;
1320                 warn $err;
1321             } else {
1322                 die $err;
1323             }
1324         }
1325     });
1326
1327     return $res; # tell caller if (some) umounts failed for the noerr case
1328 }
1329
1330 sub mount_all {
1331     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1332
1333     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1334     File::Path::make_path($rootdir);
1335
1336     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1337     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1338
1339     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1340
1341     eval {
1342         PVE::LXC::Config->foreach_volume($conf, sub {
1343             my ($ms, $mountpoint) = @_;
1344
1345             $mountpoint->{ro} = 0 if $ignore_ro;
1346
1347             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1348         });
1349     };
1350     if (my $err = $@) {
1351         warn "mounting container failed\n";
1352         umount_all($vmid, $storage_cfg, $conf, 1);
1353         die $err;
1354     }
1355
1356     return $rootdir;
1357 }
1358
1359
1360 sub mountpoint_mount_path {
1361     my ($mountpoint, $storage_cfg, $snapname) = @_;
1362
1363     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1364 }
1365
1366 sub query_loopdev {
1367     my ($path) = @_;
1368     my $found;
1369     my $parser = sub {
1370         my $line = shift;
1371         if ($line =~ m@^(/dev/loop\d+):@) {
1372             $found = $1;
1373         }
1374     };
1375     my $cmd = ['losetup', '--associated', $path];
1376     PVE::Tools::run_command($cmd, outfunc => $parser);
1377     return $found;
1378 }
1379
1380 # Run a function with a file attached to a loop device.
1381 # The loop device is always detached afterwards (or set to autoclear).
1382 # Returns the loop device.
1383 sub run_with_loopdev {
1384     my ($func, $file, $readonly) = @_;
1385     my $device = query_loopdev($file);
1386     # Try to reuse an existing device
1387     if ($device) {
1388         # We assume that whoever setup the loop device is responsible for
1389         # detaching it.
1390         &$func($device);
1391         return $device;
1392     }
1393
1394     my $parser = sub {
1395         my $line = shift;
1396         if ($line =~ m@^(/dev/loop\d+)$@) {
1397             $device = $1;
1398         }
1399     };
1400     my $losetup_cmd = [
1401         'losetup',
1402         '--show',
1403         '-f',
1404         $file,
1405     ];
1406     push @$losetup_cmd, '-r' if $readonly;
1407     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1408     die "failed to setup loop device for $file\n" if !$device;
1409     eval { &$func($device); };
1410     my $err = $@;
1411     PVE::Tools::run_command(['losetup', '-d', $device]);
1412     die $err if $err;
1413     return $device;
1414 }
1415
1416 # In scalar mode: returns a file handle to the deepest directory node.
1417 # In list context: returns a list of:
1418 #   * the deepest directory node
1419 #   * the 2nd deepest directory (parent of the above)
1420 #   * directory name of the last directory
1421 # So that the path $2/$3 should lead to $1 afterwards.
1422 sub walk_tree_nofollow($$$;$$) {
1423     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1424
1425     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1426         or die "failed to open start directory $start: $!\n";
1427
1428     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1429 }
1430
1431
1432 sub walk_tree_nofollow_fd($$$$;$$) {
1433     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1434
1435     # splitdir() returns '' for empty components including the leading /
1436     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1437
1438     my $fd = $start_fd;
1439     my $dir = $start_dirname;
1440     my $last_component = undef;
1441     my $second = $fd;
1442     foreach my $component (@comps) {
1443         $dir .= "/$component";
1444         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1445
1446         if (!$next) {
1447             # failed, check for symlinks and try to create the path
1448             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1449             die "cannot open directory $dir: $!\n" if !$mkdir;
1450
1451             # We don't check for errors on mkdirat() here and just try to
1452             # openat() again, since at least one error (EEXIST) is an
1453             # expected possibility if multiple containers start
1454             # simultaneously. If someone else injects a symlink now then
1455             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1456             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1457
1458             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1459             die "failed to create path: $dir: $!\n" if !$next;
1460
1461             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1462                 if defined($rootuid) && defined($rootgid);
1463         }
1464
1465         close $second if defined($last_component) && $second != $start_fd;
1466         $last_component = $component;
1467         $second = $fd;
1468         $fd = $next;
1469     }
1470
1471     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1472     close $second if defined($last_component) && $second != $start_fd;
1473     return $fd;
1474 }
1475
1476 # To guard against symlink attack races against other currently running
1477 # containers with shared recursive bind mount hierarchies we prepare a
1478 # directory handle for the directory we're mounting over to verify the
1479 # mountpoint afterwards.
1480 sub __bindmount_prepare {
1481     my ($hostroot, $dir) = @_;
1482     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1483     return $srcdh;
1484 }
1485
1486 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1487 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1488 # we intended to bind mount.
1489 sub __bindmount_verify {
1490     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1491     my $destdh;
1492     if ($parentfd) {
1493         # Open the mount point path coming from the parent directory since the
1494         # filehandle we would have gotten as first result of walk_tree_nofollow
1495         # earlier is still a handle to the underlying directory instead of the
1496         # mounted path.
1497         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1498         die "failed to open mount point: $!\n" if !$destdh;
1499         if ($ro) {
1500             my $dot = '.';
1501             # no separate function because 99% of the time it's the wrong thing to use.
1502             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1503                 die "failed to mark bind mount read only\n";
1504             }
1505             die "read-only check failed: $!\n" if $! != EROFS;
1506         }
1507     } else {
1508         # For the rootfs we don't have a parentfd so we open the path directly.
1509         # Note that this means bindmounting any prefix of the host's
1510         # /var/lib/lxc/$vmid path into another container is considered a grave
1511         # security error.
1512         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1513         die "failed to open mount point: $!\n" if !$destdh;
1514     }
1515
1516     my ($srcdev, $srcinode) = stat($srcdh);
1517     my ($dstdev, $dstinode) = stat($destdh);
1518     close $srcdh;
1519     close $destdh;
1520
1521     return ($srcdev == $dstdev && $srcinode == $dstinode);
1522 }
1523
1524 # Perform the actual bind mounting:
1525 sub __bindmount_do {
1526     my ($dir, $dest, $ro, @extra_opts) = @_;
1527     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1528     if ($ro) {
1529         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1530         if (my $err = $@) {
1531             warn "bindmount error\n";
1532             # don't leave writable bind-mounts behind...
1533             PVE::Tools::run_command(['umount', $dest]);
1534             die $err;
1535         }
1536     }
1537 }
1538
1539 sub bindmount {
1540     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1541
1542     my $srcdh = __bindmount_prepare('/', $dir);
1543
1544     __bindmount_do($dir, $dest, $ro, @extra_opts);
1545
1546     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1547         PVE::Tools::run_command(['umount', $dest]);
1548         die "detected mount path change at: $dir\n";
1549     }
1550 }
1551
1552 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1553 # from $rootdir and $mount and walk the path from $rootdir to the final
1554 # directory to check for symlinks.
1555 sub __mount_prepare_rootdir {
1556     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1557     $rootdir =~ s!/+!/!g;
1558     $rootdir =~ s!/+$!!;
1559     my $mount_path = "$rootdir/$mount";
1560     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1561     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1562 }
1563
1564 # use $rootdir = undef to just return the corresponding mount path
1565 sub mountpoint_mount {
1566     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1567     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1568 }
1569
1570 sub mountpoint_stage {
1571     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1572     my ($path, $loop, $dev) =
1573         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1574
1575     if (!defined($path)) {
1576         return undef if $! == ENOSYS;
1577         die "failed to mount subvolume: $!\n";
1578     }
1579
1580     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1581     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1582     # point).
1583     my $err;
1584     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1585         or die "open_tree() on mount point failed: $!\n";
1586
1587     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1588 }
1589
1590 sub mountpoint_insert_staged {
1591     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1592
1593     if (!defined($rootdir_fd)) {
1594         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1595             or die "failed to open '.': $!\n";
1596     }
1597
1598     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1599
1600     PVE::Tools::move_mount(
1601         fileno($mount_fd),
1602         '',
1603         fileno($dest_fd),
1604         '',
1605         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1606     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1607 }
1608
1609 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1610 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1611 #   Note that if the kernel does not support the new mount API, this will not perform any action
1612 #   and return `undef` with $! = ENOSYS.
1613 sub __mountpoint_mount {
1614     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1615
1616     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1617         $! = ENOSYS;
1618         return undef;
1619     }
1620
1621     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1622     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1623     # which we use in __bindmount_verify()!
1624     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1625
1626     my $volid = $mountpoint->{volume};
1627     my $type = $mountpoint->{type};
1628     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1629     my $mounted_dev;
1630
1631     return if !$volid || !$mount;
1632
1633     $mount =~ s!/+!/!g;
1634
1635     my $mount_path;
1636     my ($mpfd, $parentfd, $last_dir);
1637
1638     if (defined($rootdir)) {
1639         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1640             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1641     }
1642
1643     if (defined($stage_mount)) {
1644         $mount_path = $rootdir;
1645     }
1646
1647     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1648
1649     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1650
1651     my $optlist = [];
1652
1653     if (my $mountopts = $mountpoint->{mountoptions}) {
1654         my @opts = split(/;/, $mountpoint->{mountoptions});
1655         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1656     }
1657
1658     my $acl = $mountpoint->{acl};
1659     if (defined($acl)) {
1660         push @$optlist, ($acl ? 'acl' : 'noacl');
1661     }
1662
1663     my $optstring = join(',', @$optlist);
1664     my $readonly = $mountpoint->{ro};
1665
1666     my @extra_opts;
1667     @extra_opts = ('-o', $optstring) if $optstring;
1668
1669     if ($storage) {
1670
1671         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1672
1673         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1674
1675         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1676
1677         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1678             PVE::Storage::parse_volname($storage_cfg, $volid);
1679
1680         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1681
1682         if ($format eq 'subvol') {
1683             if ($mount_path) {
1684                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1685                 if (defined($snapname)) {
1686                     $name .= "\@$snapname";
1687                     if ($scfg->{type} eq 'zfspool') {
1688                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1689                     } else {
1690                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1691                     }
1692                 } else {
1693                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1694                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1695                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1696                     }
1697                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1698                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1699                 }
1700             }
1701             return wantarray ? ($path, 0, undef) : $path;
1702         } elsif ($format eq 'raw' || $format eq 'iso') {
1703             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1704             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1705             # Our autodev hook expects the /dev/dm-* device currently
1706             # and will create the /dev/mapper symlink accordingly
1707             $path = Cwd::realpath($path);
1708             die "failed to get device path\n" if !$path;
1709             ($path) = ($path =~ /^(.*)$/s); #untaint
1710             my $domount = sub {
1711                 my ($path) = @_;
1712                 if ($mount_path) {
1713                     if ($format eq 'iso') {
1714                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1715                     } elsif ($isBase || defined($snapname)) {
1716                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1717                     } else {
1718                         if ($quota) {
1719                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1720                         }
1721                         push @extra_opts, '-o', 'ro' if $readonly;
1722                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1723                     }
1724                 }
1725             };
1726             my $use_loopdev = 0;
1727             if ($scfg->{content}->{rootdir}) {
1728                 if ($scfg->{path}) {
1729                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1730                     $use_loopdev = 1;
1731                 } else {
1732                     $mounted_dev = $path;
1733                     &$domount($path);
1734                 }
1735             } else {
1736                 die "storage '$storage' does not support containers\n";
1737             }
1738             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1739         } else {
1740             die "unsupported image format '$format'\n";
1741         }
1742     } elsif ($type eq 'device') {
1743         push @extra_opts, '-o', 'ro' if $readonly;
1744         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1745         # See the NOTE above about devicemapper canonicalization
1746         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1747         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1748         return wantarray ? ($volid, 0, $devpath) : $volid;
1749     } elsif ($type eq 'bind') {
1750         die "directory '$volid' does not exist\n" if ! -d $volid;
1751         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1752         warn "cannot enable quota control for bind mounts\n" if $quota;
1753         return wantarray ? ($volid, 0, undef) : $volid;
1754     }
1755
1756     die "unsupported storage";
1757 }
1758
1759 sub mountpoint_hotplug($$$) {
1760     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1761
1762     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1763
1764     # We do the rest in a fork with an unshared mount namespace, because:
1765     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1766     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1767     #     container's namespace, then mount it.
1768
1769     PVE::Tools::run_fork(sub {
1770         # Pin the container pid longer, we also need to get its monitor/parent:
1771         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1772             or die "failed to open pidfd of container $vmid\'s init process\n";
1773
1774         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1775             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1776
1777         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1778         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1779
1780         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1781         # profile to lower our privileges to the same level we have in the start hook:
1782         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1783             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1784         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1785         # apparmor.
1786
1787         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1788         # namespace for it to remain active there since the container will be able to unmount
1789         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1790         # concern.
1791         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1792         chdir('/')
1793             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1794
1795         my $dir = get_staging_mount_path($opt);
1796
1797         # Now switch our apparmor profile before mounting:
1798         my $data = 'changeprofile /usr/bin/lxc-start';
1799         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1800             die "failed to change apparmor profile: $!\n";
1801         }
1802         # Check errors on close as well:
1803         close($aa_fd)
1804             or die "failed to change apparmor profile (close() failed): $!\n";
1805
1806         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1807
1808         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1809         chdir('/')
1810             or die "failed to change root directory within the container's mount namespace: $!\n";
1811
1812         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1813     });
1814 }
1815
1816 # Create a directory in the mountpoint staging tempfs.
1817 sub get_staging_mount_path($) {
1818     my ($opt) = @_;
1819
1820     my $target = get_staging_tempfs() . "/$opt";
1821     if (!mkdir($target) && $! != EEXIST) {
1822         die "failed to create directory $target: $!\n";
1823     }
1824
1825     return $target;
1826 }
1827
1828 # Mount /run/pve/mountpoints as tmpfs
1829 sub get_staging_tempfs() {
1830     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1831     # mounts to that.
1832     my $target = '/var/lib/lxc/.pve-staged-mounts';
1833     if (!mkdir($target)) {
1834         return $target if $! == EEXIST;
1835         die "failed to create directory $target: $!\n";
1836     }
1837
1838     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1839         or die "failed to mount $target as tmpfs: $!\n";
1840
1841     return $target;
1842 }
1843
1844 sub mkfs {
1845     my ($dev, $rootuid, $rootgid) = @_;
1846
1847     run_command(
1848         [
1849             'mkfs.ext4',
1850             '-O',
1851             'mmp',
1852             '-E',
1853             "root_owner=$rootuid:$rootgid",
1854             $dev,
1855         ],
1856         outfunc => sub {
1857             my $line = shift;
1858             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1859             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1860                 print "$line\n";
1861             }
1862         },
1863         errfunc => sub {
1864             my $line = shift;
1865             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1866         }
1867     );
1868 }
1869
1870 sub format_disk {
1871     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1872
1873     if ($volid =~ m!^/dev/.+!) {
1874         mkfs($volid);
1875         return;
1876     }
1877
1878     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1879
1880     die "cannot format volume '$volid' with no storage\n" if !$storage;
1881
1882     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1883
1884     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1885
1886     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1887
1888     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1889         PVE::Storage::parse_volname($storage_cfg, $volid);
1890
1891     die "cannot format volume '$volid' (format == $format)\n"
1892         if $format ne 'raw';
1893
1894     mkfs($path, $rootuid, $rootgid);
1895 }
1896
1897 sub destroy_disks {
1898     my ($storecfg, $vollist) = @_;
1899
1900     foreach my $volid (@$vollist) {
1901         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1902         warn $@ if $@;
1903     }
1904 }
1905
1906 sub alloc_disk {
1907     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1908
1909     my $needs_chown = 0;
1910     my $volid;
1911
1912     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1913     # fixme: use better naming ct-$vmid-disk-X.raw?
1914
1915     eval {
1916         my $do_format = 0;
1917         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
1918             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
1919                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1920                 $do_format = 1;
1921             } else {
1922                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1923                 $needs_chown = 1;
1924             }
1925         } elsif ($scfg->{type} eq 'zfspool') {
1926             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
1927             $needs_chown = 1;
1928         } elsif ($scfg->{content}->{rootdir}) {
1929             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1930             $do_format = 1;
1931         } else {
1932             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
1933         }
1934         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1935     };
1936     if (my $err = $@) {
1937         # in case formatting got interrupted:
1938         if (defined($volid)) {
1939             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1940             warn $@ if $@;
1941         }
1942         die $err;
1943     }
1944
1945     return ($volid, $needs_chown);
1946 }
1947
1948 sub create_disks {
1949     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1950
1951     my $vollist = [];
1952
1953     eval {
1954         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1955         my $chown_vollist = [];
1956
1957         PVE::LXC::Config->foreach_volume($settings, sub {
1958             my ($ms, $mountpoint) = @_;
1959
1960             my $volid = $mountpoint->{volume};
1961             my $mp = $mountpoint->{mp};
1962
1963             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1964
1965             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1966                 my ($storeid, $size_gb) = ($1, $2);
1967
1968                 my $size_kb = int(${size_gb}*1024) * 1024;
1969
1970                 my $needs_chown = 0;
1971                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1972                 push @$chown_vollist, $volid if $needs_chown;
1973                 push @$vollist, $volid;
1974                 $mountpoint->{volume} = $volid;
1975                 $mountpoint->{size} = $size_kb * 1024;
1976                 if ($pending) {
1977                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1978                 } else {
1979                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1980                 }
1981             } else {
1982                 # use specified/existing volid/dir/device
1983                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1984             }
1985         });
1986
1987         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1988         foreach my $volid (@$chown_vollist) {
1989             my $path = PVE::Storage::path($storecfg, $volid, undef);
1990             chown($rootuid, $rootgid, $path);
1991         }
1992         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1993     };
1994     # free allocated images on error
1995     if (my $err = $@) {
1996         destroy_disks($storecfg, $vollist);
1997         die $err;
1998     }
1999     return $vollist;
2000 }
2001
2002 sub update_disksize {
2003     my ($vmid, $conf, $all_volumes) = @_;
2004
2005     my $changes;
2006     my $prefix = "CT $vmid:";
2007
2008     my $update_mp = sub {
2009         my ($key, $mp, @param) = @_;
2010         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2011
2012         if (!defined($mp->{size}) || $size != $mp->{size}) {
2013             $changes = 1;
2014             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2015             $mp->{size} = $size;
2016             my $nomp = 1 if ($key eq 'rootfs');
2017             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
2018         }
2019     };
2020
2021     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2022
2023     return $changes;
2024 }
2025
2026 sub update_unused {
2027     my ($vmid, $conf, $all_volumes) = @_;
2028
2029     my $changes;
2030     my $prefix = "CT $vmid:";
2031
2032     # Note: it is allowed to define multiple storage entries with the same path
2033     # (alias), so we need to check both 'volid' and real 'path' (two different
2034     # volid can point to the same path).
2035
2036     # used and unused disks
2037     my $refpath = {};
2038     my $orphans = {};
2039
2040     foreach my $opt (keys %$conf) {
2041         next if ($opt !~ m/^unused\d+$/);
2042         my $vol = $all_volumes->{$conf->{$opt}};
2043         $refpath->{$vol->{path}} = $vol->{volid};
2044     }
2045
2046     foreach my $key (keys %$all_volumes) {
2047         my $vol = $all_volumes->{$key};
2048         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2049         my $path = $vol->{path};
2050
2051         if ($in_use) {
2052             $refpath->{$path} = $key;
2053             delete $orphans->{$path};
2054         } else {
2055             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2056                 $orphans->{$path} = $key;
2057             }
2058         }
2059     }
2060
2061     for my $key (keys %$orphans) {
2062         my $disk = $orphans->{$key};
2063         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2064
2065         if ($unused) {
2066             $changes = 1;
2067             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2068         }
2069     }
2070
2071     return $changes;
2072 }
2073
2074 sub scan_volids {
2075     my ($cfg, $vmid) = @_;
2076
2077     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2078
2079     my $all_volumes = {};
2080     foreach my $storeid (keys %$info) {
2081         foreach my $item (@{$info->{$storeid}}) {
2082             my $volid = $item->{volid};
2083             next if !($volid && $item->{size});
2084             $item->{path} = PVE::Storage::path($cfg, $volid);
2085             $all_volumes->{$volid} = $item;
2086         }
2087     }
2088
2089     return $all_volumes;
2090 }
2091
2092 sub rescan {
2093     my ($vmid, $nolock, $dryrun) = @_;
2094
2095     my $cfg = PVE::Storage::config();
2096
2097     print "rescan volumes...\n";
2098     my $all_volumes = scan_volids($cfg, $vmid);
2099
2100     my $updatefn =  sub {
2101         my ($vmid) = @_;
2102
2103         my $changes;
2104         my $conf = PVE::LXC::Config->load_config($vmid);
2105
2106         PVE::LXC::Config->check_lock($conf);
2107
2108         my $vm_volids = {};
2109         foreach my $volid (keys %$all_volumes) {
2110             my $info = $all_volumes->{$volid};
2111             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2112         }
2113
2114         my $upu = update_unused($vmid, $conf, $vm_volids);
2115         my $upd = update_disksize($vmid, $conf, $vm_volids);
2116         $changes = $upu || $upd;
2117
2118         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2119     };
2120
2121     if (defined($vmid)) {
2122         if ($nolock) {
2123             &$updatefn($vmid);
2124         } else {
2125             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2126         }
2127     } else {
2128         my $vmlist = config_list();
2129         foreach my $vmid (keys %$vmlist) {
2130             if ($nolock) {
2131                 &$updatefn($vmid);
2132             } else {
2133                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2134             }
2135         }
2136     }
2137 }
2138
2139
2140 # bash completion helper
2141
2142 sub complete_os_templates {
2143     my ($cmdname, $pname, $cvalue) = @_;
2144
2145     my $cfg = PVE::Storage::config();
2146
2147     my $storeid;
2148
2149     if ($cvalue =~ m/^([^:]+):/) {
2150         $storeid = $1;
2151     }
2152
2153     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2154     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2155
2156     my $res = [];
2157     foreach my $id (keys %$data) {
2158         foreach my $item (@{$data->{$id}}) {
2159             push @$res, $item->{volid} if defined($item->{volid});
2160         }
2161     }
2162
2163     return $res;
2164 }
2165
2166 my $complete_ctid_full = sub {
2167     my ($running) = @_;
2168
2169     my $idlist = vmstatus();
2170
2171     my $active_hash = list_active_containers();
2172
2173     my $res = [];
2174
2175     foreach my $id (keys %$idlist) {
2176         my $d = $idlist->{$id};
2177         if (defined($running)) {
2178             next if $d->{template};
2179             next if $running && !$active_hash->{$id};
2180             next if !$running && $active_hash->{$id};
2181         }
2182         push @$res, $id;
2183
2184     }
2185     return $res;
2186 };
2187
2188 sub complete_ctid {
2189     return &$complete_ctid_full();
2190 }
2191
2192 sub complete_ctid_stopped {
2193     return &$complete_ctid_full(0);
2194 }
2195
2196 sub complete_ctid_running {
2197     return &$complete_ctid_full(1);
2198 }
2199
2200 sub parse_id_maps {
2201     my ($conf) = @_;
2202
2203     my $id_map = [];
2204     my $rootuid = 0;
2205     my $rootgid = 0;
2206
2207     my $lxc = $conf->{lxc};
2208     foreach my $entry (@$lxc) {
2209         my ($key, $value) = @$entry;
2210         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2211         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2212         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2213             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2214             push @$id_map, [$type, $ct, $host, $length];
2215             if ($ct == 0) {
2216                 $rootuid = $host if $type eq 'u';
2217                 $rootgid = $host if $type eq 'g';
2218             }
2219         } else {
2220             die "failed to parse idmap: $value\n";
2221         }
2222     }
2223
2224     if (!@$id_map && $conf->{unprivileged}) {
2225         # Should we read them from /etc/subuid?
2226         $id_map = [ ['u', '0', '100000', '65536'],
2227                     ['g', '0', '100000', '65536'] ];
2228         $rootuid = $rootgid = 100000;
2229     }
2230
2231     return ($id_map, $rootuid, $rootgid);
2232 }
2233
2234 sub userns_command {
2235     my ($id_map) = @_;
2236     if (@$id_map) {
2237         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2238     }
2239     return [];
2240 }
2241
2242 my sub print_ct_stderr_log {
2243     my ($vmid) = @_;
2244     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2245     return if !$log;
2246
2247     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2248         my $line = $2;
2249         print STDERR "$line\n";
2250     }
2251 }
2252 my sub print_ct_warn_log {
2253     my ($vmid) = @_;
2254     my $log_fn = "/run/pve/ct-$vmid.warnings";
2255     my $log = eval { file_get_contents($log_fn) };
2256     return if !$log;
2257
2258     my $rpcenv = eval { PVE::RPCEnvironment::get() };
2259
2260     my $warn_fn = $rpcenv ? sub { $rpcenv->warn($_[0]) } : sub { print STDERR "WARN: $_[0]\n" };
2261
2262     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2263         my $line = $1;
2264         $warn_fn->($line);
2265     }
2266     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2267 }
2268
2269 my sub monitor_state_change($$) {
2270     my ($monitor_socket, $vmid) = @_;
2271     die "no monitor socket\n" if !defined($monitor_socket);
2272
2273     while (1) {
2274         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2275
2276         die "monitor socket: got EOF\n" if !defined($type);
2277
2278         next if $name ne "$vmid" || $type ne 'STATE';
2279
2280         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2281             alarm(0); # don't timeout after seeing the starting state
2282         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2283                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2284                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2285             return 0;
2286         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2287             return 1;
2288         } else {
2289             warn "unexpected message from monitor socket - " .
2290                  "type: '$type' - value: '$value'\n";
2291         }
2292     }
2293 }
2294 my sub monitor_start($$) {
2295     my ($monitor_socket, $vmid) = @_;
2296
2297     my $success = eval {
2298         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2299     };
2300     if (my $err = $@) {
2301         warn "problem with monitor socket, but continuing anyway: $err\n";
2302     } elsif (!$success) {
2303         print_ct_stderr_log($vmid);
2304         die "startup for container '$vmid' failed\n";
2305     }
2306 }
2307
2308 sub vm_start {
2309     my ($vmid, $conf, $skiplock, $debug) = @_;
2310
2311     # apply pending changes while starting
2312     if (scalar(keys %{$conf->{pending}})) {
2313         my $storecfg = PVE::Storage::config();
2314         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2315         PVE::LXC::Config->write_config($vmid, $conf);
2316         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2317     }
2318
2319     update_lxc_config($vmid, $conf);
2320
2321     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2322
2323     if ($skiplock) {
2324         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2325         close($fh);
2326     }
2327
2328     my $storage_cfg = PVE::Storage::config();
2329     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2330
2331     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2332
2333     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2334     warn $@ if $@;
2335
2336     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2337
2338     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2339     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2340
2341     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2342
2343     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2344     eval {
2345         run_command($cmd);
2346
2347         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2348
2349         # if debug is requested, print the log it also when the start succeeded
2350         print_ct_stderr_log($vmid) if $is_debug;
2351
2352         print_ct_warn_log($vmid); # always print warn log, if any
2353     };
2354     if (my $err = $@) {
2355         unlink $skiplock_flag_fn;
2356         die $err;
2357     }
2358     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2359
2360     return;
2361 }
2362
2363 # Helper to stop a container completely and make sure it has stopped completely.
2364 # This is necessary because we want the post-stop hook to have completed its
2365 # unmount-all step, but post-stop happens after lxc puts the container into the
2366 # STOPPED state.
2367 # $kill - if true it will always do an immediate hard-stop
2368 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2369 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2370 sub vm_stop {
2371     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2372
2373     # Open the container's command socket.
2374     my $path = "\0/var/lib/lxc/$vmid/command";
2375     my $sock = IO::Socket::UNIX->new(
2376         Type => SOCK_STREAM(),
2377         Peer => $path,
2378     );
2379     if (!$sock) {
2380         return if $! == ECONNREFUSED; # The container is not running
2381         die "failed to open container ${vmid}'s command socket: $!\n";
2382     }
2383
2384     my $conf = PVE::LXC::Config->load_config($vmid);
2385     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2386
2387     # Stop the container:
2388
2389     my $cmd = ['lxc-stop', '-n', $vmid];
2390
2391     if ($kill) {
2392         push @$cmd, '--kill'; # doesn't allow timeouts
2393     } else {
2394         # lxc-stop uses a default timeout
2395         push @$cmd, '--nokill' if !$kill_after_timeout;
2396
2397         if (defined($shutdown_timeout)) {
2398             push @$cmd, '--timeout', $shutdown_timeout;
2399             # Give run_command 5 extra seconds
2400             $shutdown_timeout += 5;
2401         }
2402     }
2403
2404     eval { run_command($cmd, timeout => $shutdown_timeout) };
2405     if (my $err = $@) {
2406         warn $@ if $@;
2407     }
2408
2409     my $result = <$sock>;
2410
2411     return if !defined $result; # monitor is gone and the ct has stopped.
2412     die "container did not stop\n";
2413 }
2414
2415 sub vm_reboot {
2416     my ($vmid, $timeout, $skiplock) = @_;
2417
2418     PVE::LXC::Config->lock_config($vmid, sub {
2419         return if !check_running($vmid);
2420
2421         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2422
2423         my $conf = PVE::LXC::Config->load_config($vmid);
2424         vm_start($vmid, $conf);
2425     });
2426 }
2427
2428 sub run_unshared {
2429     my ($code) = @_;
2430
2431     return PVE::Tools::run_fork(sub {
2432         # Unshare the mount namespace
2433         die "failed to unshare mount namespace: $!\n"
2434             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2435         run_command(['mount', '--make-rslave', '/']);
2436         return $code->();
2437     });
2438 }
2439
2440 my $copy_volume = sub {
2441     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2442
2443     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2444     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2445
2446     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2447     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2448
2449     my @mounted;
2450     eval {
2451         # mount and copy
2452         mkdir $src;
2453         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2454         push @mounted, $src;
2455         mkdir $dest;
2456         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2457         push @mounted, $dest;
2458
2459         $bwlimit //= 0;
2460
2461         run_command([
2462             'rsync',
2463             '--stats',
2464             '-X',
2465             '-A',
2466             '--numeric-ids',
2467             '-aH',
2468             '--whole-file',
2469             '--sparse',
2470             '--one-file-system',
2471             "--bwlimit=$bwlimit",
2472             "$src/",
2473             $dest
2474         ]);
2475     };
2476     my $err = $@;
2477
2478     # Wait for rsync's children to release dest so that
2479     # consequent file operations (umount, remove) are possible
2480     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2481
2482     foreach my $mount (reverse @mounted) {
2483         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2484         warn "Can't umount $mount\n" if $@;
2485     }
2486
2487     # If this fails they're used as mount points in a concurrent operation
2488     # (which should not happen but there's also no real need to get rid of them).
2489     rmdir $dest;
2490     rmdir $src;
2491
2492     die $err if $err;
2493 };
2494
2495 # Should not be called after unsharing the mount namespace!
2496 sub copy_volume {
2497     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2498
2499     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2500     File::Path::make_path("/var/lib/lxc/$vmid");
2501     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2502     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2503
2504     # get id's for unprivileged container
2505     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2506
2507     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2508     # are visible in this namespace, otherwise the host only sees the empty
2509     # (not-mounted) directory.
2510     my $new_volid;
2511     eval {
2512         # Make sure $mp contains a correct size.
2513         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2514         my $needs_chown;
2515         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2516         if ($needs_chown) {
2517             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2518             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2519             chown($rootuid, $rootgid, $path);
2520         }
2521
2522         run_unshared(sub {
2523             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2524         });
2525     };
2526     if (my $err = $@) {
2527         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2528             if defined($new_volid);
2529         die $err;
2530     }
2531
2532     return $new_volid;
2533 }
2534
2535 sub get_lxc_version() {
2536     my $version;
2537     run_command([qw(lxc-start --version)], outfunc => sub {
2538         my ($line) = @_;
2539         # We only parse out major & minor version numbers.
2540         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2541             $version = [$1, $2];
2542         }
2543     });
2544
2545     die "failed to get lxc version\n" if !defined($version);
2546
2547     # return as a list:
2548     return $version->@*;
2549 }
2550
2551 sub freeze($) {
2552     my ($vmid) = @_;
2553     if (PVE::CGroup::cgroup_mode() == 2) {
2554         PVE::LXC::Command::freeze($vmid, 30);
2555     } else {
2556         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2557     }
2558 }
2559
2560 sub thaw($) {
2561     my ($vmid) = @_;
2562     if (PVE::CGroup::cgroup_mode() == 2) {
2563         PVE::LXC::Command::unfreeze($vmid, 30);
2564     } else {
2565         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2566     }
2567 }
2568
2569 1;