src/PVE/LXC/Create.pm

   1 package PVE::LXC::Create;
   2
   3 use strict;
   4 use warnings;
   5 use File::Basename;
   6 use File::Path;
   7 use Data::Dumper;
   8
   9 use PVE::Storage;
  10 use PVE::LXC;
  11 use PVE::LXC::Setup;
  12 use PVE::VZDump::ConvertOVZ;
  13
  14 sub next_free_nbd_dev {
  15
  16     for(my $i = 0;;$i++) {
  17         my $dev = "/dev/nbd$i";
  18         last if ! -b $dev;
  19         next if -f "/sys/block/nbd$i/pid"; # busy
  20         return $dev;
  21     }
  22     die "unable to find free nbd device\n";
  23 }
  24
  25 sub restore_archive {
  26     my ($archive, $rootdir, $conf) = @_;
  27
  28     my $userns_cmd = [];
  29
  30 #    we always use the same mapping: 'b:0:100000:65536'
  31 #    if ($conf->{'lxc.id_map'}) {
  32 #       $userns_cmd = ['lxc-usernsexec', '-m', 'b:0:100000:65536', '--'];
  33 #       PVE::Tools::run_command(['chown', '-R', '100000:100000', $rootdir]);
  34 #    }
  35
  36     my $cmd = [@$userns_cmd, 'tar', 'xpf', $archive, '--numeric-owner', '--totals',
  37             '--sparse', '-C', $rootdir];
  38
  39     push @$cmd, '--anchored';
  40     push @$cmd, '--exclude' , './dev/*';
  41
  42     if ($archive eq '-') {
  43         print "extracting archive from STDIN\n";
  44         PVE::Tools::run_command($cmd, input => "<&STDIN");
  45     } else {
  46         print "extracting archive '$archive'\n";
  47         PVE::Tools::run_command($cmd);
  48     }
  49
  50     # determine file type of /usr/bin/file itself to get guests' architecture
  51     $cmd = [@$userns_cmd, '/usr/bin/file', '-b', '-L', "$rootdir/usr/bin/file"];
  52     PVE::Tools::run_command($cmd, outfunc => sub {
  53         shift =~ /^ELF (\d{2}-bit)/; # safely assumes x86 linux
  54         my $arch_str = $1;
  55         $conf->{'arch'} = 'amd64'; # defaults to 64bit
  56         if(defined($arch_str)) {
  57             $conf->{'arch'} = 'i386' if $arch_str =~ /32/;
  58             print "Detected container architecture: $conf->{'arch'}\n";
  59         } else {
  60             print "CT architecture detection failed, falling back to amd64.\n" .
  61                   "Edit the config in /etc/pve/nodes/{node}/lxc/{vmid}/config " .
  62                   "to set another architecture.\n";
  63         }
  64     });
  65 }
  66
  67 sub tar_archive_search_conf {
  68     my ($archive) = @_;
  69
  70     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
  71
  72     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
  73        die "unable to open file '$archive'\n";
  74
  75     my $file;
  76     while (defined($file = <$fh>)) {
  77         if ($file =~ m!^(\./etc/vzdump/(pct|vps)\.conf)$!) {
  78             $file = $1; # untaint
  79             last;
  80         }
  81     }
  82
  83     kill 15, $pid;
  84     waitpid $pid, 0;
  85     close $fh;
  86
  87     die "ERROR: archive contains no configuration file\n" if !$file;
  88     chomp $file;
  89
  90     return $file;
  91 }
  92
  93 sub recover_config {
  94     my ($archive) = @_;
  95
  96     my $conf_file = tar_archive_search_conf($archive);
  97
  98     my $raw = '';
  99     my $out = sub {
 100         my $output = shift;
 101         $raw .= "$output\n";
 102     };
 103
 104     PVE::Tools::run_command(['tar', '-xpOf', $archive, $conf_file, '--occurrence'], outfunc => $out);
 105
 106     my $conf;
 107     my $disksize;
 108
 109     if ($conf_file =~ m/pct\.conf/) {
 110
 111         $conf = PVE::LXC::parse_pct_config("/lxc/0.conf" , $raw);
 112
 113         delete $conf->{snapshots};
 114         delete $conf->{template}; # restored CT is never a template
 115
 116         if (defined($conf->{rootfs})) {
 117             my $rootinfo = PVE::LXC::parse_ct_mountpoint($conf->{rootfs});
 118             $disksize = $rootinfo->{size} if defined($rootinfo->{size});
 119         }
 120
 121     } elsif ($conf_file =~ m/vps\.conf/) {
 122
 123         ($conf, $disksize) = PVE::VZDump::ConvertOVZ::convert_ovz($raw);
 124
 125     } else {
 126
 127        die "internal error";
 128     }
 129
 130     return wantarray ? ($conf, $disksize) : $conf;
 131 }
 132
 133 sub restore_and_configure {
 134     my ($vmid, $archive, $rootdir, $conf, $password, $restore) = @_;
 135
 136     restore_archive($archive, $rootdir, $conf);
 137
 138     if (!$restore) {
 139         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 140
 141         PVE::LXC::write_config($vmid, $conf); # safe config (after OS detection)
 142         $lxc_setup->post_create_hook($password);
 143     } else {
 144         # restore: try to extract configuration from archive
 145
 146         my $pct_cfg_fn = "$rootdir/etc/vzdump/pct.conf";
 147         my $ovz_cfg_fn = "$rootdir/etc/vzdump/vps.conf";
 148         if (-f $pct_cfg_fn) {
 149             my $raw = PVE::Tools::file_get_contents($pct_cfg_fn);
 150             my $oldconf = PVE::LXC::parse_pct_config("/lxc/$vmid.conf", $raw);
 151
 152             foreach my $key (keys %$oldconf) {
 153                 next if $key eq 'digest' || $key eq 'rootfs' || $key eq 'snapshots';
 154                 $conf->{$key} = $oldconf->{$key} if !defined($conf->{$key});
 155             }
 156
 157         } elsif (-f $ovz_cfg_fn) {
 158             print "###########################################################\n";
 159             print "Converting OpenVZ configuration to LXC.\n";
 160             print "Please check the configuration and reconfigure the network.\n";
 161             print "###########################################################\n";
 162
 163             my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 164             $conf->{ostype} = $lxc_setup->{conf}->{ostype};
 165             my $raw = PVE::Tools::file_get_contents($ovz_cfg_fn);
 166             my $oldconf = PVE::VZDump::ConvertOVZ::convert_ovz($raw);
 167             foreach my $key (keys %$oldconf) {
 168                 $conf->{$key} = $oldconf->{$key} if !defined($conf->{$key});
 169             }
 170
 171         } else {
 172             print "###########################################################\n";
 173             print "Backup archive does not contain any configuration\n";
 174             print "###########################################################\n";
 175         }
 176     }
 177 }
 178
 179 sub create_rootfs {
 180     my ($storage_cfg, $vmid, $conf, $archive, $password, $restore) = @_;
 181
 182     my $config_fn = PVE::LXC::config_file($vmid);
 183     if (-f $config_fn) {
 184         die "container exists" if !$restore; # just to be sure
 185
 186         my $old_conf = PVE::LXC::load_config($vmid);
 187
 188         # destroy old container volume
 189         PVE::LXC::destroy_lxc_container($storage_cfg, $vmid, $old_conf);
 190
 191         # do not copy all settings to restored container
 192         foreach my $opt (qw(rootfs digest snapshots arch ostype)) {
 193             delete $old_conf->{$opt};
 194         }
 195         foreach my $opt (keys %$old_conf) {
 196             delete $old_conf->{$opt} if $opt =~ m/^mp\d+$/;
 197         }
 198
 199         PVE::LXC::update_pct_config($vmid, $conf, 0, $old_conf);
 200
 201         PVE::LXC::create_config($vmid, $conf);
 202
 203     } else {
 204
 205         PVE::LXC::create_config($vmid, $conf);
 206     }
 207
 208     my $loopdevs;
 209     eval {
 210         (my $rootdir, $loopdevs) = PVE::LXC::mount_all($vmid, $storage_cfg, $conf);
 211         restore_and_configure($vmid, $archive, $rootdir, $conf, $password, $restore);
 212     };
 213     if (my $err = $@) {
 214         warn $err;
 215         if ($loopdevs) {
 216             # mount_all unmounts on error so we only need to unmount
 217             # if it actually returns valid $loopdevs
 218             PVE::LXC::umount_all($vmid, $storage_cfg, $conf, 1, $loopdevs);
 219         }
 220     } else {
 221         PVE::LXC::umount_all($vmid, $storage_cfg, $conf, 0, $loopdevs);
 222     }
 223
 224     PVE::Storage::deactivate_volumes($storage_cfg, PVE::LXC::get_vm_volumes($conf));
 225 }
 226
 227 1;