src/PVE/LXC/Create.pm

   1 package PVE::LXC::Create;
   2
   3 use strict;
   4 use warnings;
   5 use File::Basename;
   6 use File::Path;
   7 use Data::Dumper;
   8
   9 use PVE::Storage;
  10 use PVE::LXC;
  11 use PVE::LXC::Setup;
  12 use PVE::VZDump::ConvertOVZ;
  13 use PVE::Tools;
  14
  15 sub next_free_nbd_dev {
  16
  17     for(my $i = 0;;$i++) {
  18         my $dev = "/dev/nbd$i";
  19         last if ! -b $dev;
  20         next if -f "/sys/block/nbd$i/pid"; # busy
  21         return $dev;
  22     }
  23     die "unable to find free nbd device\n";
  24 }
  25
  26 sub restore_archive {
  27     my ($archive, $rootdir, $conf) = @_;
  28
  29     my ($id_map, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
  30     my $userns_cmd = PVE::LXC::userns_command($id_map);
  31
  32     my $cmd = [@$userns_cmd, 'tar', 'xpf', $archive, '--totals',
  33                @$PVE::LXC::COMMON_TAR_FLAGS,
  34                '-C', $rootdir];
  35
  36     # skip-old-files doesn't have anything to do with time (old/new), but is
  37     # simply -k (annoyingly also called --keep-old-files) without the 'treat
  38     # existing files as errors' part... iow. it's bsdtar's interpretation of -k
  39     # *sigh*, gnu...
  40     push @$cmd, '--skip-old-files';
  41     push @$cmd, '--anchored';
  42     push @$cmd, '--exclude' , './dev/*';
  43
  44     if ($archive eq '-') {
  45         print "extracting archive from STDIN\n";
  46         PVE::Tools::run_command($cmd, input => "<&STDIN");
  47     } else {
  48         print "extracting archive '$archive'\n";
  49         PVE::Tools::run_command($cmd);
  50     }
  51
  52     # determine file type of /usr/bin/file itself to get guests' architecture
  53     $cmd = [@$userns_cmd, '/usr/bin/file', '-b', '-L', "$rootdir/usr/bin/file"];
  54     PVE::Tools::run_command($cmd, outfunc => sub {
  55         shift =~ /^ELF (\d{2}-bit)/; # safely assumes x86 linux
  56         my $arch_str = $1;
  57         $conf->{'arch'} = 'amd64'; # defaults to 64bit
  58         if(defined($arch_str)) {
  59             $conf->{'arch'} = 'i386' if $arch_str =~ /32/;
  60             print "Detected container architecture: $conf->{'arch'}\n";
  61         } else {
  62             print "CT architecture detection failed, falling back to amd64.\n" .
  63                   "Edit the config in /etc/pve/nodes/{node}/lxc/{vmid}/config " .
  64                   "to set another architecture.\n";
  65         }
  66     });
  67 }
  68
  69 sub tar_archive_search_conf {
  70     my ($archive) = @_;
  71
  72     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
  73
  74     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
  75        die "unable to open file '$archive'\n";
  76
  77     my $file;
  78     while (defined($file = <$fh>)) {
  79         if ($file =~ m!^(\./etc/vzdump/(pct|vps)\.conf)$!) {
  80             $file = $1; # untaint
  81             last;
  82         }
  83     }
  84
  85     kill 15, $pid;
  86     waitpid $pid, 0;
  87     close $fh;
  88
  89     die "ERROR: archive contains no configuration file\n" if !$file;
  90     chomp $file;
  91
  92     return $file;
  93 }
  94
  95 sub recover_config {
  96     my ($archive) = @_;
  97
  98     my $conf_file = tar_archive_search_conf($archive);
  99
 100     my $raw = '';
 101     my $out = sub {
 102         my $output = shift;
 103         $raw .= "$output\n";
 104     };
 105
 106     PVE::Tools::run_command(['tar', '-xpOf', $archive, $conf_file, '--occurrence'], outfunc => $out);
 107
 108     my $conf;
 109     my $disksize;
 110
 111     if ($conf_file =~ m/pct\.conf/) {
 112
 113         $conf = PVE::LXC::parse_pct_config("/lxc/0.conf" , $raw);
 114
 115         delete $conf->{snapshots};
 116         delete $conf->{template}; # restored CT is never a template
 117
 118         if (defined($conf->{rootfs})) {
 119             my $rootinfo = PVE::LXC::parse_ct_mountpoint($conf->{rootfs});
 120             $disksize = $rootinfo->{size} if defined($rootinfo->{size});
 121         }
 122
 123     } elsif ($conf_file =~ m/vps\.conf/) {
 124
 125         ($conf, $disksize) = PVE::VZDump::ConvertOVZ::convert_ovz($raw);
 126
 127     } else {
 128
 129        die "internal error";
 130     }
 131
 132     return wantarray ? ($conf, $disksize) : $conf;
 133 }
 134
 135 sub restore_and_configure {
 136     my ($vmid, $archive, $rootdir, $conf, $password, $restore, $no_unpack_error) = @_;
 137
 138     eval { restore_archive($archive, $rootdir, $conf) };
 139     die $@ if $@ && !$no_unpack_error;
 140
 141     if (!$restore) {
 142         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 143
 144         PVE::LXC::write_config($vmid, $conf); # safe config (after OS detection)
 145         $lxc_setup->post_create_hook($password);
 146     } else {
 147         # restore: try to extract configuration from archive
 148
 149         my $pct_cfg_fn = "$rootdir/etc/vzdump/pct.conf";
 150         my $pct_fwcfg_fn = "$rootdir/etc/vzdump/pct.fw";
 151         my $ovz_cfg_fn = "$rootdir/etc/vzdump/vps.conf";
 152         if (-f $pct_cfg_fn) {
 153             my $raw = PVE::Tools::file_get_contents($pct_cfg_fn);
 154             my $oldconf = PVE::LXC::parse_pct_config("/lxc/$vmid.conf", $raw);
 155
 156             foreach my $key (keys %$oldconf) {
 157                 next if $key eq 'digest' || $key eq 'rootfs' || $key eq 'snapshots' || $key eq 'unprivileged';
 158                 next if $key =~ /^mp\d+$/; # don't recover mountpoints
 159                 $conf->{$key} = $oldconf->{$key} if !defined($conf->{$key});
 160             }
 161             unlink($pct_cfg_fn);
 162
 163             if (-f $pct_fwcfg_fn) {
 164                 PVE::Tools::file_copy($pct_fwcfg_fn, "/etc/pve/firewall/$vmid.fw");
 165                 unlink $pct_fwcfg_fn;
 166             }
 167
 168         } elsif (-f $ovz_cfg_fn) {
 169             print "###########################################################\n";
 170             print "Converting OpenVZ configuration to LXC.\n";
 171             print "Please check the configuration and reconfigure the network.\n";
 172             print "###########################################################\n";
 173
 174             my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 175             $conf->{ostype} = $lxc_setup->{conf}->{ostype};
 176             my $raw = PVE::Tools::file_get_contents($ovz_cfg_fn);
 177             my $oldconf = PVE::VZDump::ConvertOVZ::convert_ovz($raw);
 178             foreach my $key (keys %$oldconf) {
 179                 $conf->{$key} = $oldconf->{$key} if !defined($conf->{$key});
 180             }
 181             unlink($ovz_cfg_fn);
 182
 183         } else {
 184             print "###########################################################\n";
 185             print "Backup archive does not contain any configuration\n";
 186             print "###########################################################\n";
 187         }
 188     }
 189 }
 190
 191 sub create_rootfs {
 192     my ($storage_cfg, $vmid, $conf, $archive, $password, $restore, $no_unpack_error) = @_;
 193
 194     my $config_fn = PVE::LXC::config_file($vmid);
 195     if (-f $config_fn) {
 196         die "container exists" if !$restore; # just to be sure
 197
 198         my $old_conf = PVE::LXC::load_config($vmid);
 199
 200         # destroy old container volume
 201         PVE::LXC::destroy_lxc_container($storage_cfg, $vmid, $old_conf);
 202
 203         # do not copy all settings to restored container
 204         foreach my $opt (qw(rootfs digest snapshots arch ostype unprivileged)) {
 205             delete $old_conf->{$opt};
 206         }
 207         foreach my $opt (keys %$old_conf) {
 208             delete $old_conf->{$opt} if $opt =~ m/^mp\d+$/;
 209         }
 210
 211         PVE::LXC::update_pct_config($vmid, $conf, 0, $old_conf);
 212
 213         PVE::LXC::create_config($vmid, $conf);
 214
 215     } else {
 216
 217         PVE::LXC::create_config($vmid, $conf);
 218     }
 219
 220     eval {
 221         my $rootdir = PVE::LXC::mount_all($vmid, $storage_cfg, $conf);
 222         restore_and_configure($vmid, $archive, $rootdir, $conf, $password, $restore, $no_unpack_error);
 223     };
 224     my $err = $@;
 225     PVE::LXC::umount_all($vmid, $storage_cfg, $conf, $err ? 1 : 0);
 226     PVE::Storage::deactivate_volumes($storage_cfg, PVE::LXC::get_vm_volumes($conf));
 227     die $err if $err;
 228 }
 229
 230 1;