src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS EEXIST);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw(
  23     dir_glob_foreach file_get_contents file_set_contents
  24     AT_FDCWD O_PATH $IPV4RE $IPV6RE
  25 );
  26 use PVE::CpuSet;
  27 use PVE::Network;
  28 use PVE::AccessControl;
  29 use PVE::ProcFSTools;
  30 use PVE::Syscall qw(:fsmount);
  31 use PVE::LXC::Config;
  32 use PVE::GuestHelpers qw(safe_string_ne safe_num_ne safe_boolean_ne);
  33 use PVE::LXC::Tools;
  34 use PVE::LXC::CGroup;
  35
  36 use Time::HiRes qw (gettimeofday);
  37 my $have_sdn;
  38 eval {
  39     require PVE::Network::SDN::Zones;
  40     $have_sdn = 1;
  41 };
  42
  43 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  44
  45 my $nodename = PVE::INotify::nodename();
  46
  47 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  48
  49 sub config_list {
  50     my $vmlist = PVE::Cluster::get_vmlist();
  51     my $res = {};
  52     return $res if !$vmlist || !$vmlist->{ids};
  53     my $ids = $vmlist->{ids};
  54
  55     foreach my $vmid (keys %$ids) {
  56         next if !$vmid; # skip CT0
  57         my $d = $ids->{$vmid};
  58         next if !$d->{node} || $d->{node} ne $nodename;
  59         next if !$d->{type} || $d->{type} ne 'lxc';
  60         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  61     }
  62     return $res;
  63 }
  64
  65 # container status helpers
  66
  67 sub list_active_containers {
  68
  69     my $filename = "/proc/net/unix";
  70
  71     # similar test is used by lcxcontainers.c: list_active_containers
  72     my $res = {};
  73
  74     my $fh = IO::File->new ($filename, "r");
  75     return $res if !$fh;
  76
  77     while (defined(my $line = <$fh>)) {
  78         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  79             my $path = $1;
  80             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  81                 $res->{$1} = 1;
  82             }
  83         }
  84     }
  85
  86     close($fh);
  87
  88     return $res;
  89 }
  90
  91 # warning: this is slow
  92 sub check_running {
  93     my ($vmid) = @_;
  94
  95     my $active_hash = list_active_containers();
  96
  97     return 1 if defined($active_hash->{$vmid});
  98
  99     return undef;
 100 }
 101
 102 sub get_container_disk_usage {
 103     my ($vmid, $pid) = @_;
 104
 105     return PVE::Tools::df("/proc/$pid/root/", 1);
 106 }
 107
 108 my $last_proc_vmid_stat;
 109
 110 our $vmstatus_return_properties = {
 111     vmid => get_standard_option('pve-vmid'),
 112     status => {
 113         description => "LXC Container status.",
 114         type => 'string',
 115         enum => ['stopped', 'running'],
 116     },
 117     maxmem => {
 118         description => "Maximum memory in bytes.",
 119         type => 'integer',
 120         optional => 1,
 121         renderer => 'bytes',
 122     },
 123     maxswap => {
 124         description => "Maximum SWAP memory in bytes.",
 125         type => 'integer',
 126         optional => 1,
 127         renderer => 'bytes',
 128     },
 129     maxdisk => {
 130         description => "Root disk size in bytes.",
 131         type => 'integer',
 132         optional => 1,
 133         renderer => 'bytes',
 134     },
 135     name => {
 136         description => "Container name.",
 137         type => 'string',
 138         optional => 1,
 139     },
 140     uptime => {
 141         description => "Uptime.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'duration',
 145     },
 146     cpus => {
 147         description => "Maximum usable CPUs.",
 148         type => 'number',
 149         optional => 1,
 150     },
 151     lock => {
 152         description => "The current config lock, if any.",
 153         type => 'string',
 154         optional => 1,
 155     },
 156     tags => {
 157         description => "The current configured tags, if any.",
 158         type => 'string',
 159         optional => 1,
 160     }
 161 };
 162
 163 sub vmstatus {
 164     my ($opt_vmid) = @_;
 165
 166     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
 167
 168     my $active_hash = list_active_containers();
 169
 170     my $cpucount = $cpuinfo->{cpus} || 1;
 171
 172     my $cdtime = gettimeofday;
 173
 174     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 175     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 176
 177     my $unprivileged = {};
 178
 179     foreach my $vmid (keys %$list) {
 180         my $d = $list->{$vmid};
 181
 182         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 183         warn $@ if $@; # ignore errors (consider them stopped)
 184
 185         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 186
 187         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 188         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 189
 190         $unprivileged->{$vmid} = $conf->{unprivileged};
 191
 192         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 193         $d->{name} =~ s/[\s]//g;
 194
 195         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 196         $d->{cpus} = $cpucount if !$d->{cpus};
 197
 198         $d->{lock} = $conf->{lock} || '';
 199         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 200
 201         if ($d->{pid}) {
 202             my $res = get_container_disk_usage($vmid, $d->{pid});
 203             $d->{disk} = $res->{used};
 204             $d->{maxdisk} = $res->{total};
 205         } else {
 206             $d->{disk} = 0;
 207             # use 4GB by default ??
 208             if (my $rootfs = $conf->{rootfs}) {
 209                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 210                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 211             } else {
 212                 $d->{maxdisk} = 4*1024*1024*1024;
 213             }
 214         }
 215
 216         $d->{mem} = 0;
 217         $d->{swap} = 0;
 218         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 219         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 220
 221         $d->{uptime} = 0;
 222         $d->{cpu} = 0;
 223
 224         $d->{netout} = 0;
 225         $d->{netin} = 0;
 226
 227         $d->{diskread} = 0;
 228         $d->{diskwrite} = 0;
 229
 230         $d->{template} = PVE::LXC::Config->is_template($conf);
 231         $d->{lock} = $conf->{lock} if $conf->{lock};
 232     }
 233
 234     foreach my $vmid (keys %$list) {
 235         my $d = $list->{$vmid};
 236         my $pid = $d->{pid};
 237
 238         next if !$pid; # skip stopped CTs
 239
 240         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 241         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 242
 243         my $unpriv = $unprivileged->{$vmid};
 244
 245         my $cgroups = PVE::LXC::CGroup->new($vmid);
 246
 247         if (defined(my $mem = $cgroups->get_memory_stat())) {
 248             $d->{mem} = $mem->{mem};
 249             $d->{swap} = $mem->{swap};
 250         } else {
 251             $d->{mem} = 0;
 252             $d->{swap} = 0;
 253         }
 254
 255         if (defined(my $blkio = $cgroups->get_io_stats())) {
 256             $d->{diskread} = $blkio->{diskread};
 257             $d->{diskwrite} = $blkio->{diskwrite};
 258         } else {
 259             $d->{diskread} = 0;
 260             $d->{diskwrite} = 0;
 261         }
 262
 263         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 264             # Total time (in milliseconds) used up by the cpu.
 265             my $used_ms = $cpu->{utime} + $cpu->{stime};
 266
 267             my $old = $last_proc_vmid_stat->{$vmid};
 268             if (!$old) {
 269                 $last_proc_vmid_stat->{$vmid} = {
 270                     time => $cdtime,
 271                     used => $used_ms,
 272                     cpu => 0,
 273                 };
 274                 next;
 275             }
 276
 277             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 278             if ($delta_ms > 1000.0) {
 279                 my $delta_used_ms = $used_ms - $old->{used};
 280                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 281                 $last_proc_vmid_stat->{$vmid} = {
 282                     time => $cdtime,
 283                     used => $used_ms,
 284                     cpu => $d->{cpu},
 285                 };
 286             } else {
 287                 $d->{cpu} = $old->{cpu};
 288             }
 289         } else {
 290             $d->{cpu} = 0;
 291         }
 292     }
 293
 294     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 295
 296     foreach my $dev (keys %$netdev) {
 297         next if $dev !~ m/^veth([1-9]\d*)i/;
 298         my $vmid = $1;
 299         my $d = $list->{$vmid};
 300
 301         next if !$d;
 302
 303         $d->{netout} += $netdev->{$dev}->{receive};
 304         $d->{netin} += $netdev->{$dev}->{transmit};
 305
 306     }
 307
 308     return $list;
 309 }
 310
 311 sub find_lxc_console_pids {
 312
 313     my $res = {};
 314
 315     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 316         my ($pid) = @_;
 317
 318         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 319         return if !$cmdline;
 320
 321         my @args = split(/\0/, $cmdline);
 322
 323         # search for lxc-console -n <vmid>
 324         return if scalar(@args) != 3;
 325         return if $args[1] ne '-n';
 326         return if $args[2] !~ m/^\d+$/;
 327         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 328
 329         my $vmid = $args[2];
 330
 331         push @{$res->{$vmid}}, $pid;
 332     });
 333
 334     return $res;
 335 }
 336
 337 sub find_lxc_pid {
 338     my ($vmid) = @_;
 339
 340     my $pid = undef;
 341     my $parser = sub {
 342         my $line = shift;
 343         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 344     };
 345     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 346
 347     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 348
 349     return $pid;
 350 }
 351
 352 sub open_pid_fd($) {
 353     my ($pid) = @_;
 354     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 355         or die "failed to open /proc/$pid pid fd\n";
 356     return $fd;
 357 }
 358
 359 sub open_lxc_pid {
 360     my ($vmid) = @_;
 361
 362     # Find the pid and open:
 363     my $pid = find_lxc_pid($vmid);
 364     my $fd = open_pid_fd($pid);
 365
 366     # Verify:
 367     my $pid2 = find_lxc_pid($vmid);
 368
 369     return () if $pid != $pid2;
 370     return ($pid, $fd);
 371 }
 372
 373 sub open_ppid {
 374     my ($pid) = @_;
 375
 376     # Find the parent pid via proc and open it:
 377     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 378     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 379
 380     my $fd = open_pid_fd($ppid);
 381
 382     # Verify:
 383     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 384     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 385
 386     return () if $ppid != $ppid2;
 387     return ($ppid, $fd);
 388 }
 389
 390 # Note: we cannot use Net:IP, because that only allows strict
 391 # CIDR networks
 392 sub parse_ipv4_cidr {
 393     my ($cidr, $noerr) = @_;
 394
 395     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 396         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 397     }
 398
 399     return undef if $noerr;
 400
 401     die "unable to parse ipv4 address/mask\n";
 402 }
 403
 404 # Deprecated. Use `PVE::LXC::CGroup::get_cgroup_controllers()` instead.
 405 sub get_cgroup_subsystems {
 406     PVE::LXC::CGroup::get_v1_controllers();
 407 }
 408
 409 # With seccomp trap to userspace we now have the ability to optionally forward
 410 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 411 #
 412 # This means that there are cases where we need to create an extra seccomp
 413 # profile for the container to load.
 414 #
 415 # This returns a configuration snippet added to the raw lxc config.
 416 sub make_seccomp_config {
 417     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 418     # User-configured profile has precedence, note that the user's entry would
 419     # be written 'after' this line anyway...
 420     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 421         # Warn the user if this conflicts with a feature:
 422         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 423         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 424             if length($warn) > 0;
 425         return '';
 426     }
 427
 428     # Privileged containers keep using the default (which is already part of
 429     # the files included via lxc.include, so we don't need to write it out,
 430     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 431     # well)
 432     return '' if !$unprivileged;
 433
 434     my $rules = {
 435         keyctl => ['errno 38'],
 436     };
 437
 438     my $raw_conf = '';
 439
 440     # Unprivileged containers will get keyctl() disabled by default as a
 441     # workaround for systemd-networkd behavior. But we have an option to
 442     # explicitly enable it:
 443     if ($features->{keyctl}) {
 444         delete $rules->{keyctl};
 445     }
 446
 447     # By default, unprivileged containers cannot use `mknod` at all.
 448     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 449     # but for now this is experimental, so it has to be enabled via a feature
 450     # flag.
 451     # Note that we only handle block and char devices (like lxd), the rest we
 452     # leave up to the kernel. We may in the future remove this if seccomp gets
 453     # a way to tell the kernel to "continue" a syscall.
 454     if ($features->{mknod}) {
 455         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 456         if (!$ok) {
 457             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 458         }
 459
 460         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 461         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 462
 463         $rules->{mknod} = [
 464             # condition: (mode & S_IFMT) == S_IFCHR
 465             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 466             # condition: (mode & S_IFMT) == S_IFBLK
 467             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 468         ];
 469         $rules->{mknodat} = [
 470             # condition: (mode & S_IFMT) == S_IFCHR
 471             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 472             # condition: (mode & S_IFMT) == S_IFBLK
 473             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 474         ];
 475     }
 476
 477     # Now build the custom seccomp rule text...
 478     my $extra_rules = join("\n", map {
 479         my $syscall = $_;
 480         map { "$syscall $_" } $rules->{$syscall}->@*
 481     } sort keys %$rules) . "\n";
 482
 483     return $raw_conf if $extra_rules eq "\n";
 484
 485     # We still have the "most common" config readily available, so don't write
 486     # out that one:
 487     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 488         # we have no extra $raw_conf and use the same we had in pve 6.1:
 489         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 490     }
 491
 492     # Write the rule file to the container's config path:
 493     my $rule_file = "$conf_dir/rules.seccomp";
 494     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 495         . $extra_rules;
 496     file_set_contents($rule_file, $rule_data);
 497     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 498
 499     return $raw_conf;
 500 }
 501
 502 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 503 # automatically. The default should be equivalent to the old
 504 # `lxc-container-default-cgns` profile.
 505 #
 506 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 507 # additional lines into the profile. We can use that to allow mounting specific
 508 # file systems.
 509 sub make_apparmor_config {
 510     my ($conf, $unprivileged, $features) = @_;
 511
 512     # user-configured profile has precedence, but first we go through our own
 513     # code to figure out whether we should warn the user:
 514
 515     my $raw = "lxc.apparmor.profile = generated\n";
 516     my @profile_uses;
 517
 518     if ($features->{fuse}) {
 519         # For the informational warning:
 520         push @profile_uses, 'features:fuse';
 521     }
 522
 523     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 524     # apparmor lines, create an apparmor namespace for the container, but also
 525     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 526     # lxcfs mounted over them, because that would prevent the container from
 527     # mounting new instances of them for nested containers.
 528     if ($features->{nesting}) {
 529         push @profile_uses, 'features:nesting';
 530         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 531     } else {
 532         # In the default profile in /etc/apparmor.d we patch this in because
 533         # otherwise a container can for example run `chown` on /sys, breaking
 534         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 535         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 536         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 537         # Preferably we could use the 'remount' flag but this does not sit well
 538         # with apparmor_parser currently:
 539         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 540     }
 541
 542     if (my $mount = $features->{mount}) {
 543         push @profile_uses, 'features:mount';
 544         foreach my $fs (PVE::Tools::split_list($mount)) {
 545             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 546         }
 547     }
 548
 549     # More to come?
 550
 551     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 552         if (length(my $used = join(', ', @profile_uses))) {
 553             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 554         }
 555         return '';
 556     }
 557
 558     return $raw;
 559 }
 560
 561 sub update_lxc_config {
 562     my ($vmid, $conf) = @_;
 563
 564     my $dir = "/var/lib/lxc/$vmid";
 565
 566     if ($conf->{template}) {
 567
 568         unlink "$dir/config";
 569
 570         return;
 571     }
 572
 573     my ($lxc_major, $lxc_minor) = get_lxc_version();
 574
 575     my $raw = '';
 576
 577     if ($lxc_major >= 4) {
 578         # Explicitly don't use relative directories, which is the default, but
 579         # note that we do this mostly because they are only applied for *some*
 580         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 581         # so we also don't need to worry about the new monitor cgroup to
 582         # confuse systemd.
 583         $raw .= "lxc.cgroup.relative = 0\n";
 584
 585         # To make things easier, let's keep our previous cgroup layout and
 586         # simply move the monitor outside:
 587         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 588         # cgroup namespace separation for stronger limits:
 589         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 590         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 591     }
 592
 593     die "missing 'arch' - internal error" if !$conf->{arch};
 594     $raw .= "lxc.arch = $conf->{arch}\n";
 595
 596     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 597     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 598
 599     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 600
 601     my $cfgpath = '/usr/share/lxc/config';
 602     my $inc = "$cfgpath/$ostype.common.conf";
 603     $inc ="$cfgpath/common.conf" if !-f $inc;
 604     $raw .= "lxc.include = $inc\n";
 605     if ($unprivileged) {
 606         $inc = "$cfgpath/$ostype.userns.conf";
 607         $inc = "$cfgpath/userns.conf" if !-f $inc;
 608         $raw .= "lxc.include = $inc\n";
 609     }
 610
 611     my $features = PVE::LXC::Config->parse_features($conf->{features});
 612
 613     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 614     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 615     if ($features->{fuse}) {
 616         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 617         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 618     }
 619
 620     if ($unprivileged && !$features->{force_rw_sys}) {
 621         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 622         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 623         $raw .= "lxc.mount.auto = sys:mixed\n";
 624     }
 625
 626     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 627     # cannot be exposed to the container with r/w access (cgroup perms).
 628     # When this is enabled mounts will still remain in the monitor's namespace
 629     # after the container unmounted them and thus will not detach from their
 630     # files while the container is running!
 631     $raw .= "lxc.monitor.unshare = 1\n";
 632
 633     my $cgv1 = get_cgroup_subsystems();
 634
 635     # Should we read them from /etc/subuid?
 636     if ($unprivileged && !$custom_idmap) {
 637         $raw .= "lxc.idmap = u 0 100000 65536\n";
 638         $raw .= "lxc.idmap = g 0 100000 65536\n";
 639     }
 640
 641     if (!PVE::LXC::Config->has_dev_console($conf)) {
 642         $raw .= "lxc.console.path = none\n";
 643         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
 644     }
 645
 646     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 647     $raw .= "lxc.tty.max = $ttycount\n";
 648
 649     # some init scripts expect a linux terminal (turnkey).
 650     $raw .= "lxc.environment = TERM=linux\n";
 651
 652     my $utsname = $conf->{hostname} || "CT$vmid";
 653     $raw .= "lxc.uts.name = $utsname\n";
 654
 655     if ($cgv1->{memory}) {
 656         my $memory = $conf->{memory} || 512;
 657         my $swap = $conf->{swap} // 0;
 658
 659         my $lxcmem = int($memory*1024*1024);
 660         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 661
 662         my $lxcswap = int(($memory + $swap)*1024*1024);
 663         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 664     }
 665
 666     if ($cgv1->{cpu}) {
 667         if (my $cpulimit = $conf->{cpulimit}) {
 668             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 669             my $value = int(100000*$cpulimit);
 670             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 671         }
 672
 673         my $shares = $conf->{cpuunits} || 1024;
 674         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 675     }
 676
 677     die "missing 'rootfs' configuration\n"
 678         if !defined($conf->{rootfs});
 679
 680     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 681
 682     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 683
 684     foreach my $k (sort keys %$conf) {
 685         next if $k !~ m/^net(\d+)$/;
 686         my $ind = $1;
 687         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 688         $raw .= "lxc.net.$ind.type = veth\n";
 689         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 690         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 691         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 692         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 693
 694         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 695         if ($lxc_major >= 4) {
 696             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 697         }
 698     }
 699
 700     my $had_cpuset = 0;
 701     if (my $lxcconf = $conf->{lxc}) {
 702         foreach my $entry (@$lxcconf) {
 703             my ($k, $v) = @$entry;
 704             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 705             $raw .= "$k = $v\n";
 706         }
 707     }
 708
 709     my $cpuset;
 710     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::LXC::CGroup::cpuset_controller_path() };
 711     if (defined($cpuset_cgroup)) {
 712         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 713             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 714     }
 715     my $cores = $conf->{cores};
 716     if (!$had_cpuset && $cores && $cpuset) {
 717         my @members = $cpuset->members();
 718         while (scalar(@members) > $cores) {
 719             my $randidx = int(rand(scalar(@members)));
 720             $cpuset->delete($members[$randidx]);
 721             splice(@members, $randidx, 1); # keep track of the changes
 722         }
 723         my $ver = $cpuset_version == 1 ? '' : '2';
 724         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 725     }
 726
 727     File::Path::mkpath("$dir/rootfs");
 728
 729     PVE::Tools::file_set_contents("$dir/config", $raw);
 730 }
 731
 732 # verify and cleanup nameserver list (replace \0 with ' ')
 733 sub verify_nameserver_list {
 734     my ($nameserver_list) = @_;
 735
 736     my @list = ();
 737     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 738         PVE::JSONSchema::pve_verify_ip($server);
 739         push @list, $server;
 740     }
 741
 742     return join(' ', @list);
 743 }
 744
 745 sub verify_searchdomain_list {
 746     my ($searchdomain_list) = @_;
 747
 748     my @list = ();
 749     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 750         # todo: should we add checks for valid dns domains?
 751         push @list, $server;
 752     }
 753
 754     return join(' ', @list);
 755 }
 756
 757 sub get_console_command {
 758     my ($vmid, $conf, $escapechar) = @_;
 759
 760     # '-1' as $escapechar disables keyboard escape sequence
 761     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 762
 763     my $cmode = PVE::LXC::Config->get_cmode($conf);
 764
 765     my $cmd = [];
 766     if ($cmode eq 'console') {
 767         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 768         push @$cmd, '-e', $escapechar if $escapechar;
 769     } elsif ($cmode eq 'tty') {
 770         push @$cmd, 'lxc-console', '-n',  $vmid;
 771         push @$cmd, '-e', $escapechar if $escapechar;
 772     } elsif ($cmode eq 'shell') {
 773         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 774     } else {
 775         die "internal error";
 776     }
 777
 778     return $cmd;
 779 }
 780
 781 sub get_primary_ips {
 782     my ($conf) = @_;
 783
 784     # return data from net0
 785
 786     return undef if !defined($conf->{net0});
 787     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 788
 789     my $ipv4 = $net->{ip};
 790     if ($ipv4) {
 791         if ($ipv4 =~ /^(dhcp|manual)$/) {
 792             $ipv4 = undef
 793         } else {
 794             $ipv4 =~ s!/\d+$!!;
 795         }
 796     }
 797     my $ipv6 = $net->{ip6};
 798     if ($ipv6) {
 799         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 800             $ipv6 = undef;
 801         } else {
 802             $ipv6 =~ s!/\d+$!!;
 803         }
 804     }
 805
 806     return ($ipv4, $ipv6);
 807 }
 808
 809 sub delete_mountpoint_volume {
 810     my ($storage_cfg, $vmid, $volume) = @_;
 811
 812     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 813
 814     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 815
 816     if ($vmid == $owner) {
 817         PVE::Storage::vdisk_free($storage_cfg, $volume);
 818     } else {
 819         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 820     }
 821 }
 822
 823 sub destroy_lxc_container {
 824     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 825
 826     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, sub {
 827         my ($ms, $mountpoint) = @_;
 828         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 829     });
 830
 831     rmdir "/var/lib/lxc/$vmid/rootfs";
 832     unlink "/var/lib/lxc/$vmid/config";
 833     rmdir "/var/lib/lxc/$vmid";
 834     if (defined $replacement_conf) {
 835         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 836     } else {
 837         PVE::LXC::Config->destroy_config($vmid);
 838     }
 839 }
 840
 841 sub vm_stop_cleanup {
 842     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 843
 844     return if $keepActive;
 845
 846     eval {
 847         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 848         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 849     };
 850     warn $@ if $@; # avoid errors - just warn
 851 }
 852
 853 sub update_net {
 854     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 855
 856     if ($newnet->{type} ne 'veth') {
 857         # for when there are physical interfaces
 858         die "cannot update interface of type $newnet->{type}";
 859     }
 860
 861     my $veth = "veth${vmid}i${netid}";
 862     my $eth = $newnet->{name};
 863
 864     if (my $oldnetcfg = $conf->{$opt}) {
 865         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 866
 867         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 868             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 869
 870             PVE::Network::veth_delete($veth);
 871             delete $conf->{$opt};
 872             PVE::LXC::Config->write_config($vmid, $conf);
 873
 874             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 875
 876         } else {
 877             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 878                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 879                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 880
 881                 if ($oldnet->{bridge}) {
 882                     PVE::Network::tap_unplug($veth);
 883                     foreach (qw(bridge tag firewall)) {
 884                         delete $oldnet->{$_};
 885                     }
 886                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 887                     PVE::LXC::Config->write_config($vmid, $conf);
 888                 }
 889
 890                 if ($have_sdn) {
 891                     PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 892                 } else {
 893                     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 894                 }
 895
 896                 # This includes the rate:
 897                 foreach (qw(bridge tag firewall rate)) {
 898                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 899                 }
 900             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 901                 # Rate can be applied on its own but any change above needs to
 902                 # include the rate in tap_plug since OVS resets everything.
 903                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 904                 $oldnet->{rate} = $newnet->{rate}
 905             }
 906             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 907             PVE::LXC::Config->write_config($vmid, $conf);
 908         }
 909     } else {
 910         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 911     }
 912
 913     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 914 }
 915
 916 sub hotplug_net {
 917     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 918
 919     my $veth = "veth${vmid}i${netid}";
 920     my $vethpeer = $veth . "p";
 921     my $eth = $newnet->{name};
 922
 923     if ($have_sdn) {
 924         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 925         PVE::Network::SDN::Zones::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 926     } else {
 927         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 928         PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 929     }
 930
 931     # attach peer in container
 932     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 933     PVE::Tools::run_command($cmd);
 934
 935     # link up peer in container
 936     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 937     PVE::Tools::run_command($cmd);
 938
 939     my $done = { type => 'veth' };
 940     foreach (qw(bridge tag firewall hwaddr name)) {
 941         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 942     }
 943     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 944
 945     PVE::LXC::Config->write_config($vmid, $conf);
 946 }
 947
 948 sub update_ipconfig {
 949     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 950
 951     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 952
 953     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 954     my $deleted = [];
 955     my $added = [];
 956     my $nscmd = sub {
 957         my $cmdargs = shift;
 958         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 959     };
 960     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 961
 962     my $change_ip_config = sub {
 963         my ($ipversion) = @_;
 964
 965         my $family_opt = "-$ipversion";
 966         my $suffix = $ipversion == 4 ? '' : $ipversion;
 967         my $gw= "gw$suffix";
 968         my $ip= "ip$suffix";
 969
 970         my $newip = $newnet->{$ip};
 971         my $newgw = $newnet->{$gw};
 972         my $oldip = $optdata->{$ip};
 973         my $oldgw = $optdata->{$gw};
 974
 975         my $change_ip = safe_string_ne($oldip, $newip);
 976         my $change_gw = safe_string_ne($oldgw, $newgw);
 977
 978         return if !$change_ip && !$change_gw;
 979
 980         # step 1: add new IP, if this fails we cancel
 981         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 982         if ($change_ip && $is_real_ip) {
 983             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 984             if (my $err = $@) {
 985                 warn $err;
 986                 return;
 987             }
 988         }
 989
 990         # step 2: replace gateway
 991         #   If this fails we delete the added IP and cancel.
 992         #   If it succeeds we save the config and delete the old IP, ignoring
 993         #   errors. The config is then saved.
 994         # Note: 'ip route replace' can add
 995         if ($change_gw) {
 996             if ($newgw) {
 997                 eval {
 998                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
 999                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1000                     }
1001                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1002                 };
1003                 if (my $err = $@) {
1004                     warn $err;
1005                     # the route was not replaced, the old IP is still available
1006                     # rollback (delete new IP) and cancel
1007                     if ($change_ip) {
1008                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1009                         warn $@ if $@; # no need to die here
1010                     }
1011                     return;
1012                 }
1013             } else {
1014                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1015                 # if the route was not deleted, the guest might have deleted it manually
1016                 # warn and continue
1017                 warn $@ if $@;
1018             }
1019             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1020                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1021                 # warn if the route was deleted manually
1022                 warn $@ if $@;
1023             }
1024         }
1025
1026         # from this point on we save the configuration
1027         # step 3: delete old IP ignoring errors
1028         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1029             # We need to enable promote_secondaries, otherwise our newly added
1030             # address will be removed along with the old one.
1031             my $promote = 0;
1032             eval {
1033                 if ($ipversion == 4) {
1034                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1035                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1036                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1037                 }
1038                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1039             };
1040             warn $@ if $@; # no need to die here
1041
1042             if ($ipversion == 4) {
1043                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1044             }
1045         }
1046
1047         foreach my $property ($ip, $gw) {
1048             if ($newnet->{$property}) {
1049                 $optdata->{$property} = $newnet->{$property};
1050             } else {
1051                 delete $optdata->{$property};
1052             }
1053         }
1054         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1055         PVE::LXC::Config->write_config($vmid, $conf);
1056         $lxc_setup->setup_network($conf);
1057     };
1058
1059     &$change_ip_config(4);
1060     &$change_ip_config(6);
1061
1062 }
1063
1064 my $open_namespace = sub {
1065     my ($vmid, $pid, $kind) = @_;
1066     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1067         or die "failed to open $kind namespace of container $vmid: $!\n";
1068     return $fd;
1069 };
1070
1071 my $enter_namespace = sub {
1072     my ($vmid, $pid, $kind, $type) = @_;
1073     my $fd = $open_namespace->($vmid, $pid, $kind);
1074     PVE::Tools::setns(fileno($fd), $type)
1075         or die "failed to enter $kind namespace of container $vmid: $!\n";
1076     close $fd;
1077 };
1078
1079 my $get_container_namespace = sub {
1080     my ($vmid, $pid, $kind) = @_;
1081
1082     my $pidfd;
1083     if (!defined($pid)) {
1084         # Pin the pid while we're grabbing its stuff from /proc
1085         ($pid, $pidfd) = open_lxc_pid($vmid)
1086             or die "failed to open pidfd of container $vmid\'s init process\n";
1087     }
1088
1089     return $open_namespace->($vmid, $pid, $kind);
1090 };
1091
1092 my $do_syncfs = sub {
1093     my ($vmid, $pid, $socket) = @_;
1094
1095     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1096
1097     # Tell the parent process to start reading our /proc/mounts
1098     print {$socket} "go\n";
1099     $socket->flush();
1100
1101     # Receive /proc/self/mounts
1102     my $mountdata = do { local $/ = undef; <$socket> };
1103     close $socket;
1104
1105     # Now sync all mountpoints...
1106     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1107     foreach my $mp (@$mounts) {
1108         my ($what, $dir, $fs) = @$mp;
1109         next if $fs eq 'fuse.lxcfs';
1110         eval { PVE::Tools::sync_mountpoint($dir); };
1111         warn $@ if $@;
1112     }
1113 };
1114
1115 sub sync_container_namespace {
1116     my ($vmid) = @_;
1117     my $pid = find_lxc_pid($vmid);
1118
1119     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1120     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1121         or die "failed to create socketpair: $!\n";
1122
1123     my $child = fork();
1124     die "fork failed: $!\n" if !defined($child);
1125
1126     if (!$child) {
1127         eval {
1128             close $pfd;
1129             &$do_syncfs($vmid, $pid, $cfd);
1130         };
1131         if (my $err = $@) {
1132             warn $err;
1133             POSIX::_exit(1);
1134         }
1135         POSIX::_exit(0);
1136     }
1137     close $cfd;
1138     my $go = <$pfd>;
1139     die "failed to enter container namespace\n" if $go ne "go\n";
1140
1141     open my $mounts, '<', "/proc/$child/mounts"
1142         or die "failed to open container's /proc/mounts: $!\n";
1143     my $mountdata = do { local $/ = undef; <$mounts> };
1144     close $mounts;
1145     print {$pfd} $mountdata;
1146     close $pfd;
1147
1148     while (waitpid($child, 0) != $child) {}
1149     die "failed to sync container namespace\n" if $? != 0;
1150 }
1151
1152 sub template_create {
1153     my ($vmid, $conf) = @_;
1154
1155     my $storecfg = PVE::Storage::config();
1156
1157     PVE::LXC::Config->foreach_volume($conf, sub {
1158         my ($ms, $mountpoint) = @_;
1159
1160         my $volid = $mountpoint->{volume};
1161
1162         die "Template feature is not available for '$volid'\n"
1163             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1164     });
1165
1166     PVE::LXC::Config->foreach_volume($conf, sub {
1167         my ($ms, $mountpoint) = @_;
1168
1169         my $volid = $mountpoint->{volume};
1170
1171         PVE::Storage::activate_volumes($storecfg, [$volid]);
1172
1173         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1174         $mountpoint->{volume} = $template_volid;
1175         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1176     });
1177
1178     PVE::LXC::Config->write_config($vmid, $conf);
1179 }
1180
1181 sub check_ct_modify_config_perm {
1182     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1183
1184     return 1 if $authuser eq 'root@pam';
1185
1186     my $check = sub {
1187         my ($opt, $delete) = @_;
1188         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1189             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1190         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1191             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1192             return if $delete;
1193             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1194             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1195                 if $data->{type} ne 'volume';
1196         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1197             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1198         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1199                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1200             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1201         } elsif ($opt eq 'features') {
1202             # For now this is restricted to root@pam
1203             raise_perm_exc("changing feature flags is only allowed for root\@pam");
1204         } elsif ($opt eq 'hookscript') {
1205             # For now this is restricted to root@pam
1206             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1207         } else {
1208             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1209         }
1210     };
1211
1212     foreach my $opt (keys %$newconf) {
1213         &$check($opt, 0);
1214     }
1215     foreach my $opt (@$delete) {
1216         &$check($opt, 1);
1217     }
1218
1219     return 1;
1220 }
1221
1222 sub umount_all {
1223     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1224
1225     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1226     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1227
1228     my $res = 1;
1229
1230     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1231         my ($ms, $mountpoint) = @_;
1232
1233         my $volid = $mountpoint->{volume};
1234         my $mount = $mountpoint->{mp};
1235
1236         return if !$volid || !$mount;
1237
1238         my $mount_path = "$rootdir/$mount";
1239         $mount_path =~ s!/+!/!g;
1240
1241         return if !PVE::ProcFSTools::is_mounted($mount_path);
1242
1243         eval {
1244             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1245         };
1246         if (my $err = $@) {
1247             if ($noerr) {
1248                 $res = 0;
1249                 warn $err;
1250             } else {
1251                 die $err;
1252             }
1253         }
1254     });
1255
1256     return $res; # tell caller if (some) umounts failed for the noerr case
1257 }
1258
1259 sub mount_all {
1260     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1261
1262     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1263     File::Path::make_path($rootdir);
1264
1265     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1266     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1267
1268     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1269
1270     eval {
1271         PVE::LXC::Config->foreach_volume($conf, sub {
1272             my ($ms, $mountpoint) = @_;
1273
1274             $mountpoint->{ro} = 0 if $ignore_ro;
1275
1276             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1277         });
1278     };
1279     if (my $err = $@) {
1280         warn "mounting container failed\n";
1281         umount_all($vmid, $storage_cfg, $conf, 1);
1282         die $err;
1283     }
1284
1285     return $rootdir;
1286 }
1287
1288
1289 sub mountpoint_mount_path {
1290     my ($mountpoint, $storage_cfg, $snapname) = @_;
1291
1292     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1293 }
1294
1295 sub query_loopdev {
1296     my ($path) = @_;
1297     my $found;
1298     my $parser = sub {
1299         my $line = shift;
1300         if ($line =~ m@^(/dev/loop\d+):@) {
1301             $found = $1;
1302         }
1303     };
1304     my $cmd = ['losetup', '--associated', $path];
1305     PVE::Tools::run_command($cmd, outfunc => $parser);
1306     return $found;
1307 }
1308
1309 # Run a function with a file attached to a loop device.
1310 # The loop device is always detached afterwards (or set to autoclear).
1311 # Returns the loop device.
1312 sub run_with_loopdev {
1313     my ($func, $file, $readonly) = @_;
1314     my $device = query_loopdev($file);
1315     # Try to reuse an existing device
1316     if ($device) {
1317         # We assume that whoever setup the loop device is responsible for
1318         # detaching it.
1319         &$func($device);
1320         return $device;
1321     }
1322
1323     my $parser = sub {
1324         my $line = shift;
1325         if ($line =~ m@^(/dev/loop\d+)$@) {
1326             $device = $1;
1327         }
1328     };
1329     my $losetup_cmd = [
1330         'losetup',
1331         '--show',
1332         '-f',
1333         $file,
1334     ];
1335     push @$losetup_cmd, '-r' if $readonly;
1336     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1337     die "failed to setup loop device for $file\n" if !$device;
1338     eval { &$func($device); };
1339     my $err = $@;
1340     PVE::Tools::run_command(['losetup', '-d', $device]);
1341     die $err if $err;
1342     return $device;
1343 }
1344
1345 # In scalar mode: returns a file handle to the deepest directory node.
1346 # In list context: returns a list of:
1347 #   * the deepest directory node
1348 #   * the 2nd deepest directory (parent of the above)
1349 #   * directory name of the last directory
1350 # So that the path $2/$3 should lead to $1 afterwards.
1351 sub walk_tree_nofollow($$$;$$) {
1352     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1353
1354     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1355         or die "failed to open start directory $start: $!\n";
1356
1357     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1358 }
1359
1360
1361 sub walk_tree_nofollow_fd($$$$;$$) {
1362     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1363
1364     # splitdir() returns '' for empty components including the leading /
1365     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1366
1367     my $fd = $start_fd;
1368     my $dir = $start_dirname;
1369     my $last_component = undef;
1370     my $second = $fd;
1371     foreach my $component (@comps) {
1372         $dir .= "/$component";
1373         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1374
1375         if (!$next) {
1376             # failed, check for symlinks and try to create the path
1377             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1378             die "cannot open directory $dir: $!\n" if !$mkdir;
1379
1380             # We don't check for errors on mkdirat() here and just try to
1381             # openat() again, since at least one error (EEXIST) is an
1382             # expected possibility if multiple containers start
1383             # simultaneously. If someone else injects a symlink now then
1384             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1385             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1386
1387             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1388             die "failed to create path: $dir: $!\n" if !$next;
1389
1390             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1391                 if defined($rootuid) && defined($rootgid);
1392         }
1393
1394         close $second if defined($last_component) && $second != $start_fd;
1395         $last_component = $component;
1396         $second = $fd;
1397         $fd = $next;
1398     }
1399
1400     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1401     close $second if defined($last_component) && $second != $start_fd;
1402     return $fd;
1403 }
1404
1405 # To guard against symlink attack races against other currently running
1406 # containers with shared recursive bind mount hierarchies we prepare a
1407 # directory handle for the directory we're mounting over to verify the
1408 # mountpoint afterwards.
1409 sub __bindmount_prepare {
1410     my ($hostroot, $dir) = @_;
1411     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1412     return $srcdh;
1413 }
1414
1415 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1416 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1417 # we intended to bind mount.
1418 sub __bindmount_verify {
1419     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1420     my $destdh;
1421     if ($parentfd) {
1422         # Open the mount point path coming from the parent directory since the
1423         # filehandle we would have gotten as first result of walk_tree_nofollow
1424         # earlier is still a handle to the underlying directory instead of the
1425         # mounted path.
1426         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1427         die "failed to open mount point: $!\n" if !$destdh;
1428         if ($ro) {
1429             my $dot = '.';
1430             # no separate function because 99% of the time it's the wrong thing to use.
1431             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1432                 die "failed to mark bind mount read only\n";
1433             }
1434             die "read-only check failed: $!\n" if $! != EROFS;
1435         }
1436     } else {
1437         # For the rootfs we don't have a parentfd so we open the path directly.
1438         # Note that this means bindmounting any prefix of the host's
1439         # /var/lib/lxc/$vmid path into another container is considered a grave
1440         # security error.
1441         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1442         die "failed to open mount point: $!\n" if !$destdh;
1443     }
1444
1445     my ($srcdev, $srcinode) = stat($srcdh);
1446     my ($dstdev, $dstinode) = stat($destdh);
1447     close $srcdh;
1448     close $destdh;
1449
1450     return ($srcdev == $dstdev && $srcinode == $dstinode);
1451 }
1452
1453 # Perform the actual bind mounting:
1454 sub __bindmount_do {
1455     my ($dir, $dest, $ro, @extra_opts) = @_;
1456     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1457     if ($ro) {
1458         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1459         if (my $err = $@) {
1460             warn "bindmount error\n";
1461             # don't leave writable bind-mounts behind...
1462             PVE::Tools::run_command(['umount', $dest]);
1463             die $err;
1464         }
1465     }
1466 }
1467
1468 sub bindmount {
1469     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1470
1471     my $srcdh = __bindmount_prepare('/', $dir);
1472
1473     __bindmount_do($dir, $dest, $ro, @extra_opts);
1474
1475     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1476         PVE::Tools::run_command(['umount', $dest]);
1477         die "detected mount path change at: $dir\n";
1478     }
1479 }
1480
1481 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1482 # from $rootdir and $mount and walk the path from $rootdir to the final
1483 # directory to check for symlinks.
1484 sub __mount_prepare_rootdir {
1485     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1486     $rootdir =~ s!/+!/!g;
1487     $rootdir =~ s!/+$!!;
1488     my $mount_path = "$rootdir/$mount";
1489     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1490     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1491 }
1492
1493 # use $rootdir = undef to just return the corresponding mount path
1494 sub mountpoint_mount {
1495     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1496     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1497 }
1498
1499 sub mountpoint_stage {
1500     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1501     my ($path, $loop, $dev) =
1502         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1503
1504     if (!defined($path)) {
1505         return undef if $! == ENOSYS;
1506         die "failed to mount subvolume: $!\n";
1507     }
1508
1509     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1510     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1511     # point).
1512     my $err;
1513     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1514         or die "open_tree() on mount point failed: $!\n";
1515
1516     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1517 }
1518
1519 sub mountpoint_insert_staged {
1520     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1521
1522     if (!defined($rootdir_fd)) {
1523         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1524             or die "failed to open '.': $!\n";
1525     }
1526
1527     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1528
1529     PVE::Tools::move_mount(
1530         fileno($mount_fd),
1531         '',
1532         fileno($dest_fd),
1533         '',
1534         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1535     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1536 }
1537
1538 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1539 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1540 #   Note that if the kernel does not support the new mount API, this will not perform any action
1541 #   and return `undef` with $! = ENOSYS.
1542 sub __mountpoint_mount {
1543     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1544
1545     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1546         $! = ENOSYS;
1547         return undef;
1548     }
1549
1550     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1551     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1552     # which we use in __bindmount_verify()!
1553     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1554
1555     my $volid = $mountpoint->{volume};
1556     my $type = $mountpoint->{type};
1557     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1558     my $mounted_dev;
1559
1560     return if !$volid || !$mount;
1561
1562     $mount =~ s!/+!/!g;
1563
1564     my $mount_path;
1565     my ($mpfd, $parentfd, $last_dir);
1566
1567     if (defined($rootdir)) {
1568         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1569             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1570     }
1571
1572     if (defined($stage_mount)) {
1573         $mount_path = $rootdir;
1574     }
1575
1576     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1577
1578     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1579
1580     my $optlist = [];
1581
1582     if (my $mountopts = $mountpoint->{mountoptions}) {
1583         my @opts = split(/;/, $mountpoint->{mountoptions});
1584         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1585     }
1586
1587     my $acl = $mountpoint->{acl};
1588     if (defined($acl)) {
1589         push @$optlist, ($acl ? 'acl' : 'noacl');
1590     }
1591
1592     my $optstring = join(',', @$optlist);
1593     my $readonly = $mountpoint->{ro};
1594
1595     my @extra_opts;
1596     @extra_opts = ('-o', $optstring) if $optstring;
1597
1598     if ($storage) {
1599
1600         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1601
1602         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1603
1604         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1605
1606         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1607             PVE::Storage::parse_volname($storage_cfg, $volid);
1608
1609         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1610
1611         if ($format eq 'subvol') {
1612             if ($mount_path) {
1613                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1614                 if (defined($snapname)) {
1615                     $name .= "\@$snapname";
1616                     if ($scfg->{type} eq 'zfspool') {
1617                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1618                     } else {
1619                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1620                     }
1621                 } else {
1622                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1623                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1624                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1625                     }
1626                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1627                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1628                 }
1629             }
1630             return wantarray ? ($path, 0, undef) : $path;
1631         } elsif ($format eq 'raw' || $format eq 'iso') {
1632             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1633             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1634             # Our autodev hook expects the /dev/dm-* device currently
1635             # and will create the /dev/mapper symlink accordingly
1636             $path = Cwd::realpath($path);
1637             die "failed to get device path\n" if !$path;
1638             ($path) = ($path =~ /^(.*)$/s); #untaint
1639             my $domount = sub {
1640                 my ($path) = @_;
1641                 if ($mount_path) {
1642                     if ($format eq 'iso') {
1643                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1644                     } elsif ($isBase || defined($snapname)) {
1645                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1646                     } else {
1647                         if ($quota) {
1648                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1649                         }
1650                         push @extra_opts, '-o', 'ro' if $readonly;
1651                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1652                     }
1653                 }
1654             };
1655             my $use_loopdev = 0;
1656             if ($scfg->{path}) {
1657                 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1658                 $use_loopdev = 1;
1659             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1660                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1661                 $mounted_dev = $path;
1662                 &$domount($path);
1663             } else {
1664                 die "unsupported storage type '$scfg->{type}'\n";
1665             }
1666             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1667         } else {
1668             die "unsupported image format '$format'\n";
1669         }
1670     } elsif ($type eq 'device') {
1671         push @extra_opts, '-o', 'ro' if $readonly;
1672         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1673         # See the NOTE above about devicemapper canonicalization
1674         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1675         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1676         return wantarray ? ($volid, 0, $devpath) : $volid;
1677     } elsif ($type eq 'bind') {
1678         die "directory '$volid' does not exist\n" if ! -d $volid;
1679         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1680         warn "cannot enable quota control for bind mounts\n" if $quota;
1681         return wantarray ? ($volid, 0, undef) : $volid;
1682     }
1683
1684     die "unsupported storage";
1685 }
1686
1687 sub mountpoint_hotplug($$$) {
1688     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1689
1690     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1691
1692     # We do the rest in a fork with an unshared mount namespace, because:
1693     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1694     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1695     #     container's namespace, then mount it.
1696
1697     PVE::Tools::run_fork(sub {
1698         # Pin the container pid longer, we also need to get its monitor/parent:
1699         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1700             or die "failed to open pidfd of container $vmid\'s init process\n";
1701
1702         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1703             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1704
1705         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1706         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1707
1708         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1709         # profile to lower our privileges to the same level we have in the start hook:
1710         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1711             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1712         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1713         # apparmor.
1714
1715         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1716         # namespace for it to remain active there since the container will be able to unmount
1717         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1718         # concern.
1719         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1720         chdir('/')
1721             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1722
1723         my $dir = get_staging_mount_path($opt);
1724
1725         # Now switch our apparmor profile before mounting:
1726         my $data = 'changeprofile /usr/bin/lxc-start';
1727         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1728             die "failed to change apparmor profile: $!\n";
1729         }
1730         # Check errors on close as well:
1731         close($aa_fd)
1732             or die "failed to change apparmor profile (close() failed): $!\n";
1733
1734         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1735
1736         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1737         chdir('/')
1738             or die "failed to change root directory within the container's mount namespace: $!\n";
1739
1740         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1741     });
1742 }
1743
1744 # Create a directory in the mountpoint staging tempfs.
1745 sub get_staging_mount_path($) {
1746     my ($opt) = @_;
1747
1748     my $target = get_staging_tempfs() . "/$opt";
1749     if (!mkdir($target) && $! != EEXIST) {
1750         die "failed to create directory $target: $!\n";
1751     }
1752
1753     return $target;
1754 }
1755
1756 # Mount /run/pve/mountpoints as tmpfs
1757 sub get_staging_tempfs() {
1758     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1759     # mounts to that.
1760     my $target = '/var/lib/lxc/.pve-staged-mounts';
1761     if (!mkdir($target)) {
1762         return $target if $! == EEXIST;
1763         die "failed to create directory $target: $!\n";
1764     }
1765
1766     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1767         or die "failed to mount $target as tmpfs: $!\n";
1768
1769     return $target;
1770 }
1771
1772 sub mkfs {
1773     my ($dev, $rootuid, $rootgid) = @_;
1774
1775     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1776                              '-E', "root_owner=$rootuid:$rootgid",
1777                              $dev]);
1778 }
1779
1780 sub format_disk {
1781     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1782
1783     if ($volid =~ m!^/dev/.+!) {
1784         mkfs($volid);
1785         return;
1786     }
1787
1788     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1789
1790     die "cannot format volume '$volid' with no storage\n" if !$storage;
1791
1792     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1793
1794     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1795
1796     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1797
1798     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1799         PVE::Storage::parse_volname($storage_cfg, $volid);
1800
1801     die "cannot format volume '$volid' (format == $format)\n"
1802         if $format ne 'raw';
1803
1804     mkfs($path, $rootuid, $rootgid);
1805 }
1806
1807 sub destroy_disks {
1808     my ($storecfg, $vollist) = @_;
1809
1810     foreach my $volid (@$vollist) {
1811         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1812         warn $@ if $@;
1813     }
1814 }
1815
1816 sub alloc_disk {
1817     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1818
1819     my $needs_chown = 0;
1820     my $volid;
1821
1822     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1823     # fixme: use better naming ct-$vmid-disk-X.raw?
1824
1825     eval {
1826         my $do_format = 0;
1827         if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1828             if ($size_kb > 0) {
1829                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1830                                                    undef, $size_kb);
1831                 $do_format = 1;
1832             } else {
1833                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1834                                                    undef, 0);
1835                 $needs_chown = 1;
1836             }
1837         } elsif ($scfg->{type} eq 'zfspool') {
1838
1839             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1840                                                undef, $size_kb);
1841             $needs_chown = 1;
1842         } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1843
1844             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1845             $do_format = 1;
1846
1847         } elsif ($scfg->{type} eq 'rbd') {
1848
1849             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1850             $do_format = 1;
1851         } else {
1852             die "unable to create containers on storage type '$scfg->{type}'\n";
1853         }
1854         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1855     };
1856     if (my $err = $@) {
1857         # in case formatting got interrupted:
1858         if (defined($volid)) {
1859             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1860             warn $@ if $@;
1861         }
1862         die $err;
1863     }
1864
1865     return ($volid, $needs_chown);
1866 }
1867
1868 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1869 sub create_disks {
1870     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1871
1872     my $vollist = [];
1873
1874     eval {
1875         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1876         my $chown_vollist = [];
1877
1878         PVE::LXC::Config->foreach_volume($settings, sub {
1879             my ($ms, $mountpoint) = @_;
1880
1881             my $volid = $mountpoint->{volume};
1882             my $mp = $mountpoint->{mp};
1883
1884             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1885
1886             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1887                 my ($storeid, $size_gb) = ($1, $2);
1888
1889                 my $size_kb = int(${size_gb}*1024) * 1024;
1890
1891                 my $needs_chown = 0;
1892                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1893                 push @$chown_vollist, $volid if $needs_chown;
1894                 push @$vollist, $volid;
1895                 $mountpoint->{volume} = $volid;
1896                 $mountpoint->{size} = $size_kb * 1024;
1897                 if ($pending) {
1898                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1899                 } else {
1900                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1901                 }
1902             } else {
1903                 # use specified/existing volid/dir/device
1904                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1905             }
1906         });
1907
1908         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1909         foreach my $volid (@$chown_vollist) {
1910             my $path = PVE::Storage::path($storecfg, $volid, undef);
1911             chown($rootuid, $rootgid, $path);
1912         }
1913         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1914     };
1915     # free allocated images on error
1916     if (my $err = $@) {
1917         destroy_disks($storecfg, $vollist);
1918         die $err;
1919     }
1920     return $vollist;
1921 }
1922
1923 sub update_disksize {
1924     my ($vmid, $conf, $all_volumes) = @_;
1925
1926     my $changes;
1927     my $prefix = "CT $vmid:";
1928
1929     my $update_mp = sub {
1930         my ($key, $mp, @param) = @_;
1931         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1932
1933         if (!defined($mp->{size}) || $size != $mp->{size}) {
1934             $changes = 1;
1935             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1936             $mp->{size} = $size;
1937             my $nomp = 1 if ($key eq 'rootfs');
1938             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1939         }
1940     };
1941
1942     PVE::LXC::Config->foreach_volume($conf, $update_mp);
1943
1944     return $changes;
1945 }
1946
1947 sub update_unused {
1948     my ($vmid, $conf, $all_volumes) = @_;
1949
1950     my $changes;
1951     my $prefix = "CT $vmid:";
1952
1953     # Note: it is allowed to define multiple storage entries with the same path
1954     # (alias), so we need to check both 'volid' and real 'path' (two different
1955     # volid can point to the same path).
1956
1957     # used and unused disks
1958     my $refpath = {};
1959     my $orphans = {};
1960
1961     foreach my $opt (keys %$conf) {
1962         next if ($opt !~ m/^unused\d+$/);
1963         my $vol = $all_volumes->{$conf->{$opt}};
1964         $refpath->{$vol->{path}} = $vol->{volid};
1965     }
1966
1967     foreach my $key (keys %$all_volumes) {
1968         my $vol = $all_volumes->{$key};
1969         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
1970         my $path = $vol->{path};
1971
1972         if ($in_use) {
1973             $refpath->{$path} = $key;
1974             delete $orphans->{$path};
1975         } else {
1976             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
1977                 $orphans->{$path} = $key;
1978             }
1979         }
1980     }
1981
1982     for my $key (keys %$orphans) {
1983         my $disk = $orphans->{$key};
1984         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
1985
1986         if ($unused) {
1987             $changes = 1;
1988             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
1989         }
1990     }
1991
1992     return $changes;
1993 }
1994
1995 sub scan_volids {
1996     my ($cfg, $vmid) = @_;
1997
1998     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid);
1999
2000     my $all_volumes = {};
2001     foreach my $storeid (keys %$info) {
2002         foreach my $item (@{$info->{$storeid}}) {
2003             my $volid = $item->{volid};
2004             next if !($volid && $item->{size});
2005             $item->{path} = PVE::Storage::path($cfg, $volid);
2006             $all_volumes->{$volid} = $item;
2007         }
2008     }
2009
2010     return $all_volumes;
2011 }
2012
2013 sub rescan {
2014     my ($vmid, $nolock, $dryrun) = @_;
2015
2016     my $cfg = PVE::Storage::config();
2017
2018     # FIXME: Remove once our RBD plugin can handle CT and VM on a single storage
2019     # see: https://pve.proxmox.com/pipermail/pve-devel/2018-July/032900.html
2020     foreach my $stor (keys %{$cfg->{ids}}) {
2021         delete($cfg->{ids}->{$stor}) if !$cfg->{ids}->{$stor}->{content}->{rootdir};
2022     }
2023
2024     print "rescan volumes...\n";
2025     my $all_volumes = scan_volids($cfg, $vmid);
2026
2027     my $updatefn =  sub {
2028         my ($vmid) = @_;
2029
2030         my $changes;
2031         my $conf = PVE::LXC::Config->load_config($vmid);
2032
2033         PVE::LXC::Config->check_lock($conf);
2034
2035         my $vm_volids = {};
2036         foreach my $volid (keys %$all_volumes) {
2037             my $info = $all_volumes->{$volid};
2038             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2039         }
2040
2041         my $upu = update_unused($vmid, $conf, $vm_volids);
2042         my $upd = update_disksize($vmid, $conf, $vm_volids);
2043         $changes = $upu || $upd;
2044
2045         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2046     };
2047
2048     if (defined($vmid)) {
2049         if ($nolock) {
2050             &$updatefn($vmid);
2051         } else {
2052             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2053         }
2054     } else {
2055         my $vmlist = config_list();
2056         foreach my $vmid (keys %$vmlist) {
2057             if ($nolock) {
2058                 &$updatefn($vmid);
2059             } else {
2060                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2061             }
2062         }
2063     }
2064 }
2065
2066
2067 # bash completion helper
2068
2069 sub complete_os_templates {
2070     my ($cmdname, $pname, $cvalue) = @_;
2071
2072     my $cfg = PVE::Storage::config();
2073
2074     my $storeid;
2075
2076     if ($cvalue =~ m/^([^:]+):/) {
2077         $storeid = $1;
2078     }
2079
2080     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2081     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2082
2083     my $res = [];
2084     foreach my $id (keys %$data) {
2085         foreach my $item (@{$data->{$id}}) {
2086             push @$res, $item->{volid} if defined($item->{volid});
2087         }
2088     }
2089
2090     return $res;
2091 }
2092
2093 my $complete_ctid_full = sub {
2094     my ($running) = @_;
2095
2096     my $idlist = vmstatus();
2097
2098     my $active_hash = list_active_containers();
2099
2100     my $res = [];
2101
2102     foreach my $id (keys %$idlist) {
2103         my $d = $idlist->{$id};
2104         if (defined($running)) {
2105             next if $d->{template};
2106             next if $running && !$active_hash->{$id};
2107             next if !$running && $active_hash->{$id};
2108         }
2109         push @$res, $id;
2110
2111     }
2112     return $res;
2113 };
2114
2115 sub complete_ctid {
2116     return &$complete_ctid_full();
2117 }
2118
2119 sub complete_ctid_stopped {
2120     return &$complete_ctid_full(0);
2121 }
2122
2123 sub complete_ctid_running {
2124     return &$complete_ctid_full(1);
2125 }
2126
2127 sub parse_id_maps {
2128     my ($conf) = @_;
2129
2130     my $id_map = [];
2131     my $rootuid = 0;
2132     my $rootgid = 0;
2133
2134     my $lxc = $conf->{lxc};
2135     foreach my $entry (@$lxc) {
2136         my ($key, $value) = @$entry;
2137         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
2138         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
2139         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2140             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2141             push @$id_map, [$type, $ct, $host, $length];
2142             if ($ct == 0) {
2143                 $rootuid = $host if $type eq 'u';
2144                 $rootgid = $host if $type eq 'g';
2145             }
2146         } else {
2147             die "failed to parse idmap: $value\n";
2148         }
2149     }
2150
2151     if (!@$id_map && $conf->{unprivileged}) {
2152         # Should we read them from /etc/subuid?
2153         $id_map = [ ['u', '0', '100000', '65536'],
2154                     ['g', '0', '100000', '65536'] ];
2155         $rootuid = $rootgid = 100000;
2156     }
2157
2158     return ($id_map, $rootuid, $rootgid);
2159 }
2160
2161 sub userns_command {
2162     my ($id_map) = @_;
2163     if (@$id_map) {
2164         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2165     }
2166     return [];
2167 }
2168
2169 sub vm_start {
2170     my ($vmid, $conf, $skiplock) = @_;
2171
2172     # apply pending changes while starting
2173     if (scalar(keys %{$conf->{pending}})) {
2174         my $storecfg = PVE::Storage::config();
2175         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2176         PVE::LXC::Config->write_config($vmid, $conf);
2177         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2178     }
2179
2180     update_lxc_config($vmid, $conf);
2181
2182     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2183
2184     if ($skiplock) {
2185         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2186         close($fh);
2187     }
2188
2189     my $storage_cfg = PVE::Storage::config();
2190     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2191
2192     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2193
2194     my $cmd = ['systemctl', 'start', "pve-container\@$vmid"];
2195
2196     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2197     eval { PVE::Tools::run_command($cmd); };
2198     if (my $err = $@) {
2199         unlink $skiplock_flag_fn;
2200         die $err;
2201     }
2202     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2203
2204     return;
2205 }
2206
2207 # Helper to stop a container completely and make sure it has stopped completely.
2208 # This is necessary because we want the post-stop hook to have completed its
2209 # unmount-all step, but post-stop happens after lxc puts the container into the
2210 # STOPPED state.
2211 # $kill - if true it will always do an immediate hard-stop
2212 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2213 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2214 sub vm_stop {
2215     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2216
2217     # Open the container's command socket.
2218     my $path = "\0/var/lib/lxc/$vmid/command";
2219     my $sock = IO::Socket::UNIX->new(
2220         Type => SOCK_STREAM(),
2221         Peer => $path,
2222     );
2223     if (!$sock) {
2224         return if $! == ECONNREFUSED; # The container is not running
2225         die "failed to open container ${vmid}'s command socket: $!\n";
2226     }
2227
2228     my $conf = PVE::LXC::Config->load_config($vmid);
2229     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2230
2231     # Stop the container:
2232
2233     my $cmd = ['lxc-stop', '-n', $vmid];
2234
2235     if ($kill) {
2236         push @$cmd, '--kill'; # doesn't allow timeouts
2237     } else {
2238         # lxc-stop uses a default timeout
2239         push @$cmd, '--nokill' if !$kill_after_timeout;
2240
2241         if (defined($shutdown_timeout)) {
2242             push @$cmd, '--timeout', $shutdown_timeout;
2243             # Give run_command 5 extra seconds
2244             $shutdown_timeout += 5;
2245         }
2246     }
2247
2248     eval { PVE::Tools::run_command($cmd, timeout => $shutdown_timeout) };
2249     if (my $err = $@) {
2250         warn $@ if $@;
2251     }
2252
2253     my $result = <$sock>;
2254
2255     return if !defined $result; # monitor is gone and the ct has stopped.
2256     die "container did not stop\n";
2257 }
2258
2259 sub vm_reboot {
2260     my ($vmid, $timeout, $skiplock) = @_;
2261
2262     PVE::LXC::Config->lock_config($vmid, sub {
2263         return if !check_running($vmid);
2264
2265         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2266
2267         my $conf = PVE::LXC::Config->load_config($vmid);
2268         vm_start($vmid, $conf);
2269     });
2270 }
2271
2272 sub run_unshared {
2273     my ($code) = @_;
2274
2275     return PVE::Tools::run_fork(sub {
2276         # Unshare the mount namespace
2277         die "failed to unshare mount namespace: $!\n"
2278             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2279         PVE::Tools::run_command(['mount', '--make-rslave', '/']);
2280         return $code->();
2281     });
2282 }
2283
2284 my $copy_volume = sub {
2285     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2286
2287     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2288     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2289
2290     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2291     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2292
2293     my @mounted;
2294     eval {
2295         # mount and copy
2296         mkdir $src;
2297         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2298         push @mounted, $src;
2299         mkdir $dest;
2300         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2301         push @mounted, $dest;
2302
2303         $bwlimit //= 0;
2304
2305         PVE::Tools::run_command(['/usr/bin/rsync', '--stats', '-X', '-A', '--numeric-ids',
2306                                  '-aH', '--whole-file', '--sparse', '--one-file-system',
2307                                  "--bwlimit=$bwlimit", "$src/", $dest]);
2308     };
2309     my $err = $@;
2310
2311     # Wait for rsync's children to release dest so that
2312     # consequent file operations (umount, remove) are possible
2313     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2314
2315     foreach my $mount (reverse @mounted) {
2316         eval { PVE::Tools::run_command(['/bin/umount', $mount], errfunc => sub{})};
2317         warn "Can't umount $mount\n" if $@;
2318     }
2319
2320     # If this fails they're used as mount points in a concurrent operation
2321     # (which should not happen but there's also no real need to get rid of them).
2322     rmdir $dest;
2323     rmdir $src;
2324
2325     die $err if $err;
2326 };
2327
2328 # Should not be called after unsharing the mount namespace!
2329 sub copy_volume {
2330     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2331
2332     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2333     File::Path::make_path("/var/lib/lxc/$vmid");
2334     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2335     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2336
2337     # get id's for unprivileged container
2338     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2339
2340     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2341     # are visible in this namespace, otherwise the host only sees the empty
2342     # (not-mounted) directory.
2343     my $new_volid;
2344     eval {
2345         # Make sure $mp contains a correct size.
2346         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2347         my $needs_chown;
2348         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2349         if ($needs_chown) {
2350             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2351             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2352             chown($rootuid, $rootgid, $path);
2353         }
2354
2355         run_unshared(sub {
2356             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2357         });
2358     };
2359     if (my $err = $@) {
2360         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2361             if defined($new_volid);
2362         die $err;
2363     }
2364
2365     return $new_volid;
2366 }
2367
2368 sub get_lxc_version() {
2369     my $version;
2370     PVE::Tools::run_command([qw(lxc-start --version)], outfunc => sub {
2371         my ($line) = @_;
2372         # We only parse out major & minor version numbers.
2373         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2374             $version = [$1, $2];
2375         }
2376     });
2377
2378     die "failed to get lxc version\n" if !defined($version);
2379
2380     # return as a list:
2381     return $version->@*;
2382 }
2383
2384 sub freeze($) {
2385     my ($vmid) = @_;
2386     PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2387 }
2388
2389 sub thaw($) {
2390     my ($vmid) = @_;
2391     PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2392 }
2393
2394 1;