src/PVE/LXC/Create.pm

   1 package PVE::LXC::Create;
   2
   3 use strict;
   4 use warnings;
   5 use File::Basename;
   6 use File::Path;
   7 use Data::Dumper;
   8
   9 use PVE::Storage;
  10 use PVE::LXC;
  11 use PVE::LXC::Setup;
  12 use PVE::VZDump::ConvertOVZ;
  13 use PVE::Tools;
  14
  15 sub next_free_nbd_dev {
  16
  17     for(my $i = 0;;$i++) {
  18         my $dev = "/dev/nbd$i";
  19         last if ! -b $dev;
  20         next if -f "/sys/block/nbd$i/pid"; # busy
  21         return $dev;
  22     }
  23     die "unable to find free nbd device\n";
  24 }
  25
  26 sub restore_archive {
  27     my ($archive, $rootdir, $conf, $no_unpack_error) = @_;
  28
  29     my ($id_map, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
  30     my $userns_cmd = PVE::LXC::userns_command($id_map);
  31
  32     my $cmd = [@$userns_cmd, 'tar', 'xpf', $archive, '--totals',
  33                @$PVE::LXC::COMMON_TAR_FLAGS,
  34                '-C', $rootdir];
  35
  36     # skip-old-files doesn't have anything to do with time (old/new), but is
  37     # simply -k (annoyingly also called --keep-old-files) without the 'treat
  38     # existing files as errors' part... iow. it's bsdtar's interpretation of -k
  39     # *sigh*, gnu...
  40     push @$cmd, '--skip-old-files';
  41     push @$cmd, '--anchored';
  42     push @$cmd, '--exclude' , './dev/*';
  43
  44     if ($archive eq '-') {
  45         print "extracting archive from STDIN\n";
  46         eval { PVE::Tools::run_command($cmd, input => "<&STDIN"); };
  47     } else {
  48         print "extracting archive '$archive'\n";
  49         eval { PVE::Tools::run_command($cmd); };
  50     }
  51     die $@ if $@ && !$no_unpack_error;
  52
  53     # determine file type of /usr/bin/file itself to get guests' architecture
  54     $cmd = [@$userns_cmd, '/usr/bin/file', '-b', '-L', "$rootdir/bin/sh"];
  55     PVE::Tools::run_command($cmd, outfunc => sub {
  56         shift =~ /^ELF (\d{2}-bit)/; # safely assumes x86 linux
  57         my $arch_str = $1;
  58         $conf->{'arch'} = 'amd64'; # defaults to 64bit
  59         if(defined($arch_str)) {
  60             $conf->{'arch'} = 'i386' if $arch_str =~ /32/;
  61             print "Detected container architecture: $conf->{'arch'}\n";
  62         } else {
  63             print "CT architecture detection failed, falling back to amd64.\n" .
  64                   "Edit the config in /etc/pve/nodes/{node}/lxc/{vmid}/config " .
  65                   "to set another architecture.\n";
  66         }
  67     });
  68 }
  69
  70 sub tar_archive_search_conf {
  71     my ($archive) = @_;
  72
  73     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
  74
  75     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
  76        die "unable to open file '$archive'\n";
  77
  78     my $file;
  79     while (defined($file = <$fh>)) {
  80         if ($file =~ m!^(\./etc/vzdump/(pct|vps)\.conf)$!) {
  81             $file = $1; # untaint
  82             last;
  83         }
  84     }
  85
  86     kill 15, $pid;
  87     waitpid $pid, 0;
  88     close $fh;
  89
  90     die "ERROR: archive contains no configuration file\n" if !$file;
  91     chomp $file;
  92
  93     return $file;
  94 }
  95
  96 sub recover_config {
  97     my ($archive) = @_;
  98
  99     my $conf_file = tar_archive_search_conf($archive);
 100
 101     my $raw = '';
 102     my $out = sub {
 103         my $output = shift;
 104         $raw .= "$output\n";
 105     };
 106
 107     PVE::Tools::run_command(['tar', '-xpOf', $archive, $conf_file, '--occurrence'], outfunc => $out);
 108
 109     my $conf;
 110     my $mp_param = {};
 111
 112     if ($conf_file =~ m/pct\.conf/) {
 113
 114         $conf = PVE::LXC::Config::parse_pct_config("/lxc/0.conf" , $raw);
 115
 116         delete $conf->{snapshots};
 117         delete $conf->{template}; # restored CT is never a template
 118
 119         PVE::LXC::Config->foreach_mountpoint($conf, sub {
 120             my ($ms, $mountpoint) = @_;
 121             $mp_param->{$ms} = $conf->{$ms};
 122         });
 123
 124     } elsif ($conf_file =~ m/vps\.conf/) {
 125
 126         ($conf, $mp_param) = PVE::VZDump::ConvertOVZ::convert_ovz($raw);
 127
 128     } else {
 129
 130        die "internal error";
 131     }
 132
 133     return wantarray ? ($conf, $mp_param) : $conf;
 134 }
 135
 136 sub restore_configuration {
 137     my ($vmid, $rootdir, $conf) = @_;
 138
 139     # restore: try to extract configuration from archive
 140
 141     my $pct_cfg_fn = "$rootdir/etc/vzdump/pct.conf";
 142     my $pct_fwcfg_fn = "$rootdir/etc/vzdump/pct.fw";
 143     my $ovz_cfg_fn = "$rootdir/etc/vzdump/vps.conf";
 144     if (-f $pct_cfg_fn) {
 145         my $raw = PVE::Tools::file_get_contents($pct_cfg_fn);
 146         my $oldconf = PVE::LXC::Config::parse_pct_config("/lxc/$vmid.conf", $raw);
 147
 148         foreach my $key (keys %$oldconf) {
 149             next if $key eq 'digest' || $key eq 'rootfs' || $key eq 'snapshots' || $key eq 'unprivileged' || $key eq 'parent';
 150             next if $key =~ /^mp\d+$/; # don't recover mountpoints
 151             next if $key =~ /^unused\d+$/; # don't recover unused disks
 152             $conf->{$key} = $oldconf->{$key} if !defined($conf->{$key});
 153         }
 154         unlink($pct_cfg_fn);
 155
 156         if (-f $pct_fwcfg_fn) {
 157             my $pve_firewall_dir = '/etc/pve/firewall';
 158             mkdir $pve_firewall_dir; # make sure the directory exists
 159             PVE::Tools::file_copy($pct_fwcfg_fn, "${pve_firewall_dir}/$vmid.fw");
 160             unlink $pct_fwcfg_fn;
 161         }
 162
 163     } elsif (-f $ovz_cfg_fn) {
 164         print "###########################################################\n";
 165         print "Converting OpenVZ configuration to LXC.\n";
 166         print "Please check the configuration and reconfigure the network.\n";
 167         print "###########################################################\n";
 168
 169         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 170         $conf->{ostype} = $lxc_setup->{conf}->{ostype};
 171         my $raw = PVE::Tools::file_get_contents($ovz_cfg_fn);
 172         my $oldconf = PVE::VZDump::ConvertOVZ::convert_ovz($raw);
 173         foreach my $key (keys %$oldconf) {
 174             $conf->{$key} = $oldconf->{$key} if !defined($conf->{$key});
 175         }
 176         unlink($ovz_cfg_fn);
 177
 178     } else {
 179         print "###########################################################\n";
 180         print "Backup archive does not contain any configuration\n";
 181         print "###########################################################\n";
 182     }
 183 }
 184
 185 1;