src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     run_command
  24     dir_glob_foreach
  25     file_get_contents
  26     file_set_contents
  27     AT_FDCWD
  28     O_PATH
  29     $IPV4RE
  30     $IPV6RE
  31 );
  32 use PVE::RPCEnvironment;
  33 use PVE::CpuSet;
  34 use PVE::Network;
  35 use PVE::AccessControl;
  36 use PVE::ProcFSTools;
  37 use PVE::Syscall qw(:fsmount);
  38 use PVE::LXC::Config;
  39 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  40 use PVE::LXC::Tools;
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Monitor;
  43 use PVE::CGroup;
  44
  45 use Time::HiRes qw (gettimeofday);
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         my $lxcmem = int($memory*1024*1024);
 689         $raw .= "lxc.cgroup2.memory.max = $lxcmem\n";
 690
 691         my $lxcswap = int($swap*1024*1024);
 692         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 693     }
 694
 695     if ($cgv1->{cpu}) {
 696         if (my $cpulimit = $conf->{cpulimit}) {
 697             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 698             my $value = int(100000*$cpulimit);
 699             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 700         }
 701
 702         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 703         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 704     } elsif ($cgv2->{cpu}) {
 705         # See PVE::CGroup
 706         if (my $cpulimit = $conf->{cpulimit}) {
 707             my $value = int(100000*$cpulimit);
 708             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 709         }
 710
 711         if (defined(my $shares = $conf->{cpuunits})) {
 712             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 713             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 714         }
 715     }
 716
 717     die "missing 'rootfs' configuration\n"
 718         if !defined($conf->{rootfs});
 719
 720     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 721
 722     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 723
 724     foreach my $k (sort keys %$conf) {
 725         next if $k !~ m/^net(\d+)$/;
 726         my $ind = $1;
 727         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 728         $raw .= "lxc.net.$ind.type = veth\n";
 729         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 730         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 731         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 732
 733         # Keep container from starting with invalid mtu configuration
 734         if (my $mtu = $d->{mtu}) {
 735             my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 736             die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 737                 if ($mtu > $bridge_mtu);
 738
 739             $raw .= "lxc.net.$ind.mtu = $mtu\n";
 740         }
 741
 742         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 743         if ($lxc_major >= 4) {
 744             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 745         }
 746     }
 747
 748     my $had_cpuset = 0;
 749     if (my $lxcconf = $conf->{lxc}) {
 750         foreach my $entry (@$lxcconf) {
 751             my ($k, $v) = @$entry;
 752             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 753             $raw .= "$k = $v\n";
 754         }
 755     }
 756
 757     my $cpuset;
 758     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 759     if (defined($cpuset_cgroup)) {
 760         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 761             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 762     }
 763     my $cores = $conf->{cores};
 764     if (!$had_cpuset && $cores && $cpuset) {
 765         my @members = $cpuset->members();
 766         while (scalar(@members) > $cores) {
 767             my $randidx = int(rand(scalar(@members)));
 768             $cpuset->delete($members[$randidx]);
 769             splice(@members, $randidx, 1); # keep track of the changes
 770         }
 771         my $ver = $cpuset_version == 1 ? '' : '2';
 772         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 773     }
 774
 775     File::Path::mkpath("$dir/rootfs");
 776
 777     PVE::Tools::file_set_contents("$dir/config", $raw);
 778 }
 779
 780 # verify and cleanup nameserver list (replace \0 with ' ')
 781 sub verify_nameserver_list {
 782     my ($nameserver_list) = @_;
 783
 784     my @list = ();
 785     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 786         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 787         push @list, $server;
 788     }
 789
 790     return join(' ', @list);
 791 }
 792
 793 sub verify_searchdomain_list {
 794     my ($searchdomain_list) = @_;
 795
 796     my @list = ();
 797     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 798         # todo: should we add checks for valid dns domains?
 799         push @list, $server;
 800     }
 801
 802     return join(' ', @list);
 803 }
 804
 805 sub get_console_command {
 806     my ($vmid, $conf, $escapechar) = @_;
 807
 808     # '-1' as $escapechar disables keyboard escape sequence
 809     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 810
 811     my $cmode = PVE::LXC::Config->get_cmode($conf);
 812
 813     my $cmd = [];
 814     if ($cmode eq 'console') {
 815         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 816         push @$cmd, '-e', $escapechar if $escapechar;
 817     } elsif ($cmode eq 'tty') {
 818         push @$cmd, 'lxc-console', '-n',  $vmid;
 819         push @$cmd, '-e', $escapechar if $escapechar;
 820     } elsif ($cmode eq 'shell') {
 821         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 822     } else {
 823         die "internal error";
 824     }
 825
 826     return $cmd;
 827 }
 828
 829 sub get_primary_ips {
 830     my ($conf) = @_;
 831
 832     # return data from net0
 833
 834     return undef if !defined($conf->{net0});
 835     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 836
 837     my $ipv4 = $net->{ip};
 838     if ($ipv4) {
 839         if ($ipv4 =~ /^(dhcp|manual)$/) {
 840             $ipv4 = undef
 841         } else {
 842             $ipv4 =~ s!/\d+$!!;
 843         }
 844     }
 845     my $ipv6 = $net->{ip6};
 846     if ($ipv6) {
 847         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 848             $ipv6 = undef;
 849         } else {
 850             $ipv6 =~ s!/\d+$!!;
 851         }
 852     }
 853
 854     return ($ipv4, $ipv6);
 855 }
 856
 857 sub delete_mountpoint_volume {
 858     my ($storage_cfg, $vmid, $volume) = @_;
 859
 860     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 861
 862     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 863
 864     if ($vmid == $owner) {
 865         PVE::Storage::vdisk_free($storage_cfg, $volume);
 866     } else {
 867         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 868     }
 869 }
 870
 871 sub destroy_lxc_container {
 872     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 873
 874     my $volids = {};
 875     my $remove_volume = sub {
 876         my ($ms, $mountpoint) = @_;
 877
 878         my $volume = $mountpoint->{volume};
 879
 880         return if $volids->{$volume};
 881         $volids->{$volume} = 1;
 882
 883         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 884     };
 885     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 886
 887     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 888
 889     if ($purge_unreferenced) { # also remove unreferenced disk
 890         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 891         PVE::Storage::foreach_volid($vmdisks, sub {
 892             my ($volid, $sid, $volname, $d) = @_;
 893             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 894             warn $@ if $@;
 895         });
 896     }
 897
 898     rmdir "/var/lib/lxc/$vmid/rootfs";
 899     unlink "/var/lib/lxc/$vmid/config";
 900     rmdir "/var/lib/lxc/$vmid";
 901     if (defined $replacement_conf) {
 902         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 903     } else {
 904         PVE::LXC::Config->destroy_config($vmid);
 905     }
 906 }
 907
 908 sub vm_stop_cleanup {
 909     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 910
 911     return if $keepActive;
 912
 913     eval {
 914         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 915         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 916     };
 917     warn $@ if $@; # avoid errors - just warn
 918 }
 919
 920 sub update_net {
 921     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 922
 923     if ($newnet->{type} ne 'veth') {
 924         # for when there are physical interfaces
 925         die "cannot update interface of type $newnet->{type}";
 926     }
 927
 928     my $veth = "veth${vmid}i${netid}";
 929     my $eth = $newnet->{name};
 930
 931     if (my $oldnetcfg = $conf->{$opt}) {
 932         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 933
 934         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 935             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 936
 937             PVE::Network::veth_delete($veth);
 938             delete $conf->{$opt};
 939             PVE::LXC::Config->write_config($vmid, $conf);
 940
 941             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 942
 943         } else {
 944             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 945                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 946                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})
 947             ) {
 948
 949                 if ($oldnet->{bridge}) {
 950                     PVE::Network::tap_unplug($veth);
 951                     foreach (qw(bridge tag firewall)) {
 952                         delete $oldnet->{$_};
 953                     }
 954                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 955                     PVE::LXC::Config->write_config($vmid, $conf);
 956                 }
 957
 958                 my ($bridge, $mac, $firewall, $rate) = $newnet->@{'bridge', 'hwaddr', 'firewall', 'rate'};
 959                 if ($have_sdn) {
 960                     PVE::Network::SDN::Zones::tap_plug(
 961                         $veth, $bridge, $newnet->{tag}, $firewall, $newnet->{trunks}, $rate);
 962                     PVE::Network::SDN::Zones::add_bridge_fdb($veth, $mac, $bridge, $firewall);
 963                 } else {
 964                     PVE::Network::tap_plug(
 965                         $veth, $bridge, $newnet->{tag}, $firewall, $newnet->{trunks}, $rate);
 966                     PVE::Network::add_bridge_fdb($veth, $mac, $firewall); # early returns if brport has learning on
 967                 }
 968
 969                 # This includes the rate:
 970                 foreach (qw(bridge tag firewall rate)) {
 971                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 972                 }
 973             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 974                 # Rate can be applied on its own but any change above needs to
 975                 # include the rate in tap_plug since OVS resets everything.
 976                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 977                 $oldnet->{rate} = $newnet->{rate}
 978             }
 979             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 980             PVE::LXC::Config->write_config($vmid, $conf);
 981         }
 982     } else {
 983         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 984     }
 985
 986     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 987 }
 988
 989 sub hotplug_net {
 990     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 991
 992     my $veth = "veth${vmid}i${netid}";
 993     my $vethpeer = $veth . "p";
 994     my $eth = $newnet->{name};
 995
 996     if ($have_sdn) {
 997         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 998         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 999         PVE::Network::SDN::Zones::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{bridge}, $newnet->{firewall});
1000     } else {
1001         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1002         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
1003         PVE::Network::add_bridge_fdb($veth, $newnet->{hwaddr}, $newnet->{firewall}); # early returns if brport has learning on
1004     }
1005
1006     # attach peer in container
1007     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1008     PVE::Tools::run_command($cmd);
1009
1010     # link up peer in container
1011     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1012     PVE::Tools::run_command($cmd);
1013
1014     my $done = { type => 'veth' };
1015     foreach (qw(bridge tag firewall hwaddr name)) {
1016         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1017     }
1018     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1019
1020     PVE::LXC::Config->write_config($vmid, $conf);
1021 }
1022
1023 sub update_ipconfig {
1024     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1025
1026     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1027
1028     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1029     my $deleted = [];
1030     my $added = [];
1031     my $nscmd = sub {
1032         my $cmdargs = shift;
1033         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1034     };
1035     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1036
1037     my $change_ip_config = sub {
1038         my ($ipversion) = @_;
1039
1040         my $family_opt = "-$ipversion";
1041         my $suffix = $ipversion == 4 ? '' : $ipversion;
1042         my $gw= "gw$suffix";
1043         my $ip= "ip$suffix";
1044
1045         my $newip = $newnet->{$ip};
1046         my $newgw = $newnet->{$gw};
1047         my $oldip = $optdata->{$ip};
1048         my $oldgw = $optdata->{$gw};
1049
1050         my $change_ip = safe_string_ne($oldip, $newip);
1051         my $change_gw = safe_string_ne($oldgw, $newgw);
1052
1053         return if !$change_ip && !$change_gw;
1054
1055         # step 1: add new IP, if this fails we cancel
1056         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1057         if ($change_ip && $is_real_ip) {
1058             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1059             if (my $err = $@) {
1060                 warn $err;
1061                 return;
1062             }
1063         }
1064
1065         # step 2: replace gateway
1066         #   If this fails we delete the added IP and cancel.
1067         #   If it succeeds we save the config and delete the old IP, ignoring
1068         #   errors. The config is then saved.
1069         # Note: 'ip route replace' can add
1070         if ($change_gw) {
1071             if ($newgw) {
1072                 eval {
1073                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1074                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1075                     }
1076                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1077                 };
1078                 if (my $err = $@) {
1079                     warn $err;
1080                     # the route was not replaced, the old IP is still available
1081                     # rollback (delete new IP) and cancel
1082                     if ($change_ip) {
1083                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1084                         warn $@ if $@; # no need to die here
1085                     }
1086                     return;
1087                 }
1088             } else {
1089                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1090                 # if the route was not deleted, the guest might have deleted it manually
1091                 # warn and continue
1092                 warn $@ if $@;
1093             }
1094             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1095                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1096                 # warn if the route was deleted manually
1097                 warn $@ if $@;
1098             }
1099         }
1100
1101         # from this point on we save the configuration
1102         # step 3: delete old IP ignoring errors
1103         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1104             # We need to enable promote_secondaries, otherwise our newly added
1105             # address will be removed along with the old one.
1106             my $promote = 0;
1107             eval {
1108                 if ($ipversion == 4) {
1109                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1110                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1111                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1112                 }
1113                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1114             };
1115             warn $@ if $@; # no need to die here
1116
1117             if ($ipversion == 4) {
1118                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1119             }
1120         }
1121
1122         foreach my $property ($ip, $gw) {
1123             if ($newnet->{$property}) {
1124                 $optdata->{$property} = $newnet->{$property};
1125             } else {
1126                 delete $optdata->{$property};
1127             }
1128         }
1129         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1130         PVE::LXC::Config->write_config($vmid, $conf);
1131         $lxc_setup->setup_network($conf);
1132     };
1133
1134     &$change_ip_config(4);
1135     &$change_ip_config(6);
1136
1137 }
1138
1139 my $open_namespace = sub {
1140     my ($vmid, $pid, $kind) = @_;
1141     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1142         or die "failed to open $kind namespace of container $vmid: $!\n";
1143     return $fd;
1144 };
1145
1146 my $enter_namespace = sub {
1147     my ($vmid, $pid, $kind, $type) = @_;
1148     my $fd = $open_namespace->($vmid, $pid, $kind);
1149     PVE::Tools::setns(fileno($fd), $type)
1150         or die "failed to enter $kind namespace of container $vmid: $!\n";
1151     close $fd;
1152 };
1153
1154 my $get_container_namespace = sub {
1155     my ($vmid, $pid, $kind) = @_;
1156
1157     my $pidfd;
1158     if (!defined($pid)) {
1159         # Pin the pid while we're grabbing its stuff from /proc
1160         ($pid, $pidfd) = open_lxc_pid($vmid)
1161             or die "failed to open pidfd of container $vmid\'s init process\n";
1162     }
1163
1164     return $open_namespace->($vmid, $pid, $kind);
1165 };
1166
1167 my $do_syncfs = sub {
1168     my ($vmid, $pid, $socket) = @_;
1169
1170     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1171
1172     # Tell the parent process to start reading our /proc/mounts
1173     print {$socket} "go\n";
1174     $socket->flush();
1175
1176     # Receive /proc/self/mounts
1177     my $mountdata = do { local $/ = undef; <$socket> };
1178     close $socket;
1179
1180     my %nosyncfs = (
1181         cgroup => 1,
1182         cgroup2 => 1,
1183         devtmpfs => 1,
1184         devpts => 1,
1185         'fuse.lxcfs' => 1,
1186         fusectl => 1,
1187         mqueue => 1,
1188         proc => 1,
1189         sysfs => 1,
1190         tmpfs => 1,
1191     );
1192
1193     # Now sync all mountpoints...
1194     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1195     foreach my $mp (@$mounts) {
1196         my ($what, $dir, $fs) = @$mp;
1197         next if $nosyncfs{$fs};
1198         eval { PVE::Tools::sync_mountpoint($dir); };
1199         warn $@ if $@;
1200     }
1201 };
1202
1203 sub sync_container_namespace {
1204     my ($vmid) = @_;
1205     my $pid = find_lxc_pid($vmid);
1206
1207     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1208     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1209         or die "failed to create socketpair: $!\n";
1210
1211     my $child = fork();
1212     die "fork failed: $!\n" if !defined($child);
1213
1214     if (!$child) {
1215         eval {
1216             close $pfd;
1217             &$do_syncfs($vmid, $pid, $cfd);
1218         };
1219         if (my $err = $@) {
1220             warn $err;
1221             POSIX::_exit(1);
1222         }
1223         POSIX::_exit(0);
1224     }
1225     close $cfd;
1226     my $go = <$pfd>;
1227     die "failed to enter container namespace\n" if $go ne "go\n";
1228
1229     open my $mounts, '<', "/proc/$child/mounts"
1230         or die "failed to open container's /proc/mounts: $!\n";
1231     my $mountdata = do { local $/ = undef; <$mounts> };
1232     close $mounts;
1233     print {$pfd} $mountdata;
1234     close $pfd;
1235
1236     while (waitpid($child, 0) != $child) {}
1237     die "failed to sync container namespace\n" if $? != 0;
1238 }
1239
1240 sub template_create {
1241     my ($vmid, $conf) = @_;
1242
1243     my $storecfg = PVE::Storage::config();
1244
1245     PVE::LXC::Config->foreach_volume($conf, sub {
1246         my ($ms, $mountpoint) = @_;
1247
1248         my $volid = $mountpoint->{volume};
1249
1250         die "Template feature is not available for '$volid'\n"
1251             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1252     });
1253
1254     PVE::LXC::Config->foreach_volume($conf, sub {
1255         my ($ms, $mountpoint) = @_;
1256
1257         my $volid = $mountpoint->{volume};
1258
1259         PVE::Storage::activate_volumes($storecfg, [$volid]);
1260
1261         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1262         $mountpoint->{volume} = $template_volid;
1263         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1264     });
1265
1266     PVE::LXC::Config->write_config($vmid, $conf);
1267 }
1268
1269 sub check_ct_modify_config_perm {
1270     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1271
1272     return 1 if $authuser eq 'root@pam';
1273     my $storage_cfg = PVE::Storage::config();
1274
1275     my $check = sub {
1276         my ($opt, $delete) = @_;
1277         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1278             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1279         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1280             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1281             return if $delete;
1282             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1283             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1284                 if $data->{type} ne 'volume';
1285             my $volid = $data->{volume};
1286             if ($volid =~ $NEW_DISK_RE) {
1287                 my $sid = $1;
1288                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1289             } else {
1290                 PVE::Storage::check_volume_access(
1291                     $rpcenv,
1292                     $authuser,
1293                     $storage_cfg,
1294                     $vmid,
1295                     $volid,
1296                     'rootdir',
1297                 );
1298             }
1299         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1300             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1301         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1302                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1303             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1304         } elsif ($opt eq 'features') {
1305             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1306                 if !$unprivileged;
1307
1308             my $nesting_changed = 0;
1309             my $other_changed = 0;
1310             if (!$delete) {
1311                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1312                 if (defined($oldconf) && $oldconf->{$opt}) {
1313                     # existing container with features
1314                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1315                     for my $feature ((keys %$old_features, keys %$features)) {
1316                         my $old = $old_features->{$feature} // '';
1317                         my $new = $features->{$feature} // '';
1318                         if ($old ne $new) {
1319                             if ($feature eq 'nesting') {
1320                                 $nesting_changed = 1;
1321                                 next;
1322                             } else {
1323                                 $other_changed = 1;
1324                                 last;
1325                             }
1326                         }
1327                     }
1328                 } else {
1329                     # new container or no features defined
1330                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1331                         $nesting_changed = 1;
1332                     } elsif (scalar(keys %$features) > 0) {
1333                         $other_changed = 1;
1334                     }
1335                 }
1336             } else {
1337                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1338                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1339                     $nesting_changed = 1;
1340                 } elsif (scalar(keys %$features) > 0) {
1341                     $other_changed = 1;
1342                 }
1343             }
1344             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1345                 if $other_changed;
1346             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1347                 if $nesting_changed;
1348         } elsif ($opt eq 'hookscript') {
1349             # For now this is restricted to root@pam
1350             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1351         } elsif ($opt eq 'tags') {
1352             my $old = $oldconf->{$opt};
1353             my $new = $delete ? '' : $newconf->{$opt};
1354             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1355         } else {
1356             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1357         }
1358     };
1359
1360     foreach my $opt (keys %$newconf) {
1361         &$check($opt, 0);
1362     }
1363     foreach my $opt (@$delete) {
1364         &$check($opt, 1);
1365     }
1366
1367     return 1;
1368 }
1369
1370 sub umount_all {
1371     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1372
1373     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1374     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1375
1376     my $res = 1;
1377
1378     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1379         my ($ms, $mountpoint) = @_;
1380
1381         my $volid = $mountpoint->{volume};
1382         my $mount = $mountpoint->{mp};
1383
1384         return if !$volid || !$mount;
1385
1386         my $mount_path = "$rootdir/$mount";
1387         $mount_path =~ s!/+!/!g;
1388
1389         return if !PVE::ProcFSTools::is_mounted($mount_path);
1390
1391         eval {
1392             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1393         };
1394         if (my $err = $@) {
1395             if ($noerr) {
1396                 $res = 0;
1397                 warn $err;
1398             } else {
1399                 die $err;
1400             }
1401         }
1402     });
1403
1404     return $res; # tell caller if (some) umounts failed for the noerr case
1405 }
1406
1407 sub mount_all {
1408     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1409
1410     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1411     File::Path::make_path($rootdir);
1412
1413     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1414     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1415
1416     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1417
1418     eval {
1419         PVE::LXC::Config->foreach_volume($conf, sub {
1420             my ($ms, $mountpoint) = @_;
1421
1422             $mountpoint->{ro} = 0 if $ignore_ro;
1423
1424             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1425         });
1426     };
1427     if (my $err = $@) {
1428         warn "mounting container failed\n";
1429         umount_all($vmid, $storage_cfg, $conf, 1);
1430         die $err;
1431     }
1432
1433     return $rootdir;
1434 }
1435
1436
1437 sub mountpoint_mount_path {
1438     my ($mountpoint, $storage_cfg, $snapname) = @_;
1439
1440     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1441 }
1442
1443 sub query_loopdev {
1444     my ($path) = @_;
1445     my $found;
1446     my $parser = sub {
1447         my $line = shift;
1448         if ($line =~ m@^(/dev/loop\d+):@) {
1449             $found = $1;
1450         }
1451     };
1452     my $cmd = ['losetup', '--associated', $path];
1453     PVE::Tools::run_command($cmd, outfunc => $parser);
1454     return $found;
1455 }
1456
1457 # Run a function with a file attached to a loop device.
1458 # The loop device is always detached afterwards (or set to autoclear).
1459 # Returns the loop device.
1460 sub run_with_loopdev {
1461     my ($func, $file, $readonly) = @_;
1462     my $device = query_loopdev($file);
1463     # Try to reuse an existing device
1464     if ($device) {
1465         # We assume that whoever setup the loop device is responsible for
1466         # detaching it.
1467         &$func($device);
1468         return $device;
1469     }
1470
1471     my $parser = sub {
1472         my $line = shift;
1473         if ($line =~ m@^(/dev/loop\d+)$@) {
1474             $device = $1;
1475         }
1476     };
1477     my $losetup_cmd = [
1478         'losetup',
1479         '--show',
1480         '-f',
1481         $file,
1482     ];
1483     push @$losetup_cmd, '-r' if $readonly;
1484     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1485     die "failed to setup loop device for $file\n" if !$device;
1486     eval { &$func($device); };
1487     my $err = $@;
1488     PVE::Tools::run_command(['losetup', '-d', $device]);
1489     die $err if $err;
1490     return $device;
1491 }
1492
1493 # In scalar mode: returns a file handle to the deepest directory node.
1494 # In list context: returns a list of:
1495 #   * the deepest directory node
1496 #   * the 2nd deepest directory (parent of the above)
1497 #   * directory name of the last directory
1498 # So that the path $2/$3 should lead to $1 afterwards.
1499 sub walk_tree_nofollow($$$;$$) {
1500     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1501
1502     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1503         or die "failed to open start directory $start: $!\n";
1504
1505     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1506 }
1507
1508
1509 sub walk_tree_nofollow_fd($$$$;$$) {
1510     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1511
1512     # splitdir() returns '' for empty components including the leading /
1513     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1514
1515     my $fd = $start_fd;
1516     my $dir = $start_dirname;
1517     my $last_component = undef;
1518     my $second = $fd;
1519     foreach my $component (@comps) {
1520         $dir .= "/$component";
1521         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1522
1523         if (!$next) {
1524             # failed, check for symlinks and try to create the path
1525             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1526             die "cannot open directory $dir: $!\n" if !$mkdir;
1527
1528             # We don't check for errors on mkdirat() here and just try to
1529             # openat() again, since at least one error (EEXIST) is an
1530             # expected possibility if multiple containers start
1531             # simultaneously. If someone else injects a symlink now then
1532             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1533             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1534
1535             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1536             die "failed to create path: $dir: $!\n" if !$next;
1537
1538             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1539                 if defined($rootuid) && defined($rootgid);
1540         }
1541
1542         close $second if defined($last_component) && $second != $start_fd;
1543         $last_component = $component;
1544         $second = $fd;
1545         $fd = $next;
1546     }
1547
1548     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1549     close $second if defined($last_component) && $second != $start_fd;
1550     return $fd;
1551 }
1552
1553 # To guard against symlink attack races against other currently running
1554 # containers with shared recursive bind mount hierarchies we prepare a
1555 # directory handle for the directory we're mounting over to verify the
1556 # mountpoint afterwards.
1557 sub __bindmount_prepare {
1558     my ($hostroot, $dir) = @_;
1559     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1560     return $srcdh;
1561 }
1562
1563 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1564 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1565 # we intended to bind mount.
1566 sub __bindmount_verify {
1567     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1568     my $destdh;
1569     if ($parentfd) {
1570         # Open the mount point path coming from the parent directory since the
1571         # filehandle we would have gotten as first result of walk_tree_nofollow
1572         # earlier is still a handle to the underlying directory instead of the
1573         # mounted path.
1574         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1575         die "failed to open mount point: $!\n" if !$destdh;
1576         if ($ro) {
1577             my $dot = '.';
1578             # no separate function because 99% of the time it's the wrong thing to use.
1579             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1580                 die "failed to mark bind mount read only\n";
1581             }
1582             die "read-only check failed: $!\n" if $! != EROFS;
1583         }
1584     } else {
1585         # For the rootfs we don't have a parentfd so we open the path directly.
1586         # Note that this means bindmounting any prefix of the host's
1587         # /var/lib/lxc/$vmid path into another container is considered a grave
1588         # security error.
1589         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1590         die "failed to open mount point: $!\n" if !$destdh;
1591     }
1592
1593     my ($srcdev, $srcinode) = stat($srcdh);
1594     my ($dstdev, $dstinode) = stat($destdh);
1595     close $srcdh;
1596     close $destdh;
1597
1598     return ($srcdev == $dstdev && $srcinode == $dstinode);
1599 }
1600
1601 # Perform the actual bind mounting:
1602 sub __bindmount_do {
1603     my ($dir, $dest, $ro, @extra_opts) = @_;
1604     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1605     if ($ro) {
1606         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1607         if (my $err = $@) {
1608             warn "bindmount error\n";
1609             # don't leave writable bind-mounts behind...
1610             PVE::Tools::run_command(['umount', $dest]);
1611             die $err;
1612         }
1613     }
1614 }
1615
1616 sub bindmount {
1617     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1618
1619     my $srcdh = __bindmount_prepare('/', $dir);
1620
1621     __bindmount_do($dir, $dest, $ro, @extra_opts);
1622
1623     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1624         PVE::Tools::run_command(['umount', $dest]);
1625         die "detected mount path change at: $dir\n";
1626     }
1627 }
1628
1629 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1630 # from $rootdir and $mount and walk the path from $rootdir to the final
1631 # directory to check for symlinks.
1632 sub __mount_prepare_rootdir {
1633     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1634     $rootdir =~ s!/+!/!g;
1635     $rootdir =~ s!/+$!!;
1636     my $mount_path = "$rootdir/$mount";
1637     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1638     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1639 }
1640
1641 # use $rootdir = undef to just return the corresponding mount path
1642 sub mountpoint_mount {
1643     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1644     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1645 }
1646
1647 sub mountpoint_stage {
1648     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1649     my ($path, $loop, $dev) =
1650         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1651
1652     if (!defined($path)) {
1653         return undef if $! == ENOSYS;
1654         die "failed to mount subvolume: $!\n";
1655     }
1656
1657     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1658     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1659     # point).
1660     my $err;
1661     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1662         or die "open_tree() on mount point failed: $!\n";
1663
1664     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1665 }
1666
1667 sub mountpoint_insert_staged {
1668     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1669
1670     if (!defined($rootdir_fd)) {
1671         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1672             or die "failed to open '.': $!\n";
1673     }
1674
1675     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1676
1677     PVE::Tools::move_mount(
1678         fileno($mount_fd),
1679         '',
1680         fileno($dest_fd),
1681         '',
1682         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1683     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1684 }
1685
1686 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1687 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1688 #   Note that if the kernel does not support the new mount API, this will not perform any action
1689 #   and return `undef` with $! = ENOSYS.
1690 sub __mountpoint_mount {
1691     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1692
1693     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1694         $! = ENOSYS;
1695         return undef;
1696     }
1697
1698     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1699     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1700     # which we use in __bindmount_verify()!
1701     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1702
1703     my $volid = $mountpoint->{volume};
1704     my $type = $mountpoint->{type};
1705     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1706     my $mounted_dev;
1707
1708     return if !$volid || !$mount;
1709
1710     $mount =~ s!/+!/!g;
1711
1712     my $mount_path;
1713     my ($mpfd, $parentfd, $last_dir);
1714
1715     if (defined($rootdir)) {
1716         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1717             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1718     }
1719
1720     if (defined($stage_mount)) {
1721         $mount_path = $rootdir;
1722     }
1723
1724     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1725
1726     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1727
1728     my $optlist = [];
1729
1730     if (my $mountopts = $mountpoint->{mountoptions}) {
1731         my @opts = split(/;/, $mountpoint->{mountoptions});
1732         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1733     }
1734
1735     my $acl = $mountpoint->{acl};
1736     if (defined($acl)) {
1737         push @$optlist, ($acl ? 'acl' : 'noacl');
1738     }
1739
1740     my $optstring = join(',', @$optlist);
1741     my $readonly = $mountpoint->{ro};
1742
1743     my @extra_opts;
1744     @extra_opts = ('-o', $optstring) if $optstring;
1745
1746     if ($storage) {
1747
1748         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1749
1750         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1751
1752         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1753
1754         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1755             PVE::Storage::parse_volname($storage_cfg, $volid);
1756
1757         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1758
1759         if ($format eq 'subvol') {
1760             if ($mount_path) {
1761                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1762                 if (defined($snapname)) {
1763                     $name .= "\@$snapname";
1764                     if ($scfg->{type} eq 'zfspool') {
1765                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1766                     } else {
1767                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1768                     }
1769                 } else {
1770                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1771                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1772                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1773                     }
1774                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1775                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1776                 }
1777             }
1778             return wantarray ? ($path, 0, undef) : $path;
1779         } elsif ($format eq 'raw' || $format eq 'iso') {
1780             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1781             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1782             # Our autodev hook expects the /dev/dm-* device currently
1783             # and will create the /dev/mapper symlink accordingly
1784             $path = Cwd::realpath($path);
1785             die "failed to get device path\n" if !$path;
1786             ($path) = ($path =~ /^(.*)$/s); #untaint
1787             my $domount = sub {
1788                 my ($path) = @_;
1789                 if ($mount_path) {
1790                     if ($format eq 'iso') {
1791                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1792                     } elsif ($isBase || defined($snapname)) {
1793                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1794                     } else {
1795                         if ($quota) {
1796                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1797                         }
1798                         push @extra_opts, '-o', 'ro' if $readonly;
1799                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1800                     }
1801                 }
1802             };
1803             my $use_loopdev = 0;
1804             if ($scfg->{content}->{rootdir}) {
1805                 if ($scfg->{path}) {
1806                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1807                     $use_loopdev = 1;
1808                 } else {
1809                     $mounted_dev = $path;
1810                     &$domount($path);
1811                 }
1812             } else {
1813                 die "storage '$storage' does not support containers\n";
1814             }
1815             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1816         } else {
1817             die "unsupported image format '$format'\n";
1818         }
1819     } elsif ($type eq 'device') {
1820         push @extra_opts, '-o', 'ro' if $readonly;
1821         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1822         # See the NOTE above about devicemapper canonicalization
1823         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1824         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1825         return wantarray ? ($volid, 0, $devpath) : $volid;
1826     } elsif ($type eq 'bind') {
1827         die "directory '$volid' does not exist\n" if ! -d $volid;
1828         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1829         warn "cannot enable quota control for bind mounts\n" if $quota;
1830         return wantarray ? ($volid, 0, undef) : $volid;
1831     }
1832
1833     die "unsupported storage";
1834 }
1835
1836 sub mountpoint_hotplug :prototype($$$$$) {
1837     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1838
1839     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1840
1841     # We do the rest in a fork with an unshared mount namespace, because:
1842     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1843     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1844     #     container's namespace, then mount it.
1845
1846     PVE::Tools::run_fork(sub {
1847         # Pin the container pid longer, we also need to get its monitor/parent:
1848         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1849             or die "failed to open pidfd of container $vmid\'s init process\n";
1850
1851         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1852             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1853
1854         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1855         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1856
1857         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1858         # profile to lower our privileges to the same level we have in the start hook:
1859         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1860             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1861         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1862         # apparmor.
1863
1864         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1865         # namespace for it to remain active there since the container will be able to unmount
1866         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1867         # concern.
1868         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1869         chdir('/')
1870             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1871
1872         my $dir = get_staging_mount_path($opt);
1873
1874         # Now switch our apparmor profile before mounting:
1875         my $data = 'changeprofile /usr/bin/lxc-start';
1876         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1877             die "failed to change apparmor profile: $!\n";
1878         }
1879         # Check errors on close as well:
1880         close($aa_fd)
1881             or die "failed to change apparmor profile (close() failed): $!\n";
1882
1883         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1884
1885         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1886         chdir('/')
1887             or die "failed to change root directory within the container's mount namespace: $!\n";
1888
1889         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1890     });
1891 }
1892
1893 # Create a directory in the mountpoint staging tempfs.
1894 sub get_staging_mount_path($) {
1895     my ($opt) = @_;
1896
1897     my $target = get_staging_tempfs() . "/$opt";
1898     if (!mkdir($target) && $! != EEXIST) {
1899         die "failed to create directory $target: $!\n";
1900     }
1901
1902     return $target;
1903 }
1904
1905 # Mount /run/pve/mountpoints as tmpfs
1906 sub get_staging_tempfs() {
1907     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1908     # mounts to that.
1909     my $target = '/var/lib/lxc/.pve-staged-mounts';
1910     if (!mkdir($target)) {
1911         return $target if $! == EEXIST;
1912         die "failed to create directory $target: $!\n";
1913     }
1914
1915     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1916         or die "failed to mount $target as tmpfs: $!\n";
1917
1918     return $target;
1919 }
1920
1921 sub mkfs {
1922     my ($dev, $rootuid, $rootgid) = @_;
1923
1924     run_command(
1925         [
1926             'mkfs.ext4',
1927             '-O',
1928             'mmp',
1929             '-E',
1930             "root_owner=$rootuid:$rootgid",
1931             $dev,
1932         ],
1933         outfunc => sub {
1934             my $line = shift;
1935             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1936             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1937                 print "$line\n";
1938             }
1939         },
1940         errfunc => sub {
1941             my $line = shift;
1942             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1943         }
1944     );
1945 }
1946
1947 sub format_disk {
1948     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1949
1950     if ($volid =~ m!^/dev/.+!) {
1951         mkfs($volid);
1952         return;
1953     }
1954
1955     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1956
1957     die "cannot format volume '$volid' with no storage\n" if !$storage;
1958
1959     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1960
1961     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1962
1963     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1964
1965     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1966         PVE::Storage::parse_volname($storage_cfg, $volid);
1967
1968     die "cannot format volume '$volid' (format == $format)\n"
1969         if $format ne 'raw';
1970
1971     mkfs($path, $rootuid, $rootgid);
1972 }
1973
1974 sub destroy_disks {
1975     my ($storecfg, $vollist) = @_;
1976
1977     foreach my $volid (@$vollist) {
1978         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1979         warn $@ if $@;
1980     }
1981 }
1982
1983 sub alloc_disk {
1984     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1985
1986     my $needs_chown = 0;
1987     my $volid;
1988
1989     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1990     # fixme: use better naming ct-$vmid-disk-X.raw?
1991
1992     eval {
1993         my $do_format = 0;
1994         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
1995             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
1996                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1997                 $do_format = 1;
1998             } else {
1999                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2000                 $needs_chown = 1;
2001             }
2002         } elsif ($scfg->{type} eq 'zfspool') {
2003             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2004             $needs_chown = 1;
2005         } elsif ($scfg->{content}->{rootdir}) {
2006             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2007             $do_format = 1;
2008         } else {
2009             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2010         }
2011         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2012     };
2013     if (my $err = $@) {
2014         # in case formatting got interrupted:
2015         if (defined($volid)) {
2016             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2017             warn $@ if $@;
2018         }
2019         die $err;
2020     }
2021
2022     return ($volid, $needs_chown);
2023 }
2024
2025 sub create_disks {
2026     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2027
2028     my $vollist = [];
2029
2030     eval {
2031         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2032         my $chown_vollist = [];
2033
2034         PVE::LXC::Config->foreach_volume($settings, sub {
2035             my ($ms, $mountpoint) = @_;
2036
2037             my $volid = $mountpoint->{volume};
2038             my $mp = $mountpoint->{mp};
2039
2040             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2041
2042             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2043                 my ($storeid, $size_gb) = ($1, $2);
2044
2045                 my $size_kb = int(${size_gb}*1024) * 1024;
2046
2047                 my $needs_chown = 0;
2048                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2049                 push @$chown_vollist, $volid if $needs_chown;
2050                 push @$vollist, $volid;
2051                 $mountpoint->{volume} = $volid;
2052                 $mountpoint->{size} = $size_kb * 1024;
2053                 if ($pending) {
2054                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2055                 } else {
2056                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2057                 }
2058             } else {
2059                 # use specified/existing volid/dir/device
2060                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2061             }
2062         });
2063
2064         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2065         foreach my $volid (@$chown_vollist) {
2066             my $path = PVE::Storage::path($storecfg, $volid, undef);
2067             chown($rootuid, $rootgid, $path);
2068         }
2069         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2070     };
2071     # free allocated images on error
2072     if (my $err = $@) {
2073         destroy_disks($storecfg, $vollist);
2074         die $err;
2075     }
2076     return $vollist;
2077 }
2078
2079 sub update_disksize {
2080     my ($vmid, $conf, $all_volumes) = @_;
2081
2082     my $changes;
2083     my $prefix = "CT $vmid:";
2084
2085     my $update_mp = sub {
2086         my ($key, $mp, @param) = @_;
2087         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2088
2089         if (!defined($mp->{size}) || $size != $mp->{size}) {
2090             $changes = 1;
2091             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2092             $mp->{size} = $size;
2093             my $nomp = 1 if ($key eq 'rootfs');
2094             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
2095         }
2096     };
2097
2098     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2099
2100     return $changes;
2101 }
2102
2103 sub update_unused {
2104     my ($vmid, $conf, $all_volumes) = @_;
2105
2106     my $changes;
2107     my $prefix = "CT $vmid:";
2108
2109     # Note: it is allowed to define multiple storage entries with the same path
2110     # (alias), so we need to check both 'volid' and real 'path' (two different
2111     # volid can point to the same path).
2112
2113     # used and unused disks
2114     my $refpath = {};
2115     my $orphans = {};
2116
2117     foreach my $opt (keys %$conf) {
2118         next if ($opt !~ m/^unused\d+$/);
2119         my $vol = $all_volumes->{$conf->{$opt}};
2120         $refpath->{$vol->{path}} = $vol->{volid};
2121     }
2122
2123     foreach my $key (keys %$all_volumes) {
2124         my $vol = $all_volumes->{$key};
2125         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2126         my $path = $vol->{path};
2127
2128         if ($in_use) {
2129             $refpath->{$path} = $key;
2130             delete $orphans->{$path};
2131         } else {
2132             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2133                 $orphans->{$path} = $key;
2134             }
2135         }
2136     }
2137
2138     for my $key (keys %$orphans) {
2139         my $disk = $orphans->{$key};
2140         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2141
2142         if ($unused) {
2143             $changes = 1;
2144             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2145         }
2146     }
2147
2148     return $changes;
2149 }
2150
2151 sub scan_volids {
2152     my ($cfg, $vmid) = @_;
2153
2154     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2155
2156     my $all_volumes = {};
2157     foreach my $storeid (keys %$info) {
2158         foreach my $item (@{$info->{$storeid}}) {
2159             my $volid = $item->{volid};
2160             next if !($volid && $item->{size});
2161             $item->{path} = PVE::Storage::path($cfg, $volid);
2162             $all_volumes->{$volid} = $item;
2163         }
2164     }
2165
2166     return $all_volumes;
2167 }
2168
2169 sub rescan {
2170     my ($vmid, $nolock, $dryrun) = @_;
2171
2172     my $cfg = PVE::Storage::config();
2173
2174     print "rescan volumes...\n";
2175     my $all_volumes = scan_volids($cfg, $vmid);
2176
2177     my $updatefn =  sub {
2178         my ($vmid) = @_;
2179
2180         my $changes;
2181         my $conf = PVE::LXC::Config->load_config($vmid);
2182
2183         PVE::LXC::Config->check_lock($conf);
2184
2185         my $vm_volids = {};
2186         foreach my $volid (keys %$all_volumes) {
2187             my $info = $all_volumes->{$volid};
2188             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2189         }
2190
2191         my $upu = update_unused($vmid, $conf, $vm_volids);
2192         my $upd = update_disksize($vmid, $conf, $vm_volids);
2193         $changes = $upu || $upd;
2194
2195         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2196     };
2197
2198     if (defined($vmid)) {
2199         if ($nolock) {
2200             &$updatefn($vmid);
2201         } else {
2202             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2203         }
2204     } else {
2205         my $vmlist = config_list();
2206         foreach my $vmid (keys %$vmlist) {
2207             if ($nolock) {
2208                 &$updatefn($vmid);
2209             } else {
2210                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2211             }
2212         }
2213     }
2214 }
2215
2216
2217 # bash completion helper
2218
2219 sub complete_os_templates {
2220     my ($cmdname, $pname, $cvalue) = @_;
2221
2222     my $cfg = PVE::Storage::config();
2223
2224     my $storeid;
2225
2226     if ($cvalue =~ m/^([^:]+):/) {
2227         $storeid = $1;
2228     }
2229
2230     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2231     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2232
2233     my $res = [];
2234     foreach my $id (keys %$data) {
2235         foreach my $item (@{$data->{$id}}) {
2236             push @$res, $item->{volid} if defined($item->{volid});
2237         }
2238     }
2239
2240     return $res;
2241 }
2242
2243 my $complete_ctid_full = sub {
2244     my ($running) = @_;
2245
2246     my $idlist = vmstatus();
2247
2248     my $active_hash = list_active_containers();
2249
2250     my $res = [];
2251
2252     foreach my $id (keys %$idlist) {
2253         my $d = $idlist->{$id};
2254         if (defined($running)) {
2255             next if $d->{template};
2256             next if $running && !$active_hash->{$id};
2257             next if !$running && $active_hash->{$id};
2258         }
2259         push @$res, $id;
2260
2261     }
2262     return $res;
2263 };
2264
2265 sub complete_ctid {
2266     return &$complete_ctid_full();
2267 }
2268
2269 sub complete_ctid_stopped {
2270     return &$complete_ctid_full(0);
2271 }
2272
2273 sub complete_ctid_running {
2274     return &$complete_ctid_full(1);
2275 }
2276
2277 sub parse_id_maps {
2278     my ($conf) = @_;
2279
2280     my $id_map = [];
2281     my $rootuid = 0;
2282     my $rootgid = 0;
2283
2284     my $lxc = $conf->{lxc};
2285     foreach my $entry (@$lxc) {
2286         my ($key, $value) = @$entry;
2287         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2288         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2289         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2290             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2291             push @$id_map, [$type, $ct, $host, $length];
2292             if ($ct == 0) {
2293                 $rootuid = $host if $type eq 'u';
2294                 $rootgid = $host if $type eq 'g';
2295             }
2296         } else {
2297             die "failed to parse idmap: $value\n";
2298         }
2299     }
2300
2301     if (!@$id_map && $conf->{unprivileged}) {
2302         # Should we read them from /etc/subuid?
2303         $id_map = [ ['u', '0', '100000', '65536'],
2304                     ['g', '0', '100000', '65536'] ];
2305         $rootuid = $rootgid = 100000;
2306     }
2307
2308     return ($id_map, $rootuid, $rootgid);
2309 }
2310
2311 sub userns_command {
2312     my ($id_map) = @_;
2313     if (@$id_map) {
2314         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2315     }
2316     return [];
2317 }
2318
2319 my sub print_ct_stderr_log {
2320     my ($vmid) = @_;
2321     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2322     return if !$log;
2323
2324     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2325         my $line = $2;
2326         print STDERR "$line\n";
2327     }
2328 }
2329 my sub print_ct_warn_log {
2330     my ($vmid) = @_;
2331     my $log_fn = "/run/pve/ct-$vmid.warnings";
2332     my $log = eval { file_get_contents($log_fn) };
2333     return if !$log;
2334
2335     my $rpcenv = eval { PVE::RPCEnvironment::get() };
2336
2337     my $warn_fn = $rpcenv ? sub { $rpcenv->warn($_[0]) } : sub { print STDERR "WARN: $_[0]\n" };
2338
2339     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2340         my $line = $1;
2341         $warn_fn->($line);
2342     }
2343     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2344 }
2345
2346 my sub monitor_state_change($$) {
2347     my ($monitor_socket, $vmid) = @_;
2348     die "no monitor socket\n" if !defined($monitor_socket);
2349
2350     while (1) {
2351         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2352
2353         die "monitor socket: got EOF\n" if !defined($type);
2354
2355         next if $name ne "$vmid" || $type ne 'STATE';
2356
2357         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2358             alarm(0); # don't timeout after seeing the starting state
2359         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2360                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2361                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2362             return 0;
2363         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2364             return 1;
2365         } else {
2366             warn "unexpected message from monitor socket - " .
2367                  "type: '$type' - value: '$value'\n";
2368         }
2369     }
2370 }
2371 my sub monitor_start($$) {
2372     my ($monitor_socket, $vmid) = @_;
2373
2374     my $success = eval {
2375         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2376     };
2377     if (my $err = $@) {
2378         warn "problem with monitor socket, but continuing anyway: $err\n";
2379     } elsif (!$success) {
2380         print_ct_stderr_log($vmid);
2381         die "startup for container '$vmid' failed\n";
2382     }
2383 }
2384
2385 sub vm_start {
2386     my ($vmid, $conf, $skiplock, $debug) = @_;
2387
2388     # apply pending changes while starting
2389     if (scalar(keys %{$conf->{pending}})) {
2390         my $storecfg = PVE::Storage::config();
2391         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2392         PVE::LXC::Config->write_config($vmid, $conf);
2393         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2394     }
2395
2396     update_lxc_config($vmid, $conf);
2397
2398     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2399
2400     if ($skiplock) {
2401         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2402         close($fh);
2403     }
2404
2405     my $storage_cfg = PVE::Storage::config();
2406     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2407
2408     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2409
2410     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2411     warn $@ if $@;
2412
2413     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2414
2415     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2416     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2417
2418     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2419
2420     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2421     eval {
2422         run_command($cmd);
2423
2424         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2425
2426         # if debug is requested, print the log it also when the start succeeded
2427         print_ct_stderr_log($vmid) if $is_debug;
2428
2429         print_ct_warn_log($vmid); # always print warn log, if any
2430     };
2431     if (my $err = $@) {
2432         unlink $skiplock_flag_fn;
2433         die $err;
2434     }
2435     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2436
2437     return;
2438 }
2439
2440 # Helper to stop a container completely and make sure it has stopped completely.
2441 # This is necessary because we want the post-stop hook to have completed its
2442 # unmount-all step, but post-stop happens after lxc puts the container into the
2443 # STOPPED state.
2444 # $kill - if true it will always do an immediate hard-stop
2445 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2446 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2447 sub vm_stop {
2448     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2449
2450     # Open the container's command socket.
2451     my $path = "\0/var/lib/lxc/$vmid/command";
2452     my $sock = IO::Socket::UNIX->new(
2453         Type => SOCK_STREAM(),
2454         Peer => $path,
2455     );
2456     if (!$sock) {
2457         return if $! == ECONNREFUSED; # The container is not running
2458         die "failed to open container ${vmid}'s command socket: $!\n";
2459     }
2460
2461     my $conf = PVE::LXC::Config->load_config($vmid);
2462     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2463
2464     # Stop the container:
2465
2466     my $cmd = ['lxc-stop', '-n', $vmid];
2467
2468     if ($kill) {
2469         push @$cmd, '--kill'; # doesn't allow timeouts
2470     } else {
2471         # lxc-stop uses a default timeout
2472         push @$cmd, '--nokill' if !$kill_after_timeout;
2473
2474         if (defined($shutdown_timeout)) {
2475             push @$cmd, '--timeout', $shutdown_timeout;
2476             # Give run_command 5 extra seconds
2477             $shutdown_timeout += 5;
2478         }
2479     }
2480
2481     eval { run_command($cmd, timeout => $shutdown_timeout) };
2482     if (my $err = $@) {
2483         warn $@ if $@;
2484     }
2485
2486     my $result = <$sock>;
2487
2488     return if !defined $result; # monitor is gone and the ct has stopped.
2489     die "container did not stop\n";
2490 }
2491
2492 sub vm_reboot {
2493     my ($vmid, $timeout, $skiplock) = @_;
2494
2495     PVE::LXC::Config->lock_config($vmid, sub {
2496         return if !check_running($vmid);
2497
2498         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2499
2500         my $conf = PVE::LXC::Config->load_config($vmid);
2501         vm_start($vmid, $conf);
2502     });
2503 }
2504
2505 sub run_unshared {
2506     my ($code) = @_;
2507
2508     return PVE::Tools::run_fork(sub {
2509         # Unshare the mount namespace
2510         die "failed to unshare mount namespace: $!\n"
2511             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2512         run_command(['mount', '--make-rslave', '/']);
2513         return $code->();
2514     });
2515 }
2516
2517 my $copy_volume = sub {
2518     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2519
2520     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2521     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2522
2523     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2524     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2525
2526     my @mounted;
2527     eval {
2528         # mount and copy
2529         mkdir $src;
2530         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2531         push @mounted, $src;
2532         mkdir $dest;
2533         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2534         push @mounted, $dest;
2535
2536         $bwlimit //= 0;
2537
2538         run_command([
2539             'rsync',
2540             '--stats',
2541             '-X',
2542             '-A',
2543             '--numeric-ids',
2544             '-aH',
2545             '--whole-file',
2546             '--sparse',
2547             '--one-file-system',
2548             "--bwlimit=$bwlimit",
2549             "$src/",
2550             $dest
2551         ]);
2552     };
2553     my $err = $@;
2554
2555     # Wait for rsync's children to release dest so that
2556     # consequent file operations (umount, remove) are possible
2557     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2558
2559     foreach my $mount (reverse @mounted) {
2560         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2561         warn "Can't umount $mount\n" if $@;
2562     }
2563
2564     # If this fails they're used as mount points in a concurrent operation
2565     # (which should not happen but there's also no real need to get rid of them).
2566     rmdir $dest;
2567     rmdir $src;
2568
2569     die $err if $err;
2570 };
2571
2572 # Should not be called after unsharing the mount namespace!
2573 sub copy_volume {
2574     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2575
2576     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2577     File::Path::make_path("/var/lib/lxc/$vmid");
2578     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2579     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2580
2581     # get id's for unprivileged container
2582     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2583
2584     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2585     # are visible in this namespace, otherwise the host only sees the empty
2586     # (not-mounted) directory.
2587     my $new_volid;
2588     eval {
2589         # Make sure $mp contains a correct size.
2590         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2591         my $needs_chown;
2592         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2593         if ($needs_chown) {
2594             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2595             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2596             chown($rootuid, $rootgid, $path);
2597         }
2598
2599         run_unshared(sub {
2600             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2601         });
2602     };
2603     if (my $err = $@) {
2604         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2605             if defined($new_volid);
2606         die $err;
2607     }
2608
2609     return $new_volid;
2610 }
2611
2612 sub get_lxc_version() {
2613     my $version;
2614     run_command([qw(lxc-start --version)], outfunc => sub {
2615         my ($line) = @_;
2616         # We only parse out major & minor version numbers.
2617         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2618             $version = [$1, $2];
2619         }
2620     });
2621
2622     die "failed to get lxc version\n" if !defined($version);
2623
2624     # return as a list:
2625     return $version->@*;
2626 }
2627
2628 sub freeze($) {
2629     my ($vmid) = @_;
2630     if (PVE::CGroup::cgroup_mode() == 2) {
2631         PVE::LXC::Command::freeze($vmid, 30);
2632     } else {
2633         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2634     }
2635 }
2636
2637 sub thaw($) {
2638     my ($vmid) = @_;
2639     if (PVE::CGroup::cgroup_mode() == 2) {
2640         PVE::LXC::Command::unfreeze($vmid, 30);
2641     } else {
2642         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2643     }
2644 }
2645
2646 1;