src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd qw();
   7 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED EEXIST);
   8 use Fcntl qw(O_RDONLY O_WRONLY O_NOFOLLOW O_DIRECTORY);
   9 use File::Path;
  10 use File::Spec;
  11 use IO::Poll qw(POLLIN POLLHUP);
  12 use IO::Socket::UNIX;
  13 use POSIX qw(EINTR);
  14 use Socket;
  15 use Time::HiRes qw (gettimeofday);
  16
  17 use PVE::AccessControl;
  18 use PVE::CGroup;
  19 use PVE::CpuSet;
  20 use PVE::Exception qw(raise_perm_exc);
  21 use PVE::GuestHelpers qw(check_vnet_access safe_string_ne safe_num_ne safe_boolean_ne);
  22 use PVE::INotify;
  23 use PVE::JSONSchema qw(get_standard_option);
  24 use PVE::Network;
  25 use PVE::ProcFSTools;
  26 use PVE::RESTEnvironment;
  27 use PVE::SafeSyslog;
  28 use PVE::Storage;
  29 use PVE::Tools qw(
  30     run_command
  31     dir_glob_foreach
  32     file_get_contents
  33     file_set_contents
  34     AT_FDCWD
  35     O_PATH
  36     $IPV4RE
  37     $IPV6RE
  38 );
  39 use PVE::Syscall qw(:fsmount);
  40
  41 use PVE::LXC::CGroup;
  42 use PVE::LXC::Config;
  43 use PVE::LXC::Monitor;
  44 use PVE::LXC::Tools;
  45
  46 my $have_sdn;
  47 eval {
  48     require PVE::Network::SDN::Zones;
  49     $have_sdn = 1;
  50 };
  51
  52 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  53
  54 my $nodename = PVE::INotify::nodename();
  55
  56 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  57
  58 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
  59
  60 sub config_list {
  61     my $vmlist = PVE::Cluster::get_vmlist();
  62     my $res = {};
  63     return $res if !$vmlist || !$vmlist->{ids};
  64     my $ids = $vmlist->{ids};
  65
  66     foreach my $vmid (keys %$ids) {
  67         next if !$vmid; # skip CT0
  68         my $d = $ids->{$vmid};
  69         next if !$d->{node} || $d->{node} ne $nodename;
  70         next if !$d->{type} || $d->{type} ne 'lxc';
  71         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  72     }
  73     return $res;
  74 }
  75
  76 # container status helpers
  77
  78 sub list_active_containers {
  79
  80     my $filename = "/proc/net/unix";
  81
  82     # similar test is used by lcxcontainers.c: list_active_containers
  83     my $res = {};
  84
  85     my $fh = IO::File->new ($filename, "r");
  86     return $res if !$fh;
  87
  88     while (defined(my $line = <$fh>)) {
  89         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  90             my $path = $1;
  91             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  92                 $res->{$1} = 1;
  93             }
  94         }
  95     }
  96
  97     close($fh);
  98
  99     return $res;
 100 }
 101
 102 # warning: this is slow
 103 sub check_running {
 104     my ($vmid) = @_;
 105
 106     my $active_hash = list_active_containers();
 107
 108     return 1 if defined($active_hash->{$vmid});
 109
 110     return undef;
 111 }
 112
 113 sub get_container_disk_usage {
 114     my ($vmid, $pid) = @_;
 115
 116     return PVE::Tools::df("/proc/$pid/root/", 1);
 117 }
 118
 119 my $last_proc_vmid_stat;
 120
 121 our $vmstatus_return_properties = {
 122     vmid => get_standard_option('pve-vmid'),
 123     status => {
 124         description => "LXC Container status.",
 125         type => 'string',
 126         enum => ['stopped', 'running'],
 127     },
 128     maxmem => {
 129         description => "Maximum memory in bytes.",
 130         type => 'integer',
 131         optional => 1,
 132         renderer => 'bytes',
 133     },
 134     maxswap => {
 135         description => "Maximum SWAP memory in bytes.",
 136         type => 'integer',
 137         optional => 1,
 138         renderer => 'bytes',
 139     },
 140     maxdisk => {
 141         description => "Root disk size in bytes.",
 142         type => 'integer',
 143         optional => 1,
 144         renderer => 'bytes',
 145     },
 146     name => {
 147         description => "Container name.",
 148         type => 'string',
 149         optional => 1,
 150     },
 151     uptime => {
 152         description => "Uptime.",
 153         type => 'integer',
 154         optional => 1,
 155         renderer => 'duration',
 156     },
 157     cpus => {
 158         description => "Maximum usable CPUs.",
 159         type => 'number',
 160         optional => 1,
 161     },
 162     lock => {
 163         description => "The current config lock, if any.",
 164         type => 'string',
 165         optional => 1,
 166     },
 167     tags => {
 168         description => "The current configured tags, if any.",
 169         type => 'string',
 170         optional => 1,
 171     }
 172 };
 173
 174 sub vmstatus {
 175     my ($opt_vmid) = @_;
 176
 177     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => int($opt_vmid) }} : config_list();
 178
 179     my $active_hash = list_active_containers();
 180
 181     my $cpucount = $cpuinfo->{cpus} || 1;
 182
 183     my $cdtime = gettimeofday;
 184
 185     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 186     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 187
 188     my $unprivileged = {};
 189
 190     foreach my $vmid (keys %$list) {
 191         my $d = $list->{$vmid};
 192
 193         eval { $d->{pid} = int(find_lxc_pid($vmid)) if defined($active_hash->{$vmid}); };
 194         warn $@ if $@; # ignore errors (consider them stopped)
 195
 196         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 197
 198         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 199         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 200
 201         $unprivileged->{$vmid} = $conf->{unprivileged};
 202
 203         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 204         $d->{name} =~ s/[\s]//g;
 205
 206         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 207         $d->{cpus} = $cpucount if !$d->{cpus};
 208
 209         $d->{tags} = $conf->{tags} if defined($conf->{tags});
 210
 211         if ($d->{pid}) {
 212             my $res = get_container_disk_usage($vmid, $d->{pid});
 213             $d->{disk} = int($res->{used});
 214             $d->{maxdisk} = int($res->{total});
 215         } else {
 216             $d->{disk} = 0;
 217             # use 4GB by default ??
 218             if (my $rootfs = $conf->{rootfs}) {
 219                 my $rootinfo = PVE::LXC::Config->parse_volume('rootfs', $rootfs);
 220                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 221             } else {
 222                 $d->{maxdisk} = 4*1024*1024*1024;
 223             }
 224         }
 225
 226         $d->{mem} = 0;
 227         $d->{swap} = 0;
 228         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 229         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 230
 231         $d->{uptime} = 0;
 232         $d->{cpu} = 0;
 233
 234         $d->{netout} = 0;
 235         $d->{netin} = 0;
 236
 237         $d->{diskread} = 0;
 238         $d->{diskwrite} = 0;
 239
 240         $d->{template} = 1 if PVE::LXC::Config->is_template($conf);
 241         $d->{lock} = $conf->{lock} if $conf->{lock};
 242     }
 243
 244     foreach my $vmid (keys %$list) {
 245         my $d = $list->{$vmid};
 246         my $pid = $d->{pid};
 247
 248         next if !$pid; # skip stopped CTs
 249
 250         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 251         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 252
 253         my $unpriv = $unprivileged->{$vmid};
 254
 255         my $cgroups = PVE::LXC::CGroup->new($vmid);
 256
 257         if (defined(my $mem = $cgroups->get_memory_stat())) {
 258             $d->{mem} = int($mem->{mem});
 259             $d->{swap} = int($mem->{swap});
 260         } else {
 261             $d->{mem} = 0;
 262             $d->{swap} = 0;
 263         }
 264
 265         if (defined(my $blkio = $cgroups->get_io_stats())) {
 266             $d->{diskread} = int($blkio->{diskread});
 267             $d->{diskwrite} = int($blkio->{diskwrite});
 268         } else {
 269             $d->{diskread} = 0;
 270             $d->{diskwrite} = 0;
 271         }
 272
 273         if (defined(my $cpu = $cgroups->get_cpu_stat())) {
 274             # Total time (in milliseconds) used up by the cpu.
 275             my $used_ms = $cpu->{utime} + $cpu->{stime};
 276
 277             my $old = $last_proc_vmid_stat->{$vmid};
 278             if (!$old) {
 279                 $last_proc_vmid_stat->{$vmid} = {
 280                     time => $cdtime,
 281                     used => $used_ms,
 282                     cpu => 0,
 283                 };
 284                 next;
 285             }
 286
 287             my $delta_ms = ($cdtime - $old->{time}) * $cpucount * 1000.0;
 288             if ($delta_ms > 1000.0) {
 289                 my $delta_used_ms = $used_ms - $old->{used};
 290                 $d->{cpu} = (($delta_used_ms / $delta_ms) * $cpucount) / $d->{cpus};
 291                 $last_proc_vmid_stat->{$vmid} = {
 292                     time => $cdtime,
 293                     used => $used_ms,
 294                     cpu => $d->{cpu},
 295                 };
 296             } else {
 297                 $d->{cpu} = $old->{cpu};
 298             }
 299         } else {
 300             $d->{cpu} = 0;
 301         }
 302     }
 303
 304     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 305
 306     foreach my $dev (keys %$netdev) {
 307         next if $dev !~ m/^veth([1-9]\d*)i/;
 308         my $vmid = $1;
 309         my $d = $list->{$vmid};
 310
 311         next if !$d;
 312
 313         $d->{netout} += $netdev->{$dev}->{receive};
 314         $d->{netin} += $netdev->{$dev}->{transmit};
 315
 316     }
 317
 318     return $list;
 319 }
 320
 321 sub find_lxc_console_pids {
 322
 323     my $res = {};
 324
 325     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 326         my ($pid) = @_;
 327
 328         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 329         return if !$cmdline;
 330
 331         my @args = split(/\0/, $cmdline);
 332
 333         # search for lxc-console -n <vmid>
 334         return if scalar(@args) != 3;
 335         return if $args[1] ne '-n';
 336         return if $args[2] !~ m/^\d+$/;
 337         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 338
 339         my $vmid = $args[2];
 340
 341         push @{$res->{$vmid}}, $pid;
 342     });
 343
 344     return $res;
 345 }
 346
 347 sub find_lxc_pid {
 348     my ($vmid) = @_;
 349
 350     my $pid = undef;
 351     my $parser = sub {
 352         my $line = shift;
 353         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 354     };
 355     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 356
 357     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 358
 359     return $pid;
 360 }
 361
 362 sub open_pid_fd($) {
 363     my ($pid) = @_;
 364     sysopen(my $fd, "/proc/$pid", O_RDONLY | O_DIRECTORY)
 365         or die "failed to open /proc/$pid pid fd\n";
 366     return $fd;
 367 }
 368
 369 sub open_lxc_pid {
 370     my ($vmid) = @_;
 371
 372     # Find the pid and open:
 373     my $pid = find_lxc_pid($vmid);
 374     my $fd = open_pid_fd($pid);
 375
 376     # Verify:
 377     my $pid2 = find_lxc_pid($vmid);
 378
 379     return () if $pid != $pid2;
 380     return ($pid, $fd);
 381 }
 382
 383 sub open_ppid {
 384     my ($pid) = @_;
 385
 386     # Find the parent pid via proc and open it:
 387     my $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 388     my $ppid = $stat->{ppid} // die "failed to get parent pid\n";
 389
 390     my $fd = open_pid_fd($ppid);
 391
 392     # Verify:
 393     $stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 394     my $ppid2 = $stat->{ppid} // die "failed to get parent pid for verification\n";
 395
 396     return () if $ppid != $ppid2;
 397     return ($ppid, $fd);
 398 }
 399
 400 # Note: we cannot use Net:IP, because that only allows strict
 401 # CIDR networks
 402 sub parse_ipv4_cidr {
 403     my ($cidr, $noerr) = @_;
 404
 405     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 406         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 407     }
 408
 409     return undef if $noerr;
 410
 411     die "unable to parse ipv4 address/mask\n";
 412 }
 413
 414 # With seccomp trap to userspace we now have the ability to optionally forward
 415 # certain syscalls to the "host" to handle (via our pve-lxc-syscalld daemon).
 416 #
 417 # This means that there are cases where we need to create an extra seccomp
 418 # profile for the container to load.
 419 #
 420 # This returns a configuration snippet added to the raw lxc config.
 421 sub make_seccomp_config {
 422     my ($conf, $vmid, $conf_dir, $unprivileged, $features) = @_;
 423     # User-configured profile has precedence, note that the user's entry would
 424     # be written 'after' this line anyway...
 425     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 426         # Warn the user if this conflicts with a feature:
 427         my $warn = join(', ', grep { $features->{$_} } qw(keyctl mknod));
 428         warn "explicitly configured lxc.seccomp.profile overrides the following settings: $warn\n"
 429             if length($warn) > 0;
 430         return '';
 431     }
 432
 433     # Privileged containers keep using the default (which is already part of
 434     # the files included via lxc.include, so we don't need to write it out,
 435     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 436     # well)
 437     return '' if !$unprivileged;
 438
 439     my $rules = {
 440         keyctl => ['errno 38'],
 441
 442         # Disable btrfs ioctrls since they don't work particularly well in user namespaces.
 443         # Particularly, without the mount option to enable rmdir removing snapshots, user
 444         # namespaces can create snapshots but neither `show` or `delete` them, which is quite
 445         # horrible, so for now, just disable this entirely:
 446         #
 447         # BTRFS_IOCTL_MAGIC 0x94, _IOC type shift is 8,
 448         # so `(req & 0xFF00) == 0x9400` is a btrfs ioctl and gets an EPERM
 449         ioctl  => ['errno 1 [1,0x9400,SCMP_CMP_MASKED_EQ,0xff00]'],
 450     };
 451
 452     my $raw_conf = '';
 453
 454     # Unprivileged containers will get keyctl() disabled by default as a
 455     # workaround for systemd-networkd behavior. But we have an option to
 456     # explicitly enable it:
 457     if ($features->{keyctl}) {
 458         delete $rules->{keyctl};
 459     }
 460
 461     # By default, unprivileged containers cannot use `mknod` at all.
 462     # Since lxc 3.2, we can use seccomp's trap to userspace feature for this,
 463     # but for now this is experimental, so it has to be enabled via a feature
 464     # flag.
 465     # Note that we only handle block and char devices (like lxd), the rest we
 466     # leave up to the kernel. We may in the future remove this if seccomp gets
 467     # a way to tell the kernel to "continue" a syscall.
 468     if ($features->{mknod}) {
 469         my ($ok, $kernel) = PVE::ProcFSTools::check_kernel_release(5, 3);
 470         if (!$ok) {
 471             die "'mknod' feature requested, but kernel too old (found $kernel, required >= 5.3)\n";
 472         }
 473
 474         $raw_conf .= "lxc.seccomp.notify.proxy = unix:/run/pve/lxc-syscalld.sock\n";
 475         $raw_conf .= "lxc.seccomp.notify.cookie = $vmid\n";
 476
 477         $rules->{mknod} = [
 478             # condition: (mode & S_IFMT) == S_IFCHR
 479             'notify [1,8192,SCMP_CMP_MASKED_EQ,61440]',
 480             # condition: (mode & S_IFMT) == S_IFBLK
 481             'notify [1,24576,SCMP_CMP_MASKED_EQ,61440]',
 482         ];
 483         $rules->{mknodat} = [
 484             # condition: (mode & S_IFMT) == S_IFCHR
 485             'notify [2,8192,SCMP_CMP_MASKED_EQ,61440]',
 486             # condition: (mode & S_IFMT) == S_IFBLK
 487             'notify [2,24576,SCMP_CMP_MASKED_EQ,61440]',
 488         ];
 489     }
 490
 491     # Now build the custom seccomp rule text...
 492     my $extra_rules = join("\n", map {
 493         my $syscall = $_;
 494         map { "$syscall $_" } $rules->{$syscall}->@*
 495     } sort keys %$rules) . "\n";
 496
 497     return $raw_conf if $extra_rules eq "\n";
 498
 499     # We still have the "most common" config readily available, so don't write
 500     # out that one:
 501     if ($raw_conf eq '' && $extra_rules eq "keyctl errno 38\n") {
 502         # we have no extra $raw_conf and use the same we had in pve 6.1:
 503         return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 504     }
 505
 506     # Write the rule file to the container's config path:
 507     my $rule_file = "$conf_dir/rules.seccomp";
 508     my $rule_data = file_get_contents("$LXC_CONFIG_PATH/common.seccomp")
 509         . $extra_rules;
 510     file_set_contents($rule_file, $rule_data);
 511     $raw_conf .= "lxc.seccomp.profile = $rule_file\n";
 512
 513     return $raw_conf;
 514 }
 515
 516 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 517 # automatically. The default should be equivalent to the old
 518 # `lxc-container-default-cgns` profile.
 519 #
 520 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 521 # additional lines into the profile. We can use that to allow mounting specific
 522 # file systems.
 523 sub make_apparmor_config {
 524     my ($conf, $unprivileged, $features) = @_;
 525
 526     # user-configured profile has precedence, but first we go through our own
 527     # code to figure out whether we should warn the user:
 528
 529     my $raw = "lxc.apparmor.profile = generated\n";
 530     my @profile_uses;
 531
 532     if ($features->{fuse}) {
 533         # For the informational warning:
 534         push @profile_uses, 'features:fuse';
 535     }
 536
 537     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 538     # apparmor lines, create an apparmor namespace for the container, but also
 539     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 540     # lxcfs mounted over them, because that would prevent the container from
 541     # mounting new instances of them for nested containers.
 542     if ($features->{nesting}) {
 543         push @profile_uses, 'features:nesting';
 544         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 545     } else {
 546         # In the default profile in /etc/apparmor.d we patch this in because
 547         # otherwise a container can for example run `chown` on /sys, breaking
 548         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 549         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 550         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 551         # Preferably we could use the 'remount' flag but this does not sit well
 552         # with apparmor_parser currently:
 553         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 554     }
 555
 556     if (my $mount = $features->{mount}) {
 557         push @profile_uses, 'features:mount';
 558         foreach my $fs (PVE::Tools::split_list($mount)) {
 559             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 560         }
 561     }
 562
 563     # More to come?
 564
 565     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 566         if (length(my $used = join(', ', @profile_uses))) {
 567             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 568         }
 569         return '';
 570     }
 571
 572     return $raw;
 573 }
 574
 575 sub update_lxc_config {
 576     my ($vmid, $conf) = @_;
 577
 578     my $dir = "/var/lib/lxc/$vmid";
 579
 580     if ($conf->{template}) {
 581
 582         unlink "$dir/config";
 583
 584         return;
 585     }
 586
 587     my ($lxc_major, $lxc_minor) = get_lxc_version();
 588
 589     my $raw = '';
 590
 591     if ($lxc_major >= 4) {
 592         # Explicitly don't use relative directories, which is the default, but
 593         # note that we do this mostly because they are only applied for *some*
 594         # cgroups. Our pve-container@.service now starts lxc-start with `-F`,
 595         # so we also don't need to worry about the new monitor cgroup to
 596         # confuse systemd.
 597         $raw .= "lxc.cgroup.relative = 0\n";
 598
 599         # To make things easier, let's keep our previous cgroup layout and
 600         # simply move the monitor outside:
 601         $raw .= "lxc.cgroup.dir.monitor = lxc.monitor/$vmid\n";
 602         # cgroup namespace separation for stronger limits:
 603         $raw .= "lxc.cgroup.dir.container = lxc/$vmid\n";
 604         $raw .= "lxc.cgroup.dir.container.inner = ns\n";
 605     }
 606
 607     die "missing 'arch' - internal error" if !$conf->{arch};
 608     $raw .= "lxc.arch = $conf->{arch}\n";
 609
 610     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 611     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 612
 613     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 614
 615     File::Path::mkpath($dir);
 616
 617     my $cfgpath = '/usr/share/lxc/config';
 618     my $inc = "$cfgpath/$ostype.common.conf";
 619     $inc ="$cfgpath/common.conf" if !-f $inc;
 620     $raw .= "lxc.include = $inc\n";
 621     if ($unprivileged) {
 622         $inc = "$cfgpath/$ostype.userns.conf";
 623         $inc = "$cfgpath/userns.conf" if !-f $inc;
 624         $raw .= "lxc.include = $inc\n";
 625     }
 626
 627     my $features = PVE::LXC::Config->parse_features($conf->{features});
 628
 629     $raw .= make_seccomp_config($conf, $vmid, $dir, $unprivileged, $features);
 630     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 631     if ($features->{fuse}) {
 632         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 633         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 634     }
 635
 636     if ($unprivileged && !$features->{force_rw_sys}) {
 637         # unpriv. CT default to sys:rw, but that doesn't always plays well with
 638         # systemd, e.g., systemd-networkd https://systemd.io/CONTAINER_INTERFACE/
 639         $raw .= "lxc.mount.auto = sys:mixed\n";
 640     }
 641
 642     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 643     # cannot be exposed to the container with r/w access (cgroup perms).
 644     # When this is enabled mounts will still remain in the monitor's namespace
 645     # after the container unmounted them and thus will not detach from their
 646     # files while the container is running!
 647     $raw .= "lxc.monitor.unshare = 1\n";
 648
 649     my ($cgv1, $cgv2) = PVE::CGroup::get_cgroup_controllers();
 650
 651     # Should we read them from /etc/subuid?
 652     if ($unprivileged && !$custom_idmap) {
 653         $raw .= "lxc.idmap = u 0 100000 65536\n";
 654         $raw .= "lxc.idmap = g 0 100000 65536\n";
 655     }
 656
 657     if (!PVE::LXC::Config->has_dev_console($conf)) {
 658         $raw .= "lxc.console.path = none\n";
 659         if ($cgv1->{devices}) {
 660             $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 661         } elsif (defined($cgv2)) {
 662             $raw .= "lxc.cgroup2.devices.deny = c 5:1 rwm\n";
 663         }
 664     }
 665
 666     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 667     $raw .= "lxc.tty.max = $ttycount\n";
 668
 669     # some init scripts expect a linux terminal (turnkey).
 670     $raw .= "lxc.environment = TERM=linux\n";
 671
 672     my $utsname = $conf->{hostname} || "CT$vmid";
 673     $raw .= "lxc.uts.name = $utsname\n";
 674
 675     if ($cgv1->{memory}) {
 676         my $memory = $conf->{memory} || 512;
 677         my $swap = $conf->{swap} // 0;
 678
 679         my $lxcmem = int($memory*1024*1024);
 680         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 681
 682         my $lxcswap = int(($memory + $swap)*1024*1024);
 683         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 684     } elsif ($cgv2->{memory}) {
 685         my $memory = $conf->{memory} || 512;
 686         my $swap = $conf->{swap} // 0;
 687
 688         # cgroup memory usage is limited by the hard 'max' limit (OOM-killer enforced) and the soft
 689         # 'high' limit (cgroup processes get throttled and put under heavy reclaim pressure).
 690         my ($lxc_mem_max, $lxc_mem_high) = PVE::LXC::Config::calculate_memory_constraints($memory);
 691         $raw .= "lxc.cgroup2.memory.max = $lxc_mem_max\n";
 692         $raw .= "lxc.cgroup2.memory.high = $lxc_mem_high\n";
 693
 694         my $lxcswap = int($swap*1024*1024);
 695         $raw .= "lxc.cgroup2.memory.swap.max = $lxcswap\n";
 696     }
 697
 698     if ($cgv1->{cpu}) {
 699         if (my $cpulimit = $conf->{cpulimit}) {
 700             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 701             my $value = int(100000*$cpulimit);
 702             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 703         }
 704
 705         my $shares = PVE::CGroup::clamp_cpu_shares($conf->{cpuunits});
 706         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 707     } elsif ($cgv2->{cpu}) {
 708         # See PVE::CGroup
 709         if (my $cpulimit = $conf->{cpulimit}) {
 710             my $value = int(100000*$cpulimit);
 711             $raw .= "lxc.cgroup2.cpu.max = $value 100000\n";
 712         }
 713
 714         if (defined(my $shares = $conf->{cpuunits})) {
 715             $shares = PVE::CGroup::clamp_cpu_shares($shares);
 716             $raw .= "lxc.cgroup2.cpu.weight = $shares\n";
 717         }
 718     }
 719
 720     die "missing 'rootfs' configuration\n"
 721         if !defined($conf->{rootfs});
 722
 723     my $mountpoint = PVE::LXC::Config->parse_volume('rootfs', $conf->{rootfs});
 724
 725     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 726
 727     foreach my $k (sort keys %$conf) {
 728         next if $k !~ m/^net(\d+)$/;
 729         my $ind = $1;
 730         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 731         $raw .= "lxc.net.$ind.type = veth\n";
 732         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 733         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 734         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 735
 736         my $bridge_mtu = PVE::Network::read_bridge_mtu($d->{bridge});
 737         my $mtu = $d->{mtu} || $bridge_mtu;
 738
 739         # Keep container from starting with invalid mtu configuration
 740         die "$k: MTU size '$mtu' is bigger than bridge MTU '$bridge_mtu'\n"
 741             if ($mtu > $bridge_mtu);
 742
 743         $raw .= "lxc.net.$ind.mtu = $mtu\n";
 744
 745         # Starting with lxc 4.0, we do not patch lxc to execute our up-scripts.
 746         if ($lxc_major >= 4) {
 747             $raw .= "lxc.net.$ind.script.up = /usr/share/lxc/lxcnetaddbr\n";
 748         }
 749     }
 750
 751     my $had_cpuset = 0;
 752     if (my $lxcconf = $conf->{lxc}) {
 753         foreach my $entry (@$lxcconf) {
 754             my ($k, $v) = @$entry;
 755             $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus' || $k eq 'lxc.cgroup2.cpuset.cpus';
 756             $raw .= "$k = $v\n";
 757         }
 758     }
 759
 760     my $cpuset;
 761     my ($cpuset_cgroup, $cpuset_version) = eval { PVE::CGroup::cpuset_controller_path() };
 762     if (defined($cpuset_cgroup)) {
 763         $cpuset = eval { PVE::CpuSet->new_from_path("$cpuset_cgroup/lxc", 1) }
 764             || PVE::CpuSet->new_from_path($cpuset_cgroup, 1);
 765     }
 766     my $cores = $conf->{cores};
 767     if (!$had_cpuset && $cores && $cpuset) {
 768         my @members = $cpuset->members();
 769         while (scalar(@members) > $cores) {
 770             my $randidx = int(rand(scalar(@members)));
 771             $cpuset->delete($members[$randidx]);
 772             splice(@members, $randidx, 1); # keep track of the changes
 773         }
 774         my $ver = $cpuset_version == 1 ? '' : '2';
 775         $raw .= "lxc.cgroup$ver.cpuset.cpus = ".$cpuset->short_string()."\n";
 776     }
 777
 778     File::Path::mkpath("$dir/rootfs");
 779
 780     PVE::Tools::file_set_contents("$dir/config", $raw);
 781 }
 782
 783 # verify and cleanup nameserver list (replace \0 with ' ')
 784 sub verify_nameserver_list {
 785     my ($nameserver_list) = @_;
 786
 787     my @list = ();
 788     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 789         PVE::LXC::Config::verify_ip_with_ll_iface($server);
 790         push @list, $server;
 791     }
 792
 793     return join(' ', @list);
 794 }
 795
 796 sub verify_searchdomain_list {
 797     my ($searchdomain_list) = @_;
 798
 799     my @list = ();
 800     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 801         # todo: should we add checks for valid dns domains?
 802         push @list, $server;
 803     }
 804
 805     return join(' ', @list);
 806 }
 807
 808 sub get_console_command {
 809     my ($vmid, $conf, $escapechar) = @_;
 810
 811     # '-1' as $escapechar disables keyboard escape sequence
 812     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 813
 814     my $cmode = PVE::LXC::Config->get_cmode($conf);
 815
 816     my $cmd = [];
 817     if ($cmode eq 'console') {
 818         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 819         push @$cmd, '-e', $escapechar if $escapechar;
 820     } elsif ($cmode eq 'tty') {
 821         push @$cmd, 'lxc-console', '-n',  $vmid;
 822         push @$cmd, '-e', $escapechar if $escapechar;
 823     } elsif ($cmode eq 'shell') {
 824         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 825     } else {
 826         die "internal error";
 827     }
 828
 829     return $cmd;
 830 }
 831
 832 sub get_primary_ips {
 833     my ($conf) = @_;
 834
 835     # return data from net0
 836
 837     return undef if !defined($conf->{net0});
 838     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 839
 840     my $ipv4 = $net->{ip};
 841     if ($ipv4) {
 842         if ($ipv4 =~ /^(dhcp|manual)$/) {
 843             $ipv4 = undef
 844         } else {
 845             $ipv4 =~ s!/\d+$!!;
 846         }
 847     }
 848     my $ipv6 = $net->{ip6};
 849     if ($ipv6) {
 850         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 851             $ipv6 = undef;
 852         } else {
 853             $ipv6 =~ s!/\d+$!!;
 854         }
 855     }
 856
 857     return ($ipv4, $ipv6);
 858 }
 859
 860 sub delete_mountpoint_volume {
 861     my ($storage_cfg, $vmid, $volume) = @_;
 862
 863     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 864
 865     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 866
 867     if ($vmid == $owner) {
 868         PVE::Storage::vdisk_free($storage_cfg, $volume);
 869     } else {
 870         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 871     }
 872 }
 873
 874 sub destroy_lxc_container {
 875     my ($storage_cfg, $vmid, $conf, $replacement_conf, $purge_unreferenced) = @_;
 876
 877     my $volids = {};
 878     my $remove_volume = sub {
 879         my ($ms, $mountpoint) = @_;
 880
 881         my $volume = $mountpoint->{volume};
 882
 883         return if $volids->{$volume};
 884         $volids->{$volume} = 1;
 885
 886         delete_mountpoint_volume($storage_cfg, $vmid, $volume);
 887     };
 888     PVE::LXC::Config->foreach_volume_full($conf, {include_unused => 1}, $remove_volume);
 889
 890     PVE::LXC::Config->foreach_volume_full($conf->{pending}, {include_unused => 1}, $remove_volume);
 891
 892     if ($purge_unreferenced) { # also remove unreferenced disk
 893         my $vmdisks = PVE::Storage::vdisk_list($storage_cfg, undef, $vmid, undef, 'rootdir');
 894         PVE::Storage::foreach_volid($vmdisks, sub {
 895             my ($volid, $sid, $volname, $d) = @_;
 896             eval { PVE::Storage::vdisk_free($storage_cfg, $volid) };
 897             warn $@ if $@;
 898         });
 899     }
 900
 901     rmdir "/var/lib/lxc/$vmid/rootfs";
 902     unlink "/var/lib/lxc/$vmid/config";
 903     rmdir "/var/lib/lxc/$vmid";
 904     if (defined $replacement_conf) {
 905         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 906     } else {
 907         PVE::LXC::Config->destroy_config($vmid);
 908     }
 909 }
 910
 911 sub vm_stop_cleanup {
 912     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 913
 914     return if $keepActive;
 915
 916     eval {
 917         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 918         PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 919     };
 920     warn $@ if $@; # avoid errors - just warn
 921 }
 922
 923 sub net_tap_plug : prototype($$) {
 924     my ($iface, $net) = @_;
 925
 926     if (defined($net->{link_down})) {
 927         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'down']);
 928         # Don't add disconnected interfaces to the bridge, otherwise e.g. applying any network
 929         # change (e.g. `ifreload -a`) could (re-)activate it unintentionally.
 930         return;
 931     }
 932
 933     my ($bridge, $tag, $firewall, $trunks, $rate, $hwaddr) =
 934         $net->@{'bridge', 'tag', 'firewall', 'trunks', 'rate', 'hwaddr'};
 935
 936     if ($have_sdn) {
 937         PVE::Network::SDN::Zones::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 938         PVE::Network::SDN::Zones::add_bridge_fdb($iface, $hwaddr, $bridge);
 939     } else {
 940         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate, { mac => $hwaddr });
 941     }
 942
 943     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', 'dev', $iface, 'up']);
 944 }
 945
 946 sub update_net {
 947     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 948
 949     if ($newnet->{type} ne 'veth') {
 950         # for when there are physical interfaces
 951         die "cannot update interface of type $newnet->{type}";
 952     }
 953
 954     my $veth = "veth${vmid}i${netid}";
 955     my $eth = $newnet->{name};
 956
 957     if (my $oldnetcfg = $conf->{$opt}) {
 958         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 959
 960         if (safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 961             safe_string_ne($oldnet->{name}, $newnet->{name})) {
 962
 963             PVE::Network::veth_delete($veth);
 964             delete $conf->{$opt};
 965             PVE::LXC::Config->write_config($vmid, $conf);
 966
 967             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 968
 969         } else {
 970             if (safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 971                 safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 972                 safe_num_ne($oldnet->{firewall}, $newnet->{firewall}) ||
 973                 safe_boolean_ne($oldnet->{link_down}, $newnet->{link_down})
 974             ) {
 975
 976                 if ($oldnet->{bridge}) {
 977                     PVE::Network::tap_unplug($veth);
 978                     foreach (qw(bridge tag firewall)) {
 979                         delete $oldnet->{$_};
 980                     }
 981                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 982                     PVE::LXC::Config->write_config($vmid, $conf);
 983                 }
 984
 985                 PVE::LXC::net_tap_plug($veth, $newnet);
 986
 987                 # This includes the rate:
 988                 foreach (qw(bridge tag firewall rate link_down)) {
 989                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 990                 }
 991             } elsif (safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 992                 # Rate can be applied on its own but any change above needs to
 993                 # include the rate in tap_plug since OVS resets everything.
 994                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 995                 $oldnet->{rate} = $newnet->{rate}
 996             }
 997             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 998             PVE::LXC::Config->write_config($vmid, $conf);
 999         }
1000     } else {
1001         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1002     }
1003
1004     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1005 }
1006
1007 sub hotplug_net {
1008     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1009
1010     my $veth = "veth${vmid}i${netid}";
1011     my $vethpeer = $veth . "p";
1012     my $eth = $newnet->{name};
1013
1014     if ($have_sdn) {
1015         PVE::Network::SDN::Zones::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1016     } else {
1017         PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1018     }
1019
1020     PVE::LXC::net_tap_plug($veth, $newnet);
1021
1022     # attach peer in container
1023     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1024     PVE::Tools::run_command($cmd);
1025
1026     # link up peer in container
1027     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1028     PVE::Tools::run_command($cmd);
1029
1030     my $done = { type => 'veth' };
1031     foreach (qw(bridge tag firewall hwaddr name link_down)) {
1032         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1033     }
1034     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
1035
1036     PVE::LXC::Config->write_config($vmid, $conf);
1037 }
1038
1039 sub get_interfaces {
1040     my ($vmid) = @_;
1041
1042     my $pid = eval { find_lxc_pid($vmid); };
1043     return if $@;
1044
1045     my $output;
1046     # enters the network namespace of the container and executes 'ip a'
1047     run_command(['nsenter', '-t', $pid, '--net', '--', 'ip', '--json', 'a'],
1048         outfunc => sub { $output .= shift; });
1049
1050     my $config = JSON::decode_json($output);
1051
1052     my $res;
1053     for my $interface ($config->@*) {
1054         my $obj = { name => $interface->{ifname} };
1055         for my $ip ($interface->{addr_info}->@*) {
1056             $obj->{$ip->{family}} = $ip->{local} . "/" . $ip->{prefixlen};
1057         }
1058         $obj->{hwaddr} = $interface->{address};
1059         push @$res, $obj
1060     }
1061
1062     return $res;
1063 }
1064
1065 sub update_ipconfig {
1066     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1067
1068     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
1069
1070     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
1071     my $deleted = [];
1072     my $added = [];
1073     my $nscmd = sub {
1074         my $cmdargs = shift;
1075         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1076     };
1077     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1078
1079     my $change_ip_config = sub {
1080         my ($ipversion) = @_;
1081
1082         my $family_opt = "-$ipversion";
1083         my $suffix = $ipversion == 4 ? '' : $ipversion;
1084         my $gw= "gw$suffix";
1085         my $ip= "ip$suffix";
1086
1087         my $newip = $newnet->{$ip};
1088         my $newgw = $newnet->{$gw};
1089         my $oldip = $optdata->{$ip};
1090         my $oldgw = $optdata->{$gw};
1091
1092         my $change_ip = safe_string_ne($oldip, $newip);
1093         my $change_gw = safe_string_ne($oldgw, $newgw);
1094
1095         return if !$change_ip && !$change_gw;
1096
1097         # step 1: add new IP, if this fails we cancel
1098         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
1099         if ($change_ip && $is_real_ip) {
1100             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1101             if (my $err = $@) {
1102                 warn $err;
1103                 return;
1104             }
1105         }
1106
1107         # step 2: replace gateway
1108         #   If this fails we delete the added IP and cancel.
1109         #   If it succeeds we save the config and delete the old IP, ignoring
1110         #   errors. The config is then saved.
1111         # Note: 'ip route replace' can add
1112         if ($change_gw) {
1113             if ($newgw) {
1114                 eval {
1115                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
1116                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
1117                     }
1118                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
1119                 };
1120                 if (my $err = $@) {
1121                     warn $err;
1122                     # the route was not replaced, the old IP is still available
1123                     # rollback (delete new IP) and cancel
1124                     if ($change_ip) {
1125                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1126                         warn $@ if $@; # no need to die here
1127                     }
1128                     return;
1129                 }
1130             } else {
1131                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1132                 # if the route was not deleted, the guest might have deleted it manually
1133                 # warn and continue
1134                 warn $@ if $@;
1135             }
1136             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
1137                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
1138                 # warn if the route was deleted manually
1139                 warn $@ if $@;
1140             }
1141         }
1142
1143         # from this point on we save the configuration
1144         # step 3: delete old IP ignoring errors
1145         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1146             # We need to enable promote_secondaries, otherwise our newly added
1147             # address will be removed along with the old one.
1148             my $promote = 0;
1149             eval {
1150                 if ($ipversion == 4) {
1151                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1152                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1153                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1154                 }
1155                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1156             };
1157             warn $@ if $@; # no need to die here
1158
1159             if ($ipversion == 4) {
1160                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1161             }
1162         }
1163
1164         foreach my $property ($ip, $gw) {
1165             if ($newnet->{$property}) {
1166                 $optdata->{$property} = $newnet->{$property};
1167             } else {
1168                 delete $optdata->{$property};
1169             }
1170         }
1171         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
1172         PVE::LXC::Config->write_config($vmid, $conf);
1173         $lxc_setup->setup_network($conf);
1174     };
1175
1176     &$change_ip_config(4);
1177     &$change_ip_config(6);
1178
1179 }
1180
1181 my $open_namespace = sub {
1182     my ($vmid, $pid, $kind) = @_;
1183     sysopen my $fd, "/proc/$pid/ns/$kind", O_RDONLY
1184         or die "failed to open $kind namespace of container $vmid: $!\n";
1185     return $fd;
1186 };
1187
1188 my $enter_namespace = sub {
1189     my ($vmid, $pid, $kind, $type) = @_;
1190     my $fd = $open_namespace->($vmid, $pid, $kind);
1191     PVE::Tools::setns(fileno($fd), $type)
1192         or die "failed to enter $kind namespace of container $vmid: $!\n";
1193     close $fd;
1194 };
1195
1196 my $get_container_namespace = sub {
1197     my ($vmid, $pid, $kind) = @_;
1198
1199     my $pidfd;
1200     if (!defined($pid)) {
1201         # Pin the pid while we're grabbing its stuff from /proc
1202         ($pid, $pidfd) = open_lxc_pid($vmid)
1203             or die "failed to open pidfd of container $vmid\'s init process\n";
1204     }
1205
1206     return $open_namespace->($vmid, $pid, $kind);
1207 };
1208
1209 my $do_syncfs = sub {
1210     my ($vmid, $pid, $socket) = @_;
1211
1212     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1213
1214     # Tell the parent process to start reading our /proc/mounts
1215     print {$socket} "go\n";
1216     $socket->flush();
1217
1218     # Receive /proc/self/mounts
1219     my $mountdata = do { local $/ = undef; <$socket> };
1220     close $socket;
1221
1222     my %nosyncfs = (
1223         cgroup => 1,
1224         cgroup2 => 1,
1225         devtmpfs => 1,
1226         devpts => 1,
1227         'fuse.lxcfs' => 1,
1228         fusectl => 1,
1229         mqueue => 1,
1230         proc => 1,
1231         sysfs => 1,
1232         tmpfs => 1,
1233     );
1234
1235     # Now sync all mountpoints...
1236     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1237     foreach my $mp (@$mounts) {
1238         my ($what, $dir, $fs) = @$mp;
1239         next if $nosyncfs{$fs};
1240         eval { PVE::Tools::sync_mountpoint($dir); };
1241         warn $@ if $@;
1242     }
1243 };
1244
1245 sub sync_container_namespace {
1246     my ($vmid) = @_;
1247     my $pid = find_lxc_pid($vmid);
1248
1249     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1250     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1251         or die "failed to create socketpair: $!\n";
1252
1253     my $child = fork();
1254     die "fork failed: $!\n" if !defined($child);
1255
1256     if (!$child) {
1257         eval {
1258             close $pfd;
1259             &$do_syncfs($vmid, $pid, $cfd);
1260         };
1261         if (my $err = $@) {
1262             warn $err;
1263             POSIX::_exit(1);
1264         }
1265         POSIX::_exit(0);
1266     }
1267     close $cfd;
1268     my $go = <$pfd>;
1269     die "failed to enter container namespace\n" if $go ne "go\n";
1270
1271     open my $mounts, '<', "/proc/$child/mounts"
1272         or die "failed to open container's /proc/mounts: $!\n";
1273     my $mountdata = do { local $/ = undef; <$mounts> };
1274     close $mounts;
1275     print {$pfd} $mountdata;
1276     close $pfd;
1277
1278     while (waitpid($child, 0) != $child) {}
1279     die "failed to sync container namespace\n" if $? != 0;
1280 }
1281
1282 sub template_create {
1283     my ($vmid, $conf) = @_;
1284
1285     my $storecfg = PVE::Storage::config();
1286
1287     PVE::LXC::Config->foreach_volume($conf, sub {
1288         my ($ms, $mountpoint) = @_;
1289
1290         my $volid = $mountpoint->{volume};
1291
1292         die "Template feature is not available for '$volid'\n"
1293             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1294     });
1295
1296     PVE::LXC::Config->foreach_volume($conf, sub {
1297         my ($ms, $mountpoint) = @_;
1298
1299         my $volid = $mountpoint->{volume};
1300
1301         PVE::Storage::activate_volumes($storecfg, [$volid]);
1302
1303         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1304         $mountpoint->{volume} = $template_volid;
1305         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1306     });
1307
1308     PVE::LXC::Config->write_config($vmid, $conf);
1309 }
1310
1311 sub check_ct_modify_config_perm {
1312     my ($rpcenv, $authuser, $vmid, $pool, $oldconf, $newconf, $delete, $unprivileged) = @_;
1313
1314     return 1 if $authuser eq 'root@pam';
1315     my $storage_cfg = PVE::Storage::config();
1316
1317     my $check = sub {
1318         my ($opt, $delete) = @_;
1319         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1320             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1321         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1322             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1323             return if $delete;
1324             my $data = PVE::LXC::Config->parse_volume($opt, $newconf->{$opt});
1325             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1326                 if $data->{type} ne 'volume';
1327             my $volid = $data->{volume};
1328             if ($volid =~ $NEW_DISK_RE) {
1329                 my $sid = $1;
1330                 $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
1331             } else {
1332                 PVE::Storage::check_volume_access(
1333                     $rpcenv,
1334                     $authuser,
1335                     $storage_cfg,
1336                     $vmid,
1337                     $volid,
1338                     'rootdir',
1339                 );
1340             }
1341         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1342             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1343         } elsif ($opt =~ m/^net\d+$/) {
1344             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1345             check_bridge_access($rpcenv, $authuser, $oldconf->{$opt}) if $oldconf->{$opt};
1346             check_bridge_access($rpcenv, $authuser, $newconf->{$opt}) if $newconf->{$opt};
1347         } elsif ($opt eq 'nameserver' || $opt eq 'searchdomain' || $opt eq 'hostname') {
1348             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1349         } elsif ($opt eq 'features') {
1350             raise_perm_exc("changing feature flags for privileged container is only allowed for root\@pam")
1351                 if !$unprivileged;
1352
1353             my $nesting_changed = 0;
1354             my $other_changed = 0;
1355             if (!$delete) {
1356                 my $features = PVE::LXC::Config->parse_features($newconf->{$opt});
1357                 if (defined($oldconf) && $oldconf->{$opt}) {
1358                     # existing container with features
1359                     my $old_features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1360                     for my $feature ((keys %$old_features, keys %$features)) {
1361                         my $old = $old_features->{$feature} // '';
1362                         my $new = $features->{$feature} // '';
1363                         if ($old ne $new) {
1364                             if ($feature eq 'nesting') {
1365                                 $nesting_changed = 1;
1366                                 next;
1367                             } else {
1368                                 $other_changed = 1;
1369                                 last;
1370                             }
1371                         }
1372                     }
1373                 } else {
1374                     # new container or no features defined
1375                     if (scalar(keys %$features) == 1 && $features->{nesting}) {
1376                         $nesting_changed = 1;
1377                     } elsif (scalar(keys %$features) > 0) {
1378                         $other_changed = 1;
1379                     }
1380                 }
1381             } else {
1382                 my $features = PVE::LXC::Config->parse_features($oldconf->{$opt});
1383                 if (scalar(keys %$features) == 1 && $features->{nesting}) {
1384                     $nesting_changed = 1;
1385                 } elsif (scalar(keys %$features) > 0) {
1386                     $other_changed = 1;
1387                 }
1388             }
1389             raise_perm_exc("changing feature flags (except nesting) is only allowed for root\@pam")
1390                 if $other_changed;
1391             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Allocate'])
1392                 if $nesting_changed;
1393         } elsif ($opt eq 'hookscript') {
1394             # For now this is restricted to root@pam
1395             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1396         } elsif ($opt eq 'tags') {
1397             my $old = $oldconf->{$opt};
1398             my $new = $delete ? '' : $newconf->{$opt};
1399             PVE::GuestHelpers::assert_tag_permissions($vmid, $old, $new, $rpcenv, $authuser);
1400         } else {
1401             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1402         }
1403     };
1404
1405     foreach my $opt (keys %$newconf) {
1406         &$check($opt, 0);
1407     }
1408     foreach my $opt (@$delete) {
1409         &$check($opt, 1);
1410     }
1411
1412     return 1;
1413 }
1414
1415 sub check_bridge_access {
1416     my ($rpcenv, $authuser, $raw) = @_;
1417
1418     return 1 if $authuser eq 'root@pam';
1419
1420     my $net = PVE::LXC::Config->parse_lxc_network($raw);
1421     my ($bridge, $tag, $trunks) = $net->@{'bridge', 'tag', 'trunks'};
1422     check_vnet_access($rpcenv, $authuser, $bridge, $tag, $trunks);
1423
1424     return 1;
1425 };
1426
1427 sub umount_all {
1428     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1429
1430     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1431     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1432
1433     my $res = 1;
1434
1435     PVE::LXC::Config->foreach_volume_full($conf, {'reverse' => 1}, sub {
1436         my ($ms, $mountpoint) = @_;
1437
1438         my $volid = $mountpoint->{volume};
1439         my $mount = $mountpoint->{mp};
1440
1441         return if !$volid || !$mount;
1442
1443         my $mount_path = "$rootdir/$mount";
1444         $mount_path =~ s!/+!/!g;
1445
1446         return if !PVE::ProcFSTools::is_mounted($mount_path);
1447
1448         eval {
1449             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1450         };
1451         if (my $err = $@) {
1452             if ($noerr) {
1453                 $res = 0;
1454                 warn $err;
1455             } else {
1456                 die $err;
1457             }
1458         }
1459     });
1460
1461     return $res; # tell caller if (some) umounts failed for the noerr case
1462 }
1463
1464 sub mount_all {
1465     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1466
1467     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1468     File::Path::make_path($rootdir);
1469
1470     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1471     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1472
1473     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1474
1475     eval {
1476         PVE::LXC::Config->foreach_volume($conf, sub {
1477             my ($ms, $mountpoint) = @_;
1478
1479             $mountpoint->{ro} = 0 if $ignore_ro;
1480
1481             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1482         });
1483     };
1484     if (my $err = $@) {
1485         warn "mounting container failed\n";
1486         umount_all($vmid, $storage_cfg, $conf, 1);
1487         die $err;
1488     }
1489
1490     return $rootdir;
1491 }
1492
1493
1494 sub mountpoint_mount_path {
1495     my ($mountpoint, $storage_cfg, $snapname) = @_;
1496
1497     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1498 }
1499
1500 sub query_loopdev {
1501     my ($path) = @_;
1502     my $found;
1503     my $parser = sub {
1504         my $line = shift;
1505         if ($line =~ m@^(/dev/loop\d+):@) {
1506             $found = $1;
1507         }
1508     };
1509     my $cmd = ['losetup', '--associated', $path];
1510     PVE::Tools::run_command($cmd, outfunc => $parser);
1511     return $found;
1512 }
1513
1514 # Run a function with a file attached to a loop device.
1515 # The loop device is always detached afterwards (or set to autoclear).
1516 # Returns the loop device.
1517 sub run_with_loopdev {
1518     my ($func, $file, $readonly) = @_;
1519     my $device = query_loopdev($file);
1520     # Try to reuse an existing device
1521     if ($device) {
1522         # We assume that whoever setup the loop device is responsible for
1523         # detaching it.
1524         &$func($device);
1525         return $device;
1526     }
1527
1528     my $parser = sub {
1529         my $line = shift;
1530         if ($line =~ m@^(/dev/loop\d+)$@) {
1531             $device = $1;
1532         }
1533     };
1534     my $losetup_cmd = [
1535         'losetup',
1536         '--show',
1537         '-f',
1538         $file,
1539     ];
1540     push @$losetup_cmd, '-r' if $readonly;
1541     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1542     die "failed to setup loop device for $file\n" if !$device;
1543     eval { &$func($device); };
1544     my $err = $@;
1545     PVE::Tools::run_command(['losetup', '-d', $device]);
1546     die $err if $err;
1547     return $device;
1548 }
1549
1550 # In scalar mode: returns a file handle to the deepest directory node.
1551 # In list context: returns a list of:
1552 #   * the deepest directory node
1553 #   * the 2nd deepest directory (parent of the above)
1554 #   * directory name of the last directory
1555 # So that the path $2/$3 should lead to $1 afterwards.
1556 sub walk_tree_nofollow($$$;$$) {
1557     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1558
1559     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1560         or die "failed to open start directory $start: $!\n";
1561
1562     return walk_tree_nofollow_fd($start, $fd, $subdir, $mkdir, $rootuid, $rootgid);
1563 }
1564
1565
1566 sub walk_tree_nofollow_fd($$$$;$$) {
1567     my ($start_dirname, $start_fd, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1568
1569     # splitdir() returns '' for empty components including the leading /
1570     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1571
1572     my $fd = $start_fd;
1573     my $dir = $start_dirname;
1574     my $last_component = undef;
1575     my $second = $fd;
1576     foreach my $component (@comps) {
1577         $dir .= "/$component";
1578         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1579
1580         if (!$next) {
1581             # failed, check for symlinks and try to create the path
1582             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1583             die "cannot open directory $dir: $!\n" if !$mkdir;
1584
1585             # We don't check for errors on mkdirat() here and just try to
1586             # openat() again, since at least one error (EEXIST) is an
1587             # expected possibility if multiple containers start
1588             # simultaneously. If someone else injects a symlink now then
1589             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1590             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1591
1592             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1593             die "failed to create path: $dir: $!\n" if !$next;
1594
1595             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1596                 if defined($rootuid) && defined($rootgid);
1597         }
1598
1599         close $second if defined($last_component) && $second != $start_fd;
1600         $last_component = $component;
1601         $second = $fd;
1602         $fd = $next;
1603     }
1604
1605     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1606     close $second if defined($last_component) && $second != $start_fd;
1607     return $fd;
1608 }
1609
1610 # To guard against symlink attack races against other currently running
1611 # containers with shared recursive bind mount hierarchies we prepare a
1612 # directory handle for the directory we're mounting over to verify the
1613 # mountpoint afterwards.
1614 sub __bindmount_prepare {
1615     my ($hostroot, $dir) = @_;
1616     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1617     return $srcdh;
1618 }
1619
1620 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1621 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1622 # we intended to bind mount.
1623 sub __bindmount_verify {
1624     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1625     my $destdh;
1626     if ($parentfd) {
1627         # Open the mount point path coming from the parent directory since the
1628         # filehandle we would have gotten as first result of walk_tree_nofollow
1629         # earlier is still a handle to the underlying directory instead of the
1630         # mounted path.
1631         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1632         die "failed to open mount point: $!\n" if !$destdh;
1633         if ($ro) {
1634             my $dot = '.';
1635             # no separate function because 99% of the time it's the wrong thing to use.
1636             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1637                 die "failed to mark bind mount read only\n";
1638             }
1639             die "read-only check failed: $!\n" if $! != EROFS;
1640         }
1641     } else {
1642         # For the rootfs we don't have a parentfd so we open the path directly.
1643         # Note that this means bindmounting any prefix of the host's
1644         # /var/lib/lxc/$vmid path into another container is considered a grave
1645         # security error.
1646         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1647         die "failed to open mount point: $!\n" if !$destdh;
1648     }
1649
1650     my ($srcdev, $srcinode) = stat($srcdh);
1651     my ($dstdev, $dstinode) = stat($destdh);
1652     close $srcdh;
1653     close $destdh;
1654
1655     return ($srcdev == $dstdev && $srcinode == $dstinode);
1656 }
1657
1658 # Perform the actual bind mounting:
1659 sub __bindmount_do {
1660     my ($dir, $dest, $ro, @extra_opts) = @_;
1661     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1662     if ($ro) {
1663         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1664         if (my $err = $@) {
1665             warn "bindmount error\n";
1666             # don't leave writable bind-mounts behind...
1667             PVE::Tools::run_command(['umount', $dest]);
1668             die $err;
1669         }
1670     }
1671 }
1672
1673 sub bindmount {
1674     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1675
1676     my $srcdh = __bindmount_prepare('/', $dir);
1677
1678     __bindmount_do($dir, $dest, $ro, @extra_opts);
1679
1680     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1681         PVE::Tools::run_command(['umount', $dest]);
1682         die "detected mount path change at: $dir\n";
1683     }
1684 }
1685
1686 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1687 # from $rootdir and $mount and walk the path from $rootdir to the final
1688 # directory to check for symlinks.
1689 sub __mount_prepare_rootdir {
1690     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1691     $rootdir =~ s!/+!/!g;
1692     $rootdir =~ s!/+$!!;
1693     my $mount_path = "$rootdir/$mount";
1694     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1695     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1696 }
1697
1698 # use $rootdir = undef to just return the corresponding mount path
1699 sub mountpoint_mount {
1700     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1701     return __mountpoint_mount($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, undef);
1702 }
1703
1704 sub mountpoint_stage {
1705     my ($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1706     my ($path, $loop, $dev) =
1707         __mountpoint_mount($mountpoint, $stage_dir, $storage_cfg, $snapname, $rootuid, $rootgid, 1);
1708
1709     if (!defined($path)) {
1710         die "failed to mount subvolume: $!\n";
1711     }
1712
1713     # We clone the mount point and leave it there in order to keep them connected to eg. loop
1714     # devices in case we're hotplugging (which would allow contaienrs to unmount the new mount
1715     # point).
1716     my $err;
1717     my $fd = PVE::Tools::open_tree(&AT_FDCWD, $stage_dir, &OPEN_TREE_CLOEXEC | &OPEN_TREE_CLONE)
1718         or die "open_tree() on mount point failed: $!\n";
1719
1720     return wantarray ? ($path, $loop, $dev, $fd) : $fd;
1721 }
1722
1723 sub mountpoint_insert_staged {
1724     my ($mount_fd, $rootdir_fd, $mp_dir, $opt, $rootuid, $rootgid) = @_;
1725
1726     if (!defined($rootdir_fd)) {
1727         sysopen($rootdir_fd, '.', O_PATH | O_DIRECTORY)
1728             or die "failed to open '.': $!\n";
1729     }
1730
1731     my $dest_fd = walk_tree_nofollow_fd('/', $rootdir_fd, $mp_dir, 1, $rootuid, $rootgid);
1732
1733     PVE::Tools::move_mount(
1734         fileno($mount_fd),
1735         '',
1736         fileno($dest_fd),
1737         '',
1738         &MOVE_MOUNT_F_EMPTY_PATH | &MOVE_MOUNT_T_EMPTY_PATH,
1739     ) or die "failed to move '$opt' into container hierarchy: $!\n";
1740 }
1741
1742 # Use $stage_mount, $rootdir is treated as a temporary path to "stage" the file system. The user
1743 #   can then open a file descriptor to it which can be used with the `move_mount` syscall.
1744 sub __mountpoint_mount {
1745     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid, $stage_mount) = @_;
1746
1747     # When staging mount points we always mount to $rootdir directly (iow. as if `mp=/`).
1748     # This is required since __mount_prepare_rootdir() will return handles to the parent directory
1749     # which we use in __bindmount_verify()!
1750     my $mount = $stage_mount ? '/': $mountpoint->{mp};
1751
1752     my $volid = $mountpoint->{volume};
1753     my $type = $mountpoint->{type};
1754     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1755     my $mounted_dev;
1756
1757     return if !$volid || !$mount;
1758
1759     $mount =~ s!/+!/!g;
1760
1761     my $mount_path;
1762     my ($mpfd, $parentfd, $last_dir);
1763
1764     if (defined($rootdir)) {
1765         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1766             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1767     }
1768
1769     if (defined($stage_mount)) {
1770         $mount_path = $rootdir;
1771     }
1772
1773     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1774
1775     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1776
1777     my $optlist = [];
1778
1779     if (my $mountopts = $mountpoint->{mountoptions}) {
1780         my @opts = split(/;/, $mountpoint->{mountoptions});
1781         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1782     }
1783
1784     my $acl = $mountpoint->{acl};
1785     if (defined($acl)) {
1786         push @$optlist, ($acl ? 'acl' : 'noacl');
1787     }
1788
1789     my $optstring = join(',', @$optlist);
1790     my $readonly = $mountpoint->{ro};
1791
1792     my @extra_opts;
1793     @extra_opts = ('-o', $optstring) if $optstring;
1794
1795     if ($storage) {
1796
1797         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1798
1799         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1800
1801         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1802
1803         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1804             PVE::Storage::parse_volname($storage_cfg, $volid);
1805
1806         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1807
1808         if ($format eq 'subvol') {
1809             if ($mount_path) {
1810                 my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1811                 if (defined($snapname)) {
1812                     $name .= "\@$snapname";
1813                     if ($scfg->{type} eq 'zfspool') {
1814                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', "$scfg->{pool}/$name", $mount_path]);
1815                     } else {
1816                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1817                     }
1818                 } else {
1819                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1820                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1821                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1822                     }
1823                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1824                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1825                 }
1826             }
1827             return wantarray ? ($path, 0, undef) : $path;
1828         } elsif ($format eq 'raw' || $format eq 'iso') {
1829             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1830             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1831             # Our autodev hook expects the /dev/dm-* device currently
1832             # and will create the /dev/mapper symlink accordingly
1833             $path = Cwd::realpath($path);
1834             die "failed to get device path\n" if !$path;
1835             ($path) = ($path =~ /^(.*)$/s); #untaint
1836             my $domount = sub {
1837                 my ($path) = @_;
1838                 if ($mount_path) {
1839                     if ($format eq 'iso') {
1840                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1841                     } elsif ($isBase || defined($snapname)) {
1842                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1843                     } else {
1844                         if ($quota) {
1845                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1846                         }
1847                         push @extra_opts, '-o', 'ro' if $readonly;
1848                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1849                     }
1850                 }
1851             };
1852             my $use_loopdev = 0;
1853             if ($scfg->{content}->{rootdir}) {
1854                 if ($scfg->{path}) {
1855                     $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1856                     $use_loopdev = 1;
1857                 } else {
1858                     $mounted_dev = $path;
1859                     &$domount($path);
1860                 }
1861             } else {
1862                 die "storage '$storage' does not support containers\n";
1863             }
1864             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1865         } else {
1866             die "unsupported image format '$format'\n";
1867         }
1868     } elsif ($type eq 'device') {
1869         push @extra_opts, '-o', 'ro' if $readonly;
1870         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1871         # See the NOTE above about devicemapper canonicalization
1872         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1873         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1874         return wantarray ? ($volid, 0, $devpath) : $volid;
1875     } elsif ($type eq 'bind') {
1876         die "directory '$volid' does not exist\n" if ! -d $volid;
1877         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1878         warn "cannot enable quota control for bind mounts\n" if $quota;
1879         return wantarray ? ($volid, 0, undef) : $volid;
1880     }
1881
1882     die "unsupported storage";
1883 }
1884
1885 sub mountpoint_hotplug :prototype($$$$$) {
1886     my ($vmid, $conf, $opt, $mp, $storage_cfg) = @_;
1887
1888     my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1889
1890     # We do the rest in a fork with an unshared mount namespace, because:
1891     #  -) change our papparmor profile to that of /usr/bin/lxc-start
1892     #  -) we're now going to 'stage' # the mountpoint, then grab it, then move into the
1893     #     container's namespace, then mount it.
1894
1895     PVE::Tools::run_fork(sub {
1896         # Pin the container pid longer, we also need to get its monitor/parent:
1897         my ($ct_pid, $ct_pidfd) = open_lxc_pid($vmid)
1898             or die "failed to open pidfd of container $vmid\'s init process\n";
1899
1900         my ($monitor_pid, $monitor_pidfd) = open_ppid($ct_pid)
1901             or die "failed to open pidfd of container $vmid\'s monitor process\n";
1902
1903         my $ct_mnt_ns = $get_container_namespace->($vmid, $ct_pid, 'mnt');
1904         my $monitor_mnt_ns = $get_container_namespace->($vmid, $monitor_pid, 'mnt');
1905
1906         # Grab a file descriptor to our apparmor label file so we can change into the 'lxc-start'
1907         # profile to lower our privileges to the same level we have in the start hook:
1908         sysopen(my $aa_fd, "/proc/self/attr/current", O_WRONLY)
1909             or die "failed to open '/proc/self/attr/current' for writing: $!\n";
1910         # But switch namespaces first, to make sure the namespace switches aren't blocked by
1911         # apparmor.
1912
1913         # Change into the monitor's mount namespace. We "pin" the mount into the monitor's
1914         # namespace for it to remain active there since the container will be able to unmount
1915         # hotplugged mount points and thereby potentially free up loop devices, which is a security
1916         # concern.
1917         PVE::Tools::setns(fileno($monitor_mnt_ns), PVE::Tools::CLONE_NEWNS);
1918         chdir('/')
1919             or die "failed to change root directory within the monitor's mount namespace: $!\n";
1920
1921         my $dir = get_staging_mount_path($opt);
1922
1923         # Now switch our apparmor profile before mounting:
1924         my $data = 'changeprofile /usr/bin/lxc-start';
1925         if (syswrite($aa_fd, $data, length($data)) != length($data)) {
1926             die "failed to change apparmor profile: $!\n";
1927         }
1928         # Check errors on close as well:
1929         close($aa_fd)
1930             or die "failed to change apparmor profile (close() failed): $!\n";
1931
1932         my $mount_fd = mountpoint_stage($mp, $dir, $storage_cfg, undef, $rootuid, $rootgid);
1933
1934         PVE::Tools::setns(fileno($ct_mnt_ns), PVE::Tools::CLONE_NEWNS);
1935         chdir('/')
1936             or die "failed to change root directory within the container's mount namespace: $!\n";
1937
1938         mountpoint_insert_staged($mount_fd, undef, $mp->{mp}, $opt, $rootuid, $rootgid);
1939     });
1940 }
1941
1942 # Create a directory in the mountpoint staging tempfs.
1943 sub get_staging_mount_path($) {
1944     my ($opt) = @_;
1945
1946     my $target = get_staging_tempfs() . "/$opt";
1947     if (!mkdir($target) && $! != EEXIST) {
1948         die "failed to create directory $target: $!\n";
1949     }
1950
1951     return $target;
1952 }
1953
1954 # Mount tmpfs for mount point staging and return the path.
1955 sub get_staging_tempfs() {
1956     # We choose a path in /var/lib/lxc/ here because the lxc-start apparmor profile restricts most
1957     # mounts to that.
1958     my $target = '/var/lib/lxc/.pve-staged-mounts';
1959     if (!mkdir($target)) {
1960         return $target if $! == EEXIST;
1961         die "failed to create directory $target: $!\n";
1962     }
1963
1964     PVE::Tools::mount("none", $target, 'tmpfs', 0, "size=8k,mode=755")
1965         or die "failed to mount $target as tmpfs: $!\n";
1966
1967     return $target;
1968 }
1969
1970 sub mkfs {
1971     my ($dev, $rootuid, $rootgid) = @_;
1972
1973     run_command(
1974         [
1975             'mkfs.ext4',
1976             '-O',
1977             'mmp',
1978             '-E',
1979             "root_owner=$rootuid:$rootgid",
1980             $dev,
1981         ],
1982         outfunc => sub {
1983             my $line = shift;
1984             # a hack to print only the relevant stuff, i.e., the one which could help on repair
1985             if ($line =~ /^(Creating filesystem|Filesystem UUID|Superblock backups|\s+\d+, \d)/) {
1986                 print "$line\n";
1987             }
1988         },
1989         errfunc => sub {
1990             my $line = shift;
1991             print STDERR "$line\n" if $line && $line !~ /^mke2fs \d\.\d/;
1992         }
1993     );
1994 }
1995
1996 sub format_disk {
1997     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1998
1999     if ($volid =~ m!^/dev/.+!) {
2000         mkfs($volid);
2001         return;
2002     }
2003
2004     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2005
2006     die "cannot format volume '$volid' with no storage\n" if !$storage;
2007
2008     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
2009
2010     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
2011
2012     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
2013
2014     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
2015         PVE::Storage::parse_volname($storage_cfg, $volid);
2016
2017     die "cannot format volume '$volid' (format == $format)\n"
2018         if $format ne 'raw';
2019
2020     mkfs($path, $rootuid, $rootgid);
2021 }
2022
2023 sub destroy_disks {
2024     my ($storecfg, $vollist) = @_;
2025
2026     foreach my $volid (@$vollist) {
2027         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2028         warn $@ if $@;
2029     }
2030 }
2031
2032 sub alloc_disk {
2033     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
2034
2035     my $needs_chown = 0;
2036     my $volid;
2037
2038     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
2039     # fixme: use better naming ct-$vmid-disk-X.raw?
2040
2041     eval {
2042         my $do_format = 0;
2043         if ($scfg->{content}->{rootdir} && $scfg->{path}) {
2044             if ($size_kb > 0 && !($scfg->{type} eq 'btrfs' && $scfg->{quotas})) {
2045                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2046                 $do_format = 1;
2047             } else {
2048                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2049                 $needs_chown = 1;
2050             }
2051         } elsif ($scfg->{type} eq 'zfspool') {
2052             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol', undef, $size_kb);
2053             $needs_chown = 1;
2054         } elsif ($scfg->{content}->{rootdir}) {
2055             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
2056             $do_format = 1;
2057         } else {
2058             die "content type 'rootdir' is not available or configured on storage '$storage'\n";
2059         }
2060         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
2061     };
2062     if (my $err = $@) {
2063         # in case formatting got interrupted:
2064         if (defined($volid)) {
2065             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
2066             warn $@ if $@;
2067         }
2068         die $err;
2069     }
2070
2071     return ($volid, $needs_chown);
2072 }
2073
2074 sub create_disks {
2075     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
2076
2077     my $vollist = [];
2078
2079     eval {
2080         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
2081         my $chown_vollist = [];
2082
2083         PVE::LXC::Config->foreach_volume($settings, sub {
2084             my ($ms, $mountpoint) = @_;
2085
2086             my $volid = $mountpoint->{volume};
2087             my $mp = $mountpoint->{mp};
2088
2089             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
2090
2091             if ($storage && ($volid =~ $NEW_DISK_RE)) {
2092                 my ($storeid, $size_gb) = ($1, $2);
2093
2094                 my $size_kb = int(${size_gb}*1024) * 1024;
2095
2096                 my $needs_chown = 0;
2097                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
2098                 push @$chown_vollist, $volid if $needs_chown;
2099                 push @$vollist, $volid;
2100                 $mountpoint->{volume} = $volid;
2101                 $mountpoint->{size} = $size_kb * 1024;
2102                 if ($pending) {
2103                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2104                 } else {
2105                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2106                 }
2107             } else {
2108                 # use specified/existing volid/dir/device
2109                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
2110             }
2111         });
2112
2113         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
2114         foreach my $volid (@$chown_vollist) {
2115             my $path = PVE::Storage::path($storecfg, $volid, undef);
2116             chown($rootuid, $rootgid, $path);
2117         }
2118         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
2119     };
2120     # free allocated images on error
2121     if (my $err = $@) {
2122         destroy_disks($storecfg, $vollist);
2123         die $err;
2124     }
2125     return $vollist;
2126 }
2127
2128 sub update_disksize {
2129     my ($vmid, $conf, $all_volumes) = @_;
2130
2131     my $changes;
2132     my $prefix = "CT $vmid:";
2133
2134     my $update_mp = sub {
2135         my ($key, $mp, @param) = @_;
2136         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
2137
2138         if (!defined($mp->{size}) || $size != $mp->{size}) {
2139             $changes = 1;
2140             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
2141             $mp->{size} = $size;
2142             my $no_mp = $key eq 'rootfs'; # rootfs is handled different from other mount points
2143             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $no_mp);
2144         }
2145     };
2146
2147     PVE::LXC::Config->foreach_volume($conf, $update_mp);
2148
2149     return $changes;
2150 }
2151
2152 sub update_unused {
2153     my ($vmid, $conf, $all_volumes) = @_;
2154
2155     my $changes;
2156     my $prefix = "CT $vmid:";
2157
2158     # Note: it is allowed to define multiple storage entries with the same path
2159     # (alias), so we need to check both 'volid' and real 'path' (two different
2160     # volid can point to the same path).
2161
2162     # used and unused disks
2163     my $refpath = {};
2164     my $orphans = {};
2165
2166     foreach my $opt (keys %$conf) {
2167         next if ($opt !~ m/^unused\d+$/);
2168         my $vol = $all_volumes->{$conf->{$opt}};
2169         $refpath->{$vol->{path}} = $vol->{volid};
2170     }
2171
2172     foreach my $key (keys %$all_volumes) {
2173         my $vol = $all_volumes->{$key};
2174         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
2175         my $path = $vol->{path};
2176
2177         if ($in_use) {
2178             $refpath->{$path} = $key;
2179             delete $orphans->{$path};
2180         } else {
2181             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
2182                 $orphans->{$path} = $key;
2183             }
2184         }
2185     }
2186
2187     for my $key (keys %$orphans) {
2188         my $disk = $orphans->{$key};
2189         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
2190
2191         if ($unused) {
2192             $changes = 1;
2193             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
2194         }
2195     }
2196
2197     return $changes;
2198 }
2199
2200 sub scan_volids {
2201     my ($cfg, $vmid) = @_;
2202
2203     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid, undef, 'rootdir');
2204
2205     my $all_volumes = {};
2206     foreach my $storeid (keys %$info) {
2207         foreach my $item (@{$info->{$storeid}}) {
2208             my $volid = $item->{volid};
2209             next if !($volid && $item->{size});
2210             $item->{path} = PVE::Storage::path($cfg, $volid);
2211             $all_volumes->{$volid} = $item;
2212         }
2213     }
2214
2215     return $all_volumes;
2216 }
2217
2218 sub rescan {
2219     my ($vmid, $nolock, $dryrun) = @_;
2220
2221     my $cfg = PVE::Storage::config();
2222
2223     print "rescan volumes...\n";
2224     my $all_volumes = scan_volids($cfg, $vmid);
2225
2226     my $updatefn =  sub {
2227         my ($vmid) = @_;
2228
2229         my $changes;
2230         my $conf = PVE::LXC::Config->load_config($vmid);
2231
2232         PVE::LXC::Config->check_lock($conf);
2233
2234         my $vm_volids = {};
2235         foreach my $volid (keys %$all_volumes) {
2236             my $info = $all_volumes->{$volid};
2237             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
2238         }
2239
2240         my $upu = update_unused($vmid, $conf, $vm_volids);
2241         my $upd = update_disksize($vmid, $conf, $vm_volids);
2242         $changes = $upu || $upd;
2243
2244         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
2245     };
2246
2247     if (defined($vmid)) {
2248         if ($nolock) {
2249             &$updatefn($vmid);
2250         } else {
2251             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2252         }
2253     } else {
2254         my $vmlist = config_list();
2255         foreach my $vmid (keys %$vmlist) {
2256             if ($nolock) {
2257                 &$updatefn($vmid);
2258             } else {
2259                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
2260             }
2261         }
2262     }
2263 }
2264
2265
2266 # bash completion helper
2267
2268 sub complete_os_templates {
2269     my ($cmdname, $pname, $cvalue) = @_;
2270
2271     my $cfg = PVE::Storage::config();
2272
2273     my $storeid;
2274
2275     if ($cvalue =~ m/^([^:]+):/) {
2276         $storeid = $1;
2277     }
2278
2279     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
2280     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
2281
2282     my $res = [];
2283     foreach my $id (keys %$data) {
2284         foreach my $item (@{$data->{$id}}) {
2285             push @$res, $item->{volid} if defined($item->{volid});
2286         }
2287     }
2288
2289     return $res;
2290 }
2291
2292 my $complete_ctid_full = sub {
2293     my ($running) = @_;
2294
2295     my $idlist = vmstatus();
2296
2297     my $active_hash = list_active_containers();
2298
2299     my $res = [];
2300
2301     foreach my $id (keys %$idlist) {
2302         my $d = $idlist->{$id};
2303         if (defined($running)) {
2304             next if $d->{template};
2305             next if $running && !$active_hash->{$id};
2306             next if !$running && $active_hash->{$id};
2307         }
2308         push @$res, $id;
2309
2310     }
2311     return $res;
2312 };
2313
2314 sub complete_ctid {
2315     return &$complete_ctid_full();
2316 }
2317
2318 sub complete_ctid_stopped {
2319     return &$complete_ctid_full(0);
2320 }
2321
2322 sub complete_ctid_running {
2323     return &$complete_ctid_full(1);
2324 }
2325
2326 sub parse_id_maps {
2327     my ($conf) = @_;
2328
2329     my $id_map = [];
2330     my $rootuid = 0;
2331     my $rootgid = 0;
2332
2333     my $lxc = $conf->{lxc};
2334     foreach my $entry (@$lxc) {
2335         my ($key, $value) = @$entry;
2336
2337         next if $key ne 'lxc.idmap';
2338
2339         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
2340             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
2341             push @$id_map, [$type, $ct, $host, $length];
2342             if ($ct == 0) {
2343                 $rootuid = $host if $type eq 'u';
2344                 $rootgid = $host if $type eq 'g';
2345             }
2346         } else {
2347             die "failed to parse idmap: $value\n";
2348         }
2349     }
2350
2351     if (!@$id_map && $conf->{unprivileged}) {
2352         # Should we read them from /etc/subuid?
2353         $id_map = [ ['u', '0', '100000', '65536'],
2354                     ['g', '0', '100000', '65536'] ];
2355         $rootuid = $rootgid = 100000;
2356     }
2357
2358     return ($id_map, $rootuid, $rootgid);
2359 }
2360
2361 sub validate_id_maps {
2362     my ($id_map) = @_;
2363
2364     # $mappings->{$type}->{$side} = [ { line => $line, start => $start, count => $count }, ... ]
2365     #   $type: either "u" or "g"
2366     #   $side: either "container" or "host"
2367     #   $line: index of this mapping in @$id_map
2368     #   $start, $count: interval of this mapping
2369     my $mappings = { u => {}, g => {} };
2370     for (my $i = 0; $i < scalar(@$id_map); $i++) {
2371         my ($type, $ct_start, $host_start, $count) = $id_map->[$i]->@*;
2372         my $sides = $mappings->{$type};
2373         push $sides->{host}->@*, { line => $i, start => $host_start, count => $count };
2374         push $sides->{container}->@*, { line => $i, start => $ct_start, count => $count };
2375     }
2376
2377     # find the first conflict between two consecutive mappings when sorted by their start id
2378     for my $type (qw(u g)) {
2379         for my $side (qw(container host)) {
2380             my @entries = sort { $a->{start} <=> $b->{start} } $mappings->{$type}->{$side}->@*;
2381             for my $idx (1..scalar(@entries) - 1) {
2382                 my $previous = $entries[$idx - 1];
2383                 my $current = $entries[$idx];
2384                 if ($previous->{start} + $previous->{count} > $current->{start}) {
2385                     my $conflict = $current->{start};
2386                     my @previous_line = $id_map->[$previous->{line}]->@*;
2387                     my @current_line = $id_map->[$current->{line}]->@*;
2388                     die "invalid map entry '@current_line': $side ${type}id $conflict "
2389                        ."is also mapped by entry '@previous_line'\n";
2390                 }
2391             }
2392         }
2393     }
2394 }
2395
2396 sub userns_command {
2397     my ($id_map) = @_;
2398     if (@$id_map) {
2399         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
2400     }
2401     return [];
2402 }
2403
2404 my sub print_ct_stderr_log {
2405     my ($vmid) = @_;
2406     my $log = eval { file_get_contents("/run/pve/ct-$vmid.stderr") };
2407     return if !$log;
2408
2409     while ($log =~ /^\h*(lxc-start:?\s+$vmid:?\s*\S+\s*)?(.*?)\h*$/gm) {
2410         my $line = $2;
2411         print STDERR "$line\n";
2412     }
2413 }
2414 my sub print_ct_warn_log {
2415     my ($vmid) = @_;
2416     my $log_fn = "/run/pve/ct-$vmid.warnings";
2417     my $log = eval { file_get_contents($log_fn) };
2418     return if !$log;
2419
2420     while ($log =~ /^\h*\s*(.*?)\h*$/gm) {
2421         PVE::RESTEnvironment::log_warn($1);
2422     }
2423     unlink $log_fn or warn "could not unlink '$log_fn' - $!\n";
2424 }
2425
2426 my sub monitor_state_change($$) {
2427     my ($monitor_socket, $vmid) = @_;
2428     die "no monitor socket\n" if !defined($monitor_socket);
2429
2430     while (1) {
2431         my ($type, $name, $value) = PVE::LXC::Monitor::read_lxc_message($monitor_socket);
2432
2433         die "monitor socket: got EOF\n" if !defined($type);
2434
2435         next if $name ne "$vmid" || $type ne 'STATE';
2436
2437         if ($value eq PVE::LXC::Monitor::STATE_STARTING) {
2438             alarm(0); # don't timeout after seeing the starting state
2439         } elsif ($value eq PVE::LXC::Monitor::STATE_ABORTING ||
2440                  $value eq PVE::LXC::Monitor::STATE_STOPPING ||
2441                  $value eq PVE::LXC::Monitor::STATE_STOPPED) {
2442             return 0;
2443         } elsif ($value eq PVE::LXC::Monitor::STATE_RUNNING) {
2444             return 1;
2445         } else {
2446             warn "unexpected message from monitor socket - " .
2447                  "type: '$type' - value: '$value'\n";
2448         }
2449     }
2450 }
2451 my sub monitor_start($$) {
2452     my ($monitor_socket, $vmid) = @_;
2453
2454     my $success = eval {
2455         PVE::Tools::run_with_timeout(10, \&monitor_state_change, $monitor_socket, $vmid)
2456     };
2457     if (my $err = $@) {
2458         warn "problem with monitor socket, but continuing anyway: $err\n";
2459     } elsif (!$success) {
2460         print_ct_stderr_log($vmid);
2461         die "startup for container '$vmid' failed\n";
2462     }
2463 }
2464
2465 sub vm_start {
2466     my ($vmid, $conf, $skiplock, $debug) = @_;
2467
2468     # apply pending changes while starting
2469     if (scalar(keys %{$conf->{pending}})) {
2470         my $storecfg = PVE::Storage::config();
2471         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
2472         PVE::LXC::Config->write_config($vmid, $conf);
2473         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
2474     }
2475
2476     update_lxc_config($vmid, $conf);
2477
2478     eval {
2479         my ($id_map, undef, undef) = PVE::LXC::parse_id_maps($conf);
2480         PVE::LXC::validate_id_maps($id_map);
2481     };
2482     warn "lxc.idmap: $@" if $@;
2483
2484     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
2485
2486     if ($skiplock) {
2487         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
2488         close($fh);
2489     }
2490
2491     my $storage_cfg = PVE::Storage::config();
2492     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
2493
2494     PVE::Storage::activate_volumes($storage_cfg, $vollist);
2495
2496     my $monitor_socket = eval { PVE::LXC::Monitor::get_monitor_socket() };
2497     warn $@ if $@;
2498
2499     unlink "/run/pve/ct-$vmid.stderr"; # systemd does not truncate log files
2500
2501     my $is_debug = $debug || (!defined($debug) && $conf->{debug});
2502     my $base_unit = $is_debug ? 'pve-container-debug' : 'pve-container';
2503
2504     my $cmd = ['systemctl', 'start', "$base_unit\@$vmid"];
2505
2506     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
2507     eval {
2508         run_command($cmd);
2509
2510         monitor_start($monitor_socket, $vmid) if defined($monitor_socket);
2511
2512         # if debug is requested, print the log it also when the start succeeded
2513         print_ct_stderr_log($vmid) if $is_debug;
2514
2515         print_ct_warn_log($vmid); # always print warn log, if any
2516     };
2517     if (my $err = $@) {
2518         unlink $skiplock_flag_fn;
2519         die $err;
2520     }
2521     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
2522
2523     return;
2524 }
2525
2526 # Helper to stop a container completely and make sure it has stopped completely.
2527 # This is necessary because we want the post-stop hook to have completed its
2528 # unmount-all step, but post-stop happens after lxc puts the container into the
2529 # STOPPED state.
2530 # $kill - if true it will always do an immediate hard-stop
2531 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
2532 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
2533 sub vm_stop {
2534     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
2535
2536     # Open the container's command socket.
2537     my $path = "\0/var/lib/lxc/$vmid/command";
2538     my $sock = IO::Socket::UNIX->new(
2539         Type => SOCK_STREAM(),
2540         Peer => $path,
2541     );
2542     if (!$sock) {
2543         return if $! == ECONNREFUSED; # The container is not running
2544         die "failed to open container ${vmid}'s command socket: $!\n";
2545     }
2546
2547     my $conf = PVE::LXC::Config->load_config($vmid);
2548     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
2549
2550     # Stop the container:
2551
2552     my $cmd = ['lxc-stop', '-n', $vmid];
2553
2554     if ($kill) {
2555         push @$cmd, '--kill'; # doesn't allow timeouts
2556     } else {
2557         # lxc-stop uses a default timeout
2558         push @$cmd, '--nokill' if !$kill_after_timeout;
2559
2560         if (defined($shutdown_timeout)) {
2561             push @$cmd, '--timeout', $shutdown_timeout;
2562             # Give run_command 5 extra seconds
2563             $shutdown_timeout += 5;
2564         }
2565     }
2566
2567     eval { run_command($cmd, timeout => $shutdown_timeout) };
2568
2569     # Wait until the command socket is closed.
2570     # In case the lxc-stop call failed, reading from the command socket may block forever,
2571     # so poll with another timeout to avoid freezing the shutdown task.
2572     if (my $err = $@) {
2573         warn $err if $err;
2574
2575         my $poll = IO::Poll->new();
2576         $poll->mask($sock => POLLIN | POLLHUP); # watch for input and EOF events
2577         $poll->poll($shutdown_timeout); # IO::Poll timeout is in seconds
2578         return if ($poll->events($sock) & POLLHUP);
2579     } else {
2580         my $result = <$sock>;
2581         return if !defined $result; # monitor is gone and the ct has stopped.
2582     }
2583
2584     die "container did not stop\n";
2585 }
2586
2587 sub vm_reboot {
2588     my ($vmid, $timeout, $skiplock) = @_;
2589
2590     PVE::LXC::Config->lock_config($vmid, sub {
2591         return if !check_running($vmid);
2592
2593         vm_stop($vmid, 0, $timeout, 1); # kill if timeout exceeds
2594
2595         my $conf = PVE::LXC::Config->load_config($vmid);
2596         vm_start($vmid, $conf);
2597     });
2598 }
2599
2600 sub run_unshared {
2601     my ($code) = @_;
2602
2603     return PVE::Tools::run_fork(sub {
2604         # Unshare the mount namespace
2605         die "failed to unshare mount namespace: $!\n"
2606             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2607         run_command(['mount', '--make-rslave', '/']);
2608         return $code->();
2609     });
2610 }
2611
2612 my $copy_volume = sub {
2613     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2614
2615     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2616     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2617
2618     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2619     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2620
2621     my @mounted;
2622     eval {
2623         # mount and copy
2624         mkdir $src;
2625         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2626         push @mounted, $src;
2627         mkdir $dest;
2628         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2629         push @mounted, $dest;
2630
2631         $bwlimit //= 0;
2632
2633         run_command([
2634             'rsync',
2635             '--stats',
2636             '-X',
2637             '-A',
2638             '--numeric-ids',
2639             '-aH',
2640             '--whole-file',
2641             '--sparse',
2642             '--one-file-system',
2643             "--bwlimit=$bwlimit",
2644             "$src/",
2645             $dest
2646         ]);
2647     };
2648     my $err = $@;
2649
2650     # Wait for rsync's children to release dest so that
2651     # consequent file operations (umount, remove) are possible
2652     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2653
2654     foreach my $mount (reverse @mounted) {
2655         eval { run_command(['/bin/umount', $mount], errfunc => sub{})};
2656         warn "Can't umount $mount\n" if $@;
2657     }
2658
2659     # If this fails they're used as mount points in a concurrent operation
2660     # (which should not happen but there's also no real need to get rid of them).
2661     rmdir $dest;
2662     rmdir $src;
2663
2664     die $err if $err;
2665 };
2666
2667 # Should not be called after unsharing the mount namespace!
2668 sub copy_volume {
2669     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2670
2671     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2672     File::Path::make_path("/var/lib/lxc/$vmid");
2673     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2674     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2675
2676     # get id's for unprivileged container
2677     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2678
2679     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2680     # are visible in this namespace, otherwise the host only sees the empty
2681     # (not-mounted) directory.
2682     my $new_volid;
2683     eval {
2684         # Make sure $mp contains a correct size.
2685         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2686         my $needs_chown;
2687         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2688         if ($needs_chown) {
2689             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2690             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2691             chown($rootuid, $rootgid, $path);
2692         }
2693
2694         run_unshared(sub {
2695             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2696         });
2697     };
2698     if (my $err = $@) {
2699         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2700             if defined($new_volid);
2701         die $err;
2702     }
2703
2704     return $new_volid;
2705 }
2706
2707 sub get_lxc_version() {
2708     my $version;
2709     run_command([qw(lxc-start --version)], outfunc => sub {
2710         my ($line) = @_;
2711         # We only parse out major & minor version numbers.
2712         if ($line =~ /^(\d+)\.(\d+)(?:\D.*)?$/) {
2713             $version = [$1, $2];
2714         }
2715     });
2716
2717     die "failed to get lxc version\n" if !defined($version);
2718
2719     # return as a list:
2720     return $version->@*;
2721 }
2722
2723 sub freeze($) {
2724     my ($vmid) = @_;
2725     if (PVE::CGroup::cgroup_mode() == 2) {
2726         PVE::LXC::Command::freeze($vmid, 30);
2727     } else {
2728         PVE::LXC::CGroup->new($vmid)->freeze_thaw(1);
2729     }
2730 }
2731
2732 sub thaw($) {
2733     my ($vmid) = @_;
2734     if (PVE::CGroup::cgroup_mode() == 2) {
2735         PVE::LXC::Command::unfreeze($vmid, 30);
2736     } else {
2737         PVE::LXC::CGroup->new($vmid)->freeze_thaw(0);
2738     }
2739 }
2740
2741 1;