src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED ENOSYS);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw($IPV6RE $IPV4RE dir_glob_foreach lock_file lock_file_full O_PATH AT_FDCWD);
  23 use PVE::CpuSet;
  24 use PVE::Network;
  25 use PVE::AccessControl;
  26 use PVE::ProcFSTools;
  27 use PVE::Syscall qw(:fsmount);
  28 use PVE::LXC::Config;
  29 use PVE::GuestHelpers;
  30 use PVE::LXC::Tools;
  31
  32 use Time::HiRes qw (gettimeofday);
  33
  34 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  35
  36 my $nodename = PVE::INotify::nodename();
  37
  38 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  39
  40 sub config_list {
  41     my $vmlist = PVE::Cluster::get_vmlist();
  42     my $res = {};
  43     return $res if !$vmlist || !$vmlist->{ids};
  44     my $ids = $vmlist->{ids};
  45
  46     foreach my $vmid (keys %$ids) {
  47         next if !$vmid; # skip CT0
  48         my $d = $ids->{$vmid};
  49         next if !$d->{node} || $d->{node} ne $nodename;
  50         next if !$d->{type} || $d->{type} ne 'lxc';
  51         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  52     }
  53     return $res;
  54 }
  55
  56 # container status helpers
  57
  58 sub list_active_containers {
  59
  60     my $filename = "/proc/net/unix";
  61
  62     # similar test is used by lcxcontainers.c: list_active_containers
  63     my $res = {};
  64
  65     my $fh = IO::File->new ($filename, "r");
  66     return $res if !$fh;
  67
  68     while (defined(my $line = <$fh>)) {
  69         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  70             my $path = $1;
  71             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  72                 $res->{$1} = 1;
  73             }
  74         }
  75     }
  76
  77     close($fh);
  78
  79     return $res;
  80 }
  81
  82 # warning: this is slow
  83 sub check_running {
  84     my ($vmid) = @_;
  85
  86     my $active_hash = list_active_containers();
  87
  88     return 1 if defined($active_hash->{$vmid});
  89
  90     return undef;
  91 }
  92
  93 sub get_container_disk_usage {
  94     my ($vmid, $pid) = @_;
  95
  96     return PVE::Tools::df("/proc/$pid/root/", 1);
  97 }
  98
  99 my $last_proc_vmid_stat;
 100
 101 my $parse_cpuacct_stat = sub {
 102     my ($vmid, $unprivileged) = @_;
 103
 104     my $raw = read_cgroup_value('cpuacct', $vmid, $unprivileged, 'cpuacct.stat', 1);
 105
 106     my $stat = {};
 107
 108     if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
 109
 110         $stat->{utime} = $1;
 111         $stat->{stime} = $2;
 112
 113     }
 114
 115     return $stat;
 116 };
 117
 118 our $vmstatus_return_properties = {
 119     vmid => get_standard_option('pve-vmid'),
 120     status => {
 121         description => "LXC Container status.",
 122         type => 'string',
 123         enum => ['stopped', 'running'],
 124     },
 125     maxmem => {
 126         description => "Maximum memory in bytes.",
 127         type => 'integer',
 128         optional => 1,
 129         renderer => 'bytes',
 130     },
 131     maxswap => {
 132         description => "Maximum SWAP memory in bytes.",
 133         type => 'integer',
 134         optional => 1,
 135         renderer => 'bytes',
 136     },
 137     maxdisk => {
 138         description => "Root disk size in bytes.",
 139         type => 'integer',
 140         optional => 1,
 141         renderer => 'bytes',
 142     },
 143     name => {
 144         description => "Container name.",
 145         type => 'string',
 146         optional => 1,
 147     },
 148     uptime => {
 149         description => "Uptime.",
 150         type => 'integer',
 151         optional => 1,
 152         renderer => 'duration',
 153     },
 154     cpus => {
 155         description => "Maximum usable CPUs.",
 156         type => 'number',
 157         optional => 1,
 158     },
 159     lock => {
 160         description => "The current config lock, if any.",
 161         type => 'string',
 162         optional => 1,
 163     }
 164 };
 165
 166 sub vmstatus {
 167     my ($opt_vmid) = @_;
 168
 169     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
 170
 171     my $active_hash = list_active_containers();
 172
 173     my $cpucount = $cpuinfo->{cpus} || 1;
 174
 175     my $cdtime = gettimeofday;
 176
 177     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 178     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 179
 180     my $unprivileged = {};
 181
 182     foreach my $vmid (keys %$list) {
 183         my $d = $list->{$vmid};
 184
 185         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 186         warn $@ if $@; # ignore errors (consider them stopped)
 187
 188         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 189
 190         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 191         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 192
 193         $unprivileged->{$vmid} = $conf->{unprivileged};
 194
 195         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 196         $d->{name} =~ s/[\s]//g;
 197
 198         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 199         $d->{cpus} = $cpucount if !$d->{cpus};
 200
 201         $d->{lock} = $conf->{lock} || '';
 202
 203         if ($d->{pid}) {
 204             my $res = get_container_disk_usage($vmid, $d->{pid});
 205             $d->{disk} = $res->{used};
 206             $d->{maxdisk} = $res->{total};
 207         } else {
 208             $d->{disk} = 0;
 209             # use 4GB by default ??
 210             if (my $rootfs = $conf->{rootfs}) {
 211                 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
 212                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 213             } else {
 214                 $d->{maxdisk} = 4*1024*1024*1024;
 215             }
 216         }
 217
 218         $d->{mem} = 0;
 219         $d->{swap} = 0;
 220         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 221         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 222
 223         $d->{uptime} = 0;
 224         $d->{cpu} = 0;
 225
 226         $d->{netout} = 0;
 227         $d->{netin} = 0;
 228
 229         $d->{diskread} = 0;
 230         $d->{diskwrite} = 0;
 231
 232         $d->{template} = PVE::LXC::Config->is_template($conf);
 233         $d->{lock} = $conf->{lock} if $conf->{lock};
 234     }
 235
 236     foreach my $vmid (keys %$list) {
 237         my $d = $list->{$vmid};
 238         my $pid = $d->{pid};
 239
 240         next if !$pid; # skip stopped CTs
 241
 242         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 243         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 244
 245         my $unpriv = $unprivileged->{$vmid};
 246
 247         if (-d '/sys/fs/cgroup/memory') {
 248             my $memory_stat = read_cgroup_list('memory', $vmid, $unpriv, 'memory.stat');
 249             my $mem_usage_in_bytes = read_cgroup_value('memory', $vmid, $unpriv, 'memory.usage_in_bytes');
 250
 251             $d->{mem} = $mem_usage_in_bytes - $memory_stat->{total_cache};
 252             $d->{swap} = read_cgroup_value('memory', $vmid, $unpriv, 'memory.memsw.usage_in_bytes') - $mem_usage_in_bytes;
 253         } else {
 254             $d->{mem} = 0;
 255             $d->{swap} = 0;
 256         }
 257
 258         if (-d '/sys/fs/cgroup/blkio') {
 259             my $blkio_bytes = read_cgroup_value('blkio', $vmid, 0, 'blkio.throttle.io_service_bytes', 1); # don't check if unpriv
 260             my @bytes = split(/\n/, $blkio_bytes);
 261             foreach my $byte (@bytes) {
 262                 if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 263                     $d->{diskread} += $2 if $key eq 'Read';
 264                     $d->{diskwrite} += $2 if $key eq 'Write';
 265                 }
 266             }
 267         } else {
 268             $d->{diskread} = 0;
 269             $d->{diskwrite} = 0;
 270         }
 271
 272         if (-d '/sys/fs/cgroup/cpuacct') {
 273             my $pstat = $parse_cpuacct_stat->($vmid, $unpriv);
 274
 275             my $used = $pstat->{utime} + $pstat->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $dtime = ($cdtime -  $old->{time}) * $cpucount * $cpuinfo->{user_hz};
 288
 289             if ($dtime > 1000) {
 290                 my $dutime = $used -  $old->{used};
 291
 292                 $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
 293                 $last_proc_vmid_stat->{$vmid} = {
 294                     time => $cdtime,
 295                     used => $used,
 296                     cpu => $d->{cpu},
 297                 };
 298             } else {
 299                 $d->{cpu} = $old->{cpu};
 300             }
 301         } else {
 302             $d->{cpu} = 0;
 303         }
 304     }
 305
 306     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 307
 308     foreach my $dev (keys %$netdev) {
 309         next if $dev !~ m/^veth([1-9]\d*)i/;
 310         my $vmid = $1;
 311         my $d = $list->{$vmid};
 312
 313         next if !$d;
 314
 315         $d->{netout} += $netdev->{$dev}->{receive};
 316         $d->{netin} += $netdev->{$dev}->{transmit};
 317
 318     }
 319
 320     return $list;
 321 }
 322
 323 sub read_cgroup_list($$$$) {
 324     my ($group, $vmid, $unprivileged, $name) = @_;
 325
 326     my $content = read_cgroup_value($group, $vmid, $unprivileged, $name, 1);
 327
 328     return { split(/\s+/, $content) };
 329 }
 330
 331 sub read_cgroup_value($$$$$) {
 332     my ($group, $vmid, $unprivileged, $name, $full) = @_;
 333
 334     my $nsdir = $unprivileged ? '' : 'ns/';
 335     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/${nsdir}$name";
 336
 337     return PVE::Tools::file_get_contents($path) if $full;
 338
 339     return PVE::Tools::file_read_firstline($path);
 340 }
 341
 342 sub write_cgroup_value {
 343    my ($group, $vmid, $name, $value) = @_;
 344
 345    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 346    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 347
 348 }
 349
 350 sub find_lxc_console_pids {
 351
 352     my $res = {};
 353
 354     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 355         my ($pid) = @_;
 356
 357         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 358         return if !$cmdline;
 359
 360         my @args = split(/\0/, $cmdline);
 361
 362         # search for lxc-console -n <vmid>
 363         return if scalar(@args) != 3;
 364         return if $args[1] ne '-n';
 365         return if $args[2] !~ m/^\d+$/;
 366         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 367
 368         my $vmid = $args[2];
 369
 370         push @{$res->{$vmid}}, $pid;
 371     });
 372
 373     return $res;
 374 }
 375
 376 sub find_lxc_pid {
 377     my ($vmid) = @_;
 378
 379     my $pid = undef;
 380     my $parser = sub {
 381         my $line = shift;
 382         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 383     };
 384     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 385
 386     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 387
 388     return $pid;
 389 }
 390
 391 # Note: we cannot use Net:IP, because that only allows strict
 392 # CIDR networks
 393 sub parse_ipv4_cidr {
 394     my ($cidr, $noerr) = @_;
 395
 396     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 397         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 398     }
 399
 400     return undef if $noerr;
 401
 402     die "unable to parse ipv4 address/mask\n";
 403 }
 404
 405 sub get_cgroup_subsystems {
 406         my $v1 = {};
 407         my $v2 = 0;
 408         my $data = PVE::Tools::file_get_contents('/proc/self/cgroup');
 409         while ($data =~ /^\d+:([^:\n]*):.*$/gm) {
 410                 my $type = $1;
 411                 if (length($type)) {
 412                         $v1->{$_} = 1 foreach split(/,/, $type);
 413                 } else {
 414                         $v2 = 1;
 415                 }
 416         }
 417         return wantarray ? ($v1, $v2) : $v1;
 418 }
 419
 420 # Currently we do not need to create seccomp profile 'files' as the only
 421 # choice our configuration actually allows is "with or without keyctl()",
 422 # so we distinguish between using lxc's "default" seccomp profile and our
 423 # added pve-userns.seccomp file.
 424 #
 425 # This returns a configuration line added to the raw lxc config.
 426 sub make_seccomp_config {
 427     my ($conf, $unprivileged, $features) = @_;
 428     # User-configured profile has precedence, note that the user's entry would
 429     # be written 'after' this line anyway...
 430     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 431         # Warn the user if this conflicts with a feature:
 432         if ($features->{keyctl}) {
 433             warn "explicitly configured lxc.seccomp.profile overrides the following settings: features:keyctl\n";
 434         }
 435         return '';
 436     }
 437
 438     # Privileged containers keep using the default (which is already part of
 439     # the files included via lxc.include, so we don't need to write it out,
 440     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 441     # well)
 442     return '' if !$unprivileged;
 443
 444     # Unprivileged containers will get keyctl() disabled by default as a
 445     # workaround for systemd-networkd behavior. But we have an option to
 446     # explicitly enable it:
 447     return '' if $features->{keyctl};
 448
 449     # Finally we're in an unprivileged container without `keyctl` set
 450     # explicitly. We have a file prepared for this:
 451     return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 452 }
 453
 454 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 455 # automatically. The default should be equivalent to the old
 456 # `lxc-container-default-cgns` profile.
 457 #
 458 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 459 # additional lines into the profile. We can use that to allow mounting specific
 460 # file systems.
 461 sub make_apparmor_config {
 462     my ($conf, $unprivileged, $features) = @_;
 463
 464     # user-configured profile has precedence, but first we go through our own
 465     # code to figure out whether we should warn the user:
 466
 467     my $raw = "lxc.apparmor.profile = generated\n";
 468     my @profile_uses;
 469
 470     if ($features->{fuse}) {
 471         # For the informational warning:
 472         push @profile_uses, 'features:fuse';
 473     }
 474
 475     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 476     # apparmor lines, create an apparmor namespace for the container, but also
 477     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 478     # lxcfs mounted over them, because that would prevent the container from
 479     # mounting new instances of them for nested containers.
 480     if ($features->{nesting}) {
 481         push @profile_uses, 'features:nesting';
 482         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 483     } else {
 484         # In the default profile in /etc/apparmor.d we patch this in because
 485         # otherwise a container can for example run `chown` on /sys, breaking
 486         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 487         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 488         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 489         # Preferably we could use the 'remount' flag but this does not sit well
 490         # with apparmor_parser currently:
 491         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 492     }
 493
 494     if (my $mount = $features->{mount}) {
 495         push @profile_uses, 'features:mount';
 496         foreach my $fs (PVE::Tools::split_list($mount)) {
 497             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 498         }
 499     }
 500
 501     # More to come?
 502
 503     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 504         if (length(my $used = join(', ', @profile_uses))) {
 505             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 506         }
 507         return '';
 508     }
 509
 510     return $raw;
 511 }
 512
 513 sub update_lxc_config {
 514     my ($vmid, $conf) = @_;
 515
 516     my $dir = "/var/lib/lxc/$vmid";
 517
 518     if ($conf->{template}) {
 519
 520         unlink "$dir/config";
 521
 522         return;
 523     }
 524
 525     my $raw = '';
 526
 527     die "missing 'arch' - internal error" if !$conf->{arch};
 528     $raw .= "lxc.arch = $conf->{arch}\n";
 529
 530     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 531     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 532
 533     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 534
 535     my $cfgpath = '/usr/share/lxc/config';
 536     my $inc = "$cfgpath/$ostype.common.conf";
 537     $inc ="$cfgpath/common.conf" if !-f $inc;
 538     $raw .= "lxc.include = $inc\n";
 539     if ($unprivileged) {
 540         $inc = "$cfgpath/$ostype.userns.conf";
 541         $inc = "$cfgpath/userns.conf" if !-f $inc;
 542         $raw .= "lxc.include = $inc\n";
 543     }
 544
 545     my $features = PVE::LXC::Config->parse_features($conf->{features});
 546
 547     $raw .= make_seccomp_config($conf, $unprivileged, $features);
 548     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 549     if ($features->{fuse}) {
 550         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 551         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 552     }
 553
 554     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 555     # cannot be exposed to the container with r/w access (cgroup perms).
 556     # When this is enabled mounts will still remain in the monitor's namespace
 557     # after the container unmounted them and thus will not detach from their
 558     # files while the container is running!
 559     $raw .= "lxc.monitor.unshare = 1\n";
 560
 561     my $cgv1 = get_cgroup_subsystems();
 562
 563     # Should we read them from /etc/subuid?
 564     if ($unprivileged && !$custom_idmap) {
 565         $raw .= "lxc.idmap = u 0 100000 65536\n";
 566         $raw .= "lxc.idmap = g 0 100000 65536\n";
 567     }
 568
 569     if (!PVE::LXC::Config->has_dev_console($conf)) {
 570         $raw .= "lxc.console.path = none\n";
 571         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
 572     }
 573
 574     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 575     $raw .= "lxc.tty.max = $ttycount\n";
 576
 577     # some init scripts expect a linux terminal (turnkey).
 578     $raw .= "lxc.environment = TERM=linux\n";
 579
 580     my $utsname = $conf->{hostname} || "CT$vmid";
 581     $raw .= "lxc.uts.name = $utsname\n";
 582
 583     if ($cgv1->{memory}) {
 584         my $memory = $conf->{memory} || 512;
 585         my $swap = $conf->{swap} // 0;
 586
 587         my $lxcmem = int($memory*1024*1024);
 588         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 589
 590         my $lxcswap = int(($memory + $swap)*1024*1024);
 591         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 592     }
 593
 594     if ($cgv1->{cpu}) {
 595         if (my $cpulimit = $conf->{cpulimit}) {
 596             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 597             my $value = int(100000*$cpulimit);
 598             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 599         }
 600
 601         my $shares = $conf->{cpuunits} || 1024;
 602         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 603     }
 604
 605     die "missing 'rootfs' configuration\n"
 606         if !defined($conf->{rootfs});
 607
 608     my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 609
 610     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 611
 612     foreach my $k (sort keys %$conf) {
 613         next if $k !~ m/^net(\d+)$/;
 614         my $ind = $1;
 615         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 616         $raw .= "lxc.net.$ind.type = veth\n";
 617         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 618         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 619         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 620         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 621     }
 622
 623     if ($cgv1->{cpuset}) {
 624         my $had_cpuset = 0;
 625         if (my $lxcconf = $conf->{lxc}) {
 626             foreach my $entry (@$lxcconf) {
 627                 my ($k, $v) = @$entry;
 628                 $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus';
 629                 $raw .= "$k = $v\n";
 630             }
 631         }
 632
 633         my $cores = $conf->{cores};
 634         if (!$had_cpuset && $cores) {
 635             my $cpuset = eval { PVE::CpuSet->new_from_cgroup('lxc', 'effective_cpus') };
 636             $cpuset = PVE::CpuSet->new_from_cgroup('', 'effective_cpus') if !$cpuset;
 637             my @members = $cpuset->members();
 638             while (scalar(@members) > $cores) {
 639                 my $randidx = int(rand(scalar(@members)));
 640                 $cpuset->delete($members[$randidx]);
 641                 splice(@members, $randidx, 1); # keep track of the changes
 642             }
 643             $raw .= "lxc.cgroup.cpuset.cpus = ".$cpuset->short_string()."\n";
 644         }
 645     }
 646
 647     File::Path::mkpath("$dir/rootfs");
 648
 649     PVE::Tools::file_set_contents("$dir/config", $raw);
 650 }
 651
 652 # verify and cleanup nameserver list (replace \0 with ' ')
 653 sub verify_nameserver_list {
 654     my ($nameserver_list) = @_;
 655
 656     my @list = ();
 657     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 658         PVE::JSONSchema::pve_verify_ip($server);
 659         push @list, $server;
 660     }
 661
 662     return join(' ', @list);
 663 }
 664
 665 sub verify_searchdomain_list {
 666     my ($searchdomain_list) = @_;
 667
 668     my @list = ();
 669     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 670         # todo: should we add checks for valid dns domains?
 671         push @list, $server;
 672     }
 673
 674     return join(' ', @list);
 675 }
 676
 677 sub get_console_command {
 678     my ($vmid, $conf, $escapechar) = @_;
 679
 680     # '-1' as $escapechar disables keyboard escape sequence
 681     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 682
 683     my $cmode = PVE::LXC::Config->get_cmode($conf);
 684
 685     my $cmd = [];
 686     if ($cmode eq 'console') {
 687         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 688         push @$cmd, '-e', $escapechar if $escapechar;
 689     } elsif ($cmode eq 'tty') {
 690         push @$cmd, 'lxc-console', '-n',  $vmid;
 691         push @$cmd, '-e', $escapechar if $escapechar;
 692     } elsif ($cmode eq 'shell') {
 693         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 694     } else {
 695         die "internal error";
 696     }
 697
 698     return $cmd;
 699 }
 700
 701 sub get_primary_ips {
 702     my ($conf) = @_;
 703
 704     # return data from net0
 705
 706     return undef if !defined($conf->{net0});
 707     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 708
 709     my $ipv4 = $net->{ip};
 710     if ($ipv4) {
 711         if ($ipv4 =~ /^(dhcp|manual)$/) {
 712             $ipv4 = undef
 713         } else {
 714             $ipv4 =~ s!/\d+$!!;
 715         }
 716     }
 717     my $ipv6 = $net->{ip6};
 718     if ($ipv6) {
 719         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 720             $ipv6 = undef;
 721         } else {
 722             $ipv6 =~ s!/\d+$!!;
 723         }
 724     }
 725
 726     return ($ipv4, $ipv6);
 727 }
 728
 729 sub delete_mountpoint_volume {
 730     my ($storage_cfg, $vmid, $volume) = @_;
 731
 732     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 733
 734     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 735
 736     if ($vmid == $owner) {
 737         PVE::Storage::vdisk_free($storage_cfg, $volume);
 738     } else {
 739         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 740     }
 741 }
 742
 743 sub destroy_lxc_container {
 744     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 745
 746     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 747         my ($ms, $mountpoint) = @_;
 748         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 749     });
 750
 751     rmdir "/var/lib/lxc/$vmid/rootfs";
 752     unlink "/var/lib/lxc/$vmid/config";
 753     rmdir "/var/lib/lxc/$vmid";
 754     if (defined $replacement_conf) {
 755         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 756     } else {
 757         PVE::LXC::Config->destroy_config($vmid);
 758     }
 759 }
 760
 761 sub vm_stop_cleanup {
 762     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 763
 764     return if $keepActive;
 765
 766     eval {
 767         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 768         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 769     };
 770     warn $@ if $@; # avoid errors - just warn
 771 }
 772
 773 my $safe_num_ne = sub {
 774     my ($a, $b) = @_;
 775
 776     return 0 if !defined($a) && !defined($b);
 777     return 1 if !defined($a);
 778     return 1 if !defined($b);
 779
 780     return $a != $b;
 781 };
 782
 783 my $safe_string_ne = sub {
 784     my ($a, $b) = @_;
 785
 786     return 0 if !defined($a) && !defined($b);
 787     return 1 if !defined($a);
 788     return 1 if !defined($b);
 789
 790     return $a ne $b;
 791 };
 792
 793 sub update_net {
 794     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 795
 796     if ($newnet->{type} ne 'veth') {
 797         # for when there are physical interfaces
 798         die "cannot update interface of type $newnet->{type}";
 799     }
 800
 801     my $veth = "veth${vmid}i${netid}";
 802     my $eth = $newnet->{name};
 803
 804     if (my $oldnetcfg = $conf->{$opt}) {
 805         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 806
 807         if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 808             &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
 809
 810             PVE::Network::veth_delete($veth);
 811             delete $conf->{$opt};
 812             PVE::LXC::Config->write_config($vmid, $conf);
 813
 814             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 815
 816         } else {
 817             if (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 818                 &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 819                 &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 820
 821                 if ($oldnet->{bridge}) {
 822                     PVE::Network::tap_unplug($veth);
 823                     foreach (qw(bridge tag firewall)) {
 824                         delete $oldnet->{$_};
 825                     }
 826                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 827                     PVE::LXC::Config->write_config($vmid, $conf);
 828                 }
 829
 830                 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 831                 # This includes the rate:
 832                 foreach (qw(bridge tag firewall rate)) {
 833                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 834                 }
 835             } elsif (&$safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 836                 # Rate can be applied on its own but any change above needs to
 837                 # include the rate in tap_plug since OVS resets everything.
 838                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 839                 $oldnet->{rate} = $newnet->{rate}
 840             }
 841             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 842             PVE::LXC::Config->write_config($vmid, $conf);
 843         }
 844     } else {
 845         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 846     }
 847
 848     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 849 }
 850
 851 sub hotplug_net {
 852     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 853
 854     my $veth = "veth${vmid}i${netid}";
 855     my $vethpeer = $veth . "p";
 856     my $eth = $newnet->{name};
 857
 858     PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 859     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 860
 861     # attach peer in container
 862     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 863     PVE::Tools::run_command($cmd);
 864
 865     # link up peer in container
 866     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 867     PVE::Tools::run_command($cmd);
 868
 869     my $done = { type => 'veth' };
 870     foreach (qw(bridge tag firewall hwaddr name)) {
 871         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 872     }
 873     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 874
 875     PVE::LXC::Config->write_config($vmid, $conf);
 876 }
 877
 878 sub update_ipconfig {
 879     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 880
 881     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 882
 883     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 884     my $deleted = [];
 885     my $added = [];
 886     my $nscmd = sub {
 887         my $cmdargs = shift;
 888         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 889     };
 890     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 891
 892     my $change_ip_config = sub {
 893         my ($ipversion) = @_;
 894
 895         my $family_opt = "-$ipversion";
 896         my $suffix = $ipversion == 4 ? '' : $ipversion;
 897         my $gw= "gw$suffix";
 898         my $ip= "ip$suffix";
 899
 900         my $newip = $newnet->{$ip};
 901         my $newgw = $newnet->{$gw};
 902         my $oldip = $optdata->{$ip};
 903         my $oldgw = $optdata->{$gw};
 904
 905         my $change_ip = &$safe_string_ne($oldip, $newip);
 906         my $change_gw = &$safe_string_ne($oldgw, $newgw);
 907
 908         return if !$change_ip && !$change_gw;
 909
 910         # step 1: add new IP, if this fails we cancel
 911         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 912         if ($change_ip && $is_real_ip) {
 913             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 914             if (my $err = $@) {
 915                 warn $err;
 916                 return;
 917             }
 918         }
 919
 920         # step 2: replace gateway
 921         #   If this fails we delete the added IP and cancel.
 922         #   If it succeeds we save the config and delete the old IP, ignoring
 923         #   errors. The config is then saved.
 924         # Note: 'ip route replace' can add
 925         if ($change_gw) {
 926             if ($newgw) {
 927                 eval {
 928                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
 929                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
 930                     }
 931                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
 932                 };
 933                 if (my $err = $@) {
 934                     warn $err;
 935                     # the route was not replaced, the old IP is still available
 936                     # rollback (delete new IP) and cancel
 937                     if ($change_ip) {
 938                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
 939                         warn $@ if $@; # no need to die here
 940                     }
 941                     return;
 942                 }
 943             } else {
 944                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
 945                 # if the route was not deleted, the guest might have deleted it manually
 946                 # warn and continue
 947                 warn $@ if $@;
 948             }
 949             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
 950                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
 951                 # warn if the route was deleted manually
 952                 warn $@ if $@;
 953             }
 954         }
 955
 956         # from this point on we save the configuration
 957         # step 3: delete old IP ignoring errors
 958         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
 959             # We need to enable promote_secondaries, otherwise our newly added
 960             # address will be removed along with the old one.
 961             my $promote = 0;
 962             eval {
 963                 if ($ipversion == 4) {
 964                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
 965                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
 966                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
 967                 }
 968                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
 969             };
 970             warn $@ if $@; # no need to die here
 971
 972             if ($ipversion == 4) {
 973                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
 974             }
 975         }
 976
 977         foreach my $property ($ip, $gw) {
 978             if ($newnet->{$property}) {
 979                 $optdata->{$property} = $newnet->{$property};
 980             } else {
 981                 delete $optdata->{$property};
 982             }
 983         }
 984         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
 985         PVE::LXC::Config->write_config($vmid, $conf);
 986         $lxc_setup->setup_network($conf);
 987     };
 988
 989     &$change_ip_config(4);
 990     &$change_ip_config(6);
 991
 992 }
 993
 994 my $enter_namespace = sub {
 995     my ($vmid, $pid, $which, $type) = @_;
 996     sysopen my $fd, "/proc/$pid/ns/$which", O_RDONLY
 997         or die "failed to open $which namespace of container $vmid: $!\n";
 998     PVE::Tools::setns(fileno($fd), $type)
 999         or die "failed to enter $which namespace of container $vmid: $!\n";
1000     close $fd;
1001 };
1002
1003 my $do_syncfs = sub {
1004     my ($vmid, $pid, $socket) = @_;
1005
1006     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1007
1008     # Tell the parent process to start reading our /proc/mounts
1009     print {$socket} "go\n";
1010     $socket->flush();
1011
1012     # Receive /proc/self/mounts
1013     my $mountdata = do { local $/ = undef; <$socket> };
1014     close $socket;
1015
1016     # Now sync all mountpoints...
1017     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1018     foreach my $mp (@$mounts) {
1019         my ($what, $dir, $fs) = @$mp;
1020         next if $fs eq 'fuse.lxcfs';
1021         eval { PVE::Tools::sync_mountpoint($dir); };
1022         warn $@ if $@;
1023     }
1024 };
1025
1026 sub sync_container_namespace {
1027     my ($vmid) = @_;
1028     my $pid = find_lxc_pid($vmid);
1029
1030     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1031     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1032         or die "failed to create socketpair: $!\n";
1033
1034     my $child = fork();
1035     die "fork failed: $!\n" if !defined($child);
1036
1037     if (!$child) {
1038         eval {
1039             close $pfd;
1040             &$do_syncfs($vmid, $pid, $cfd);
1041         };
1042         if (my $err = $@) {
1043             warn $err;
1044             POSIX::_exit(1);
1045         }
1046         POSIX::_exit(0);
1047     }
1048     close $cfd;
1049     my $go = <$pfd>;
1050     die "failed to enter container namespace\n" if $go ne "go\n";
1051
1052     open my $mounts, '<', "/proc/$child/mounts"
1053         or die "failed to open container's /proc/mounts: $!\n";
1054     my $mountdata = do { local $/ = undef; <$mounts> };
1055     close $mounts;
1056     print {$pfd} $mountdata;
1057     close $pfd;
1058
1059     while (waitpid($child, 0) != $child) {}
1060     die "failed to sync container namespace\n" if $? != 0;
1061 }
1062
1063 sub template_create {
1064     my ($vmid, $conf) = @_;
1065
1066     my $storecfg = PVE::Storage::config();
1067
1068     PVE::LXC::Config->foreach_mountpoint($conf, sub {
1069         my ($ms, $mountpoint) = @_;
1070
1071         my $volid = $mountpoint->{volume};
1072
1073         die "Template feature is not available for '$volid'\n"
1074             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1075     });
1076
1077     PVE::LXC::Config->foreach_mountpoint($conf, sub {
1078         my ($ms, $mountpoint) = @_;
1079
1080         my $volid = $mountpoint->{volume};
1081
1082         PVE::Storage::activate_volumes($storecfg, [$volid]);
1083
1084         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1085         $mountpoint->{volume} = $template_volid;
1086         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1087     });
1088
1089     PVE::LXC::Config->write_config($vmid, $conf);
1090 }
1091
1092 sub check_ct_modify_config_perm {
1093     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1094
1095     return 1 if $authuser eq 'root@pam';
1096
1097     my $check = sub {
1098         my ($opt, $delete) = @_;
1099         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1100             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1101         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1102             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1103             return if $delete;
1104             my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
1105                                         : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
1106             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1107                 if $data->{type} ne 'volume';
1108         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1109             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1110         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1111                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1112             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1113         } elsif ($opt eq 'features') {
1114             # For now this is restricted to root@pam
1115             raise_perm_exc("changing feature flags is only allowed for root\@pam");
1116         } elsif ($opt eq 'hookscript') {
1117             # For now this is restricted to root@pam
1118             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1119         } else {
1120             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1121         }
1122     };
1123
1124     foreach my $opt (keys %$newconf) {
1125         &$check($opt, 0);
1126     }
1127     foreach my $opt (@$delete) {
1128         &$check($opt, 1);
1129     }
1130
1131     return 1;
1132 }
1133
1134 sub umount_all {
1135     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1136
1137     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1138     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1139
1140     my $res = 1;
1141
1142     PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
1143         my ($ms, $mountpoint) = @_;
1144
1145         my $volid = $mountpoint->{volume};
1146         my $mount = $mountpoint->{mp};
1147
1148         return if !$volid || !$mount;
1149
1150         my $mount_path = "$rootdir/$mount";
1151         $mount_path =~ s!/+!/!g;
1152
1153         return if !PVE::ProcFSTools::is_mounted($mount_path);
1154
1155         eval {
1156             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1157         };
1158         if (my $err = $@) {
1159             if ($noerr) {
1160                 $res = 0;
1161                 warn $err;
1162             } else {
1163                 die $err;
1164             }
1165         }
1166     });
1167
1168     return $res; # tell caller if (some) umounts failed for the noerr case
1169 }
1170
1171 sub mount_all {
1172     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1173
1174     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1175     File::Path::make_path($rootdir);
1176
1177     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1178     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1179
1180     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1181
1182     eval {
1183         PVE::LXC::Config->foreach_mountpoint($conf, sub {
1184             my ($ms, $mountpoint) = @_;
1185
1186             $mountpoint->{ro} = 0 if $ignore_ro;
1187
1188             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1189         });
1190     };
1191     if (my $err = $@) {
1192         warn "mounting container failed\n";
1193         umount_all($vmid, $storage_cfg, $conf, 1);
1194         die $err;
1195     }
1196
1197     return $rootdir;
1198 }
1199
1200
1201 sub mountpoint_mount_path {
1202     my ($mountpoint, $storage_cfg, $snapname) = @_;
1203
1204     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1205 }
1206
1207 sub query_loopdev {
1208     my ($path) = @_;
1209     my $found;
1210     my $parser = sub {
1211         my $line = shift;
1212         if ($line =~ m@^(/dev/loop\d+):@) {
1213             $found = $1;
1214         }
1215     };
1216     my $cmd = ['losetup', '--associated', $path];
1217     PVE::Tools::run_command($cmd, outfunc => $parser);
1218     return $found;
1219 }
1220
1221 # Run a function with a file attached to a loop device.
1222 # The loop device is always detached afterwards (or set to autoclear).
1223 # Returns the loop device.
1224 sub run_with_loopdev {
1225     my ($func, $file, $readonly) = @_;
1226     my $device = query_loopdev($file);
1227     # Try to reuse an existing device
1228     if ($device) {
1229         # We assume that whoever setup the loop device is responsible for
1230         # detaching it.
1231         &$func($device);
1232         return $device;
1233     }
1234
1235     my $parser = sub {
1236         my $line = shift;
1237         if ($line =~ m@^(/dev/loop\d+)$@) {
1238             $device = $1;
1239         }
1240     };
1241     my $losetup_cmd = [
1242         'losetup',
1243         '--show',
1244         '-f',
1245         $file,
1246     ];
1247     push @$losetup_cmd, '-r' if $readonly;
1248     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1249     die "failed to setup loop device for $file\n" if !$device;
1250     eval { &$func($device); };
1251     my $err = $@;
1252     PVE::Tools::run_command(['losetup', '-d', $device]);
1253     die $err if $err;
1254     return $device;
1255 }
1256
1257 # In scalar mode: returns a file handle to the deepest directory node.
1258 # In list context: returns a list of:
1259 #   * the deepest directory node
1260 #   * the 2nd deepest directory (parent of the above)
1261 #   * directory name of the last directory
1262 # So that the path $2/$3 should lead to $1 afterwards.
1263 sub walk_tree_nofollow($$$;$$) {
1264     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1265
1266     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1267         or die "failed to open start directory $start: $!\n";
1268
1269     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1270 }
1271
1272
1273 sub walk_tree_nofollow_fd($$$$;$$) {
1274     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1275
1276     # splitdir() returns '' for empty components including the leading /
1277     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1278
1279     my $fd = $start_fd;
1280     my $dir = $start_dirname;
1281     my $last_component = undef;
1282     my $second = $fd;
1283     foreach my $component (@comps) {
1284         $dir .= "/$component";
1285         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1286
1287         if (!$next) {
1288             # failed, check for symlinks and try to create the path
1289             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1290             die "cannot open directory $dir: $!\n" if !$mkdir;
1291
1292             # We don't check for errors on mkdirat() here and just try to
1293             # openat() again, since at least one error (EEXIST) is an
1294             # expected possibility if multiple containers start
1295             # simultaneously. If someone else injects a symlink now then
1296             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1297             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1298
1299             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1300             die "failed to create path: $dir: $!\n" if !$next;
1301
1302             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1303                 if defined($rootuid) && defined($rootgid);
1304         }
1305
1306         close $second if defined($last_component) && $second != $start_fd;
1307         $last_component = $component;
1308         $second = $fd;
1309         $fd = $next;
1310     }
1311
1312     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1313     close $second if defined($last_component) && $second != $start_fd;
1314     return $fd;
1315 }
1316
1317 # To guard against symlink attack races against other currently running
1318 # containers with shared recursive bind mount hierarchies we prepare a
1319 # directory handle for the directory we're mounting over to verify the
1320 # mountpoint afterwards.
1321 sub __bindmount_prepare {
1322     my ($hostroot, $dir) = @_;
1323     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1324     return $srcdh;
1325 }
1326
1327 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1328 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1329 # we intended to bind mount.
1330 sub __bindmount_verify {
1331     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1332     my $destdh;
1333     if ($parentfd) {
1334         # Open the mount point path coming from the parent directory since the
1335         # filehandle we would have gotten as first result of walk_tree_nofollow
1336         # earlier is still a handle to the underlying directory instead of the
1337         # mounted path.
1338         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1339         die "failed to open mount point: $!\n" if !$destdh;
1340         if ($ro) {
1341             my $dot = '.';
1342             # no separate function because 99% of the time it's the wrong thing to use.
1343             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1344                 die "failed to mark bind mount read only\n";
1345             }
1346             die "read-only check failed: $!\n" if $! != EROFS;
1347         }
1348     } else {
1349         # For the rootfs we don't have a parentfd so we open the path directly.
1350         # Note that this means bindmounting any prefix of the host's
1351         # /var/lib/lxc/$vmid path into another container is considered a grave
1352         # security error.
1353         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1354         die "failed to open mount point: $!\n" if !$destdh;
1355     }
1356
1357     my ($srcdev, $srcinode) = stat($srcdh);
1358     my ($dstdev, $dstinode) = stat($destdh);
1359     close $srcdh;
1360     close $destdh;
1361
1362     return ($srcdev == $dstdev && $srcinode == $dstinode);
1363 }
1364
1365 # Perform the actual bind mounting:
1366 sub __bindmount_do {
1367     my ($dir, $dest, $ro, @extra_opts) = @_;
1368     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1369     if ($ro) {
1370         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1371         if (my $err = $@) {
1372             warn "bindmount error\n";
1373             # don't leave writable bind-mounts behind...
1374             PVE::Tools::run_command(['umount', $dest]);
1375             die $err;
1376         }
1377     }
1378 }
1379
1380 sub bindmount {
1381     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1382
1383     my $srcdh = __bindmount_prepare('/', $dir);
1384
1385     __bindmount_do($dir, $dest, $ro, @extra_opts);
1386
1387     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1388         PVE::Tools::run_command(['umount', $dest]);
1389         die "detected mount path change at: $dir\n";
1390     }
1391 }
1392
1393 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1394 # from $rootdir and $mount and walk the path from $rootdir to the final
1395 # directory to check for symlinks.
1396 sub __mount_prepare_rootdir {
1397     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1398     $rootdir =~ s!/+!/!g;
1399     $rootdir =~ s!/+$!!;
1400     my $mount_path = "$rootdir/$mount";
1401     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1402     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1403 }
1404
1405 # use $rootdir = undef to just return the corresponding mount path
1406 sub mountpoint_mount {
1407     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1408     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1409 }
1410
1411 sub mountpoint_stage {
1412     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1413     my ($path, $loop, $dev) =
1414         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1415
1416     if (!defined($path)) {
1417         return undef if $! == ENOSYS;
1418         die "failed to mount subvolume: $!\n";
1419     }
1420
1421     my $err;
1422     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1423         or die "open_tree() on mount point failed: $!\n";
1424
1425     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1426 }
1427
1428 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1429 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1430 #   Note that if the kernel does not support the new mount API, this will not perform any action
1431 #   and return `undef` with $! = ENOSYS.
1432 sub __mountpoint_mount {
1433     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1434
1435     if (defined($stage_mount) && !PVE::LXC::Tools::can_use_new_mount_api()) {
1436         $! = ENOSYS;
1437         return undef;
1438     }
1439
1440     my $volid = $mountpoint->{volume};
1441     my $mount = $mountpoint->{mp};
1442     my $type = $mountpoint->{type};
1443     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1444     my $mounted_dev;
1445
1446     return if !$volid || !$mount;
1447
1448     $mount =~ s!/+!/!g;
1449
1450     my $mount_path;
1451     my ($mpfd, $parentfd, $last_dir);
1452
1453     if (defined($rootdir)) {
1454         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1455             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1456     }
1457
1458     if (defined($stage_mount)) {
1459         $mount_path = $rootdir;
1460     }
1461
1462     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1463
1464     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1465
1466     my $optlist = [];
1467
1468     if (my $mountopts = $mountpoint->{mountoptions}) {
1469         my @opts = split(/;/, $mountpoint->{mountoptions});
1470         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1471     }
1472
1473     my $acl = $mountpoint->{acl};
1474     if (defined($acl)) {
1475         push @$optlist, ($acl ? 'acl' : 'noacl');
1476     }
1477
1478     my $optstring = join(',', @$optlist);
1479     my $readonly = $mountpoint->{ro};
1480
1481     my @extra_opts;
1482     @extra_opts = ('-o', $optstring) if $optstring;
1483
1484     if ($storage) {
1485
1486         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1487
1488         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1489
1490         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1491
1492         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1493             PVE::Storage::parse_volname($storage_cfg, $volid);
1494
1495         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1496
1497         if ($format eq 'subvol') {
1498             if ($mount_path) {
1499                 if ($snapname) {
1500                     if ($scfg->{type} eq 'zfspool') {
1501                         my $path_arg = $path;
1502                         $path_arg =~ s!^/+!!;
1503                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', $path_arg, $mount_path]);
1504                     } else {
1505                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1506                     }
1507                 } else {
1508                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1509                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1510                         my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1511                         $name .= "\@$snapname" if defined($snapname);
1512                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1513                     }
1514                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1515                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1516                 }
1517             }
1518             return wantarray ? ($path, 0, undef) : $path;
1519         } elsif ($format eq 'raw' || $format eq 'iso') {
1520             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1521             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1522             # Our autodev hook expects the /dev/dm-* device currently
1523             # and will create the /dev/mapper symlink accordingly
1524             $path = Cwd::realpath($path);
1525             die "failed to get device path\n" if !$path;
1526             ($path) = ($path =~ /^(.*)$/s); #untaint
1527             my $domount = sub {
1528                 my ($path) = @_;
1529                 if ($mount_path) {
1530                     if ($format eq 'iso') {
1531                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1532                     } elsif ($isBase || defined($snapname)) {
1533                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1534                     } else {
1535                         if ($quota) {
1536                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1537                         }
1538                         push @extra_opts, '-o', 'ro' if $readonly;
1539                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1540                     }
1541                 }
1542             };
1543             my $use_loopdev = 0;
1544             if ($scfg->{path}) {
1545                 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1546                 $use_loopdev = 1;
1547             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1548                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1549                 $mounted_dev = $path;
1550                 &$domount($path);
1551             } else {
1552                 die "unsupported storage type '$scfg->{type}'\n";
1553             }
1554             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1555         } else {
1556             die "unsupported image format '$format'\n";
1557         }
1558     } elsif ($type eq 'device') {
1559         push @extra_opts, '-o', 'ro' if $readonly;
1560         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1561         # See the NOTE above about devicemapper canonicalization
1562         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1563         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1564         return wantarray ? ($volid, 0, $devpath) : $volid;
1565     } elsif ($type eq 'bind') {
1566         die "directory '$volid' does not exist\n" if ! -d $volid;
1567         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1568         warn "cannot enable quota control for bind mounts\n" if $quota;
1569         return wantarray ? ($volid, 0, undef) : $volid;
1570     }
1571
1572     die "unsupported storage";
1573 }
1574
1575 sub mkfs {
1576     my ($dev, $rootuid, $rootgid) = @_;
1577
1578     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1579                              '-E', "root_owner=$rootuid:$rootgid",
1580                              $dev]);
1581 }
1582
1583 sub format_disk {
1584     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1585
1586     if ($volid =~ m!^/dev/.+!) {
1587         mkfs($volid);
1588         return;
1589     }
1590
1591     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1592
1593     die "cannot format volume '$volid' with no storage\n" if !$storage;
1594
1595     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1596
1597     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1598
1599     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1600
1601     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1602         PVE::Storage::parse_volname($storage_cfg, $volid);
1603
1604     die "cannot format volume '$volid' (format == $format)\n"
1605         if $format ne 'raw';
1606
1607     mkfs($path, $rootuid, $rootgid);
1608 }
1609
1610 sub destroy_disks {
1611     my ($storecfg, $vollist) = @_;
1612
1613     foreach my $volid (@$vollist) {
1614         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1615         warn $@ if $@;
1616     }
1617 }
1618
1619 sub alloc_disk {
1620     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1621
1622     my $needs_chown = 0;
1623     my $volid;
1624
1625     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1626     # fixme: use better naming ct-$vmid-disk-X.raw?
1627
1628     eval {
1629         my $do_format = 0;
1630         if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1631             if ($size_kb > 0) {
1632                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1633                                                    undef, $size_kb);
1634                 $do_format = 1;
1635             } else {
1636                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1637                                                    undef, 0);
1638                 $needs_chown = 1;
1639             }
1640         } elsif ($scfg->{type} eq 'zfspool') {
1641
1642             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1643                                                undef, $size_kb);
1644             $needs_chown = 1;
1645         } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1646
1647             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1648             $do_format = 1;
1649
1650         } elsif ($scfg->{type} eq 'rbd') {
1651
1652             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1653             $do_format = 1;
1654         } else {
1655             die "unable to create containers on storage type '$scfg->{type}'\n";
1656         }
1657         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1658     };
1659     if (my $err = $@) {
1660         # in case formatting got interrupted:
1661         if (defined($volid)) {
1662             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1663             warn $@ if $@;
1664         }
1665         die $err;
1666     }
1667
1668     return ($volid, $needs_chown);
1669 }
1670
1671 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1672 sub create_disks {
1673     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1674
1675     my $vollist = [];
1676
1677     eval {
1678         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1679         my $chown_vollist = [];
1680
1681         PVE::LXC::Config->foreach_mountpoint($settings, sub {
1682             my ($ms, $mountpoint) = @_;
1683
1684             my $volid = $mountpoint->{volume};
1685             my $mp = $mountpoint->{mp};
1686
1687             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1688
1689             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1690                 my ($storeid, $size_gb) = ($1, $2);
1691
1692                 my $size_kb = int(${size_gb}*1024) * 1024;
1693
1694                 my $needs_chown = 0;
1695                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1696                 push @$chown_vollist, $volid if $needs_chown;
1697                 push @$vollist, $volid;
1698                 $mountpoint->{volume} = $volid;
1699                 $mountpoint->{size} = $size_kb * 1024;
1700                 if ($pending) {
1701                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1702                 } else {
1703                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1704                 }
1705             } else {
1706                 # use specified/existing volid/dir/device
1707                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1708             }
1709         });
1710
1711         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1712         foreach my $volid (@$chown_vollist) {
1713             my $path = PVE::Storage::path($storecfg, $volid, undef);
1714             chown($rootuid, $rootgid, $path);
1715         }
1716         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1717     };
1718     # free allocated images on error
1719     if (my $err = $@) {
1720         destroy_disks($storecfg, $vollist);
1721         die $err;
1722     }
1723     return $vollist;
1724 }
1725
1726 sub update_disksize {
1727     my ($vmid, $conf, $all_volumes) = @_;
1728
1729     my $changes;
1730     my $prefix = "CT $vmid:";
1731
1732     my $update_mp = sub {
1733         my ($key, $mp, @param) = @_;
1734         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1735
1736         if (!defined($mp->{size}) || $size != $mp->{size}) {
1737             $changes = 1;
1738             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1739             $mp->{size} = $size;
1740             my $nomp = 1 if ($key eq 'rootfs');
1741             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1742         }
1743     };
1744
1745     PVE::LXC::Config->foreach_mountpoint($conf, $update_mp);
1746
1747     return $changes;
1748 }
1749
1750 sub update_unused {
1751     my ($vmid, $conf, $all_volumes) = @_;
1752
1753     my $changes;
1754     my $prefix = "CT $vmid:";
1755
1756     # Note: it is allowed to define multiple storage entries with the same path
1757     # (alias), so we need to check both 'volid' and real 'path' (two different
1758     # volid can point to the same path).
1759
1760     # used and unused disks
1761     my $refpath = {};
1762     my $orphans = {};
1763
1764     foreach my $opt (keys %$conf) {
1765         next if ($opt !~ m/^unused\d+$/);
1766         my $vol = $all_volumes->{$conf->{$opt}};
1767         $refpath->{$vol->{path}} = $vol->{volid};
1768     }
1769
1770     foreach my $key (keys %$all_volumes) {
1771         my $vol = $all_volumes->{$key};
1772         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
1773         my $path = $vol->{path};
1774
1775         if ($in_use) {
1776             $refpath->{$path} = $key;
1777             delete $orphans->{$path};
1778         } else {
1779             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
1780                 $orphans->{$path} = $key;
1781             }
1782         }
1783     }
1784
1785     for my $key (keys %$orphans) {
1786         my $disk = $orphans->{$key};
1787         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
1788
1789         if ($unused) {
1790             $changes = 1;
1791             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
1792         }
1793     }
1794
1795     return $changes;
1796 }
1797
1798 sub scan_volids {
1799     my ($cfg, $vmid) = @_;
1800
1801     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid);
1802
1803     my $all_volumes = {};
1804     foreach my $storeid (keys %$info) {
1805         foreach my $item (@{$info->{$storeid}}) {
1806             my $volid = $item->{volid};
1807             next if !($volid && $item->{size});
1808             $item->{path} = PVE::Storage::path($cfg, $volid);
1809             $all_volumes->{$volid} = $item;
1810         }
1811     }
1812
1813     return $all_volumes;
1814 }
1815
1816 sub rescan {
1817     my ($vmid, $nolock, $dryrun) = @_;
1818
1819     my $cfg = PVE::Storage::config();
1820
1821     # FIXME: Remove once our RBD plugin can handle CT and VM on a single storage
1822     # see: https://pve.proxmox.com/pipermail/pve-devel/2018-July/032900.html
1823     foreach my $stor (keys %{$cfg->{ids}}) {
1824         delete($cfg->{ids}->{$stor}) if !$cfg->{ids}->{$stor}->{content}->{rootdir};
1825     }
1826
1827     print "rescan volumes...\n";
1828     my $all_volumes = scan_volids($cfg, $vmid);
1829
1830     my $updatefn =  sub {
1831         my ($vmid) = @_;
1832
1833         my $changes;
1834         my $conf = PVE::LXC::Config->load_config($vmid);
1835
1836         PVE::LXC::Config->check_lock($conf);
1837
1838         my $vm_volids = {};
1839         foreach my $volid (keys %$all_volumes) {
1840             my $info = $all_volumes->{$volid};
1841             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
1842         }
1843
1844         my $upu = update_unused($vmid, $conf, $vm_volids);
1845         my $upd = update_disksize($vmid, $conf, $vm_volids);
1846         $changes = $upu || $upd;
1847
1848         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
1849     };
1850
1851     if (defined($vmid)) {
1852         if ($nolock) {
1853             &$updatefn($vmid);
1854         } else {
1855             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
1856         }
1857     } else {
1858         my $vmlist = config_list();
1859         foreach my $vmid (keys %$vmlist) {
1860             if ($nolock) {
1861                 &$updatefn($vmid);
1862             } else {
1863                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
1864             }
1865         }
1866     }
1867 }
1868
1869
1870 # bash completion helper
1871
1872 sub complete_os_templates {
1873     my ($cmdname, $pname, $cvalue) = @_;
1874
1875     my $cfg = PVE::Storage::config();
1876
1877     my $storeid;
1878
1879     if ($cvalue =~ m/^([^:]+):/) {
1880         $storeid = $1;
1881     }
1882
1883     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
1884     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
1885
1886     my $res = [];
1887     foreach my $id (keys %$data) {
1888         foreach my $item (@{$data->{$id}}) {
1889             push @$res, $item->{volid} if defined($item->{volid});
1890         }
1891     }
1892
1893     return $res;
1894 }
1895
1896 my $complete_ctid_full = sub {
1897     my ($running) = @_;
1898
1899     my $idlist = vmstatus();
1900
1901     my $active_hash = list_active_containers();
1902
1903     my $res = [];
1904
1905     foreach my $id (keys %$idlist) {
1906         my $d = $idlist->{$id};
1907         if (defined($running)) {
1908             next if $d->{template};
1909             next if $running && !$active_hash->{$id};
1910             next if !$running && $active_hash->{$id};
1911         }
1912         push @$res, $id;
1913
1914     }
1915     return $res;
1916 };
1917
1918 sub complete_ctid {
1919     return &$complete_ctid_full();
1920 }
1921
1922 sub complete_ctid_stopped {
1923     return &$complete_ctid_full(0);
1924 }
1925
1926 sub complete_ctid_running {
1927     return &$complete_ctid_full(1);
1928 }
1929
1930 sub parse_id_maps {
1931     my ($conf) = @_;
1932
1933     my $id_map = [];
1934     my $rootuid = 0;
1935     my $rootgid = 0;
1936
1937     my $lxc = $conf->{lxc};
1938     foreach my $entry (@$lxc) {
1939         my ($key, $value) = @$entry;
1940         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
1941         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
1942         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
1943             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
1944             push @$id_map, [$type, $ct, $host, $length];
1945             if ($ct == 0) {
1946                 $rootuid = $host if $type eq 'u';
1947                 $rootgid = $host if $type eq 'g';
1948             }
1949         } else {
1950             die "failed to parse idmap: $value\n";
1951         }
1952     }
1953
1954     if (!@$id_map && $conf->{unprivileged}) {
1955         # Should we read them from /etc/subuid?
1956         $id_map = [ ['u', '0', '100000', '65536'],
1957                     ['g', '0', '100000', '65536'] ];
1958         $rootuid = $rootgid = 100000;
1959     }
1960
1961     return ($id_map, $rootuid, $rootgid);
1962 }
1963
1964 sub userns_command {
1965     my ($id_map) = @_;
1966     if (@$id_map) {
1967         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
1968     }
1969     return [];
1970 }
1971
1972 sub vm_start {
1973     my ($vmid, $conf, $skiplock) = @_;
1974
1975     # apply pending changes while starting
1976     if (scalar(keys %{$conf->{pending}})) {
1977         my $storecfg = PVE::Storage::config();
1978         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
1979         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
1980     }
1981
1982     update_lxc_config($vmid, $conf);
1983
1984     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
1985
1986     if ($skiplock) {
1987         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
1988         close($fh);
1989     }
1990
1991     my $cmd = ['systemctl', 'start', "pve-container\@$vmid"];
1992
1993     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
1994     eval { PVE::Tools::run_command($cmd); };
1995     if (my $err = $@) {
1996         unlink $skiplock_flag_fn;
1997         die $err;
1998     }
1999     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2000
2001     return;
2002 }
2003
2004 # Helper to stop a container completely and make sure it has stopped completely.
2005 # This is necessary because we want the post-stop hook to have completed its
2006 # unmount-all step, but post-stop happens after lxc puts the container into the
2007 # STOPPED state.
2008 # $kill - if true it will always do an immediate hard-stop
2009 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2010 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2011 sub vm_stop {
2012     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2013
2014     # Open the container's command socket.
2015     my $path = "\0/var/lib/lxc/$vmid/command";
2016     my $sock = IO::Socket::UNIX->new(
2017         Type => SOCK_STREAM(),
2018         Peer => $path,
2019     );
2020     if (!$sock) {
2021         return if $! == ECONNREFUSED; # The container is not running
2022         die "failed to open container ${vmid}'s command socket: $!\n";
2023     }
2024
2025     my $conf = PVE::LXC::Config->load_config($vmid);
2026     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2027
2028     # Stop the container:
2029
2030     my $cmd = ['lxc-stop', '-n', $vmid];
2031
2032     if ($kill) {
2033         push @$cmd, '--kill'; # doesn't allow timeouts
2034     } else {
2035         # lxc-stop uses a default timeout
2036         push @$cmd, '--nokill' if !$kill_after_timeout;
2037
2038         if (defined($shutdown_timeout)) {
2039             push @$cmd, '--timeout', $shutdown_timeout;
2040             # Give run_command 5 extra seconds
2041             $shutdown_timeout += 5;
2042         }
2043     }
2044
2045     eval { PVE::Tools::run_command($cmd, timeout => $shutdown_timeout) };
2046     if (my $err = $@) {
2047         warn $@ if $@;
2048     }
2049
2050     my $result = <$sock>;
2051
2052     return if !defined $result; # monitor is gone and the ct has stopped.
2053     die "container did not stop\n";
2054 }
2055
2056 sub run_unshared {
2057     my ($code) = @_;
2058
2059     return PVE::Tools::run_fork(sub {
2060         # Unshare the mount namespace
2061         die "failed to unshare mount namespace: $!\n"
2062             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2063         PVE::Tools::run_command(['mount', '--make-rslave', '/']);
2064         return $code->();
2065     });
2066 }
2067
2068 my $copy_volume = sub {
2069     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2070
2071     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2072     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2073
2074     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2075     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2076
2077     my @mounted;
2078     eval {
2079         # mount and copy
2080         mkdir $src;
2081         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2082         push @mounted, $src;
2083         mkdir $dest;
2084         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2085         push @mounted, $dest;
2086
2087         $bwlimit //= 0;
2088
2089         PVE::Tools::run_command(['/usr/bin/rsync', '--stats', '-X', '-A', '--numeric-ids',
2090                                  '-aH', '--whole-file', '--sparse', '--one-file-system',
2091                                  "--bwlimit=$bwlimit", "$src/", $dest]);
2092     };
2093     my $err = $@;
2094
2095     # Wait for rsync's children to release dest so that
2096     # consequent file operations (umount, remove) are possible
2097     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2098
2099     foreach my $mount (reverse @mounted) {
2100         eval { PVE::Tools::run_command(['/bin/umount', $mount], errfunc => sub{})};
2101         warn "Can't umount $mount\n" if $@;
2102     }
2103
2104     # If this fails they're used as mount points in a concurrent operation
2105     # (which should not happen but there's also no real need to get rid of them).
2106     rmdir $dest;
2107     rmdir $src;
2108
2109     die $err if $err;
2110 };
2111
2112 # Should not be called after unsharing the mount namespace!
2113 sub copy_volume {
2114     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2115
2116     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2117     File::Path::make_path("/var/lib/lxc/$vmid");
2118     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2119     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2120
2121     # get id's for unprivileged container
2122     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2123
2124     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2125     # are visible in this namespace, otherwise the host only sees the empty
2126     # (not-mounted) directory.
2127     my $new_volid;
2128     eval {
2129         # Make sure $mp contains a correct size.
2130         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2131         my $needs_chown;
2132         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2133         if ($needs_chown) {
2134             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2135             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2136             chown($rootuid, $rootgid, $path);
2137         }
2138
2139         run_unshared(sub {
2140             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2141         });
2142     };
2143     if (my $err = $@) {
2144         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2145             if defined($new_volid);
2146         die $err;
2147     }
2148
2149     return $new_volid;
2150 }
2151
2152 1;